lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes.
   2 ;;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: FSF
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 \f
  26 ;;; Commentary:
  27
  28 ;; GNU Emacs is already, in a sense, object oriented -- each object
  29 ;; (buffer) belongs to a class (major mode), and that class defines
  30 ;; the relationship between messages (input events) and methods
  31 ;; (commands) by means of a keymap.
  32 ;;
  33 ;; The only thing missing is a good scheme of inheritance.  It is
  34 ;; possible to simulate a single level of inheritance with generous
  35 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  36 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  37 ;; -- but generally, each major mode ends up reinventing the wheel.
  38 ;; Ideally, someone should redesign all of Emacs's major modes to
  39 ;; follow a more conventional object-oriented system: when defining a
  40 ;; new major mode, the user should need only to name the existing mode
  41 ;; it is most similar to, then list the (few) differences.
  42 ;;
  43 ;; In the mean time, this package offers most of the advantages of
  44 ;; full inheritance with the existing major modes.  The macro
  45 ;; `define-derived-mode' allows the user to make a variant of an existing
  46 ;; major mode, with its own keymap.  The new mode will inherit the key
  47 ;; bindings of its parent, and will, in fact, run its parent first
  48 ;; every time it is called.  For example, the commands
  49 ;;
  50 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  51 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  52 ;;    (setq case-fold-search nil))
  53 ;;
  54 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  55 ;;
  56 ;; will create a function `hypertext-mode' with its own (sparse)
  57 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  58 ;; perform the following actions:
  59 ;;
  60 ;; - run the command (text-mode) to get its default setup
  61 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  62 ;;   inherit from 'text-mode-map'.
  63 ;; - replace the current syntax table with
  64 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  65 ;;   from the current text-mode-syntax-table.
  66 ;; - replace the current abbrev table with
  67 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  68 ;;   from the current text-mode-abbrev table
  69 ;; - change the mode line to read "Hypertext"
  70 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  71 ;; - run the body of commands provided in the macro -- in this case,
  72 ;;   set the local variable `case-fold-search' to nil.
  73 ;; - **run the command (hypertext-mode-setup), which is empty by
  74 ;;   default, but may be redefined by the user to contain special
  75 ;;   commands (ie. setting local variables like 'outline-regexp')
  76 ;;   **NOTE: do not use this option -- it will soon be obsolete.
  77 ;; - run anything assigned to 'hypertext-mode-hooks' (obsolete, but
  78 ;;   supported for the sake of compatibility).
  79 ;;
  80 ;; The advantages of this system are threefold.  First, text mode is
  81 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  82 ;; possibly using hooks, you would have added it to all text buffers
  83 ;; -- here, it appears only in hypertext buffers, where it makes
  84 ;; sense.  Second, it is possible to build even further, and make
  85 ;; a derived mode from a derived mode.  The commands
  86 ;;
  87 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  88 ;;   [various key definitions]
  89 ;;
  90 ;; will add a new major mode for HTML with very little fuss.
  91 ;;
  92 ;; Note also the function `derived-mode-class,' which returns the non-derived
  93 ;; major mode which a derived mode is based on (ie. NOT necessarily the
  94 ;; immediate parent).
  95 ;;
  96 ;; (derived-mode-class 'text-mode) ==> text-mode
  97 ;; (derived-mode-class 'hypertext-mode) ==> text-mode
  98 ;; (derived-mode-class 'html-mode) ==> text-mode
  99 \f
 100 ;;; Code:
 101
 102 ;; PUBLIC: define a new major mode which inherits from an existing one.
 103
 104 ;;;###autoload
 105 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 106   "Create a new mode as a variant of an existing mode.
 107
 108 The arguments to this command are as follow:
 109
 110 CHILD:     the name of the command for the derived mode.
 111 PARENT:    the name of the command for the parent mode (ie. text-mode).
 112 NAME:      a string which will appear in the status line (ie. \"Hypertext\")
 113 DOCSTRING: an optional documentation string--if you do not supply one,
 114            the function will attempt to invent something useful.
 115 BODY:      forms to execute just before running the
 116            hooks for the new mode.
 117
 118 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 119
 120   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 121
 122 You could then make new key bindings for `LaTeX-thesis-mode-map'
 123 without changing regular LaTeX mode.  In this example, BODY is empty,
 124 and DOCSTRING is generated by default.
 125
 126 On a more complicated level, the following command uses sgml-mode as
 127 the parent, and then sets the variable `case-fold-search' to nil:
 128
 129   (define-derived-mode article-mode sgml-mode \"Article\"
 130     \"Major mode for editing technical articles.\"
 131     (setq case-fold-search nil))
 132
 133 Note that if the documentation string had been left out, it would have
 134 been generated automatically, with a reference to the keymap."
 135
 136                                         ; Some trickiness, since what
 137                                         ; appears to be the docstring
 138                                         ; may really be the first
 139                                         ; element of the body.
 140   (if (and docstring (not (stringp docstring)))
 141       (progn (setq body (cons docstring body))
 142              (setq docstring nil)))
 143   (setq docstring (or docstring (derived-mode-make-docstring parent child)))
 144
 145   (` (progn
 146        (derived-mode-init-mode-variables '(, child))
 147        (put '(, child) 'derived-mode-parent '(, parent))
 148        (defun (, child) ()
 149          (, docstring)
 150          (interactive)
 151                                         ; Run the parent.
 152          ((, parent))
 153                                         ; Identify special modes.
 154          (if (get '(, parent) 'special)
 155              (put '(, child) 'special t))
 156                                         ; Identify the child mode.
 157          (setq major-mode '(, child))
 158          (setq mode-name (, name))
 159                                         ; Set up maps and tables.
 160          (derived-mode-set-keymap '(, child))
 161          (derived-mode-set-syntax-table '(, child))
 162          (derived-mode-set-abbrev-table '(, child))
 163                                         ; Splice in the body (if any).
 164          (,@ body)
 165 ;;;                                     ; Run the setup function, if
 166 ;;;                                     ; any -- this will soon be
 167 ;;;                                     ; obsolete.
 168 ;;;      (derived-mode-run-setup-function '(, child))
 169                                         ; Run the hooks, if any.
 170          (derived-mode-run-hooks '(, child))))))
 171
 172
 173 ;; PUBLIC: find the ultimate class of a derived mode.
 174
 175 (defun derived-mode-class (mode)
 176   "Find the class of a major mode.
 177 A mode's class is the first ancestor which is NOT a derived mode.
 178 Use the `derived-mode-parent' property of the symbol to trace backwards."
 179   (while (get mode 'derived-mode-parent)
 180     (setq mode (get mode 'derived-mode-parent)))
 181   mode)
 182
 183 \f
 184 ;; Inline functions to construct various names from a mode name.
 185
 186 (defsubst derived-mode-setup-function-name (mode)
 187   "Construct a setup-function name based on a mode name."
 188   (intern (concat (symbol-name mode) "-setup")))
 189
 190 (defsubst derived-mode-hooks-name (mode)
 191   "Construct a hooks name based on a mode name."
 192   (intern (concat (symbol-name mode) "-hooks")))
 193
 194 (defsubst derived-mode-map-name (mode)
 195   "Construct a map name based on a mode name."
 196   (intern (concat (symbol-name mode) "-map")))
 197
 198 (defsubst derived-mode-syntax-table-name (mode)
 199   "Construct a syntax-table name based on a mode name."
 200   (intern (concat (symbol-name mode) "-syntax-table")))
 201
 202 (defsubst derived-mode-abbrev-table-name (mode)
 203   "Construct an abbrev-table name based on a mode name."
 204   (intern (concat (symbol-name mode) "-abbrev-table")))
 205
 206 \f
 207 ;; Utility functions for defining a derived mode.
 208
 209 ;;;###autoload
 210 (defun derived-mode-init-mode-variables (mode)
 211   "Initialise variables for a new mode.
 212 Right now, if they don't already exist, set up a blank keymap, an
 213 empty syntax table, and an empty abbrev table -- these will be merged
 214 the first time the mode is used."
 215
 216   (if (boundp (derived-mode-map-name mode))
 217       t
 218     (eval (` (defvar (, (derived-mode-map-name mode))
 219                (make-sparse-keymap)
 220                (, (format "Keymap for %s." mode)))))
 221     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 222
 223   (if (boundp (derived-mode-syntax-table-name mode))
 224       t
 225     (eval (` (defvar (, (derived-mode-syntax-table-name mode))
 226                ;; Make a syntax table which doesn't specify anything
 227                ;; for any char.  Valid data will be merged in by
 228                ;; derived-mode-merge-syntax-tables.
 229                (make-char-table 'syntax-table nil)
 230                (, (format "Syntax table for %s." mode)))))
 231     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 232
 233   (if (boundp (derived-mode-abbrev-table-name mode))
 234       t
 235     (eval (` (defvar (, (derived-mode-abbrev-table-name mode))
 236                (progn (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 237                       (make-abbrev-table))
 238                (, (format "Abbrev table for %s." mode)))))))
 239
 240 (defun derived-mode-make-docstring (parent child)
 241   "Construct a docstring for a new mode if none is provided."
 242
 243   (format "This major mode is a variant of `%s', created by `define-derived-mode'.
 244 It inherits all of the parent's attributes, but has its own keymap,
 245 abbrev table and syntax table:
 246
 247   `%s-map' and `%s-syntax-table'
 248
 249 which more-or-less shadow
 250
 251   `%s-map' and `%s-syntax-table'
 252
 253 \\{%s-map}" parent child child parent parent child))
 254
 255 \f
 256 ;; Utility functions for running a derived mode.
 257
 258 (defun derived-mode-set-keymap (mode)
 259   "Set the keymap of the new mode, maybe merging with the parent."
 260   (let* ((map-name (derived-mode-map-name mode))
 261          (new-map (eval map-name))
 262          (old-map (current-local-map)))
 263     (and old-map
 264          (get map-name 'derived-mode-unmerged)
 265          (derived-mode-merge-keymaps old-map new-map))
 266     (put map-name 'derived-mode-unmerged nil)
 267     (use-local-map new-map)))
 268
 269 (defun derived-mode-set-syntax-table (mode)
 270   "Set the syntax table of the new mode, maybe merging with the parent."
 271   (let* ((table-name (derived-mode-syntax-table-name mode))
 272          (old-table (syntax-table))
 273          (new-table (eval table-name)))
 274     (if (get table-name 'derived-mode-unmerged)
 275         (derived-mode-merge-syntax-tables old-table new-table))
 276     (put table-name 'derived-mode-unmerged nil)
 277     (set-syntax-table new-table)))
 278
 279 (defun derived-mode-set-abbrev-table (mode)
 280   "Set the abbrev table if it exists.
 281 Always merge its parent into it, since the merge is non-destructive."
 282   (let* ((table-name (derived-mode-abbrev-table-name mode))
 283          (old-table local-abbrev-table)
 284          (new-table (eval table-name)))
 285     (derived-mode-merge-abbrev-tables old-table new-table)
 286     (setq local-abbrev-table new-table)))
 287
 288 ;;;(defun derived-mode-run-setup-function (mode)
 289 ;;;  "Run the setup function if it exists."
 290
 291 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 292 ;;;    (if (fboundp fname)
 293 ;;;     (funcall fname))))
 294
 295 (defun derived-mode-run-hooks (mode)
 296   "Run the hooks if they exist."
 297
 298   (let ((hooks-name (derived-mode-hooks-name mode)))
 299     (if (boundp hooks-name)
 300         (run-hooks hooks-name))))
 301
 302 ;; Functions to merge maps and tables.
 303
 304 (defun derived-mode-merge-keymaps (old new)
 305   "Merge an old keymap into a new one.
 306 The old keymap is set to be the last cdr of the new one, so that there will
 307 be automatic inheritance."
 308   (let ((tail new))
 309     ;; Scan the NEW map for prefix keys.
 310     (while (consp tail)
 311       (and (consp (car tail))
 312            (let* ((key (vector (car (car tail))))
 313                   (subnew (lookup-key new key))
 314                   (subold (lookup-key old key)))
 315              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 316              (and (keymapp subnew) (keymapp subold)
 317                   (derived-mode-merge-keymaps subold subnew))))
 318       (and (vectorp (car tail))
 319            ;; Search a vector of ASCII char bindings for prefix keys.
 320            (let ((i (1- (length (car tail)))))
 321              (while (>= i 0)
 322                (let* ((key (vector i))
 323                       (subnew (lookup-key new key))
 324                       (subold (lookup-key old key)))
 325                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 326                  (and (keymapp subnew) (keymapp subold)
 327                       (derived-mode-merge-keymaps subold subnew)))
 328                (setq i (1- i)))))
 329       (setq tail (cdr tail))))
 330   (setcdr (nthcdr (1- (length new)) new) old))
 331
 332 (defun derived-mode-merge-syntax-tables (old new)
 333   "Merge an old syntax table into a new one.
 334 Where the new table already has an entry, nothing is copied from the old one."
 335   (set-char-table-parent new old))
 336
 337 ;; Merge an old abbrev table into a new one.
 338 ;; This function requires internal knowledge of how abbrev tables work,
 339 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 340 ;; as the value of the symbol, and the hook as the function definition.
 341 (defun derived-mode-merge-abbrev-tables (old new)
 342   (if old
 343       (mapatoms
 344        (function
 345         (lambda (symbol)
 346           (or (intern-soft (symbol-name symbol) new)
 347               (define-abbrev new (symbol-name symbol)
 348                 (symbol-value symbol) (symbol-function symbol)))))
 349        old)))
 350
 351 (provide 'derived)
 352
 353 ;;; derived.el ends here