configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 dnl _ON results in a '--without' option in the --help output, so
 148 dnl the help text should refer to "don't compile", etc.
 149 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 150 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 151 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 152 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 153 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 154 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 155 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 156 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH(gameuser,dnl
 204 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 205 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 206   && gameuser="${with_gameuser}"
 207 test "X$gameuser" = X && gameuser=games
 208
 209 AC_ARG_WITH([gnustep-conf],dnl
 210 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 211 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 212   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 213 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 214      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 215
 216 AC_ARG_ENABLE(ns-self-contained,
 217 [AS_HELP_STRING([--disable-ns-self-contained],
 218                 [disable self contained build under NeXTstep])],
 219    EN_NS_SELF_CONTAINED=$enableval,
 220    EN_NS_SELF_CONTAINED=yes)
 221
 222 AC_ARG_ENABLE(asserts,
 223 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 224       USE_XASSERTS=$enableval,
 225       USE_XASSERTS=no)
 226
 227 AC_ARG_ENABLE(maintainer-mode,
 228 [AS_HELP_STRING([--enable-maintainer-mode],
 229                 [enable make rules and dependencies not useful (and sometimes
 230                  confusing) to the casual installer])],
 231       USE_MAINTAINER_MODE=$enableval,
 232       USE_MAINTAINER_MODE=yes)
 233 if test $USE_MAINTAINER_MODE = yes; then
 234   MAINT=
 235 else
 236   MAINT=#
 237 fi
 238 AC_SUBST(MAINT)
 239
 240 AC_ARG_ENABLE(locallisppath,
 241 [AS_HELP_STRING([--enable-locallisppath=PATH],
 242                 [directories Emacs should search for lisp files specific
 243                  to this site])],
 244 if test "${enableval}" = "no"; then
 245   locallisppath=
 246 elif test "${enableval}" != "yes"; then
 247   locallisppath=${enableval}
 248 fi)
 249
 250 AC_ARG_ENABLE(checking,
 251 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 252                 [enable expensive run-time checks.  With LIST,
 253                  enable only specific categories of checks.
 254                  Categories are: all,yes,no.
 255                  Flags are: stringbytes, stringoverrun, stringfreelist,
 256                  xmallocoverrun, conslist])],
 257 [ac_checking_flags="${enableval}"],[])
 258 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 259 for check in $ac_checking_flags
 260 do
 261         case $check in
 262         # these set all the flags to specific states
 263         yes)            ac_enable_checking=1 ;;
 264         no)             ac_enable_checking= ;
 265                         ac_gc_check_stringbytes= ;
 266                         ac_gc_check_string_overrun= ;
 267                         ac_gc_check_string_free_list= ;
 268                         ac_xmalloc_overrun= ;
 269                         ac_gc_check_cons_list= ;;
 270         all)            ac_enable_checking=1 ;
 271                         ac_gc_check_stringbytes=1 ;
 272                         ac_gc_check_string_overrun=1 ;
 273                         ac_gc_check_string_free_list=1 ;
 274                         ac_xmalloc_overrun=1 ;
 275                         ac_gc_check_cons_list=1 ;;
 276         # these enable particular checks
 277         stringbytes)    ac_gc_check_stringbytes=1 ;;
 278         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 279         stringfreelist) ac_gc_check_string_free_list=1 ;;
 280         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 281         conslist)       ac_gc_check_cons_list=1 ;;
 282         *)      AC_MSG_ERROR(unknown check category $check) ;;
 283         esac
 284 done
 285 IFS="$ac_save_IFS"
 286
 287 if test x$ac_enable_checking != x ; then
 288   AC_DEFINE(ENABLE_CHECKING, 1,
 289 [Enable expensive run-time checking of data types?])
 290 fi
 291 if test x$ac_gc_check_stringbytes != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 293 [Define this temporarily to hunt a bug.  If defined, the size of
 294    strings is redundantly recorded in sdata structures so that it can
 295    be compared to the sizes recorded in Lisp strings.])
 296 fi
 297 if test x$ac_gc_check_string_overrun != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 299 [Define this to check for short string overrun.])
 300 fi
 301 if test x$ac_gc_check_string_free_list != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 303 [Define this to check the string free list.])
 304 fi
 305 if test x$ac_xmalloc_overrun != x ; then
 306   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 307 [Define this to check for malloc buffer overrun.])
 308 fi
 309 if test x$ac_gc_check_cons_list != x ; then
 310   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 311 [Define this to check for errors in cons list.])
 312 fi
 313
 314 AC_ARG_ENABLE(use-lisp-union-type,
 315 [AS_HELP_STRING([--enable-use-lisp-union-type],
 316                 [use a union for the Lisp_Object data type.
 317                 This is only useful for development for catching certain types of bugs.])],
 318 if test "${enableval}" != "no"; then
 319    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 320    [Define this to use a lisp union for the Lisp_Object data type.])
 321 fi)
 322
 323
 324 AC_ARG_ENABLE(profiling,
 325 [AS_HELP_STRING([--enable-profiling],
 326                 [build emacs with profiling support.
 327                  This might not work on all platforms])],
 328 [ac_enable_profiling="${enableval}"],[])
 329 if test x$ac_enable_profiling != x ; then
 330    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 331 else
 332    PROFILING_CFLAGS=
 333 fi
 334 AC_SUBST(PROFILING_CFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Given the configuration name, set machfile and opsysfile to the
 368 #### names of the m/*.h and s/*.h files we should use.
 369
 370 ### Canonicalize the configuration name.
 371
 372 AC_CANONICAL_HOST
 373 canonical=$host
 374 configuration=${host_alias-${build_alias-$host}}
 375
 376 dnl This used to use changequote, but, apart from `changequote is evil'
 377 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 378 dnl the great gob of text.  Thus it's not processed for possible expansion.
 379 dnl Just make sure the brackets remain balanced.
 380 dnl
 381 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 382 dnl indicated by comments.
 383 dnl quotation begins
 384 [
 385
 386 ### If you add support for a new configuration, add code to this
 387 ### switch statement to recognize your configuration name and select
 388 ### the appropriate operating system and machine description files.
 389
 390 ### You would hope that you could choose an m/*.h file pretty much
 391 ### based on the machine portion of the configuration name, and an s/*.h
 392 ### file based on the operating system portion.  However, it turns out
 393 ### that each m/*.h file is pretty manufacturer-specific - for
 394 ### example mips.h is MIPS
 395 ### So we basically have to have a special case for each
 396 ### configuration name.
 397 ###
 398 ### As far as handling version numbers on operating systems is
 399 ### concerned, make sure things will fail in a fixable way.  If
 400 ### /etc/MACHINES doesn't say anything about version numbers, be
 401 ### prepared to handle anything reasonably.  If version numbers
 402 ### matter, be sure /etc/MACHINES says something about it.
 403
 404 machine='' opsys='' unported=no
 405 case "${canonical}" in
 406
 407   ## GNU/Linux ports
 408   *-*-linux-gnu*)
 409     opsys=gnu-linux
 410     case ${canonical} in
 411       alpha*)   machine=alpha ;;
 412       s390-*)   machine=ibms390 ;;
 413       s390x-*)  machine=ibms390x ;;
 414       powerpc*) machine=macppc ;;
 415       sparc*)   machine=sparc ;;
 416       ia64*)    machine=ia64 ;;
 417       m68k*)    machine=m68k ;;
 418       x86_64*)  machine=amdx86-64 ;;
 419     esac
 420   ;;
 421
 422   ## FreeBSD ports
 423   *-*-freebsd* )
 424     opsys=freebsd
 425     case "${canonical}" in
 426       alpha*)           machine=alpha ;;
 427       amd64-*|x86_64-*) machine=amdx86-64 ;;
 428       ia64-*)           machine=ia64 ;;
 429       i[3456]86-*)      machine=intel386 ;;
 430       powerpc-*)        machine=macppc ;;
 431       sparc-*)          machine=sparc ;;
 432       sparc64-*)        machine=sparc ;;
 433     esac
 434   ;;
 435
 436   ## FreeBSD kernel + glibc based userland
 437   *-*-kfreebsd*gnu* )
 438     opsys=gnu-kfreebsd
 439     case "${canonical}" in
 440       alpha*)           machine=alpha ;;
 441       amd64-*|x86_64-*) machine=amdx86-64 ;;
 442       ia64-*)           machine=ia64 ;;
 443       i[3456]86-*)      machine=intel386 ;;
 444       powerpc-*)        machine=macppc ;;
 445       sparc-*)          machine=sparc ;;
 446       sparc64-*)        machine=sparc ;;
 447     esac
 448   ;;
 449
 450   ## NetBSD ports
 451   *-*-netbsd* )
 452     opsys=netbsd
 453     case "${canonical}" in
 454       alpha*)      machine=alpha ;;
 455       x86_64-*)    machine=amdx86-64 ;;
 456       i[3456]86-*) machine=intel386 ;;
 457       m68k-*)      machine=m68k ;;
 458       powerpc-*)   machine=macppc ;;
 459       sparc*-)     machine=sparc ;;
 460       vax-*)       machine=vax ;;
 461     esac
 462   ;;
 463
 464   ## OpenBSD ports
 465   *-*-openbsd* )
 466     opsys=openbsd
 467     case "${canonical}" in
 468       alpha*)    machine=alpha ;;
 469       x86_64-*)  machine=amdx86-64 ;;
 470       i386-*)    machine=intel386 ;;
 471       powerpc-*) machine=macppc ;;
 472       sparc*)    machine=sparc ;;
 473       vax-*)     machine=vax ;;
 474     esac
 475   ;;
 476
 477   ## Apple Darwin / Mac OS X
 478   *-apple-darwin* )
 479     case "${canonical}" in
 480       i[3456]86-* )  machine=intel386 ;;
 481       powerpc-* )    machine=macppc ;;
 482       x86_64-* )     machine=amdx86-64 ;;
 483       * )            unported=yes ;;
 484     esac
 485     opsys=darwin
 486     # Define CPP as follows to make autoconf work correctly.
 487     CPP="${CC-cc} -E -no-cpp-precomp"
 488     # Use fink packages if available.
 489     if test -d /sw/include && test -d /sw/lib; then
 490       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 491       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 492       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 493     fi
 494   ;;
 495
 496   ## HP 9000 series 700 and 800, running HP/UX
 497   hppa*-hp-hpux10.2* )
 498     opsys=hpux10-20
 499   ;;
 500   hppa*-hp-hpux1[1-9]* )
 501     opsys=hpux11
 502     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 503   ;;
 504
 505   ia64*-hp-hpux1[1-9]* )
 506     machine=hp800 opsys=hpux11
 507     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 508     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 509     CANNOT_DUMP=yes
 510   ;;
 511
 512   hppa*-*-linux-gnu* )
 513     machine=hp800 opsys=gnu-linux
 514   ;;
 515
 516   ## IBM machines
 517   rs6000-ibm-aix4.[23]* )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520   powerpc-ibm-aix4.[23]*  )
 521     machine=ibmrs6000 opsys=aix4-2
 522   ;;
 523   rs6000-ibm-aix[56]* )
 524     machine=ibmrs6000 opsys=aix4-2
 525   ;;
 526   powerpc-ibm-aix[56]*  )
 527     machine=ibmrs6000 opsys=aix4-2
 528   ;;
 529
 530   ## Silicon Graphics machines
 531   ## Iris 4D
 532   mips-sgi-irix6.5 )
 533     machine=iris4d opsys=irix6-5
 534     # Without defining _LANGUAGE_C, things get masked out in the headers
 535     # so that, for instance, grepping for `free' in stdlib.h fails and
 536     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 537     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 538     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 539   ;;
 540
 541   ## Suns
 542   *-sun-solaris* \
 543     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 544     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 545     case "${canonical}" in
 546       i[3456]86-*-* )     machine=intel386 ;;
 547       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 548       sparc* )          machine=sparc ;;
 549       * )               unported=yes ;;
 550     esac
 551     case "${canonical}" in
 552       *-sunos5.6* | *-solaris2.6* )
 553                 opsys=sol2-6
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 RANLIB="ar -ts"
 556                 ;;
 557       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 558                 opsys=sol2-6
 559                 emacs_check_sunpro_c=yes
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 ;;
 562       *-sunos5* | *-solaris* )
 563                 opsys=sol2-10
 564                 emacs_check_sunpro_c=yes
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 ;;
 567     esac
 568     ## Watch out for a compiler that we know will not work.
 569     case "${canonical}" in
 570      *-solaris* | *-sunos5* )
 571                 if [ "x$CC" = x/usr/ucb/cc ]; then
 572                   ## /usr/ucb/cc doesn't work;
 573                   ## we should find some other compiler that does work.
 574                   unset CC
 575                 fi
 576                 ;;
 577       *) ;;
 578     esac
 579   ;;
 580
 581   ## Intel 386 machines where we don't care about the manufacturer.
 582   i[3456]86-*-* )
 583     machine=intel386
 584     case "${canonical}" in
 585       *-cygwin )                opsys=cygwin ;;
 586       *-darwin* )               opsys=darwin
 587                                 CPP="${CC-cc} -E -no-cpp-precomp"
 588                                 ;;
 589       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 593     esac
 594   ;;
 595
 596   * )
 597     unported=yes
 598   ;;
 599 esac
 600
 601 ### If the code above didn't choose an operating system, just choose
 602 ### an operating system based on the configuration name.  You really
 603 ### only want to use this when you have no idea what the right
 604 ### operating system is; if you know what operating systems a machine
 605 ### runs, it's cleaner to make it explicit in the case statement
 606 ### above.
 607 if test x"${opsys}" = x; then
 608   case "${canonical}" in
 609     *-gnu* )                            opsys=gnu ;;
 610     * )
 611       unported=yes
 612     ;;
 613   esac
 614 fi
 615
 616 ]
 617 dnl quotation ends
 618
 619 if test $unported = yes; then
 620   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 621 Check `etc/MACHINES' for recognized configuration names.])
 622 fi
 623
 624 if test -n "$machine"; then
 625   machfile="m/${machine}.h"
 626 else
 627   machfile=
 628 fi
 629 opsysfile="s/${opsys}.h"
 630
 631
 632 #### Choose a compiler.
 633 test -n "$CC" && cc_specified=yes
 634
 635 # Save the value of CFLAGS that the user specified.
 636 SPECIFIED_CFLAGS="$CFLAGS"
 637
 638 dnl Sets GCC=yes if using gcc.
 639 AC_PROG_CC
 640 AM_PROG_CC_C_O
 641
 642 # Initialize gnulib right after verifying that the C compiler works.
 643 gl_EARLY
 644
 645 # On Suns, sometimes $CPP names a directory.
 646 if test -n "$CPP" && test -d "$CPP"; then
 647   CPP=
 648 fi
 649
 650 ## If not using gcc, and on Solaris, and no CPP specified, see if
 651 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 652 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 653  test x"$CPP" = x; then
 654   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 655   AC_CACHE_VAL(emacs_cv_sunpro_c,
 656   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 657 [[#ifndef __SUNPRO_C
 658 fail;
 659 #endif
 660 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 661   AC_MSG_RESULT($emacs_cv_sunpro_c)
 662
 663   if test x"$emacs_cv_sunpro_c" = xyes; then
 664     NON_GNU_CPP="$CC -E -Xs"
 665   fi
 666 fi
 667
 668 #### Some systems specify a CPP to use unless we are using GCC.
 669 #### Now that we know whether we are using GCC, we can decide whether
 670 #### to use that one.
 671 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 672 then
 673   CPP="$NON_GNU_CPP"
 674 fi
 675
 676 #### Some systems specify a CC to use unless we are using GCC.
 677 #### Now that we know whether we are using GCC, we can decide whether
 678 #### to use that one.
 679 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 680   test x$cc_specified != xyes
 681 then
 682   CC="$NON_GNU_CC"
 683 fi
 684
 685 if test x$GCC = xyes; then
 686   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 687 else
 688   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 689 fi
 690
 691 ### Use -Wdeclaration-after-statement if the compiler supports it
 692 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 693 SAVE_CFLAGS="$CFLAGS"
 694 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 695 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 696 if test $has_option = yes; then
 697    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 698 fi
 699 AC_MSG_RESULT($has_option)
 700 CFLAGS="$SAVE_CFLAGS"
 701 unset has_option
 702 unset SAVE_CFLAGS
 703
 704 ### Use -Wold-style-definition if the compiler supports it
 705 # This can be removed when conversion to standard C is finished.
 706 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 707 SAVE_CFLAGS="$CFLAGS"
 708 CFLAGS="$CFLAGS -Wold-style-definition"
 709 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 710 if test $has_option = yes; then
 711    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 712 fi
 713 AC_MSG_RESULT($has_option)
 714 CFLAGS="$SAVE_CFLAGS"
 715 unset has_option
 716 unset SAVE_CFLAGS
 717
 718 ### Use -Wimplicit-function-declaration if the compiler supports it
 719 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 720 SAVE_CFLAGS="$CFLAGS"
 721 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 722 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 723 if test $has_option = yes; then
 724    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 725 fi
 726 AC_MSG_RESULT($has_option)
 727 CFLAGS="$SAVE_CFLAGS"
 728 unset has_option
 729 unset SAVE_CFLAGS
 730
 731 AC_SUBST(C_WARNINGS_SWITCH)
 732
 733
 734 #### Some other nice autoconf tests.
 735
 736 dnl checks for programs
 737 AC_PROG_CPP
 738 AC_PROG_INSTALL
 739 if test "x$RANLIB" = x; then
 740   AC_PROG_RANLIB
 741 fi
 742
 743 ## Although we're running on an amd64 kernel, we're actually compiling for
 744 ## the x86 architecture.  The user should probably have provided an
 745 ## explicit --build to `configure', but if everything else than the kernel
 746 ## is running in i386 mode, we can help them out.
 747 if test "$machine" = "amdx86-64"; then
 748   AC_CHECK_DECL([i386])
 749   if test "$ac_cv_have_decl_i386" = "yes"; then
 750     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 751     machine=intel386
 752     machfile="m/${machine}.h"
 753   fi
 754 fi
 755
 756 AC_PATH_PROG(INSTALL_INFO, install-info)
 757 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 758 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 759 dnl Don't use GZIP, which is used by gzip for additional parameters.
 760 AC_PATH_PROG(GZIP_PROG, gzip)
 761
 762
 763 ## Need makeinfo >= 4.6 (?) to build the manuals.
 764 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 765 dnl By this stage, configure has already checked for egrep and set EGREP,
 766 dnl or exited with an error if no egrep was found.
 767 if test "$MAKEINFO" != "no" && \
 768   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 769    MAKEINFO=no
 770 fi
 771
 772 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 773 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 774 ## therefore in the category of "special tools" not normally required, which
 775 ## configure does not have to check for (eg autoconf itself).
 776 ## In a Bazaar checkout on the other hand, the manuals are not included.
 777 ## So makeinfo is a requirement to build from Bazaar, and configure
 778 ## should test for it as it does for any other build requirement.
 779 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 780 ## with pre-built manuals, from a Bazaar checkout.
 781 HAVE_MAKEINFO=yes
 782
 783 if test "$MAKEINFO" = "no"; then
 784   MAKEINFO=makeinfo
 785   if test "x${with_makeinfo}" = "xno"; then
 786     HAVE_MAKEINFO=no
 787   elif test ! -e $srcdir/info/emacs; then
 788     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 789 source tree does not seem to have pre-built manuals in the `info' directory.
 790 Either install a suitable version of makeinfo, or re-run configure
 791 with the `--without-makeinfo' option to build without the manuals.] )
 792   fi
 793 fi
 794 AC_SUBST(HAVE_MAKEINFO)
 795
 796 dnl Add our options to ac_link now, after it is set up.
 797
 798 if test x$GCC = xyes; then
 799   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 800     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 801 else
 802   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 803     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 804 fi
 805
 806 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 807 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 808 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 809 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 810 dnl if not built to support GNU ld.
 811
 812 late_LDFLAGS=$LDFLAGS
 813 if test x$GCC = xyes; then
 814   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 815 else
 816   LDFLAGS="$LDFLAGS -znocombreloc"
 817 fi
 818
 819 AC_MSG_CHECKING([for -znocombreloc])
 820 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 821   [AC_MSG_RESULT(yes)],
 822   LDFLAGS=$late_LDFLAGS
 823   [AC_MSG_RESULT(no)])
 824
 825
 826 # The value of CPP is a quoted variable reference, so we need to do this
 827 # to get its actual value...
 828 CPP=`eval "echo $CPP"`
 829
 830
 831 dnl The function dump-emacs will not be defined and temacs will do
 832 dnl (load "loadup") automatically unless told otherwise.
 833 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 834 case "$opsys" in
 835   your-opsys-here) CANNOT_DUMP=yes ;;
 836 esac
 837
 838 test "$CANNOT_DUMP" = "yes" && \
 839   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 840
 841 AC_SUBST(CANNOT_DUMP)
 842
 843
 844 UNEXEC_OBJ=unexelf.o
 845 case "$opsys" in
 846   # MSDOS uses unexcoff.o
 847   # MSWindows uses unexw32.o
 848   aix4-2)
 849    UNEXEC_OBJ=unexaix.o
 850    ;;
 851   cygwin)
 852    UNEXEC_OBJ=unexcw.o
 853    ;;
 854   darwin)
 855    UNEXEC_OBJ=unexmacosx.o
 856    ;;
 857   hpux10-20 | hpux11)
 858    UNEXEC_OBJ=unexhp9k800.o
 859    ;;
 860   sol2-10)
 861    # Use the Solaris dldump() function, called from unexsol.c, to dump
 862    # emacs, instead of the generic ELF dump code found in unexelf.c.
 863    # The resulting binary has a complete symbol table, and is better
 864    # for debugging and other observability tools (debuggers, pstack, etc).
 865    #
 866    # If you encounter a problem using dldump(), please consider sending
 867    # a message to the OpenSolaris tools-linking mailing list:
 868    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 869    #
 870    # It is likely that dldump() works with older Solaris too, but this has
 871    # not been tested, so for now this change is for Solaris 10 or newer.
 872    UNEXEC_OBJ=unexsol.o
 873    ;;
 874 esac
 875
 876 LD_SWITCH_SYSTEM=
 877 case "$opsys" in
 878   freebsd)
 879    ## Let `ld' find image libs and similar things in /usr/local/lib.
 880    ## The system compiler, GCC, has apparently been modified to not
 881    ## look there, contrary to what a stock GCC would do.
 882    LD_SWITCH_SYSTEM=-L/usr/local/lib
 883    ;;
 884
 885   gnu-linux)
 886    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 887    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 888    ;;
 889
 890   netbsd)
 891    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 892    ;;
 893
 894   openbsd)
 895    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 896    ## otherwise Emacs dumps core on elf systems.
 897    LD_SWITCH_SYSTEM="-Z"
 898    ;;
 899 esac
 900 AC_SUBST(LD_SWITCH_SYSTEM)
 901
 902 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 903
 904 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 905 ## which has not been defined yet.  When this was handled with cpp,
 906 ## it was expanded to null when configure sourced the s/*.h file.
 907 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 908 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 909 ## (or somesuch), but because it is supposed to go at the _front_
 910 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 911 ## Compare with the gnu-linux case below, which added to the end
 912 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 913 ## LD_SWITCH_SYSTEM_TEMACS.
 914 case "$opsys" in
 915   netbsd|openbsd)
 916    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 917    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 918 esac
 919
 920
 921 C_SWITCH_MACHINE=
 922 if test "$machine" = "alpha"; then
 923   AC_CHECK_DECL([__ELF__])
 924   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 925     ## With ELF, make sure that all common symbols get allocated to in the
 926     ## data section.  Otherwise, the dump of temacs may miss variables in
 927     ## the shared library that have been initialized.  For example, with
 928     ## GNU libc, __malloc_initialized would normally be resolved to the
 929     ## shared library's .bss section, which is fatal.
 930     if test "x$GCC" = "xyes"; then
 931       C_SWITCH_MACHINE="-fno-common"
 932     else
 933       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 934     fi
 935   else
 936     UNEXEC_OBJ=unexalpha.o
 937   fi
 938 fi
 939 AC_SUBST(C_SWITCH_MACHINE)
 940
 941 AC_SUBST(UNEXEC_OBJ)
 942
 943 C_SWITCH_SYSTEM=
 944 ## Some programs in src produce warnings saying certain subprograms
 945 ## are too complex and need a MAXMEM value greater than 2000 for
 946 ## additional optimization.  --nils@exp-math.uni-essen.de
 947 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 948   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 949 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 950 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 951 AC_SUBST(C_SWITCH_SYSTEM)
 952
 953
 954 LIBS_SYSTEM=
 955 case "$opsys" in
 956   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 957   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 958
 959   freebsd) LIBS_SYSTEM="-lutil" ;;
 960
 961   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 962
 963   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 964
 965   ## Motif needs -lgen.
 966   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 967 esac
 968 AC_SUBST(LIBS_SYSTEM)
 969
 970
 971 ### Make sure subsequent tests use flags consistent with the build flags.
 972
 973 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 974   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 975 else
 976   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 977 fi
 978
 979 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 980 AC_DEFUN([AC_TYPE_SIZE_T])
 981
 982 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 983 AC_SYS_LARGEFILE
 984
 985
 986 ## If user specified a crt-dir, use that unconditionally.
 987 if test "X$CRT_DIR" = "X"; then
 988
 989   case "$canonical" in
 990     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
 991     ## On x86-64 and s390x GNU/Linux distributions, the standard library
 992     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
 993     ## For anything else (eg /usr/lib32), it is up the user to specify
 994     ## the location (bug#5655).
 995     ## Test for crtn.o, not just the directory, because sometimes the
 996     ## directory exists but does not have the relevant files (bug#1287).
 997     ## FIXME better to test for binary compatibility somehow.
 998     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
 999     ;;
