lisp/iswitchb.el

   1 ;;; iswitchb.el --- switch between buffers using substrings
   2
   3 ;; Copyright (C) 1996, 1997, 2000, 2001  Free Software Foundation, Inc.
   4
   5 ;; Author: Stephen Eglen <stephen@gnu.org>
   6 ;; Maintainer: Stephen Eglen <stephen@gnu.org>
   7 ;; Keywords: completion convenience
   8 ;; location: http://www.anc.ed.ac.uk/~stephen/emacs/
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Installation:
  30 ;; To get the functions in this package bound to keys, use
  31 ;; M-x iswitchb-mode or customize the option `iswitchb-mode'.
  32
  33 ;; As you type in a substring, the list of buffers currently matching
  34 ;; the substring is displayed as you type.  The list is ordered so
  35 ;; that the most recent buffers visited come at the start of the list.
  36 ;; The buffer at the start of the list will be the one visited when
  37 ;; you press return.  By typing more of the substring, the list is
  38 ;; narrowed down so that gradually the buffer you want will be at the
  39 ;; top of the list.  Alternatively, you can use C-s and C-r to rotate
  40 ;; buffer names in the list until the one you want is at the top of
  41 ;; the list.  Completion is also available so that you can see what is
  42 ;; common to all of the matching buffers as you type.
  43
  44 ;; This code is similar to a couple of other packages.  Michael R Cook
  45 ;; <cook@sightpath.com> wrote a similar buffer switching package, but
  46 ;; does exact matching rather than substring matching on buffer names.
  47 ;; I also modified a couple of functions from icomplete.el to provide
  48 ;; the completion feedback in the minibuffer.
  49
  50 ;;; Example
  51
  52 ;;If I have two buffers called "123456" and "123", with "123456" the
  53 ;;most recent, when I use iswitchb, I first of all get presented with
  54 ;;the list of all the buffers
  55 ;;
  56 ;;       iswitch  {123456,123}
  57 ;;
  58 ;; If I then press 2:
  59 ;;       iswitch 2[3]{123456,123}
  60 ;;
  61 ;; The list in {} are the matching buffers, most recent first (buffers
  62 ;; visible in the current frame are put at the end of the list by
  63 ;; default).  At any time I can select the item at the head of the
  64 ;; list by pressing RET.  I can also bring the put the first element
  65 ;; at the end of the list by pressing C-s, or put the last element at
  66 ;; the head of the list by pressing C-r.  The item in [] indicates
  67 ;; what can be added to my input by pressing TAB.  In this case, I
  68 ;; will get "3" added to my input.  So, press TAB:
  69 ;;       iswitch 23{123456,123}
  70 ;;
  71 ;; At this point, I still have two matching buffers.
  72 ;; If I want the first buffer in the list, I simply press RET.  If I
  73 ;; wanted the second in the list, I could press C-s to move it to the
  74 ;; top of the list and then RET to select it.
  75 ;;
  76 ;;However, If I type 4, I only have one match left:
  77 ;;       iswitch 234[123456] [Matched]
  78 ;;
  79 ;;Since there is only one matching buffer left, it is given in [] and we
  80 ;;see the text [Matched] afterwards.  I can now press TAB or RET to go
  81 ;;to that buffer.
  82 ;;
  83 ;; If however, I now type "a":
  84 ;;       iswitch 234a [No match]
  85 ;; There are no matching buffers.  If I press RET or TAB, I can be
  86 ;; prompted to create a new buffer called "234a".
  87 ;;
  88 ;; Of course, where this function comes in really useful is when you
  89 ;; can specify the buffer using only a few keystrokes.  In the above
  90 ;; example, the quickest way to get to the "123456" buffer would be
  91 ;; just to type 4 and then RET (assuming there isn't any newer buffer
  92 ;; with 4 in its name).
  93
  94 ;; To see a full list of all matching buffers in a separate buffer,
  95 ;; hit ? or press TAB when there are no further completions to the
  96 ;; substring.  Repeated TAB presses will scroll you through this
  97 ;; separate buffer.
  98
  99 ;; The buffer at the head of the list can be killed by pressing C-k.
 100 ;; If the buffer needs saving, you will be queried before the buffer
 101 ;; is killed.
 102
 103 ;; If you find that the file you are after is not in a buffer, you can
 104 ;; press C-x C-f to immediately drop into find-file.
 105
 106 ;;
 107 ;;  See the doc string of iswitchb for full keybindings and features.
 108 ;;  (describe-function 'iswitchb)
 109
 110 ;; Case matching: The case of strings when matching can be ignored or
 111 ;; used depending on the value of iswitchb-case (default is the same
 112 ;; as case-fold-search, normally t).  Imagine you have the following
 113 ;; buffers:
 114 ;;
 115 ;; INBOX *info* *scratch*
 116 ;;
 117 ;; Then these will be the matching buffers, depending on how you type
 118 ;; the two letters `in' and the value of iswitchb-case:
 119 ;;
 120 ;; iswitchb-case   user input  | matching buffers
 121 ;; ----------------------------------------------
 122 ;; nil             in          | *info*
 123 ;; t               in          | INBOX, *info*
 124 ;; t               IN          | INBOX
 125 ;; t               In          | [No match]
 126
 127 ;;; Customisation
 128
 129 ;; See the User Variables section below for easy ways to change the
 130 ;; functionality of the program.  These are accessible using the
 131 ;; custom package.
 132 ;; To modify the keybindings, use the hook provided.  For example:
 133 ;;(add-hook 'iswitchb-define-mode-map-hook
 134 ;;        'iswitchb-my-keys)
 135 ;;
 136 ;;(defun iswitchb-my-keys ()
 137 ;;  "Add my keybindings for iswitchb."
 138 ;;  (define-key iswitchb-mode-map " " 'iswitchb-next-match)
 139 ;;  )
 140 ;;
 141 ;; Seeing all the matching buffers
 142 ;;
 143 ;; If you have many matching buffers, they may not all fit onto one
 144 ;; line of the minibuffer.  In Emacs 21, the variable
 145 ;; `resize-mini-windows' controls how many lines of the minibuffer can
 146 ;; be seen.  For older versions of emacs, you can use
 147 ;; `resize-minibuffer-mode'.  You can also limit iswitchb so that it
 148 ;; only shows a certain number of lines -- see the documentation for
 149 ;; `iswitchb-minibuffer-setup-hook'.
 150
 151 ;; Changing the list of buffers
 152
 153 ;; By default, the list of current buffers is most recent first,
 154 ;; oldest last, with the exception that the buffers visible in the
 155 ;; current frame are put at the end of the list.  A hook exists to
 156 ;; allow other functions to order the list.  For example, if you add:
 157 ;;
 158 ;; (add-hook 'iswitchb-make-buflist-hook 'iswitchb-summaries-to-end)
 159 ;;
 160 ;; then all buffers matching "Summary" are moved to the end of the
 161 ;; list.  (I find this handy for keeping the INBOX Summary and so on
 162 ;; out of the way.)  It also moves buffers matching "output\*$" to the
 163 ;; end of the list (these are created by AUC TeX when compiling.)
 164 ;; Other functions could be made available which alter the list of
 165 ;; matching buffers (either deleting or rearranging elements.)
 166
 167 ;; Font-Lock
 168
 169 ;; If you have font-lock loaded, the first matching buffer is
 170 ;; highlighted.  To switch this off, set (setq iswitchb-use-fonts nil)
 171 ;; I don't use font-lock that much, so I've hardcoded the faces.  If
 172 ;; this is too harsh, let me know.  Colouring of the matching buffer
 173 ;; name was suggested by Carsten Dominik (dominik@strw.leidenuniv.nl)
 174
 175 ;; Replacement for read-buffer
 176
 177 ;; iswitchb-read-buffer has been written to be a drop in replacement
 178 ;; for the normal buffer selection routine `read-buffer'.  To use
 179 ;; iswitch for all buffer selections in Emacs, add:
 180 ;; (setq read-buffer-function 'iswitchb-read-buffer)
 181 ;; (This variable should be present in Emacs 20.3+)
 182 ;; XEmacs users can get the same behaviour by doing:
 183 ;; (defalias 'read-buffer 'iswitchb-read-buffer)
 184 ;; since `read-buffer' is defined in lisp.
 185
 186 ;; Regexp matching
 187
 188 ;; There is limited provision for regexp matching within iswitchb,
 189 ;; enabled through `iswitchb-regexp'.  This allows you to type `c$'
 190 ;; for example and see all buffer names ending in `c'.  This facility
 191 ;; is quite limited though in two respects.  First, you can't
 192 ;; currently type in expressions like `[0-9]' directly -- you have to
 193 ;; type them in when iswitchb-regexp is nil and then toggle on the
 194 ;; regexp functionality.  Likewise, don't enter an expression
 195 ;; containing `\' in regexp mode.  If you try, iswitchb gets confused,
 196 ;; so just hit C-g and try again.  Secondly, no completion mechanism
 197 ;; is currently offered when regexp searching.
 198
 199 ;;; TODO
 200
 201 ;;; Acknowledgements
 202
 203 ;; Thanks to Jari Aalto <jari.aalto@poboxes.com> for help with the
 204 ;; first version of this package, iswitch-buffer.  Thanks also to many
 205 ;; others for testing earlier versions.
 206
 207 ;;; Code:
 208
 209 ;; CL needed for cadr and last
 210 (if (not (and (fboundp 'cadr)
 211               (fboundp 'last)))
 212     (require 'cl))
 213
 214 ;; Set up the custom library.
 215 ;; taken from http://www.dina.kvl.dk/~abraham/custom/
 216 (eval-and-compile
 217   (condition-case ()
 218       (require 'custom)
 219     (error nil))
 220   (if (and (featurep 'custom) (fboundp 'custom-declare-variable))
 221       nil ;; We've got what we needed
 222     ;; We have the old custom-library, hack around it!
 223     (defmacro defgroup (&rest args)
 224       nil)
 225     (defmacro defcustom (var value doc &rest args)
 226       `(defvar ,var ,value ,doc))))
 227
 228 ;;; User Variables
 229 ;;
 230 ;; These are some things you might want to change.
 231
 232 (defgroup iswitchb nil
 233   "Switch between buffers using substrings."
 234   :group 'convenience
 235   :group 'completion
 236   :link '(emacs-commentary-link :tag "Commentary" "iswitchb.el")
 237   :link '(url-link "http://www.anc.ed.ac.uk/~stephen/emacs/")
 238   :link '(emacs-library-link :tag "Lisp File" "iswitchb.el"))
 239
 240 ;;;###autoload
 241 (defcustom iswitchb-mode nil
 242   "Toggle Iswitchb mode.
 243 Setting this variable directly does not take effect;
 244 use either \\[customize] or the function `iswitchb-mode'."
 245   :set (lambda (symbol value)
 246          (iswitchb-mode (or value 0)))
 247   :initialize 'custom-initialize-default
 248   :group 'iswitchb
 249   :require 'iswitchb
 250   :version "21.1"
 251   :type 'boolean)
 252
 253 (defcustom iswitchb-mode-hook nil
 254   "Hook run at the end of function `iswitchb-mode'."
 255   :group 'iswitchb
 256   :type 'hook)
 257
 258 (defcustom iswitchb-case case-fold-search
 259   "*Non-nil if searching of buffer names should ignore case.
 260 If this is non-nil but the user input has any upper case letters, matching
 261 is temporarily case sensitive."
 262   :type 'boolean
 263   :group 'iswitchb)
 264
 265 (defcustom iswitchb-buffer-ignore
 266   '("^ ")
 267   "*List of regexps or functions matching buffer names to ignore.
 268 For example, traditional behavior is not to list buffers whose names begin
 269 with a space, for which the regexp is `^ '.  See the source file for
 270 example functions that filter buffernames."
 271   :type '(repeat regexp)
 272   :group 'iswitchb)
 273
 274 (defcustom iswitchb-cannot-complete-hook 'iswitchb-completion-help
 275   "*Hook run when `iswitchb-complete' can't complete any more.
 276 The most useful values are `iswitchb-completion-help', which pops up a
 277 window with completion alternatives, or `iswitchb-next-match' or
 278 `iswitchb-prev-match', which cycle the buffer list."
 279   :type 'hook
 280   :group 'iswitchb)
 281
 282 ;;; Examples for setting the value of iswitchb-buffer-ignore
 283 ;(defun iswitchb-ignore-c-mode (name)
 284 ;  "Ignore all c mode buffers -- example function for iswitchb."
 285 ;  (save-excursion
 286 ;    (set-buffer name)
 287 ;    (string-match "^C$" mode-name)))
 288
 289 ;(setq iswitchb-buffer-ignore '("^ " iswitchb-ignore-c-mode))
 290 ;(setq iswitchb-buffer-ignore '("^ " "\\.c$" "\\.h$"))
 291
 292 (defcustom iswitchb-default-method  'always-frame
 293     "*How to switch to new buffer when using `iswitchb-buffer'.
 294 Possible values:
 295 `samewindow'    Show new buffer in same window
 296 `otherwindow'   Show new buffer in another window (same frame)
 297 `display'       Display buffer in another window without switching to it
 298 `otherframe'    Show new buffer in another frame
 299 `maybe-frame'   If a buffer is visible in another frame, prompt to ask if you
 300                 you want to see the buffer in the same window of the current
 301                 frame or in the other frame.
 302 `always-frame'  If a buffer is visible in another frame, raise that
 303                 frame.  Otherwise, visit the buffer in the same window."
 304     :type '(choice (const samewindow)
 305                    (const otherwindow)
 306                    (const display)
 307                    (const otherframe)
 308                    (const maybe-frame)
 309                    (const always-frame))
 310     :group 'iswitchb)
 311
 312 (defcustom iswitchb-regexp nil
 313   "*Non-nil means that `iswitchb' will do regexp matching.
 314 Value can be toggled within `iswitchb' using `iswitchb-toggle-regexp'."
 315   :type 'boolean
 316   :group 'iswitchb)
 317
 318 (defcustom iswitchb-newbuffer t
 319   "*Non-nil means create new buffer if no buffer matches substring.
 320 See also `iswitchb-prompt-newbuffer'."
 321   :type 'boolean
 322   :group 'iswitchb)
 323
 324 (defcustom iswitchb-prompt-newbuffer t
 325   "*Non-nil means prompt user to confirm before creating new buffer.
 326 See also `iswitchb-newbuffer'."
 327   :type 'boolean
 328   :group 'iswitchb)
 329
 330 (defcustom iswitchb-define-mode-map-hook  nil
 331   "Hook to define keys in `iswitchb-mode-map' for extra keybindings."
 332   :type 'hook
 333   :group 'iswitchb)
 334
 335 (defcustom iswitchb-use-fonts t
 336   "*Non-nil means use font-lock fonts for showing first match."
 337   :type 'boolean
 338   :group 'iswitchb)
 339
 340 (defcustom iswitchb-use-frame-buffer-list nil
 341   "*Non-nil means use the currently selected frame's buffer list."
 342   :type 'boolean
 343   :group 'iswitchb)
 344
 345 (defcustom iswitchb-make-buflist-hook  nil
 346   "Hook to run when list of matching buffers is created."
 347   :type 'hook
 348   :group 'iswitchb)
 349
 350 (defvar iswitchb-all-frames 'visible
 351   "*Argument to pass to `walk-windows' when finding visible buffers.
 352 See documentation of `walk-windows' for useful values.")
 353
 354 (defcustom iswitchb-minibuffer-setup-hook nil
 355   "Iswitchb-specific customization of minibuffer setup.
 356
 357 This hook is run during minibuffer setup iff `iswitchb' will be active.
 358 It is intended for use in customizing iswitchb for interoperation
 359 with other packages."
 360 ;;;   For instance:
 361
 362 ;;;   \(add-hook 'iswitchb-minibuffer-setup-hook
 363 ;;;         \(function
 364 ;;;          \(lambda ()
 365 ;;;            \(make-local-variable 'resize-minibuffer-window-max-height)
 366 ;;;            \(setq resize-minibuffer-window-max-height 3))))
 367
 368 ;;; will constrain rsz-mini to a maximum minibuffer height of 3 lines when
 369 ;;; iswitchb is running.  Copied from `icomplete-minibuffer-setup-hook'."
 370   :type 'hook
 371   :group 'iswitchb)
 372
 373 ;; Do we need the variable iswitchb-use-mycompletion?
 374
 375 ;;; Internal Variables
 376
 377 (defvar iswitchb-method nil
 378   "Stores the method for viewing the selected buffer.
 379 Its value is one of `samewindow', `otherwindow', `display', `otherframe',
 380 `maybe-frame' or `always-frame'.  See `iswitchb-default-method' for
 381 details of values.")
 382
 383 (defvar iswitchb-eoinput 1
 384   "Point where minibuffer input ends and completion info begins.
 385 Copied from `icomplete-eoinput'.")
 386 (make-variable-buffer-local 'iswitchb-eoinput)
 387
 388 (defvar iswitchb-buflist nil
 389   "Stores the current list of buffers that will be searched through.
 390 The list is ordered, so that the most recent buffers come first,
 391 although by default, the buffers visible in the current frame are put
 392 at the end of the list.  Created by `iswitchb-make-buflist'.")
 393
 394 ;; todo -- is this necessary?
 395
 396 (defvar iswitchb-use-mycompletion nil
 397   "Non-nil means use `iswitchb-buffer' completion feedback.
 398 Should only be set to t by iswitchb functions, so that it doesn't
 399 interfere with other minibuffer usage.")
 400
 401 (defvar iswitchb-change-word-sub nil
 402   "Private variable used by `iswitchb-word-matching-substring'.")
 403
 404 (defvar iswitchb-common-match-string  nil
 405   "Stores the string that is common to all matching buffers.")
 406
 407 (defvar iswitchb-rescan nil
 408   "Non-nil means we need to regenerate the list of matching buffers.")
 409
 410 (defvar iswitchb-text nil
 411   "Stores the users string as it is typed in.")
 412
 413 (defvar iswitchb-matches nil
 414   "List of buffers currently matching `iswitchb-text'.")
 415
 416 (defvar iswitchb-mode-map
 417   (let ((map (make-sparse-keymap)))
 418     (set-keymap-parent map minibuffer-local-map)
 419     (define-key map "?" 'iswitchb-completion-help)
 420     (define-key map "\C-s" 'iswitchb-next-match)
 421     (define-key map "\C-r" 'iswitchb-prev-match)
 422     (define-key map "\t" 'iswitchb-complete)
 423     (define-key map "\C-j" 'iswitchb-select-buffer-text)
 424     (define-key map "\C-t" 'iswitchb-toggle-regexp)
 425     (define-key map "\C-x\C-f" 'iswitchb-find-file)
 426     (define-key map "\C-c" 'iswitchb-toggle-case)
 427     (define-key map "\C-k" 'iswitchb-kill-buffer)
 428     (define-key map "\C-m" 'iswitchb-exit-minibuffer)
 429     map)
 430   "Minibuffer keymap for `iswitchb-buffer'.")
 431
 432 (defvar iswitchb-global-map
 433   (let ((map (make-sparse-keymap)))
 434     (substitute-key-definition 'switch-to-buffer ; normally C-x b
 435                                'iswitchb-buffer map global-map)
 436     (substitute-key-definition 'switch-to-buffer-other-window ; C-x 4 b
 437                                'iswitchb-buffer-other-window map global-map)
 438     (substitute-key-definition 'switch-to-buffer-other-frame ; C-x 5 b
 439                                'iswitchb-buffer-other-frame map global-map)
 440     (substitute-key-definition 'display-buffer ; C-x 4 C-o
 441                                'iswitchb-display-buffer map global-map)
 442     map)
 443   "Global keymap for `iswtichb-mode'.")
 444
 445 (defvar iswitchb-history nil
 446   "History of buffers selected using `iswitchb-buffer'.")
 447
 448 (defvar iswitchb-exit nil
 449   "Flag to monitor how `iswitchb-buffer' exits.
 450 If equal to `takeprompt', we use the prompt as the buffer name to be
 451 selected.")
 452
 453 (defvar iswitchb-buffer-ignore-orig nil
 454   "Stores original value of `iswitchb-buffer-ignore'.")
 455
 456 (defvar iswitchb-xemacs  (string-match "XEmacs" (emacs-version))
 457   "Non-nil if we are running XEmacs.  Otherwise, assume we are running Emacs.")
 458
 459 (defvar iswitchb-default nil
 460   "Default buffer for iswitchb.")
 461
 462 ;; The following variables are needed to keep the byte compiler quiet.
 463 (defvar iswitchb-require-match nil
 464   "Non-nil if matching buffer must be selected.")
 465
 466 (defvar iswitchb-temp-buflist nil
 467   "Stores a temporary version of the buffer list being created.")
 468
 469 (defvar iswitchb-bufs-in-frame nil
 470   "List of the buffers visible in the current frame.")
 471
 472 (defvar iswitchb-minibuf-depth nil
 473   "Value we expect to be returned by `minibuffer-depth' in the minibuffer.")
 474
 475 ;;; FUNCTIONS
 476
 477 ;;; ISWITCHB KEYMAP
 478 (defun iswitchb-define-mode-map ()
 479   "Set up the keymap for `iswitchb-buffer'.
 480 This is obsolete.  Use \\[iswitchb-mode] or customize the
 481 variable `iswitchb-mode'."
 482   (interactive)
 483   (let (map)
 484     ;; generated every time so that it can inherit new functions.
 485     ;;(or iswitchb-mode-map
 486
 487     (setq map (copy-keymap minibuffer-local-map))
 488     (define-key map "?" 'iswitchb-completion-help)
 489     (define-key map "\C-s" 'iswitchb-next-match)
 490     (define-key map "\C-r" 'iswitchb-prev-match)
 491     (define-key map "\t" 'iswitchb-complete)
 492     (define-key map "\C-j" 'iswitchb-select-buffer-text)
 493     (define-key map "\C-t" 'iswitchb-toggle-regexp)
 494     (define-key map "\C-x\C-f" 'iswitchb-find-file)
 495     ;;(define-key map "\C-a" 'iswitchb-toggle-ignore)
 496     (define-key map "\C-c" 'iswitchb-toggle-case)
 497     (define-key map "\C-k" 'iswitchb-kill-buffer)
 498     (define-key map "\C-m" 'iswitchb-exit-minibuffer)
 499     (setq iswitchb-mode-map map)
 500     (run-hooks 'iswitchb-define-mode-map-hook)))
 501
 502 ;;; MAIN FUNCTION
 503 (defun iswitchb ()
 504   "Switch to buffer matching a substring.
 505 As you type in a string, all of the buffers matching the string are
 506 displayed.  When you have found the buffer you want, it can then be
 507 selected.  As you type, most keys have their normal keybindings,
 508 except for the following:
 509 \\<iswitchb-mode-map>
 510
 511 RET Select the buffer at the front of the list of matches.  If the
 512 list is empty, possibly prompt to create new buffer.
 513
 514 \\[iswitchb-select-buffer-text] Select the current prompt as the buffer.
 515 If no buffer is found, prompt for a new one.
 516
 517 \\[iswitchb-next-match] Put the first element at the end of the list.
 518 \\[iswitchb-prev-match] Put the last element at the start of the list.
 519 \\[iswitchb-complete] Complete a common suffix to the current string that
 520 matches all buffers.  If there is only one match, select that buffer.
 521 If there is no common suffix, show a list of all matching buffers
 522 in a separate window.
 523 \\[iswitchb-toggle-regexp] Toggle regexp searching.
 524 \\[iswitchb-toggle-case] Toggle case-sensitive searching of buffer names.
 525 \\[iswitchb-completion-help] Show list of matching buffers in separate window.
 526 \\[iswitchb-find-file] Exit iswitchb and drop into `find-file'.
 527 \\[iswitchb-kill-buffer] Kill buffer at head of buffer list."
 528   ;;\\[iswitchb-toggle-ignore] Toggle ignoring certain buffers (see \
 529   ;;`iswitchb-buffer-ignore')
 530
 531   (let
 532       (prompt buf)
 533
 534     (setq prompt (format "iswitch "))
 535
 536     (setq buf (iswitchb-read-buffer prompt))
 537
 538     ;;(message "chosen text %s" iswitchb-final-text)
 539     ;; Choose the buffer name: either the text typed in, or the head
 540     ;; of the list of matches
 541
 542     (cond ( (eq iswitchb-exit 'findfile)
 543             (call-interactively 'find-file))
 544
 545           (t
 546            ;; View the buffer
 547            ;;(message "go to buf %s" buf)
 548            ;; Check buf is non-nil.
 549            (if buf
 550                (if (get-buffer buf)
 551                    ;; buffer exists, so view it and then exit
 552                    (iswitchb-visit-buffer buf)
 553                  ;; else buffer doesn't exist
 554                  (iswitchb-possible-new-buffer buf)))
 555            ))))
 556
 557 ;;;###autoload
 558 (defun iswitchb-read-buffer (prompt &optional default require-match)
 559   "Replacement for the built-in `read-buffer'.
 560 Return the name of a buffer selected.
 561 PROMPT is the prompt to give to the user.  DEFAULT if given is the default
 562 buffer to be selected, which will go to the front of the list.
 563 If REQUIRE-MATCH is non-nil, an existing-buffer must be selected."
 564   (let
 565       (
 566        buf-sel
 567        iswitchb-final-text
 568        (icomplete-mode nil) ;; prevent icomplete starting up
 569        ;; can only use fonts if they have been bound.
 570        (iswitchb-use-fonts (and iswitchb-use-fonts
 571                                 (boundp 'font-lock-comment-face)
 572                                 (boundp 'font-lock-function-name-face))))
 573
 574     (iswitchb-define-mode-map)
 575     (setq iswitchb-exit nil)
 576     (setq iswitchb-rescan t)
 577     (setq iswitchb-text "")
 578     (setq iswitchb-default
 579           (if (bufferp default)
 580               (buffer-name default)
 581             default))
 582     (iswitchb-make-buflist iswitchb-default)
 583     (iswitchb-set-matches)
 584     (let
 585         ((minibuffer-local-completion-map iswitchb-mode-map)
 586          (iswitchb-prepost-hooks t)
 587          ;; Record the minibuffer depth that we expect to find once
 588          ;; the minibuffer is set up and iswitchb-entryfn-p is called.
 589          (iswitchb-minibuf-depth (1+ (minibuffer-depth)))
 590          (iswitchb-require-match require-match))
 591       ;; prompt the user for the buffer name
 592       (setq iswitchb-final-text (completing-read
 593                                  prompt ;the prompt
 594                                  '(("dummy" . 1)) ;table
 595                                  nil    ;predicate
 596                                  nil    ;require-match [handled elsewhere]
 597                                  nil    ;initial-contents
 598                                  'iswitchb-history)))
 599     ;; Handling the require-match must be done in a better way.
 600     (if (and require-match (not (iswitchb-existing-buffer-p)))
 601         (error "Must specify valid buffer"))
 602
 603     (if (or
 604          (eq iswitchb-exit 'takeprompt)
 605          (null iswitchb-matches))
 606         (setq buf-sel iswitchb-final-text)
 607       ;; else take head of list
 608       (setq buf-sel (car iswitchb-matches)))
 609
 610     ;; Or possibly choose the default buffer
 611     (if  (equal iswitchb-final-text "")
 612         (setq buf-sel
 613               (car iswitchb-matches)))
 614
 615     buf-sel))
 616
 617 (defun iswitchb-existing-buffer-p ()
 618   "Return non-nil if there is a matching buffer."
 619   (not (null iswitchb-matches)))
 620
 621 ;;; COMPLETION CODE
 622
 623 (defun iswitchb-set-common-completion  ()
 624   "Find common completion of `iswitchb-text' in `iswitchb-matches'.
 625 The result is stored in `iswitchb-common-match-string'."
 626
 627   (let* (val)
 628     (setq  iswitchb-common-match-string nil)
 629     (if (and iswitchb-matches
 630              (not iswitchb-regexp) ;; testing
 631              (stringp iswitchb-text)
 632              (> (length iswitchb-text) 0))
 633         (if (setq val (iswitchb-find-common-substring
 634                        iswitchb-matches iswitchb-text))
 635             (setq iswitchb-common-match-string val)))
 636     val))
 637
 638 (defun iswitchb-complete ()
 639   "Try and complete the current pattern amongst the buffer names."
 640   (interactive)
 641   (let (res)
 642     (cond ((not  iswitchb-matches)
 643            (run-hooks 'iswitchb-cannot-complete-hook))
 644
 645           ((= 1 (length iswitchb-matches))
 646            ;; only one choice, so select it.
 647            (exit-minibuffer))
 648
 649           (t
 650            ;; else there could be some completions
 651            (setq res iswitchb-common-match-string)
 652            (if (and (not (memq res '(t nil)))
 653                     (not (equal res iswitchb-text)))
 654                ;; found something to complete, so put it in the minibuffer.
 655                (progn
 656                  (setq iswitchb-rescan nil)
 657                  (delete-region (minibuffer-prompt-end) (point))
 658                  (insert  res))
 659              ;; else nothing to complete
 660              (run-hooks 'iswitchb-cannot-complete-hook)
 661              )))))
 662
 663 ;;; TOGGLE FUNCTIONS
 664
 665 (defun iswitchb-toggle-case ()
 666   "Toggle the value of variable `iswitchb-case'."
 667   (interactive)
 668   (setq iswitchb-case (not iswitchb-case))
 669   ;; ask for list to be regenerated.
 670   (setq iswitchb-rescan t))
 671
 672 (defun iswitchb-toggle-regexp ()
 673   "Toggle the value of `iswitchb-regexp'."
 674   (interactive)
 675   (setq iswitchb-regexp (not iswitchb-regexp))
 676   ;; ask for list to be regenerated.
 677   (setq iswitchb-rescan t))
 678
 679 (defun iswitchb-toggle-ignore ()
 680   "Toggle ignoring buffers specified with `iswitchb-buffer-ignore'."
 681   (interactive)
 682   (if iswitchb-buffer-ignore
 683       (progn
 684         (setq iswitchb-buffer-ignore-orig iswitchb-buffer-ignore)
 685         (setq iswitchb-buffer-ignore nil))
 686     ;; else
 687     (setq iswitchb-buffer-ignore iswitchb-buffer-ignore-orig))
 688   (iswitchb-make-buflist iswitchb-default)
 689   ;; ask for list to be regenerated.
 690   (setq iswitchb-rescan t))
 691
 692 (defun iswitchb-exit-minibuffer ()
 693   "Exit minibuffer, but make sure we have a match if one is needed."
 694   (interactive)
 695   (if (or (not iswitchb-require-match)
 696            (iswitchb-existing-buffer-p))
 697       (throw 'exit nil)))
 698
 699 (defun iswitchb-select-buffer-text ()
 700   "Select the buffer named by the prompt.
 701 If no buffer exactly matching the prompt exists, maybe create a new one."
 702   (interactive)
 703   (setq iswitchb-exit 'takeprompt)
 704   (exit-minibuffer))
 705
 706 (defun iswitchb-find-file ()
 707   "Drop into `find-file' from buffer switching."
 708   (interactive)
 709   (setq iswitchb-exit 'findfile)
 710   (exit-minibuffer))
 711
 712 (defun iswitchb-next-match ()
 713   "Put first element of `iswitchb-matches' at the end of the list."
 714   (interactive)
 715   (let ((next  (cadr iswitchb-matches)))
 716     (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist next))
 717     (setq iswitchb-rescan t)))
 718
 719 (defun iswitchb-prev-match ()
 720   "Put last element of `iswitchb-matches' at the front of the list."
 721   (interactive)
 722   (let ((prev  (car (last iswitchb-matches))))
 723     (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist prev))
 724     (setq iswitchb-rescan t)))
 725
 726 (defun iswitchb-chop (list elem)
 727   "Remove all elements before ELEM and put them at the end of LIST."
 728   (let ((ret nil)
 729         (next nil)
 730         (sofar nil))
 731     (while (not ret)
 732       (setq next (car list))
 733       (if (equal next elem)
 734           (setq ret (append list (nreverse sofar)))
 735         ;; else
 736         (progn
 737           (setq list (cdr list))
 738           (setq sofar (cons next sofar)))))
 739     ret))
 740
 741 ;;; CREATE LIST OF ALL CURRENT BUFFERS
 742
 743 (defun iswitchb-make-buflist (default)
 744   "Set `iswitchb-buflist' to the current list of buffers.
 745 Currently visible buffers are put at the end of the list.
 746 The hook `iswitchb-make-buflist-hook' is run after the list has been
 747 created to allow the user to further modify the order of the buffer names
 748 in this list.  If DEFAULT is non-nil, and corresponds to an existing buffer,
 749 it is put to the start of the list."
 750   (setq iswitchb-buflist
 751         (let* ((iswitchb-current-buffers (iswitchb-get-buffers-in-frames))
 752                (iswitchb-temp-buflist
 753                 (delq nil
 754                       (mapcar
 755                        (lambda (x)
 756                          (let ((b-name (buffer-name x)))
 757                            (if (not
 758                                 (or
 759                                  (iswitchb-ignore-buffername-p b-name)
 760                                  (memq b-name iswitchb-current-buffers)))
 761                                b-name)))
 762                        (buffer-list (and iswitchb-use-frame-buffer-list
 763                                          (selected-frame)))))))
 764           (setq iswitchb-temp-buflist
 765                 (nconc iswitchb-temp-buflist iswitchb-current-buffers))
 766           (run-hooks 'iswitchb-make-buflist-hook)
 767          ;; Should this be after the hooks, or should the hooks be the
 768           ;; final thing to be run?
 769           (if default
 770               (progn
 771                 (setq iswitchb-temp-buflist
 772                       (delete default iswitchb-temp-buflist))
 773                 (setq iswitchb-temp-buflist
 774                       (cons default iswitchb-temp-buflist))))
 775           iswitchb-temp-buflist)))
 776
 777 (defun iswitchb-to-end (lst)
 778   "Move the elements from LST to the end of `iswitchb-temp-buflist'."
 779   (mapcar
 780    (lambda (elem)
 781      (setq iswitchb-temp-buflist (delq elem iswitchb-temp-buflist)))
 782    lst)
 783   (setq iswitchb-temp-buflist (nconc iswitchb-temp-buflist lst)))
 784
 785 (defun iswitchb-get-buffers-in-frames (&optional current)
 786   "Return the list of buffers that are visible in the current frame.
 787 If optional argument CURRENT is given, restrict searching to the
 788 current frame, rather than all frames, regardless of value of
 789 `iswitchb-all-frames'."
 790   (let ((iswitchb-bufs-in-frame nil))
 791     (walk-windows 'iswitchb-get-bufname nil
 792                   (if current
 793                       nil
 794                     iswitchb-all-frames))
 795     iswitchb-bufs-in-frame))
 796
 797 (defun iswitchb-get-bufname (win)
 798   "Used by `iswitchb-get-buffers-in-frames' to walk through all windows."
 799   (let ((buf (buffer-name (window-buffer win))))
 800         (if (not (member buf iswitchb-bufs-in-frame))
 801             ;; Only add buf if it is not already in list.
 802             ;; This prevents same buf in two different windows being
 803             ;; put into the list twice.
 804             (setq iswitchb-bufs-in-frame
 805                   (cons buf iswitchb-bufs-in-frame)))))
 806
 807 ;;; FIND MATCHING BUFFERS
 808
 809 (defun iswitchb-set-matches ()
 810   "Set `iswitchb-matches' to the list of buffers matching prompt."
 811   (if iswitchb-rescan
 812       (setq iswitchb-matches
 813             (let* ((buflist iswitchb-buflist))
 814               (iswitchb-get-matched-buffers iswitchb-text iswitchb-regexp
 815                                             buflist)))))
 816
 817 (defun iswitchb-get-matched-buffers (regexp
 818                                      &optional string-format buffer-list)
 819   "Return buffers matching REGEXP.
 820 If STRING-FORMAT is nil, consider REGEXP as just a string.
 821 BUFFER-LIST can be list of buffers or list of strings."
 822   (let* ((case-fold-search  (iswitchb-case))
 823          ;; need reverse since we are building up list backwards
 824          (list              (reverse buffer-list))
 825          (do-string         (stringp (car list)))
 826          name
 827          ret)
 828     (mapcar
 829      (lambda (x)
 830
 831        (if do-string
 832            (setq name x)               ;We already have the name
 833          (setq name (buffer-name x)))
 834
 835        (cond
 836         ((and (or (and string-format (string-match regexp name))
 837                   (and (null string-format)
 838                        (string-match (regexp-quote regexp) name)))
 839
 840               (not (iswitchb-ignore-buffername-p name)))
 841          (setq ret (cons name ret))
 842           )))
 843      list)
 844     ret))
 845
 846 (defun iswitchb-ignore-buffername-p (bufname)
 847   "Return t if the buffer BUFNAME should be ignored."
 848   (let ((data       (match-data))
 849         (re-list    iswitchb-buffer-ignore)
 850         ignorep
 851         nextstr)
 852     (while re-list
 853       (setq nextstr (car re-list))
 854       (cond
 855        ((stringp nextstr)
 856         (if (string-match nextstr bufname)
 857             (progn
 858               (setq ignorep t)
 859               (setq re-list nil))))
 860        ((fboundp nextstr)
 861         (if (funcall nextstr bufname)
 862             (progn
 863               (setq ignorep t)
 864               (setq re-list nil)))))
 865       (setq re-list (cdr re-list)))
 866     (set-match-data data)
 867
 868     ;; return the result
 869     ignorep))
 870
 871 (defun iswitchb-word-matching-substring (word)
 872   "Return part of WORD before 1st match to `iswitchb-change-word-sub'.
 873 If `iswitchb-change-word-sub' cannot be found in WORD, return nil."
 874   (let ((case-fold-search (iswitchb-case)))
 875     (let ((m (string-match iswitchb-change-word-sub word)))
 876       (if m
 877           (substring word m)
 878         ;; else no match
 879         nil))))
 880
 881 (defun iswitchb-find-common-substring (lis subs)
 882   "Return common string following SUBS in each element of LIS."
 883   (let (res
 884         alist
 885         iswitchb-change-word-sub)
 886     (setq iswitchb-change-word-sub
 887           (if iswitchb-regexp
 888               subs
 889             (regexp-quote subs)))
 890     (setq res (mapcar 'iswitchb-word-matching-substring lis))
 891     (setq res (delq nil res)) ;; remove any nil elements (shouldn't happen)
 892     (setq alist (mapcar 'iswitchb-makealist res)) ;; could use an  OBARRAY
 893
 894     ;; try-completion returns t if there is an exact match.
 895     (let ((completion-ignore-case (iswitchb-case)))
 896
 897     (try-completion subs alist))))
 898
 899 (defun iswitchb-makealist (res)
 900   "Return dotted pair (RES . 1)."
 901   (cons res 1))
 902
 903 ;; from Wayne Mesard <wmesard@esd.sgi.com>
 904 (defun iswitchb-rotate-list (lis)
 905   "Destructively remove the last element from LIS.
 906 Return the modified list with the last element prepended to it."
 907   (if (<= (length lis) 1)
 908       lis
 909     (let ((las lis)
 910           (prev lis))
 911       (while (consp (cdr las))
 912         (setq prev las
 913               las (cdr las)))
 914       (setcdr prev nil)
 915       (cons (car las) lis))))
 916
 917 (defun iswitchb-completion-help ()
 918   "Show possible completions in a *Buffer Completions* buffer."
 919   ;; we could allow this buffer to be used to select match, but I think
 920   ;; choose-completion-string will need redefining, so it just inserts
 921   ;; choice with out any previous input.
 922   (interactive)
 923   (setq iswitchb-rescan nil)
 924   (let ((completion-setup-hook nil)     ;disable fancy highlight/selection.
 925         (buf (current-buffer))
 926         (temp-buf "*Buffer Completions*")
 927         (win)
 928         (again (eq last-command this-command)))
 929
 930     (if again
 931         ;; scroll buffer
 932         (progn
 933           (set-buffer temp-buf)
 934           (setq win (get-buffer-window temp-buf))
 935           (if (pos-visible-in-window-p (point-max) win)
 936               (set-window-start win (point-min))
 937             (scroll-other-window))
 938           (set-buffer buf))
 939
 940       (with-output-to-temp-buffer temp-buf
 941         (if iswitchb-xemacs
 942
 943             ;; XEmacs extents are put on by default, doesn't seem to be
 944             ;; any way of switching them off.
 945             (display-completion-list (if iswitchb-matches
 946                                          iswitchb-matches
 947                                        iswitchb-buflist)
 948                                      :help-string "iswitchb "
 949                                      :activate-callback
 950                                      (lambda (x y z)
 951                                        (message "doesn't work yet, sorry!")))
 952           ;; else running Emacs
 953           (with-current-buffer standard-output
 954             (fundamental-mode))
 955           (display-completion-list (if iswitchb-matches
 956                                        iswitchb-matches
 957                                      iswitchb-buflist))
 958           )))))
 959
 960 ;;; KILL CURRENT BUFFER
 961
 962 (defun iswitchb-kill-buffer ()
 963   "Kill the buffer at the head of `iswitchb-matches'."
 964   (interactive)
 965   (let ( (enable-recursive-minibuffers t)
 966          buf)
 967
 968     (setq buf (car iswitchb-matches))
 969     ;; check to see if buf is non-nil.
 970     (if buf
 971         (progn
 972           (kill-buffer buf)
 973
 974           ;; Check if buffer exists.  XEmacs gnuserv.el makes alias
 975           ;; for kill-buffer which does not return t if buffer is
 976           ;; killed, so we can't rely on kill-buffer return value.
 977           (if (get-buffer buf)
 978               ;; buffer couldn't be killed.
 979               (setq iswitchb-rescan t)
 980             ;; else buffer was killed so remove name from list.
 981             (setq iswitchb-buflist  (delq buf iswitchb-buflist)))))))
 982
 983 ;;; VISIT CHOSEN BUFFER
 984 (defun iswitchb-visit-buffer (buffer)
 985   "Visit buffer named BUFFER according to `iswitchb-method'."
 986   (let* (win  newframe)
 987     (cond
 988      ((eq iswitchb-method 'samewindow)
 989       (switch-to-buffer buffer))
 990
 991      ((memq iswitchb-method '(always-frame maybe-frame))
 992       (cond
 993        ((and (setq win (iswitchb-window-buffer-p buffer))
 994              (or (eq iswitchb-method 'always-frame)
 995                  (y-or-n-p "Jump to frame? ")))
 996         (setq newframe (window-frame win))
 997         (raise-frame newframe)
 998         (select-frame newframe)
 999         (select-window win)
1000         (if (not iswitchb-xemacs)
1001             ;; reposition mouse to make frame active.  not needed in XEmacs
1002             ;; This line came from the other-frame defun in Emacs.
1003             (set-mouse-position (selected-frame) (1- (frame-width)) 0)))
1004        (t
1005         ;;  No buffer in other frames...
1006         (switch-to-buffer buffer)
1007         )))
1008
1009      ((eq iswitchb-method 'otherwindow)
1010       (switch-to-buffer-other-window buffer))
1011
1012      ((eq iswitchb-method 'display)
1013       (display-buffer buffer))
1014
1015      ((eq iswitchb-method 'otherframe)
1016       (progn
1017         (switch-to-buffer-other-frame buffer)
1018         (if (not iswitchb-xemacs)
1019             (set-mouse-position (selected-frame) (1- (frame-width)) 0))
1020         )))))
1021
1022 (defun iswitchb-possible-new-buffer (buf)
1023   "Possibly create and visit a new buffer called BUF."
1024
1025   (let ((newbufcreated))
1026     (if (and iswitchb-newbuffer
1027              (or
1028               (not iswitchb-prompt-newbuffer)
1029
1030               (and iswitchb-prompt-newbuffer
1031                    (y-or-n-p
1032                     (format
1033                      "No buffer matching `%s', create one? "
1034                      buf)))))
1035         ;; then create a new buffer
1036         (progn
1037           (setq newbufcreated (get-buffer-create buf))
1038           (if (fboundp 'set-buffer-major-mode)
1039               (set-buffer-major-mode newbufcreated))
1040           (iswitchb-visit-buffer newbufcreated))
1041       ;; else wont create new buffer
1042       (message (format "no buffer matching `%s'" buf)))))
1043
1044 (defun iswitchb-window-buffer-p  (buffer)
1045   "Return window pointer if BUFFER is visible in another frame.
1046 If BUFFER is visible in the current frame, return nil."
1047   (interactive)
1048   (let ((blist (iswitchb-get-buffers-in-frames 'current)))
1049     ;;If the buffer is visible in current frame, return nil
1050     (if (memq buffer blist)
1051         nil
1052       ;;  maybe in other frame or icon
1053       (get-buffer-window buffer 0) ; better than 'visible
1054       )))
1055
1056 ;;;###autoload
1057 (defun iswitchb-default-keybindings ()
1058   "Set up default keybindings for `iswitchb-buffer'.
1059 Call this function to override the normal bindings.  This function also
1060 adds a hook to the minibuffer.
1061
1062 Obsolescent.  Use `iswitchb-mode'."
1063   (interactive)
1064   (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)
1065   (global-set-key "\C-xb" 'iswitchb-buffer)
1066   (global-set-key "\C-x4b" 'iswitchb-buffer-other-window)
1067   (global-set-key "\C-x4\C-o" 'iswitchb-display-buffer)
1068   (global-set-key "\C-x5b" 'iswitchb-buffer-other-frame))
1069
1070 ;;;###autoload
1071 (defun iswitchb-buffer ()
1072   "Switch to another buffer.
1073
1074 The buffer name is selected interactively by typing a substring.  The
1075 buffer is displayed according to `iswitchb-default-method' -- the
1076 default is to show it in the same window, unless it is already visible
1077 in another frame.
1078 For details of keybindings, do `\\[describe-function] iswitchb'."
1079   (interactive)
1080   (setq iswitchb-method iswitchb-default-method)
1081   (iswitchb))
1082
1083 ;;;###autoload
1084 (defun iswitchb-buffer-other-window ()
1085   "Switch to another buffer and show it in another window.
1086 The buffer name is selected interactively by typing a substring.
1087 For details of keybindings, do `\\[describe-function] iswitchb'."
1088   (interactive)
1089   (setq iswitchb-method 'otherwindow)
1090   (iswitchb))
1091
1092 ;;;###autoload
1093 (defun iswitchb-display-buffer ()
1094   "Display a buffer in another window but don't select it.
1095 The buffer name is selected interactively by typing a substring.
1096 For details of keybindings, do `\\[describe-function] iswitchb'."
1097   (interactive)
1098   (setq iswitchb-method 'display)
1099   (iswitchb))
1100
1101 ;;;###autoload
1102 (defun iswitchb-buffer-other-frame ()
1103   "Switch to another buffer and show it in another frame.
1104 The buffer name is selected interactively by typing a substring.
1105 For details of keybindings, do `\\[describe-function] iswitchb'."
1106   (interactive)
1107   (setq iswitchb-method 'otherframe)
1108   (iswitchb))
1109
1110 ;;; XEmacs hack for showing default buffer
1111
1112 ;; The first time we enter the minibuffer, Emacs puts up the default
1113 ;; buffer to switch to, but XEmacs doesn't -- presumably there is a
1114 ;; subtle difference in the two versions of post-command-hook.  The
1115 ;; default is shown for both whenever we delete all of our text
1116 ;; though, indicating its just a problem the first time we enter the
1117 ;; function.  To solve this, we use another entry hook for emacs to
1118 ;; show the default the first time we enter the minibuffer.
1119
1120 (defun iswitchb-init-XEmacs-trick ()
1121   "Display default buffer when first entering minibuffer.
1122 This is a hack for XEmacs, and should really be handled by `iswitchb-exhibit'."
1123   (if (iswitchb-entryfn-p)
1124       (progn
1125         (iswitchb-exhibit)
1126         (goto-char (point-min)))))
1127
1128 ;; add this hook for XEmacs only.
1129 (if iswitchb-xemacs
1130     (add-hook 'iswitchb-minibuffer-setup-hook
1131               'iswitchb-init-XEmacs-trick))
1132
1133 ;;; XEmacs / backspace key
1134 ;; For some reason, if the backspace key is pressed in XEmacs, the
1135 ;; line gets confused, so I've added a simple key definition to make
1136 ;; backspace act like the normal delete key.
1137
1138 (defun iswitchb-xemacs-backspacekey ()
1139   "Bind backspace to `backward-delete-char'."
1140   (define-key iswitchb-mode-map '[backspace] 'backward-delete-char)
1141   (define-key iswitchb-mode-map '[(meta backspace)] 'backward-kill-word))
1142
1143 (if iswitchb-xemacs
1144     (add-hook 'iswitchb-define-mode-map-hook
1145               'iswitchb-xemacs-backspacekey))
1146
1147 ;;; ICOMPLETE TYPE CODE
1148
1149 (defun iswitchb-exhibit ()
1150   "Find matching buffers and display a list in the minibuffer.
1151 Copied from `icomplete-exhibit' with two changes:
1152 1. It prints a default buffer name when there is no text yet entered.
1153 2. It calls my completion routine rather than the standard completion."
1154   (if iswitchb-use-mycompletion
1155       (let ((contents (buffer-substring (minibuffer-prompt-end) (point-max)))
1156             (buffer-undo-list t))
1157         (save-excursion
1158           (goto-char (point-max))
1159                                         ; Register the end of input, so we
1160                                         ; know where the extra stuff
1161                                         ; (match-status info) begins:
1162           (if (not (boundp 'iswitchb-eoinput))
1163               ;; In case it got wiped out by major mode business:
1164               (make-local-variable 'iswitchb-eoinput))
1165           (setq iswitchb-eoinput (point))
1166           ;; Update the list of matches
1167           (setq iswitchb-text contents)
1168           (iswitchb-set-matches)
1169           (setq iswitchb-rescan t)
1170           (iswitchb-set-common-completion)
1171
1172           ;; Insert the match-status information:
1173           (insert-string (iswitchb-completions
1174                           contents
1175                           minibuffer-completion-table
1176                           minibuffer-completion-predicate
1177                           (not minibuffer-completion-confirm)))))))
1178
1179 (defun iswitchb-completions (name candidates predicate require-match)
1180   "Return the string that is displayed after the user's text.
1181 Modified from `icomplete-completions'."
1182
1183   (let ((comps iswitchb-matches)
1184                                         ; "-determined" - only one candidate
1185         (open-bracket-determined (if require-match "(" "["))
1186         (close-bracket-determined (if require-match ")" "]"))
1187                                         ;"-prospects" - more than one candidate
1188         (open-bracket-prospects "{")
1189         (close-bracket-prospects "}")
1190         first)
1191
1192     (if (and iswitchb-use-fonts  comps)
1193         (progn
1194           (setq first (car comps))
1195           (setq first (format "%s" first))
1196           (put-text-property 0 (length first) 'face
1197                              (if (= (length comps) 1)
1198                                  'font-lock-comment-face
1199                                'font-lock-function-name-face)
1200                              first)
1201           (setq comps  (cons first (cdr comps)))))
1202
1203     (cond ((null comps) (format " %sNo match%s"
1204                                 open-bracket-determined
1205                                 close-bracket-determined))
1206
1207           ((null (cdr comps))           ;one match
1208            (concat (if (and (> (length (car comps))
1209                                (length name)))
1210                        (concat open-bracket-determined
1211                                ;; when there is one match, show the
1212                                ;; matching buffer name in full
1213                                (car comps)
1214                                close-bracket-determined)
1215                      "")
1216                    (if (not iswitchb-use-fonts) " [Matched]")))
1217           (t                            ;multiple matches
1218            (let* (
1219                   ;;(most (try-completion name candidates predicate))
1220                   (most nil)
1221                   (most-len (length most))
1222                   most-is-exact
1223                   first
1224                   (alternatives
1225                    (apply
1226                     (function concat)
1227                     (cdr (apply
1228                           (function nconc)
1229                           (mapcar '(lambda (com)
1230                                      (if (= (length com) most-len)
1231                                          ;; Most is one exact match,
1232                                          ;; note that and leave out
1233                                          ;; for later indication:
1234                                          (progn
1235                                            (setq most-is-exact t)
1236                                            ())
1237                                        (list ","
1238                                              (substring com
1239                                                         most-len))))
1240                                   comps))))))
1241
1242              (concat
1243
1244               ;; put in common completion item -- what you get by
1245               ;; pressing tab
1246               (if (> (length iswitchb-common-match-string) (length name))
1247                   (concat open-bracket-determined
1248                           (substring iswitchb-common-match-string
1249                                      (length name))
1250                           close-bracket-determined))
1251               ;; end of partial matches...
1252
1253               ;; think this bit can be ignored.
1254               (and (> most-len (length name))
1255                    (concat open-bracket-determined
1256                            (substring most (length name))
1257                            close-bracket-determined))
1258
1259               ;; list all alternatives
1260               open-bracket-prospects
1261               (if most-is-exact
1262                   (concat "," alternatives)
1263                 alternatives)
1264               close-bracket-prospects))))))
1265
1266 (defun iswitchb-minibuffer-setup ()
1267   "Set up minibuffer for `iswitchb-buffer'.
1268 Copied from `icomplete-minibuffer-setup-hook'."
1269   (if (iswitchb-entryfn-p)
1270       (progn
1271
1272         (make-local-variable 'iswitchb-use-mycompletion)
1273         (setq iswitchb-use-mycompletion t)
1274         (make-local-hook 'pre-command-hook)
1275         (add-hook 'pre-command-hook
1276                   'iswitchb-pre-command
1277                   nil t)
1278         (make-local-hook 'post-command-hook)
1279         (add-hook 'post-command-hook
1280                   'iswitchb-post-command
1281                   nil t)
1282
1283         (run-hooks 'iswitchb-minibuffer-setup-hook))))
1284
1285 (defun iswitchb-pre-command ()
1286   "Run before command in `iswitchb-buffer'."
1287   (iswitchb-tidy))
1288
1289 (defun iswitchb-post-command ()
1290   "Run after command in `iswitchb-buffer'."
1291   (iswitchb-exhibit))
1292
1293 (defun iswitchb-tidy ()
1294   "Remove completions display, if any, prior to new user input.
1295 Copied from `icomplete-tidy'."
1296
1297   (if (and (boundp 'iswitchb-eoinput)
1298            iswitchb-eoinput)
1299
1300       (if (> iswitchb-eoinput (point-max))
1301           ;; Oops, got rug pulled out from under us - reinit:
1302           (setq iswitchb-eoinput (point-max))
1303         (let ((buffer-undo-list buffer-undo-list )) ; prevent entry
1304           (delete-region iswitchb-eoinput (point-max))))
1305
1306     ;; Reestablish the local variable 'cause minibuffer-setup is weird:
1307     (make-local-variable 'iswitchb-eoinput)
1308     (setq iswitchb-eoinput 1)))
1309
1310 (defun iswitchb-entryfn-p ()
1311   "Return non-nil if we are using `iswitchb-buffer'."
1312   (eq iswitchb-minibuf-depth (minibuffer-depth)))
1313
1314 (defun iswitchb-summaries-to-end ()
1315   "Move the summaries to the end of the list.
1316 This is an example function which can be hooked on to
1317 `iswitchb-make-buflist-hook'.  Any buffer matching the regexps
1318 `Summary' or `output\*$'are put to the end of the list."
1319   (let ((summaries (delq nil
1320                          (mapcar
1321                           (lambda (x)
1322                             (if (string-match "Summary\\|output\\*$" x)
1323                                 x))
1324                           iswitchb-temp-buflist))))
1325     (iswitchb-to-end summaries)))
1326
1327 (defun iswitchb-case ()
1328   "Return non-nil iff we should ignore case when matching.
1329 See the variable `iswitchb-case' for details."
1330   (if iswitchb-case
1331       (if iswitchb-xemacs
1332           (isearch-no-upper-case-p iswitchb-text)
1333         (isearch-no-upper-case-p iswitchb-text t))))
1334
1335 ;;;###autoload
1336 (defun iswitchb-mode (&optional arg)
1337   "Toggle Iswitchb global minor mode.
1338 With arg, turn Iswitchb mode on if and only iff ARG is positive.
1339 This mode enables switching between buffers using substrings.  See
1340 `iswitchb' for details."
1341   (interactive "P")
1342   (setq iswitchb-mode
1343         (if arg
1344             (> (prefix-numeric-value arg) 0)
1345           (not iswitchb-mode)))
1346   (if iswitchb-mode
1347       (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)
1348     (remove-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup))
1349   (run-hooks 'iswitchb-mode-hook)
1350   (if (interactive-p)
1351       (message "Iswitchb mode %sabled"
1352                (if iswitchb-mode "en" "dis"))))
1353
1354 (unless (assq 'iswitchb-mode minor-mode-map-alist)
1355   (push (cons 'iswitchb-mode iswitchb-global-map)
1356         minor-mode-map-alist))
1357
1358 (provide 'iswitchb)
1359
1360 ;;; iswitchb.el ends here