lisp/find-cmd.el

   1 ;;; find-cmd.el --- Build a valid find(1) command with sexps
   2
   3 ;; Copyright (C) 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Philip Jackson <phil@shellarchive.co.uk>
   6 ;; Version: 0.6
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; With this module you can build up a (hopefully) valid find(1)
  28 ;; string ready for the command line. For example:
  29
  30 ;; (find-cmd '(prune (name ".svn" ".git" ".CVS"))
  31 ;;           '(and (or (name "*.pl" "*.pm" "*.t")
  32 ;;                     (mtime "+1"))
  33 ;;                 (fstype "nfs" "ufs"))))
  34
  35 ;; will become (un-wrapped):
  36
  37 ;;     "find '/home/phil/' \\( \\( -name '.svn' -or -name '.git' -or
  38 ;;      -name '.CVS' \\) -prune -or -true \\) \\( \\( \\( -name '*.pl'
  39 ;;      -or -name '*.pm' -or -name '*.t' \\) -or -mtime '+1' \\) -and \\(
  40 ;;      -fstype 'nfs' -or -fstype 'ufs' \\) \\)"
  41
  42 ;;; Code:
  43
  44 (defconst find-constituents
  45   '((and . find-and)
  46     (not . find-not)
  47     (or  . find-or)
  48
  49     (a . find-and)
  50     (n . find-not)
  51     (o . find-or)
  52
  53     (prune . find-prune)
  54
  55     ;; switches
  56     (L . (0))
  57     (P . (0))
  58     (H . (0))
  59
  60     ;; generic tests
  61     (amin       . (1))
  62     (anewer     . (1))
  63     (atime      . (1))
  64     (cmin       . (1))
  65     (cnewer     . (1))
  66     (ctime      . (1))
  67     (empty      . (0))
  68     (false      . (0))
  69     (fstype     . (1))
  70     (gid        . (1))
  71     (group      . (1))
  72     (ilname     . (1))
  73     (iname      . (1))
  74     (inum       . (1))
  75     (iwholename . (1))
  76     (iregex     . (1))
  77     (links      . (1))
  78     (lname      . (1))
  79     (mmin       . (1))
  80     (mtime      . (1))
  81     (name       . (1))
  82     (newer      . (1))
  83     (nouser     . (0))
  84     (nogroup    . (0))
  85     (path       . (1))
  86     (perm       . (0))
  87     (regex      . (1))
  88     (wholename  . (1))
  89     (size       . (1))
  90     (true       . (0))
  91     (type       . (1))
  92     (uid        . (1))
  93     (used       . (1))
  94     (user       . (1))
  95     (xtype      . (nil))
  96
  97     ;; normal options (always true)
  98     (depth                 . (0))
  99     (maxdepth              . (1))
 100     (mindepth              . (1))
 101     (mount                 . (0))
 102     (noleaf                . (0))
 103     (xdev                  . (0))
 104     (ignore_readdir_race   . (0))
 105     (noignore_readdir_race . (0))
 106
 107     ;; actions
 108     (delete  . (0))
 109     (print0  . (0))
 110     (printf  . (1))
 111     (fprintf . (2))
 112     (print   . (0))
 113     (fprint0 . (1))
 114     (fprint  . (1))
 115     (ls      . (0))
 116     (fls     . (1))
 117     (prune   . (0))
 118     (quit    . (0))
 119
 120     ;; these need to be terminated with a ;
 121     (exec    . (1 find-command t))
 122     (ok      . (1 find-command t))
 123     (execdir . (1 find-command t))
 124     (okdir   . (1 find-command t)))
 125   "Holds details of each of the find options. The car of each
 126 alist is the name. The cdr is minimum args, the function used
 127 to join many occurences of the argument together, and whether or
 128 not to leave quotes off the string (non-nil means the string will
 129 be quoted).")
 130
 131 ;;;###autoload
 132 (defun find-cmd (&rest subfinds)
 133   "Initiate the building of a find command. For exmple:
 134
 135 \(find-cmd '\(prune \(name \".svn\" \".git\" \".CVS\"\)\)
 136           '\(and \(or \(name \"*.pl\" \"*.pm\" \"*.t\"\)
 137                     \(mtime \"+1\"\)\)
 138                 \(fstype \"nfs\" \"ufs\"\)\)\)\)
 139
 140 `default-directory' is used as the initial search path. The
 141 result is a string that should be ready for the command line."
 142   (concat
 143    "find " (shell-quote-argument (expand-file-name default-directory)) " "
 144            (cond
 145             ((cdr subfinds)
 146              (mapconcat 'find-to-string subfinds ""))
 147             (t
 148              (find-to-string (car subfinds))))))
 149
 150 (defun find-and (form)
 151   "And FORMs together, so:
 152   \(and \(mtime \"+1\"\) \(name \"something\"\)\)
 153 will produce:
 154   find . \\\( -mtime '+1' -and -name 'something' \\\)"
 155   (if (< (length form) 2)
 156       (find-to-string (car form))
 157       (concat "\\( "
 158               (mapconcat 'find-to-string form "-and ")
 159               "\\) ")))
 160
 161 (defun find-or (form)
 162   "Or FORMs together, so:
 163   \(or \(mtime \"+1\"\) \(name \"something\"\)\)
 164 will produce:
 165   find . \\\( -mtime '+1' -or -name 'something' \\\)"
 166   (if (< (length form) 2)
 167       (find-to-string (car form))
 168       (concat "\\( "
 169               (mapconcat 'find-to-string form "-or ")
 170               "\\) ")))
 171
 172 (defun find-not (form)
 173   "Or FORMs together and prefix with a -not, so:
 174   \(not \(mtime \"+1\"\) \(name \"something\"\)\)
 175 will produce:
 176   -not \\\( -mtime '+1' -or -name 'something' \\\)
 177 If you wanted the FORMs -and(ed) together instead then this would
 178 suffice:
 179   \(not \(and \(mtime \"+1\"\) \(name \"something\"\)\)\)"
 180   (concat "-not " (find-or (mapcar 'find-to-string form))))
 181
 182 (defun find-prune (form)
 183   "-or together FORM(s) postfix '-prune' and then -or that with a
 184 -true, so:
 185   \(prune \(name \".svn\" \".git\"\)\) \(name \"*.pm\"\)
 186 will produce (unwrapped):
 187   \\\( \\\( \\\( -name '.svn' -or -name '.git' \\\) /
 188   -prune -or -true \\\) -and -name '*.pm' \\\)"
 189   (find-or
 190    (list
 191     (concat (find-or (mapcar 'find-to-string form)) (find-generic "prune"))
 192     (find-generic "true"))))
 193
 194 (defun find-generic (option &optional oper argcount args dont-quote)
 195   "This function allows an arbitrary string to be used as a
 196 form. OPTION is the name of the form, OPER is the function used
 197 to either OR or AND multiple results together. ARGCOUNT is the
 198 minimum of args that OPTION can receive and ARGS are the
 199 arguments for OPTION."
 200   (when (and (numberp argcount) (< (length args) argcount))
 201     (error "'%s' needs at least %d arguments" option argcount))
 202   (let ((oper (or oper 'find-or)))
 203     (if (and args (length args))
 204         (funcall oper (mapcar (lambda (x)
 205                                 (concat "-" option
 206                                         (if dont-quote
 207                                             (concat " " x " ")
 208                                             (concat " "
 209                                                     (shell-quote-argument x)
 210                                                     " "))))
 211                               args))
 212         (concat "-" option " "))))
 213
 214 (defun find-command (form)
 215   "For each item in FORM add a terminating semi-colon and turn
 216 them into valid switches. The result is -and(ed) together."
 217   (find-and (mapcar (lambda (x)
 218                       (concat (find-to-string x) "\\; "))
 219                     form)))
 220
 221 (defun find-to-string (form)
 222   "Parse FORM to produce a set of valid find arguments."
 223   (cond
 224     ((stringp form)
 225      form)
 226     ((consp form)
 227      (let ((option (cdr (assoc (car form) find-constituents))))
 228        (cond
 229          ((and (symbolp option) (fboundp option))
 230           (funcall option (cdr form)))
 231          ((consp option)
 232           (let ((option (symbol-name (car form)))
 233                 (argcnt (car option))
 234                 (oper (cadr option))
 235                 (dont-quote (car (cddr option))))
 236             (find-to-string
 237              (find-generic option oper argcnt (cdr form) dont-quote))))
 238          (t
 239           (error "Sorry I don't know how to handle '%s'" (car form))))))))
 240
 241 (provide 'find-cmd)
 242
 243 ;; arch-tag: 9687fd9e-4e90-4022-864a-f904526e2046
 244 ;;; find-cmd.el ends here