configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 dnl _ON results in a '--without' option in the --help output, so
 148 dnl the help text should refer to "don't compile", etc.
 149 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 150 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 151 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 152 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 153 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 154 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 155 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 156 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH(gameuser,dnl
 204 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 205 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 206   && gameuser="${with_gameuser}"
 207 test "X$gameuser" = X && gameuser=games
 208
 209 AC_ARG_WITH([gnustep-conf],dnl
 210 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 211 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 212   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 213 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 214      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 215
 216 AC_ARG_ENABLE(ns-self-contained,
 217 [AS_HELP_STRING([--disable-ns-self-contained],
 218                 [disable self contained build under NeXTstep])],
 219    EN_NS_SELF_CONTAINED=$enableval,
 220    EN_NS_SELF_CONTAINED=yes)
 221
 222 AC_ARG_ENABLE(asserts,
 223 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 224       USE_XASSERTS=$enableval,
 225       USE_XASSERTS=no)
 226
 227 AC_ARG_ENABLE(maintainer-mode,
 228 [AS_HELP_STRING([--enable-maintainer-mode],
 229                 [enable make rules and dependencies not useful (and sometimes
 230                  confusing) to the casual installer])],
 231       USE_MAINTAINER_MODE=$enableval,
 232       USE_MAINTAINER_MODE=yes)
 233 if test $USE_MAINTAINER_MODE = yes; then
 234   MAINT=
 235 else
 236   MAINT=#
 237 fi
 238 AC_SUBST(MAINT)
 239
 240 AC_ARG_ENABLE(locallisppath,
 241 [AS_HELP_STRING([--enable-locallisppath=PATH],
 242                 [directories Emacs should search for lisp files specific
 243                  to this site])],
 244 if test "${enableval}" = "no"; then
 245   locallisppath=
 246 elif test "${enableval}" != "yes"; then
 247   locallisppath=${enableval}
 248 fi)
 249
 250 AC_ARG_ENABLE(checking,
 251 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 252                 [enable expensive run-time checks.  With LIST,
 253                  enable only specific categories of checks.
 254                  Categories are: all,yes,no.
 255                  Flags are: stringbytes, stringoverrun, stringfreelist,
 256                  xmallocoverrun, conslist])],
 257 [ac_checking_flags="${enableval}"],[])
 258 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 259 for check in $ac_checking_flags
 260 do
 261         case $check in
 262         # these set all the flags to specific states
 263         yes)            ac_enable_checking=1 ;;
 264         no)             ac_enable_checking= ;
 265                         ac_gc_check_stringbytes= ;
 266                         ac_gc_check_string_overrun= ;
 267                         ac_gc_check_string_free_list= ;
 268                         ac_xmalloc_overrun= ;
 269                         ac_gc_check_cons_list= ;;
 270         all)            ac_enable_checking=1 ;
 271                         ac_gc_check_stringbytes=1 ;
 272                         ac_gc_check_string_overrun=1 ;
 273                         ac_gc_check_string_free_list=1 ;
 274                         ac_xmalloc_overrun=1 ;
 275                         ac_gc_check_cons_list=1 ;;
 276         # these enable particular checks
 277         stringbytes)    ac_gc_check_stringbytes=1 ;;
 278         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 279         stringfreelist) ac_gc_check_string_free_list=1 ;;
 280         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 281         conslist)       ac_gc_check_cons_list=1 ;;
 282         *)      AC_MSG_ERROR(unknown check category $check) ;;
 283         esac
 284 done
 285 IFS="$ac_save_IFS"
 286
 287 if test x$ac_enable_checking != x ; then
 288   AC_DEFINE(ENABLE_CHECKING, 1,
 289 [Enable expensive run-time checking of data types?])
 290 fi
 291 if test x$ac_gc_check_stringbytes != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 293 [Define this temporarily to hunt a bug.  If defined, the size of
 294    strings is redundantly recorded in sdata structures so that it can
 295    be compared to the sizes recorded in Lisp strings.])
 296 fi
 297 if test x$ac_gc_check_string_overrun != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 299 [Define this to check for short string overrun.])
 300 fi
 301 if test x$ac_gc_check_string_free_list != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 303 [Define this to check the string free list.])
 304 fi
 305 if test x$ac_xmalloc_overrun != x ; then
 306   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 307 [Define this to check for malloc buffer overrun.])
 308 fi
 309 if test x$ac_gc_check_cons_list != x ; then
 310   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 311 [Define this to check for errors in cons list.])
 312 fi
 313
 314 AC_ARG_ENABLE(use-lisp-union-type,
 315 [AS_HELP_STRING([--enable-use-lisp-union-type],
 316                 [use a union for the Lisp_Object data type.
 317                 This is only useful for development for catching certain types of bugs.])],
 318 if test "${enableval}" != "no"; then
 319    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 320    [Define this to use a lisp union for the Lisp_Object data type.])
 321 fi)
 322
 323
 324 AC_ARG_ENABLE(profiling,
 325 [AS_HELP_STRING([--enable-profiling],
 326                 [build emacs with profiling support.
 327                  This might not work on all platforms])],
 328 [ac_enable_profiling="${enableval}"],[])
 329 if test x$ac_enable_profiling != x ; then
 330    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 331 else
 332    PROFILING_CFLAGS=
 333 fi
 334 AC_SUBST(PROFILING_CFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Check if the source directory already has a configured system in it.
 368 if test `pwd` != `(cd ${srcdir} && pwd)` \
 369    && test -f "${srcdir}/src/config.h" ; then
 370   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 371    as a build directory right now; it has been configured in its own
 372    right.  To configure in another directory as well, you MUST
 373    use GNU make.  If you do not have GNU make, then you must
 374    now do `make distclean' in ${srcdir},
 375    and then run $0 again.]])
 376 fi
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## GNU/Linux ports
 419   *-*-linux-gnu*)
 420     opsys=gnu-linux
 421     case ${canonical} in
 422       alpha*)   machine=alpha ;;
 423       s390-*)   machine=ibms390 ;;
 424       s390x-*)  machine=ibms390x ;;
 425       powerpc*) machine=macppc ;;
 426       sparc*)   machine=sparc ;;
 427       ia64*)    machine=ia64 ;;
 428       m68k*)    machine=m68k ;;
 429       x86_64*)  machine=amdx86-64 ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD ports
 434   *-*-freebsd* )
 435     opsys=freebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## FreeBSD kernel + glibc based userland
 448   *-*-kfreebsd*gnu* )
 449     opsys=gnu-kfreebsd
 450     case "${canonical}" in
 451       alpha*)           machine=alpha ;;
 452       amd64-*|x86_64-*) machine=amdx86-64 ;;
 453       ia64-*)           machine=ia64 ;;
 454       i[3456]86-*)      machine=intel386 ;;
 455       powerpc-*)        machine=macppc ;;
 456       sparc-*)          machine=sparc ;;
 457       sparc64-*)        machine=sparc ;;
 458     esac
 459   ;;
 460
 461   ## NetBSD ports
 462   *-*-netbsd* )
 463     opsys=netbsd
 464     case "${canonical}" in
 465       alpha*)      machine=alpha ;;
 466       x86_64-*)    machine=amdx86-64 ;;
 467       i[3456]86-*) machine=intel386 ;;
 468       m68k-*)      machine=m68k ;;
 469       powerpc-*)   machine=macppc ;;
 470       sparc*-)     machine=sparc ;;
 471       vax-*)       machine=vax ;;
 472     esac
 473   ;;
 474
 475   ## OpenBSD ports
 476   *-*-openbsd* )
 477     opsys=openbsd
 478     case "${canonical}" in
 479       alpha*)    machine=alpha ;;
 480       x86_64-*)  machine=amdx86-64 ;;
 481       i386-*)    machine=intel386 ;;
 482       powerpc-*) machine=macppc ;;
 483       sparc*)    machine=sparc ;;
 484       vax-*)     machine=vax ;;
 485     esac
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   ia64*-hp-hpux1[1-9]* )
 517     machine=hp800 opsys=hpux11
 518     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 519     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 520     CANNOT_DUMP=yes
 521   ;;
 522
 523   hppa*-*-linux-gnu* )
 524     machine=hp800 opsys=gnu-linux
 525   ;;
 526
 527   ## IBM machines
 528   rs6000-ibm-aix4.[23]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix4.[23]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   rs6000-ibm-aix[56]* )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537   powerpc-ibm-aix[56]*  )
 538     machine=ibmrs6000 opsys=aix4-2
 539   ;;
 540
 541   ## Silicon Graphics machines
 542   ## Iris 4D
 543   mips-sgi-irix6.5 )
 544     machine=iris4d opsys=irix6-5
 545     # Without defining _LANGUAGE_C, things get masked out in the headers
 546     # so that, for instance, grepping for `free' in stdlib.h fails and
 547     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 548     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 549     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 550   ;;
 551
 552   ## Suns
 553   *-sun-solaris* \
 554     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 555     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 556     case "${canonical}" in
 557       i[3456]86-*-* )     machine=intel386 ;;
 558       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 559       sparc* )          machine=sparc ;;
 560       * )               unported=yes ;;
 561     esac
 562     case "${canonical}" in
 563       *-sunos5.6* | *-solaris2.6* )
 564                 opsys=sol2-6
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 RANLIB="ar -ts"
 567                 ;;
 568       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 569                 opsys=sol2-6
 570                 emacs_check_sunpro_c=yes
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 ;;
 573       *-sunos5* | *-solaris* )
 574                 opsys=sol2-10
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578     esac
 579     ## Watch out for a compiler that we know will not work.
 580     case "${canonical}" in
 581      *-solaris* | *-sunos5* )
 582                 if [ "x$CC" = x/usr/ucb/cc ]; then
 583                   ## /usr/ucb/cc doesn't work;
 584                   ## we should find some other compiler that does work.
 585                   unset CC
 586                 fi
 587                 ;;
 588       *) ;;
 589     esac
 590   ;;
 591
 592   ## Intel 386 machines where we don't care about the manufacturer.
 593   i[3456]86-*-* )
 594     machine=intel386
 595     case "${canonical}" in
 596       *-cygwin )                opsys=cygwin ;;
 597       *-darwin* )               opsys=darwin
 598                                 CPP="${CC-cc} -E -no-cpp-precomp"
 599                                 ;;
 600       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 604     esac
 605   ;;
 606
 607   * )
 608     unported=yes
 609   ;;
 610 esac
 611
 612 ### If the code above didn't choose an operating system, just choose
 613 ### an operating system based on the configuration name.  You really
 614 ### only want to use this when you have no idea what the right
 615 ### operating system is; if you know what operating systems a machine
 616 ### runs, it's cleaner to make it explicit in the case statement
 617 ### above.
 618 if test x"${opsys}" = x; then
 619   case "${canonical}" in
 620     *-gnu* )                            opsys=gnu ;;
 621     * )
 622       unported=yes
 623     ;;
 624   esac
 625 fi
 626
 627 ]
 628 dnl quotation ends
 629
 630 if test $unported = yes; then
 631   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 632 Check `etc/MACHINES' for recognized configuration names.])
 633 fi
 634
 635 if test -n "$machine"; then
 636   machfile="m/${machine}.h"
 637 else
 638   machfile=
 639 fi
 640 opsysfile="s/${opsys}.h"
 641
 642
 643 #### Choose a compiler.
 644 test -n "$CC" && cc_specified=yes
 645
 646 # Save the value of CFLAGS that the user specified.
 647 SPECIFIED_CFLAGS="$CFLAGS"
 648
 649 dnl Sets GCC=yes if using gcc.
 650 AC_PROG_CC
 651 AM_PROG_CC_C_O
 652
 653 # Initialize gnulib right after verifying that the C compiler works.
 654 gl_EARLY
 655
 656 # On Suns, sometimes $CPP names a directory.
 657 if test -n "$CPP" && test -d "$CPP"; then
 658   CPP=
 659 fi
 660
 661 ## If not using gcc, and on Solaris, and no CPP specified, see if
 662 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 663 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 664  test x"$CPP" = x; then
 665   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 666   AC_CACHE_VAL(emacs_cv_sunpro_c,
 667   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 668 [[#ifndef __SUNPRO_C
 669 fail;
 670 #endif
 671 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 672   AC_MSG_RESULT($emacs_cv_sunpro_c)
 673
 674   if test x"$emacs_cv_sunpro_c" = xyes; then
 675     NON_GNU_CPP="$CC -E -Xs"
 676   fi
 677 fi
 678
 679 #### Some systems specify a CPP to use unless we are using GCC.
 680 #### Now that we know whether we are using GCC, we can decide whether
 681 #### to use that one.
 682 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 683 then
 684   CPP="$NON_GNU_CPP"
 685 fi
 686
 687 #### Some systems specify a CC to use unless we are using GCC.
 688 #### Now that we know whether we are using GCC, we can decide whether
 689 #### to use that one.
 690 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 691   test x$cc_specified != xyes
 692 then
 693   CC="$NON_GNU_CC"
 694 fi
 695
 696 if test x$GCC = xyes; then
 697   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 698 else
 699   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 700 fi
 701
 702 ### Use -Wdeclaration-after-statement if the compiler supports it
 703 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 704 SAVE_CFLAGS="$CFLAGS"
 705 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 706 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 707 if test $has_option = yes; then
 708    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 709 fi
 710 AC_MSG_RESULT($has_option)
 711 CFLAGS="$SAVE_CFLAGS"
 712 unset has_option
 713 unset SAVE_CFLAGS
 714
 715 ### Use -Wold-style-definition if the compiler supports it
 716 # This can be removed when conversion to standard C is finished.
 717 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 718 SAVE_CFLAGS="$CFLAGS"
 719 CFLAGS="$CFLAGS -Wold-style-definition"
 720 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 721 if test $has_option = yes; then
 722    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 723 fi
 724 AC_MSG_RESULT($has_option)
 725 CFLAGS="$SAVE_CFLAGS"
 726 unset has_option
 727 unset SAVE_CFLAGS
 728
 729 ### Use -Wimplicit-function-declaration if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 733 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 AC_SUBST(C_WARNINGS_SWITCH)
 743
 744
 745 #### Some other nice autoconf tests.
 746
 747 dnl checks for programs
 748 AC_PROG_CPP
 749 AC_PROG_INSTALL
 750 if test "x$RANLIB" = x; then
 751   AC_PROG_RANLIB
 752 fi
 753
 754 ## Although we're running on an amd64 kernel, we're actually compiling for
 755 ## the x86 architecture.  The user should probably have provided an
 756 ## explicit --build to `configure', but if everything else than the kernel
 757 ## is running in i386 mode, we can help them out.
 758 if test "$machine" = "amdx86-64"; then
 759   AC_CHECK_DECL([i386])
 760   if test "$ac_cv_have_decl_i386" = "yes"; then
 761     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 762     machine=intel386
 763     machfile="m/${machine}.h"
 764   fi
 765 fi
 766
 767 AC_PATH_PROG(INSTALL_INFO, install-info)
 768 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 769 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 770 dnl Don't use GZIP, which is used by gzip for additional parameters.
 771 AC_PATH_PROG(GZIP_PROG, gzip)
 772
 773
 774 ## Need makeinfo >= 4.6 (?) to build the manuals.
 775 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 776 dnl By this stage, configure has already checked for egrep and set EGREP,
 777 dnl or exited with an error if no egrep was found.
 778 if test "$MAKEINFO" != "no" && \
 779   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 780    MAKEINFO=no
 781 fi
 782
 783 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 784 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 785 ## therefore in the category of "special tools" not normally required, which
 786 ## configure does not have to check for (eg autoconf itself).
 787 ## In a Bazaar checkout on the other hand, the manuals are not included.
 788 ## So makeinfo is a requirement to build from Bazaar, and configure
 789 ## should test for it as it does for any other build requirement.
 790 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 791 ## with pre-built manuals, from a Bazaar checkout.
 792 HAVE_MAKEINFO=yes
 793
 794 if test "$MAKEINFO" = "no"; then
 795   MAKEINFO=makeinfo
 796   if test "x${with_makeinfo}" = "xno"; then
 797     HAVE_MAKEINFO=no
 798   elif test ! -e $srcdir/info/emacs; then
 799     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 800 source tree does not seem to have pre-built manuals in the `info' directory.
 801 Either install a suitable version of makeinfo, or re-run configure
 802 with the `--without-makeinfo' option to build without the manuals.] )
 803   fi
 804 fi
 805 AC_SUBST(HAVE_MAKEINFO)
 806
 807 dnl Add our options to ac_link now, after it is set up.
 808
 809 if test x$GCC = xyes; then
 810   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 811     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 812 else
 813   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 814     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 815 fi
 816
 817 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 818 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 819 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 820 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 821 dnl if not built to support GNU ld.
 822
 823 late_LDFLAGS=$LDFLAGS
 824 if test x$GCC = xyes; then
 825   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 826 else
 827   LDFLAGS="$LDFLAGS -znocombreloc"
 828 fi
 829
 830 AC_MSG_CHECKING([for -znocombreloc])
 831 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 832   [AC_MSG_RESULT(yes)],
 833   LDFLAGS=$late_LDFLAGS
 834   [AC_MSG_RESULT(no)])
 835
 836
 837 # The value of CPP is a quoted variable reference, so we need to do this
 838 # to get its actual value...
 839 CPP=`eval "echo $CPP"`
 840
 841
 842 dnl The function dump-emacs will not be defined and temacs will do
 843 dnl (load "loadup") automatically unless told otherwise.
 844 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 845 case "$opsys" in
 846   your-opsys-here) CANNOT_DUMP=yes ;;
 847 esac
 848
 849 test "$CANNOT_DUMP" = "yes" && \
 850   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 851
 852 AC_SUBST(CANNOT_DUMP)
 853
 854
 855 UNEXEC_OBJ=unexelf.o
 856 case "$opsys" in
 857   # MSDOS uses unexcoff.o
 858   # MSWindows uses unexw32.o
 859   aix4-2)
 860    UNEXEC_OBJ=unexaix.o
 861    ;;
 862   cygwin)
 863    UNEXEC_OBJ=unexcw.o
 864    ;;
 865   darwin)
 866    UNEXEC_OBJ=unexmacosx.o
 867    ;;
 868   hpux10-20 | hpux11)
 869    UNEXEC_OBJ=unexhp9k800.o
 870    ;;
 871   sol2-10)
 872    # Use the Solaris dldump() function, called from unexsol.c, to dump
 873    # emacs, instead of the generic ELF dump code found in unexelf.c.
 874    # The resulting binary has a complete symbol table, and is better
 875    # for debugging and other observability tools (debuggers, pstack, etc).
 876    #
 877    # If you encounter a problem using dldump(), please consider sending
 878    # a message to the OpenSolaris tools-linking mailing list:
 879    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 880    #
 881    # It is likely that dldump() works with older Solaris too, but this has
 882    # not been tested, so for now this change is for Solaris 10 or newer.
 883    UNEXEC_OBJ=unexsol.o
 884    ;;
 885 esac
 886
 887 LD_SWITCH_SYSTEM=
 888 case "$opsys" in
 889   freebsd)
 890    ## Let `ld' find image libs and similar things in /usr/local/lib.
 891    ## The system compiler, GCC, has apparently been modified to not
 892    ## look there, contrary to what a stock GCC would do.
 893    LD_SWITCH_SYSTEM=-L/usr/local/lib
 894    ;;
 895
 896   gnu-linux)
 897    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 898    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 899    ;;
 900
 901   netbsd)
 902    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 903    ;;
 904
 905   openbsd)
 906    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 907    ## otherwise Emacs dumps core on elf systems.
 908    LD_SWITCH_SYSTEM="-Z"
 909    ;;
 910 esac
 911 AC_SUBST(LD_SWITCH_SYSTEM)
 912
 913 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 914
 915 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 916 ## which has not been defined yet.  When this was handled with cpp,
 917 ## it was expanded to null when configure sourced the s/*.h file.
 918 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 919 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 920 ## (or somesuch), but because it is supposed to go at the _front_
 921 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 922 ## Compare with the gnu-linux case below, which added to the end
 923 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 924 ## LD_SWITCH_SYSTEM_TEMACS.
 925 case "$opsys" in
 926   netbsd|openbsd)
 927    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 928    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 929 esac
 930
 931
 932 C_SWITCH_MACHINE=
 933 if test "$machine" = "alpha"; then
 934   AC_CHECK_DECL([__ELF__])
 935   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 936     ## With ELF, make sure that all common symbols get allocated to in the
 937     ## data section.  Otherwise, the dump of temacs may miss variables in
 938     ## the shared library that have been initialized.  For example, with
 939     ## GNU libc, __malloc_initialized would normally be resolved to the
 940     ## shared library's .bss section, which is fatal.
 941     if test "x$GCC" = "xyes"; then
 942       C_SWITCH_MACHINE="-fno-common"
 943     else
 944       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 945     fi
 946   else
 947     UNEXEC_OBJ=unexalpha.o
 948   fi
 949 fi
 950 AC_SUBST(C_SWITCH_MACHINE)
 951
 952 AC_SUBST(UNEXEC_OBJ)
 953
 954 C_SWITCH_SYSTEM=
 955 ## Some programs in src produce warnings saying certain subprograms
 956 ## are too complex and need a MAXMEM value greater than 2000 for
 957 ## additional optimization.  --nils@exp-math.uni-essen.de
 958 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 959   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 960 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 961 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 962 AC_SUBST(C_SWITCH_SYSTEM)
 963
 964
 965 LIBS_SYSTEM=
 966 case "$opsys" in
 967   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 968   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 969
 970   freebsd) LIBS_SYSTEM="-lutil" ;;
 971
 972   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 973
 974   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 975
 976   ## Motif needs -lgen.
 977   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 978 esac
 979 AC_SUBST(LIBS_SYSTEM)
 980
 981
 982 ### Make sure subsequent tests use flags consistent with the build flags.
 983
 984 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 985   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 986 else
 987   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 988 fi
 989
 990 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 991 AC_DEFUN([AC_TYPE_SIZE_T])
 992
 993 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 994 AC_SYS_LARGEFILE
 995
 996
 997 ## If user specified a crt-dir, use that unconditionally.
 998 if test "X$CRT_DIR" = "X"; then
 999