1000
1001     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1002   esac
1003
1004   case "$opsys" in
1005     hpux10-20) CRT_DIR=/lib ;;
1006   esac
1007
1008   ## Default is /usr/lib.
1009   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1010
1011 else
1012
1013   ## Some platforms don't use any of these files, so it is not
1014   ## appropriate to put this test outside the if block.
1015   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1016     AC_MSG_ERROR([crt*.o not found in specified location.])
1017
1018 fi
1019
1020 AC_SUBST(CRT_DIR)
1021
1022 LIB_MATH=-lm
1023 LIB_STANDARD=
1024 START_FILES=
1025
1026 case $opsys in
1027   cygwin )
1028     LIB_MATH=
1029     START_FILES='pre-crt0.o'
1030     ;;
1031   darwin )
1032     ## Adding -lm confuses the dynamic linker, so omit it.
1033     LIB_MATH=
1034     START_FILES='pre-crt0.o'
1035     ;;
1036   freebsd )
1037     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1038     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1039     ;;
1040   gnu-linux | gnu-kfreebsd )
1041     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1042     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1043     ;;
1044   hpux10-20 | hpux11 )
1045     LIB_STANDARD=-lc
1046     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1047     ;;
1048   netbsd | openbsd )
1049     if test -f $CRT_DIR/crti.o; then
1050         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1051         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1052     else
1053         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1054         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1055     fi
1056     ;;
1057 esac
1058
1059 AC_SUBST(LIB_MATH)
1060 AC_SUBST(START_FILES)
1061
1062 dnl This function definition taken from Gnome 2.0
1063 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1064 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1065 dnl also defines GSTUFF_PKG_ERRORS on error
1066 AC_DEFUN([PKG_CHECK_MODULES], [
1067   succeeded=no
1068
1069   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1070
1071   if test "$PKG_CONFIG" = "no" ; then
1072      ifelse([$4], , [AC_MSG_ERROR([
1073       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1074   else
1075      PKG_CONFIG_MIN_VERSION=0.9.0
1076      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1077         AC_MSG_CHECKING(for $2)
1078
1079         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1080             AC_MSG_RESULT(yes)
1081             succeeded=yes
1082
1083             AC_MSG_CHECKING($1_CFLAGS)
1084             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1085             AC_MSG_RESULT($$1_CFLAGS)
1086
1087             AC_MSG_CHECKING($1_LIBS)
1088             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1089             AC_MSG_RESULT($$1_LIBS)
1090         else
1091             AC_MSG_RESULT(no)
1092             $1_CFLAGS=""
1093             $1_LIBS=""
1094             ## If we have a custom action on failure, don't print errors, but
1095             ## do set a variable so people can do so.
1096             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1097             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1098         fi
1099
1100         AC_SUBST($1_CFLAGS)
1101         AC_SUBST($1_LIBS)
1102      else
1103         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1104         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1105      fi
1106   fi
1107
1108   if test $succeeded = yes; then
1109      ifelse([$3], , :, [$3])
1110   else
1111      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1112   fi
1113 ])
1114
1115
1116 if test "${with_sound}" != "no"; then
1117   # Sound support for GNU/Linux and the free BSDs.
1118   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1119     have_sound_header=yes)
1120   # Emulation library used on NetBSD.
1121   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1122   AC_SUBST(LIBSOUND)
1123
1124   ALSA_REQUIRED=1.0.0
1125   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1126   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1127   if test $HAVE_ALSA = yes; then
1128     SAVE_CFLAGS="$CFLAGS"
1129     SAVE_LDFLAGS="$LDFLAGS"
1130     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1131     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1132     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1133                     emacs_alsa_normal=yes,
1134                     emacs_alsa_normal=no)
1135     if test "$emacs_alsa_normal" != yes; then
1136       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1137                      [[snd_lib_error_set_handler (0);]])],
1138                      emacs_alsa_subdir=yes,
1139                      emacs_alsa_subdir=no)
1140       if test "$emacs_alsa_subdir" != yes; then
1141         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1142       fi
1143       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1144     fi
1145
1146     CFLAGS="$SAVE_CFLAGS"
1147     LDFLAGS="$SAVE_LDFLAGS"
1148     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1149     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1150     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1151   fi
1152
1153   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1154   dnl compiles only on the specified platforms.  For others, it
1155   dnl probably doesn't make sense to try.
1156   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1157      case "$opsys" in
1158        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1159        gnu-linux|freebsd|netbsd)
1160          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1161          ;;
1162      esac
1163   fi
1164
1165   AC_SUBST(CFLAGS_SOUND)
1166 fi
1167
1168 dnl checks for header files
1169 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1170   linux/version.h sys/systeminfo.h limits.h \
1171   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1172   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1173   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1174
1175 AC_MSG_CHECKING(if personality LINUX32 can be set)
1176 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1177                emacs_cv_personality_linux32=yes,
1178                emacs_cv_personality_linux32=no)
1179 AC_MSG_RESULT($emacs_cv_personality_linux32)
1180
1181 if test $emacs_cv_personality_linux32 = yes; then
1182   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1183             [Define to 1 if personality LINUX32 can be set.])
1184 fi
1185
1186 dnl On Solaris 8 there's a compilation warning for term.h because
1187 dnl it doesn't define `bool'.
1188 AC_CHECK_HEADERS(term.h, , , -)
1189 AC_HEADER_STDC
1190 AC_HEADER_TIME
1191 AC_CHECK_DECLS([sys_siglist])
1192 if test $ac_cv_have_decl_sys_siglist != yes; then
1193   # For Tru64, at least:
1194   AC_CHECK_DECLS([__sys_siglist])
1195   if test $ac_cv_have_decl___sys_siglist = yes; then
1196     AC_DEFINE(sys_siglist, __sys_siglist,
1197               [Define to any substitute for sys_siglist.])
1198   fi
1199 fi
1200 AC_HEADER_SYS_WAIT
1201
1202 dnl Some systems have utime.h but don't declare the struct anyplace.
1203 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1204 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1205 #include <sys/time.h>
1206 #include <time.h>
1207 #else
1208 #ifdef HAVE_SYS_TIME_H
1209 #include <sys/time.h>
1210 #else
1211 #include <time.h>
1212 #endif
1213 #endif
1214 #ifdef HAVE_UTIME_H
1215 #include <utime.h>
1216 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1217   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1218 if test $emacs_cv_struct_utimbuf = yes; then
1219   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1220 fi
1221
1222 dnl Check for speed_t typedef.
1223 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1224   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1225     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1226 if test $emacs_cv_speed_t = yes; then
1227   AC_DEFINE(HAVE_SPEED_T, 1,
1228            [Define to 1 if `speed_t' is declared by <termios.h>.])
1229 fi
1230
1231 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1232 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1233 #include <sys/time.h>
1234 #include <time.h>
1235 #else
1236 #ifdef HAVE_SYS_TIME_H
1237 #include <sys/time.h>
1238 #else
1239 #include <time.h>
1240 #endif
1241 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1242   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1243 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1244 if test $emacs_cv_struct_timeval = yes; then
1245   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1246 fi
1247
1248 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1249 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1250 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1251   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1252 HAVE_EXCEPTION=$emacs_cv_struct_exception
1253 if test $emacs_cv_struct_exception != yes; then
1254   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1255 fi
1256
1257 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1258 #if HAVE_SYS_SOCKET_H
1259 #include <sys/socket.h>
1260 #endif])
1261
1262 dnl checks for structure members
1263 AC_STRUCT_TM
1264 AC_STRUCT_TIMEZONE
1265 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1266                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1267                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1268                 [#include <time.h>])
1269 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1270                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1271                   struct ifreq.ifr_addr], , ,
1272                  [AC_INCLUDES_DEFAULT
1273 #if HAVE_SYS_SOCKET_H
1274 #include <sys/socket.h>
1275 #endif
1276 #if HAVE_NET_IF_H
1277 #include <net/if.h>
1278 #endif])
1279
1280 dnl checks for compiler characteristics
1281
1282 dnl Testing __STDC__ to determine prototype support isn't good enough.
1283 dnl DEC C, for instance, doesn't define it with default options, and
1284 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1285 dnl and void *.
1286 AC_C_PROTOTYPES
1287 AC_C_VOLATILE
1288 AC_C_CONST
1289 dnl This isn't useful because we can't turn on use of `inline' unless
1290 dnl the compiler groks `extern inline'.
1291 dnl AC_C_INLINE
1292 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1293   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1294                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1295 if test $emacs_cv_void_star = yes; then
1296   AC_DEFINE(POINTER_TYPE, void)
1297 else
1298   AC_DEFINE(POINTER_TYPE, char)
1299 fi
1300 AH_TEMPLATE(POINTER_TYPE,
1301             [Define as `void' if your compiler accepts `void *'; otherwise
1302              define as `char'.])dnl
1303
1304 dnl Check for endianess
1305 AC_C_BIGENDIAN
1306
1307 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1308   [emacs_cv_attribute_aligned],
1309   [AC_COMPILE_IFELSE(
1310      [AC_LANG_PROGRAM(
1311         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1312         [[]])],
1313      [emacs_cv_attribute_aligned=yes],
1314      [emacs_cv_attribute_aligned=no])])
1315 if test $emacs_cv_attribute_aligned = yes; then
1316   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1317     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1318 fi
1319
1320 dnl check for Make feature
1321 AC_PROG_MAKE_SET
1322
1323 DEPFLAGS=
1324 MKDEPDIR=":"
1325 deps_frag=deps.mk
1326 dnl check for GNU Make if we have GCC and autodepend is on.
1327 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1328    AC_MSG_CHECKING([whether we are using GNU Make])
1329    HAVE_GNU_MAKE=no
1330    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1331    if test "x$testval" != x; then
1332       HAVE_GNU_MAKE=yes
1333    else
1334       ac_enable_autodepend=no
1335    fi
1336    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1337    if test $HAVE_GNU_MAKE = yes; then
1338       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1339       SAVE_CFLAGS="$CFLAGS"
1340       CFLAGS="$CFLAGS -MMD -MF deps.d"
1341       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1342       CFLAGS="$SAVE_CFLAGS"
1343       test -f deps.d || ac_enable_autodepend=no
1344       rm -rf deps.d
1345       AC_MSG_RESULT([$ac_enable_autodepend])
1346    fi
1347    if test $ac_enable_autodepend = yes; then
1348       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1349       ## In parallel builds, another make might create depdir between
1350       ## the first test and mkdir, so stick another test on the end.
1351       ## Or use install-sh -d?  mkdir -p is not portable.
1352       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1353       deps_frag=autodeps.mk
1354    fi
1355 fi
1356 deps_frag=$srcdir/src/$deps_frag
1357 AC_SUBST(MKDEPDIR)
1358 AC_SUBST(DEPFLAGS)
1359 AC_SUBST_FILE(deps_frag)
1360
1361
1362 lisp_frag=$srcdir/src/lisp.mk
1363 AC_SUBST_FILE(lisp_frag)
1364
1365
1366 dnl checks for operating system services
1367 AC_SYS_LONG_FILE_NAMES
1368
1369 #### Choose a window system.
1370
1371 AC_PATH_X
1372 if test "$no_x" = yes; then
1373   window_system=none
1374 else
1375   window_system=x11
1376 fi
1377
1378 ## Workaround for bug in autoconf <= 2.62.
1379 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1380 ## No need to do anything special for these standard directories.
1381 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1382
1383    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1384
1385 fi
1386
1387 LD_SWITCH_X_SITE_AUX=
1388 LD_SWITCH_X_SITE_AUX_RPATH=
1389 if test "${x_libraries}" != NONE; then
1390   if test -n "${x_libraries}"; then
1391     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1392     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1393     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1394   fi
1395   x_default_search_path=""
1396   x_search_path=${x_libraries}
1397   if test -z "${x_search_path}"; then
1398     x_search_path=/usr/lib
1399   fi
1400   for x_library in `echo ${x_search_path}: | \
1401                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1402     x_search_path="\
1403 ${x_library}/X11/%L/%T/%N%C%S:\
1404 ${x_library}/X11/%l/%T/%N%C%S:\
1405 ${x_library}/X11/%T/%N%C%S:\
1406 ${x_library}/X11/%L/%T/%N%S:\
1407 ${x_library}/X11/%l/%T/%N%S:\
1408 ${x_library}/X11/%T/%N%S"
1409     if test x"${x_default_search_path}" = x; then
1410       x_default_search_path=${x_search_path}
1411     else
1412       x_default_search_path="${x_search_path}:${x_default_search_path}"
1413     fi
1414   done
1415 fi
1416 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1417 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1418
1419 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1420   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1421 fi
1422
1423 if test x"${x_includes}" = x; then
1424   bitmapdir=/usr/include/X11/bitmaps
1425 else
1426   # accumulate include directories that have X11 bitmap subdirectories
1427   bmd_acc="dummyval"
1428   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1429     if test -d "${bmd}/X11/bitmaps"; then
1430       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1431     fi
1432     if test -d "${bmd}/bitmaps"; then
1433       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1434     fi
1435   done
1436   if test ${bmd_acc} != "dummyval"; then
1437     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1438   fi
1439 fi
1440
1441 HAVE_NS=no
1442 NS_IMPL_COCOA=no
1443 NS_IMPL_GNUSTEP=no
1444 tmp_CPPFLAGS="$CPPFLAGS"
1445 tmp_CFLAGS="$CFLAGS"
1446 CPPFLAGS="$CPPFLAGS -x objective-c"
1447 CFLAGS="$CFLAGS -x objective-c"
1448 TEMACS_LDFLAGS2="\${LDFLAGS}"
1449 dnl I don't think it's especially important, but src/Makefile.in
1450 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1451 dnl trailing "/" to it, so now we do it here.
1452 if test "${with_ns}" != no; then
1453   if test "${opsys}" = darwin; then
1454      NS_IMPL_COCOA=yes
1455      ns_appdir=`pwd`/nextstep/Emacs.app
1456      ns_appbindir=${ns_appdir}/Contents/MacOS/
1457      ns_appresdir=${ns_appdir}/Contents/Resources
1458      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1459   elif test -f $GNUSTEP_CONFIG_FILE; then
1460      NS_IMPL_GNUSTEP=yes
1461      ns_appdir=`pwd`/nextstep/Emacs.app
1462      ns_appbindir=${ns_appdir}/
1463      ns_appresdir=${ns_appdir}/Resources
1464      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1465      dnl FIXME sourcing this several times in subshells seems inefficient.
1466      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1467      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1468      dnl I seemed to need these as well with GNUstep-startup 0.25.
1469      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1470      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1471      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1472        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1473      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1474        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1475      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1476      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1477      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1478      LIB_STANDARD=
1479      START_FILES=
1480      TEMACS_LDFLAGS2=
1481   fi
1482   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1483                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1484   files are missing or cannot be compiled.])])
1485   NS_HAVE_NSINTEGER=yes
1486   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1487                                      [NSInteger i;])],
1488                     ns_have_nsinteger=yes,
1489                     ns_have_nsinteger=no)
1490   if test $ns_have_nsinteger = no; then
1491     NS_HAVE_NSINTEGER=no
1492   fi
1493 fi
1494 AC_SUBST(TEMACS_LDFLAGS2)
1495
1496 ns_frag=/dev/null
1497 NS_OBJ=
1498 NS_OBJC_OBJ=
1499 if test "${HAVE_NS}" = yes; then
1500   window_system=nextstep
1501   with_xft=no
1502   # set up packaging dirs
1503   exec_prefix=${ns_appbindir}
1504   libexecdir=${ns_appbindir}/libexec
1505   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1506      prefix=${ns_appresdir}
1507   fi
1508   ns_frag=$srcdir/src/ns.mk
1509   NS_OBJ="fontset.o fringe.o image.o"
1510   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1511 fi
1512 CFLAGS="$tmp_CFLAGS"
1513 CPPFLAGS="$tmp_CPPFLAGS"
1514 AC_SUBST(NS_OBJ)
1515 AC_SUBST(NS_OBJC_OBJ)
1516 AC_SUBST(LIB_STANDARD)
1517 AC_SUBST_FILE(ns_frag)
1518
1519 case "${window_system}" in
1520   x11 )
1521     HAVE_X_WINDOWS=yes
1522     HAVE_X11=yes
1523     case "${with_x_toolkit}" in
1524       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1525       motif ) USE_X_TOOLKIT=MOTIF ;;
1526       gtk ) with_gtk=yes
1527 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1528 dnl USE_X_TOOLKIT is set.
1529             USE_X_TOOLKIT=none ;;
1530       gtk3 ) with_gtk3=yes
1531              USE_X_TOOLKIT=none ;;
1532       no ) USE_X_TOOLKIT=none ;;
1533 dnl If user did not say whether to use a toolkit, make this decision later:
1534 dnl use the toolkit if we have gtk, or X11R5 or newer.
1535       * ) USE_X_TOOLKIT=maybe ;;
1536     esac
1537   ;;
1538   nextstep | none )
1539     HAVE_X_WINDOWS=no
1540     HAVE_X11=no
1541     USE_X_TOOLKIT=none
1542   ;;
1543 esac
1544
1545 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1546    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1547    if test "$HAVE_XSERVER" = true ||
1548       test -n "$DISPLAY" ||
1549       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1550         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1551 were found.  You should install the relevant development files for X
1552 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1553 sure you have development files for image handling, i.e.
1554 tiff, gif, jpeg, png and xpm.
1555 If you are sure you want Emacs compiled without X window support, pass
1556   --without-x
1557 to configure.])
1558    fi
1559 fi
1560
1561 ### If we're using X11, we should use the X menu package.
1562 HAVE_MENUS=no
1563 case ${HAVE_X11} in
1564   yes ) HAVE_MENUS=yes ;;
1565 esac
1566
1567 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1568 # Assume not, until told otherwise.
1569 GNU_MALLOC=yes
1570 doug_lea_malloc=yes
1571 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1572 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1573 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1574                emacs_cv_var___after_morecore_hook,
1575 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1576   emacs_cv_var___after_morecore_hook=yes,
1577   emacs_cv_var___after_morecore_hook=no)])
1578 if test $emacs_cv_var___after_morecore_hook = no; then
1579   doug_lea_malloc=no
1580 fi
1581
1582
1583 dnl See comments in aix4-2.h about maybe using system malloc there.
1584 system_malloc=no
1585 case "$opsys" in
1586   ## darwin ld insists on the use of malloc routines in the System framework.
1587   darwin|sol2-10) system_malloc=yes ;;
1588 esac
1589
1590 if test "${system_malloc}" = "yes"; then
1591   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1592   GNU_MALLOC=no
1593   GNU_MALLOC_reason="
1594     (The GNU allocators don't work with this system configuration.)"
1595   GMALLOC_OBJ=
1596   VMLIMIT_OBJ=
1597 else
1598   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1599   VMLIMIT_OBJ=vm-limit.o
1600 fi
1601 AC_SUBST(GMALLOC_OBJ)
1602 AC_SUBST(VMLIMIT_OBJ)
1603
1604 if test "$doug_lea_malloc" = "yes" ; then
1605   if test "$GNU_MALLOC" = yes ; then
1606     GNU_MALLOC_reason="
1607       (Using Doug Lea's new malloc from the GNU C Library.)"
1608   fi
1609   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1610             [Define to 1 if you are using the GNU C Library.])
1611
1612   ## Use mmap directly for allocating larger buffers.
1613   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1614   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1615   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1616   case "$opsys" in
1617     gnu*) REL_ALLOC=no ;;
1618   esac
1619 fi
1620
1621 if test x"${REL_ALLOC}" = x; then
1622   REL_ALLOC=${GNU_MALLOC}
1623 fi
1624
1625 use_mmap_for_buffers=no
1626 case "$opsys" in
1627   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1628 esac
1629
1630 AC_FUNC_MMAP
1631 if test $use_mmap_for_buffers = yes; then
1632   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1633   REL_ALLOC=no
1634 fi
1635
1636 LIBS="$LIBS_SYSTEM $LIBS"
1637
1638 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1639 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1640 AC_CHECK_LIB(dnet, dnet_ntoa)
1641 dnl This causes -lresolv to get used in subsequent tests,
1642 dnl which causes failures on some systems such as HPUX 9.
1643 dnl AC_CHECK_LIB(resolv, gethostbyname)
1644
1645 dnl FIXME replace main with a function we actually want from this library.
1646 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1647
1648 AC_CHECK_LIB(pthreads, cma_open)
1649
1650 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1651 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1652 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1653 ## added to LIBS in configure would never contain the pthreads part,
1654 ## but the value used in Makefiles might.  FIXME?
1655 ##
1656 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1657 ## be harmless on older versions of X where it happens to exist.
1658 test "$opsys" = "aix4-2" && \
1659   test $ac_cv_lib_pthreads_cma_open = yes && \
1660   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1661
1662 dnl Check for need for bigtoc support on IBM AIX
1663
1664 case ${host_os} in
1665 aix*)
1666   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1667     case $GCC in
1668     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1669     *) gdb_cv_bigtoc=-bbigtoc ;;
1670     esac
1671
1672     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1673     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1674   ])
1675   ;;
1676 esac
1677
1678 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1679 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1680 # REAL_CPPFLAGS later on.
1681
1682 REAL_CFLAGS="$CFLAGS"
1683 REAL_CPPFLAGS="$CPPFLAGS"
1684
1685 if test "${HAVE_X11}" = "yes"; then
1686   DEFS="$C_SWITCH_X_SITE $DEFS"
1687   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1688   LIBS="-lX11 $LIBS"
1689   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1690   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1691
1692   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1693   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1694   # but it's more convenient here to set LD_RUN_PATH
1695   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1696   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1697     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1698     export LD_RUN_PATH
1699   fi
1700
1701   if test "${opsys}" = "gnu-linux"; then
1702     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1703     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1704      [[XOpenDisplay ("foo");]])],
1705      [xlinux_first_failure=no],
1706      [xlinux_first_failure=yes])
1707     if test "${xlinux_first_failure}" = "yes"; then
1708       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1709       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1710       OLD_CPPFLAGS="$CPPFLAGS"
1711       OLD_LIBS="$LIBS"
1712       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1713       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1714       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1715       LIBS="$LIBS -b i486-linuxaout"
1716       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1717        [[XOpenDisplay ("foo");]])],
1718        [xlinux_second_failure=no],
1719        [xlinux_second_failure=yes])
1720       if test "${xlinux_second_failure}" = "yes"; then
1721         # If we get the same failure with -b, there is no use adding -b.
1722         # So take it out.  This plays safe.
1723         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1724         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1725         CPPFLAGS="$OLD_CPPFLAGS"
1726         LIBS="$OLD_LIBS"
1727         AC_MSG_RESULT(no)
1728       else
1729         AC_MSG_RESULT(yes)
1730       fi
1731     else
1732       AC_MSG_RESULT(no)
1733     fi
1734   fi
1735
1736   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1737   # header files included from there.
1738   AC_MSG_CHECKING(for Xkb)
1739   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1740 #include <X11/XKBlib.h>]],
1741         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1742         emacs_xkb=yes, emacs_xkb=no)
1743   AC_MSG_RESULT($emacs_xkb)
1744   if test $emacs_xkb = yes; then
1745     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1746   fi
1747
1748   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1749 XScreenNumberOfScreen XSetWMProtocols)
1750 fi
1751
1752 if test "${window_system}" = "x11"; then
1753   AC_MSG_CHECKING(X11 version 6)
1754   AC_CACHE_VAL(emacs_cv_x11_version_6,
1755   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1756 [[#if XlibSpecificationRelease < 6
1757 fail;
1758 #endif
1759 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1760   if test $emacs_cv_x11_version_6 = yes; then
1761     AC_MSG_RESULT(6 or newer)
1762     AC_DEFINE(HAVE_X11R6, 1,
1763               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1764     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1765     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1766     ## XIM support.
1767     case "$opsys" in
1768       sol2-*) : ;;
1769       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1770            [Define if you have usable X11R6-style XIM support.])
1771          ;;
1772     esac
1773   else
1774     AC_MSG_RESULT(before 6)
1775   fi
1776 fi
1777
1778
1779 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1780 HAVE_RSVG=no
1781 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1782   if test "${with_rsvg}" != "no"; then
1783     RSVG_REQUIRED=2.11.0
1784     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1785
1786     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1787     AC_SUBST(RSVG_CFLAGS)
1788     AC_SUBST(RSVG_LIBS)
1789
1790     if test $HAVE_RSVG = yes; then
1791       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1792       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1793       LIBS="$RSVG_LIBS $LIBS"
1794     fi
1795   fi
1796 fi
1797
1798 HAVE_IMAGEMAGICK=no
1799 if test "${HAVE_X11}" = "yes"; then
1800   if test "${with_imagemagick}" != "no"; then
1801     ## 6.2.8 is the earliest version known to work, but earlier versions
1802     ## might work - let us know if you find one.
1803     ## 6.0.7 does not work.  See bug#7955.
1804     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1805     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1806     AC_SUBST(IMAGEMAGICK_CFLAGS)
1807     AC_SUBST(IMAGEMAGICK_LIBS)
1808
1809     if test $HAVE_IMAGEMAGICK = yes; then
1810       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1811       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1812       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1813       AC_CHECK_FUNCS(MagickExportImagePixels)
1814     fi
1815   fi
1816 fi
1817
1818
1819 HAVE_GTK=no
1820 if test "${with_gtk3}" = "yes"; then
1821   GLIB_REQUIRED=2.28
1822   GTK_REQUIRED=3.0
1823   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1824
1825   dnl Checks for libraries.
1826   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1827   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1828      AC_MSG_ERROR($GTK_PKG_ERRORS)
1829   fi
1830   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1831 fi
1832
1833 if test "$pkg_check_gtk" != "yes"; then
1834   HAVE_GTK=no
1835 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1836   GLIB_REQUIRED=2.6
1837   GTK_REQUIRED=2.6
1838   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1839
1840   dnl Checks for libraries.
1841   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1842   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1843      AC_MSG_ERROR($GTK_PKG_ERRORS)
1844   fi
1845 fi
1846 fi
1847
1848 GTK_OBJ=
1849 if test x"$pkg_check_gtk" = xyes; then
1850
1851   AC_SUBST(GTK_CFLAGS)
1852   AC_SUBST(GTK_LIBS)
1853   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1854   CFLAGS="$CFLAGS $GTK_CFLAGS"
1855   LIBS="$GTK_LIBS $LIBS"
1856   dnl Try to compile a simple GTK program.
1857   GTK_COMPILES=no
1858   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1859   if test "${GTK_COMPILES}" != "yes"; then
1860     if test "$USE_X_TOOLKIT" != "maybe"; then
1861       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1862     fi
1863   else
1864     HAVE_GTK=yes
1865     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1866     GTK_OBJ=gtkutil.o
1867     USE_X_TOOLKIT=none
1868     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1869       :
1870     else
1871       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1872        closing open displays.  This is no problem if you just use
1873        one display, but if you use more than one and close one of them
1874        Emacs may crash.]])
1875       sleep 3
1876     fi
1877   fi
1878
1879 fi
1880 AC_SUBST(GTK_OBJ)
1881
1882
1883 if test "${HAVE_GTK}" = "yes"; then
1884
1885   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1886   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1887   if test "$with_toolkit_scroll_bars" != no; then
1888     with_toolkit_scroll_bars=yes
1889   fi
1890
1891   dnl  Check if we have the old file selection dialog declared and
1892   dnl  in the link library.  In 2.x it may be in the library,
1893   dnl  but not declared if deprecated featured has been selected out.
1894   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1895   HAVE_GTK_FILE_SELECTION=no
1896   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1897                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1898 #include <gtk/gtk.h>])
1899   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1900     AC_CHECK_FUNCS(gtk_file_selection_new)
1901   fi
1902
1903   dnl Check if pthreads are available.  Emacs only needs this when using
1904   dnl gtk_file_chooser under Gnome.
1905     HAVE_GTK_AND_PTHREAD=no
1906     AC_CHECK_HEADERS(pthread.h)
1907     if test "$ac_cv_header_pthread_h"; then
1908       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1909     fi
1910     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1911       case "${canonical}" in
1912         *-hpux*) ;;
1913         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1914       esac
1915       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1916                [Define to 1 if you have GTK and pthread (-lpthread).])
1917     fi
1918
1919   dnl Check for functions introduced in 2.14 and later.
1920   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1921                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1922                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1923                  gtk_orientable_set_orientation)
1924
1925 fi
1926
1927 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1928 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1929 dnl also not configured.
1930 HAVE_DBUS=no
1931 DBUS_OBJ=
1932 if test "${with_dbus}" = "yes"; then
1933    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1934    if test "$HAVE_DBUS" = yes; then
1935      LIBS="$LIBS $DBUS_LIBS"
1936      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1937      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1938      DBUS_OBJ=dbusbind.o
1939    fi
1940 fi
1941 AC_SUBST(DBUS_OBJ)
1942
1943 dnl GConf has been tested under GNU/Linux only.
1944 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1945 HAVE_GCONF=no
1946 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1947    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1948    if test "$HAVE_GCONF" = yes; then
1949       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1950       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1951       AC_CHECK_FUNCS([g_type_init])
1952    fi
1953 fi
1954
1955 dnl SELinux is available for GNU/Linux only.
1956 HAVE_LIBSELINUX=no
1957 LIBSELINUX_LIBS=
1958 if test "${with_selinux}" = "yes"; then
1959    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1960    if test "$HAVE_LIBSELINUX" = yes; then
1961       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1962       LIBSELINUX_LIBS=-lselinux
1963    fi
1964 fi
1965 AC_SUBST(LIBSELINUX_LIBS)
1966
1967 HAVE_GNUTLS=no
1968 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
1969 if test "${with_gnutls}" = "yes" ; then
1970   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1971   if test "${HAVE_GNUTLS}" = "yes"; then
1972     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1973   fi
1974
1975   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
1976   LIBS="$LIBGNUTLS_LIBS $LIBS"
1977   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
1978
1979   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
1980     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
1981   fi
1982 fi
1983
1984 AC_SUBST(LIBGNUTLS_LIBS)
1985 AC_SUBST(LIBGNUTLS_CFLAGS)
1986
1987 dnl Do not put whitespace before the #include statements below.
1988 dnl Older compilers (eg sunos4 cc) choke on it.
1989 HAVE_XAW3D=no
1990 LUCID_LIBW=
1991 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1992   if test "$with_xaw3d" != no; then
1993     AC_MSG_CHECKING(for xaw3d)
1994     AC_CACHE_VAL(emacs_cv_xaw3d,
1995     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1996 #include <X11/Intrinsic.h>
1997 #include <X11/Xaw3d/Simple.h>]],
1998       [[]])],
1999       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2000                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2001       emacs_cv_xaw3d=no)])
2002   else
2003     emacs_cv_xaw3d=no
2004   fi
2005   if test $emacs_cv_xaw3d = yes; then
2006     AC_MSG_RESULT([yes; using Lucid toolkit])
2007     USE_X_TOOLKIT=LUCID
2008     HAVE_XAW3D=yes
2009     LUCID_LIBW=-lXaw3d
2010     AC_DEFINE(HAVE_XAW3D, 1,
2011               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2012   else
2013     AC_MSG_RESULT(no)
2014     AC_MSG_CHECKING(for libXaw)
2015     AC_CACHE_VAL(emacs_cv_xaw,
2016     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2017 #include <X11/Intrinsic.h>
2018 #include <X11/Xaw/Simple.h>]],
2019       [[]])],
2020       emacs_cv_xaw=yes,
2021       emacs_cv_xaw=no)])
2022     if test $emacs_cv_xaw = yes; then
2023       AC_MSG_RESULT([yes; using Lucid toolkit])
2024       USE_X_TOOLKIT=LUCID
2025       LUCID_LIBW=-lXaw
2026     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2027       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2028     else
2029       AC_MSG_ERROR([No X toolkit could be found.
2030 If you are sure you want Emacs compiled without an X toolkit, pass
2031   --with-x-toolkit=no
2032 to configure.  Otherwise, install the development libraries for the toolkit
2033 that you want to use (e.g. Gtk+) and re-run configure.])
2034     fi
2035   fi
2036 fi
2037
2038 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2039
2040 LIBXTR6=
2041 if test "${USE_X_TOOLKIT}" != "none"; then
2042   AC_MSG_CHECKING(X11 toolkit version)
2043   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2044   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2045 [[#if XtSpecificationRelease < 6
2046 fail;
2047 #endif
2048 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2049   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2050   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2051     AC_MSG_RESULT(6 or newer)
2052     AC_DEFINE(HAVE_X11XTR6, 1,
2053               [Define to 1 if you have the X11R6 or newer version of Xt.])
2054     LIBXTR6="-lSM -lICE"
2055     case "$opsys" in
2056       ## Use libw.a along with X11R6 Xt.
2057       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2058     esac
2059   else
2060     AC_MSG_RESULT(before 6)
2061   fi
2062
2063 dnl If using toolkit, check whether libXmu.a exists.
2064 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2065   OLDLIBS="$LIBS"
2066   if test x$HAVE_X11XTR6 = xyes; then
2067     LIBS="-lXt -lSM -lICE $LIBS"
2068   else
2069     LIBS="-lXt $LIBS"
2070   fi
2071   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2072   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2073 fi
2074 AC_SUBST(LIBXTR6)
2075
2076 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2077 dnl Why not just test for libxmu in the normal way?
2078 LIBXMU=-lXmu
2079 case $opsys in
2080   ## These systems don't supply Xmu.
2081   hpux* | aix4-2 )
2082     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2083     ;;
2084 esac
2085 AC_SUBST(LIBXMU)
2086
2087 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2088 if test "${HAVE_X11}" = "yes"; then
2089   if test "${USE_X_TOOLKIT}" != "none"; then
2090     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2091   fi
2092 fi
2093
2094 LIBXP=
2095 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2096   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2097   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2098     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2099 int x = 5;
2100 #else
2101 Motif version prior to 2.1.
2102 #endif]])],
2103     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2104   if test $emacs_cv_motif_version_2_1 = yes; then
2105     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2106   else
2107     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2108     # We put this in CFLAGS temporarily to precede other -I options
2109     # that might be in CFLAGS temporarily.
2110     # We put this in CPPFLAGS where it precedes the other -I options.
2111     OLD_CPPFLAGS=$CPPFLAGS
2112     OLD_CFLAGS=$CFLAGS
2113     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2114     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2115     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2116       [[int x = 5;]])],
2117       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2118     if test $emacs_cv_lesstif = yes; then
2119       # Make sure this -I option remains in CPPFLAGS after it is set
2120       # back to REAL_CPPFLAGS.
2121       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2122       # have those other -I options anyway.  Ultimately, having this
2123       # directory ultimately in CPPFLAGS will be enough.
2124       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2125       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2126     else
2127       CFLAGS=$OLD_CFLAGS
2128       CPPFLAGS=$OLD_CPPFLAGS
2129     fi
2130   fi
2131 fi
2132
2133 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2134 dnl using Motif or Xaw3d is available, and unless
2135 dnl --with-toolkit-scroll-bars=no was specified.
2136
2137 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2138             [Define to 1 if we should use toolkit scroll bars.])dnl
2139 USE_TOOLKIT_SCROLL_BARS=no
2140 if test "${with_toolkit_scroll_bars}" != "no"; then
2141   if test "${USE_X_TOOLKIT}" != "none"; then
2142     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2143       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2144       HAVE_XAW3D=no
2145       USE_TOOLKIT_SCROLL_BARS=yes
2146     elif test "${HAVE_XAW3D}" = "yes"; then
2147       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2148       USE_TOOLKIT_SCROLL_BARS=yes
2149     fi
2150   elif test "${HAVE_GTK}" = "yes"; then
2151     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2152     USE_TOOLKIT_SCROLL_BARS=yes
2153   elif test "${HAVE_NS}" = "yes"; then
2154     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2155     USE_TOOLKIT_SCROLL_BARS=yes
2156   fi
2157 fi
2158
2159 dnl See if XIM is available.
2160 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2161           #include <X11/Xlib.h>
2162           #include <X11/Xresource.h>]],
2163          [[XIMProc  callback;]])],
2164          [HAVE_XIM=yes
2165          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2166          HAVE_XIM=no)
2167
2168 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2169
2170 if test "${with_xim}" != "no"; then
2171   AC_DEFINE(USE_XIM, 1,
2172             [Define to 1 if we should use XIM, if it is available.])
2173 fi
2174
2175
2176 if test "${HAVE_XIM}" != "no"; then
2177   late_CFLAGS=$CFLAGS
2178   if test "$GCC" = yes; then
2179     CFLAGS="$CFLAGS --pedantic-errors"
2180   fi
2181   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2182 #include <X11/Xlib.h>
2183 #include <X11/Xresource.h>]],
2184 [[Display *display;
2185 XrmDatabase db;
2186 char *res_name;
2187 char *res_class;
2188 XIMProc  callback;
2189 XPointer *client_data;
2190 #ifndef __GNUC__
2191 /* If we're not using GCC, it's probably not XFree86, and this is
2192    probably right, but we can't use something like --pedantic-errors.  */
2193 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2194                                            char*, XIMProc, XPointer*);
2195 #endif
2196 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2197    client_data);]])],
2198     [emacs_cv_arg6_star=yes])
2199   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2200          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2201 either XPointer or XPointer*.])dnl
2202   if test "$emacs_cv_arg6_star" = yes; then
2203     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2204   else
2205     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2206   fi
2207   CFLAGS=$late_CFLAGS
2208 fi
2209
2210 ### Start of font-backend (under any platform) section.
2211 # (nothing here yet -- this is a placeholder)
2212 ### End of font-backend (under any platform) section.
2213
2214 ### Start of font-backend (under X11) section.
2215 if test "${HAVE_X11}" = "yes"; then
2216    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2217
2218    ## Use -lXft if available, unless `--with-xft=no'.
2219    HAVE_XFT=maybe
2220     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2221       with_xft="no";
2222     fi
2223     if test "x${with_xft}" != "xno"; then
2224
2225       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2226       ## Because xftfont.c uses XRenderQueryExtension, we also
2227       ## need to link to -lXrender.
2228       HAVE_XRENDER=no
2229       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2230       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2231         OLD_CPPFLAGS="$CPPFLAGS"
2232         OLD_CFLAGS="$CFLAGS"
2233         OLD_LIBS="$LIBS"
2234         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2235         CFLAGS="$CFLAGS $XFT_CFLAGS"
2236         XFT_LIBS="-lXrender $XFT_LIBS"
2237         LIBS="$XFT_LIBS $LIBS"
2238         AC_CHECK_HEADER(X11/Xft/Xft.h,
2239           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2240
2241         if test "${HAVE_XFT}" = "yes"; then
2242           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2243             AC_SUBST(XFT_LIBS)
2244           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2245         else
2246           CPPFLAGS="$OLD_CPPFLAGS"
2247           CFLAGS="$OLD_CFLAGS"
2248           LIBS="$OLD_LIBS"
2249         fi                        # "${HAVE_XFT}" = "yes"
2250       fi                          # "$HAVE_XFT" != no
2251     fi                            # "x${with_xft}" != "xno"
2252
2253     ## We used to allow building with FreeType and without Xft.
2254     ## However, the ftx font backend driver is not in good shape.
2255     if test "$HAVE_XFT" != "yes"; then
2256        dnl For the "Does Emacs use" message at the end.
2257        HAVE_XFT=no
2258        HAVE_FREETYPE=no
2259     else
2260        dnl Strict linkers fail with
2261        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2262        dnl if -lfreetype is not specified.
2263        dnl The following is needed to set FREETYPE_LIBS.
2264        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2265                          HAVE_FREETYPE=no)
2266
2267        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2268     fi
2269
2270     HAVE_LIBOTF=no
2271     if test "${HAVE_FREETYPE}" = "yes"; then
2272       AC_DEFINE(HAVE_FREETYPE, 1,
2273                 [Define to 1 if using the freetype and fontconfig libraries.])
2274       if test "${with_libotf}" != "no"; then
2275         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2276                           HAVE_LIBOTF=no)
2277         if test "$HAVE_LIBOTF" = "yes"; then
2278           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2279           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2280                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2281                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2282           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2283             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2284                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2285           fi
2286         fi
2287       fi
2288     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2289     dnl Does the new font backend require it, or can it work without it?
2290     fi
2291
2292     HAVE_M17N_FLT=no
2293     if test "${HAVE_LIBOTF}" = yes; then
2294       if test "${with_m17n_flt}" != "no"; then
2295         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2296         if test "$HAVE_M17N_FLT" = "yes"; then
2297           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2298         fi
2299       fi
2300     fi
2301 else
2302     HAVE_XFT=no
2303     HAVE_FREETYPE=no
2304     HAVE_LIBOTF=no
2305     HAVE_M17N_FLT=no
2306 fi
2307
2308 ### End of font-backend (under X11) section.
2309
2310 AC_SUBST(FREETYPE_CFLAGS)
2311 AC_SUBST(FREETYPE_LIBS)
2312 AC_SUBST(FONTCONFIG_CFLAGS)
2313 AC_SUBST(FONTCONFIG_LIBS)
2314 AC_SUBST(LIBOTF_CFLAGS)
2315 AC_SUBST(LIBOTF_LIBS)
2316 AC_SUBST(M17N_FLT_CFLAGS)
2317 AC_SUBST(M17N_FLT_LIBS)
2318
2319 ### Use -lXpm if available, unless `--with-xpm=no'.
2320 HAVE_XPM=no
2321 LIBXPM=
2322 if test "${HAVE_X11}" = "yes"; then
2323   if test "${with_xpm}" != "no"; then
2324     AC_CHECK_HEADER(X11/xpm.h,
2325       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2326     if test "${HAVE_XPM}" = "yes"; then
2327       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2328       AC_EGREP_CPP(no_return_alloc_pixels,
2329       [#include "X11/xpm.h"
2330 #ifndef XpmReturnAllocPixels
2331 no_return_alloc_pixels
2332 #endif
2333       ], HAVE_XPM=no, HAVE_XPM=yes)
2334
2335       if test "${HAVE_XPM}" = "yes"; then
2336         AC_MSG_RESULT(yes)
2337       else
2338         AC_MSG_RESULT(no)
2339       fi
2340     fi
2341   fi
2342
2343   if test "${HAVE_XPM}" = "yes"; then
2344     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2345     LIBXPM=-lXpm
2346   fi
2347 fi
2348 AC_SUBST(LIBXPM)
2349
2350 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2351 HAVE_JPEG=no
2352 LIBJPEG=
2353 if test "${HAVE_X11}" = "yes"; then
2354   if test "${with_jpeg}" != "no"; then
2355     dnl Checking for jpeglib.h can lose because of a redefinition of
2356     dnl  HAVE_STDLIB_H.
2357     AC_CHECK_HEADER(jerror.h,
2358       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2359   fi
2360
2361   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2362   if test "${HAVE_JPEG}" = "yes"; then
2363     AC_DEFINE(HAVE_JPEG)
2364     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2365         [#include <jpeglib.h>
2366          version=JPEG_LIB_VERSION
2367 ],
2368         [AC_DEFINE(HAVE_JPEG)],
2369         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2370         HAVE_JPEG=no])
2371   fi
2372   if test "${HAVE_JPEG}" = "yes"; then
2373     LIBJPEG=-ljpeg
2374   fi
2375 fi
2376 AC_SUBST(LIBJPEG)
2377
2378 ### Use -lpng if available, unless `--with-png=no'.
2379 HAVE_PNG=no
2380 LIBPNG=
2381 if test "${HAVE_X11}" = "yes"; then
2382   if test "${with_png}" != "no"; then
2383     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2384     # in /usr/include/libpng.
2385     AC_CHECK_HEADERS(png.h libpng/png.h)
2386     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2387       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2388     fi
2389   fi
2390
2391   if test "${HAVE_PNG}" = "yes"; then
2392     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2393     LIBPNG="-lpng -lz -lm"
2394   fi
2395 fi
2396 AC_SUBST(LIBPNG)
2397
2398 ### Use -ltiff if available, unless `--with-tiff=no'.
2399 HAVE_TIFF=no
2400 LIBTIFF=
2401 if test "${HAVE_X11}" = "yes"; then
2402   if test "${with_tiff}" != "no"; then
2403     AC_CHECK_HEADER(tiffio.h,
2404       [tifflibs="-lz -lm"
2405       # At least one tiff package requires the jpeg library.
2406       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2407       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2408   fi
2409
2410   if test "${HAVE_TIFF}" = "yes"; then
2411     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2412     dnl FIXME -lz -lm, as per libpng?
2413     LIBTIFF=-ltiff
2414   fi
2415 fi
2416 AC_SUBST(LIBTIFF)
2417
2418 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2419 HAVE_GIF=no
2420 LIBGIF=
2421 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2422   AC_CHECK_HEADER(gif_lib.h,
2423 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2424 # Earlier versions can crash Emacs.
2425     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2426
2427   if test "$HAVE_GIF" = yes; then
2428     LIBGIF=-lgif
2429   elif test "$HAVE_GIF" = maybe; then
2430 # If gif_lib.h but no libgif, try libungif.
2431     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2432     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2433   fi
2434
2435   if test "${HAVE_GIF}" = "yes"; then
2436     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2437   fi
2438 fi
2439 AC_SUBST(LIBGIF)
2440
2441 dnl Check for required libraries.
2442 if test "${HAVE_X11}" = "yes"; then
2443   MISSING=""
2444   WITH_NO=""
2445   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2446     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2447   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2448     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2449   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2450     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2451   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2452     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2453   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2454     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2455
2456   if test "X${MISSING}" != X; then
2457     AC_MSG_ERROR([The following required libraries were not found:
2458     $MISSING
2459 Maybe some development libraries/packages are missing?
2460 If you don't want to link with them give
2461     $WITH_NO
2462 as options to configure])
2463   fi
2464 fi
2465
2466 ### Use -lgpm if available, unless `--with-gpm=no'.
2467 HAVE_GPM=no
2468 LIBGPM=
2469 if test "${with_gpm}" != "no"; then
2470   AC_CHECK_HEADER(gpm.h,
2471     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2472
2473   if test "${HAVE_GPM}" = "yes"; then
2474     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2475     LIBGPM=-lgpm
2476   fi
2477 fi
2478 AC_SUBST(LIBGPM)
2479
2480 dnl Check for malloc/malloc.h on darwin
2481 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2482
2483 C_SWITCH_X_SYSTEM=
2484 ### Use NeXTstep API to implement GUI.
2485 if test "${HAVE_NS}" = "yes"; then
2486   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2487   if test "${NS_IMPL_COCOA}" = "yes"; then
2488     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2489     GNU_OBJC_CFLAGS=
2490   fi
2491   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2492     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2493     # See also .m.o rule in Makefile.in */
2494     # FIXME: are all these flags really needed?  Document here why.  */
2495     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2496     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2497   fi
2498   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2499     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2500   fi
2501   # We also have mouse menus.
2502   HAVE_MENUS=yes
2503   OTHER_FILES=ns-app
2504 fi
2505
2506
2507 ### Use session management (-lSM -lICE) if available
2508 HAVE_X_SM=no
2509 LIBXSM=
2510 if test "${HAVE_X11}" = "yes"; then
2511   AC_CHECK_HEADER(X11/SM/SMlib.h,
2512     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2513
2514   if test "${HAVE_X_SM}" = "yes"; then
2515     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2516     LIBXSM="-lSM -lICE"
2517     case "$LIBS" in
2518       *-lSM*) ;;
2519       *)      LIBS="$LIBXSM $LIBS" ;;
2520     esac
2521   fi
2522 fi
2523 AC_SUBST(LIBXSM)
2524
2525 ### Use libxml (-lxml2) if available
2526 if test "${with_xml2}" != "no"; then
2527   ### I'm not sure what the version number should be, so I just guessed.
2528   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2529   if test "${HAVE_LIBXML2}" = "yes"; then
2530     LIBS="$LIBXML2_LIBS $LIBS"
2531     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2532     if test "${HAVE_LIBXML2}" = "yes"; then
2533       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2534     else
2535       LIBXML2_LIBS=""
2536       LIBXML2_CFLAGS=""
2537     fi
2538   fi
2539 fi
2540 AC_SUBST(LIBXML2_LIBS)
2541 AC_SUBST(LIBXML2_CFLAGS)
2542
2543 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2544 AC_CACHE_CHECK(whether netdb declares h_errno,
2545                emacs_cv_netdb_declares_h_errno,
2546 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2547   [[return h_errno;]])],
2548   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2549 if test $emacs_cv_netdb_declares_h_errno = yes; then
2550   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2551 fi
2552
2553 AC_FUNC_ALLOCA
2554
2555 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2556 dnl FIXME is there an autoconf test that does the right thing, without
2557 dnl needing to call A_M_E afterwards?
2558 if test x"$ac_cv_func_alloca_works" != xyes; then
2559    AC_MSG_ERROR( [a system implementation of alloca is required] )
2560 fi
2561
2562 # fmod, logb, and frexp are found in -lm on most systems.
2563 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2564 AC_CHECK_LIB(m, sqrt)
2565
2566 # Check for mail-locking functions in a "mail" library.  Probably this should
2567 # have the same check as for liblockfile below.
2568 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2569 if test $have_mail = yes; then
2570   LIBS_MAIL=-lmail
2571   LIBS="$LIBS_MAIL $LIBS"
2572   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2573 else
2574   LIBS_MAIL=
2575 fi
2576 dnl Debian, at least:
2577 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2578 if test $have_lockfile = yes; then
2579    LIBS_MAIL=-llockfile
2580    LIBS="$LIBS_MAIL $LIBS"
2581    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2582 else
2583 # If we have the shared liblockfile, assume we must use it for mail
2584 # locking (e.g. Debian).  If we couldn't link against liblockfile
2585 # (no liblockfile.a installed), ensure that we don't need to.
2586   dnl This works for files generally, not just executables.
2587   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2588   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2589                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2590   if test $ac_cv_prog_liblockfile = yes; then
2591     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2592 This probably means that movemail could lose mail.
2593 There may be a `development' package to install containing liblockfile.])
2594   fi
2595 fi
2596 AC_CHECK_FUNCS(touchlock)
2597 AC_CHECK_HEADERS(maillock.h)
2598 AC_SUBST(LIBS_MAIL)
2599
2600 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2601 ## interlock access to the mail spool.  The alternative is a lock file named
2602 ## /usr/spool/mail/$USER.lock.
2603 mail_lock=no
2604 case "$opsys" in
2605   aix4-2) mail_lock="lockf" ;;
2606
2607   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2608
2609   ## On GNU/Linux systems, both methods are used by various mail programs.
2610   ## I assume most people are using newer mailers that have heard of flock.
2611   ## Change this if you need to.
2612   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2613   ## configure gets the right answers, and that means *NOT* using flock.
2614   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2615   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2616   ## Debian maintainer hasn't provided a clean fix for Emacs.
2617   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2618   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2619   ## correct logic.  -- fx
2620   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2621   ## liblockfile is a Free Software replacement for libmail, used on
2622   ## Debian systems and elsewhere. -rfr.
2623   gnu-*)
2624     mail_lock="flock"
2625     if test $have_mail = yes || test $have_lockfile = yes; then
2626       test $ac_cv_header_maillock_h = yes && mail_lock=no
2627     fi
2628     ;;
2629 esac
2630
2631 BLESSMAIL_TARGET=
2632 case "$mail_lock" in
2633   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2634
2635   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2636
2637   *) BLESSMAIL_TARGET="need-blessmail" ;;
2638 esac
2639 AC_SUBST(BLESSMAIL_TARGET)
2640
2641
2642 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2643 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2644 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2645 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2646 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2647 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2648 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2649 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2650 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2651 cfmakeraw cfsetspeed isnan copysign __executable_start)
2652
2653 dnl Cannot use AC_CHECK_FUNCS
2654 AC_CACHE_CHECK([for __builtin_unwind_init],
2655                emacs_cv_func___builtin_unwind_init,
2656 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2657                 emacs_cv_func___builtin_unwind_init=yes,
2658                 emacs_cv_func___builtin_unwind_init=no)])
2659 if test $emacs_cv_func___builtin_unwind_init = yes; then
2660   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2661             [Define to 1 if you have the `__builtin_unwind_init' function.])
2662 fi
2663
2664 AC_CHECK_HEADERS(sys/un.h)
2665
2666 AC_FUNC_FSEEKO
2667
2668 AC_FUNC_GETPGRP
2669
2670 # Configure gnulib.
2671 gl_ASSERT_NO_GNULIB_POSIXCHECK
2672 gl_ASSERT_NO_GNULIB_TESTS
2673 gl_INIT
2674
2675 # UNIX98 PTYs.
2676 AC_CHECK_FUNCS(grantpt)
2677
2678 # PTY-related GNU extensions.
2679 AC_CHECK_FUNCS(getpt)
2680
2681 # Check this now, so that we will NOT find the above functions in ncurses.
2682 # That is because we have not set up to link ncurses in lib-src.
2683 # It's better to believe a function is not available
2684 # than to expect to find it in ncurses.
2685 # Also we need tputs and friends to be able to build at all.
2686 have_tputs_et_al=true
2687 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2688 if test "$have_tputs_et_al" != true; then
2689   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2690 Maybe some development libraries/packages are missing?  Try installing
2691 libncurses-dev(el), libterminfo-dev(el) or similar.])
2692 fi
2693 # Must define this when any termcap library is found.
2694 AC_DEFINE(HAVE_LIBNCURSES, 1,
2695           [Define to 1 if you have the `ncurses' library (-lncurses).])
2696 ## FIXME This was the cpp logic, but I am not sure it is right.
2697 ## The above test has not necessarily found libncurses.
2698 HAVE_LIBNCURSES=yes
2699
2700 ## Use terminfo instead of termcap?
2701 ## Note only system files NOT using terminfo are:
2702 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2703 ## darwin|gnu without ncurses.
2704 TERMINFO=no
2705 LIBS_TERMCAP=
2706 case "$opsys" in
2707   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2708   ## hpux10-20: Use the system provided termcap(3) library.
2709   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2710   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2711   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2712
2713   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2714   ##  The ncurses library has been moved out of the System framework in
2715   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2716   ##  option to use it.
2717   darwin|gnu*)
2718     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2719     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2720       TERMINFO=yes
2721       LIBS_TERMCAP="-lncurses"
2722     fi
2723     ;;
2724
2725   freebsd)
2726     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2727     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2728     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2729 [[#if __FreeBSD_version < 400000
2730 fail;
2731 #endif
2732 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2733
2734     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2735
2736     if test $emacs_cv_freebsd_terminfo = yes; then
2737       TERMINFO=yes
2738       LIBS_TERMCAP="-lncurses"
2739     else
2740       LIBS_TERMCAP="-ltermcap"
2741     fi
2742     ;;
2743
2744   netbsd)
2745     if test $ac_cv_search_tputs = -lterminfo; then
2746       TERMINFO=yes
2747       LIBS_TERMCAP="-lterminfo"
2748     else
2749       LIBS_TERMCAP="-ltermcap"
2750     fi
2751     ;;
2752
2753 esac
2754
2755 case "$opsys" in
2756   ## hpux: Make sure we get select from libc rather than from libcurses
2757   ##  because libcurses on HPUX 10.10 has a broken version of select.
2758   ##  We used to use -lc -lcurses, but this may be cleaner.
2759   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2760
2761   openbsd) LIBS_TERMCAP="-lncurses" ;;
2762
2763   ## Must use system termcap, if we use any termcap.  It does special things.
2764   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2765 esac
2766
2767 TERMCAP_OBJ=tparam.o
2768 if test $TERMINFO = yes; then
2769   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2770
2771   ## Default used to be -ltermcap.  Add a case above if need something else.
2772   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2773
2774   TERMCAP_OBJ=terminfo.o
2775 fi
2776 AC_SUBST(LIBS_TERMCAP)
2777 AC_SUBST(TERMCAP_OBJ)
2778
2779
2780 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2781 resolv=no
2782 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2783 #include <arpa/nameser.h>
2784 #include <resolv.h>]],
2785     [[return res_init();]])],
2786     have_res_init=yes, have_res_init=no)
2787 if test "$have_res_init" = no; then
2788   OLIBS="$LIBS"
2789   LIBS="$LIBS -lresolv"
2790   AC_MSG_CHECKING(for res_init with -lresolv)
2791   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2792 #include <arpa/nameser.h>
2793 #include <resolv.h>]],
2794     [[return res_init();]])],
2795     have_res_init=yes, have_res_init=no)
2796   AC_MSG_RESULT($have_res_init)
2797   if test "$have_res_init" = yes ; then
2798     resolv=yes
2799   fi
2800   LIBS="$OLIBS"
2801 fi
2802
2803 if test "$have_res_init" = yes; then
2804   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2805 fi
2806
2807 # Do we need the Hesiod library to provide the support routines?
2808 LIBHESIOD=
2809 if test "$with_hesiod" != no ; then
2810   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2811   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2812      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2813                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2814   if test "$resolv" = yes ; then
2815     RESOLVLIB=-lresolv
2816   else
2817     RESOLVLIB=
2818   fi
2819   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2820         hesiod=yes, :, $RESOLVLIB)])
2821
2822   if test x"$hesiod" = xyes; then
2823     AC_DEFINE(HAVE_LIBHESIOD, 1,
2824               [Define to 1 if you have the hesiod library (-lhesiod).])
2825     LIBHESIOD=-lhesiod
2826   fi
2827 fi
2828 AC_SUBST(LIBHESIOD)
2829
2830 # Do we need libresolv (due to res_init or Hesiod)?
2831 if test "$resolv" = yes ; then
2832   AC_DEFINE(HAVE_LIBRESOLV, 1,
2833             [Define to 1 if you have the resolv library (-lresolv).])
2834   LIBRESOLV=-lresolv
2835 else
2836   LIBRESOLV=
2837 fi
2838 AC_SUBST(LIBRESOLV)
2839
2840 # These tell us which Kerberos-related libraries to use.
2841 COM_ERRLIB=
2842 CRYPTOLIB=
2843 KRB5LIB=
2844 DESLIB=
2845 KRB4LIB=
2846
2847 if test "${with_kerberos}" != no; then
2848   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2849   if test $have_com_err = yes; then
2850     COM_ERRLIB=-lcom_err
2851     LIBS="$COM_ERRLIB $LIBS"
2852     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2853   fi
2854   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2855   if test $have_crypto = yes; then
2856     CRYPTOLIB=-lcrypto
2857     LIBS="$CRYPTOLIB $LIBS"
2858     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2859   fi
2860   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2861   if test $have_k5crypto = yes; then
2862     CRYPTOLIB=-lk5crypto
2863     LIBS="$CRYPTOLIB $LIBS"
2864     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2865   fi
2866   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2867   if test $have_krb5=yes; then
2868     KRB5LIB=-lkrb5
2869     LIBS="$KRB5LIB $LIBS"
2870     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2871   fi
2872   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2873   if test "${with_kerberos5}" = no; then
2874     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2875     if test $have_des425 = yes; then
2876       DESLIB=-ldes425
2877       LIBS="$DESLIB $LIBS"
2878       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2879     else
2880       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2881       if test $have_des = yes; then
2882         DESLIB=-ldes
2883         LIBS="$DESLIB $LIBS"
2884         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2885       fi
2886     fi
2887     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2888     if test $have_krb4 = yes; then
2889       KRB4LIB=-lkrb4
2890       LIBS="$KRB4LIB $LIBS"
2891       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2892     else
2893       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2894       if test $have_krb = yes; then
2895         KRB4LIB=-lkrb
2896         LIBS="$KRB4LIB $LIBS"
2897         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2898       fi
2899     fi
2900   fi
2901
2902   if test "${with_kerberos5}" != no; then
2903     AC_CHECK_HEADERS(krb5.h,
2904       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2905                         [#include <krb5.h>])])
2906   else
2907     AC_CHECK_HEADERS(des.h,,
2908                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2909                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2910     AC_CHECK_HEADERS(krb.h,,
2911                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2912                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2913   fi
2914   AC_CHECK_HEADERS(com_err.h)
2915 fi
2916
2917 AC_SUBST(COM_ERRLIB)
2918 AC_SUBST(CRYPTOLIB)
2919 AC_SUBST(KRB5LIB)
2920 AC_SUBST(DESLIB)
2921 AC_SUBST(KRB4LIB)
2922
2923 # Solaris requires -lintl if you want strerror (which calls dgettext)
2924 # to return localized messages.
2925 AC_CHECK_LIB(intl, dgettext)
2926
2927 AC_MSG_CHECKING(whether localtime caches TZ)
2928 AC_CACHE_VAL(emacs_cv_localtime_cache,
2929 [if test x$ac_cv_func_tzset = xyes; then
2930 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2931 char TZ_GMT0[] = "TZ=GMT0";
2932 char TZ_PST8[] = "TZ=PST8";
2933 main()
2934 {
2935   time_t now = time ((time_t *) 0);
2936   int hour_GMT0, hour_unset;
2937   if (putenv (TZ_GMT0) != 0)
2938     exit (1);
2939   hour_GMT0 = localtime (&now)->tm_hour;
2940   unsetenv("TZ");
2941   hour_unset = localtime (&now)->tm_hour;
2942   if (putenv (TZ_PST8) != 0)
2943     exit (1);
2944   if (localtime (&now)->tm_hour == hour_GMT0)
2945     exit (1);
2946   unsetenv("TZ");
2947   if (localtime (&now)->tm_hour != hour_unset)
2948     exit (1);
2949   exit (0);
2950 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2951 [# If we have tzset, assume the worst when cross-compiling.
2952 emacs_cv_localtime_cache=yes])
2953 else
2954         # If we lack tzset, report that localtime does not cache TZ,
2955         # since we can't invalidate the cache if we don't have tzset.
2956         emacs_cv_localtime_cache=no
2957 fi])dnl
2958 AC_MSG_RESULT($emacs_cv_localtime_cache)
2959 if test $emacs_cv_localtime_cache = yes; then
2960   AC_DEFINE(LOCALTIME_CACHE, 1,
2961             [Define to 1 if localtime caches TZ.])
2962 fi
2963
2964 if test "x$HAVE_TIMEVAL" = xyes; then
2965   AC_CHECK_FUNCS(gettimeofday)
2966   if test $ac_cv_func_gettimeofday = yes; then
2967     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2968                    emacs_cv_gettimeofday_two_arguments,
2969     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2970 #ifdef TIME_WITH_SYS_TIME
2971 #include <sys/time.h>
2972 #include <time.h>
2973 #else
2974 #ifdef HAVE_SYS_TIME_H
2975 #include <sys/time.h>
2976 #else
2977 #include <time.h>
2978 #endif
2979 #endif]],
2980       [[struct timeval time;
2981        gettimeofday (&time, 0);]])],
2982       emacs_cv_gettimeofday_two_arguments=yes,
2983       emacs_cv_gettimeofday_two_arguments=no)])
2984     if test $emacs_cv_gettimeofday_two_arguments = no; then
2985       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2986                 [Define to 1 if gettimeofday accepts only one argument.])
2987     fi
2988   fi
2989 fi
2990
2991 ok_so_far=yes
2992 AC_CHECK_FUNC(socket, , ok_so_far=no)
2993 if test $ok_so_far = yes; then
2994   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2995 fi
2996 if test $ok_so_far = yes; then
2997   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2998 fi
2999 if test $ok_so_far = yes; then
3000 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3001   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3002             [Define to 1 if you have inet sockets.])
3003 fi
3004
3005 if test -f /usr/lpp/X11/bin/smt.exp; then
3006   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3007             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3008 fi
3009
3010 AC_MSG_CHECKING(whether system supports dynamic ptys)
3011 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3012   AC_MSG_RESULT(yes)
3013   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3014 else
3015   AC_MSG_RESULT(no)
3016 fi
3017
3018 AC_FUNC_FORK
3019
3020 dnl Adapted from Haible's version.
3021 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3022   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3023     [[char* cs = nl_langinfo(CODESET);]])],
3024     emacs_cv_langinfo_codeset=yes,
3025     emacs_cv_langinfo_codeset=no)
3026   ])
3027 if test $emacs_cv_langinfo_codeset = yes; then
3028   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3029     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3030 fi
3031
3032 AC_TYPE_MBSTATE_T
3033
3034 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3035   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3036                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3037 if test "$emacs_cv_c_restrict_arr" = yes; then
3038   AC_DEFINE(__restrict_arr, __restrict,
3039     [Define to compiler's equivalent of C99 restrict keyword in array
3040      declarations.  Define as empty for no equivalent.])
3041 fi
3042
3043 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3044 dnl how the tty code is related to POSIX and/or other versions of termios.
3045 dnl The following looks like a useful start.
3046 dnl
3047 dnl AC_SYS_POSIX_TERMIOS
3048 dnl if test $ac_cv_sys_posix_termios = yes; then
3049 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3050 dnl                                and macros for terminal control.])
3051 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3052 dnl fi
3053
3054 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3055
3056 # Set up the CFLAGS for real compilation, so we can substitute it.
3057 CFLAGS="$REAL_CFLAGS"
3058 CPPFLAGS="$REAL_CPPFLAGS"
3059
3060 ## Hack to detect a buggy GCC version.
3061 if test "x$GCC" = xyes \
3062    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3063    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3064    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3065    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3066 fi
3067
3068 version=$PACKAGE_VERSION
3069
3070 ### Specify what sort of things we'll be editing into Makefile and config.h.
3071 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3072 AC_SUBST(version)
3073 AC_SUBST(configuration)
3074 ## Unused?
3075 AC_SUBST(canonical)
3076 AC_SUBST(srcdir)
3077 AC_SUBST(prefix)
3078 AC_SUBST(exec_prefix)
3079 AC_SUBST(bindir)
3080 AC_SUBST(datadir)
3081 AC_SUBST(sharedstatedir)
3082 AC_SUBST(libexecdir)
3083 AC_SUBST(mandir)
3084 AC_SUBST(infodir)
3085 AC_SUBST(lispdir)
3086 AC_SUBST(locallisppath)
3087 AC_SUBST(lisppath)
3088 AC_SUBST(x_default_search_path)
3089 AC_SUBST(etcdir)
3090 AC_SUBST(archlibdir)
3091 AC_SUBST(docdir)
3092 AC_SUBST(bitmapdir)
3093 AC_SUBST(gamedir)
3094 AC_SUBST(gameuser)
3095 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3096 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3097 ## end of LIBX_BASE, but nothing ever set it.
3098 AC_SUBST(LD_SWITCH_X_SITE)
3099 AC_SUBST(C_SWITCH_X_SITE)
3100 AC_SUBST(C_SWITCH_X_SYSTEM)
3101 AC_SUBST(CFLAGS)
3102 ## Used in lwlib/Makefile.in.
3103 AC_SUBST(X_TOOLKIT_TYPE)
3104 if test -n "${machfile}"; then
3105   M_FILE="\$(srcdir)/${machfile}"
3106 else
3107   M_FILE=
3108 fi
3109 S_FILE="\$(srcdir)/${opsysfile}"
3110 AC_SUBST(M_FILE)
3111 AC_SUBST(S_FILE)
3112 AC_SUBST(ns_appdir)
3113 AC_SUBST(ns_appbindir)
3114 AC_SUBST(ns_appresdir)
3115 AC_SUBST(ns_appsrc)
3116 AC_SUBST(GNU_OBJC_CFLAGS)
3117 AC_SUBST(OTHER_FILES)
3118
3119 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3120                    [Define to the canonical Emacs configuration name.])
3121 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3122                    [Define to the options passed to configure.])
3123 if test -n "$machfile"; then
3124   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3125                      [Define to the used machine dependent file.])
3126 fi
3127 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3128                    [Define to the used os dependent file.])
3129
3130 XMENU_OBJ=
3131 XOBJ=
3132 FONT_OBJ=
3133 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3134   AC_DEFINE(HAVE_X_WINDOWS, 1,
3135             [Define to 1 if you want to use the X window system.])
3136   XMENU_OBJ=xmenu.o
3137   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3138   FONT_OBJ=xfont.o
3139   if test "$HAVE_XFT" = "yes"; then
3140     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3141   elif test "$HAVE_FREETYPE" = "yes"; then
3142     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3143   fi
3144   AC_SUBST(FONT_OBJ)
3145 fi
3146 AC_SUBST(XMENU_OBJ)
3147 AC_SUBST(XOBJ)
3148 AC_SUBST(FONT_OBJ)
3149
3150 WIDGET_OBJ=
3151 MOTIF_LIBW=
3152 if test "${USE_X_TOOLKIT}" != "none" ; then
3153   WIDGET_OBJ=widget.o
3154   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3155   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3156     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3157   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3158     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3159     MOTIF_LIBW=-lXm
3160     case "$opsys" in
3161       gnu-linux)
3162         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3163         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3164         ;;
3165
3166       unixware)
3167         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3168         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3169         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3170         ;;
3171
3172       aix4-2)
3173         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3174         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3175         ;;
3176     esac
3177     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3178   fi
3179 fi
3180 AC_SUBST(WIDGET_OBJ)
3181
3182 TOOLKIT_LIBW=
3183 case "$USE_X_TOOLKIT" in
3184   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3185   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3186   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3187 esac
3188 AC_SUBST(TOOLKIT_LIBW)
3189
3190 if test "$USE_X_TOOLKIT" = "none"; then
3191   LIBXT_OTHER="\$(LIBXSM)"
3192   OLDXMENU_TARGET="really-oldXMenu"
3193 else
3194   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3195   OLDXMENU_TARGET="really-lwlib"
3196 fi
3197 AC_SUBST(LIBXT_OTHER)
3198
3199 ## The X Menu stuff is present in the X10 distribution, but missing
3200 ## from X11.  If we have X10, just use the installed library;
3201 ## otherwise, use our own copy.
3202 if test "${HAVE_X11}" = "yes" ; then
3203   AC_DEFINE(HAVE_X11, 1,
3204             [Define to 1 if you want to use version 11 of X windows.
3205              Otherwise, Emacs expects to use version 10.])
3206
3207   if test "$USE_X_TOOLKIT" = "none"; then
3208     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3209   else
3210     OLDXMENU="\${lwlibdir}/liblw.a"
3211   fi
3212   LIBXMENU="\$(OLDXMENU)"
3213   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3214   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3215 else
3216   ## For a syntactically valid Makefile; not actually used for anything.
3217   ## See comments in src/Makefile.in.
3218   OLDXMENU=nothing
3219   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3220   if test "${HAVE_X_WINDOWS}" = "yes"; then
3221     LIBXMENU="-lXMenu"
3222   else
3223     LIBXMENU=
3224   fi
3225   LIBX_OTHER=
3226   OLDXMENU_DEPS=
3227 fi
3228
3229 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3230   OLDXMENU_TARGET=
3231   OLDXMENU=nothing
3232   LIBXMENU=
3233   OLDXMENU_DEPS=
3234 fi
3235
3236 AC_SUBST(OLDXMENU_TARGET)
3237 AC_SUBST(OLDXMENU)
3238 AC_SUBST(LIBXMENU)
3239 AC_SUBST(LIBX_OTHER)
3240 AC_SUBST(OLDXMENU_DEPS)
3241
3242 if test "${HAVE_MENUS}" = "yes" ; then
3243   AC_DEFINE(HAVE_MENUS, 1,
3244             [Define to 1 if you have mouse menus.
3245              (This is automatic if you use X, but the option to specify it remains.)
3246              It is also defined with other window systems that support xmenu.c.])
3247 fi
3248
3249 if test "${GNU_MALLOC}" = "yes" ; then
3250   AC_DEFINE(GNU_MALLOC, 1,
3251             [Define to 1 if you want to use the GNU memory allocator.])
3252 fi
3253
3254 RALLOC_OBJ=
3255 if test "${REL_ALLOC}" = "yes" ; then
3256   AC_DEFINE(REL_ALLOC, 1,
3257             [Define REL_ALLOC if you want to use the relocating allocator for
3258              buffer space.])
3259
3260   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3261 fi
3262 AC_SUBST(RALLOC_OBJ)
3263
3264 if test "$opsys" = "cygwin"; then
3265   CYGWIN_OBJ="sheap.o"
3266   ## Cygwin differs because of its unexec().
3267   PRE_ALLOC_OBJ=
3268   POST_ALLOC_OBJ=lastfile.o
3269 else
3270   CYGWIN_OBJ=
3271   PRE_ALLOC_OBJ=lastfile.o
3272   POST_ALLOC_OBJ=
3273 fi
3274 AC_SUBST(CYGWIN_OBJ)
3275 AC_SUBST(PRE_ALLOC_OBJ)
3276 AC_SUBST(POST_ALLOC_OBJ)
3277
3278
3279 case "$opsys" in
3280   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3281
3282   darwin)
3283    ## The -headerpad option tells ld (see man page) to leave room at the
3284    ## end of the header for adding load commands.  Needed for dumping.
3285    ## 0x690 is the total size of 30 segment load commands (at 56
3286    ## each); under Cocoa 31 commands are required.
3287    if test "$HAVE_NS" = "yes"; then
3288      libs_nsgui="-framework AppKit"
3289      headerpad_extra=6C8
3290    else
3291      libs_nsgui=
3292      headerpad_extra=690
3293    fi
3294    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3295
3296    ## This is here because src/Makefile.in did some extra fiddling around
3297    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3298    ##   #ifndef LD_SWITCH_SYSTEM
3299    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3300    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3301    ## not using gcc, darwin system not on an alpha (ie darwin, since
3302    ## darwin + alpha does not occur).
3303    ## Because this was done in src/Makefile.in, the resulting part of
3304    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3305    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3306    ## rather than LD_SWITCH_SYSTEM.
3307    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3308      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3309    ;;
3310
3311   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3312   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3313   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3314   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3315   ## had different values in configure (in ac_link) and src/Makefile.in.
3316   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3317   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3318
3319   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3320 esac
3321
3322 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3323   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3324 fi
3325
3326 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3327
3328
3329 LD_FIRSTFLAG=
3330 ORDINARY_LINK=
3331 case "$opsys" in
3332   ## gnu: GNU needs its own crt0.
3333   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3334
3335   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3336   ## library search parth, i.e. it won't search /usr/lib for libc and
3337   ## friends.  Using -nostartfiles instead avoids this problem, and
3338   ## will also work on earlier NetBSD releases.
3339   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3340
3341   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3342   ##   MkLinux/LinuxPPC needs this.
3343   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3344   gnu-*)
3345     case "$machine" in
3346       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3347     esac
3348     ;;
3349 esac
3350
3351
3352 if test "x$ORDINARY_LINK" = "xyes"; then
3353
3354   LD_FIRSTFLAG=""
3355   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3356
3357 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3358 ## freebsd, gnu-* not on macppc|ibms390x.
3359 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3360
3361   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3362   ## places that are difficult to figure out at make time.  Fortunately,
3363   ## these same versions allow you to pass arbitrary flags on to the
3364   ## linker, so there is no reason not to use it as a linker.
3365   ##
3366   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3367   ## searching for libraries in its internal directories, so we have to
3368   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3369   LD_FIRSTFLAG="-nostdlib"
3370 fi
3371
3372 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3373 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3374
3375 AC_SUBST(LD_FIRSTFLAG)
3376
3377
3378 ## FIXME? The logic here is not precisely the same as that above.
3379 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3380 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3381 LIB_GCC=
3382 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3383
3384   case "$opsys" in
3385     freebsd|netbsd|openbsd) LIB_GCC= ;;
3386
3387     gnu-*)
3388       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3389       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3390       case $host_cpu in
3391       arm*)
3392         LIB_GCC="-lgcc_s"
3393         ;;
3394       *)
3395         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3396         ## immediately undefine it again and redefine it to empty.
3397         ## Was the C_SWITCH_X_SITE part really necessary?
3398 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3399         LIB_GCC=
3400         ;;
3401       esac
3402       ;;
3403
3404     ## Ask GCC where to find libgcc.a.
3405     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3406   esac
3407 fi                              dnl if $GCC
3408 AC_SUBST(LIB_GCC)
3409
3410
3411 ## If we're using X11/GNUstep, define some consequences.
3412 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3413   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3414   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3415 fi
3416
3417
3418 AH_TOP([/* GNU Emacs site configuration template file.
3419
3420 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3421   Free Software Foundation, Inc.
3422
3423 This file is part of GNU Emacs.
3424
3425 GNU Emacs is free software: you can redistribute it and/or modify
3426 it under the terms of the GNU General Public License as published by
3427 the Free Software Foundation, either version 3 of the License, or
3428 (at your option) any later version.
3429
3430 GNU Emacs is distributed in the hope that it will be useful,
3431 but WITHOUT ANY WARRANTY; without even the implied warranty of
3432 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3433 GNU General Public License for more details.
3434
3435 You should have received a copy of the GNU General Public License
3436 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3437
3438
3439 /* No code in Emacs #includes config.h twice, but some bits of code
3440    intended to work with other packages as well (like gmalloc.c)
3441    think they can include it as many times as they like.  */
3442 #ifndef EMACS_CONFIG_H
3443 #define EMACS_CONFIG_H
3444 ])dnl
3445
3446 AH_BOTTOM([
3447 /* Define AMPERSAND_FULL_NAME if you use the convention
3448    that & in the full name stands for the login id.  */
3449 /* Turned on June 1996 supposing nobody will mind it.  */
3450 #define AMPERSAND_FULL_NAME
3451
3452 /* If using GNU, then support inline function declarations.  */
3453 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3454    generally, because even if non-gcc compilers accept `inline', they
3455    may reject `extern inline'.  */
3456 #if defined (__GNUC__)
3457 #define INLINE __inline__
3458 #else
3459 #define INLINE
3460 #endif
3461
3462 /* `subprocesses' should be defined if you want to
3463    have code for asynchronous subprocesses
3464    (as used in M-x compile and M-x shell).
3465    Only MSDOS does not support this (it overrides
3466    this in its config_opsysfile below).  */
3467
3468 #define subprocesses
3469
3470 /* Include the os and machine dependent files.  */
3471 #include config_opsysfile
3472 #ifdef config_machfile
3473 # include config_machfile
3474 #endif
3475
3476 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3477    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3478   (There is probably a better place to do this, but right now the
3479    Cocoa side does this in s/darwin.h and we cannot parallel this
3480    exactly since GNUstep is multi-OS.  */
3481 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3482 #  define SYSTEM_PURESIZE_EXTRA 30000
3483 #endif
3484
3485 #ifdef emacs /* Don't do this for lib-src.  */
3486 /* Tell regex.c to use a type compatible with Emacs.  */
3487 #define RE_TRANSLATE_TYPE Lisp_Object
3488 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3489 #ifdef make_number
3490 /* If make_number is a macro, use it.  */
3491 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3492 #else
3493 /* If make_number is a function, avoid it.  */
3494 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3495 #endif
3496 #endif
3497
3498 /* These default definitions are good for almost all machines.
3499    Any exceptions should override them in m/MACHINE.h.
3500    They must be usable in preprocessor conditionals.  */
3501
3502 #ifndef BITS_PER_CHAR
3503 #define BITS_PER_CHAR 8
3504 #endif
3505
3506 #ifndef BITS_PER_SHORT
3507 #define BITS_PER_SHORT 16
3508 #endif
3509
3510 #ifndef BITS_PER_INT
3511 #define BITS_PER_INT 32
3512 #endif
3513
3514 #ifndef BITS_PER_LONG
3515 #ifdef _LP64
3516 #define BITS_PER_LONG 64
3517 #else
3518 #define BITS_PER_LONG 32
3519 #endif
3520 #endif
3521
3522 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3523 #define BITS_PER_LONG_LONG 64
3524 #endif
3525
3526 /* Define if the compiler supports function prototypes.  It may do so but
3527    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3528 #undef PROTOTYPES
3529
3530 #include <string.h>
3531 #include <stdlib.h>
3532
3533 #ifdef HAVE_ALLOCA_H
3534 # include <alloca.h>
3535 #elif defined __GNUC__
3536 # define alloca __builtin_alloca
3537 #elif defined _AIX
3538 # define alloca __alloca
3539 #else
3540 # include <stddef.h>
3541 # ifdef  __cplusplus
3542 extern "C"
3543 # endif
3544 void *alloca (size_t);
3545 #endif
3546
3547 #ifndef HAVE_STRCHR
3548 #define strchr(a, b) index (a, b)
3549 #endif
3550
3551 #ifndef HAVE_STRRCHR
3552 #define strrchr(a, b) rindex (a, b)
3553 #endif
3554
3555 #if defined __GNUC__ && (__GNUC__ > 2 \
3556                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3557 #define NO_RETURN       __attribute__ ((__noreturn__))
3558 #else
3559 #define NO_RETURN       /* nothing */
3560 #endif
3561
3562 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3563 #define NO_INLINE __attribute__((noinline))
3564 #else
3565 #define NO_INLINE
3566 #endif
3567
3568 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3569 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3570 #else
3571 #define EXTERNALLY_VISIBLE
3572 #endif
3573
3574 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3575 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3576 #else
3577 # define ATTRIBUTE_FORMAT(spec) /* empty */
3578 #endif
3579
3580 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3581 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3582    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3583 #else
3584 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3585    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3586 #endif
3587
3588 /* Some versions of GNU/Linux define noinline in their headers.  */
3589 #ifdef noinline
3590 #undef noinline
3591 #endif
3592
3593 /* These won't be used automatically yet.  We also need to know, at least,
3594    that the stack is continuous.  */
3595 #ifdef __GNUC__
3596 #  ifndef GC_SETJMP_WORKS
3597   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3598 #    define GC_SETJMP_WORKS 1
3599 #  endif
3600 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3601 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3602 #  endif
3603 #endif
3604
3605 #endif /* EMACS_CONFIG_H */
3606
3607 /*
3608 Local Variables:
3609 mode: c
3610 End:
3611 */
3612 ])dnl
3613
3614 #### Report on what we decided to do.
3615 #### Report GTK as a toolkit, even if it doesn't use Xt.
3616 #### It makes printing result more understandable as using GTK sets
3617 #### toolkit_scroll_bars to yes by default.
3618 if test "${HAVE_GTK}" = "yes"; then
3619   USE_X_TOOLKIT=GTK
3620 fi
3621
3622 and_machfile=
3623 if test -n "$machfile"; then
3624   and_machfile=" and \`${machfile}'"
3625 fi
3626
3627 echo "
3628 Configured for \`${canonical}'.
3629
3630   Where should the build process find the source code?    ${srcdir}
3631   What operating system and machine description files should Emacs use?
3632         \`${opsysfile}'${and_machfile}
3633   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3634   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3635   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3636   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3637   What window system should Emacs use?                    ${window_system}
3638   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3639
3640 if test -n "${x_includes}"; then
3641 echo "  Where do we find X Windows header files?                ${x_includes}"
3642 else
3643 echo "  Where do we find X Windows header files?                Standard dirs"
3644 fi
3645 if test -n "${x_libraries}"; then
3646 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3647 else
3648 echo "  Where do we find X Windows libraries?                   Standard dirs"
3649 fi
3650
3651 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3652 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3653 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3654 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3655 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3656 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3657 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3658 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3659
3660 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3661 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3662 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3663 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3664 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3665 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3666
3667 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3668 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3669 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3670 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3671
3672 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3673 echo
3674
3675 if test $USE_XASSERTS = yes; then
3676    echo "  Compiling with asserts turned on."
3677    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3678 fi
3679
3680 echo
3681
3682 if test "$HAVE_NS" = "yes"; then
3683    echo
3684    echo "You must run \"make install\" in order to test the built application.
3685 The installed application will go to nextstep/Emacs.app and can be
3686 run or moved from there."
3687    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3688       echo "The application will be fully self-contained."
3689     else
3690       echo "The lisp resources for the application will be installed under ${prefix}.
3691 You may need to run \"make install\" with sudo.  The application will fail
3692 to run if these resources are not installed."
3693    fi
3694    echo
3695 fi
3696
3697
3698 # Remove any trailing slashes in these variables.
3699 [test "${prefix}" != NONE &&
3700   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3701 test "${exec_prefix}" != NONE &&
3702   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3703
3704 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3705 dnl You _can_ use that variable here, so long as any directory using
3706 dnl automake (ie lib/) is explicitly listed and not "hidden" in a variable
3707 dnl (else you get "no `Makefile.am' found for any configure output").
3708 dnl This will work, but you get a config.status that is not quite right
3709 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3710 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3711 dnl it seems better to just live with the duplication.
3712 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3713
3714 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3715        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3716        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3717        leim/Makefile])
3718
3719 dnl test/ is not present in release tarfiles.
3720 opt_makefile=test/automated/Makefile
3721
3722 if test -f $srcdir/${opt_makefile}.in; then
3723   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3724   dnl Again, it's best not to use a variable.  Though you can add
3725   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3726   AC_CONFIG_FILES([test/automated/Makefile])
3727 fi
3728
3729 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3730
3731 AC_SUBST(SUBDIR_MAKEFILES_IN)
3732
3733 dnl Make the necessary directories, if they don't exist.
3734 AC_CONFIG_COMMANDS([mkdirs], [
3735 for dir in etc lisp ; do
3736   test -d ${dir} || mkdir ${dir}
3737 done
3738 ])
3739
3740 dnl You might wonder (I did) why epaths.h is generated by running make,
3741 dnl rather than just letting configure generate it from epaths.in.
3742 dnl One reason is that the various paths are not fully expanded (see above);
3743 dnl eg gamedir=${prefix}/var/games/emacs.
3744 dnl Secondly, the GNU Coding standards require that one should be able
3745 dnl to run `make prefix=/some/where/else' and override the values set
3746 dnl by configure.  This also explains the `move-if-change' test and
3747 dnl the use of force in the `epaths-force' rule in Makefile.in.
3748 AC_CONFIG_COMMANDS([epaths], [
3749 echo creating src/epaths.h
3750 ${MAKE-make} epaths-force
3751 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3752
3753 AC_CONFIG_COMMANDS([gdbinit], [
3754 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3755   echo creating src/.gdbinit
3756   echo source $srcdir/src/.gdbinit > src/.gdbinit
3757 fi
3758 ])
3759
3760 AC_OUTPUT
3761
3762 dnl configure.in ends here