lisp/progmodes/asm-mode.el

   1 ;;; asm-mode.el --- mode for editing assembler code
   2
   3 ;; Copyright (C) 1991, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: tools, languages
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This mode was written by Eric S. Raymond <esr@snark.thyrsus.com>,
  28 ;; inspired by an earlier asm-mode by Martin Neitzel.
  29
  30 ;; This minor mode is based on text mode.  It defines a private abbrev table
  31 ;; that can be used to save abbrevs for assembler mnemonics.  It binds just
  32 ;; five keys:
  33 ;;
  34 ;;      TAB             tab to next tab stop
  35 ;;      :               outdent preceding label, tab to tab stop
  36 ;;      comment char    place or move comment
  37 ;;                      asm-comment-char specifies which character this is;
  38 ;;                      you can use a different character in different
  39 ;;                      Asm mode buffers.
  40 ;;      C-j, C-m        newline and tab to tab stop
  41 ;;
  42 ;; Code is indented to the first tab stop level.
  43
  44 ;; This mode runs two hooks:
  45 ;;   1) An asm-mode-set-comment-hook before the part of the initialization
  46 ;; depending on asm-comment-char, and
  47 ;;   2) an asm-mode-hook at the end of initialization.
  48
  49 ;;; Code:
  50
  51 (defgroup asm nil
  52   "Mode for editing assembler code."
  53   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  54   :group 'languages)
  55
  56 (defcustom asm-comment-char ?\;
  57   "*The comment-start character assumed by Asm mode."
  58   :type 'character
  59   :group 'asm)
  60
  61 (defvar asm-mode-syntax-table
  62   (let ((st (make-syntax-table)))
  63     (modify-syntax-entry ?\n "> b" st)
  64     (modify-syntax-entry ?/  ". 124b" st)
  65     (modify-syntax-entry ?*  ". 23" st)
  66     st)
  67   "Syntax table used while in Asm mode.")
  68
  69 (defvar asm-mode-abbrev-table nil
  70   "Abbrev table used while in Asm mode.")
  71 (define-abbrev-table 'asm-mode-abbrev-table ())
  72
  73 (defvar asm-mode-map
  74   (let ((map (make-sparse-keymap)))
  75     ;; Note that the comment character isn't set up until asm-mode is called.
  76     (define-key map ":"         'asm-colon)
  77     (define-key map "\C-c;"     'comment-region)
  78     (define-key map "\C-j"      'newline-and-indent)
  79     (define-key map "\C-m"      'newline-and-indent)
  80     (define-key map [menu-bar] (make-sparse-keymap))
  81     (define-key map [menu-bar asm-mode] (cons "Asm" map))
  82     (define-key map [comment-region]
  83       '(menu-item "Comment Region" comment-region
  84                   :help "Comment or uncomment each line in the region"))
  85     (define-key map [newline-and-indent]
  86       '(menu-item "Insert Newline and Indent" newline-and-indent
  87                   :help "Insert a newline, then indent according to major mode"))
  88     (define-key map [asm-colon]
  89       '(menu-item "Insert Colon" asm-colon
  90                   :help "Insert a colon; if it follows a label, delete the label's indentation"))
  91     map)
  92   "Keymap for Asm mode.")
  93
  94 (defconst asm-font-lock-keywords
  95   (append
  96    '(("^\\(\\(\\sw\\|\\s_\\)+\\)\\>:?[ \t]*\\(\\sw+\\(\\.\\sw+\\)*\\)?"
  97       (1 font-lock-function-name-face) (3 font-lock-keyword-face nil t))
  98      ;; label started from ".".
  99      ("^\\(\\.\\(\\sw\\|\\s_\\)+\\)\\>:"
 100       1 font-lock-function-name-face)
 101      ("^\\((\\sw+)\\)?\\s +\\(\\(\\.?\\sw\\|\\s_\\)+\\(\\.\\sw+\\)*\\)"
 102       2 font-lock-keyword-face)
 103      ;; directive started from ".".
 104      ("^\\(\\.\\(\\sw\\|\\s_\\)+\\)\\>[^:]?"
 105       1 font-lock-keyword-face)
 106      ;; %register
 107      ("%\\sw+" . font-lock-variable-name-face))
 108    cpp-font-lock-keywords)
 109   "Additional expressions to highlight in Assembler mode.")
 110
 111 ;;;###autoload
 112 (define-derived-mode asm-mode prog-mode "Assembler"
 113   "Major mode for editing typical assembler code.
 114 Features a private abbrev table and the following bindings:
 115
 116 \\[asm-colon]\toutdent a preceding label, tab to next tab stop.
 117 \\[tab-to-tab-stop]\ttab to next tab stop.
 118 \\[asm-newline]\tnewline, then tab to next tab stop.
 119 \\[asm-comment]\tsmart placement of assembler comments.
 120
 121 The character used for making comments is set by the variable
 122 `asm-comment-char' (which defaults to `?\\;').
 123
 124 Alternatively, you may set this variable in `asm-mode-set-comment-hook',
 125 which is called near the beginning of mode initialization.
 126
 127 Turning on Asm mode runs the hook `asm-mode-hook' at the end of initialization.
 128
 129 Special commands:
 130 \\{asm-mode-map}"
 131   (setq local-abbrev-table asm-mode-abbrev-table)
 132   (set (make-local-variable 'font-lock-defaults) '(asm-font-lock-keywords))
 133   (set (make-local-variable 'indent-line-function) 'asm-indent-line)
 134   ;; Stay closer to the old TAB behavior (was tab-to-tab-stop).
 135   (set (make-local-variable 'tab-always-indent) nil)
 136
 137   (run-hooks 'asm-mode-set-comment-hook)
 138   ;; Make our own local child of asm-mode-map
 139   ;; so we can define our own comment character.
 140   (use-local-map (nconc (make-sparse-keymap) asm-mode-map))
 141   (local-set-key (vector asm-comment-char) 'asm-comment)
 142   (set-syntax-table (make-syntax-table asm-mode-syntax-table))
 143   (modify-syntax-entry  asm-comment-char "< b")
 144
 145   (make-local-variable 'comment-start)
 146   (setq comment-start (string asm-comment-char))
 147   (make-local-variable 'comment-add)
 148   (setq comment-add 1)
 149   (make-local-variable 'comment-start-skip)
 150   (setq comment-start-skip "\\(?:\\s<+\\|/[/*]+\\)[ \t]*")
 151   (make-local-variable 'comment-end-skip)
 152   (setq comment-end-skip "[ \t]*\\(\\s>\\|\\*+/\\)")
 153   (make-local-variable 'comment-end)
 154   (setq comment-end "")
 155   (setq fill-prefix "\t"))
 156
 157 (defun asm-indent-line ()
 158   "Auto-indent the current line."
 159   (interactive)
 160   (let* ((savep (point))
 161          (indent (condition-case nil
 162                      (save-excursion
 163                        (forward-line 0)
 164                        (skip-chars-forward " \t")
 165                        (if (>= (point) savep) (setq savep nil))
 166                        (max (asm-calculate-indentation) 0))
 167                    (error 0))))
 168     (if savep
 169         (save-excursion (indent-line-to indent))
 170       (indent-line-to indent))))
 171
 172 (defun asm-calculate-indentation ()
 173   (or
 174    ;; Flush labels to the left margin.
 175    (and (looking-at "\\(\\sw\\|\\s_\\)+:") 0)
 176    ;; Same thing for `;;;' comments.
 177    (and (looking-at "\\s<\\s<\\s<") 0)
 178    ;; Simple `;' comments go to the comment-column.
 179    (and (looking-at "\\s<\\(\\S<\\|\\'\\)") comment-column)
 180    ;; The rest goes at the first tab stop.
 181    (or (car tab-stop-list) tab-width)))
 182
 183 (defun asm-colon ()
 184   "Insert a colon; if it follows a label, delete the label's indentation."
 185   (interactive)
 186   (let ((labelp nil))
 187     (save-excursion
 188       (skip-syntax-backward "w_")
 189       (skip-syntax-backward " ")
 190       (if (setq labelp (bolp)) (delete-horizontal-space)))
 191     (call-interactively 'self-insert-command)
 192     (when labelp
 193       (delete-horizontal-space)
 194       (tab-to-tab-stop))))
 195
 196 ;; Obsolete since Emacs-22.1.
 197 (defalias 'asm-newline 'newline-and-indent)
 198
 199 (defun asm-comment ()
 200   "Convert an empty comment to a `larger' kind, or start a new one.
 201 These are the known comment classes:
 202
 203    1 -- comment to the right of the code (at the comment-column)
 204    2 -- comment on its own line, indented like code
 205    3 -- comment on its own line, beginning at the left-most column.
 206
 207 Suggested usage:  while writing your code, trigger asm-comment
 208 repeatedly until you are satisfied with the kind of comment."
 209   (interactive)
 210   (comment-normalize-vars)
 211   (let (comempty comment)
 212     (save-excursion
 213       (beginning-of-line)
 214       (with-no-warnings
 215         (setq comment (comment-search-forward (line-end-position) t)))
 216       (setq comempty (looking-at "[ \t]*$")))
 217
 218   (cond
 219
 220    ;; Blank line?  Then start comment at code indent level.
 221    ;; Just like `comment-dwim'.  -stef
 222    ((save-excursion (beginning-of-line) (looking-at "^[ \t]*$"))
 223     (indent-according-to-mode)
 224     (insert asm-comment-char asm-comment-char ?\ ))
 225
 226    ;; Nonblank line w/o comment => start a comment at comment-column.
 227    ;; Also: point before the comment => jump inside.
 228    ((or (null comment) (< (point) comment))
 229     (indent-for-comment))
 230
 231    ;; Flush-left or non-empty comment present => just insert character.
 232    ((or (not comempty) (save-excursion (goto-char comment) (bolp)))
 233     (insert asm-comment-char))
 234
 235    ;; Empty code-level comment => upgrade to next comment level.
 236    ((save-excursion (goto-char comment) (skip-chars-backward " \t") (bolp))
 237     (goto-char comment)
 238     (insert asm-comment-char)
 239     (indent-for-comment))
 240
 241    ;; Empty comment ends non-empty code line => new comment above.
 242    (t
 243     (goto-char comment)
 244     (skip-chars-backward " \t")
 245     (delete-region (point) (line-end-position))
 246     (beginning-of-line) (insert "\n") (backward-char)
 247     (asm-comment)))))
 248
 249 (provide 'asm-mode)
 250
 251 ;; arch-tag: 210e695f-f338-4376-8913-a4c5c72ac848
 252 ;;; asm-mode.el ends here