1000   case "$canonical" in
1001     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1002     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1003     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1004     ## For anything else (eg /usr/lib32), it is up the user to specify
1005     ## the location (bug#5655).
1006     ## Test for crtn.o, not just the directory, because sometimes the
1007     ## directory exists but does not have the relevant files (bug#1287).
1008     ## FIXME better to test for binary compatibility somehow.
1009     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1010     ;;
1011
1012     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1013   esac
1014
1015   case "$opsys" in
1016     hpux10-20) CRT_DIR=/lib ;;
1017   esac
1018
1019   ## Default is /usr/lib.
1020   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1021
1022 else
1023
1024   ## Some platforms don't use any of these files, so it is not
1025   ## appropriate to put this test outside the if block.
1026   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1027     AC_MSG_ERROR([crt*.o not found in specified location.])
1028
1029 fi
1030
1031 AC_SUBST(CRT_DIR)
1032
1033 LIB_MATH=-lm
1034 LIB_STANDARD=
1035 START_FILES=
1036
1037 case $opsys in
1038   cygwin )
1039     LIB_MATH=
1040     START_FILES='pre-crt0.o'
1041     ;;
1042   darwin )
1043     ## Adding -lm confuses the dynamic linker, so omit it.
1044     LIB_MATH=
1045     START_FILES='pre-crt0.o'
1046     ;;
1047   freebsd )
1048     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1049     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1050     ;;
1051   gnu-linux | gnu-kfreebsd )
1052     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1053     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1054     ;;
1055   hpux10-20 | hpux11 )
1056     LIB_STANDARD=-lc
1057     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1058     ;;
1059   netbsd | openbsd )
1060     if test -f $CRT_DIR/crti.o; then
1061         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1062         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1063     else
1064         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1065         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1066     fi
1067     ;;
1068 esac
1069
1070 AC_SUBST(LIB_MATH)
1071 AC_SUBST(START_FILES)
1072
1073 dnl This function definition taken from Gnome 2.0
1074 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1075 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1076 dnl also defines GSTUFF_PKG_ERRORS on error
1077 AC_DEFUN([PKG_CHECK_MODULES], [
1078   succeeded=no
1079
1080   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1081
1082   if test "$PKG_CONFIG" = "no" ; then
1083      ifelse([$4], , [AC_MSG_ERROR([
1084       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1085   else
1086      PKG_CONFIG_MIN_VERSION=0.9.0
1087      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1088         AC_MSG_CHECKING(for $2)
1089
1090         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1091             AC_MSG_RESULT(yes)
1092             succeeded=yes
1093
1094             AC_MSG_CHECKING($1_CFLAGS)
1095             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1096             AC_MSG_RESULT($$1_CFLAGS)
1097
1098             AC_MSG_CHECKING($1_LIBS)
1099             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1100             AC_MSG_RESULT($$1_LIBS)
1101         else
1102             AC_MSG_RESULT(no)
1103             $1_CFLAGS=""
1104             $1_LIBS=""
1105             ## If we have a custom action on failure, don't print errors, but
1106             ## do set a variable so people can do so.
1107             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1108             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1109         fi
1110
1111         AC_SUBST($1_CFLAGS)
1112         AC_SUBST($1_LIBS)
1113      else
1114         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1115         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1116      fi
1117   fi
1118
1119   if test $succeeded = yes; then
1120      ifelse([$3], , :, [$3])
1121   else
1122      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1123   fi
1124 ])
1125
1126
1127 if test "${with_sound}" != "no"; then
1128   # Sound support for GNU/Linux and the free BSDs.
1129   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1130     have_sound_header=yes)
1131   # Emulation library used on NetBSD.
1132   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1133   AC_SUBST(LIBSOUND)
1134
1135   ALSA_REQUIRED=1.0.0
1136   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1137   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1138   if test $HAVE_ALSA = yes; then
1139     SAVE_CFLAGS="$CFLAGS"
1140     SAVE_LDFLAGS="$LDFLAGS"
1141     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1142     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1143     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1144                     emacs_alsa_normal=yes,
1145                     emacs_alsa_normal=no)
1146     if test "$emacs_alsa_normal" != yes; then
1147       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1148                      [[snd_lib_error_set_handler (0);]])],
1149                      emacs_alsa_subdir=yes,
1150                      emacs_alsa_subdir=no)
1151       if test "$emacs_alsa_subdir" != yes; then
1152         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1153       fi
1154       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1155     fi
1156
1157     CFLAGS="$SAVE_CFLAGS"
1158     LDFLAGS="$SAVE_LDFLAGS"
1159     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1160     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1161     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1162   fi
1163
1164   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1165   dnl compiles only on the specified platforms.  For others, it
1166   dnl probably doesn't make sense to try.
1167   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1168      case "$opsys" in
1169        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1170        gnu-linux|freebsd|netbsd)
1171          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1172          ;;
1173      esac
1174   fi
1175
1176   AC_SUBST(CFLAGS_SOUND)
1177 fi
1178
1179 dnl checks for header files
1180 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1181   linux/version.h sys/systeminfo.h limits.h \
1182   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1183   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1184   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1185
1186 AC_MSG_CHECKING(if personality LINUX32 can be set)
1187 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1188                emacs_cv_personality_linux32=yes,
1189                emacs_cv_personality_linux32=no)
1190 AC_MSG_RESULT($emacs_cv_personality_linux32)
1191
1192 if test $emacs_cv_personality_linux32 = yes; then
1193   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1194             [Define to 1 if personality LINUX32 can be set.])
1195 fi
1196
1197 dnl On Solaris 8 there's a compilation warning for term.h because
1198 dnl it doesn't define `bool'.
1199 AC_CHECK_HEADERS(term.h, , , -)
1200 AC_HEADER_STDC
1201 AC_HEADER_TIME
1202 AC_CHECK_DECLS([sys_siglist])
1203 if test $ac_cv_have_decl_sys_siglist != yes; then
1204   # For Tru64, at least:
1205   AC_CHECK_DECLS([__sys_siglist])
1206   if test $ac_cv_have_decl___sys_siglist = yes; then
1207     AC_DEFINE(sys_siglist, __sys_siglist,
1208               [Define to any substitute for sys_siglist.])
1209   fi
1210 fi
1211 AC_HEADER_SYS_WAIT
1212
1213 dnl Some systems have utime.h but don't declare the struct anyplace.
1214 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1215 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1216 #include <sys/time.h>
1217 #include <time.h>
1218 #else
1219 #ifdef HAVE_SYS_TIME_H
1220 #include <sys/time.h>
1221 #else
1222 #include <time.h>
1223 #endif
1224 #endif
1225 #ifdef HAVE_UTIME_H
1226 #include <utime.h>
1227 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1228   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1229 if test $emacs_cv_struct_utimbuf = yes; then
1230   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1231 fi
1232
1233 dnl Check for speed_t typedef.
1234 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1235   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1236     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1237 if test $emacs_cv_speed_t = yes; then
1238   AC_DEFINE(HAVE_SPEED_T, 1,
1239            [Define to 1 if `speed_t' is declared by <termios.h>.])
1240 fi
1241
1242 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1243 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1244 #include <sys/time.h>
1245 #include <time.h>
1246 #else
1247 #ifdef HAVE_SYS_TIME_H
1248 #include <sys/time.h>
1249 #else
1250 #include <time.h>
1251 #endif
1252 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1253   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1254 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1255 if test $emacs_cv_struct_timeval = yes; then
1256   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1257 fi
1258
1259 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1260 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1261 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1262   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1263 HAVE_EXCEPTION=$emacs_cv_struct_exception
1264 if test $emacs_cv_struct_exception != yes; then
1265   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1266 fi
1267
1268 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1269 #if HAVE_SYS_SOCKET_H
1270 #include <sys/socket.h>
1271 #endif])
1272
1273 dnl checks for structure members
1274 AC_STRUCT_TM
1275 AC_STRUCT_TIMEZONE
1276 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1277                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1278                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1279                 [#include <time.h>])
1280 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1281                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1282                   struct ifreq.ifr_addr], , ,
1283                  [AC_INCLUDES_DEFAULT
1284 #if HAVE_SYS_SOCKET_H
1285 #include <sys/socket.h>
1286 #endif
1287 #if HAVE_NET_IF_H
1288 #include <net/if.h>
1289 #endif])
1290
1291 dnl checks for compiler characteristics
1292
1293 dnl Testing __STDC__ to determine prototype support isn't good enough.
1294 dnl DEC C, for instance, doesn't define it with default options, and
1295 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1296 dnl and void *.
1297 AC_C_PROTOTYPES
1298 AC_C_VOLATILE
1299 AC_C_CONST
1300 dnl This isn't useful because we can't turn on use of `inline' unless
1301 dnl the compiler groks `extern inline'.
1302 dnl AC_C_INLINE
1303 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1304   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1305                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1306 if test $emacs_cv_void_star = yes; then
1307   AC_DEFINE(POINTER_TYPE, void)
1308 else
1309   AC_DEFINE(POINTER_TYPE, char)
1310 fi
1311 AH_TEMPLATE(POINTER_TYPE,
1312             [Define as `void' if your compiler accepts `void *'; otherwise
1313              define as `char'.])dnl
1314
1315 dnl Check for endianess
1316 AC_C_BIGENDIAN
1317
1318 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1319   [emacs_cv_attribute_aligned],
1320   [AC_COMPILE_IFELSE(
1321      [AC_LANG_PROGRAM(
1322         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1323         [[]])],
1324      [emacs_cv_attribute_aligned=yes],
1325      [emacs_cv_attribute_aligned=no])])
1326 if test $emacs_cv_attribute_aligned = yes; then
1327   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1328     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1329 fi
1330
1331 dnl check for Make feature
1332 AC_PROG_MAKE_SET
1333
1334 DEPFLAGS=
1335 MKDEPDIR=":"
1336 deps_frag=deps.mk
1337 dnl check for GNU Make if we have GCC and autodepend is on.
1338 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1339    AC_MSG_CHECKING([whether we are using GNU Make])
1340    HAVE_GNU_MAKE=no
1341    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1342    if test "x$testval" != x; then
1343       HAVE_GNU_MAKE=yes
1344    else
1345       ac_enable_autodepend=no
1346    fi
1347    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1348    if test $HAVE_GNU_MAKE = yes; then
1349       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1350       SAVE_CFLAGS="$CFLAGS"
1351       CFLAGS="$CFLAGS -MMD -MF deps.d"
1352       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1353       CFLAGS="$SAVE_CFLAGS"
1354       test -f deps.d || ac_enable_autodepend=no
1355       rm -rf deps.d
1356       AC_MSG_RESULT([$ac_enable_autodepend])
1357    fi
1358    if test $ac_enable_autodepend = yes; then
1359       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1360       ## In parallel builds, another make might create depdir between
1361       ## the first test and mkdir, so stick another test on the end.
1362       ## Or use install-sh -d?  mkdir -p is not portable.
1363       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1364       deps_frag=autodeps.mk
1365    fi
1366 fi
1367 deps_frag=$srcdir/src/$deps_frag
1368 AC_SUBST(MKDEPDIR)
1369 AC_SUBST(DEPFLAGS)
1370 AC_SUBST_FILE(deps_frag)
1371
1372
1373 lisp_frag=$srcdir/src/lisp.mk
1374 AC_SUBST_FILE(lisp_frag)
1375
1376
1377 dnl checks for operating system services
1378 AC_SYS_LONG_FILE_NAMES
1379
1380 #### Choose a window system.
1381
1382 AC_PATH_X
1383 if test "$no_x" = yes; then
1384   window_system=none
1385 else
1386   window_system=x11
1387 fi
1388
1389 ## Workaround for bug in autoconf <= 2.62.
1390 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1391 ## No need to do anything special for these standard directories.
1392 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1393
1394    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1395
1396 fi
1397
1398 LD_SWITCH_X_SITE_AUX=
1399 LD_SWITCH_X_SITE_AUX_RPATH=
1400 if test "${x_libraries}" != NONE; then
1401   if test -n "${x_libraries}"; then
1402     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1403     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1404     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1405   fi
1406   x_default_search_path=""
1407   x_search_path=${x_libraries}
1408   if test -z "${x_search_path}"; then
1409     x_search_path=/usr/lib
1410   fi
1411   for x_library in `echo ${x_search_path}: | \
1412                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1413     x_search_path="\
1414 ${x_library}/X11/%L/%T/%N%C%S:\
1415 ${x_library}/X11/%l/%T/%N%C%S:\
1416 ${x_library}/X11/%T/%N%C%S:\
1417 ${x_library}/X11/%L/%T/%N%S:\
1418 ${x_library}/X11/%l/%T/%N%S:\
1419 ${x_library}/X11/%T/%N%S"
1420     if test x"${x_default_search_path}" = x; then
1421       x_default_search_path=${x_search_path}
1422     else
1423       x_default_search_path="${x_search_path}:${x_default_search_path}"
1424     fi
1425   done
1426 fi
1427 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1428 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1429
1430 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1431   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1432 fi
1433
1434 if test x"${x_includes}" = x; then
1435   bitmapdir=/usr/include/X11/bitmaps
1436 else
1437   # accumulate include directories that have X11 bitmap subdirectories
1438   bmd_acc="dummyval"
1439   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1440     if test -d "${bmd}/X11/bitmaps"; then
1441       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1442     fi
1443     if test -d "${bmd}/bitmaps"; then
1444       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1445     fi
1446   done
1447   if test ${bmd_acc} != "dummyval"; then
1448     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1449   fi
1450 fi
1451
1452 HAVE_NS=no
1453 NS_IMPL_COCOA=no
1454 NS_IMPL_GNUSTEP=no
1455 tmp_CPPFLAGS="$CPPFLAGS"
1456 tmp_CFLAGS="$CFLAGS"
1457 CPPFLAGS="$CPPFLAGS -x objective-c"
1458 CFLAGS="$CFLAGS -x objective-c"
1459 TEMACS_LDFLAGS2="\${LDFLAGS}"
1460 dnl I don't think it's especially important, but src/Makefile.in
1461 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1462 dnl trailing "/" to it, so now we do it here.
1463 if test "${with_ns}" != no; then
1464   if test "${opsys}" = darwin; then
1465      NS_IMPL_COCOA=yes
1466      ns_appdir=`pwd`/nextstep/Emacs.app
1467      ns_appbindir=${ns_appdir}/Contents/MacOS/
1468      ns_appresdir=${ns_appdir}/Contents/Resources
1469      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1470   elif test -f $GNUSTEP_CONFIG_FILE; then
1471      NS_IMPL_GNUSTEP=yes
1472      ns_appdir=`pwd`/nextstep/Emacs.app
1473      ns_appbindir=${ns_appdir}/
1474      ns_appresdir=${ns_appdir}/Resources
1475      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1476      dnl FIXME sourcing this several times in subshells seems inefficient.
1477      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1478      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1479      dnl I seemed to need these as well with GNUstep-startup 0.25.
1480      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1481      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1482      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1483        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1484      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1485        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1486      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1487      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1488      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1489      LIB_STANDARD=
1490      START_FILES=
1491      TEMACS_LDFLAGS2=
1492   fi
1493   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1494                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1495   files are missing or cannot be compiled.])])
1496   NS_HAVE_NSINTEGER=yes
1497   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1498                                      [NSInteger i;])],
1499                     ns_have_nsinteger=yes,
1500                     ns_have_nsinteger=no)
1501   if test $ns_have_nsinteger = no; then
1502     NS_HAVE_NSINTEGER=no
1503   fi
1504 fi
1505 AC_SUBST(TEMACS_LDFLAGS2)
1506
1507 ns_frag=/dev/null
1508 NS_OBJ=
1509 NS_OBJC_OBJ=
1510 if test "${HAVE_NS}" = yes; then
1511   window_system=nextstep
1512   with_xft=no
1513   # set up packaging dirs
1514   exec_prefix=${ns_appbindir}
1515   libexecdir=${ns_appbindir}/libexec
1516   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1517      prefix=${ns_appresdir}
1518   fi
1519   ns_frag=$srcdir/src/ns.mk
1520   NS_OBJ="fontset.o fringe.o image.o"
1521   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1522 fi
1523 CFLAGS="$tmp_CFLAGS"
1524 CPPFLAGS="$tmp_CPPFLAGS"
1525 AC_SUBST(NS_OBJ)
1526 AC_SUBST(NS_OBJC_OBJ)
1527 AC_SUBST(LIB_STANDARD)
1528 AC_SUBST_FILE(ns_frag)
1529
1530 case "${window_system}" in
1531   x11 )
1532     HAVE_X_WINDOWS=yes
1533     HAVE_X11=yes
1534     case "${with_x_toolkit}" in
1535       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1536       motif ) USE_X_TOOLKIT=MOTIF ;;
1537       gtk ) with_gtk=yes
1538 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1539 dnl USE_X_TOOLKIT is set.
1540             USE_X_TOOLKIT=none ;;
1541       gtk3 ) with_gtk3=yes
1542              USE_X_TOOLKIT=none ;;
1543       no ) USE_X_TOOLKIT=none ;;
1544 dnl If user did not say whether to use a toolkit, make this decision later:
1545 dnl use the toolkit if we have gtk, or X11R5 or newer.
1546       * ) USE_X_TOOLKIT=maybe ;;
1547     esac
1548   ;;
1549   nextstep | none )
1550     HAVE_X_WINDOWS=no
1551     HAVE_X11=no
1552     USE_X_TOOLKIT=none
1553   ;;
1554 esac
1555
1556 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1557    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1558    if test "$HAVE_XSERVER" = true ||
1559       test -n "$DISPLAY" ||
1560       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1561         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1562 were found.  You should install the relevant development files for X
1563 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1564 sure you have development files for image handling, i.e.
1565 tiff, gif, jpeg, png and xpm.
1566 If you are sure you want Emacs compiled without X window support, pass
1567   --without-x
1568 to configure.])
1569    fi
1570 fi
1571
1572 ### If we're using X11, we should use the X menu package.
1573 HAVE_MENUS=no
1574 case ${HAVE_X11} in
1575   yes ) HAVE_MENUS=yes ;;
1576 esac
1577
1578 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1579 # Assume not, until told otherwise.
1580 GNU_MALLOC=yes
1581 doug_lea_malloc=yes
1582 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1583 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1584 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1585                emacs_cv_var___after_morecore_hook,
1586 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1587   emacs_cv_var___after_morecore_hook=yes,
1588   emacs_cv_var___after_morecore_hook=no)])
1589 if test $emacs_cv_var___after_morecore_hook = no; then
1590   doug_lea_malloc=no
1591 fi
1592
1593
1594 dnl See comments in aix4-2.h about maybe using system malloc there.
1595 system_malloc=no
1596 case "$opsys" in
1597   ## darwin ld insists on the use of malloc routines in the System framework.
1598   darwin|sol2-10) system_malloc=yes ;;
1599 esac
1600
1601 if test "${system_malloc}" = "yes"; then
1602   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1603   GNU_MALLOC=no
1604   GNU_MALLOC_reason="
1605     (The GNU allocators don't work with this system configuration.)"
1606   GMALLOC_OBJ=
1607   VMLIMIT_OBJ=
1608 else
1609   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1610   VMLIMIT_OBJ=vm-limit.o
1611 fi
1612 AC_SUBST(GMALLOC_OBJ)
1613 AC_SUBST(VMLIMIT_OBJ)
1614
1615 if test "$doug_lea_malloc" = "yes" ; then
1616   if test "$GNU_MALLOC" = yes ; then
1617     GNU_MALLOC_reason="
1618       (Using Doug Lea's new malloc from the GNU C Library.)"
1619   fi
1620   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1621             [Define to 1 if you are using the GNU C Library.])
1622
1623   ## Use mmap directly for allocating larger buffers.
1624   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1625   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1626   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1627   case "$opsys" in
1628     gnu*) REL_ALLOC=no ;;
1629   esac
1630 fi
1631
1632 if test x"${REL_ALLOC}" = x; then
1633   REL_ALLOC=${GNU_MALLOC}
1634 fi
1635
1636 use_mmap_for_buffers=no
1637 case "$opsys" in
1638   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1639 esac
1640
1641 AC_FUNC_MMAP
1642 if test $use_mmap_for_buffers = yes; then
1643   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1644   REL_ALLOC=no
1645 fi
1646
1647 LIBS="$LIBS_SYSTEM $LIBS"
1648
1649 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1650 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1651 AC_CHECK_LIB(dnet, dnet_ntoa)
1652 dnl This causes -lresolv to get used in subsequent tests,
1653 dnl which causes failures on some systems such as HPUX 9.
1654 dnl AC_CHECK_LIB(resolv, gethostbyname)
1655
1656 dnl FIXME replace main with a function we actually want from this library.
1657 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1658
1659 AC_CHECK_LIB(pthreads, cma_open)
1660
1661 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1662 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1663 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1664 ## added to LIBS in configure would never contain the pthreads part,
1665 ## but the value used in Makefiles might.  FIXME?
1666 ##
1667 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1668 ## be harmless on older versions of X where it happens to exist.
1669 test "$opsys" = "aix4-2" && \
1670   test $ac_cv_lib_pthreads_cma_open = yes && \
1671   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1672
1673 dnl Check for need for bigtoc support on IBM AIX
1674
1675 case ${host_os} in
1676 aix*)
1677   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1678     case $GCC in
1679     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1680     *) gdb_cv_bigtoc=-bbigtoc ;;
1681     esac
1682
1683     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1684     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1685   ])
1686   ;;
1687 esac
1688
1689 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1690 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1691 # REAL_CPPFLAGS later on.
1692
1693 REAL_CFLAGS="$CFLAGS"
1694 REAL_CPPFLAGS="$CPPFLAGS"
1695
1696 if test "${HAVE_X11}" = "yes"; then
1697   DEFS="$C_SWITCH_X_SITE $DEFS"
1698   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1699   LIBS="-lX11 $LIBS"
1700   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1701   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1702
1703   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1704   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1705   # but it's more convenient here to set LD_RUN_PATH
1706   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1707   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1708     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1709     export LD_RUN_PATH
1710   fi
1711
1712   if test "${opsys}" = "gnu-linux"; then
1713     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1714     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1715      [[XOpenDisplay ("foo");]])],
1716      [xlinux_first_failure=no],
1717      [xlinux_first_failure=yes])
1718     if test "${xlinux_first_failure}" = "yes"; then
1719       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1720       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1721       OLD_CPPFLAGS="$CPPFLAGS"
1722       OLD_LIBS="$LIBS"
1723       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1724       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1725       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1726       LIBS="$LIBS -b i486-linuxaout"
1727       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1728        [[XOpenDisplay ("foo");]])],
1729        [xlinux_second_failure=no],
1730        [xlinux_second_failure=yes])
1731       if test "${xlinux_second_failure}" = "yes"; then
1732         # If we get the same failure with -b, there is no use adding -b.
1733         # So take it out.  This plays safe.
1734         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1735         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1736         CPPFLAGS="$OLD_CPPFLAGS"
1737         LIBS="$OLD_LIBS"
1738         AC_MSG_RESULT(no)
1739       else
1740         AC_MSG_RESULT(yes)
1741       fi
1742     else
1743       AC_MSG_RESULT(no)
1744     fi
1745   fi
1746
1747   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1748   # header files included from there.
1749   AC_MSG_CHECKING(for Xkb)
1750   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1751 #include <X11/XKBlib.h>]],
1752         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1753         emacs_xkb=yes, emacs_xkb=no)
1754   AC_MSG_RESULT($emacs_xkb)
1755   if test $emacs_xkb = yes; then
1756     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1757   fi
1758
1759   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1760 XScreenNumberOfScreen XSetWMProtocols)
1761 fi
1762
1763 if test "${window_system}" = "x11"; then
1764   AC_MSG_CHECKING(X11 version 6)
1765   AC_CACHE_VAL(emacs_cv_x11_version_6,
1766   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1767 [[#if XlibSpecificationRelease < 6
1768 fail;
1769 #endif
1770 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1771   if test $emacs_cv_x11_version_6 = yes; then
1772     AC_MSG_RESULT(6 or newer)
1773     AC_DEFINE(HAVE_X11R6, 1,
1774               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1775     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1776     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1777     ## XIM support.
1778     case "$opsys" in
1779       sol2-*) : ;;
1780       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1781            [Define if you have usable X11R6-style XIM support.])
1782          ;;
1783     esac
1784   else
1785     AC_MSG_RESULT(before 6)
1786   fi
1787 fi
1788
1789
1790 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1791 HAVE_RSVG=no
1792 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1793   if test "${with_rsvg}" != "no"; then
1794     RSVG_REQUIRED=2.11.0
1795     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1796
1797     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1798     AC_SUBST(RSVG_CFLAGS)
1799     AC_SUBST(RSVG_LIBS)
1800
1801     if test $HAVE_RSVG = yes; then
1802       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1803       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1804       LIBS="$RSVG_LIBS $LIBS"
1805     fi
1806   fi
1807 fi
1808
1809 HAVE_IMAGEMAGICK=no
1810 if test "${HAVE_X11}" = "yes"; then
1811   if test "${with_imagemagick}" != "no"; then
1812     ## 6.2.8 is the earliest version known to work, but earlier versions
1813     ## might work - let us know if you find one.
1814     ## 6.0.7 does not work.  See bug#7955.
1815     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1816     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1817     AC_SUBST(IMAGEMAGICK_CFLAGS)
1818     AC_SUBST(IMAGEMAGICK_LIBS)
1819
1820     if test $HAVE_IMAGEMAGICK = yes; then
1821       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1822       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1823       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1824       AC_CHECK_FUNCS(MagickExportImagePixels)
1825     fi
1826   fi
1827 fi
1828
1829
1830 HAVE_GTK=no
1831 if test "${with_gtk3}" = "yes"; then
1832   GLIB_REQUIRED=2.28
1833   GTK_REQUIRED=3.0
1834   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1835
1836   dnl Checks for libraries.
1837   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1838   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1839      AC_MSG_ERROR($GTK_PKG_ERRORS)
1840   fi
1841   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1842 fi
1843
1844 if test "$pkg_check_gtk" != "yes"; then
1845   HAVE_GTK=no
1846 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1847   GLIB_REQUIRED=2.6
1848   GTK_REQUIRED=2.6
1849   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1850
1851   dnl Checks for libraries.
1852   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1853   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1854      AC_MSG_ERROR($GTK_PKG_ERRORS)
1855   fi
1856 fi
1857 fi
1858
1859 GTK_OBJ=
1860 if test x"$pkg_check_gtk" = xyes; then
1861
1862   AC_SUBST(GTK_CFLAGS)
1863   AC_SUBST(GTK_LIBS)
1864   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1865   CFLAGS="$CFLAGS $GTK_CFLAGS"
1866   LIBS="$GTK_LIBS $LIBS"
1867   dnl Try to compile a simple GTK program.
1868   GTK_COMPILES=no
1869   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1870   if test "${GTK_COMPILES}" != "yes"; then
1871     if test "$USE_X_TOOLKIT" != "maybe"; then
1872       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1873     fi
1874   else
1875     HAVE_GTK=yes
1876     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1877     GTK_OBJ=gtkutil.o
1878     USE_X_TOOLKIT=none
1879     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1880       :
1881     else
1882       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1883        closing open displays.  This is no problem if you just use
1884        one display, but if you use more than one and close one of them
1885        Emacs may crash.]])
1886       sleep 3
1887     fi
1888   fi
1889
1890 fi
1891 AC_SUBST(GTK_OBJ)
1892
1893
1894 if test "${HAVE_GTK}" = "yes"; then
1895
1896   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1897   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1898   if test "$with_toolkit_scroll_bars" != no; then
1899     with_toolkit_scroll_bars=yes
1900   fi
1901
1902   dnl  Check if we have the old file selection dialog declared and
1903   dnl  in the link library.  In 2.x it may be in the library,
1904   dnl  but not declared if deprecated featured has been selected out.
1905   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1906   HAVE_GTK_FILE_SELECTION=no
1907   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1908                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1909 #include <gtk/gtk.h>])
1910   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1911     AC_CHECK_FUNCS(gtk_file_selection_new)
1912   fi
1913
1914   dnl Check if pthreads are available.  Emacs only needs this when using
1915   dnl gtk_file_chooser under Gnome.
1916     HAVE_GTK_AND_PTHREAD=no
1917     AC_CHECK_HEADERS(pthread.h)
1918     if test "$ac_cv_header_pthread_h"; then
1919       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1920     fi
1921     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1922       case "${canonical}" in
1923         *-hpux*) ;;
1924         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1925       esac
1926       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1927                [Define to 1 if you have GTK and pthread (-lpthread).])
1928     fi
1929
1930   dnl Check for functions introduced in 2.14 and later.
1931   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1932                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1933                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1934                  gtk_orientable_set_orientation)
1935
1936 fi
1937
1938 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1939 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1940 dnl also not configured.
1941 HAVE_DBUS=no
1942 DBUS_OBJ=
1943 if test "${with_dbus}" = "yes"; then
1944    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1945    if test "$HAVE_DBUS" = yes; then
1946      LIBS="$LIBS $DBUS_LIBS"
1947      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1948      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1949      DBUS_OBJ=dbusbind.o
1950    fi
1951 fi
1952 AC_SUBST(DBUS_OBJ)
1953
1954 dnl GConf has been tested under GNU/Linux only.
1955 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1956 HAVE_GCONF=no
1957 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1958    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1959    if test "$HAVE_GCONF" = yes; then
1960       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1961       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1962       AC_CHECK_FUNCS([g_type_init])
1963    fi
1964 fi
1965
1966 dnl SELinux is available for GNU/Linux only.
1967 HAVE_LIBSELINUX=no
1968 LIBSELINUX_LIBS=
1969 if test "${with_selinux}" = "yes"; then
1970    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1971    if test "$HAVE_LIBSELINUX" = yes; then
1972       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1973       LIBSELINUX_LIBS=-lselinux
1974    fi
1975 fi
1976 AC_SUBST(LIBSELINUX_LIBS)
1977
1978 HAVE_GNUTLS=no
1979 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
1980 if test "${with_gnutls}" = "yes" ; then
1981   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1982   if test "${HAVE_GNUTLS}" = "yes"; then
1983     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1984   fi
1985
1986   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
1987   LIBS="$LIBGNUTLS_LIBS $LIBS"
1988   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
1989
1990   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
1991     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
1992   fi
1993 fi
1994
1995 AC_SUBST(LIBGNUTLS_LIBS)
1996 AC_SUBST(LIBGNUTLS_CFLAGS)
1997
1998 dnl Do not put whitespace before the #include statements below.
1999 dnl Older compilers (eg sunos4 cc) choke on it.
2000 HAVE_XAW3D=no
2001 LUCID_LIBW=
2002 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2003   if test "$with_xaw3d" != no; then
2004     AC_MSG_CHECKING(for xaw3d)
2005     AC_CACHE_VAL(emacs_cv_xaw3d,
2006     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2007 #include <X11/Intrinsic.h>
2008 #include <X11/Xaw3d/Simple.h>]],
2009       [[]])],
2010       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2011                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2012       emacs_cv_xaw3d=no)])
2013   else
2014     emacs_cv_xaw3d=no
2015   fi
2016   if test $emacs_cv_xaw3d = yes; then
2017     AC_MSG_RESULT([yes; using Lucid toolkit])
2018     USE_X_TOOLKIT=LUCID
2019     HAVE_XAW3D=yes
2020     LUCID_LIBW=-lXaw3d
2021     AC_DEFINE(HAVE_XAW3D, 1,
2022               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2023   else
2024     AC_MSG_RESULT(no)
2025     AC_MSG_CHECKING(for libXaw)
2026     AC_CACHE_VAL(emacs_cv_xaw,
2027     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2028 #include <X11/Intrinsic.h>
2029 #include <X11/Xaw/Simple.h>]],
2030       [[]])],
2031       emacs_cv_xaw=yes,
2032       emacs_cv_xaw=no)])
2033     if test $emacs_cv_xaw = yes; then
2034       AC_MSG_RESULT([yes; using Lucid toolkit])
2035       USE_X_TOOLKIT=LUCID
2036       LUCID_LIBW=-lXaw
2037     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2038       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2039     else
2040       AC_MSG_ERROR([No X toolkit could be found.
2041 If you are sure you want Emacs compiled without an X toolkit, pass
2042   --with-x-toolkit=no
2043 to configure.  Otherwise, install the development libraries for the toolkit
2044 that you want to use (e.g. Gtk+) and re-run configure.])
2045     fi
2046   fi
2047 fi
2048
2049 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2050
2051 LIBXTR6=
2052 if test "${USE_X_TOOLKIT}" != "none"; then
2053   AC_MSG_CHECKING(X11 toolkit version)
2054   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2055   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2056 [[#if XtSpecificationRelease < 6
2057 fail;
2058 #endif
2059 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2060   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2061   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2062     AC_MSG_RESULT(6 or newer)
2063     AC_DEFINE(HAVE_X11XTR6, 1,
2064               [Define to 1 if you have the X11R6 or newer version of Xt.])
2065     LIBXTR6="-lSM -lICE"
2066     case "$opsys" in
2067       ## Use libw.a along with X11R6 Xt.
2068       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2069     esac
2070   else
2071     AC_MSG_RESULT(before 6)
2072   fi
2073
2074 dnl If using toolkit, check whether libXmu.a exists.
2075 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2076   OLDLIBS="$LIBS"
2077   if test x$HAVE_X11XTR6 = xyes; then
2078     LIBS="-lXt -lSM -lICE $LIBS"
2079   else
2080     LIBS="-lXt $LIBS"
2081   fi
2082   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2083   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2084 fi
2085 AC_SUBST(LIBXTR6)
2086
2087 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2088 dnl Why not just test for libxmu in the normal way?
2089 LIBXMU=-lXmu
2090 case $opsys in
2091   ## These systems don't supply Xmu.
2092   hpux* | aix4-2 )
2093     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2094     ;;
2095 esac
2096 AC_SUBST(LIBXMU)
2097
2098 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2099 if test "${HAVE_X11}" = "yes"; then
2100   if test "${USE_X_TOOLKIT}" != "none"; then
2101     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2102   fi
2103 fi
2104
2105 LIBXP=
2106 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2107   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2108   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2109     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2110 int x = 5;
2111 #else
2112 Motif version prior to 2.1.
2113 #endif]])],
2114     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2115   if test $emacs_cv_motif_version_2_1 = yes; then
2116     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2117   else
2118     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2119     # We put this in CFLAGS temporarily to precede other -I options
2120     # that might be in CFLAGS temporarily.
2121     # We put this in CPPFLAGS where it precedes the other -I options.
2122     OLD_CPPFLAGS=$CPPFLAGS
2123     OLD_CFLAGS=$CFLAGS
2124     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2125     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2126     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2127       [[int x = 5;]])],
2128       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2129     if test $emacs_cv_lesstif = yes; then
2130       # Make sure this -I option remains in CPPFLAGS after it is set
2131       # back to REAL_CPPFLAGS.
2132       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2133       # have those other -I options anyway.  Ultimately, having this
2134       # directory ultimately in CPPFLAGS will be enough.
2135       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2136       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2137     else
2138       CFLAGS=$OLD_CFLAGS
2139       CPPFLAGS=$OLD_CPPFLAGS
2140     fi
2141   fi
2142 fi
2143
2144 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2145 dnl using Motif or Xaw3d is available, and unless
2146 dnl --with-toolkit-scroll-bars=no was specified.
2147
2148 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2149             [Define to 1 if we should use toolkit scroll bars.])dnl
2150 USE_TOOLKIT_SCROLL_BARS=no
2151 if test "${with_toolkit_scroll_bars}" != "no"; then
2152   if test "${USE_X_TOOLKIT}" != "none"; then
2153     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2154       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2155       HAVE_XAW3D=no
2156       USE_TOOLKIT_SCROLL_BARS=yes
2157     elif test "${HAVE_XAW3D}" = "yes"; then
2158       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2159       USE_TOOLKIT_SCROLL_BARS=yes
2160     fi
2161   elif test "${HAVE_GTK}" = "yes"; then
2162     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2163     USE_TOOLKIT_SCROLL_BARS=yes
2164   elif test "${HAVE_NS}" = "yes"; then
2165     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2166     USE_TOOLKIT_SCROLL_BARS=yes
2167   fi
2168 fi
2169
2170 dnl See if XIM is available.
2171 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2172           #include <X11/Xlib.h>
2173           #include <X11/Xresource.h>]],
2174          [[XIMProc  callback;]])],
2175          [HAVE_XIM=yes
2176          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2177          HAVE_XIM=no)
2178
2179 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2180
2181 if test "${with_xim}" != "no"; then
2182   AC_DEFINE(USE_XIM, 1,
2183             [Define to 1 if we should use XIM, if it is available.])
2184 fi
2185
2186
2187 if test "${HAVE_XIM}" != "no"; then
2188   late_CFLAGS=$CFLAGS
2189   if test "$GCC" = yes; then
2190     CFLAGS="$CFLAGS --pedantic-errors"
2191   fi
2192   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2193 #include <X11/Xlib.h>
2194 #include <X11/Xresource.h>]],
2195 [[Display *display;
2196 XrmDatabase db;
2197 char *res_name;
2198 char *res_class;
2199 XIMProc  callback;
2200 XPointer *client_data;
2201 #ifndef __GNUC__
2202 /* If we're not using GCC, it's probably not XFree86, and this is
2203    probably right, but we can't use something like --pedantic-errors.  */
2204 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2205                                            char*, XIMProc, XPointer*);
2206 #endif
2207 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2208    client_data);]])],
2209     [emacs_cv_arg6_star=yes])
2210   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2211          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2212 either XPointer or XPointer*.])dnl
2213   if test "$emacs_cv_arg6_star" = yes; then
2214     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2215   else
2216     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2217   fi
2218   CFLAGS=$late_CFLAGS
2219 fi
2220
2221 ### Start of font-backend (under any platform) section.
2222 # (nothing here yet -- this is a placeholder)
2223 ### End of font-backend (under any platform) section.
2224
2225 ### Start of font-backend (under X11) section.
2226 if test "${HAVE_X11}" = "yes"; then
2227    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2228
2229    ## Use -lXft if available, unless `--with-xft=no'.
2230    HAVE_XFT=maybe
2231     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2232       with_xft="no";
2233     fi
2234     if test "x${with_xft}" != "xno"; then
2235
2236       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2237       ## Because xftfont.c uses XRenderQueryExtension, we also
2238       ## need to link to -lXrender.
2239       HAVE_XRENDER=no
2240       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2241       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2242         OLD_CPPFLAGS="$CPPFLAGS"
2243         OLD_CFLAGS="$CFLAGS"
2244         OLD_LIBS="$LIBS"
2245         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2246         CFLAGS="$CFLAGS $XFT_CFLAGS"
2247         XFT_LIBS="-lXrender $XFT_LIBS"
2248         LIBS="$XFT_LIBS $LIBS"
2249         AC_CHECK_HEADER(X11/Xft/Xft.h,
2250           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2251
2252         if test "${HAVE_XFT}" = "yes"; then
2253           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2254             AC_SUBST(XFT_LIBS)
2255           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2256         else
2257           CPPFLAGS="$OLD_CPPFLAGS"
2258           CFLAGS="$OLD_CFLAGS"
2259           LIBS="$OLD_LIBS"
2260         fi                        # "${HAVE_XFT}" = "yes"
2261       fi                          # "$HAVE_XFT" != no
2262     fi                            # "x${with_xft}" != "xno"
2263
2264     ## We used to allow building with FreeType and without Xft.
2265     ## However, the ftx font backend driver is not in good shape.
2266     if test "$HAVE_XFT" != "yes"; then
2267        dnl For the "Does Emacs use" message at the end.
2268        HAVE_XFT=no
2269        HAVE_FREETYPE=no
2270     else
2271        dnl Strict linkers fail with
2272        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2273        dnl if -lfreetype is not specified.
2274        dnl The following is needed to set FREETYPE_LIBS.
2275        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2276                          HAVE_FREETYPE=no)
2277
2278        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2279     fi
2280
2281     HAVE_LIBOTF=no
2282     if test "${HAVE_FREETYPE}" = "yes"; then
2283       AC_DEFINE(HAVE_FREETYPE, 1,
2284                 [Define to 1 if using the freetype and fontconfig libraries.])
2285       if test "${with_libotf}" != "no"; then
2286         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2287                           HAVE_LIBOTF=no)
2288         if test "$HAVE_LIBOTF" = "yes"; then
2289           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2290           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2291                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2292                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2293           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2294             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2295                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2296           fi
2297         fi
2298       fi
2299     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2300     dnl Does the new font backend require it, or can it work without it?
2301     fi
2302
2303     HAVE_M17N_FLT=no
2304     if test "${HAVE_LIBOTF}" = yes; then
2305       if test "${with_m17n_flt}" != "no"; then
2306         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2307         if test "$HAVE_M17N_FLT" = "yes"; then
2308           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2309         fi
2310       fi
2311     fi
2312 else
2313     HAVE_XFT=no
2314     HAVE_FREETYPE=no
2315     HAVE_LIBOTF=no
2316     HAVE_M17N_FLT=no
2317 fi
2318
2319 ### End of font-backend (under X11) section.
2320
2321 AC_SUBST(FREETYPE_CFLAGS)
2322 AC_SUBST(FREETYPE_LIBS)
2323 AC_SUBST(FONTCONFIG_CFLAGS)
2324 AC_SUBST(FONTCONFIG_LIBS)
2325 AC_SUBST(LIBOTF_CFLAGS)
2326 AC_SUBST(LIBOTF_LIBS)
2327 AC_SUBST(M17N_FLT_CFLAGS)
2328 AC_SUBST(M17N_FLT_LIBS)
2329
2330 ### Use -lXpm if available, unless `--with-xpm=no'.
2331 HAVE_XPM=no
2332 LIBXPM=
2333 if test "${HAVE_X11}" = "yes"; then
2334   if test "${with_xpm}" != "no"; then
2335     AC_CHECK_HEADER(X11/xpm.h,
2336       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2337     if test "${HAVE_XPM}" = "yes"; then
2338       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2339       AC_EGREP_CPP(no_return_alloc_pixels,
2340       [#include "X11/xpm.h"
2341 #ifndef XpmReturnAllocPixels
2342 no_return_alloc_pixels
2343 #endif
2344       ], HAVE_XPM=no, HAVE_XPM=yes)
2345
2346       if test "${HAVE_XPM}" = "yes"; then
2347         AC_MSG_RESULT(yes)
2348       else
2349         AC_MSG_RESULT(no)
2350       fi
2351     fi
2352   fi
2353
2354   if test "${HAVE_XPM}" = "yes"; then
2355     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2356     LIBXPM=-lXpm
2357   fi
2358 fi
2359 AC_SUBST(LIBXPM)
2360
2361 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2362 HAVE_JPEG=no
2363 LIBJPEG=
2364 if test "${HAVE_X11}" = "yes"; then
2365   if test "${with_jpeg}" != "no"; then
2366     dnl Checking for jpeglib.h can lose because of a redefinition of
2367     dnl  HAVE_STDLIB_H.
2368     AC_CHECK_HEADER(jerror.h,
2369       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2370   fi
2371
2372   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2373   if test "${HAVE_JPEG}" = "yes"; then
2374     AC_DEFINE(HAVE_JPEG)
2375     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2376         [#include <jpeglib.h>
2377          version=JPEG_LIB_VERSION
2378 ],
2379         [AC_DEFINE(HAVE_JPEG)],
2380         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2381         HAVE_JPEG=no])
2382   fi
2383   if test "${HAVE_JPEG}" = "yes"; then
2384     LIBJPEG=-ljpeg
2385   fi
2386 fi
2387 AC_SUBST(LIBJPEG)
2388
2389 ### Use -lpng if available, unless `--with-png=no'.
2390 HAVE_PNG=no
2391 LIBPNG=
2392 if test "${HAVE_X11}" = "yes"; then
2393   if test "${with_png}" != "no"; then
2394     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2395     # in /usr/include/libpng.
2396     AC_CHECK_HEADERS(png.h libpng/png.h)
2397     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2398       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2399     fi
2400   fi
2401
2402   if test "${HAVE_PNG}" = "yes"; then
2403     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2404     LIBPNG="-lpng -lz -lm"
2405   fi
2406 fi
2407 AC_SUBST(LIBPNG)
2408
2409 ### Use -ltiff if available, unless `--with-tiff=no'.
2410 HAVE_TIFF=no
2411 LIBTIFF=
2412 if test "${HAVE_X11}" = "yes"; then
2413   if test "${with_tiff}" != "no"; then
2414     AC_CHECK_HEADER(tiffio.h,
2415       [tifflibs="-lz -lm"
2416       # At least one tiff package requires the jpeg library.
2417       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2418       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2419   fi
2420
2421   if test "${HAVE_TIFF}" = "yes"; then
2422     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2423     dnl FIXME -lz -lm, as per libpng?
2424     LIBTIFF=-ltiff
2425   fi
2426 fi
2427 AC_SUBST(LIBTIFF)
2428
2429 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2430 HAVE_GIF=no
2431 LIBGIF=
2432 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2433   AC_CHECK_HEADER(gif_lib.h,
2434 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2435 # Earlier versions can crash Emacs.
2436     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2437
2438   if test "$HAVE_GIF" = yes; then
2439     LIBGIF=-lgif
2440   elif test "$HAVE_GIF" = maybe; then
2441 # If gif_lib.h but no libgif, try libungif.
2442     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2443     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2444   fi
2445
2446   if test "${HAVE_GIF}" = "yes"; then
2447     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2448   fi
2449 fi
2450 AC_SUBST(LIBGIF)
2451
2452 dnl Check for required libraries.
2453 if test "${HAVE_X11}" = "yes"; then
2454   MISSING=""
2455   WITH_NO=""
2456   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2457     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2458   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2459     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2460   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2461     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2462   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2463     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2464   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2465     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2466
2467   if test "X${MISSING}" != X; then
2468     AC_MSG_ERROR([The following required libraries were not found:
2469     $MISSING
2470 Maybe some development libraries/packages are missing?
2471 If you don't want to link with them give
2472     $WITH_NO
2473 as options to configure])
2474   fi
2475 fi
2476
2477 ### Use -lgpm if available, unless `--with-gpm=no'.
2478 HAVE_GPM=no
2479 LIBGPM=
2480 if test "${with_gpm}" != "no"; then
2481   AC_CHECK_HEADER(gpm.h,
2482     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2483
2484   if test "${HAVE_GPM}" = "yes"; then
2485     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2486     LIBGPM=-lgpm
2487   fi
2488 fi
2489 AC_SUBST(LIBGPM)
2490
2491 dnl Check for malloc/malloc.h on darwin
2492 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2493
2494 C_SWITCH_X_SYSTEM=
2495 ### Use NeXTstep API to implement GUI.
2496 if test "${HAVE_NS}" = "yes"; then
2497   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2498   if test "${NS_IMPL_COCOA}" = "yes"; then
2499     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2500     GNU_OBJC_CFLAGS=
2501   fi
2502   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2503     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2504     # See also .m.o rule in Makefile.in */
2505     # FIXME: are all these flags really needed?  Document here why.  */
2506     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2507     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2508   fi
2509   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2510     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2511   fi
2512   # We also have mouse menus.
2513   HAVE_MENUS=yes
2514   OTHER_FILES=ns-app
2515 fi
2516
2517
2518 ### Use session management (-lSM -lICE) if available
2519 HAVE_X_SM=no
2520 LIBXSM=
2521 if test "${HAVE_X11}" = "yes"; then
2522   AC_CHECK_HEADER(X11/SM/SMlib.h,
2523     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2524
2525   if test "${HAVE_X_SM}" = "yes"; then
2526     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2527     LIBXSM="-lSM -lICE"
2528     case "$LIBS" in
2529       *-lSM*) ;;
2530       *)      LIBS="$LIBXSM $LIBS" ;;
2531     esac
2532   fi
2533 fi
2534 AC_SUBST(LIBXSM)
2535
2536 ### Use libxml (-lxml2) if available
2537 if test "${with_xml2}" != "no"; then
2538   ### I'm not sure what the version number should be, so I just guessed.
2539   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2540   if test "${HAVE_LIBXML2}" = "yes"; then
2541     LIBS="$LIBXML2_LIBS $LIBS"
2542     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2543     if test "${HAVE_LIBXML2}" = "yes"; then
2544       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2545     else
2546       LIBXML2_LIBS=""
2547       LIBXML2_CFLAGS=""
2548     fi
2549   fi
2550 fi
2551 AC_SUBST(LIBXML2_LIBS)
2552 AC_SUBST(LIBXML2_CFLAGS)
2553
2554 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2555 AC_CACHE_CHECK(whether netdb declares h_errno,
2556                emacs_cv_netdb_declares_h_errno,
2557 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2558   [[return h_errno;]])],
2559   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2560 if test $emacs_cv_netdb_declares_h_errno = yes; then
2561   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2562 fi
2563
2564 AC_FUNC_ALLOCA
2565
2566 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2567 dnl FIXME is there an autoconf test that does the right thing, without
2568 dnl needing to call A_M_E afterwards?
2569 if test x"$ac_cv_func_alloca_works" != xyes; then
2570    AC_MSG_ERROR( [a system implementation of alloca is required] )
2571 fi
2572
2573 # fmod, logb, and frexp are found in -lm on most systems.
2574 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2575 AC_CHECK_LIB(m, sqrt)
2576
2577 # Check for mail-locking functions in a "mail" library.  Probably this should
2578 # have the same check as for liblockfile below.
2579 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2580 if test $have_mail = yes; then
2581   LIBS_MAIL=-lmail
2582   LIBS="$LIBS_MAIL $LIBS"
2583   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2584 else
2585   LIBS_MAIL=
2586 fi
2587 dnl Debian, at least:
2588 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2589 if test $have_lockfile = yes; then
2590    LIBS_MAIL=-llockfile
2591    LIBS="$LIBS_MAIL $LIBS"
2592    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2593 else
2594 # If we have the shared liblockfile, assume we must use it for mail
2595 # locking (e.g. Debian).  If we couldn't link against liblockfile
2596 # (no liblockfile.a installed), ensure that we don't need to.
2597   dnl This works for files generally, not just executables.
2598   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2599   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2600                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2601   if test $ac_cv_prog_liblockfile = yes; then
2602     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2603 This probably means that movemail could lose mail.
2604 There may be a `development' package to install containing liblockfile.])
2605   fi
2606 fi
2607 AC_CHECK_FUNCS(touchlock)
2608 AC_CHECK_HEADERS(maillock.h)
2609 AC_SUBST(LIBS_MAIL)
2610
2611 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2612 ## interlock access to the mail spool.  The alternative is a lock file named
2613 ## /usr/spool/mail/$USER.lock.
2614 mail_lock=no
2615 case "$opsys" in
2616   aix4-2) mail_lock="lockf" ;;
2617
2618   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2619
2620   ## On GNU/Linux systems, both methods are used by various mail programs.
2621   ## I assume most people are using newer mailers that have heard of flock.
2622   ## Change this if you need to.
2623   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2624   ## configure gets the right answers, and that means *NOT* using flock.
2625   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2626   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2627   ## Debian maintainer hasn't provided a clean fix for Emacs.
2628   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2629   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2630   ## correct logic.  -- fx
2631   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2632   ## liblockfile is a Free Software replacement for libmail, used on
2633   ## Debian systems and elsewhere. -rfr.
2634   gnu-*)
2635     mail_lock="flock"
2636     if test $have_mail = yes || test $have_lockfile = yes; then
2637       test $ac_cv_header_maillock_h = yes && mail_lock=no
2638     fi
2639     ;;
2640 esac
2641
2642 BLESSMAIL_TARGET=
2643 case "$mail_lock" in
2644   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2645
2646   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2647
2648   *) BLESSMAIL_TARGET="need-blessmail" ;;
2649 esac
2650 AC_SUBST(BLESSMAIL_TARGET)
2651
2652
2653 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2654 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2655 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2656 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2657 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2658 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2659 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2660 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2661 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2662 cfmakeraw cfsetspeed isnan copysign __executable_start)
2663
2664 dnl Cannot use AC_CHECK_FUNCS
2665 AC_CACHE_CHECK([for __builtin_unwind_init],
2666                emacs_cv_func___builtin_unwind_init,
2667 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2668                 emacs_cv_func___builtin_unwind_init=yes,
2669                 emacs_cv_func___builtin_unwind_init=no)])
2670 if test $emacs_cv_func___builtin_unwind_init = yes; then
2671   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2672             [Define to 1 if you have the `__builtin_unwind_init' function.])
2673 fi
2674
2675 AC_CHECK_HEADERS(sys/un.h)
2676
2677 AC_FUNC_FSEEKO
2678
2679 AC_FUNC_GETPGRP
2680
2681 # Configure gnulib.
2682 gl_ASSERT_NO_GNULIB_POSIXCHECK
2683 gl_ASSERT_NO_GNULIB_TESTS
2684 gl_INIT
2685
2686 # UNIX98 PTYs.
2687 AC_CHECK_FUNCS(grantpt)
2688
2689 # PTY-related GNU extensions.
2690 AC_CHECK_FUNCS(getpt)
2691
2692 # Check this now, so that we will NOT find the above functions in ncurses.
2693 # That is because we have not set up to link ncurses in lib-src.
2694 # It's better to believe a function is not available
2695 # than to expect to find it in ncurses.
2696 # Also we need tputs and friends to be able to build at all.
2697 have_tputs_et_al=true
2698 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2699 if test "$have_tputs_et_al" != true; then
2700   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2701 Maybe some development libraries/packages are missing?  Try installing
2702 libncurses-dev(el), libterminfo-dev(el) or similar.])
2703 fi
2704 # Must define this when any termcap library is found.
2705 AC_DEFINE(HAVE_LIBNCURSES, 1,
2706           [Define to 1 if you have the `ncurses' library (-lncurses).])
2707 ## FIXME This was the cpp logic, but I am not sure it is right.
2708 ## The above test has not necessarily found libncurses.
2709 HAVE_LIBNCURSES=yes
2710
2711 ## Use terminfo instead of termcap?
2712 ## Note only system files NOT using terminfo are:
2713 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2714 ## darwin|gnu without ncurses.
2715 TERMINFO=no
2716 LIBS_TERMCAP=
2717 case "$opsys" in
2718   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2719   ## hpux10-20: Use the system provided termcap(3) library.
2720   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2721   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2722   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2723
2724   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2725   ##  The ncurses library has been moved out of the System framework in
2726   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2727   ##  option to use it.
2728   darwin|gnu*)
2729     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2730     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2731       TERMINFO=yes
2732       LIBS_TERMCAP="-lncurses"
2733     fi
2734     ;;
2735
2736   freebsd)
2737     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2738     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2739     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2740 [[#if __FreeBSD_version < 400000
2741 fail;
2742 #endif
2743 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2744
2745     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2746
2747     if test $emacs_cv_freebsd_terminfo = yes; then
2748       TERMINFO=yes
2749       LIBS_TERMCAP="-lncurses"
2750     else
2751       LIBS_TERMCAP="-ltermcap"
2752     fi
2753     ;;
2754
2755   netbsd)
2756     if test $ac_cv_search_tputs = -lterminfo; then
2757       TERMINFO=yes
2758       LIBS_TERMCAP="-lterminfo"
2759     else
2760       LIBS_TERMCAP="-ltermcap"
2761     fi
2762     ;;
2763
2764 esac
2765
2766 case "$opsys" in
2767   ## hpux: Make sure we get select from libc rather than from libcurses
2768   ##  because libcurses on HPUX 10.10 has a broken version of select.
2769   ##  We used to use -lc -lcurses, but this may be cleaner.
2770   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2771
2772   openbsd) LIBS_TERMCAP="-lncurses" ;;
2773
2774   ## Must use system termcap, if we use any termcap.  It does special things.
2775   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2776 esac
2777
2778 TERMCAP_OBJ=tparam.o
2779 if test $TERMINFO = yes; then
2780   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2781
2782   ## Default used to be -ltermcap.  Add a case above if need something else.
2783   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2784
2785   TERMCAP_OBJ=terminfo.o
2786 fi
2787 AC_SUBST(LIBS_TERMCAP)
2788 AC_SUBST(TERMCAP_OBJ)
2789
2790
2791 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2792 resolv=no
2793 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2794 #include <arpa/nameser.h>
2795 #include <resolv.h>]],
2796     [[return res_init();]])],
2797     have_res_init=yes, have_res_init=no)
2798 if test "$have_res_init" = no; then
2799   OLIBS="$LIBS"
2800   LIBS="$LIBS -lresolv"
2801   AC_MSG_CHECKING(for res_init with -lresolv)
2802   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2803 #include <arpa/nameser.h>
2804 #include <resolv.h>]],
2805     [[return res_init();]])],
2806     have_res_init=yes, have_res_init=no)
2807   AC_MSG_RESULT($have_res_init)
2808   if test "$have_res_init" = yes ; then
2809     resolv=yes
2810   fi
2811   LIBS="$OLIBS"
2812 fi
2813
2814 if test "$have_res_init" = yes; then
2815   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2816 fi
2817
2818 # Do we need the Hesiod library to provide the support routines?
2819 LIBHESIOD=
2820 if test "$with_hesiod" != no ; then
2821   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2822   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2823      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2824                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2825   if test "$resolv" = yes ; then
2826     RESOLVLIB=-lresolv
2827   else
2828     RESOLVLIB=
2829   fi
2830   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2831         hesiod=yes, :, $RESOLVLIB)])
2832
2833   if test x"$hesiod" = xyes; then
2834     AC_DEFINE(HAVE_LIBHESIOD, 1,
2835               [Define to 1 if you have the hesiod library (-lhesiod).])
2836     LIBHESIOD=-lhesiod
2837   fi
2838 fi
2839 AC_SUBST(LIBHESIOD)
2840
2841 # Do we need libresolv (due to res_init or Hesiod)?
2842 if test "$resolv" = yes ; then
2843   AC_DEFINE(HAVE_LIBRESOLV, 1,
2844             [Define to 1 if you have the resolv library (-lresolv).])
2845   LIBRESOLV=-lresolv
2846 else
2847   LIBRESOLV=
2848 fi
2849 AC_SUBST(LIBRESOLV)
2850
2851 # These tell us which Kerberos-related libraries to use.
2852 COM_ERRLIB=
2853 CRYPTOLIB=
2854 KRB5LIB=
2855 DESLIB=
2856 KRB4LIB=
2857
2858 if test "${with_kerberos}" != no; then
2859   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2860   if test $have_com_err = yes; then
2861     COM_ERRLIB=-lcom_err
2862     LIBS="$COM_ERRLIB $LIBS"
2863     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2864   fi
2865   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2866   if test $have_crypto = yes; then
2867     CRYPTOLIB=-lcrypto
2868     LIBS="$CRYPTOLIB $LIBS"
2869     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2870   fi
2871   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2872   if test $have_k5crypto = yes; then
2873     CRYPTOLIB=-lk5crypto
2874     LIBS="$CRYPTOLIB $LIBS"
2875     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2876   fi
2877   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2878   if test $have_krb5=yes; then
2879     KRB5LIB=-lkrb5
2880     LIBS="$KRB5LIB $LIBS"
2881     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2882   fi
2883   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2884   if test "${with_kerberos5}" = no; then
2885     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2886     if test $have_des425 = yes; then
2887       DESLIB=-ldes425
2888       LIBS="$DESLIB $LIBS"
2889       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2890     else
2891       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2892       if test $have_des = yes; then
2893         DESLIB=-ldes
2894         LIBS="$DESLIB $LIBS"
2895         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2896       fi
2897     fi
2898     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2899     if test $have_krb4 = yes; then
2900       KRB4LIB=-lkrb4
2901       LIBS="$KRB4LIB $LIBS"
2902       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2903     else
2904       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2905       if test $have_krb = yes; then
2906         KRB4LIB=-lkrb
2907         LIBS="$KRB4LIB $LIBS"
2908         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2909       fi
2910     fi
2911   fi
2912
2913   if test "${with_kerberos5}" != no; then
2914     AC_CHECK_HEADERS(krb5.h,
2915       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2916                         [#include <krb5.h>])])
2917   else
2918     AC_CHECK_HEADERS(des.h,,
2919                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2920                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2921     AC_CHECK_HEADERS(krb.h,,
2922                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2923                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2924   fi
2925   AC_CHECK_HEADERS(com_err.h)
2926 fi
2927
2928 AC_SUBST(COM_ERRLIB)
2929 AC_SUBST(CRYPTOLIB)
2930 AC_SUBST(KRB5LIB)
2931 AC_SUBST(DESLIB)
2932 AC_SUBST(KRB4LIB)
2933
2934 # Solaris requires -lintl if you want strerror (which calls dgettext)
2935 # to return localized messages.
2936 AC_CHECK_LIB(intl, dgettext)
2937
2938 AC_MSG_CHECKING(whether localtime caches TZ)
2939 AC_CACHE_VAL(emacs_cv_localtime_cache,
2940 [if test x$ac_cv_func_tzset = xyes; then
2941 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2942 char TZ_GMT0[] = "TZ=GMT0";
2943 char TZ_PST8[] = "TZ=PST8";
2944 main()
2945 {
2946   time_t now = time ((time_t *) 0);
2947   int hour_GMT0, hour_unset;
2948   if (putenv (TZ_GMT0) != 0)
2949     exit (1);
2950   hour_GMT0 = localtime (&now)->tm_hour;
2951   unsetenv("TZ");
2952   hour_unset = localtime (&now)->tm_hour;
2953   if (putenv (TZ_PST8) != 0)
2954     exit (1);
2955   if (localtime (&now)->tm_hour == hour_GMT0)
2956     exit (1);
2957   unsetenv("TZ");
2958   if (localtime (&now)->tm_hour != hour_unset)
2959     exit (1);
2960   exit (0);
2961 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2962 [# If we have tzset, assume the worst when cross-compiling.
2963 emacs_cv_localtime_cache=yes])
2964 else
2965         # If we lack tzset, report that localtime does not cache TZ,
2966         # since we can't invalidate the cache if we don't have tzset.
2967         emacs_cv_localtime_cache=no
2968 fi])dnl
2969 AC_MSG_RESULT($emacs_cv_localtime_cache)
2970 if test $emacs_cv_localtime_cache = yes; then
2971   AC_DEFINE(LOCALTIME_CACHE, 1,
2972             [Define to 1 if localtime caches TZ.])
2973 fi
2974
2975 if test "x$HAVE_TIMEVAL" = xyes; then
2976   AC_CHECK_FUNCS(gettimeofday)
2977   if test $ac_cv_func_gettimeofday = yes; then
2978     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2979                    emacs_cv_gettimeofday_two_arguments,
2980     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2981 #ifdef TIME_WITH_SYS_TIME
2982 #include <sys/time.h>
2983 #include <time.h>
2984 #else
2985 #ifdef HAVE_SYS_TIME_H
2986 #include <sys/time.h>
2987 #else
2988 #include <time.h>
2989 #endif
2990 #endif]],
2991       [[struct timeval time;
2992        gettimeofday (&time, 0);]])],
2993       emacs_cv_gettimeofday_two_arguments=yes,
2994       emacs_cv_gettimeofday_two_arguments=no)])
2995     if test $emacs_cv_gettimeofday_two_arguments = no; then
2996       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2997                 [Define to 1 if gettimeofday accepts only one argument.])
2998     fi
2999   fi
3000 fi
3001
3002 ok_so_far=yes
3003 AC_CHECK_FUNC(socket, , ok_so_far=no)
3004 if test $ok_so_far = yes; then
3005   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3006 fi
3007 if test $ok_so_far = yes; then
3008   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3009 fi
3010 if test $ok_so_far = yes; then
3011 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3012   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3013             [Define to 1 if you have inet sockets.])
3014 fi
3015
3016 if test -f /usr/lpp/X11/bin/smt.exp; then
3017   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3018             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3019 fi
3020
3021 AC_MSG_CHECKING(whether system supports dynamic ptys)
3022 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3023   AC_MSG_RESULT(yes)
3024   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3025 else
3026   AC_MSG_RESULT(no)
3027 fi
3028
3029 AC_FUNC_FORK
3030
3031 dnl Adapted from Haible's version.
3032 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3033   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3034     [[char* cs = nl_langinfo(CODESET);]])],
3035     emacs_cv_langinfo_codeset=yes,
3036     emacs_cv_langinfo_codeset=no)
3037   ])
3038 if test $emacs_cv_langinfo_codeset = yes; then
3039   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3040     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3041 fi
3042
3043 AC_TYPE_MBSTATE_T
3044
3045 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3046   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3047                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3048 if test "$emacs_cv_c_restrict_arr" = yes; then
3049   AC_DEFINE(__restrict_arr, __restrict,
3050     [Define to compiler's equivalent of C99 restrict keyword in array
3051      declarations.  Define as empty for no equivalent.])
3052 fi
3053
3054 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3055 dnl how the tty code is related to POSIX and/or other versions of termios.
3056 dnl The following looks like a useful start.
3057 dnl
3058 dnl AC_SYS_POSIX_TERMIOS
3059 dnl if test $ac_cv_sys_posix_termios = yes; then
3060 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3061 dnl                                and macros for terminal control.])
3062 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3063 dnl fi
3064
3065 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3066
3067 # Set up the CFLAGS for real compilation, so we can substitute it.
3068 CFLAGS="$REAL_CFLAGS"
3069 CPPFLAGS="$REAL_CPPFLAGS"
3070
3071 ## Hack to detect a buggy GCC version.
3072 if test "x$GCC" = xyes \
3073    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3074    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3075    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3076    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3077 fi
3078
3079 version=$PACKAGE_VERSION
3080
3081 ### Specify what sort of things we'll be editing into Makefile and config.h.
3082 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3083 AC_SUBST(version)
3084 AC_SUBST(configuration)
3085 ## Unused?
3086 AC_SUBST(canonical)
3087 AC_SUBST(srcdir)
3088 AC_SUBST(prefix)
3089 AC_SUBST(exec_prefix)
3090 AC_SUBST(bindir)
3091 AC_SUBST(datadir)
3092 AC_SUBST(sharedstatedir)
3093 AC_SUBST(libexecdir)
3094 AC_SUBST(mandir)
3095 AC_SUBST(infodir)
3096 AC_SUBST(lispdir)
3097 AC_SUBST(locallisppath)
3098 AC_SUBST(lisppath)
3099 AC_SUBST(x_default_search_path)
3100 AC_SUBST(etcdir)
3101 AC_SUBST(archlibdir)
3102 AC_SUBST(docdir)
3103 AC_SUBST(bitmapdir)
3104 AC_SUBST(gamedir)
3105 AC_SUBST(gameuser)
3106 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3107 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3108 ## end of LIBX_BASE, but nothing ever set it.
3109 AC_SUBST(LD_SWITCH_X_SITE)
3110 AC_SUBST(C_SWITCH_X_SITE)
3111 AC_SUBST(C_SWITCH_X_SYSTEM)
3112 AC_SUBST(CFLAGS)
3113 ## Used in lwlib/Makefile.in.
3114 AC_SUBST(X_TOOLKIT_TYPE)
3115 if test -n "${machfile}"; then
3116   M_FILE="\$(srcdir)/${machfile}"
3117 else
3118   M_FILE=
3119 fi
3120 S_FILE="\$(srcdir)/${opsysfile}"
3121 AC_SUBST(M_FILE)
3122 AC_SUBST(S_FILE)
3123 AC_SUBST(ns_appdir)
3124 AC_SUBST(ns_appbindir)
3125 AC_SUBST(ns_appresdir)
3126 AC_SUBST(ns_appsrc)
3127 AC_SUBST(GNU_OBJC_CFLAGS)
3128 AC_SUBST(OTHER_FILES)
3129
3130 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3131                    [Define to the canonical Emacs configuration name.])
3132 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3133                    [Define to the options passed to configure.])
3134 if test -n "$machfile"; then
3135   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3136                      [Define to the used machine dependent file.])
3137 fi
3138 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3139                    [Define to the used os dependent file.])
3140
3141 XMENU_OBJ=
3142 XOBJ=
3143 FONT_OBJ=
3144 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3145   AC_DEFINE(HAVE_X_WINDOWS, 1,
3146             [Define to 1 if you want to use the X window system.])
3147   XMENU_OBJ=xmenu.o
3148   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3149   FONT_OBJ=xfont.o
3150   if test "$HAVE_XFT" = "yes"; then
3151     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3152   elif test "$HAVE_FREETYPE" = "yes"; then
3153     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3154   fi
3155   AC_SUBST(FONT_OBJ)
3156 fi
3157 AC_SUBST(XMENU_OBJ)
3158 AC_SUBST(XOBJ)
3159 AC_SUBST(FONT_OBJ)
3160
3161 WIDGET_OBJ=
3162 MOTIF_LIBW=
3163 if test "${USE_X_TOOLKIT}" != "none" ; then
3164   WIDGET_OBJ=widget.o
3165   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3166   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3167     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3168   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3169     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3170     MOTIF_LIBW=-lXm
3171     case "$opsys" in
3172       gnu-linux)
3173         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3174         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3175         ;;
3176
3177       unixware)
3178         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3179         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3180         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3181         ;;
3182
3183       aix4-2)
3184         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3185         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3186         ;;
3187     esac
3188     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3189   fi
3190 fi
3191 AC_SUBST(WIDGET_OBJ)
3192
3193 TOOLKIT_LIBW=
3194 case "$USE_X_TOOLKIT" in
3195   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3196   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3197   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3198 esac
3199 AC_SUBST(TOOLKIT_LIBW)
3200
3201 if test "$USE_X_TOOLKIT" = "none"; then
3202   LIBXT_OTHER="\$(LIBXSM)"
3203   OLDXMENU_TARGET="really-oldXMenu"
3204 else
3205   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3206   OLDXMENU_TARGET="really-lwlib"
3207 fi
3208 AC_SUBST(LIBXT_OTHER)
3209
3210 ## The X Menu stuff is present in the X10 distribution, but missing
3211 ## from X11.  If we have X10, just use the installed library;
3212 ## otherwise, use our own copy.
3213 if test "${HAVE_X11}" = "yes" ; then
3214   AC_DEFINE(HAVE_X11, 1,
3215             [Define to 1 if you want to use version 11 of X windows.
3216              Otherwise, Emacs expects to use version 10.])
3217
3218   if test "$USE_X_TOOLKIT" = "none"; then
3219     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3220   else
3221     OLDXMENU="\${lwlibdir}/liblw.a"
3222   fi
3223   LIBXMENU="\$(OLDXMENU)"
3224   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3225   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3226 else
3227   ## For a syntactically valid Makefile; not actually used for anything.
3228   ## See comments in src/Makefile.in.
3229   OLDXMENU=nothing
3230   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3231   if test "${HAVE_X_WINDOWS}" = "yes"; then
3232     LIBXMENU="-lXMenu"
3233   else
3234     LIBXMENU=
3235   fi
3236   LIBX_OTHER=
3237   OLDXMENU_DEPS=
3238 fi
3239
3240 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3241   OLDXMENU_TARGET=
3242   OLDXMENU=nothing
3243   LIBXMENU=
3244   OLDXMENU_DEPS=
3245 fi
3246
3247 AC_SUBST(OLDXMENU_TARGET)
3248 AC_SUBST(OLDXMENU)
3249 AC_SUBST(LIBXMENU)
3250 AC_SUBST(LIBX_OTHER)
3251 AC_SUBST(OLDXMENU_DEPS)
3252
3253 if test "${HAVE_MENUS}" = "yes" ; then
3254   AC_DEFINE(HAVE_MENUS, 1,
3255             [Define to 1 if you have mouse menus.
3256              (This is automatic if you use X, but the option to specify it remains.)
3257              It is also defined with other window systems that support xmenu.c.])
3258 fi
3259
3260 if test "${GNU_MALLOC}" = "yes" ; then
3261   AC_DEFINE(GNU_MALLOC, 1,
3262             [Define to 1 if you want to use the GNU memory allocator.])
3263 fi
3264
3265 RALLOC_OBJ=
3266 if test "${REL_ALLOC}" = "yes" ; then
3267   AC_DEFINE(REL_ALLOC, 1,
3268             [Define REL_ALLOC if you want to use the relocating allocator for
3269              buffer space.])
3270
3271   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3272 fi
3273 AC_SUBST(RALLOC_OBJ)
3274
3275 if test "$opsys" = "cygwin"; then
3276   CYGWIN_OBJ="sheap.o"
3277   ## Cygwin differs because of its unexec().
3278   PRE_ALLOC_OBJ=
3279   POST_ALLOC_OBJ=lastfile.o
3280 else
3281   CYGWIN_OBJ=
3282   PRE_ALLOC_OBJ=lastfile.o
3283   POST_ALLOC_OBJ=
3284 fi
3285 AC_SUBST(CYGWIN_OBJ)
3286 AC_SUBST(PRE_ALLOC_OBJ)
3287 AC_SUBST(POST_ALLOC_OBJ)
3288
3289
3290 case "$opsys" in
3291   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3292
3293   darwin)
3294    ## The -headerpad option tells ld (see man page) to leave room at the
3295    ## end of the header for adding load commands.  Needed for dumping.
3296    ## 0x690 is the total size of 30 segment load commands (at 56
3297    ## each); under Cocoa 31 commands are required.
3298    if test "$HAVE_NS" = "yes"; then
3299      libs_nsgui="-framework AppKit"
3300      headerpad_extra=6C8
3301    else
3302      libs_nsgui=
3303      headerpad_extra=690
3304    fi
3305    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3306
3307    ## This is here because src/Makefile.in did some extra fiddling around
3308    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3309    ##   #ifndef LD_SWITCH_SYSTEM
3310    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3311    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3312    ## not using gcc, darwin system not on an alpha (ie darwin, since
3313    ## darwin + alpha does not occur).
3314    ## Because this was done in src/Makefile.in, the resulting part of
3315    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3316    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3317    ## rather than LD_SWITCH_SYSTEM.
3318    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3319      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3320    ;;
3321
3322   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3323   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3324   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3325   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3326   ## had different values in configure (in ac_link) and src/Makefile.in.
3327   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3328   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3329
3330   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3331 esac
3332
3333 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3334   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3335 fi
3336
3337 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3338
3339
3340 LD_FIRSTFLAG=
3341 ORDINARY_LINK=
3342 case "$opsys" in
3343   ## gnu: GNU needs its own crt0.
3344   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3345
3346   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3347   ## library search parth, i.e. it won't search /usr/lib for libc and
3348   ## friends.  Using -nostartfiles instead avoids this problem, and
3349   ## will also work on earlier NetBSD releases.
3350   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3351
3352   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3353   ##   MkLinux/LinuxPPC needs this.
3354   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3355   gnu-*)
3356     case "$machine" in
3357       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3358     esac
3359     ;;
3360 esac
3361
3362
3363 if test "x$ORDINARY_LINK" = "xyes"; then
3364
3365   LD_FIRSTFLAG=""
3366   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3367
3368 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3369 ## freebsd, gnu-* not on macppc|ibms390x.
3370 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3371
3372   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3373   ## places that are difficult to figure out at make time.  Fortunately,
3374   ## these same versions allow you to pass arbitrary flags on to the
3375   ## linker, so there is no reason not to use it as a linker.
3376   ##
3377   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3378   ## searching for libraries in its internal directories, so we have to
3379   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3380   LD_FIRSTFLAG="-nostdlib"
3381 fi
3382
3383 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3384 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3385
3386 AC_SUBST(LD_FIRSTFLAG)
3387
3388
3389 ## FIXME? The logic here is not precisely the same as that above.
3390 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3391 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3392 LIB_GCC=
3393 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3394
3395   case "$opsys" in
3396     freebsd|netbsd|openbsd) LIB_GCC= ;;
3397
3398     gnu-*)
3399       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3400       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3401       case $host_cpu in
3402       arm*)
3403         LIB_GCC="-lgcc_s"
3404         ;;
3405       *)
3406         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3407         ## immediately undefine it again and redefine it to empty.
3408         ## Was the C_SWITCH_X_SITE part really necessary?
3409 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3410         LIB_GCC=
3411         ;;
3412       esac
3413       ;;
3414
3415     ## Ask GCC where to find libgcc.a.
3416     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3417   esac
3418 fi                              dnl if $GCC
3419 AC_SUBST(LIB_GCC)
3420
3421
3422 ## If we're using X11/GNUstep, define some consequences.
3423 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3424   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3425   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3426 fi
3427
3428
3429 AH_TOP([/* GNU Emacs site configuration template file.
3430
3431 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3432   Free Software Foundation, Inc.
3433
3434 This file is part of GNU Emacs.
3435
3436 GNU Emacs is free software: you can redistribute it and/or modify
3437 it under the terms of the GNU General Public License as published by
3438 the Free Software Foundation, either version 3 of the License, or
3439 (at your option) any later version.
3440
3441 GNU Emacs is distributed in the hope that it will be useful,
3442 but WITHOUT ANY WARRANTY; without even the implied warranty of
3443 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3444 GNU General Public License for more details.
3445
3446 You should have received a copy of the GNU General Public License
3447 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3448
3449
3450 /* No code in Emacs #includes config.h twice, but some bits of code
3451    intended to work with other packages as well (like gmalloc.c)
3452    think they can include it as many times as they like.  */
3453 #ifndef EMACS_CONFIG_H
3454 #define EMACS_CONFIG_H
3455 ])dnl
3456
3457 AH_BOTTOM([
3458 /* Define AMPERSAND_FULL_NAME if you use the convention
3459    that & in the full name stands for the login id.  */
3460 /* Turned on June 1996 supposing nobody will mind it.  */
3461 #define AMPERSAND_FULL_NAME
3462
3463 /* If using GNU, then support inline function declarations.  */
3464 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3465    generally, because even if non-gcc compilers accept `inline', they
3466    may reject `extern inline'.  */
3467 #if defined (__GNUC__)
3468 #define INLINE __inline__
3469 #else
3470 #define INLINE
3471 #endif
3472
3473 /* `subprocesses' should be defined if you want to
3474    have code for asynchronous subprocesses
3475    (as used in M-x compile and M-x shell).
3476    Only MSDOS does not support this (it overrides
3477    this in its config_opsysfile below).  */
3478
3479 #define subprocesses
3480
3481 /* Include the os and machine dependent files.  */
3482 #include config_opsysfile
3483 #ifdef config_machfile
3484 # include config_machfile
3485 #endif
3486
3487 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3488    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3489   (There is probably a better place to do this, but right now the
3490    Cocoa side does this in s/darwin.h and we cannot parallel this
3491    exactly since GNUstep is multi-OS.  */
3492 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3493 #  define SYSTEM_PURESIZE_EXTRA 30000
3494 #endif
3495
3496 #ifdef emacs /* Don't do this for lib-src.  */
3497 /* Tell regex.c to use a type compatible with Emacs.  */
3498 #define RE_TRANSLATE_TYPE Lisp_Object
3499 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3500 #ifdef make_number
3501 /* If make_number is a macro, use it.  */
3502 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3503 #else
3504 /* If make_number is a function, avoid it.  */
3505 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3506 #endif
3507 #endif
3508
3509 /* These default definitions are good for almost all machines.
3510    Any exceptions should override them in m/MACHINE.h.
3511    They must be usable in preprocessor conditionals.  */
3512
3513 #ifndef BITS_PER_CHAR
3514 #define BITS_PER_CHAR 8
3515 #endif
3516
3517 #ifndef BITS_PER_SHORT
3518 #define BITS_PER_SHORT 16
3519 #endif
3520
3521 #ifndef BITS_PER_INT
3522 #define BITS_PER_INT 32
3523 #endif
3524
3525 #ifndef BITS_PER_LONG
3526 #ifdef _LP64
3527 #define BITS_PER_LONG 64
3528 #else
3529 #define BITS_PER_LONG 32
3530 #endif
3531 #endif
3532
3533 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3534 #define BITS_PER_LONG_LONG 64
3535 #endif
3536
3537 /* Define if the compiler supports function prototypes.  It may do so but
3538    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3539 #undef PROTOTYPES
3540
3541 #include <string.h>
3542 #include <stdlib.h>
3543
3544 #ifdef HAVE_ALLOCA_H
3545 # include <alloca.h>
3546 #elif defined __GNUC__
3547 # define alloca __builtin_alloca
3548 #elif defined _AIX
3549 # define alloca __alloca
3550 #else
3551 # include <stddef.h>
3552 # ifdef  __cplusplus
3553 extern "C"
3554 # endif
3555 void *alloca (size_t);
3556 #endif
3557
3558 #ifndef HAVE_STRCHR
3559 #define strchr(a, b) index (a, b)
3560 #endif
3561
3562 #ifndef HAVE_STRRCHR
3563 #define strrchr(a, b) rindex (a, b)
3564 #endif
3565
3566 #if defined __GNUC__ && (__GNUC__ > 2 \
3567                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3568 #define NO_RETURN       __attribute__ ((__noreturn__))
3569 #else
3570 #define NO_RETURN       /* nothing */
3571 #endif
3572
3573 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3574 #define NO_INLINE __attribute__((noinline))
3575 #else
3576 #define NO_INLINE
3577 #endif
3578
3579 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3580 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3581 #else
3582 #define EXTERNALLY_VISIBLE
3583 #endif
3584
3585 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3586 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3587 #else
3588 # define ATTRIBUTE_FORMAT(spec) /* empty */
3589 #endif
3590
3591 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3592 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3593    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3594 #else
3595 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3596    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3597 #endif
3598
3599 /* Some versions of GNU/Linux define noinline in their headers.  */
3600 #ifdef noinline
3601 #undef noinline
3602 #endif
3603
3604 /* These won't be used automatically yet.  We also need to know, at least,
3605    that the stack is continuous.  */
3606 #ifdef __GNUC__
3607 #  ifndef GC_SETJMP_WORKS
3608   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3609 #    define GC_SETJMP_WORKS 1
3610 #  endif
3611 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3612 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3613 #  endif
3614 #endif
3615
3616 #endif /* EMACS_CONFIG_H */
3617
3618 /*
3619 Local Variables:
3620 mode: c
3621 End:
3622 */
3623 ])dnl
3624
3625 #### Report on what we decided to do.
3626 #### Report GTK as a toolkit, even if it doesn't use Xt.
3627 #### It makes printing result more understandable as using GTK sets
3628 #### toolkit_scroll_bars to yes by default.
3629 if test "${HAVE_GTK}" = "yes"; then
3630   USE_X_TOOLKIT=GTK
3631 fi
3632
3633 and_machfile=
3634 if test -n "$machfile"; then
3635   and_machfile=" and \`${machfile}'"
3636 fi
3637
3638 echo "
3639 Configured for \`${canonical}'.
3640
3641   Where should the build process find the source code?    ${srcdir}
3642   What operating system and machine description files should Emacs use?
3643         \`${opsysfile}'${and_machfile}
3644   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3645   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3646   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3647   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3648   What window system should Emacs use?                    ${window_system}
3649   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3650
3651 if test -n "${x_includes}"; then
3652 echo "  Where do we find X Windows header files?                ${x_includes}"
3653 else
3654 echo "  Where do we find X Windows header files?                Standard dirs"
3655 fi
3656 if test -n "${x_libraries}"; then
3657 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3658 else
3659 echo "  Where do we find X Windows libraries?                   Standard dirs"
3660 fi
3661
3662 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3663 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3664 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3665 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3666 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3667 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3668 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3669 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3670
3671 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3672 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3673 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3674 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3675 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3676 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3677
3678 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3679 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3680 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3681 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3682
3683 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3684 echo
3685
3686 if test $USE_XASSERTS = yes; then
3687    echo "  Compiling with asserts turned on."
3688    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3689 fi
3690
3691 echo
3692
3693 if test "$HAVE_NS" = "yes"; then
3694    echo
3695    echo "You must run \"make install\" in order to test the built application.
3696 The installed application will go to nextstep/Emacs.app and can be
3697 run or moved from there."
3698    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3699       echo "The application will be fully self-contained."
3700     else
3701       echo "The lisp resources for the application will be installed under ${prefix}.
3702 You may need to run \"make install\" with sudo.  The application will fail
3703 to run if these resources are not installed."
3704    fi
3705    echo
3706 fi
3707
3708
3709 # Remove any trailing slashes in these variables.
3710 [test "${prefix}" != NONE &&
3711   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3712 test "${exec_prefix}" != NONE &&
3713   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3714
3715 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3716         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3717         doc/lispref/Makefile src/Makefile \
3718         lwlib/Makefile lisp/Makefile leim/Makefile])
3719
3720 dnl test/ is not present in release tarfiles.
3721 if test -f $srcdir/test/automated/Makefile.in; then
3722   OPT_MAKEFILES_IN="\$(srcdir)/test/automated/Makefile.in"
3723   AC_CONFIG_FILES([test/automated/Makefile])
3724 else
3725   OPT_MAKEFILES_IN=
3726 fi
3727 AC_SUBST(OPT_MAKEFILES_IN)
3728
3729 dnl Make the necessary directories, if they don't exist.
3730 AC_CONFIG_COMMANDS([mkdirs], [
3731 for dir in etc lisp ; do
3732   test -d ${dir} || mkdir ${dir}
3733 done
3734 ])
3735
3736 dnl You might wonder (I did) why epaths.h is generated by running make,
3737 dnl rather than just letting configure generate it from epaths.in.
3738 dnl One reason is that the various paths are not fully expanded (see above);
3739 dnl eg gamedir=${prefix}/var/games/emacs.
3740 dnl Secondly, the GNU Coding standards require that one should be able
3741 dnl to run `make prefix=/some/where/else' and override the values set
3742 dnl by configure.  This also explains the `move-if-change' test and
3743 dnl the use of force in the `epaths-force' rule in Makefile.in.
3744 AC_CONFIG_COMMANDS([epaths], [
3745 echo creating src/epaths.h
3746 ${MAKE-make} epaths-force
3747 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3748
3749 AC_CONFIG_COMMANDS([gdbinit], [
3750 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3751   echo creating src/.gdbinit
3752   echo source $srcdir/src/.gdbinit > src/.gdbinit
3753 fi
3754 ])
3755
3756 AC_OUTPUT
3757
3758 dnl configure.in ends here