configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 dnl _ON results in a '--without' option in the --help output, so
 148 dnl the help text should refer to "don't compile", etc.
 149 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 150 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 151 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 152 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 153 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 154 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 155 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 156 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH(gameuser,dnl
 204 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 205 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 206   && gameuser="${with_gameuser}"
 207 test "X$gameuser" = X && gameuser=games
 208
 209 AC_ARG_WITH([gnustep-conf],dnl
 210 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 211 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 212   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 213 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 214      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 215
 216 AC_ARG_ENABLE(ns-self-contained,
 217 [AS_HELP_STRING([--disable-ns-self-contained],
 218                 [disable self contained build under NeXTstep])],
 219    EN_NS_SELF_CONTAINED=$enableval,
 220    EN_NS_SELF_CONTAINED=yes)
 221
 222 AC_ARG_ENABLE(asserts,
 223 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 224       USE_XASSERTS=$enableval,
 225       USE_XASSERTS=no)
 226
 227 AC_ARG_ENABLE(maintainer-mode,
 228 [AS_HELP_STRING([--enable-maintainer-mode],
 229                 [enable make rules and dependencies not useful (and sometimes
 230                  confusing) to the casual installer])],
 231       USE_MAINTAINER_MODE=$enableval,
 232       USE_MAINTAINER_MODE=no)
 233 if test $USE_MAINTAINER_MODE = yes; then
 234   MAINT=
 235 else
 236   MAINT=#
 237 fi
 238 AC_SUBST(MAINT)
 239
 240 AC_ARG_ENABLE(locallisppath,
 241 [AS_HELP_STRING([--enable-locallisppath=PATH],
 242                 [directories Emacs should search for lisp files specific
 243                  to this site])],
 244 if test "${enableval}" = "no"; then
 245   locallisppath=
 246 elif test "${enableval}" != "yes"; then
 247   locallisppath=${enableval}
 248 fi)
 249
 250 AC_ARG_ENABLE(checking,
 251 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 252                 [enable expensive run-time checks.  With LIST,
 253                  enable only specific categories of checks.
 254                  Categories are: all,yes,no.
 255                  Flags are: stringbytes, stringoverrun, stringfreelist,
 256                  xmallocoverrun, conslist])],
 257 [ac_checking_flags="${enableval}"],[])
 258 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 259 for check in $ac_checking_flags
 260 do
 261         case $check in
 262         # these set all the flags to specific states
 263         yes)            ac_enable_checking=1 ;;
 264         no)             ac_enable_checking= ;
 265                         ac_gc_check_stringbytes= ;
 266                         ac_gc_check_string_overrun= ;
 267                         ac_gc_check_string_free_list= ;
 268                         ac_xmalloc_overrun= ;
 269                         ac_gc_check_cons_list= ;;
 270         all)            ac_enable_checking=1 ;
 271                         ac_gc_check_stringbytes=1 ;
 272                         ac_gc_check_string_overrun=1 ;
 273                         ac_gc_check_string_free_list=1 ;
 274                         ac_xmalloc_overrun=1 ;
 275                         ac_gc_check_cons_list=1 ;;
 276         # these enable particular checks
 277         stringbytes)    ac_gc_check_stringbytes=1 ;;
 278         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 279         stringfreelist) ac_gc_check_string_free_list=1 ;;
 280         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 281         conslist)       ac_gc_check_cons_list=1 ;;
 282         *)      AC_MSG_ERROR(unknown check category $check) ;;
 283         esac
 284 done
 285 IFS="$ac_save_IFS"
 286
 287 if test x$ac_enable_checking != x ; then
 288   AC_DEFINE(ENABLE_CHECKING, 1,
 289 [Enable expensive run-time checking of data types?])
 290 fi
 291 if test x$ac_gc_check_stringbytes != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 293 [Define this temporarily to hunt a bug.  If defined, the size of
 294    strings is redundantly recorded in sdata structures so that it can
 295    be compared to the sizes recorded in Lisp strings.])
 296 fi
 297 if test x$ac_gc_check_stringoverrun != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 299 [Define this to check for short string overrun.])
 300 fi
 301 if test x$ac_gc_check_string_free_list != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 303 [Define this to check the string free list.])
 304 fi
 305 if test x$ac_xmalloc_overrun != x ; then
 306   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 307 [Define this to check for malloc buffer overrun.])
 308 fi
 309 if test x$ac_gc_check_cons_list != x ; then
 310   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 311 [Define this to check for errors in cons list.])
 312 fi
 313
 314 AC_ARG_ENABLE(use-lisp-union-type,
 315 [AS_HELP_STRING([--enable-use-lisp-union-type],
 316                 [use a union for the Lisp_Object data type.
 317                 This is only useful for development for catching certain types of bugs.])],
 318 if test "${enableval}" != "no"; then
 319    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 320    [Define this to use a lisp union for the Lisp_Object data type.])
 321 fi)
 322
 323
 324 AC_ARG_ENABLE(profiling,
 325 [AS_HELP_STRING([--enable-profiling],
 326                 [build emacs with profiling support.
 327                  This might not work on all platforms])],
 328 [ac_enable_profiling="${enableval}"],[])
 329 if test x$ac_enable_profiling != x ; then
 330    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 331 else
 332    PROFILING_CFLAGS=
 333 fi
 334 AC_SUBST(PROFILING_CFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Check if the source directory already has a configured system in it.
 368 if test `pwd` != `(cd ${srcdir} && pwd)` \
 369    && test -f "${srcdir}/src/config.h" ; then
 370   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 371    as a build directory right now; it has been configured in its own
 372    right.  To configure in another directory as well, you MUST
 373    use GNU make.  If you do not have GNU make, then you must
 374    now do `make distclean' in ${srcdir},
 375    and then run $0 again.]])
 376 fi
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## GNU/Linux ports
 419   *-*-linux-gnu*)
 420     opsys=gnu-linux
 421     case ${canonical} in
 422       alpha*)   machine=alpha ;;
 423       s390-*)   machine=ibms390 ;;
 424       s390x-*)  machine=ibms390x ;;
 425       powerpc*) machine=macppc ;;
 426       sparc*)   machine=sparc ;;
 427       ia64*)    machine=ia64 ;;
 428       m68k*)    machine=m68k ;;
 429       x86_64*)  machine=amdx86-64 ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD ports
 434   *-*-freebsd* )
 435     opsys=freebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## FreeBSD kernel + glibc based userland
 448   *-*-kfreebsd*gnu* )
 449     opsys=gnu-kfreebsd
 450     case "${canonical}" in
 451       alpha*)           machine=alpha ;;
 452       amd64-*|x86_64-*) machine=amdx86-64 ;;
 453       ia64-*)           machine=ia64 ;;
 454       i[3456]86-*)      machine=intel386 ;;
 455       powerpc-*)        machine=macppc ;;
 456       sparc-*)          machine=sparc ;;
 457       sparc64-*)        machine=sparc ;;
 458     esac
 459   ;;
 460
 461   ## NetBSD ports
 462   *-*-netbsd* )
 463     opsys=netbsd
 464     case "${canonical}" in
 465       alpha*)      machine=alpha ;;
 466       x86_64-*)    machine=amdx86-64 ;;
 467       i[3456]86-*) machine=intel386 ;;
 468       m68k-*)      machine=m68k ;;
 469       powerpc-*)   machine=macppc ;;
 470       sparc*-)     machine=sparc ;;
 471       vax-*)       machine=vax ;;
 472     esac
 473   ;;
 474
 475   ## OpenBSD ports
 476   *-*-openbsd* )
 477     opsys=openbsd
 478     case "${canonical}" in
 479       alpha*)    machine=alpha ;;
 480       x86_64-*)  machine=amdx86-64 ;;
 481       i386-*)    machine=intel386 ;;
 482       powerpc-*) machine=macppc ;;
 483       sparc*)    machine=sparc ;;
 484       vax-*)     machine=vax ;;
 485     esac
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   ia64*-hp-hpux1[1-9]* )
 517     machine=hp800 opsys=hpux11
 518     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 519     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 520     CANNOT_DUMP=yes
 521   ;;
 522
 523   hppa*-*-linux-gnu* )
 524     machine=hp800 opsys=gnu-linux
 525   ;;
 526
 527   ## IBM machines
 528   rs6000-ibm-aix4.[23]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix4.[23]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   rs6000-ibm-aix[56]* )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537   powerpc-ibm-aix[56]*  )
 538     machine=ibmrs6000 opsys=aix4-2
 539   ;;
 540
 541   ## Silicon Graphics machines
 542   ## Iris 4D
 543   mips-sgi-irix6.5 )
 544     machine=iris4d opsys=irix6-5
 545     # Without defining _LANGUAGE_C, things get masked out in the headers
 546     # so that, for instance, grepping for `free' in stdlib.h fails and
 547     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 548     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 549     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 550   ;;
 551
 552   ## Suns
 553   *-sun-solaris* \
 554     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 555     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 556     case "${canonical}" in
 557       i[3456]86-*-* )     machine=intel386 ;;
 558       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 559       sparc* )          machine=sparc ;;
 560       * )               unported=yes ;;
 561     esac
 562     case "${canonical}" in
 563       *-sunos5.6* | *-solaris2.6* )
 564                 opsys=sol2-6
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 RANLIB="ar -ts"
 567                 ;;
 568       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 569                 opsys=sol2-6
 570                 emacs_check_sunpro_c=yes
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 ;;
 573       *-sunos5* | *-solaris* )
 574                 opsys=sol2-10
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578     esac
 579     ## Watch out for a compiler that we know will not work.
 580     case "${canonical}" in
 581      *-solaris* | *-sunos5* )
 582                 if [ "x$CC" = x/usr/ucb/cc ]; then
 583                   ## /usr/ucb/cc doesn't work;
 584                   ## we should find some other compiler that does work.
 585                   unset CC
 586                 fi
 587                 ;;
 588       *) ;;
 589     esac
 590   ;;
 591
 592   ## Intel 386 machines where we don't care about the manufacturer.
 593   i[3456]86-*-* )
 594     machine=intel386
 595     case "${canonical}" in
 596       *-cygwin )                opsys=cygwin ;;
 597       *-darwin* )               opsys=darwin
 598                                 CPP="${CC-cc} -E -no-cpp-precomp"
 599                                 ;;
 600       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 604     esac
 605   ;;
 606
 607   * )
 608     unported=yes
 609   ;;
 610 esac
 611
 612 ### If the code above didn't choose an operating system, just choose
 613 ### an operating system based on the configuration name.  You really
 614 ### only want to use this when you have no idea what the right
 615 ### operating system is; if you know what operating systems a machine
 616 ### runs, it's cleaner to make it explicit in the case statement
 617 ### above.
 618 if test x"${opsys}" = x; then
 619   case "${canonical}" in
 620     *-gnu* )                            opsys=gnu ;;
 621     * )
 622       unported=yes
 623     ;;
 624   esac
 625 fi
 626
 627 ]
 628 dnl quotation ends
 629
 630 if test $unported = yes; then
 631   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 632 Check `etc/MACHINES' for recognized configuration names.])
 633 fi
 634
 635 if test -n "$machine"; then
 636   machfile="m/${machine}.h"
 637 else
 638   machfile=
 639 fi
 640 opsysfile="s/${opsys}.h"
 641
 642
 643 #### Choose a compiler.
 644 test -n "$CC" && cc_specified=yes
 645
 646 # Save the value of CFLAGS that the user specified.
 647 SPECIFIED_CFLAGS="$CFLAGS"
 648
 649 dnl Sets GCC=yes if using gcc.
 650 AC_PROG_CC
 651 AM_PROG_CC_C_O
 652
 653 # Initialize gnulib right after verifying that the C compiler works.
 654 gl_EARLY
 655
 656 # On Suns, sometimes $CPP names a directory.
 657 if test -n "$CPP" && test -d "$CPP"; then
 658   CPP=
 659 fi
 660
 661 ## If not using gcc, and on Solaris, and no CPP specified, see if
 662 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 663 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 664  test x"$CPP" = x; then
 665   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 666   AC_CACHE_VAL(emacs_cv_sunpro_c,
 667   [AC_TRY_LINK([],
 668 [#ifndef __SUNPRO_C
 669 fail;
 670 #endif
 671 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 672   AC_MSG_RESULT($emacs_cv_sunpro_c)
 673
 674   if test x"$emacs_cv_sunpro_c" = xyes; then
 675     NON_GNU_CPP="$CC -E -Xs"
 676   fi
 677 fi
 678
 679 #### Some systems specify a CPP to use unless we are using GCC.
 680 #### Now that we know whether we are using GCC, we can decide whether
 681 #### to use that one.
 682 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 683 then
 684   CPP="$NON_GNU_CPP"
 685 fi
 686
 687 #### Some systems specify a CC to use unless we are using GCC.
 688 #### Now that we know whether we are using GCC, we can decide whether
 689 #### to use that one.
 690 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 691   test x$cc_specified != xyes
 692 then
 693   CC="$NON_GNU_CC"
 694 fi
 695
 696 if test x$GCC = xyes; then
 697   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 698 else
 699   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 700 fi
 701
 702 ### Use -Wno-pointer-sign if the compiler supports it
 703 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 704 SAVE_CFLAGS="$CFLAGS"
 705 CFLAGS="$CFLAGS -Wno-pointer-sign"
 706 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 707 if test $has_option = yes; then
 708    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 709 fi
 710 AC_MSG_RESULT($has_option)
 711 CFLAGS="$SAVE_CFLAGS"
 712 unset has_option
 713 unset SAVE_CFLAGS
 714
 715 ### Use -Wdeclaration-after-statement if the compiler supports it
 716 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 717 SAVE_CFLAGS="$CFLAGS"
 718 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 719 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 720 if test $has_option = yes; then
 721    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 722 fi
 723 AC_MSG_RESULT($has_option)
 724 CFLAGS="$SAVE_CFLAGS"
 725 unset has_option
 726 unset SAVE_CFLAGS
 727
 728 ### Use -Wold-style-definition if the compiler supports it
 729 # This can be removed when conversion to standard C is finished.
 730 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wold-style-definition"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 ### Use -Wimplicit-function-declaration if the compiler supports it
 743 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 744 SAVE_CFLAGS="$CFLAGS"
 745 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 746 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 747 if test $has_option = yes; then
 748    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 749 fi
 750 AC_MSG_RESULT($has_option)
 751 CFLAGS="$SAVE_CFLAGS"
 752 unset has_option
 753 unset SAVE_CFLAGS
 754
 755 AC_SUBST(C_WARNINGS_SWITCH)
 756
 757
 758 #### Some other nice autoconf tests.
 759
 760 dnl checks for programs
 761 AC_PROG_CPP
 762 AC_PROG_INSTALL
 763 if test "x$RANLIB" = x; then
 764   AC_PROG_RANLIB
 765 fi
 766
 767 ## Although we're running on an amd64 kernel, we're actually compiling for
 768 ## the x86 architecture.  The user should probably have provided an
 769 ## explicit --build to `configure', but if everything else than the kernel
 770 ## is running in i386 mode, we can help them out.
 771 if test "$machine" = "amdx86-64"; then
 772   AC_CHECK_DECL([i386])
 773   if test "$ac_cv_have_decl_i386" = "yes"; then
 774     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 775     machine=intel386
 776     machfile="m/${machine}.h"
 777   fi
 778 fi
 779
 780 AC_PATH_PROG(INSTALL_INFO, install-info)
 781 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 782 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 783 dnl Don't use GZIP, which is used by gzip for additional parameters.
 784 AC_PATH_PROG(GZIP_PROG, gzip)
 785
 786
 787 ## Need makeinfo >= 4.6 (?) to build the manuals.
 788 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 789 dnl By this stage, configure has already checked for egrep and set EGREP,
 790 dnl or exited with an error if no egrep was found.
 791 if test "$MAKEINFO" != "no" && \
 792   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 793    MAKEINFO=no
 794 fi
 795
 796 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 797 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 798 ## therefore in the category of "special tools" not normally required, which
 799 ## configure does not have to check for (eg autoconf itself).
 800 ## In a Bazaar checkout on the other hand, the manuals are not included.
 801 ## So makeinfo is a requirement to build from Bazaar, and configure
 802 ## should test for it as it does for any other build requirement.
 803 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 804 ## with pre-built manuals, from a Bazaar checkout.
 805 HAVE_MAKEINFO=yes
 806
 807 if test "$MAKEINFO" = "no"; then
 808   MAKEINFO=makeinfo
 809   if test "x${with_makeinfo}" = "xno"; then
 810     HAVE_MAKEINFO=no
 811   elif test ! -e $srcdir/info/emacs; then
 812     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 813 source tree does not seem to have pre-built manuals in the `info' directory.
 814 Either install a suitable version of makeinfo, or re-run configure
 815 with the `--without-makeinfo' option to build without the manuals.] )
 816   fi
 817 fi
 818 AC_SUBST(HAVE_MAKEINFO)
 819
 820 dnl Add our options to ac_link now, after it is set up.
 821
 822 if test x$GCC = xyes; then
 823   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 824     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 825 else
 826   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 827     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 828 fi
 829
 830 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 831 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 832 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 833 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 834 dnl if not built to support GNU ld.
 835
 836 late_LDFLAGS=$LDFLAGS
 837 if test x$GCC = xyes; then
 838   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 839 else
 840   LDFLAGS="$LDFLAGS -znocombreloc"
 841 fi
 842
 843 AC_MSG_CHECKING([for -znocombreloc])
 844 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 845   [AC_MSG_RESULT(yes)],
 846   LDFLAGS=$late_LDFLAGS
 847   [AC_MSG_RESULT(no)])
 848
 849
 850 # The value of CPP is a quoted variable reference, so we need to do this
 851 # to get its actual value...
 852 CPP=`eval "echo $CPP"`
 853
 854
 855 dnl The function dump-emacs will not be defined and temacs will do
 856 dnl (load "loadup") automatically unless told otherwise.
 857 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 858 case "$opsys" in
 859   your-opsys-here) CANNOT_DUMP=yes ;;
 860 esac
 861
 862 test "$CANNOT_DUMP" = "yes" && \
 863   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 864
 865 AC_SUBST(CANNOT_DUMP)
 866
 867
 868 UNEXEC_OBJ=unexelf.o
 869 case "$opsys" in
 870   # MSDOS uses unexcoff.o
 871   # MSWindows uses unexw32.o
 872   aix4-2)
 873    UNEXEC_OBJ=unexaix.o
 874    ;;
 875   cygwin)
 876    UNEXEC_OBJ=unexcw.o
 877    ;;
 878   darwin)
 879    UNEXEC_OBJ=unexmacosx.o
 880    ;;
 881   hpux10-20 | hpux11)
 882    UNEXEC_OBJ=unexhp9k800.o
 883    ;;
 884   sol2-10)
 885    # Use the Solaris dldump() function, called from unexsol.c, to dump
 886    # emacs, instead of the generic ELF dump code found in unexelf.c.
 887    # The resulting binary has a complete symbol table, and is better
 888    # for debugging and other observability tools (debuggers, pstack, etc).
 889    #
 890    # If you encounter a problem using dldump(), please consider sending
 891    # a message to the OpenSolaris tools-linking mailing list:
 892    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 893    #
 894    # It is likely that dldump() works with older Solaris too, but this has
 895    # not been tested, so for now this change is for Solaris 10 or newer.
 896    UNEXEC_OBJ=unexsol.o
 897    ;;
 898 esac
 899
 900 LD_SWITCH_SYSTEM=
 901 case "$opsys" in
 902   freebsd)
 903    ## Let `ld' find image libs and similar things in /usr/local/lib.
 904    ## The system compiler, GCC, has apparently been modified to not
 905    ## look there, contrary to what a stock GCC would do.
 906    LD_SWITCH_SYSTEM=-L/usr/local/lib
 907    ;;
 908
 909   gnu-linux)
 910    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 911    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 912    ;;
 913
 914   netbsd)
 915    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 916    ;;
 917
 918   openbsd)
 919    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 920    ## otherwise Emacs dumps core on elf systems.
 921    LD_SWITCH_SYSTEM="-Z"
 922    ;;
 923 esac
 924 AC_SUBST(LD_SWITCH_SYSTEM)
 925
 926 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 927
 928 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 929 ## which has not been defined yet.  When this was handled with cpp,
 930 ## it was expanded to null when configure sourced the s/*.h file.
 931 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 932 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 933 ## (or somesuch), but because it is supposed to go at the _front_
 934 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 935 ## Compare with the gnu-linux case below, which added to the end
 936 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 937 ## LD_SWITCH_SYSTEM_TEMACS.
 938 case "$opsys" in
 939   netbsd|openbsd)
 940    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 941    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 942 esac
 943
 944
 945 C_SWITCH_MACHINE=
 946 if test "$machine" = "alpha"; then
 947   AC_CHECK_DECL([__ELF__])
 948   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 949     ## With ELF, make sure that all common symbols get allocated to in the
 950     ## data section.  Otherwise, the dump of temacs may miss variables in
 951     ## the shared library that have been initialized.  For example, with
 952     ## GNU libc, __malloc_initialized would normally be resolved to the
 953     ## shared library's .bss section, which is fatal.
 954     if test "x$GCC" = "xyes"; then
 955       C_SWITCH_MACHINE="-fno-common"
 956     else
 957       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 958     fi
 959   else
 960     UNEXEC_OBJ=unexalpha.o
 961   fi
 962 fi
 963 AC_SUBST(C_SWITCH_MACHINE)
 964
 965 AC_SUBST(UNEXEC_OBJ)
 966
 967 C_SWITCH_SYSTEM=
 968 ## Some programs in src produce warnings saying certain subprograms
 969 ## are too complex and need a MAXMEM value greater than 2000 for
 970 ## additional optimization.  --nils@exp-math.uni-essen.de
 971 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 972   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 973 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 974 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 975 AC_SUBST(C_SWITCH_SYSTEM)
 976
 977
 978 LIBS_SYSTEM=
 979 case "$opsys" in
 980   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 981   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 982
 983   freebsd) LIBS_SYSTEM="-lutil" ;;
 984
 985   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 986
 987   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 988
 989   ## Motif needs -lgen.
 990   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 991 esac
 992 AC_SUBST(LIBS_SYSTEM)
 993
 994
 995 ### Make sure subsequent tests use flags consistent with the build flags.
 996
 997 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 998   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 999 else
