lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;;         Riccardo Murri <riccardo.murri@gmail.com>
   7 ;; Keywords: tools
   8 ;; Created: Sept 2006
   9 ;; Version: 2008-01-04 (Bzr revno 25)
  10 ;; URL: http://launchpad.net/vc-bzr
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
  30 ;; <URL:http://launchpad.net/vc-bzr> for alternate development
  31 ;; branches of `vc-bzr'.
  32
  33 ;; Load this library to register bzr support in VC.
  34
  35 ;; Known bugs
  36 ;; ==========
  37
  38 ;; When edititing a symlink and *both* the symlink and its target
  39 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  40 ;; symlink, thereby not detecting whether the actual contents
  41 ;; (that is, the target contents) are changed.
  42 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  43
  44 ;; For an up-to-date list of bugs, please see:
  45 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  46
  47 ;;; Properties of the backend
  48
  49 (defun vc-bzr-revision-granularity () 'repository)
  50 (defun vc-bzr-checkout-model (files) 'implicit)
  51
  52 ;;; Code:
  53
  54 (eval-when-compile
  55   (require 'cl)
  56   (require 'vc)  ;; for vc-exec-after
  57   (require 'vc-dir))
  58
  59 ;; Clear up the cache to force vc-call to check again and discover
  60 ;; new functions when we reload this file.
  61 (put 'Bzr 'vc-functions nil)
  62
  63 (defgroup vc-bzr nil
  64   "VC bzr backend."
  65   :version "22.2"
  66   :group 'vc)
  67
  68 (defcustom vc-bzr-program "bzr"
  69   "Name of the bzr command (excluding any arguments)."
  70   :group 'vc-bzr
  71   :type 'string)
  72
  73 (defcustom vc-bzr-diff-switches nil
  74   "String or list of strings specifying switches for bzr diff under VC.
  75 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  76   :type '(choice (const :tag "Unspecified" nil)
  77                  (const :tag "None" t)
  78                  (string :tag "Argument String")
  79                  (repeat :tag "Argument List" :value ("") string))
  80   :group 'vc-bzr)
  81
  82 (defcustom vc-bzr-log-switches nil
  83   "String or list of strings specifying switches for bzr log under VC."
  84   :type '(choice (const :tag "None" nil)
  85                  (string :tag "Argument String")
  86                  (repeat :tag "Argument List" :value ("") string))
  87   :group 'vc-bzr)
  88
  89 ;; since v0.9, bzr supports removing the progress indicators
  90 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  91 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  92   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  93 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  94 `LC_MESSAGES=C' to the environment."
  95   (let ((process-environment
  96          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  97                 "LC_MESSAGES=C"         ; Force English output
  98                 process-environment)))
  99     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
 100            file-or-list bzr-command args)))
 101
 102
 103 ;;;###autoload
 104 (defconst vc-bzr-admin-dirname ".bzr"
 105   "Name of the directory containing Bzr repository status files.")
 106 ;;;###autoload
 107 (defconst vc-bzr-admin-checkout-format-file
 108   (concat vc-bzr-admin-dirname "/checkout/format"))
 109 (defconst vc-bzr-admin-dirstate
 110   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 111 (defconst vc-bzr-admin-branch-format-file
 112   (concat vc-bzr-admin-dirname "/branch/format"))
 113 (defconst vc-bzr-admin-revhistory
 114   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 115 (defconst vc-bzr-admin-lastrev
 116   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 117
 118 ;;;###autoload (defun vc-bzr-registered (file)
 119 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 120 ;;;###autoload       (progn
 121 ;;;###autoload         (load "vc-bzr")
 122 ;;;###autoload         (vc-bzr-registered file))))
 123
 124 (defun vc-bzr-root (file)
 125   "Return the root directory of the bzr repository containing FILE."
 126   ;; Cache technique copied from vc-arch.el.
 127   (or (vc-file-getprop file 'bzr-root)
 128       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 129         (when root (vc-file-setprop file 'bzr-root root)))))
 130
 131 (require 'sha1)                         ;For sha1-program
 132
 133 (defun vc-bzr-sha1 (file)
 134   (with-temp-buffer
 135     (set-buffer-multibyte nil)
 136     (let ((prog sha1-program)
 137           (args nil))
 138       (when (consp prog)
 139         (setq args (cdr prog))
 140         (setq prog (car prog)))
 141       (apply 'process-file prog (file-relative-name file) t nil args)
 142       (buffer-substring (point-min) (+ (point-min) 40)))))
 143
 144 (defun vc-bzr-state-heuristic (file)
 145   "Like `vc-bzr-state' but hopefully without running Bzr."
 146   ;; `bzr status' was excrutiatingly slow with large histories and
 147   ;; pending merges, so try to avoid using it until they fix their
 148   ;; performance problems.
 149   ;; This function tries first to parse Bzr internal file
 150   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 151   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 152   ;; only parsed if it contains the string `#bazaar dirstate flat
 153   ;; format 3' in the first line.
 154   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 155   ;; running `vc-bzr-state'."
 156   (lexical-let ((root (vc-bzr-root file)))
 157     (when root    ; Short cut.
 158       ;; This looks at internal files.  May break if they change
 159       ;; their format.
 160       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 161         (condition-case nil
 162             (with-temp-buffer
 163               (insert-file-contents dirstate)
 164               (goto-char (point-min))
 165               (if (not (looking-at "#bazaar dirstate flat format 3"))
 166                   (vc-bzr-state file)   ; Some other unknown format?
 167                 (let* ((relfile (file-relative-name file root))
 168                        (reldir (file-name-directory relfile)))
 169                   (if (re-search-forward
 170                        (concat "^\0"
 171                                (if reldir (regexp-quote
 172                                            (directory-file-name reldir)))
 173                                "\0"
 174                                (regexp-quote (file-name-nondirectory relfile))
 175                                "\0"
 176                                "[^\0]*\0"     ;id?
 177                                "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 178                                "[^\0]*\0" ;sha1 (empty if conflicted)?
 179                                "\\([^\0]*\\)\0" ;size?
 180                                "[^\0]*\0"       ;"y/n", executable?
 181                                "[^\0]*\0"       ;?
 182                                "\\([^\0]*\\)\0" ;"a/f/d" a=added?
 183                                "\\([^\0]*\\)\0" ;sha1 again?
 184                                "[^\0]*\0"       ;size again?
 185                                "[^\0]*\0" ;"y/n", executable again?
 186                                "[^\0]*\0" ;last revid?
 187                                ;; There are more fields when merges are pending.
 188                                )
 189                        nil t)
 190                       ;; Apparently the second sha1 is the one we want: when
 191                       ;; there's a conflict, the first sha1 is absent (and the
 192                       ;; first size seems to correspond to the file with
 193                       ;; conflict markers).
 194                       (cond
 195                        ((eq (char-after (match-beginning 1)) ?a) 'removed)
 196                        ((eq (char-after (match-beginning 3)) ?a) 'added)
 197                        ((and (eq (string-to-number (match-string 2))
 198                                  (nth 7 (file-attributes file)))
 199                              (equal (match-string 4)
 200                                     (vc-bzr-sha1 file)))
 201                         'up-to-date)
 202                        (t 'edited))
 203                     'unregistered))))
 204           ;; Either the dirstate file can't be read, or the sha1
 205           ;; executable is missing, or ...
 206           ;; In either case, recent versions of Bzr aren't that slow
 207           ;; any more.
 208           (error (vc-bzr-state file)))))))
 209
 210
 211 (defun vc-bzr-registered (file)
 212   "Return non-nil if FILE is registered with bzr."
 213   (let ((state (vc-bzr-state-heuristic file)))
 214     (not (memq state '(nil unregistered ignored)))))
 215
 216 (defconst vc-bzr-state-words
 217   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 218   "Regexp matching file status words as reported in `bzr' output.")
 219
 220 (defun vc-bzr-file-name-relative (filename)
 221   "Return file name FILENAME stripped of the initial Bzr repository path."
 222   (lexical-let*
 223       ((filename* (expand-file-name filename))
 224        (rootdir (vc-bzr-root filename*)))
 225     (when rootdir
 226          (file-relative-name filename* rootdir))))
 227
 228 (defun vc-bzr-status (file)
 229   "Return FILE status according to Bzr.
 230 Return value is a cons (STATUS . WARNING), where WARNING is a
 231 string or nil, and STATUS is one of the symbols: `added',
 232 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 233 which directly correspond to `bzr status' output, or 'unchanged
 234 for files whose copy in the working tree is identical to the one
 235 in the branch repository, or nil for files that are not
 236 registered with Bzr.
 237
 238 If any error occurred in running `bzr status', then return nil."
 239   (with-temp-buffer
 240     (let ((ret (condition-case nil
 241                    (vc-bzr-command "status" t 0 file)
 242                  (file-error nil)))     ; vc-bzr-program not found.
 243           (status 'unchanged))
 244           ;; the only secure status indication in `bzr status' output
 245           ;; is a couple of lines following the pattern::
 246           ;;   | <status>:
 247           ;;   |   <file name>
 248           ;; if the file is up-to-date, we get no status report from `bzr',
 249           ;; so if the regexp search for the above pattern fails, we consider
 250           ;; the file to be up-to-date.
 251           (goto-char (point-min))
 252           (when (re-search-forward
 253                  ;; bzr prints paths relative to the repository root.
 254                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 255                          (regexp-quote (vc-bzr-file-name-relative file))
 256                          ;; Bzr appends a '/' to directory names and
 257                          ;; '*' to executable files
 258                          (if (file-directory-p file) "/?" "\\*?")
 259                          "[ \t\n]*$")
 260                  nil t)
 261             (lexical-let ((statusword (match-string 1)))
 262               ;; Erase the status text that matched.
 263               (delete-region (match-beginning 0) (match-end 0))
 264               (setq status
 265                     (intern (replace-regexp-in-string " " "" statusword)))))
 266           (when status
 267             (goto-char (point-min))
 268             (skip-chars-forward " \n\t") ;Throw away spaces.
 269             (cons status
 270                   ;; "bzr" will output warnings and informational messages to
 271                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 272                   ;; `start-process' itself) limitations, we cannot catch stderr
 273                   ;; and stdout into different buffers.  So, if there's anything
 274                   ;; left in the buffer after removing the above status
 275                   ;; keywords, let us just presume that any other message from
 276                   ;; "bzr" is a user warning, and display it.
 277                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 278
 279 (defun vc-bzr-state (file)
 280   (lexical-let ((result (vc-bzr-status file)))
 281     (when (consp result)
 282       (when (cdr result)
 283         (message "Warnings in `bzr' output: %s" (cdr result)))
 284       (cdr (assq (car result)
 285                  '((added . added)
 286                    (kindchanged . edited)
 287                    (renamed . edited)
 288                    (modified . edited)
 289                    (removed . removed)
 290                    (ignored . ignored)
 291                    (unknown . unregistered)
 292                    (unchanged . up-to-date)))))))
 293
 294 (defun vc-bzr-resolve-when-done ()
 295   "Call \"bzr resolve\" if the conflict markers have been removed."
 296   (save-excursion
 297     (goto-char (point-min))
 298     (unless (re-search-forward "^<<<<<<< " nil t)
 299       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 300       ;; Remove the hook so that it is not called multiple times.
 301       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 302
 303 (defun vc-bzr-find-file-hook ()
 304   (when (and buffer-file-name
 305              ;; FIXME: We should check that "bzr status" says "conflict".
 306              (file-exists-p (concat buffer-file-name ".BASE"))
 307              (file-exists-p (concat buffer-file-name ".OTHER"))
 308              (file-exists-p (concat buffer-file-name ".THIS"))
 309              ;; If "bzr status" says there's a conflict but there are no
 310              ;; conflict markers, it's not clear what we should do.
 311              (save-excursion
 312                (goto-char (point-min))
 313                (re-search-forward "^<<<<<<< " nil t)))
 314     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 315     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 316     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 317     (smerge-start-session)
 318     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 319     (message "There are unresolved conflicts in this file")))
 320
 321 (defun vc-bzr-workfile-unchanged-p (file)
 322   (eq 'unchanged (car (vc-bzr-status file))))
 323
 324 (defun vc-bzr-working-revision (file)
 325   ;; Together with the code in vc-state-heuristic, this makes it possible
 326   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 327   (lexical-let*
 328       ((rootdir (vc-bzr-root file))
 329        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 330                                              rootdir))
 331        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 332        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 333     ;; This looks at internal files to avoid forking a bzr process.
 334     ;; May break if they change their format.
 335     (if (and (file-exists-p branch-format-file)
 336              ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
 337              ;; the branch-format-file does not contain the revision
 338              ;; information, we need to look up the branch-format-file
 339              ;; in the place where the lightweight checkout comes
 340              ;; from.  We only do that if it's a local file.
 341              (let ((location-fname (expand-file-name
 342                                     (concat vc-bzr-admin-dirname
 343                                             "/branch/location") rootdir)))
 344                ;; The existence of this file is how we distinguish
 345                ;; lightweight checkouts.
 346                (if (file-exists-p location-fname)
 347                    (with-temp-buffer
 348                      (insert-file-contents location-fname)
 349                      (when (re-search-forward "file://\(.+\)" nil t)
 350                        (setq branch-format-file (match-string 1))
 351                        (file-exists-p branch-format-file)))
 352                  t)))
 353         (with-temp-buffer
 354           (insert-file-contents branch-format-file)
 355           (goto-char (point-min))
 356           (cond
 357            ((or
 358              (looking-at "Bazaar-NG branch, format 0.0.4")
 359              (looking-at "Bazaar-NG branch format 5"))
 360             ;; count lines in .bzr/branch/revision-history
 361             (insert-file-contents revhistory-file)
 362             (number-to-string (count-lines (line-end-position) (point-max))))
 363            ((or
 364              (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 365              (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
 366             ;; revno is the first number in .bzr/branch/last-revision
 367             (insert-file-contents lastrev-file)
 368             (when (re-search-forward "[0-9]+" nil t)
 369               (buffer-substring (match-beginning 0) (match-end 0))))))
 370       ;; fallback to calling "bzr revno"
 371       (lexical-let*
 372           ((result (vc-bzr-command-discarding-stderr
 373                     vc-bzr-program "revno" (file-relative-name file)))
 374            (exitcode (car result))
 375            (output (cdr result)))
 376         (cond
 377          ((eq exitcode 0) (substring output 0 -1))
 378          (t nil))))))
 379
 380 (defun vc-bzr-create-repo ()
 381   "Create a new Bzr repository."
 382   (vc-bzr-command "init" nil 0 nil))
 383
 384 (defun vc-bzr-init-revision (&optional file)
 385   "Always return nil, as Bzr cannot register explicit versions."
 386   nil)
 387
 388 (defun vc-bzr-previous-revision (file rev)
 389   (if (string-match "\\`[0-9]+\\'" rev)
 390       (number-to-string (1- (string-to-number rev)))
 391     (concat "before:" rev)))
 392
 393 (defun vc-bzr-next-revision (file rev)
 394   (if (string-match "\\`[0-9]+\\'" rev)
 395       (number-to-string (1+ (string-to-number rev)))
 396     (error "Don't know how to compute the next revision of %s" rev)))
 397
 398 (defun vc-bzr-register (files &optional rev comment)
 399   "Register FILE under bzr.
 400 Signal an error unless REV is nil.
 401 COMMENT is ignored."
 402   (if rev (error "Can't register explicit revision with bzr"))
 403   (vc-bzr-command "add" nil 0 files))
 404
 405 ;; Could run `bzr status' in the directory and see if it succeeds, but
 406 ;; that's relatively expensive.
 407 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 408   "Return non-nil if FILE is (potentially) controlled by bzr.
 409 The criterion is that there is a `.bzr' directory in the same
 410 or a superior directory.")
 411
 412 (defun vc-bzr-could-register (file)
 413   "Return non-nil if FILE could be registered under bzr."
 414   (and (vc-bzr-responsible-p file)      ; shortcut
 415        (condition-case ()
 416            (with-temp-buffer
 417              (vc-bzr-command "add" t 0 file "--dry-run")
 418              ;; The command succeeds with no output if file is
 419              ;; registered (in bzr 0.8).
 420              (goto-char (point-min))
 421              (looking-at "added "))
 422          (error))))
 423
 424 (defun vc-bzr-unregister (file)
 425   "Unregister FILE from bzr."
 426   (vc-bzr-command "remove" nil 0 file "--keep"))
 427
 428 (defun vc-bzr-checkin (files rev comment)
 429   "Check FILE in to bzr with log message COMMENT.
 430 REV non-nil gets an error."
 431   (if rev (error "Can't check in a specific revision with bzr"))
 432   (vc-bzr-command "commit" nil 0 files "-m" comment))
 433
 434 (defun vc-bzr-find-revision (file rev buffer)
 435   "Fetch revision REV of file FILE and put it into BUFFER."
 436     (with-current-buffer buffer
 437       (if (and rev (stringp rev) (not (string= rev "")))
 438           (vc-bzr-command "cat" t 0 file "-r" rev)
 439         (vc-bzr-command "cat" t 0 file))))
 440
 441 (defun vc-bzr-checkout (file &optional editable rev)
 442   (if rev (error "Operation not supported")
 443     ;; Else, there's nothing to do.
 444     nil))
 445
 446 (defun vc-bzr-revert (file &optional contents-done)
 447   (unless contents-done
 448     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 449
 450 (defvar log-view-message-re)
 451 (defvar log-view-file-re)
 452 (defvar log-view-font-lock-keywords)
 453 (defvar log-view-current-tag-function)
 454 (defvar log-view-per-file-logs)
 455
 456 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 457   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 458   (require 'add-log)
 459   (set (make-local-variable 'log-view-per-file-logs) nil)
 460   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 461   (set (make-local-variable 'log-view-message-re)
 462        "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)")
 463   (set (make-local-variable 'log-view-font-lock-keywords)
 464        ;; log-view-font-lock-keywords is careful to use the buffer-local
 465        ;; value of log-view-message-re only since Emacs-23.
 466        (append `((,log-view-message-re . 'log-view-message-face))
 467                ;; log-view-font-lock-keywords
 468                '(("^ *committer: \
 469 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 470                   (1 'change-log-name)
 471                   (2 'change-log-email))
 472                  ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face))))))
 473
 474 (defun vc-bzr-print-log (files &optional buffer) ; get buffer arg in Emacs 22
 475   "Get bzr change log for FILES into specified BUFFER."
 476   ;; `vc-do-command' creates the buffer, but we need it before running
 477   ;; the command.
 478   (vc-setup-buffer buffer)
 479   ;; If the buffer exists from a previous invocation it might be
 480   ;; read-only.
 481   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 482   ;; the log display may not what the user wants - but I see no other
 483   ;; way of getting the above regexps working.
 484   (with-current-buffer buffer
 485     (apply 'vc-bzr-command "log" buffer 'async files
 486            (if (stringp vc-bzr-log-switches)
 487                (list vc-bzr-log-switches)
 488              vc-bzr-log-switches))))
 489
 490 (defun vc-bzr-show-log-entry (revision)
 491   "Find entry for patch name REVISION in bzr change log buffer."
 492   (goto-char (point-min))
 493   (when revision
 494     (let (case-fold-search)
 495       (if (re-search-forward
 496            ;; "revno:" can appear either at the beginning of a line,
 497            ;; or indented.
 498            (concat "^[ ]*-+\n[ ]*revno: "
 499                    ;; The revision can contain ".", quote it so that it
 500                    ;; does not interfere with regexp matching.
 501                    (regexp-quote revision) "$") nil t)
 502           (beginning-of-line 0)
 503         (goto-char (point-min))))))
 504
 505 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 506   "VC bzr backend for diff."
 507   ;; `bzr diff' exits with code 1 if diff is non-empty.
 508   (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*") 'async files
 509          "--diff-options" (mapconcat 'identity
 510                                      (vc-switches 'bzr 'diff)
 511                                      " ")
 512          ;; This `when' is just an optimization because bzr-1.2 is *much*
 513          ;; faster when the revision argument is not given.
 514          (when (or rev1 rev2)
 515            (list "-r" (format "%s..%s"
 516                               (or rev1 "revno:-1")
 517                               (or rev2 ""))))))
 518
 519
 520 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 521 ;; straight integer revisions.
 522
 523 (defun vc-bzr-delete-file (file)
 524   "Delete FILE and delete it in the bzr repository."
 525   (condition-case ()
 526       (delete-file file)
 527     (file-error nil))
 528   (vc-bzr-command "remove" nil 0 file))
 529
 530 (defun vc-bzr-rename-file (old new)
 531   "Rename file from OLD to NEW using `bzr mv'."
 532   (vc-bzr-command "mv" nil 0 new old))
 533
 534 (defvar vc-bzr-annotation-table nil
 535   "Internal use.")
 536 (make-variable-buffer-local 'vc-bzr-annotation-table)
 537
 538 (defun vc-bzr-annotate-command (file buffer &optional revision)
 539   "Prepare BUFFER for `vc-annotate' on FILE.
 540 Each line is tagged with the revision number, which has a `help-echo'
 541 property containing author and date information."
 542   (apply #'vc-bzr-command "annotate" buffer 0 file "--long" "--all"
 543          (if revision (list "-r" revision)))
 544   (with-current-buffer buffer
 545     ;; Store the tags for the annotated source lines in a hash table
 546     ;; to allow saving space by sharing the text properties.
 547     (setq vc-bzr-annotation-table (make-hash-table :test 'equal))
 548     (goto-char (point-min))
 549     (while (re-search-forward "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\) |"
 550                               nil t)
 551       (let* ((rev (match-string 1))
 552              (author (match-string 2))
 553              (date (match-string 3))
 554              (key (match-string 0))
 555              (tag (gethash key vc-bzr-annotation-table)))
 556         (unless tag
 557           (setq tag (propertize rev 'help-echo (concat "Author: " author
 558                                                        ", date: " date)
 559                                 'mouse-face 'highlight))
 560           (puthash key tag vc-bzr-annotation-table))
 561         (replace-match "")
 562         (insert tag " |")))))
 563
 564 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 565
 566 (defun vc-bzr-annotate-time ()
 567   (when (re-search-forward "^ *[0-9.]+ +|" nil t)
 568     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 569       (string-match "[0-9]+\\'" prop)
 570       (let ((str (match-string-no-properties 0 prop)))
 571       (vc-annotate-convert-time
 572        (encode-time 0 0 0
 573                       (string-to-number (substring str 6 8))
 574                       (string-to-number (substring str 4 6))
 575                       (string-to-number (substring str 0 4))))))))
 576
 577 (defun vc-bzr-annotate-extract-revision-at-line ()
 578   "Return revision for current line of annoation buffer, or nil.
 579 Return nil if current line isn't annotated."
 580   (save-excursion
 581     (beginning-of-line)
 582     (if (looking-at " *\\([0-9.]+\\) *| ")
 583         (match-string-no-properties 1))))
 584
 585 (defun vc-bzr-command-discarding-stderr (command &rest args)
 586   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 587 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 588 the (numerical) exit code of the process, and OUTPUT is a string
 589 containing whatever the process sent to its standard output
 590 stream.  Standard error output is discarded."
 591   (with-temp-buffer
 592     (cons
 593      (apply #'process-file command nil (list (current-buffer) nil) nil args)
 594      (buffer-substring (point-min) (point-max)))))
 595
 596 (defun vc-bzr-prettify-state-info (file)
 597   "Bzr-specific version of `vc-prettify-state-info'."
 598   (if (eq 'edited (vc-state file))
 599         (concat "(" (symbol-name (or (vc-file-getprop file 'vc-bzr-state)
 600                                      'edited)) ")")
 601     ;; else fall back to default vc.el representation
 602     (vc-default-prettify-state-info 'Bzr file)))
 603
 604 (defstruct (vc-bzr-extra-fileinfo
 605             (:copier nil)
 606             (:constructor vc-bzr-create-extra-fileinfo (extra-name))
 607             (:conc-name vc-bzr-extra-fileinfo->))
 608   extra-name)         ;; original name for rename targets, new name for
 609
 610 (defun vc-bzr-dir-printer (info)
 611   "Pretty-printer for the vc-dir-fileinfo structure."
 612   (let ((extra (vc-dir-fileinfo->extra info)))
 613     (vc-default-dir-printer 'Bzr info)
 614     (when extra
 615       (insert (propertize
 616                (format "   (renamed from %s)"
 617                        (vc-bzr-extra-fileinfo->extra-name extra))
 618                'face 'font-lock-comment-face)))))
 619
 620 ;; FIXME: this needs testing, it's probably incomplete.
 621 (defun vc-bzr-after-dir-status (update-function)
 622   (let ((status-str nil)
 623         (translation '(("+N " . added)
 624                        ("-D " . removed)
 625                        (" M " . edited) ;; file text modified
 626                        ("  *" . edited) ;; execute bit changed
 627                        (" M*" . edited) ;; text modified + execute bit changed
 628                        ;; FIXME: what about ignored files?
 629                        (" D " . missing)
 630                        ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
 631                        ("C  " . conflict)
 632                        ("?  " . unregistered)
 633                        ("?  " . unregistered)
 634                        ;; No such state, but we need to distinguish this case.
 635                        ("R  " . renamed)
 636                        ;; For a non existent file FOO, the output is:
 637                        ;; bzr: ERROR: Path(s) do not exist: FOO
 638                        ("bzr" . not-found)
 639                        ;; If the tree is not up to date, bzr will print this warning:
 640                        ;; working tree is out of date, run 'bzr update'
 641                        ;; ignore it.
 642                        ;; FIXME: maybe this warning can be put in the vc-dir header...
 643                        ("wor" . not-found)
 644                        ;; Ignore "P " and "P." for pending patches.
 645                        ))
 646         (translated nil)
 647         (result nil))
 648       (goto-char (point-min))
 649       (while (not (eobp))
 650         (setq status-str
 651               (buffer-substring-no-properties (point) (+ (point) 3)))
 652         (setq translated (cdr (assoc status-str translation)))
 653         (cond
 654          ((eq translated 'conflict)
 655           ;; For conflicts the file appears twice in the listing: once
 656           ;; with the M flag and once with the C flag, so take care
 657           ;; not to add it twice to `result'.  Ugly.
 658           (let* ((file
 659                   (buffer-substring-no-properties
 660                    ;;For files with conflicts the format is:
 661                    ;;C   Text conflict in FILENAME
 662                    ;; Bah.
 663                    (+ (point) 21) (line-end-position)))
 664                  (entry (assoc file result)))
 665             (when entry
 666               (setf (nth 1 entry) 'conflict))))
 667          ((eq translated 'renamed)
 668           (re-search-forward "R   \\(.*\\) => \\(.*\\)$" (line-end-position) t)
 669           (let ((new-name (match-string 2))
 670                 (old-name (match-string 1)))
 671             (push (list new-name 'edited
 672                       (vc-bzr-create-extra-fileinfo old-name)) result)))
 673          ;; do nothing for non existent files
 674          ((eq translated 'not-found))
 675          (t
 676           (push (list (buffer-substring-no-properties
 677                        (+ (point) 4)
 678                        (line-end-position))
 679                       translated) result)))
 680         (forward-line))
 681       (funcall update-function result)))
 682
 683 (defun vc-bzr-dir-status (dir update-function)
 684   "Return a list of conses (file . state) for DIR."
 685   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 686   (vc-exec-after
 687    `(vc-bzr-after-dir-status (quote ,update-function))))
 688
 689 (defun vc-bzr-dir-status-files (dir files default-state update-function)
 690   "Return a list of conses (file . state) for DIR."
 691   (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
 692   (vc-exec-after
 693    `(vc-bzr-after-dir-status (quote ,update-function))))
 694
 695 (defun vc-bzr-dir-extra-headers (dir)
 696   (let*
 697       ((str (with-temp-buffer
 698               (vc-bzr-command "info" t 0 dir)
 699               (buffer-string)))
 700        (light-checkout
 701         (when (string-match ".+light checkout root: \\(.+\\)$" str)
 702           (match-string 1 str)))
 703        (light-checkout-branch
 704         (when light-checkout
 705           (when (string-match ".+checkout of branch: \\(.+\\)$" str)
 706             (match-string 1 str)))))
 707     (concat
 708      (propertize "Parent branch      : " 'face 'font-lock-type-face)
 709      (propertize
 710       (if (string-match "parent branch: \\(.+\\)$" str)
 711           (match-string 1 str)
 712         "None")
 713        'face 'font-lock-variable-name-face)
 714      "\n"
 715       (when light-checkout
 716         (concat
 717          (propertize "Light checkout root: " 'face 'font-lock-type-face)
 718          (propertize light-checkout 'face 'font-lock-variable-name-face)
 719          "\n"))
 720       (when light-checkout-branch
 721         (concat
 722          (propertize "Checkout of branch : " 'face 'font-lock-type-face)
 723          (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
 724          "\n")))))
 725
 726 ;;; Revision completion
 727
 728 (defun vc-bzr-revision-completion-table (files)
 729   (lexical-let ((files files))
 730     ;; What about using `files'?!?  --Stef
 731     (lambda (string pred action)
 732       (cond
 733        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
 734                       string)
 735         (completion-table-with-context (substring string 0 (match-end 0))
 736                                        ;; FIXME: only allow directories.
 737                                        ;; FIXME: don't allow envvars.
 738                                        'read-file-name-internal
 739                                        (substring string (match-end 0))
 740                                        ;; Dropping `pred'.   Maybe we should
 741                                        ;; just stash it in
 742                                        ;; `read-file-name-predicate'?
 743                                        nil
 744                                        action))
 745        ((string-match "\\`\\(before\\):" string)
 746         (completion-table-with-context (substring string 0 (match-end 0))
 747                                        (vc-bzr-revision-completion-table files)
 748                                        (substring string (match-end 0))
 749                                        pred
 750                                        action))
 751        ((string-match "\\`\\(tag\\):" string)
 752         (let ((prefix (substring string 0 (match-end 0)))
 753               (tag (substring string (match-end 0)))
 754               (table nil))
 755           (with-temp-buffer
 756             ;; "bzr-1.2 tags" is much faster with --show-ids.
 757             (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
 758             ;; The output is ambiguous, unless we assume that revids do not
 759             ;; contain spaces.
 760             (goto-char (point-min))
 761             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
 762               (push (match-string-no-properties 1) table)))
 763           (completion-table-with-context prefix table tag pred action)))
 764
 765        ((string-match "\\`\\(revid\\):" string)
 766         ;; FIXME: How can I get a list of revision ids?
 767         )
 768        ((eq (car-safe action) 'boundaries)
 769         (list* 'boundaries
 770                (string-match "[^:]*\\'" string)
 771                (string-match ":" (cdr action))))
 772        (t
 773         ;; Could use completion-table-with-terminator, except that it
 774         ;; currently doesn't work right w.r.t pcm and doesn't give
 775         ;; the *Completions* output we want.
 776         (complete-with-action action '("revno:" "revid:" "last:" "before:"
 777                                        "tag:" "date:" "ancestor:" "branch:"
 778                                        "submit:")
 779                               string pred))))))
 780
 781 (eval-after-load "vc"
 782   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
 783
 784 (provide 'vc-bzr)
 785 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
 786 ;;; vc-bzr.el ends here