lisp/emacs-lisp/shadow.el

   1 ;;; shadow.el --- locate Emacs Lisp file shadowings
   2
   3 ;; Copyright (C) 1995, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Terry Jones <terry@santafe.edu>
   7 ;; Keywords: lisp
   8 ;; Created: 15 December 1995
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The functions in this file detect (`find-emacs-lisp-shadows')
  28 ;; and display (`list-load-path-shadows') potential load-path
  29 ;; problems that arise when Emacs Lisp files "shadow" each other.
  30 ;;
  31 ;; For example, a file XXX.el early in one's load-path will shadow
  32 ;; a file with the same name in a later load-path directory.  When
  33 ;; this is unintentional, it may result in problems that could have
  34 ;; been easily avoided.  This occurs often (to me) when installing a
  35 ;; new version of emacs and something in the site-lisp directory
  36 ;; has been updated and added to the emacs distribution.  The old
  37 ;; version, now outdated, shadows the new one. This is obviously
  38 ;; undesirable.
  39 ;;
  40 ;; The `list-load-path-shadows' function was run when you installed
  41 ;; this version of emacs. To run it by hand in emacs:
  42 ;;
  43 ;;     M-x load-library RET shadow RET
  44 ;;     M-x list-load-path-shadows
  45 ;;
  46 ;; or run it non-interactively via:
  47 ;;
  48 ;;     emacs -batch -l shadow.el -f list-load-path-shadows
  49 ;;
  50 ;; Thanks to Francesco Potorti` <pot@cnuce.cnr.it> for suggestions,
  51 ;; rewritings & speedups.
  52
  53 ;;; Code:
  54 \f
  55 (defgroup lisp-shadow nil
  56   "Locate Emacs Lisp file shadowings."
  57   :prefix "shadows-"
  58   :group 'lisp)
  59
  60 (defcustom shadows-compare-text-p nil
  61   "*If non-nil, then shadowing files are reported only if their text differs.
  62 This is slower, but filters out some innocuous shadowing."
  63   :type 'boolean
  64   :group 'lisp-shadow)
  65
  66 (defun find-emacs-lisp-shadows (&optional path)
  67   "Return a list of Emacs Lisp files that create shadows.
  68 This function does the work for `list-load-path-shadows'.
  69
  70 We traverse PATH looking for shadows, and return a \(possibly empty\)
  71 even-length list of files.  A file in this list at position 2i shadows
  72 the file in position 2i+1.  Emacs Lisp file suffixes \(.el and .elc\)
  73 are stripped from the file names in the list.
  74
  75 See the documentation for `list-load-path-shadows' for further information."
  76
  77   (or path (setq path load-path))
  78
  79   (let (true-names                      ; List of dirs considered.
  80         shadows                         ; List of shadowings, to be returned.
  81         files                           ; File names ever seen, with dirs.
  82         dir                             ; The dir being currently scanned.
  83         curr-files                      ; This dir's Emacs Lisp files.
  84         orig-dir                        ; Where the file was first seen.
  85         files-seen-this-dir             ; Files seen so far in this dir.
  86         file)                           ; The current file.
  87
  88
  89     (while path
  90
  91       (setq dir (directory-file-name (file-truename (or (car path) "."))))
  92       (if (member dir true-names)
  93           ;; We have already considered this PATH redundant directory.
  94           ;; Show the redundancy if we are interactive, unless the PATH
  95           ;; dir is nil or "." (these redundant directories are just a
  96           ;; result of the current working directory, and are therefore
  97           ;; not always redundant).
  98           (or noninteractive
  99               (and (car path)
 100                    (not (string= (car path) "."))
 101                    (message "Ignoring redundant directory %s" (car path))))
 102
 103         (setq true-names (append true-names (list dir)))
 104         (setq dir (directory-file-name (or (car path) ".")))
 105         (setq curr-files (if (file-accessible-directory-p dir)
 106                              (directory-files dir nil ".\\.elc?\\(\\.gz\\)?$" t)))
 107         (and curr-files
 108              (not noninteractive)
 109              (message "Checking %d files in %s..." (length curr-files) dir))
 110
 111         (setq files-seen-this-dir nil)
 112
 113         (while curr-files
 114
 115           (setq file (car curr-files))
 116           (if (string-match "\\.gz$" file)
 117               (setq file (substring file 0 -3)))
 118           (setq file (substring
 119                       file 0 (if (string= (substring file -1) "c") -4 -3)))
 120
 121           ;; FILE now contains the current file name, with no suffix.
 122           (unless (or (member file files-seen-this-dir)
 123                       ;; Ignore these files.
 124                       (member file '("subdirs")))
 125             ;; File has not been seen yet in this directory.
 126             ;; This test prevents us declaring that XXX.el shadows
 127             ;; XXX.elc (or vice-versa) when they are in the same directory.
 128             (setq files-seen-this-dir (cons file files-seen-this-dir))
 129
 130             (if (setq orig-dir (assoc file files))
 131                 ;; This file was seen before, we have a shadowing.
 132                 ;; Report it unless the files are identical.
 133                 (let ((base1 (concat (cdr orig-dir) "/" file))
 134                       (base2 (concat dir "/" file)))
 135                   (if (not (and shadows-compare-text-p
 136                                 (shadow-same-file-or-nonexistent
 137                                  (concat base1 ".el") (concat base2 ".el"))
 138                                 ;; This is a bit strict, but safe.
 139                                 (shadow-same-file-or-nonexistent
 140                                  (concat base1 ".elc") (concat base2 ".elc"))))
 141                       (setq shadows
 142                             (append shadows (list base1 base2)))))
 143
 144               ;; Not seen before, add it to the list of seen files.
 145               (setq files (cons (cons file dir) files))))
 146
 147           (setq curr-files (cdr curr-files))))
 148         (setq path (cdr path)))
 149
 150     ;; Return the list of shadowings.
 151     shadows))
 152
 153 ;; Return true if neither file exists, or if both exist and have identical
 154 ;; contents.
 155 (defun shadow-same-file-or-nonexistent (f1 f2)
 156   (let ((exists1 (file-exists-p f1))
 157         (exists2 (file-exists-p f2)))
 158     (or (and (not exists1) (not exists2))
 159         (and exists1 exists2
 160              (or (equal (file-truename f1) (file-truename f2))
 161                  ;; As a quick test, avoiding spawning a process, compare file
 162                  ;; sizes.
 163                  (and (= (nth 7 (file-attributes f1))
 164                          (nth 7 (file-attributes f2)))
 165                       (eq 0 (call-process "cmp" nil nil nil "-s" f1 f2))))))))
 166 \f
 167 ;;;###autoload
 168 (defun list-load-path-shadows ()
 169   "Display a list of Emacs Lisp files that shadow other files.
 170
 171 This function lists potential load path problems.  Directories in
 172 the `load-path' variable are searched, in order, for Emacs Lisp
 173 files.  When a previously encountered file name is found again, a
 174 message is displayed indicating that the later file is \"hidden\" by
 175 the earlier.
 176
 177 For example, suppose `load-path' is set to
 178
 179 \(\"/usr/gnu/emacs/site-lisp\" \"/usr/gnu/emacs/share/emacs/19.30/lisp\"\)
 180
 181 and that each of these directories contains a file called XXX.el.  Then
 182 XXX.el in the site-lisp directory is referred to by all of:
 183 \(require 'XXX\), \(autoload .... \"XXX\"\), \(load-library \"XXX\"\) etc.
 184
 185 The first XXX.el file prevents Emacs from seeing the second \(unless
 186 the second is loaded explicitly via `load-file'\).
 187
 188 When not intended, such shadowings can be the source of subtle
 189 problems.  For example, the above situation may have arisen because the
 190 XXX package was not distributed with versions of Emacs prior to
 191 19.30.  An Emacs maintainer downloaded XXX from elsewhere and installed
 192 it.  Later, XXX was updated and included in the Emacs distribution.
 193 Unless the Emacs maintainer checks for this, the new version of XXX
 194 will be hidden behind the old \(which may no longer work with the new
 195 Emacs version\).
 196
 197 This function performs these checks and flags all possible
 198 shadowings.  Because a .el file may exist without a corresponding .elc
 199 \(or vice-versa\), these suffixes are essentially ignored.  A file
 200 XXX.elc in an early directory \(that does not contain XXX.el\) is
 201 considered to shadow a later file XXX.el, and vice-versa.
 202
 203 When run interactively, the shadowings \(if any\) are displayed in a
 204 buffer called `*Shadows*'.  Shadowings are located by calling the
 205 \(non-interactive\) companion function, `find-emacs-lisp-shadows'."
 206
 207   (interactive)
 208   (let* ((path (copy-sequence load-path))
 209         (tem path)
 210         toplevs)
 211     ;; If we can find simple.el in two places,
 212     (while tem
 213       (if (or (file-exists-p (expand-file-name "simple.el" (car tem)))
 214               (file-exists-p (expand-file-name "simple.el.gz" (car tem))))
 215           (setq toplevs (cons (car tem) toplevs)))
 216       (setq tem (cdr tem)))
 217     (if (> (length toplevs) 1)
 218         ;; Cut off our copy of load-path right before
 219         ;; the last directory which has simple.el in it.
 220         ;; This avoids loads of duplications between the source dir
 221         ;; and the dir where these files were copied by installation.
 222         (let ((break (car toplevs)))
 223           (setq tem path)
 224           (while tem
 225             (if (eq (nth 1 tem) break)
 226                 (progn
 227                   (setcdr tem nil)
 228                   (setq tem nil)))
 229             (setq tem (cdr tem)))))
 230
 231     (let* ((shadows (find-emacs-lisp-shadows path))
 232            (n (/ (length shadows) 2))
 233            (msg (format "%s Emacs Lisp load-path shadowing%s found"
 234                         (if (zerop n) "No" (concat "\n" (number-to-string n)))
 235                         (if (= n 1) " was" "s were"))))
 236       (if (interactive-p)
 237           (save-excursion
 238             ;; We are interactive.
 239             ;; Create the *Shadows* buffer and display shadowings there.
 240             (let ((output-buffer (get-buffer-create "*Shadows*")))
 241               (display-buffer output-buffer)
 242               (set-buffer output-buffer)
 243               (erase-buffer)
 244               (while shadows
 245                 (insert (format "%s hides %s\n" (car shadows)
 246                                 (car (cdr shadows))))
 247                 (setq shadows (cdr (cdr shadows))))
 248               (insert msg "\n")))
 249         ;; We are non-interactive, print shadows via message.
 250         (when shadows
 251           (message "This site has duplicate Lisp libraries with the same name.
 252 If a locally-installed Lisp library overrides a library in the Emacs release,
 253 that can cause trouble, and you should probably remove the locally-installed
 254 version unless you know what you are doing.\n")
 255           (while shadows
 256             (message "%s hides %s" (car shadows) (car (cdr shadows)))
 257             (setq shadows (cdr (cdr shadows))))
 258           (message "%s" msg))))))
 259
 260 (provide 'shadow)
 261
 262 ;; arch-tag: 0480e8a7-62ed-4a12-a9f6-f44ded9b0830
 263 ;;; shadow.el ends here