lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: FSF (unless Dodd can be found)
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001 Free Software Foundation, Inc.
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  32 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  33 ;; been removed or renamed in order to work properly with dired of GNU
  34 ;; Emacs.  All suggestions or comments are most welcomed.
  35
  36 ;;
  37 ;; Please, PLEASE, *PLEASE* see the info pages.
  38 ;;
  39
  40 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  41
  42 ;; INSTALLATION: In your ~/.emacs,
  43 ;;
  44 ;; (add-hook 'dired-load-hook
  45 ;;           (function (lambda ()
  46 ;;                       (load "dired-x")
  47 ;;                       ;; Set global variables here.  For example:
  48 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  49 ;;                       )))
  50 ;; (add-hook 'dired-mode-hook
  51 ;;           (function (lambda ()
  52 ;;                       ;; Set buffer-local variables here.  For example:
  53 ;;                       ;; (setq dired-omit-files-p t)
  54 ;;                       )))
  55 ;;
  56 ;; At load time dired-x.el will install itself, redefine some functions, and
  57 ;; bind some dired keys.  *Please* see the info pages for more details.
  58
  59 ;; *Please* see the info pages for more details.
  60
  61 ;; User defined variables:
  62 ;;
  63 ;;      dired-bind-vm
  64 ;;      dired-vm-read-only-folders
  65 ;;      dired-bind-jump
  66 ;;      dired-bind-info
  67 ;;      dired-bind-man
  68 ;;      dired-x-hands-off-my-keys
  69 ;;      dired-find-subdir
  70 ;;      dired-enable-local-variables
  71 ;;      dired-local-variables-file
  72 ;;      dired-guess-shell-gnutar
  73 ;;      dired-guess-shell-gzip-quiet
  74 ;;      dired-guess-shell-znew-switches
  75 ;;      dired-guess-shell-alist-user
  76 ;;      dired-clean-up-buffers-too
  77 ;;      dired-omit-files-p
  78 ;;      dired-omit-files
  79 ;;      dired-omit-extensions
  80 ;;      dired-omit-size-limit
  81 ;;
  82 ;; To find out more about these variables, load this file, put your cursor at
  83 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  84 ;; the info pages for more details.
  85
  86 ;; When loaded this code redefines the following functions of GNU Emacs
  87 ;;
  88 ;;   Function                         Found in this file of GNU Emacs
  89 ;;   --------                         -------------------------------
  90 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  91 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  92 ;;   dired-initial-position           ../lisp/dired.el
  93 ;;
  94 ;;   dired-add-entry                  ../lisp/dired-aux.el
  95 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  96
  97 \f
  98 ;;; Code:
  99
 100 ;; LOAD.
 101
 102 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 103 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 104 ;; (instead of autoloading to dired as is suggested in the info-pages).
 105
 106 (require 'dired)
 107
 108 ;; We will redefine some functions and also need some macros so we need to
 109 ;; load dired stuff of GNU Emacs.
 110
 111 (require 'dired-aux)
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 127 `dired-advertised-find-file', will run rmail."
 128   :type 'boolean
 129   :group 'dired-keys)
 130
 131 (defcustom dired-bind-jump t
 132   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 133   :type 'boolean
 134   :group 'dired-keys)
 135
 136 (defcustom dired-bind-man t
 137   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 138   :type 'boolean
 139   :group 'dired-keys)
 140
 141 (defcustom dired-bind-info t
 142   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 143   :type 'boolean
 144   :group 'dired-keys)
 145
 146 (defcustom dired-vm-read-only-folders nil
 147   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 148 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 149 files not writable by you are visited read-only.
 150
 151 Read-only folders only work in VM 5, not in VM 4."
 152   :type '(choice (const :tag "off" nil)
 153                  (const :tag "on" t)
 154                  (other :tag "non-writable only" if-file-read-only))
 155   :group 'dired-x)
 156
 157 (defcustom dired-omit-files-p nil
 158   "*If non-nil, \"uninteresting\" files are not listed (buffer-local).
 159 Use \\[dired-omit-toggle] to toggle its value.
 160 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 161 plus those ending with extensions in `dired-omit-extensions'."
 162   :type 'boolean
 163   :group 'dired-x)
 164 (make-variable-buffer-local 'dired-omit-files-p)
 165
 166 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 167   "*Filenames matching this regexp will not be displayed.
 168 This only has effect when `dired-omit-files-p' is t.  See interactive function
 169 `dired-omit-toggle' \(\\[dired-omit-toggle]\) and variable
 170 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 171 files and lock files."
 172   :type 'regexp
 173   :group 'dired-x)
 174
 175 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 176   "*If non-nil, Dired always finds a directory in a buffer of its own.
 177 If nil, Dired finds the directory as a subdirectory in some other buffer
 178 if it is present as one.
 179
 180 If there are several Dired buffers for a directory, the most recently
 181 used is chosen.
 182
 183 Dired avoids switching to the current buffer, so that if you have
 184 a normal and a wildcard buffer for the same directory, \\[dired] will
 185 toggle between those two."
 186   :type 'boolean
 187   :group 'dired-x)
 188
 189 (defcustom dired-omit-size-limit 30000
 190   "*Maximum size for the \"omitting\" feature.
 191 If nil, there is no maximum size."
 192   :type '(choice (const :tag "no maximum" nil) integer)
 193   :group 'dired-x)
 194
 195 (defcustom dired-enable-local-variables t
 196   "*Control use of local-variables lists in dired.
 197 The value can be t, nil or something else.
 198 A value of t means local-variables lists are obeyed;
 199 nil means they are ignored; anything else means query.
 200
 201 This temporarily overrides the value of `enable-local-variables' when listing
 202 a directory.  See also `dired-local-variables-file'."
 203   :type 'boolean
 204   :group 'dired-x)
 205
 206 (defcustom dired-guess-shell-gnutar nil
 207   "*If non-nil, name of GNU tar executable.
 208 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 209 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 210 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 211   :type '(choice (const :tag "Not GNU tar" nil)
 212                  (string :tag "Command name"))
 213   :group 'dired-x)
 214
 215 (defcustom dired-guess-shell-gzip-quiet t
 216   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 217   :type 'boolean
 218   :group 'dired-x)
 219
 220 (defcustom dired-guess-shell-znew-switches nil
 221   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 222   :type '(choice (const :tag "None" nil)
 223                  (string :tag "Switches"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-clean-up-buffers-too t
 227   "*Non-nil means offer to kill buffers visiting files and dirs deleted in dired."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 ;;; KEY BINDINGS.
 232
 233 (define-key dired-mode-map "\M-o" 'dired-omit-toggle)
 234 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 235 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 236 (define-key dired-mode-map "*." 'dired-mark-extension)
 237 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 238 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 239 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 240 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 241 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 242 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 243 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 244 (define-key dired-mode-map "V" 'dired-do-run-mail)
 245
 246 (if dired-bind-man
 247     (define-key dired-mode-map "N" 'dired-man))
 248
 249 (if dired-bind-info
 250     (define-key dired-mode-map "I" 'dired-info))
 251
 252 ;;; GLOBAL BINDING.
 253 (if dired-bind-jump
 254     (progn
 255       (define-key global-map "\C-x\C-j" 'dired-jump)
 256       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 257
 258 \f
 259 ;;; Install into appropriate hooks.
 260
 261 (add-hook 'dired-mode-hook 'dired-extra-startup)
 262 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 263
 264 (defun dired-extra-startup ()
 265   "Automatically put on `dired-mode-hook' to get extra dired features:
 266 \\<dired-mode-map>
 267   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 268   \\[dired-info]\t-- run info on file
 269   \\[dired-man]\t-- run man on file
 270   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 271   \\[dired-omit-toggle]\t-- toggle omitting of files
 272   \\[dired-mark-sexp]\t-- mark by Lisp expression
 273   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring.
 274   \t   You can feed it to other commands using \\[yank].
 275
 276 For more features, see variables
 277
 278   `dired-bind-vm'
 279   `dired-bind-jump'
 280   `dired-bind-info'
 281   `dired-bind-man'
 282   `dired-vm-read-only-folders'
 283   `dired-omit-files-p'
 284   `dired-omit-files'
 285   `dired-omit-extensions'
 286   `dired-omit-size-limit'
 287   `dired-find-subdir'
 288   `dired-enable-local-variables'
 289   `dired-local-variables-file'
 290   `dired-guess-shell-gnutar'
 291   `dired-guess-shell-gzip-quiet'
 292   `dired-guess-shell-znew-switches'
 293   `dired-guess-shell-alist-user'
 294   `dired-clean-up-buffers-too'
 295
 296 See also functions
 297
 298   `dired-flag-extension'
 299   `dired-virtual'
 300   `dired-jump'
 301   `dired-man'
 302   `dired-vm'
 303   `dired-rmail'
 304   `dired-info'
 305   `dired-do-find-marked-files'"
 306   (interactive)
 307
 308   ;; These must be done in each new dired buffer.
 309   (dired-hack-local-variables)
 310   (dired-omit-startup))
 311
 312 \f
 313 ;;; BUFFER CLEANING.
 314
 315 ;; REDEFINE.
 316 (defun dired-clean-up-after-deletion (fn)
 317   "Clean up after a deleted file or directory FN.
 318 Remove expanded subdir of deleted dir, if any."
 319   (save-excursion (and (cdr dired-subdir-alist)
 320                        (dired-goto-subdir fn)
 321                        (dired-kill-subdir)))
 322
 323   ;; Offer to kill buffer of deleted file FN.
 324   (if dired-clean-up-buffers-too
 325       (progn
 326         (let ((buf (get-file-buffer fn)))
 327           (and buf
 328                (funcall (function y-or-n-p)
 329                         (format "Kill buffer of %s, too? "
 330                                 (file-name-nondirectory fn)))
 331                (save-excursion ; you never know where kill-buffer leaves you
 332                  (kill-buffer buf))))
 333         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 334               (buf nil))
 335           (and buf-list
 336                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 337                                  (dired-plural-s (length buf-list))
 338                                  (file-name-nondirectory fn)))
 339                (while buf-list
 340                  (save-excursion (kill-buffer (car buf-list)))
 341                  (setq buf-list (cdr buf-list)))))))
 342   ;; Anything else?
 343   )
 344
 345 \f
 346 ;;; EXTENSION MARKING FUNCTIONS.
 347
 348 ;;; Mark files with some extension.
 349 (defun dired-mark-extension (extension &optional marker-char)
 350   "Mark all files with a certain EXTENSION for use in later commands.
 351 A `.' is not automatically prepended to the string entered."
 352   ;; EXTENSION may also be a list of extensions instead of a single one.
 353   ;; Optional MARKER-CHAR is marker to use.
 354   (interactive "sMarking extension: \nP")
 355   (or (listp extension)
 356       (setq extension (list extension)))
 357   (dired-mark-files-regexp
 358    (concat ".";; don't match names with nothing but an extension
 359            "\\("
 360            (mapconcat 'regexp-quote extension "\\|")
 361            "\\)$")
 362    marker-char))
 363
 364 (defun dired-flag-extension (extension)
 365   "In dired, flag all files with a certain EXTENSION for deletion.
 366 A `.' is *not* automatically prepended to the string entered."
 367   (interactive "sFlagging extension: ")
 368   (dired-mark-extension extension dired-del-marker))
 369
 370 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 371
 372 (defvar dired-patch-unclean-extensions
 373   '(".rej" ".orig")
 374   "List of extensions of dispensable files created by the `patch' program.")
 375
 376 (defvar dired-tex-unclean-extensions
 377   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 378   "List of extensions of dispensable files created by TeX.")
 379
 380 (defvar dired-latex-unclean-extensions
 381   '(".idx" ".lof" ".lot" ".glo")
 382   "List of extensions of dispensable files created by LaTeX.")
 383
 384 (defvar dired-bibtex-unclean-extensions
 385   '(".blg" ".bbl")
 386   "List of extensions of dispensable files created by BibTeX.")
 387
 388 (defvar dired-texinfo-unclean-extensions
 389   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 390     ".tp" ".tps" ".vr" ".vrs")
 391   "List of extensions of dispensable files created by texinfo.")
 392
 393 (defun dired-clean-patch ()
 394   "Flag dispensable files created by patch for deletion.
 395 See variable `dired-patch-unclean-extensions'."
 396   (interactive)
 397   (dired-flag-extension dired-patch-unclean-extensions))
 398
 399 (defun dired-clean-tex ()
 400   "Flag dispensable files created by [La]TeX etc. for deletion.
 401 See variables `dired-texinfo-unclean-extensions',
 402 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 403 `dired-texinfo-unclean-extensions'."
 404   (interactive)
 405   (dired-flag-extension (append dired-texinfo-unclean-extensions
 406                                 dired-latex-unclean-extensions
 407                                 dired-bibtex-unclean-extensions
 408                                 dired-tex-unclean-extensions)))
 409
 410 (defun dired-very-clean-tex ()
 411   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 412 See variables `dired-texinfo-unclean-extensions',
 413 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 414 `dired-texinfo-unclean-extensions'."
 415   (interactive)
 416   (dired-flag-extension (append dired-texinfo-unclean-extensions
 417                                 dired-latex-unclean-extensions
 418                                 dired-bibtex-unclean-extensions
 419                                 dired-tex-unclean-extensions
 420                                 (list ".dvi"))))
 421 \f
 422 ;;; JUMP.
 423
 424 ;;;###autoload
 425 (defun dired-jump (&optional other-window)
 426   "Jump to dired buffer corresponding to current buffer.
 427 If in a file, dired the current directory and move to file's line.
 428 If in dired already, pop up a level and goto old directory's line.
 429 In case the proper dired file line cannot be found, refresh the dired
 430 buffer and try again."
 431   (interactive "P")
 432   (let* ((file buffer-file-name)
 433          (dir (if file (file-name-directory file) default-directory)))
 434     (if (eq major-mode 'dired-mode)
 435         (progn
 436           (setq dir (dired-current-directory))
 437           (dired-up-directory other-window)
 438           (or (dired-goto-file dir)
 439               ;; refresh and try again
 440               (progn
 441                 (dired-insert-subdir (file-name-directory dir))
 442                 (dired-goto-file dir))))
 443       (if other-window
 444           (dired-other-window dir)
 445         (dired dir))
 446       (if file
 447           (or (dired-goto-file file)
 448               ;; refresh and try again
 449               (progn
 450                 (dired-insert-subdir (file-name-directory file))
 451                 (dired-goto-file file))
 452               ;; Toggle omitting, if it is on, and try again.
 453               (if dired-omit-files-p
 454                   (progn
 455                     (dired-omit-toggle)
 456                     (dired-goto-file file))))))))
 457
 458 (defun dired-jump-other-window ()
 459   "Like \\[dired-jump] (dired-jump) but in other window."
 460   (interactive)
 461   (dired-jump t))
 462 \f
 463 ;;; OMITTING.
 464
 465 ;;; Enhanced omitting of lines from directory listings.
 466 ;;; Marked files are never omitted.
 467
 468 ;; should probably get rid of this and always use 'no-dir.
 469 ;; sk 28-Aug-1991 09:37
 470 (defvar dired-omit-localp 'no-dir
 471   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 472 If it is 'no-dir, omitting is much faster, but you can only match
 473 against the basename of the file.  Set it to nil if you need to match the
 474 whole pathname.")
 475
 476 ;; \017=^O for Omit - other packages can chose other control characters.
 477 (defvar dired-omit-marker-char ?\017
 478   "Temporary marker used by by dired-omit.
 479 Should never be used as marker by the user or other packages.")
 480
 481 (defun dired-omit-startup ()
 482   (or (assq 'dired-omit-files-p minor-mode-alist)
 483       (setq minor-mode-alist
 484             (append '((dired-omit-files-p
 485                        (:eval (if (eq major-mode 'dired-mode)
 486                                   " Omit" ""))))
 487                     minor-mode-alist))))
 488
 489 (defun dired-omit-toggle (&optional flag)
 490   "Toggle omitting files matching `dired-omit-files' and `dired-omit-extensions'.
 491 With an arg, and if omitting was off, don't toggle and just mark the
 492   files but don't actually omit them.
 493 With an arg, and if omitting was on, turn it off but don't refresh the buffer."
 494   (interactive "P")
 495   (if flag
 496       (if dired-omit-files-p
 497           (setq dired-omit-files-p (not dired-omit-files-p))
 498         (dired-mark-unmarked-files (dired-omit-regexp) nil nil
 499                                    dired-omit-localp))
 500     ;; no FLAG
 501     (setq dired-omit-files-p (not dired-omit-files-p))
 502     (if (not dired-omit-files-p)
 503         (revert-buffer)
 504       ;; this will mention how many were omitted:
 505       (let ((dired-omit-size-limit nil))
 506         (dired-omit-expunge)))))
 507
 508 (defvar dired-omit-extensions
 509   (append completion-ignored-extensions
 510           dired-latex-unclean-extensions
 511           dired-bibtex-unclean-extensions
 512           dired-texinfo-unclean-extensions)
 513   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 514 Defaults to elements of `completion-ignored-extensions',
 515 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 516 `dired-texinfo-unclean-extensions'.
 517
 518 See interactive function `dired-omit-toggle' \(\\[dired-omit-toggle]\) and
 519 variables `dired-omit-files-p' and `dired-omit-files'.")
 520
 521 (defun dired-omit-expunge (&optional regexp)
 522   "Erases all unmarked files matching REGEXP.
 523 Does nothing if global variable `dired-omit-files-p' is nil, or if called
 524   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 525 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 526   filenames ending in `dired-omit-extensions'.
 527 If REGEXP is the empty string, this function is a no-op.
 528
 529 This functions works by temporarily binding `dired-marker-char' to
 530 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 531   (interactive "sOmit files (regexp): ")
 532   (if (and dired-omit-files-p
 533            (or (interactive-p)
 534                (not dired-omit-size-limit)
 535                (< (buffer-size) dired-omit-size-limit)
 536                (progn
 537                  (message "Not omitting: directory larger than %d characters."
 538                           dired-omit-size-limit)
 539                  (setq dired-omit-files-p nil)
 540                  nil)))
 541       (let ((omit-re (or regexp (dired-omit-regexp)))
 542             (old-modified-p (buffer-modified-p))
 543             count)
 544         (or (string= omit-re "")
 545             (let ((dired-marker-char dired-omit-marker-char))
 546               (message "Omitting...")
 547               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 548                   (progn
 549                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 550                     (force-mode-line-update))
 551                 (message "(Nothing to omit)"))))
 552         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 553         ;; in mode-line of omitted buffers.
 554         (set-buffer-modified-p (and old-modified-p
 555                                     (save-excursion
 556                                       (goto-char (point-min))
 557                                       (re-search-forward dired-re-mark nil t))))
 558         count)))
 559
 560 (defun dired-omit-regexp ()
 561   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 562           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 563           (if dired-omit-extensions
 564               (concat ".";; a non-extension part should exist
 565                       "\\("
 566                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 567                       "\\)$")
 568             "")))
 569
 570 ;; Returns t if any work was done, nil otherwise.
 571 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 572   "Mark unmarked files matching REGEXP, displaying MSG.
 573 REGEXP is matched against the complete pathname.
 574 Does not re-mark files which already have a mark.
 575 With prefix argument, unflag all those files.
 576 Second optional argument LOCALP is as in `dired-get-filename'."
 577   (interactive "P")
 578   (let ((dired-marker-char (if unflag-p ?\  dired-marker-char)))
 579     (dired-mark-if
 580      (and
 581       ;; not already marked
 582       (looking-at " ")
 583       ;; uninteresting
 584       (let ((fn (dired-get-filename localp t)))
 585         (and fn (string-match regexp fn))))
 586      msg)))
 587
 588 ;;; REDEFINE.
 589 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 590   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 591   ;; files that are going to be omitted anyway.
 592   (if dired-omit-files-p
 593       ;; perhaps return t without calling ls
 594       (let ((omit-re (dired-omit-regexp)))
 595         (if (or (string= omit-re "")
 596                 (not
 597                  (string-match omit-re
 598                                (cond
 599                                 ((eq 'no-dir dired-omit-localp)
 600                                  filename)
 601                                 ((eq t dired-omit-localp)
 602                                  (dired-make-relative filename))
 603                                 (t
 604                                  (dired-make-absolute
 605                                   filename
 606                                   (file-name-directory filename)))))))
 607             ;; if it didn't match, go ahead and add the entry
 608             (dired-omit-old-add-entry filename marker-char relative)
 609           ;; dired-add-entry returns t for success, perhaps we should
 610           ;; return file-exists-p
 611           t))
 612     ;; omitting is not turned on at all
 613     (dired-omit-old-add-entry filename marker-char relative)))
 614
 615 ;;; REDEFINE.
 616 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 617 ;;; Save old defun if not already done:
 618 (or (fboundp 'dired-omit-old-add-entry)
 619     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 620 ;; Redefine it.
 621 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 622
 623 \f
 624 ;;; VIRTUAL DIRED MODE.
 625
 626 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 627
 628 (fset 'virtual-dired 'dired-virtual)
 629 (defun dired-virtual (dirname &optional switches)
 630   "Put this buffer into Virtual Dired mode.
 631
 632 In Virtual Dired mode, all commands that do not actually consult the
 633 filesystem will work.
 634
 635 This is useful if you want to peruse and move around in an ls -lR
 636 output file, for example one you got from an ftp server.  With
 637 ange-ftp, you can even dired a directory containing an ls-lR file,
 638 visit that file and turn on virtual dired mode.  But don't try to save
 639 this file, as dired-virtual indents the listing and thus changes the
 640 buffer.
 641
 642 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 643 resume it in a later session.
 644
 645 Type \\<dired-mode-map>\\[revert-buffer] in the
 646 Virtual Dired buffer and answer `y' to convert the virtual to a real
 647 dired buffer again.  You don't have to do this, though: you can relist
 648 single subdirs using \\[dired-do-redisplay]."
 649
 650   ;; DIRNAME is the top level directory of the buffer.  It will become
 651   ;; its `default-directory'.  If nil, the old value of
 652   ;; default-directory is used.
 653
 654   ;; Optional SWITCHES are the ls switches to use.
 655
 656   ;; Shell wildcards will be used if there already is a `wildcard'
 657   ;; line in the buffer (thus it is a saved Dired buffer), but there
 658   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 659   ;; hand if you want them.
 660
 661   (interactive
 662    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 663   (goto-char (point-min))
 664   (or (looking-at "  ")
 665       ;; if not already indented, do it now:
 666       (indent-region (point-min) (point-max) 2))
 667   (or dirname (setq dirname default-directory))
 668   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 669   (setq default-directory dirname)      ; contains no wildcards
 670   (let ((wildcard (save-excursion
 671                     (goto-char (point-min))
 672                     (forward-line 1)
 673                     (and (looking-at "^  wildcard ")
 674                          (buffer-substring (match-end 0)
 675                                            (progn (end-of-line) (point)))))))
 676   (if wildcard
 677         (setq dirname (expand-file-name wildcard default-directory))))
 678   ;; If raw ls listing (not a saved old dired buffer), give it a
 679   ;; decent subdir headerline:
 680   (goto-char (point-min))
 681   (or (looking-at dired-subdir-regexp)
 682       (dired-insert-headerline default-directory))
 683   (dired-mode dirname (or switches dired-listing-switches))
 684   (setq mode-name "Virtual Dired"
 685         revert-buffer-function 'dired-virtual-revert)
 686   (set (make-local-variable 'dired-subdir-alist) nil)
 687   (dired-build-subdir-alist)
 688   (goto-char (point-min))
 689   (dired-initial-position dirname))
 690
 691 (defun dired-virtual-guess-dir ()
 692   "Guess and return appropriate working directory of this buffer.
 693 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 694 based upon buffer contents.  If nothing could be guessed, returns
 695 nil."
 696
 697   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 698         (subexpr 2))
 699     (goto-char (point-min))
 700     (cond ((looking-at regexp)
 701            ;; If a saved dired buffer, look to which dir and
 702            ;; perhaps wildcard it belongs:
 703            (let ((dir (buffer-substring (match-beginning subexpr)
 704                                         (match-end subexpr))))
 705              (file-name-as-directory dir)))
 706           ;; Else no match for headerline found.  It's a raw ls listing.
 707           ;; In raw ls listings the directory does not have a headerline
 708           ;; try parent of first subdir, if any
 709           ((re-search-forward regexp nil t)
 710            (file-name-directory
 711             (directory-file-name
 712              (file-name-as-directory
 713               (buffer-substring (match-beginning subexpr)
 714                                 (match-end subexpr))))))
 715           (t                            ; if all else fails
 716            nil))))
 717
 718
 719 (defun dired-virtual-revert (&optional arg noconfirm)
 720   (if (not
 721        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 722       (error "Cannot revert a Virtual Dired buffer")
 723     (setq mode-name "Dired"
 724           revert-buffer-function 'dired-revert)
 725     (revert-buffer)))
 726
 727 ;; A zero-arg version of dired-virtual.
 728 ;; You need my modified version of set-auto-mode for the
 729 ;; `buffer-contents-mode-alist'.
 730 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 731 (defun dired-virtual-mode ()
 732   "Put current buffer into virtual dired mode (see `dired-virtual').
 733 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 734
 735     \"^  \\(/[^ /]+\\)/?+:$\"
 736
 737 to put saved dired buffers automatically into virtual dired mode.
 738
 739 Also useful for `auto-mode-alist' (which see) like this:
 740
 741   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 742                               auto-mode-alist)\)"
 743   (interactive)
 744   (dired-virtual (dired-virtual-guess-dir)))
 745
 746 \f
 747 ;;; SMART SHELL.
 748
 749 ;;; An Emacs buffer can have but one working directory, stored in the
 750 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 751 ;;; several subdirectories inserted, but still has but one working directory:
 752 ;;; that of the top level Dired directory in that buffer.  For some commands
 753 ;;; it is appropriate that they use the current Dired directory instead of
 754 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 755 ;;; mechanism is provided for special handling of the working directory in
 756 ;;; special major modes.
 757
 758 ;; It's easier to add to this alist than redefine function
 759 ;; default-directory while keeping the old information.
 760 (defconst default-directory-alist
 761   '((dired-mode . (if (fboundp 'dired-current-directory)
 762                       (dired-current-directory)
 763                     default-directory)))
 764   "Alist of major modes and their opinion on `default-directory'.
 765 This is given as a Lisp expression to evaluate.  A resulting value of
 766 nil is ignored in favor of `default-directory'.")
 767
 768 (defun dired-default-directory ()
 769   "Usage like variable `default-directory'.
 770 Knows about the special cases in variable `default-directory-alist'."
 771   (or (eval (cdr (assq major-mode default-directory-alist)))
 772       default-directory))
 773
 774 (defun dired-smart-shell-command (cmd &optional insert)
 775   "Like function `shell-command', but in the current Tree Dired directory."
 776   (interactive (list (read-from-minibuffer "Shell command: "
 777                                            nil nil nil 'shell-command-history)
 778                      current-prefix-arg))
 779   (let ((default-directory (dired-default-directory)))
 780     (shell-command cmd insert)))
 781
 782 \f
 783 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 784
 785 ;;; Brief Description:
 786 ;;;
 787 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 788 ;;;
 789 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 790 ;;;
 791 ;;; * `dired-hack-local-variables' checks the value of
 792 ;;;   `dired-local-variables-file'
 793 ;;;
 794 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 795 ;;;   filename found in the directory of the Dired Buffer being created.
 796 ;;;
 797 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 798 ;;;   include it in the Dired Buffer at the bottom.
 799 ;;;
 800 ;;; * Set `enable-local-variables' temporarily to the user variable
 801 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 802 ;;;   Dired Buffer.
 803
 804 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 805   "Filename, as string, containing local dired buffer variables to be hacked.
 806 If this file found in current directory, then it will be inserted into dired
 807 buffer and `hack-local-variables' will be run.  See Emacs Info pages for more
 808 information on local variables.  See also `dired-enable-local-variables'.")
 809
 810 (defun dired-hack-local-variables ()
 811   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 812   (if (and dired-local-variables-file
 813            (stringp dired-local-variables-file)
 814            (file-exists-p dired-local-variables-file))
 815       (let ((opoint (point-max))
 816             buffer-read-only
 817             ;; In case user has `enable-local-variables' set to nil we
 818             ;; override it locally with dired's variable.
 819             (enable-local-variables dired-enable-local-variables))
 820         ;; Insert 'em.
 821         (save-excursion
 822           (goto-char opoint)
 823           (insert "\^L\n")
 824           (insert-file-contents dired-local-variables-file))
 825         ;; Hack 'em.
 826         (let ((buffer-file-name dired-local-variables-file))
 827           (hack-local-variables))
 828         ;; Make sure that the modeline shows the proper information.
 829         (dired-sort-set-modeline)
 830         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 831         (delete-region opoint (point-max)))))
 832
 833 (defun dired-omit-here-always ()
 834   "Create `dired-local-variables-file' for omitting and reverts directory.
 835 Sets dired-omit-file-p to t in a local variables file that is readable by
 836 dired."
 837   (interactive)
 838   (if (file-exists-p dired-local-variables-file)
 839       (message "File `./%s' already exists." dired-local-variables-file)
 840
 841     ;; Create `dired-local-variables-file'.
 842     (save-excursion
 843       (set-buffer (get-buffer-create " *dot-dired*"))
 844       (erase-buffer)
 845       (insert "Local Variables:\ndired-omit-files-p: t\nEnd:\n")
 846       (write-file dired-local-variables-file)
 847       (kill-buffer (current-buffer)))
 848
 849     ;; Run extra-hooks and revert directory.
 850     (dired-extra-startup)
 851     (dired-revert)))
 852
 853 \f
 854 ;;; GUESS SHELL COMMAND.
 855
 856 ;;; Brief Description:
 857 ;;;
 858 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 859 ;;;
 860 ;;; * Redefine `dired-do-shell-command' so it calls
 861 ;;;   `dired-guess-shell-command'.
 862 ;;;
 863 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 864 ;;;    marked files.
 865 ;;;
 866 ;;; * Parse `dired-guess-shell-alist-user' and
 867 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 868 ;;;   that matches the first file in the file list.
 869 ;;;
 870 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 871 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 872 ;;;   string.  COMMAND may be a list of commands.
 873 ;;;
 874 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 875 ;;;   with it.  The list of commands is temporarily put into the history list.
 876 ;;;   If a command is used successfully then it is stored permanently in
 877 ;;;   `dired-shell-command-history'.
 878
 879 ;;; Guess what shell command to apply to a file.
 880 (defvar dired-shell-command-history nil
 881   "History list for commands that read dired-shell commands.")
 882
 883 ;;; Default list of shell commands.
 884
 885 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 886 ;;; install GNU zip's version of zcat.
 887
 888 (defvar dired-guess-shell-alist-default
 889   (list
 890    (list "\\.tar$" '(if dired-guess-shell-gnutar
 891                         (concat dired-guess-shell-gnutar " xvf")
 892                       "tar xvf"))
 893
 894    ;; REGEXPS for compressed archives must come before the .Z rule to
 895    ;; be recognized:
 896    (list "\\.tar\\.Z$"
 897          ;; Untar it.
 898          '(if dired-guess-shell-gnutar
 899               (concat dired-guess-shell-gnutar " zxvf")
 900             (concat "zcat * | tar xvf -"))
 901          ;; Optional conversion to gzip format.
 902          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 903                   " " dired-guess-shell-znew-switches))
 904
 905    ;; gzip'ed archives
 906    (list "\\.t\\(ar\\.\\)?gz$"
 907          '(if dired-guess-shell-gnutar
 908               (concat dired-guess-shell-gnutar " zxvf")
 909             (concat "gunzip -qc * | tar xvf -"))
 910          ;; Optional decompression.
 911          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 912    ;; bzip2'ed archives
 913    (list "\\.tar\\.bz2$"
 914          "bunzip2 -c * | tar xvf -"
 915          ;; Optional decompression.
 916          "bunzip2")
 917
 918    '("\\.shar.Z$" "zcat * | unshar")
 919    '("\\.shar.g?z$" "gunzip -qc * | unshar")
 920
 921    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
 922    (list "\\.e?ps.g?z$" "gunzip -qc * | ghostview -"
 923          ;; Optional decompression.
 924          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 925    (list "\\.e?ps.Z$" "zcat * | ghostview -"
 926          ;; Optional conversion to gzip format.
 927          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 928                   " " dired-guess-shell-znew-switches))
 929    '("\\.patch$" "cat * | patch")
 930    '("\\.patch.g?z$" "gunzip -qc * | patch")
 931    (list "\\.patch.Z$" "zcat * | patch"
 932          ;; Optional conversion to gzip format.
 933          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 934                   " " dired-guess-shell-znew-switches))
 935
 936    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
 937    '("\\.au$" "play")                   ; play Sun audiofiles
 938    '("\\.mpg$" "mpeg_play")
 939    '("\\.uu$" "uudecode")               ; for uudecoded files
 940    '("\\.hqx$" "mcvert")
 941    '("\\.sh$" "sh")                     ; execute shell scripts
 942    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
 943    '("\\.gp$" "gnuplot")
 944    '("\\.p[bgpn]m$" "xloadimage")
 945    '("\\.gif$" "xloadimage")                    ; view gif pictures
 946    '("\\.tif$" "xloadimage")
 947    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
 948    '("\\.jpg$" "xloadimage")
 949    '("\\.fig$" "xfig")                  ; edit fig pictures
 950    '("\\.out$" "xgraph")                ; for plotting purposes.
 951    '("\\.tex$" "latex" "tex")
 952    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
 953    '("\\.pdf$" "xpdf")              ; edit PDF files
 954
 955    ;; Some other popular archivers.
 956    '("\\.zoo$" "zoo x//")
 957    '("\\.zip$" "unzip")
 958    '("\\.lzh$" "lharc x")
 959    '("\\.arc$" "arc x")
 960    '("\\.shar$" "unshar")
 961
 962    ;; Compression.
 963    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 964    (list "\\.bz2$" "bunzip2")
 965    (list "\\.Z$" "uncompress"
 966          ;; Optional conversion to gzip format.
 967          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 968                   " " dired-guess-shell-znew-switches))
 969    )
 970
 971   "Default alist used for shell command guessing.
 972 See `dired-guess-shell-alist-user'.")
 973
 974 (defcustom dired-guess-shell-alist-user nil
 975   "User-defined alist of rules for suggested commands.
 976 These rules take precedence over the predefined rules in the variable
 977 `dired-guess-shell-alist-default' (to which they are prepended).
 978
 979 Each element of this list looks like
 980
 981     \(REGEXP COMMAND...\)
 982
 983 where each COMMAND can either be a string or a lisp expression that evaluates
 984 to a string.  If several COMMANDs are given, the first one will be the default
 985 and the rest will be added temporarily to the history and can be retrieved
 986 with \\[previous-history-element] (M-p) .
 987
 988 You can set this variable in your ~/.emacs.  For example, to add rules for
 989 `.foo' and `.bar' files, write
 990
 991  \(setq dired-guess-shell-alist-user
 992        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
 993               ;; possibly more rules ...
 994               (list \"\\\\.bar\\\'\";; rule with condition test
 995                     '(if condition
 996                           \"BAR-COMMAND-1\"
 997                         \"BAR-COMMAND-2\")))\)"
 998   :group 'dired-x
 999   :type '(alist :key-type regexp :value-type (repeat sexp)))
1000
1001 (defun dired-guess-default (files)
1002   "Guess a shell commands for FILES.  Return command or list of commands.
1003 See `dired-guess-shell-alist-user'."
1004
1005   (let* ((case-fold-search nil) ; case-sensitive matching
1006          ;; Prepend the user's alist to the default alist.
1007          (alist (append dired-guess-shell-alist-user
1008                         dired-guess-shell-alist-default))
1009          (file (car files))
1010          (flist (cdr files))
1011          elt regexp cmds)
1012
1013     ;; Find the first match in the alist for first file in FILES.
1014     (while alist
1015       (setq elt (car alist)
1016             regexp (car elt)
1017             alist (cdr alist))
1018       (if (string-match regexp file)
1019           (setq cmds (cdr elt)
1020                 alist nil)))
1021
1022     ;; If more than one file, see if all of FILES match regular expression.
1023     (while (and flist
1024                 (string-match regexp (car flist)))
1025       (setq flist (cdr flist)))
1026
1027     ;; If flist is still non-nil, then do not guess since this means that not
1028     ;; all the files in FILES were matched by the regexp.
1029     (setq cmds (and (not flist) cmds))
1030
1031     ;; Return commands or nil if flist is still non-nil.
1032     ;; Evaluate the commands in order that any logical testing will be done.
1033     (cond ((not (cdr cmds))
1034            (eval (car cmds))) ; single command
1035           (t
1036            (mapcar (function eval) cmds)))))
1037
1038 (defun dired-guess-shell-command (prompt files)
1039   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1040
1041   (let ((default (dired-guess-default files))
1042         default-list old-history val (failed t))
1043
1044     (if (null default)
1045         ;; Nothing to guess
1046         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1047
1048       ;; Save current history list
1049       (setq old-history dired-shell-command-history)
1050
1051       (if (listp default)
1052
1053           ;; More than one guess
1054           (setq default-list default
1055                 default (car default)
1056                 prompt (concat
1057                         prompt
1058                         (format "{%d guesses} " (length default-list))))
1059
1060         ;; Just one guess
1061         (setq default-list (list default)))
1062
1063       ;; Push all guesses onto history so that they can be retrieved with M-p
1064       ;; and put the first guess in the prompt but not in the initial value.
1065       (setq dired-shell-command-history
1066             (append default-list dired-shell-command-history)
1067             prompt (concat prompt (format "[%s] " default)))
1068
1069       ;; The unwind-protect returns VAL, and we too.
1070       (unwind-protect
1071           ;; BODYFORM
1072           (progn
1073             (setq val (read-from-minibuffer prompt nil nil nil
1074                                             'dired-shell-command-history)
1075                   failed nil)
1076             ;; If we got a return, then use default.
1077             (if (equal val "")
1078                 (setq val default))
1079             val)
1080
1081         ;; UNWINDFORMS
1082         ;; Undo pushing onto the history list so that an aborted
1083         ;; command doesn't get the default in the next command.
1084         (setq dired-shell-command-history old-history)
1085         (if (not failed)
1086             (or (equal val (car-safe dired-shell-command-history))
1087                 (setq dired-shell-command-history
1088                       (cons val dired-shell-command-history))))))))
1089
1090
1091 ;;; REDEFINE.
1092 ;;; Redefine dired-aux.el's version:
1093 (defun dired-read-shell-command (prompt arg files)
1094   "Read a dired shell command prompting with PROMPT (using read-string).
1095 ARG is the prefix arg and may be used to indicate in the prompt which
1096   files are affected.
1097 This is an extra function so that you can redefine it."
1098   (dired-mark-pop-up
1099    nil 'shell files
1100    'dired-guess-shell-command
1101    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1102    files))                                       ; FILES
1103
1104 \f
1105 ;;; RELATIVE SYMBOLIC LINKS.
1106
1107 (defvar dired-keep-marker-relsymlink ?S
1108   "See variable `dired-keep-marker-move'.")
1109
1110 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1111   "Make a symbolic link (pointing to FILE1) in FILE2.
1112 The link is relative (if possible), for example
1113
1114     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1115
1116 results in
1117
1118     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1119   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1120   (let (name1 name2 len1 len2 (index 0) sub)
1121     (setq file1 (expand-file-name file1)
1122           file2 (expand-file-name file2)
1123           len1 (length file1)
1124           len2 (length file2))
1125     ;; Find common initial pathname components:
1126     (let (next)
1127       (while (and (setq next (string-match "/" file1 index))
1128                   (setq next (1+ next))
1129                   (< next (min len1 len2))
1130                   ;; For the comparison, both substrings must end in
1131                   ;; `/', so NEXT is *one plus* the result of the
1132                   ;; string-match.
1133                   ;; E.g., consider the case of linking "/tmp/a/abc"
1134                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1135                   ;; of "/tmp/" as common initial component
1136                   (string-equal (substring file1 0 next)
1137                                 (substring file2 0 next)))
1138         (setq index next))
1139       (setq name2 file2
1140             sub (substring file1 0 index)
1141             name1 (substring file1 index)))
1142     (if (string-equal sub "/")
1143         ;; No common initial pathname found
1144         (setq name1 file1)
1145       ;; Else they have a common parent directory
1146       (let ((tem (substring file2 index))
1147             (start 0)
1148             (count 0))
1149         ;; Count number of slashes we must compensate for ...
1150         (while (setq start (string-match "/" tem start))
1151           (setq count (1+ count)
1152                 start (1+ start)))
1153         ;; ... and prepend a "../" for each slash found:
1154         (while (> count 0)
1155           (setq count (1- count)
1156                 name1 (concat "../" name1)))))
1157     (make-symbolic-link
1158      (directory-file-name name1)        ; must not link to foo/
1159                                         ; (trailing slash!)
1160      name2 ok-if-already-exists)))
1161
1162 (defun dired-do-relsymlink (&optional arg)
1163    "Relative symlink all marked (or next ARG) files into a directory.
1164 Otherwise make a relative symbolic link to the current file.
1165 This creates relative symbolic links like
1166
1167     foo -> ../bar/foo
1168
1169 not absolute ones like
1170
1171     foo -> /ugly/path/that/may/change/any/day/bar/foo"
1172   (interactive "P")
1173   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1174                            "RelSymLink" arg dired-keep-marker-relsymlink))
1175
1176 (defun dired-do-relsymlink-regexp (regexp newname &optional whole-path)
1177   "RelSymlink all marked files containing REGEXP to NEWNAME.
1178 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1179 for more info."
1180   (interactive (dired-mark-read-regexp "RelSymLink"))
1181   (dired-do-create-files-regexp
1182    (function dired-make-relative-symlink)
1183    "RelSymLink" nil regexp newname whole-path dired-keep-marker-relsymlink))
1184
1185 \f
1186 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1187
1188 ;;; Brief Description:
1189 ;;;
1190 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1191 ;;;
1192 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1193 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1194 ;;;
1195 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1196 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1197 ;;;
1198 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1199 ;;;   list each time.
1200 ;;;
1201 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1202 ;;;   element of FILE-LIST.
1203 ;;;
1204 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1205 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1206 ;;;   cognizant of the window-configuration.
1207 ;;;
1208 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1209 ;;;   of FILE-LIST giving each a window of height `size'.
1210
1211 (defun dired-do-find-marked-files (&optional noselect)
1212   "Find all marked files displaying all of them simultaneously.
1213 With optional NOSELECT just find files but do not select them.
1214
1215 The current window is split across all files marked, as evenly as possible.
1216 Remaining lines go to bottom-most window.  The number of files that can be
1217 displayed this way is restricted by the height of the current window and
1218 `window-min-height'.
1219
1220 To keep dired buffer displayed, type \\[split-window-vertically] first.
1221 To display just marked files, type \\[delete-other-windows] first."
1222
1223   (interactive "P")
1224   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1225
1226 (defun dired-simultaneous-find-file (file-list noselect)
1227
1228   "Visit all files in FILE-LIST and display them simultaneously.
1229 The current window is split across all files in FILE-LIST, as evenly as
1230 possible.  Remaining lines go to the bottom-most window.  The number of
1231 files that can be displayed this way is restricted by the height of the
1232 current window and the variable `window-min-height'.  With non-nil
1233 NOSELECT the files are merely found but not selected."
1234
1235   ;; We don't make this function interactive because it is usually too clumsy
1236   ;; to specify FILE-LIST interactively unless via dired.
1237
1238   (let (size)
1239
1240     (if noselect
1241         ;; Do not select the buffer.
1242         (find-file-noselect (car file-list))
1243
1244       ;; We will have to select the buffer.  Calculate and check window size.
1245       (setq size (/ (window-height) (length file-list)))
1246       (or (<= window-min-height size)
1247           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1248       (find-file (car file-list)))
1249
1250     ;; Decrement.
1251     (setq file-list (cdr file-list))
1252
1253     (while file-list
1254
1255       (if noselect
1256           ;; Do not select the buffer.
1257           (find-file-noselect (car file-list))
1258
1259         ;; Vertically split off a window of desired size.  Upper window will
1260         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1261         (select-window (split-window nil size))
1262         (find-file (car file-list)))
1263
1264       ;; Decrement.
1265       (setq file-list (cdr file-list)))))
1266
1267 \f
1268 ;;; MISCELLANEOUS COMMANDS.
1269
1270 ;;; Run man on files.
1271
1272 (defun dired-man ()
1273   "Run man on this file.  Display old buffer if buffer name matches filename.
1274 Uses ../lisp/man.el of \\[manual-entry] fame."
1275   (interactive)
1276   (require 'man)
1277   (let ((file (dired-get-filename))
1278         (manual-program "nroff -man -h"))
1279     (Man-getpage-in-background file)))
1280
1281 ;;; Run Info on files.
1282
1283 (defun dired-info ()
1284   "Run info on this file."
1285   (interactive)
1286   (info (dired-get-filename)))
1287
1288 ;;; Run mail on mail folders.
1289
1290 ;;; (and (not (fboundp 'vm-visit-folder))
1291 ;;;      (defun vm-visit-folder (file &optional arg)
1292 ;;;        nil))
1293
1294 (defun dired-vm (&optional read-only)
1295   "Run VM on this file.
1296 With prefix arg, visit folder read-only (this requires at least VM 5).
1297 See also variable `dired-vm-read-only-folders'."
1298   (interactive "P")
1299   (let ((dir (dired-current-directory))
1300         (fil (dired-get-filename)))
1301     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1302     (cond (read-only (vm-visit-folder fil t))
1303           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1304           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1305           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1306     ;; so that pressing `v' inside VM does prompt within current directory:
1307     (set (make-local-variable 'vm-folder-directory) dir)))
1308
1309 (defun dired-rmail ()
1310   "Run RMAIL on this file."
1311   (interactive)
1312   (rmail (dired-get-filename)))
1313
1314 (defun dired-do-run-mail ()
1315   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1316   (interactive)
1317   (if dired-bind-vm
1318       ;; Read mail folder using vm.
1319       (dired-vm)
1320     ;; Read mail folder using rmail.
1321     (dired-rmail)))
1322
1323 \f
1324 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1325
1326 (or (fboundp 'dired-old-find-buffer-nocreate)
1327     (fset 'dired-old-find-buffer-nocreate
1328           (symbol-function 'dired-find-buffer-nocreate)))
1329
1330 ;;; REDEFINE.
1331 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1332 (defun dired-find-buffer-nocreate (dirname &optional mode)
1333   (if (and dired-find-subdir
1334            ;; don't try to find a wildcard as a subdirectory
1335            (string-equal dirname (file-name-directory dirname)))
1336       (let* ((cur-buf (current-buffer))
1337              (buffers (nreverse
1338                        (dired-buffers-for-dir (expand-file-name dirname))))
1339              (cur-buf-matches (and (memq cur-buf buffers)
1340                                    ;; wildcards must match, too:
1341                                    (equal dired-directory dirname))))
1342         ;; We don't want to switch to the same buffer---
1343         (setq buffers (delq cur-buf buffers));;need setq with delq
1344         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1345             ;; ---unless it's the only possibility:
1346             (and cur-buf-matches cur-buf)))
1347     (dired-old-find-buffer-nocreate dirname mode)))
1348
1349 ;; This should be a builtin
1350 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1351   "Return t if BUFFER1 is more recently used than BUFFER2."
1352   (if (equal buffer1 buffer2)
1353       nil
1354     (let ((more-recent nil)
1355           (list (buffer-list)))
1356       (while (and list
1357                   (not (setq more-recent (equal buffer1 (car list))))
1358                   (not (equal buffer2 (car list))))
1359         (setq list (cdr list)))
1360       more-recent)))
1361
1362 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1363 ;;; (defun dired-buffers-for-dir-exact (dir)
1364 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1365 ;;; ;; at top level, or as subdirectory.
1366 ;;; ;; Top level matches must match the wildcard part too, if any.
1367 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1368 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1369 ;;; ;; dired-buffers.
1370 ;;;   (let ((alist dired-buffers) result elt)
1371 ;;;     (while alist
1372 ;;;       (setq elt (car alist)
1373 ;;;             alist (cdr alist))
1374 ;;;       (let ((buf (cdr elt)))
1375 ;;;         (if (buffer-name buf)
1376 ;;;             ;; Top level must match exactly against dired-directory in
1377 ;;;             ;; case one of them is a wildcard.
1378 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1379 ;;;                                                dired-directory))
1380 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1381 ;;;                                                dired-subdir-alist)))
1382 ;;;                 (setq result (cons buf result)))
1383 ;;;           ;; else buffer is killed - clean up:
1384 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1385 ;;;     result))
1386
1387 ;;; REDEFINE.
1388 ;;; Redefines dired.el's version of `dired-initial-position'
1389 (defun dired-initial-position (dirname)
1390   "Where point should go in a new listing of DIRNAME.
1391 Point assumed at beginning of new subdir line.
1392 You may redefine this function as you wish, e.g. like in dired-x.el."
1393   (end-of-line)
1394   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1395   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1396
1397 \f
1398 ;; Does anyone use this? - lrd 6/29/93.
1399 ;; Apparently people do use it. - lrd 12/22/97.
1400 (defun dired-mark-sexp (predicate &optional unflag-p)
1401   "Mark files for which PREDICATE returns non-nil.
1402 With a prefix arg, unflag those files instead.
1403
1404 PREDICATE is a lisp expression that can refer to the following symbols:
1405
1406     inode  [integer] the inode of the file (only for ls -i output)
1407     s      [integer] the size of the file for ls -s output
1408                      (usually in blocks or, with -k, in KByte)
1409     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1410     nlink  [integer] number of links to file
1411     uid    [string]  owner
1412     gid    [string]  group  (If the gid is not displayed by ls,
1413                      this will still be set (to the same as uid))
1414     size   [integer] file size in bytes
1415     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1416     name   [string]  the name of the file
1417     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1418
1419 For example, use
1420
1421         (equal 0 size)
1422
1423 to mark all zero length files."
1424   ;; Using sym="" instead of nil avoids the trap of
1425   ;; (string-match "foo" sym) into which a user would soon fall.
1426   ;; Give `equal' instead of `=' in the example, as this works on
1427   ;; integers and strings.
1428   (interactive "xMark if (lisp expr): \nP")
1429   (message "%s" predicate)
1430   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1431         inode s mode nlink uid gid size time name sym)
1432     (dired-mark-if
1433      (save-excursion
1434        (and
1435         ;; Sets vars
1436         ;;                inode s mode nlink uid gid size time name sym
1437
1438         ;; according to current file line.  Returns t for success, nil if
1439         ;; there is no file line.  Upon success, all variables are set, either
1440         ;; to nil or the appropriate value, so they need not be initialized.
1441         ;; Moves point within the current line.
1442         (if (dired-move-to-filename)
1443             (let (pos
1444                   (mode-len 10) ; length of mode string
1445                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1446                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1447               (beginning-of-line)
1448               (forward-char 2)
1449               (if (looking-at dired-re-inode-size)
1450                   (progn
1451                     (goto-char (match-end 0))
1452                     (setq inode (string-to-int (buffer-substring (match-beginning 1)
1453                                                                  (match-end 1)))
1454                           s (string-to-int (buffer-substring (match-beginning 2)
1455                                                              (match-end 2)))))
1456                 (setq inode nil
1457                       s nil))
1458               (setq mode (buffer-substring (point) (+ mode-len (point))))
1459               (forward-char mode-len)
1460               (setq nlink (read (current-buffer)))
1461               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1462               (setq uid (buffer-substring (+ (point) 1)
1463                                           (progn (forward-word 1) (point))))
1464               (re-search-forward "\\(Jan\\|Feb\\|Mar\\|Apr\\|May\\|Jun\\|\
1465 Jul\\|Aug\\|Sep\\|Oct\\|Nov\\|Dec\\)")
1466               (goto-char (match-beginning 1))
1467               (forward-char -1)
1468               (setq size (string-to-int (buffer-substring (save-excursion
1469                                                             (backward-word 1)
1470                                                             (setq pos (point)))
1471                                                           (point))))
1472               (goto-char pos)
1473               (backward-word 1)
1474               ;; if no gid is displayed, gid will be set to uid
1475               ;; but user will then not reference it anyway in PREDICATE.
1476               (setq gid (buffer-substring (save-excursion
1477                                             (forward-word 1) (point))
1478                                           (point))
1479                     time (buffer-substring (match-beginning 1)
1480                                            (1- (dired-move-to-filename)))
1481                     name (buffer-substring (point)
1482                                            (or
1483                                             (dired-move-to-end-of-filename t)
1484                                             (point)))
1485                     sym  (progn
1486                            (if (looking-at " -> ")
1487                                (buffer-substring
1488                                 (progn (forward-char 4) (point))
1489                                 (progn (end-of-line) (point)))
1490                              "")))
1491               t)
1492           nil)
1493                       (eval predicate)))
1494      (format "'%s file" predicate))))
1495
1496 \f
1497 ;;; FIND FILE AT POINT.
1498
1499 (defvar dired-x-hands-off-my-keys t
1500   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1501 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1502 If you change this variable after dired-x.el is loaded then do
1503 \\[dired-x-bind-find-file].")
1504
1505 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1506 ;;; `find-file{-other-window}' is bound?
1507 (defun dired-x-bind-find-file ()
1508   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1509 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1510 Binding direction based on `dired-x-hands-off-my-keys'.
1511 This function part of `after-init-hook'."
1512   (interactive)
1513   (if (interactive-p)
1514       (setq dired-x-hands-off-my-keys
1515             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1516   (cond ((not dired-x-hands-off-my-keys)
1517          (substitute-key-definition 'find-file
1518                                     'dired-x-find-file
1519                                     (current-global-map))
1520          (substitute-key-definition 'find-file-other-window
1521                                     'dired-x-find-file-other-window
1522                                     (current-global-map)))
1523         (t
1524          (substitute-key-definition 'dired-x-find-file
1525                                     'find-file
1526                                     (current-global-map))
1527          (substitute-key-definition 'dired-x-find-file-other-window
1528                                     'find-file-other-window
1529                                     (current-global-map))))
1530   ;; Clear mini-buffer.
1531   (message nil))
1532
1533 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1534 ;;; user changes binding.
1535 (dired-x-bind-find-file)
1536 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1537
1538 (defun dired-x-find-file (filename)
1539   "Edit file FILENAME.
1540 May create a new window, or reuse an existing one.
1541 See the function `display-buffer'.
1542
1543 Identical to `find-file' except when called interactively, with a prefix arg
1544 \(e.g., \\[universal-argument]\), in which case it guesses filename near
1545 point.  Useful for editing file mentioned in buffer you are viewing, or to
1546 test if that file exists.  Use minibuffer after snatching filename."
1547   (interactive (list (read-filename-at-point "Find file: ")))
1548   (find-file (expand-file-name filename)))
1549
1550 (defun dired-x-find-file-other-window (filename)
1551   "Edit file FILENAME, in another window.
1552 May create a new window, or reuse an existing one.
1553 See the function `display-buffer'.
1554
1555 Identical to `find-file-other-window' except when called interactively, with a
1556 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename
1557 near point.  Useful for editing file mentioned in buffer you are viewing, or
1558 to test if that file exists.  Use minibuffer after snatching filename."
1559   (interactive (list (read-filename-at-point "Find file: ")))
1560   (find-file-other-window (expand-file-name filename)))
1561
1562 ;;; Internal functions.
1563 (defun dired-filename-at-point ()
1564
1565   "Get the filename closest to point, but do not change position.
1566 Has a preference for looking backward when not directly on a symbol.  Not
1567 perfect - point must be in middle of or end of filename."
1568
1569   (let ((filename-chars ".a-zA-Z0-9---_/:$+@") ; fixme: allow non-ASCII
1570         (bol (save-excursion (beginning-of-line) (point)))
1571         (eol (save-excursion (end-of-line) (point)))
1572         start end filename prefix)
1573
1574     (save-excursion
1575       ;; First see if just past a filename.
1576       (if (not (eobp))
1577           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1578               (progn
1579                 (skip-chars-backward " \n\t\r({[]})")
1580                 (if (not (bobp))
1581                     (backward-char 1)))))
1582
1583       (if (string-match (concat "[" filename-chars "]")
1584                         (char-to-string (following-char)))
1585           (progn
1586             (skip-chars-backward filename-chars)
1587             (setq start (point))
1588             (setq prefix
1589                   (and (string-match "^\\w+@"
1590                                      (buffer-substring start eol))
1591                        "/"))
1592             (goto-char start)
1593             (if (string-match "[/~]" (char-to-string (preceding-char)))
1594                 (setq start (1- start)))
1595             (skip-chars-forward filename-chars))
1596
1597         (error "No file found around point!"))
1598
1599       ;; Return string.
1600       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1601
1602 (defun read-filename-at-point (prompt)
1603   "Return filename prompting with PROMPT with completion.
1604 If `current-prefix-arg' is non-nil, uses name at point as guess."
1605   (if current-prefix-arg
1606       (let ((guess (dired-filename-at-point)))
1607         (read-file-name prompt
1608                         (file-name-directory guess)
1609                         guess
1610                         nil (file-name-nondirectory guess)))
1611     (read-file-name prompt default-directory)))
1612 \f
1613 ;;; BUG REPORTS
1614
1615 ;; Fixme: get rid of this later.
1616
1617 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1618 ;;; reporter.el which is bundled with GNU Emacs v19.
1619
1620 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1621   "Address(es) accepting submission of reports on dired-x.el.")
1622
1623 (defconst dired-x-variable-list
1624   (list
1625    'dired-bind-vm
1626    'dired-vm-read-only-folders
1627    'dired-bind-jump
1628    'dired-bind-info
1629    'dired-bind-man
1630    'dired-find-subdir
1631    'dired-enable-local-variables
1632    'dired-local-variables-file
1633    'dired-guess-shell-gnutar
1634    'dired-guess-shell-gzip-quiet
1635    'dired-guess-shell-znew-switches
1636    'dired-guess-shell-alist-user
1637    'dired-clean-up-buffers-too
1638    'dired-omit-files-p
1639    'dired-omit-files
1640    'dired-omit-extensions
1641    )
1642   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1643
1644 (defun dired-x-submit-report ()
1645   "Submit via reporter.el a bug report on program.
1646 Send report on `dired-x-file' version `dired-x-version,' to
1647 `dired-x-maintainer' at address `dired-x-help-address' listing
1648 variables `dired-x-variable-list' in the message."
1649   (interactive)
1650
1651   (reporter-submit-bug-report
1652    dired-x-help-address                 ; address
1653    "dired-x"                            ; pkgname
1654    dired-x-variable-list                ; varlist
1655    nil nil                              ; pre-/post-hooks
1656    ""))
1657
1658 \f
1659 ;; As Barry Warsaw would say: "This might be useful..."
1660 (provide 'dired-x)
1661
1662 ;;; dired-x.el ends here