lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 1995, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: wp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package is a major mode for editing nroff source code.  It knows
  29 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  30 ;; and indent paragraphs properly in their presence.  It also includes
  31 ;; a command to count text lines (excluding nroff constructs), a command
  32 ;; to center a line, and movement commands that know how to skip macros.
  33
  34 ;; Paragraph filling and line-counting currently don't respect comments,
  35 ;; as they should.
  36
  37 ;;; Code:
  38
  39 (defgroup nroff nil
  40   "Nroff mode."
  41   :group 'wp
  42   :prefix "nroff-")
  43
  44 (defcustom nroff-electric-mode nil
  45   "*Non-nil means automatically closing requests when you insert an open."
  46   :group 'nroff
  47   :type 'boolean)
  48
  49 (defvar nroff-mode-map
  50   (let ((map (make-sparse-keymap)))
  51     (define-key map "\t"  'tab-to-tab-stop)
  52     (define-key map "\es" 'center-line)
  53     (define-key map "\e?" 'count-text-lines)
  54     (define-key map "\n"  'electric-nroff-newline)
  55     (define-key map "\en" 'forward-text-line)
  56     (define-key map "\ep" 'backward-text-line)
  57     map)
  58   "Major mode keymap for `nroff-mode'.")
  59
  60 (defvar nroff-mode-syntax-table
  61   (let ((st (copy-syntax-table text-mode-syntax-table)))
  62     ;; " isn't given string quote syntax in text-mode but it
  63     ;; (arguably) should be for use round nroff arguments (with ` and
  64     ;; ' used otherwise).
  65     (modify-syntax-entry ?\" "\"  2" st)
  66     ;; Comments are delimited by \" and newline.
  67     (modify-syntax-entry ?\\ "\\  1" st)
  68     (modify-syntax-entry ?\n ">  1" st)
  69     st)
  70   "Syntax table used while in `nroff-mode'.")
  71
  72 (defvar nroff-imenu-expression
  73   ;; man headers:
  74   '((nil "^\\.SH \"?\\([^\"\n]*\\)\"?$" 1)))
  75
  76 (defcustom nroff-font-lock-keywords
  77   (list
  78    ;; Directives are . or ' at start of line, followed by
  79    ;; optional whitespace, then command (which my be longer than
  80    ;; 2 characters in groff).  Perhaps the arguments should be
  81    ;; fontified as well.
  82    "^[.']\\s-*\\sw+"
  83    ;; There are numerous groff escapes; the following get things
  84    ;; like \-, \(em (standard troff) and \f[bar] (groff
  85    ;; variants).  This won't currently do groff's \A'foo' and
  86    ;; the like properly.  One might expect it to highlight an escape's
  87    ;; arguments in common cases, like \f.
  88    (concat "\\\\"                     ; backslash
  89          "\\("                        ; followed by various possibilities
  90          (mapconcat 'identity
  91                     '("[f*n]*\\[.+]"  ; some groff extensions
  92                       "(.."           ; two chars after (
  93                       "[^(\"]"        ; single char escape
  94                       ) "\\|")
  95          "\\)")
  96    )
  97   "Font-lock highlighting control in `nroff-mode'."
  98   :group 'nroff
  99   :type '(repeat regexp))
 100
 101 (defcustom nroff-mode-hook nil
 102   "Hook run by function `nroff-mode'."
 103   :type 'hook
 104   :group 'nroff)
 105
 106 ;;;###autoload
 107 (define-derived-mode nroff-mode text-mode "Nroff"
 108   "Major mode for editing text intended for nroff to format.
 109 \\{nroff-mode-map}
 110 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
 111 Also, try `nroff-electric-mode', for automatically inserting
 112 closing requests for requests that are used in matched pairs."
 113   (set (make-local-variable 'font-lock-defaults)
 114        ;; SYNTAX-BEGIN is set to backward-paragraph to avoid slow-down
 115        ;; near the end of large buffers due to searching to buffer's
 116        ;; beginning.
 117        '(nroff-font-lock-keywords nil t nil backward-paragraph))
 118   (set (make-local-variable 'nroff-electric-mode) nil)
 119   (set (make-local-variable 'outline-regexp) "\\.H[ ]+[1-7]+ ")
 120   (set (make-local-variable 'outline-level) 'nroff-outline-level)
 121   ;; now define a bunch of variables for use by commands in this mode
 122   (set (make-local-variable 'page-delimiter) "^\\.\\(bp\\|SK\\|OP\\)")
 123   (set (make-local-variable 'paragraph-start)
 124        (concat "[.']\\|" paragraph-start))
 125   (set (make-local-variable 'paragraph-separate)
 126        (concat "[.']\\|" paragraph-separate))
 127   ;; comment syntax added by mit-erl!gildea 18 Apr 86
 128   (set (make-local-variable 'comment-start) "\\\" ")
 129   (set (make-local-variable 'comment-start-skip) "\\\\\"[ \t]*")
 130   (set (make-local-variable 'comment-column) 24)
 131   (set (make-local-variable 'comment-indent-function) 'nroff-comment-indent)
 132   (set (make-local-variable 'imenu-generic-expression) nroff-imenu-expression))
 133
 134 (defun nroff-outline-level ()
 135   (save-excursion
 136     (looking-at outline-regexp)
 137     (skip-chars-forward ".H ")
 138     (string-to-number (buffer-substring (point) (+ 1 (point))))))
 139
 140 ;;; Compute how much to indent a comment in nroff/troff source.
 141 ;;; By mit-erl!gildea April 86
 142 (defun nroff-comment-indent ()
 143   "Compute indent for an nroff/troff comment.
 144 Puts a full-stop before comments on a line by themselves."
 145   (let ((pt (point)))
 146     (unwind-protect
 147         (progn
 148           (skip-chars-backward " \t")
 149           (if (bolp)
 150               (progn
 151                 (setq pt (1+ pt))
 152                 (insert ?.)
 153                 1)
 154             (if (save-excursion
 155                   (backward-char 1)
 156                   (looking-at "^[.']"))
 157                 1
 158               (max comment-column
 159                    (* 8 (/ (+ (current-column)
 160                               9) 8)))))) ; add 9 to ensure at least two blanks
 161       (goto-char pt))))
 162
 163 (defun count-text-lines (start end &optional print)
 164   "Count lines in region, except for nroff request lines.
 165 All lines not starting with a period are counted up.
 166 Interactively, print result in echo area.
 167 Noninteractively, return number of non-request lines from START to END."
 168   (interactive "r\np")
 169   (if print
 170       (message "Region has %d text lines" (count-text-lines start end))
 171     (save-excursion
 172       (save-restriction
 173         (narrow-to-region start end)
 174         (goto-char (point-min))
 175         (- (buffer-size) (forward-text-line (buffer-size)))))))
 176
 177 (defun forward-text-line (&optional cnt)
 178   "Go forward one nroff text line, skipping lines of nroff requests.
 179 An argument is a repeat count; if negative, move backward."
 180   (interactive "p")
 181   (if (not cnt) (setq cnt 1))
 182   (while (and (> cnt 0) (not (eobp)))
 183     (forward-line 1)
 184     (while (and (not (eobp)) (looking-at "[.']."))
 185       (forward-line 1))
 186     (setq cnt (- cnt 1)))
 187   (while (and (< cnt 0) (not (bobp)))
 188     (forward-line -1)
 189     (while (and (not (bobp))
 190                 (looking-at "[.']."))
 191       (forward-line -1))
 192     (setq cnt (+ cnt 1)))
 193   cnt)
 194
 195 (defun backward-text-line (&optional cnt)
 196   "Go backward one nroff text line, skipping lines of nroff requests.
 197 An argument is a repeat count; negative means move forward."
 198   (interactive "p")
 199   (forward-text-line (- cnt)))
 200
 201 (defconst nroff-brace-table
 202   '((".(b" . ".)b")
 203     (".(l" . ".)l")
 204     (".(q" . ".)q")
 205     (".(c" . ".)c")
 206     (".(x" . ".)x")
 207     (".(z" . ".)z")
 208     (".(d" . ".)d")
 209     (".(f" . ".)f")
 210     (".LG" . ".NL")
 211     (".SM" . ".NL")
 212     (".LD" . ".DE")
 213     (".CD" . ".DE")
 214     (".BD" . ".DE")
 215     (".DS" . ".DE")
 216     (".DF" . ".DE")
 217     (".FS" . ".FE")
 218     (".KS" . ".KE")
 219     (".KF" . ".KE")
 220     (".LB" . ".LE")
 221     (".AL" . ".LE")
 222     (".BL" . ".LE")
 223     (".DL" . ".LE")
 224     (".ML" . ".LE")
 225     (".RL" . ".LE")
 226     (".VL" . ".LE")
 227     (".RS" . ".RE")
 228     (".TS" . ".TE")
 229     (".EQ" . ".EN")
 230     (".PS" . ".PE")
 231     (".BS" . ".BE")
 232     (".G1" . ".G2")                     ; grap
 233     (".na" . ".ad b")
 234     (".nf" . ".fi")
 235     (".de" . "..")))
 236
 237 (defun electric-nroff-newline (arg)
 238   "Insert newline for nroff mode; special if electric-nroff mode.
 239 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 240 automatically inserts the matching closing request after point."
 241   (interactive "P")
 242   (let ((completion (save-excursion
 243                       (beginning-of-line)
 244                       (and (null arg)
 245                            nroff-electric-mode
 246                            (<= (point) (- (point-max) 3))
 247                            (cdr (assoc (buffer-substring (point)
 248                                                          (+ 3 (point)))
 249                                        nroff-brace-table)))))
 250         (needs-nl (not (looking-at "[ \t]*$"))))
 251     (if (null completion)
 252         (newline (prefix-numeric-value arg))
 253       (save-excursion
 254         (insert "\n\n" completion)
 255         (if needs-nl (insert "\n")))
 256       (forward-char 1))))
 257
 258 (defun electric-nroff-mode (&optional arg)
 259   "Toggle `nroff-electric-newline' minor mode.
 260 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 261 beginning of the line, and insert the matching closing request if necessary.
 262 This command toggles that mode (off->on, on->off), with an argument,
 263 turns it on iff arg is positive, otherwise off."
 264   (interactive "P")
 265   (or (eq major-mode 'nroff-mode) (error "Must be in nroff mode"))
 266   (or (assq 'nroff-electric-mode minor-mode-alist)
 267       (setq minor-mode-alist (append minor-mode-alist
 268                                      (list '(nroff-electric-mode
 269                                              " Electric")))))
 270   (setq nroff-electric-mode
 271         (cond ((null arg) (null nroff-electric-mode))
 272               (t (> (prefix-numeric-value arg) 0)))))
 273
 274 (provide 'nroff-mode)
 275
 276 ;;; arch-tag: 6e276340-6c65-4f65-b4e3-0ca431ddfb6c
 277 ;;; nroff-mode.el ends here