lisp/vc/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;;         Riccardo Murri <riccardo.murri@gmail.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: vc tools
   9 ;; Created: Sept 2006
  10 ;; Package: vc
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar.canonical.com/> concerning bzr.
  30
  31 ;; This library provides bzr support in VC.
  32
  33 ;; Known bugs
  34 ;; ==========
  35
  36 ;; When editing a symlink and *both* the symlink and its target
  37 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  38 ;; symlink, thereby not detecting whether the actual contents
  39 ;; (that is, the target contents) are changed.
  40 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  41
  42 ;;; Properties of the backend
  43
  44 (defun vc-bzr-revision-granularity () 'repository)
  45 (defun vc-bzr-checkout-model (files) 'implicit)
  46
  47 ;;; Code:
  48
  49 (eval-when-compile
  50   (require 'cl)
  51   (require 'vc)  ;; for vc-exec-after
  52   (require 'vc-dir))
  53
  54 ;; Clear up the cache to force vc-call to check again and discover
  55 ;; new functions when we reload this file.
  56 (put 'Bzr 'vc-functions nil)
  57
  58 (defgroup vc-bzr nil
  59   "VC bzr backend."
  60   :version "22.2"
  61   :group 'vc)
  62
  63 (defcustom vc-bzr-program "bzr"
  64   "Name of the bzr command (excluding any arguments)."
  65   :group 'vc-bzr
  66   :type 'string)
  67
  68 (defcustom vc-bzr-sha1-program '("sha1sum")
  69   "Name of program to compute SHA1.
  70 It must be a string \(program name\) or list of strings \(name and its args\)."
  71   :type '(repeat string)
  72   :group 'vc-bzr)
  73
  74 (define-obsolete-variable-alias 'sha1-program 'vc-bzr-sha1-program "24.1")
  75
  76 (defcustom vc-bzr-diff-switches nil
  77   "String or list of strings specifying switches for bzr diff under VC.
  78 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  79   :type '(choice (const :tag "Unspecified" nil)
  80                  (const :tag "None" t)
  81                  (string :tag "Argument String")
  82                  (repeat :tag "Argument List" :value ("") string))
  83   :group 'vc-bzr)
  84
  85 (defcustom vc-bzr-log-switches nil
  86   "String or list of strings specifying switches for bzr log under VC."
  87   :type '(choice (const :tag "None" nil)
  88                  (string :tag "Argument String")
  89                  (repeat :tag "Argument List" :value ("") string))
  90   :group 'vc-bzr)
  91
  92 ;; since v0.9, bzr supports removing the progress indicators
  93 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  94 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  95   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  96 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  97 `LC_MESSAGES=C' to the environment."
  98   (let ((process-environment
  99          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
 100                 "LC_MESSAGES=C"         ; Force English output
 101                 process-environment)))
 102     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
 103            file-or-list bzr-command args)))
 104
 105 (defun vc-bzr-async-command (bzr-command &rest args)
 106   "Wrapper round `vc-do-async-command' using `vc-bzr-program' as COMMAND.
 107 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
 108 `LC_MESSAGES=C' to the environment.
 109 Use the current Bzr root directory as the ROOT argument to
 110 `vc-do-async-command', and specify an output buffer named
 111 \"*vc-bzr : ROOT*\".  Return this buffer."
 112   (let* ((process-environment
 113           (list* "BZR_PROGRESS_BAR=none" "LC_MESSAGES=C"
 114                  process-environment))
 115          (root (vc-bzr-root default-directory))
 116          (buffer (format "*vc-bzr : %s*" (expand-file-name root))))
 117     (apply 'vc-do-async-command buffer root
 118            vc-bzr-program bzr-command args)
 119     buffer))
 120
 121 ;;;###autoload
 122 (defconst vc-bzr-admin-dirname ".bzr"
 123   "Name of the directory containing Bzr repository status files.")
 124 ;; Used in the autoloaded vc-bzr-registered; see below.
 125 ;;;###autoload
 126 (defconst vc-bzr-admin-checkout-format-file
 127   (concat vc-bzr-admin-dirname "/checkout/format"))
 128 (defconst vc-bzr-admin-dirstate
 129   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 130 (defconst vc-bzr-admin-branch-format-file
 131   (concat vc-bzr-admin-dirname "/branch/format"))
 132 (defconst vc-bzr-admin-revhistory
 133   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 134 (defconst vc-bzr-admin-lastrev
 135   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 136 (defconst vc-bzr-admin-branchconf
 137   (concat vc-bzr-admin-dirname "/branch/branch.conf"))
 138
 139 ;;;###autoload (defun vc-bzr-registered (file)
 140 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 141 ;;;###autoload       (progn
 142 ;;;###autoload         (load "vc-bzr")
 143 ;;;###autoload         (vc-bzr-registered file))))
 144
 145 (defun vc-bzr-root (file)
 146   "Return the root directory of the bzr repository containing FILE."
 147   ;; Cache technique copied from vc-arch.el.
 148   (or (vc-file-getprop file 'bzr-root)
 149       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 150         (when root (vc-file-setprop file 'bzr-root root)))))
 151
 152 (defun vc-bzr-branch-conf (file)
 153   "Return the Bazaar branch settings for file FILE, as an alist.
 154 Each element of the returned alist has the form (NAME . VALUE),
 155 which are the name and value of a Bazaar setting, as strings.
 156
 157 The settings are read from the file \".bzr/branch/branch.conf\"
 158 in the repository root directory of FILE."
 159   (let (settings)
 160     (with-temp-buffer
 161       (insert-file-contents
 162        (expand-file-name vc-bzr-admin-branchconf (vc-bzr-root file)))
 163       (while (re-search-forward "^\\([^#=][^=]*?\\) *= *\\(.*\\)$" nil t)
 164         (push (cons (match-string 1) (match-string 2)) settings)))
 165     settings))
 166
 167 (defun vc-bzr-sha1 (file)
 168   (with-temp-buffer
 169     (set-buffer-multibyte nil)
 170     (let ((prog vc-bzr-sha1-program)
 171           (args nil)
 172           process-file-side-effects)
 173       (when (consp prog)
 174         (setq args (cdr prog))
 175         (setq prog (car prog)))
 176       (apply 'process-file prog (file-relative-name file) t nil args)
 177       (buffer-substring (point-min) (+ (point-min) 40)))))
 178
 179 (defun vc-bzr-state-heuristic (file)
 180   "Like `vc-bzr-state' but hopefully without running Bzr."
 181   ;; `bzr status' was excruciatingly slow with large histories and
 182   ;; pending merges, so try to avoid using it until they fix their
 183   ;; performance problems.
 184   ;; This function tries first to parse Bzr internal file
 185   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 186   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 187   ;; only parsed if it contains the string `#bazaar dirstate flat
 188   ;; format 3' in the first line.
 189   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 190   ;; running `vc-bzr-state'."
 191   ;;
 192   ;; The format of the dirstate file is explained in bzrlib/dirstate.py
 193   ;; in the bzr distribution.  Basically:
 194   ;; header-line giving the version of the file format in use.
 195   ;; a few lines of stuff
 196   ;; entries, one per line, with null-separated fields.  Each line:
 197   ;; entry_key = dirname (may be empty), basename, file-id
 198   ;; current = common ( = kind, fingerprint, size, executable )
 199   ;;           + working ( = packed_stat )
 200   ;; parent = common ( as above ) + history ( = rev_id )
 201   ;; kinds = (r)elocated, (a)bsent, (d)irectory, (f)ile, (l)ink
 202   (lexical-let ((root (vc-bzr-root file)))
 203     (when root    ; Short cut.
 204       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 205         (condition-case nil
 206             (with-temp-buffer
 207               (insert-file-contents dirstate)
 208               (goto-char (point-min))
 209               (if (not (looking-at "#bazaar dirstate flat format 3"))
 210                   (vc-bzr-state file)   ; Some other unknown format?
 211                 (let* ((relfile (file-relative-name file root))
 212                        (reldir (file-name-directory relfile)))
 213                   (if (re-search-forward
 214                        (concat "^\0"
 215                                (if reldir (regexp-quote
 216                                            (directory-file-name reldir)))
 217                                "\0"
 218                                (regexp-quote (file-name-nondirectory relfile))
 219                                "\0"
 220                                "[^\0]*\0"     ;id?
 221                                "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 222                                "\\([^\0]*\\)\0" ;sha1 (empty if conflicted)?
 223                                "\\([^\0]*\\)\0" ;size?p
 224                                ;; y/n.  Whether or not the current copy
 225                                ;; was executable the last time bzr checked?
 226                                "[^\0]*\0"
 227                                "[^\0]*\0"       ;?
 228                                ;; Parent information.  Absent in a new repo.
 229                                "\\(?:\\([^\0]*\\)\0" ;"a/f/d" a=added?
 230                                "\\([^\0]*\\)\0" ;sha1 again?
 231                                "\\([^\0]*\\)\0" ;size again?
 232                                ;; y/n.  Whether or not the repo thinks
 233                                ;; the file should be executable?
 234                                "\\([^\0]*\\)\0"
 235                                "[^\0]*\0\\)?" ;last revid?
 236                                ;; There are more fields when merges are pending.
 237                                )
 238                        nil t)
 239                       ;; Apparently the second sha1 is the one we want: when
 240                       ;; there's a conflict, the first sha1 is absent (and the
 241                       ;; first size seems to correspond to the file with
 242                       ;; conflict markers).
 243                       (cond
 244                        ((eq (char-after (match-beginning 1)) ?a) 'removed)
 245                        ;; If there is no parent, this must be a new repo.
 246                        ;; If file is in dirstate, can only be added (b#8025).
 247                        ((or (not (match-beginning 4))
 248                             (eq (char-after (match-beginning 4)) ?a)) 'added)
 249                        ((or (and (eq (string-to-number (match-string 3))
 250                                  (nth 7 (file-attributes file)))
 251                                  (equal (match-string 5)
 252                                         (vc-bzr-sha1 file))
 253                                  ;; For a file, does the executable state match?
 254                                  ;; (Bug#7544)
 255                                  (or (not
 256                                       (eq (char-after (match-beginning 1)) ?f))
 257                                      (let ((exe
 258                                             (memq
 259                                              ?x
 260                                              (mapcar
 261                                               'identity
 262                                               (nth 8 (file-attributes file))))))
 263                                        (if (eq (char-after (match-beginning 7))
 264                                                ?y)
 265                                            exe
 266                                          (not exe)))))
 267                             (and
 268                              ;; It looks like for lightweight
 269                              ;; checkouts \2 is empty and we need to
 270                              ;; look for size in \6.
 271                              (eq (match-beginning 2) (match-end 2))
 272                              (eq (string-to-number (match-string 6))
 273                                  (nth 7 (file-attributes file)))
 274                              (equal (match-string 5)
 275                                     (vc-bzr-sha1 file))))
 276                         'up-to-date)
 277                        (t 'edited))
 278                     'unregistered))))
 279           ;; Either the dirstate file can't be read, or the sha1
 280           ;; executable is missing, or ...
 281           ;; In either case, recent versions of Bzr aren't that slow
 282           ;; any more.
 283           (error (vc-bzr-state file)))))))
 284
 285
 286 (defun vc-bzr-registered (file)
 287   "Return non-nil if FILE is registered with bzr."
 288   (let ((state (vc-bzr-state-heuristic file)))
 289     (not (memq state '(nil unregistered ignored)))))
 290
 291 (defconst vc-bzr-state-words
 292   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 293   "Regexp matching file status words as reported in `bzr' output.")
 294
 295 ;; History of Bzr commands.
 296 (defvar vc-bzr-history nil)
 297
 298 (defun vc-bzr-file-name-relative (filename)
 299   "Return file name FILENAME stripped of the initial Bzr repository path."
 300   (lexical-let*
 301       ((filename* (expand-file-name filename))
 302        (rootdir (vc-bzr-root filename*)))
 303     (when rootdir
 304          (file-relative-name filename* rootdir))))
 305
 306 (defvar vc-bzr-error-regex-alist
 307   '(("^\\( M[* ]\\|+N \\|-D \\|\\|  \\*\\|R[M ] \\) \\(.+\\)" 2 nil nil 1)
 308     ("^C  \\(.+\\)" 2)
 309     ("^Text conflict in \\(.+\\)" 1 nil nil 2)
 310     ("^Using saved parent location: \\(.+\\)" 1 nil nil 0))
 311   "Value of `compilation-error-regexp-alist' in *vc-bzr* buffers.")
 312
 313 (defun vc-bzr-pull (prompt)
 314   "Pull changes into the current Bzr branch.
 315 Normally, this runs \"bzr pull\".  However, if the branch is a
 316 bound branch, run \"bzr update\" instead.  If there is no default
 317 location from which to pull or update, or if PROMPT is non-nil,
 318 prompt for the Bzr command to run."
 319   (let* ((vc-bzr-program vc-bzr-program)
 320          (branch-conf (vc-bzr-branch-conf default-directory))
 321          ;; Check whether the branch is bound.
 322          (bound (assoc "bound" branch-conf))
 323          (bound (and bound (equal "true" (downcase (cdr bound)))))
 324          ;; If we need to do a "bzr pull", check for a parent.  If it
 325          ;; does not exist, bzr will need a pull location.
 326          (has-parent (unless bound
 327                        (assoc "parent_location" branch-conf)))
 328          (command (if bound "update" "pull"))
 329          args)
 330     ;; If necessary, prompt for the exact command.
 331     (when (or prompt (not (or bound has-parent)))
 332       (setq args (split-string
 333                   (read-shell-command
 334                    "Bzr pull command: "
 335                    (concat vc-bzr-program " " command)
 336                    'vc-bzr-history)
 337                   " " t))
 338       (setq vc-bzr-program (car  args)
 339             command        (cadr args)
 340             args           (cddr args)))
 341     (let ((buf (apply 'vc-bzr-async-command command args)))
 342       (with-current-buffer buf
 343         (vc-exec-after
 344          `(progn
 345             (let ((compilation-error-regexp-alist
 346                    vc-bzr-error-regex-alist))
 347               (compilation-mode))
 348             (set (make-local-variable 'compilation-error-regexp-alist)
 349                  vc-bzr-error-regex-alist))))
 350       (vc-set-async-update buf))))
 351
 352 (defun vc-bzr-merge-branch ()
 353   "Merge another Bzr branch into the current one.
 354 Prompt for the Bzr command to run, providing a pre-defined merge
 355 source (an upstream branch or a previous merge source) as a
 356 default if it is available."
 357   (let* ((branch-conf (vc-bzr-branch-conf default-directory))
 358          ;; "bzr merge" without an argument defaults to submit_branch,
 359          ;; then parent_location.  Extract the specific location and
 360          ;; add it explicitly to the command line.
 361          (setting nil)
 362          (location
 363           (cond
 364            ((setq setting (assoc "submit_branch" branch-conf))
 365             (cdr setting))
 366            ((setq setting (assoc "parent_location" branch-conf))
 367             (cdr setting))))
 368          (cmd
 369           (split-string
 370            (read-shell-command
 371             "Bzr merge command: "
 372             (concat vc-bzr-program " merge --pull"
 373                     (if location (concat " " location) ""))
 374             'vc-bzr-history)
 375            " " t))
 376          (vc-bzr-program (car  cmd))
 377          (command        (cadr cmd))
 378          (args           (cddr cmd)))
 379     (let ((buf (apply 'vc-bzr-async-command command args)))
 380       (with-current-buffer buf
 381         (vc-exec-after
 382          `(progn
 383             (let ((compilation-error-regexp-alist
 384                    vc-bzr-error-regex-alist))
 385               (compilation-mode))
 386             (set (make-local-variable 'compilation-error-regexp-alist)
 387                  vc-bzr-error-regex-alist))))
 388       (vc-set-async-update buf))))
 389
 390 (defun vc-bzr-status (file)
 391   "Return FILE status according to Bzr.
 392 Return value is a cons (STATUS . WARNING), where WARNING is a
 393 string or nil, and STATUS is one of the symbols: `added',
 394 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 395 which directly correspond to `bzr status' output, or 'unchanged
 396 for files whose copy in the working tree is identical to the one
 397 in the branch repository, or nil for files that are not
 398 registered with Bzr.
 399
 400 If any error occurred in running `bzr status', then return nil."
 401   (with-temp-buffer
 402     (let ((ret (condition-case nil
 403                    (vc-bzr-command "status" t 0 file)
 404                  (file-error nil)))     ; vc-bzr-program not found.
 405           (status 'unchanged))
 406           ;; the only secure status indication in `bzr status' output
 407           ;; is a couple of lines following the pattern::
 408           ;;   | <status>:
 409           ;;   |   <file name>
 410           ;; if the file is up-to-date, we get no status report from `bzr',
 411           ;; so if the regexp search for the above pattern fails, we consider
 412           ;; the file to be up-to-date.
 413           (goto-char (point-min))
 414           (when (re-search-forward
 415                  ;; bzr prints paths relative to the repository root.
 416                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 417                          (regexp-quote (vc-bzr-file-name-relative file))
 418                          ;; Bzr appends a '/' to directory names and
 419                          ;; '*' to executable files
 420                          (if (file-directory-p file) "/?" "\\*?")
 421                          "[ \t\n]*$")
 422                  nil t)
 423             (lexical-let ((statusword (match-string 1)))
 424               ;; Erase the status text that matched.
 425               (delete-region (match-beginning 0) (match-end 0))
 426               (setq status
 427                     (intern (replace-regexp-in-string " " "" statusword)))))
 428           (when status
 429             (goto-char (point-min))
 430             (skip-chars-forward " \n\t") ;Throw away spaces.
 431             (cons status
 432                   ;; "bzr" will output warnings and informational messages to
 433                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 434                   ;; `start-process' itself) limitations, we cannot catch stderr
 435                   ;; and stdout into different buffers.  So, if there's anything
 436                   ;; left in the buffer after removing the above status
 437                   ;; keywords, let us just presume that any other message from
 438                   ;; "bzr" is a user warning, and display it.
 439                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 440
 441 (defun vc-bzr-state (file)
 442   (lexical-let ((result (vc-bzr-status file)))
 443     (when (consp result)
 444       (let ((warnings (cdr result)))
 445         (when warnings
 446           ;; bzr 2.3.0 returns info about shelves, which is not really a warning
 447           (when (string-match "[1-9]+ shel\\(f\\|ves\\) exists?\\..*?\n" warnings)
 448             (setq warnings (replace-match "" nil nil warnings)))
 449           (unless (string= warnings "")
 450             (message "Warnings in `bzr' output: %s" warnings))))
 451       (cdr (assq (car result)
 452                  '((added . added)
 453                    (kindchanged . edited)
 454                    (renamed . edited)
 455                    (modified . edited)
 456                    (removed . removed)
 457                    (ignored . ignored)
 458                    (unknown . unregistered)
 459                    (unchanged . up-to-date)))))))
 460
 461 (defun vc-bzr-resolve-when-done ()
 462   "Call \"bzr resolve\" if the conflict markers have been removed."
 463   (save-excursion
 464     (goto-char (point-min))
 465     (unless (re-search-forward "^<<<<<<< " nil t)
 466       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 467       ;; Remove the hook so that it is not called multiple times.
 468       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 469
 470 (defun vc-bzr-find-file-hook ()
 471   (when (and buffer-file-name
 472              ;; FIXME: We should check that "bzr status" says "conflict".
 473              (file-exists-p (concat buffer-file-name ".BASE"))
 474              (file-exists-p (concat buffer-file-name ".OTHER"))
 475              (file-exists-p (concat buffer-file-name ".THIS"))
 476              ;; If "bzr status" says there's a conflict but there are no
 477              ;; conflict markers, it's not clear what we should do.
 478              (save-excursion
 479                (goto-char (point-min))
 480                (re-search-forward "^<<<<<<< " nil t)))
 481     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 482     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 483     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 484     (smerge-start-session)
 485     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 486     (message "There are unresolved conflicts in this file")))
 487
 488 (defun vc-bzr-workfile-unchanged-p (file)
 489   (eq 'unchanged (car (vc-bzr-status file))))
 490
 491 (defun vc-bzr-working-revision (file)
 492   ;; Together with the code in vc-state-heuristic, this makes it possible
 493   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 494   (lexical-let*
 495       ((rootdir (vc-bzr-root file))
 496        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 497                                              rootdir))
 498        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 499        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 500     ;; This looks at internal files to avoid forking a bzr process.
 501     ;; May break if they change their format.
 502     (if (and (file-exists-p branch-format-file)
 503              ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
 504              ;; the branch-format-file does not contain the revision
 505              ;; information, we need to look up the branch-format-file
 506              ;; in the place where the lightweight checkout comes
 507              ;; from.  We only do that if it's a local file.
 508              (let ((location-fname (expand-file-name
 509                                     (concat vc-bzr-admin-dirname
 510                                             "/branch/location") rootdir)))
 511                ;; The existence of this file is how we distinguish
 512                ;; lightweight checkouts.
 513                (if (file-exists-p location-fname)
 514                    (with-temp-buffer
 515                      (insert-file-contents location-fname)
 516                      ;; If the lightweight checkout points to a
 517                      ;; location in the local file system, then we can
 518                      ;; look there for the version information.
 519                      (when (re-search-forward "file://\\(.+\\)" nil t)
 520                        (let ((l-c-parent-dir (match-string 1)))
 521                          (when (and (memq system-type '(ms-dos windows-nt))
 522                                     (string-match-p "^/[[:alpha:]]:" l-c-parent-dir))
 523                            ;;; The non-Windows code takes a shortcut by using the host/path
 524                            ;;; separator slash as the start of the absolute path.  That
 525                            ;;; does not work on Windows, so we must remove it (bug#5345)
 526                            (setq l-c-parent-dir (substring l-c-parent-dir 1)))
 527                          (setq branch-format-file
 528                                (expand-file-name vc-bzr-admin-branch-format-file
 529                                                  l-c-parent-dir))
 530                          (setq lastrev-file
 531                                (expand-file-name vc-bzr-admin-lastrev l-c-parent-dir))
 532                          ;; FIXME: maybe it's overkill to check if both these files exist.
 533                          (and (file-exists-p branch-format-file)
 534                               (file-exists-p lastrev-file)))))
 535                  t)))
 536         (with-temp-buffer
 537           (insert-file-contents branch-format-file)
 538           (goto-char (point-min))
 539           (cond
 540            ((or
 541              (looking-at "Bazaar-NG branch, format 0.0.4")
 542              (looking-at "Bazaar-NG branch format 5"))
 543             ;; count lines in .bzr/branch/revision-history
 544             (insert-file-contents revhistory-file)
 545             (number-to-string (count-lines (line-end-position) (point-max))))
 546            ((or
 547              (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 548              (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
 549             ;; revno is the first number in .bzr/branch/last-revision
 550             (insert-file-contents lastrev-file)
 551             (when (re-search-forward "[0-9]+" nil t)
 552               (buffer-substring (match-beginning 0) (match-end 0))))))
 553       ;; fallback to calling "bzr revno"
 554       (lexical-let*
 555           ((result (vc-bzr-command-discarding-stderr
 556                     vc-bzr-program "revno" (file-relative-name file)))
 557            (exitcode (car result))
 558            (output (cdr result)))
 559         (cond
 560          ((eq exitcode 0) (substring output 0 -1))
 561          (t nil))))))
 562
 563 (defun vc-bzr-create-repo ()
 564   "Create a new Bzr repository."
 565   (vc-bzr-command "init" nil 0 nil))
 566
 567 (defun vc-bzr-init-revision (&optional file)
 568   "Always return nil, as Bzr cannot register explicit versions."
 569   nil)
 570
 571 (defun vc-bzr-previous-revision (file rev)
 572   (if (string-match "\\`[0-9]+\\'" rev)
 573       (number-to-string (1- (string-to-number rev)))
 574     (concat "before:" rev)))
 575
 576 (defun vc-bzr-next-revision (file rev)
 577   (if (string-match "\\`[0-9]+\\'" rev)
 578       (number-to-string (1+ (string-to-number rev)))
 579     (error "Don't know how to compute the next revision of %s" rev)))
 580
 581 (defun vc-bzr-register (files &optional rev comment)
 582   "Register FILES under bzr.
 583 Signal an error unless REV is nil.
 584 COMMENT is ignored."
 585   (if rev (error "Can't register explicit revision with bzr"))
 586   (vc-bzr-command "add" nil 0 files))
 587
 588 ;; Could run `bzr status' in the directory and see if it succeeds, but
 589 ;; that's relatively expensive.
 590 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 591   "Return non-nil if FILE is (potentially) controlled by bzr.
 592 The criterion is that there is a `.bzr' directory in the same
 593 or a superior directory.")
 594
 595 (defun vc-bzr-could-register (file)
 596   "Return non-nil if FILE could be registered under bzr."
 597   (and (vc-bzr-responsible-p file)      ; shortcut
 598        (condition-case ()
 599            (with-temp-buffer
 600              (vc-bzr-command "add" t 0 file "--dry-run")
 601              ;; The command succeeds with no output if file is
 602              ;; registered (in bzr 0.8).
 603              (goto-char (point-min))
 604              (looking-at "added "))
 605          (error))))
 606
 607 (defun vc-bzr-unregister (file)
 608   "Unregister FILE from bzr."
 609   (vc-bzr-command "remove" nil 0 file "--keep"))
 610
 611 (declare-function log-edit-extract-headers "log-edit" (headers string))
 612
 613 (defun vc-bzr-checkin (files rev comment)
 614   "Check FILES in to bzr with log message COMMENT.
 615 REV non-nil gets an error."
 616   (if rev (error "Can't check in a specific revision with bzr"))
 617   (apply 'vc-bzr-command "commit" nil 0
 618          files (cons "-m" (log-edit-extract-headers '(("Author" . "--author")
 619                                                       ("Date" . "--commit-time")
 620                                                       ("Fixes" . "--fixes"))
 621                                                     comment))))
 622
 623 (defun vc-bzr-find-revision (file rev buffer)
 624   "Fetch revision REV of file FILE and put it into BUFFER."
 625     (with-current-buffer buffer
 626       (if (and rev (stringp rev) (not (string= rev "")))
 627           (vc-bzr-command "cat" t 0 file "-r" rev)
 628         (vc-bzr-command "cat" t 0 file))))
 629
 630 (defun vc-bzr-checkout (file &optional editable rev)
 631   (if rev (error "Operation not supported")
 632     ;; Else, there's nothing to do.
 633     nil))
 634
 635 (defun vc-bzr-revert (file &optional contents-done)
 636   (unless contents-done
 637     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 638
 639 (defvar log-view-message-re)
 640 (defvar log-view-file-re)
 641 (defvar log-view-font-lock-keywords)
 642 (defvar log-view-current-tag-function)
 643 (defvar log-view-per-file-logs)
 644 (defvar log-view-expanded-log-entry-function)
 645
 646 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 647   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 648   (require 'add-log)
 649   (set (make-local-variable 'log-view-per-file-logs) nil)
 650   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 651   (set (make-local-variable 'log-view-message-re)
 652        (if (eq vc-log-view-type 'short)
 653            "^ *\\([0-9.]+\\): \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)\\( \\[merge\\]\\)?"
 654          "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)"))
 655   ;; Allow expanding short log entries
 656   (when (eq vc-log-view-type 'short)
 657     (setq truncate-lines t)
 658     (set (make-local-variable 'log-view-expanded-log-entry-function)
 659          'vc-bzr-expanded-log-entry))
 660   (set (make-local-variable 'log-view-font-lock-keywords)
 661        ;; log-view-font-lock-keywords is careful to use the buffer-local
 662        ;; value of log-view-message-re only since Emacs-23.
 663        (if (eq vc-log-view-type 'short)
 664          (append `((,log-view-message-re
 665                     (1 'log-view-message-face)
 666                     (2 'change-log-name)
 667                     (3 'change-log-date)
 668                     (4 'change-log-list nil lax))))
 669          (append `((,log-view-message-re . 'log-view-message-face))
 670                  ;; log-view-font-lock-keywords
 671                  '(("^ *\\(?:committer\\|author\\): \
 672 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 673                     (1 'change-log-name)
 674                     (2 'change-log-email))
 675                    ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face)))))))
 676
 677 (defun vc-bzr-print-log (files buffer &optional shortlog start-revision limit)
 678   "Get bzr change log for FILES into specified BUFFER."
 679   ;; `vc-do-command' creates the buffer, but we need it before running
 680   ;; the command.
 681   (vc-setup-buffer buffer)
 682   ;; If the buffer exists from a previous invocation it might be
 683   ;; read-only.
 684   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 685   ;; the log display may not what the user wants - but I see no other
 686   ;; way of getting the above regexps working.
 687   (with-current-buffer buffer
 688     (apply 'vc-bzr-command "log" buffer 'async files
 689            (append
 690             (when shortlog '("--line"))
 691             (when start-revision (list (format "-r..%s" start-revision)))
 692             (when limit (list "-l" (format "%s" limit)))
 693             (if (stringp vc-bzr-log-switches)
 694                 (list vc-bzr-log-switches)
 695               vc-bzr-log-switches)))))
 696
 697 (defun vc-bzr-expanded-log-entry (revision)
 698   (with-temp-buffer
 699     (apply 'vc-bzr-command "log" t nil nil
 700            (list (format "-r%s" revision)))
 701     (goto-char (point-min))
 702     (when (looking-at "^-+\n")
 703       ;; Indent the expanded log entry.
 704       (indent-region (match-end 0) (point-max) 2)
 705       (buffer-substring (match-end 0) (point-max)))))
 706
 707 (defun vc-bzr-log-incoming (buffer remote-location)
 708   (apply 'vc-bzr-command "missing" buffer 'async nil
 709          (list "--theirs-only" (unless (string= remote-location "") remote-location))))
 710
 711 (defun vc-bzr-log-outgoing (buffer remote-location)
 712   (apply 'vc-bzr-command "missing" buffer 'async nil
 713          (list "--mine-only" (unless (string= remote-location "") remote-location))))
 714
 715 (defun vc-bzr-show-log-entry (revision)
 716   "Find entry for patch name REVISION in bzr change log buffer."
 717   (goto-char (point-min))
 718   (when revision
 719     (let (case-fold-search
 720           found)
 721       (if (re-search-forward
 722            ;; "revno:" can appear either at the beginning of a line,
 723            ;; or indented.
 724            (concat "^[ ]*-+\n[ ]*revno: "
 725                    ;; The revision can contain ".", quote it so that it
 726                    ;; does not interfere with regexp matching.
 727                    (regexp-quote revision) "$") nil t)
 728           (progn
 729             (beginning-of-line 0)
 730             (setq found t))
 731         (goto-char (point-min)))
 732       found)))
 733
 734 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 735   "VC bzr backend for diff."
 736   (let* ((switches (vc-switches 'bzr 'diff))
 737          (args
 738           (append
 739            ;; Only add --diff-options if there are any diff switches.
 740            (unless (zerop (length switches))
 741              (list "--diff-options" (mapconcat 'identity switches " ")))
 742            ;; This `when' is just an optimization because bzr-1.2 is *much*
 743            ;; faster when the revision argument is not given.
 744            (when (or rev1 rev2)
 745              (list "-r" (format "%s..%s"
 746                                 (or rev1 "revno:-1")
 747                                 (or rev2 "")))))))
 748     ;; `bzr diff' exits with code 1 if diff is non-empty.
 749     (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*")
 750            (if vc-disable-async-diff 1 'async) files
 751            args)))
 752
 753
 754 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 755 ;; straight integer revisions.
 756
 757 (defun vc-bzr-delete-file (file)
 758   "Delete FILE and delete it in the bzr repository."
 759   (condition-case ()
 760       (delete-file file)
 761     (file-error nil))
 762   (vc-bzr-command "remove" nil 0 file))
 763
 764 (defun vc-bzr-rename-file (old new)
 765   "Rename file from OLD to NEW using `bzr mv'."
 766   (vc-bzr-command "mv" nil 0 new old))
 767
 768 (defvar vc-bzr-annotation-table nil
 769   "Internal use.")
 770 (make-variable-buffer-local 'vc-bzr-annotation-table)
 771
 772 (defun vc-bzr-annotate-command (file buffer &optional revision)
 773   "Prepare BUFFER for `vc-annotate' on FILE.
 774 Each line is tagged with the revision number, which has a `help-echo'
 775 property containing author and date information."
 776   (apply #'vc-bzr-command "annotate" buffer 'async file "--long" "--all"
 777          (if revision (list "-r" revision)))
 778   (lexical-let ((table (make-hash-table :test 'equal)))
 779     (set-process-filter
 780      (get-buffer-process buffer)
 781      (lambda (proc string)
 782        (when (process-buffer proc)
 783          (with-current-buffer (process-buffer proc)
 784            (setq string (concat (process-get proc :vc-left-over) string))
 785            ;; Eg: 102020      Gnus developers          20101020 | regexp."
 786            ;; As of bzr 2.2.2, no email address in whoami (which can
 787            ;; lead to spaces in the author field) is allowed but discouraged.
 788            ;; See bug#7792.
 789            (while (string-match "^\\( *[0-9.]+ *\\) \\(.+?\\) +\\([0-9]\\{8\\}\\)\\( |.*\n\\)" string)
 790              (let* ((rev (match-string 1 string))
 791                     (author (match-string 2 string))
 792                     (date (match-string 3 string))
 793                     (key (substring string (match-beginning 0)
 794                                     (match-beginning 4)))
 795                     (line (match-string 4 string))
 796                     (tag (gethash key table))
 797                     (inhibit-read-only t))
 798                (setq string (substring string (match-end 0)))
 799                (unless tag
 800                  (setq tag
 801                        (propertize
 802                         (format "%s %-7.7s" rev author)
 803                         'help-echo (format "Revision: %d, author: %s, date: %s"
 804                                            (string-to-number rev)
 805                                            author date)
 806                         'mouse-face 'highlight))
 807                  (puthash key tag table))
 808                (goto-char (process-mark proc))
 809                (insert tag line)
 810                (move-marker (process-mark proc) (point))))
 811            (process-put proc :vc-left-over string)))))))
 812
 813 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 814
 815 (defun vc-bzr-annotate-time ()
 816   (when (re-search-forward "^ *[0-9.]+ +.+? +|" nil t)
 817     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 818       (string-match "[0-9]+\\'" prop)
 819       (let ((str (match-string-no-properties 0 prop)))
 820       (vc-annotate-convert-time
 821        (encode-time 0 0 0
 822                       (string-to-number (substring str 6 8))
 823                       (string-to-number (substring str 4 6))
 824                       (string-to-number (substring str 0 4))))))))
 825
 826 (defun vc-bzr-annotate-extract-revision-at-line ()
 827   "Return revision for current line of annotation buffer, or nil.
 828 Return nil if current line isn't annotated."
 829   (save-excursion
 830     (beginning-of-line)
 831     (if (looking-at "^ *\\([0-9.]+\\) +.* +|")
 832         (match-string-no-properties 1))))
 833
 834 (defun vc-bzr-command-discarding-stderr (command &rest args)
 835   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 836 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 837 the (numerical) exit code of the process, and OUTPUT is a string
 838 containing whatever the process sent to its standard output
 839 stream.  Standard error output is discarded."
 840   (with-temp-buffer
 841     (cons
 842      (apply #'process-file command nil (list (current-buffer) nil) nil args)
 843      (buffer-substring (point-min) (point-max)))))
 844
 845 (defstruct (vc-bzr-extra-fileinfo
 846             (:copier nil)
 847             (:constructor vc-bzr-create-extra-fileinfo (extra-name))
 848             (:conc-name vc-bzr-extra-fileinfo->))
 849   extra-name)         ;; original name for rename targets, new name for
 850
 851 (defun vc-bzr-dir-printer (info)
 852   "Pretty-printer for the vc-dir-fileinfo structure."
 853   (let ((extra (vc-dir-fileinfo->extra info)))
 854     (vc-default-dir-printer 'Bzr info)
 855     (when extra
 856       (insert (propertize
 857                (format "   (renamed from %s)"
 858                        (vc-bzr-extra-fileinfo->extra-name extra))
 859                'face 'font-lock-comment-face)))))
 860
 861 ;; FIXME: this needs testing, it's probably incomplete.
 862 (defun vc-bzr-after-dir-status (update-function relative-dir)
 863   (let ((status-str nil)
 864         (translation '(("+N " . added)
 865                        ("-D " . removed)
 866                        (" M " . edited) ;; file text modified
 867                        ("  *" . edited) ;; execute bit changed
 868                        (" M*" . edited) ;; text modified + execute bit changed
 869                        ;; FIXME: what about ignored files?
 870                        (" D " . missing)
 871                        ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
 872                        ("C  " . conflict)
 873                        ("?  " . unregistered)
 874                        ;; No such state, but we need to distinguish this case.
 875                        ("R  " . renamed)
 876                        ("RM " . renamed)
 877                        ;; For a non existent file FOO, the output is:
 878                        ;; bzr: ERROR: Path(s) do not exist: FOO
 879                        ("bzr" . not-found)
 880                        ;; If the tree is not up to date, bzr will print this warning:
 881                        ;; working tree is out of date, run 'bzr update'
 882                        ;; ignore it.
 883                        ;; FIXME: maybe this warning can be put in the vc-dir header...
 884                        ("wor" . not-found)
 885                        ;; Ignore "P " and "P." for pending patches.
 886                        ("P  " . not-found)
 887                        ("P. " . not-found)
 888                        ))
 889         (translated nil)
 890         (result nil))
 891       (goto-char (point-min))
 892       (while (not (eobp))
 893         ;; Bzr 2.3.0 added this if there are shelves.  (Bug#8170)
 894         (unless (looking-at "[1-9]+ shel\\(f\\|ves\\) exists?\\.")
 895           (setq status-str
 896                 (buffer-substring-no-properties (point) (+ (point) 3)))
 897           (setq translated (cdr (assoc status-str translation)))
 898           (cond
 899            ((eq translated 'conflict)
 900             ;; For conflicts the file appears twice in the listing: once
 901             ;; with the M flag and once with the C flag, so take care
 902             ;; not to add it twice to `result'.  Ugly.
 903             (let* ((file
 904                     (buffer-substring-no-properties
 905                      ;;For files with conflicts the format is:
 906                      ;;C   Text conflict in FILENAME
 907                      ;; Bah.
 908                      (+ (point) 21) (line-end-position)))
 909                    (entry (assoc file result)))
 910               (when entry
 911                 (setf (nth 1 entry) 'conflict))))
 912            ((eq translated 'renamed)
 913             (re-search-forward "R[ M]  \\(.*\\) => \\(.*\\)$" (line-end-position) t)
 914             (let ((new-name (file-relative-name (match-string 2) relative-dir))
 915                   (old-name (file-relative-name (match-string 1) relative-dir)))
 916               (push (list new-name 'edited
 917                           (vc-bzr-create-extra-fileinfo old-name)) result)))
 918            ;; do nothing for non existent files
 919            ((eq translated 'not-found))
 920            (t
 921             (push (list (file-relative-name
 922                          (buffer-substring-no-properties
 923                           (+ (point) 4)
 924                           (line-end-position)) relative-dir)
 925                         translated) result))))
 926         (forward-line))
 927       (funcall update-function result)))
 928
 929 (defun vc-bzr-dir-status (dir update-function)
 930   "Return a list of conses (file . state) for DIR."
 931   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 932   (vc-exec-after
 933    `(vc-bzr-after-dir-status (quote ,update-function)
 934                              ;; "bzr status" results are relative to
 935                              ;; the bzr root directory, NOT to the
 936                              ;; directory "bzr status" was invoked in.
 937                              ;; Ugh.
 938                              ;; We pass the relative directory here so
 939                              ;; that `vc-bzr-after-dir-status' can
 940                              ;; frob the results accordingly.
 941                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 942
 943 (defun vc-bzr-dir-status-files (dir files default-state update-function)
 944   "Return a list of conses (file . state) for DIR."
 945   (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
 946   (vc-exec-after
 947    `(vc-bzr-after-dir-status (quote ,update-function)
 948                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 949
 950 (defvar vc-bzr-shelve-map
 951   (let ((map (make-sparse-keymap)))
 952     ;; Turn off vc-dir marking
 953     (define-key map [mouse-2] 'ignore)
 954
 955     (define-key map [down-mouse-3] 'vc-bzr-shelve-menu)
 956     (define-key map "\C-k" 'vc-bzr-shelve-delete-at-point)
 957     (define-key map "=" 'vc-bzr-shelve-show-at-point)
 958     (define-key map "\C-m" 'vc-bzr-shelve-show-at-point)
 959     (define-key map "A" 'vc-bzr-shelve-apply-and-keep-at-point)
 960     (define-key map "P" 'vc-bzr-shelve-apply-at-point)
 961     (define-key map "S" 'vc-bzr-shelve-snapshot)
 962     map))
 963
 964 (defvar vc-bzr-shelve-menu-map
 965   (let ((map (make-sparse-keymap "Bzr Shelve")))
 966     (define-key map [de]
 967       '(menu-item "Delete shelf" vc-bzr-shelve-delete-at-point
 968                   :help "Delete the current shelf"))
 969     (define-key map [ap]
 970       '(menu-item "Apply and keep shelf" vc-bzr-shelve-apply-and-keep-at-point
 971                   :help "Apply the current shelf and keep it"))
 972     (define-key map [po]
 973       '(menu-item "Apply and remove shelf (pop)" vc-bzr-shelve-apply-at-point
 974                   :help "Apply the current shelf and remove it"))
 975     (define-key map [sh]
 976       '(menu-item "Show shelve" vc-bzr-shelve-show-at-point
 977                   :help "Show the contents of the current shelve"))
 978     map))
 979
 980 (defvar vc-bzr-extra-menu-map
 981   (let ((map (make-sparse-keymap)))
 982     (define-key map [bzr-sn]
 983       '(menu-item "Shelve a snapshot" vc-bzr-shelve-snapshot
 984                   :help "Shelve the current state of the tree and keep the current state"))
 985     (define-key map [bzr-sh]
 986       '(menu-item "Shelve..." vc-bzr-shelve
 987                   :help "Shelve changes"))
 988     map))
 989
 990 (defun vc-bzr-extra-menu () vc-bzr-extra-menu-map)
 991
 992 (defun vc-bzr-extra-status-menu () vc-bzr-extra-menu-map)
 993
 994 (defun vc-bzr-dir-extra-headers (dir)
 995   (let*
 996       ((str (with-temp-buffer
 997               (vc-bzr-command "info" t 0 dir)
 998               (buffer-string)))
 999        (shelve (vc-bzr-shelve-list))
1000        (shelve-help-echo "Use M-x vc-bzr-shelve to create shelves")
1001        (root-dir (vc-bzr-root dir))
1002        (pending-merge
1003         ;; FIXME: looking for .bzr/checkout/merge-hashes is not a
1004         ;; reliable method to detect pending merges, disable this
1005         ;; until a proper solution is implemented.
1006         (and nil
1007          (file-exists-p
1008          (expand-file-name ".bzr/checkout/merge-hashes" root-dir))))
1009        (pending-merge-help-echo
1010         (format "A merge has been performed.\nA commit from the top-level directory (%s)\nis required before being able to check in anything else" root-dir))
1011        (light-checkout
1012         (when (string-match ".+light checkout root: \\(.+\\)$" str)
1013           (match-string 1 str)))
1014        (light-checkout-branch
1015         (when light-checkout
1016           (when (string-match ".+checkout of branch: \\(.+\\)$" str)
1017             (match-string 1 str)))))
1018     (concat
1019      (propertize "Parent branch      : " 'face 'font-lock-type-face)
1020      (propertize
1021       (if (string-match "parent branch: \\(.+\\)$" str)
1022           (match-string 1 str)
1023         "None")
1024        'face 'font-lock-variable-name-face)
1025      "\n"
1026       (when light-checkout
1027         (concat
1028          (propertize "Light checkout root: " 'face 'font-lock-type-face)
1029          (propertize light-checkout 'face 'font-lock-variable-name-face)
1030          "\n"))
1031       (when light-checkout-branch
1032         (concat
1033          (propertize "Checkout of branch : " 'face 'font-lock-type-face)
1034          (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
1035          "\n"))
1036       (when pending-merge
1037         (concat
1038          (propertize "Warning            : " 'face 'font-lock-warning-face
1039                      'help-echo pending-merge-help-echo)
1040          (propertize "Pending merges, commit recommended before any other action"
1041                      'help-echo pending-merge-help-echo
1042                      'face 'font-lock-warning-face)
1043          "\n"))
1044       (if shelve
1045           (concat
1046            (propertize "Shelves            :\n" 'face 'font-lock-type-face
1047                        'help-echo shelve-help-echo)
1048            (mapconcat
1049             (lambda (x)
1050               (propertize x
1051                           'face 'font-lock-variable-name-face
1052                           'mouse-face 'highlight
1053                           'help-echo "mouse-3: Show shelve menu\nA: Apply and keep shelf\nP: Apply and remove shelf (pop)\nS: Snapshot to a shelf\nC-k: Delete shelf"
1054                           'keymap vc-bzr-shelve-map))
1055             shelve "\n"))
1056         (concat
1057          (propertize "Shelves            : " 'face 'font-lock-type-face
1058                      'help-echo shelve-help-echo)
1059          (propertize "No shelved changes"
1060                      'help-echo shelve-help-echo
1061                      'face 'font-lock-variable-name-face))))))
1062
1063 (defun vc-bzr-shelve (name)
1064   "Create a shelve."
1065   (interactive "sShelf name: ")
1066   (let ((root (vc-bzr-root default-directory)))
1067     (when root
1068       (vc-bzr-command "shelve" nil 0 nil "--all" "-m" name)
1069       (vc-resynch-buffer root t t))))
1070
1071 (defun vc-bzr-shelve-show (name)
1072   "Show the contents of shelve NAME."
1073   (interactive "sShelve name: ")
1074   (vc-setup-buffer "*vc-diff*")
1075   ;; FIXME: how can you show the contents of a shelf?
1076   (vc-bzr-command "unshelve" "*vc-diff*" 'async nil "--preview" name)
1077   (set-buffer "*vc-diff*")
1078   (diff-mode)
1079   (setq buffer-read-only t)
1080   (pop-to-buffer (current-buffer)))
1081
1082 (defun vc-bzr-shelve-apply (name)
1083   "Apply shelve NAME and remove it afterwards."
1084   (interactive "sApply (and remove) shelf: ")
1085   (vc-bzr-command "unshelve" nil 0 nil "--apply" name)
1086   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
1087
1088 (defun vc-bzr-shelve-apply-and-keep (name)
1089   "Apply shelve NAME and keep it afterwards."
1090   (interactive "sApply (and keep) shelf: ")
1091   (vc-bzr-command "unshelve" nil 0 nil "--apply" "--keep" name)
1092   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
1093
1094 (defun vc-bzr-shelve-snapshot ()
1095   "Create a stash with the current tree state."
1096   (interactive)
1097   (vc-bzr-command "shelve" nil 0 nil "--all" "-m"
1098                   (let ((ct (current-time)))
1099                     (concat
1100                      (format-time-string "Snapshot on %Y-%m-%d" ct)
1101                      (format-time-string " at %H:%M" ct))))
1102   (vc-bzr-command "unshelve" nil 0 nil "--apply" "--keep")
1103   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
1104
1105 (defun vc-bzr-shelve-list ()
1106   (with-temp-buffer
1107     (vc-bzr-command "shelve" (current-buffer) 1 nil "--list" "-q")
1108     (delete
1109      ""
1110      (split-string
1111       (buffer-substring (point-min) (point-max))
1112       "\n"))))
1113
1114 (defun vc-bzr-shelve-get-at-point (point)
1115   (save-excursion
1116     (goto-char point)
1117     (beginning-of-line)
1118     (if (looking-at "^ +\\([0-9]+\\):")
1119         (match-string 1)
1120       (error "Cannot find shelf at point"))))
1121
1122 (defun vc-bzr-shelve-delete-at-point ()
1123   (interactive)
1124   (let ((shelve (vc-bzr-shelve-get-at-point (point))))
1125     (when (y-or-n-p (format "Remove shelf %s ? " shelve))
1126       (vc-bzr-command "unshelve" nil 0 nil "--delete-only" shelve)
1127       (vc-dir-refresh))))
1128
1129 (defun vc-bzr-shelve-show-at-point ()
1130   (interactive)
1131   (vc-bzr-shelve-show (vc-bzr-shelve-get-at-point (point))))
1132
1133 (defun vc-bzr-shelve-apply-at-point ()
1134   (interactive)
1135   (vc-bzr-shelve-apply (vc-bzr-shelve-get-at-point (point))))
1136
1137 (defun vc-bzr-shelve-apply-and-keep-at-point ()
1138   (interactive)
1139   (vc-bzr-shelve-apply-and-keep (vc-bzr-shelve-get-at-point (point))))
1140
1141 (defun vc-bzr-shelve-menu (e)
1142   (interactive "e")
1143   (vc-dir-at-event e (popup-menu vc-bzr-shelve-menu-map e)))
1144
1145 (defun vc-bzr-revision-table (files)
1146   (let ((vc-bzr-revisions '())
1147         (default-directory (file-name-directory (car files))))
1148     (with-temp-buffer
1149       (vc-bzr-command "log" t 0 files "--line")
1150       (let ((start (point-min))
1151             (loglines (buffer-substring-no-properties (point-min) (point-max))))
1152         (while (string-match "^\\([0-9]+\\):" loglines)
1153           (push (match-string 1 loglines) vc-bzr-revisions)
1154           (setq start (+ start (match-end 0)))
1155           (setq loglines (buffer-substring-no-properties start (point-max))))))
1156     vc-bzr-revisions))
1157
1158 (defun vc-bzr-conflicted-files (dir)
1159   (let ((default-directory (vc-bzr-root dir))
1160         (files ()))
1161     (with-temp-buffer
1162       (vc-bzr-command "status" t 0 default-directory)
1163       (goto-char (point-min))
1164       (when (re-search-forward "^conflicts:\n" nil t)
1165         (while (looking-at "  \\(?:Text conflict in \\(.*\\)\\|.*\\)\n")
1166           (if (match-end 1)
1167               (push (expand-file-name (match-string 1)) files))
1168           (goto-char (match-end 0)))))
1169     files))
1170
1171 ;;; Revision completion
1172
1173 (eval-and-compile
1174   (defconst vc-bzr-revision-keywords
1175     '("revno" "revid" "last" "before"
1176       "tag" "date" "ancestor" "branch" "submit")))
1177
1178 (defun vc-bzr-revision-completion-table (files)
1179   (lexical-let ((files files))
1180     ;; What about using `files'?!?  --Stef
1181     (lambda (string pred action)
1182       (cond
1183        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
1184                       string)
1185         (completion-table-with-context (substring string 0 (match-end 0))
1186                                        (apply-partially
1187                                         'completion-table-with-predicate
1188                                         'completion-file-name-table
1189                                         'file-directory-p t)
1190                                        (substring string (match-end 0))
1191                                        pred
1192                                        action))
1193        ((string-match "\\`\\(before\\):" string)
1194         (completion-table-with-context (substring string 0 (match-end 0))
1195                                        (vc-bzr-revision-completion-table files)
1196                                        (substring string (match-end 0))
1197                                        pred
1198                                        action))
1199        ((string-match "\\`\\(tag\\):" string)
1200         (let ((prefix (substring string 0 (match-end 0)))
1201               (tag (substring string (match-end 0)))
1202               (table nil)
1203               process-file-side-effects)
1204           (with-temp-buffer
1205             ;; "bzr-1.2 tags" is much faster with --show-ids.
1206             (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
1207             ;; The output is ambiguous, unless we assume that revids do not
1208             ;; contain spaces.
1209             (goto-char (point-min))
1210             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
1211               (push (match-string-no-properties 1) table)))
1212           (completion-table-with-context prefix table tag pred action)))
1213
1214        ((string-match "\\`\\([a-z]+\\):" string)
1215         ;; no actual completion for the remaining keywords.
1216         (completion-table-with-context (substring string 0 (match-end 0))
1217                                        (if (member (match-string 1 string)
1218                                                    vc-bzr-revision-keywords)
1219                                            ;; If it's a valid keyword,
1220                                            ;; use a non-empty table to
1221                                            ;; indicate it.
1222                                            '("") nil)
1223                                        (substring string (match-end 0))
1224                                        pred
1225                                        action))
1226        (t
1227         ;; Could use completion-table-with-terminator, except that it
1228         ;; currently doesn't work right w.r.t pcm and doesn't give
1229         ;; the *Completions* output we want.
1230         (complete-with-action action (eval-when-compile
1231                                        (mapcar (lambda (s) (concat s ":"))
1232                                                vc-bzr-revision-keywords))
1233                               string pred))))))
1234
1235 (provide 'vc-bzr)
1236
1237 ;;; vc-bzr.el ends here