configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(cocoa-experimental-ctrl-g,
 180 [AS_HELP_STRING([--enable-cocoa-experimental-ctrl-g],
 181                 [enable experimental improved ctrl-g recognition])],
 182    EN_COCOA_EXPERIMENTAL_CTRL_G=$enableval,
 183    EN_COCOA_EXPERIMENTAL_CTRL_G=no)
 184
 185 AC_ARG_ENABLE(ns-self-contained,
 186 [AS_HELP_STRING([--disable-ns-self-contained],
 187                 [disable self contained build under NeXTstep])],
 188    EN_NS_SELF_CONTAINED=$enableval,
 189    EN_NS_SELF_CONTAINED=yes)
 190
 191 AC_ARG_ENABLE(asserts,
 192 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 193       USE_XASSERTS=$enableval,
 194       USE_XASSERTS=no)
 195
 196 AC_ARG_ENABLE(maintainer-mode,
 197 [AS_HELP_STRING([--enable-maintainer-mode],
 198                 [enable make rules and dependencies not useful (and sometimes
 199                  confusing) to the casual installer])],
 200       USE_MAINTAINER_MODE=$enableval,
 201       USE_MAINTAINER_MODE=no)
 202 if test $USE_MAINTAINER_MODE = yes; then
 203   MAINT=
 204 else
 205   MAINT=#
 206 fi
 207 AC_SUBST(MAINT)
 208
 209 AC_ARG_ENABLE(locallisppath,
 210 [AS_HELP_STRING([--enable-locallisppath=PATH],
 211                 [directories Emacs should search for lisp files specific
 212                  to this site])],
 213 if test "${enableval}" = "no"; then
 214   locallisppath=
 215 elif test "${enableval}" != "yes"; then
 216   locallisppath=${enableval}
 217 fi)
 218
 219 #### Make srcdir absolute, if it isn't already.  It's important to
 220 #### avoid running the path through pwd unnecessarily, since pwd can
 221 #### give you automounter prefixes, which can go away.  We do all this
 222 #### so Emacs can find its files when run uninstalled.
 223 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 224 unset CDPATH
 225 case "${srcdir}" in
 226   /* ) ;;
 227   . )
 228     ## We may be able to use the $PWD environment variable to make this
 229     ## absolute.  But sometimes PWD is inaccurate.
 230     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 231     ## but that tested only for a well-formed and valid PWD,
 232     ## it did not object when PWD was well-formed and valid but just wrong.
 233     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 234     then
 235       srcdir="$PWD"
 236     else
 237       srcdir="`(cd ${srcdir}; pwd)`"
 238     fi
 239   ;;
 240   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 241 esac
 242
 243 #### Check if the source directory already has a configured system in it.
 244 if test `pwd` != `(cd ${srcdir} && pwd)` \
 245    && test -f "${srcdir}/src/config.h" ; then
 246   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 247    as a build directory right now; it has been configured in its own
 248    right.  To configure in another directory as well, you MUST
 249    use GNU make.  If you do not have GNU make, then you must
 250    now do `make distclean' in ${srcdir},
 251    and then run $0 again.]])
 252 fi
 253
 254 #### Given the configuration name, set machfile and opsysfile to the
 255 #### names of the m/*.h and s/*.h files we should use.
 256
 257 ### Canonicalize the configuration name.
 258
 259 AC_CANONICAL_HOST
 260 canonical=$host
 261 configuration=${host_alias-${build_alias-$host}}
 262
 263 dnl This used to use changequote, but, apart from `changequote is evil'
 264 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 265 dnl the great gob of text.  Thus it's not processed for possible expansion.
 266 dnl Just make sure the brackets remain balanced.
 267 dnl
 268 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 269 dnl indicated by comments.
 270 dnl quotation begins
 271 [
 272
 273 ### If you add support for a new configuration, add code to this
 274 ### switch statement to recognize your configuration name and select
 275 ### the appropriate operating system and machine description files.
 276
 277 ### You would hope that you could choose an m/*.h file pretty much
 278 ### based on the machine portion of the configuration name, and an s-
 279 ### file based on the operating system portion.  However, it turns out
 280 ### that each m/*.h file is pretty manufacturer-specific - for
 281 ### example mips.h is MIPS
 282 ### So we basically have to have a special case for each
 283 ### configuration name.
 284 ###
 285 ### As far as handling version numbers on operating systems is
 286 ### concerned, make sure things will fail in a fixable way.  If
 287 ### /etc/MACHINES doesn't say anything about version numbers, be
 288 ### prepared to handle anything reasonably.  If version numbers
 289 ### matter, be sure /etc/MACHINES says something about it.
 290 ###
 291 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 292 ### "System V Release 4"; he writes, "The old convention encouraged
 293 ### confusion between `system' and `release' levels'."
 294
 295 machine='' opsys='' unported=no
 296 case "${canonical}" in
 297
 298   ## FreeBSD ports
 299   *-*-freebsd* )
 300     opsys=freebsd
 301     case "${canonical}" in
 302       alpha*-*-freebsd*)        machine=alpha ;;
 303       arm*-*-freebsd*)          machine=arm ;;
 304       ia64-*-freebsd*)          machine=ia64 ;;
 305       sparc-*-freebsd*)         machine=sparc ;;
 306       sparc64-*-freebsd*)       machine=sparc ;;
 307       powerpc-*-freebsd*)       machine=macppc ;;
 308       i[3456]86-*-freebsd*)     machine=intel386 ;;
 309       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 310     esac
 311   ;;
 312
 313   ## FreeBSD kernel + glibc based userland
 314   *-*-kfreebsd*gnu* )
 315     opsys=gnu-kfreebsd
 316     case "${canonical}" in
 317       alpha*-*-kfreebsd*)       machine=alpha ;;
 318       ia64-*-kfreebsd*)         machine=ia64 ;;
 319       sparc-*-kfreebsd*)        machine=sparc ;;
 320       sparc64-*-kfreebsd*)      machine=sparc ;;
 321       powerpc-*-kfreebsd*)      machine=macppc ;;
 322       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 323       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 324     esac
 325   ;;
 326
 327   ## NetBSD ports
 328   *-*-netbsd* )
 329     opsys=netbsd
 330     if test -f /usr/lib/crti.o; then]
 331 dnl The close and open brackets here are because this section is quoted --
 332 dnl see the `changequote' comment above.
 333       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 334 [   fi
 335
 336     case "${canonical}" in
 337       alpha*-*-netbsd*) machine=alpha ;;
 338       i[3456]86-*-netbsd*) machine=intel386 ;;
 339       powerpc-*-netbsd*) machine=macppc ;;
 340       sparc*-*-netbsd*) machine=sparc ;;
 341       vax-*-netbsd*)    machine=vax ;;
 342       arm-*-netbsd*)    machine=arm ;;
 343       x86_64-*-netbsd*) machine=amdx86-64 ;;
 344       hppa-*-netbsd*)   machine=hp800 ;;
 345     esac
 346   ;;
 347
 348   ## OpenBSD ports
 349   *-*-openbsd* )
 350     opsys=openbsd
 351     case "${canonical}" in
 352       alpha*-*-openbsd*)        machine=alpha ;;
 353       arm-*-openbsd*)          machine=arm ;;
 354       i386-*-openbsd*)         machine=intel386 ;;
 355       powerpc-*-openbsd*)      machine=macppc ;;
 356       sparc*-*-openbsd*)       machine=sparc ;;
 357       vax-*-openbsd*)          machine=vax ;;
 358       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 359       hppa-*-openbsd*)         machine=hp800 ;;
 360     esac
 361   ;;
 362
 363   ## LynxOS ports
 364   *-*-lynxos* )
 365     opsys=lynxos
 366     case "${canonical}" in
 367       i[3456]86-*-lynxos*) machine=intel386 ;;
 368       powerpc-*-lynxos*) machine=powerpc ;;
 369     esac
 370   ;;
 371
 372   alpha*-*-linux-gnu* )
 373     machine=alpha opsys=gnu-linux
 374   ;;
 375
 376   arm*-*-linux-gnu* )
 377     machine=arm opsys=gnu-linux
 378   ;;
 379
 380   ## Apple Darwin / Mac OS X
 381   *-apple-darwin* )
 382     case "${canonical}" in
 383       i[3456]86-* )  machine=intel386 ;;
 384       powerpc-* )    machine=macppc ;;
 385       * )            unported=yes ;;
 386     esac
 387     opsys=darwin
 388     # Define CPP as follows to make autoconf work correctly.
 389     CPP="${CC-cc} -E -no-cpp-precomp"
 390     # Use fink packages if available.
 391     if test -d /sw/include && test -d /sw/lib; then
 392       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 393       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 394       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 395     fi
 396   ;;
 397
 398   ## HP 9000 series 700 and 800, running HP/UX
 399   hppa*-hp-hpux10.2* )
 400     machine=hp800 opsys=hpux10-20
 401   ;;
 402   hppa*-hp-hpux1[1-9]* )
 403     machine=hp800 opsys=hpux11
 404     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 405   ;;
 406
 407   hppa*-*-linux-gnu* )
 408     machine=hp800 opsys=gnu-linux
 409   ;;
 410
 411   ## IBM machines
 412   s390-*-linux-gnu* )
 413     machine=ibms390 opsys=gnu-linux
 414   ;;
 415   s390x-*-linux-gnu* )
 416     machine=ibms390x opsys=gnu-linux
 417   ;;
 418   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 419     machine=ibmrs6000 opsys=aix4-2
 420   ;;
 421   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 422     machine=ibmrs6000 opsys=aix4-2
 423   ;;
 424   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 425     machine=ibmrs6000 opsys=aix4-2
 426   ;;
 427   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 428     machine=ibmrs6000 opsys=aix4-2
 429   ;;
 430
 431   ## Macintosh PowerPC
 432   powerpc*-*-linux-gnu* )
 433     machine=macppc opsys=gnu-linux
 434   ;;
 435
 436   ## Silicon Graphics machines
 437   ## Iris 4D
 438   mips-sgi-irix6.5 )
 439     machine=iris4d opsys=irix6-5
 440     # Without defining _LANGUAGE_C, things get masked out in the headers
 441     # so that, for instance, grepping for `free' in stdlib.h fails and
 442     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 443     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 444     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 445   ;;
 446
 447   ## Suns
 448   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 449     machine=sparc opsys=gnu-linux
 450   ;;
 451
 452   *-sun-solaris* \
 453     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 454     | rs6000-*-solaris2*)
 455     case "${canonical}" in
 456       i[3456]86-*-* )     machine=intel386 ;;
 457       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 458       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 459       sparc* )          machine=sparc ;;
 460       * )               unported=yes ;;
 461     esac
 462     case "${canonical}" in
 463       *-sunos5.3* | *-solaris2.3* )
 464                 opsys=sol2-3
 465                 NON_GNU_CPP=/usr/ccs/lib/cpp
 466                 ;;
 467       *-sunos5.4* | *-solaris2.4* )
 468                 opsys=sol2-4
 469                 NON_GNU_CPP=/usr/ccs/lib/cpp
 470                 RANLIB="ar -ts"
 471                 ;;
 472       *-sunos5.5* | *-solaris2.5* )
 473                 opsys=sol2-5
 474                 NON_GNU_CPP=/usr/ccs/lib/cpp
 475                 RANLIB="ar -ts"
 476                 ;;
 477       *-sunos5.6* | *-solaris2.6* )
 478                 opsys=sol2-6
 479                 NON_GNU_CPP=/usr/ccs/lib/cpp
 480                 RANLIB="ar -ts"
 481                 ;;
 482       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 483                 opsys=sol2-6
 484                 emacs_check_sunpro_c=yes
 485                 NON_GNU_CPP=/usr/ccs/lib/cpp
 486                 ;;
 487       *-sunos5* | *-solaris* )
 488                 opsys=sol2-10
 489                 emacs_check_sunpro_c=yes
 490                 NON_GNU_CPP=/usr/ccs/lib/cpp
 491                 ;;
 492     esac
 493     ## Watch out for a compiler that we know will not work.
 494     case "${canonical}" in
 495      *-solaris* | *-sunos5* )
 496                 if [ "x$CC" = x/usr/ucb/cc ]; then
 497                   ## /usr/ucb/cc doesn't work;
 498                   ## we should find some other compiler that does work.
 499                   unset CC
 500                 fi
 501                 ;;
 502       *) ;;
 503     esac
 504   ;;
 505
 506   ## Vaxen.
 507   vax-dec-* )
 508     machine=vax
 509     case "${canonical}" in
 510       *-vms* )                                          opsys=vms ;;
 511       * )                                               unported=yes
 512     esac
 513   ;;
 514
 515   ## IA-64
 516   ia64*-*-linux* )
 517     machine=ia64 opsys=gnu-linux
 518   ;;
 519
 520   ## Intel 386 machines where we don't care about the manufacturer
 521   i[3456]86-*-* )
 522     machine=intel386
 523     case "${canonical}" in
 524       *-cygwin )                opsys=cygwin ;;
 525       *-darwin* )               opsys=darwin
 526                                 CPP="${CC-cc} -E -no-cpp-precomp"
 527                                 ;;
 528       *-linux-gnu* )            opsys=gnu-linux ;;
 529       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 530       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 531       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 532       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 533     esac
 534   ;;
 535
 536   ## m68k Linux-based GNU system
 537   m68k-*-linux-gnu* )
 538     machine=m68k opsys=gnu-linux
 539   ;;
 540
 541   ## Mips Linux-based GNU system
 542   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 543     machine=mips opsys=gnu-linux
 544   ;;
 545
 546   ## AMD x86-64 Linux-based GNU system
 547   x86_64-*-linux-gnu* )
 548     machine=amdx86-64 opsys=gnu-linux
 549   ;;
 550
 551   ## Tensilica Xtensa Linux-based GNU system
 552   xtensa*-*-linux-gnu* )
 553     machine=xtensa opsys=gnu-linux
 554     ;;
 555
 556   ## SuperH Linux-based GNU system
 557   sh[34]*-*-linux-gnu* )
 558     machine=sh3 opsys=gnu-linux
 559   ;;
 560
 561   * )
 562     unported=yes
 563   ;;
 564 esac
 565
 566 ### If the code above didn't choose an operating system, just choose
 567 ### an operating system based on the configuration name.  You really
 568 ### only want to use this when you have no idea what the right
 569 ### operating system is; if you know what operating systems a machine
 570 ### runs, it's cleaner to make it explicit in the case statement
 571 ### above.
 572 if test x"${opsys}" = x; then
 573   case "${canonical}" in
 574     *-gnu* )                            opsys=gnu ;;
 575     *-sysv4.2uw* )                      opsys=unixware ;;
 576     *-sysv5uw* )                        opsys=unixware ;;
 577     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 578     *-sysv4.1* | *-sysvr4.1* )
 579         NON_GNU_CPP=/usr/lib/cpp
 580         opsys=usg5-4 ;;
 581     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 582         if [ x$NON_GNU_CPP = x ]; then
 583           if [ -f /usr/ccs/lib/cpp ]; then
 584             NON_GNU_CPP=/usr/ccs/lib/cpp
 585           else
 586             NON_GNU_CPP=/lib/cpp
 587           fi
 588         fi
 589         opsys=usg5-4-2 ;;
 590     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 591     * )
 592       unported=yes
 593     ;;
 594   esac
 595 fi
 596
 597 ]
 598 dnl quotation ends
 599
 600 if test $unported = yes; then
 601   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 602 Check `etc/MACHINES' for recognized configuration names.])
 603 fi
 604
 605 machfile="m/${machine}.h"
 606 opsysfile="s/${opsys}.h"
 607
 608
 609 #### Choose a compiler.
 610 test -n "$CC" && cc_specified=yes
 611
 612 # Save the value of CFLAGS that the user specified.
 613 SPECIFIED_CFLAGS="$CFLAGS"
 614
 615 dnl Sets GCC=yes if using gcc.
 616 AC_PROG_CC
 617
 618 # On Suns, sometimes $CPP names a directory.
 619 if test -n "$CPP" && test -d "$CPP"; then
 620   CPP=
 621 fi
 622
 623 ## If not using gcc, and on Solaris, and no CPP specified, see if
 624 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 625 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 626  test x"$CPP" = x; then
 627   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 628   AC_CACHE_VAL(emacs_cv_sunpro_c,
 629   [AC_TRY_LINK([],
 630 [#ifndef __SUNPRO_C
 631 fail;
 632 #endif
 633 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 634   AC_MSG_RESULT($emacs_cv_sunpro_c)
 635
 636   if test x"$emacs_cv_sunpro_c" = xyes; then
 637     NON_GNU_CPP="$CC -E -Xs"
 638   fi
 639 fi
 640
 641 #### Some systems specify a CPP to use unless we are using GCC.
 642 #### Now that we know whether we are using GCC, we can decide whether
 643 #### to use that one.
 644 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 645 then
 646   CPP="$NON_GNU_CPP"
 647 fi
 648
 649 #### Some systems specify a CC to use unless we are using GCC.
 650 #### Now that we know whether we are using GCC, we can decide whether
 651 #### to use that one.
 652 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 653   test x$cc_specified != xyes
 654 then
 655   CC="$NON_GNU_CC"
 656 fi
 657
 658 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 659 then
 660   CC="$CC $GCC_TEST_OPTIONS"
 661 fi
 662
 663 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 664 then
 665   CC="$CC $NON_GCC_TEST_OPTIONS"
 666 fi
 667
 668 dnl checks for Unix variants
 669 AC_USE_SYSTEM_EXTENSIONS
 670
 671 ### Use -Wno-pointer-sign if the compiler supports it
 672 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 673 SAVE_CFLAGS="$CFLAGS"
 674 CFLAGS="$CFLAGS -Wno-pointer-sign"
 675 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 676 if test $has_option = yes; then
 677    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 678 fi
 679 AC_MSG_RESULT($has_option)
 680 CFLAGS="$SAVE_CFLAGS"
 681 unset has_option
 682 unset SAVE_CFLAGS
 683
 684 #### Some other nice autoconf tests.
 685
 686 dnl checks for programs
 687 AC_PROG_LN_S
 688 AC_PROG_CPP
 689 AC_PROG_INSTALL
 690 if test "x$RANLIB" = x; then
 691   AC_PROG_RANLIB
 692 fi
 693 AC_PATH_PROG(INSTALL_INFO, install-info)
 694 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 695 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 696 dnl Don't use GZIP, which is used by gzip for additional parameters.
 697 AC_PATH_PROG(GZIP_PROG, gzip)
 698
 699
 700 ## Need makeinfo >= 4.6 (?) to build the manuals.
 701 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 702 dnl By this stage, configure has already checked for egrep and set EGREP,
 703 dnl or exited with an error if no egrep was found.
 704 if test "$MAKEINFO" != "no" && \
 705   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 706    MAKEINFO=no
 707 fi
 708
 709 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 710 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 711 ## therefore in the category of "special tools" not normally required, which
 712 ## configure does not have to check for (eg autoconf itself).
 713 ## In a CVS checkout on the other hand, the manuals are not included.
 714 ## So makeinfo is a requirement to build from CVS, and configure
 715 ## should test for it as it does for any other build requirement.
 716 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 717 ## with pre-built manuals, from a CVS checkout.
 718 if test "$MAKEINFO" = "no"; then
 719   if test "x${with_makeinfo}" = "xno"; then
 720     MAKEINFO=off
 721   elif ! test -e $srcdir/info/emacs; then
 722     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 723 source tree does not seem to have pre-built manuals in the `info' directory.
 724 Either install a suitable version of makeinfo, or re-run configure
 725 with the `--without-makeinfo' option to build without the manuals.] )
 726   fi
 727 fi
 728
 729 dnl Add our options to ac_link now, after it is set up.
 730
 731 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 732 then
 733   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 734 fi
 735
 736 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 737 then
 738   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 739 fi
 740
 741 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 742 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 743 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 744 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 745 dnl if not built to support GNU ld.
 746
 747 late_LDFLAGS=$LDFLAGS
 748 if test "$GCC" = yes; then
 749   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 750 else
 751   LDFLAGS="$LDFLAGS -znocombreloc"
 752 fi
 753
 754 AC_MSG_CHECKING([for -znocombreloc])
 755 AC_LINK_IFELSE([main(){return 0;}],
 756   [AC_MSG_RESULT(yes)],
 757   LDFLAGS=$late_LDFLAGS
 758   [AC_MSG_RESULT(no)])
 759
 760 #### Extract some information from the operating system and machine files.
 761
 762 AC_CHECKING([the machine- and system-dependent files to find out
 763  - which libraries the lib-src programs will want, and
 764  - whether the GNU malloc routines are usable])
 765
 766 ### First figure out CFLAGS (which we use for running the compiler here)
 767 ### and REAL_CFLAGS (which we use for real compilation).
 768 ### The two are the same except on a few systems, where they are made
 769 ### different to work around various lossages.  For example,
 770 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 771 ### as implying static linking.
 772
 773 ### If the CFLAGS env var is specified, we use that value
 774 ### instead of the default.
 775
 776 ### It's not important that this name contain the PID; you can't run
 777 ### two configures in the same directory and have anything work
 778 ### anyway.
 779 tempcname="conftest.c"
 780
 781 echo '
 782 #include "'${srcdir}'/src/'${opsysfile}'"
 783 #include "'${srcdir}'/src/'${machfile}'"
 784 #ifndef LIBS_MACHINE
 785 #define LIBS_MACHINE
 786 #endif
 787 #ifndef LIBS_SYSTEM
 788 #define LIBS_SYSTEM
 789 #endif
 790 #ifndef C_SWITCH_SYSTEM
 791 #define C_SWITCH_SYSTEM
 792 #endif
 793 #ifndef C_SWITCH_MACHINE
 794 #define C_SWITCH_MACHINE
 795 #endif
 796 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 797 configure___ c_switch_system=C_SWITCH_SYSTEM
 798 configure___ c_switch_machine=C_SWITCH_MACHINE
 799
 800 #ifndef LIB_X11_LIB
 801 #define LIB_X11_LIB -lX11
 802 #endif
 803
 804 #ifndef LIBX11_SYSTEM
 805 #define LIBX11_SYSTEM
 806 #endif
 807 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 808
 809 #ifdef UNEXEC
 810 configure___ unexec=UNEXEC
 811 #else
 812 configure___ unexec=unexec.o
 813 #endif
 814
 815 #ifdef SYSTEM_MALLOC
 816 configure___ system_malloc=yes
 817 #else
 818 configure___ system_malloc=no
 819 #endif
 820
 821 #ifdef USE_MMAP_FOR_BUFFERS
 822 configure___ use_mmap_for_buffers=yes
 823 #else
 824 configure___ use_mmap_for_buffers=no
 825 #endif
 826
 827 #ifndef C_DEBUG_SWITCH
 828 #define C_DEBUG_SWITCH -g
 829 #endif
 830
 831 #ifndef C_OPTIMIZE_SWITCH
 832 #ifdef __GNUC__
 833 #define C_OPTIMIZE_SWITCH -O2
 834 #else
 835 #define C_OPTIMIZE_SWITCH -O
 836 #endif
 837 #endif
 838
 839 #ifndef C_WARNINGS_SWITCH
 840 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 841 #endif
 842
 843 #ifndef LD_SWITCH_MACHINE
 844 #define LD_SWITCH_MACHINE
 845 #endif
 846
 847 #ifndef LD_SWITCH_SYSTEM
 848 #define LD_SWITCH_SYSTEM
 849 #endif
 850
 851 #ifndef LD_SWITCH_X_SITE_AUX
 852 #define LD_SWITCH_X_SITE_AUX
 853 #endif
 854
 855 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 856 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 857
 858 #ifdef THIS_IS_CONFIGURE
 859
 860 /* Get the CFLAGS for tests in configure.  */
 861 #ifdef __GNUC__
 862 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 863 #else
 864 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 865 #endif
 866
 867 #else /* not THIS_IS_CONFIGURE */
 868
 869 /* Get the CFLAGS for real compilation.  */
 870 #ifdef __GNUC__
 871 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 872 #else
 873 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 874 #endif
 875
 876 #endif /* not THIS_IS_CONFIGURE */
 877 ' > ${tempcname}
 878
 879 # The value of CPP is a quoted variable reference, so we need to do this
 880 # to get its actual value...
 881 CPP=`eval "echo $CPP"`
 882 [eval `${CPP} -Isrc ${tempcname} \
 883        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 884 if test "x$SPECIFIED_CFLAGS" = x; then
 885   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 886          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 887 else
 888   REAL_CFLAGS="$CFLAGS"
 889 fi]
 890 rm ${tempcname}
 891
 892 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 893
 894 ### Make sure subsequent tests use flags consistent with the build flags.
 895
 896 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 897   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 898 else
 899   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 900 fi
 901
 902 dnl For AC_FUNC_GETLOADAVG, at least:
 903 AC_CONFIG_LIBOBJ_DIR(src)
 904
 905 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 906 AC_SYS_LARGEFILE
 907
 908
 909 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 910 ### be located in either /usr/lib64 or /usr/lib.
 911 ### In some rare cases, /usr/lib64 exists but does not contain the
 912 ### relevant files (bug#1287).  Hence test for crtn.o.
 913 case "${canonical}" in
 914   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 915     if test -e /usr/lib64/crtn.o; then
 916       AC_DEFINE(HAVE_LIB64_DIR, 1,
 917         [Define to 1 if the directory /usr/lib64 exists.])
 918 fi
 919 esac
 920
 921 dnl This function defintion taken from Gnome 2.0
 922 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 923 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 924 dnl also defines GSTUFF_PKG_ERRORS on error
 925 AC_DEFUN([PKG_CHECK_MODULES], [
 926   succeeded=no
 927
 928   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 929
 930   if test "$PKG_CONFIG" = "no" ; then
 931      ifelse([$4], , [AC_MSG_ERROR([
 932       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 933   else
 934      PKG_CONFIG_MIN_VERSION=0.9.0
 935      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 936         AC_MSG_CHECKING(for $2)
 937
 938         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 939             AC_MSG_RESULT(yes)
 940             succeeded=yes
 941
 942             AC_MSG_CHECKING($1_CFLAGS)
 943             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 944             AC_MSG_RESULT($$1_CFLAGS)
 945
 946             AC_MSG_CHECKING($1_LIBS)
 947             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 948             AC_MSG_RESULT($$1_LIBS)
 949         else
 950             AC_MSG_RESULT(no)
 951             $1_CFLAGS=""
 952             $1_LIBS=""
 953             ## If we have a custom action on failure, don't print errors, but
 954             ## do set a variable so people can do so.
 955             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 956             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 957         fi
 958
 959         AC_SUBST($1_CFLAGS)
 960         AC_SUBST($1_LIBS)
 961      else
 962         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 963         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 964      fi
 965   fi
 966
 967   if test $succeeded = yes; then
 968      ifelse([$3], , :, [$3])
 969   else
 970      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 971   fi
 972 ])
 973
 974
 975 if test "${with_sound}" != "no"; then
 976   # Sound support for GNU/Linux and the free BSDs.
 977   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 978   # Emulation library used on NetBSD.
 979   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 980   AC_SUBST(LIBSOUND)
 981
 982   ALSA_REQUIRED=1.0.0
 983   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 984   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 985   if test $HAVE_ALSA = yes; then
 986     SAVE_CFLAGS="$CFLAGS"
 987     SAVE_LDFLAGS="$LDFLAGS"
 988     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 989     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 990     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 991                     emacs_alsa_normal=yes,
 992                     emacs_alsa_normal=no)
 993     if test "$emacs_alsa_normal" != yes; then
 994       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 995                      [snd_lib_error_set_handler (0);],
 996                      emacs_alsa_subdir=yes,
 997                      emacs_alsa_subdir=no)
 998       if test "$emacs_alsa_subdir" != yes; then
 999         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1000       fi
1001       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1002     fi
1003
1004     CFLAGS="$SAVE_CFLAGS"
1005     LDFLAGS="$SAVE_LDFLAGS"
1006     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1007     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1008     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1009   fi
1010   AC_SUBST(CFLAGS_SOUND)
1011 fi
1012
1013 dnl checks for header files
1014 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1015   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1016   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1017   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1018   sys/utsname.h pwd.h)
1019
1020 AC_MSG_CHECKING(if personality LINUX32 can be set)
1021 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1022                emacs_cv_personality_linux32=yes,
1023                emacs_cv_personality_linux32=no)
1024 AC_MSG_RESULT($emacs_cv_personality_linux32)
1025
1026 if test $emacs_cv_personality_linux32 = yes; then
1027   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1028             [Define to 1 if personality LINUX32 can be set.])
1029 fi
1030
1031 dnl On Solaris 8 there's a compilation warning for term.h because
1032 dnl it doesn't define `bool'.
1033 AC_CHECK_HEADERS(term.h, , , -)
1034 AC_HEADER_STDC
1035 AC_HEADER_TIME
1036 AC_CHECK_DECLS([sys_siglist])
1037 if test $ac_cv_have_decl_sys_siglist != yes; then
1038   # For Tru64, at least:
1039   AC_CHECK_DECLS([__sys_siglist])
1040   if test $ac_cv_have_decl___sys_siglist = yes; then
1041     AC_DEFINE(sys_siglist, __sys_siglist,
1042               [Define to any substitute for sys_siglist.])
1043   fi
1044 fi
1045 AC_HEADER_SYS_WAIT
1046
1047 dnl Some systems have utime.h but don't declare the struct anyplace.
1048 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1049 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1050 #include <sys/time.h>
1051 #include <time.h>
1052 #else
1053 #ifdef HAVE_SYS_TIME_H
1054 #include <sys/time.h>
1055 #else
1056 #include <time.h>
1057 #endif
1058 #endif
1059 #ifdef HAVE_UTIME_H
1060 #include <utime.h>
1061 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1062   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1063 if test $emacs_cv_struct_utimbuf = yes; then
1064   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1065 fi
1066
1067 dnl checks for typedefs
1068 AC_TYPE_SIGNAL
1069
1070 dnl Check for speed_t typedef.
1071 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1072   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1073     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1074 if test $emacs_cv_speed_t = yes; then
1075   AC_DEFINE(HAVE_SPEED_T, 1,
1076            [Define to 1 if `speed_t' is declared by <termios.h>.])
1077 fi
1078
1079 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1080 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1081 #include <sys/time.h>
1082 #include <time.h>
1083 #else
1084 #ifdef HAVE_SYS_TIME_H
1085 #include <sys/time.h>
1086 #else
1087 #include <time.h>
1088 #endif
1089 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1090   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1091 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1092 if test $emacs_cv_struct_timeval = yes; then
1093   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1094 fi
1095
1096 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1097 AC_TRY_COMPILE([#include <math.h>],
1098 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1099   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1100 HAVE_EXCEPTION=$emacs_cv_struct_exception
1101 if test $emacs_cv_struct_exception != yes; then
1102   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1103 fi
1104
1105 AC_CHECK_HEADERS(sys/socket.h)
1106 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1107 #if HAVE_SYS_SOCKET_H
1108 #include <sys/socket.h>
1109 #endif])
1110
1111 dnl checks for structure members
1112 AC_STRUCT_TM
1113 AC_STRUCT_TIMEZONE
1114 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1115                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1116                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1117                 [#include <time.h>])
1118 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1119                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1120                   struct ifreq.ifr_addr], , ,
1121                  [AC_INCLUDES_DEFAULT
1122 #if HAVE_SYS_SOCKET_H
1123 #include <sys/socket.h>
1124 #endif
1125 #if HAVE_NET_IF_H
1126 #include <net/if.h>
1127 #endif])
1128
1129 dnl checks for compiler characteristics
1130
1131 dnl Testing __STDC__ to determine prototype support isn't good enough.
1132 dnl DEC C, for instance, doesn't define it with default options, and
1133 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1134 dnl and void *.
1135 AC_C_PROTOTYPES
1136 AC_C_VOLATILE
1137 AC_C_CONST
1138 dnl This isn't useful because we can't turn on use of `inline' unless
1139 dnl the compiler groks `extern inline'.
1140 dnl AC_C_INLINE
1141 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1142   [AC_TRY_COMPILE(, [void * foo;],
1143                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1144 if test $emacs_cv_void_star = yes; then
1145   AC_DEFINE(POINTER_TYPE, void)
1146 else
1147   AC_DEFINE(POINTER_TYPE, char)
1148 fi
1149 AH_TEMPLATE(POINTER_TYPE,
1150             [Define as `void' if your compiler accepts `void *'; otherwise
1151              define as `char'.])dnl
1152
1153
1154
1155 dnl This could be used for targets which can have both byte sexes.
1156 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1157 dnl AC_C_BIGENDIAN
1158
1159 dnl check for Make feature
1160 AC_PROG_MAKE_SET
1161
1162 dnl checks for operating system services
1163 AC_SYS_LONG_FILE_NAMES
1164
1165 #### Choose a window system.
1166
1167 AC_PATH_X
1168 if test "$no_x" = yes; then
1169   window_system=none
1170 else
1171   window_system=x11
1172 fi
1173
1174 ## Workaround for bug in autoconf <= 2.62.
1175 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1176 ## No need to do anything special for these standard directories.
1177 ## This is an experiment, take it out if it causes problems.
1178 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1179
1180    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1181
1182 fi
1183
1184 if test "${x_libraries}" != NONE; then
1185   if test -n "${x_libraries}"; then
1186     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1187     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1188   fi
1189   x_default_search_path=""
1190   x_search_path=${x_libraries}
1191   if test -z "${x_search_path}"; then
1192     x_search_path=/usr/lib
1193   fi
1194   for x_library in `echo ${x_search_path}: | \
1195                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1196     x_search_path="\
1197 ${x_library}/X11/%L/%T/%N%C%S:\
1198 ${x_library}/X11/%l/%T/%N%C%S:\
1199 ${x_library}/X11/%T/%N%C%S:\
1200 ${x_library}/X11/%L/%T/%N%S:\
1201 ${x_library}/X11/%l/%T/%N%S:\
1202 ${x_library}/X11/%T/%N%S"
1203     if test x"${x_default_search_path}" = x; then
1204       x_default_search_path=${x_search_path}
1205     else
1206       x_default_search_path="${x_search_path}:${x_default_search_path}"
1207     fi
1208   done
1209 fi
1210 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1211   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1212 fi
1213
1214 if test x"${x_includes}" = x; then
1215   bitmapdir=/usr/include/X11/bitmaps
1216 else
1217   # accumulate include directories that have X11 bitmap subdirectories
1218   bmd_acc="dummyval"
1219   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1220     if test -d "${bmd}/X11/bitmaps"; then
1221       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1222     fi
1223     if test -d "${bmd}/bitmaps"; then
1224       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1225     fi
1226   done
1227   if test ${bmd_acc} != "dummyval"; then
1228     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1229   fi
1230 fi
1231
1232 HAVE_NS=no
1233 NS_IMPL_COCOA=no
1234 NS_IMPL_GNUSTEP=no
1235 tmp_CPPFLAGS="$CPPFLAGS"
1236 tmp_CFLAGS="$CFLAGS"
1237 CPPFLAGS="$CPPFLAGS -x objective-c"
1238 CFLAGS="$CFLAGS -x objective-c"
1239 if test "${with_ns}" != no; then
1240   if test "${opsys}" = darwin; then
1241      NS_IMPL_COCOA=yes
1242      ns_appdir=`pwd`/nextstep/Emacs.app
1243      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1244      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1245      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1246   elif test -f $GNUSTEP_CONFIG_FILE; then
1247      NS_IMPL_GNUSTEP=yes
1248      ns_appdir=`pwd`/nextstep/Emacs.app
1249      ns_appbindir=`pwd`/nextstep/Emacs.app
1250      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1251      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1252      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1253      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1254      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1255      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1256      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1257      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1258      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1259      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1260   fi
1261   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1262                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1263   files are missing or cannot be compiled.])])
1264   NS_HAVE_NSINTEGER=yes
1265   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1266                                      [NSInteger i;])],
1267                     ns_have_nsinteger=yes,
1268                     ns_have_nsinteger=no)
1269   if test $ns_have_nsinteger = no; then
1270     NS_HAVE_NSINTEGER=no
1271   fi
1272 fi
1273 if test "${HAVE_NS}" = yes; then
1274   window_system=nextstep
1275   with_xft=no
1276   with_freetype=no
1277   # set up packaging dirs
1278   exec_prefix=${ns_appbindir}
1279   libexecdir=${ns_appbindir}/libexec
1280   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1281      prefix=${ns_appresdir}
1282   fi
1283 fi
1284 CFLAGS="$tmp_CFLAGS"
1285 CPPFLAGS="$tmp_CPPFLAGS"
1286
1287 case "${window_system}" in
1288   x11 )
1289     HAVE_X_WINDOWS=yes
1290     HAVE_X11=yes
1291     case "${with_x_toolkit}" in
1292       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1293       motif ) USE_X_TOOLKIT=MOTIF ;;
1294       gtk ) with_gtk=yes
1295 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1296 dnl USE_X_TOOLKIT is set.
1297             USE_X_TOOLKIT=none ;;
1298       no ) USE_X_TOOLKIT=none ;;
1299 dnl If user did not say whether to use a toolkit, make this decision later:
1300 dnl use the toolkit if we have gtk, or X11R5 or newer.
1301       * ) USE_X_TOOLKIT=maybe ;;
1302     esac
1303   ;;
1304   nextstep | none )
1305     HAVE_X_WINDOWS=no
1306     HAVE_X11=no
1307     USE_X_TOOLKIT=none
1308   ;;
1309 esac
1310
1311 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1312    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1313    if test "$HAVE_XSERVER" = true ||
1314       test -n "$DISPLAY" ||
1315       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1316         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1317 were found.  You should install the relevant development files for X
1318 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1319 sure you have development files for image handling, i.e.
1320 tiff, gif, jpeg, png and xpm.
1321 If you are sure you want Emacs compiled without X window support, pass
1322   --without-x
1323 to configure.])
1324    fi
1325 fi
1326
1327 ### If we're using X11, we should use the X menu package.
1328 HAVE_MENUS=no
1329 case ${HAVE_X11} in
1330   yes ) HAVE_MENUS=yes ;;
1331 esac
1332
1333 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1334 # Assume not, until told otherwise.
1335 GNU_MALLOC=yes
1336 doug_lea_malloc=yes
1337 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1338 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1339 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1340                emacs_cv_var___after_morecore_hook,
1341 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1342   emacs_cv_var___after_morecore_hook=yes,
1343   emacs_cv_var___after_morecore_hook=no)])
1344 if test $emacs_cv_var___after_morecore_hook = no; then
1345   doug_lea_malloc=no
1346 fi
1347 if test "${system_malloc}" = "yes"; then
1348   GNU_MALLOC=no
1349   GNU_MALLOC_reason="
1350     (The GNU allocators don't work with this system configuration.)"
1351 fi
1352 if test "$doug_lea_malloc" = "yes" ; then
1353   if test "$GNU_MALLOC" = yes ; then
1354     GNU_MALLOC_reason="
1355       (Using Doug Lea's new malloc from the GNU C Library.)"
1356   fi
1357   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1358             [Define to 1 if you are using the GNU C Library.])
1359 fi
1360
1361 if test x"${REL_ALLOC}" = x; then
1362   REL_ALLOC=${GNU_MALLOC}
1363 fi
1364
1365 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1366 dnl the system configuration file (s/*.h) to turn the use of mmap
1367 dnl in the relocating allocator on.
1368
1369 AC_FUNC_MMAP
1370 if test $use_mmap_for_buffers = yes; then
1371   REL_ALLOC=no
1372 fi
1373
1374 LIBS="$libsrc_libs $LIBS"
1375
1376 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1377 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1378 AC_CHECK_LIB(dnet, dnet_ntoa)
1379 dnl This causes -lresolv to get used in subsequent tests,
1380 dnl which causes failures on some systems such as HPUX 9.
1381 dnl AC_CHECK_LIB(resolv, gethostbyname)
1382
1383 dnl FIXME replace main with a function we actually want from this library.
1384 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1385
1386 AC_CHECK_LIB(pthreads, cma_open)
1387
1388 dnl Check for need for bigtoc support on IBM AIX
1389
1390 case ${host_os} in
1391 aix*)
1392   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1393     case $GCC in
1394     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1395     *) gdb_cv_bigtoc=-bbigtoc ;;
1396     esac
1397
1398     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1399     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1400   ])
1401   ;;
1402 esac
1403
1404 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1405 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1406 # REAL_CPPFLAGS later on.
1407
1408 REAL_CPPFLAGS="$CPPFLAGS"
1409
1410 if test "${HAVE_X11}" = "yes"; then
1411   DEFS="$C_SWITCH_X_SITE $DEFS"
1412   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1413   LIBS="$LIBX $LIBS"
1414   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1415   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1416
1417   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1418   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1419   # but it's more convenient here to set LD_RUN_PATH
1420   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1421   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1422     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1423     export LD_RUN_PATH
1424   fi
1425
1426   if test "${opsys}" = "gnu-linux"; then
1427     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1428     AC_TRY_LINK([],
1429      [XOpenDisplay ("foo");],
1430      [xlinux_first_failure=no],
1431      [xlinux_first_failure=yes])
1432     if test "${xlinux_first_failure}" = "yes"; then
1433       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1434       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1435       OLD_CPPFLAGS="$CPPFLAGS"
1436       OLD_LIBS="$LIBS"
1437       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1438       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1439       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1440       LIBS="$LIBS -b i486-linuxaout"
1441       AC_TRY_LINK([],
1442        [XOpenDisplay ("foo");],
1443        [xlinux_second_failure=no],
1444        [xlinux_second_failure=yes])
1445       if test "${xlinux_second_failure}" = "yes"; then
1446         # If we get the same failure with -b, there is no use adding -b.
1447         # So take it out.  This plays safe.
1448         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1449         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1450         CPPFLAGS="$OLD_CPPFLAGS"
1451         LIBS="$OLD_LIBS"
1452         AC_MSG_RESULT(no)
1453       else
1454         AC_MSG_RESULT(yes)
1455       fi
1456     else
1457       AC_MSG_RESULT(no)
1458     fi
1459   fi
1460
1461   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1462   # header files included from there.
1463   AC_MSG_CHECKING(for Xkb)
1464   AC_TRY_LINK([#include <X11/Xlib.h>
1465 #include <X11/XKBlib.h>],
1466         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1467         emacs_xkb=yes, emacs_xkb=no)
1468   AC_MSG_RESULT($emacs_xkb)
1469   if test $emacs_xkb = yes; then
1470     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1471   fi
1472
1473   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1474 XScreenNumberOfScreen XSetWMProtocols)
1475 fi
1476
1477 if test "${window_system}" = "x11"; then
1478   AC_MSG_CHECKING(X11 version 6)
1479   AC_CACHE_VAL(emacs_cv_x11_version_6,
1480   [AC_TRY_LINK([#include <X11/Xlib.h>],
1481 [#if XlibSpecificationRelease < 6
1482 fail;
1483 #endif
1484 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1485   if test $emacs_cv_x11_version_6 = yes; then
1486     AC_MSG_RESULT(6 or newer)
1487     AC_DEFINE(HAVE_X11R6, 1,
1488               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1489   else
1490     AC_MSG_RESULT(before 6)
1491   fi
1492 fi
1493
1494
1495 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1496 HAVE_RSVG=no
1497 if test "${HAVE_X11}" = "yes"; then
1498   if test "${with_rsvg}" != "no"; then
1499     RSVG_REQUIRED=2.0.0
1500     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1501
1502     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1503     AC_SUBST(RSVG_CFLAGS)
1504     AC_SUBST(RSVG_LIBS)
1505
1506     if test ".${RSVG_CFLAGS}" != "."; then
1507       HAVE_RSVG=yes
1508       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1509       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1510       LIBS="$RSVG_LIBS $LIBS"
1511     fi
1512   fi
1513 fi
1514
1515
1516 HAVE_GTK=no
1517 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1518   GLIB_REQUIRED=2.6
1519   GTK_REQUIRED=2.6
1520   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1521
1522   dnl Checks for libraries.
1523   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1524   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1525      AC_MSG_ERROR($GTK_PKG_ERRORS)
1526   fi
1527 fi
1528
1529
1530 if test x"$pkg_check_gtk" = xyes; then
1531
1532   AC_SUBST(GTK_CFLAGS)
1533   AC_SUBST(GTK_LIBS)
1534   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1535   CFLAGS="$CFLAGS $GTK_CFLAGS"
1536   LIBS="$GTK_LIBS $LIBS"
1537   dnl Try to compile a simple GTK program.
1538   GTK_COMPILES=no
1539   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1540   if test "${GTK_COMPILES}" != "yes"; then
1541     if test "$USE_X_TOOLKIT" != "maybe"; then
1542       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1543     fi
1544   else
1545     HAVE_GTK=yes
1546     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1547     USE_X_TOOLKIT=none
1548     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1549       :
1550     else
1551       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1552        closing open displays.  This is no problem if you just use
1553        one display, but if you use more than one and close one of them
1554        Emacs may crash.]])
1555       sleep 3
1556     fi
1557   fi
1558
1559 fi
1560
1561
1562 if test "${HAVE_GTK}" = "yes"; then
1563
1564   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1565   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1566   if test "$with_toolkit_scroll_bars" != no; then
1567     with_toolkit_scroll_bars=yes
1568   fi
1569
1570   dnl  Check if we can use multiple displays with this GTK version.
1571   dnl  If gdk_display_open exists, assume all others are there also.
1572   HAVE_GTK_MULTIDISPLAY=no
1573   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1574   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1575     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1576               [Define to 1 if GTK can handle more than one display.])
1577   fi
1578
1579   dnl  Check if we have the old file selection dialog.
1580   dnl  If gdk_display_open exists, assume all others are there also.
1581   HAVE_GTK_FILE_SELECTION=no
1582   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1583
1584   dnl  Check if we have the new file chooser dialog
1585   dnl  If gdk_display_open exists, assume all others are there also.
1586   HAVE_GTK_FILE_CHOOSER=no
1587   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1588
1589   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1590      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1591     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1592               [Define to 1 if GTK has both file selection and chooser dialog.])
1593   fi
1594
1595   dnl Check if pthreads are available.  Emacs only needs this when using
1596   dnl gtk_file_chooser under Gnome.
1597   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1598     HAVE_GTK_AND_PTHREAD=no
1599     AC_CHECK_HEADERS(pthread.h)
1600     if test "$ac_cv_header_pthread_h"; then
1601       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1602     fi
1603     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1604       case "${canonical}" in
1605         *-hpux*) ;;
1606         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1607       esac
1608       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1609                [Define to 1 if you have GTK and pthread (-lpthread).])
1610     fi
1611   fi
1612 fi
1613
1614 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1615 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1616 dnl also not configured.
1617 HAVE_DBUS=no
1618 if test "${with_dbus}" = "yes"; then
1619    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1620    if test "$HAVE_DBUS" = yes; then
1621       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1622    fi
1623 fi
1624
1625 dnl Do not put whitespace before the #include statements below.
1626 dnl Older compilers (eg sunos4 cc) choke on it.
1627 HAVE_XAW3D=no
1628 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1629   if test "$with_xaw3d" != no; then
1630     AC_MSG_CHECKING(for xaw3d)
1631     AC_CACHE_VAL(emacs_cv_xaw3d,
1632     [AC_TRY_LINK([
1633 #include <X11/Intrinsic.h>
1634 #include <X11/Xaw3d/Simple.h>],
1635       [],
1636       emacs_cv_xaw3d=yes,
1637       emacs_cv_xaw3d=no)])
1638   else
1639     emacs_cv_xaw3d=no
1640   fi
1641   if test $emacs_cv_xaw3d = yes; then
1642     AC_MSG_RESULT([yes; using Lucid toolkit])
1643     USE_X_TOOLKIT=LUCID
1644     HAVE_XAW3D=yes
1645     AC_DEFINE(HAVE_XAW3D, 1,
1646               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1647   else
1648     AC_MSG_RESULT(no)
1649     AC_MSG_CHECKING(for libXaw)
1650     AC_CACHE_VAL(emacs_cv_xaw,
1651     [AC_TRY_LINK([
1652 #include <X11/Intrinsic.h>
1653 #include <X11/Xaw/Simple.h>],
1654       [],
1655       emacs_cv_xaw=yes,
1656       emacs_cv_xaw=no)])
1657     if test $emacs_cv_xaw = yes; then
1658       AC_MSG_RESULT([yes; using Lucid toolkit])
1659       USE_X_TOOLKIT=LUCID
1660     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1661       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1662     else
1663       AC_MSG_RESULT([no; do not use toolkit by default])
1664       USE_X_TOOLKIT=none
1665     fi
1666   fi
1667 fi
1668
1669 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1670
1671 if test "${USE_X_TOOLKIT}" != "none"; then
1672   AC_MSG_CHECKING(X11 toolkit version)
1673   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1674   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1675 [#if XtSpecificationRelease < 6
1676 fail;
1677 #endif
1678 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1679   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1680   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1681     AC_MSG_RESULT(6 or newer)
1682     AC_DEFINE(HAVE_X11XTR6, 1,
1683               [Define to 1 if you have the X11R6 or newer version of Xt.])
1684   else
1685     AC_MSG_RESULT(before 6)
1686   fi
1687
1688 dnl If using toolkit, check whether libXmu.a exists.
1689 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1690   OLDLIBS="$LIBS"
1691   if test x$HAVE_X11XTR6 = xyes; then
1692     LIBS="-lXt -lSM -lICE $LIBS"
1693   else
1694     LIBS="-lXt $LIBS"
1695   fi
1696   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1697   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1698 fi
1699
1700 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1701 if test "${HAVE_X11}" = "yes"; then
1702   if test "${USE_X_TOOLKIT}" != "none"; then
1703     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1704   fi
1705 fi
1706
1707 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1708   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1709   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1710     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1711 int x = 5;
1712 #else
1713 Motif version prior to 2.1.
1714 #endif],
1715     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1716   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1717   if test $emacs_cv_motif_version_2_1 = yes; then
1718     HAVE_LIBXP=no
1719     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1720               [Define to 1 if you have Motif 2.1 or newer.])
1721     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1722     if test ${HAVE_LIBXP} = yes; then
1723       AC_DEFINE(HAVE_LIBXP, 1,
1724                 [Define to 1 if you have the Xp library (-lXp).])
1725     fi
1726   else
1727     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1728     # We put this in CFLAGS temporarily to precede other -I options
1729     # that might be in CFLAGS temporarily.
1730     # We put this in CPPFLAGS where it precedes the other -I options.
1731     OLD_CPPFLAGS=$CPPFLAGS
1732     OLD_CFLAGS=$CFLAGS
1733     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1734     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1735     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1736       [int x = 5;],
1737       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1738     if test $emacs_cv_lesstif = yes; then
1739       # Make sure this -I option remains in CPPFLAGS after it is set
1740       # back to REAL_CPPFLAGS.
1741       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1742       # have those other -I options anyway.  Ultimately, having this
1743       # directory ultimately in CPPFLAGS will be enough.
1744       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1745       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1746     else
1747       CFLAGS=$OLD_CFLAGS
1748       CPPFLAGS=$OLD_CPPFLAGS
1749     fi
1750   fi
1751 fi
1752
1753 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1754 dnl using Motif or Xaw3d is available, and unless
1755 dnl --with-toolkit-scroll-bars=no was specified.
1756
1757 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1758             [Define to 1 if we should use toolkit scroll bars.])dnl
1759 USE_TOOLKIT_SCROLL_BARS=no
1760 if test "${with_toolkit_scroll_bars}" != "no"; then
1761   if test "${USE_X_TOOLKIT}" != "none"; then
1762     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1763       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1764       HAVE_XAW3D=no
1765       USE_TOOLKIT_SCROLL_BARS=yes
1766     elif test "${HAVE_XAW3D}" = "yes"; then
1767       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1768       USE_TOOLKIT_SCROLL_BARS=yes
1769     fi
1770   elif test "${HAVE_GTK}" = "yes"; then
1771     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1772     USE_TOOLKIT_SCROLL_BARS=yes
1773   elif test "${HAVE_NS}" = "yes"; then
1774     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1775     USE_TOOLKIT_SCROLL_BARS=yes
1776   fi
1777 fi
1778
1779 dnl See if XIM is available.
1780 AC_TRY_COMPILE([
1781           #include <X11/Xlib.h>
1782           #include <X11/Xresource.h>],
1783          [XIMProc  callback;],
1784          [HAVE_XIM=yes
1785          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1786          HAVE_XIM=no)
1787
1788 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1789
1790 if test "${with_xim}" != "no"; then
1791   AC_DEFINE(USE_XIM, 1,
1792             [Define to 1 if we should use XIM, if it is available.])
1793 fi
1794
1795
1796 if test "${HAVE_XIM}" != "no"; then
1797   late_CFLAGS=$CFLAGS
1798   if test "$GCC" = yes; then
1799     CFLAGS="$CFLAGS --pedantic-errors"
1800   fi
1801   AC_TRY_COMPILE([
1802 #include <X11/Xlib.h>
1803 #include <X11/Xresource.h>],
1804 [Display *display;
1805 XrmDatabase db;
1806 char *res_name;
1807 char *res_class;
1808 XIMProc  callback;
1809 XPointer *client_data;
1810 #ifndef __GNUC__
1811 /* If we're not using GCC, it's probably not XFree86, and this is
1812    probably right, but we can't use something like --pedantic-errors.  */
1813 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1814                                            char*, XIMProc, XPointer*);
1815 #endif
1816 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1817    client_data);],
1818     [emacs_cv_arg6_star=yes])
1819   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1820          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1821 either XPointer or XPointer*.])dnl
1822   if test "$emacs_cv_arg6_star" = yes; then
1823     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1824   else
1825     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1826   fi
1827   CFLAGS=$late_CFLAGS
1828 fi
1829
1830 ### Start of font-backend section.
1831 PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1832 test "${HAVE_FC}" = "no" && with_freetype=no
1833
1834 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1835 HAVE_XFT=maybe
1836 if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1837   with_xft="no";
1838 fi
1839 if test "x${with_xft}" != "xno"; then
1840
1841   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1842   if test "$HAVE_XFT" != no; then
1843     OLD_CPPFLAGS="$CPPFLAGS"
1844     OLD_CFLAGS="$CFLAGS"
1845     OLD_LIBS="$LIBS"
1846     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1847     CFLAGS="$CFLAGS $XFT_CFLAGS"
1848     LIBS="$XFT_LIBS $LIBS"
1849     AC_CHECK_HEADER(X11/Xft/Xft.h,
1850       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1851
1852     if test "${HAVE_XFT}" = "yes"; then
1853       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1854         AC_SUBST(XFT_LIBS)
1855       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1856     else
1857       CPPFLAGS="$OLD_CPPFLAGS"
1858       CFLAGS="$OLD_CFLAGS"
1859       LIBS="$OLD_LIBS"
1860     fi                        # "${HAVE_XFT}" = "yes"
1861   fi                          # "$HAVE_XFT" != no
1862 fi                            # "x${with_xft}" != "xno"
1863
1864 dnl For the "Does Emacs use" message at the end.
1865 if test "$HAVE_XFT" != "yes"; then
1866    HAVE_XFT=no
1867 fi
1868
1869
1870 HAVE_FREETYPE=no
1871 ### Use -lfreetype if available, unless `--with-freetype=no'.
1872 if test "${HAVE_XFT}" = "yes"; then
1873   dnl As we use Xft, we anyway use freetype.
1874   dnl In this case, there's no need of additional CFLAGS and LIBS.
1875   HAVE_FREETYPE=yes
1876   FONTCONFIG_CFLAGS=
1877   FONTCONFIG_LIBS=
1878 elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1879
1880   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1881 fi
1882
1883 HAVE_LIBOTF=no
1884 if test "${HAVE_FREETYPE}" = "yes"; then
1885   AC_DEFINE(HAVE_FREETYPE, 1,
1886             [Define to 1 if using the freetype and fontconfig libraries.])
1887   if test "${with_libotf}" != "no"; then
1888     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1889                       HAVE_LIBOTF=no)
1890     if test "$HAVE_LIBOTF" = "yes"; then
1891       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1892     fi
1893   fi
1894 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1895 dnl Does the new font backend require it, or can it work without it?
1896 fi
1897
1898 HAVE_M17N_FLT=no
1899 if test "${HAVE_LIBOTF}" = yes; then
1900   if test "${with_m17n_flt}" != "no"; then
1901     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1902     if test "$HAVE_M17N_FLT" = "yes"; then
1903       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1904     fi
1905   fi
1906 fi
1907
1908 AC_SUBST(FREETYPE_CFLAGS)
1909 AC_SUBST(FREETYPE_LIBS)
1910 AC_SUBST(FONTCONFIG_CFLAGS)
1911 AC_SUBST(FONTCONFIG_LIBS)
1912 AC_SUBST(LIBOTF_CFLAGS)
1913 AC_SUBST(LIBOTF_LIBS)
1914 AC_SUBST(M17N_FLT_CFLAGS)
1915 AC_SUBST(M17N_FLT_LIBS)
1916
1917 ### End of font-backend section.
1918
1919 ### Use -lXpm if available, unless `--with-xpm=no'.
1920 HAVE_XPM=no
1921 if test "${HAVE_X11}" = "yes"; then
1922   if test "${with_xpm}" != "no"; then
1923     AC_CHECK_HEADER(X11/xpm.h,
1924       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1925     if test "${HAVE_XPM}" = "yes"; then
1926       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1927       AC_EGREP_CPP(no_return_alloc_pixels,
1928       [#include "X11/xpm.h"
1929 #ifndef XpmReturnAllocPixels
1930 no_return_alloc_pixels
1931 #endif
1932       ], HAVE_XPM=no, HAVE_XPM=yes)
1933
1934       if test "${HAVE_XPM}" = "yes"; then
1935         AC_MSG_RESULT(yes)
1936       else
1937         AC_MSG_RESULT(no)
1938       fi
1939     fi
1940   fi
1941
1942   if test "${HAVE_XPM}" = "yes"; then
1943     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1944   fi
1945 fi
1946
1947 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1948 HAVE_JPEG=no
1949 if test "${HAVE_X11}" = "yes"; then
1950   if test "${with_jpeg}" != "no"; then
1951     dnl Checking for jpeglib.h can lose because of a redefinition of
1952     dnl  HAVE_STDLIB_H.
1953     AC_CHECK_HEADER(jerror.h,
1954       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1955   fi
1956
1957   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1958   if test "${HAVE_JPEG}" = "yes"; then
1959     AC_DEFINE(HAVE_JPEG)
1960     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1961         [#include <jpeglib.h>
1962          version=JPEG_LIB_VERSION
1963 ],
1964         [AC_DEFINE(HAVE_JPEG)],
1965         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1966         HAVE_JPEG=no])
1967   fi
1968 fi
1969
1970 ### Use -lpng if available, unless `--with-png=no'.
1971 HAVE_PNG=no
1972 if test "${HAVE_X11}" = "yes"; then
1973   if test "${with_png}" != "no"; then
1974     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1975     # in /usr/include/libpng.
1976     AC_CHECK_HEADERS(png.h libpng/png.h)
1977     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1978       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1979     fi
1980   fi
1981
1982   if test "${HAVE_PNG}" = "yes"; then
1983     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1984   fi
1985 fi
1986
1987 ### Use -ltiff if available, unless `--with-tiff=no'.
1988 HAVE_TIFF=no
1989 if test "${HAVE_X11}" = "yes"; then
1990   if test "${with_tiff}" != "no"; then
1991     AC_CHECK_HEADER(tiffio.h,
1992       [tifflibs="-lz -lm"
1993       # At least one tiff package requires the jpeg library.
1994       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1995       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
1996   fi
1997
1998   if test "${HAVE_TIFF}" = "yes"; then
1999     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2000   fi
2001 fi
2002
2003 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2004 HAVE_GIF=no
2005 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2006   AC_CHECK_HEADER(gif_lib.h,
2007 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2008 # Earlier versions can crash Emacs.
2009     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2010
2011   if test "$HAVE_GIF" = yes; then
2012       ac_gif_lib_name="-lgif"
2013   fi
2014
2015 # If gif_lib.h but no libgif, try libungif.
2016   if test x"$try_libungif" = xyes; then
2017     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2018
2019     if test "$HAVE_GIF" = yes; then
2020       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2021       ac_gif_lib_name="-lungif"
2022     fi
2023   fi
2024
2025   if test "${HAVE_GIF}" = "yes"; then
2026     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2027   fi
2028 fi
2029
2030 dnl Check for required libraries.
2031 if test "${HAVE_X11}" = "yes"; then
2032   MISSING=""
2033   WITH_NO=""
2034   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2035     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2036   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2037     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2038   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2039     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2040   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2041     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2042   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2043     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2044
2045   if test "X${MISSING}" != X; then
2046     AC_MSG_ERROR([The following required libraries were not found:
2047     $MISSING
2048 Maybe some development libraries/packages are missing?
2049 If you don't want to link with them give
2050     $WITH_NO
2051 as options to configure])
2052   fi
2053 fi
2054
2055 ### Use -lgpm if available, unless `--with-gpm=no'.
2056 HAVE_GPM=no
2057 if test "${with_gpm}" != "no"; then
2058   AC_CHECK_HEADER(gpm.h,
2059     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2060 fi
2061
2062 if test "${HAVE_GPM}" = "yes"; then
2063   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2064 fi
2065
2066 dnl Check for malloc/malloc.h on darwin
2067 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2068
2069 ### Use NeXTstep API to implement GUI.
2070 if test "${HAVE_NS}" = "yes"; then
2071   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2072   if test "${NS_IMPL_COCOA}" = "yes"; then
2073     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2074     GNU_OBJC_CFLAGS=
2075     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2076   fi
2077   if test "${EN_COCOA_EXPERIMENTAL_CTRL_G}" = "yes"; then
2078     AC_DEFINE(COCOA_EXPERIMENTAL_CTRL_G, 1, [Define to 1 if you are trying experimental enhanced Ctrl-g support using NS windowing under MacOS X.])
2079   fi
2080   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2081     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2082     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2083   fi
2084   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2085     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2086   fi
2087   # We also have mouse menus.
2088   HAVE_MENUS=yes
2089 fi
2090
2091
2092 ### Use session management (-lSM -lICE) if available
2093 HAVE_X_SM=no
2094 if test "${HAVE_X11}" = "yes"; then
2095   AC_CHECK_HEADER(X11/SM/SMlib.h,
2096     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2097
2098   if test "${HAVE_X_SM}" = "yes"; then
2099     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2100     case "$LIBS" in
2101       *-lSM*) ;;
2102       *)      LIBS="-lSM -lICE $LIBS" ;;
2103     esac
2104   fi
2105 fi
2106
2107 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2108 AC_CACHE_CHECK(whether netdb declares h_errno,
2109                emacs_cv_netdb_declares_h_errno,
2110 [AC_TRY_LINK([#include <netdb.h>],
2111   [return h_errno;],
2112   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2113 if test $emacs_cv_netdb_declares_h_errno = yes; then
2114   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2115 fi
2116
2117 AC_FUNC_ALLOCA
2118
2119 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2120 dnl FIXME is there an autoconf test that does the right thing, without
2121 dnl needing to call A_M_E afterwards?
2122 if test x"$ac_cv_func_alloca_works" != xyes; then
2123    AC_MSG_ERROR( [a system implementation of alloca is required] )
2124 fi
2125
2126 # fmod, logb, and frexp are found in -lm on most systems.
2127 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2128 AC_CHECK_LIB(m, sqrt)
2129
2130 # Check for mail-locking functions in a "mail" library.  Probably this should
2131 # have the same check as for liblockfile below.
2132 AC_CHECK_LIB(mail, maillock)
2133 dnl Debian, at least:
2134 AC_CHECK_LIB(lockfile, maillock)
2135 # If we have the shared liblockfile, assume we must use it for mail
2136 # locking (e.g. Debian).  If we couldn't link against liblockfile
2137 # (no liblockfile.a installed), ensure that we don't need to.
2138 if test "$ac_cv_lib_lockfile_maillock" = no; then
2139   dnl This works for files generally, not just executables.
2140   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2141   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2142                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2143   if test $ac_cv_prog_liblockfile = yes; then
2144     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2145 This probably means that movemail could lose mail.
2146 There may be a `development' package to install containing liblockfile.])
2147   else :
2148   fi
2149 fi
2150 AC_CHECK_FUNCS(touchlock)
2151 AC_CHECK_HEADERS(maillock.h)
2152
2153 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2154 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2155 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2156 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2157 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2158 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2159 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2160 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2161 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2162 cfmakeraw cfsetspeed)
2163
2164 AC_CHECK_HEADERS(sys/un.h)
2165
2166 AC_FUNC_MKTIME
2167 if test "$ac_cv_func_working_mktime" = no; then
2168   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2169 fi
2170
2171 AC_FUNC_GETLOADAVG
2172
2173 AC_FUNC_FSEEKO
2174
2175 # Configure getopt.
2176 m4_include([m4/getopt.m4])
2177 gl_GETOPT_IFELSE([
2178   gl_GETOPT_SUBSTITUTE_HEADER
2179   gl_PREREQ_GETOPT
2180   GETOPTOBJS='getopt.o getopt1.o'
2181 ])
2182 AC_SUBST(GETOPTOBJS)
2183
2184 AC_FUNC_GETPGRP
2185
2186 AC_FUNC_STRFTIME
2187
2188 # UNIX98 PTYs.
2189 AC_CHECK_FUNCS(grantpt)
2190
2191 # PTY-related GNU extensions.
2192 AC_CHECK_FUNCS(getpt)
2193
2194 # Check this now, so that we will NOT find the above functions in ncurses.
2195 # That is because we have not set up to link ncurses in lib-src.
2196 # It's better to believe a function is not available
2197 # than to expect to find it in ncurses.
2198 AC_CHECK_LIB(ncurses, tparm)
2199
2200 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2201
2202 resolv=no
2203 AC_TRY_LINK([#include <netinet/in.h>
2204 #include <arpa/nameser.h>
2205 #include <resolv.h>],
2206     [return res_init();],
2207     have_res_init=yes, have_res_init=no)
2208 if test "$have_res_init" = no; then
2209   OLIBS="$LIBS"
2210   LIBS="$LIBS -lresolv"
2211   AC_MSG_CHECKING(for res_init with -lresolv)
2212   AC_TRY_LINK([#include <netinet/in.h>
2213 #include <arpa/nameser.h>
2214 #include <resolv.h>],
2215     [return res_init();],
2216     have_res_init=yes, have_res_init=no)
2217   AC_MSG_RESULT($have_res_init)
2218   if test "$have_res_init" = yes ; then
2219     resolv=yes
2220   fi
2221   LIBS="$OLIBS"
2222 fi
2223
2224 if test "$have_res_init" = yes; then
2225   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2226 fi
2227
2228 # Do we need the Hesiod library to provide the support routines?
2229 if test "$with_hesiod" != no ; then
2230   # Don't set $LIBS here -- see comments above.
2231   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2232      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2233                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2234   if test "$resolv" = yes ; then
2235     RESOLVLIB=-lresolv
2236   else
2237     RESOLVLIB=
2238   fi
2239   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2240         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2241                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2242         :, $RESOLVLIB)])
2243 fi
2244
2245 # Do we need libresolv (due to res_init or Hesiod)?
2246 if test "$resolv" = yes ; then
2247   AC_DEFINE(HAVE_LIBRESOLV, 1,
2248             [Define to 1 if you have the resolv library (-lresolv).])
2249 fi
2250
2251 # These tell us which Kerberos-related libraries to use.
2252 if test "${with_kerberos}" != no; then
2253   AC_CHECK_LIB(com_err, com_err)
2254   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2255   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2256   AC_CHECK_LIB(krb5, krb5_init_context)
2257   if test "${with_kerberos5}" = no; then
2258     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2259                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2260     AC_CHECK_LIB(krb4, krb_get_cred,,
2261                  [AC_CHECK_LIB(krb, krb_get_cred)])
2262   fi
2263
2264   if test "${with_kerberos5}" != no; then
2265     AC_CHECK_HEADERS(krb5.h,
2266       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2267                         [#include <krb5.h>])])
2268   else
2269     AC_CHECK_HEADERS(des.h,,
2270                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2271                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2272     AC_CHECK_HEADERS(krb.h,,
2273                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2274                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2275   fi
2276   AC_CHECK_HEADERS(com_err.h)
2277 fi
2278
2279 # Solaris requires -lintl if you want strerror (which calls dgettext)
2280 # to return localized messages.
2281 AC_CHECK_LIB(intl, dgettext)
2282
2283 AC_MSG_CHECKING(whether localtime caches TZ)
2284 AC_CACHE_VAL(emacs_cv_localtime_cache,
2285 [if test x$ac_cv_func_tzset = xyes; then
2286 AC_TRY_RUN([#include <time.h>
2287 extern char **environ;
2288 unset_TZ ()
2289 {
2290   char **from, **to;
2291   for (to = from = environ; (*to = *from); from++)
2292     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2293       to++;
2294 }
2295 char TZ_GMT0[] = "TZ=GMT0";
2296 char TZ_PST8[] = "TZ=PST8";
2297 main()
2298 {
2299   time_t now = time ((time_t *) 0);
2300   int hour_GMT0, hour_unset;
2301   if (putenv (TZ_GMT0) != 0)
2302     exit (1);
2303   hour_GMT0 = localtime (&now)->tm_hour;
2304   unset_TZ ();
2305   hour_unset = localtime (&now)->tm_hour;
2306   if (putenv (TZ_PST8) != 0)
2307     exit (1);
2308   if (localtime (&now)->tm_hour == hour_GMT0)
2309     exit (1);
2310   unset_TZ ();
2311   if (localtime (&now)->tm_hour != hour_unset)
2312     exit (1);
2313   exit (0);
2314 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2315 [# If we have tzset, assume the worst when cross-compiling.
2316 emacs_cv_localtime_cache=yes])
2317 else
2318         # If we lack tzset, report that localtime does not cache TZ,
2319         # since we can't invalidate the cache if we don't have tzset.
2320         emacs_cv_localtime_cache=no
2321 fi])dnl
2322 AC_MSG_RESULT($emacs_cv_localtime_cache)
2323 if test $emacs_cv_localtime_cache = yes; then
2324   AC_DEFINE(LOCALTIME_CACHE, 1,
2325             [Define to 1 if localtime caches TZ.])
2326 fi
2327
2328 if test "x$HAVE_TIMEVAL" = xyes; then
2329   AC_CHECK_FUNCS(gettimeofday)
2330   if test $ac_cv_func_gettimeofday = yes; then
2331     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2332                    emacs_cv_gettimeofday_two_arguments,
2333     [AC_TRY_COMPILE([
2334 #ifdef TIME_WITH_SYS_TIME
2335 #include <sys/time.h>
2336 #include <time.h>
2337 #else
2338 #ifdef HAVE_SYS_TIME_H
2339 #include <sys/time.h>
2340 #else
2341 #include <time.h>
2342 #endif
2343 #endif],
2344       [struct timeval time;
2345        gettimeofday (&time, 0);],
2346       emacs_cv_gettimeofday_two_arguments=yes,
2347       emacs_cv_gettimeofday_two_arguments=no)])
2348     if test $emacs_cv_gettimeofday_two_arguments = no; then
2349       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2350                 [Define to 1 if gettimeofday accepts only one argument.])
2351     fi
2352   fi
2353 fi
2354
2355 ok_so_far=yes
2356 AC_CHECK_FUNC(socket, , ok_so_far=no)
2357 if test $ok_so_far = yes; then
2358   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2359 fi
2360 if test $ok_so_far = yes; then
2361   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2362 fi
2363 if test $ok_so_far = yes; then
2364 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2365   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2366             [Define to 1 if you have inet sockets.])
2367 fi
2368
2369 AC_CHECK_HEADERS(sys/ioctl.h)
2370
2371 if test -f /usr/lpp/X11/bin/smt.exp; then
2372   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2373             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2374 fi
2375
2376 AC_MSG_CHECKING(whether system supports dynamic ptys)
2377 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2378   AC_MSG_RESULT(yes)
2379   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2380 else
2381   AC_MSG_RESULT(no)
2382 fi
2383
2384 AC_FUNC_FORK
2385
2386 dnl Adapted from Haible's version.
2387 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2388   [AC_TRY_LINK([#include <langinfo.h>],
2389     [char* cs = nl_langinfo(CODESET);],
2390     emacs_cv_langinfo_codeset=yes,
2391     emacs_cv_langinfo_codeset=no)
2392   ])
2393 if test $emacs_cv_langinfo_codeset = yes; then
2394   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2395     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2396 fi
2397
2398 AC_CHECK_TYPES(size_t)
2399
2400 AC_TYPE_MBSTATE_T
2401
2402 dnl Restrict could probably be used effectively other than in regex.c.
2403 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2404   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2405                   emacs_cv_c_restrict=yes,
2406                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2407                                   emacs_cv_c_restrict=__restrict,
2408                                   emacs_cv_c_restrict=no)])])
2409 case "$emacs_cv_c_restrict" in
2410   yes) emacs_restrict=restrict;;
2411   no) emacs_restrict="";;
2412   *) emacs_restrict="$emacs_cv_c_restrict";;
2413 esac
2414 if test "$emacs_restrict" != __restrict; then
2415   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2416     [Define to compiler's equivalent of C99 restrict keyword.
2417      Don't define if equivalent is `__restrict'.])
2418 fi
2419
2420 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2421   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2422                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2423 if test "$emacs_cv_c_restrict_arr" = yes; then
2424   AC_DEFINE(__restrict_arr, __restrict,
2425     [Define to compiler's equivalent of C99 restrict keyword in array
2426      declarations.  Define as empty for no equivalent.])
2427 fi
2428
2429 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2430 dnl how the tty code is related to POSIX and/or other versions of termios.
2431 dnl The following looks like a useful start.
2432 dnl
2433 dnl AC_SYS_POSIX_TERMIOS
2434 dnl if test $ac_cv_sys_posix_termios = yes; then
2435 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2436 dnl                                and macros for terminal control.])
2437 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2438 dnl fi
2439
2440 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2441
2442 # Set up the CFLAGS for real compilation, so we can substitute it.
2443 CFLAGS="$REAL_CFLAGS"
2444 CPPFLAGS="$REAL_CPPFLAGS"
2445
2446 #### Find out which version of Emacs this is.
2447 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2448          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2449 if test x"${version}" = x; then
2450   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2451 fi
2452
2453 ### Specify what sort of things we'll be editing into Makefile and config.h.
2454 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2455 AC_SUBST(version)
2456 AC_SUBST(configuration)
2457 AC_SUBST(canonical)
2458 AC_SUBST(srcdir)
2459 AC_SUBST(prefix)
2460 AC_SUBST(exec_prefix)
2461 AC_SUBST(bindir)
2462 AC_SUBST(datadir)
2463 AC_SUBST(sharedstatedir)
2464 AC_SUBST(libexecdir)
2465 AC_SUBST(mandir)
2466 AC_SUBST(infodir)
2467 AC_SUBST(lispdir)
2468 AC_SUBST(locallisppath)
2469 AC_SUBST(lisppath)
2470 AC_SUBST(x_default_search_path)
2471 AC_SUBST(etcdir)
2472 AC_SUBST(archlibdir)
2473 AC_SUBST(docdir)
2474 AC_SUBST(bitmapdir)
2475 AC_SUBST(gamedir)
2476 AC_SUBST(gameuser)
2477 AC_SUBST(c_switch_system)
2478 AC_SUBST(c_switch_machine)
2479 AC_SUBST(LD_SWITCH_X_SITE)
2480 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2481 AC_SUBST(C_SWITCH_X_SITE)
2482 AC_SUBST(CFLAGS)
2483 AC_SUBST(X_TOOLKIT_TYPE)
2484 AC_SUBST(machfile)
2485 AC_SUBST(opsysfile)
2486 AC_SUBST(GETLOADAVG_LIBS)
2487 AC_SUBST(ns_appdir)
2488 AC_SUBST(ns_appbindir)
2489 AC_SUBST(ns_appresdir)
2490 AC_SUBST(ns_appsrc)
2491 AC_SUBST(GNUSTEP_MAKEFILES)
2492 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2493 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2494 AC_SUBST(GNU_OBJC_CFLAGS)
2495 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2496
2497 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2498                    [Define to the canonical Emacs configuration name.])
2499 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2500                    [Define to the options passed to configure.])
2501 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2502                    [Define to the used machine dependent file.])
2503 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2504                    [Define to the used os dependent file.])
2505 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2506 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2507  may need to deal with X Windows.  For instance, if you've defined
2508  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2509  your loader can find on its own, you might want to add "-L/..." or
2510  something similar.])
2511 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2512                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2513                     in case it's needed (for Solaris, for example).])
2514 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2515 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2516  may need to deal with X Windows.  For instance, if you've defined
2517  HAVE_X_WINDOWS above and your X include files aren't in a place
2518  that your compiler can find on its own, you might want to add
2519  "-I/..." or something similar.])
2520 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2521                    [Define to the unexec source file name.])
2522
2523 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2524   AC_DEFINE(HAVE_X_WINDOWS, 1,
2525             [Define to 1 if you want to use the X window system.])
2526 fi
2527 if test "${USE_X_TOOLKIT}" != "none" ; then
2528   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2529   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2530     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2531   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2532     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2533   fi
2534 fi
2535 if test "${HAVE_X11}" = "yes" ; then
2536   AC_DEFINE(HAVE_X11, 1,
2537             [Define to 1 if you want to use version 11 of X windows.
2538              Otherwise, Emacs expects to use version 10.])
2539 fi
2540 if test "${HAVE_MENUS}" = "yes" ; then
2541   AC_DEFINE(HAVE_MENUS, 1,
2542             [Define to 1 if you have mouse menus.
2543              (This is automatic if you use X, but the option to specify it remains.)
2544              It is also defined with other window systems that support xmenu.c.])
2545 fi
2546 if test "${GNU_MALLOC}" = "yes" ; then
2547   AC_DEFINE(GNU_MALLOC, 1,
2548             [Define to 1 if you want to use the GNU memory allocator.])
2549 fi
2550 if test "${REL_ALLOC}" = "yes" ; then
2551   AC_DEFINE(REL_ALLOC, 1,
2552             [Define REL_ALLOC if you want to use the relocating allocator for
2553              buffer space.])
2554 fi
2555
2556
2557 AH_TOP([/* GNU Emacs site configuration template file.
2558    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2559      2006, 2007, 2008  Free Software Foundation, Inc.
2560
2561 This file is part of GNU Emacs.
2562
2563 GNU Emacs is free software: you can redistribute it and/or modify
2564 it under the terms of the GNU General Public License as published by
2565 the Free Software Foundation, either version 3 of the License, or
2566 (at your option) any later version.
2567
2568 GNU Emacs is distributed in the hope that it will be useful,
2569 but WITHOUT ANY WARRANTY; without even the implied warranty of
2570 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2571 GNU General Public License for more details.
2572
2573 You should have received a copy of the GNU General Public License
2574 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2575
2576
2577 /* No code in Emacs #includes config.h twice, but some bits of code
2578    intended to work with other packages as well (like gmalloc.c)
2579    think they can include it as many times as they like.  */
2580 #ifndef EMACS_CONFIG_H
2581 #define EMACS_CONFIG_H
2582 ])dnl
2583
2584 AH_BOTTOM([
2585 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2586 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2587 #define HAVE_WINDOW_SYSTEM
2588 #define HAVE_MOUSE
2589 #endif
2590
2591 /* Sadly for now, GNUstep dump does not work.  */
2592 #ifdef NS_IMPL_GNUSTEP
2593 #define CANNOT_DUMP
2594 #endif
2595
2596 /* Define AMPERSAND_FULL_NAME if you use the convention
2597    that & in the full name stands for the login id.  */
2598 /* Turned on June 1996 supposing nobody will mind it.  */
2599 #define AMPERSAND_FULL_NAME
2600
2601 /* Define HAVE_SOUND if we have sound support.  We know it works
2602    and compiles only on the specified platforms.   For others,
2603    it probably doesn't make sense to try.  */
2604
2605 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2606 #ifdef HAVE_MACHINE_SOUNDCARD_H
2607 #define HAVE_SOUND 1
2608 #endif
2609 #ifdef HAVE_SYS_SOUNDCARD_H
2610 #define HAVE_SOUND 1
2611 #endif
2612 #ifdef HAVE_SOUNDCARD_H
2613 #define HAVE_SOUND 1
2614 #endif
2615 #ifdef HAVE_ALSA
2616 #define HAVE_SOUND 1
2617 #endif
2618 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2619
2620 /* If using GNU, then support inline function declarations. */
2621 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2622    generally, because even if non-gcc compilers accept `inline', they
2623    may reject `extern inline'.  */
2624 #if defined (__GNUC__) && defined (OPTIMIZE)
2625 #define INLINE __inline__
2626 #else
2627 #define INLINE
2628 #endif
2629
2630 /* `subprocesses' should be defined if you want to
2631    have code for asynchronous subprocesses
2632    (as used in M-x compile and M-x shell).
2633    Only MSDOS does not support this (it overrides
2634    this in its config_opsysfile below).  */
2635
2636 #define subprocesses
2637
2638 /* Include the os and machine dependent files.  */
2639 #include config_opsysfile
2640 #include config_machfile
2641
2642 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2643   (There is probably a better place to do this, but right now the Cocoa
2644    side does this in s/darwin.h and we cannot
2645    parallel this exactly since GNUstep is multi-OS. */
2646 #ifdef HAVE_NS
2647 #define OTHER_FILES ns-app
2648 # ifdef NS_IMPL_GNUSTEP
2649 /* See also .m.o rule in Makefile.in */
2650 /* FIXME: are all these flags really needed?  Document here why.  */
2651 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2652 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2653 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2654 #  define SYSTEM_PURESIZE_EXTRA 30000
2655 # endif /* NS_IMPL_GNUSTEP */
2656 #endif /* HAVE_NS */
2657
2658 /* SIGTYPE is the macro we actually use.  */
2659 #ifndef SIGTYPE
2660 #define SIGTYPE RETSIGTYPE
2661 #endif
2662
2663 #ifdef emacs /* Don't do this for lib-src.  */
2664 /* Tell regex.c to use a type compatible with Emacs.  */
2665 #define RE_TRANSLATE_TYPE Lisp_Object
2666 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2667 #ifdef make_number
2668 /* If make_number is a macro, use it.  */
2669 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2670 #else
2671 /* If make_number is a function, avoid it.  */
2672 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2673 #endif
2674 #endif
2675
2676 /* Avoid link-time collision with system mktime if we will use our own.  */
2677 #if ! HAVE_MKTIME || BROKEN_MKTIME
2678 #define mktime emacs_mktime
2679 #endif
2680
2681 #define my_strftime nstrftime   /* for strftime.c */
2682
2683 /* The rest of the code currently tests the CPP symbol BSTRING.
2684    Override any claims made by the system-description files.
2685    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2686 #undef BSTRING
2687 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2688 #define BSTRING
2689 #endif
2690
2691 /* Some of the files of Emacs which are intended for use with other
2692    programs assume that if you have a config.h file, you must declare
2693    the type of getenv.
2694
2695    This declaration shouldn't appear when alloca.s or Makefile.in
2696    includes config.h.  */
2697 #ifndef NOT_C_CODE
2698 extern char *getenv ();
2699 #endif
2700
2701 /* These default definitions are good for almost all machines.
2702    The exceptions override them in m/MACHINE.h.  */
2703
2704 #ifndef BITS_PER_CHAR
2705 #define BITS_PER_CHAR 8
2706 #endif
2707
2708 #ifndef BITS_PER_SHORT
2709 #define BITS_PER_SHORT 16
2710 #endif
2711
2712 /* Note that lisp.h uses this in a preprocessor conditional, so it
2713    would not work to use sizeof.  That being so, we do all of them
2714    without sizeof, for uniformity's sake.  */
2715 #ifndef BITS_PER_INT
2716 #define BITS_PER_INT 32
2717 #endif
2718
2719 #ifndef BITS_PER_LONG
2720 #ifdef _LP64
2721 #define BITS_PER_LONG 64
2722 #else
2723 #define BITS_PER_LONG 32
2724 #endif
2725 #endif
2726
2727 /* Define if the compiler supports function prototypes.  It may do so
2728    but not define __STDC__ (e.g. DEC C by default) or may define it as
2729    zero.  */
2730 #undef PROTOTYPES
2731 /* For mktime.c:  */
2732 #ifndef __P
2733 # if defined PROTOTYPES
2734 #  define __P(args) args
2735 # else
2736 #  define __P(args) ()
2737 # endif  /* GCC.  */
2738 #endif /* __P */
2739
2740 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2741 #ifndef NOT_C_CODE
2742 #ifdef HAVE_STRING_H
2743 #include "string.h"
2744 #endif
2745 #ifdef HAVE_STRINGS_H
2746 #include "strings.h"  /* May be needed for bcopy & al. */
2747 #endif
2748 #ifdef HAVE_STDLIB_H
2749 #include <stdlib.h>
2750 #endif
2751 #ifndef __GNUC__
2752 # ifdef HAVE_ALLOCA_H
2753 #  include <alloca.h>
2754 # else /* AIX files deal with #pragma.  */
2755 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2756 char *alloca ();
2757 #  endif
2758 # endif /* HAVE_ALLOCA_H */
2759 #endif /* __GNUC__ */
2760 #ifndef HAVE_SIZE_T
2761 typedef unsigned size_t;
2762 #endif
2763 #endif /* NOT_C_CODE */
2764
2765 /* Define HAVE_X_I18N if we have usable i18n support.  */
2766
2767 #ifdef HAVE_X11R6
2768 #define HAVE_X_I18N
2769 #elif !defined X11R5_INHIBIT_I18N
2770 #define HAVE_X_I18N
2771 #endif
2772
2773 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2774
2775 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2776 #define HAVE_X11R6_XIM
2777 #endif
2778
2779 /* Should we enable expensive run-time checking of data types?  */
2780 #undef ENABLE_CHECKING
2781
2782 #if defined __GNUC__ && (__GNUC__ > 2 \
2783                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2784 #define NO_RETURN       __attribute__ ((__noreturn__))
2785 #else
2786 #define NO_RETURN       /* nothing */
2787 #endif
2788
2789 /* These won't be used automatically yet.  We also need to know, at least,
2790    that the stack is continuous.  */
2791 #ifdef __GNUC__
2792 #  ifndef GC_SETJMP_WORKS
2793   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2794      see NON_SAVING_SETJMP in the target descriptions.  */
2795   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2796      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2797      Fixme: Deal with SVR3.  */
2798 #    define GC_SETJMP_WORKS 1
2799 #  endif
2800 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2801 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2802 #  endif
2803 #endif
2804
2805 #ifndef HAVE_BCOPY
2806 #define bcopy(a,b,s) memcpy (b,a,s)
2807 #endif
2808 #ifndef HAVE_BZERO
2809 #define bzero(a,s) memset (a,0,s)
2810 #endif
2811 #ifndef HAVE_BCMP
2812 #define BCMP memcmp
2813 #endif
2814
2815 #endif /* EMACS_CONFIG_H */
2816
2817 /*
2818 Local Variables:
2819 mode: c
2820 End:
2821 */
2822 ])dnl
2823
2824 #### Report on what we decided to do.
2825 #### Report GTK as a toolkit, even if it doesn't use Xt.
2826 #### It makes printing result more understandable as using GTK sets
2827 #### toolkit_scroll_bars to yes by default.
2828 if test "${HAVE_GTK}" = "yes"; then
2829   USE_X_TOOLKIT=GTK
2830 fi
2831
2832 echo "
2833 Configured for \`${canonical}'.
2834
2835   Where should the build process find the source code?    ${srcdir}
2836   What operating system and machine description files should Emacs use?
2837         \`${opsysfile}' and \`${machfile}'
2838   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2839   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2840   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2841   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2842   What window system should Emacs use?                    ${window_system}
2843   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2844
2845 if test -n "${x_includes}"; then
2846 echo "  Where do we find X Windows header files?                ${x_includes}"
2847 else
2848 echo "  Where do we find X Windows header files?                Standard dirs"
2849 fi
2850 if test -n "${x_libraries}"; then
2851 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2852 else
2853 echo "  Where do we find X Windows libraries?                   Standard dirs"
2854 fi
2855
2856 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2857 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2858 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2859 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2860 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2861 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2862 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2863 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2864 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2865
2866 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2867 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2868 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2869 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2870
2871 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2872 echo
2873
2874 if test $USE_XASSERTS = yes; then
2875    echo "  Compiling with asserts turned on."
2876    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2877 fi
2878
2879 echo
2880
2881 if test "$USE_X_TOOLKIT" = GTK; then
2882   case "$canonical" in
2883   *cygwin*)
2884     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2885   will probably get a crash on startup.  If this happens, please use another
2886   toolkit for Emacs.  See etc/PROBLEMS for more information."
2887   ;;
2888   esac
2889 fi
2890
2891 if test "$HAVE_NS" = "yes"; then
2892    echo
2893    echo "You must run \"make install\" in order to test the built application.
2894 The installed application will go to nextstep/Emacs.app and can be
2895 run or moved from there."
2896    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2897       echo "The application will be fully self-contained."
2898     else
2899       echo "The lisp resources for the application will be installed under ${prefix}.
2900 You may need to run \"make install\" with sudo.  The application will fail
2901 to run if these resources are not installed."
2902    fi
2903    echo
2904 fi
2905
2906 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2907   echo "D-Bus integration has been tested for GNU/Linux only."
2908   echo
2909 fi
2910
2911
2912 # Remove any trailing slashes in these variables.
2913 [test "${prefix}" != NONE &&
2914   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2915 test "${exec_prefix}" != NONE &&
2916   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2917
2918 # Now get this: Some word that is part of the ${srcdir} directory name
2919 # or the ${configuration} value might, just might, happen to be an
2920 # identifier like `sun4' or `i386' or something, and be predefined by
2921 # the C preprocessor to some helpful value like 1, or maybe the empty
2922 # string.  Needless to say consequent macro substitutions are less
2923 # than conducive to the makefile finding the correct directory.
2924 [cpp_undefs="`echo $srcdir $configuration $canonical |
2925   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2926   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2927
2928 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2929 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2930 ## from Makefile.c can correctly provide the arg `-traditional' to the
2931 ## C preprocessor.
2932
2933 AC_EGREP_CPP(yes..yes,
2934         [yes..yes],
2935         CPP_NEED_TRADITIONAL=no,
2936         CPP_NEED_TRADITIONAL=yes)
2937
2938 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2939         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2940         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2941         lwlib/Makefile lisp/Makefile leim/Makefile, [
2942
2943 ### Make the necessary directories, if they don't exist.
2944 for dir in etc lisp ; do
2945   test -d ${dir} || mkdir ${dir}
2946 done
2947
2948 # Build src/Makefile from ${srcdir}/src/Makefile.c
2949 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2950 # This must be done after src/config.h is built, since we rely on that file.
2951
2952 echo creating src/epaths.h
2953 ${MAKE-make} epaths-force
2954
2955 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2956 # `..' to `. .'  unless invoked with -traditional
2957
2958 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2959   CPPFLAGS="$CPPFLAGS -traditional"
2960 fi
2961
2962 echo creating lib-src/Makefile
2963 ( cd lib-src
2964   rm -f junk.c junk1.c junk2.c
2965   sed -e '/start of cpp stuff/q' \
2966       < Makefile.c > junk1.c
2967   sed -e '1,/start of cpp stuff/d'\
2968       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2969       < Makefile.c > junk.c
2970   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2971       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2972   cat junk1.c junk2.c > Makefile.new
2973   rm -f junk.c junk1.c junk2.c
2974   chmod 444 Makefile.new
2975   mv -f Makefile.new Makefile
2976 )
2977
2978 echo creating src/Makefile
2979 ( cd src
2980   rm -f junk.c junk1.c junk2.c
2981   sed -e '/start of cpp stuff/q' \
2982       < Makefile.c > junk1.c
2983   sed -e '1,/start of cpp stuff/d'\
2984       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2985       < Makefile.c > junk.c
2986   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2987       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2988   cat junk1.c junk2.c > Makefile.new
2989   rm -f junk.c junk1.c junk2.c
2990   chmod 444 Makefile.new
2991   mv -f Makefile.new Makefile
2992 )
2993
2994 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2995   echo creating src/.gdbinit
2996   echo source $srcdir/src/.gdbinit > src/.gdbinit
2997 fi
2998
2999 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3000
3001 m4_if(dnl       Do not change this comment
3002    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3003 )dnl