lisp/progmodes/ada-prj.el

   1 ;;; ada-prj.el --- GUI editing of project files for the ada-mode
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Emmanuel Briot <briot@gnat.com>
   7 ;; Maintainer: Stephen Leake <stephen_leake@stephe-leake.org>
   8 ;; Keywords: languages, ada, project file
   9 ;; Package: ada-mode
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;; This package provides a set of functions to easily edit the project
  29 ;;; files used by the ada-mode.
  30 ;;; The only function publicly available here is `ada-customize'.
  31 ;;; See the documentation of the Ada mode for more information on the project
  32 ;;; files.
  33 ;;; Internally, a project file is represented as a property list, with each
  34 ;;; field of the project file matching one property of the list.
  35
  36
  37 ;;; History:
  38 ;;
  39
  40 ;;; Code:
  41
  42
  43 ;; ----- Requirements -----------------------------------------------------
  44
  45 (require 'cus-edit)
  46 (require 'ada-xref)
  47
  48 (eval-when-compile
  49    (require 'ada-mode))
  50
  51 ;; ----- Buffer local variables -------------------------------------------
  52
  53 (defvar ada-prj-current-values nil
  54   "Hold the current value of the fields, This is a property list.")
  55 (make-variable-buffer-local 'ada-prj-current-values)
  56
  57 (defvar ada-prj-default-values nil
  58   "Hold the default value for the fields, This is a property list.")
  59 (make-variable-buffer-local 'ada-prj-default-values)
  60
  61 (defvar ada-prj-ada-buffer nil
  62   "Indicates what Ada source file was being edited.")
  63
  64 (defvar ada-old-cross-prefix nil
  65   "The cross-prefix associated with the currently loaded runtime library.")
  66
  67
  68 ;; ----- Functions --------------------------------------------------------
  69
  70 (defun ada-prj-new ()
  71   "Open a new project file."
  72   (interactive)
  73   (let* ((prj
  74           (if (and ada-prj-default-project-file
  75                    (not (string= ada-prj-default-project-file "")))
  76               ada-prj-default-project-file
  77             "default.adp"))
  78          (filename (read-file-name "Project file: "
  79                                    (if prj "" nil)
  80                                    nil
  81                                    nil
  82                                    prj)))
  83     (if (not (string= (file-name-extension filename t) ".adp"))
  84         (error "File name extension for project files must be .adp"))
  85
  86     (ada-customize nil filename)))
  87
  88 (defun ada-prj-edit ()
  89   "Editing the project file associated with the current Ada buffer.
  90 If there is none, opens a new project file."
  91   (interactive)
  92   (if ada-prj-default-project-file
  93       (ada-customize)
  94     (ada-prj-new)))
  95
  96 (defun ada-prj-initialize-values (symbol ada-buffer filename)
  97   "Set SYMBOL to the property list of the project file FILENAME.
  98 If FILENAME is null, read the file associated with ADA-BUFFER.
  99 If no project file is found, return the default values."
 100 ;; FIXME: rationalize arguments; make ada-buffer optional?
 101   (if (and filename
 102            (not (string= filename ""))
 103            (assoc filename ada-xref-project-files))
 104       (set symbol (copy-sequence (cdr (assoc filename ada-xref-project-files))))
 105
 106     ;;  Set default values (except for the file name if this was given
 107     ;;  in the buffer
 108     (set symbol (ada-default-prj-properties))
 109     (if (and filename (not (string= filename "")))
 110         (set symbol (plist-put (eval symbol) 'filename filename)))
 111     ))
 112
 113
 114 (defun ada-prj-save-specific-option (field)
 115   "Return the string to print in the project file to save FIELD.
 116 If the current value of FIELD is the default value, return an empty string."
 117   (if (string= (plist-get ada-prj-current-values field)
 118                (plist-get ada-prj-default-values field))
 119       ""
 120     (concat (symbol-name field)
 121             "=" (plist-get ada-prj-current-values field) "\n")))
 122
 123 (defun ada-prj-save ()
 124   "Save the edited project file."
 125   (interactive)
 126   (let ((file-name (or (plist-get ada-prj-current-values 'filename)
 127                        (read-file-name "Save project as: ")))
 128         output)
 129     (set 'output
 130          (concat
 131
 132           ;;  Save the fields that do not depend on the current buffer
 133           ;;  only if they are different from the default value
 134
 135           (ada-prj-save-specific-option 'comp_opt)
 136           (ada-prj-save-specific-option 'bind_opt)
 137           (ada-prj-save-specific-option 'link_opt)
 138           (ada-prj-save-specific-option 'gnatmake_opt)
 139           (ada-prj-save-specific-option 'gnatfind_opt)
 140           (ada-prj-save-specific-option 'cross_prefix)
 141           (ada-prj-save-specific-option 'remote_machine)
 142           (ada-prj-save-specific-option 'debug_cmd)
 143
 144           ;;  Always save the fields that depend on the current buffer
 145           "main="      (plist-get ada-prj-current-values 'main) "\n"
 146           "build_dir=" (plist-get ada-prj-current-values 'build_dir) "\n"
 147           (ada-prj-set-list "check_cmd"
 148                             (plist-get ada-prj-current-values 'check_cmd)) "\n"
 149           (ada-prj-set-list "make_cmd"
 150                             (plist-get ada-prj-current-values 'make_cmd)) "\n"
 151           (ada-prj-set-list "comp_cmd"
 152                             (plist-get ada-prj-current-values 'comp_cmd)) "\n"
 153           (ada-prj-set-list "run_cmd"
 154                             (plist-get ada-prj-current-values 'run_cmd)) "\n"
 155           (ada-prj-set-list "src_dir"
 156                             (plist-get ada-prj-current-values 'src_dir)
 157                             t) "\n"
 158           (ada-prj-set-list "obj_dir"
 159                             (plist-get ada-prj-current-values 'obj_dir)
 160                             t) "\n"
 161           (ada-prj-set-list "debug_pre_cmd"
 162                             (plist-get ada-prj-current-values 'debug_pre_cmd))
 163           "\n"
 164           (ada-prj-set-list "debug_post_cmd"
 165                             (plist-get ada-prj-current-values 'debug_post_cmd))
 166           "\n"
 167           ))
 168
 169     (find-file file-name)
 170     (erase-buffer)
 171     (insert output)
 172     (save-buffer)
 173     ;; kill the project buffer
 174     (kill-buffer nil)
 175
 176     ;; kill the editor buffer
 177     (kill-buffer "*Edit Ada Mode Project*")
 178
 179     ;; automatically set the new project file as the active one
 180     (set 'ada-prj-default-project-file file-name)
 181
 182     ;; force Emacs to reread the project files
 183     (ada-reread-prj-file file-name)
 184     )
 185   )
 186
 187 (defun ada-prj-load-from-file (symbol)
 188   "Load SYMBOL value from file.
 189 One item per line should be found in the file."
 190   (save-excursion
 191     (let ((file (read-file-name "File name: " nil nil t))
 192           (buffer (current-buffer))
 193           line
 194           list)
 195       (find-file file)
 196       (widen)
 197       (goto-char (point-min))
 198       (while (not (eobp))
 199         (set 'line (buffer-substring-no-properties (point) (point-at-eol)))
 200         (add-to-list 'list line)
 201         (forward-line 1))
 202       (kill-buffer nil)
 203       (set-buffer buffer)
 204       (set 'ada-prj-current-values
 205            (plist-put ada-prj-current-values
 206                       symbol
 207                       (append (plist-get ada-prj-current-values symbol)
 208                               (reverse list)))))
 209     (ada-prj-display-page 2)))
 210
 211 (defun ada-prj-subdirs-of (dir)
 212   "Return a list of all the subdirectories of DIR, recursively."
 213   (let ((subdirs (directory-files dir t "^[^.].*"))
 214         (dirlist (list dir)))
 215     (while subdirs
 216       (if (file-directory-p (car subdirs))
 217           (let ((sub (ada-prj-subdirs-of (car subdirs))))
 218             (if sub
 219                 (set 'dirlist (append sub dirlist)))))
 220       (set 'subdirs (cdr subdirs)))
 221     dirlist))
 222
 223 (defun ada-prj-load-directory (field &optional file-name)
 224   "Append to FIELD in the current project the subdirectories of FILE-NAME.
 225 If FILE-NAME is nil, ask the user for the name."
 226
 227   ;;  Do not use an external dialog for this, since it wouldn't allow
 228   ;;  the user to select a directory
 229   (let ((use-dialog-box nil))
 230     (unless file-name
 231       (set 'file-name (read-file-name "Root directory: " nil nil t))))
 232
 233   (set 'ada-prj-current-values
 234        (plist-put ada-prj-current-values
 235                   field
 236                   (append (plist-get ada-prj-current-values field)
 237                           (reverse (ada-prj-subdirs-of
 238                                     (expand-file-name file-name))))))
 239   (ada-prj-display-page 2))
 240
 241 (defun ada-prj-display-page (tab-num)
 242   "Display page TAB-NUM in the notebook.
 243 The current buffer must be the project editing buffer."
 244
 245   (let ((inhibit-read-only t))
 246     (erase-buffer))
 247
 248   ;;  Widget support in Emacs 21 requires that we clear the buffer first
 249   (if (and (not (featurep 'xemacs)) (>= emacs-major-version 21))
 250       (progn
 251         (setq widget-field-new  nil
 252               widget-field-list nil)
 253         (mapc (lambda (x) (delete-overlay x)) (car (overlay-lists)))
 254         (mapc (lambda (x) (delete-overlay x)) (cdr (overlay-lists)))))
 255
 256   ;;  Display the tabs
 257
 258   (widget-insert "\n               Project configuration.\n
 259   ___________    ____________    ____________    ____________    ____________\n / ")
 260   (widget-create 'push-button :notify
 261                  (lambda (&rest dummy) (ada-prj-display-page 1)) "General")
 262   (widget-insert " \\  /   ")
 263   (widget-create 'push-button :notify
 264                  (lambda (&rest dummy) (ada-prj-display-page 2)) "Paths")
 265   (widget-insert "  \\  / ")
 266   (widget-create 'push-button :notify
 267                  (lambda (&rest dummy) (ada-prj-display-page 3)) "Switches")
 268   (widget-insert " \\  / ")
 269   (widget-create 'push-button :notify
 270                  (lambda (&rest dummy) (ada-prj-display-page 4)) "Ada Menu")
 271   (widget-insert " \\  / ")
 272   (widget-create 'push-button :notify
 273                  (lambda (&rest dummy) (ada-prj-display-page 5)) "Debugger")
 274   (widget-insert " \\\n")
 275
 276   ;;  Display the currently selected page
 277
 278   (cond
 279
 280    ;;
 281    ;;  First page (General)
 282    ;;
 283    ((= tab-num 1)
 284     (widget-insert "/             \\/______________\\/______________\\/______________\\/______________\\\n")
 285
 286     (widget-insert "Project file name:\n")
 287     (widget-insert (plist-get ada-prj-current-values 'filename))
 288     (widget-insert "\n\n")
 289     (ada-prj-field 'casing "Casing Exceptions"
 290 "List of files that contain casing exception
 291 dictionaries. All these files contain one
 292 identifier per line, with a special casing.
 293 The first file has the highest priority."
 294       t nil
 295       (mapconcat (lambda(x)
 296                    (concat "           " x))
 297                  (ada-xref-get-project-field 'casing)
 298                  "\n")
 299       )
 300     (ada-prj-field 'main "Executable file name"
 301 "Name of the executable generated when you
 302 compile your application. This should include
 303 the full directory name, using ${build_dir} if
 304 you wish.")
 305     (ada-prj-field 'build_dir  "Build directory"
 306                    "Reference directory for relative paths in
 307 src_dir and obj_dir below. This is also the directory
 308 where the compilation is done.")
 309     (ada-prj-field 'remote_machine "Name of the remote machine (if any)"
 310 "If you want to remotely compile, debug and
 311 run your application, specify the name of a
 312 remote machine here. This capability requires
 313 the 'rsh' protocol on the remote machine.")
 314     (ada-prj-field 'cross_prefix "Prefix used in for the cross tool chain"
 315 "When working on multiple cross targets, it is
 316 most convenient to specify the prefix of the
 317 tool chain here. For instance, on PowerPc
 318 vxworks, you would enter 'powerpc-wrs-vxworks-'.
 319 To use JGNAT, enter 'j'.")
 320     )
 321
 322
 323    ;;
 324    ;;  Second page (Paths)
 325    ;;
 326    ((= tab-num 2)
 327     (if (not (equal (plist-get ada-prj-current-values 'cross_prefix)
 328                     ada-old-cross-prefix))
 329         (progn
 330           (setq ada-old-cross-prefix
 331                 (plist-get ada-prj-current-values 'cross_prefix))
 332           (ada-initialize-runtime-library ada-old-cross-prefix)))
 333
 334
 335     (widget-insert "/_____________\\/              \\/______________\\/______________\\/______________\\\n")
 336     (ada-prj-field 'src_dir  "Source directories"
 337 "Enter the list of directories where your Ada
 338 sources can be found. These directories will be
 339 used for the cross-references and for the default
 340 compilation commands.
 341 Note that src_dir includes both the build directory
 342 and the standard runtime."
 343       t t
 344       (mapconcat (lambda(x)
 345                    (concat "           " x))
 346                  ada-xref-runtime-library-specs-path
 347                  "\n")
 348       )
 349     (widget-insert "\n\n")
 350
 351     (ada-prj-field 'obj_dir  "Object directories"
 352 "Enter the list of directories where the GNAT
 353 library files (ALI files) can be found. These
 354 files are used for cross-references and by the
 355 gnatmake command.
 356 Note that obj_dir includes both the build directory
 357 and the standard runtime."
 358       t t
 359       (mapconcat (lambda(x)
 360                    (concat "           " x))
 361                  ada-xref-runtime-library-ali-path
 362                  "\n")
 363       )
 364     (widget-insert "\n\n")
 365     )
 366
 367    ;;
 368    ;;  Third page (Switches)
 369    ;;
 370    ((= tab-num 3)
 371     (widget-insert "/_____________\\/______________\\/              \\/______________\\/______________\\\n")
 372     (ada-prj-field 'comp_opt "Switches for the compiler"
 373 "These switches are used in the default
 374 compilation commands, both for compiling a
 375 single file and rebuilding the whole project")
 376     (ada-prj-field 'bind_opt "Switches for the binder"
 377 "These switches are used in the default build
 378 command and are passed to the binder")
 379     (ada-prj-field 'link_opt "Switches for the linker"
 380 "These switches are used in the default build
 381 command and are passed to the linker")
 382     (ada-prj-field 'gnatmake_opt "Switches for gnatmake"
 383 "These switches are used in the default gnatmake
 384 command.")
 385     (ada-prj-field 'gnatfind_opt "Switches for gnatfind"
 386 "The command gnatfind is run every time the Ada/Goto/List_References menu.
 387 You should for instance add -a if you are working in an environment
 388 where most ALI files are write-protected, since otherwise they get
 389 ignored by gnatfind and you don't see the references within.")
 390     )
 391
 392    ;;
 393    ;;  Fourth page
 394    ;;
 395    ((= tab-num 4)
 396     (widget-insert "/_____________\\/______________\\/______________\\/              \\/______________\\\n")
 397     (widget-insert
 398 "All the fields below can use variable substitution. The syntax is ${name},
 399 where name is the name that appears after the Help buttons in this buffer. As
 400 a special case, ${current} is replaced with the name of the file currently
 401 edited, with directory name but no extension, whereas ${full_current} is
 402 replaced with the name of the current file with directory name and
 403 extension.\n")
 404     (widget-insert
 405 "The environment variables ADA_INCLUDE_PATH and ADA_OBJECTS_PATH are set to
 406 ${src_dir} and ${obj_dir} before running the compilation commands, so that you
 407 don't need to specify the -aI and -aO switches on the command line\n")
 408     (widget-insert
 409 "You can reference any environment variable using the same ${...} syntax as
 410 above, and put the name of the variable between the quotes.\n\n")
 411     (ada-prj-field 'check_cmd
 412       "Check syntax of a single file (menu Ada->Check File)"
 413 "This command is run to check the syntax and semantics of a file.
 414 The file name is added at the end of this command." t)
 415     (ada-prj-field 'comp_cmd
 416       "Compiling a single file (menu Ada->Compile File)"
 417 "This command is run when the recompilation
 418 of a single file is needed. The file name is
 419 added at the end of this command." t)
 420     (ada-prj-field 'make_cmd "Rebuilding the whole project (menu Ada->Build)"
 421 "This command is run when you want to rebuild
 422 your whole application. It is never issues
 423 automatically and you will need to ask for it.
 424 If remote_machine has been set, this command
 425 will be executed on the remote machine." t)
 426     (ada-prj-field 'run_cmd "Running the application (menu Ada->Run)"
 427 "This command specifies how to run the
 428 application, including any switch you need to
 429 specify. If remote_machine has been set, this
 430 command will be executed on the remote host." t)
 431     )
 432
 433    ;;
 434    ;;  Fifth page
 435    ;;
 436    ((= tab-num 5)
 437     (widget-insert "/_____________\\/______________\\/______________\\/______________\\/              \\\n")
 438     (ada-prj-field 'debug_pre_cmd "Commands to execute before launching the
 439 debugger"
 440 "The following commands are executed one after the other before starting
 441 the debugger. These can be used to set up your environment." t)
 442
 443     (ada-prj-field 'debug_cmd "Debugging the application"
 444 "Specifies how to debug the application, possibly
 445 remotely if remote_machine has been set. We
 446 recommend the following debuggers:
 447   > gdb
 448   > gvd --tty
 449   > ddd --tty -fullname -toolbar")
 450
 451     (ada-prj-field 'debug_post_cmd "Commands to execute in the debugger"
 452 "The following commands are executed one in the debugger once it has been
 453 started. These can be used to initialize the debugger, for instance to
 454 connect to the target when working with cross-environments" t)
 455     )
 456
 457    )
 458
 459
 460   (widget-insert "______________________________________________________________________\n\n       ")
 461   (widget-create 'push-button
 462                  :notify (lambda (&rest ignore)
 463                            (setq ada-prj-current-values (ada-default-prj-properties))
 464                            (ada-prj-display-page 1))
 465                  "Reset to Default Values")
 466   (widget-insert "         ")
 467   (widget-create 'push-button :notify (lambda (&rest ignore) (kill-buffer nil))
 468                  "Cancel")
 469   (widget-insert "         ")
 470   (widget-create 'push-button :notify (lambda (&rest ignore) (ada-prj-save))
 471                  "Save")
 472   (widget-insert "\n\n")
 473
 474   (widget-setup)
 475   (with-no-warnings
 476     (beginning-of-buffer))
 477   )
 478
 479
 480 (defun ada-customize (&optional new-file filename)
 481   "Edit the project file associated with the current buffer.
 482 If there is none or NEW-FILE is non-nil, make a new one.
 483 If FILENAME is given, edit that file."
 484   (interactive)
 485
 486   (let ((ada-buffer (current-buffer))
 487         (inhibit-read-only t))
 488
 489     ;;  We can only edit interactively the standard ada-mode project files. If
 490     ;;  the user is using other formats for the project file (through hooks in
 491     ;;  `ada-load-project-hook', we simply edit the file
 492
 493     (if (and (not new-file)
 494              (or ada-prj-default-project-file filename)
 495              (string= (file-name-extension
 496                        (or filename ada-prj-default-project-file))
 497                       "gpr"))
 498         (progn
 499           (find-file ada-prj-default-project-file)
 500           (add-hook 'after-save-hook 'ada-reread-prj-file t t)
 501           )
 502
 503       (if filename
 504           (ada-reread-prj-file filename)
 505         (if (not (string= ada-prj-default-project-file ""))
 506             (ada-reread-prj-file ada-prj-default-project-file)
 507           (ada-reread-prj-file)))
 508
 509       (switch-to-buffer "*Edit Ada Mode Project*")
 510
 511       (ada-prj-initialize-values 'ada-prj-current-values
 512                                  ada-buffer
 513                                  ada-prj-default-project-file)
 514
 515       (set (make-local-variable 'ada-prj-ada-buffer) ada-buffer)
 516
 517       (use-local-map (copy-keymap custom-mode-map))
 518       (local-set-key "\C-x\C-s" 'ada-prj-save)
 519
 520       (make-local-variable 'widget-keymap)
 521       (define-key widget-keymap "\C-x\C-s" 'ada-prj-save)
 522
 523       (set (make-local-variable 'ada-old-cross-prefix)
 524            (ada-xref-get-project-field 'cross-prefix))
 525
 526       (ada-prj-display-page 1)
 527       )))
 528
 529 ;; ---------------- Utilities --------------------------------
 530
 531 (defun ada-prj-set-list (string ada-list &optional is-directory)
 532   "Prepend STRING to strings in ADA-LIST, return new-line separated string.
 533 If IS-DIRECTORY is non-nil, each element of ADA-LIST is explicitly
 534 converted to a directory name."
 535
 536   (mapconcat (lambda (x) (concat string "="
 537                                  (if is-directory
 538                                      (file-name-as-directory x)
 539                                    x)))
 540              ada-list "\n"))
 541
 542
 543 (defun ada-prj-field-modified (widget &rest dummy)
 544   "Callback for modification of WIDGET.
 545 Remaining args DUMMY are ignored.
 546 Save the change in `ada-prj-current-values' so that selecting
 547 another page and coming back keeps the new value."
 548   (set 'ada-prj-current-values
 549        (plist-put ada-prj-current-values
 550                   (widget-get widget ':prj-field)
 551                   (widget-value widget))))
 552
 553 (defun ada-prj-display-help (widget widget-modified event)
 554   "Callback for help button in WIDGET.
 555 Parameters WIDGET-MODIFIED, EVENT match :notify for the widget."
 556   (let ((text (widget-get widget 'prj-help)))
 557     (if event
 558         ;;  If we have a mouse-event, popup a menu
 559         (widget-choose "Help"
 560                        (mapcar (lambda (a) (cons a t))
 561                                (split-string text "\n"))
 562                        event)
 563       ;;  Else display the help string just before the next group of
 564       ;;  variables
 565       (momentary-string-display
 566        (concat "*****Help*****\n" text "\n**************\n")
 567        (point-at-bol 2)))))
 568
 569 (defun ada-prj-show-value (widget widget-modified event)
 570   "Show the current field value in WIDGET.
 571 Parameters WIDGET-MODIFIED, EVENT match :notify for the widget."
 572   (let* ((field (widget-get widget ':prj-field))
 573          (value (plist-get ada-prj-current-values field))
 574          (inhibit-read-only t)
 575          w)
 576
 577     ;;  If the other widget is already visible, delete it
 578     (if (widget-get widget 'prj-other-widget)
 579         (progn
 580           (widget-delete (widget-get widget 'prj-other-widget))
 581           (widget-put widget 'prj-other-widget nil)
 582           (widget-put widget ':prj-field field)
 583           (widget-default-value-set widget "Show Value")
 584           )
 585
 586       ;;  Else create it
 587       (save-excursion
 588         (mouse-set-point event)
 589         (forward-line 1)
 590         (beginning-of-line)
 591         (setq w (widget-create 'editable-list
 592                                :entry-format "%i%d %v"
 593                                :notify 'ada-prj-field-modified
 594                                :help-echo (widget-get widget 'prj-help)
 595                                :value value
 596                                (list 'editable-field :keymap widget-keymap)))
 597         (widget-put widget 'prj-other-widget w)
 598         (widget-put w ':prj-field field)
 599         (widget-put widget ':prj-field field)
 600         (widget-default-value-set widget "Hide Value")
 601         )
 602       )
 603     (widget-setup)
 604     ))
 605
 606 (defun ada-prj-field (field text help-text &optional is-list is-paths after-text)
 607   "Create a widget to edit FIELD in the current buffer.
 608 TEXT is a short explanation of what the field means, whereas HELP-TEXT
 609 is the text displayed when the user pressed the help button.
 610 If IS-LIST is non-nil, the field contains a list.  Otherwise, it contains
 611 a single string.
 612 If IS-PATHS is true, some special buttons are added to load paths,...
 613 AFTER-TEXT is inserted just after the widget."
 614   (let ((value (plist-get ada-prj-current-values field))
 615         (inhibit-read-only t)
 616         widget)
 617     (unless value
 618       (set 'value
 619            (if is-list  '() "")))
 620     (widget-insert text)
 621     (widget-insert ":")
 622     (move-to-column 54 t)
 623     (widget-put (widget-create 'push-button
 624                                :notify 'ada-prj-display-help
 625                                "Help")
 626                 'prj-help
 627                 help-text)
 628     (widget-insert (concat "  (" (symbol-name field) ")\n"))
 629     (if is-paths
 630         (progn
 631           (widget-create 'push-button
 632                          :notify
 633                          (list 'lambda '(&rest dummy) '(interactive)
 634                                (list 'ada-prj-load-from-file
 635                                      (list 'quote field)))
 636                          "Load From File")
 637           (widget-insert "      ")
 638           (widget-create 'push-button
 639                          :notify
 640                          (list 'lambda '(&rest dummy) '(interactive)
 641                                (list 'ada-prj-load-directory
 642                                      (list 'quote field)))
 643                          "Load Recursive Directory")
 644           (widget-insert "\n           ${build_dir}\n")))
 645
 646     (set 'widget
 647          (if is-list
 648              (if (< (length value) 15)
 649                  (widget-create 'editable-list
 650                                 :entry-format "%i%d %v"
 651                                 :notify 'ada-prj-field-modified
 652                                 :help-echo help-text
 653                                 :value value
 654                                 (list 'editable-field :keymap widget-keymap))
 655
 656                (let ((w (widget-create 'push-button
 657                                        :notify 'ada-prj-show-value
 658                                        "Show value")))
 659                  (widget-insert "\n")
 660                  (widget-put w 'prj-help  help-text)
 661                  (widget-put w 'prj-other-widget nil)
 662                  w)
 663                )
 664            (widget-create 'editable-field
 665                           :format "%v"
 666                           :notify 'ada-prj-field-modified
 667                           :help-echo help-text
 668                           :keymap widget-keymap
 669                           value)))
 670     (widget-put widget ':prj-field field)
 671     (if after-text
 672         (widget-insert after-text))
 673     (widget-insert "\n")
 674     ))
 675
 676
 677 (provide 'ada-prj)
 678
 679 ;;; ada-prj.el ends here