lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   6 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   7 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   8 ;; Keywords: dired extensions files
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  29 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  30
  31 ;; USAGE: In your ~/.emacs,
  32 ;;
  33 ;; (add-hook 'dired-load-hook
  34 ;;           (lambda ()
  35 ;;                       (load "dired-x")
  36 ;;                       ;; Set global variables here.  For example:
  37 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  38 ;;                       ))
  39 ;; (add-hook 'dired-mode-hook
  40 ;;           (lambda ()
  41 ;;                       ;; Set buffer-local variables here.  For example:
  42 ;;                       ;; (dired-omit-mode 1)
  43 ;;                       ))
  44 ;;
  45 ;; At load time dired-x.el will install itself, redefine some functions, and
  46 ;; bind some dired keys.
  47
  48 ;; User customization: M-x customize-group RET dired-x RET.
  49
  50 ;; When loaded this code redefines dired.el's dired-find-buffer-nocreate.
  51
  52 ;; *Please* see the `dired-x' info pages for more details.
  53
  54 \f
  55 ;;; Code:
  56
  57 ;; LOAD.
  58
  59 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  60 ;; but maybe not if a dired-x function is being autoloaded.
  61 (require 'dired)
  62
  63 ;; We will redefine some functions and also need some macros.
  64 (require 'dired-aux)
  65
  66 ;;; User-defined variables.
  67
  68 (defgroup dired-x nil
  69   "Extended directory editing (dired-x)."
  70   :group 'dired)
  71
  72 (defgroup dired-keys nil
  73   "Dired keys customizations."
  74   :prefix "dired-"
  75   :group 'dired-x)
  76
  77 (defcustom dired-bind-vm nil
  78   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  79 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  80 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  81 will run `rmail' on these files.  New RMAIL files use the standard
  82 mbox format, and so cannot be distinguished in this way."
  83   :type 'boolean
  84   :group 'dired-keys)
  85
  86 (defcustom dired-bind-jump t
  87   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  88 Setting this variable directly after dired-x is loaded has no effect -
  89 use \\[customize]."
  90   :type 'boolean
  91   :set (lambda (sym val)
  92          (if (set sym val)
  93              (progn
  94                (define-key global-map "\C-x\C-j" 'dired-jump)
  95                (define-key global-map "\C-x4\C-j" 'dired-jump-other-window))
  96            (if (eq 'dired-jump (lookup-key global-map "\C-x\C-j"))
  97                (define-key global-map "\C-x\C-j" nil))
  98            (if (eq 'dired-jump-other-window (lookup-key global-map "\C-x4\C-j"))
  99                (define-key global-map "\C-x4\C-j" nil))))
 100   :group 'dired-keys)
 101
 102 (defcustom dired-bind-man t
 103   "Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not.
 104 Setting this variable directly after dired-x is loaded has no effect -
 105 use \\[customize]."
 106   :type 'boolean
 107   :set (lambda (sym val)
 108          (if (set sym val)
 109              (define-key dired-mode-map "N" 'dired-man)
 110            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
 111                (define-key dired-mode-map "N" nil))))
 112   :group 'dired-keys)
 113
 114 (defcustom dired-bind-info t
 115   "Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not.
 116 Setting this variable directly after dired-x is loaded has no effect -
 117 use \\[customize]."
 118   :type 'boolean
 119   :set (lambda (sym val)
 120          (if (set sym val)
 121              (define-key dired-mode-map "I" 'dired-info)
 122            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 123                (define-key dired-mode-map "I" nil))))
 124   :group 'dired-keys)
 125
 126 (defcustom dired-vm-read-only-folders nil
 127   "If non-nil, \\[dired-vm] will visit all folders read-only.
 128 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 129 files not writable by you are visited read-only."
 130   :type '(choice (const :tag "off" nil)
 131                  (const :tag "on" t)
 132                  (other :tag "non-writable only" if-file-read-only))
 133   :group 'dired-x)
 134
 135 (define-minor-mode dired-omit-mode
 136   "Toggle Dired-Omit mode.
 137 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 138 otherwise.  Enabling and disabling is buffer-local.
 139 If enabled, \"uninteresting\" files are not listed.
 140 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 141 plus those ending with extensions in `dired-omit-extensions'.
 142
 143 To enable omitting in every Dired buffer, you can put in your ~/.emacs
 144
 145   (add-hook 'dired-mode-hook (lambda () (dired-omit-mode 1)))
 146
 147 See Info node `(dired-x) Omitting Variables' for more information."
 148   :group 'dired-x
 149   (if dired-omit-mode
 150       ;; This will mention how many lines were omitted:
 151       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 152     (revert-buffer)))
 153
 154 ;; For backward compatibility
 155 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 156
 157 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 158   "Filenames matching this regexp will not be displayed.
 159 This only has effect when `dired-omit-mode' is t.  See interactive function
 160 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 161 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 162 files and lock files."
 163   :type 'regexp
 164   :group 'dired-x)
 165
 166 (defcustom dired-omit-verbose t
 167   "When non-nil, show messages when omitting files.
 168 When nil, don't show messages."
 169   :type 'boolean
 170   :group 'dired-x)
 171
 172 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 173   "If non-nil, Dired always finds a directory in a buffer of its own.
 174 If nil, Dired finds the directory as a subdirectory in some other buffer
 175 if it is present as one.
 176
 177 If there are several dired buffers for a directory, the most recently
 178 used is chosen.
 179
 180 Dired avoids switching to the current buffer, so that if you have
 181 a normal and a wildcard buffer for the same directory, \\[dired] will
 182 toggle between those two."
 183   :type 'boolean
 184   :group 'dired-x)
 185
 186 (defcustom dired-omit-size-limit 30000
 187   "Maximum size for the \"omitting\" feature.
 188 If nil, there is no maximum size."
 189   :type '(choice (const :tag "no maximum" nil) integer)
 190   :group 'dired-x)
 191
 192 (defcustom dired-enable-local-variables t
 193   "Control use of local-variables lists in Dired.
 194 The value can be t, nil or something else.
 195 A value of t means local-variables lists are obeyed;
 196 nil means they are ignored; anything else means query.
 197
 198 This temporarily overrides the value of `enable-local-variables' when
 199 listing a directory.  See also `dired-local-variables-file'."
 200   :type 'boolean
 201   :group 'dired-x)
 202
 203 (defcustom dired-guess-shell-gnutar
 204   (catch 'found
 205     (dolist (exe '("tar" "gtar"))
 206       (if (with-temp-buffer
 207             (ignore-errors (call-process exe nil t nil "--version"))
 208             (and (re-search-backward "GNU tar" nil t) t))
 209           (throw 'found exe))))
 210   "If non-nil, name of GNU tar executable.
 211 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 212 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 213 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 214   ;; Changed from system-type test to testing --version output.
 215   ;; Maybe test --help for -z instead?
 216   :version "24.1"
 217   :type '(choice (const :tag "Not GNU tar" nil)
 218                  (string :tag "Command name"))
 219   :group 'dired-x)
 220
 221 (defcustom dired-guess-shell-gzip-quiet t
 222   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 223   :type 'boolean
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-znew-switches nil
 227   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 228   :type '(choice (const :tag "None" nil)
 229                  (string :tag "Switches"))
 230   :group 'dired-x)
 231
 232 (defcustom dired-clean-up-buffers-too t
 233   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 234   :type 'boolean
 235   :group 'dired-x)
 236
 237 ;;; KEY BINDINGS.
 238
 239 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 240 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 241 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 242 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 243 (define-key dired-mode-map "*." 'dired-mark-extension)
 244 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 245 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 246 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 247 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 248 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 249 (define-key dired-mode-map "V" 'dired-do-run-mail)
 250
 251 ;;; MENU BINDINGS
 252
 253 (require 'easymenu)
 254
 255 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 256   (easy-menu-add-item menu '("Operate")
 257                       ["Find Files" dired-do-find-marked-files
 258                        :help "Find current or marked files"]
 259                       "Shell Command...")
 260   (easy-menu-add-item menu '("Operate")
 261                       ["Relative Symlink to..." dired-do-relsymlink
 262                        :visible (fboundp 'make-symbolic-link)
 263                        :help "Make relative symbolic links for current or \
 264 marked files"]
 265                       "Hardlink to...")
 266   (easy-menu-add-item menu '("Mark")
 267                       ["Flag Extension..." dired-flag-extension
 268                        :help "Flag files with a certain extension for deletion"]
 269                       "Mark Executables")
 270   (easy-menu-add-item menu '("Mark")
 271                       ["Mark Extension..." dired-mark-extension
 272                        :help "Mark files with a certain extension"]
 273                       "Unmark All")
 274   (easy-menu-add-item menu '("Mark")
 275                       ["Mark Omitted" dired-mark-omitted
 276                        :help "Mark files matching `dired-omit-files' \
 277 and `dired-omit-extensions'"]
 278                       "Unmark All")
 279   (easy-menu-add-item menu '("Regexp")
 280                       ["Relative Symlink..." dired-do-relsymlink-regexp
 281                        :visible (fboundp 'make-symbolic-link)
 282                        :help "Make relative symbolic links for files \
 283 matching regexp"]
 284                       "Hardlink...")
 285   (easy-menu-add-item menu '("Immediate")
 286                       ["Omit Mode" dired-omit-mode
 287                        :style toggle :selected dired-omit-mode
 288                        :help "Enable or disable omitting \"uninteresting\" \
 289 files"]
 290                       "Refresh"))
 291
 292 \f
 293 ;; Install into appropriate hooks.
 294
 295 (add-hook 'dired-mode-hook 'dired-extra-startup)
 296 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 297
 298 (defun dired-extra-startup ()
 299   "Automatically put on `dired-mode-hook' to get extra Dired features:
 300 \\<dired-mode-map>
 301   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 302   \\[dired-info]\t-- run info on file
 303   \\[dired-man]\t-- run man on file
 304   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 305   \\[dired-omit-mode]\t-- toggle omitting of files
 306   \\[dired-mark-sexp]\t-- mark by Lisp expression
 307
 308 To see the options you can set, use M-x customize-group RET dired-x RET.
 309 See also the functions:
 310   `dired-flag-extension'
 311   `dired-virtual'
 312   `dired-jump'
 313   `dired-man'
 314   `dired-vm'
 315   `dired-rmail'
 316   `dired-info'
 317   `dired-do-find-marked-files'"
 318   (interactive)
 319   ;; These must be done in each new dired buffer.
 320   (dired-hack-local-variables)
 321   (dired-omit-startup))
 322
 323 \f
 324 ;;; EXTENSION MARKING FUNCTIONS.
 325
 326 ;; Mark files with some extension.
 327 (defun dired-mark-extension (extension &optional marker-char)
 328   "Mark all files with a certain EXTENSION for use in later commands.
 329 A `.' is *not* automatically prepended to the string entered."
 330   ;; EXTENSION may also be a list of extensions instead of a single one.
 331   ;; Optional MARKER-CHAR is marker to use.
 332   (interactive "sMarking extension: \nP")
 333   (or (listp extension)
 334       (setq extension (list extension)))
 335   (dired-mark-files-regexp
 336    (concat ".";; don't match names with nothing but an extension
 337            "\\("
 338            (mapconcat 'regexp-quote extension "\\|")
 339            "\\)$")
 340    marker-char))
 341
 342 (defun dired-flag-extension (extension)
 343   "In dired, flag all files with a certain EXTENSION for deletion.
 344 A `.' is *not* automatically prepended to the string entered."
 345   (interactive "sFlagging extension: ")
 346   (dired-mark-extension extension dired-del-marker))
 347
 348 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 349
 350 (defvar dired-patch-unclean-extensions
 351   '(".rej" ".orig")
 352   "List of extensions of dispensable files created by the `patch' program.")
 353
 354 (defvar dired-tex-unclean-extensions
 355   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 356   "List of extensions of dispensable files created by TeX.")
 357
 358 (defvar dired-latex-unclean-extensions
 359   '(".idx" ".lof" ".lot" ".glo")
 360   "List of extensions of dispensable files created by LaTeX.")
 361
 362 (defvar dired-bibtex-unclean-extensions
 363   '(".blg" ".bbl")
 364   "List of extensions of dispensable files created by BibTeX.")
 365
 366 (defvar dired-texinfo-unclean-extensions
 367   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 368     ".tp" ".tps" ".vr" ".vrs")
 369   "List of extensions of dispensable files created by texinfo.")
 370
 371 (defun dired-clean-patch ()
 372   "Flag dispensable files created by patch for deletion.
 373 See variable `dired-patch-unclean-extensions'."
 374   (interactive)
 375   (dired-flag-extension dired-patch-unclean-extensions))
 376
 377 (defun dired-clean-tex ()
 378   "Flag dispensable files created by [La]TeX etc. for deletion.
 379 See variables `dired-tex-unclean-extensions',
 380 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 381 `dired-texinfo-unclean-extensions'."
 382   (interactive)
 383   (dired-flag-extension (append dired-texinfo-unclean-extensions
 384                                 dired-latex-unclean-extensions
 385                                 dired-bibtex-unclean-extensions
 386                                 dired-tex-unclean-extensions)))
 387
 388 (defun dired-very-clean-tex ()
 389   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 390 See variables `dired-texinfo-unclean-extensions',
 391 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 392 `dired-texinfo-unclean-extensions'."
 393   (interactive)
 394   (dired-flag-extension (append dired-texinfo-unclean-extensions
 395                                 dired-latex-unclean-extensions
 396                                 dired-bibtex-unclean-extensions
 397                                 dired-tex-unclean-extensions
 398                                 (list ".dvi"))))
 399 \f
 400 ;;; JUMP.
 401
 402 ;;;###autoload
 403 (defun dired-jump (&optional other-window file-name)
 404   "Jump to dired buffer corresponding to current buffer.
 405 If in a file, dired the current directory and move to file's line.
 406 If in Dired already, pop up a level and goto old directory's line.
 407 In case the proper dired file line cannot be found, refresh the dired
 408 buffer and try again.
 409 When OTHER-WINDOW is non-nil, jump to dired buffer in other window.
 410 Interactively with prefix argument, read FILE-NAME and
 411 move to its line in dired."
 412   (interactive
 413    (list nil (and current-prefix-arg
 414                   (read-file-name "Jump to dired file: "))))
 415   (let* ((file (or file-name buffer-file-name))
 416          (dir (if file (file-name-directory file) default-directory)))
 417     (if (and (eq major-mode 'dired-mode) (null file-name))
 418         (progn
 419           (setq dir (dired-current-directory))
 420           (dired-up-directory other-window)
 421           (unless (dired-goto-file dir)
 422               ;; refresh and try again
 423             (dired-insert-subdir (file-name-directory dir))
 424             (dired-goto-file dir)))
 425       (if other-window
 426           (dired-other-window dir)
 427         (dired dir))
 428       (if file
 429           (or (dired-goto-file file)
 430               ;; refresh and try again
 431               (progn
 432                 (dired-insert-subdir (file-name-directory file))
 433                 (dired-goto-file file))
 434               ;; Toggle omitting, if it is on, and try again.
 435               (when dired-omit-mode
 436                 (dired-omit-mode)
 437                 (dired-goto-file file)))))))
 438
 439 (defun dired-jump-other-window (&optional file-name)
 440   "Like \\[dired-jump] (`dired-jump') but in other window."
 441   (interactive
 442    (list (and current-prefix-arg
 443               (read-file-name "Jump to dired file: "))))
 444   (dired-jump t file-name))
 445 \f
 446 ;;; OMITTING.
 447
 448 ;; Enhanced omitting of lines from directory listings.
 449 ;; Marked files are never omitted.
 450
 451 ;; should probably get rid of this and always use 'no-dir.
 452 ;; sk 28-Aug-1991 09:37
 453 (defvar dired-omit-localp 'no-dir
 454   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 455 If it is `no-dir', omitting is much faster, but you can only match
 456 against the non-directory part of the file name.  Set it to nil if you
 457 need to match the entire file name.")
 458
 459 ;; \017=^O for Omit - other packages can chose other control characters.
 460 (defvar dired-omit-marker-char ?\017
 461   "Temporary marker used by Dired-Omit.
 462 Should never be used as marker by the user or other packages.")
 463
 464 (defun dired-omit-startup ()
 465   (or (assq 'dired-omit-mode minor-mode-alist)
 466       (setq minor-mode-alist
 467             (append '((dired-omit-mode
 468                        (:eval (if (eq major-mode 'dired-mode)
 469                                   " Omit" ""))))
 470                     minor-mode-alist))))
 471
 472 (defun dired-mark-omitted ()
 473   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 474   (interactive)
 475   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 476   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 477
 478 (defcustom dired-omit-extensions
 479   (append completion-ignored-extensions
 480           dired-latex-unclean-extensions
 481           dired-bibtex-unclean-extensions
 482           dired-texinfo-unclean-extensions)
 483   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 484 Defaults to elements of `completion-ignored-extensions',
 485 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 486 `dired-texinfo-unclean-extensions'.
 487
 488 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 489 variables `dired-omit-mode' and `dired-omit-files'."
 490   :type '(repeat string)
 491   :group 'dired-x)
 492
 493 (defun dired-omit-expunge (&optional regexp)
 494   "Erases all unmarked files matching REGEXP.
 495 Does nothing if global variable `dired-omit-mode' is nil, or if called
 496   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 497 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 498   filenames ending in `dired-omit-extensions'.
 499 If REGEXP is the empty string, this function is a no-op.
 500
 501 This functions works by temporarily binding `dired-marker-char' to
 502 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 503   (interactive "sOmit files (regexp): ")
 504   (if (and dired-omit-mode
 505            (or (called-interactively-p 'interactive)
 506                (not dired-omit-size-limit)
 507                (< (buffer-size) dired-omit-size-limit)
 508                (progn
 509                  (when dired-omit-verbose
 510                    (message "Not omitting: directory larger than %d characters."
 511                             dired-omit-size-limit))
 512                  (setq dired-omit-mode nil)
 513                  nil)))
 514       (let ((omit-re (or regexp (dired-omit-regexp)))
 515             (old-modified-p (buffer-modified-p))
 516             count)
 517         (or (string= omit-re "")
 518             (let ((dired-marker-char dired-omit-marker-char))
 519               (when dired-omit-verbose (message "Omitting..."))
 520               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 521                   (progn
 522                     (setq count (dired-do-kill-lines
 523                                  nil
 524                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 525                     (force-mode-line-update))
 526                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 527         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 528         ;; in mode-line of omitted buffers.
 529         (set-buffer-modified-p (and old-modified-p
 530                                     (save-excursion
 531                                       (goto-char (point-min))
 532                                       (re-search-forward dired-re-mark nil t))))
 533         count)))
 534
 535 (defun dired-omit-regexp ()
 536   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 537           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 538           (if dired-omit-extensions
 539               (concat ".";; a non-extension part should exist
 540                       "\\("
 541                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 542                       "\\)$")
 543             "")))
 544
 545 ;; Returns t if any work was done, nil otherwise.
 546 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 547   "Mark unmarked files matching REGEXP, displaying MSG.
 548 REGEXP is matched against the entire file name.
 549 Does not re-mark files which already have a mark.
 550 With prefix argument, unflag all those files.
 551 Optional fourth argument LOCALP is as in `dired-get-filename'."
 552   (interactive "P")
 553   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 554     (dired-mark-if
 555      (and
 556       ;; not already marked
 557       (looking-at " ")
 558       ;; uninteresting
 559       (let ((fn (dired-get-filename localp t)))
 560         (and fn (string-match regexp fn))))
 561      msg)))
 562
 563 \f
 564 ;;; VIRTUAL DIRED MODE.
 565
 566 ;; For browsing `ls -lR' listings in a dired-like fashion.
 567
 568 (defalias 'virtual-dired 'dired-virtual)
 569 (defun dired-virtual (dirname &optional switches)
 570   "Put this buffer into Virtual Dired mode.
 571
 572 In Virtual Dired mode, all commands that do not actually consult the
 573 filesystem will work.
 574
 575 This is useful if you want to peruse and move around in an ls -lR
 576 output file, for example one you got from an ftp server.  With
 577 ange-ftp, you can even dired a directory containing an ls-lR file,
 578 visit that file and turn on virtual dired mode.  But don't try to save
 579 this file, as dired-virtual indents the listing and thus changes the
 580 buffer.
 581
 582 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 583 resume it in a later session.
 584
 585 Type \\<dired-mode-map>\\[revert-buffer] \
 586 in the Virtual Dired buffer and answer `y' to convert
 587 the virtual to a real dired buffer again.  You don't have to do this, though:
 588 you can relist single subdirs using \\[dired-do-redisplay]."
 589
 590   ;; DIRNAME is the top level directory of the buffer.  It will become
 591   ;; its `default-directory'.  If nil, the old value of
 592   ;; default-directory is used.
 593
 594   ;; Optional SWITCHES are the ls switches to use.
 595
 596   ;; Shell wildcards will be used if there already is a `wildcard'
 597   ;; line in the buffer (thus it is a saved Dired buffer), but there
 598   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 599   ;; hand if you want them.
 600
 601   (interactive
 602    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 603   (goto-char (point-min))
 604   (or (looking-at "  ")
 605       ;; if not already indented, do it now:
 606       (indent-region (point-min) (point-max) 2))
 607   (or dirname (setq dirname default-directory))
 608   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 609   (setq default-directory dirname)      ; contains no wildcards
 610   (let ((wildcard (save-excursion
 611                     (goto-char (point-min))
 612                     (forward-line 1)
 613                     (and (looking-at "^  wildcard ")
 614                          (buffer-substring (match-end 0)
 615                                            (line-end-position))))))
 616   (if wildcard
 617         (setq dirname (expand-file-name wildcard default-directory))))
 618   ;; If raw ls listing (not a saved old dired buffer), give it a
 619   ;; decent subdir headerline:
 620   (goto-char (point-min))
 621   (or (looking-at dired-subdir-regexp)
 622       (insert "  "
 623               (directory-file-name (file-name-directory default-directory))
 624               ":\n"))
 625   (dired-mode dirname (or switches dired-listing-switches))
 626   (setq mode-name "Virtual Dired"
 627         revert-buffer-function 'dired-virtual-revert)
 628   (set (make-local-variable 'dired-subdir-alist) nil)
 629   (dired-build-subdir-alist)
 630   (goto-char (point-min))
 631   (dired-initial-position dirname))
 632
 633 (defun dired-virtual-guess-dir ()
 634   "Guess and return appropriate working directory of this buffer.
 635 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 636 based upon buffer contents.  If nothing could be guessed, returns
 637 nil."
 638
 639   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 640         (subexpr 2))
 641     (goto-char (point-min))
 642     (cond ((looking-at regexp)
 643            ;; If a saved dired buffer, look to which dir and
 644            ;; perhaps wildcard it belongs:
 645            (let ((dir (buffer-substring (match-beginning subexpr)
 646                                         (match-end subexpr))))
 647              (file-name-as-directory dir)))
 648           ;; Else no match for headerline found.  It's a raw ls listing.
 649           ;; In raw ls listings the directory does not have a headerline
 650           ;; try parent of first subdir, if any
 651           ((re-search-forward regexp nil t)
 652            (file-name-directory
 653             (directory-file-name
 654              (file-name-as-directory
 655               (buffer-substring (match-beginning subexpr)
 656                                 (match-end subexpr))))))
 657           (t                            ; if all else fails
 658            nil))))
 659
 660
 661 (defun dired-virtual-revert (&optional arg noconfirm)
 662   (if (not
 663        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 664       (error "Cannot revert a Virtual Dired buffer")
 665     (setq mode-name "Dired"
 666           revert-buffer-function 'dired-revert)
 667     (revert-buffer)))
 668
 669 ;; A zero-arg version of dired-virtual.
 670 (defun dired-virtual-mode ()
 671   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 672 Useful on `magic-mode-alist' with the regexp
 673
 674   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 675
 676 to put saved dired buffers automatically into Virtual Dired mode.
 677
 678 Also useful for `auto-mode-alist' like this:
 679
 680   (add-to-list 'auto-mode-alist
 681                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 682   (interactive)
 683   (dired-virtual (dired-virtual-guess-dir)))
 684
 685 \f
 686 ;;; SMART SHELL.
 687
 688 ;; An Emacs buffer can have but one working directory, stored in the
 689 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 690 ;; several subdirectories inserted, but still has but one working directory:
 691 ;; that of the top level Dired directory in that buffer.  For some commands
 692 ;; it is appropriate that they use the current Dired directory instead of
 693 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 694 ;; mechanism is provided for special handling of the working directory in
 695 ;; special major modes.
 696
 697 (define-obsolete-variable-alias 'default-directory-alist
 698   'dired-default-directory-alist "24.1")
 699
 700 ;; It's easier to add to this alist than redefine function
 701 ;; default-directory while keeping the old information.
 702 (defconst dired-default-directory-alist
 703   '((dired-mode . (if (fboundp 'dired-current-directory)
 704                       (dired-current-directory)
 705                     default-directory)))
 706   "Alist of major modes and their opinion on `default-directory'.
 707 This is given as a Lisp expression to evaluate.  A resulting value of
 708 nil is ignored in favor of `default-directory'.")
 709
 710 (defun dired-default-directory ()
 711   "Usage like variable `default-directory'.
 712 Knows about the special cases in variable `dired-default-directory-alist'."
 713   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 714       default-directory))
 715
 716 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 717   "Like function `shell-command', but in the current Virtual Dired directory."
 718   (interactive
 719    (list
 720     (read-shell-command "Shell command: " nil nil
 721                         (cond
 722                          (buffer-file-name (file-relative-name buffer-file-name))
 723                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 724     current-prefix-arg
 725     shell-command-default-error-buffer))
 726   (let ((default-directory (dired-default-directory)))
 727     (shell-command command output-buffer error-buffer)))
 728
 729 \f
 730 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 731
 732 ;; Brief Description:
 733 ;;;
 734 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 735 ;;;
 736 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 737 ;;;
 738 ;; * `dired-hack-local-variables' checks the value of
 739 ;;;   `dired-local-variables-file'
 740 ;;;
 741 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 742 ;;;   filename found in the directory of the Dired Buffer being created.
 743 ;;;
 744 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 745 ;;;   include it in the Dired Buffer at the bottom.
 746 ;;;
 747 ;; * Set `enable-local-variables' temporarily to the user variable
 748 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 749 ;;;   Dired Buffer.
 750
 751 ;; FIXME do standard dir-locals obsolete this?
 752 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 753   "Filename, as string, containing local dired buffer variables to be hacked.
 754 If this file found in current directory, then it will be inserted into dired
 755 buffer and `hack-local-variables' will be run.  See Info node
 756 `(emacs)File Variables' for more information on local variables.
 757 See also `dired-enable-local-variables'."
 758   :type 'file
 759   :group 'dired)
 760
 761 (defun dired-hack-local-variables ()
 762   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 763   (and (stringp dired-local-variables-file)
 764        (file-exists-p dired-local-variables-file)
 765        (let ((opoint (point-max))
 766              (inhibit-read-only t)
 767              ;; In case user has `enable-local-variables' set to nil we
 768              ;; override it locally with dired's variable.
 769              (enable-local-variables dired-enable-local-variables))
 770          ;; Insert 'em.
 771          (save-excursion
 772            (goto-char opoint)
 773            (insert "\^L\n")
 774            (insert-file-contents dired-local-variables-file))
 775          ;; Hack 'em.
 776          (let ((buffer-file-name dired-local-variables-file))
 777            (hack-local-variables))
 778          ;; Make sure that the modeline shows the proper information.
 779          (dired-sort-set-modeline)
 780          ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 781          (delete-region opoint (point-max)))))
 782
 783 (defun dired-omit-here-always ()
 784   "Create `dired-local-variables-file' for omitting and reverts directory.
 785 Sets `dired-omit-mode' to t in a local variables file that is readable by
 786 dired."
 787   (interactive)
 788   (if (file-exists-p dired-local-variables-file)
 789       (message "File `./%s' already exists." dired-local-variables-file)
 790     ;; Create `dired-local-variables-file'.
 791     (with-current-buffer (get-buffer-create " *dot-dired*")
 792       (erase-buffer)
 793       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 794       (write-file dired-local-variables-file)
 795       (kill-buffer))
 796     ;; Run extra-hooks and revert directory.
 797     (dired-extra-startup)
 798     (dired-revert)))
 799
 800 \f
 801 ;;; GUESS SHELL COMMAND.
 802
 803 ;; Brief Description:
 804 ;;;
 805 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 806 ;;;
 807 ;; * `dired-guess-shell-command' provides smarter defaults for
 808 ;;;    dired-aux.el's `dired-read-shell-command'.
 809 ;;;
 810 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 811 ;;;    marked files.
 812 ;;;
 813 ;; * Parse `dired-guess-shell-alist-user' and
 814 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 815 ;;;   that matches the first file in the file list.
 816 ;;;
 817 ;; * If the REGEXP matches all the entries of the file list then evaluate
 818 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 819 ;;;   string.  COMMAND may be a list of commands.
 820 ;;;
 821 ;; * Return this command to `dired-guess-shell-command' which prompts user
 822 ;;;   with it.  The list of commands is put into the list of default values.
 823 ;;;   If a command is used successfully then it is stored permanently in
 824 ;;;   `dired-shell-command-history'.
 825
 826 ;; Guess what shell command to apply to a file.
 827 (defvar dired-shell-command-history nil
 828   "History list for commands that read dired-shell commands.")
 829
 830 ;; Default list of shell commands.
 831
 832 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 833 ;; install GNU zip's version of zcat.
 834
 835 (declare-function Man-support-local-filenames "man" ())
 836
 837 (defvar dired-guess-shell-alist-default
 838   (list
 839    (list "\\.tar$"
 840          '(if dired-guess-shell-gnutar
 841               (concat dired-guess-shell-gnutar " xvf")
 842             "tar xvf")
 843          ;; Extract files into a separate subdirectory
 844          '(if dired-guess-shell-gnutar
 845               (concat "mkdir " (file-name-sans-extension file)
 846                       "; " dired-guess-shell-gnutar " -C "
 847                       (file-name-sans-extension file) " -xvf")
 848             (concat "mkdir " (file-name-sans-extension file)
 849                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 850          ;; List archive contents.
 851          '(if dired-guess-shell-gnutar
 852               (concat dired-guess-shell-gnutar " tvf")
 853             "tar tvf"))
 854
 855    ;; REGEXPS for compressed archives must come before the .Z rule to
 856    ;; be recognized:
 857    (list "\\.tar\\.Z$"
 858          ;; Untar it.
 859          '(if dired-guess-shell-gnutar
 860               (concat dired-guess-shell-gnutar " zxvf")
 861             (concat "zcat * | tar xvf -"))
 862          ;; Optional conversion to gzip format.
 863          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 864                   " " dired-guess-shell-znew-switches))
 865
 866    ;; gzip'ed archives
 867    (list "\\.t\\(ar\\.\\)?gz$"
 868          '(if dired-guess-shell-gnutar
 869               (concat dired-guess-shell-gnutar " zxvf")
 870             (concat "gunzip -qc * | tar xvf -"))
 871          ;; Extract files into a separate subdirectory
 872          '(if dired-guess-shell-gnutar
 873               (concat "mkdir " (file-name-sans-extension file)
 874                       "; " dired-guess-shell-gnutar " -C "
 875                       (file-name-sans-extension file) " -zxvf")
 876             (concat "mkdir " (file-name-sans-extension file)
 877                     "; gunzip -qc * | tar -C "
 878                     (file-name-sans-extension file) " -xvf -"))
 879          ;; Optional decompression.
 880          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 881          ;; List archive contents.
 882          '(if dired-guess-shell-gnutar
 883               (concat dired-guess-shell-gnutar " ztvf")
 884             (concat "gunzip -qc * | tar tvf -")))
 885
 886    ;; bzip2'ed archives
 887    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
 888          "bunzip2 -c * | tar xvf -"
 889          ;; Extract files into a separate subdirectory
 890          '(concat "mkdir " (file-name-sans-extension file)
 891                   "; bunzip2 -c * | tar -C "
 892                   (file-name-sans-extension file) " -xvf -")
 893          ;; Optional decompression.
 894          "bunzip2")
 895
 896    ;; xz'ed archives
 897    (list "\\.t\\(ar\\.\\)?xz$"
 898          "unxz -c * | tar xvf -"
 899          ;; Extract files into a separate subdirectory
 900          '(concat "mkdir " (file-name-sans-extension file)
 901                   "; unxz -c * | tar -C "
 902                   (file-name-sans-extension file) " -xvf -")
 903          ;; Optional decompression.
 904          "unxz")
 905
 906    '("\\.shar\\.Z$" "zcat * | unshar")
 907    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
 908
 909    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
 910    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
 911          ;; Optional decompression.
 912          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 913    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
 914          ;; Optional conversion to gzip format.
 915          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 916                   " " dired-guess-shell-znew-switches))
 917
 918    '("\\.patch$" "cat * | patch")
 919    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
 920          ;; Optional decompression.
 921          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 922    (list "\\.patch\\.Z$" "zcat * | patch"
 923          ;; Optional conversion to gzip format.
 924          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 925                   " " dired-guess-shell-znew-switches))
 926
 927    ;; The following four extensions are useful with dired-man ("N" key)
 928    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
 929                                            (if (Man-support-local-filenames)
 930                                                "man -l"
 931                                              "cat * | tbl | nroff -man -h")))
 932    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
 933                                                  (if (Man-support-local-filenames)
 934                                                      "man -l"
 935                                                    "gunzip -qc * | tbl | nroff -man -h"))
 936          ;; Optional decompression.
 937          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 938    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
 939                                  (if (Man-support-local-filenames)
 940                                      "man -l"
 941                                    "zcat * | tbl | nroff -man -h"))
 942          ;; Optional conversion to gzip format.
 943          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 944                   " " dired-guess-shell-znew-switches))
 945    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
 946
 947    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
 948    '("\\.au$" "play")                   ; play Sun audiofiles
 949    '("\\.mpe?g$\\|\\.avi$" "xine -p")
 950    '("\\.ogg$" "ogg123")
 951    '("\\.mp3$" "mpg123")
 952    '("\\.wav$" "play")
 953    '("\\.uu$" "uudecode")               ; for uudecoded files
 954    '("\\.hqx$" "mcvert")
 955    '("\\.sh$" "sh")                     ; execute shell scripts
 956    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
 957    '("\\.gp$" "gnuplot")
 958    '("\\.p[bgpn]m$" "xloadimage")
 959    '("\\.gif$" "xloadimage")            ; view gif pictures
 960    '("\\.tif$" "xloadimage")
 961    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
 962    '("\\.jpe?g$" "xloadimage")
 963    '("\\.fig$" "xfig")                  ; edit fig pictures
 964    '("\\.out$" "xgraph")                ; for plotting purposes.
 965    '("\\.tex$" "latex" "tex")
 966    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
 967    '("\\.pdf$" "xpdf")
 968    '("\\.doc$" "antiword" "strings")
 969    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
 970    '("\\.dia$" "dia")
 971    '("\\.mgp$" "mgp")
 972
 973    ;; Some other popular archivers.
 974    (list "\\.zip$" "unzip" "unzip -l"
 975          ;; Extract files into a separate subdirectory
 976          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
 977                   " -d " (file-name-sans-extension file)))
 978    '("\\.zoo$" "zoo x//")
 979    '("\\.lzh$" "lharc x")
 980    '("\\.arc$" "arc x")
 981    '("\\.shar$" "unshar")
 982
 983    ;; Compression.
 984    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 985    (list "\\.dz$" "dictunzip")
 986    (list "\\.bz2$" "bunzip2")
 987    (list "\\.xz$" "unxz")
 988    (list "\\.Z$" "uncompress"
 989          ;; Optional conversion to gzip format.
 990          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 991                   " " dired-guess-shell-znew-switches))
 992
 993    '("\\.sign?$" "gpg --verify"))
 994
 995   "Default alist used for shell command guessing.
 996 See `dired-guess-shell-alist-user'.")
 997
 998 (defcustom dired-guess-shell-alist-user nil
 999   "User-defined alist of rules for suggested commands.
1000 These rules take precedence over the predefined rules in the variable
1001 `dired-guess-shell-alist-default' (to which they are prepended).
1002
1003 Each element of this list looks like
1004
1005     \(REGEXP COMMAND...\)
1006
1007 where each COMMAND can either be a string or a Lisp expression that evaluates
1008 to a string.  If several COMMANDs are given, the first one will be the default
1009 and the rest will be added temporarily to the history and can be retrieved
1010 with \\[previous-history-element] (M-p) .
1011
1012 The variable `dired-guess-shell-case-fold-search' controls whether
1013 REGEXP is matched case-sensitively.
1014
1015 You can set this variable in your ~/.emacs.  For example, to add rules for
1016 `.foo' and `.bar' files, write
1017
1018  \(setq dired-guess-shell-alist-user
1019        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1020               ;; possibly more rules ...
1021               (list \"\\\\.bar\\\\'\";; rule with condition test
1022                     '(if condition
1023                           \"BAR-COMMAND-1\"
1024                         \"BAR-COMMAND-2\")))\)"
1025   :group 'dired-x
1026   :type '(alist :key-type regexp :value-type (repeat sexp)))
1027
1028 (defcustom dired-guess-shell-case-fold-search t
1029   "If non-nil, `dired-guess-shell-alist-default' and
1030 `dired-guess-shell-alist-user' are matched case-insensitively."
1031   :group 'dired-x
1032   :type 'boolean)
1033
1034 (defun dired-guess-default (files)
1035   "Guess a shell commands for FILES.  Return command or list of commands.
1036 See `dired-guess-shell-alist-user'."
1037
1038   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1039          ;; Prepend the user's alist to the default alist.
1040          (alist (append dired-guess-shell-alist-user
1041                         dired-guess-shell-alist-default))
1042          (file (car files))
1043          (flist (cdr files))
1044          elt regexp cmds)
1045
1046     ;; Find the first match in the alist for first file in FILES.
1047     (while alist
1048       (setq elt (car alist)
1049             regexp (car elt)
1050             alist (cdr alist))
1051       (if (string-match regexp file)
1052           (setq cmds (cdr elt)
1053                 alist nil)))
1054
1055     ;; If more than one file, see if all of FILES match regular expression.
1056     (while (and flist
1057                 (string-match regexp (car flist)))
1058       (setq flist (cdr flist)))
1059
1060     ;; If flist is still non-nil, then do not guess since this means that not
1061     ;; all the files in FILES were matched by the regexp.
1062     (setq cmds (and (not flist) cmds))
1063
1064     ;; Return commands or nil if flist is still non-nil.
1065     ;; Evaluate the commands in order that any logical testing will be done.
1066     (if (cdr cmds)
1067         (mapcar #'eval cmds)
1068       (eval (car cmds))))) ; single command
1069
1070 (defun dired-guess-shell-command (prompt files)
1071   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1072   (let ((default (dired-guess-default files))
1073         default-list val)
1074     (if (null default)
1075         ;; Nothing to guess
1076         (read-shell-command prompt nil 'dired-shell-command-history)
1077       (if (listp default)
1078           ;; More than one guess
1079           (setq default-list default
1080                 default (car default)
1081                 prompt (concat
1082                         prompt
1083                         (format "{%d guesses} " (length default-list))))
1084         ;; Just one guess
1085         (setq default-list (list default)))
1086       ;; Put the first guess in the prompt but not in the initial value.
1087       (setq prompt (concat prompt (format "[%s] " default)))
1088       ;; All guesses can be retrieved with M-n
1089       (setq val (read-shell-command prompt nil
1090                                     'dired-shell-command-history
1091                                     default-list))
1092       ;; If we got a return, then return default.
1093       (if (equal val "") default val))))
1094
1095 \f
1096 ;;; RELATIVE SYMBOLIC LINKS.
1097
1098 (declare-function make-symbolic-link "fileio.c")
1099
1100 (defvar dired-keep-marker-relsymlink ?S
1101   "See variable `dired-keep-marker-move'.")
1102
1103 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1104   "Make a symbolic link (pointing to FILE1) in FILE2.
1105 The link is relative (if possible), for example
1106
1107     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1108
1109 results in
1110
1111     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1112   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1113   (let (name1 name2 len1 len2 (index 0) sub)
1114     (setq file1 (expand-file-name file1)
1115           file2 (expand-file-name file2)
1116           len1 (length file1)
1117           len2 (length file2))
1118     ;; Find common initial file name components:
1119     (let (next)
1120       (while (and (setq next (string-match "/" file1 index))
1121                   (< (setq next (1+ next)) (min len1 len2))
1122                   ;; For the comparison, both substrings must end in
1123                   ;; `/', so NEXT is *one plus* the result of the
1124                   ;; string-match.
1125                   ;; E.g., consider the case of linking "/tmp/a/abc"
1126                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1127                   ;; of "/tmp/" as common initial component
1128                   (string-equal (substring file1 0 next)
1129                                 (substring file2 0 next)))
1130         (setq index next))
1131       (setq name2 file2
1132             sub (substring file1 0 index)
1133             name1 (substring file1 index)))
1134     (if (string-equal sub "/")
1135         ;; No common initial file name found
1136         (setq name1 file1)
1137       ;; Else they have a common parent directory
1138       (let ((tem (substring file2 index))
1139             (start 0)
1140             (count 0))
1141         ;; Count number of slashes we must compensate for ...
1142         (while (setq start (string-match "/" tem start))
1143           (setq count (1+ count)
1144                 start (1+ start)))
1145         ;; ... and prepend a "../" for each slash found:
1146         (dotimes (n count)
1147           (setq name1 (concat "../" name1)))))
1148     (make-symbolic-link
1149      (directory-file-name name1)        ; must not link to foo/
1150                                         ; (trailing slash!)
1151      name2 ok-if-already-exists)))
1152
1153 ;;;###autoload
1154 (defun dired-do-relsymlink (&optional arg)
1155    "Relative symlink all marked (or next ARG) files into a directory.
1156 Otherwise make a relative symbolic link to the current file.
1157 This creates relative symbolic links like
1158
1159     foo -> ../bar/foo
1160
1161 not absolute ones like
1162
1163     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1164
1165 For absolute symlinks, use \\[dired-do-symlink]."
1166   (interactive "P")
1167   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1168                            "RelSymLink" arg dired-keep-marker-relsymlink))
1169
1170 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1171   "RelSymlink all marked files containing REGEXP to NEWNAME.
1172 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1173 for more info."
1174   (interactive (dired-mark-read-regexp "RelSymLink"))
1175   (dired-do-create-files-regexp
1176    #'dired-make-relative-symlink
1177    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1178
1179 \f
1180 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1181
1182 ;; Brief Description:
1183 ;;;
1184 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1185 ;;;
1186 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1187 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1188 ;;;
1189 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1190 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1191 ;;;
1192 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1193 ;;;   list each time.
1194 ;;;
1195 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1196 ;;;   element of FILE-LIST.
1197 ;;;
1198 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1199 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1200 ;;;   cognizant of the window-configuration.
1201 ;;;
1202 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1203 ;;;   of FILE-LIST giving each a window of height `size'.
1204
1205 (defun dired-do-find-marked-files (&optional noselect)
1206   "Find all marked files displaying all of them simultaneously.
1207 With optional NOSELECT just find files but do not select them.
1208
1209 The current window is split across all files marked, as evenly as possible.
1210 Remaining lines go to bottom-most window.  The number of files that can be
1211 displayed this way is restricted by the height of the current window and
1212 `window-min-height'.
1213
1214 To keep dired buffer displayed, type \\[split-window-vertically] first.
1215 To display just marked files, type \\[delete-other-windows] first."
1216   (interactive "P")
1217   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1218
1219 (defun dired-simultaneous-find-file (file-list noselect)
1220   "Visit all files in FILE-LIST and display them simultaneously.
1221 The current window is split across all files in FILE-LIST, as evenly as
1222 possible.  Remaining lines go to the bottom-most window.  The number of
1223 files that can be displayed this way is restricted by the height of the
1224 current window and the variable `window-min-height'.  With non-nil
1225 NOSELECT the files are merely found but not selected."
1226   ;; We don't make this function interactive because it is usually too clumsy
1227   ;; to specify FILE-LIST interactively unless via dired.
1228   (let (size)
1229     (if noselect
1230         ;; Do not select the buffer.
1231         (find-file-noselect (car file-list))
1232       ;; We will have to select the buffer.  Calculate and check window size.
1233       (setq size (/ (window-height) (length file-list)))
1234       (or (<= window-min-height size)
1235           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1236       (find-file (car file-list)))
1237     ;; Decrement.
1238     (dolist (file (cdr file-list))
1239       (if noselect
1240           ;; Do not select the buffer.
1241           (find-file-noselect file)
1242         ;; Vertically split off a window of desired size.  Upper window will
1243         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1244         (select-window (split-window nil size))
1245         (find-file file)))))
1246
1247 \f
1248 ;;; MISCELLANEOUS COMMANDS.
1249
1250 ;; Run man on files.
1251
1252 (declare-function Man-getpage-in-background "man" (topic))
1253
1254 (defun dired-man ()
1255   "Run `man' on this file."
1256 ;; Used also to say: "Display old buffer if buffer name matches filename."
1257 ;; but I have no idea what that means.
1258   (interactive)
1259   (require 'man)
1260   (let* ((file (dired-get-filename))
1261          (manual-program (replace-regexp-in-string "\\*" "%s"
1262                           (dired-guess-shell-command
1263                            "Man command: " (list file)))))
1264     (Man-getpage-in-background file)))
1265
1266 ;; Run Info on files.
1267
1268 (defun dired-info ()
1269   "Run `info' on this file."
1270   (interactive)
1271   (info (dired-get-filename)))
1272
1273 ;; Run mail on mail folders.
1274
1275 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1276 (defvar vm-folder-directory)
1277
1278 (defun dired-vm (&optional read-only)
1279   "Run VM on this file.
1280 With optional prefix argument, visits the folder read-only.
1281 Otherwise obeys the value of `dired-vm-read-only-folders'."
1282   (interactive "P")
1283   (let ((dir (dired-current-directory))
1284         (fil (dired-get-filename)))
1285     (vm-visit-folder fil (or read-only
1286                              (eq t dired-vm-read-only-folders)
1287                              (and dired-vm-read-only-folders
1288                                   (not (file-writable-p fil)))))
1289     ;; So that pressing `v' inside VM does prompt within current directory:
1290     (set (make-local-variable 'vm-folder-directory) dir)))
1291
1292 (defun dired-rmail ()
1293   "Run RMAIL on this file."
1294   (interactive)
1295   (rmail (dired-get-filename)))
1296
1297 (defun dired-do-run-mail ()
1298   "If `dired-bind-vm' is non-nil, call `dired-vm', else call `dired-rmail'."
1299   (interactive)
1300   (if dired-bind-vm
1301       ;; Read mail folder using vm.
1302       (dired-vm)
1303     ;; Read mail folder using rmail.
1304     (dired-rmail)))
1305
1306 \f
1307 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1308
1309 (declare-function dired-old-find-buffer-nocreate "dired-x")
1310
1311 (or (fboundp 'dired-old-find-buffer-nocreate)
1312     (fset 'dired-old-find-buffer-nocreate
1313           (symbol-function 'dired-find-buffer-nocreate)))
1314
1315 ;; REDEFINE.
1316 ;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1317 (defun dired-find-buffer-nocreate (dirname &optional mode)
1318   (if (and dired-find-subdir
1319            ;; don't try to find a wildcard as a subdirectory
1320            (string-equal dirname (file-name-directory dirname)))
1321       (let* ((cur-buf (current-buffer))
1322              (buffers (nreverse
1323                        (dired-buffers-for-dir (expand-file-name dirname))))
1324              (cur-buf-matches (and (memq cur-buf buffers)
1325                                    ;; wildcards must match, too:
1326                                    (equal dired-directory dirname))))
1327         ;; We don't want to switch to the same buffer---
1328         (setq buffers (delq cur-buf buffers));;need setq with delq
1329         (or (car (sort buffers #'dired-buffer-more-recently-used-p))
1330             ;; ---unless it's the only possibility:
1331             (and cur-buf-matches cur-buf)))
1332     (dired-old-find-buffer-nocreate dirname mode)))
1333
1334 ;; This should be a builtin
1335 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1336   "Return t if BUFFER1 is more recently used than BUFFER2.
1337 Considers buffers closer to the car of `buffer-list' to be more recent."
1338   (and (not (equal buffer1 buffer2))
1339        (memq buffer1 (buffer-list))
1340        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1341
1342 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1343 ;; (defun dired-buffers-for-dir-exact (dir)
1344 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1345 ;; ;; at top level, or as subdirectory.
1346 ;; ;; Top level matches must match the wildcard part too, if any.
1347 ;; ;; The list is in reverse order of buffer creation, most recent last.
1348 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1349 ;; ;; dired-buffers.
1350 ;;   (let ((alist dired-buffers) result elt)
1351 ;;     (while alist
1352 ;;       (setq elt (car alist)
1353 ;;             alist (cdr alist))
1354 ;;       (let ((buf (cdr elt)))
1355 ;;         (if (buffer-name buf)
1356 ;;             ;; Top level must match exactly against dired-directory in
1357 ;;             ;; case one of them is a wildcard.
1358 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1359 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1360 ;;                 (setq result (cons buf result)))
1361 ;;           ;; else buffer is killed - clean up:
1362 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1363 ;;     result))
1364
1365 \f
1366 ;; Does anyone use this? - lrd 6/29/93.
1367 ;; Apparently people do use it. - lrd 12/22/97.
1368 (defun dired-mark-sexp (predicate &optional unflag-p)
1369   "Mark files for which PREDICATE returns non-nil.
1370 With a prefix arg, unflag those files instead.
1371
1372 PREDICATE is a lisp expression that can refer to the following symbols:
1373
1374     inode  [integer] the inode of the file (only for ls -i output)
1375     s      [integer] the size of the file for ls -s output
1376                      (usually in blocks or, with -k, in KByte)
1377     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1378     nlink  [integer] number of links to file
1379     uid    [string]  owner
1380     gid    [string]  group  (If the gid is not displayed by ls,
1381                      this will still be set (to the same as uid))
1382     size   [integer] file size in bytes
1383     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1384     name   [string]  the name of the file
1385     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1386
1387 For example, use
1388
1389         (equal 0 size)
1390
1391 to mark all zero length files."
1392   ;; Using sym="" instead of nil avoids the trap of
1393   ;; (string-match "foo" sym) into which a user would soon fall.
1394   ;; Give `equal' instead of `=' in the example, as this works on
1395   ;; integers and strings.
1396   (interactive "xMark if (lisp expr): \nP")
1397   (message "%s" predicate)
1398   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1399         inode s mode nlink uid gid size time name sym)
1400     (dired-mark-if
1401      (save-excursion
1402        (and
1403         ;; Sets vars
1404         ;;                inode s mode nlink uid gid size time name sym
1405
1406         ;; according to current file line.  Returns t for success, nil if
1407         ;; there is no file line.  Upon success, all variables are set, either
1408         ;; to nil or the appropriate value, so they need not be initialized.
1409         ;; Moves point within the current line.
1410         (dired-move-to-filename)
1411         (let (pos
1412               (mode-len 10) ; length of mode string
1413               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1414               (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1415           (beginning-of-line)
1416           (forward-char 2)
1417           (if (looking-at dired-re-inode-size)
1418               (progn
1419                 (goto-char (match-end 0))
1420                 (setq inode (string-to-number
1421                              (buffer-substring (match-beginning 1)
1422                                                (match-end 1)))
1423                       s (string-to-number
1424                          (buffer-substring (match-beginning 2)
1425                                            (match-end 2)))))
1426             (setq inode nil
1427                   s nil))
1428           (setq mode (buffer-substring (point) (+ mode-len (point))))
1429           (forward-char mode-len)
1430           (setq nlink (read (current-buffer)))
1431           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1432           (setq uid (buffer-substring (1+ (point))
1433                                       (progn (forward-word 1) (point))))
1434           (re-search-forward directory-listing-before-filename-regexp)
1435           (goto-char (match-beginning 1))
1436           (forward-char -1)
1437           (setq size (string-to-number
1438                       (buffer-substring (save-excursion
1439                                           (backward-word 1)
1440                                           (setq pos (point)))
1441                                         (point))))
1442           (goto-char pos)
1443           (backward-word 1)
1444           ;; if no gid is displayed, gid will be set to uid
1445           ;; but user will then not reference it anyway in PREDICATE.
1446           (setq gid (buffer-substring (save-excursion
1447                                         (forward-word 1) (point))
1448                                       (point))
1449                 time (buffer-substring (match-beginning 1)
1450                                        (1- (dired-move-to-filename)))
1451                 name (buffer-substring (point)
1452                                        (or
1453                                         (dired-move-to-end-of-filename t)
1454                                         (point)))
1455                 sym (if (looking-at " -> ")
1456                         (buffer-substring (progn (forward-char 4) (point))
1457                                           (line-end-position))
1458                       ""))
1459           t)
1460         (eval predicate)))
1461      (format "'%s file" predicate))))
1462
1463 \f
1464 ;;; FIND FILE AT POINT.
1465
1466 (defcustom dired-x-hands-off-my-keys t
1467   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1468 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1469 If you change this variable without using \\[customize] after `dired-x.el'
1470 is loaded then call \\[dired-x-bind-find-file]."
1471   :type 'boolean
1472   :initialize 'custom-initialize-default
1473   :set (lambda (sym val)
1474          (set sym val)
1475          (dired-x-bind-find-file))
1476   :group 'dired-x)
1477
1478 (defun dired-x-bind-find-file ()
1479   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1480 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1481 Binding direction based on `dired-x-hands-off-my-keys'."
1482   (interactive)
1483   (if (called-interactively-p 'interactive)
1484       (setq dired-x-hands-off-my-keys
1485             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1486   (define-key (current-global-map) [remap find-file]
1487     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file))
1488   (define-key (current-global-map) [remap find-file-other-window]
1489     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window)))
1490
1491 ;; Now call it so binding is correct.  This could go in the :initialize
1492 ;; slot, but then dired-x-bind-find-file has to be defined before the
1493 ;; defcustom, and we get free variable warnings.
1494 (dired-x-bind-find-file)
1495
1496 (defun dired-x-find-file (filename)
1497   "Edit file FILENAME.
1498 Like `find-file', except that when called interactively with a
1499 prefix argument, it offers the filename near point as a default."
1500   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1501   (find-file filename))
1502
1503 (defun dired-x-find-file-other-window (filename)
1504   "Edit file FILENAME, in another window.
1505 Like `find-file-other-window', except that when called interactively with
1506 a prefix argument, when it offers the filename near point as a default."
1507   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1508   (find-file-other-window filename))
1509
1510 ;;; Internal functions.
1511
1512 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1513 (defun dired-filename-at-point ()
1514   "Return the filename closest to point, expanded.
1515 Point should be in or after a filename."
1516   (save-excursion
1517     ;; First see if just past a filename.
1518     (or (eobp)                             ; why?
1519         (when (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1520           (skip-chars-backward " \n\t\r({[]})")
1521           (or (bobp) (backward-char 1))))
1522     (let ((filename-chars "-.[:alnum:]_/:$+@")
1523           start prefix)
1524       (if (looking-at (format "[%s]" filename-chars))
1525           (progn
1526             (skip-chars-backward filename-chars)
1527             (setq start (point)
1528                   prefix
1529                   ;; This is something to do with ange-ftp filenames.
1530                   ;; It convert foo@bar to /foo@bar.
1531                   ;; But when does the former occur in dired buffers?
1532                   (and (string-match
1533                         "^\\w+@"
1534                         (buffer-substring start (line-end-position)))
1535                        "/"))
1536             (if (string-match "[/~]" (char-to-string (preceding-char)))
1537                 (setq start (1- start)))
1538             (skip-chars-forward filename-chars))
1539         (error "No file found around point!"))
1540       ;; Return string.
1541       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1542
1543 (defun dired-x-read-filename-at-point (prompt)
1544   "Return filename prompting with PROMPT with completion.
1545 If `current-prefix-arg' is non-nil, uses name at point as guess."
1546   (if current-prefix-arg
1547       (let ((guess (dired-filename-at-point)))
1548         (read-file-name prompt
1549                         (file-name-directory guess)
1550                         guess
1551                         nil (file-name-nondirectory guess)))
1552     (read-file-name prompt default-directory)))
1553
1554 (define-obsolete-function-alias 'read-filename-at-point
1555   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1556 \f
1557 ;;; BUG REPORTS
1558
1559 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1560
1561 \f
1562 ;; As Barry Warsaw would say: "This might be useful..."
1563 (provide 'dired-x)
1564
1565 ;; Local Variables:
1566 ;; byte-compile-dynamic: t
1567 ;; generated-autoload-file: "dired.el"
1568 ;; End:
1569
1570 ;;; dired-x.el ends here