lisp/textmodes/tex-mode.el

   1 ;;; tex-mode.el --- TeX, LaTeX, and SliTeX mode commands.
   2
   3 ;; Copyright (C) 1985, 1986, 1989, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: tex
   7
   8 ;; Contributions over the years by William F. Schelter, Dick King,
   9 ;; Stephen Gildea, Michael Prange, and Jacob Gore.
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  26
  27 ;;; Code:
  28
  29 (require 'comint)
  30 (require 'compile)
  31
  32 ;;;###autoload
  33 (defvar tex-shell-file-name nil
  34   "*If non-nil, is file name to use for the subshell in which TeX is run.")
  35
  36 ;;;###autoload
  37 (defvar tex-directory "."
  38   "*Directory in which temporary files are left.
  39 You can make this /tmp if your TEXINPUTS has no relative directories in it
  40 and you don't try to apply \\[tex-region] or \\[tex-buffer] when there are
  41 \\input commands with relative directories.")
  42
  43 ;;;###autoload
  44 (defvar tex-offer-save t
  45   "*If non-nil, ask about saving modified buffers before \\[tex-file] is run.")
  46
  47 ;;;###autoload
  48 (defvar tex-run-command "tex"
  49   "*Command used to run TeX subjob.
  50 If this string contains an asterisk (*), it will be replaced by the
  51 filename; if not, the name of the file, preceded by blank, will be added to
  52 this string.")
  53
  54 ;;;###autoload
  55 (defvar latex-run-command "latex"
  56   "*Command used to run LaTeX subjob.
  57 If this string contains an asterisk (*), it will be replaced by the
  58 filename; if not, the name of the file, preceded by blank, will be added to
  59 this string.")
  60
  61 (defvar standard-latex-block-names
  62       '("abstract"         "array"            "center"       "description"
  63         "displaymath"      "document"         "enumerate"    "eqnarray"
  64         "eqnarray*"        "equation"         "figure"       "figure*"
  65         "flushleft"        "flushright"       "itemize"      "letter"
  66         "list"             "minipage"         "picture"      "quotation"
  67         "quote"            "slide"            "sloppypar"     "tabbing"
  68         "table"            "table*"           "tabular"       "tabular*"
  69         "thebibliography"  "theindex*"        "titlepage"     "trivlist"
  70         "verbatim"         "verbatim*"        "verse")
  71   "Standard LaTeX block names.")
  72
  73 ;;;###autoload
  74 (defvar latex-block-names nil
  75   "*User defined LaTeX block names.
  76 Combined with `standard-latex-block-names' for minibuffer completion.")
  77
  78 ;;;###autoload
  79 (defvar slitex-run-command "slitex"
  80   "*Command used to run SliTeX subjob.
  81 If this string contains an asterisk (*), it will be replaced by the
  82 filename; if not, the name of the file, preceded by blank, will be added to
  83 this string.")
  84
  85 ;;;###autoload
  86 (defvar tex-bibtex-command "bibtex"
  87   "*Command used by `tex-bibtex-file' to gather bibliographic data.
  88 If this string contains an asterisk (*), it will be replaced by the
  89 filename; if not, the name of the file, preceded by blank, will be added to
  90 this string.")
  91
  92 ;;;###autoload
  93 (defvar tex-dvi-print-command "lpr -d"
  94   "*Command used by \\[tex-print] to print a .dvi file.
  95 If this string contains an asterisk (*), it will be replaced by the
  96 filename; if not, the name of the file, preceded by blank, will be added to
  97 this string.")
  98
  99 ;;;###autoload
 100 (defvar tex-alt-dvi-print-command "lpr -d"
 101   "*Command used by \\[tex-print] with a prefix arg to print a .dvi file.
 102 If this string contains an asterisk (*), it will be replaced by the
 103 filename; if not, the name of the file, preceded by blank, will be added to
 104 this string.
 105
 106 If two printers are not enough of a choice, you can define the value
 107 of tex-alt-dvi-print-command to be an expression that asks what you want;
 108 for example,
 109
 110     (setq tex-alt-dvi-print-command
 111          '(format \"lpr -P%s\" (read-string \"Use printer: \")))
 112
 113 would tell \\[tex-print] with a prefix argument to ask you which printer to
 114 use.")
 115
 116 ;;;###autoload
 117 (defvar tex-dvi-view-command nil
 118   "*Command used by \\[tex-view] to display a .dvi file.
 119 If this string contains an asterisk (*), it will be replaced by the
 120 filename; if not, the name of the file, preceded by blank, will be added to
 121 this string.
 122
 123 This can be set conditionally so that the previewer used is suitable for the
 124 window system being used.  For example,
 125
 126     (setq tex-dvi-view-command
 127           (if (eq window-system 'x) \"xdvi\" \"dvi2tty * | cat -s\"))
 128
 129 would tell \\[tex-view] use xdvi under X windows and to use dvi2tty
 130 otherwise.")
 131
 132 ;;;###autoload
 133 (defvar tex-show-queue-command "lpq"
 134   "*Command used by \\[tex-show-print-queue] to show the print queue.
 135 Should show the queue(s) that \\[tex-print] puts jobs on.")
 136
 137 ;;;###autoload
 138 (defvar tex-default-mode 'plain-tex-mode
 139   "*Mode to enter for a new file that might be either TeX or LaTeX.
 140 This variable is used when it can't be determined whether the file
 141 is plain TeX or LaTeX or what because the file contains no commands.
 142 Normally set to either 'plain-tex-mode or 'latex-mode.")
 143
 144 ;;;###autoload
 145 (defvar tex-open-quote "``"
 146   "*String inserted by typing \\[tex-insert-quote] to open a quotation.")
 147
 148 ;;;###autoload
 149 (defvar tex-close-quote "''"
 150   "*String inserted by typing \\[tex-insert-quote] to close a quotation.")
 151
 152 (defvar tex-last-temp-file nil
 153   "Latest temporary file generated by \\[tex-region] and \\[tex-buffer].
 154 Deleted when the \\[tex-region] or \\[tex-buffer] is next run, or when the
 155 tex-shell goes away.")
 156
 157 (defvar tex-command nil
 158   "Command to run TeX.
 159 The name of the file, preceded by a blank, will be added to this string.")
 160
 161 (defvar tex-trailer nil
 162   "String appended after the end of a region sent to TeX by \\[tex-region].")
 163
 164 (defvar tex-start-of-header nil
 165   "String used by \\[tex-region] to delimit the start of the file's header.")
 166
 167 (defvar tex-end-of-header nil
 168   "String used by \\[tex-region] to delimit the end of the file's header.")
 169
 170 (defvar tex-shell-cd-command "cd"
 171   "Command to give to shell running TeX to change directory.
 172 The value of tex-directory will be appended to this, separated by a space.")
 173
 174 (defvar tex-zap-file nil
 175   "Temporary file name used for text being sent as input to TeX.
 176 Should be a simple file name with no extension or directory specification.")
 177
 178 (defvar tex-last-buffer-texed nil
 179   "Buffer which was last TeXed.")
 180
 181 (defvar tex-print-file nil
 182   "File name that \\[tex-print] prints.
 183 Set by \\[tex-region], \\[tex-buffer], and \\[tex-file].")
 184
 185 (defvar tex-mode-syntax-table nil
 186   "Syntax table used while in TeX mode.")
 187
 188 (defun tex-define-common-keys (keymap)
 189   "Define the keys that we want defined both in TeX mode and in the tex-shell."
 190   (define-key keymap "\C-c\C-k" 'tex-kill-job)
 191   (define-key keymap "\C-c\C-l" 'tex-recenter-output-buffer)
 192   (define-key keymap "\C-c\C-q" 'tex-show-print-queue)
 193   (define-key keymap "\C-c\C-p" 'tex-print)
 194   (define-key keymap "\C-c\C-v" 'tex-view)
 195   )
 196
 197 (defvar tex-mode-map nil "Keymap for TeX mode.")
 198
 199 (if tex-mode-map
 200     nil
 201   (setq tex-mode-map (make-sparse-keymap))
 202   (tex-define-common-keys tex-mode-map)
 203   (define-key tex-mode-map "\"" 'tex-insert-quote)
 204   (define-key tex-mode-map "\n" 'tex-terminate-paragraph)
 205   (define-key tex-mode-map "\C-c}" 'up-list)
 206   (define-key tex-mode-map "\C-c{" 'tex-insert-braces)
 207   (define-key tex-mode-map "\C-c\C-r" 'tex-region)
 208   (define-key tex-mode-map "\C-c\C-b" 'tex-buffer)
 209   (define-key tex-mode-map "\C-c\C-f" 'tex-file)
 210   (define-key tex-mode-map "\C-c\C-i" 'tex-bibtex-file)
 211   (define-key tex-mode-map "\C-c\C-o" 'tex-latex-block)
 212   (define-key tex-mode-map "\C-c\C-e" 'tex-close-latex-block))
 213
 214 (defvar tex-shell-map nil
 215   "Keymap for the tex-shell.  A comint-mode-map with a few additions.")
 216
 217 (defvar compare-windows-whitespace nil) ; Pacify the byte-compiler
 218
 219 ;;; This would be a lot simpler if we just used a regexp search,
 220 ;;; but then it would be too slow.
 221 ;;;###autoload
 222 (defun tex-mode ()
 223   "Major mode for editing files of input for TeX, LaTeX, or SliTeX.
 224 Tries to determine (by looking at the beginning of the file) whether
 225 this file is for plain TeX, LaTeX, or SliTeX and calls plain-tex-mode,
 226 latex-mode, or slitex-mode, respectively.  If it cannot be determined,
 227 such as if there are no commands in the file, the value of tex-default-mode
 228 is used."
 229   (interactive)
 230   (let (mode slash comment)
 231     (save-excursion
 232       (goto-char (point-min))
 233       (while (and (setq slash (search-forward "\\" nil t))
 234                   (setq comment (let ((search-end (point)))
 235                                   (save-excursion
 236                                     (beginning-of-line)
 237                                     (search-forward "%" search-end t))))))
 238       (if (and slash (not comment))
 239           (setq mode (if (looking-at "documentstyle")
 240                          (if (looking-at "documentstyle{slides}")
 241                              'slitex-mode
 242                            'latex-mode)
 243                        'plain-tex-mode))))
 244     (if mode (funcall mode)
 245       (funcall tex-default-mode))))
 246
 247 ;;;###autoload
 248 (defalias 'TeX-mode 'tex-mode)
 249 ;;;###autoload
 250 (defalias 'LaTeX-mode 'latex-mode)
 251
 252 ;;;###autoload
 253 (defun plain-tex-mode ()
 254   "Major mode for editing files of input for plain TeX.
 255 Makes $ and } display the characters they match.
 256 Makes \" insert `` when it seems to be the beginning of a quotation,
 257 and '' when it appears to be the end; it inserts \" only after a \\.
 258
 259 Use \\[tex-region] to run TeX on the current region, plus a \"header\"
 260 copied from the top of the file (containing macro definitions, etc.),
 261 running TeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 262 \\[tex-file] saves the buffer and then processes the file.
 263 \\[tex-print] prints the .dvi file made by any of these.
 264 \\[tex-view] previews the .dvi file made by any of these.
 265 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 266
 267 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 268 mismatched $'s or braces.
 269
 270 Special commands:
 271 \\{tex-mode-map}
 272
 273 Mode variables:
 274 tex-run-command
 275         Command string used by \\[tex-region] or \\[tex-buffer].
 276 tex-directory
 277         Directory in which to create temporary files for TeX jobs
 278         run by \\[tex-region] or \\[tex-buffer].
 279 tex-dvi-print-command
 280         Command string used by \\[tex-print] to print a .dvi file.
 281 tex-alt-dvi-print-command
 282         Alternative command string used by \\[tex-print] (when given a prefix
 283         argument) to print a .dvi file.
 284 tex-dvi-view-command
 285         Command string used by \\[tex-view] to preview a .dvi file.
 286 tex-show-queue-command
 287         Command string used by \\[tex-show-print-queue] to show the print
 288         queue that \\[tex-print] put your job on.
 289
 290 Entering Plain-tex mode calls the value of `text-mode-hook', then the value
 291 of `tex-mode-hook', and then the value of `plain-tex-mode-hook'.  When the
 292 special subshell is initiated, the value of `tex-shell-hook' is called."
 293
 294   (interactive)
 295   (tex-common-initialization)
 296   (setq mode-name "TeX")
 297   (setq major-mode 'plain-tex-mode)
 298   (setq tex-command tex-run-command)
 299   (setq tex-start-of-header "%**start of header")
 300   (setq tex-end-of-header "%**end of header")
 301   (setq tex-trailer "\\bye\n")
 302   (run-hooks 'text-mode-hook 'tex-mode-hook 'plain-tex-mode-hook))
 303 ;;;###autoload
 304 (defalias 'plain-TeX-mode 'plain-tex-mode)
 305
 306 ;;;###autoload
 307 (defun latex-mode ()
 308   "Major mode for editing files of input for LaTeX.
 309 Makes $ and } display the characters they match.
 310 Makes \" insert `` when it seems to be the beginning of a quotation,
 311 and '' when it appears to be the end; it inserts \" only after a \\.
 312
 313 Use \\[tex-region] to run LaTeX on the current region, plus the preamble
 314 copied from the top of the file (containing \\documentstyle, etc.),
 315 running LaTeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 316 \\[tex-file] saves the buffer and then processes the file.
 317 \\[tex-print] prints the .dvi file made by any of these.
 318 \\[tex-view] previews the .dvi file made by any of these.
 319 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 320
 321 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 322 mismatched $'s or braces.
 323
 324 Special commands:
 325 \\{tex-mode-map}
 326
 327 Mode variables:
 328 latex-run-command
 329         Command string used by \\[tex-region] or \\[tex-buffer].
 330 tex-directory
 331         Directory in which to create temporary files for LaTeX jobs
 332         run by \\[tex-region] or \\[tex-buffer].
 333 tex-dvi-print-command
 334         Command string used by \\[tex-print] to print a .dvi file.
 335 tex-alt-dvi-print-command
 336         Alternative command string used by \\[tex-print] (when given a prefix
 337         argument) to print a .dvi file.
 338 tex-dvi-view-command
 339         Command string used by \\[tex-view] to preview a .dvi file.
 340 tex-show-queue-command
 341         Command string used by \\[tex-show-print-queue] to show the print
 342         queue that \\[tex-print] put your job on.
 343
 344 Entering Latex mode calls the value of text-mode-hook, then the value of
 345 tex-mode-hook, and then the value of latex-mode-hook.  When the special
 346 subshell is initiated, the value of tex-shell-hook is called."
 347   (interactive)
 348   (tex-common-initialization)
 349   (setq mode-name "LaTeX")
 350   (setq major-mode 'latex-mode)
 351   (setq tex-command latex-run-command)
 352   (setq tex-start-of-header "\\documentstyle")
 353   (setq tex-end-of-header "\\begin{document}")
 354   (setq tex-trailer "\\end{document}\n")
 355   (run-hooks 'text-mode-hook 'tex-mode-hook 'latex-mode-hook))
 356
 357 (defun slitex-mode ()
 358   "Major mode for editing files of input for SliTeX.
 359 Makes $ and } display the characters they match.
 360 Makes \" insert `` when it seems to be the beginning of a quotation,
 361 and '' when it appears to be the end; it inserts \" only after a \\.
 362
 363 Use \\[tex-region] to run SliTeX on the current region, plus the preamble
 364 copied from the top of the file (containing \\documentstyle, etc.),
 365 running SliTeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 366 \\[tex-file] saves the buffer and then processes the file.
 367 \\[tex-print] prints the .dvi file made by any of these.
 368 \\[tex-view] previews the .dvi file made by any of these.
 369 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 370
 371 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 372 mismatched $'s or braces.
 373
 374 Special commands:
 375 \\{tex-mode-map}
 376
 377 Mode variables:
 378 slitex-run-command
 379         Command string used by \\[tex-region] or \\[tex-buffer].
 380 tex-directory
 381         Directory in which to create temporary files for SliTeX jobs
 382         run by \\[tex-region] or \\[tex-buffer].
 383 tex-dvi-print-command
 384         Command string used by \\[tex-print] to print a .dvi file.
 385 tex-alt-dvi-print-command
 386         Alternative command string used by \\[tex-print] (when given a prefix
 387         argument) to print a .dvi file.
 388 tex-dvi-view-command
 389         Command string used by \\[tex-view] to preview a .dvi file.
 390 tex-show-queue-command
 391         Command string used by \\[tex-show-print-queue] to show the print
 392         queue that \\[tex-print] put your job on.
 393
 394 Entering SliTeX mode calls the value of `text-mode-hook', then the value of
 395 `tex-mode-hook', then the value of `latex-mode-hook', and then the value of
 396 `slitex-mode-hook'.  When the special subshell is initiated, the value of
 397 `tex-shell-hook' is called."
 398   (interactive)
 399   (tex-common-initialization)
 400   (setq mode-name "SliTeX")
 401   (setq major-mode 'slitex-mode)
 402   (setq tex-command slitex-run-command)
 403   (setq tex-start-of-header "\\documentstyle{slides}")
 404   (setq tex-end-of-header "\\begin{document}")
 405   (setq tex-trailer "\\end{document}\n")
 406   (run-hooks
 407    'text-mode-hook 'tex-mode-hook 'latex-mode-hook 'slitex-mode-hook))
 408
 409 (defun tex-common-initialization ()
 410   (kill-all-local-variables)
 411   (use-local-map tex-mode-map)
 412   (setq local-abbrev-table text-mode-abbrev-table)
 413   (if (null tex-mode-syntax-table)
 414       (let ((char 0))
 415         (setq tex-mode-syntax-table (make-syntax-table))
 416         (set-syntax-table tex-mode-syntax-table)
 417         (while (< char ? )
 418           (modify-syntax-entry char ".")
 419           (setq char (1+ char)))
 420         (modify-syntax-entry ?\C-@ "w")
 421         (modify-syntax-entry ?\t " ")
 422         (modify-syntax-entry ?\n ">")
 423         (modify-syntax-entry ?\f ">")
 424         (modify-syntax-entry ?$ "$$")
 425         (modify-syntax-entry ?% "<")
 426         (modify-syntax-entry ?\\ "/")
 427         (modify-syntax-entry ?\" ".")
 428         (modify-syntax-entry ?& ".")
 429         (modify-syntax-entry ?_ ".")
 430         (modify-syntax-entry ?@ "_")
 431         (modify-syntax-entry ?~ " ")
 432         (modify-syntax-entry ?' "w"))
 433     (set-syntax-table tex-mode-syntax-table))
 434   (make-local-variable 'paragraph-start)
 435   (setq paragraph-start "^[ \t]*$\\|^[\f\\\\%]")
 436   (make-local-variable 'paragraph-separate)
 437   (setq paragraph-separate paragraph-start)
 438   (make-local-variable 'comment-start)
 439   (setq comment-start "%")
 440   (make-local-variable 'comment-start-skip)
 441   (setq comment-start-skip "\\(\\(^\\|[^\\]\\)\\(\\\\\\\\\\)*\\)\\(%+ *\\)")
 442   (make-local-variable 'comment-indent-function)
 443   (setq comment-indent-function 'tex-comment-indent)
 444   (make-local-variable 'compare-windows-whitespace)
 445   (setq compare-windows-whitespace 'tex-categorize-whitespace)
 446   (make-local-variable 'tex-command)
 447   (make-local-variable 'tex-start-of-header)
 448   (make-local-variable 'tex-end-of-header)
 449   (make-local-variable 'tex-trailer))
 450
 451 (defun tex-comment-indent ()
 452   (if (looking-at "%%%")
 453       (current-column)
 454     (skip-chars-backward " \t")
 455     (max (if (bolp) 0 (1+ (current-column)))
 456          comment-column)))
 457
 458 (defun tex-categorize-whitespace (backward-limit)
 459   ;; compare-windows-whitespace is set to this.
 460   ;; This is basically a finite-state machine.
 461   ;; Returns a symbol telling how TeX would treat
 462   ;; the whitespace we are looking at: null, space, or par.
 463   (let ((category 'null)
 464         (not-finished t))
 465     (skip-chars-backward " \t\n\f" backward-limit)
 466     (while not-finished
 467       (cond ((looking-at "[ \t]+")
 468              (goto-char (match-end 0))
 469              (if (eql category 'null)
 470                  (setq category 'space)))
 471             ((looking-at "\n")
 472              (cond ((eql category 'newline)
 473                     (setq category 'par)
 474                     (setq not-finished nil))
 475                    (t
 476                     (setq category 'newline) ;a strictly internal state
 477                     (goto-char (match-end 0)))))
 478             ((looking-at "\f+")
 479              (setq category 'par)
 480              (setq not-finished nil))
 481             (t
 482              (setq not-finished nil))))
 483     (skip-chars-forward " \t\n\f")
 484     (if (eql category 'newline)
 485         'space                          ;TeX doesn't distinguish
 486       category)))
 487
 488 (defun tex-insert-quote (arg)
 489   "Insert the appropriate quote marks for TeX.
 490 Inserts the value of `tex-open-quote' (normally ``) or `tex-close-quote'
 491 \(normally '') depending on the context.  With prefix argument, always
 492 inserts \" characters."
 493   (interactive "*P")
 494   (if arg
 495       (self-insert-command (prefix-numeric-value arg))
 496     (insert
 497      (cond ((or (bobp)
 498                 (save-excursion
 499                   (forward-char -1)
 500                   (looking-at "\\s(\\|\\s \\|\\s>")))
 501             tex-open-quote)
 502            ((= (preceding-char) ?\\)
 503             ?\")
 504            (t
 505             tex-close-quote)))))
 506
 507 (defun validate-tex-buffer ()
 508   "Check current buffer for paragraphs containing mismatched $s.
 509 As each such paragraph is found, a mark is pushed at its beginning,
 510 and the location is displayed for a few seconds."
 511   (interactive)
 512   (let ((opoint (point)))
 513     (goto-char (point-max))
 514     ;; Does not use save-excursion
 515     ;; because we do not want to save the mark.
 516     (unwind-protect
 517         (while (and (not (input-pending-p)) (not (bobp)))
 518           (let ((end (point)))
 519             (search-backward "\n\n" nil 'move)
 520             (or (tex-validate-region (point) end)
 521                 (progn
 522                   (push-mark (point))
 523                   (message "Mismatch found in paragraph starting here")
 524                   (sit-for 4)))))
 525       (goto-char opoint))))
 526
 527 (defun tex-validate-region (start end)
 528   "Check for mismatched braces or $'s in region.
 529 Returns t if no mismatches.  Returns nil and moves point to suspect
 530 area if a mismatch is found."
 531   (interactive "r")
 532   (let ((failure-point nil) (max-possible-sexps (- end start)))
 533     (save-excursion
 534       (condition-case ()
 535           (save-restriction
 536             (narrow-to-region start end)
 537             (goto-char start)
 538             (while (< 0 (setq max-possible-sexps (1- max-possible-sexps)))
 539               (forward-sexp 1)))
 540         (error
 541           (setq failure-point (point)))))
 542     (if failure-point
 543         (progn
 544           (goto-char failure-point)
 545           nil)
 546       t)))
 547
 548 (defun tex-terminate-paragraph (inhibit-validation)
 549   "Insert two newlines, breaking a paragraph for TeX.
 550 Check for mismatched braces/$'s in paragraph being terminated.
 551 A prefix arg inhibits the checking."
 552   (interactive "*P")
 553   (or inhibit-validation
 554       (save-excursion
 555         (tex-validate-region
 556           (save-excursion
 557             (search-backward "\n\n" nil 'move)
 558             (point))
 559           (point)))
 560       (message "Paragraph being closed appears to contain a mismatch"))
 561   (insert "\n\n"))
 562
 563 (defun tex-insert-braces ()
 564   "Make a pair of braces and be poised to type inside of them."
 565   (interactive "*")
 566   (insert ?\{)
 567   (save-excursion
 568     (insert ?})))
 569
 570 ;;; Like tex-insert-braces, but for LaTeX.
 571 (defun tex-latex-block (name)
 572   "Creates a matching pair of lines \\begin{NAME} and \\end{NAME} at point.
 573 Puts point on a blank line between them."
 574   (interactive
 575    (prog2
 576       (barf-if-buffer-read-only)
 577       (list
 578        (completing-read "LaTeX block name: "
 579                         (mapcar 'list
 580                                 (append standard-latex-block-names
 581                                         latex-block-names))))))
 582   (let ((col (current-column)))
 583     (insert (format "\\begin{%s}\n" name))
 584     (indent-to col)
 585     (save-excursion
 586       (insert ?\n)
 587       (indent-to col)
 588       (insert-string (format "\\end{%s}" name))
 589       (if (eobp) (insert ?\n)))))
 590
 591 (defun tex-last-unended-begin ()
 592   "Leave point at the beginning of the last \\begin{...} that is unended."
 593   (while (and (re-search-backward "\\(\\\\begin\\s *{\\)\\|\\(\\\\end\\s *{\\)")
 594               (looking-at "\\\\end{"))
 595     (tex-last-unended-begin)))
 596
 597 (defun tex-close-latex-block ()
 598   "Creates an \\end{...} to match the last unclosed \\begin{...}."
 599   (interactive "*")
 600   (let ((new-line-needed (bolp))
 601         text indentation)
 602     (save-excursion
 603       (condition-case nil
 604           (tex-last-unended-begin)
 605         (error (error "Couldn't find unended \\begin")))
 606       (setq indentation (current-column))
 607       (re-search-forward "\\\\begin\\(\\s *{[^}\n]*}\\)")
 608       (setq text (buffer-substring (match-beginning 1) (match-end 1))))
 609     (indent-to indentation)
 610     (insert "\\end" text)
 611     (if new-line-needed (insert ?\n))))
 612 \f
 613 (defun tex-compilation-parse-errors ()
 614   "Parse the current buffer as error messages.
 615 This makes a list of error descriptors, compilation-error-list.
 616 For each source-file, line-number pair in the buffer,
 617 the source file is read in, and the text location is saved in
 618 compilation-error-list.  The function `next-error', assigned to
 619 \\[next-error], takes the next error off the list and visits its location.
 620
 621 This function works on TeX compilations only.  It is necessary for
 622 that purpose, since TeX does not put file names on the same line as
 623 line numbers for the errors."
 624   (setq compilation-error-list nil)
 625   (message "Parsing error messages...")
 626   (modify-syntax-entry ?\{ "_")
 627   (modify-syntax-entry ?\} "_")
 628   (modify-syntax-entry ?\[ "_")
 629   (modify-syntax-entry ?\] "_")
 630   (let (text-buffer
 631         last-filename last-linenum)
 632     ;; Don't reparse messages already seen at last parse.
 633     (goto-char compilation-parsing-end)
 634     ;; Don't parse the first two lines as error messages.
 635     ;; This matters for grep.
 636     (if (bobp)
 637         (forward-line 2))
 638     (while (re-search-forward "^l\.[0-9]+ " nil t)
 639       (let (linenum filename
 640             error-marker text-marker)
 641         ;; Extract file name and line number from error message.
 642         ;; Line number is 2 away from beginning of line: "l.23"
 643         (beginning-of-line)
 644         (goto-char (+ (point) 2))
 645         (setq linenum (read (current-buffer)))
 646         ;; The file is the one that was opened last and is still open.
 647         ;; We need to find the last open parenthesis.
 648         (insert ?\))
 649         (backward-sexp)
 650         (forward-char)
 651         (setq filename (current-word))
 652         ;; Locate the erring file and line.
 653         (if (and (equal filename last-filename)
 654                  (= linenum last-linenum))
 655             nil
 656           (skip-chars-backward "^(")
 657           (backward-char)
 658           (forward-sexp)
 659           (backward-delete-char 1)
 660           (setq error-marker (point-marker))
 661           ;; text-buffer gets the buffer containing this error's file.
 662           (if (not (equal filename last-filename))
 663               (setq text-buffer
 664                     (and (file-exists-p (setq last-filename filename))
 665                          (find-file-noselect filename))
 666                     last-linenum 0))
 667           (if text-buffer
 668               ;; Go to that buffer and find the erring line.
 669               (save-excursion
 670                 (set-buffer text-buffer)
 671                 (if (zerop last-linenum)
 672                     (progn
 673                       (goto-char 1)
 674                       (setq last-linenum 1)))
 675                 (forward-line (- linenum last-linenum))
 676                 (setq last-linenum linenum)
 677                 (setq text-marker (point-marker))
 678                 (setq compilation-error-list
 679                       (cons (list error-marker text-marker)
 680                             compilation-error-list)))))
 681         (forward-line 1)))
 682     (setq compilation-parsing-end (point-max)))
 683   (message "Parsing error messages...done")
 684   (setq compilation-error-list (nreverse compilation-error-list)))
 685 \f
 686 ;;; Invoking TeX in an inferior shell.
 687
 688 ;;; Why use a shell instead of running TeX directly?  Because if TeX
 689 ;;; gets stuck, the user can switch to the shell window and type at it.
 690
 691 ;;; The utility functions:
 692
 693 (defun tex-start-shell ()
 694   (save-excursion
 695     (set-buffer
 696      (make-comint
 697       "tex-shell"
 698       (or tex-shell-file-name (getenv "ESHELL") (getenv "SHELL") "/bin/sh")
 699       nil "-v"))
 700     (let ((proc (get-process "tex-shell")))
 701       (set-process-sentinel proc 'tex-shell-sentinel)
 702       (process-kill-without-query proc)
 703       (setq tex-shell-map (copy-keymap comint-mode-map))
 704       (tex-define-common-keys tex-shell-map)
 705       (use-local-map tex-shell-map)
 706       (run-hooks 'tex-shell-hook)
 707       (while (zerop (buffer-size))
 708           (sleep-for 1)))))
 709
 710 (defun tex-shell-sentinel (proc msg)
 711   (cond ((null (buffer-name (process-buffer proc)))
 712          ;; buffer killed
 713          (set-process-buffer proc nil)
 714          (tex-delete-last-temp-files))
 715         ((memq (process-status proc) '(signal exit))
 716          (tex-delete-last-temp-files))))
 717
 718 (defun tex-set-buffer-directory (buffer directory)
 719   "Set BUFFER's default directory to be DIRECTORY."
 720   (setq directory (file-name-as-directory (expand-file-name directory)))
 721   (if (not (file-directory-p directory))
 722       (error "%s is not a directory" directory)
 723     (save-excursion
 724       (set-buffer buffer)
 725       (setq default-directory directory))))
 726
 727 (defun tex-send-command (command &optional file background)
 728   "Send COMMAND to tex-shell, substituting optional FILE for *.
 729 Do this in background if optional BACKGROUND is t.  If COMMAND has no *,
 730 FILE will be appended, preceded by a blank, to COMMAND.  If FILE is nil, no
 731 substitution will be made in COMMAND.  COMMAND can be any expression that
 732 evaluates to a command string."
 733   (save-excursion
 734     (let* ((cmd (eval command))
 735            (star (string-match "\\*" cmd))
 736            (front (substring cmd 0 star))
 737            (back (if star (substring cmd (1+ star)) "")))
 738       (comint-proc-query (get-process "tex-shell")
 739                          (concat
 740                           (if file (if star (concat front file back)
 741                                      (concat cmd " " file))
 742                             cmd)
 743                           (if background "&\n" "\n"))))))
 744
 745 (defun tex-delete-last-temp-files ()
 746   "Delete any junk files from last temp file."
 747   (if tex-last-temp-file
 748       (let* ((dir (file-name-directory tex-last-temp-file))
 749              (list (file-name-all-completions
 750                     (file-name-nondirectory tex-last-temp-file) dir)))
 751         (while list
 752           (delete-file (concat dir (car list)))
 753           (setq list (cdr list))))))
 754
 755 (add-hook 'kill-emacs-hook 'tex-delete-last-temp-files)
 756
 757 ;;; The commands:
 758
 759 (defun tex-region (beg end)
 760   "Run TeX on the current region, via a temporary file.
 761 The file's name comes from the variable `tex-zap-file' and the
 762 variable `tex-directory' says where to put it.
 763
 764 If the buffer has a header, the header is given to TeX before the
 765 region itself.  The buffer's header is all lines between the strings
 766 defined by `tex-start-of-header' and `tex-end-of-header' inclusive.
 767 The header must start in the first 100 lines of the buffer.
 768
 769 The value of `tex-trailer' is given to TeX as input after the region.
 770
 771 The value of `tex-command' specifies the command to use to run TeX."
 772   (interactive "r")
 773   (if (tex-shell-running)
 774       (tex-kill-job)
 775     (tex-start-shell))
 776   (or tex-zap-file
 777       (setq tex-zap-file (tex-generate-zap-file-name)))
 778   (let* ((temp-buffer (get-buffer-create " TeX-Output-Buffer"))
 779          ; Temp file will be written and TeX will be run in zap-directory.
 780          ; If the TEXINPUTS file has relative directories or if the region has
 781          ; \input of files, this must be the same directory as the file for
 782          ; TeX to access the correct inputs.  That's why it's safest if
 783          ; tex-directory is ".".
 784          (zap-directory
 785           (file-name-as-directory (expand-file-name tex-directory)))
 786          (tex-out-file (concat zap-directory tex-zap-file)))
 787     (tex-delete-last-temp-files)
 788     ;; Write the new temp file.
 789     (save-excursion
 790       (save-restriction
 791         (widen)
 792         (goto-char (point-min))
 793         (forward-line 100)
 794         (let ((search-end (point))
 795               (hbeg (point-min)) (hend (point-min))
 796               (default-directory zap-directory))
 797           (goto-char (point-min))
 798           ;; Initialize the temp file with either the header or nothing
 799           (if (search-forward tex-start-of-header search-end t)
 800               (progn
 801                 (beginning-of-line)
 802                 (setq hbeg (point))     ;mark beginning of header
 803                 (if (search-forward tex-end-of-header nil t)
 804                     (progn (forward-line 1)
 805                            (setq hend (point))) ;mark end of header
 806                   (setq hbeg (point-min))))) ;no header
 807           (write-region (min hbeg beg) hend
 808                         (concat tex-out-file ".tex") nil nil)
 809           (write-region (max beg hend) end (concat tex-out-file ".tex") t nil))
 810         (let ((local-tex-trailer tex-trailer))
 811           (set-buffer temp-buffer)
 812           (erase-buffer)
 813           ;; make sure trailer isn't hidden by a comment
 814           (insert-string "\n")
 815           (if local-tex-trailer (insert-string local-tex-trailer))
 816           (tex-set-buffer-directory temp-buffer zap-directory)
 817           (write-region (point-min) (point-max)
 818                         (concat tex-out-file ".tex") t nil))))
 819     ;; Record the file name to be deleted afterward.
 820     (setq tex-last-temp-file tex-out-file)
 821     (tex-send-command tex-shell-cd-command zap-directory)
 822     (tex-send-command tex-command tex-out-file)
 823     (setq tex-print-file tex-out-file)
 824     (setq tex-last-buffer-texed (current-buffer))))
 825
 826 (defun tex-buffer ()
 827   "Run TeX on current buffer.  See \\[tex-region] for more information.
 828 Does not save the buffer, so it's useful for trying experimental versions.
 829 See \\[tex-file] for an alternative."
 830   (interactive)
 831   (tex-region (point-min) (point-max)))
 832
 833 (defun tex-file ()
 834   "Prompt to save all buffers and run TeX (or LaTeX) on current buffer's file.
 835 This function is more useful than \\[tex-buffer] when you need the
 836 `.aux' file of LaTeX to have the correct name."
 837   (interactive)
 838   (let ((tex-out-file
 839          (if (buffer-file-name)
 840              (file-name-nondirectory (buffer-file-name))
 841            (error "Buffer does not seem to be associated with any file")))
 842         (file-dir (file-name-directory (buffer-file-name))))
 843     (if tex-offer-save
 844         (save-some-buffers))
 845     (if (tex-shell-running)
 846         (tex-kill-job)
 847       (tex-start-shell))
 848     (tex-send-command tex-shell-cd-command file-dir)
 849     (tex-send-command tex-command tex-out-file))
 850   (setq tex-last-buffer-texed (current-buffer))
 851   (setq tex-print-file (buffer-file-name)))
 852
 853 (defun tex-generate-zap-file-name ()
 854   "Generate a unique name suitable for use as a file name."
 855   ;; Include the shell process number and host name
 856   ;; in case there are multiple shells (for same or different user).
 857   (format "#tz%d%s"
 858           (process-id (get-buffer-process "*tex-shell*"))
 859           (tex-strip-dots (system-name))))
 860
 861 (defun tex-strip-dots (s)
 862   (setq s (copy-sequence s))
 863   (while (string-match "\\." s)
 864     (aset s (match-beginning 0) ?-))
 865   s)
 866
 867 ;; This will perhaps be useful for modifying TEXINPUTS.
 868 ;; Expand each file name, separated by colons, in the string S.
 869 (defun tex-expand-files (s)
 870   (let (elts (start 0))
 871     (while (string-match ":" s start)
 872       (setq elts (cons (substring s start (match-beginning 0)) elts))
 873       (setq start (match-end 0)))
 874     (or (= start 0)
 875         (setq elts (cons (substring s start) elts)))
 876     (mapconcat 'expand-file-name (nreverse elts) ":")))
 877
 878 (defun tex-shell-running ()
 879   (and (get-process "tex-shell")
 880        (eq (process-status (get-process "tex-shell")) 'run)))
 881
 882 (defun tex-kill-job ()
 883   "Kill the currently running TeX job."
 884   (interactive)
 885   (quit-process (get-process "tex-shell") t))
 886
 887 (defun tex-recenter-output-buffer (linenum)
 888   "Redisplay buffer of TeX job output so that most recent output can be seen.
 889 The last line of the buffer is displayed on
 890 line LINE of the window, or centered if LINE is nil."
 891   (interactive "P")
 892   (let ((tex-shell (get-buffer "*tex-shell*"))
 893         (old-buffer (current-buffer)))
 894     (if (null tex-shell)
 895         (message "No TeX output buffer")
 896       (pop-to-buffer tex-shell)
 897       (bury-buffer tex-shell)
 898       (goto-char (point-max))
 899       (recenter (if linenum
 900                     (prefix-numeric-value linenum)
 901                   (/ (window-height) 2)))
 902       (pop-to-buffer old-buffer))))
 903
 904 (defun tex-print (&optional alt)
 905   "Print the .dvi file made by \\[tex-region], \\[tex-buffer] or \\[tex-file].
 906 Runs the shell command defined by `tex-dvi-print-command'.  If prefix argument
 907 is provided, use the alternative command, `tex-alt-dvi-print-command'."
 908   (interactive "P")
 909   (let ((print-file-name-dvi (tex-append tex-print-file ".dvi"))
 910         test-name)
 911     (if (and (not (equal (current-buffer) tex-last-buffer-texed))
 912              (file-newer-than-file-p
 913               (setq test-name (tex-append (buffer-file-name) ".dvi"))
 914               print-file-name-dvi))
 915         (setq print-file-name-dvi test-name))
 916     (if (not (file-exists-p print-file-name-dvi))
 917         (error "No appropriate `.dvi' file could be found")
 918       (tex-send-command
 919         (if alt tex-alt-dvi-print-command tex-dvi-print-command)
 920         print-file-name-dvi t))))
 921
 922 (defun tex-view ()
 923   "Preview the last `.dvi' file made by running TeX under Emacs.
 924 This means, made using \\[tex-region], \\[tex-buffer] or \\[tex-file].
 925 The variable `tex-dvi-view-command' specifies the shell command for preview."
 926   (interactive)
 927   (let ((tex-dvi-print-command tex-dvi-view-command))
 928     (tex-print)))
 929
 930 (defun tex-append (file-name suffix)
 931   "Append to FILENAME the suffix SUFFIX, using same algorithm TeX uses.
 932 Scans for the first (not last) period.
 933 No period is retained immediately before SUFFIX,
 934 so normally SUFFIX starts with one."
 935   (if (stringp file-name)
 936       (let ((file (file-name-nondirectory file-name)))
 937         (concat (file-name-directory file-name)
 938                 (substring file 0
 939                            (string-match "\\." file))
 940                 suffix))
 941     " "))
 942
 943 (defun tex-show-print-queue ()
 944   "Show the print queue that \\[tex-print] put your job on.
 945 Runs the shell command defined by `tex-show-queue-command'."
 946   (interactive)
 947   (if (tex-shell-running)
 948       (tex-kill-job)
 949     (tex-start-shell))
 950   (tex-send-command tex-show-queue-command))
 951
 952 (defun tex-bibtex-file ()
 953   "Run BibTeX on the current buffer's file."
 954   (interactive)
 955   (if (tex-shell-running)
 956       (tex-kill-job)
 957     (tex-start-shell))
 958   (let ((tex-out-file
 959          (tex-append (file-name-nondirectory (buffer-file-name)) ""))
 960         (file-dir (file-name-directory (buffer-file-name))))
 961     (tex-send-command tex-shell-cd-command file-dir)
 962     (tex-send-command tex-bibtex-command tex-out-file)))
 963
 964 (run-hooks 'tex-mode-load-hook)
 965
 966 (provide 'tex-mode)
 967
 968 ;;; tex-mode.el ends here
 969