lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package is a major mode for editing nroff source code.  It knows
  27 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  28 ;; and indent paragraphs properly in their presence.  It also includes
  29 ;; a command to count text lines (excluding nroff constructs), a command
  30 ;; to center a line, and movement commands that know how to skip macros.
  31
  32 ;;; Code:
  33
  34 (defvar nroff-mode-abbrev-table nil
  35   "Abbrev table used while in nroff mode.")
  36
  37 (defvar nroff-mode-map nil
  38      "Major mode keymap for nroff mode.")
  39 (if (not nroff-mode-map)
  40     (progn
  41       (setq nroff-mode-map (make-sparse-keymap))
  42       (define-key nroff-mode-map "\t"  'tab-to-tab-stop)
  43       (define-key nroff-mode-map "\es" 'center-line)
  44       (define-key nroff-mode-map "\e?" 'count-text-lines)
  45       (define-key nroff-mode-map "\n"  'electric-nroff-newline)
  46       (define-key nroff-mode-map "\en" 'forward-text-line)
  47       (define-key nroff-mode-map "\ep" 'backward-text-line)))
  48
  49 ;;;###autoload
  50 (defun nroff-mode ()
  51   "Major mode for editing text intended for nroff to format.
  52 \\{nroff-mode-map}
  53 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
  54 Also, try `nroff-electric-mode', for automatically inserting
  55 closing requests for requests that are used in matched pairs."
  56   (interactive)
  57   (kill-all-local-variables)
  58   (use-local-map nroff-mode-map)
  59   (setq mode-name "Nroff")
  60   (setq major-mode 'nroff-mode)
  61   (set-syntax-table text-mode-syntax-table)
  62   (setq local-abbrev-table nroff-mode-abbrev-table)
  63   (make-local-variable 'nroff-electric-mode)
  64   (setq nroff-electric-mode nil)
  65   ;; now define a bunch of variables for use by commands in this mode
  66   (make-local-variable 'page-delimiter)
  67   (setq page-delimiter "^\\.\\(bp\\|SK\\|OP\\)")
  68   (make-local-variable 'paragraph-start)
  69   (setq paragraph-start (concat "^[.']\\|" paragraph-start))
  70   (make-local-variable 'paragraph-separate)
  71   (setq paragraph-separate (concat "^[.']\\|" paragraph-separate))
  72   ;; comment syntax added by mit-erl!gildea 18 Apr 86
  73   (make-local-variable 'comment-start)
  74   (setq comment-start "\\\" ")
  75   (make-local-variable 'comment-start-skip)
  76   (setq comment-start-skip "\\\\\"[ \t]*")
  77   (make-local-variable 'comment-column)
  78   (setq comment-column 24)
  79   (make-local-variable 'comment-indent-function)
  80   (setq comment-indent-function 'nroff-comment-indent)
  81   (run-hooks 'text-mode-hook 'nroff-mode-hook))
  82
  83 ;;; Compute how much to indent a comment in nroff/troff source.
  84 ;;; By mit-erl!gildea April 86
  85 (defun nroff-comment-indent ()
  86   "Compute indent for an nroff/troff comment.
  87 Puts a full-stop before comments on a line by themselves."
  88   (let ((pt (point)))
  89     (unwind-protect
  90         (progn
  91           (skip-chars-backward " \t")
  92           (if (bolp)
  93               (progn
  94                 (setq pt (1+ pt))
  95                 (insert ?.)
  96                 1)
  97             (if (save-excursion
  98                   (backward-char 1)
  99                   (looking-at "^[.']"))
 100                 1
 101               (max comment-column
 102                    (* 8 (/ (+ (current-column)
 103                               9) 8)))))) ; add 9 to ensure at least two blanks
 104       (goto-char pt))))
 105
 106 (defun count-text-lines (start end &optional print)
 107   "Count lines in region, except for nroff request lines.
 108 All lines not starting with a period are counted up.
 109 Interactively, print result in echo area.
 110 Noninteractively, return number of non-request lines from START to END."
 111   (interactive "r\np")
 112   (if print
 113       (message "Region has %d text lines" (count-text-lines start end))
 114     (save-excursion
 115       (save-restriction
 116         (narrow-to-region start end)
 117         (goto-char (point-min))
 118         (- (buffer-size) (forward-text-line (buffer-size)))))))
 119
 120 (defun forward-text-line (&optional cnt)
 121   "Go forward one nroff text line, skipping lines of nroff requests.
 122 An argument is a repeat count; if negative, move backward."
 123   (interactive "p")
 124   (if (not cnt) (setq cnt 1))
 125   (while (and (> cnt 0) (not (eobp)))
 126     (forward-line 1)
 127     (while (and (not (eobp)) (looking-at "[.']."))
 128       (forward-line 1))
 129     (setq cnt (- cnt 1)))
 130   (while (and (< cnt 0) (not (bobp)))
 131     (forward-line -1)
 132     (while (and (not (bobp))
 133                 (looking-at "[.']."))
 134       (forward-line -1))
 135     (setq cnt (+ cnt 1)))
 136   cnt)
 137
 138 (defun backward-text-line (&optional cnt)
 139   "Go backward one nroff text line, skipping lines of nroff requests.
 140 An argument is a repeat count; negative means move forward."
 141   (interactive "p")
 142   (forward-text-line (- cnt)))
 143
 144 (defconst nroff-brace-table
 145   '((".(b" . ".)b")
 146     (".(l" . ".)l")
 147     (".(q" . ".)q")
 148     (".(c" . ".)c")
 149     (".(x" . ".)x")
 150     (".(z" . ".)z")
 151     (".(d" . ".)d")
 152     (".(f" . ".)f")
 153     (".LG" . ".NL")
 154     (".SM" . ".NL")
 155     (".LD" . ".DE")
 156     (".CD" . ".DE")
 157     (".BD" . ".DE")
 158     (".DS" . ".DE")
 159     (".DF" . ".DE")
 160     (".FS" . ".FE")
 161     (".KS" . ".KE")
 162     (".KF" . ".KE")
 163     (".LB" . ".LE")
 164     (".AL" . ".LE")
 165     (".BL" . ".LE")
 166     (".DL" . ".LE")
 167     (".ML" . ".LE")
 168     (".RL" . ".LE")
 169     (".VL" . ".LE")
 170     (".RS" . ".RE")
 171     (".TS" . ".TE")
 172     (".EQ" . ".EN")
 173     (".PS" . ".PE")
 174     (".BS" . ".BE")
 175     (".G1" . ".G2")                     ; grap
 176     (".na" . ".ad b")
 177     (".nf" . ".fi")
 178     (".de" . "..")))
 179
 180 (defun electric-nroff-newline (arg)
 181   "Insert newline for nroff mode; special if electric-nroff mode.
 182 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 183 automatically inserts the matching closing request after point."
 184   (interactive "P")
 185   (let ((completion (save-excursion
 186                       (beginning-of-line)
 187                       (and (null arg)
 188                            nroff-electric-mode
 189                            (<= (point) (- (point-max) 3))
 190                            (cdr (assoc (buffer-substring (point)
 191                                                          (+ 3 (point)))
 192                                        nroff-brace-table)))))
 193         (needs-nl (not (looking-at "[ \t]*$"))))
 194     (if (null completion)
 195         (newline (prefix-numeric-value arg))
 196       (save-excursion
 197         (insert "\n\n" completion)
 198         (if needs-nl (insert "\n")))
 199       (forward-char 1))))
 200
 201 (defun electric-nroff-mode (&optional arg)
 202   "Toggle `nroff-electric-newline' minor mode.
 203 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 204 beginning of the line, and insert the matching closing request if necessary.
 205 This command toggles that mode (off->on, on->off), with an argument,
 206 turns it on iff arg is positive, otherwise off."
 207   (interactive "P")
 208   (or (eq major-mode 'nroff-mode) (error "Must be in nroff mode"))
 209   (or (assq 'nroff-electric-mode minor-mode-alist)
 210       (setq minor-mode-alist (append minor-mode-alist
 211                                      (list '(nroff-electric-mode
 212                                              " Electric")))))
 213   (setq nroff-electric-mode
 214         (cond ((null arg) (null nroff-electric-mode))
 215               (t (> (prefix-numeric-value arg) 0)))))
 216
 217 ;;; nroff-mode.el ends here