lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
  11 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  33 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  34 ;; been removed or renamed in order to work properly with dired of GNU
  35 ;; Emacs.  All suggestions or comments are most welcomed.
  36
  37 ;;
  38 ;; Please, PLEASE, *PLEASE* see the info pages.
  39 ;;
  40
  41 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  42
  43 ;; INSTALLATION: In your ~/.emacs,
  44 ;;
  45 ;; (add-hook 'dired-load-hook
  46 ;;           (function (lambda ()
  47 ;;                       (load "dired-x")
  48 ;;                       ;; Set variables here.  For example:
  49 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  50 ;;                       ;; (dired-omit-mode 1)
  51 ;;                       )))
  52 ;;
  53 ;; At load time dired-x.el will install itself, redefine some functions, and
  54 ;; bind some dired keys.  *Please* see the info pages for more details.
  55
  56 ;; *Please* see the info pages for more details.
  57
  58 ;; User defined variables:
  59 ;;
  60 ;;      dired-bind-vm
  61 ;;      dired-vm-read-only-folders
  62 ;;      dired-bind-jump
  63 ;;      dired-bind-info
  64 ;;      dired-bind-man
  65 ;;      dired-x-hands-off-my-keys
  66 ;;      dired-find-subdir
  67 ;;      dired-enable-local-variables
  68 ;;      dired-local-variables-file
  69 ;;      dired-guess-shell-gnutar
  70 ;;      dired-guess-shell-gzip-quiet
  71 ;;      dired-guess-shell-znew-switches
  72 ;;      dired-guess-shell-alist-user
  73 ;;      dired-clean-up-buffers-too
  74 ;;      dired-omit-mode
  75 ;;      dired-omit-files
  76 ;;      dired-omit-extensions
  77 ;;      dired-omit-size-limit
  78 ;;
  79 ;; To find out more about these variables, load this file, put your cursor at
  80 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  81 ;; the info pages for more details.
  82
  83 ;; When loaded this code redefines the following functions of GNU Emacs
  84 ;;
  85 ;;   Function                         Found in this file of GNU Emacs
  86 ;;   --------                         -------------------------------
  87 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  88 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  89 ;;   dired-initial-position           ../lisp/dired.el
  90 ;;
  91 ;;   dired-add-entry                  ../lisp/dired-aux.el
  92 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  93
  94 \f
  95 ;;; Code:
  96
  97 ;; LOAD.
  98
  99 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 100 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 101 ;; (instead of autoloading to dired as is suggested in the info-pages).
 102
 103 (require 'dired)
 104
 105 ;; We will redefine some functions and also need some macros so we need to
 106 ;; load dired stuff of GNU Emacs.
 107
 108 (require 'dired-aux)
 109
 110 (defvar vm-folder-directory)
 111 (eval-when-compile (require 'man))
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 127 `dired-advertised-find-file', will run rmail."
 128   :type 'boolean
 129   :group 'dired-keys)
 130
 131 (defcustom dired-bind-jump t
 132   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 133   :type 'boolean
 134   :group 'dired-keys)
 135
 136 (defcustom dired-bind-man t
 137   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 138   :type 'boolean
 139   :group 'dired-keys)
 140
 141 (defcustom dired-bind-info t
 142   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 143   :type 'boolean
 144   :group 'dired-keys)
 145
 146 (defcustom dired-vm-read-only-folders nil
 147   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 148 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 149 files not writable by you are visited read-only.
 150
 151 Read-only folders only work in VM 5, not in VM 4."
 152   :type '(choice (const :tag "off" nil)
 153                  (const :tag "on" t)
 154                  (other :tag "non-writable only" if-file-read-only))
 155   :group 'dired-x)
 156
 157 (define-minor-mode dired-omit-mode
 158   "Toggle Dired-Omit mode.
 159 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 160 otherwise.  Enabling and disabling is buffer-local.
 161 If enabled, \"uninteresting\" files are not listed.
 162 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 163 plus those ending with extensions in `dired-omit-extensions'."
 164   :group 'dired-x
 165   (if dired-omit-mode
 166       ;; This will mention how many lines were omitted:
 167       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 168     (revert-buffer)))
 169
 170 ;; For backward compatibility
 171 (defvaralias 'dired-omit-files-p 'dired-omit-mode)
 172 (make-obsolete-variable 'dired-omit-files-p 'dired-omit-mode)
 173
 174 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 175   "*Filenames matching this regexp will not be displayed.
 176 This only has effect when `dired-omit-mode' is t.  See interactive function
 177 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 178 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 179 files and lock files."
 180   :type 'regexp
 181   :group 'dired-x)
 182
 183 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 184   "*If non-nil, Dired always finds a directory in a buffer of its own.
 185 If nil, Dired finds the directory as a subdirectory in some other buffer
 186 if it is present as one.
 187
 188 If there are several dired buffers for a directory, the most recently
 189 used is chosen.
 190
 191 Dired avoids switching to the current buffer, so that if you have
 192 a normal and a wildcard buffer for the same directory, \\[dired] will
 193 toggle between those two."
 194   :type 'boolean
 195   :group 'dired-x)
 196
 197 (defcustom dired-omit-size-limit 30000
 198   "*Maximum size for the \"omitting\" feature.
 199 If nil, there is no maximum size."
 200   :type '(choice (const :tag "no maximum" nil) integer)
 201   :group 'dired-x)
 202
 203 (defcustom dired-enable-local-variables t
 204   "*Control use of local-variables lists in Dired.
 205 The value can be t, nil or something else.
 206 A value of t means local-variables lists are obeyed;
 207 nil means they are ignored; anything else means query.
 208
 209 This temporarily overrides the value of `enable-local-variables' when listing
 210 a directory.  See also `dired-local-variables-file'."
 211   :type 'boolean
 212   :group 'dired-x)
 213
 214 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 215                                               (eq system-type 'gnu/linux))
 216                                       "tar")
 217   "*If non-nil, name of GNU tar executable.
 218 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 219 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 220 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 221   :type '(choice (const :tag "Not GNU tar" nil)
 222                  (string :tag "Command name"))
 223   :group 'dired-x)
 224
 225 (defcustom dired-guess-shell-gzip-quiet t
 226   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 227   :type 'boolean
 228   :group 'dired-x)
 229
 230 (defcustom dired-guess-shell-znew-switches nil
 231   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 232   :type '(choice (const :tag "None" nil)
 233                  (string :tag "Switches"))
 234   :group 'dired-x)
 235
 236 (defcustom dired-clean-up-buffers-too t
 237   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 238   :type 'boolean
 239   :group 'dired-x)
 240
 241 ;;; KEY BINDINGS.
 242
 243 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 244 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 245 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 246 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*." 'dired-mark-extension)
 248 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 249 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 250 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 251 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 252 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 253 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 254 (define-key dired-mode-map "V" 'dired-do-run-mail)
 255
 256 (if dired-bind-man
 257     (define-key dired-mode-map "N" 'dired-man))
 258
 259 (if dired-bind-info
 260     (define-key dired-mode-map "I" 'dired-info))
 261
 262 ;;; MENU BINDINGS
 263
 264 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 265   (let ((menu (lookup-key menu-bar [operate])))
 266     (define-key-after
 267       menu
 268       [find-files]
 269       '(menu-item
 270         "Find files"
 271         dired-do-find-marked-files
 272         :help "Find current or marked files")
 273       'delete)
 274     (define-key-after
 275       menu
 276       [relsymlink]
 277       '(menu-item
 278         "Relative symlink to..."
 279         dired-do-relsymlink
 280         :visible (fboundp 'make-symbolic-link)
 281         :help "Make relative symbolic links for current or marked files")
 282       'symlink))
 283   (let ((menu (lookup-key menu-bar [mark])))
 284     (define-key-after
 285       menu
 286       [flag-extension]
 287       '(menu-item
 288         "Flag extension..."
 289         dired-flag-extension
 290         :help "Flag files with a certain extension for deletion")
 291       'garbage-files)
 292     (define-key-after
 293       menu
 294       [mark-extension]
 295       '(menu-item
 296         "Mark extension..."
 297         dired-mark-extension
 298         :help "Mark files with a certain extension")
 299       'symlinks)
 300     (define-key-after
 301       menu
 302       [mark-omitted]
 303       '(menu-item
 304         "Mark omitted"
 305         dired-mark-omitted
 306         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 307       'mark-extension))
 308   (let ((menu (lookup-key menu-bar [regexp])))
 309     (define-key-after
 310       menu
 311       [relsymlink-regexp]
 312       '(menu-item
 313         "Relative symlink..."
 314         dired-do-relsymlink-regexp
 315         :visible (fboundp 'make-symbolic-link)
 316         :help "Make relative symbolic links for files matching regexp")
 317       'symlink))
 318   (let ((menu (lookup-key menu-bar [immediate])))
 319     (define-key-after
 320       menu
 321       [omit-mode]
 322       '(menu-item
 323         "Omit mode" dired-omit-mode
 324         :button (:toggle . dired-omit-mode)
 325         :help "Enable or disable omitting \"uninteresting\" files")
 326       'dashes)))
 327
 328 ;;; GLOBAL BINDING.
 329 (if dired-bind-jump
 330     (progn
 331       (define-key global-map "\C-x\C-j" 'dired-jump)
 332       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 333
 334 \f
 335 ;;; Install into appropriate hooks.
 336
 337 (add-hook 'dired-mode-hook 'dired-extra-startup)
 338 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 339
 340 (defun dired-extra-startup ()
 341   "Automatically put on `dired-mode-hook' to get extra Dired features:
 342 \\<dired-mode-map>
 343   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 344   \\[dired-info]\t-- run info on file
 345   \\[dired-man]\t-- run man on file
 346   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 347   \\[dired-omit-mode]\t-- toggle omitting of files
 348   \\[dired-mark-sexp]\t-- mark by Lisp expression
 349   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 350   \t   you can feed it to other commands using \\[yank]
 351
 352 For more features, see variables
 353
 354   `dired-bind-vm'
 355   `dired-bind-jump'
 356   `dired-bind-info'
 357   `dired-bind-man'
 358   `dired-vm-read-only-folders'
 359   `dired-omit-mode'
 360   `dired-omit-files'
 361   `dired-omit-extensions'
 362   `dired-omit-size-limit'
 363   `dired-find-subdir'
 364   `dired-enable-local-variables'
 365   `dired-local-variables-file'
 366   `dired-guess-shell-gnutar'
 367   `dired-guess-shell-gzip-quiet'
 368   `dired-guess-shell-znew-switches'
 369   `dired-guess-shell-alist-user'
 370   `dired-clean-up-buffers-too'
 371
 372 See also functions
 373
 374   `dired-flag-extension'
 375   `dired-virtual'
 376   `dired-jump'
 377   `dired-man'
 378   `dired-vm'
 379   `dired-rmail'
 380   `dired-info'
 381   `dired-do-find-marked-files'"
 382   (interactive)
 383
 384   ;; These must be done in each new dired buffer.
 385   (dired-hack-local-variables)
 386   (dired-omit-startup))
 387
 388 \f
 389 ;;; BUFFER CLEANING.
 390
 391 ;; REDEFINE.
 392 (defun dired-clean-up-after-deletion (fn)
 393   "Clean up after a deleted file or directory FN.
 394 Remove expanded subdir of deleted dir, if any."
 395   (save-excursion (and (cdr dired-subdir-alist)
 396                        (dired-goto-subdir fn)
 397                        (dired-kill-subdir)))
 398
 399   ;; Offer to kill buffer of deleted file FN.
 400   (if dired-clean-up-buffers-too
 401       (progn
 402         (let ((buf (get-file-buffer fn)))
 403           (and buf
 404                (funcall (function y-or-n-p)
 405                         (format "Kill buffer of %s, too? "
 406                                 (file-name-nondirectory fn)))
 407                (save-excursion ; you never know where kill-buffer leaves you
 408                  (kill-buffer buf))))
 409         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 410               (buf nil))
 411           (and buf-list
 412                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 413                                  (dired-plural-s (length buf-list))
 414                                  (file-name-nondirectory fn)))
 415                (while buf-list
 416                  (save-excursion (kill-buffer (car buf-list)))
 417                  (setq buf-list (cdr buf-list)))))))
 418   ;; Anything else?
 419   )
 420
 421 \f
 422 ;;; EXTENSION MARKING FUNCTIONS.
 423
 424 ;;; Mark files with some extension.
 425 (defun dired-mark-extension (extension &optional marker-char)
 426   "Mark all files with a certain EXTENSION for use in later commands.
 427 A `.' is *not* automatically prepended to the string entered."
 428   ;; EXTENSION may also be a list of extensions instead of a single one.
 429   ;; Optional MARKER-CHAR is marker to use.
 430   (interactive "sMarking extension: \nP")
 431   (or (listp extension)
 432       (setq extension (list extension)))
 433   (dired-mark-files-regexp
 434    (concat ".";; don't match names with nothing but an extension
 435            "\\("
 436            (mapconcat 'regexp-quote extension "\\|")
 437            "\\)$")
 438    marker-char))
 439
 440 (defun dired-flag-extension (extension)
 441   "In dired, flag all files with a certain EXTENSION for deletion.
 442 A `.' is *not* automatically prepended to the string entered."
 443   (interactive "sFlagging extension: ")
 444   (dired-mark-extension extension dired-del-marker))
 445
 446 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 447
 448 (defvar dired-patch-unclean-extensions
 449   '(".rej" ".orig")
 450   "List of extensions of dispensable files created by the `patch' program.")
 451
 452 (defvar dired-tex-unclean-extensions
 453   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 454   "List of extensions of dispensable files created by TeX.")
 455
 456 (defvar dired-latex-unclean-extensions
 457   '(".idx" ".lof" ".lot" ".glo")
 458   "List of extensions of dispensable files created by LaTeX.")
 459
 460 (defvar dired-bibtex-unclean-extensions
 461   '(".blg" ".bbl")
 462   "List of extensions of dispensable files created by BibTeX.")
 463
 464 (defvar dired-texinfo-unclean-extensions
 465   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 466     ".tp" ".tps" ".vr" ".vrs")
 467   "List of extensions of dispensable files created by texinfo.")
 468
 469 (defun dired-clean-patch ()
 470   "Flag dispensable files created by patch for deletion.
 471 See variable `dired-patch-unclean-extensions'."
 472   (interactive)
 473   (dired-flag-extension dired-patch-unclean-extensions))
 474
 475 (defun dired-clean-tex ()
 476   "Flag dispensable files created by [La]TeX etc. for deletion.
 477 See variables `dired-tex-unclean-extensions',
 478 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 479 `dired-texinfo-unclean-extensions'."
 480   (interactive)
 481   (dired-flag-extension (append dired-texinfo-unclean-extensions
 482                                 dired-latex-unclean-extensions
 483                                 dired-bibtex-unclean-extensions
 484                                 dired-tex-unclean-extensions)))
 485
 486 (defun dired-very-clean-tex ()
 487   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 488 See variables `dired-texinfo-unclean-extensions',
 489 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 490 `dired-texinfo-unclean-extensions'."
 491   (interactive)
 492   (dired-flag-extension (append dired-texinfo-unclean-extensions
 493                                 dired-latex-unclean-extensions
 494                                 dired-bibtex-unclean-extensions
 495                                 dired-tex-unclean-extensions
 496                                 (list ".dvi"))))
 497 \f
 498 ;;; JUMP.
 499
 500 ;;;###autoload
 501 (defun dired-jump (&optional other-window)
 502   "Jump to dired buffer corresponding to current buffer.
 503 If in a file, dired the current directory and move to file's line.
 504 If in Dired already, pop up a level and goto old directory's line.
 505 In case the proper dired file line cannot be found, refresh the dired
 506 buffer and try again."
 507   (interactive "P")
 508   (let* ((file buffer-file-name)
 509          (dir (if file (file-name-directory file) default-directory)))
 510     (if (eq major-mode 'dired-mode)
 511         (progn
 512           (setq dir (dired-current-directory))
 513           (dired-up-directory other-window)
 514           (or (dired-goto-file dir)
 515               ;; refresh and try again
 516               (progn
 517                 (dired-insert-subdir (file-name-directory dir))
 518                 (dired-goto-file dir))))
 519       (if other-window
 520           (dired-other-window dir)
 521         (dired dir))
 522       (if file
 523           (or (dired-goto-file file)
 524               ;; refresh and try again
 525               (progn
 526                 (dired-insert-subdir (file-name-directory file))
 527                 (dired-goto-file file))
 528               ;; Toggle omitting, if it is on, and try again.
 529               (if dired-omit-mode
 530                   (progn
 531                     (dired-omit-mode)
 532                     (dired-goto-file file))))))))
 533
 534 (defun dired-jump-other-window ()
 535   "Like \\[dired-jump] (`dired-jump') but in other window."
 536   (interactive)
 537   (dired-jump t))
 538 \f
 539 ;;; OMITTING.
 540
 541 ;;; Enhanced omitting of lines from directory listings.
 542 ;;; Marked files are never omitted.
 543
 544 ;; should probably get rid of this and always use 'no-dir.
 545 ;; sk 28-Aug-1991 09:37
 546 (defvar dired-omit-localp 'no-dir
 547   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 548 If it is `no-dir', omitting is much faster, but you can only match
 549 against the non-directory part of the file name.  Set it to nil if you
 550 need to match the entire file name.")
 551
 552 ;; \017=^O for Omit - other packages can chose other control characters.
 553 (defvar dired-omit-marker-char ?\017
 554   "Temporary marker used by dired-omit.
 555 Should never be used as marker by the user or other packages.")
 556
 557 (defun dired-omit-startup ()
 558   (or (assq 'dired-omit-mode minor-mode-alist)
 559       (setq minor-mode-alist
 560             (append '((dired-omit-mode
 561                        (:eval (if (eq major-mode 'dired-mode)
 562                                   " Omit" ""))))
 563                     minor-mode-alist))))
 564
 565 (defun dired-mark-omitted ()
 566   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 567   (interactive)
 568   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 569   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 570
 571 (defvar dired-omit-extensions
 572   (append completion-ignored-extensions
 573           dired-latex-unclean-extensions
 574           dired-bibtex-unclean-extensions
 575           dired-texinfo-unclean-extensions)
 576   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 577 Defaults to elements of `completion-ignored-extensions',
 578 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 579 `dired-texinfo-unclean-extensions'.
 580
 581 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 582 variables `dired-omit-mode' and `dired-omit-files'.")
 583
 584 (defun dired-omit-expunge (&optional regexp)
 585   "Erases all unmarked files matching REGEXP.
 586 Does nothing if global variable `dired-omit-mode' is nil, or if called
 587   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 588 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 589   filenames ending in `dired-omit-extensions'.
 590 If REGEXP is the empty string, this function is a no-op.
 591
 592 This functions works by temporarily binding `dired-marker-char' to
 593 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 594   (interactive "sOmit files (regexp): ")
 595   (if (and dired-omit-mode
 596            (or (interactive-p)
 597                (not dired-omit-size-limit)
 598                (< (buffer-size) dired-omit-size-limit)
 599                (progn
 600                  (message "Not omitting: directory larger than %d characters."
 601                           dired-omit-size-limit)
 602                  (setq dired-omit-mode nil)
 603                  nil)))
 604       (let ((omit-re (or regexp (dired-omit-regexp)))
 605             (old-modified-p (buffer-modified-p))
 606             count)
 607         (or (string= omit-re "")
 608             (let ((dired-marker-char dired-omit-marker-char))
 609               (message "Omitting...")
 610               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 611                   (progn
 612                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 613                     (force-mode-line-update))
 614                 (message "(Nothing to omit)"))))
 615         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 616         ;; in mode-line of omitted buffers.
 617         (set-buffer-modified-p (and old-modified-p
 618                                     (save-excursion
 619                                       (goto-char (point-min))
 620                                       (re-search-forward dired-re-mark nil t))))
 621         count)))
 622
 623 (defun dired-omit-regexp ()
 624   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 625           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 626           (if dired-omit-extensions
 627               (concat ".";; a non-extension part should exist
 628                       "\\("
 629                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 630                       "\\)$")
 631             "")))
 632
 633 ;; Returns t if any work was done, nil otherwise.
 634 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 635   "Mark unmarked files matching REGEXP, displaying MSG.
 636 REGEXP is matched against the entire file name.
 637 Does not re-mark files which already have a mark.
 638 With prefix argument, unflag all those files.
 639 Optional fourth argument LOCALP is as in `dired-get-filename'."
 640   (interactive "P")
 641   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 642     (dired-mark-if
 643      (and
 644       ;; not already marked
 645       (looking-at " ")
 646       ;; uninteresting
 647       (let ((fn (dired-get-filename localp t)))
 648         (and fn (string-match regexp fn))))
 649      msg)))
 650
 651 ;;; REDEFINE.
 652 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 653   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 654   ;; files that are going to be omitted anyway.
 655   (if dired-omit-mode
 656       ;; perhaps return t without calling ls
 657       (let ((omit-re (dired-omit-regexp)))
 658         (if (or (string= omit-re "")
 659                 (not
 660                  (string-match omit-re
 661                                (cond
 662                                 ((eq 'no-dir dired-omit-localp)
 663                                  filename)
 664                                 ((eq t dired-omit-localp)
 665                                  (dired-make-relative filename))
 666                                 (t
 667                                  (dired-make-absolute
 668                                   filename
 669                                   (file-name-directory filename)))))))
 670             ;; if it didn't match, go ahead and add the entry
 671             (dired-omit-old-add-entry filename marker-char relative)
 672           ;; dired-add-entry returns t for success, perhaps we should
 673           ;; return file-exists-p
 674           t))
 675     ;; omitting is not turned on at all
 676     (dired-omit-old-add-entry filename marker-char relative)))
 677
 678 ;;; REDEFINE.
 679 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 680 ;;; Save old defun if not already done:
 681 (or (fboundp 'dired-omit-old-add-entry)
 682     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 683 ;; Redefine it.
 684 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 685
 686 \f
 687 ;;; VIRTUAL DIRED MODE.
 688
 689 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 690
 691 (defalias 'virtual-dired 'dired-virtual)
 692 (defun dired-virtual (dirname &optional switches)
 693   "Put this buffer into Virtual Dired mode.
 694
 695 In Virtual Dired mode, all commands that do not actually consult the
 696 filesystem will work.
 697
 698 This is useful if you want to peruse and move around in an ls -lR
 699 output file, for example one you got from an ftp server.  With
 700 ange-ftp, you can even dired a directory containing an ls-lR file,
 701 visit that file and turn on virtual dired mode.  But don't try to save
 702 this file, as dired-virtual indents the listing and thus changes the
 703 buffer.
 704
 705 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 706 resume it in a later session.
 707
 708 Type \\<dired-mode-map>\\[revert-buffer] \
 709 in the Virtual Dired buffer and answer `y' to convert
 710 the virtual to a real dired buffer again.  You don't have to do this, though:
 711 you can relist single subdirs using \\[dired-do-redisplay]."
 712
 713   ;; DIRNAME is the top level directory of the buffer.  It will become
 714   ;; its `default-directory'.  If nil, the old value of
 715   ;; default-directory is used.
 716
 717   ;; Optional SWITCHES are the ls switches to use.
 718
 719   ;; Shell wildcards will be used if there already is a `wildcard'
 720   ;; line in the buffer (thus it is a saved Dired buffer), but there
 721   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 722   ;; hand if you want them.
 723
 724   (interactive
 725    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 726   (goto-char (point-min))
 727   (or (looking-at "  ")
 728       ;; if not already indented, do it now:
 729       (indent-region (point-min) (point-max) 2))
 730   (or dirname (setq dirname default-directory))
 731   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 732   (setq default-directory dirname)      ; contains no wildcards
 733   (let ((wildcard (save-excursion
 734                     (goto-char (point-min))
 735                     (forward-line 1)
 736                     (and (looking-at "^  wildcard ")
 737                          (buffer-substring (match-end 0)
 738                                            (progn (end-of-line) (point)))))))
 739   (if wildcard
 740         (setq dirname (expand-file-name wildcard default-directory))))
 741   ;; If raw ls listing (not a saved old dired buffer), give it a
 742   ;; decent subdir headerline:
 743   (goto-char (point-min))
 744   (or (looking-at dired-subdir-regexp)
 745       (insert "  "
 746               (directory-file-name (file-name-directory default-directory))
 747               ":\n"))
 748   (dired-mode dirname (or switches dired-listing-switches))
 749   (setq mode-name "Virtual Dired"
 750         revert-buffer-function 'dired-virtual-revert)
 751   (set (make-local-variable 'dired-subdir-alist) nil)
 752   (dired-build-subdir-alist)
 753   (goto-char (point-min))
 754   (dired-initial-position dirname))
 755
 756 (defun dired-virtual-guess-dir ()
 757   "Guess and return appropriate working directory of this buffer.
 758 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 759 based upon buffer contents.  If nothing could be guessed, returns
 760 nil."
 761
 762   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 763         (subexpr 2))
 764     (goto-char (point-min))
 765     (cond ((looking-at regexp)
 766            ;; If a saved dired buffer, look to which dir and
 767            ;; perhaps wildcard it belongs:
 768            (let ((dir (buffer-substring (match-beginning subexpr)
 769                                         (match-end subexpr))))
 770              (file-name-as-directory dir)))
 771           ;; Else no match for headerline found.  It's a raw ls listing.
 772           ;; In raw ls listings the directory does not have a headerline
 773           ;; try parent of first subdir, if any
 774           ((re-search-forward regexp nil t)
 775            (file-name-directory
 776             (directory-file-name
 777              (file-name-as-directory
 778               (buffer-substring (match-beginning subexpr)
 779                                 (match-end subexpr))))))
 780           (t                            ; if all else fails
 781            nil))))
 782
 783
 784 (defun dired-virtual-revert (&optional arg noconfirm)
 785   (if (not
 786        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 787       (error "Cannot revert a Virtual Dired buffer")
 788     (setq mode-name "Dired"
 789           revert-buffer-function 'dired-revert)
 790     (revert-buffer)))
 791
 792 ;; A zero-arg version of dired-virtual.
 793 ;; You need my modified version of set-auto-mode for the
 794 ;; `buffer-contents-mode-alist'.
 795 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 796 (defun dired-virtual-mode ()
 797   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 798 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 799
 800     \"^  \\(/[^ /]+\\)/?+:$\"
 801
 802 to put saved dired buffers automatically into Virtual Dired mode.
 803
 804 Also useful for `auto-mode-alist' (which see) like this:
 805
 806   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 807                               auto-mode-alist)\)"
 808   (interactive)
 809   (dired-virtual (dired-virtual-guess-dir)))
 810
 811 \f
 812 ;;; SMART SHELL.
 813
 814 ;;; An Emacs buffer can have but one working directory, stored in the
 815 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 816 ;;; several subdirectories inserted, but still has but one working directory:
 817 ;;; that of the top level Dired directory in that buffer.  For some commands
 818 ;;; it is appropriate that they use the current Dired directory instead of
 819 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 820 ;;; mechanism is provided for special handling of the working directory in
 821 ;;; special major modes.
 822
 823 ;; It's easier to add to this alist than redefine function
 824 ;; default-directory while keeping the old information.
 825 (defconst default-directory-alist
 826   '((dired-mode . (if (fboundp 'dired-current-directory)
 827                       (dired-current-directory)
 828                     default-directory)))
 829   "Alist of major modes and their opinion on `default-directory'.
 830 This is given as a Lisp expression to evaluate.  A resulting value of
 831 nil is ignored in favor of `default-directory'.")
 832
 833 (defun dired-default-directory ()
 834   "Usage like variable `default-directory'.
 835 Knows about the special cases in variable `default-directory-alist'."
 836   (or (eval (cdr (assq major-mode default-directory-alist)))
 837       default-directory))
 838
 839 (defun dired-smart-shell-command (cmd &optional insert)
 840   "Like function `shell-command', but in the current Virtual Dired directory."
 841   (interactive (list (read-from-minibuffer "Shell command: "
 842                                            nil nil nil 'shell-command-history)
 843                      current-prefix-arg))
 844   (let ((default-directory (dired-default-directory)))
 845     (shell-command cmd insert)))
 846
 847 \f
 848 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 849
 850 ;;; Brief Description:
 851 ;;;
 852 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 853 ;;;
 854 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 855 ;;;
 856 ;;; * `dired-hack-local-variables' checks the value of
 857 ;;;   `dired-local-variables-file'
 858 ;;;
 859 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 860 ;;;   filename found in the directory of the Dired Buffer being created.
 861 ;;;
 862 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 863 ;;;   include it in the Dired Buffer at the bottom.
 864 ;;;
 865 ;;; * Set `enable-local-variables' temporarily to the user variable
 866 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 867 ;;;   Dired Buffer.
 868
 869 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 870   "Filename, as string, containing local dired buffer variables to be hacked.
 871 If this file found in current directory, then it will be inserted into dired
 872 buffer and `hack-local-variables' will be run.  See Info node
 873 `(emacs)File Variables' for more information on local variables.
 874 See also `dired-enable-local-variables'.")
 875
 876 (defun dired-hack-local-variables ()
 877   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 878   (if (and dired-local-variables-file
 879            (stringp dired-local-variables-file)
 880            (file-exists-p dired-local-variables-file))
 881       (let ((opoint (point-max))
 882             buffer-read-only
 883             ;; In case user has `enable-local-variables' set to nil we
 884             ;; override it locally with dired's variable.
 885             (enable-local-variables dired-enable-local-variables))
 886         ;; Insert 'em.
 887         (save-excursion
 888           (goto-char opoint)
 889           (insert "\^L\n")
 890           (insert-file-contents dired-local-variables-file))
 891         ;; Hack 'em.
 892         (let ((buffer-file-name dired-local-variables-file))
 893           (hack-local-variables))
 894         ;; Make sure that the modeline shows the proper information.
 895         (dired-sort-set-modeline)
 896         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 897         (delete-region opoint (point-max)))))
 898
 899 (defun dired-omit-here-always ()
 900   "Create `dired-local-variables-file' for omitting and reverts directory.
 901 Sets `dired-omit-mode' to t in a local variables file that is readable by
 902 dired."
 903   (interactive)
 904   (if (file-exists-p dired-local-variables-file)
 905       (message "File `./%s' already exists." dired-local-variables-file)
 906
 907     ;; Create `dired-local-variables-file'.
 908     (save-excursion
 909       (set-buffer (get-buffer-create " *dot-dired*"))
 910       (erase-buffer)
 911       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 912       (write-file dired-local-variables-file)
 913       (kill-buffer (current-buffer)))
 914
 915     ;; Run extra-hooks and revert directory.
 916     (dired-extra-startup)
 917     (dired-revert)))
 918
 919 \f
 920 ;;; GUESS SHELL COMMAND.
 921
 922 ;;; Brief Description:
 923 ;;;
 924 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 925 ;;;
 926 ;;; * Redefine `dired-do-shell-command' so it calls
 927 ;;;   `dired-guess-shell-command'.
 928 ;;;
 929 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 930 ;;;    marked files.
 931 ;;;
 932 ;;; * Parse `dired-guess-shell-alist-user' and
 933 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 934 ;;;   that matches the first file in the file list.
 935 ;;;
 936 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 937 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 938 ;;;   string.  COMMAND may be a list of commands.
 939 ;;;
 940 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 941 ;;;   with it.  The list of commands is temporarily put into the history list.
 942 ;;;   If a command is used successfully then it is stored permanently in
 943 ;;;   `dired-shell-command-history'.
 944
 945 ;;; Guess what shell command to apply to a file.
 946 (defvar dired-shell-command-history nil
 947   "History list for commands that read dired-shell commands.")
 948
 949 ;;; Default list of shell commands.
 950
 951 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 952 ;;; install GNU zip's version of zcat.
 953
 954 (defvar dired-guess-shell-alist-default
 955   (list
 956    (list "\\.tar$"
 957          '(if dired-guess-shell-gnutar
 958               (concat dired-guess-shell-gnutar " xvf")
 959             "tar xvf")
 960          ;; Extract files into a separate subdirectory
 961          '(if dired-guess-shell-gnutar
 962               (concat "mkdir " (file-name-sans-extension file)
 963                       "; " dired-guess-shell-gnutar " -C "
 964                       (file-name-sans-extension file) " -xvf")
 965             (concat "mkdir " (file-name-sans-extension file)
 966                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 967          ;; List archive contents.
 968          '(if dired-guess-shell-gnutar
 969               (concat dired-guess-shell-gnutar " tvf")
 970             "tar tvf"))
 971
 972    ;; REGEXPS for compressed archives must come before the .Z rule to
 973    ;; be recognized:
 974    (list "\\.tar\\.Z$"
 975          ;; Untar it.
 976          '(if dired-guess-shell-gnutar
 977               (concat dired-guess-shell-gnutar " zxvf")
 978             (concat "zcat * | tar xvf -"))
 979          ;; Optional conversion to gzip format.
 980          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 981                   " " dired-guess-shell-znew-switches))
 982
 983    ;; gzip'ed archives
 984    (list "\\.t\\(ar\\.\\)?gz$"
 985          '(if dired-guess-shell-gnutar
 986               (concat dired-guess-shell-gnutar " zxvf")
 987             (concat "gunzip -qc * | tar xvf -"))
 988          ;; Extract files into a separate subdirectory
 989          '(if dired-guess-shell-gnutar
 990               (concat "mkdir " (file-name-sans-extension file)
 991                       "; " dired-guess-shell-gnutar " -C "
 992                       (file-name-sans-extension file) " -zxvf")
 993             (concat "mkdir " (file-name-sans-extension file)
 994                     "; gunzip -qc * | tar -C "
 995                     (file-name-sans-extension file) " -xvf -"))
 996          ;; Optional decompression.
 997          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 998          ;; List archive contents.
 999          '(if dired-guess-shell-gnutar
1000               (concat dired-guess-shell-gnutar " ztvf")
1001             (concat "gunzip -qc * | tar tvf -")))
1002
1003    ;; bzip2'ed archives
1004    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1005          "bunzip2 -c * | tar xvf -"
1006          ;; Extract files into a separate subdirectory
1007          '(concat "mkdir " (file-name-sans-extension file)
1008                   "; bunzip2 -c * | tar -C "
1009                   (file-name-sans-extension file) " -xvf -")
1010          ;; Optional decompression.
1011          "bunzip2")
1012
1013    '("\\.shar\\.Z$" "zcat * | unshar")
1014    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1015
1016    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1017    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1018          ;; Optional decompression.
1019          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1020    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1021          ;; Optional conversion to gzip format.
1022          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1023                   " " dired-guess-shell-znew-switches))
1024
1025    '("\\.patch$" "cat * | patch")
1026    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1027          ;; Optional decompression.
1028          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1029    (list "\\.patch\\.Z$" "zcat * | patch"
1030          ;; Optional conversion to gzip format.
1031          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1032                   " " dired-guess-shell-znew-switches))
1033
1034    ;; The following four extensions are useful with dired-man ("N" key)
1035    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1036                                            (if (Man-support-local-filenames)
1037                                                "man -l"
1038                                              "cat * | tbl | nroff -man -h")))
1039    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1040                                                  (if (Man-support-local-filenames)
1041                                                      "man -l"
1042                                                    "gunzip -qc * | tbl | nroff -man -h"))
1043          ;; Optional decompression.
1044          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1045    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1046                                  (if (Man-support-local-filenames)
1047                                      "man -l"
1048                                    "zcat * | tbl | nroff -man -h"))
1049          ;; Optional conversion to gzip format.
1050          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1051                   " " dired-guess-shell-znew-switches))
1052    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1053
1054    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1055    '("\\.au$" "play")                   ; play Sun audiofiles
1056    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1057    '("\\.wav$" "play")
1058    '("\\.uu$" "uudecode")               ; for uudecoded files
1059    '("\\.hqx$" "mcvert")
1060    '("\\.sh$" "sh")                     ; execute shell scripts
1061    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1062    '("\\.gp$" "gnuplot")
1063    '("\\.p[bgpn]m$" "xloadimage")
1064    '("\\.gif$" "xloadimage")            ; view gif pictures
1065    '("\\.tif$" "xloadimage")
1066    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1067    '("\\.jpe?g$" "xloadimage")
1068    '("\\.fig$" "xfig")                  ; edit fig pictures
1069    '("\\.out$" "xgraph")                ; for plotting purposes.
1070    '("\\.tex$" "latex" "tex")
1071    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1072    '("\\.pdf$" "xpdf")
1073    '("\\.doc$" "antiword" "strings")
1074    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1075    '("\\.dia$" "dia")
1076    '("\\.mgp$" "mgp")
1077
1078    ;; Some other popular archivers.
1079    (list "\\.zip$" "unzip" "unzip -l"
1080          ;; Extract files into a separate subdirectory
1081          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1082                   " -d " (file-name-sans-extension file)))
1083    '("\\.zoo$" "zoo x//")
1084    '("\\.lzh$" "lharc x")
1085    '("\\.arc$" "arc x")
1086    '("\\.shar$" "unshar")
1087
1088    ;; Compression.
1089    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1090    (list "\\.dz$" "dictunzip")
1091    (list "\\.bz2$" "bunzip2")
1092    (list "\\.Z$" "uncompress"
1093          ;; Optional conversion to gzip format.
1094          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1095                   " " dired-guess-shell-znew-switches))
1096
1097    '("\\.sign?$" "gpg --verify"))
1098
1099   "Default alist used for shell command guessing.
1100 See `dired-guess-shell-alist-user'.")
1101
1102 (defcustom dired-guess-shell-alist-user nil
1103   "User-defined alist of rules for suggested commands.
1104 These rules take precedence over the predefined rules in the variable
1105 `dired-guess-shell-alist-default' (to which they are prepended).
1106
1107 Each element of this list looks like
1108
1109     \(REGEXP COMMAND...\)
1110
1111 where each COMMAND can either be a string or a Lisp expression that evaluates
1112 to a string.  If several COMMANDs are given, the first one will be the default
1113 and the rest will be added temporarily to the history and can be retrieved
1114 with \\[previous-history-element] (M-p) .
1115
1116 You can set this variable in your ~/.emacs.  For example, to add rules for
1117 `.foo' and `.bar' files, write
1118
1119  \(setq dired-guess-shell-alist-user
1120        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1121               ;; possibly more rules ...
1122               (list \"\\\\.bar\\\'\";; rule with condition test
1123                     '(if condition
1124                           \"BAR-COMMAND-1\"
1125                         \"BAR-COMMAND-2\")))\)"
1126   :group 'dired-x
1127   :type '(alist :key-type regexp :value-type (repeat sexp)))
1128
1129 (defun dired-guess-default (files)
1130   "Guess a shell commands for FILES.  Return command or list of commands.
1131 See `dired-guess-shell-alist-user'."
1132
1133   (let* ((case-fold-search t)
1134          ;; Prepend the user's alist to the default alist.
1135          (alist (append dired-guess-shell-alist-user
1136                         dired-guess-shell-alist-default))
1137          (file (car files))
1138          (flist (cdr files))
1139          elt regexp cmds)
1140
1141     ;; Find the first match in the alist for first file in FILES.
1142     (while alist
1143       (setq elt (car alist)
1144             regexp (car elt)
1145             alist (cdr alist))
1146       (if (string-match regexp file)
1147           (setq cmds (cdr elt)
1148                 alist nil)))
1149
1150     ;; If more than one file, see if all of FILES match regular expression.
1151     (while (and flist
1152                 (string-match regexp (car flist)))
1153       (setq flist (cdr flist)))
1154
1155     ;; If flist is still non-nil, then do not guess since this means that not
1156     ;; all the files in FILES were matched by the regexp.
1157     (setq cmds (and (not flist) cmds))
1158
1159     ;; Return commands or nil if flist is still non-nil.
1160     ;; Evaluate the commands in order that any logical testing will be done.
1161     (cond ((not (cdr cmds))
1162            (eval (car cmds))) ; single command
1163           (t
1164            (mapcar (function eval) cmds)))))
1165
1166 (defun dired-guess-shell-command (prompt files)
1167   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1168
1169   (let ((default (dired-guess-default files))
1170         default-list old-history val (failed t))
1171
1172     (if (null default)
1173         ;; Nothing to guess
1174         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1175
1176       ;; Save current history list
1177       (setq old-history dired-shell-command-history)
1178
1179       (if (listp default)
1180
1181           ;; More than one guess
1182           (setq default-list default
1183                 default (car default)
1184                 prompt (concat
1185                         prompt
1186                         (format "{%d guesses} " (length default-list))))
1187
1188         ;; Just one guess
1189         (setq default-list (list default)))
1190
1191       ;; Push all guesses onto history so that they can be retrieved with M-p
1192       ;; and put the first guess in the prompt but not in the initial value.
1193       (setq dired-shell-command-history
1194             (append default-list dired-shell-command-history)
1195             prompt (concat prompt (format "[%s] " default)))
1196
1197       ;; The unwind-protect returns VAL, and we too.
1198       (unwind-protect
1199           ;; BODYFORM
1200           (progn
1201             (setq val (read-from-minibuffer prompt nil nil nil
1202                                             'dired-shell-command-history)
1203                   failed nil)
1204             ;; If we got a return, then use default.
1205             (if (equal val "")
1206                 (setq val default))
1207             val)
1208
1209         ;; UNWINDFORMS
1210         ;; Undo pushing onto the history list so that an aborted
1211         ;; command doesn't get the default in the next command.
1212         (setq dired-shell-command-history old-history)
1213         (if (not failed)
1214             (or (equal val (car-safe dired-shell-command-history))
1215                 (setq dired-shell-command-history
1216                       (cons val dired-shell-command-history))))))))
1217
1218
1219 ;;; REDEFINE.
1220 ;;; Redefine dired-aux.el's version:
1221 (defun dired-read-shell-command (prompt arg files)
1222   "Read a dired shell command prompting with PROMPT (using read-string).
1223 ARG is the prefix arg and may be used to indicate in the prompt which
1224   files are affected.
1225 This is an extra function so that you can redefine it."
1226   (dired-mark-pop-up
1227    nil 'shell files
1228    'dired-guess-shell-command
1229    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1230    files))                                       ; FILES
1231
1232 \f
1233 ;;; RELATIVE SYMBOLIC LINKS.
1234
1235 (defvar dired-keep-marker-relsymlink ?S
1236   "See variable `dired-keep-marker-move'.")
1237
1238 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1239   "Make a symbolic link (pointing to FILE1) in FILE2.
1240 The link is relative (if possible), for example
1241
1242     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1243
1244 results in
1245
1246     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1247   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1248   (let (name1 name2 len1 len2 (index 0) sub)
1249     (setq file1 (expand-file-name file1)
1250           file2 (expand-file-name file2)
1251           len1 (length file1)
1252           len2 (length file2))
1253     ;; Find common initial file name components:
1254     (let (next)
1255       (while (and (setq next (string-match "/" file1 index))
1256                   (setq next (1+ next))
1257                   (< next (min len1 len2))
1258                   ;; For the comparison, both substrings must end in
1259                   ;; `/', so NEXT is *one plus* the result of the
1260                   ;; string-match.
1261                   ;; E.g., consider the case of linking "/tmp/a/abc"
1262                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1263                   ;; of "/tmp/" as common initial component
1264                   (string-equal (substring file1 0 next)
1265                                 (substring file2 0 next)))
1266         (setq index next))
1267       (setq name2 file2
1268             sub (substring file1 0 index)
1269             name1 (substring file1 index)))
1270     (if (string-equal sub "/")
1271         ;; No common initial file name found
1272         (setq name1 file1)
1273       ;; Else they have a common parent directory
1274       (let ((tem (substring file2 index))
1275             (start 0)
1276             (count 0))
1277         ;; Count number of slashes we must compensate for ...
1278         (while (setq start (string-match "/" tem start))
1279           (setq count (1+ count)
1280                 start (1+ start)))
1281         ;; ... and prepend a "../" for each slash found:
1282         (while (> count 0)
1283           (setq count (1- count)
1284                 name1 (concat "../" name1)))))
1285     (make-symbolic-link
1286      (directory-file-name name1)        ; must not link to foo/
1287                                         ; (trailing slash!)
1288      name2 ok-if-already-exists)))
1289
1290 ;;;###autoload
1291 (defun dired-do-relsymlink (&optional arg)
1292    "Relative symlink all marked (or next ARG) files into a directory.
1293 Otherwise make a relative symbolic link to the current file.
1294 This creates relative symbolic links like
1295
1296     foo -> ../bar/foo
1297
1298 not absolute ones like
1299
1300     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1301
1302 For absolute symlinks, use \\[dired-do-symlink]."
1303   (interactive "P")
1304   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1305                            "RelSymLink" arg dired-keep-marker-relsymlink))
1306
1307 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1308   "RelSymlink all marked files containing REGEXP to NEWNAME.
1309 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1310 for more info."
1311   (interactive (dired-mark-read-regexp "RelSymLink"))
1312   (dired-do-create-files-regexp
1313    (function dired-make-relative-symlink)
1314    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1315
1316 \f
1317 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1318
1319 ;;; Brief Description:
1320 ;;;
1321 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1322 ;;;
1323 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1324 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1325 ;;;
1326 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1327 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1328 ;;;
1329 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1330 ;;;   list each time.
1331 ;;;
1332 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1333 ;;;   element of FILE-LIST.
1334 ;;;
1335 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1336 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1337 ;;;   cognizant of the window-configuration.
1338 ;;;
1339 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1340 ;;;   of FILE-LIST giving each a window of height `size'.
1341
1342 (defun dired-do-find-marked-files (&optional noselect)
1343   "Find all marked files displaying all of them simultaneously.
1344 With optional NOSELECT just find files but do not select them.
1345
1346 The current window is split across all files marked, as evenly as possible.
1347 Remaining lines go to bottom-most window.  The number of files that can be
1348 displayed this way is restricted by the height of the current window and
1349 `window-min-height'.
1350
1351 To keep dired buffer displayed, type \\[split-window-vertically] first.
1352 To display just marked files, type \\[delete-other-windows] first."
1353
1354   (interactive "P")
1355   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1356
1357 (defun dired-simultaneous-find-file (file-list noselect)
1358
1359   "Visit all files in FILE-LIST and display them simultaneously.
1360 The current window is split across all files in FILE-LIST, as evenly as
1361 possible.  Remaining lines go to the bottom-most window.  The number of
1362 files that can be displayed this way is restricted by the height of the
1363 current window and the variable `window-min-height'.  With non-nil
1364 NOSELECT the files are merely found but not selected."
1365
1366   ;; We don't make this function interactive because it is usually too clumsy
1367   ;; to specify FILE-LIST interactively unless via dired.
1368
1369   (let (size)
1370
1371     (if noselect
1372         ;; Do not select the buffer.
1373         (find-file-noselect (car file-list))
1374
1375       ;; We will have to select the buffer.  Calculate and check window size.
1376       (setq size (/ (window-height) (length file-list)))
1377       (or (<= window-min-height size)
1378           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1379       (find-file (car file-list)))
1380
1381     ;; Decrement.
1382     (setq file-list (cdr file-list))
1383
1384     (while file-list
1385
1386       (if noselect
1387           ;; Do not select the buffer.
1388           (find-file-noselect (car file-list))
1389
1390         ;; Vertically split off a window of desired size.  Upper window will
1391         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1392         (select-window (split-window nil size))
1393         (find-file (car file-list)))
1394
1395       ;; Decrement.
1396       (setq file-list (cdr file-list)))))
1397
1398 \f
1399 ;;; MISCELLANEOUS COMMANDS.
1400
1401 ;;; Run man on files.
1402
1403 (defun dired-man ()
1404   "Run man on this file.  Display old buffer if buffer name matches filename.
1405 Uses `man.el' of \\[manual-entry] fame."
1406   (interactive)
1407   (require 'man)
1408   (let* ((file (dired-get-filename))
1409          (manual-program (replace-regexp-in-string "\\*" "%s"
1410                           (dired-guess-shell-command
1411                            "Man command: " (list file)))))
1412     (Man-getpage-in-background file)))
1413
1414 ;;; Run Info on files.
1415
1416 (defun dired-info ()
1417   "Run info on this file."
1418   (interactive)
1419   (info (dired-get-filename)))
1420
1421 ;;; Run mail on mail folders.
1422
1423 ;; Avoid compiler warning.
1424 (eval-when-compile
1425   (when (not (fboundp 'vm-visit-folder))
1426     (defun vm-visit-folder (file &optional arg)
1427       nil)))
1428
1429 (defun dired-vm (&optional read-only)
1430   "Run VM on this file.
1431 With prefix arg, visit folder read-only (this requires at least VM 5).
1432 See also variable `dired-vm-read-only-folders'."
1433   (interactive "P")
1434   (let ((dir (dired-current-directory))
1435         (fil (dired-get-filename)))
1436     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1437     (cond (read-only (vm-visit-folder fil t))
1438           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1439           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1440           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1441     ;; so that pressing `v' inside VM does prompt within current directory:
1442     (set (make-local-variable 'vm-folder-directory) dir)))
1443
1444 (defun dired-rmail ()
1445   "Run RMAIL on this file."
1446   (interactive)
1447   (rmail (dired-get-filename)))
1448
1449 (defun dired-do-run-mail ()
1450   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1451   (interactive)
1452   (if dired-bind-vm
1453       ;; Read mail folder using vm.
1454       (dired-vm)
1455     ;; Read mail folder using rmail.
1456     (dired-rmail)))
1457
1458 \f
1459 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1460
1461 (or (fboundp 'dired-old-find-buffer-nocreate)
1462     (fset 'dired-old-find-buffer-nocreate
1463           (symbol-function 'dired-find-buffer-nocreate)))
1464
1465 ;;; REDEFINE.
1466 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1467 (defun dired-find-buffer-nocreate (dirname &optional mode)
1468   (if (and dired-find-subdir
1469            ;; don't try to find a wildcard as a subdirectory
1470            (string-equal dirname (file-name-directory dirname)))
1471       (let* ((cur-buf (current-buffer))
1472              (buffers (nreverse
1473                        (dired-buffers-for-dir (expand-file-name dirname))))
1474              (cur-buf-matches (and (memq cur-buf buffers)
1475                                    ;; wildcards must match, too:
1476                                    (equal dired-directory dirname))))
1477         ;; We don't want to switch to the same buffer---
1478         (setq buffers (delq cur-buf buffers));;need setq with delq
1479         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1480             ;; ---unless it's the only possibility:
1481             (and cur-buf-matches cur-buf)))
1482     (dired-old-find-buffer-nocreate dirname mode)))
1483
1484 ;; This should be a builtin
1485 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1486   "Return t if BUFFER1 is more recently used than BUFFER2."
1487   (if (equal buffer1 buffer2)
1488       nil
1489     (let ((more-recent nil)
1490           (list (buffer-list)))
1491       (while (and list
1492                   (not (setq more-recent (equal buffer1 (car list))))
1493                   (not (equal buffer2 (car list))))
1494         (setq list (cdr list)))
1495       more-recent)))
1496
1497 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1498 ;;; (defun dired-buffers-for-dir-exact (dir)
1499 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1500 ;;; ;; at top level, or as subdirectory.
1501 ;;; ;; Top level matches must match the wildcard part too, if any.
1502 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1503 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1504 ;;; ;; dired-buffers.
1505 ;;;   (let ((alist dired-buffers) result elt)
1506 ;;;     (while alist
1507 ;;;       (setq elt (car alist)
1508 ;;;             alist (cdr alist))
1509 ;;;       (let ((buf (cdr elt)))
1510 ;;;         (if (buffer-name buf)
1511 ;;;             ;; Top level must match exactly against dired-directory in
1512 ;;;             ;; case one of them is a wildcard.
1513 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1514 ;;;                                                dired-directory))
1515 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1516 ;;;                                                dired-subdir-alist)))
1517 ;;;                 (setq result (cons buf result)))
1518 ;;;           ;; else buffer is killed - clean up:
1519 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1520 ;;;     result))
1521
1522 ;;; REDEFINE.
1523 ;;; Redefines dired.el's version of `dired-initial-position'
1524 (defun dired-initial-position (dirname)
1525   "Where point should go in a new listing of DIRNAME.
1526 Point assumed at beginning of new subdir line.
1527 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1528   (end-of-line)
1529   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1530   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1531
1532 \f
1533 ;; Does anyone use this? - lrd 6/29/93.
1534 ;; Apparently people do use it. - lrd 12/22/97.
1535 (defun dired-mark-sexp (predicate &optional unflag-p)
1536   "Mark files for which PREDICATE returns non-nil.
1537 With a prefix arg, unflag those files instead.
1538
1539 PREDICATE is a lisp expression that can refer to the following symbols:
1540
1541     inode  [integer] the inode of the file (only for ls -i output)
1542     s      [integer] the size of the file for ls -s output
1543                      (usually in blocks or, with -k, in KByte)
1544     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1545     nlink  [integer] number of links to file
1546     uid    [string]  owner
1547     gid    [string]  group  (If the gid is not displayed by ls,
1548                      this will still be set (to the same as uid))
1549     size   [integer] file size in bytes
1550     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1551     name   [string]  the name of the file
1552     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1553
1554 For example, use
1555
1556         (equal 0 size)
1557
1558 to mark all zero length files."
1559   ;; Using sym="" instead of nil avoids the trap of
1560   ;; (string-match "foo" sym) into which a user would soon fall.
1561   ;; Give `equal' instead of `=' in the example, as this works on
1562   ;; integers and strings.
1563   (interactive "xMark if (lisp expr): \nP")
1564   (message "%s" predicate)
1565   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1566         inode s mode nlink uid gid size time name sym)
1567     (dired-mark-if
1568      (save-excursion
1569        (and
1570         ;; Sets vars
1571         ;;                inode s mode nlink uid gid size time name sym
1572
1573         ;; according to current file line.  Returns t for success, nil if
1574         ;; there is no file line.  Upon success, all variables are set, either
1575         ;; to nil or the appropriate value, so they need not be initialized.
1576         ;; Moves point within the current line.
1577         (if (dired-move-to-filename)
1578             (let (pos
1579                   (mode-len 10) ; length of mode string
1580                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1581                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1582               (beginning-of-line)
1583               (forward-char 2)
1584               (if (looking-at dired-re-inode-size)
1585                   (progn
1586                     (goto-char (match-end 0))
1587                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1588                                                                     (match-end 1)))
1589                           s (string-to-number (buffer-substring (match-beginning 2)
1590                                                                 (match-end 2)))))
1591                 (setq inode nil
1592                       s nil))
1593               (setq mode (buffer-substring (point) (+ mode-len (point))))
1594               (forward-char mode-len)
1595               (setq nlink (read (current-buffer)))
1596               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1597               (setq uid (buffer-substring (+ (point) 1)
1598                                           (progn (forward-word 1) (point))))
1599               (re-search-forward directory-listing-before-filename-regexp)
1600               (goto-char (match-beginning 1))
1601               (forward-char -1)
1602               (setq size (string-to-number (buffer-substring (save-excursion
1603                                                                (backward-word 1)
1604                                                                (setq pos (point)))
1605                                                              (point))))
1606               (goto-char pos)
1607               (backward-word 1)
1608               ;; if no gid is displayed, gid will be set to uid
1609               ;; but user will then not reference it anyway in PREDICATE.
1610               (setq gid (buffer-substring (save-excursion
1611                                             (forward-word 1) (point))
1612                                           (point))
1613                     time (buffer-substring (match-beginning 1)
1614                                            (1- (dired-move-to-filename)))
1615                     name (buffer-substring (point)
1616                                            (or
1617                                             (dired-move-to-end-of-filename t)
1618                                             (point)))
1619                     sym  (progn
1620                            (if (looking-at " -> ")
1621                                (buffer-substring
1622                                 (progn (forward-char 4) (point))
1623                                 (progn (end-of-line) (point)))
1624                              "")))
1625               t)
1626           nil)
1627                       (eval predicate)))
1628      (format "'%s file" predicate))))
1629
1630 \f
1631 ;;; FIND FILE AT POINT.
1632
1633 (defvar dired-x-hands-off-my-keys t
1634   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1635 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1636 If you change this variable after `dired-x.el' is loaded then do
1637 \\[dired-x-bind-find-file].")
1638
1639 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1640 ;;; `find-file{-other-window}' is bound?
1641 (defun dired-x-bind-find-file ()
1642   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1643 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1644 Binding direction based on `dired-x-hands-off-my-keys'.
1645 This function is part of `after-init-hook'."
1646   (interactive)
1647   (if (interactive-p)
1648       (setq dired-x-hands-off-my-keys
1649             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1650   (cond ((not dired-x-hands-off-my-keys)
1651          (substitute-key-definition 'find-file
1652                                     'dired-x-find-file
1653                                     (current-global-map))
1654          (substitute-key-definition 'find-file-other-window
1655                                     'dired-x-find-file-other-window
1656                                     (current-global-map)))
1657         (t
1658          (substitute-key-definition 'dired-x-find-file
1659                                     'find-file
1660                                     (current-global-map))
1661          (substitute-key-definition 'dired-x-find-file-other-window
1662                                     'find-file-other-window
1663                                     (current-global-map))))
1664   ;; Clear mini-buffer.
1665   (message nil))
1666
1667 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1668 ;;; user changes binding.
1669 (dired-x-bind-find-file)
1670 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1671
1672 (defun dired-x-find-file (filename)
1673   "Edit file FILENAME.
1674 May create a new window, or reuse an existing one.
1675 See the function `display-buffer'.
1676
1677 Identical to `find-file' except when called interactively, with a prefix arg
1678 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1679 Useful for editing file mentioned in buffer you are viewing,
1680 or to test if that file exists.  Use minibuffer after snatching filename."
1681   (interactive (list (read-filename-at-point "Find file: ")))
1682   (find-file (expand-file-name filename)))
1683
1684 (defun dired-x-find-file-other-window (filename)
1685   "Edit file FILENAME, in another window.
1686 May create a new window, or reuse an existing one.
1687 See the function `display-buffer'.
1688
1689 Identical to `find-file-other-window' except when called interactively, with a
1690 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1691 Useful for editing file mentioned in buffer you are viewing,
1692 or to test if that file exists.  Use minibuffer after snatching filename."
1693   (interactive (list (read-filename-at-point "Find file: ")))
1694   (find-file-other-window (expand-file-name filename)))
1695
1696 ;;; Internal functions.
1697
1698 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1699 (defun dired-filename-at-point ()
1700   "Get the filename closest to point, but do not change position.
1701 Has a preference for looking backward when not directly on a symbol.  Not
1702 perfect - point must be in middle of or end of filename."
1703
1704   (let ((filename-chars "-.[:alnum:]_/:$+@")
1705         start end filename prefix)
1706
1707     (save-excursion
1708       ;; First see if just past a filename.
1709       (if (not (eobp))
1710           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1711               (progn
1712                 (skip-chars-backward " \n\t\r({[]})")
1713                 (if (not (bobp))
1714                     (backward-char 1)))))
1715
1716       (if (string-match (concat "[" filename-chars "]")
1717                         (char-to-string (following-char)))
1718           (progn
1719             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1720                 (forward-char)
1721               (goto-char (point-min)))
1722             (setq start (point))
1723             (setq prefix
1724                   (and (string-match
1725                         "^\\w+@"
1726                         (buffer-substring start (line-beginning-position)))
1727                        "/"))
1728             (goto-char start)
1729             (if (string-match "[/~]" (char-to-string (preceding-char)))
1730                 (setq start (1- start)))
1731             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1732
1733         (error "No file found around point!"))
1734
1735       ;; Return string.
1736       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1737
1738 (defun read-filename-at-point (prompt)
1739   "Return filename prompting with PROMPT with completion.
1740 If `current-prefix-arg' is non-nil, uses name at point as guess."
1741   (if current-prefix-arg
1742       (let ((guess (dired-filename-at-point)))
1743         (read-file-name prompt
1744                         (file-name-directory guess)
1745                         guess
1746                         nil (file-name-nondirectory guess)))
1747     (read-file-name prompt default-directory)))
1748 \f
1749 ;;; BUG REPORTS
1750
1751 ;; Fixme: get rid of this later.
1752
1753 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1754 ;;; reporter.el which is bundled with GNU Emacs v19.
1755
1756 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1757   "Address(es) accepting submission of reports on dired-x.el.")
1758
1759 (defconst dired-x-variable-list
1760   (list
1761    'dired-bind-vm
1762    'dired-vm-read-only-folders
1763    'dired-bind-jump
1764    'dired-bind-info
1765    'dired-bind-man
1766    'dired-find-subdir
1767    'dired-enable-local-variables
1768    'dired-local-variables-file
1769    'dired-guess-shell-gnutar
1770    'dired-guess-shell-gzip-quiet
1771    'dired-guess-shell-znew-switches
1772    'dired-guess-shell-alist-user
1773    'dired-clean-up-buffers-too
1774    'dired-omit-mode
1775    'dired-omit-files
1776    'dired-omit-extensions
1777    )
1778   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1779
1780 (defun dired-x-submit-report ()
1781   "Submit via `reporter.el' a bug report on program.
1782 Send report on `dired-x-file' version `dired-x-version,' to
1783 `dired-x-maintainer' at address `dired-x-help-address' listing
1784 variables `dired-x-variable-list' in the message."
1785   (interactive)
1786
1787   (reporter-submit-bug-report
1788    dired-x-help-address                 ; address
1789    "dired-x"                            ; pkgname
1790    dired-x-variable-list                ; varlist
1791    nil nil                              ; pre-/post-hooks
1792    ""))
1793
1794 \f
1795 ;; As Barry Warsaw would say: "This might be useful..."
1796 (provide 'dired-x)
1797
1798 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1799 ;;; dired-x.el ends here