1000   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1001 fi
1002
1003 dnl For AC_FUNC_GETLOADAVG, at least:
1004 AC_CONFIG_LIBOBJ_DIR(src)
1005
1006 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1007 AC_SYS_LARGEFILE
1008
1009
1010 ## If user specified a crt-dir, use that unconditionally.
1011 if test "X$CRT_DIR" = "X"; then
1012
1013   case "$canonical" in
1014     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1015     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1016     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1017     ## For anything else (eg /usr/lib32), it is up the user to specify
1018     ## the location (bug#5655).
1019     ## Test for crtn.o, not just the directory, because sometimes the
1020     ## directory exists but does not have the relevant files (bug#1287).
1021     ## FIXME better to test for binary compatibility somehow.
1022     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1023     ;;
1024
1025     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1026   esac
1027
1028   case "$opsys" in
1029     hpux10-20) CRT_DIR=/lib ;;
1030   esac
1031
1032   ## Default is /usr/lib.
1033   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1034
1035 else
1036
1037   ## Some platforms don't use any of these files, so it is not
1038   ## appropriate to put this test outside the if block.
1039   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1040     AC_MSG_ERROR([crt*.o not found in specified location.])
1041
1042 fi
1043
1044 AC_SUBST(CRT_DIR)
1045
1046 LIB_MATH=-lm
1047 LIB_STANDARD=
1048 START_FILES=
1049
1050 case $opsys in
1051   cygwin )
1052     LIB_MATH=
1053     START_FILES='pre-crt0.o'
1054     ;;
1055   darwin )
1056     ## Adding -lm confuses the dynamic linker, so omit it.
1057     LIB_MATH=
1058     START_FILES='pre-crt0.o'
1059     ;;
1060   freebsd )
1061     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1062     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1063     ;;
1064   gnu-linux | gnu-kfreebsd )
1065     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1066     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1067     ;;
1068   hpux10-20 | hpux11 )
1069     LIB_STANDARD=-lc
1070     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1071     ;;
1072   netbsd | openbsd )
1073     if test -f $CRT_DIR/crti.o; then
1074         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1075         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1076     else
1077         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1078         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1079     fi
1080     ;;
1081 esac
1082
1083 AC_SUBST(LIB_MATH)
1084 AC_SUBST(START_FILES)
1085
1086 dnl This function definition taken from Gnome 2.0
1087 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1088 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1089 dnl also defines GSTUFF_PKG_ERRORS on error
1090 AC_DEFUN([PKG_CHECK_MODULES], [
1091   succeeded=no
1092
1093   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1094
1095   if test "$PKG_CONFIG" = "no" ; then
1096      ifelse([$4], , [AC_MSG_ERROR([
1097       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1098   else
1099      PKG_CONFIG_MIN_VERSION=0.9.0
1100      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1101         AC_MSG_CHECKING(for $2)
1102
1103         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1104             AC_MSG_RESULT(yes)
1105             succeeded=yes
1106
1107             AC_MSG_CHECKING($1_CFLAGS)
1108             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1109             AC_MSG_RESULT($$1_CFLAGS)
1110
1111             AC_MSG_CHECKING($1_LIBS)
1112             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1113             AC_MSG_RESULT($$1_LIBS)
1114         else
1115             AC_MSG_RESULT(no)
1116             $1_CFLAGS=""
1117             $1_LIBS=""
1118             ## If we have a custom action on failure, don't print errors, but
1119             ## do set a variable so people can do so.
1120             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1121             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1122         fi
1123
1124         AC_SUBST($1_CFLAGS)
1125         AC_SUBST($1_LIBS)
1126      else
1127         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1128         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1129      fi
1130   fi
1131
1132   if test $succeeded = yes; then
1133      ifelse([$3], , :, [$3])
1134   else
1135      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1136   fi
1137 ])
1138
1139
1140 if test "${with_sound}" != "no"; then
1141   # Sound support for GNU/Linux and the free BSDs.
1142   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1143     have_sound_header=yes)
1144   # Emulation library used on NetBSD.
1145   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1146   AC_SUBST(LIBSOUND)
1147
1148   ALSA_REQUIRED=1.0.0
1149   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1150   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1151   if test $HAVE_ALSA = yes; then
1152     SAVE_CFLAGS="$CFLAGS"
1153     SAVE_LDFLAGS="$LDFLAGS"
1154     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1155     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1156     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1157                     emacs_alsa_normal=yes,
1158                     emacs_alsa_normal=no)
1159     if test "$emacs_alsa_normal" != yes; then
1160       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1161                      [snd_lib_error_set_handler (0);],
1162                      emacs_alsa_subdir=yes,
1163                      emacs_alsa_subdir=no)
1164       if test "$emacs_alsa_subdir" != yes; then
1165         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1166       fi
1167       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1168     fi
1169
1170     CFLAGS="$SAVE_CFLAGS"
1171     LDFLAGS="$SAVE_LDFLAGS"
1172     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1173     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1174     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1175   fi
1176
1177   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1178   dnl compiles only on the specified platforms.  For others, it
1179   dnl probably doesn't make sense to try.
1180   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1181      case "$opsys" in
1182        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1183        gnu-linux|freebsd|netbsd)
1184          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1185          ;;
1186      esac
1187   fi
1188
1189   AC_SUBST(CFLAGS_SOUND)
1190 fi
1191
1192 dnl checks for header files
1193 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1194   linux/version.h sys/systeminfo.h limits.h \
1195   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1196   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1197   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1198
1199 AC_MSG_CHECKING(if personality LINUX32 can be set)
1200 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1201                emacs_cv_personality_linux32=yes,
1202                emacs_cv_personality_linux32=no)
1203 AC_MSG_RESULT($emacs_cv_personality_linux32)
1204
1205 if test $emacs_cv_personality_linux32 = yes; then
1206   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1207             [Define to 1 if personality LINUX32 can be set.])
1208 fi
1209
1210 dnl On Solaris 8 there's a compilation warning for term.h because
1211 dnl it doesn't define `bool'.
1212 AC_CHECK_HEADERS(term.h, , , -)
1213 AC_HEADER_STDC
1214 AC_HEADER_TIME
1215 AC_CHECK_DECLS([sys_siglist])
1216 if test $ac_cv_have_decl_sys_siglist != yes; then
1217   # For Tru64, at least:
1218   AC_CHECK_DECLS([__sys_siglist])
1219   if test $ac_cv_have_decl___sys_siglist = yes; then
1220     AC_DEFINE(sys_siglist, __sys_siglist,
1221               [Define to any substitute for sys_siglist.])
1222   fi
1223 fi
1224 AC_HEADER_SYS_WAIT
1225
1226 dnl Some systems have utime.h but don't declare the struct anyplace.
1227 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1228 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1229 #include <sys/time.h>
1230 #include <time.h>
1231 #else
1232 #ifdef HAVE_SYS_TIME_H
1233 #include <sys/time.h>
1234 #else
1235 #include <time.h>
1236 #endif
1237 #endif
1238 #ifdef HAVE_UTIME_H
1239 #include <utime.h>
1240 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1241   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1242 if test $emacs_cv_struct_utimbuf = yes; then
1243   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1244 fi
1245
1246 dnl checks for typedefs
1247 AC_TYPE_SIGNAL
1248
1249 dnl Check for speed_t typedef.
1250 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1251   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1252     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1253 if test $emacs_cv_speed_t = yes; then
1254   AC_DEFINE(HAVE_SPEED_T, 1,
1255            [Define to 1 if `speed_t' is declared by <termios.h>.])
1256 fi
1257
1258 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1259 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1260 #include <sys/time.h>
1261 #include <time.h>
1262 #else
1263 #ifdef HAVE_SYS_TIME_H
1264 #include <sys/time.h>
1265 #else
1266 #include <time.h>
1267 #endif
1268 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1269   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1270 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1271 if test $emacs_cv_struct_timeval = yes; then
1272   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1273 fi
1274
1275 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1276 AC_TRY_COMPILE([#include <math.h>],
1277 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1278   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1279 HAVE_EXCEPTION=$emacs_cv_struct_exception
1280 if test $emacs_cv_struct_exception != yes; then
1281   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1282 fi
1283
1284 AC_CHECK_HEADERS(sys/socket.h)
1285 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1286 #if HAVE_SYS_SOCKET_H
1287 #include <sys/socket.h>
1288 #endif])
1289
1290 dnl checks for structure members
1291 AC_STRUCT_TM
1292 AC_STRUCT_TIMEZONE
1293 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1294                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1295                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1296                 [#include <time.h>])
1297 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1298                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1299                   struct ifreq.ifr_addr], , ,
1300                  [AC_INCLUDES_DEFAULT
1301 #if HAVE_SYS_SOCKET_H
1302 #include <sys/socket.h>
1303 #endif
1304 #if HAVE_NET_IF_H
1305 #include <net/if.h>
1306 #endif])
1307
1308 dnl checks for compiler characteristics
1309
1310 dnl Testing __STDC__ to determine prototype support isn't good enough.
1311 dnl DEC C, for instance, doesn't define it with default options, and
1312 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1313 dnl and void *.
1314 AC_C_PROTOTYPES
1315 AC_C_VOLATILE
1316 AC_C_CONST
1317 dnl This isn't useful because we can't turn on use of `inline' unless
1318 dnl the compiler groks `extern inline'.
1319 dnl AC_C_INLINE
1320 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1321   [AC_TRY_COMPILE(, [void * foo;],
1322                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1323 if test $emacs_cv_void_star = yes; then
1324   AC_DEFINE(POINTER_TYPE, void)
1325 else
1326   AC_DEFINE(POINTER_TYPE, char)
1327 fi
1328 AH_TEMPLATE(POINTER_TYPE,
1329             [Define as `void' if your compiler accepts `void *'; otherwise
1330              define as `char'.])dnl
1331
1332 dnl Check for endianess
1333 AC_C_BIGENDIAN
1334
1335 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1336   [emacs_cv_attribute_aligned],
1337   [AC_COMPILE_IFELSE(
1338      [AC_LANG_PROGRAM(
1339         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1340         [[]])],
1341      [emacs_cv_attribute_aligned=yes],
1342      [emacs_cv_attribute_aligned=no])])
1343 if test $emacs_cv_attribute_aligned = yes; then
1344   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1345     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1346 fi
1347
1348 dnl check for Make feature
1349 AC_PROG_MAKE_SET
1350
1351 DEPFLAGS=
1352 MKDEPDIR=":"
1353 deps_frag=deps.mk
1354 dnl check for GNU Make if we have GCC and autodepend is on.
1355 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1356    AC_MSG_CHECKING([whether we are using GNU Make])
1357    HAVE_GNU_MAKE=no
1358    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1359    if test "x$testval" != x; then
1360       HAVE_GNU_MAKE=yes
1361    else
1362       ac_enable_autodepend=no
1363    fi
1364    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1365    if test $HAVE_GNU_MAKE = yes; then
1366       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1367       SAVE_CFLAGS="$CFLAGS"
1368       CFLAGS="$CFLAGS -MMD -MF deps.d"
1369       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1370       CFLAGS="$SAVE_CFLAGS"
1371       test -f deps.d || ac_enable_autodepend=no
1372       rm -rf deps.d
1373       AC_MSG_RESULT([$ac_enable_autodepend])
1374    fi
1375    if test $ac_enable_autodepend = yes; then
1376       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1377       ## In parallel builds, another make might create depdir between
1378       ## the first test and mkdir, so stick another test on the end.
1379       ## Or use mkinstalldirs?  mkdir -p is not portable.
1380       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1381       deps_frag=autodeps.mk
1382    fi
1383 fi
1384 deps_frag=$srcdir/src/$deps_frag
1385 AC_SUBST(MKDEPDIR)
1386 AC_SUBST(DEPFLAGS)
1387 AC_SUBST_FILE(deps_frag)
1388
1389
1390 dnl checks for operating system services
1391 AC_SYS_LONG_FILE_NAMES
1392
1393 #### Choose a window system.
1394
1395 AC_PATH_X
1396 if test "$no_x" = yes; then
1397   window_system=none
1398 else
1399   window_system=x11
1400 fi
1401
1402 ## Workaround for bug in autoconf <= 2.62.
1403 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1404 ## No need to do anything special for these standard directories.
1405 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1406
1407    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1408
1409 fi
1410
1411 LD_SWITCH_X_SITE_AUX=
1412 LD_SWITCH_X_SITE_AUX_RPATH=
1413 if test "${x_libraries}" != NONE; then
1414   if test -n "${x_libraries}"; then
1415     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1416     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1417     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1418   fi
1419   x_default_search_path=""
1420   x_search_path=${x_libraries}
1421   if test -z "${x_search_path}"; then
1422     x_search_path=/usr/lib
1423   fi
1424   for x_library in `echo ${x_search_path}: | \
1425                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1426     x_search_path="\
1427 ${x_library}/X11/%L/%T/%N%C%S:\
1428 ${x_library}/X11/%l/%T/%N%C%S:\
1429 ${x_library}/X11/%T/%N%C%S:\
1430 ${x_library}/X11/%L/%T/%N%S:\
1431 ${x_library}/X11/%l/%T/%N%S:\
1432 ${x_library}/X11/%T/%N%S"
1433     if test x"${x_default_search_path}" = x; then
1434       x_default_search_path=${x_search_path}
1435     else
1436       x_default_search_path="${x_search_path}:${x_default_search_path}"
1437     fi
1438   done
1439 fi
1440 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1441 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1442
1443 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1444   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1445 fi
1446
1447 if test x"${x_includes}" = x; then
1448   bitmapdir=/usr/include/X11/bitmaps
1449 else
1450   # accumulate include directories that have X11 bitmap subdirectories
1451   bmd_acc="dummyval"
1452   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1453     if test -d "${bmd}/X11/bitmaps"; then
1454       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1455     fi
1456     if test -d "${bmd}/bitmaps"; then
1457       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1458     fi
1459   done
1460   if test ${bmd_acc} != "dummyval"; then
1461     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1462   fi
1463 fi
1464
1465 HAVE_NS=no
1466 NS_IMPL_COCOA=no
1467 NS_IMPL_GNUSTEP=no
1468 tmp_CPPFLAGS="$CPPFLAGS"
1469 tmp_CFLAGS="$CFLAGS"
1470 CPPFLAGS="$CPPFLAGS -x objective-c"
1471 CFLAGS="$CFLAGS -x objective-c"
1472 TEMACS_LDFLAGS2="\${LDFLAGS}"
1473 dnl I don't think it's especially important, but src/Makefile.in
1474 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1475 dnl trailing "/" to it, so now we do it here.
1476 if test "${with_ns}" != no; then
1477   if test "${opsys}" = darwin; then
1478      NS_IMPL_COCOA=yes
1479      ns_appdir=`pwd`/nextstep/Emacs.app
1480      ns_appbindir=${ns_appdir}/Contents/MacOS/
1481      ns_appresdir=${ns_appdir}/Contents/Resources
1482      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1483   elif test -f $GNUSTEP_CONFIG_FILE; then
1484      NS_IMPL_GNUSTEP=yes
1485      ns_appdir=`pwd`/nextstep/Emacs.app
1486      ns_appbindir=${ns_appdir}/
1487      ns_appresdir=${ns_appdir}/Resources
1488      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1489      dnl FIXME sourcing this several times in subshells seems inefficient.
1490      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1491      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1492      dnl I seemed to need these as well with GNUstep-startup 0.25.
1493      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1494      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1495      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1496        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1497      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1498        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1499      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1500      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1501      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1502      LIB_STANDARD=
1503      START_FILES=
1504      TEMACS_LDFLAGS2=
1505   fi
1506   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1507                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1508   files are missing or cannot be compiled.])])
1509   NS_HAVE_NSINTEGER=yes
1510   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1511                                      [NSInteger i;])],
1512                     ns_have_nsinteger=yes,
1513                     ns_have_nsinteger=no)
1514   if test $ns_have_nsinteger = no; then
1515     NS_HAVE_NSINTEGER=no
1516   fi
1517 fi
1518 AC_SUBST(TEMACS_LDFLAGS2)
1519
1520 ns_frag=/dev/null
1521 NS_OBJ=
1522 NS_OBJC_OBJ=
1523 NS_SUPPORT=
1524 if test "${HAVE_NS}" = yes; then
1525   window_system=nextstep
1526   with_xft=no
1527   # set up packaging dirs
1528   exec_prefix=${ns_appbindir}
1529   libexecdir=${ns_appbindir}/libexec
1530   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1531      prefix=${ns_appresdir}
1532   fi
1533   ns_frag=$srcdir/src/ns.mk
1534   NS_OBJ="fontset.o fringe.o image.o"
1535   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1536   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1537 fi
1538 CFLAGS="$tmp_CFLAGS"
1539 CPPFLAGS="$tmp_CPPFLAGS"
1540 AC_SUBST(NS_OBJ)
1541 AC_SUBST(NS_OBJC_OBJ)
1542 AC_SUBST(NS_SUPPORT)
1543 AC_SUBST(LIB_STANDARD)
1544 AC_SUBST_FILE(ns_frag)
1545
1546 case "${window_system}" in
1547   x11 )
1548     HAVE_X_WINDOWS=yes
1549     HAVE_X11=yes
1550     case "${with_x_toolkit}" in
1551       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1552       motif ) USE_X_TOOLKIT=MOTIF ;;
1553       gtk ) with_gtk=yes
1554 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1555 dnl USE_X_TOOLKIT is set.
1556             USE_X_TOOLKIT=none ;;
1557       gtk3 ) with_gtk3=yes
1558              USE_X_TOOLKIT=none ;;
1559       no ) USE_X_TOOLKIT=none ;;
1560 dnl If user did not say whether to use a toolkit, make this decision later:
1561 dnl use the toolkit if we have gtk, or X11R5 or newer.
1562       * ) USE_X_TOOLKIT=maybe ;;
1563     esac
1564   ;;
1565   nextstep | none )
1566     HAVE_X_WINDOWS=no
1567     HAVE_X11=no
1568     USE_X_TOOLKIT=none
1569   ;;
1570 esac
1571
1572 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1573    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1574    if test "$HAVE_XSERVER" = true ||
1575       test -n "$DISPLAY" ||
1576       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1577         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1578 were found.  You should install the relevant development files for X
1579 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1580 sure you have development files for image handling, i.e.
1581 tiff, gif, jpeg, png and xpm.
1582 If you are sure you want Emacs compiled without X window support, pass
1583   --without-x
1584 to configure.])
1585    fi
1586 fi
1587
1588 ### If we're using X11, we should use the X menu package.
1589 HAVE_MENUS=no
1590 case ${HAVE_X11} in
1591   yes ) HAVE_MENUS=yes ;;
1592 esac
1593
1594 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1595 # Assume not, until told otherwise.
1596 GNU_MALLOC=yes
1597 doug_lea_malloc=yes
1598 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1599 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1600 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1601                emacs_cv_var___after_morecore_hook,
1602 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1603   emacs_cv_var___after_morecore_hook=yes,
1604   emacs_cv_var___after_morecore_hook=no)])
1605 if test $emacs_cv_var___after_morecore_hook = no; then
1606   doug_lea_malloc=no
1607 fi
1608
1609
1610 dnl See comments in aix4-2.h about maybe using system malloc there.
1611 system_malloc=no
1612 case "$opsys" in
1613   ## darwin ld insists on the use of malloc routines in the System framework.
1614   darwin|sol2-10) system_malloc=yes ;;
1615 esac
1616
1617 if test "${system_malloc}" = "yes"; then
1618   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1619   GNU_MALLOC=no
1620   GNU_MALLOC_reason="
1621     (The GNU allocators don't work with this system configuration.)"
1622   GMALLOC_OBJ=
1623   VMLIMIT_OBJ=
1624 else
1625   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1626   VMLIMIT_OBJ=vm-limit.o
1627 fi
1628 AC_SUBST(GMALLOC_OBJ)
1629 AC_SUBST(VMLIMIT_OBJ)
1630
1631 if test "$doug_lea_malloc" = "yes" ; then
1632   if test "$GNU_MALLOC" = yes ; then
1633     GNU_MALLOC_reason="
1634       (Using Doug Lea's new malloc from the GNU C Library.)"
1635   fi
1636   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1637             [Define to 1 if you are using the GNU C Library.])
1638
1639   ## Use mmap directly for allocating larger buffers.
1640   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1641   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1642   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1643   case "$opsys" in
1644     gnu*) REL_ALLOC=no ;;
1645   esac
1646 fi
1647
1648 if test x"${REL_ALLOC}" = x; then
1649   REL_ALLOC=${GNU_MALLOC}
1650 fi
1651
1652 use_mmap_for_buffers=no
1653 case "$opsys" in
1654   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1655 esac
1656
1657 AC_FUNC_MMAP
1658 if test $use_mmap_for_buffers = yes; then
1659   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1660   REL_ALLOC=no
1661 fi
1662
1663 LIBS="$LIBS_SYSTEM $LIBS"
1664
1665 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1666 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1667 AC_CHECK_LIB(dnet, dnet_ntoa)
1668 dnl This causes -lresolv to get used in subsequent tests,
1669 dnl which causes failures on some systems such as HPUX 9.
1670 dnl AC_CHECK_LIB(resolv, gethostbyname)
1671
1672 dnl FIXME replace main with a function we actually want from this library.
1673 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1674
1675 AC_CHECK_LIB(pthreads, cma_open)
1676
1677 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1678 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1679 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1680 ## added to LIBS in configure would never contain the pthreads part,
1681 ## but the value used in Makefiles might.  FIXME?
1682 ##
1683 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1684 ## be harmless on older versions of X where it happens to exist.
1685 test "$opsys" = "aix4-2" && \
1686   test $ac_cv_lib_pthreads_cma_open = yes && \
1687   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1688
1689 dnl Check for need for bigtoc support on IBM AIX
1690
1691 case ${host_os} in
1692 aix*)
1693   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1694     case $GCC in
1695     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1696     *) gdb_cv_bigtoc=-bbigtoc ;;
1697     esac
1698
1699     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1700     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1701   ])
1702   ;;
1703 esac
1704
1705 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1706 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1707 # REAL_CPPFLAGS later on.
1708
1709 REAL_CFLAGS="$CFLAGS"
1710 REAL_CPPFLAGS="$CPPFLAGS"
1711
1712 if test "${HAVE_X11}" = "yes"; then
1713   DEFS="$C_SWITCH_X_SITE $DEFS"
1714   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1715   LIBS="-lX11 $LIBS"
1716   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1717   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1718
1719   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1720   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1721   # but it's more convenient here to set LD_RUN_PATH
1722   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1723   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1724     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1725     export LD_RUN_PATH
1726   fi
1727
1728   if test "${opsys}" = "gnu-linux"; then
1729     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1730     AC_TRY_LINK([],
1731      [XOpenDisplay ("foo");],
1732      [xlinux_first_failure=no],
1733      [xlinux_first_failure=yes])
1734     if test "${xlinux_first_failure}" = "yes"; then
1735       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1736       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1737       OLD_CPPFLAGS="$CPPFLAGS"
1738       OLD_LIBS="$LIBS"
1739       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1740       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1741       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1742       LIBS="$LIBS -b i486-linuxaout"
1743       AC_TRY_LINK([],
1744        [XOpenDisplay ("foo");],
1745        [xlinux_second_failure=no],
1746        [xlinux_second_failure=yes])
1747       if test "${xlinux_second_failure}" = "yes"; then
1748         # If we get the same failure with -b, there is no use adding -b.
1749         # So take it out.  This plays safe.
1750         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1751         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1752         CPPFLAGS="$OLD_CPPFLAGS"
1753         LIBS="$OLD_LIBS"
1754         AC_MSG_RESULT(no)
1755       else
1756         AC_MSG_RESULT(yes)
1757       fi
1758     else
1759       AC_MSG_RESULT(no)
1760     fi
1761   fi
1762
1763   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1764   # header files included from there.
1765   AC_MSG_CHECKING(for Xkb)
1766   AC_TRY_LINK([#include <X11/Xlib.h>
1767 #include <X11/XKBlib.h>],
1768         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1769         emacs_xkb=yes, emacs_xkb=no)
1770   AC_MSG_RESULT($emacs_xkb)
1771   if test $emacs_xkb = yes; then
1772     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1773   fi
1774
1775   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1776 XScreenNumberOfScreen XSetWMProtocols)
1777 fi
1778
1779 if test "${window_system}" = "x11"; then
1780   AC_MSG_CHECKING(X11 version 6)
1781   AC_CACHE_VAL(emacs_cv_x11_version_6,
1782   [AC_TRY_LINK([#include <X11/Xlib.h>],
1783 [#if XlibSpecificationRelease < 6
1784 fail;
1785 #endif
1786 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1787   if test $emacs_cv_x11_version_6 = yes; then
1788     AC_MSG_RESULT(6 or newer)
1789     AC_DEFINE(HAVE_X11R6, 1,
1790               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1791     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1792     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1793     ## XIM support.
1794     case "$opsys" in
1795       sol2-*) : ;;
1796       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1797            [Define if you have usable X11R6-style XIM support.])
1798          ;;
1799     esac
1800   else
1801     AC_MSG_RESULT(before 6)
1802   fi
1803 fi
1804
1805
1806 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1807 HAVE_RSVG=no
1808 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1809   if test "${with_rsvg}" != "no"; then
1810     RSVG_REQUIRED=2.11.0
1811     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1812
1813     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1814     AC_SUBST(RSVG_CFLAGS)
1815     AC_SUBST(RSVG_LIBS)
1816
1817     if test $HAVE_RSVG = yes; then
1818       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1819       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1820       LIBS="$RSVG_LIBS $LIBS"
1821     fi
1822   fi
1823 fi
1824
1825 HAVE_IMAGEMAGICK=no
1826 if test "${HAVE_X11}" = "yes"; then
1827   if test "${with_imagemagick}" != "no"; then
1828     IMAGEMAGICK_MODULE="Wand"
1829     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1830     AC_SUBST(IMAGEMAGICK_CFLAGS)
1831     AC_SUBST(IMAGEMAGICK_LIBS)
1832
1833     if test $HAVE_IMAGEMAGICK = yes; then
1834       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1835       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1836       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1837       AC_CHECK_FUNCS(MagickExportImagePixels)
1838     fi
1839   fi
1840 fi
1841
1842
1843 HAVE_GTK=no
1844 if test "${with_gtk3}" = "yes"; then
1845   GLIB_REQUIRED=2.6
1846   GTK_REQUIRED=2.90
1847   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1848
1849   dnl Checks for libraries.
1850   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1851   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1852      AC_MSG_ERROR($GTK_PKG_ERRORS)
1853   fi
1854 fi
1855
1856 if test "$pkg_check_gtk" != "yes"; then
1857   HAVE_GTK=no
1858 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1859   GLIB_REQUIRED=2.6
1860   GTK_REQUIRED=2.6
1861   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1862
1863   dnl Checks for libraries.
1864   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1865   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1866      AC_MSG_ERROR($GTK_PKG_ERRORS)
1867   fi
1868 fi
1869 fi
1870
1871 GTK_OBJ=
1872 if test x"$pkg_check_gtk" = xyes; then
1873
1874   AC_SUBST(GTK_CFLAGS)
1875   AC_SUBST(GTK_LIBS)
1876   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1877   CFLAGS="$CFLAGS $GTK_CFLAGS"
1878   LIBS="$GTK_LIBS $LIBS"
1879   dnl Try to compile a simple GTK program.
1880   GTK_COMPILES=no
1881   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1882   if test "${GTK_COMPILES}" != "yes"; then
1883     if test "$USE_X_TOOLKIT" != "maybe"; then
1884       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1885     fi
1886   else
1887     HAVE_GTK=yes
1888     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1889     GTK_OBJ=gtkutil.o
1890     USE_X_TOOLKIT=none
1891     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1892       :
1893     else
1894       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1895        closing open displays.  This is no problem if you just use
1896        one display, but if you use more than one and close one of them
1897        Emacs may crash.]])
1898       sleep 3
1899     fi
1900   fi
1901
1902 fi
1903 AC_SUBST(GTK_OBJ)
1904
1905
1906 if test "${HAVE_GTK}" = "yes"; then
1907
1908   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1909   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1910   if test "$with_toolkit_scroll_bars" != no; then
1911     with_toolkit_scroll_bars=yes
1912   fi
1913
1914   dnl  Check if we have the old file selection dialog declared and
1915   dnl  in the link library.  In 2.x it may be in the library,
1916   dnl  but not declared if deprecated featured has been selected out.
1917   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1918   HAVE_GTK_FILE_SELECTION=no
1919   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1920                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1921 #include <gtk/gtk.h>])
1922   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1923     AC_CHECK_FUNCS(gtk_file_selection_new)
1924   fi
1925
1926   dnl Check if pthreads are available.  Emacs only needs this when using
1927   dnl gtk_file_chooser under Gnome.
1928     HAVE_GTK_AND_PTHREAD=no
1929     AC_CHECK_HEADERS(pthread.h)
1930     if test "$ac_cv_header_pthread_h"; then
1931       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1932     fi
1933     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1934       case "${canonical}" in
1935         *-hpux*) ;;
1936         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1937       esac
1938       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1939                [Define to 1 if you have GTK and pthread (-lpthread).])
1940     fi
1941
1942   dnl Check for functions introduced in 2.14 and later.
1943   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1944                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1945                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1946                  gtk_orientable_set_orientation)
1947
1948 fi
1949
1950 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1951 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1952 dnl also not configured.
1953 HAVE_DBUS=no
1954 DBUS_OBJ=
1955 if test "${with_dbus}" = "yes"; then
1956    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1957    if test "$HAVE_DBUS" = yes; then
1958      LIBS="$LIBS $DBUS_LIBS"
1959      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1960      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1961      DBUS_OBJ=dbusbind.o
1962    fi
1963 fi
1964 AC_SUBST(DBUS_OBJ)
1965
1966 dnl GConf has been tested under GNU/Linux only.
1967 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1968 HAVE_GCONF=no
1969 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1970    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1971    if test "$HAVE_GCONF" = yes; then
1972       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1973       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1974       AC_CHECK_FUNCS([g_type_init])
1975    fi
1976 fi
1977
1978 dnl SELinux is available for GNU/Linux only.
1979 HAVE_LIBSELINUX=no
1980 LIBSELINUX_LIBS=
1981 if test "${with_selinux}" = "yes"; then
1982    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1983    if test "$HAVE_LIBSELINUX" = yes; then
1984       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1985       LIBSELINUX_LIBS=-lselinux
1986    fi
1987 fi
1988 AC_SUBST(LIBSELINUX_LIBS)
1989
1990 HAVE_GNUTLS=no
1991 if test "${with_gnutls}" = "yes" ; then
1992   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1993   if test "${HAVE_GNUTLS}" = "yes"; then
1994     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1995   fi
1996 fi
1997 AC_SUBST(LIBGNUTLS_LIBS)
1998 AC_SUBST(LIBGNUTLS_CFLAGS)
1999
2000 dnl Do not put whitespace before the #include statements below.
2001 dnl Older compilers (eg sunos4 cc) choke on it.
2002 HAVE_XAW3D=no
2003 LUCID_LIBW=
2004 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2005   if test "$with_xaw3d" != no; then
2006     AC_MSG_CHECKING(for xaw3d)
2007     AC_CACHE_VAL(emacs_cv_xaw3d,
2008     [AC_TRY_LINK([
2009 #include <X11/Intrinsic.h>
2010 #include <X11/Xaw3d/Simple.h>],
2011       [],
2012       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2013                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2014       emacs_cv_xaw3d=no)])
2015   else
2016     emacs_cv_xaw3d=no
2017   fi
2018   if test $emacs_cv_xaw3d = yes; then
2019     AC_MSG_RESULT([yes; using Lucid toolkit])
2020     USE_X_TOOLKIT=LUCID
2021     HAVE_XAW3D=yes
2022     LUCID_LIBW=-lXaw3d
2023     AC_DEFINE(HAVE_XAW3D, 1,
2024               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2025   else
2026     AC_MSG_RESULT(no)
2027     AC_MSG_CHECKING(for libXaw)
2028     AC_CACHE_VAL(emacs_cv_xaw,
2029     [AC_TRY_LINK([
2030 #include <X11/Intrinsic.h>
2031 #include <X11/Xaw/Simple.h>],
2032       [],
2033       emacs_cv_xaw=yes,
2034       emacs_cv_xaw=no)])
2035     if test $emacs_cv_xaw = yes; then
2036       AC_MSG_RESULT([yes; using Lucid toolkit])
2037       USE_X_TOOLKIT=LUCID
2038       LUCID_LIBW=-lXaw
2039     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2040       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2041     else
2042       AC_MSG_RESULT([no; do not use toolkit by default])
2043       USE_X_TOOLKIT=none
2044     fi
2045   fi
2046 fi
2047
2048 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2049
2050 LIBXTR6=
2051 if test "${USE_X_TOOLKIT}" != "none"; then
2052   AC_MSG_CHECKING(X11 toolkit version)
2053   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2054   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2055 [#if XtSpecificationRelease < 6
2056 fail;
2057 #endif
2058 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2059   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2060   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2061     AC_MSG_RESULT(6 or newer)
2062     AC_DEFINE(HAVE_X11XTR6, 1,
2063               [Define to 1 if you have the X11R6 or newer version of Xt.])
2064     LIBXTR6="-lSM -lICE"
2065     case "$opsys" in
2066       ## Use libw.a along with X11R6 Xt.
2067       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2068     esac
2069   else
2070     AC_MSG_RESULT(before 6)
2071   fi
2072
2073 dnl If using toolkit, check whether libXmu.a exists.
2074 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2075   OLDLIBS="$LIBS"
2076   if test x$HAVE_X11XTR6 = xyes; then
2077     LIBS="-lXt -lSM -lICE $LIBS"
2078   else
2079     LIBS="-lXt $LIBS"
2080   fi
2081   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2082   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2083 fi
2084 AC_SUBST(LIBXTR6)
2085
2086 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2087 dnl Why not just test for libxmu in the normal way?
2088 LIBXMU=-lXmu
2089 case $opsys in
2090   ## These systems don't supply Xmu.
2091   hpux* | aix4-2 )
2092     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2093     ;;
2094 esac
2095 AC_SUBST(LIBXMU)
2096
2097 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2098 if test "${HAVE_X11}" = "yes"; then
2099   if test "${USE_X_TOOLKIT}" != "none"; then
2100     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2101   fi
2102 fi
2103
2104 LIBXP=
2105 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2106   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2107   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2108     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2109 int x = 5;
2110 #else
2111 Motif version prior to 2.1.
2112 #endif],
2113     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2114   if test $emacs_cv_motif_version_2_1 = yes; then
2115     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2116   else
2117     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2118     # We put this in CFLAGS temporarily to precede other -I options
2119     # that might be in CFLAGS temporarily.
2120     # We put this in CPPFLAGS where it precedes the other -I options.
2121     OLD_CPPFLAGS=$CPPFLAGS
2122     OLD_CFLAGS=$CFLAGS
2123     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2124     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2125     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2126       [int x = 5;],
2127       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2128     if test $emacs_cv_lesstif = yes; then
2129       # Make sure this -I option remains in CPPFLAGS after it is set
2130       # back to REAL_CPPFLAGS.
2131       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2132       # have those other -I options anyway.  Ultimately, having this
2133       # directory ultimately in CPPFLAGS will be enough.
2134       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2135       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2136     else
2137       CFLAGS=$OLD_CFLAGS
2138       CPPFLAGS=$OLD_CPPFLAGS
2139     fi
2140   fi
2141 fi
2142
2143 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2144 dnl using Motif or Xaw3d is available, and unless
2145 dnl --with-toolkit-scroll-bars=no was specified.
2146
2147 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2148             [Define to 1 if we should use toolkit scroll bars.])dnl
2149 USE_TOOLKIT_SCROLL_BARS=no
2150 if test "${with_toolkit_scroll_bars}" != "no"; then
2151   if test "${USE_X_TOOLKIT}" != "none"; then
2152     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2153       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2154       HAVE_XAW3D=no
2155       USE_TOOLKIT_SCROLL_BARS=yes
2156     elif test "${HAVE_XAW3D}" = "yes"; then
2157       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2158       USE_TOOLKIT_SCROLL_BARS=yes
2159     fi
2160   elif test "${HAVE_GTK}" = "yes"; then
2161     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2162     USE_TOOLKIT_SCROLL_BARS=yes
2163   elif test "${HAVE_NS}" = "yes"; then
2164     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2165     USE_TOOLKIT_SCROLL_BARS=yes
2166   fi
2167 fi
2168
2169 dnl See if XIM is available.
2170 AC_TRY_COMPILE([
2171           #include <X11/Xlib.h>
2172           #include <X11/Xresource.h>],
2173          [XIMProc  callback;],
2174          [HAVE_XIM=yes
2175          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2176          HAVE_XIM=no)
2177
2178 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2179
2180 if test "${with_xim}" != "no"; then
2181   AC_DEFINE(USE_XIM, 1,
2182             [Define to 1 if we should use XIM, if it is available.])
2183 fi
2184
2185
2186 if test "${HAVE_XIM}" != "no"; then
2187   late_CFLAGS=$CFLAGS
2188   if test "$GCC" = yes; then
2189     CFLAGS="$CFLAGS --pedantic-errors"
2190   fi
2191   AC_TRY_COMPILE([
2192 #include <X11/Xlib.h>
2193 #include <X11/Xresource.h>],
2194 [Display *display;
2195 XrmDatabase db;
2196 char *res_name;
2197 char *res_class;
2198 XIMProc  callback;
2199 XPointer *client_data;
2200 #ifndef __GNUC__
2201 /* If we're not using GCC, it's probably not XFree86, and this is
2202    probably right, but we can't use something like --pedantic-errors.  */
2203 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2204                                            char*, XIMProc, XPointer*);
2205 #endif
2206 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2207    client_data);],
2208     [emacs_cv_arg6_star=yes])
2209   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2210          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2211 either XPointer or XPointer*.])dnl
2212   if test "$emacs_cv_arg6_star" = yes; then
2213     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2214   else
2215     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2216   fi
2217   CFLAGS=$late_CFLAGS
2218 fi
2219
2220 ### Start of font-backend (under any platform) section.
2221 # (nothing here yet -- this is a placeholder)
2222 ### End of font-backend (under any platform) section.
2223
2224 ### Start of font-backend (under X11) section.
2225 if test "${HAVE_X11}" = "yes"; then
2226    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2227
2228    ## Use -lXft if available, unless `--with-xft=no'.
2229    HAVE_XFT=maybe
2230     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2231       with_xft="no";
2232     fi
2233     if test "x${with_xft}" != "xno"; then
2234
2235       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2236       ## Because xftfont.c uses XRenderQueryExtension, we also
2237       ## need to link to -lXrender.
2238       HAVE_XRENDER=no
2239       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2240       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2241         OLD_CPPFLAGS="$CPPFLAGS"
2242         OLD_CFLAGS="$CFLAGS"
2243         OLD_LIBS="$LIBS"
2244         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2245         CFLAGS="$CFLAGS $XFT_CFLAGS"
2246         XFT_LIBS="-lXrender $XFT_LIBS"
2247         LIBS="$XFT_LIBS $LIBS"
2248         AC_CHECK_HEADER(X11/Xft/Xft.h,
2249           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2250
2251         if test "${HAVE_XFT}" = "yes"; then
2252           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2253             AC_SUBST(XFT_LIBS)
2254           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2255         else
2256           CPPFLAGS="$OLD_CPPFLAGS"
2257           CFLAGS="$OLD_CFLAGS"
2258           LIBS="$OLD_LIBS"
2259         fi                        # "${HAVE_XFT}" = "yes"
2260       fi                          # "$HAVE_XFT" != no
2261     fi                            # "x${with_xft}" != "xno"
2262
2263     dnl For the "Does Emacs use" message at the end.
2264     if test "$HAVE_XFT" != "yes"; then
2265        HAVE_XFT=no
2266     fi
2267
2268     ## We used to allow building with FreeType and without Xft.
2269     ## However, the ftx font backend driver is not in good shape.
2270     HAVE_FREETYPE=$HAVE_XFT
2271
2272     HAVE_LIBOTF=no
2273     if test "${HAVE_FREETYPE}" = "yes"; then
2274       AC_DEFINE(HAVE_FREETYPE, 1,
2275                 [Define to 1 if using the freetype and fontconfig libraries.])
2276       if test "${with_libotf}" != "no"; then
2277         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2278                           HAVE_LIBOTF=no)
2279         if test "$HAVE_LIBOTF" = "yes"; then
2280           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2281           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2282                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2283                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2284           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2285             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2286                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2287           fi
2288         fi
2289       fi
2290     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2291     dnl Does the new font backend require it, or can it work without it?
2292     fi
2293
2294     HAVE_M17N_FLT=no
2295     if test "${HAVE_LIBOTF}" = yes; then
2296       if test "${with_m17n_flt}" != "no"; then
2297         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2298         if test "$HAVE_M17N_FLT" = "yes"; then
2299           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2300         fi
2301       fi
2302     fi
2303 else
2304     HAVE_XFT=no
2305     HAVE_FREETYPE=no
2306     HAVE_LIBOTF=no
2307     HAVE_M17N_FLT=no
2308 fi
2309
2310 ### End of font-backend (under X11) section.
2311
2312 AC_SUBST(FREETYPE_CFLAGS)
2313 AC_SUBST(FREETYPE_LIBS)
2314 AC_SUBST(FONTCONFIG_CFLAGS)
2315 AC_SUBST(FONTCONFIG_LIBS)
2316 AC_SUBST(LIBOTF_CFLAGS)
2317 AC_SUBST(LIBOTF_LIBS)
2318 AC_SUBST(M17N_FLT_CFLAGS)
2319 AC_SUBST(M17N_FLT_LIBS)
2320
2321 ### Use -lXpm if available, unless `--with-xpm=no'.
2322 HAVE_XPM=no
2323 LIBXPM=
2324 if test "${HAVE_X11}" = "yes"; then
2325   if test "${with_xpm}" != "no"; then
2326     AC_CHECK_HEADER(X11/xpm.h,
2327       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2328     if test "${HAVE_XPM}" = "yes"; then
2329       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2330       AC_EGREP_CPP(no_return_alloc_pixels,
2331       [#include "X11/xpm.h"
2332 #ifndef XpmReturnAllocPixels
2333 no_return_alloc_pixels
2334 #endif
2335       ], HAVE_XPM=no, HAVE_XPM=yes)
2336
2337       if test "${HAVE_XPM}" = "yes"; then
2338         AC_MSG_RESULT(yes)
2339       else
2340         AC_MSG_RESULT(no)
2341       fi
2342     fi
2343   fi
2344
2345   if test "${HAVE_XPM}" = "yes"; then
2346     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2347     LIBXPM=-lXpm
2348   fi
2349 fi
2350 AC_SUBST(LIBXPM)
2351
2352 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2353 HAVE_JPEG=no
2354 LIBJPEG=
2355 if test "${HAVE_X11}" = "yes"; then
2356   if test "${with_jpeg}" != "no"; then
2357     dnl Checking for jpeglib.h can lose because of a redefinition of
2358     dnl  HAVE_STDLIB_H.
2359     AC_CHECK_HEADER(jerror.h,
2360       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2361   fi
2362
2363   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2364   if test "${HAVE_JPEG}" = "yes"; then
2365     AC_DEFINE(HAVE_JPEG)
2366     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2367         [#include <jpeglib.h>
2368          version=JPEG_LIB_VERSION
2369 ],
2370         [AC_DEFINE(HAVE_JPEG)],
2371         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2372         HAVE_JPEG=no])
2373   fi
2374   if test "${HAVE_JPEG}" = "yes"; then
2375     LIBJPEG=-ljpeg
2376   fi
2377 fi
2378 AC_SUBST(LIBJPEG)
2379
2380 ### Use -lpng if available, unless `--with-png=no'.
2381 HAVE_PNG=no
2382 LIBPNG=
2383 if test "${HAVE_X11}" = "yes"; then
2384   if test "${with_png}" != "no"; then
2385     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2386     # in /usr/include/libpng.
2387     AC_CHECK_HEADERS(png.h libpng/png.h)
2388     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2389       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2390     fi
2391   fi
2392
2393   if test "${HAVE_PNG}" = "yes"; then
2394     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2395     LIBPNG="-lpng -lz -lm"
2396   fi
2397 fi
2398 AC_SUBST(LIBPNG)
2399
2400 ### Use -ltiff if available, unless `--with-tiff=no'.
2401 HAVE_TIFF=no
2402 LIBTIFF=
2403 if test "${HAVE_X11}" = "yes"; then
2404   if test "${with_tiff}" != "no"; then
2405     AC_CHECK_HEADER(tiffio.h,
2406       [tifflibs="-lz -lm"
2407       # At least one tiff package requires the jpeg library.
2408       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2409       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2410   fi
2411
2412   if test "${HAVE_TIFF}" = "yes"; then
2413     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2414     dnl FIXME -lz -lm, as per libpng?
2415     LIBTIFF=-ltiff
2416   fi
2417 fi
2418 AC_SUBST(LIBTIFF)
2419
2420 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2421 HAVE_GIF=no
2422 LIBGIF=
2423 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2424   AC_CHECK_HEADER(gif_lib.h,
2425 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2426 # Earlier versions can crash Emacs.
2427     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2428
2429   if test "$HAVE_GIF" = yes; then
2430     LIBGIF=-lgif
2431   elif test "$HAVE_GIF" = maybe; then
2432 # If gif_lib.h but no libgif, try libungif.
2433     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2434     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2435   fi
2436
2437   if test "${HAVE_GIF}" = "yes"; then
2438     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2439   fi
2440 fi
2441 AC_SUBST(LIBGIF)
2442
2443 dnl Check for required libraries.
2444 if test "${HAVE_X11}" = "yes"; then
2445   MISSING=""
2446   WITH_NO=""
2447   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2448     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2449   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2450     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2451   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2452     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2453   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2454     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2455   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2456     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2457
2458   if test "X${MISSING}" != X; then
2459     AC_MSG_ERROR([The following required libraries were not found:
2460     $MISSING
2461 Maybe some development libraries/packages are missing?
2462 If you don't want to link with them give
2463     $WITH_NO
2464 as options to configure])
2465   fi
2466 fi
2467
2468 ### Use -lgpm if available, unless `--with-gpm=no'.
2469 HAVE_GPM=no
2470 LIBGPM=
2471 MOUSE_SUPPORT=
2472 if test "${with_gpm}" != "no"; then
2473   AC_CHECK_HEADER(gpm.h,
2474     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2475
2476   if test "${HAVE_GPM}" = "yes"; then
2477     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2478     LIBGPM=-lgpm
2479     ## May be reset below.
2480     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2481   fi
2482 fi
2483 AC_SUBST(LIBGPM)
2484
2485 dnl Check for malloc/malloc.h on darwin
2486 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2487
2488 C_SWITCH_X_SYSTEM=
2489 ### Use NeXTstep API to implement GUI.
2490 if test "${HAVE_NS}" = "yes"; then
2491   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2492   if test "${NS_IMPL_COCOA}" = "yes"; then
2493     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2494     GNU_OBJC_CFLAGS=
2495   fi
2496   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2497     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2498     # See also .m.o rule in Makefile.in */
2499     # FIXME: are all these flags really needed?  Document here why.  */
2500     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2501     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2502   fi
2503   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2504     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2505   fi
2506   # We also have mouse menus.
2507   HAVE_MENUS=yes
2508   OTHER_FILES=ns-app
2509 fi
2510
2511
2512 ### Use session management (-lSM -lICE) if available
2513 HAVE_X_SM=no
2514 LIBXSM=
2515 if test "${HAVE_X11}" = "yes"; then
2516   AC_CHECK_HEADER(X11/SM/SMlib.h,
2517     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2518
2519   if test "${HAVE_X_SM}" = "yes"; then
2520     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2521     LIBXSM="-lSM -lICE"
2522     case "$LIBS" in
2523       *-lSM*) ;;
2524       *)      LIBS="$LIBXSM $LIBS" ;;
2525     esac
2526   fi
2527 fi
2528 AC_SUBST(LIBXSM)
2529
2530 ### Use libxml (-lxml2) if available
2531 if test "${with_xml2}" != "no"; then
2532   ### I'm not sure what the version number should be, so I just guessed.
2533   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2534   if test "${HAVE_LIBXML2}" = "yes"; then
2535     LIBS="$LIBXML2_LIBS $LIBS"
2536     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2537     if test "${HAVE_LIBXML2}" = "yes"; then
2538       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2539     else
2540       LIBXML2_LIBS=""
2541       LIBXML2_CFLAGS=""
2542     fi
2543   fi
2544 fi
2545 AC_SUBST(LIBXML2_LIBS)
2546 AC_SUBST(LIBXML2_CFLAGS)
2547
2548 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2549 AC_CACHE_CHECK(whether netdb declares h_errno,
2550                emacs_cv_netdb_declares_h_errno,
2551 [AC_TRY_LINK([#include <netdb.h>],
2552   [return h_errno;],
2553   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2554 if test $emacs_cv_netdb_declares_h_errno = yes; then
2555   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2556 fi
2557
2558 AC_FUNC_ALLOCA
2559
2560 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2561 dnl FIXME is there an autoconf test that does the right thing, without
2562 dnl needing to call A_M_E afterwards?
2563 if test x"$ac_cv_func_alloca_works" != xyes; then
2564    AC_MSG_ERROR( [a system implementation of alloca is required] )
2565 fi
2566
2567 # fmod, logb, and frexp are found in -lm on most systems.
2568 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2569 AC_CHECK_LIB(m, sqrt)
2570
2571 # Check for mail-locking functions in a "mail" library.  Probably this should
2572 # have the same check as for liblockfile below.
2573 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2574 if test $have_mail = yes; then
2575   LIBS_MAIL=-lmail
2576   LIBS="$LIBS_MAIL $LIBS"
2577   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2578 else
2579   LIBS_MAIL=
2580 fi
2581 dnl Debian, at least:
2582 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2583 if test $have_lockfile = yes; then
2584    LIBS_MAIL=-llockfile
2585    LIBS="$LIBS_MAIL $LIBS"
2586    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2587 else
2588 # If we have the shared liblockfile, assume we must use it for mail
2589 # locking (e.g. Debian).  If we couldn't link against liblockfile
2590 # (no liblockfile.a installed), ensure that we don't need to.
2591   dnl This works for files generally, not just executables.
2592   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2593   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2594                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2595   if test $ac_cv_prog_liblockfile = yes; then
2596     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2597 This probably means that movemail could lose mail.
2598 There may be a `development' package to install containing liblockfile.])
2599   fi
2600 fi
2601 AC_CHECK_FUNCS(touchlock)
2602 AC_CHECK_HEADERS(maillock.h)
2603 AC_SUBST(LIBS_MAIL)
2604
2605 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2606 ## interlock access to the mail spool.  The alternative is a lock file named
2607 ## /usr/spool/mail/$USER.lock.
2608 mail_lock=no
2609 case "$opsys" in
2610   aix4-2) mail_lock="lockf" ;;
2611
2612   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2613
2614   ## On GNU/Linux systems, both methods are used by various mail programs.
2615   ## I assume most people are using newer mailers that have heard of flock.
2616   ## Change this if you need to.
2617   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2618   ## configure gets the right answers, and that means *NOT* using flock.
2619   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2620   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2621   ## Debian maintainer hasn't provided a clean fix for Emacs.
2622   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2623   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2624   ## correct logic.  -- fx
2625   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2626   ## liblockfile is a Free Software replacement for libmail, used on
2627   ## Debian systems and elsewhere. -rfr.
2628   gnu-*)
2629     mail_lock="flock"
2630     if test $have_mail = yes || test $have_lockfile = yes; then
2631       test $ac_cv_header_maillock_h = yes && mail_lock=no
2632     fi
2633     ;;
2634 esac
2635
2636 BLESSMAIL_TARGET=
2637 case "$mail_lock" in
2638   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2639
2640   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2641
2642   *) BLESSMAIL_TARGET="need-blessmail" ;;
2643 esac
2644 AC_SUBST(BLESSMAIL_TARGET)
2645
2646
2647 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2648 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2649 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2650 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2651 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2652 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2653 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2654 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2655 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2656 cfmakeraw cfsetspeed isnan copysign __executable_start)
2657
2658 dnl Cannot use AC_CHECK_FUNCS
2659 AC_CACHE_CHECK([for __builtin_unwind_init],
2660                emacs_cv_func___builtin_unwind_init,
2661 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2662                 emacs_cv_func___builtin_unwind_init=yes,
2663                 emacs_cv_func___builtin_unwind_init=no)])
2664 if test $emacs_cv_func___builtin_unwind_init = yes; then
2665   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2666             [Define to 1 if you have the `__builtin_unwind_init' function.])
2667 fi
2668
2669 AC_CHECK_HEADERS(sys/un.h)
2670
2671 AC_FUNC_GETLOADAVG
2672
2673 AC_FUNC_FSEEKO
2674
2675 AC_FUNC_GETPGRP
2676
2677 # Configure gnulib.
2678 gl_ASSERT_NO_GNULIB_POSIXCHECK
2679 gl_ASSERT_NO_GNULIB_TESTS
2680 gl_INIT
2681
2682 # UNIX98 PTYs.
2683 AC_CHECK_FUNCS(grantpt)
2684
2685 # PTY-related GNU extensions.
2686 AC_CHECK_FUNCS(getpt)
2687
2688 # Check this now, so that we will NOT find the above functions in ncurses.
2689 # That is because we have not set up to link ncurses in lib-src.
2690 # It's better to believe a function is not available
2691 # than to expect to find it in ncurses.
2692 # Also we need tputs and friends to be able to build at all.
2693 have_tputs_et_al=true
2694 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2695 if test "$have_tputs_et_al" != true; then
2696   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2697 Maybe some development libraries/packages are missing?  Try installing
2698 libncurses-dev(el), libterminfo-dev(el) or similar.])
2699 fi
2700 # Must define this when any termcap library is found.
2701 AC_DEFINE(HAVE_LIBNCURSES, 1,
2702           [Define to 1 if you have the `ncurses' library (-lncurses).])
2703 ## FIXME This was the cpp logic, but I am not sure it is right.
2704 ## The above test has not necessarily found libncurses.
2705 HAVE_LIBNCURSES=yes
2706
2707 ## Use terminfo instead of termcap?
2708 ## Note only system files NOT using terminfo are:
2709 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2710 ## darwin|gnu without ncurses.
2711 TERMINFO=no
2712 LIBS_TERMCAP=
2713 case "$opsys" in
2714   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2715   ## hpux10-20: Use the system provided termcap(3) library.
2716   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2717   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2718   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2719
2720   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2721   ##  The ncurses library has been moved out of the System framework in
2722   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2723   ##  option to use it.
2724   darwin|gnu*)
2725     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2726     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2727       TERMINFO=yes
2728       LIBS_TERMCAP="-lncurses"
2729     fi
2730     ;;
2731
2732   freebsd)
2733     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2734     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2735     [AC_TRY_LINK([#include <osreldate.h>],
2736 [#if __FreeBSD_version < 400000
2737 fail;
2738 #endif
2739 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2740
2741     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2742
2743     if test $emacs_cv_freebsd_terminfo = yes; then
2744       TERMINFO=yes
2745       LIBS_TERMCAP="-lncurses"
2746     else
2747       LIBS_TERMCAP="-ltermcap"
2748     fi
2749     ;;
2750
2751   netbsd)
2752     if test $ac_cv_search_tputs = -lterminfo; then
2753       TERMINFO=yes
2754       LIBS_TERMCAP="-lterminfo"
2755     else
2756       LIBS_TERMCAP="-ltermcap"
2757     fi
2758     ;;
2759
2760 esac
2761
2762 case "$opsys" in
2763   ## hpux: Make sure we get select from libc rather than from libcurses
2764   ##  because libcurses on HPUX 10.10 has a broken version of select.
2765   ##  We used to use -lc -lcurses, but this may be cleaner.
2766   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2767
2768   openbsd) LIBS_TERMCAP="-lncurses" ;;
2769
2770   ## Must use system termcap, if we use any termcap.  It does special things.
2771   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2772 esac
2773
2774 TERMCAP_OBJ=tparam.o
2775 if test $TERMINFO = yes; then
2776   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2777
2778   ## Default used to be -ltermcap.  Add a case above if need something else.
2779   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2780
2781   TERMCAP_OBJ=terminfo.o
2782 fi
2783 AC_SUBST(LIBS_TERMCAP)
2784 AC_SUBST(TERMCAP_OBJ)
2785
2786
2787 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2788 resolv=no
2789 AC_TRY_LINK([#include <netinet/in.h>
2790 #include <arpa/nameser.h>
2791 #include <resolv.h>],
2792     [return res_init();],
2793     have_res_init=yes, have_res_init=no)
2794 if test "$have_res_init" = no; then
2795   OLIBS="$LIBS"
2796   LIBS="$LIBS -lresolv"
2797   AC_MSG_CHECKING(for res_init with -lresolv)
2798   AC_TRY_LINK([#include <netinet/in.h>
2799 #include <arpa/nameser.h>
2800 #include <resolv.h>],
2801     [return res_init();],
2802     have_res_init=yes, have_res_init=no)
2803   AC_MSG_RESULT($have_res_init)
2804   if test "$have_res_init" = yes ; then
2805     resolv=yes
2806   fi
2807   LIBS="$OLIBS"
2808 fi
2809
2810 if test "$have_res_init" = yes; then
2811   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2812 fi
2813
2814 # Do we need the Hesiod library to provide the support routines?
2815 LIBHESIOD=
2816 if test "$with_hesiod" != no ; then
2817   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2818   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2819      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2820                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2821   if test "$resolv" = yes ; then
2822     RESOLVLIB=-lresolv
2823   else
2824     RESOLVLIB=
2825   fi
2826   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2827         hesiod=yes, :, $RESOLVLIB)])
2828
2829   if test x"$hesiod" = xyes; then
2830     AC_DEFINE(HAVE_LIBHESIOD, 1,
2831               [Define to 1 if you have the hesiod library (-lhesiod).])
2832     LIBHESIOD=-lhesiod
2833   fi
2834 fi
2835 AC_SUBST(LIBHESIOD)
2836
2837 # Do we need libresolv (due to res_init or Hesiod)?
2838 if test "$resolv" = yes ; then
2839   AC_DEFINE(HAVE_LIBRESOLV, 1,
2840             [Define to 1 if you have the resolv library (-lresolv).])
2841   LIBRESOLV=-lresolv
2842 else
2843   LIBRESOLV=
2844 fi
2845 AC_SUBST(LIBRESOLV)
2846
2847 # These tell us which Kerberos-related libraries to use.
2848 COM_ERRLIB=
2849 CRYPTOLIB=
2850 KRB5LIB=
2851 DESLIB=
2852 KRB4LIB=
2853
2854 if test "${with_kerberos}" != no; then
2855   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2856   if test $have_com_err = yes; then
2857     COM_ERRLIB=-lcom_err
2858     LIBS="$COM_ERRLIB $LIBS"
2859     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2860   fi
2861   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2862   if test $have_crypto = yes; then
2863     CRYPTOLIB=-lcrypto
2864     LIBS="$CRYPTOLIB $LIBS"
2865     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2866   fi
2867   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2868   if test $have_k5crypto = yes; then
2869     CRYPTOLIB=-lk5crypto
2870     LIBS="$CRYPTOLIB $LIBS"
2871     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2872   fi
2873   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2874   if test $have_krb5=yes; then
2875     KRB5LIB=-lkrb5
2876     LIBS="$KRB5LIB $LIBS"
2877     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2878   fi
2879   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2880   if test "${with_kerberos5}" = no; then
2881     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2882     if test $have_des425 = yes; then
2883       DESLIB=-ldes425
2884       LIBS="$DESLIB $LIBS"
2885       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2886     else
2887       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2888       if test $have_des = yes; then
2889         DESLIB=-ldes
2890         LIBS="$DESLIB $LIBS"
2891         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2892       fi
2893     fi
2894     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2895     if test $have_krb4 = yes; then
2896       KRB4LIB=-lkrb4
2897       LIBS="$KRB4LIB $LIBS"
2898       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2899     else
2900       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2901       if test $have_krb = yes; then
2902         KRB4LIB=-lkrb
2903         LIBS="$KRB4LIB $LIBS"
2904         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2905       fi
2906     fi
2907   fi
2908
2909   if test "${with_kerberos5}" != no; then
2910     AC_CHECK_HEADERS(krb5.h,
2911       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2912                         [#include <krb5.h>])])
2913   else
2914     AC_CHECK_HEADERS(des.h,,
2915                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2916                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2917     AC_CHECK_HEADERS(krb.h,,
2918                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2919                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2920   fi
2921   AC_CHECK_HEADERS(com_err.h)
2922 fi
2923
2924 AC_SUBST(COM_ERRLIB)
2925 AC_SUBST(CRYPTOLIB)
2926 AC_SUBST(KRB5LIB)
2927 AC_SUBST(DESLIB)
2928 AC_SUBST(KRB4LIB)
2929
2930 # Solaris requires -lintl if you want strerror (which calls dgettext)
2931 # to return localized messages.
2932 AC_CHECK_LIB(intl, dgettext)
2933
2934 AC_MSG_CHECKING(whether localtime caches TZ)
2935 AC_CACHE_VAL(emacs_cv_localtime_cache,
2936 [if test x$ac_cv_func_tzset = xyes; then
2937 AC_TRY_RUN([#include <time.h>
2938 char TZ_GMT0[] = "TZ=GMT0";
2939 char TZ_PST8[] = "TZ=PST8";
2940 main()
2941 {
2942   time_t now = time ((time_t *) 0);
2943   int hour_GMT0, hour_unset;
2944   if (putenv (TZ_GMT0) != 0)
2945     exit (1);
2946   hour_GMT0 = localtime (&now)->tm_hour;
2947   unsetenv("TZ");
2948   hour_unset = localtime (&now)->tm_hour;
2949   if (putenv (TZ_PST8) != 0)
2950     exit (1);
2951   if (localtime (&now)->tm_hour == hour_GMT0)
2952     exit (1);
2953   unsetenv("TZ");
2954   if (localtime (&now)->tm_hour != hour_unset)
2955     exit (1);
2956   exit (0);
2957 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2958 [# If we have tzset, assume the worst when cross-compiling.
2959 emacs_cv_localtime_cache=yes])
2960 else
2961         # If we lack tzset, report that localtime does not cache TZ,
2962         # since we can't invalidate the cache if we don't have tzset.
2963         emacs_cv_localtime_cache=no
2964 fi])dnl
2965 AC_MSG_RESULT($emacs_cv_localtime_cache)
2966 if test $emacs_cv_localtime_cache = yes; then
2967   AC_DEFINE(LOCALTIME_CACHE, 1,
2968             [Define to 1 if localtime caches TZ.])
2969 fi
2970
2971 if test "x$HAVE_TIMEVAL" = xyes; then
2972   AC_CHECK_FUNCS(gettimeofday)
2973   if test $ac_cv_func_gettimeofday = yes; then
2974     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2975                    emacs_cv_gettimeofday_two_arguments,
2976     [AC_TRY_COMPILE([
2977 #ifdef TIME_WITH_SYS_TIME
2978 #include <sys/time.h>
2979 #include <time.h>
2980 #else
2981 #ifdef HAVE_SYS_TIME_H
2982 #include <sys/time.h>
2983 #else
2984 #include <time.h>
2985 #endif
2986 #endif],
2987       [struct timeval time;
2988        gettimeofday (&time, 0);],
2989       emacs_cv_gettimeofday_two_arguments=yes,
2990       emacs_cv_gettimeofday_two_arguments=no)])
2991     if test $emacs_cv_gettimeofday_two_arguments = no; then
2992       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2993                 [Define to 1 if gettimeofday accepts only one argument.])
2994     fi
2995   fi
2996 fi
2997
2998 ok_so_far=yes
2999 AC_CHECK_FUNC(socket, , ok_so_far=no)
3000 if test $ok_so_far = yes; then
3001   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3002 fi
3003 if test $ok_so_far = yes; then
3004   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3005 fi
3006 if test $ok_so_far = yes; then
3007 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3008   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3009             [Define to 1 if you have inet sockets.])
3010 fi
3011
3012 if test -f /usr/lpp/X11/bin/smt.exp; then
3013   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3014             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3015 fi
3016
3017 AC_MSG_CHECKING(whether system supports dynamic ptys)
3018 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3019   AC_MSG_RESULT(yes)
3020   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3021 else
3022   AC_MSG_RESULT(no)
3023 fi
3024
3025 AC_FUNC_FORK
3026
3027 dnl Adapted from Haible's version.
3028 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3029   [AC_TRY_LINK([#include <langinfo.h>],
3030     [char* cs = nl_langinfo(CODESET);],
3031     emacs_cv_langinfo_codeset=yes,
3032     emacs_cv_langinfo_codeset=no)
3033   ])
3034 if test $emacs_cv_langinfo_codeset = yes; then
3035   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3036     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3037 fi
3038
3039 AC_CHECK_TYPES(size_t)
3040
3041 AC_TYPE_MBSTATE_T
3042
3043 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3044   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3045                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3046 if test "$emacs_cv_c_restrict_arr" = yes; then
3047   AC_DEFINE(__restrict_arr, __restrict,
3048     [Define to compiler's equivalent of C99 restrict keyword in array
3049      declarations.  Define as empty for no equivalent.])
3050 fi
3051
3052 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3053 dnl how the tty code is related to POSIX and/or other versions of termios.
3054 dnl The following looks like a useful start.
3055 dnl
3056 dnl AC_SYS_POSIX_TERMIOS
3057 dnl if test $ac_cv_sys_posix_termios = yes; then
3058 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3059 dnl                                and macros for terminal control.])
3060 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3061 dnl fi
3062
3063 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3064
3065 # Set up the CFLAGS for real compilation, so we can substitute it.
3066 CFLAGS="$REAL_CFLAGS"
3067 CPPFLAGS="$REAL_CPPFLAGS"
3068
3069 ## Hack to detect a buggy GCC version.
3070 if test "x$GCC" = xyes \
3071    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3072    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3073    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3074    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3075 fi
3076
3077 version=$PACKAGE_VERSION
3078
3079 ### Specify what sort of things we'll be editing into Makefile and config.h.
3080 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3081 AC_SUBST(version)
3082 AC_SUBST(configuration)
3083 ## Unused?
3084 AC_SUBST(canonical)
3085 AC_SUBST(srcdir)
3086 AC_SUBST(prefix)
3087 AC_SUBST(exec_prefix)
3088 AC_SUBST(bindir)
3089 AC_SUBST(datadir)
3090 AC_SUBST(sharedstatedir)
3091 AC_SUBST(libexecdir)
3092 AC_SUBST(mandir)
3093 AC_SUBST(infodir)
3094 AC_SUBST(lispdir)
3095 AC_SUBST(locallisppath)
3096 AC_SUBST(lisppath)
3097 AC_SUBST(x_default_search_path)
3098 AC_SUBST(etcdir)
3099 AC_SUBST(archlibdir)
3100 AC_SUBST(docdir)
3101 AC_SUBST(bitmapdir)
3102 AC_SUBST(gamedir)
3103 AC_SUBST(gameuser)
3104 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3105 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3106 ## end of LIBX_BASE, but nothing ever set it.
3107 AC_SUBST(LD_SWITCH_X_SITE)
3108 AC_SUBST(C_SWITCH_X_SITE)
3109 AC_SUBST(C_SWITCH_X_SYSTEM)
3110 AC_SUBST(CFLAGS)
3111 ## Used in lwlib/Makefile.in.
3112 AC_SUBST(X_TOOLKIT_TYPE)
3113 if test -n "${machfile}"; then
3114   M_FILE="\$(srcdir)/${machfile}"
3115 else
3116   M_FILE=
3117 fi
3118 S_FILE="\$(srcdir)/${opsysfile}"
3119 AC_SUBST(M_FILE)
3120 AC_SUBST(S_FILE)
3121 AC_SUBST(GETLOADAVG_LIBS)
3122 AC_SUBST(ns_appdir)
3123 AC_SUBST(ns_appbindir)
3124 AC_SUBST(ns_appresdir)
3125 AC_SUBST(ns_appsrc)
3126 AC_SUBST(GNU_OBJC_CFLAGS)
3127 AC_SUBST(OTHER_FILES)
3128
3129 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3130                    [Define to the canonical Emacs configuration name.])
3131 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3132                    [Define to the options passed to configure.])
3133 if test -n "$machfile"; then
3134   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3135                      [Define to the used machine dependent file.])
3136 fi
3137 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3138                    [Define to the used os dependent file.])
3139
3140 XMENU_OBJ=
3141 XOBJ=
3142 FONT_OBJ=
3143 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3144   AC_DEFINE(HAVE_X_WINDOWS, 1,
3145             [Define to 1 if you want to use the X window system.])
3146   XMENU_OBJ=xmenu.o
3147   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3148   FONT_OBJ=xfont.o
3149   if test "$HAVE_XFT" = "yes"; then
3150     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3151   elif test "$HAVE_FREETYPE" = "yes"; then
3152     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3153   fi
3154   AC_SUBST(FONT_OBJ)
3155 fi
3156 AC_SUBST(XMENU_OBJ)
3157 AC_SUBST(XOBJ)
3158 AC_SUBST(FONT_OBJ)
3159
3160 WIDGET_OBJ=
3161 MOTIF_LIBW=
3162 if test "${USE_X_TOOLKIT}" != "none" ; then
3163   WIDGET_OBJ=widget.o
3164   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3165   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3166     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3167   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3168     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3169     MOTIF_LIBW=-lXm
3170     case "$opsys" in
3171       gnu-linux)
3172         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3173         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3174         ;;
3175
3176       unixware)
3177         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3178         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3179         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3180         ;;
3181
3182       aix4-2)
3183         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3184         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3185         ;;
3186     esac
3187     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3188   fi
3189 fi
3190 AC_SUBST(WIDGET_OBJ)
3191
3192 TOOLKIT_LIBW=
3193 case "$USE_X_TOOLKIT" in
3194   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3195   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3196   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3197 esac
3198 AC_SUBST(TOOLKIT_LIBW)
3199
3200 if test "$USE_X_TOOLKIT" = "none"; then
3201   LIBXT_OTHER="\$(LIBXSM)"
3202   OLDXMENU_TARGET="really-oldXMenu"
3203 else
3204   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3205   OLDXMENU_TARGET="really-lwlib"
3206 fi
3207 AC_SUBST(LIBXT_OTHER)
3208
3209 ## The X Menu stuff is present in the X10 distribution, but missing
3210 ## from X11.  If we have X10, just use the installed library;
3211 ## otherwise, use our own copy.
3212 if test "${HAVE_X11}" = "yes" ; then
3213   AC_DEFINE(HAVE_X11, 1,
3214             [Define to 1 if you want to use version 11 of X windows.
3215              Otherwise, Emacs expects to use version 10.])
3216
3217   if test "$USE_X_TOOLKIT" = "none"; then
3218     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3219   else
3220     OLDXMENU="\${lwlibdir}/liblw.a"
3221   fi
3222   LIBXMENU="\$(OLDXMENU)"
3223   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3224   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3225 else
3226   ## For a syntactically valid Makefile; not actually used for anything.
3227   ## See comments in src/Makefile.in.
3228   OLDXMENU=nothing
3229   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3230   if test "${HAVE_X_WINDOWS}" = "yes"; then
3231     LIBXMENU="-lXMenu"
3232   else
3233     LIBXMENU=
3234   fi
3235   LIBX_OTHER=
3236   OLDXMENU_DEPS=
3237 fi
3238
3239 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3240   OLDXMENU_TARGET=
3241   OLDXMENU=nothing
3242   LIBXMENU=
3243   OLDXMENU_DEPS=
3244 fi
3245
3246 AC_SUBST(OLDXMENU_TARGET)
3247 AC_SUBST(OLDXMENU)
3248 AC_SUBST(LIBXMENU)
3249 AC_SUBST(LIBX_OTHER)
3250 AC_SUBST(OLDXMENU_DEPS)
3251
3252 if test "${HAVE_MENUS}" = "yes" ; then
3253   AC_DEFINE(HAVE_MENUS, 1,
3254             [Define to 1 if you have mouse menus.
3255              (This is automatic if you use X, but the option to specify it remains.)
3256              It is also defined with other window systems that support xmenu.c.])
3257 fi
3258
3259 if test "${GNU_MALLOC}" = "yes" ; then
3260   AC_DEFINE(GNU_MALLOC, 1,
3261             [Define to 1 if you want to use the GNU memory allocator.])
3262 fi
3263
3264 RALLOC_OBJ=
3265 if test "${REL_ALLOC}" = "yes" ; then
3266   AC_DEFINE(REL_ALLOC, 1,
3267             [Define REL_ALLOC if you want to use the relocating allocator for
3268              buffer space.])
3269
3270   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3271 fi
3272 AC_SUBST(RALLOC_OBJ)
3273
3274 if test "$opsys" = "cygwin"; then
3275   CYGWIN_OBJ="sheap.o"
3276   ## Cygwin differs because of its unexec().
3277   PRE_ALLOC_OBJ=
3278   POST_ALLOC_OBJ=lastfile.o
3279 else
3280   CYGWIN_OBJ=
3281   PRE_ALLOC_OBJ=lastfile.o
3282   POST_ALLOC_OBJ=
3283 fi
3284 AC_SUBST(CYGWIN_OBJ)
3285 AC_SUBST(PRE_ALLOC_OBJ)
3286 AC_SUBST(POST_ALLOC_OBJ)
3287
3288
3289 case "$opsys" in
3290   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3291
3292   darwin)
3293    ## The -headerpad option tells ld (see man page) to leave room at the
3294    ## end of the header for adding load commands.  Needed for dumping.
3295    ## 0x690 is the total size of 30 segment load commands (at 56
3296    ## each); under Cocoa 31 commands are required.
3297    if test "$HAVE_NS" = "yes"; then
3298      libs_nsgui="-framework AppKit"
3299      headerpad_extra=6C8
3300    else
3301      libs_nsgui=
3302      headerpad_extra=690
3303    fi
3304    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3305
3306    ## This is here because src/Makefile.in did some extra fiddling around
3307    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3308    ##   #ifndef LD_SWITCH_SYSTEM
3309    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3310    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3311    ## not using gcc, darwin system not on an alpha (ie darwin, since
3312    ## darwin + alpha does not occur).
3313    ## Because this was done in src/Makefile.in, the resulting part of
3314    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3315    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3316    ## rather than LD_SWITCH_SYSTEM.
3317    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3318      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3319    ;;
3320
3321   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3322   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3323   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3324   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3325   ## had different values in configure (in ac_link) and src/Makefile.in.
3326   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3327   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3328
3329   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3330 esac
3331
3332 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3333   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3334 fi
3335
3336 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3337
3338
3339 LD_FIRSTFLAG=
3340 ORDINARY_LINK=
3341 case "$opsys" in
3342   ## gnu: GNU needs its own crt0.
3343   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3344
3345   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3346   ## library search parth, i.e. it won't search /usr/lib for libc and
3347   ## friends.  Using -nostartfiles instead avoids this problem, and
3348   ## will also work on earlier NetBSD releases.
3349   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3350
3351   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3352   ##   MkLinux/LinuxPPC needs this.
3353   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3354   gnu-*)
3355     case "$machine" in
3356       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3357     esac
3358     ;;
3359 esac
3360
3361
3362 if test "x$ORDINARY_LINK" = "xyes"; then
3363
3364   LD_FIRSTFLAG=""
3365   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3366
3367 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3368 ## freebsd, gnu-* not on macppc|ibms390x.
3369 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3370
3371   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3372   ## places that are difficult to figure out at make time.  Fortunately,
3373   ## these same versions allow you to pass arbitrary flags on to the
3374   ## linker, so there is no reason not to use it as a linker.
3375   ##
3376   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3377   ## searching for libraries in its internal directories, so we have to
3378   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3379   LD_FIRSTFLAG="-nostdlib"
3380 fi
3381
3382 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3383 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3384
3385 AC_SUBST(LD_FIRSTFLAG)
3386
3387
3388 ## FIXME? The logic here is not precisely the same as that above.
3389 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3390 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3391 LIB_GCC=
3392 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3393
3394   case "$opsys" in
3395     freebsd|netbsd|openbsd) LIB_GCC= ;;
3396
3397     gnu-*)
3398       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3399       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3400       case $host_cpu in
3401       arm*)
3402         LIB_GCC="-lgcc_s"
3403         ;;
3404       *)
3405         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3406         ## immediately undefine it again and redefine it to empty.
3407         ## Was the C_SWITCH_X_SITE part really necessary?
3408 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3409         LIB_GCC=
3410         ;;
3411       esac
3412       ;;
3413
3414     ## Ask GCC where to find libgcc.a.
3415     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3416   esac
3417 fi                              dnl if $GCC
3418 AC_SUBST(LIB_GCC)
3419
3420
3421 TOOLTIP_SUPPORT=
3422 WINDOW_SUPPORT=
3423 ## If we're using X11/GNUstep, define some consequences.
3424 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3425   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3426   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3427   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3428   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3429
3430   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3431   test "$HAVE_X_WINDOWS" = "yes" && \
3432     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3433
3434 fi
3435 AC_SUBST(MOUSE_SUPPORT)
3436 AC_SUBST(TOOLTIP_SUPPORT)
3437 AC_SUBST(WINDOW_SUPPORT)
3438
3439
3440 AH_TOP([/* GNU Emacs site configuration template file.
3441
3442 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3443   Free Software Foundation, Inc.
3444
3445 This file is part of GNU Emacs.
3446
3447 GNU Emacs is free software: you can redistribute it and/or modify
3448 it under the terms of the GNU General Public License as published by
3449 the Free Software Foundation, either version 3 of the License, or
3450 (at your option) any later version.
3451
3452 GNU Emacs is distributed in the hope that it will be useful,
3453 but WITHOUT ANY WARRANTY; without even the implied warranty of
3454 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3455 GNU General Public License for more details.
3456
3457 You should have received a copy of the GNU General Public License
3458 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3459
3460
3461 /* No code in Emacs #includes config.h twice, but some bits of code
3462    intended to work with other packages as well (like gmalloc.c)
3463    think they can include it as many times as they like.  */
3464 #ifndef EMACS_CONFIG_H
3465 #define EMACS_CONFIG_H
3466 ])dnl
3467
3468 AH_BOTTOM([
3469 /* Define AMPERSAND_FULL_NAME if you use the convention
3470    that & in the full name stands for the login id.  */
3471 /* Turned on June 1996 supposing nobody will mind it.  */
3472 #define AMPERSAND_FULL_NAME
3473
3474 /* If using GNU, then support inline function declarations.  */
3475 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3476    generally, because even if non-gcc compilers accept `inline', they
3477    may reject `extern inline'.  */
3478 #if defined (__GNUC__)
3479 #define INLINE __inline__
3480 #else
3481 #define INLINE
3482 #endif
3483
3484 /* `subprocesses' should be defined if you want to
3485    have code for asynchronous subprocesses
3486    (as used in M-x compile and M-x shell).
3487    Only MSDOS does not support this (it overrides
3488    this in its config_opsysfile below).  */
3489
3490 #define subprocesses
3491
3492 /* Include the os and machine dependent files.  */
3493 #include config_opsysfile
3494 #ifdef config_machfile
3495 # include config_machfile
3496 #endif
3497
3498 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3499    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3500   (There is probably a better place to do this, but right now the
3501    Cocoa side does this in s/darwin.h and we cannot parallel this
3502    exactly since GNUstep is multi-OS.  */
3503 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3504 #  define SYSTEM_PURESIZE_EXTRA 30000
3505 #endif
3506
3507 /* SIGTYPE is the macro we actually use.  */
3508 #ifndef SIGTYPE
3509 #define SIGTYPE RETSIGTYPE
3510 #endif
3511
3512 #ifdef emacs /* Don't do this for lib-src.  */
3513 /* Tell regex.c to use a type compatible with Emacs.  */
3514 #define RE_TRANSLATE_TYPE Lisp_Object
3515 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3516 #ifdef make_number
3517 /* If make_number is a macro, use it.  */
3518 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3519 #else
3520 /* If make_number is a function, avoid it.  */
3521 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3522 #endif
3523 #endif
3524
3525 /* These default definitions are good for almost all machines.
3526    The exceptions override them in m/MACHINE.h.  */
3527
3528 #ifndef BITS_PER_CHAR
3529 #define BITS_PER_CHAR 8
3530 #endif
3531
3532 #ifndef BITS_PER_SHORT
3533 #define BITS_PER_SHORT 16
3534 #endif
3535
3536 /* Note that lisp.h uses this in a preprocessor conditional, so it
3537    would not work to use sizeof.  That being so, we do all of them
3538    without sizeof, for uniformity's sake.  */
3539 #ifndef BITS_PER_INT
3540 #define BITS_PER_INT 32
3541 #endif
3542
3543 #ifndef BITS_PER_LONG
3544 #ifdef _LP64
3545 #define BITS_PER_LONG 64
3546 #else
3547 #define BITS_PER_LONG 32
3548 #endif
3549 #endif
3550
3551 /* Define if the compiler supports function prototypes.  It may do so but
3552    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3553 #undef PROTOTYPES
3554
3555 #include <string.h>
3556 #include <stdlib.h>
3557
3558 #ifdef HAVE_ALLOCA_H
3559 # include <alloca.h>
3560 #elif defined __GNUC__
3561 # define alloca __builtin_alloca
3562 #elif defined _AIX
3563 # define alloca __alloca
3564 #else
3565 # include <stddef.h>
3566 # ifdef  __cplusplus
3567 extern "C"
3568 # endif
3569 void *alloca (size_t);
3570 #endif
3571
3572 #ifndef HAVE_SIZE_T
3573 typedef unsigned size_t;
3574 #endif
3575
3576 #ifndef HAVE_STRCHR
3577 #define strchr(a, b) index (a, b)
3578 #endif
3579
3580 #ifndef HAVE_STRRCHR
3581 #define strrchr(a, b) rindex (a, b)
3582 #endif
3583
3584 #if defined __GNUC__ && (__GNUC__ > 2 \
3585                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3586 #define NO_RETURN       __attribute__ ((__noreturn__))
3587 #else
3588 #define NO_RETURN       /* nothing */
3589 #endif
3590
3591 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3592 #define NO_INLINE __attribute__((noinline))
3593 #else
3594 #define NO_INLINE
3595 #endif
3596
3597 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3598 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3599 #else
3600 #define EXTERNALLY_VISIBLE
3601 #endif
3602
3603 /* Some versions of GNU/Linux define noinline in their headers.  */
3604 #ifdef noinline
3605 #undef noinline
3606 #endif
3607
3608 /* These won't be used automatically yet.  We also need to know, at least,
3609    that the stack is continuous.  */
3610 #ifdef __GNUC__
3611 #  ifndef GC_SETJMP_WORKS
3612   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3613 #    define GC_SETJMP_WORKS 1
3614 #  endif
3615 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3616 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3617 #  endif
3618 #endif
3619
3620 #endif /* EMACS_CONFIG_H */
3621
3622 /*
3623 Local Variables:
3624 mode: c
3625 End:
3626 */
3627 ])dnl
3628
3629 #### Report on what we decided to do.
3630 #### Report GTK as a toolkit, even if it doesn't use Xt.
3631 #### It makes printing result more understandable as using GTK sets
3632 #### toolkit_scroll_bars to yes by default.
3633 if test "${HAVE_GTK}" = "yes"; then
3634   USE_X_TOOLKIT=GTK
3635 fi
3636
3637 and_machfile=
3638 if test -n "$machfile"; then
3639   and_machfile=" and \`${machfile}'"
3640 fi
3641
3642 echo "
3643 Configured for \`${canonical}'.
3644
3645   Where should the build process find the source code?    ${srcdir}
3646   What operating system and machine description files should Emacs use?
3647         \`${opsysfile}'${and_machfile}
3648   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3649   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3650   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3651   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3652   What window system should Emacs use?                    ${window_system}
3653   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3654
3655 if test -n "${x_includes}"; then
3656 echo "  Where do we find X Windows header files?                ${x_includes}"
3657 else
3658 echo "  Where do we find X Windows header files?                Standard dirs"
3659 fi
3660 if test -n "${x_libraries}"; then
3661 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3662 else
3663 echo "  Where do we find X Windows libraries?                   Standard dirs"
3664 fi
3665
3666 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3667 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3668 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3669 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3670 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3671 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3672 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3673 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3674
3675 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3676 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3677 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3678 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3679 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3680 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3681
3682 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3683 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3684 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3685 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3686
3687 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3688 echo
3689
3690 if test $USE_XASSERTS = yes; then
3691    echo "  Compiling with asserts turned on."
3692    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3693 fi
3694
3695 echo
3696
3697 if test "$HAVE_NS" = "yes"; then
3698    echo
3699    echo "You must run \"make install\" in order to test the built application.
3700 The installed application will go to nextstep/Emacs.app and can be
3701 run or moved from there."
3702    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3703       echo "The application will be fully self-contained."
3704     else
3705       echo "The lisp resources for the application will be installed under ${prefix}.
3706 You may need to run \"make install\" with sudo.  The application will fail
3707 to run if these resources are not installed."
3708    fi
3709    echo
3710 fi
3711
3712
3713 # Remove any trailing slashes in these variables.
3714 [test "${prefix}" != NONE &&
3715   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3716 test "${exec_prefix}" != NONE &&
3717   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3718
3719 dnl You might wonder (I did) why epaths.h is generated by running make,
3720 dnl rather than just letting configure generate it from epaths.in.
3721 dnl One reason is that the various paths are not fully expanded (see above);
3722 dnl eg gamedir=${prefix}/var/games/emacs.
3723 dnl Secondly, the GNU Coding standards require that one should be able
3724 dnl to run `make prefix=/some/where/else' and override the values set
3725 dnl by configure.  This also explains the `move-if-change' test and
3726 dnl the use of force in the `epaths-force' rule in Makefile.in.
3727 AC_OUTPUT(Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3728         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3729         doc/lispref/Makefile src/Makefile \
3730         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile, [
3731
3732 ### Make the necessary directories, if they don't exist.
3733 for dir in etc lisp ; do
3734   test -d ${dir} || mkdir ${dir}
3735 done
3736
3737 echo creating src/epaths.h
3738 ${MAKE-make} epaths-force
3739
3740 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3741   echo creating src/.gdbinit
3742   echo source $srcdir/src/.gdbinit > src/.gdbinit
3743 fi
3744
3745 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])