lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info, where USAGE info
  69 is a string describing the argument list of DEF, such as
  70 \"(apply FUNCTION &rest ARGUMENTS)\".
  71 DEF is the function whose usage we're looking for in DOCSTRING."
  72   ;; Functions can get the calling sequence at the end of the doc string.
  73   ;; In cases where `function' has been fset to a subr we can't search for
  74   ;; function's name in the doc string so we use `fn' as the anonymous
  75   ;; function name instead.
  76   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  77     (cons (format "(%s%s"
  78                   ;; Replace `fn' with the actual function name.
  79                   (if (consp def) "anonymous" def)
  80                   (match-string 1 docstring))
  81           (unless (zerop (match-beginning 0))
  82             (substring docstring 0 (match-beginning 0))))))
  83
  84 ;; FIXME: Move to subr.el?
  85 (defun help-add-fundoc-usage (docstring arglist)
  86   "Add the usage info to DOCSTRING.
  87 If DOCSTRING already has a usage info, then just return it unchanged.
  88 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  89 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  90   (unless (stringp docstring) (setq docstring ""))
  91   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring)
  92           (eq arglist t))
  93       docstring
  94     (concat docstring
  95             (if (string-match "\n?\n\\'" docstring)
  96                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  97               "\n\n")
  98             (if (and (stringp arglist)
  99                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
 100                 (concat "(fn" (match-string 1 arglist) ")")
 101               (format "%S" (help-make-usage 'fn arglist))))))
 102
 103 ;; FIXME: Move to subr.el?
 104 (defun help-function-arglist (def &optional preserve-names)
 105   "Return a formal argument list for the function DEF.
 106 IF PRESERVE-NAMES is non-nil, return a formal arglist that uses
 107 the same names as used in the original source code, when possible."
 108   ;; Handle symbols aliased to other symbols.
 109   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 110   ;; If definition is a macro, find the function inside it.
 111   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 112   (cond
 113    ((and (byte-code-function-p def) (listp (aref def 0))) (aref def 0))
 114    ((eq (car-safe def) 'lambda) (nth 1 def))
 115    ((eq (car-safe def) 'closure) (nth 2 def))
 116    ((or (and (byte-code-function-p def) (integerp (aref def 0)))
 117         (subrp def))
 118     (or (when preserve-names
 119           (let* ((doc (condition-case nil (documentation def) (error nil)))
 120                  (docargs (if doc (car (help-split-fundoc doc nil))))
 121                  (arglist (if docargs
 122                               (cdar (read-from-string (downcase docargs)))))
 123                  (valid t))
 124             ;; Check validity.
 125             (dolist (arg arglist)
 126               (unless (and (symbolp arg)
 127                            (let ((name (symbol-name arg)))
 128                              (if (eq (aref name 0) ?&)
 129                                  (memq arg '(&rest &optional))
 130                                (not (string-match "\\." name)))))
 131                 (setq valid nil)))
 132             (when valid arglist)))
 133         (let* ((args-desc (if (not (subrp def))
 134                               (aref def 0)
 135                             (let ((a (subr-arity def)))
 136                               (logior (car a)
 137                                       (if (numberp (cdr a))
 138                                           (lsh (cdr a) 8)
 139                                         (lsh 1 7))))))
 140                (max (lsh args-desc -8))
 141                (min (logand args-desc 127))
 142                (rest (logand args-desc 128))
 143                (arglist ()))
 144           (dotimes (i min)
 145             (push (intern (concat "arg" (number-to-string (1+ i)))) arglist))
 146           (when (> max min)
 147             (push '&optional arglist)
 148             (dotimes (i (- max min))
 149               (push (intern (concat "arg" (number-to-string (+ 1 i min))))
 150                     arglist)))
 151           (unless (zerop rest) (push '&rest arglist) (push 'rest arglist))
 152           (nreverse arglist))))
 153    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 154     "[Arg list not available until function definition is loaded.]")
 155    (t t)))
 156
 157 ;; FIXME: Move to subr.el?
 158 (defun help-make-usage (function arglist)
 159   (cons (if (symbolp function) function 'anonymous)
 160         (mapcar (lambda (arg)
 161                   (if (not (symbolp arg)) arg
 162                     (let ((name (symbol-name arg)))
 163                       (cond
 164                        ((string-match "\\`&" name) arg)
 165                        ((string-match "\\`_" name)
 166                         (intern (upcase (substring name 1))))
 167                        (t (intern (upcase name)))))))
 168                 arglist)))
 169
 170 ;; Could be this, if we make symbol-file do the work below.
 171 ;; (defun help-C-file-name (subr-or-var kind)
 172 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 173 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 174 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 175 ;;               (subr-name subr-or-var))
 176 ;;             (if (eq kind 'var) 'defvar 'defun)))
 177 ;;;###autoload
 178 (defun help-C-file-name (subr-or-var kind)
 179   "Return the name of the C file where SUBR-OR-VAR is defined.
 180 KIND should be `var' for a variable or `subr' for a subroutine."
 181   (let ((docbuf (get-buffer-create " *DOC*"))
 182         (name (if (eq 'var kind)
 183                   (concat "V" (symbol-name subr-or-var))
 184                 (concat "F" (subr-name subr-or-var)))))
 185     (with-current-buffer docbuf
 186       (goto-char (point-min))
 187       (if (eobp)
 188           (insert-file-contents-literally
 189            (expand-file-name internal-doc-file-name doc-directory)))
 190       (let ((file (catch 'loop
 191                     (while t
 192                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 193                         (re-search-backward "\1fS\\(.*\\)")
 194                         (let ((file (match-string 1)))
 195                           (if (member file build-files)
 196                               (throw 'loop file)
 197                             (goto-char pnt))))))))
 198         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 199             (setq file (replace-match ".m" t t file 1))
 200           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 201               (setq file (replace-match ".c" t t file))))
 202         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 203             (concat "src/" file)
 204           file)))))
 205
 206 (defcustom help-downcase-arguments nil
 207   "If non-nil, argument names in *Help* buffers are downcased."
 208   :type 'boolean
 209   :group 'help
 210   :version "23.2")
 211
 212 (defun help-highlight-arg (arg)
 213   "Highlight ARG as an argument name for a *Help* buffer.
 214 Return ARG in face `help-argument-name'; ARG is also downcased
 215 if the variable `help-downcase-arguments' is non-nil."
 216   (propertize (if help-downcase-arguments (downcase arg) arg)
 217               'face 'help-argument-name))
 218
 219 (defun help-do-arg-highlight (doc args)
 220   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 221     (modify-syntax-entry ?\- "w")
 222     (dolist (arg args)
 223       (setq doc (replace-regexp-in-string
 224                  ;; This is heuristic, but covers all common cases
 225                  ;; except ARG1-ARG2
 226                  (concat "\\<"                   ; beginning of word
 227                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 228                          "\\("
 229                          (regexp-quote arg)
 230                          "\\)"
 231                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 232                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 233                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 234                          "\\>")                  ; end of word
 235                  (help-highlight-arg arg)
 236                  doc t t 1)))
 237     doc))
 238
 239 (defun help-highlight-arguments (usage doc &rest args)
 240   (when (and usage (string-match "^(" usage))
 241     (with-temp-buffer
 242       (insert usage)
 243       (goto-char (point-min))
 244       (let ((case-fold-search nil)
 245             (next (not (or args (looking-at "\\["))))
 246             (opt nil))
 247         ;; Make a list of all arguments
 248         (skip-chars-forward "^ ")
 249         (while next
 250           (or opt (not (looking-at " &")) (setq opt t))
 251           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 252               (setq next nil)
 253             (setq args (cons (match-string 2) args))
 254             (when (and opt (string= (match-string 1) "("))
 255               ;; A pesky CL-style optional argument with default value,
 256               ;; so let's skip over it
 257               (search-backward "(")
 258               (goto-char (scan-sexps (point) 1)))))
 259         ;; Highlight arguments in the USAGE string
 260         (setq usage (help-do-arg-highlight (buffer-string) args))
 261         ;; Highlight arguments in the DOC string
 262         (setq doc (and doc (help-do-arg-highlight doc args))))))
 263   ;; Return value is like the one from help-split-fundoc, but highlighted
 264   (cons usage doc))
 265
 266 ;; The following function was compiled from the former functions
 267 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 268 ;; some excerpts from `describe-function-1' and `describe-variable'.
 269 ;; The only additional twists provided are (1) locate the defining file
 270 ;; for autoloaded functions, and (2) give preference to files in the
 271 ;; "install directory" (directories found via `load-path') rather than
 272 ;; to files in the "compile directory" (directories found by searching
 273 ;; the loaddefs.el file).  We autoload it because it's also used by
 274 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 275
 276 ;;;###autoload
 277 (defun find-lisp-object-file-name (object type)
 278   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 279 OBJECT should be a symbol associated with a function, variable, or face;
 280   alternatively, it can be a function definition.
 281 If TYPE is `defvar', search for a variable definition.
 282 If TYPE is `defface', search for a face definition.
 283 If TYPE is the value returned by `symbol-function' for a function symbol,
 284  search for a function definition.
 285
 286 The return value is the absolute name of a readable file where OBJECT is
 287 defined.  If several such files exist, preference is given to a file
 288 found via `load-path'.  The return value can also be `C-source', which
 289 means that OBJECT is a function or variable defined in C.  If no
 290 suitable file is found, return nil."
 291   (let* ((autoloaded (eq (car-safe type) 'autoload))
 292          (file-name (or (and autoloaded (nth 1 type))
 293                         (symbol-file
 294                          object (if (memq type (list 'defvar 'defface))
 295                                     type
 296                                   'defun)))))
 297     (cond
 298      (autoloaded
 299       ;; An autoloaded function: Locate the file since `symbol-function'
 300       ;; has only returned a bare string here.
 301       (setq file-name
 302             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 303      ((and (stringp file-name)
 304            (string-match "[.]*loaddefs.el\\'" file-name))
 305       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 306       ;; and try to extract the defining file.  The following form is
 307       ;; from `describe-function-1' and `describe-variable'.
 308       (let ((location
 309              (condition-case nil
 310                  (find-function-search-for-symbol object nil file-name)
 311                (error nil))))
 312         (when (cdr location)
 313           (with-current-buffer (car location)
 314             (goto-char (cdr location))
 315             (when (re-search-backward
 316                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 317               (setq file-name
 318                     (locate-file
 319                      (file-name-sans-extension
 320                       (match-string-no-properties 1))
 321                      load-path '(".el" ".elc") 'readable))))))))
 322
 323     (cond
 324      ((and (not file-name) (subrp type))
 325       ;; A built-in function.  The form is from `describe-function-1'.
 326       (if (get-buffer " *DOC*")
 327           (help-C-file-name type 'subr)
 328         'C-source))
 329      ((and (not file-name) (symbolp object)
 330            (integerp (get object 'variable-documentation)))
 331       ;; A variable defined in C.  The form is from `describe-variable'.
 332       (if (get-buffer " *DOC*")
 333           (help-C-file-name object 'var)
 334         'C-source))
 335      ((not (stringp file-name))
 336       ;; If we don't have a file-name string by now, we lost.
 337       nil)
 338      ;; Now, `file-name' should have become an absolute file name.
 339      ;; For files loaded from ~/.emacs.elc, try ~/.emacs.
 340      ((let (fn)
 341         (and (string-equal file-name
 342                            (expand-file-name ".emacs.elc" "~"))
 343              (file-readable-p (setq fn (expand-file-name ".emacs" "~")))
 344              fn)))
 345      ;; When the Elisp source file can be found in the install
 346      ;; directory, return the name of that file.
 347      ((let ((lib-name
 348              (if (string-match "[.]elc\\'" file-name)
 349                  (substring-no-properties file-name 0 -1)
 350                file-name)))
 351         (or (and (file-readable-p lib-name) lib-name)
 352             ;; The library might be compressed.
 353             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 354      ((let* ((lib-name (file-name-nondirectory file-name))
 355              ;; The next form is from `describe-simplify-lib-file-name'.
 356              (file-name
 357               ;; Try converting the absolute file name to a library
 358               ;; name, convert that back to a file name and see if we
 359               ;; get the original one.  If so, they are equivalent.
 360               (if (equal file-name (locate-file lib-name load-path '("")))
 361                   (if (string-match "[.]elc\\'" lib-name)
 362                       (substring-no-properties lib-name 0 -1)
 363                     lib-name)
 364                 file-name))
 365              ;; The next three forms are from `find-source-lisp-file'.
 366              (elc-file (locate-file
 367                         (concat file-name
 368                                 (if (string-match "\\.el\\'" file-name)
 369                                     "c"
 370                                   ".elc"))
 371                         load-path nil 'readable))
 372              (str (when elc-file
 373                     (with-temp-buffer
 374                       (insert-file-contents-literally elc-file nil 0 256)
 375                       (buffer-string))))
 376              (src-file (and str
 377                             (string-match ";;; from file \\(.*\\.el\\)" str)
 378                             (match-string 1 str))))
 379         (and src-file (file-readable-p src-file) src-file))))))
 380
 381 (declare-function ad-get-advice-info "advice" (function))
 382
 383 (defun help-fns--compiler-macro (function)
 384   (let ((handler nil))
 385     ;; FIXME: Copied from macroexp.el.
 386     (while (and (symbolp function)
 387                 (not (setq handler (get function 'compiler-macro)))
 388                 (fboundp function))
 389       ;; Follow the sequence of aliases.
 390       (setq function (symbol-function function)))
 391     (when handler
 392       (princ "This function has a compiler macro")
 393       (let ((lib (get function 'compiler-macro-file)))
 394         ;; FIXME: rather than look at the compiler-macro-file property,
 395         ;; just look at `handler' itself.
 396         (when (stringp lib)
 397           (princ (format " in `%s'" lib))
 398           (with-current-buffer standard-output
 399             (save-excursion
 400               (re-search-backward "`\\([^`']+\\)'" nil t)
 401               (help-xref-button 1 'help-function-cmacro function lib)))))
 402       (princ ".\n\n"))))
 403
 404 ;; We could use `symbol-file' but this is a wee bit more efficient.
 405 (defun help-fns--autoloaded-p (function file)
 406   "Return non-nil if FUNCTION has previously been autoloaded.
 407 FILE is the file where FUNCTION was probably defined."
 408   (let* ((file (file-name-sans-extension (file-truename file)))
 409          (load-hist load-history)
 410          (target (cons t function))
 411          found)
 412     (while (and load-hist (not found))
 413       (and (caar load-hist)
 414            (equal (file-name-sans-extension (caar load-hist)) file)
 415            (setq found (member target (cdar load-hist))))
 416       (setq load-hist (cdr load-hist)))
 417     found))
 418
 419 ;;;###autoload
 420 (defun describe-function-1 (function)
 421   (let* ((advised (and (symbolp function) (featurep 'advice)
 422                        (ad-get-advice-info function)))
 423          ;; If the function is advised, use the symbol that has the
 424          ;; real definition, if that symbol is already set up.
 425          (real-function
 426           (or (and advised
 427                    (let ((origname (cdr (assq 'origname advised))))
 428                      (and (fboundp origname) origname)))
 429               function))
 430          ;; Get the real definition.
 431          (def (if (symbolp real-function)
 432                   (symbol-function real-function)
 433                 function))
 434          (aliased (symbolp def))
 435          (real-def (if aliased
 436                        (let ((f def))
 437                          (while (and (fboundp f)
 438                                      (symbolp (symbol-function f)))
 439                            (setq f (symbol-function f)))
 440                          f)
 441                      def))
 442          (file-name (find-lisp-object-file-name function def))
 443          (pt1 (with-current-buffer (help-buffer) (point)))
 444          (beg (if (and (or (byte-code-function-p def)
 445                            (keymapp def)
 446                            (memq (car-safe def) '(macro lambda closure)))
 447                        (help-fns--autoloaded-p function file-name))
 448                   (if (commandp def)
 449                       "an interactive autoloaded "
 450                     "an autoloaded ")
 451                 (if (commandp def) "an interactive " "a "))))
 452
 453     ;; Print what kind of function-like object FUNCTION is.
 454     (princ (cond ((or (stringp def) (vectorp def))
 455                   "a keyboard macro")
 456                  ((subrp def)
 457                   (if (eq 'unevalled (cdr (subr-arity def)))
 458                       (concat beg "special form")
 459                     (concat beg "built-in function")))
 460                  ((byte-code-function-p def)
 461                   (concat beg "compiled Lisp function"))
 462                  (aliased
 463                   (format "an alias for `%s'" real-def))
 464                  ((eq (car-safe def) 'lambda)
 465                   (concat beg "Lisp function"))
 466                  ((eq (car-safe def) 'macro)
 467                   (concat beg "Lisp macro"))
 468                  ((eq (car-safe def) 'closure)
 469                   (concat beg "Lisp closure"))
 470                  ((eq (car-safe def) 'autoload)
 471                   (format "%s autoloaded %s"
 472                           (if (commandp def) "an interactive" "an")
 473                           (if (eq (nth 4 def) 'keymap) "keymap"
 474                             (if (nth 4 def) "Lisp macro" "Lisp function"))))
 475                  ((keymapp def)
 476                   (let ((is-full nil)
 477                         (elts (cdr-safe def)))
 478                     (while elts
 479                       (if (char-table-p (car-safe elts))
 480                           (setq is-full t
 481                                 elts nil))
 482                       (setq elts (cdr-safe elts)))
 483                     (concat beg (if is-full "keymap" "sparse keymap"))))
 484                  (t "")))
 485
 486     (if (and aliased (not (fboundp real-def)))
 487         (princ ",\nwhich is not defined.  Please make a bug report.")
 488       (with-current-buffer standard-output
 489         (save-excursion
 490           (save-match-data
 491             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 492               (help-xref-button 1 'help-function real-def)))))
 493
 494       (when file-name
 495         (princ " in `")
 496         ;; We used to add .el to the file name,
 497         ;; but that's completely wrong when the user used load-file.
 498         (princ (if (eq file-name 'C-source)
 499                    "C source code"
 500                  (file-name-nondirectory file-name)))
 501         (princ "'")
 502         ;; Make a hyperlink to the library.
 503         (with-current-buffer standard-output
 504           (save-excursion
 505             (re-search-backward "`\\([^`']+\\)'" nil t)
 506             (help-xref-button 1 'help-function-def function file-name))))
 507       (princ ".")
 508       (with-current-buffer (help-buffer)
 509         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 510                                   (point)))
 511       (terpri)(terpri)
 512       (when (commandp function)
 513         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 514               (remapped (command-remapping function)))
 515           (unless (memq remapped '(ignore undefined))
 516             (let ((keys (where-is-internal
 517                          (or remapped function) overriding-local-map nil nil))
 518                   non-modified-keys)
 519               (if (and (eq function 'self-insert-command)
 520                        (vectorp (car-safe keys))
 521                        (consp (aref (car keys) 0)))
 522                   (princ "It is bound to many ordinary text characters.\n")
 523                 ;; Which non-control non-meta keys run this command?
 524                 (dolist (key keys)
 525                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 526                       (push key non-modified-keys)))
 527                 (when remapped
 528                   (princ "Its keys are remapped to `")
 529                   (princ (symbol-name remapped))
 530                   (princ "'.\n"))
 531
 532                 (when keys
 533                   (princ (if remapped
 534                              "Without this remapping, it would be bound to "
 535                            "It is bound to "))
 536                   ;; If lots of ordinary text characters run this command,
 537                   ;; don't mention them one by one.
 538                   (if (< (length non-modified-keys) 10)
 539                       (princ (mapconcat 'key-description keys ", "))
 540                     (dolist (key non-modified-keys)
 541                       (setq keys (delq key keys)))
 542                     (if keys
 543                         (progn
 544                           (princ (mapconcat 'key-description keys ", "))
 545                           (princ ", and many ordinary text characters"))
 546                       (princ "many ordinary text characters"))))
 547                 (when (or remapped keys non-modified-keys)
 548                   (princ ".")
 549                   (terpri)))))
 550
 551           (with-current-buffer (help-buffer)
 552             (fill-region-as-paragraph pt2 (point))
 553             (unless (looking-back "\n\n")
 554               (terpri)))))
 555       (help-fns--compiler-macro function)
 556       (let* ((advertised (gethash real-def advertised-signature-table t))
 557              (arglist (if (listp advertised)
 558                           advertised (help-function-arglist real-def)))
 559              (doc-raw (condition-case err
 560                           (documentation function t)
 561                         (error (format "No Doc! %S" err))))
 562              ;; If the function is autoloaded, and its docstring has
 563              ;; key substitution constructs, load the library.
 564              (doc (progn
 565                     (and (eq (car-safe real-def) 'autoload)
 566                          help-enable-auto-load
 567                          (string-match "\\([^\\]=\\|[^=]\\|\\`\\)\\\\[[{<]"
 568                                        doc-raw)
 569                          (load (cadr real-def) t))
 570                     (substitute-command-keys doc-raw)))
 571              (usage (help-split-fundoc doc function)))
 572         (with-current-buffer standard-output
 573           ;; If definition is a keymap, skip arglist note.
 574           (unless (keymapp function)
 575             (if usage (setq doc (cdr usage)))
 576             (let* ((use (cond
 577                          ((and usage (not (listp advertised))) (car usage))
 578                          ((listp arglist)
 579                           (format "%S" (help-make-usage function arglist)))
 580                          ((stringp arglist) arglist)
 581                          ;; Maybe the arglist is in the docstring of a symbol
 582                          ;; this one is aliased to.
 583                          ((let ((fun real-function))
 584                             (while (and (symbolp fun)
 585                                         (setq fun (symbol-function fun))
 586                                         (not (setq usage (help-split-fundoc
 587                                                           (documentation fun)
 588                                                           function)))))
 589                             usage)
 590                           (car usage))
 591                          ((or (stringp real-def)
 592                               (vectorp real-def))
 593                           (format "\nMacro: %s" (format-kbd-macro real-def)))
 594                          (t "[Missing arglist.  Please make a bug report.]")))
 595                    (high (help-highlight-arguments use doc)))
 596               (let ((fill-begin (point)))
 597                 (insert (car high) "\n")
 598                 (fill-region fill-begin (point)))
 599               (setq doc (cdr high))))
 600
 601           ;; If this is a derived mode, link to the parent.
 602           (let ((parent-mode (and (symbolp real-function)
 603                                   (get real-function
 604                                        'derived-mode-parent))))
 605             (when parent-mode
 606               (with-current-buffer standard-output
 607                 (insert "\nParent mode: `")
 608                 (let ((beg (point)))
 609                   (insert (format "%s" parent-mode))
 610                   (make-text-button beg (point)
 611                                     'type 'help-function
 612                                     'help-args (list parent-mode))))
 613               (princ "'.\n")))
 614
 615           (let* ((obsolete (and
 616                             ;; function might be a lambda construct.
 617                             (symbolp function)
 618                             (get function 'byte-obsolete-info)))
 619                  (use (car obsolete)))
 620             (when obsolete
 621               (princ "\nThis function is obsolete")
 622               (when (nth 2 obsolete)
 623                 (insert (format " since %s" (nth 2 obsolete))))
 624               (insert (cond ((stringp use) (concat ";\n" use))
 625                             (use (format ";\nuse `%s' instead." use))
 626                             (t "."))
 627                       "\n"))
 628             (insert "\n"
 629                     (or doc "Not documented."))))))))
 630
 631 \f
 632 ;; Variables
 633
 634 ;;;###autoload
 635 (defun variable-at-point (&optional any-symbol)
 636   "Return the bound variable symbol found at or before point.
 637 Return 0 if there is no such symbol.
 638 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 639   (with-syntax-table emacs-lisp-mode-syntax-table
 640     (or (condition-case ()
 641             (save-excursion
 642               (skip-chars-forward "'")
 643               (or (not (zerop (skip-syntax-backward "_w")))
 644                   (eq (char-syntax (following-char)) ?w)
 645                   (eq (char-syntax (following-char)) ?_)
 646                   (forward-sexp -1))
 647               (skip-chars-forward "'")
 648               (let ((obj (read (current-buffer))))
 649                 (and (symbolp obj) (boundp obj) obj)))
 650           (error nil))
 651         (let* ((str (find-tag-default))
 652                (sym (if str (intern-soft str))))
 653           (if (and sym (or any-symbol (boundp sym)))
 654               sym
 655             (save-match-data
 656               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 657                 (setq sym (intern-soft (match-string 1 str)))
 658                 (and (or any-symbol (boundp sym)) sym)))))
 659         0)))
 660
 661 (defun describe-variable-custom-version-info (variable)
 662   (let ((custom-version (get variable 'custom-version))
 663         (cpv (get variable 'custom-package-version))
 664         (output nil))
 665     (if custom-version
 666         (setq output
 667               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 668                       custom-version))
 669       (when cpv
 670         (let* ((package (car-safe cpv))
 671                (version (if (listp (cdr-safe cpv))
 672                             (car (cdr-safe cpv))
 673                           (cdr-safe cpv)))
 674                (pkg-versions (assq package customize-package-emacs-version-alist))
 675                (emacsv (cdr (assoc version pkg-versions))))
 676           (if (and package version)
 677               (setq output
 678                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 679                                     (if emacsv
 680                                         (format " that is part of Emacs %s" emacsv))
 681                                     ".\n")
 682                             version package))))))
 683     output))
 684
 685 ;;;###autoload
 686 (defun describe-variable (variable &optional buffer frame)
 687   "Display the full documentation of VARIABLE (a symbol).
 688 Returns the documentation as a string, also.
 689 If VARIABLE has a buffer-local value in BUFFER or FRAME
 690 \(default to the current buffer and current frame),
 691 it is displayed along with the global value."
 692   (interactive
 693    (let ((v (variable-at-point))
 694          (enable-recursive-minibuffers t)
 695          val)
 696      (setq val (completing-read (if (symbolp v)
 697                                     (format
 698                                      "Describe variable (default %s): " v)
 699                                   "Describe variable: ")
 700                                 obarray
 701                                 (lambda (vv)
 702                                   (or (get vv 'variable-documentation)
 703                                       (and (boundp vv) (not (keywordp vv)))))
 704                                 t nil nil
 705                                 (if (symbolp v) (symbol-name v))))
 706      (list (if (equal val "")
 707                v (intern val)))))
 708   (let (file-name)
 709     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 710     (unless (frame-live-p frame) (setq frame (selected-frame)))
 711     (if (not (symbolp variable))
 712         (message "You did not specify a variable")
 713       (save-excursion
 714         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 715               val val-start-pos locus)
 716           ;; Extract the value before setting up the output buffer,
 717           ;; in case `buffer' *is* the output buffer.
 718           (unless valvoid
 719             (with-selected-frame frame
 720               (with-current-buffer buffer
 721                 (setq val (symbol-value variable)
 722                       locus (variable-binding-locus variable)))))
 723           (help-setup-xref (list #'describe-variable variable buffer)
 724                            (called-interactively-p 'interactive))
 725           (with-help-window (help-buffer)
 726             (with-current-buffer buffer
 727               (prin1 variable)
 728               (setq file-name (find-lisp-object-file-name variable 'defvar))
 729
 730               (if file-name
 731                   (progn
 732                     (princ " is a variable defined in `")
 733                     (princ (if (eq file-name 'C-source)
 734                                "C source code"
 735                              (file-name-nondirectory file-name)))
 736                     (princ "'.\n")
 737                     (with-current-buffer standard-output
 738                       (save-excursion
 739                         (re-search-backward "`\\([^`']+\\)'" nil t)
 740                         (help-xref-button 1 'help-variable-def
 741                                           variable file-name)))
 742                     (if valvoid
 743                         (princ "It is void as a variable.")
 744                       (princ "Its ")))
 745                 (if valvoid
 746                     (princ " is void as a variable.")
 747                   (princ "'s "))))
 748             (unless valvoid
 749               (with-current-buffer standard-output
 750                 (setq val-start-pos (point))
 751                 (princ "value is ")
 752                 (let ((from (point))
 753                       (line-beg (line-beginning-position))
 754                       ;;
 755                       (print-rep
 756                        (let ((print-quoted t))
 757                          (prin1-to-string val))))
 758                   (if (< (+ (length print-rep) (point) (- line-beg)) 68)
 759                       (insert print-rep)
 760                     (terpri)
 761                     (pp val)
 762                     (if (< (point) (+ 68 (line-beginning-position 0)))
 763                         (delete-region from (1+ from))
 764                       (delete-region (1- from) from)))
 765                   (let* ((sv (get variable 'standard-value))
 766                          (origval (and (consp sv)
 767                                        (condition-case nil
 768                                            (eval (car sv))
 769                                          (error :help-eval-error)))))
 770                     (when (and (consp sv)
 771                                (not (equal origval val))
 772                                (not (equal origval :help-eval-error)))
 773                       (princ "\nOriginal value was \n")
 774                       (setq from (point))
 775                       (pp origval)
 776                       (if (< (point) (+ from 20))
 777                           (delete-region (1- from) from)))))))
 778             (terpri)
 779             (when locus
 780               (cond
 781                ((bufferp locus)
 782                 (princ (format "%socal in buffer %s; "
 783                                (if (get variable 'permanent-local)
 784                                    "Permanently l" "L")
 785                                (buffer-name))))
 786                ((framep locus)
 787                 (princ (format "It is a frame-local variable; ")))
 788                ((terminal-live-p locus)
 789                 (princ (format "It is a terminal-local variable; ")))
 790                (t
 791                 (princ (format "It is local to %S" locus))))
 792               (if (not (default-boundp variable))
 793                   (princ "globally void")
 794                 (let ((val (default-value variable)))
 795                   (with-current-buffer standard-output
 796                     (princ "global value is ")
 797                     (terpri)
 798                     ;; Fixme: pp can take an age if you happen to
 799                     ;; ask for a very large expression.  We should
 800                     ;; probably print it raw once and check it's a
 801                     ;; sensible size before prettyprinting.  -- fx
 802                     (let ((from (point)))
 803                       (pp val)
 804                       ;; See previous comment for this function.
 805                       ;; (help-xref-on-pp from (point))
 806                       (if (< (point) (+ from 20))
 807                           (delete-region (1- from) from))))))
 808               (terpri))
 809
 810             ;; If the value is large, move it to the end.
 811             (with-current-buffer standard-output
 812               (when (> (count-lines (point-min) (point-max)) 10)
 813                 ;; Note that setting the syntax table like below
 814                 ;; makes forward-sexp move over a `'s' at the end
 815                 ;; of a symbol.
 816                 (set-syntax-table emacs-lisp-mode-syntax-table)
 817                 (goto-char val-start-pos)
 818                 ;; The line below previously read as
 819                 ;; (delete-region (point) (progn (end-of-line) (point)))
 820                 ;; which suppressed display of the buffer local value for
 821                 ;; large values.
 822                 (when (looking-at "value is") (replace-match ""))
 823                 (save-excursion
 824                   (insert "\n\nValue:")
 825                   (set (make-local-variable 'help-button-cache)
 826                        (point-marker)))
 827                 (insert "value is shown ")
 828                 (insert-button "below"
 829                                'action help-button-cache
 830                                'follow-link t
 831                                'help-echo "mouse-2, RET: show value")
 832                 (insert ".\n")))
 833             (terpri)
 834
 835             (let* ((alias (condition-case nil
 836                               (indirect-variable variable)
 837                             (error variable)))
 838                    (obsolete (get variable 'byte-obsolete-variable))
 839                    (use (car obsolete))
 840                    (safe-var (get variable 'safe-local-variable))
 841                    (doc (condition-case err
 842                             (or (documentation-property
 843                                  variable 'variable-documentation)
 844                                 (documentation-property
 845                                  alias 'variable-documentation))
 846                           (error (format "Doc not found: %S" err))))
 847                    (extra-line nil))
 848               ;; Add a note for variables that have been make-var-buffer-local.
 849               (when (and (local-variable-if-set-p variable)
 850                          (or (not (local-variable-p variable))
 851                              (with-temp-buffer
 852                                (local-variable-if-set-p variable))))
 853                 (setq extra-line t)
 854                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 855
 856               ;; Mention if it's an alias
 857               (unless (eq alias variable)
 858                 (setq extra-line t)
 859                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 860
 861               (when obsolete
 862                 (setq extra-line t)
 863                 (princ "  This variable is obsolete")
 864                 (if (nth 2 obsolete)
 865                     (princ (format " since %s" (nth 2 obsolete))))
 866                 (princ (cond ((stringp use) (concat ";\n  " use))
 867                              (use (format ";\n  use `%s' instead." (car obsolete)))
 868                              (t ".")))
 869                 (terpri))
 870
 871               (when (member (cons variable val) file-local-variables-alist)
 872                 (setq extra-line t)
 873                 (if (member (cons variable val) dir-local-variables-alist)
 874                     (let ((file (and (buffer-file-name)
 875                                       (not (file-remote-p (buffer-file-name)))
 876                                       (dir-locals-find-file
 877                                        (buffer-file-name))))
 878                           (type "file"))
 879                       (princ "  This variable is a directory local variable")
 880                       (when file
 881                         (if (consp file) ; result from cache
 882                             ;; If the cache element has an mtime, we
 883                             ;; assume it came from a file.
 884                             (if (nth 2 file)
 885                                 (setq file (expand-file-name
 886                                             dir-locals-file (car file)))
 887                               ;; Otherwise, assume it was set directly.
 888                               (setq type "directory")))
 889                         (princ (format "\n  from the %s \"%s\"" type file)))
 890                       (princ ".\n"))
 891                   (princ "  This variable is a file local variable.\n")))
 892
 893               (when (memq variable ignored-local-variables)
 894                 (setq extra-line t)
 895                 (princ "  This variable is ignored when used as a file local \
 896 variable.\n"))
 897
 898               ;; Can be both risky and safe, eg auto-fill-function.
 899               (when (risky-local-variable-p variable)
 900                 (setq extra-line t)
 901                 (princ "  This variable is potentially risky when used as a \
 902 file local variable.\n")
 903                 (when (assq variable safe-local-variable-values)
 904                   (princ "  However, you have added it to \
 905 `safe-local-variable-values'.\n")))
 906
 907               (when safe-var
 908                 (setq extra-line t)
 909                 (princ "  This variable is safe as a file local variable ")
 910                 (princ "if its value\n  satisfies the predicate ")
 911                 (princ (if (byte-code-function-p safe-var)
 912                            "which is byte-compiled expression.\n"
 913                          (format "`%s'.\n" safe-var))))
 914
 915               (if extra-line (terpri))
 916               (princ "Documentation:\n")
 917               (with-current-buffer standard-output
 918                 (insert (or doc "Not documented as a variable."))))
 919
 920             ;; Make a link to customize if this variable can be customized.
 921             (when (custom-variable-p variable)
 922               (let ((customize-label "customize"))
 923                 (terpri)
 924                 (terpri)
 925                 (princ (concat "You can " customize-label " this variable."))
 926                 (with-current-buffer standard-output
 927                   (save-excursion
 928                     (re-search-backward
 929                      (concat "\\(" customize-label "\\)") nil t)
 930                     (help-xref-button 1 'help-customize-variable variable))))
 931               ;; Note variable's version or package version
 932               (let ((output (describe-variable-custom-version-info variable)))
 933                 (when output
 934                   (terpri)
 935                   (terpri)
 936                   (princ output))))
 937
 938             (with-current-buffer standard-output
 939               ;; Return the text we displayed.
 940               (buffer-string))))))))
 941
 942
 943 ;;;###autoload
 944 (defun describe-syntax (&optional buffer)
 945   "Describe the syntax specifications in the syntax table of BUFFER.
 946 The descriptions are inserted in a help buffer, which is then displayed.
 947 BUFFER defaults to the current buffer."
 948   (interactive)
 949   (setq buffer (or buffer (current-buffer)))
 950   (help-setup-xref (list #'describe-syntax buffer)
 951                    (called-interactively-p 'interactive))
 952   (with-help-window (help-buffer)
 953     (let ((table (with-current-buffer buffer (syntax-table))))
 954       (with-current-buffer standard-output
 955         (describe-vector table 'internal-describe-syntax-value)
 956         (while (setq table (char-table-parent table))
 957           (insert "\nThe parent syntax table is:")
 958           (describe-vector table 'internal-describe-syntax-value))))))
 959
 960 (defun help-describe-category-set (value)
 961   (insert (cond
 962            ((null value) "default")
 963            ((char-table-p value) "deeper char-table ...")
 964            (t (condition-case nil
 965                   (category-set-mnemonics value)
 966                 (error "invalid"))))))
 967
 968 ;;;###autoload
 969 (defun describe-categories (&optional buffer)
 970   "Describe the category specifications in the current category table.
 971 The descriptions are inserted in a buffer, which is then displayed.
 972 If BUFFER is non-nil, then describe BUFFER's category table instead.
 973 BUFFER should be a buffer or a buffer name."
 974   (interactive)
 975   (setq buffer (or buffer (current-buffer)))
 976   (help-setup-xref (list #'describe-categories buffer)
 977                    (called-interactively-p 'interactive))
 978   (with-help-window (help-buffer)
 979     (let* ((table (with-current-buffer buffer (category-table)))
 980            (docs (char-table-extra-slot table 0)))
 981       (if (or (not (vectorp docs)) (/= (length docs) 95))
 982           (error "Invalid first extra slot in this category table\n"))
 983       (with-current-buffer standard-output
 984         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 985         (let ((pos (point)) (items 0) lines n)
 986           (dotimes (i 95)
 987             (if (aref docs i) (setq items (1+ items))))
 988           (setq lines (1+ (/ (1- items) 4)))
 989           (setq n 0)
 990           (dotimes (i 95)
 991             (let ((elt (aref docs i)))
 992               (when elt
 993                 (string-match ".*" elt)
 994                 (setq elt (match-string 0 elt))
 995                 (if (>= (length elt) 17)
 996                     (setq elt (concat (substring elt 0 14) "...")))
 997                 (if (< (point) (point-max))
 998                     (move-to-column (* 20 (/ n lines)) t))
 999                 (insert (+ i ?\s) ?: elt)
1000                 (if (< (point) (point-max))
1001                     (forward-line 1)
1002                   (insert "\n"))
1003                 (setq n (1+ n))
1004                 (if (= (% n lines) 0)
1005                     (goto-char pos))))))
1006         (goto-char (point-max))
1007         (insert "\n"
1008                 "character(s)\tcategory mnemonics\n"
1009                 "------------\t------------------")
1010         (describe-vector table 'help-describe-category-set)
1011         (insert "Legend of category mnemonics:\n")
1012         (dotimes (i 95)
1013           (let ((elt (aref docs i)))
1014             (when elt
1015               (if (string-match "\n" elt)
1016                   (setq elt (substring elt (match-end 0))))
1017               (insert (+ i ?\s) ": " elt "\n"))))
1018         (while (setq table (char-table-parent table))
1019           (insert "\nThe parent category table is:")
1020           (describe-vector table 'help-describe-category-set))))))
1021
1022 \f
1023 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
1024
1025 ;; Replaces lib-src/digest-doc.c.
1026 ;;;###autoload
1027 (defun doc-file-to-man (file)
1028   "Produce an nroff buffer containing the doc-strings from the DOC file."
1029   (interactive (list (read-file-name "Name of DOC file: " doc-directory
1030                                      internal-doc-file-name t)))
1031   (or (file-readable-p file)
1032       (error "Cannot read file `%s'" file))
1033   (pop-to-buffer (generate-new-buffer "*man-doc*"))
1034   (setq buffer-undo-list t)
1035   (insert ".TH \"Command Summary for GNU Emacs\"\n"
1036           ".AU Richard M. Stallman\n")
1037   (insert-file-contents file)
1038   (let (notfirst)
1039     (while (search-forward "\1f" nil 'move)
1040       (if (looking-at "S")
1041           (delete-region (1- (point)) (line-end-position))
1042         (delete-char -1)
1043         (if notfirst
1044             (insert "\n.DE\n")
1045           (setq notfirst t))
1046         (insert "\n.SH ")
1047         (insert (if (looking-at "F") "Function " "Variable "))
1048         (delete-char 1)
1049         (forward-line 1)
1050         (insert ".DS L\n"))))
1051   (insert "\n.DE\n")
1052   (setq buffer-undo-list nil)
1053   (nroff-mode))
1054
1055 ;; Replaces lib-src/sorted-doc.c.
1056 ;;;###autoload
1057 (defun doc-file-to-info (file)
1058   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
1059   (interactive (list (read-file-name "Name of DOC file: " doc-directory
1060                                      internal-doc-file-name t)))
1061   (or (file-readable-p file)
1062       (error "Cannot read file `%s'" file))
1063   (let ((i 0) type name doc alist)
1064     (with-temp-buffer
1065       (insert-file-contents file)
1066       ;; The characters "@{}" need special treatment.
1067       (while (re-search-forward "[@{}]" nil t)
1068         (backward-char)
1069         (insert "@")
1070         (forward-char 1))
1071       (goto-char (point-min))
1072       (while (search-forward "\1f" nil t)
1073         (unless (looking-at "S")
1074           (setq type (char-after)
1075                 name (buffer-substring (1+ (point)) (line-end-position))
1076                 doc (buffer-substring (line-beginning-position 2)
1077                                       (if (search-forward  "\1f" nil 'move)
1078                                           (1- (point))
1079                                         (point)))
1080                 alist (cons (list name type doc) alist))
1081           (backward-char 1))))
1082     (pop-to-buffer (generate-new-buffer "*info-doc*"))
1083     (setq buffer-undo-list t)
1084     ;; Write the output header.
1085     (insert "\\input texinfo  @c -*-texinfo-*-\n"
1086             "@setfilename emacsdoc.info\n"
1087             "@settitle Command Summary for GNU Emacs\n"
1088             "@finalout\n"
1089             "\n@node Top\n"
1090             "@unnumbered Command Summary for GNU Emacs\n\n"
1091             "@table @asis\n\n"
1092             "@iftex\n"
1093             "@global@let@ITEM@item\n"
1094             "@def@item{@filbreak@vskip5pt@ITEM}\n"
1095             "@font@tensy cmsy10 scaled @magstephalf\n"
1096             "@font@teni cmmi10 scaled @magstephalf\n"
1097             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
1098             "@def|{{@tensy@char106}}\n"
1099             "@def@{{{@tensy@char102}}\n"
1100             "@def@}{{@tensy@char103}}\n"
1101             "@def<{{@teni@char62}}\n"
1102             "@def>{{@teni@char60}}\n"
1103             "@chardef@@64\n"
1104             "@catcode43=12\n"
1105             "@tableindent-0.2in\n"
1106             "@end iftex\n")
1107     ;; Sort the array by name; within each name, by type (functions first).
1108     (setq alist (sort alist (lambda (e1 e2)
1109                               (if (string-equal (car e1) (car e2))
1110                                   (<= (cadr e1) (cadr e2))
1111                                 (string-lessp (car e1) (car e2))))))
1112     ;; Print each function.
1113     (dolist (e alist)
1114       (insert "\n@item "
1115               (if (char-equal (cadr e) ?\F) "Function" "Variable")
1116               " @code{" (car e) "}\n@display\n"
1117               (nth 2 e)
1118               "\n@end display\n")
1119       ;; Try to avoid a save size overflow in the TeX output routine.
1120       (if (zerop (setq i (% (1+ i) 100)))
1121           (insert "\n@end table\n@table @asis\n")))
1122     (insert "@end table\n"
1123             "@bye\n")
1124     (setq buffer-undo-list nil)
1125     (texinfo-mode)))
1126
1127 (provide 'help-fns)
1128
1129 ;;; help-fns.el ends here