lisp/gnus/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-sum)
  32 (require 'message)
  33 (require 'gnus-msg)
  34 (require 'nndraft)
  35 (require 'gnus-agent)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode nil
  41   "Minor mode for providing a draft summary buffers.")
  42
  43 (defvar gnus-draft-mode-map nil)
  44
  45 (unless gnus-draft-mode-map
  46   (setq gnus-draft-mode-map (make-sparse-keymap))
  47
  48   (gnus-define-keys gnus-draft-mode-map
  49     "Dt" gnus-draft-toggle-sending
  50     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  51     "De" gnus-draft-edit-message
  52     "Ds" gnus-draft-send-message
  53     "DS" gnus-draft-send-all-messages))
  54
  55 (defun gnus-draft-make-menu-bar ()
  56   (unless (boundp 'gnus-draft-menu)
  57     (easy-menu-define
  58      gnus-draft-menu gnus-draft-mode-map ""
  59      '("Drafts"
  60        ["Toggle whether to send" gnus-draft-toggle-sending t]
  61        ["Edit" gnus-draft-edit-message t]
  62        ["Send selected message(s)" gnus-draft-send-message t]
  63        ["Send all messages" gnus-draft-send-all-messages t]
  64        ["Delete draft" gnus-summary-delete-article t]))))
  65
  66 (defun gnus-draft-mode (&optional arg)
  67   "Minor mode for providing a draft summary buffers.
  68
  69 \\{gnus-draft-mode-map}"
  70   (interactive "P")
  71   (when (eq major-mode 'gnus-summary-mode)
  72     (when (set (make-local-variable 'gnus-draft-mode)
  73                (if (null arg) (not gnus-draft-mode)
  74                  (> (prefix-numeric-value arg) 0)))
  75       ;; Set up the menu.
  76       (when (gnus-visual-p 'draft-menu 'menu)
  77         (gnus-draft-make-menu-bar))
  78       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  79       (gnus-run-hooks 'gnus-draft-mode-hook))))
  80
  81 ;;; Commands
  82
  83 (defun gnus-draft-toggle-sending (article)
  84   "Toggle whether to send an article or not."
  85   (interactive (list (gnus-summary-article-number)))
  86   (if (gnus-draft-article-sendable-p article)
  87       (progn
  88         (push article gnus-newsgroup-unsendable)
  89         (gnus-summary-mark-article article gnus-unsendable-mark))
  90     (setq gnus-newsgroup-unsendable
  91           (delq article gnus-newsgroup-unsendable))
  92     (gnus-summary-mark-article article gnus-unread-mark))
  93   (gnus-summary-position-point))
  94
  95 (defun gnus-draft-edit-message ()
  96   "Enter a mail/post buffer to edit and send the draft."
  97   (interactive)
  98   (let ((article (gnus-summary-article-number))
  99         (group gnus-newsgroup-name))
 100     (gnus-draft-check-draft-articles (list article))
 101     (gnus-summary-mark-as-read article gnus-canceled-mark)
 102     (gnus-draft-setup article group t)
 103     (set-buffer-modified-p t)
 104     (save-excursion
 105       (save-restriction
 106         (message-narrow-to-headers)
 107         (message-remove-header "date")))
 108     (save-buffer)
 109     (let ((gnus-verbose-backends nil))
 110       (gnus-request-expire-articles (list article) group t))
 111     (push
 112      `((lambda ()
 113          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 114            (save-excursion
 115              (set-buffer ,gnus-summary-buffer)
 116              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 117      message-send-actions)))
 118
 119 (defun gnus-draft-send-message (&optional n)
 120   "Send the current draft."
 121   (interactive "P")
 122   (let* ((articles (gnus-summary-work-articles n))
 123          (total (length articles))
 124          article)
 125     (gnus-draft-check-draft-articles articles)
 126     (while (setq article (pop articles))
 127       (gnus-summary-remove-process-mark article)
 128       (unless (memq article gnus-newsgroup-unsendable)
 129         (let ((message-sending-message
 130                (format "Sending message %d of %d..."
 131                        (- total (length articles)) total)))
 132           (gnus-draft-send article gnus-newsgroup-name t))
 133         (gnus-summary-mark-article article gnus-canceled-mark)))))
 134
 135 (defun gnus-draft-send (article &optional group interactive)
 136   "Send message ARTICLE."
 137   (let* ((is-queue (or (not group)
 138                        (equal group "nndraft:queue")))
 139          (message-syntax-checks (if interactive message-syntax-checks
 140                                   'dont-check-for-anything-just-trust-me))
 141          (message-hidden-headers nil)
 142          (message-inhibit-body-encoding (or is-queue
 143                                             message-inhibit-body-encoding))
 144          (message-send-hook (and (not is-queue)
 145                                  message-send-hook))
 146          (message-setup-hook (and (not is-queue)
 147                                   message-setup-hook))
 148          (message-signature (and (not is-queue)
 149                                  message-signature))
 150          (gnus-agent-queue-mail (and (not is-queue)
 151                                      gnus-agent-queue-mail))
 152          (rfc2047-encode-encoded-words nil)
 153          type method move-to)
 154     (gnus-draft-setup article (or group "nndraft:queue"))
 155     ;; We read the meta-information that says how and where
 156     ;; this message is to be sent.
 157     (save-restriction
 158       (message-narrow-to-headers)
 159       (when (re-search-forward
 160              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 161                      ":") nil t)
 162         (skip-syntax-forward "-")
 163         (setq move-to (buffer-substring (point) (gnus-point-at-eol)))
 164         (message-remove-header gnus-agent-target-move-group-header))
 165       (goto-char (point-min))
 166       (when (re-search-forward
 167              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 168              nil t)
 169         (setq type (ignore-errors (read (current-buffer)))
 170               method (ignore-errors (read (current-buffer))))
 171         (message-remove-header gnus-agent-meta-information-header)))
 172     ;; Let Agent restore any GCC lines and have message.el perform them.
 173     (gnus-agent-restore-gcc)
 174     ;; Then we send it.  If we have no meta-information, we just send
 175     ;; it and let Message figure out how.
 176     (when (and (or (null method)
 177                    (gnus-server-opened method)
 178                    (gnus-open-server method))
 179                (if type
 180                    (let ((message-this-is-news (eq type 'news))
 181                          (message-this-is-mail (eq type 'mail))
 182                          (gnus-post-method method)
 183                          (message-post-method method))
 184                      (if move-to
 185                          (gnus-inews-do-gcc move-to)
 186                        (message-send-and-exit)))
 187                  (if move-to
 188                      (gnus-inews-do-gcc move-to)
 189                    (message-send-and-exit))))
 190       (let ((gnus-verbose-backends nil))
 191         (gnus-request-expire-articles
 192          (list article) (or group "nndraft:queue") t)))))
 193
 194 (defun gnus-draft-send-all-messages ()
 195   "Send all the sendable drafts."
 196   (interactive)
 197   (when (or
 198          gnus-expert-user
 199          (gnus-y-or-n-p
 200           "Send all drafts? "))
 201     (gnus-uu-mark-buffer)
 202     (gnus-draft-send-message)))
 203
 204 (defun gnus-group-send-queue ()
 205   "Send all sendable articles from the queue group."
 206   (interactive)
 207   (when (or gnus-plugged
 208             (not gnus-agent-prompt-send-queue)
 209             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 210     (gnus-activate-group "nndraft:queue")
 211     (save-excursion
 212       (let* ((articles (nndraft-articles))
 213              (unsendable (gnus-uncompress-range
 214                           (cdr (assq 'unsend
 215                                      (gnus-info-marks
 216                                       (gnus-get-info "nndraft:queue"))))))
 217              (gnus-posting-styles nil)
 218              (total (length articles))
 219              article)
 220         (while (setq article (pop articles))
 221           (unless (memq article unsendable)
 222             (let ((message-sending-message
 223                    (format "Sending message %d of %d..."
 224                            (- total (length articles)) total)))
 225               (gnus-draft-send article))))))))
 226
 227 ;;;###autoload
 228 (defun gnus-draft-reminder ()
 229   "Reminder user if there are unsent drafts."
 230   (interactive)
 231   (if (gnus-alive-p)
 232       (let (active)
 233         (catch 'continue
 234           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 235             (setq active (gnus-activate-group group))
 236             (if (and active (>= (cdr active) (car active)))
 237                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 238                     (throw 'continue t)
 239                   (error "Stop!"))))))))
 240
 241 ;;; Utility functions
 242
 243 ;;;!!!If this is byte-compiled, it fails miserably.
 244 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 245 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 246 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 247
 248 (progn
 249   (defun gnus-draft-setup (narticle group &optional restore)
 250     (let (ga)
 251       (gnus-setup-message 'forward
 252         (let ((article narticle))
 253           (message-mail)
 254           (erase-buffer)
 255           (if (not (gnus-request-restore-buffer article group))
 256               (error "Couldn't restore the article")
 257             (when (and restore
 258                        (equal group "nndraft:queue"))
 259               (mime-to-mml))
 260             ;; Insert the separator.
 261             (goto-char (point-min))
 262             (search-forward "\n\n")
 263             (forward-char -1)
 264             (save-restriction
 265               (narrow-to-region (point-min) (point))
 266               (setq ga
 267                     (message-fetch-field gnus-draft-meta-information-header)))
 268             (insert mail-header-separator)
 269             (forward-line 1)
 270             (message-set-auto-save-file-name))))
 271       (gnus-backlog-remove-article group narticle)
 272       (when (and ga
 273                  (ignore-errors (setq ga (car (read-from-string ga)))))
 274         (setq gnus-newsgroup-name
 275               (if (equal (car ga) "") nil (car ga)))
 276         (gnus-configure-posting-styles)
 277         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 278         (setq message-post-method
 279               `(lambda (arg)
 280                  (gnus-post-method arg ,(car ga))))
 281         (unless (equal (cadr ga) "")
 282           (dolist (article (cdr ga))
 283             (message-add-action
 284              `(progn
 285                 (gnus-add-mark ,(car ga) 'replied ,article)
 286                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 287                                                              'add '(reply)))))
 288              'send)))))))
 289
 290 (defun gnus-draft-article-sendable-p (article)
 291   "Say whether ARTICLE is sendable."
 292   (not (memq article gnus-newsgroup-unsendable)))
 293
 294 (defun gnus-draft-check-draft-articles (articles)
 295   "Check whether the draft articles ARTICLES are under edit."
 296   (when (equal gnus-newsgroup-name "nndraft:drafts")
 297     (let ((buffers (buffer-list))
 298           file buffs buff)
 299       (save-current-buffer
 300         (while (and articles
 301                     (not buff))
 302           (setq file (nndraft-article-filename (pop articles))
 303                 buffs buffers)
 304           (while buffs
 305             (set-buffer (setq buff (pop buffs)))
 306             (if (and buffer-file-name
 307                      (string-equal (file-truename buffer-file-name)
 308                                    (file-truename file))
 309                      (buffer-modified-p))
 310                 (setq buffs nil)
 311               (setq buff nil)))))
 312       (when buff
 313         (let* ((window (get-buffer-window buff t))
 314                (frame (and window (window-frame window))))
 315           (if frame
 316               (gnus-select-frame-set-input-focus frame)
 317             (pop-to-buffer buff t)))
 318         (error "The draft %s is under edit" file)))))
 319
 320 (provide 'gnus-draft)
 321
 322 ;;; arch-tag: 3d92af58-8c97-4a5c-9db4-a98e85198022
 323 ;;; gnus-draft.el ends here