lisp/textmodes/page.el

   1 ;;; page.el --- page motion commands for emacs.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; This code provides the page-oriented movement and selection commands
  26 ;; documented in the Emacs manual.
  27
  28 ;;; Code:
  29
  30 (defun forward-page (&optional count)
  31   "Move forward to page boundary.  With arg, repeat, or go back if negative.
  32 A page boundary is any line whose beginning matches the regexp
  33 `page-delimiter'."
  34   (interactive "p")
  35   (or count (setq count 1))
  36   (while (and (> count 0) (not (eobp)))
  37     ;; In case the page-delimiter matches the null string,
  38     ;; don't find a match without moving.
  39     (if (bolp) (forward-char 1))
  40     (if (re-search-forward page-delimiter nil t)
  41         nil
  42       (goto-char (point-max)))
  43     (setq count (1- count)))
  44   (while (and (< count 0) (not (bobp)))
  45     (forward-char -1)
  46     (if (re-search-backward page-delimiter nil t)
  47         (goto-char (match-end 0))
  48       (goto-char (point-min)))
  49     (setq count (1+ count))))
  50
  51 (defun backward-page (&optional count)
  52   "Move backward to page boundary.  With arg, repeat, or go fwd if negative.
  53 A page boundary is any line whose beginning matches the regexp
  54 `page-delimiter'."
  55   (interactive "p")
  56   (or count (setq count 1))
  57   (forward-page (- count)))
  58
  59 (defun mark-page (&optional arg)
  60   "Put mark at end of page, point at beginning.
  61 A numeric arg specifies to move forward or backward by that many pages,
  62 thus marking a page other than the one point was originally in."
  63   (interactive "P")
  64   (setq arg (if arg (prefix-numeric-value arg) 0))
  65   (if (> arg 0)
  66       (forward-page arg)
  67     (if (< arg 0)
  68         (forward-page (1- arg))))
  69   (forward-page)
  70   (push-mark nil t t)
  71   (forward-page -1))
  72
  73 (defun narrow-to-page (&optional arg)
  74   "Make text outside current page invisible.
  75 A numeric arg specifies to move forward or backward by that many pages,
  76 thus showing a page other than the one point was originally in."
  77   (interactive "P")
  78   (setq arg (if arg (prefix-numeric-value arg) 0))
  79   (save-excursion
  80     (widen)
  81     (if (> arg 0)
  82         (forward-page arg)
  83       (if (< arg 0)
  84           (forward-page (1- arg))))
  85     ;; Find the end of the page.
  86     (forward-page)
  87     ;; If we stopped due to end of buffer, stay there.
  88     ;; If we stopped after a page delimiter, put end of restriction
  89     ;; at the beginning of that line.
  90     (if (save-excursion (beginning-of-line)
  91                         (looking-at page-delimiter))
  92         (beginning-of-line))
  93     (narrow-to-region (point)
  94                       (progn
  95                         ;; Find the top of the page.
  96                         (forward-page -1)
  97                         ;; If we found beginning of buffer, stay there.
  98                         ;; If extra text follows page delimiter on same line,
  99                         ;; include it.
 100                         ;; Otherwise, show text starting with following line.
 101                         (if (and (eolp) (not (bobp)))
 102                             (forward-line 1))
 103                         (point)))))
 104 (put 'narrow-to-page 'disabled t)
 105
 106 (defun count-lines-page ()
 107   "Report number of lines on current page, and how many are before or after point."
 108   (interactive)
 109   (save-excursion
 110     (let ((opoint (point)) beg end
 111           total before after)
 112       (forward-page)
 113       (beginning-of-line)
 114       (or (looking-at page-delimiter)
 115           (end-of-line))
 116       (setq end (point))
 117       (backward-page)
 118       (setq beg (point))
 119       (setq total (count-lines beg end)
 120             before (count-lines beg opoint)
 121             after (count-lines opoint end))
 122       (message "Page has %d lines (%d + %d)" total before after))))
 123
 124 (defun what-page ()
 125   "Print page and line number of point."
 126   (interactive)
 127   (save-restriction
 128     (widen)
 129     (save-excursion
 130       (beginning-of-line)
 131       (let ((count 1)
 132             (opoint (point)))
 133         (goto-char 1)
 134         (while (re-search-forward page-delimiter opoint t)
 135           (setq count (1+ count)))
 136         (message "Page %d, line %d"
 137                  count
 138                  (1+ (count-lines (point) opoint)))))))
 139
 140 ;;; page.el ends here