configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164
 165 ## For the times when you want to build Emacs but don't have
 166 ## a suitable makeinfo, and can live without the manuals.
 167 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 168 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 169
 170 dnl Can remove these in Emacs 24.
 171 AC_ARG_WITH([gtk],,
 172   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 173 specify a toolkit.])],,)
 174
 175 AC_ARG_WITH([gcc],,
 176   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 177 variable to specify a compiler.])],,)
 178
 179 AC_ARG_WITH([pkg-config-prog],dnl
 180 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 181                   [path to pkg-config for finding GTK and librsvg])])
 182 if test "X${with_pkg_config_prog}" != X; then
 183    if test "${with_pkg_config_prog}" != yes; then
 184       PKG_CONFIG="${with_pkg_config_prog}"
 185    fi
 186 fi
 187
 188 AC_ARG_WITH([gnustep-conf],dnl
 189 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 190 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 191   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 192 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 193      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 194
 195 AC_ARG_ENABLE(ns-self-contained,
 196 [AS_HELP_STRING([--disable-ns-self-contained],
 197                 [disable self contained build under NeXTstep])],
 198    EN_NS_SELF_CONTAINED=$enableval,
 199    EN_NS_SELF_CONTAINED=yes)
 200
 201 AC_ARG_ENABLE(asserts,
 202 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 203       USE_XASSERTS=$enableval,
 204       USE_XASSERTS=no)
 205
 206 AC_ARG_ENABLE(maintainer-mode,
 207 [AS_HELP_STRING([--enable-maintainer-mode],
 208                 [enable make rules and dependencies not useful (and sometimes
 209                  confusing) to the casual installer])],
 210       USE_MAINTAINER_MODE=$enableval,
 211       USE_MAINTAINER_MODE=no)
 212 if test $USE_MAINTAINER_MODE = yes; then
 213   MAINT=
 214 else
 215   MAINT=#
 216 fi
 217 AC_SUBST(MAINT)
 218
 219 AC_ARG_ENABLE(locallisppath,
 220 [AS_HELP_STRING([--enable-locallisppath=PATH],
 221                 [directories Emacs should search for lisp files specific
 222                  to this site])],
 223 if test "${enableval}" = "no"; then
 224   locallisppath=
 225 elif test "${enableval}" != "yes"; then
 226   locallisppath=${enableval}
 227 fi)
 228
 229 AC_ARG_ENABLE(checking,
 230 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 231                 [enable expensive run-time checks.  With LIST,
 232                  enable only specific categories of checks.
 233                  Categories are: all,yes,no.
 234                  Flags are: stringbytes, stringoverrun, stringfreelist,
 235                  xmallocoverrun, conslist])],
 236 [ac_checking_flags="${enableval}"],[])
 237 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 238 for check in $ac_checking_flags
 239 do
 240         case $check in
 241         # these set all the flags to specific states
 242         yes)            ac_enable_checking=1 ;;
 243         no)             ac_enable_checking= ;
 244                         ac_gc_check_stringbytes= ;
 245                         ac_gc_check_string_overrun= ;
 246                         ac_gc_check_string_free_list= ;
 247                         ac_xmalloc_overrun= ;
 248                         ac_gc_check_cons_list= ;;
 249         all)            ac_enable_checking=1 ;
 250                         ac_gc_check_stringbytes=1 ;
 251                         ac_gc_check_string_overrun=1 ;
 252                         ac_gc_check_string_free_list=1 ;
 253                         ac_xmalloc_overrun=1 ;
 254                         ac_gc_check_cons_list=1 ;;
 255         # these enable particular checks
 256         stringbytes)    ac_gc_check_stringbytes=1 ;;
 257         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 258         stringfreelist) ac_gc_check_string_free_list=1 ;;
 259         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 260         conslist)       ac_gc_check_cons_list=1 ;;
 261         *)      AC_MSG_ERROR(unknown check category $check) ;;
 262         esac
 263 done
 264 IFS="$ac_save_IFS"
 265
 266 if test x$ac_enable_checking != x ; then
 267   AC_DEFINE(ENABLE_CHECKING, 1,
 268 [Enable expensive run-time checking of data types?])
 269 fi
 270 if test x$ac_gc_check_stringbytes != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 272 [Define this temporarily to hunt a bug.  If defined, the size of
 273    strings is redundantly recorded in sdata structures so that it can
 274    be compared to the sizes recorded in Lisp strings.])
 275 fi
 276 if test x$ac_gc_check_stringoverrun != x ; then
 277   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 278 [Define this to check for short string overrun.])
 279 fi
 280 if test x$ac_gc_check_string_free_list != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 282 [Define this to check the string free list.])
 283 fi
 284 if test x$ac_xmalloc_overrun != x ; then
 285   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 286 [Define this to check for malloc buffer overrun.])
 287 fi
 288 if test x$ac_gc_check_cons_list != x ; then
 289   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 290 [Define this to check for errors in cons list.])
 291 fi
 292
 293 AC_ARG_ENABLE(profiling,
 294 [AS_HELP_STRING([--enable-profiling],
 295                 [build emacs with profiling support.
 296                  This might not work on all platforms])],
 297 [ac_enable_profiling="${enableval}"],[])
 298 if test x$ac_enable_profiling != x ; then
 299    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 300    PROFILING_LDFLAGS="-pg"
 301 else
 302    PROFILING_CFLAGS=
 303    PROFILING_LDFLAGS=
 304 fi
 305
 306 AC_ARG_ENABLE(autodepend,
 307 [AS_HELP_STRING([--enable-autodepend],
 308                 [automatically generate dependencies to .h-files.
 309                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 310                  found])],
 311 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 312
 313 #### Make srcdir absolute, if it isn't already.  It's important to
 314 #### avoid running the path through pwd unnecessarily, since pwd can
 315 #### give you automounter prefixes, which can go away.  We do all this
 316 #### so Emacs can find its files when run uninstalled.
 317 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 318 unset CDPATH
 319 case "${srcdir}" in
 320   /* ) ;;
 321   . )
 322     ## We may be able to use the $PWD environment variable to make this
 323     ## absolute.  But sometimes PWD is inaccurate.
 324     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 325     ## but that tested only for a well-formed and valid PWD,
 326     ## it did not object when PWD was well-formed and valid but just wrong.
 327     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 328     then
 329       srcdir="$PWD"
 330     else
 331       srcdir="`(cd ${srcdir}; pwd)`"
 332     fi
 333   ;;
 334   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 335 esac
 336
 337 #### Check if the source directory already has a configured system in it.
 338 if test `pwd` != `(cd ${srcdir} && pwd)` \
 339    && test -f "${srcdir}/src/config.h" ; then
 340   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 341    as a build directory right now; it has been configured in its own
 342    right.  To configure in another directory as well, you MUST
 343    use GNU make.  If you do not have GNU make, then you must
 344    now do `make distclean' in ${srcdir},
 345    and then run $0 again.]])
 346 fi
 347
 348 #### Given the configuration name, set machfile and opsysfile to the
 349 #### names of the m/*.h and s/*.h files we should use.
 350
 351 ### Canonicalize the configuration name.
 352
 353 AC_CANONICAL_HOST
 354 canonical=$host
 355 configuration=${host_alias-${build_alias-$host}}
 356
 357 dnl This used to use changequote, but, apart from `changequote is evil'
 358 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 359 dnl the great gob of text.  Thus it's not processed for possible expansion.
 360 dnl Just make sure the brackets remain balanced.
 361 dnl
 362 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 363 dnl indicated by comments.
 364 dnl quotation begins
 365 [
 366
 367 ### If you add support for a new configuration, add code to this
 368 ### switch statement to recognize your configuration name and select
 369 ### the appropriate operating system and machine description files.
 370
 371 ### You would hope that you could choose an m/*.h file pretty much
 372 ### based on the machine portion of the configuration name, and an s-
 373 ### file based on the operating system portion.  However, it turns out
 374 ### that each m/*.h file is pretty manufacturer-specific - for
 375 ### example mips.h is MIPS
 376 ### So we basically have to have a special case for each
 377 ### configuration name.
 378 ###
 379 ### As far as handling version numbers on operating systems is
 380 ### concerned, make sure things will fail in a fixable way.  If
 381 ### /etc/MACHINES doesn't say anything about version numbers, be
 382 ### prepared to handle anything reasonably.  If version numbers
 383 ### matter, be sure /etc/MACHINES says something about it.
 384 ###
 385 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 386 ### "System V Release 4"; he writes, "The old convention encouraged
 387 ### confusion between `system' and `release' levels'."
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*-*-freebsd*)        machine=alpha ;;
 397       arm*-*-freebsd*)          machine=arm ;;
 398       ia64-*-freebsd*)          machine=ia64 ;;
 399       sparc-*-freebsd*)         machine=sparc ;;
 400       sparc64-*-freebsd*)       machine=sparc ;;
 401       powerpc-*-freebsd*)       machine=macppc ;;
 402       i[3456]86-*-freebsd*)     machine=intel386 ;;
 403       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*-*-kfreebsd*)       machine=alpha ;;
 412       ia64-*-kfreebsd*)         machine=ia64 ;;
 413       sparc-*-kfreebsd*)        machine=sparc ;;
 414       sparc64-*-kfreebsd*)      machine=sparc ;;
 415       powerpc-*-kfreebsd*)      machine=macppc ;;
 416       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 417       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     if test -f /usr/lib/crti.o; then]
 425 dnl The close and open brackets here are because this section is quoted --
 426 dnl see the `changequote' comment above.
 427       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 428 [   fi
 429
 430     case "${canonical}" in
 431       alpha*-*-netbsd*) machine=alpha ;;
 432       i[3456]86-*-netbsd*) machine=intel386 ;;
 433       mips-*-netbsd*)   machine=mips ;;
 434       mipsel-*-netbsd*) machine=mips ;;
 435       mipseb-*-netbsd*) machine=mips ;;
 436       powerpc-*-netbsd*) machine=macppc ;;
 437       sparc*-*-netbsd*) machine=sparc ;;
 438       vax-*-netbsd*)    machine=vax ;;
 439       arm-*-netbsd*)    machine=arm ;;
 440       x86_64-*-netbsd*) machine=amdx86-64 ;;
 441       hppa-*-netbsd*)   machine=hp800 ;;
 442       m68k-*-netbsd*)   machine=m68k ;;
 443     esac
 444   ;;
 445
 446   ## OpenBSD ports
 447   *-*-openbsd* )
 448     opsys=openbsd
 449     case "${canonical}" in
 450       alpha*-*-openbsd*)        machine=alpha ;;
 451       arm-*-openbsd*)          machine=arm ;;
 452       i386-*-openbsd*)         machine=intel386 ;;
 453       powerpc-*-openbsd*)      machine=macppc ;;
 454       sparc*-*-openbsd*)       machine=sparc ;;
 455       vax-*-openbsd*)          machine=vax ;;
 456       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 457       hppa-*-openbsd*)         machine=hp800 ;;
 458     esac
 459   ;;
 460
 461   alpha*-*-linux-gnu* )
 462     machine=alpha opsys=gnu-linux
 463   ;;
 464
 465   arm*-*-linux-gnu* )
 466     machine=arm opsys=gnu-linux
 467   ;;
 468
 469   ## Apple Darwin / Mac OS X
 470   *-apple-darwin* )
 471     case "${canonical}" in
 472       i[3456]86-* )  machine=intel386 ;;
 473       powerpc-* )    machine=macppc ;;
 474       x86_64-* )     machine=amdx86-64 ;;
 475       * )            unported=yes ;;
 476     esac
 477     opsys=darwin
 478     # Define CPP as follows to make autoconf work correctly.
 479     CPP="${CC-cc} -E -no-cpp-precomp"
 480     # Use fink packages if available.
 481     if test -d /sw/include && test -d /sw/lib; then
 482       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 483       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 484       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 485     fi
 486   ;;
 487
 488   ## HP 9000 series 700 and 800, running HP/UX
 489   hppa*-hp-hpux10.2* )
 490     machine=hp800 opsys=hpux10-20
 491   ;;
 492   hppa*-hp-hpux1[1-9]* )
 493     machine=hp800 opsys=hpux11
 494     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 495   ;;
 496
 497   hppa*-*-linux-gnu* )
 498     machine=hp800 opsys=gnu-linux
 499   ;;
 500
 501   ## IBM machines
 502   s390-*-linux-gnu* )
 503     machine=ibms390 opsys=gnu-linux
 504   ;;
 505   s390x-*-linux-gnu* )
 506     machine=ibms390x opsys=gnu-linux
 507   ;;
 508   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 515     machine=ibmrs6000 opsys=aix4-2
 516   ;;
 517   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520
 521   ## Macintosh PowerPC
 522   powerpc*-*-linux-gnu* )
 523     machine=macppc opsys=gnu-linux
 524   ;;
 525
 526   ## Silicon Graphics machines
 527   ## Iris 4D
 528   mips-sgi-irix6.5 )
 529     machine=iris4d opsys=irix6-5
 530     # Without defining _LANGUAGE_C, things get masked out in the headers
 531     # so that, for instance, grepping for `free' in stdlib.h fails and
 532     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 533     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 534     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 535   ;;
 536
 537   ## Suns
 538   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 539     machine=sparc opsys=gnu-linux
 540   ;;
 541
 542   *-sun-solaris* \
 543     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 544     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 545     case "${canonical}" in
 546       i[3456]86-*-* )     machine=intel386 ;;
 547       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 548       sparc* )          machine=sparc ;;
 549       * )               unported=yes ;;
 550     esac
 551     case "${canonical}" in
 552       *-sunos5.6* | *-solaris2.6* )
 553                 opsys=sol2-6
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 RANLIB="ar -ts"
 556                 ;;
 557       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 558                 opsys=sol2-6
 559                 emacs_check_sunpro_c=yes
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 ;;
 562       *-sunos5* | *-solaris* )
 563                 opsys=sol2-10
 564                 emacs_check_sunpro_c=yes
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 ;;
 567     esac
 568     ## Watch out for a compiler that we know will not work.
 569     case "${canonical}" in
 570      *-solaris* | *-sunos5* )
 571                 if [ "x$CC" = x/usr/ucb/cc ]; then
 572                   ## /usr/ucb/cc doesn't work;
 573                   ## we should find some other compiler that does work.
 574                   unset CC
 575                 fi
 576                 ;;
 577       *) ;;
 578     esac
 579   ;;
 580
 581   ## IA-64
 582   ia64*-*-linux* )
 583     machine=ia64 opsys=gnu-linux
 584   ;;
 585
 586   ## Intel 386 machines where we don't care about the manufacturer
 587   i[3456]86-*-* )
 588     machine=intel386
 589     case "${canonical}" in
 590       *-cygwin )                opsys=cygwin ;;
 591       *-darwin* )               opsys=darwin
 592                                 CPP="${CC-cc} -E -no-cpp-precomp"
 593                                 ;;
 594       *-linux-gnu* )            opsys=gnu-linux ;;
 595       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 596       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 599     esac
 600   ;;
 601
 602   ## m68k Linux-based GNU system
 603   m68k-*-linux-gnu* )
 604     machine=m68k opsys=gnu-linux
 605   ;;
 606
 607   ## Mips Linux-based GNU system
 608   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 609     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 610     machine=mips opsys=gnu-linux
 611   ;;
 612
 613   ## AMD x86-64 Linux-based GNU system
 614   x86_64-*-linux-gnu* )
 615     machine=amdx86-64 opsys=gnu-linux
 616   ;;
 617
 618   ## Tensilica Xtensa Linux-based GNU system
 619   xtensa*-*-linux-gnu* )
 620     machine=xtensa opsys=gnu-linux
 621     ;;
 622
 623   ## SuperH Linux-based GNU system
 624   sh[34]*-*-linux-gnu* )
 625     machine=sh3 opsys=gnu-linux
 626   ;;
 627
 628   * )
 629     unported=yes
 630   ;;
 631 esac
 632
 633 ### If the code above didn't choose an operating system, just choose
 634 ### an operating system based on the configuration name.  You really
 635 ### only want to use this when you have no idea what the right
 636 ### operating system is; if you know what operating systems a machine
 637 ### runs, it's cleaner to make it explicit in the case statement
 638 ### above.
 639 if test x"${opsys}" = x; then
 640   case "${canonical}" in
 641     *-gnu* )                            opsys=gnu ;;
 642     * )
 643       unported=yes
 644     ;;
 645   esac
 646 fi
 647
 648 ]
 649 dnl quotation ends
 650
 651 if test $unported = yes; then
 652   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 653 Check `etc/MACHINES' for recognized configuration names.])
 654 fi
 655
 656 machfile="m/${machine}.h"
 657 opsysfile="s/${opsys}.h"
 658
 659
 660 #### Choose a compiler.
 661 test -n "$CC" && cc_specified=yes
 662
 663 # Save the value of CFLAGS that the user specified.
 664 SPECIFIED_CFLAGS="$CFLAGS"
 665
 666 dnl Sets GCC=yes if using gcc.
 667 AC_PROG_CC
 668
 669 # On Suns, sometimes $CPP names a directory.
 670 if test -n "$CPP" && test -d "$CPP"; then
 671   CPP=
 672 fi
 673
 674 ## If not using gcc, and on Solaris, and no CPP specified, see if
 675 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 676 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 677  test x"$CPP" = x; then
 678   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 679   AC_CACHE_VAL(emacs_cv_sunpro_c,
 680   [AC_TRY_LINK([],
 681 [#ifndef __SUNPRO_C
 682 fail;
 683 #endif
 684 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 685   AC_MSG_RESULT($emacs_cv_sunpro_c)
 686
 687   if test x"$emacs_cv_sunpro_c" = xyes; then
 688     NON_GNU_CPP="$CC -E -Xs"
 689   fi
 690 fi
 691
 692 #### Some systems specify a CPP to use unless we are using GCC.
 693 #### Now that we know whether we are using GCC, we can decide whether
 694 #### to use that one.
 695 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 696 then
 697   CPP="$NON_GNU_CPP"
 698 fi
 699
 700 #### Some systems specify a CC to use unless we are using GCC.
 701 #### Now that we know whether we are using GCC, we can decide whether
 702 #### to use that one.
 703 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 704   test x$cc_specified != xyes
 705 then
 706   CC="$NON_GNU_CC"
 707 fi
 708
 709 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 710 then
 711   CC="$CC $GCC_TEST_OPTIONS"
 712 fi
 713
 714 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 715 then
 716   CC="$CC $NON_GCC_TEST_OPTIONS"
 717 fi
 718
 719 dnl checks for Unix variants
 720 AC_USE_SYSTEM_EXTENSIONS
 721
 722 ### Use -Wno-pointer-sign if the compiler supports it
 723 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 724 SAVE_CFLAGS="$CFLAGS"
 725 CFLAGS="$CFLAGS -Wno-pointer-sign"
 726 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 727 if test $has_option = yes; then
 728    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 729 fi
 730 AC_MSG_RESULT($has_option)
 731 CFLAGS="$SAVE_CFLAGS"
 732 unset has_option
 733 unset SAVE_CFLAGS
 734
 735 ### Use -Wdeclaration-after-statement if the compiler supports it
 736 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 737 SAVE_CFLAGS="$CFLAGS"
 738 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 739 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 740 if test $has_option = yes; then
 741    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 742 fi
 743 AC_MSG_RESULT($has_option)
 744 CFLAGS="$SAVE_CFLAGS"
 745 unset has_option
 746 unset SAVE_CFLAGS
 747
 748 #### Some other nice autoconf tests.
 749
 750 dnl checks for programs
 751 AC_PROG_LN_S
 752 AC_PROG_CPP
 753 AC_PROG_INSTALL
 754 if test "x$RANLIB" = x; then
 755   AC_PROG_RANLIB
 756 fi
 757 AC_PATH_PROG(INSTALL_INFO, install-info)
 758 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 759 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 760 dnl Don't use GZIP, which is used by gzip for additional parameters.
 761 AC_PATH_PROG(GZIP_PROG, gzip)
 762
 763
 764 ## Need makeinfo >= 4.6 (?) to build the manuals.
 765 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 766 dnl By this stage, configure has already checked for egrep and set EGREP,
 767 dnl or exited with an error if no egrep was found.
 768 if test "$MAKEINFO" != "no" && \
 769   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 770    MAKEINFO=no
 771 fi
 772
 773 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 774 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 775 ## therefore in the category of "special tools" not normally required, which
 776 ## configure does not have to check for (eg autoconf itself).
 777 ## In a Bazaar checkout on the other hand, the manuals are not included.
 778 ## So makeinfo is a requirement to build from Bazaar, and configure
 779 ## should test for it as it does for any other build requirement.
 780 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 781 ## with pre-built manuals, from a Bazaar checkout.
 782 if test "$MAKEINFO" = "no"; then
 783   if test "x${with_makeinfo}" = "xno"; then
 784     MAKEINFO=off
 785   elif ! test -e $srcdir/info/emacs; then
 786     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 787 source tree does not seem to have pre-built manuals in the `info' directory.
 788 Either install a suitable version of makeinfo, or re-run configure
 789 with the `--without-makeinfo' option to build without the manuals.] )
 790   fi
 791 fi
 792
 793 dnl Add our options to ac_link now, after it is set up.
 794
 795 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 796 then
 797   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 798 fi
 799
 800 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 801 then
 802   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 803 fi
 804
 805 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 806 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 807 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 808 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 809 dnl if not built to support GNU ld.
 810
 811 late_LDFLAGS=$LDFLAGS
 812 if test "$GCC" = yes; then
 813   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 814 else
 815   LDFLAGS="$LDFLAGS -znocombreloc"
 816 fi
 817
 818 AC_MSG_CHECKING([for -znocombreloc])
 819 AC_LINK_IFELSE([main(){return 0;}],
 820   [AC_MSG_RESULT(yes)],
 821   LDFLAGS=$late_LDFLAGS
 822   [AC_MSG_RESULT(no)])
 823
 824 #### Extract some information from the operating system and machine files.
 825
 826 AC_CHECKING([the machine- and system-dependent files to find out
 827  - which libraries the lib-src programs will want, and
 828  - whether the GNU malloc routines are usable])
 829
 830 ### First figure out CFLAGS (which we use for running the compiler here)
 831 ### and REAL_CFLAGS (which we use for real compilation).
 832 ### The two are the same except on a few systems, where they are made
 833 ### different to work around various lossages.  For example,
 834 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 835 ### as implying static linking.
 836
 837 ### If the CFLAGS env var is specified, we use that value
 838 ### instead of the default.
 839
 840 ### It's not important that this name contain the PID; you can't run
 841 ### two configures in the same directory and have anything work
 842 ### anyway.
 843 tempcname="conftest.c"
 844
 845 echo '
 846 #include "'${srcdir}'/src/'${opsysfile}'"
 847 #include "'${srcdir}'/src/'${machfile}'"
 848 #ifndef LIBS_MACHINE
 849 #define LIBS_MACHINE
 850 #endif
 851 #ifndef LIBS_SYSTEM
 852 #define LIBS_SYSTEM
 853 #endif
 854 #ifndef C_SWITCH_SYSTEM
 855 #define C_SWITCH_SYSTEM
 856 #endif
 857 #ifndef C_SWITCH_MACHINE
 858 #define C_SWITCH_MACHINE
 859 #endif
 860 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 861 configure___ c_switch_system=C_SWITCH_SYSTEM
 862 configure___ c_switch_machine=C_SWITCH_MACHINE
 863
 864 #ifndef LIB_X11_LIB
 865 #define LIB_X11_LIB -lX11
 866 #endif
 867
 868 #ifndef LIBX11_SYSTEM
 869 #define LIBX11_SYSTEM
 870 #endif
 871 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 872
 873 #ifdef UNEXEC
 874 configure___ unexec=UNEXEC
 875 #else
 876 configure___ unexec=unexec.o
 877 #endif
 878
 879 #ifdef SYSTEM_MALLOC
 880 configure___ system_malloc=yes
 881 #else
 882 configure___ system_malloc=no
 883 #endif
 884
 885 #ifdef USE_MMAP_FOR_BUFFERS
 886 configure___ use_mmap_for_buffers=yes
 887 #else
 888 configure___ use_mmap_for_buffers=no
 889 #endif
 890
 891 #ifndef C_OPTIMIZE_SWITCH
 892 #ifdef __GNUC__
 893 #define C_OPTIMIZE_SWITCH -O2
 894 #else
 895 #define C_OPTIMIZE_SWITCH -O
 896 #endif
 897 #endif
 898
 899 #ifndef C_WARNINGS_SWITCH
 900 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 901 #endif
 902
 903 #ifndef LD_SWITCH_MACHINE
 904 #define LD_SWITCH_MACHINE
 905 #endif
 906
 907 #ifndef LD_SWITCH_SYSTEM
 908 #define LD_SWITCH_SYSTEM
 909 #endif
 910
 911 #ifndef LD_SWITCH_X_SITE_AUX
 912 #define LD_SWITCH_X_SITE_AUX
 913 #endif
 914
 915 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 916 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 917
 918 #ifdef THIS_IS_CONFIGURE
 919
 920 /* Get the CFLAGS for tests in configure.  */
 921 #ifdef __GNUC__
 922 configure___ CFLAGS=C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 923 #else
 924 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 925 #endif
 926
 927 #else /* not THIS_IS_CONFIGURE */
 928
 929 /* Get the CFLAGS for real compilation.  */
 930 #ifdef __GNUC__
 931 configure___ REAL_CFLAGS=C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 932 #else
 933 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 934 #endif
 935
 936 #endif /* not THIS_IS_CONFIGURE */
 937 ' > ${tempcname}
 938
 939 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 940
 941 # The value of CPP is a quoted variable reference, so we need to do this
 942 # to get its actual value...
 943 CPP=`eval "echo $CPP"`
 944 [eval `${CPP} -Isrc ${tempcname} \
 945        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 946 if test "x$SPECIFIED_CFLAGS" = x; then
 947   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 948          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 949 else
 950   REAL_CFLAGS="$CFLAGS"
 951 fi]
 952 rm ${tempcname}
 953
 954 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 955
 956 ### Make sure subsequent tests use flags consistent with the build flags.
 957
 958 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 959   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 960 else
 961   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 962 fi
 963
 964 dnl For AC_FUNC_GETLOADAVG, at least:
 965 AC_CONFIG_LIBOBJ_DIR(src)
 966
 967 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 968 AC_SYS_LARGEFILE
 969
 970
 971 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 972 ### be located in either /usr/lib64 or /usr/lib.
 973 ### In some rare cases, /usr/lib64 exists but does not contain the
 974 ### relevant files (bug#1287).  Hence test for crtn.o.
 975 case "${canonical}" in
 976   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 977     if test -e /usr/lib64/crtn.o; then
 978       AC_DEFINE(HAVE_LIB64_DIR, 1,
 979         [Define to 1 if the directory /usr/lib64 exists.])
 980 fi
 981 esac
 982
 983 dnl This function defintion taken from Gnome 2.0
 984 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 985 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 986 dnl also defines GSTUFF_PKG_ERRORS on error
 987 AC_DEFUN([PKG_CHECK_MODULES], [
 988   succeeded=no
 989
 990   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 991
 992   if test "$PKG_CONFIG" = "no" ; then
 993      ifelse([$4], , [AC_MSG_ERROR([
 994       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 995   else
 996      PKG_CONFIG_MIN_VERSION=0.9.0
 997      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 998         AC_MSG_CHECKING(for $2)
 999
1000         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1001             AC_MSG_RESULT(yes)
1002             succeeded=yes
1003
1004             AC_MSG_CHECKING($1_CFLAGS)
1005             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1006             AC_MSG_RESULT($$1_CFLAGS)
1007
1008             AC_MSG_CHECKING($1_LIBS)
1009             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1010             AC_MSG_RESULT($$1_LIBS)
1011         else
1012             AC_MSG_RESULT(no)
1013             $1_CFLAGS=""
1014             $1_LIBS=""
1015             ## If we have a custom action on failure, don't print errors, but
1016             ## do set a variable so people can do so.
1017             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1018             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1019         fi
1020
1021         AC_SUBST($1_CFLAGS)
1022         AC_SUBST($1_LIBS)
1023      else
1024         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1025         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1026      fi
1027   fi
1028
1029   if test $succeeded = yes; then
1030      ifelse([$3], , :, [$3])
1031   else
1032      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1033   fi
1034 ])
1035
1036
1037 if test "${with_sound}" != "no"; then
1038   # Sound support for GNU/Linux and the free BSDs.
1039   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1040   # Emulation library used on NetBSD.
1041   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1042   AC_SUBST(LIBSOUND)
1043
1044   ALSA_REQUIRED=1.0.0
1045   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1046   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1047   if test $HAVE_ALSA = yes; then
1048     SAVE_CFLAGS="$CFLAGS"
1049     SAVE_LDFLAGS="$LDFLAGS"
1050     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1051     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1052     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1053                     emacs_alsa_normal=yes,
1054                     emacs_alsa_normal=no)
1055     if test "$emacs_alsa_normal" != yes; then
1056       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1057                      [snd_lib_error_set_handler (0);],
1058                      emacs_alsa_subdir=yes,
1059                      emacs_alsa_subdir=no)
1060       if test "$emacs_alsa_subdir" != yes; then
1061         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1062       fi
1063       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1064     fi
1065
1066     CFLAGS="$SAVE_CFLAGS"
1067     LDFLAGS="$SAVE_LDFLAGS"
1068     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1069     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1070     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1071   fi
1072   AC_SUBST(CFLAGS_SOUND)
1073 fi
1074
1075 dnl checks for header files
1076 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1077   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1078   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1079   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1080   sys/utsname.h pwd.h utmp.h)
1081
1082 AC_MSG_CHECKING(if personality LINUX32 can be set)
1083 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1084                emacs_cv_personality_linux32=yes,
1085                emacs_cv_personality_linux32=no)
1086 AC_MSG_RESULT($emacs_cv_personality_linux32)
1087
1088 if test $emacs_cv_personality_linux32 = yes; then
1089   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1090             [Define to 1 if personality LINUX32 can be set.])
1091 fi
1092
1093 dnl On Solaris 8 there's a compilation warning for term.h because
1094 dnl it doesn't define `bool'.
1095 AC_CHECK_HEADERS(term.h, , , -)
1096 AC_HEADER_STDC
1097 AC_HEADER_TIME
1098 AC_CHECK_DECLS([sys_siglist])
1099 if test $ac_cv_have_decl_sys_siglist != yes; then
1100   # For Tru64, at least:
1101   AC_CHECK_DECLS([__sys_siglist])
1102   if test $ac_cv_have_decl___sys_siglist = yes; then
1103     AC_DEFINE(sys_siglist, __sys_siglist,
1104               [Define to any substitute for sys_siglist.])
1105   fi
1106 fi
1107 AC_HEADER_SYS_WAIT
1108
1109 dnl Some systems have utime.h but don't declare the struct anyplace.
1110 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1111 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1112 #include <sys/time.h>
1113 #include <time.h>
1114 #else
1115 #ifdef HAVE_SYS_TIME_H
1116 #include <sys/time.h>
1117 #else
1118 #include <time.h>
1119 #endif
1120 #endif
1121 #ifdef HAVE_UTIME_H
1122 #include <utime.h>
1123 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1124   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1125 if test $emacs_cv_struct_utimbuf = yes; then
1126   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1127 fi
1128
1129 dnl checks for typedefs
1130 AC_TYPE_SIGNAL
1131
1132 dnl Check for speed_t typedef.
1133 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1134   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1135     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1136 if test $emacs_cv_speed_t = yes; then
1137   AC_DEFINE(HAVE_SPEED_T, 1,
1138            [Define to 1 if `speed_t' is declared by <termios.h>.])
1139 fi
1140
1141 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1142 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1143 #include <sys/time.h>
1144 #include <time.h>
1145 #else
1146 #ifdef HAVE_SYS_TIME_H
1147 #include <sys/time.h>
1148 #else
1149 #include <time.h>
1150 #endif
1151 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1152   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1153 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1154 if test $emacs_cv_struct_timeval = yes; then
1155   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1156 fi
1157
1158 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1159 AC_TRY_COMPILE([#include <math.h>],
1160 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1161   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1162 HAVE_EXCEPTION=$emacs_cv_struct_exception
1163 if test $emacs_cv_struct_exception != yes; then
1164   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1165 fi
1166
1167 AC_CHECK_HEADERS(sys/socket.h)
1168 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1169 #if HAVE_SYS_SOCKET_H
1170 #include <sys/socket.h>
1171 #endif])
1172
1173 dnl checks for structure members
1174 AC_STRUCT_TM
1175 AC_STRUCT_TIMEZONE
1176 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1177                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1178                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1179                 [#include <time.h>])
1180 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1181                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1182                   struct ifreq.ifr_addr], , ,
1183                  [AC_INCLUDES_DEFAULT
1184 #if HAVE_SYS_SOCKET_H
1185 #include <sys/socket.h>
1186 #endif
1187 #if HAVE_NET_IF_H
1188 #include <net/if.h>
1189 #endif])
1190
1191 dnl checks for compiler characteristics
1192
1193 dnl Testing __STDC__ to determine prototype support isn't good enough.
1194 dnl DEC C, for instance, doesn't define it with default options, and
1195 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1196 dnl and void *.
1197 AC_C_PROTOTYPES
1198 AC_C_VOLATILE
1199 AC_C_CONST
1200 dnl This isn't useful because we can't turn on use of `inline' unless
1201 dnl the compiler groks `extern inline'.
1202 dnl AC_C_INLINE
1203 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1204   [AC_TRY_COMPILE(, [void * foo;],
1205                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1206 if test $emacs_cv_void_star = yes; then
1207   AC_DEFINE(POINTER_TYPE, void)
1208 else
1209   AC_DEFINE(POINTER_TYPE, char)
1210 fi
1211 AH_TEMPLATE(POINTER_TYPE,
1212             [Define as `void' if your compiler accepts `void *'; otherwise
1213              define as `char'.])dnl
1214
1215
1216
1217 dnl This could be used for targets which can have both byte sexes.
1218 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1219 dnl AC_C_BIGENDIAN
1220
1221 dnl check for Make feature
1222 AC_PROG_MAKE_SET
1223
1224 dnl check for GNU Make if we have GCC and autodepend is on.
1225 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1226    AC_MSG_CHECKING([whether we are using GNU Make])
1227    HAVE_GNU_MAKE=no
1228    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1229    if test "x$testval" != x; then
1230       HAVE_GNU_MAKE=yes
1231    else
1232       ac_enable_autodepend=no
1233    fi
1234    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1235    if test $HAVE_GNU_MAKE = yes; then
1236       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1237       SAVE_CFLAGS="$CFLAGS"
1238       CFLAGS="$CFLAGS -MMD -MF deps.d"
1239       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1240       CFLAGS="$SAVE_CFLAGS"
1241       test -f deps.d || ac_enable_autodepend=no
1242       rm -rf deps.d
1243       AC_MSG_RESULT([$ac_enable_autodepend])
1244    fi
1245    if test $ac_enable_autodepend = yes; then
1246       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1247    fi
1248 fi
1249
1250 dnl checks for operating system services
1251 AC_SYS_LONG_FILE_NAMES
1252
1253 #### Choose a window system.
1254
1255 AC_PATH_X
1256 if test "$no_x" = yes; then
1257   window_system=none
1258 else
1259   window_system=x11
1260 fi
1261
1262 ## Workaround for bug in autoconf <= 2.62.
1263 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1264 ## No need to do anything special for these standard directories.
1265 ## This is an experiment, take it out if it causes problems.
1266 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1267
1268    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1269
1270 fi
1271
1272 if test "${x_libraries}" != NONE; then
1273   if test -n "${x_libraries}"; then
1274     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1275     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1276   fi
1277   x_default_search_path=""
1278   x_search_path=${x_libraries}
1279   if test -z "${x_search_path}"; then
1280     x_search_path=/usr/lib
1281   fi
1282   for x_library in `echo ${x_search_path}: | \
1283                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1284     x_search_path="\
1285 ${x_library}/X11/%L/%T/%N%C%S:\
1286 ${x_library}/X11/%l/%T/%N%C%S:\
1287 ${x_library}/X11/%T/%N%C%S:\
1288 ${x_library}/X11/%L/%T/%N%S:\
1289 ${x_library}/X11/%l/%T/%N%S:\
1290 ${x_library}/X11/%T/%N%S"
1291     if test x"${x_default_search_path}" = x; then
1292       x_default_search_path=${x_search_path}
1293     else
1294       x_default_search_path="${x_search_path}:${x_default_search_path}"
1295     fi
1296   done
1297 fi
1298 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1299   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1300 fi
1301
1302 if test x"${x_includes}" = x; then
1303   bitmapdir=/usr/include/X11/bitmaps
1304 else
1305   # accumulate include directories that have X11 bitmap subdirectories
1306   bmd_acc="dummyval"
1307   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1308     if test -d "${bmd}/X11/bitmaps"; then
1309       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1310     fi
1311     if test -d "${bmd}/bitmaps"; then
1312       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1313     fi
1314   done
1315   if test ${bmd_acc} != "dummyval"; then
1316     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1317   fi
1318 fi
1319
1320 HAVE_NS=no
1321 NS_IMPL_COCOA=no
1322 NS_IMPL_GNUSTEP=no
1323 tmp_CPPFLAGS="$CPPFLAGS"
1324 tmp_CFLAGS="$CFLAGS"
1325 CPPFLAGS="$CPPFLAGS -x objective-c"
1326 CFLAGS="$CFLAGS -x objective-c"
1327 if test "${with_ns}" != no; then
1328   if test "${opsys}" = darwin; then
1329      NS_IMPL_COCOA=yes
1330      ns_appdir=`pwd`/nextstep/Emacs.app
1331      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1332      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1333      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1334   elif test -f $GNUSTEP_CONFIG_FILE; then
1335      NS_IMPL_GNUSTEP=yes
1336      ns_appdir=`pwd`/nextstep/Emacs.app
1337      ns_appbindir=`pwd`/nextstep/Emacs.app
1338      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1339      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1340      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1341      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1342      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1343      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1344      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1345      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1346      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1347      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1348   fi
1349   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1350                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1351   files are missing or cannot be compiled.])])
1352   NS_HAVE_NSINTEGER=yes
1353   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1354                                      [NSInteger i;])],
1355                     ns_have_nsinteger=yes,
1356                     ns_have_nsinteger=no)
1357   if test $ns_have_nsinteger = no; then
1358     NS_HAVE_NSINTEGER=no
1359   fi
1360 fi
1361 if test "${HAVE_NS}" = yes; then
1362   window_system=nextstep
1363   with_xft=no
1364   # set up packaging dirs
1365   exec_prefix=${ns_appbindir}
1366   libexecdir=${ns_appbindir}/libexec
1367   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1368      prefix=${ns_appresdir}
1369   fi
1370 fi
1371 CFLAGS="$tmp_CFLAGS"
1372 CPPFLAGS="$tmp_CPPFLAGS"
1373
1374 case "${window_system}" in
1375   x11 )
1376     HAVE_X_WINDOWS=yes
1377     HAVE_X11=yes
1378     case "${with_x_toolkit}" in
1379       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1380       motif ) USE_X_TOOLKIT=MOTIF ;;
1381       gtk ) with_gtk=yes
1382 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1383 dnl USE_X_TOOLKIT is set.
1384             USE_X_TOOLKIT=none ;;
1385       no ) USE_X_TOOLKIT=none ;;
1386 dnl If user did not say whether to use a toolkit, make this decision later:
1387 dnl use the toolkit if we have gtk, or X11R5 or newer.
1388       * ) USE_X_TOOLKIT=maybe ;;
1389     esac
1390   ;;
1391   nextstep | none )
1392     HAVE_X_WINDOWS=no
1393     HAVE_X11=no
1394     USE_X_TOOLKIT=none
1395   ;;
1396 esac
1397
1398 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1399    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1400    if test "$HAVE_XSERVER" = true ||
1401       test -n "$DISPLAY" ||
1402       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1403         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1404 were found.  You should install the relevant development files for X
1405 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1406 sure you have development files for image handling, i.e.
1407 tiff, gif, jpeg, png and xpm.
1408 If you are sure you want Emacs compiled without X window support, pass
1409   --without-x
1410 to configure.])
1411    fi
1412 fi
1413
1414 ### If we're using X11, we should use the X menu package.
1415 HAVE_MENUS=no
1416 case ${HAVE_X11} in
1417   yes ) HAVE_MENUS=yes ;;
1418 esac
1419
1420 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1421 # Assume not, until told otherwise.
1422 GNU_MALLOC=yes
1423 doug_lea_malloc=yes
1424 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1425 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1426 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1427                emacs_cv_var___after_morecore_hook,
1428 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1429   emacs_cv_var___after_morecore_hook=yes,
1430   emacs_cv_var___after_morecore_hook=no)])
1431 if test $emacs_cv_var___after_morecore_hook = no; then
1432   doug_lea_malloc=no
1433 fi
1434 if test "${system_malloc}" = "yes"; then
1435   GNU_MALLOC=no
1436   GNU_MALLOC_reason="
1437     (The GNU allocators don't work with this system configuration.)"
1438 fi
1439 if test "$doug_lea_malloc" = "yes" ; then
1440   if test "$GNU_MALLOC" = yes ; then
1441     GNU_MALLOC_reason="
1442       (Using Doug Lea's new malloc from the GNU C Library.)"
1443   fi
1444   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1445             [Define to 1 if you are using the GNU C Library.])
1446 fi
1447
1448 if test x"${REL_ALLOC}" = x; then
1449   REL_ALLOC=${GNU_MALLOC}
1450 fi
1451
1452 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1453 dnl the system configuration file (s/*.h) to turn the use of mmap
1454 dnl in the relocating allocator on.
1455
1456 AC_FUNC_MMAP
1457 if test $use_mmap_for_buffers = yes; then
1458   REL_ALLOC=no
1459 fi
1460
1461 LIBS="$libsrc_libs $LIBS"
1462
1463 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1464 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1465 AC_CHECK_LIB(dnet, dnet_ntoa)
1466 dnl This causes -lresolv to get used in subsequent tests,
1467 dnl which causes failures on some systems such as HPUX 9.
1468 dnl AC_CHECK_LIB(resolv, gethostbyname)
1469
1470 dnl FIXME replace main with a function we actually want from this library.
1471 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1472
1473 AC_CHECK_LIB(pthreads, cma_open)
1474
1475 dnl Check for need for bigtoc support on IBM AIX
1476
1477 case ${host_os} in
1478 aix*)
1479   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1480     case $GCC in
1481     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1482     *) gdb_cv_bigtoc=-bbigtoc ;;
1483     esac
1484
1485     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1486     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1487   ])
1488   ;;
1489 esac
1490
1491 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1492 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1493 # REAL_CPPFLAGS later on.
1494
1495 REAL_CPPFLAGS="$CPPFLAGS"
1496
1497 if test "${HAVE_X11}" = "yes"; then
1498   DEFS="$C_SWITCH_X_SITE $DEFS"
1499   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1500   LIBS="$LIBX $LIBS"
1501   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1502   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1503
1504   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1505   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1506   # but it's more convenient here to set LD_RUN_PATH
1507   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1508   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1509     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1510     export LD_RUN_PATH
1511   fi
1512
1513   if test "${opsys}" = "gnu-linux"; then
1514     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1515     AC_TRY_LINK([],
1516      [XOpenDisplay ("foo");],
1517      [xlinux_first_failure=no],
1518      [xlinux_first_failure=yes])
1519     if test "${xlinux_first_failure}" = "yes"; then
1520       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1521       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1522       OLD_CPPFLAGS="$CPPFLAGS"
1523       OLD_LIBS="$LIBS"
1524       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1525       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1526       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1527       LIBS="$LIBS -b i486-linuxaout"
1528       AC_TRY_LINK([],
1529        [XOpenDisplay ("foo");],
1530        [xlinux_second_failure=no],
1531        [xlinux_second_failure=yes])
1532       if test "${xlinux_second_failure}" = "yes"; then
1533         # If we get the same failure with -b, there is no use adding -b.
1534         # So take it out.  This plays safe.
1535         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1536         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1537         CPPFLAGS="$OLD_CPPFLAGS"
1538         LIBS="$OLD_LIBS"
1539         AC_MSG_RESULT(no)
1540       else
1541         AC_MSG_RESULT(yes)
1542       fi
1543     else
1544       AC_MSG_RESULT(no)
1545     fi
1546   fi
1547
1548   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1549   # header files included from there.
1550   AC_MSG_CHECKING(for Xkb)
1551   AC_TRY_LINK([#include <X11/Xlib.h>
1552 #include <X11/XKBlib.h>],
1553         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1554         emacs_xkb=yes, emacs_xkb=no)
1555   AC_MSG_RESULT($emacs_xkb)
1556   if test $emacs_xkb = yes; then
1557     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1558   fi
1559
1560   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1561 XScreenNumberOfScreen XSetWMProtocols)
1562 fi
1563
1564 if test "${window_system}" = "x11"; then
1565   AC_MSG_CHECKING(X11 version 6)
1566   AC_CACHE_VAL(emacs_cv_x11_version_6,
1567   [AC_TRY_LINK([#include <X11/Xlib.h>],
1568 [#if XlibSpecificationRelease < 6
1569 fail;
1570 #endif
1571 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1572   if test $emacs_cv_x11_version_6 = yes; then
1573     AC_MSG_RESULT(6 or newer)
1574     AC_DEFINE(HAVE_X11R6, 1,
1575               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1576   else
1577     AC_MSG_RESULT(before 6)
1578   fi
1579 fi
1580
1581
1582 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1583 HAVE_RSVG=no
1584 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1585   if test "${with_rsvg}" != "no"; then
1586     RSVG_REQUIRED=2.11.0
1587     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1588
1589     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1590     AC_SUBST(RSVG_CFLAGS)
1591     AC_SUBST(RSVG_LIBS)
1592
1593     if test ".${RSVG_CFLAGS}" != "."; then
1594       HAVE_RSVG=yes
1595       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1596       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1597       LIBS="$RSVG_LIBS $LIBS"
1598     fi
1599   fi
1600 fi
1601
1602
1603 HAVE_GTK=no
1604 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1605   GLIB_REQUIRED=2.6
1606   GTK_REQUIRED=2.6
1607   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1608
1609   dnl Checks for libraries.
1610   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1611   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1612      AC_MSG_ERROR($GTK_PKG_ERRORS)
1613   fi
1614 fi
1615
1616
1617 if test x"$pkg_check_gtk" = xyes; then
1618
1619   AC_SUBST(GTK_CFLAGS)
1620   AC_SUBST(GTK_LIBS)
1621   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1622   CFLAGS="$CFLAGS $GTK_CFLAGS"
1623   LIBS="$GTK_LIBS $LIBS"
1624   dnl Try to compile a simple GTK program.
1625   GTK_COMPILES=no
1626   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1627   if test "${GTK_COMPILES}" != "yes"; then
1628     if test "$USE_X_TOOLKIT" != "maybe"; then
1629       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1630     fi
1631   else
1632     HAVE_GTK=yes
1633     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1634     USE_X_TOOLKIT=none
1635     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1636       :
1637     else
1638       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1639        closing open displays.  This is no problem if you just use
1640        one display, but if you use more than one and close one of them
1641        Emacs may crash.]])
1642       sleep 3
1643     fi
1644   fi
1645
1646 fi
1647
1648
1649 if test "${HAVE_GTK}" = "yes"; then
1650
1651   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1652   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1653   if test "$with_toolkit_scroll_bars" != no; then
1654     with_toolkit_scroll_bars=yes
1655   fi
1656
1657   dnl  Check if we can use multiple displays with this GTK version.
1658   dnl  If gdk_display_open exists, assume all others are there also.
1659   HAVE_GTK_MULTIDISPLAY=no
1660   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1661   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1662     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1663               [Define to 1 if GTK can handle more than one display.])
1664   fi
1665
1666   dnl  Check if we have the old file selection dialog declared and
1667   dnl  in the link library.  In 2.x it may be in the library,
1668   dnl  but not declared if deprecated featured has been selected out.
1669   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1670   HAVE_GTK_FILE_SELECTION=no
1671   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1672                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1673 #include <gtk/gtk.h>])
1674   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1675     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1676                    HAVE_GTK_FILE_SELECTION=no)
1677   fi
1678
1679   dnl  Check if we have the new file chooser dialog
1680   HAVE_GTK_FILE_CHOOSER=no
1681   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1682                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1683 #include <gtk/gtk.h>])
1684   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1685     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1686                    HAVE_GTK_FILE_CHOOSER=no)
1687   fi
1688
1689   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1690      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1691     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1692               [Define to 1 if GTK has both file selection and chooser dialog.])
1693   fi
1694
1695   dnl Check if pthreads are available.  Emacs only needs this when using
1696   dnl gtk_file_chooser under Gnome.
1697   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1698     HAVE_GTK_AND_PTHREAD=no
1699     AC_CHECK_HEADERS(pthread.h)
1700     if test "$ac_cv_header_pthread_h"; then
1701       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1702     fi
1703     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1704       case "${canonical}" in
1705         *-hpux*) ;;
1706         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1707       esac
1708       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1709                [Define to 1 if you have GTK and pthread (-lpthread).])
1710     fi
1711   fi
1712 fi
1713
1714 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1715 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1716 dnl also not configured.
1717 HAVE_DBUS=no
1718 if test "${with_dbus}" = "yes"; then
1719    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1720    if test "$HAVE_DBUS" = yes; then
1721      LIBS="$LIBS $DBUS_LIBS"
1722      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1723      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1724    fi
1725 fi
1726
1727 dnl GConf has been tested under GNU/Linux only.
1728 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1729 HAVE_GCONF=no
1730 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1731    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1732    if test "$HAVE_GCONF" = yes; then
1733       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1734    fi
1735 fi
1736
1737 dnl Do not put whitespace before the #include statements below.
1738 dnl Older compilers (eg sunos4 cc) choke on it.
1739 HAVE_XAW3D=no
1740 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1741   if test "$with_xaw3d" != no; then
1742     AC_MSG_CHECKING(for xaw3d)
1743     AC_CACHE_VAL(emacs_cv_xaw3d,
1744     [AC_TRY_LINK([
1745 #include <X11/Intrinsic.h>
1746 #include <X11/Xaw3d/Simple.h>],
1747       [],
1748       emacs_cv_xaw3d=yes,
1749       emacs_cv_xaw3d=no)])
1750   else
1751     emacs_cv_xaw3d=no
1752   fi
1753   if test $emacs_cv_xaw3d = yes; then
1754     AC_MSG_RESULT([yes; using Lucid toolkit])
1755     USE_X_TOOLKIT=LUCID
1756     HAVE_XAW3D=yes
1757     AC_DEFINE(HAVE_XAW3D, 1,
1758               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1759   else
1760     AC_MSG_RESULT(no)
1761     AC_MSG_CHECKING(for libXaw)
1762     AC_CACHE_VAL(emacs_cv_xaw,
1763     [AC_TRY_LINK([
1764 #include <X11/Intrinsic.h>
1765 #include <X11/Xaw/Simple.h>],
1766       [],
1767       emacs_cv_xaw=yes,
1768       emacs_cv_xaw=no)])
1769     if test $emacs_cv_xaw = yes; then
1770       AC_MSG_RESULT([yes; using Lucid toolkit])
1771       USE_X_TOOLKIT=LUCID
1772     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1773       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1774     else
1775       AC_MSG_RESULT([no; do not use toolkit by default])
1776       USE_X_TOOLKIT=none
1777     fi
1778   fi
1779 fi
1780
1781 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1782
1783 if test "${USE_X_TOOLKIT}" != "none"; then
1784   AC_MSG_CHECKING(X11 toolkit version)
1785   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1786   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1787 [#if XtSpecificationRelease < 6
1788 fail;
1789 #endif
1790 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1791   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1792   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1793     AC_MSG_RESULT(6 or newer)
1794     AC_DEFINE(HAVE_X11XTR6, 1,
1795               [Define to 1 if you have the X11R6 or newer version of Xt.])
1796   else
1797     AC_MSG_RESULT(before 6)
1798   fi
1799
1800 dnl If using toolkit, check whether libXmu.a exists.
1801 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1802   OLDLIBS="$LIBS"
1803   if test x$HAVE_X11XTR6 = xyes; then
1804     LIBS="-lXt -lSM -lICE $LIBS"
1805   else
1806     LIBS="-lXt $LIBS"
1807   fi
1808   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1809   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1810 fi
1811
1812 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1813 if test "${HAVE_X11}" = "yes"; then
1814   if test "${USE_X_TOOLKIT}" != "none"; then
1815     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1816   fi
1817 fi
1818
1819 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1820   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1821   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1822     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1823 int x = 5;
1824 #else
1825 Motif version prior to 2.1.
1826 #endif],
1827     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1828   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1829   if test $emacs_cv_motif_version_2_1 = yes; then
1830     HAVE_LIBXP=no
1831     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1832               [Define to 1 if you have Motif 2.1 or newer.])
1833     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1834     if test ${HAVE_LIBXP} = yes; then
1835       AC_DEFINE(HAVE_LIBXP, 1,
1836                 [Define to 1 if you have the Xp library (-lXp).])
1837     fi
1838   else
1839     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1840     # We put this in CFLAGS temporarily to precede other -I options
1841     # that might be in CFLAGS temporarily.
1842     # We put this in CPPFLAGS where it precedes the other -I options.
1843     OLD_CPPFLAGS=$CPPFLAGS
1844     OLD_CFLAGS=$CFLAGS
1845     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1846     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1847     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1848       [int x = 5;],
1849       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1850     if test $emacs_cv_lesstif = yes; then
1851       # Make sure this -I option remains in CPPFLAGS after it is set
1852       # back to REAL_CPPFLAGS.
1853       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1854       # have those other -I options anyway.  Ultimately, having this
1855       # directory ultimately in CPPFLAGS will be enough.
1856       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1857       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1858     else
1859       CFLAGS=$OLD_CFLAGS
1860       CPPFLAGS=$OLD_CPPFLAGS
1861     fi
1862   fi
1863 fi
1864
1865 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1866 dnl using Motif or Xaw3d is available, and unless
1867 dnl --with-toolkit-scroll-bars=no was specified.
1868
1869 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1870             [Define to 1 if we should use toolkit scroll bars.])dnl
1871 USE_TOOLKIT_SCROLL_BARS=no
1872 if test "${with_toolkit_scroll_bars}" != "no"; then
1873   if test "${USE_X_TOOLKIT}" != "none"; then
1874     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1875       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1876       HAVE_XAW3D=no
1877       USE_TOOLKIT_SCROLL_BARS=yes
1878     elif test "${HAVE_XAW3D}" = "yes"; then
1879       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1880       USE_TOOLKIT_SCROLL_BARS=yes
1881     fi
1882   elif test "${HAVE_GTK}" = "yes"; then
1883     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1884     USE_TOOLKIT_SCROLL_BARS=yes
1885   elif test "${HAVE_NS}" = "yes"; then
1886     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1887     USE_TOOLKIT_SCROLL_BARS=yes
1888   fi
1889 fi
1890
1891 dnl See if XIM is available.
1892 AC_TRY_COMPILE([
1893           #include <X11/Xlib.h>
1894           #include <X11/Xresource.h>],
1895          [XIMProc  callback;],
1896          [HAVE_XIM=yes
1897          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1898          HAVE_XIM=no)
1899
1900 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1901
1902 if test "${with_xim}" != "no"; then
1903   AC_DEFINE(USE_XIM, 1,
1904             [Define to 1 if we should use XIM, if it is available.])
1905 fi
1906
1907
1908 if test "${HAVE_XIM}" != "no"; then
1909   late_CFLAGS=$CFLAGS
1910   if test "$GCC" = yes; then
1911     CFLAGS="$CFLAGS --pedantic-errors"
1912   fi
1913   AC_TRY_COMPILE([
1914 #include <X11/Xlib.h>
1915 #include <X11/Xresource.h>],
1916 [Display *display;
1917 XrmDatabase db;
1918 char *res_name;
1919 char *res_class;
1920 XIMProc  callback;
1921 XPointer *client_data;
1922 #ifndef __GNUC__
1923 /* If we're not using GCC, it's probably not XFree86, and this is
1924    probably right, but we can't use something like --pedantic-errors.  */
1925 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1926                                            char*, XIMProc, XPointer*);
1927 #endif
1928 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1929    client_data);],
1930     [emacs_cv_arg6_star=yes])
1931   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1932          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1933 either XPointer or XPointer*.])dnl
1934   if test "$emacs_cv_arg6_star" = yes; then
1935     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1936   else
1937     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1938   fi
1939   CFLAGS=$late_CFLAGS
1940 fi
1941
1942 ### Start of font-backend (under any platform) section.
1943 # (nothing here yet -- this is a placeholder)
1944 ### End of font-backend (under any platform) section.
1945
1946 ### Start of font-backend (under X11) section.
1947 if test "${HAVE_X11}" = "yes"; then
1948    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1949
1950    ## Use -lXft if available, unless `--with-xft=no'.
1951    HAVE_XFT=maybe
1952     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1953       with_xft="no";
1954     fi
1955     if test "x${with_xft}" != "xno"; then
1956
1957       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1958       ## Because xftfont.c uses XRenderQueryExtension, we also
1959       ## need to link to -lXrender.
1960       HAVE_XRENDER=no
1961       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
1962       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
1963         OLD_CPPFLAGS="$CPPFLAGS"
1964         OLD_CFLAGS="$CFLAGS"
1965         OLD_LIBS="$LIBS"
1966         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1967         CFLAGS="$CFLAGS $XFT_CFLAGS"
1968         XFT_LIBS="-lXrender $XFT_LIBS"
1969         LIBS="$XFT_LIBS $LIBS"
1970         AC_CHECK_HEADER(X11/Xft/Xft.h,
1971           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1972
1973         if test "${HAVE_XFT}" = "yes"; then
1974           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1975             AC_SUBST(XFT_LIBS)
1976           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1977         else
1978           CPPFLAGS="$OLD_CPPFLAGS"
1979           CFLAGS="$OLD_CFLAGS"
1980           LIBS="$OLD_LIBS"
1981         fi                        # "${HAVE_XFT}" = "yes"
1982       fi                          # "$HAVE_XFT" != no
1983     fi                            # "x${with_xft}" != "xno"
1984
1985     dnl For the "Does Emacs use" message at the end.
1986     if test "$HAVE_XFT" != "yes"; then
1987        HAVE_XFT=no
1988     fi
1989
1990
1991     HAVE_FREETYPE=no
1992     ## We used to allow building with FreeType and without Xft.
1993     ## However, the ftx font backend driver is not in good shape.
1994     if test "${HAVE_XFT}" = "yes"; then
1995       dnl As we use Xft, we anyway use freetype.
1996       dnl There's no need for additional CFLAGS and LIBS.
1997       HAVE_FREETYPE=yes
1998       FONTCONFIG_CFLAGS=
1999       FONTCONFIG_LIBS=
2000     fi
2001
2002     HAVE_LIBOTF=no
2003     if test "${HAVE_FREETYPE}" = "yes"; then
2004       AC_DEFINE(HAVE_FREETYPE, 1,
2005                 [Define to 1 if using the freetype and fontconfig libraries.])
2006       if test "${with_libotf}" != "no"; then
2007         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2008                           HAVE_LIBOTF=no)
2009         if test "$HAVE_LIBOTF" = "yes"; then
2010           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2011           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2012                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2013                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2014           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2015             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2016                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2017           fi
2018         fi
2019       fi
2020     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2021     dnl Does the new font backend require it, or can it work without it?
2022     fi
2023
2024     HAVE_M17N_FLT=no
2025     if test "${HAVE_LIBOTF}" = yes; then
2026       if test "${with_m17n_flt}" != "no"; then
2027         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2028         if test "$HAVE_M17N_FLT" = "yes"; then
2029           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2030         fi
2031       fi
2032     fi
2033 else
2034     HAVE_XFT=no
2035     HAVE_FREETYPE=no
2036     HAVE_LIBOTF=no
2037     HAVE_M17N_FLT=no
2038 fi
2039 ### End of font-backend (under X11) section.
2040
2041 AC_SUBST(FREETYPE_CFLAGS)
2042 AC_SUBST(FREETYPE_LIBS)
2043 AC_SUBST(FONTCONFIG_CFLAGS)
2044 AC_SUBST(FONTCONFIG_LIBS)
2045 AC_SUBST(LIBOTF_CFLAGS)
2046 AC_SUBST(LIBOTF_LIBS)
2047 AC_SUBST(M17N_FLT_CFLAGS)
2048 AC_SUBST(M17N_FLT_LIBS)
2049
2050 ### Use -lXpm if available, unless `--with-xpm=no'.
2051 HAVE_XPM=no
2052 LIBXPM=
2053 if test "${HAVE_X11}" = "yes"; then
2054   if test "${with_xpm}" != "no"; then
2055     AC_CHECK_HEADER(X11/xpm.h,
2056       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2057     if test "${HAVE_XPM}" = "yes"; then
2058       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2059       AC_EGREP_CPP(no_return_alloc_pixels,
2060       [#include "X11/xpm.h"
2061 #ifndef XpmReturnAllocPixels
2062 no_return_alloc_pixels
2063 #endif
2064       ], HAVE_XPM=no, HAVE_XPM=yes)
2065
2066       if test "${HAVE_XPM}" = "yes"; then
2067         AC_MSG_RESULT(yes)
2068       else
2069         AC_MSG_RESULT(no)
2070       fi
2071     fi
2072   fi
2073
2074   if test "${HAVE_XPM}" = "yes"; then
2075     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2076     LIBXPM=-lXpm
2077   fi
2078 fi
2079 AC_SUBST(LIBXPM)
2080
2081 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2082 HAVE_JPEG=no
2083 LIBJPEG=
2084 if test "${HAVE_X11}" = "yes"; then
2085   if test "${with_jpeg}" != "no"; then
2086     dnl Checking for jpeglib.h can lose because of a redefinition of
2087     dnl  HAVE_STDLIB_H.
2088     AC_CHECK_HEADER(jerror.h,
2089       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2090   fi
2091
2092   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2093   if test "${HAVE_JPEG}" = "yes"; then
2094     AC_DEFINE(HAVE_JPEG)
2095     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2096         [#include <jpeglib.h>
2097          version=JPEG_LIB_VERSION
2098 ],
2099         [AC_DEFINE(HAVE_JPEG)],
2100         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2101         HAVE_JPEG=no])
2102   fi
2103   if test "${HAVE_JPEG}" = "yes"; then
2104     LIBJPEG=-ljpeg
2105   fi
2106 fi
2107 AC_SUBST(LIBJPEG)
2108
2109 ### Use -lpng if available, unless `--with-png=no'.
2110 HAVE_PNG=no
2111 LIBPNG=
2112 if test "${HAVE_X11}" = "yes"; then
2113   if test "${with_png}" != "no"; then
2114     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2115     # in /usr/include/libpng.
2116     AC_CHECK_HEADERS(png.h libpng/png.h)
2117     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2118       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2119     fi
2120   fi
2121
2122   if test "${HAVE_PNG}" = "yes"; then
2123     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2124     LIBPNG="-lpng -lz -lm"
2125   fi
2126 fi
2127 AC_SUBST(LIBPNG)
2128
2129 ### Use -ltiff if available, unless `--with-tiff=no'.
2130 HAVE_TIFF=no
2131 LIBTIFF=
2132 if test "${HAVE_X11}" = "yes"; then
2133   if test "${with_tiff}" != "no"; then
2134     AC_CHECK_HEADER(tiffio.h,
2135       [tifflibs="-lz -lm"
2136       # At least one tiff package requires the jpeg library.
2137       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2138       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2139   fi
2140
2141   if test "${HAVE_TIFF}" = "yes"; then
2142     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2143     dnl FIXME -lz -lm, as per libpng?
2144     LIBTIFF=-ltiff
2145   fi
2146 fi
2147 AC_SUBST(LIBTIFF)
2148
2149 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2150 HAVE_GIF=no
2151 LIBGIF=
2152 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2153   AC_CHECK_HEADER(gif_lib.h,
2154 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2155 # Earlier versions can crash Emacs.
2156     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2157
2158   if test "$HAVE_GIF" = yes; then
2159     LIBGIF=-lgif
2160   elif test "$HAVE_GIF" = maybe; then
2161 # If gif_lib.h but no libgif, try libungif.
2162     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2163     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2164   fi
2165
2166   if test "${HAVE_GIF}" = "yes"; then
2167     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2168   fi
2169 fi
2170 AC_SUBST(LIBGIF)
2171
2172 dnl Check for required libraries.
2173 if test "${HAVE_X11}" = "yes"; then
2174   MISSING=""
2175   WITH_NO=""
2176   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2177     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2178   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2179     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2180   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2181     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2182   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2183     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2184   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2185     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2186
2187   if test "X${MISSING}" != X; then
2188     AC_MSG_ERROR([The following required libraries were not found:
2189     $MISSING
2190 Maybe some development libraries/packages are missing?
2191 If you don't want to link with them give
2192     $WITH_NO
2193 as options to configure])
2194   fi
2195 fi
2196
2197 ### Use -lgpm if available, unless `--with-gpm=no'.
2198 HAVE_GPM=no
2199 LIBGPM=
2200 if test "${with_gpm}" != "no"; then
2201   AC_CHECK_HEADER(gpm.h,
2202     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2203
2204   if test "${HAVE_GPM}" = "yes"; then
2205     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2206     LIBGPM=-lgpm
2207   fi
2208 fi
2209 AC_SUBST(LIBGPM)
2210
2211 dnl Check for malloc/malloc.h on darwin
2212 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2213
2214 ### Use NeXTstep API to implement GUI.
2215 if test "${HAVE_NS}" = "yes"; then
2216   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2217   if test "${NS_IMPL_COCOA}" = "yes"; then
2218     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2219     GNU_OBJC_CFLAGS=
2220   fi
2221   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2222     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2223     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2224   fi
2225   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2226     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2227   fi
2228   # We also have mouse menus.
2229   HAVE_MENUS=yes
2230   OTHER_FILES=ns-app
2231 fi
2232
2233
2234 ### Use session management (-lSM -lICE) if available
2235 HAVE_X_SM=no
2236 if test "${HAVE_X11}" = "yes"; then
2237   AC_CHECK_HEADER(X11/SM/SMlib.h,
2238     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2239
2240   if test "${HAVE_X_SM}" = "yes"; then
2241     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2242     case "$LIBS" in
2243       *-lSM*) ;;
2244       *)      LIBS="-lSM -lICE $LIBS" ;;
2245     esac
2246   fi
2247 fi
2248
2249 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2250 AC_CACHE_CHECK(whether netdb declares h_errno,
2251                emacs_cv_netdb_declares_h_errno,
2252 [AC_TRY_LINK([#include <netdb.h>],
2253   [return h_errno;],
2254   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2255 if test $emacs_cv_netdb_declares_h_errno = yes; then
2256   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2257 fi
2258
2259 AC_FUNC_ALLOCA
2260
2261 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2262 dnl FIXME is there an autoconf test that does the right thing, without
2263 dnl needing to call A_M_E afterwards?
2264 if test x"$ac_cv_func_alloca_works" != xyes; then
2265    AC_MSG_ERROR( [a system implementation of alloca is required] )
2266 fi
2267
2268 # fmod, logb, and frexp are found in -lm on most systems.
2269 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2270 AC_CHECK_LIB(m, sqrt)
2271
2272 # Check for mail-locking functions in a "mail" library.  Probably this should
2273 # have the same check as for liblockfile below.
2274 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2275 if test $have_mail = yes; then
2276   LIBS_MAIL=-lmail
2277   LIBS="$LIBS_MAIL $LIBS"
2278   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2279 else
2280   LIBS_MAIL=
2281 fi
2282 dnl Debian, at least:
2283 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2284 if test $have_lockfile = yes; then
2285    LIBS_MAIL=-llockfile
2286    LIBS="$LIBS_MAIL $LIBS"
2287    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2288 else
2289 # If we have the shared liblockfile, assume we must use it for mail
2290 # locking (e.g. Debian).  If we couldn't link against liblockfile
2291 # (no liblockfile.a installed), ensure that we don't need to.
2292   dnl This works for files generally, not just executables.
2293   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2294   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2295                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2296   if test $ac_cv_prog_liblockfile = yes; then
2297     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2298 This probably means that movemail could lose mail.
2299 There may be a `development' package to install containing liblockfile.])
2300   fi
2301 fi
2302 AC_CHECK_FUNCS(touchlock)
2303 AC_CHECK_HEADERS(maillock.h)
2304 AC_SUBST(LIBS_MAIL)
2305
2306 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2307 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2308 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2309 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2310 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2311 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2312 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2313 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2314 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2315 cfmakeraw cfsetspeed)
2316
2317 AC_CHECK_HEADERS(sys/un.h)
2318
2319 AC_FUNC_MKTIME
2320 if test "$ac_cv_func_working_mktime" = no; then
2321   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2322 fi
2323
2324 AC_FUNC_GETLOADAVG
2325
2326 AC_FUNC_FSEEKO
2327
2328 # Configure getopt.
2329 m4_include([m4/getopt.m4])
2330 gl_GETOPT_IFELSE([
2331   gl_GETOPT_SUBSTITUTE_HEADER
2332   gl_PREREQ_GETOPT
2333   GETOPTOBJS='getopt.o getopt1.o'
2334 ])
2335 AC_SUBST(GETOPTOBJS)
2336
2337 AC_FUNC_GETPGRP
2338
2339 AC_FUNC_STRFTIME
2340
2341 # UNIX98 PTYs.
2342 AC_CHECK_FUNCS(grantpt)
2343
2344 # PTY-related GNU extensions.
2345 AC_CHECK_FUNCS(getpt)
2346
2347 # Check this now, so that we will NOT find the above functions in ncurses.
2348 # That is because we have not set up to link ncurses in lib-src.
2349 # It's better to believe a function is not available
2350 # than to expect to find it in ncurses.
2351 # Also we need tputs and frieds to be able to build at all.
2352 have_tputs_et_al=true
2353 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2354 if test "$have_tputs_et_al" != true; then
2355   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2356 Maybe some development libraries/packages are missing?  Try installing
2357 libncurses-dev(el), libterminfo-dev(el) or similar.])
2358 fi
2359 # Must define this when any termcap library is found.
2360 AC_DEFINE(HAVE_LIBNCURSES, 1,
2361           [Define to 1 if you have the `ncurses' library (-lncurses).])
2362
2363 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2364
2365 resolv=no
2366 AC_TRY_LINK([#include <netinet/in.h>
2367 #include <arpa/nameser.h>
2368 #include <resolv.h>],
2369     [return res_init();],
2370     have_res_init=yes, have_res_init=no)
2371 if test "$have_res_init" = no; then
2372   OLIBS="$LIBS"
2373   LIBS="$LIBS -lresolv"
2374   AC_MSG_CHECKING(for res_init with -lresolv)
2375   AC_TRY_LINK([#include <netinet/in.h>
2376 #include <arpa/nameser.h>
2377 #include <resolv.h>],
2378     [return res_init();],
2379     have_res_init=yes, have_res_init=no)
2380   AC_MSG_RESULT($have_res_init)
2381   if test "$have_res_init" = yes ; then
2382     resolv=yes
2383   fi
2384   LIBS="$OLIBS"
2385 fi
2386
2387 if test "$have_res_init" = yes; then
2388   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2389 fi
2390
2391 # Do we need the Hesiod library to provide the support routines?
2392 LIBHESIOD=
2393 if test "$with_hesiod" != no ; then
2394   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2395   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2396      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2397                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2398   if test "$resolv" = yes ; then
2399     RESOLVLIB=-lresolv
2400   else
2401     RESOLVLIB=
2402   fi
2403   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2404         hesiod=yes, :, $RESOLVLIB)])
2405
2406   if test x"$hesiod" = xyes; then
2407     AC_DEFINE(HAVE_LIBHESIOD, 1,
2408               [Define to 1 if you have the hesiod library (-lhesiod).])
2409     LIBHESIOD=-lhesiod
2410   fi
2411 fi
2412 AC_SUBST(LIBHESIOD)
2413
2414 # Do we need libresolv (due to res_init or Hesiod)?
2415 if test "$resolv" = yes ; then
2416   AC_DEFINE(HAVE_LIBRESOLV, 1,
2417             [Define to 1 if you have the resolv library (-lresolv).])
2418   LIBRESOLV=-lresolv
2419 else
2420   LIBRESOLV=
2421 fi
2422 AC_SUBST(LIBRESOLV)
2423
2424 # These tell us which Kerberos-related libraries to use.
2425 COM_ERRLIB=
2426 CRYPTOLIB=
2427 KRB5LIB=
2428 DESLIB=
2429 KRB4LIB=
2430
2431 if test "${with_kerberos}" != no; then
2432   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2433   if test $have_com_err = yes; then
2434     COM_ERRLIB=-lcom_err
2435     LIBS="$COM_ERRLIB $LIBS"
2436     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2437   fi
2438   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2439   if test $have_crypto = yes; then
2440     CRYPTOLIB=-lcrypto
2441     LIBS="$CRYPTOLIB $LIBS"
2442     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2443   fi
2444   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2445   if test $have_k5crypto = yes; then
2446     CRYPTOLIB=-lk5crypto
2447     LIBS="$CRYPTOLIB $LIBS"
2448     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2449   fi
2450   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2451   if test $have_krb5=yes; then
2452     KRB5LIB=-lkrb5
2453     LIBS="$KRB5LIB $LIBS"
2454     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2455   fi
2456   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2457   if test "${with_kerberos5}" = no; then
2458     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2459     if test $have_des425 = yes; then
2460       DESLIB=-ldes425
2461       LIBS="$DESLIB $LIBS"
2462       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2463     else
2464       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2465       if test $have_des = yes; then
2466         DESLIB=-ldes
2467         LIBS="$DESLIB $LIBS"
2468         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2469       fi
2470     fi
2471     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2472     if test $have_krb4 = yes; then
2473       KRB4LIB=-lkrb4
2474       LIBS="$KRB4LIB $LIBS"
2475       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2476     else
2477       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2478       if test $have_krb = yes; then
2479         KRB4LIB=-lkrb
2480         LIBS="$KRB4LIB $LIBS"
2481         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2482       fi
2483     fi
2484   fi
2485
2486   if test "${with_kerberos5}" != no; then
2487     AC_CHECK_HEADERS(krb5.h,
2488       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2489                         [#include <krb5.h>])])
2490   else
2491     AC_CHECK_HEADERS(des.h,,
2492                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2493                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2494     AC_CHECK_HEADERS(krb.h,,
2495                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2496                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2497   fi
2498   AC_CHECK_HEADERS(com_err.h)
2499 fi
2500
2501 AC_SUBST(COM_ERRLIB)
2502 AC_SUBST(CRYPTOLIB)
2503 AC_SUBST(KRB5LIB)
2504 AC_SUBST(DESLIB)
2505 AC_SUBST(KRB4LIB)
2506
2507 # Solaris requires -lintl if you want strerror (which calls dgettext)
2508 # to return localized messages.
2509 AC_CHECK_LIB(intl, dgettext)
2510
2511 AC_MSG_CHECKING(whether localtime caches TZ)
2512 AC_CACHE_VAL(emacs_cv_localtime_cache,
2513 [if test x$ac_cv_func_tzset = xyes; then
2514 AC_TRY_RUN([#include <time.h>
2515 extern char **environ;
2516 unset_TZ ()
2517 {
2518   char **from, **to;
2519   for (to = from = environ; (*to = *from); from++)
2520     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2521       to++;
2522 }
2523 char TZ_GMT0[] = "TZ=GMT0";
2524 char TZ_PST8[] = "TZ=PST8";
2525 main()
2526 {
2527   time_t now = time ((time_t *) 0);
2528   int hour_GMT0, hour_unset;
2529   if (putenv (TZ_GMT0) != 0)
2530     exit (1);
2531   hour_GMT0 = localtime (&now)->tm_hour;
2532   unset_TZ ();
2533   hour_unset = localtime (&now)->tm_hour;
2534   if (putenv (TZ_PST8) != 0)
2535     exit (1);
2536   if (localtime (&now)->tm_hour == hour_GMT0)
2537     exit (1);
2538   unset_TZ ();
2539   if (localtime (&now)->tm_hour != hour_unset)
2540     exit (1);
2541   exit (0);
2542 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2543 [# If we have tzset, assume the worst when cross-compiling.
2544 emacs_cv_localtime_cache=yes])
2545 else
2546         # If we lack tzset, report that localtime does not cache TZ,
2547         # since we can't invalidate the cache if we don't have tzset.
2548         emacs_cv_localtime_cache=no
2549 fi])dnl
2550 AC_MSG_RESULT($emacs_cv_localtime_cache)
2551 if test $emacs_cv_localtime_cache = yes; then
2552   AC_DEFINE(LOCALTIME_CACHE, 1,
2553             [Define to 1 if localtime caches TZ.])
2554 fi
2555
2556 if test "x$HAVE_TIMEVAL" = xyes; then
2557   AC_CHECK_FUNCS(gettimeofday)
2558   if test $ac_cv_func_gettimeofday = yes; then
2559     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2560                    emacs_cv_gettimeofday_two_arguments,
2561     [AC_TRY_COMPILE([
2562 #ifdef TIME_WITH_SYS_TIME
2563 #include <sys/time.h>
2564 #include <time.h>
2565 #else
2566 #ifdef HAVE_SYS_TIME_H
2567 #include <sys/time.h>
2568 #else
2569 #include <time.h>
2570 #endif
2571 #endif],
2572       [struct timeval time;
2573        gettimeofday (&time, 0);],
2574       emacs_cv_gettimeofday_two_arguments=yes,
2575       emacs_cv_gettimeofday_two_arguments=no)])
2576     if test $emacs_cv_gettimeofday_two_arguments = no; then
2577       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2578                 [Define to 1 if gettimeofday accepts only one argument.])
2579     fi
2580   fi
2581 fi
2582
2583 ok_so_far=yes
2584 AC_CHECK_FUNC(socket, , ok_so_far=no)
2585 if test $ok_so_far = yes; then
2586   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2587 fi
2588 if test $ok_so_far = yes; then
2589   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2590 fi
2591 if test $ok_so_far = yes; then
2592 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2593   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2594             [Define to 1 if you have inet sockets.])
2595 fi
2596
2597 AC_CHECK_HEADERS(sys/ioctl.h)
2598
2599 if test -f /usr/lpp/X11/bin/smt.exp; then
2600   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2601             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2602 fi
2603
2604 AC_MSG_CHECKING(whether system supports dynamic ptys)
2605 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2606   AC_MSG_RESULT(yes)
2607   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2608 else
2609   AC_MSG_RESULT(no)
2610 fi
2611
2612 AC_FUNC_FORK
2613
2614 dnl Adapted from Haible's version.
2615 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2616   [AC_TRY_LINK([#include <langinfo.h>],
2617     [char* cs = nl_langinfo(CODESET);],
2618     emacs_cv_langinfo_codeset=yes,
2619     emacs_cv_langinfo_codeset=no)
2620   ])
2621 if test $emacs_cv_langinfo_codeset = yes; then
2622   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2623     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2624 fi
2625
2626 AC_CHECK_TYPES(size_t)
2627
2628 AC_TYPE_MBSTATE_T
2629
2630 dnl Restrict could probably be used effectively other than in regex.c.
2631 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2632   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2633                   emacs_cv_c_restrict=yes,
2634                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2635                                   emacs_cv_c_restrict=__restrict,
2636                                   emacs_cv_c_restrict=no)])])
2637 case "$emacs_cv_c_restrict" in
2638   yes) emacs_restrict=restrict;;
2639   no) emacs_restrict="";;
2640   *) emacs_restrict="$emacs_cv_c_restrict";;
2641 esac
2642 if test "$emacs_restrict" != __restrict; then
2643   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2644     [Define to compiler's equivalent of C99 restrict keyword.
2645      Don't define if equivalent is `__restrict'.])
2646 fi
2647
2648 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2649   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2650                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2651 if test "$emacs_cv_c_restrict_arr" = yes; then
2652   AC_DEFINE(__restrict_arr, __restrict,
2653     [Define to compiler's equivalent of C99 restrict keyword in array
2654      declarations.  Define as empty for no equivalent.])
2655 fi
2656
2657 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2658 dnl how the tty code is related to POSIX and/or other versions of termios.
2659 dnl The following looks like a useful start.
2660 dnl
2661 dnl AC_SYS_POSIX_TERMIOS
2662 dnl if test $ac_cv_sys_posix_termios = yes; then
2663 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2664 dnl                                and macros for terminal control.])
2665 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2666 dnl fi
2667
2668 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2669
2670 # Set up the CFLAGS for real compilation, so we can substitute it.
2671 CFLAGS="$REAL_CFLAGS"
2672 CPPFLAGS="$REAL_CPPFLAGS"
2673
2674 #### Find out which version of Emacs this is.
2675 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2676          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2677 if test x"${version}" = x; then
2678   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2679 fi
2680 if test x"${version}" != x"$PACKAGE_VERSION"; then
2681   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2682 fi
2683
2684 ### Specify what sort of things we'll be editing into Makefile and config.h.
2685 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2686 AC_SUBST(version)
2687 AC_SUBST(configuration)
2688 AC_SUBST(canonical)
2689 AC_SUBST(srcdir)
2690 AC_SUBST(prefix)
2691 AC_SUBST(exec_prefix)
2692 AC_SUBST(bindir)
2693 AC_SUBST(datadir)
2694 AC_SUBST(sharedstatedir)
2695 AC_SUBST(libexecdir)
2696 AC_SUBST(mandir)
2697 AC_SUBST(infodir)
2698 AC_SUBST(lispdir)
2699 AC_SUBST(locallisppath)
2700 AC_SUBST(lisppath)
2701 AC_SUBST(x_default_search_path)
2702 AC_SUBST(etcdir)
2703 AC_SUBST(archlibdir)
2704 AC_SUBST(docdir)
2705 AC_SUBST(bitmapdir)
2706 AC_SUBST(gamedir)
2707 AC_SUBST(gameuser)
2708 AC_SUBST(c_switch_system)
2709 AC_SUBST(c_switch_machine)
2710 AC_SUBST(LD_SWITCH_X_SITE)
2711 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2712 AC_SUBST(C_SWITCH_X_SITE)
2713 AC_SUBST(CFLAGS)
2714 AC_SUBST(X_TOOLKIT_TYPE)
2715 AC_SUBST(machfile)
2716 AC_SUBST(opsysfile)
2717 AC_SUBST(GETLOADAVG_LIBS)
2718 AC_SUBST(ns_appdir)
2719 AC_SUBST(ns_appbindir)
2720 AC_SUBST(ns_appresdir)
2721 AC_SUBST(ns_appsrc)
2722 AC_SUBST(GNUSTEP_MAKEFILES)
2723 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2724 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2725 AC_SUBST(GNU_OBJC_CFLAGS)
2726 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2727 AC_SUBST(OTHER_FILES)
2728
2729 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2730                    [Define to the canonical Emacs configuration name.])
2731 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2732                    [Define to the options passed to configure.])
2733 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2734                    [Define to the used machine dependent file.])
2735 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2736                    [Define to the used os dependent file.])
2737 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2738 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2739  may need to deal with X Windows.  For instance, if you've defined
2740  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2741  your loader can find on its own, you might want to add "-L/..." or
2742  something similar.])
2743 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2744                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2745                     in case it's needed (for Solaris, for example).])
2746 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2747 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2748  may need to deal with X Windows.  For instance, if you've defined
2749  HAVE_X_WINDOWS above and your X include files aren't in a place
2750  that your compiler can find on its own, you might want to add
2751  "-I/..." or something similar.])
2752 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2753                    [Define to the unexec source file name.])
2754
2755 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2756   AC_DEFINE(HAVE_X_WINDOWS, 1,
2757             [Define to 1 if you want to use the X window system.])
2758 fi
2759 if test "${USE_X_TOOLKIT}" != "none" ; then
2760   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2761   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2762     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2763   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2764     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2765   fi
2766 fi
2767 if test "${HAVE_X11}" = "yes" ; then
2768   AC_DEFINE(HAVE_X11, 1,
2769             [Define to 1 if you want to use version 11 of X windows.
2770              Otherwise, Emacs expects to use version 10.])
2771 fi
2772 if test "${HAVE_MENUS}" = "yes" ; then
2773   AC_DEFINE(HAVE_MENUS, 1,
2774             [Define to 1 if you have mouse menus.
2775              (This is automatic if you use X, but the option to specify it remains.)
2776              It is also defined with other window systems that support xmenu.c.])
2777 fi
2778 if test "${GNU_MALLOC}" = "yes" ; then
2779   AC_DEFINE(GNU_MALLOC, 1,
2780             [Define to 1 if you want to use the GNU memory allocator.])
2781 fi
2782 if test "${REL_ALLOC}" = "yes" ; then
2783   AC_DEFINE(REL_ALLOC, 1,
2784             [Define REL_ALLOC if you want to use the relocating allocator for
2785              buffer space.])
2786 fi
2787
2788
2789 AH_TOP([/* GNU Emacs site configuration template file.
2790    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2791      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2792
2793 This file is part of GNU Emacs.
2794
2795 GNU Emacs is free software: you can redistribute it and/or modify
2796 it under the terms of the GNU General Public License as published by
2797 the Free Software Foundation, either version 3 of the License, or
2798 (at your option) any later version.
2799
2800 GNU Emacs is distributed in the hope that it will be useful,
2801 but WITHOUT ANY WARRANTY; without even the implied warranty of
2802 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2803 GNU General Public License for more details.
2804
2805 You should have received a copy of the GNU General Public License
2806 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2807
2808
2809 /* No code in Emacs #includes config.h twice, but some bits of code
2810    intended to work with other packages as well (like gmalloc.c)
2811    think they can include it as many times as they like.  */
2812 #ifndef EMACS_CONFIG_H
2813 #define EMACS_CONFIG_H
2814 ])dnl
2815
2816 AH_BOTTOM([
2817 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2818 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2819 #define HAVE_WINDOW_SYSTEM
2820 #define HAVE_MOUSE
2821 #endif
2822
2823 /* Define AMPERSAND_FULL_NAME if you use the convention
2824    that & in the full name stands for the login id.  */
2825 /* Turned on June 1996 supposing nobody will mind it.  */
2826 #define AMPERSAND_FULL_NAME
2827
2828 /* Define HAVE_SOUND if we have sound support.  We know it works
2829    and compiles only on the specified platforms.   For others,
2830    it probably doesn't make sense to try.  */
2831
2832 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2833 #ifdef HAVE_MACHINE_SOUNDCARD_H
2834 #define HAVE_SOUND 1
2835 #endif
2836 #ifdef HAVE_SYS_SOUNDCARD_H
2837 #define HAVE_SOUND 1
2838 #endif
2839 #ifdef HAVE_SOUNDCARD_H
2840 #define HAVE_SOUND 1
2841 #endif
2842 #ifdef HAVE_ALSA
2843 #define HAVE_SOUND 1
2844 #endif
2845 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2846
2847 /* If using GNU, then support inline function declarations. */
2848 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2849    generally, because even if non-gcc compilers accept `inline', they
2850    may reject `extern inline'.  */
2851 #if defined (__GNUC__) && defined (OPTIMIZE)
2852 #define INLINE __inline__
2853 #else
2854 #define INLINE
2855 #endif
2856
2857 /* `subprocesses' should be defined if you want to
2858    have code for asynchronous subprocesses
2859    (as used in M-x compile and M-x shell).
2860    Only MSDOS does not support this (it overrides
2861    this in its config_opsysfile below).  */
2862
2863 #define subprocesses
2864
2865 /* Include the os and machine dependent files.  */
2866 #include config_opsysfile
2867 #include config_machfile
2868
2869 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2870   (There is probably a better place to do this, but right now the Cocoa
2871    side does this in s/darwin.h and we cannot
2872    parallel this exactly since GNUstep is multi-OS. */
2873 #ifdef HAVE_NS
2874 # ifdef NS_IMPL_GNUSTEP
2875 /* See also .m.o rule in Makefile.in */
2876 /* FIXME: are all these flags really needed?  Document here why.  */
2877 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2878 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2879 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2880 #  define SYSTEM_PURESIZE_EXTRA 30000
2881 # endif /* NS_IMPL_GNUSTEP */
2882 #endif /* HAVE_NS */
2883
2884 /* SIGTYPE is the macro we actually use.  */
2885 #ifndef SIGTYPE
2886 #define SIGTYPE RETSIGTYPE
2887 #endif
2888
2889 #ifdef emacs /* Don't do this for lib-src.  */
2890 /* Tell regex.c to use a type compatible with Emacs.  */
2891 #define RE_TRANSLATE_TYPE Lisp_Object
2892 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2893 #ifdef make_number
2894 /* If make_number is a macro, use it.  */
2895 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2896 #else
2897 /* If make_number is a function, avoid it.  */
2898 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2899 #endif
2900 #endif
2901
2902 /* Avoid link-time collision with system mktime if we will use our own.  */
2903 #if ! HAVE_MKTIME || BROKEN_MKTIME
2904 #define mktime emacs_mktime
2905 #endif
2906
2907 #define my_strftime nstrftime   /* for strftime.c */
2908
2909 /* The rest of the code currently tests the CPP symbol BSTRING.
2910    Override any claims made by the system-description files.
2911    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2912 #undef BSTRING
2913 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2914 #define BSTRING
2915 #endif
2916
2917 /* Some of the files of Emacs which are intended for use with other
2918    programs assume that if you have a config.h file, you must declare
2919    the type of getenv.
2920
2921    This declaration shouldn't appear when alloca.s or Makefile.in
2922    includes config.h.  */
2923 #ifndef NOT_C_CODE
2924 extern char *getenv ();
2925 #endif
2926
2927 /* These default definitions are good for almost all machines.
2928    The exceptions override them in m/MACHINE.h.  */
2929
2930 #ifndef BITS_PER_CHAR
2931 #define BITS_PER_CHAR 8
2932 #endif
2933
2934 #ifndef BITS_PER_SHORT
2935 #define BITS_PER_SHORT 16
2936 #endif
2937
2938 /* Note that lisp.h uses this in a preprocessor conditional, so it
2939    would not work to use sizeof.  That being so, we do all of them
2940    without sizeof, for uniformity's sake.  */
2941 #ifndef BITS_PER_INT
2942 #define BITS_PER_INT 32
2943 #endif
2944
2945 #ifndef BITS_PER_LONG
2946 #ifdef _LP64
2947 #define BITS_PER_LONG 64
2948 #else
2949 #define BITS_PER_LONG 32
2950 #endif
2951 #endif
2952
2953 /* Define if the compiler supports function prototypes.  It may do so
2954    but not define __STDC__ (e.g. DEC C by default) or may define it as
2955    zero.  */
2956 #undef PROTOTYPES
2957 /* For mktime.c:  */
2958 #ifndef __P
2959 # if defined PROTOTYPES
2960 #  define __P(args) args
2961 # else
2962 #  define __P(args) ()
2963 # endif  /* GCC.  */
2964 #endif /* __P */
2965
2966 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2967 #ifndef NOT_C_CODE
2968 #ifdef HAVE_STRING_H
2969 #include "string.h"
2970 #endif
2971 #ifdef HAVE_STRINGS_H
2972 #include "strings.h"  /* May be needed for bcopy & al. */
2973 #endif
2974 #ifdef HAVE_STDLIB_H
2975 #include <stdlib.h>
2976 #endif
2977 #ifndef __GNUC__
2978 # ifdef HAVE_ALLOCA_H
2979 #  include <alloca.h>
2980 # else /* AIX files deal with #pragma.  */
2981 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2982 char *alloca ();
2983 #  endif
2984 # endif /* HAVE_ALLOCA_H */
2985 #endif /* __GNUC__ */
2986 #ifndef HAVE_SIZE_T
2987 typedef unsigned size_t;
2988 #endif
2989 #endif /* NOT_C_CODE */
2990
2991 /* Define HAVE_X_I18N if we have usable i18n support.  */
2992
2993 #ifdef HAVE_X11R6
2994 #define HAVE_X_I18N
2995 #elif !defined X11R5_INHIBIT_I18N
2996 #define HAVE_X_I18N
2997 #endif
2998
2999 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3000
3001 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3002 #define HAVE_X11R6_XIM
3003 #endif
3004
3005 #if defined __GNUC__ && (__GNUC__ > 2 \
3006                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3007 #define NO_RETURN       __attribute__ ((__noreturn__))
3008 #else
3009 #define NO_RETURN       /* nothing */
3010 #endif
3011
3012 /* These won't be used automatically yet.  We also need to know, at least,
3013    that the stack is continuous.  */
3014 #ifdef __GNUC__
3015 #  ifndef GC_SETJMP_WORKS
3016   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3017      see NON_SAVING_SETJMP in the target descriptions.  */
3018   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3019      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3020      Fixme: Deal with SVR3.  */
3021 #    define GC_SETJMP_WORKS 1
3022 #  endif
3023 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3024 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3025 #  endif
3026 #endif
3027
3028 #ifndef HAVE_BCOPY
3029 #define bcopy(a,b,s) memcpy (b,a,s)
3030 #endif
3031 #ifndef HAVE_BZERO
3032 #define bzero(a,s) memset (a,0,s)
3033 #endif
3034 #ifndef HAVE_BCMP
3035 #define BCMP memcmp
3036 #endif
3037
3038 #endif /* EMACS_CONFIG_H */
3039
3040 /*
3041 Local Variables:
3042 mode: c
3043 End:
3044 */
3045 ])dnl
3046
3047 #### Report on what we decided to do.
3048 #### Report GTK as a toolkit, even if it doesn't use Xt.
3049 #### It makes printing result more understandable as using GTK sets
3050 #### toolkit_scroll_bars to yes by default.
3051 if test "${HAVE_GTK}" = "yes"; then
3052   USE_X_TOOLKIT=GTK
3053 fi
3054
3055 echo "
3056 Configured for \`${canonical}'.
3057
3058   Where should the build process find the source code?    ${srcdir}
3059   What operating system and machine description files should Emacs use?
3060         \`${opsysfile}' and \`${machfile}'
3061   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3062   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3063   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3064   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3065   What window system should Emacs use?                    ${window_system}
3066   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3067
3068 if test -n "${x_includes}"; then
3069 echo "  Where do we find X Windows header files?                ${x_includes}"
3070 else
3071 echo "  Where do we find X Windows header files?                Standard dirs"
3072 fi
3073 if test -n "${x_libraries}"; then
3074 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3075 else
3076 echo "  Where do we find X Windows libraries?                   Standard dirs"
3077 fi
3078
3079 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3080 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3081 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3082 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3083 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3084 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3085 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3086 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3087 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3088 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3089
3090 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3091 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3092 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3093 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3094
3095 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3096 echo
3097
3098 if test $USE_XASSERTS = yes; then
3099    echo "  Compiling with asserts turned on."
3100    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3101 fi
3102
3103 echo
3104
3105 if test "$HAVE_NS" = "yes"; then
3106    echo
3107    echo "You must run \"make install\" in order to test the built application.
3108 The installed application will go to nextstep/Emacs.app and can be
3109 run or moved from there."
3110    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3111       echo "The application will be fully self-contained."
3112     else
3113       echo "The lisp resources for the application will be installed under ${prefix}.
3114 You may need to run \"make install\" with sudo.  The application will fail
3115 to run if these resources are not installed."
3116    fi
3117    echo
3118 fi
3119
3120 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3121   echo "D-Bus integration has been tested for GNU/Linux only."
3122   echo
3123 fi
3124
3125
3126 # Remove any trailing slashes in these variables.
3127 [test "${prefix}" != NONE &&
3128   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3129 test "${exec_prefix}" != NONE &&
3130   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3131
3132 # Now get this: Some word that is part of the ${srcdir} directory name
3133 # or the ${configuration} value might, just might, happen to be an
3134 # identifier like `sun4' or `i386' or something, and be predefined by
3135 # the C preprocessor to some helpful value like 1, or maybe the empty
3136 # string.  Needless to say consequent macro substitutions are less
3137 # than conducive to the makefile finding the correct directory.
3138 [cpp_undefs="`echo $srcdir $configuration $canonical |
3139   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3140   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3141
3142 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3143 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3144 ## from Makefile.c can correctly provide the arg `-traditional' to the
3145 ## C preprocessor.
3146
3147 AC_EGREP_CPP(yes..yes,
3148         [yes..yes],
3149         CPP_NEED_TRADITIONAL=no,
3150         CPP_NEED_TRADITIONAL=yes)
3151
3152 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3153         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3154         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3155         lwlib/Makefile lisp/Makefile leim/Makefile, [
3156
3157 ### Make the necessary directories, if they don't exist.
3158 for dir in etc lisp ; do
3159   test -d ${dir} || mkdir ${dir}
3160 done
3161
3162 # Build src/Makefile from ${srcdir}/src/Makefile.c
3163 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3164 # This must be done after src/config.h is built, since we rely on that file.
3165
3166 echo creating src/epaths.h
3167 ${MAKE-make} epaths-force
3168
3169 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3170 # `..' to `. .'  unless invoked with -traditional
3171
3172 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3173   CPPFLAGS="$CPPFLAGS -traditional"
3174 fi
3175
3176 echo creating lib-src/Makefile
3177 ( cd lib-src
3178   rm -f junk.c junk1.c junk2.c
3179   sed -e '/start of cpp stuff/q' \
3180       < Makefile.c > junk1.c
3181   sed -e '1,/start of cpp stuff/d'\
3182       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3183       < Makefile.c > junk.c
3184   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3185       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3186   cat junk1.c junk2.c > Makefile.new
3187   rm -f junk.c junk1.c junk2.c
3188   chmod 444 Makefile.new
3189   mv -f Makefile.new Makefile
3190 )
3191
3192 echo creating src/Makefile
3193 ( cd src
3194   rm -f junk.c junk1.c junk2.c
3195   sed -e '/start of cpp stuff/q' \
3196       < Makefile.c > junk1.c
3197   sed -e '1,/start of cpp stuff/d'\
3198       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3199       < Makefile.c > junk.c
3200   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3201       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3202   cat junk1.c junk2.c > Makefile.new
3203   rm -f junk.c junk1.c junk2.c
3204   chmod 444 Makefile.new
3205   mv -f Makefile.new Makefile
3206 )
3207
3208 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3209   echo creating src/.gdbinit
3210   echo source $srcdir/src/.gdbinit > src/.gdbinit
3211 fi
3212
3213 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3214
3215 m4_if(dnl       Do not change this comment
3216    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3217 )dnl