configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## This is an option because I do not know if all info/man support
 186 ## compressed files, nor how to test if they do so.
 187 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 188 if test $with_compress_info = yes; then
 189    GZIP_INFO=yes
 190 else
 191    GZIP_INFO=
 192 fi
 193 AC_SUBST(GZIP_INFO)
 194
 195 AC_ARG_WITH([pkg-config-prog],dnl
 196 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 197                   [path to pkg-config for finding GTK and librsvg])])
 198 if test "X${with_pkg_config_prog}" != X; then
 199    if test "${with_pkg_config_prog}" != yes; then
 200       PKG_CONFIG="${with_pkg_config_prog}"
 201    fi
 202 fi
 203
 204 CRT_DIR=
 205 AC_ARG_WITH([crt-dir],dnl
 206 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 207 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 208 CRT_DIR="${with_crt_dir}"
 209
 210 AC_ARG_WITH(gameuser,dnl
 211 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 212 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 213   && gameuser="${with_gameuser}"
 214 test "X$gameuser" = X && gameuser=games
 215
 216 AC_ARG_WITH([gnustep-conf],dnl
 217 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 218 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 219   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 220 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 221      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 222
 223 AC_ARG_ENABLE(ns-self-contained,
 224 [AS_HELP_STRING([--disable-ns-self-contained],
 225                 [disable self contained build under NeXTstep])],
 226    EN_NS_SELF_CONTAINED=$enableval,
 227    EN_NS_SELF_CONTAINED=yes)
 228
 229 AC_ARG_ENABLE(asserts,
 230 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 231       USE_XASSERTS=$enableval,
 232       USE_XASSERTS=no)
 233
 234 AC_ARG_ENABLE(maintainer-mode,
 235 [AS_HELP_STRING([--disable-maintainer-mode],
 236                 [disable make rules and dependencies not useful (and sometimes
 237                  confusing) to the casual installer])],
 238       USE_MAINTAINER_MODE=$enableval,
 239       USE_MAINTAINER_MODE=yes)
 240 if test $USE_MAINTAINER_MODE = yes; then
 241   MAINT=
 242 else
 243   MAINT=#
 244 fi
 245 AC_SUBST(MAINT)
 246
 247 AC_ARG_ENABLE(locallisppath,
 248 [AS_HELP_STRING([--enable-locallisppath=PATH],
 249                 [directories Emacs should search for lisp files specific
 250                  to this site])],
 251 if test "${enableval}" = "no"; then
 252   locallisppath=
 253 elif test "${enableval}" != "yes"; then
 254   locallisppath=${enableval}
 255 fi)
 256
 257 AC_ARG_ENABLE(checking,
 258 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 259                 [enable expensive run-time checks.  With LIST,
 260                  enable only specific categories of checks.
 261                  Categories are: all,yes,no.
 262                  Flags are: stringbytes, stringoverrun, stringfreelist,
 263                  xmallocoverrun, conslist])],
 264 [ac_checking_flags="${enableval}"],[])
 265 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 266 for check in $ac_checking_flags
 267 do
 268         case $check in
 269         # these set all the flags to specific states
 270         yes)            ac_enable_checking=1 ;;
 271         no)             ac_enable_checking= ;
 272                         ac_gc_check_stringbytes= ;
 273                         ac_gc_check_string_overrun= ;
 274                         ac_gc_check_string_free_list= ;
 275                         ac_xmalloc_overrun= ;
 276                         ac_gc_check_cons_list= ;;
 277         all)            ac_enable_checking=1 ;
 278                         ac_gc_check_stringbytes=1 ;
 279                         ac_gc_check_string_overrun=1 ;
 280                         ac_gc_check_string_free_list=1 ;
 281                         ac_xmalloc_overrun=1 ;
 282                         ac_gc_check_cons_list=1 ;;
 283         # these enable particular checks
 284         stringbytes)    ac_gc_check_stringbytes=1 ;;
 285         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 286         stringfreelist) ac_gc_check_string_free_list=1 ;;
 287         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 288         conslist)       ac_gc_check_cons_list=1 ;;
 289         *)      AC_MSG_ERROR(unknown check category $check) ;;
 290         esac
 291 done
 292 IFS="$ac_save_IFS"
 293
 294 if test x$ac_enable_checking != x ; then
 295   AC_DEFINE(ENABLE_CHECKING, 1,
 296 [Enable expensive run-time checking of data types?])
 297 fi
 298 if test x$ac_gc_check_stringbytes != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 300 [Define this temporarily to hunt a bug.  If defined, the size of
 301    strings is redundantly recorded in sdata structures so that it can
 302    be compared to the sizes recorded in Lisp strings.])
 303 fi
 304 if test x$ac_gc_check_string_overrun != x ; then
 305   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 306 [Define this to check for short string overrun.])
 307 fi
 308 if test x$ac_gc_check_string_free_list != x ; then
 309   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 310 [Define this to check the string free list.])
 311 fi
 312 if test x$ac_xmalloc_overrun != x ; then
 313   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 314 [Define this to check for malloc buffer overrun.])
 315 fi
 316 if test x$ac_gc_check_cons_list != x ; then
 317   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 318 [Define this to check for errors in cons list.])
 319 fi
 320
 321 AC_ARG_ENABLE(use-lisp-union-type,
 322 [AS_HELP_STRING([--enable-use-lisp-union-type],
 323                 [use a union for the Lisp_Object data type.
 324                 This is only useful for development for catching certain types of bugs.])],
 325 if test "${enableval}" != "no"; then
 326    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 327    [Define this to use a lisp union for the Lisp_Object data type.])
 328 fi)
 329
 330
 331 AC_ARG_ENABLE(profiling,
 332 [AS_HELP_STRING([--enable-profiling],
 333                 [build emacs with profiling support.
 334                  This might not work on all platforms])],
 335 [ac_enable_profiling="${enableval}"],[])
 336 if test x$ac_enable_profiling != x ; then
 337    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 338 else
 339    PROFILING_CFLAGS=
 340 fi
 341 AC_SUBST(PROFILING_CFLAGS)
 342
 343 AC_ARG_ENABLE(autodepend,
 344 [AS_HELP_STRING([--enable-autodepend],
 345                 [automatically generate dependencies to .h-files.
 346                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 347                  found])],
 348 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 349
 350 #### Make srcdir absolute, if it isn't already.  It's important to
 351 #### avoid running the path through pwd unnecessarily, since pwd can
 352 #### give you automounter prefixes, which can go away.  We do all this
 353 #### so Emacs can find its files when run uninstalled.
 354 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 355 unset CDPATH
 356 case "${srcdir}" in
 357   /* ) ;;
 358   . )
 359     ## We may be able to use the $PWD environment variable to make this
 360     ## absolute.  But sometimes PWD is inaccurate.
 361     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 362     ## but that tested only for a well-formed and valid PWD,
 363     ## it did not object when PWD was well-formed and valid but just wrong.
 364     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 365     then
 366       srcdir="$PWD"
 367     else
 368       srcdir="`(cd ${srcdir}; pwd)`"
 369     fi
 370   ;;
 371   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 372 esac
 373
 374 #### Given the configuration name, set machfile and opsysfile to the
 375 #### names of the m/*.h and s/*.h files we should use.
 376
 377 ### Canonicalize the configuration name.
 378
 379 AC_CANONICAL_HOST
 380 canonical=$host
 381 configuration=${host_alias-${build_alias-$host}}
 382
 383 dnl This used to use changequote, but, apart from `changequote is evil'
 384 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 385 dnl the great gob of text.  Thus it's not processed for possible expansion.
 386 dnl Just make sure the brackets remain balanced.
 387 dnl
 388 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 389 dnl indicated by comments.
 390 dnl quotation begins
 391 [
 392
 393 ### If you add support for a new configuration, add code to this
 394 ### switch statement to recognize your configuration name and select
 395 ### the appropriate operating system and machine description files.
 396
 397 ### You would hope that you could choose an m/*.h file pretty much
 398 ### based on the machine portion of the configuration name, and an s/*.h
 399 ### file based on the operating system portion.  However, it turns out
 400 ### that each m/*.h file is pretty manufacturer-specific - for
 401 ### example mips.h is MIPS
 402 ### So we basically have to have a special case for each
 403 ### configuration name.
 404 ###
 405 ### As far as handling version numbers on operating systems is
 406 ### concerned, make sure things will fail in a fixable way.  If
 407 ### /etc/MACHINES doesn't say anything about version numbers, be
 408 ### prepared to handle anything reasonably.  If version numbers
 409 ### matter, be sure /etc/MACHINES says something about it.
 410
 411 machine='' opsys='' unported=no
 412 case "${canonical}" in
 413
 414   ## GNU/Linux and similar ports
 415   *-*-linux* )
 416     opsys=gnu-linux
 417     case ${canonical} in
 418       alpha*)   machine=alpha ;;
 419       s390-*)   machine=ibms390 ;;
 420       s390x-*)  machine=ibms390x ;;
 421       powerpc*) machine=macppc ;;
 422       sparc*)   machine=sparc ;;
 423       ia64*)    machine=ia64 ;;
 424       m68k*)    machine=m68k ;;
 425       x86_64*)  machine=amdx86-64 ;;
 426     esac
 427   ;;
 428
 429   ## FreeBSD ports
 430   *-*-freebsd* )
 431     opsys=freebsd
 432     case "${canonical}" in
 433       alpha*)           machine=alpha ;;
 434       amd64-*|x86_64-*) machine=amdx86-64 ;;
 435       ia64-*)           machine=ia64 ;;
 436       i[3456]86-*)      machine=intel386 ;;
 437       powerpc-*)        machine=macppc ;;
 438       sparc-*)          machine=sparc ;;
 439       sparc64-*)        machine=sparc ;;
 440     esac
 441   ;;
 442
 443   ## FreeBSD kernel + glibc based userland
 444   *-*-kfreebsd*gnu* )
 445     opsys=gnu-kfreebsd
 446     case "${canonical}" in
 447       alpha*)           machine=alpha ;;
 448       amd64-*|x86_64-*) machine=amdx86-64 ;;
 449       ia64-*)           machine=ia64 ;;
 450       i[3456]86-*)      machine=intel386 ;;
 451       powerpc-*)        machine=macppc ;;
 452       sparc-*)          machine=sparc ;;
 453       sparc64-*)        machine=sparc ;;
 454     esac
 455   ;;
 456
 457   ## NetBSD ports
 458   *-*-netbsd* )
 459     opsys=netbsd
 460     case "${canonical}" in
 461       alpha*)      machine=alpha ;;
 462       x86_64-*)    machine=amdx86-64 ;;
 463       i[3456]86-*) machine=intel386 ;;
 464       m68k-*)      machine=m68k ;;
 465       powerpc-*)   machine=macppc ;;
 466       sparc*-)     machine=sparc ;;
 467       vax-*)       machine=vax ;;
 468     esac
 469   ;;
 470
 471   ## OpenBSD ports
 472   *-*-openbsd* )
 473     opsys=openbsd
 474     case "${canonical}" in
 475       alpha*)    machine=alpha ;;
 476       x86_64-*)  machine=amdx86-64 ;;
 477       i386-*)    machine=intel386 ;;
 478       powerpc-*) machine=macppc ;;
 479       sparc*)    machine=sparc ;;
 480       vax-*)     machine=vax ;;
 481     esac
 482   ;;
 483
 484   ## Apple Darwin / Mac OS X
 485   *-apple-darwin* )
 486     case "${canonical}" in
 487       i[3456]86-* )  machine=intel386 ;;
 488       powerpc-* )    machine=macppc ;;
 489       x86_64-* )     machine=amdx86-64 ;;
 490       * )            unported=yes ;;
 491     esac
 492     opsys=darwin
 493     # Define CPP as follows to make autoconf work correctly.
 494     CPP="${CC-cc} -E -no-cpp-precomp"
 495     # Use fink packages if available.
 496     if test -d /sw/include && test -d /sw/lib; then
 497       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 498       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 499       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 500     fi
 501   ;;
 502
 503   ## HP 9000 series 700 and 800, running HP/UX
 504   hppa*-hp-hpux10.2* )
 505     opsys=hpux10-20
 506   ;;
 507   hppa*-hp-hpux1[1-9]* )
 508     opsys=hpux11
 509     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 510   ;;
 511
 512   ## IBM machines
 513   rs6000-ibm-aix4.[23]* )
 514     machine=ibmrs6000 opsys=aix4-2
 515   ;;
 516   powerpc-ibm-aix4.[23]*  )
 517     machine=ibmrs6000 opsys=aix4-2
 518   ;;
 519   rs6000-ibm-aix[56]* )
 520     machine=ibmrs6000 opsys=aix4-2
 521   ;;
 522   powerpc-ibm-aix[56]*  )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525
 526   ## Silicon Graphics machines
 527   ## Iris 4D
 528   mips-sgi-irix6.5 )
 529     opsys=irix6-5
 530     # Without defining _LANGUAGE_C, things get masked out in the headers
 531     # so that, for instance, grepping for `free' in stdlib.h fails and
 532     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 533     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 534     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 535   ;;
 536
 537   ## Suns
 538   *-sun-solaris* \
 539     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 540     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 541     case "${canonical}" in
 542       i[3456]86-*-* )     machine=intel386 ;;
 543       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 544       sparc* )          machine=sparc ;;
 545       * )               unported=yes ;;
 546     esac
 547     case "${canonical}" in
 548       *-sunos5.6* | *-solaris2.6* )
 549                 opsys=sol2-6
 550                 NON_GNU_CPP=/usr/ccs/lib/cpp
 551                 RANLIB="ar -ts"
 552                 ;;
 553       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 554                 opsys=sol2-6
 555                 emacs_check_sunpro_c=yes
 556                 NON_GNU_CPP=/usr/ccs/lib/cpp
 557                 ;;
 558       *-sunos5* | *-solaris* )
 559                 opsys=sol2-10
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563     esac
 564     ## Watch out for a compiler that we know will not work.
 565     case "${canonical}" in
 566      *-solaris* | *-sunos5* )
 567                 if [ "x$CC" = x/usr/ucb/cc ]; then
 568                   ## /usr/ucb/cc doesn't work;
 569                   ## we should find some other compiler that does work.
 570                   unset CC
 571                 fi
 572                 ;;
 573       *) ;;
 574     esac
 575   ;;
 576
 577   ## Intel 386 machines where we don't care about the manufacturer.
 578   i[3456]86-*-* )
 579     machine=intel386
 580     case "${canonical}" in
 581       *-cygwin )                opsys=cygwin ;;
 582       *-darwin* )               opsys=darwin
 583                                 CPP="${CC-cc} -E -no-cpp-precomp"
 584                                 ;;
 585       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 586       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 587       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 588       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 589     esac
 590   ;;
 591
 592   * )
 593     unported=yes
 594   ;;
 595 esac
 596
 597 ### If the code above didn't choose an operating system, just choose
 598 ### an operating system based on the configuration name.  You really
 599 ### only want to use this when you have no idea what the right
 600 ### operating system is; if you know what operating systems a machine
 601 ### runs, it's cleaner to make it explicit in the case statement
 602 ### above.
 603 if test x"${opsys}" = x; then
 604   case "${canonical}" in
 605     *-gnu* )                            opsys=gnu ;;
 606     * )
 607       unported=yes
 608     ;;
 609   esac
 610 fi
 611
 612 ]
 613 dnl quotation ends
 614
 615 if test $unported = yes; then
 616   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 617 Check `etc/MACHINES' for recognized configuration names.])
 618 fi
 619
 620 if test -n "$machine"; then
 621   machfile="m/${machine}.h"
 622 else
 623   machfile=
 624 fi
 625 opsysfile="s/${opsys}.h"
 626
 627
 628 #### Choose a compiler.
 629 test -n "$CC" && cc_specified=yes
 630
 631 # Save the value of CFLAGS that the user specified.
 632 SPECIFIED_CFLAGS="$CFLAGS"
 633
 634 dnl Sets GCC=yes if using gcc.
 635 AC_PROG_CC
 636 AM_PROG_CC_C_O
 637
 638 # Initialize gnulib right after verifying that the C compiler works.
 639 gl_EARLY
 640
 641 # On Suns, sometimes $CPP names a directory.
 642 if test -n "$CPP" && test -d "$CPP"; then
 643   CPP=
 644 fi
 645
 646 ## If not using gcc, and on Solaris, and no CPP specified, see if
 647 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 648 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 649  test x"$CPP" = x; then
 650   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 651   AC_CACHE_VAL(emacs_cv_sunpro_c,
 652   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 653 [[#ifndef __SUNPRO_C
 654 fail;
 655 #endif
 656 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 657   AC_MSG_RESULT($emacs_cv_sunpro_c)
 658
 659   if test x"$emacs_cv_sunpro_c" = xyes; then
 660     NON_GNU_CPP="$CC -E -Xs"
 661   fi
 662 fi
 663
 664 #### Some systems specify a CPP to use unless we are using GCC.
 665 #### Now that we know whether we are using GCC, we can decide whether
 666 #### to use that one.
 667 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 668 then
 669   CPP="$NON_GNU_CPP"
 670 fi
 671
 672 #### Some systems specify a CC to use unless we are using GCC.
 673 #### Now that we know whether we are using GCC, we can decide whether
 674 #### to use that one.
 675 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 676   test x$cc_specified != xyes
 677 then
 678   CC="$NON_GNU_CC"
 679 fi
 680
 681 if test x$GCC = xyes; then
 682   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 683 else
 684   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 685 fi
 686
 687 ### Use -Wdeclaration-after-statement if the compiler supports it
 688 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 689 SAVE_CFLAGS="$CFLAGS"
 690 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 691 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 692 if test $has_option = yes; then
 693    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 694 fi
 695 AC_MSG_RESULT($has_option)
 696 CFLAGS="$SAVE_CFLAGS"
 697 unset has_option
 698 unset SAVE_CFLAGS
 699
 700 ### Use -Wold-style-definition if the compiler supports it
 701 # This can be removed when conversion to standard C is finished.
 702 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 703 SAVE_CFLAGS="$CFLAGS"
 704 CFLAGS="$CFLAGS -Wold-style-definition"
 705 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 706 if test $has_option = yes; then
 707    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 708 fi
 709 AC_MSG_RESULT($has_option)
 710 CFLAGS="$SAVE_CFLAGS"
 711 unset has_option
 712 unset SAVE_CFLAGS
 713
 714 ### Use -Wimplicit-function-declaration if the compiler supports it
 715 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 716 SAVE_CFLAGS="$CFLAGS"
 717 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 718 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 719 if test $has_option = yes; then
 720    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 721 fi
 722 AC_MSG_RESULT($has_option)
 723 CFLAGS="$SAVE_CFLAGS"
 724 unset has_option
 725 unset SAVE_CFLAGS
 726
 727 AC_SUBST(C_WARNINGS_SWITCH)
 728
 729
 730 #### Some other nice autoconf tests.
 731
 732 dnl checks for programs
 733 AC_PROG_CPP
 734 AC_PROG_INSTALL
 735 if test "x$RANLIB" = x; then
 736   AC_PROG_RANLIB
 737 fi
 738
 739 ## Although we're running on an amd64 kernel, we're actually compiling for
 740 ## the x86 architecture.  The user should probably have provided an
 741 ## explicit --build to `configure', but if everything else than the kernel
 742 ## is running in i386 mode, we can help them out.
 743 if test "$machine" = "amdx86-64"; then
 744   AC_CHECK_DECL([i386])
 745   if test "$ac_cv_have_decl_i386" = "yes"; then
 746     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 747     machine=intel386
 748     machfile="m/${machine}.h"
 749   fi
 750 fi
 751
 752 AC_PATH_PROG(INSTALL_INFO, install-info)
 753 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 754 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 755 dnl Don't use GZIP, which is used by gzip for additional parameters.
 756 AC_PATH_PROG(GZIP_PROG, gzip)
 757
 758
 759 ## Need makeinfo >= 4.6 (?) to build the manuals.
 760 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 761 dnl By this stage, configure has already checked for egrep and set EGREP,
 762 dnl or exited with an error if no egrep was found.
 763 if test "$MAKEINFO" != "no" && \
 764   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 765    MAKEINFO=no
 766 fi
 767
 768 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 769 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 770 ## therefore in the category of "special tools" not normally required, which
 771 ## configure does not have to check for (eg autoconf itself).
 772 ## In a Bazaar checkout on the other hand, the manuals are not included.
 773 ## So makeinfo is a requirement to build from Bazaar, and configure
 774 ## should test for it as it does for any other build requirement.
 775 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 776 ## with pre-built manuals, from a Bazaar checkout.
 777 HAVE_MAKEINFO=yes
 778
 779 if test "$MAKEINFO" = "no"; then
 780   MAKEINFO=makeinfo
 781   if test "x${with_makeinfo}" = "xno"; then
 782     HAVE_MAKEINFO=no
 783   elif test ! -e $srcdir/info/emacs; then
 784     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 785 source tree does not seem to have pre-built manuals in the `info' directory.
 786 Either install a suitable version of makeinfo, or re-run configure
 787 with the `--without-makeinfo' option to build without the manuals.] )
 788   fi
 789 fi
 790 AC_SUBST(HAVE_MAKEINFO)
 791
 792 dnl Add our options to ac_link now, after it is set up.
 793
 794 if test x$GCC = xyes; then
 795   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 796     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 797 else
 798   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 799     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 800 fi
 801
 802 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 803 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 804 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 805 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 806 dnl if not built to support GNU ld.
 807
 808 late_LDFLAGS=$LDFLAGS
 809 if test x$GCC = xyes; then
 810   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 811 else
 812   LDFLAGS="$LDFLAGS -znocombreloc"
 813 fi
 814
 815 AC_MSG_CHECKING([for -znocombreloc])
 816 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 817   [AC_MSG_RESULT(yes)],
 818   LDFLAGS=$late_LDFLAGS
 819   [AC_MSG_RESULT(no)])
 820
 821
 822 # The value of CPP is a quoted variable reference, so we need to do this
 823 # to get its actual value...
 824 CPP=`eval "echo $CPP"`
 825
 826
 827 dnl The function dump-emacs will not be defined and temacs will do
 828 dnl (load "loadup") automatically unless told otherwise.
 829 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 830 case "$opsys" in
 831   your-opsys-here) CANNOT_DUMP=yes ;;
 832 esac
 833
 834 test "$CANNOT_DUMP" = "yes" && \
 835   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 836
 837 AC_SUBST(CANNOT_DUMP)
 838
 839
 840 UNEXEC_OBJ=unexelf.o
 841 case "$opsys" in
 842   # MSDOS uses unexcoff.o
 843   # MSWindows uses unexw32.o
 844   aix4-2)
 845    UNEXEC_OBJ=unexaix.o
 846    ;;
 847   cygwin)
 848    UNEXEC_OBJ=unexcw.o
 849    ;;
 850   darwin)
 851    UNEXEC_OBJ=unexmacosx.o
 852    ;;
 853   hpux10-20 | hpux11)
 854    UNEXEC_OBJ=unexhp9k800.o
 855    ;;
 856   sol2-10)
 857    # Use the Solaris dldump() function, called from unexsol.c, to dump
 858    # emacs, instead of the generic ELF dump code found in unexelf.c.
 859    # The resulting binary has a complete symbol table, and is better
 860    # for debugging and other observability tools (debuggers, pstack, etc).
 861    #
 862    # If you encounter a problem using dldump(), please consider sending
 863    # a message to the OpenSolaris tools-linking mailing list:
 864    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 865    #
 866    # It is likely that dldump() works with older Solaris too, but this has
 867    # not been tested, so for now this change is for Solaris 10 or newer.
 868    UNEXEC_OBJ=unexsol.o
 869    ;;
 870 esac
 871
 872 LD_SWITCH_SYSTEM=
 873 case "$opsys" in
 874   freebsd)
 875    ## Let `ld' find image libs and similar things in /usr/local/lib.
 876    ## The system compiler, GCC, has apparently been modified to not
 877    ## look there, contrary to what a stock GCC would do.
 878    LD_SWITCH_SYSTEM=-L/usr/local/lib
 879    ;;
 880
 881   gnu-linux)
 882    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 883    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 884    ;;
 885
 886   netbsd)
 887    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 888    ;;
 889
 890   openbsd)
 891    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 892    ## otherwise Emacs dumps core on elf systems.
 893    LD_SWITCH_SYSTEM="-Z"
 894    ;;
 895 esac
 896 AC_SUBST(LD_SWITCH_SYSTEM)
 897
 898 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 899
 900 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 901 ## which has not been defined yet.  When this was handled with cpp,
 902 ## it was expanded to null when configure sourced the s/*.h file.
 903 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 904 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 905 ## (or somesuch), but because it is supposed to go at the _front_
 906 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 907 ## Compare with the gnu-linux case below, which added to the end
 908 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 909 ## LD_SWITCH_SYSTEM_TEMACS.
 910 case "$opsys" in
 911   netbsd|openbsd)
 912    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 913    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 914 esac
 915
 916
 917 C_SWITCH_MACHINE=
 918 if test "$machine" = "alpha"; then
 919   AC_CHECK_DECL([__ELF__])
 920   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 921     ## With ELF, make sure that all common symbols get allocated to in the
 922     ## data section.  Otherwise, the dump of temacs may miss variables in
 923     ## the shared library that have been initialized.  For example, with
 924     ## GNU libc, __malloc_initialized would normally be resolved to the
 925     ## shared library's .bss section, which is fatal.
 926     if test "x$GCC" = "xyes"; then
 927       C_SWITCH_MACHINE="-fno-common"
 928     else
 929       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 930     fi
 931   else
 932     UNEXEC_OBJ=unexalpha.o
 933   fi
 934 fi
 935 AC_SUBST(C_SWITCH_MACHINE)
 936
 937 AC_SUBST(UNEXEC_OBJ)
 938
 939 C_SWITCH_SYSTEM=
 940 ## Some programs in src produce warnings saying certain subprograms
 941 ## are too complex and need a MAXMEM value greater than 2000 for
 942 ## additional optimization.  --nils@exp-math.uni-essen.de
 943 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 944   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 945 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 946 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 947 AC_SUBST(C_SWITCH_SYSTEM)
 948
 949
 950 LIBS_SYSTEM=
 951 case "$opsys" in
 952   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 953   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 954
 955   freebsd) LIBS_SYSTEM="-lutil" ;;
 956
 957   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 958
 959   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 960
 961   ## Motif needs -lgen.
 962   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 963 esac
 964 AC_SUBST(LIBS_SYSTEM)
 965
 966
 967 ### Make sure subsequent tests use flags consistent with the build flags.
 968
 969 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 970   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 971 else
 972   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 973 fi
 974
 975 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 976 AC_DEFUN([AC_TYPE_SIZE_T])
 977 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 978 AC_DEFUN([AC_TYPE_UID_T])
 979
 980 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 981 AC_SYS_LARGEFILE
 982
 983
 984 LIB_MATH=-lm
 985 LIB_STANDARD=
 986 START_FILES=
 987
 988 case $opsys in
 989   cygwin )
 990     LIB_MATH=
 991     START_FILES='pre-crt0.o'
 992     ;;
 993   darwin )
 994     ## Adding -lm confuses the dynamic linker, so omit it.
 995     LIB_MATH=
 996     START_FILES='pre-crt0.o'
 997     ;;
 998   freebsd )
 999     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1000     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1001     ;;
1002   gnu-linux | gnu-kfreebsd )
1003     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1004     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1005     ;;
1006   hpux10-20 | hpux11 )
1007     LIB_STANDARD=-lc
1008     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1009     ;;
1010   netbsd | openbsd )
1011     if test -f $CRT_DIR/crti.o; then
1012         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1013         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1014     else
1015         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1016         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1017     fi
1018     ;;
1019 esac
1020
1021 AC_SUBST(LIB_MATH)
1022 AC_SUBST(START_FILES)
1023
1024 dnl Not all platforms use crtn.o files.  Check if the current one does.
1025 crt_files=
1026
1027 for file in x $LIB_STANDARD $START_FILES; do
1028   case "$file" in
1029     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1030   esac
1031 done
1032
1033 if test "x$crt_files" != x; then
1034
1035   ## If user specified a crt-dir, use that unconditionally.
1036   crt_gcc=no
1037
1038   if test "X$CRT_DIR" = "X"; then
1039
1040     CRT_DIR=/usr/lib            # default
1041
1042     case "$canonical" in
1043       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1044       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1045       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1046       ## For anything else (eg /usr/lib32), it is up the user to specify
1047       ## the location (bug#5655).
1048       ## Test for crtn.o, not just the directory, because sometimes the
1049       ## directory exists but does not have the relevant files (bug#1287).
1050       ## FIXME better to test for binary compatibility somehow.
1051       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1052       ;;
1053
1054       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1055     esac
1056
1057     case "$opsys" in
1058       hpux10-20) CRT_DIR=/lib ;;
1059     esac
1060
1061     test "x${GCC}" = xyes && crt_gcc=yes
1062
1063   fi                            # CRT_DIR = ""
1064
1065   crt_missing=
1066
1067   for file in $crt_files; do
1068
1069     ## If we're using gcc, try to determine it automatically by asking
1070     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1071     ## system-dependent default from above.]
1072     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1073
1074        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1075        case "$crt_file" in
1076          */*)
1077            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1078            ;;
1079        esac
1080     fi
1081
1082     dnl We expect all the files to be in a single directory, so after the
1083     dnl first there is no point asking gcc.
1084     crt_gcc=no
1085
1086     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1087   done                          # $crt_files
1088
1089   test "x$crt_missing" = x || \
1090     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1091 Try using the --with-crt-dir option.])
1092
1093 fi                              # crt_files != ""
1094
1095 AC_SUBST(CRT_DIR)
1096
1097
1098 dnl This function definition taken from Gnome 2.0
1099 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1100 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1101 dnl also defines GSTUFF_PKG_ERRORS on error
1102 AC_DEFUN([PKG_CHECK_MODULES], [
1103   succeeded=no
1104
1105   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1106
1107   if test "$PKG_CONFIG" = "no" ; then
1108      ifelse([$4], , [AC_MSG_ERROR([
1109       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1110   else
1111      PKG_CONFIG_MIN_VERSION=0.9.0
1112      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1113         AC_MSG_CHECKING(for $2)
1114
1115         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1116             AC_MSG_RESULT(yes)
1117             succeeded=yes
1118
1119             AC_MSG_CHECKING($1_CFLAGS)
1120             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1121             AC_MSG_RESULT($$1_CFLAGS)
1122
1123             AC_MSG_CHECKING($1_LIBS)
1124             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1125             AC_MSG_RESULT($$1_LIBS)
1126         else
1127             AC_MSG_RESULT(no)
1128             $1_CFLAGS=""
1129             $1_LIBS=""
1130             ## If we have a custom action on failure, don't print errors, but
1131             ## do set a variable so people can do so.
1132             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1133             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1134         fi
1135
1136         AC_SUBST($1_CFLAGS)
1137         AC_SUBST($1_LIBS)
1138      else
1139         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1140         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1141      fi
1142   fi
1143
1144   if test $succeeded = yes; then
1145      ifelse([$3], , :, [$3])
1146   else
1147      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1148   fi
1149 ])
1150
1151
1152 if test "${with_sound}" != "no"; then
1153   # Sound support for GNU/Linux and the free BSDs.
1154   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1155     have_sound_header=yes)
1156   # Emulation library used on NetBSD.
1157   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1158   AC_SUBST(LIBSOUND)
1159
1160   ALSA_REQUIRED=1.0.0
1161   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1162   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1163   if test $HAVE_ALSA = yes; then
1164     SAVE_CFLAGS="$CFLAGS"
1165     SAVE_LDFLAGS="$LDFLAGS"
1166     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1167     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1168     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1169                     emacs_alsa_normal=yes,
1170                     emacs_alsa_normal=no)
1171     if test "$emacs_alsa_normal" != yes; then
1172       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1173                      [[snd_lib_error_set_handler (0);]])],
1174                      emacs_alsa_subdir=yes,
1175                      emacs_alsa_subdir=no)
1176       if test "$emacs_alsa_subdir" != yes; then
1177         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1178       fi
1179       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1180     fi
1181
1182     CFLAGS="$SAVE_CFLAGS"
1183     LDFLAGS="$SAVE_LDFLAGS"
1184     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1185     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1186     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1187   fi
1188
1189   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1190   dnl compiles only on the specified platforms.  For others, it
1191   dnl probably doesn't make sense to try.
1192   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1193      case "$opsys" in
1194        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1195        gnu-linux|freebsd|netbsd)
1196          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1197          ;;
1198      esac
1199   fi
1200
1201   AC_SUBST(CFLAGS_SOUND)
1202 fi
1203
1204 dnl checks for header files
1205 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1206   linux/version.h sys/systeminfo.h \
1207   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1208   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1209   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1210
1211 AC_MSG_CHECKING(if personality LINUX32 can be set)
1212 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1213                emacs_cv_personality_linux32=yes,
1214                emacs_cv_personality_linux32=no)
1215 AC_MSG_RESULT($emacs_cv_personality_linux32)
1216
1217 if test $emacs_cv_personality_linux32 = yes; then
1218   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1219             [Define to 1 if personality LINUX32 can be set.])
1220 fi
1221
1222 dnl On Solaris 8 there's a compilation warning for term.h because
1223 dnl it doesn't define `bool'.
1224 AC_CHECK_HEADERS(term.h, , , -)
1225 AC_HEADER_TIME
1226 AC_CHECK_DECLS([sys_siglist])
1227 if test $ac_cv_have_decl_sys_siglist != yes; then
1228   # For Tru64, at least:
1229   AC_CHECK_DECLS([__sys_siglist])
1230   if test $ac_cv_have_decl___sys_siglist = yes; then
1231     AC_DEFINE(sys_siglist, __sys_siglist,
1232               [Define to any substitute for sys_siglist.])
1233   fi
1234 fi
1235 AC_HEADER_SYS_WAIT
1236
1237 dnl Some systems have utime.h but don't declare the struct anyplace.
1238 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1239 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1240 #include <sys/time.h>
1241 #include <time.h>
1242 #else
1243 #ifdef HAVE_SYS_TIME_H
1244 #include <sys/time.h>
1245 #else
1246 #include <time.h>
1247 #endif
1248 #endif
1249 #ifdef HAVE_UTIME_H
1250 #include <utime.h>
1251 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1252   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1253 if test $emacs_cv_struct_utimbuf = yes; then
1254   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1255 fi
1256
1257 dnl Check for speed_t typedef.
1258 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1259   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1260     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1261 if test $emacs_cv_speed_t = yes; then
1262   AC_DEFINE(HAVE_SPEED_T, 1,
1263            [Define to 1 if `speed_t' is declared by <termios.h>.])
1264 fi
1265
1266 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1267 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1268 #include <sys/time.h>
1269 #include <time.h>
1270 #else
1271 #ifdef HAVE_SYS_TIME_H
1272 #include <sys/time.h>
1273 #else
1274 #include <time.h>
1275 #endif
1276 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1277   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1278 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1279 if test $emacs_cv_struct_timeval = yes; then
1280   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1281 fi
1282
1283 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1284 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1285 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1286   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1287 HAVE_EXCEPTION=$emacs_cv_struct_exception
1288 if test $emacs_cv_struct_exception != yes; then
1289   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1290 fi
1291
1292 AC_CHECK_HEADERS(sys/socket.h)
1293 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1294 #if HAVE_SYS_SOCKET_H
1295 #include <sys/socket.h>
1296 #endif])
1297 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1298 #if HAVE_SYS_SOCKET_H
1299 #include <sys/socket.h>
1300 #endif])
1301 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1302 #if HAVE_SYS_SOCKET_H
1303 #include <sys/socket.h>
1304 #endif])
1305 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1306
1307 dnl checks for structure members
1308 AC_STRUCT_TM
1309 AC_STRUCT_TIMEZONE
1310 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1311                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1312                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1313                 [#include <time.h>])
1314 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1315                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1316                   struct ifreq.ifr_addr,
1317                   struct ifreq.ifr_addr.sa_len], , ,
1318                  [AC_INCLUDES_DEFAULT
1319 #if HAVE_SYS_SOCKET_H
1320 #include <sys/socket.h>
1321 #endif
1322 #if HAVE_NET_IF_H
1323 #include <net/if.h>
1324 #endif])
1325
1326 dnl checks for compiler characteristics
1327
1328 dnl Testing __STDC__ to determine prototype support isn't good enough.
1329 dnl DEC C, for instance, doesn't define it with default options, and
1330 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1331 dnl and void *.
1332 AC_C_PROTOTYPES
1333 AC_C_VOLATILE
1334 AC_C_CONST
1335 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1336   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1337                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1338 if test $emacs_cv_void_star = yes; then
1339   AC_DEFINE(POINTER_TYPE, void)
1340 else
1341   AC_DEFINE(POINTER_TYPE, char)
1342 fi
1343 AH_TEMPLATE(POINTER_TYPE,
1344             [Define as `void' if your compiler accepts `void *'; otherwise
1345              define as `char'.])dnl
1346
1347 dnl Check for endianess
1348 AC_C_BIGENDIAN
1349
1350 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1351   [emacs_cv_attribute_aligned],
1352   [AC_COMPILE_IFELSE(
1353      [AC_LANG_PROGRAM(
1354         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1355         [[]])],
1356      [emacs_cv_attribute_aligned=yes],
1357      [emacs_cv_attribute_aligned=no])])
1358 if test $emacs_cv_attribute_aligned = yes; then
1359   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1360     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1361 fi
1362
1363 dnl check for Make feature
1364 AC_PROG_MAKE_SET
1365
1366 DEPFLAGS=
1367 MKDEPDIR=":"
1368 deps_frag=deps.mk
1369 dnl check for GNU Make if we have GCC and autodepend is on.
1370 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1371    AC_MSG_CHECKING([whether we are using GNU Make])
1372    HAVE_GNU_MAKE=no
1373    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1374    if test "x$testval" != x; then
1375       HAVE_GNU_MAKE=yes
1376    else
1377       ac_enable_autodepend=no
1378    fi
1379    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1380    if test $HAVE_GNU_MAKE = yes; then
1381       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1382       SAVE_CFLAGS="$CFLAGS"
1383       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1384       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1385       CFLAGS="$SAVE_CFLAGS"
1386       test -f deps.d || ac_enable_autodepend=no
1387       rm -rf deps.d
1388       AC_MSG_RESULT([$ac_enable_autodepend])
1389    fi
1390    if test $ac_enable_autodepend = yes; then
1391       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1392       ## In parallel builds, another make might create depdir between
1393       ## the first test and mkdir, so stick another test on the end.
1394       ## Or use install-sh -d?  mkdir -p is not portable.
1395       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1396       deps_frag=autodeps.mk
1397    fi
1398 fi
1399 deps_frag=$srcdir/src/$deps_frag
1400 AC_SUBST(MKDEPDIR)
1401 AC_SUBST(DEPFLAGS)
1402 AC_SUBST_FILE(deps_frag)
1403
1404
1405 lisp_frag=$srcdir/src/lisp.mk
1406 AC_SUBST_FILE(lisp_frag)
1407
1408
1409 dnl checks for operating system services
1410 AC_SYS_LONG_FILE_NAMES
1411
1412 #### Choose a window system.
1413
1414 AC_PATH_X
1415 if test "$no_x" = yes; then
1416   window_system=none
1417 else
1418   window_system=x11
1419 fi
1420
1421 ## Workaround for bug in autoconf <= 2.62.
1422 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1423 ## No need to do anything special for these standard directories.
1424 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1425
1426    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1427
1428 fi
1429
1430 LD_SWITCH_X_SITE_AUX=
1431 LD_SWITCH_X_SITE_AUX_RPATH=
1432 if test "${x_libraries}" != NONE; then
1433   if test -n "${x_libraries}"; then
1434     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1435     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1436     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1437   fi
1438   x_default_search_path=""
1439   x_search_path=${x_libraries}
1440   if test -z "${x_search_path}"; then
1441     x_search_path=/usr/lib
1442   fi
1443   for x_library in `echo ${x_search_path}: | \
1444                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1445     x_search_path="\
1446 ${x_library}/X11/%L/%T/%N%C%S:\
1447 ${x_library}/X11/%l/%T/%N%C%S:\
1448 ${x_library}/X11/%T/%N%C%S:\
1449 ${x_library}/X11/%L/%T/%N%S:\
1450 ${x_library}/X11/%l/%T/%N%S:\
1451 ${x_library}/X11/%T/%N%S"
1452     if test x"${x_default_search_path}" = x; then
1453       x_default_search_path=${x_search_path}
1454     else
1455       x_default_search_path="${x_search_path}:${x_default_search_path}"
1456     fi
1457   done
1458 fi
1459 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1460 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1461
1462 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1463   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1464 fi
1465
1466 if test x"${x_includes}" = x; then
1467   bitmapdir=/usr/include/X11/bitmaps
1468 else
1469   # accumulate include directories that have X11 bitmap subdirectories
1470   bmd_acc="dummyval"
1471   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1472     if test -d "${bmd}/X11/bitmaps"; then
1473       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1474     fi
1475     if test -d "${bmd}/bitmaps"; then
1476       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1477     fi
1478   done
1479   if test ${bmd_acc} != "dummyval"; then
1480     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1481   fi
1482 fi
1483
1484 HAVE_NS=no
1485 NS_IMPL_COCOA=no
1486 NS_IMPL_GNUSTEP=no
1487 tmp_CPPFLAGS="$CPPFLAGS"
1488 tmp_CFLAGS="$CFLAGS"
1489 CPPFLAGS="$CPPFLAGS -x objective-c"
1490 CFLAGS="$CFLAGS -x objective-c"
1491 TEMACS_LDFLAGS2="\${LDFLAGS}"
1492 dnl I don't think it's especially important, but src/Makefile.in
1493 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1494 dnl trailing "/" to it, so now we do it here.
1495 if test "${with_ns}" != no; then
1496   if test "${opsys}" = darwin; then
1497      NS_IMPL_COCOA=yes
1498      ns_appdir=`pwd`/nextstep/Emacs.app
1499      ns_appbindir=${ns_appdir}/Contents/MacOS/
1500      ns_appresdir=${ns_appdir}/Contents/Resources
1501      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1502   elif test -f $GNUSTEP_CONFIG_FILE; then
1503      NS_IMPL_GNUSTEP=yes
1504      ns_appdir=`pwd`/nextstep/Emacs.app
1505      ns_appbindir=${ns_appdir}/
1506      ns_appresdir=${ns_appdir}/Resources
1507      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1508      dnl FIXME sourcing this several times in subshells seems inefficient.
1509      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1510      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1511      dnl I seemed to need these as well with GNUstep-startup 0.25.
1512      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1513      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1514      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1515        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1516      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1517        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1518      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1519      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1520      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1521      LIB_STANDARD=
1522      START_FILES=
1523      TEMACS_LDFLAGS2=
1524   fi
1525   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1526                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1527   files are missing or cannot be compiled.])])
1528   NS_HAVE_NSINTEGER=yes
1529   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1530                                      [NSInteger i;])],
1531                     ns_have_nsinteger=yes,
1532                     ns_have_nsinteger=no)
1533   if test $ns_have_nsinteger = no; then
1534     NS_HAVE_NSINTEGER=no
1535   fi
1536 fi
1537 AC_SUBST(TEMACS_LDFLAGS2)
1538
1539 ns_frag=/dev/null
1540 NS_OBJ=
1541 NS_OBJC_OBJ=
1542 if test "${HAVE_NS}" = yes; then
1543   window_system=nextstep
1544   with_xft=no
1545   # set up packaging dirs
1546   exec_prefix=${ns_appbindir}
1547   libexecdir=${ns_appbindir}/libexec
1548   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1549      prefix=${ns_appresdir}
1550   fi
1551   ns_frag=$srcdir/src/ns.mk
1552   NS_OBJ="fontset.o fringe.o image.o"
1553   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1554 fi
1555 CFLAGS="$tmp_CFLAGS"
1556 CPPFLAGS="$tmp_CPPFLAGS"
1557 AC_SUBST(NS_OBJ)
1558 AC_SUBST(NS_OBJC_OBJ)
1559 AC_SUBST(LIB_STANDARD)
1560 AC_SUBST_FILE(ns_frag)
1561
1562 case "${window_system}" in
1563   x11 )
1564     HAVE_X_WINDOWS=yes
1565     HAVE_X11=yes
1566     case "${with_x_toolkit}" in
1567       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1568       motif ) USE_X_TOOLKIT=MOTIF ;;
1569       gtk ) with_gtk=yes
1570 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1571 dnl USE_X_TOOLKIT is set.
1572             USE_X_TOOLKIT=none ;;
1573       gtk3 ) with_gtk3=yes
1574              USE_X_TOOLKIT=none ;;
1575       no ) USE_X_TOOLKIT=none ;;
1576 dnl If user did not say whether to use a toolkit, make this decision later:
1577 dnl use the toolkit if we have gtk, or X11R5 or newer.
1578       * ) USE_X_TOOLKIT=maybe ;;
1579     esac
1580   ;;
1581   nextstep | none )
1582     HAVE_X_WINDOWS=no
1583     HAVE_X11=no
1584     USE_X_TOOLKIT=none
1585   ;;
1586 esac
1587
1588 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1589    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1590    if test "$HAVE_XSERVER" = true ||
1591       test -n "$DISPLAY" ||
1592       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1593         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1594 were found.  You should install the relevant development files for X
1595 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1596 sure you have development files for image handling, i.e.
1597 tiff, gif, jpeg, png and xpm.
1598 If you are sure you want Emacs compiled without X window support, pass
1599   --without-x
1600 to configure.])
1601    fi
1602 fi
1603
1604 ### If we're using X11, we should use the X menu package.
1605 HAVE_MENUS=no
1606 case ${HAVE_X11} in
1607   yes ) HAVE_MENUS=yes ;;
1608 esac
1609
1610 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1611 # Assume not, until told otherwise.
1612 GNU_MALLOC=yes
1613 doug_lea_malloc=yes
1614 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1615 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1616 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1617                emacs_cv_var___after_morecore_hook,
1618 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1619   emacs_cv_var___after_morecore_hook=yes,
1620   emacs_cv_var___after_morecore_hook=no)])
1621 if test $emacs_cv_var___after_morecore_hook = no; then
1622   doug_lea_malloc=no
1623 fi
1624
1625
1626 dnl See comments in aix4-2.h about maybe using system malloc there.
1627 system_malloc=no
1628 case "$opsys" in
1629   ## darwin ld insists on the use of malloc routines in the System framework.
1630   darwin|sol2-10) system_malloc=yes ;;
1631 esac
1632
1633 if test "${system_malloc}" = "yes"; then
1634   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1635   GNU_MALLOC=no
1636   GNU_MALLOC_reason="
1637     (The GNU allocators don't work with this system configuration.)"
1638   GMALLOC_OBJ=
1639   VMLIMIT_OBJ=
1640 else
1641   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1642   VMLIMIT_OBJ=vm-limit.o
1643 fi
1644 AC_SUBST(GMALLOC_OBJ)
1645 AC_SUBST(VMLIMIT_OBJ)
1646
1647 if test "$doug_lea_malloc" = "yes" ; then
1648   if test "$GNU_MALLOC" = yes ; then
1649     GNU_MALLOC_reason="
1650       (Using Doug Lea's new malloc from the GNU C Library.)"
1651   fi
1652   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1653             [Define to 1 if you are using the GNU C Library.])
1654
1655   ## Use mmap directly for allocating larger buffers.
1656   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1657   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1658   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1659   case "$opsys" in
1660     gnu*) REL_ALLOC=no ;;
1661   esac
1662 fi
1663
1664 if test x"${REL_ALLOC}" = x; then
1665   REL_ALLOC=${GNU_MALLOC}
1666 fi
1667
1668 use_mmap_for_buffers=no
1669 case "$opsys" in
1670   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1671 esac
1672
1673 AC_FUNC_MMAP
1674 if test $use_mmap_for_buffers = yes; then
1675   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1676   REL_ALLOC=no
1677 fi
1678
1679 LIBS="$LIBS_SYSTEM $LIBS"
1680
1681 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1682 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1683 AC_CHECK_LIB(dnet, dnet_ntoa)
1684 dnl This causes -lresolv to get used in subsequent tests,
1685 dnl which causes failures on some systems such as HPUX 9.
1686 dnl AC_CHECK_LIB(resolv, gethostbyname)
1687
1688 dnl FIXME replace main with a function we actually want from this library.
1689 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1690
1691 dnl Check if pthreads is available.
1692 LIB_PTHREAD=
1693 AC_CHECK_HEADERS(pthread.h)
1694 if test "$ac_cv_header_pthread_h"; then
1695   AC_CHECK_LIB(pthread, pthread_self, HAVE_PTHREAD=yes)
1696 fi
1697 if test "$HAVE_PTHREAD" = yes; then
1698   case "${canonical}" in
1699     *-hpux*) ;;
1700     *) LIB_PTHREAD="-lpthread" ;;
1701   esac
1702   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1703 fi
1704 AC_SUBST([LIB_PTHREAD])
1705
1706 AC_CHECK_LIB(pthreads, cma_open)
1707
1708 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1709 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1710 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1711 ## added to LIBS in configure would never contain the pthreads part,
1712 ## but the value used in Makefiles might.  FIXME?
1713 ##
1714 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1715 ## be harmless on older versions of X where it happens to exist.
1716 test "$opsys" = "aix4-2" && \
1717   test $ac_cv_lib_pthreads_cma_open = yes && \
1718   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1719
1720 dnl Check for need for bigtoc support on IBM AIX
1721
1722 case ${host_os} in
1723 aix*)
1724   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1725     case $GCC in
1726     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1727     *) gdb_cv_bigtoc=-bbigtoc ;;
1728     esac
1729
1730     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1731     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1732   ])
1733   ;;
1734 esac
1735
1736 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1737 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1738 # REAL_CPPFLAGS later on.
1739
1740 REAL_CFLAGS="$CFLAGS"
1741 REAL_CPPFLAGS="$CPPFLAGS"
1742
1743 if test "${HAVE_X11}" = "yes"; then
1744   DEFS="$C_SWITCH_X_SITE $DEFS"
1745   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1746   LIBS="-lX11 $LIBS"
1747   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1748   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1749
1750   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1751   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1752   # but it's more convenient here to set LD_RUN_PATH
1753   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1754   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1755     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1756     export LD_RUN_PATH
1757   fi
1758
1759   if test "${opsys}" = "gnu-linux"; then
1760     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1761     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1762      [[XOpenDisplay ("foo");]])],
1763      [xlinux_first_failure=no],
1764      [xlinux_first_failure=yes])
1765     if test "${xlinux_first_failure}" = "yes"; then
1766       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1767       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1768       OLD_CPPFLAGS="$CPPFLAGS"
1769       OLD_LIBS="$LIBS"
1770       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1771       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1772       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1773       LIBS="$LIBS -b i486-linuxaout"
1774       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1775        [[XOpenDisplay ("foo");]])],
1776        [xlinux_second_failure=no],
1777        [xlinux_second_failure=yes])
1778       if test "${xlinux_second_failure}" = "yes"; then
1779         # If we get the same failure with -b, there is no use adding -b.
1780         # So take it out.  This plays safe.
1781         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1782         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1783         CPPFLAGS="$OLD_CPPFLAGS"
1784         LIBS="$OLD_LIBS"
1785         AC_MSG_RESULT(no)
1786       else
1787         AC_MSG_RESULT(yes)
1788       fi
1789     else
1790       AC_MSG_RESULT(no)
1791     fi
1792   fi
1793
1794   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1795   # header files included from there.
1796   AC_MSG_CHECKING(for Xkb)
1797   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1798 #include <X11/XKBlib.h>]],
1799         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1800         emacs_xkb=yes, emacs_xkb=no)
1801   AC_MSG_RESULT($emacs_xkb)
1802   if test $emacs_xkb = yes; then
1803     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1804   fi
1805
1806   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1807 XScreenNumberOfScreen XSetWMProtocols)
1808 fi
1809
1810 if test "${window_system}" = "x11"; then
1811   AC_MSG_CHECKING(X11 version 6)
1812   AC_CACHE_VAL(emacs_cv_x11_version_6,
1813   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1814 [[#if XlibSpecificationRelease < 6
1815 fail;
1816 #endif
1817 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1818   if test $emacs_cv_x11_version_6 = yes; then
1819     AC_MSG_RESULT(6 or newer)
1820     AC_DEFINE(HAVE_X11R6, 1,
1821               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1822     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1823     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1824     ## XIM support.
1825     case "$opsys" in
1826       sol2-*) : ;;
1827       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1828            [Define if you have usable X11R6-style XIM support.])
1829          ;;
1830     esac
1831   else
1832     AC_MSG_RESULT(before 6)
1833   fi
1834 fi
1835
1836
1837 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1838 HAVE_RSVG=no
1839 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1840   if test "${with_rsvg}" != "no"; then
1841     RSVG_REQUIRED=2.11.0
1842     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1843
1844     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1845     AC_SUBST(RSVG_CFLAGS)
1846     AC_SUBST(RSVG_LIBS)
1847
1848     if test $HAVE_RSVG = yes; then
1849       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1850       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1851       LIBS="$RSVG_LIBS $LIBS"
1852     fi
1853   fi
1854 fi
1855
1856 HAVE_IMAGEMAGICK=no
1857 if test "${HAVE_X11}" = "yes"; then
1858   if test "${with_imagemagick}" != "no"; then
1859     ## 6.2.8 is the earliest version known to work, but earlier versions
1860     ## might work - let us know if you find one.
1861     ## 6.0.7 does not work.  See bug#7955.
1862     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1863     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1864     AC_SUBST(IMAGEMAGICK_CFLAGS)
1865     AC_SUBST(IMAGEMAGICK_LIBS)
1866
1867     if test $HAVE_IMAGEMAGICK = yes; then
1868       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1869       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1870       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1871       AC_CHECK_FUNCS(MagickExportImagePixels)
1872     fi
1873   fi
1874 fi
1875
1876
1877 HAVE_GTK=no
1878 GTK_OBJ=
1879 if test "${with_gtk3}" = "yes"; then
1880   GLIB_REQUIRED=2.28
1881   GTK_REQUIRED=3.0
1882   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1883
1884   dnl Checks for libraries.
1885   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1886   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1887      AC_MSG_ERROR($GTK_PKG_ERRORS)
1888   fi
1889   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1890   GTK_OBJ=emacsgtkfixed.o
1891 fi
1892
1893 if test "$pkg_check_gtk" != "yes"; then
1894   HAVE_GTK=no
1895 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1896   GLIB_REQUIRED=2.6
1897   GTK_REQUIRED=2.6
1898   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1899
1900   dnl Checks for libraries.
1901   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1902   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1903      AC_MSG_ERROR($GTK_PKG_ERRORS)
1904   fi
1905 fi
1906 fi
1907
1908 if test x"$pkg_check_gtk" = xyes; then
1909
1910   AC_SUBST(GTK_CFLAGS)
1911   AC_SUBST(GTK_LIBS)
1912   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1913   CFLAGS="$CFLAGS $GTK_CFLAGS"
1914   LIBS="$GTK_LIBS $LIBS"
1915   dnl Try to compile a simple GTK program.
1916   GTK_COMPILES=no
1917   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1918   if test "${GTK_COMPILES}" != "yes"; then
1919     if test "$USE_X_TOOLKIT" != "maybe"; then
1920       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1921     fi
1922   else
1923     HAVE_GTK=yes
1924     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1925     GTK_OBJ="gtkutil.o $GTK_OBJ"
1926     USE_X_TOOLKIT=none
1927     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1928       :
1929     else
1930       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1931        closing open displays.  This is no problem if you just use
1932        one display, but if you use more than one and close one of them
1933        Emacs may crash.]])
1934       sleep 3
1935     fi
1936   fi
1937
1938 fi
1939 AC_SUBST(GTK_OBJ)
1940
1941
1942 if test "${HAVE_GTK}" = "yes"; then
1943
1944   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1945   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1946   if test "$with_toolkit_scroll_bars" != no; then
1947     with_toolkit_scroll_bars=yes
1948   fi
1949
1950   dnl  Check if we have the old file selection dialog declared and
1951   dnl  in the link library.  In 2.x it may be in the library,
1952   dnl  but not declared if deprecated featured has been selected out.
1953   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1954   HAVE_GTK_FILE_SELECTION=no
1955   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1956                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1957 #include <gtk/gtk.h>])
1958   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1959     AC_CHECK_FUNCS(gtk_file_selection_new)
1960   fi
1961
1962
1963   dnl Check for functions introduced in 2.14 and later.
1964   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1965                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1966                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1967                  gtk_orientable_set_orientation)
1968
1969 fi
1970
1971 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1972 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1973 dnl also not configured.
1974 HAVE_DBUS=no
1975 DBUS_OBJ=
1976 if test "${with_dbus}" = "yes"; then
1977    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1978    if test "$HAVE_DBUS" = yes; then
1979      LIBS="$LIBS $DBUS_LIBS"
1980      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1981      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1982      DBUS_OBJ=dbusbind.o
1983    fi
1984 fi
1985 AC_SUBST(DBUS_OBJ)
1986
1987 dnl GSettings has been tested under GNU/Linux only.
1988 HAVE_GSETTINGS=no
1989 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1990    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1991    if test "$HAVE_GSETTINGS" = "yes"; then
1992       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1993       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1994       SETTINGS_LIBS="$GSETTINGS_LIBS"
1995    fi
1996 fi
1997
1998 dnl GConf has been tested under GNU/Linux only.
1999 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2000 HAVE_GCONF=no
2001 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2002    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2003    if test "$HAVE_GCONF" = yes; then
2004       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2005       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2006       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2007       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2008    fi
2009 fi
2010
2011 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2012     SAVE_CFLAGS="$CFLAGS"
2013     SAVE_LDFLAGS="$LDFLAGS"
2014     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2015     LDFLAGS="$SETTINGS_LIBS $LDFLAGS"
2016     AC_CHECK_FUNCS([g_type_init])
2017     CFLAGS="$SAVE_CFLAGS"
2018     LDFLAGS="$SAVE_LDFLAGS"
2019 fi
2020 AC_SUBST(SETTINGS_CFLAGS)
2021 AC_SUBST(SETTINGS_LIBS)
2022
2023
2024 dnl SELinux is available for GNU/Linux only.
2025 HAVE_LIBSELINUX=no
2026 LIBSELINUX_LIBS=
2027 if test "${with_selinux}" = "yes"; then
2028    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2029    if test "$HAVE_LIBSELINUX" = yes; then
2030       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2031       LIBSELINUX_LIBS=-lselinux
2032    fi
2033 fi
2034 AC_SUBST(LIBSELINUX_LIBS)
2035
2036 HAVE_GNUTLS=no
2037 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2038 if test "${with_gnutls}" = "yes" ; then
2039   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2040   if test "${HAVE_GNUTLS}" = "yes"; then
2041     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2042   fi
2043
2044   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2045   LIBS="$LIBGNUTLS_LIBS $LIBS"
2046   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2047
2048   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2049     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2050   fi
2051 fi
2052
2053 AC_SUBST(LIBGNUTLS_LIBS)
2054 AC_SUBST(LIBGNUTLS_CFLAGS)
2055
2056 dnl Do not put whitespace before the #include statements below.
2057 dnl Older compilers (eg sunos4 cc) choke on it.
2058 HAVE_XAW3D=no
2059 LUCID_LIBW=
2060 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2061   if test "$with_xaw3d" != no; then
2062     AC_MSG_CHECKING(for xaw3d)
2063     AC_CACHE_VAL(emacs_cv_xaw3d,
2064     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2065 #include <X11/Intrinsic.h>
2066 #include <X11/Xaw3d/Simple.h>]],
2067       [[]])],
2068       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2069                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2070       emacs_cv_xaw3d=no)])
2071   else
2072     emacs_cv_xaw3d=no
2073   fi
2074   if test $emacs_cv_xaw3d = yes; then
2075     AC_MSG_RESULT([yes; using Lucid toolkit])
2076     USE_X_TOOLKIT=LUCID
2077     HAVE_XAW3D=yes
2078     LUCID_LIBW=-lXaw3d
2079     AC_DEFINE(HAVE_XAW3D, 1,
2080               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2081   else
2082     AC_MSG_RESULT(no)
2083     AC_MSG_CHECKING(for libXaw)
2084     AC_CACHE_VAL(emacs_cv_xaw,
2085     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2086 #include <X11/Intrinsic.h>
2087 #include <X11/Xaw/Simple.h>]],
2088       [[]])],
2089       emacs_cv_xaw=yes,
2090       emacs_cv_xaw=no)])
2091     if test $emacs_cv_xaw = yes; then
2092       AC_MSG_RESULT([yes; using Lucid toolkit])
2093       USE_X_TOOLKIT=LUCID
2094       LUCID_LIBW=-lXaw
2095     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2096       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2097     else
2098       AC_MSG_ERROR([No X toolkit could be found.
2099 If you are sure you want Emacs compiled without an X toolkit, pass
2100   --with-x-toolkit=no
2101 to configure.  Otherwise, install the development libraries for the toolkit
2102 that you want to use (e.g. Gtk+) and re-run configure.])
2103     fi
2104   fi
2105 fi
2106
2107 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2108
2109 LIBXTR6=
2110 if test "${USE_X_TOOLKIT}" != "none"; then
2111   AC_MSG_CHECKING(X11 toolkit version)
2112   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2113   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2114 [[#if XtSpecificationRelease < 6
2115 fail;
2116 #endif
2117 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2118   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2119   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2120     AC_MSG_RESULT(6 or newer)
2121     AC_DEFINE(HAVE_X11XTR6, 1,
2122               [Define to 1 if you have the X11R6 or newer version of Xt.])
2123     LIBXTR6="-lSM -lICE"
2124     case "$opsys" in
2125       ## Use libw.a along with X11R6 Xt.
2126       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2127     esac
2128   else
2129     AC_MSG_RESULT(before 6)
2130   fi
2131
2132 dnl If using toolkit, check whether libXmu.a exists.
2133 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2134   OLDLIBS="$LIBS"
2135   if test x$HAVE_X11XTR6 = xyes; then
2136     LIBS="-lXt -lSM -lICE $LIBS"
2137   else
2138     LIBS="-lXt $LIBS"
2139   fi
2140   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2141   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2142 fi
2143 AC_SUBST(LIBXTR6)
2144
2145 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2146 dnl Why not just test for libxmu in the normal way?
2147 LIBXMU=-lXmu
2148 case $opsys in
2149   ## These systems don't supply Xmu.
2150   hpux* | aix4-2 )
2151     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2152     ;;
2153 esac
2154 AC_SUBST(LIBXMU)
2155
2156 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2157 if test "${HAVE_X11}" = "yes"; then
2158   if test "${USE_X_TOOLKIT}" != "none"; then
2159     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2160   fi
2161 fi
2162
2163 LIBXP=
2164 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2165   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2166   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2167     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2168 int x = 5;
2169 #else
2170 Motif version prior to 2.1.
2171 #endif]])],
2172     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2173   if test $emacs_cv_motif_version_2_1 = yes; then
2174     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2175   else
2176     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2177     # We put this in CFLAGS temporarily to precede other -I options
2178     # that might be in CFLAGS temporarily.
2179     # We put this in CPPFLAGS where it precedes the other -I options.
2180     OLD_CPPFLAGS=$CPPFLAGS
2181     OLD_CFLAGS=$CFLAGS
2182     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2183     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2184     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2185       [[int x = 5;]])],
2186       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2187     if test $emacs_cv_lesstif = yes; then
2188       # Make sure this -I option remains in CPPFLAGS after it is set
2189       # back to REAL_CPPFLAGS.
2190       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2191       # have those other -I options anyway.  Ultimately, having this
2192       # directory ultimately in CPPFLAGS will be enough.
2193       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2194       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2195     else
2196       CFLAGS=$OLD_CFLAGS
2197       CPPFLAGS=$OLD_CPPFLAGS
2198     fi
2199   fi
2200 fi
2201
2202 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2203 dnl using Motif or Xaw3d is available, and unless
2204 dnl --with-toolkit-scroll-bars=no was specified.
2205
2206 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2207             [Define to 1 if we should use toolkit scroll bars.])dnl
2208 USE_TOOLKIT_SCROLL_BARS=no
2209 if test "${with_toolkit_scroll_bars}" != "no"; then
2210   if test "${USE_X_TOOLKIT}" != "none"; then
2211     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2212       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2213       HAVE_XAW3D=no
2214       USE_TOOLKIT_SCROLL_BARS=yes
2215     elif test "${HAVE_XAW3D}" = "yes"; then
2216       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2217       USE_TOOLKIT_SCROLL_BARS=yes
2218     fi
2219   elif test "${HAVE_GTK}" = "yes"; then
2220     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2221     USE_TOOLKIT_SCROLL_BARS=yes
2222   elif test "${HAVE_NS}" = "yes"; then
2223     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2224     USE_TOOLKIT_SCROLL_BARS=yes
2225   fi
2226 fi
2227
2228 dnl See if XIM is available.
2229 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2230           #include <X11/Xlib.h>
2231           #include <X11/Xresource.h>]],
2232          [[XIMProc  callback;]])],
2233          [HAVE_XIM=yes
2234          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2235          HAVE_XIM=no)
2236
2237 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2238
2239 if test "${with_xim}" != "no"; then
2240   AC_DEFINE(USE_XIM, 1,
2241             [Define to 1 if we should use XIM, if it is available.])
2242 fi
2243
2244
2245 if test "${HAVE_XIM}" != "no"; then
2246   late_CFLAGS=$CFLAGS
2247   if test "$GCC" = yes; then
2248     CFLAGS="$CFLAGS --pedantic-errors"
2249   fi
2250   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2251 #include <X11/Xlib.h>
2252 #include <X11/Xresource.h>]],
2253 [[Display *display;
2254 XrmDatabase db;
2255 char *res_name;
2256 char *res_class;
2257 XIMProc  callback;
2258 XPointer *client_data;
2259 #ifndef __GNUC__
2260 /* If we're not using GCC, it's probably not XFree86, and this is
2261    probably right, but we can't use something like --pedantic-errors.  */
2262 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2263                                            char*, XIMProc, XPointer*);
2264 #endif
2265 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2266    client_data);]])],
2267     [emacs_cv_arg6_star=yes])
2268   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2269          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2270 either XPointer or XPointer*.])dnl
2271   if test "$emacs_cv_arg6_star" = yes; then
2272     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2273   else
2274     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2275   fi
2276   CFLAGS=$late_CFLAGS
2277 fi
2278
2279 ### Start of font-backend (under any platform) section.
2280 # (nothing here yet -- this is a placeholder)
2281 ### End of font-backend (under any platform) section.
2282
2283 ### Start of font-backend (under X11) section.
2284 if test "${HAVE_X11}" = "yes"; then
2285    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2286
2287    ## Use -lXft if available, unless `--with-xft=no'.
2288    HAVE_XFT=maybe
2289     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2290       with_xft="no";
2291     fi
2292     if test "x${with_xft}" != "xno"; then
2293
2294       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2295       ## Because xftfont.c uses XRenderQueryExtension, we also
2296       ## need to link to -lXrender.
2297       HAVE_XRENDER=no
2298       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2299       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2300         OLD_CPPFLAGS="$CPPFLAGS"
2301         OLD_CFLAGS="$CFLAGS"
2302         OLD_LIBS="$LIBS"
2303         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2304         CFLAGS="$CFLAGS $XFT_CFLAGS"
2305         XFT_LIBS="-lXrender $XFT_LIBS"
2306         LIBS="$XFT_LIBS $LIBS"
2307         AC_CHECK_HEADER(X11/Xft/Xft.h,
2308           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2309
2310         if test "${HAVE_XFT}" = "yes"; then
2311           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2312             AC_SUBST(XFT_LIBS)
2313           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2314         else
2315           CPPFLAGS="$OLD_CPPFLAGS"
2316           CFLAGS="$OLD_CFLAGS"
2317           LIBS="$OLD_LIBS"
2318         fi                        # "${HAVE_XFT}" = "yes"
2319       fi                          # "$HAVE_XFT" != no
2320     fi                            # "x${with_xft}" != "xno"
2321
2322     ## We used to allow building with FreeType and without Xft.
2323     ## However, the ftx font backend driver is not in good shape.
2324     if test "$HAVE_XFT" != "yes"; then
2325        dnl For the "Does Emacs use" message at the end.
2326        HAVE_XFT=no
2327        HAVE_FREETYPE=no
2328     else
2329        dnl Strict linkers fail with
2330        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2331        dnl if -lfreetype is not specified.
2332        dnl The following is needed to set FREETYPE_LIBS.
2333        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2334                          HAVE_FREETYPE=no)
2335
2336        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2337     fi
2338
2339     HAVE_LIBOTF=no
2340     if test "${HAVE_FREETYPE}" = "yes"; then
2341       AC_DEFINE(HAVE_FREETYPE, 1,
2342                 [Define to 1 if using the freetype and fontconfig libraries.])
2343       if test "${with_libotf}" != "no"; then
2344         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2345                           HAVE_LIBOTF=no)
2346         if test "$HAVE_LIBOTF" = "yes"; then
2347           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2348           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2349                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2350                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2351           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2352             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2353                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2354           fi
2355         fi
2356       fi
2357     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2358     dnl Does the new font backend require it, or can it work without it?
2359     fi
2360
2361     HAVE_M17N_FLT=no
2362     if test "${HAVE_LIBOTF}" = yes; then
2363       if test "${with_m17n_flt}" != "no"; then
2364         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2365         if test "$HAVE_M17N_FLT" = "yes"; then
2366           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2367         fi
2368       fi
2369     fi
2370 else
2371     HAVE_XFT=no
2372     HAVE_FREETYPE=no
2373     HAVE_LIBOTF=no
2374     HAVE_M17N_FLT=no
2375 fi
2376
2377 ### End of font-backend (under X11) section.
2378
2379 AC_SUBST(FREETYPE_CFLAGS)
2380 AC_SUBST(FREETYPE_LIBS)
2381 AC_SUBST(FONTCONFIG_CFLAGS)
2382 AC_SUBST(FONTCONFIG_LIBS)
2383 AC_SUBST(LIBOTF_CFLAGS)
2384 AC_SUBST(LIBOTF_LIBS)
2385 AC_SUBST(M17N_FLT_CFLAGS)
2386 AC_SUBST(M17N_FLT_LIBS)
2387
2388 ### Use -lXpm if available, unless `--with-xpm=no'.
2389 HAVE_XPM=no
2390 LIBXPM=
2391 if test "${HAVE_X11}" = "yes"; then
2392   if test "${with_xpm}" != "no"; then
2393     AC_CHECK_HEADER(X11/xpm.h,
2394       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2395     if test "${HAVE_XPM}" = "yes"; then
2396       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2397       AC_EGREP_CPP(no_return_alloc_pixels,
2398       [#include "X11/xpm.h"
2399 #ifndef XpmReturnAllocPixels
2400 no_return_alloc_pixels
2401 #endif
2402       ], HAVE_XPM=no, HAVE_XPM=yes)
2403
2404       if test "${HAVE_XPM}" = "yes"; then
2405         AC_MSG_RESULT(yes)
2406       else
2407         AC_MSG_RESULT(no)
2408       fi
2409     fi
2410   fi
2411
2412   if test "${HAVE_XPM}" = "yes"; then
2413     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2414     LIBXPM=-lXpm
2415   fi
2416 fi
2417 AC_SUBST(LIBXPM)
2418
2419 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2420 HAVE_JPEG=no
2421 LIBJPEG=
2422 if test "${HAVE_X11}" = "yes"; then
2423   if test "${with_jpeg}" != "no"; then
2424     dnl Checking for jpeglib.h can lose because of a redefinition of
2425     dnl  HAVE_STDLIB_H.
2426     AC_CHECK_HEADER(jerror.h,
2427       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2428   fi
2429
2430   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2431   if test "${HAVE_JPEG}" = "yes"; then
2432     AC_DEFINE(HAVE_JPEG)
2433     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2434         [#include <jpeglib.h>
2435          version=JPEG_LIB_VERSION
2436 ],
2437         [AC_DEFINE(HAVE_JPEG)],
2438         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2439         HAVE_JPEG=no])
2440   fi
2441   if test "${HAVE_JPEG}" = "yes"; then
2442     LIBJPEG=-ljpeg
2443   fi
2444 fi
2445 AC_SUBST(LIBJPEG)
2446
2447 ### Use -lpng if available, unless `--with-png=no'.
2448 HAVE_PNG=no
2449 LIBPNG=
2450 if test "${HAVE_X11}" = "yes"; then
2451   if test "${with_png}" != "no"; then
2452     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2453     # in /usr/include/libpng.
2454     AC_CHECK_HEADERS(png.h libpng/png.h)
2455     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2456       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2457     fi
2458   fi
2459
2460   if test "${HAVE_PNG}" = "yes"; then
2461     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2462     LIBPNG="-lpng -lz -lm"
2463   fi
2464 fi
2465 AC_SUBST(LIBPNG)
2466
2467 ### Use -ltiff if available, unless `--with-tiff=no'.
2468 HAVE_TIFF=no
2469 LIBTIFF=
2470 if test "${HAVE_X11}" = "yes"; then
2471   if test "${with_tiff}" != "no"; then
2472     AC_CHECK_HEADER(tiffio.h,
2473       [tifflibs="-lz -lm"
2474       # At least one tiff package requires the jpeg library.
2475       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2476       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2477   fi
2478
2479   if test "${HAVE_TIFF}" = "yes"; then
2480     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2481     dnl FIXME -lz -lm, as per libpng?
2482     LIBTIFF=-ltiff
2483   fi
2484 fi
2485 AC_SUBST(LIBTIFF)
2486
2487 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2488 HAVE_GIF=no
2489 LIBGIF=
2490 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2491   AC_CHECK_HEADER(gif_lib.h,
2492 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2493 # Earlier versions can crash Emacs.
2494     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2495
2496   if test "$HAVE_GIF" = yes; then
2497     LIBGIF=-lgif
2498   elif test "$HAVE_GIF" = maybe; then
2499 # If gif_lib.h but no libgif, try libungif.
2500     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2501     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2502   fi
2503
2504   if test "${HAVE_GIF}" = "yes"; then
2505     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2506   fi
2507 fi
2508 AC_SUBST(LIBGIF)
2509
2510 dnl Check for required libraries.
2511 if test "${HAVE_X11}" = "yes"; then
2512   MISSING=""
2513   WITH_NO=""
2514   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2515     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2516   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2517     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2518   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2519     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2520   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2521     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2522   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2523     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2524
2525   if test "X${MISSING}" != X; then
2526     AC_MSG_ERROR([The following required libraries were not found:
2527     $MISSING
2528 Maybe some development libraries/packages are missing?
2529 If you don't want to link with them give
2530     $WITH_NO
2531 as options to configure])
2532   fi
2533 fi
2534
2535 ### Use -lgpm if available, unless `--with-gpm=no'.
2536 HAVE_GPM=no
2537 LIBGPM=
2538 if test "${with_gpm}" != "no"; then
2539   AC_CHECK_HEADER(gpm.h,
2540     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2541
2542   if test "${HAVE_GPM}" = "yes"; then
2543     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2544     LIBGPM=-lgpm
2545   fi
2546 fi
2547 AC_SUBST(LIBGPM)
2548
2549 dnl Check for malloc/malloc.h on darwin
2550 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2551
2552 C_SWITCH_X_SYSTEM=
2553 ### Use NeXTstep API to implement GUI.
2554 if test "${HAVE_NS}" = "yes"; then
2555   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2556   if test "${NS_IMPL_COCOA}" = "yes"; then
2557     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2558     GNU_OBJC_CFLAGS=
2559   fi
2560   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2561     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2562     # See also .m.o rule in Makefile.in */
2563     # FIXME: are all these flags really needed?  Document here why.  */
2564     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2565     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2566   fi
2567   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2568     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2569   fi
2570   # We also have mouse menus.
2571   HAVE_MENUS=yes
2572   OTHER_FILES=ns-app
2573 fi
2574
2575
2576 ### Use session management (-lSM -lICE) if available
2577 HAVE_X_SM=no
2578 LIBXSM=
2579 if test "${HAVE_X11}" = "yes"; then
2580   AC_CHECK_HEADER(X11/SM/SMlib.h,
2581     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2582
2583   if test "${HAVE_X_SM}" = "yes"; then
2584     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2585     LIBXSM="-lSM -lICE"
2586     case "$LIBS" in
2587       *-lSM*) ;;
2588       *)      LIBS="$LIBXSM $LIBS" ;;
2589     esac
2590   fi
2591 fi
2592 AC_SUBST(LIBXSM)
2593
2594 ### Use libxml (-lxml2) if available
2595 if test "${with_xml2}" != "no"; then
2596   ### I'm not sure what the version number should be, so I just guessed.
2597   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2598   if test "${HAVE_LIBXML2}" = "yes"; then
2599     LIBS="$LIBXML2_LIBS $LIBS"
2600     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2601     if test "${HAVE_LIBXML2}" = "yes"; then
2602       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2603     else
2604       LIBXML2_LIBS=""
2605       LIBXML2_CFLAGS=""
2606     fi
2607   fi
2608 fi
2609 AC_SUBST(LIBXML2_LIBS)
2610 AC_SUBST(LIBXML2_CFLAGS)
2611
2612 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2613 AC_CACHE_CHECK(whether netdb declares h_errno,
2614                emacs_cv_netdb_declares_h_errno,
2615 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2616   [[return h_errno;]])],
2617   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2618 if test $emacs_cv_netdb_declares_h_errno = yes; then
2619   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2620 fi
2621
2622 # fmod, logb, and frexp are found in -lm on most systems.
2623 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2624 AC_CHECK_LIB(m, sqrt)
2625
2626 # Check for mail-locking functions in a "mail" library.  Probably this should
2627 # have the same check as for liblockfile below.
2628 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2629 if test $have_mail = yes; then
2630   LIBS_MAIL=-lmail
2631   LIBS="$LIBS_MAIL $LIBS"
2632   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2633 else
2634   LIBS_MAIL=
2635 fi
2636 dnl Debian, at least:
2637 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2638 if test $have_lockfile = yes; then
2639    LIBS_MAIL=-llockfile
2640    LIBS="$LIBS_MAIL $LIBS"
2641    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2642 else
2643 # If we have the shared liblockfile, assume we must use it for mail
2644 # locking (e.g. Debian).  If we couldn't link against liblockfile
2645 # (no liblockfile.a installed), ensure that we don't need to.
2646   dnl This works for files generally, not just executables.
2647   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2648   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2649                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2650   if test $ac_cv_prog_liblockfile = yes; then
2651     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2652 This probably means that movemail could lose mail.
2653 There may be a `development' package to install containing liblockfile.])
2654   fi
2655 fi
2656 AC_CHECK_FUNCS(touchlock)
2657 AC_CHECK_HEADERS(maillock.h)
2658 AC_SUBST(LIBS_MAIL)
2659
2660 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2661 ## interlock access to the mail spool.  The alternative is a lock file named
2662 ## /usr/spool/mail/$USER.lock.
2663 mail_lock=no
2664 case "$opsys" in
2665   aix4-2) mail_lock="lockf" ;;
2666
2667   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2668
2669   ## On GNU/Linux systems, both methods are used by various mail programs.
2670   ## I assume most people are using newer mailers that have heard of flock.
2671   ## Change this if you need to.
2672   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2673   ## configure gets the right answers, and that means *NOT* using flock.
2674   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2675   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2676   ## Debian maintainer hasn't provided a clean fix for Emacs.
2677   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2678   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2679   ## correct logic.  -- fx
2680   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2681   ## liblockfile is a Free Software replacement for libmail, used on
2682   ## Debian systems and elsewhere. -rfr.
2683   gnu-*)
2684     mail_lock="flock"
2685     if test $have_mail = yes || test $have_lockfile = yes; then
2686       test $ac_cv_header_maillock_h = yes && mail_lock=no
2687     fi
2688     ;;
2689 esac
2690
2691 BLESSMAIL_TARGET=
2692 case "$mail_lock" in
2693   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2694
2695   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2696
2697   *) BLESSMAIL_TARGET="need-blessmail" ;;
2698 esac
2699 AC_SUBST(BLESSMAIL_TARGET)
2700
2701
2702 AC_CHECK_FUNCS(gethostname getdomainname \
2703 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2704 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2705 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2706 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2707 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2708 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2709 gai_strerror mkstemp getline getdelim mremap fsync sync \
2710 difftime mempcpy mblen mbrlen posix_memalign \
2711 cfmakeraw cfsetspeed isnan copysign __executable_start)
2712
2713 dnl Cannot use AC_CHECK_FUNCS
2714 AC_CACHE_CHECK([for __builtin_unwind_init],
2715                emacs_cv_func___builtin_unwind_init,
2716 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2717                 emacs_cv_func___builtin_unwind_init=yes,
2718                 emacs_cv_func___builtin_unwind_init=no)])
2719 if test $emacs_cv_func___builtin_unwind_init = yes; then
2720   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2721             [Define to 1 if you have the `__builtin_unwind_init' function.])
2722 fi
2723
2724 AC_CHECK_HEADERS(sys/un.h)
2725
2726 AC_FUNC_FSEEKO
2727
2728 AC_FUNC_GETPGRP
2729
2730 # UNIX98 PTYs.
2731 AC_CHECK_FUNCS(grantpt)
2732
2733 # PTY-related GNU extensions.
2734 AC_CHECK_FUNCS(getpt)
2735
2736 # Check this now, so that we will NOT find the above functions in ncurses.
2737 # That is because we have not set up to link ncurses in lib-src.
2738 # It's better to believe a function is not available
2739 # than to expect to find it in ncurses.
2740 # Also we need tputs and friends to be able to build at all.
2741 have_tputs_et_al=true
2742 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2743 if test "$have_tputs_et_al" != true; then
2744   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2745 Maybe some development libraries/packages are missing?  Try installing
2746 libncurses-dev(el), libterminfo-dev(el) or similar.])
2747 fi
2748 # Must define this when any termcap library is found.
2749 AC_DEFINE(HAVE_LIBNCURSES, 1,
2750           [Define to 1 if you have the `ncurses' library (-lncurses).])
2751 ## FIXME This was the cpp logic, but I am not sure it is right.
2752 ## The above test has not necessarily found libncurses.
2753 HAVE_LIBNCURSES=yes
2754
2755 ## Use terminfo instead of termcap?
2756 ## Note only system files NOT using terminfo are:
2757 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2758 ## darwin|gnu without ncurses.
2759 TERMINFO=no
2760 LIBS_TERMCAP=
2761 case "$opsys" in
2762   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2763   ## hpux10-20: Use the system provided termcap(3) library.
2764   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2765   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2766   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2767
2768   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2769   ##  The ncurses library has been moved out of the System framework in
2770   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2771   ##  option to use it.
2772   darwin|gnu*)
2773     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2774     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2775       TERMINFO=yes
2776       LIBS_TERMCAP="-lncurses"
2777     fi
2778     ;;
2779
2780   freebsd)
2781     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2782     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2783     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2784 [[#if __FreeBSD_version < 400000
2785 fail;
2786 #endif
2787 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2788
2789     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2790
2791     if test $emacs_cv_freebsd_terminfo = yes; then
2792       TERMINFO=yes
2793       LIBS_TERMCAP="-lncurses"
2794     else
2795       LIBS_TERMCAP="-ltermcap"
2796     fi
2797     ;;
2798
2799   netbsd)
2800     if test $ac_cv_search_tputs = -lterminfo; then
2801       TERMINFO=yes
2802       LIBS_TERMCAP="-lterminfo"
2803     else
2804       LIBS_TERMCAP="-ltermcap"
2805     fi
2806     ;;
2807
2808 esac
2809
2810 case "$opsys" in
2811   ## hpux: Make sure we get select from libc rather than from libcurses
2812   ##  because libcurses on HPUX 10.10 has a broken version of select.
2813   ##  We used to use -lc -lcurses, but this may be cleaner.
2814   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2815
2816   openbsd) LIBS_TERMCAP="-lncurses" ;;
2817
2818   ## Must use system termcap, if we use any termcap.  It does special things.
2819   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2820 esac
2821
2822 TERMCAP_OBJ=tparam.o
2823 if test $TERMINFO = yes; then
2824   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2825
2826   ## Default used to be -ltermcap.  Add a case above if need something else.
2827   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2828
2829   TERMCAP_OBJ=terminfo.o
2830 fi
2831 AC_SUBST(LIBS_TERMCAP)
2832 AC_SUBST(TERMCAP_OBJ)
2833
2834
2835 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2836 resolv=no
2837 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2838 #include <arpa/nameser.h>
2839 #include <resolv.h>]],
2840     [[return res_init();]])],
2841     have_res_init=yes, have_res_init=no)
2842 if test "$have_res_init" = no; then
2843   OLIBS="$LIBS"
2844   LIBS="$LIBS -lresolv"
2845   AC_MSG_CHECKING(for res_init with -lresolv)
2846   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2847 #include <arpa/nameser.h>
2848 #include <resolv.h>]],
2849     [[return res_init();]])],
2850     have_res_init=yes, have_res_init=no)
2851   AC_MSG_RESULT($have_res_init)
2852   if test "$have_res_init" = yes ; then
2853     resolv=yes
2854   fi
2855   LIBS="$OLIBS"
2856 fi
2857
2858 if test "$have_res_init" = yes; then
2859   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2860 fi
2861
2862 # Do we need the Hesiod library to provide the support routines?
2863 LIBHESIOD=
2864 if test "$with_hesiod" != no ; then
2865   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2866   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2867      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2868                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2869   if test "$resolv" = yes ; then
2870     RESOLVLIB=-lresolv
2871   else
2872     RESOLVLIB=
2873   fi
2874   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2875         hesiod=yes, :, $RESOLVLIB)])
2876
2877   if test x"$hesiod" = xyes; then
2878     AC_DEFINE(HAVE_LIBHESIOD, 1,
2879               [Define to 1 if you have the hesiod library (-lhesiod).])
2880     LIBHESIOD=-lhesiod
2881   fi
2882 fi
2883 AC_SUBST(LIBHESIOD)
2884
2885 # Do we need libresolv (due to res_init or Hesiod)?
2886 if test "$resolv" = yes ; then
2887   AC_DEFINE(HAVE_LIBRESOLV, 1,
2888             [Define to 1 if you have the resolv library (-lresolv).])
2889   LIBRESOLV=-lresolv
2890 else
2891   LIBRESOLV=
2892 fi
2893 AC_SUBST(LIBRESOLV)
2894
2895 # These tell us which Kerberos-related libraries to use.
2896 COM_ERRLIB=
2897 CRYPTOLIB=
2898 KRB5LIB=
2899 DESLIB=
2900 KRB4LIB=
2901
2902 if test "${with_kerberos}" != no; then
2903   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2904   if test $have_com_err = yes; then
2905     COM_ERRLIB=-lcom_err
2906     LIBS="$COM_ERRLIB $LIBS"
2907     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2908   fi
2909   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2910   if test $have_crypto = yes; then
2911     CRYPTOLIB=-lcrypto
2912     LIBS="$CRYPTOLIB $LIBS"
2913     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2914   fi
2915   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2916   if test $have_k5crypto = yes; then
2917     CRYPTOLIB=-lk5crypto
2918     LIBS="$CRYPTOLIB $LIBS"
2919     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2920   fi
2921   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2922   if test $have_krb5=yes; then
2923     KRB5LIB=-lkrb5
2924     LIBS="$KRB5LIB $LIBS"
2925     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2926   fi
2927   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2928   if test "${with_kerberos5}" = no; then
2929     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2930     if test $have_des425 = yes; then
2931       DESLIB=-ldes425
2932       LIBS="$DESLIB $LIBS"
2933       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2934     else
2935       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2936       if test $have_des = yes; then
2937         DESLIB=-ldes
2938         LIBS="$DESLIB $LIBS"
2939         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2940       fi
2941     fi
2942     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2943     if test $have_krb4 = yes; then
2944       KRB4LIB=-lkrb4
2945       LIBS="$KRB4LIB $LIBS"
2946       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2947     else
2948       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2949       if test $have_krb = yes; then
2950         KRB4LIB=-lkrb
2951         LIBS="$KRB4LIB $LIBS"
2952         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2953       fi
2954     fi
2955   fi
2956
2957   if test "${with_kerberos5}" != no; then
2958     AC_CHECK_HEADERS(krb5.h,
2959       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2960                         [#include <krb5.h>])])
2961   else
2962     AC_CHECK_HEADERS(des.h,,
2963                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2964                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2965     AC_CHECK_HEADERS(krb.h,,
2966                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2967                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2968   fi
2969   AC_CHECK_HEADERS(com_err.h)
2970 fi
2971
2972 AC_SUBST(COM_ERRLIB)
2973 AC_SUBST(CRYPTOLIB)
2974 AC_SUBST(KRB5LIB)
2975 AC_SUBST(DESLIB)
2976 AC_SUBST(KRB4LIB)
2977
2978 # Solaris requires -lintl if you want strerror (which calls dgettext)
2979 # to return localized messages.
2980 AC_CHECK_LIB(intl, dgettext)
2981
2982 AC_MSG_CHECKING(whether localtime caches TZ)
2983 AC_CACHE_VAL(emacs_cv_localtime_cache,
2984 [if test x$ac_cv_func_tzset = xyes; then
2985 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2986 char TZ_GMT0[] = "TZ=GMT0";
2987 char TZ_PST8[] = "TZ=PST8";
2988 main()
2989 {
2990   time_t now = time ((time_t *) 0);
2991   int hour_GMT0, hour_unset;
2992   if (putenv (TZ_GMT0) != 0)
2993     exit (1);
2994   hour_GMT0 = localtime (&now)->tm_hour;
2995   unsetenv("TZ");
2996   hour_unset = localtime (&now)->tm_hour;
2997   if (putenv (TZ_PST8) != 0)
2998     exit (1);
2999   if (localtime (&now)->tm_hour == hour_GMT0)
3000     exit (1);
3001   unsetenv("TZ");
3002   if (localtime (&now)->tm_hour != hour_unset)
3003     exit (1);
3004   exit (0);
3005 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3006 [# If we have tzset, assume the worst when cross-compiling.
3007 emacs_cv_localtime_cache=yes])
3008 else
3009         # If we lack tzset, report that localtime does not cache TZ,
3010         # since we can't invalidate the cache if we don't have tzset.
3011         emacs_cv_localtime_cache=no
3012 fi])dnl
3013 AC_MSG_RESULT($emacs_cv_localtime_cache)
3014 if test $emacs_cv_localtime_cache = yes; then
3015   AC_DEFINE(LOCALTIME_CACHE, 1,
3016             [Define to 1 if localtime caches TZ.])
3017 fi
3018
3019 if test "x$HAVE_TIMEVAL" = xyes; then
3020   AC_CHECK_FUNCS(gettimeofday)
3021   if test $ac_cv_func_gettimeofday = yes; then
3022     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3023                    emacs_cv_gettimeofday_two_arguments,
3024     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3025 #ifdef TIME_WITH_SYS_TIME
3026 #include <sys/time.h>
3027 #include <time.h>
3028 #else
3029 #ifdef HAVE_SYS_TIME_H
3030 #include <sys/time.h>
3031 #else
3032 #include <time.h>
3033 #endif
3034 #endif]],
3035       [[struct timeval time;
3036        gettimeofday (&time, 0);]])],
3037       emacs_cv_gettimeofday_two_arguments=yes,
3038       emacs_cv_gettimeofday_two_arguments=no)])
3039     if test $emacs_cv_gettimeofday_two_arguments = no; then
3040       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3041                 [Define to 1 if gettimeofday accepts only one argument.])
3042     fi
3043   fi
3044 fi
3045
3046 ok_so_far=yes
3047 AC_CHECK_FUNC(socket, , ok_so_far=no)
3048 if test $ok_so_far = yes; then
3049   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3050 fi
3051 if test $ok_so_far = yes; then
3052   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3053 fi
3054 if test $ok_so_far = yes; then
3055 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3056   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3057             [Define to 1 if you have inet sockets.])
3058 fi
3059
3060 if test -f /usr/lpp/X11/bin/smt.exp; then
3061   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3062             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3063 fi
3064
3065 AC_MSG_CHECKING(whether system supports dynamic ptys)
3066 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3067   AC_MSG_RESULT(yes)
3068   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3069 else
3070   AC_MSG_RESULT(no)
3071 fi
3072
3073 AC_FUNC_FORK
3074
3075 dnl Adapted from Haible's version.
3076 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3077   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3078     [[char* cs = nl_langinfo(CODESET);]])],
3079     emacs_cv_langinfo_codeset=yes,
3080     emacs_cv_langinfo_codeset=no)
3081   ])
3082 if test $emacs_cv_langinfo_codeset = yes; then
3083   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3084     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3085 fi
3086
3087 AC_TYPE_MBSTATE_T
3088
3089 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3090   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3091                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3092 if test "$emacs_cv_c_restrict_arr" = yes; then
3093   AC_DEFINE(__restrict_arr, __restrict,
3094     [Define to compiler's equivalent of C99 restrict keyword in array
3095      declarations.  Define as empty for no equivalent.])
3096 fi
3097
3098 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3099 dnl how the tty code is related to POSIX and/or other versions of termios.
3100 dnl The following looks like a useful start.
3101 dnl
3102 dnl AC_SYS_POSIX_TERMIOS
3103 dnl if test $ac_cv_sys_posix_termios = yes; then
3104 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3105 dnl                                and macros for terminal control.])
3106 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3107 dnl fi
3108
3109 # Set up the CFLAGS for real compilation, so we can substitute it.
3110 CFLAGS="$REAL_CFLAGS"
3111 CPPFLAGS="$REAL_CPPFLAGS"
3112
3113 ## Hack to detect a buggy GCC version.
3114 if test "x$GCC" = xyes \
3115    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3116    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3117    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3118    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3119 fi
3120
3121 version=$PACKAGE_VERSION
3122
3123 ### Specify what sort of things we'll be editing into Makefile and config.h.
3124 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3125 AC_SUBST(version)
3126 AC_SUBST(configuration)
3127 ## Unused?
3128 AC_SUBST(canonical)
3129 AC_SUBST(srcdir)
3130 AC_SUBST(prefix)
3131 AC_SUBST(exec_prefix)
3132 AC_SUBST(bindir)
3133 AC_SUBST(datadir)
3134 AC_SUBST(sharedstatedir)
3135 AC_SUBST(libexecdir)
3136 AC_SUBST(mandir)
3137 AC_SUBST(infodir)
3138 AC_SUBST(lispdir)
3139 AC_SUBST(locallisppath)
3140 AC_SUBST(lisppath)
3141 AC_SUBST(x_default_search_path)
3142 AC_SUBST(etcdir)
3143 AC_SUBST(archlibdir)
3144 AC_SUBST(docdir)
3145 AC_SUBST(bitmapdir)
3146 AC_SUBST(gamedir)
3147 AC_SUBST(gameuser)
3148 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3149 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3150 ## end of LIBX_BASE, but nothing ever set it.
3151 AC_SUBST(LD_SWITCH_X_SITE)
3152 AC_SUBST(C_SWITCH_X_SITE)
3153 AC_SUBST(C_SWITCH_X_SYSTEM)
3154 AC_SUBST(CFLAGS)
3155 ## Used in lwlib/Makefile.in.
3156 AC_SUBST(X_TOOLKIT_TYPE)
3157 if test -n "${machfile}"; then
3158   M_FILE="\$(srcdir)/${machfile}"
3159 else
3160   M_FILE=
3161 fi
3162 S_FILE="\$(srcdir)/${opsysfile}"
3163 AC_SUBST(M_FILE)
3164 AC_SUBST(S_FILE)
3165 AC_SUBST(ns_appdir)
3166 AC_SUBST(ns_appbindir)
3167 AC_SUBST(ns_appresdir)
3168 AC_SUBST(ns_appsrc)
3169 AC_SUBST(GNU_OBJC_CFLAGS)
3170 AC_SUBST(OTHER_FILES)
3171
3172 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3173                    [Define to the canonical Emacs configuration name.])
3174 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3175                    [Define to the options passed to configure.])
3176 if test -n "$machfile"; then
3177   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3178                      [Define to the used machine dependent file.])
3179 fi
3180 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3181                    [Define to the used os dependent file.])
3182
3183 XMENU_OBJ=
3184 XOBJ=
3185 FONT_OBJ=
3186 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3187   AC_DEFINE(HAVE_X_WINDOWS, 1,
3188             [Define to 1 if you want to use the X window system.])
3189   XMENU_OBJ=xmenu.o
3190   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3191   FONT_OBJ=xfont.o
3192   if test "$HAVE_XFT" = "yes"; then
3193     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3194   elif test "$HAVE_FREETYPE" = "yes"; then
3195     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3196   fi
3197   AC_SUBST(FONT_OBJ)
3198 fi
3199 AC_SUBST(XMENU_OBJ)
3200 AC_SUBST(XOBJ)
3201 AC_SUBST(FONT_OBJ)
3202
3203 WIDGET_OBJ=
3204 MOTIF_LIBW=
3205 if test "${USE_X_TOOLKIT}" != "none" ; then
3206   WIDGET_OBJ=widget.o
3207   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3208   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3209     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3210   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3211     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3212     MOTIF_LIBW=-lXm
3213     case "$opsys" in
3214       gnu-linux)
3215         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3216         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3217         ;;
3218
3219       unixware)
3220         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3221         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3222         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3223         ;;
3224
3225       aix4-2)
3226         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3227         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3228         ;;
3229     esac
3230     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3231   fi
3232 fi
3233 AC_SUBST(WIDGET_OBJ)
3234
3235 TOOLKIT_LIBW=
3236 case "$USE_X_TOOLKIT" in
3237   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3238   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3239   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3240 esac
3241 AC_SUBST(TOOLKIT_LIBW)
3242
3243 if test "$USE_X_TOOLKIT" = "none"; then
3244   LIBXT_OTHER="\$(LIBXSM)"
3245   OLDXMENU_TARGET="really-oldXMenu"
3246 else
3247   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3248   OLDXMENU_TARGET="really-lwlib"
3249 fi
3250 AC_SUBST(LIBXT_OTHER)
3251
3252 ## The X Menu stuff is present in the X10 distribution, but missing
3253 ## from X11.  If we have X10, just use the installed library;
3254 ## otherwise, use our own copy.
3255 if test "${HAVE_X11}" = "yes" ; then
3256   AC_DEFINE(HAVE_X11, 1,
3257             [Define to 1 if you want to use version 11 of X windows.
3258              Otherwise, Emacs expects to use version 10.])
3259
3260   if test "$USE_X_TOOLKIT" = "none"; then
3261     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3262   else
3263     OLDXMENU="\${lwlibdir}/liblw.a"
3264   fi
3265   LIBXMENU="\$(OLDXMENU)"
3266   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3267   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3268 else
3269   ## For a syntactically valid Makefile; not actually used for anything.
3270   ## See comments in src/Makefile.in.
3271   OLDXMENU=nothing
3272   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3273   if test "${HAVE_X_WINDOWS}" = "yes"; then
3274     LIBXMENU="-lXMenu"
3275   else
3276     LIBXMENU=
3277   fi
3278   LIBX_OTHER=
3279   OLDXMENU_DEPS=
3280 fi
3281
3282 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3283   OLDXMENU_TARGET=
3284   OLDXMENU=nothing
3285   LIBXMENU=
3286   OLDXMENU_DEPS=
3287 fi
3288
3289 AC_SUBST(OLDXMENU_TARGET)
3290 AC_SUBST(OLDXMENU)
3291 AC_SUBST(LIBXMENU)
3292 AC_SUBST(LIBX_OTHER)
3293 AC_SUBST(OLDXMENU_DEPS)
3294
3295 if test "${HAVE_MENUS}" = "yes" ; then
3296   AC_DEFINE(HAVE_MENUS, 1,
3297             [Define to 1 if you have mouse menus.
3298              (This is automatic if you use X, but the option to specify it remains.)
3299              It is also defined with other window systems that support xmenu.c.])
3300 fi
3301
3302 if test "${GNU_MALLOC}" = "yes" ; then
3303   AC_DEFINE(GNU_MALLOC, 1,
3304             [Define to 1 if you want to use the GNU memory allocator.])
3305 fi
3306
3307 RALLOC_OBJ=
3308 if test "${REL_ALLOC}" = "yes" ; then
3309   AC_DEFINE(REL_ALLOC, 1,
3310             [Define REL_ALLOC if you want to use the relocating allocator for
3311              buffer space.])
3312
3313   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3314 fi
3315 AC_SUBST(RALLOC_OBJ)
3316
3317 if test "$opsys" = "cygwin"; then
3318   CYGWIN_OBJ="sheap.o"
3319   ## Cygwin differs because of its unexec().
3320   PRE_ALLOC_OBJ=
3321   POST_ALLOC_OBJ=lastfile.o
3322 else
3323   CYGWIN_OBJ=
3324   PRE_ALLOC_OBJ=lastfile.o
3325   POST_ALLOC_OBJ=
3326 fi
3327 AC_SUBST(CYGWIN_OBJ)
3328 AC_SUBST(PRE_ALLOC_OBJ)
3329 AC_SUBST(POST_ALLOC_OBJ)
3330
3331 # Configure gnulib here, now that we know LIBS.
3332 gl_ASSERT_NO_GNULIB_POSIXCHECK
3333 gl_ASSERT_NO_GNULIB_TESTS
3334 gl_INIT
3335
3336 case "$opsys" in
3337   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3338
3339   darwin)
3340    ## The -headerpad option tells ld (see man page) to leave room at the
3341    ## end of the header for adding load commands.  Needed for dumping.
3342    ## 0x690 is the total size of 30 segment load commands (at 56
3343    ## each); under Cocoa 31 commands are required.
3344    if test "$HAVE_NS" = "yes"; then
3345      libs_nsgui="-framework AppKit"
3346      headerpad_extra=6C8
3347    else
3348      libs_nsgui=
3349      headerpad_extra=690
3350    fi
3351    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3352
3353    ## This is here because src/Makefile.in did some extra fiddling around
3354    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3355    ##   #ifndef LD_SWITCH_SYSTEM
3356    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3357    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3358    ## not using gcc, darwin system not on an alpha (ie darwin, since
3359    ## darwin + alpha does not occur).
3360    ## Because this was done in src/Makefile.in, the resulting part of
3361    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3362    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3363    ## rather than LD_SWITCH_SYSTEM.
3364    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3365      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3366    ;;
3367
3368   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3369   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3370   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3371   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3372   ## had different values in configure (in ac_link) and src/Makefile.in.
3373   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3374   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3375
3376   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3377 esac
3378
3379 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3380   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3381 fi
3382
3383 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3384
3385
3386 LD_FIRSTFLAG=
3387 ORDINARY_LINK=
3388 case "$opsys" in
3389   ## gnu: GNU needs its own crt0.
3390   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3391
3392   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3393   ## library search parth, i.e. it won't search /usr/lib for libc and
3394   ## friends.  Using -nostartfiles instead avoids this problem, and
3395   ## will also work on earlier NetBSD releases.
3396   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3397
3398   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3399   ##   MkLinux/LinuxPPC needs this.
3400   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3401   gnu-*)
3402     case "$machine" in
3403       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3404     esac
3405     ;;
3406 esac
3407
3408
3409 if test "x$ORDINARY_LINK" = "xyes"; then
3410
3411   LD_FIRSTFLAG=""
3412   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3413
3414 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3415 ## freebsd, gnu-* not on macppc|ibms390x.
3416 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3417
3418   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3419   ## places that are difficult to figure out at make time.  Fortunately,
3420   ## these same versions allow you to pass arbitrary flags on to the
3421   ## linker, so there is no reason not to use it as a linker.
3422   ##
3423   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3424   ## searching for libraries in its internal directories, so we have to
3425   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3426   LD_FIRSTFLAG="-nostdlib"
3427 fi
3428
3429 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3430 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3431
3432 AC_SUBST(LD_FIRSTFLAG)
3433
3434
3435 ## FIXME? The logic here is not precisely the same as that above.
3436 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3437 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3438 LIB_GCC=
3439 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3440
3441   case "$opsys" in
3442     freebsd|netbsd|openbsd) LIB_GCC= ;;
3443
3444     gnu-*)
3445       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3446       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3447       case $host_cpu in
3448       arm*)
3449         LIB_GCC="-lgcc_s"
3450         ;;
3451       *)
3452         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3453         ## immediately undefine it again and redefine it to empty.
3454         ## Was the C_SWITCH_X_SITE part really necessary?
3455 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3456         LIB_GCC=
3457         ;;
3458       esac
3459       ;;
3460
3461     ## Ask GCC where to find libgcc.a.
3462     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3463   esac
3464 fi                              dnl if $GCC
3465 AC_SUBST(LIB_GCC)
3466
3467
3468 ## If we're using X11/GNUstep, define some consequences.
3469 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3470   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3471   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3472 fi
3473
3474
3475 AH_TOP([/* GNU Emacs site configuration template file.
3476
3477 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3478   Free Software Foundation, Inc.
3479
3480 This file is part of GNU Emacs.
3481
3482 GNU Emacs is free software: you can redistribute it and/or modify
3483 it under the terms of the GNU General Public License as published by
3484 the Free Software Foundation, either version 3 of the License, or
3485 (at your option) any later version.
3486
3487 GNU Emacs is distributed in the hope that it will be useful,
3488 but WITHOUT ANY WARRANTY; without even the implied warranty of
3489 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3490 GNU General Public License for more details.
3491
3492 You should have received a copy of the GNU General Public License
3493 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3494
3495
3496 /* No code in Emacs #includes config.h twice, but some bits of code
3497    intended to work with other packages as well (like gmalloc.c)
3498    think they can include it as many times as they like.  */
3499 #ifndef EMACS_CONFIG_H
3500 #define EMACS_CONFIG_H
3501 ])dnl
3502
3503 AH_BOTTOM([
3504 /* On AIX 3 this must be included before any other include file.  */
3505 #include <alloca.h>
3506 #if ! HAVE_ALLOCA
3507 # error "alloca not available on this machine"
3508 #endif
3509
3510 /* Define AMPERSAND_FULL_NAME if you use the convention
3511    that & in the full name stands for the login id.  */
3512 /* Turned on June 1996 supposing nobody will mind it.  */
3513 #define AMPERSAND_FULL_NAME
3514
3515 /* `subprocesses' should be defined if you want to
3516    have code for asynchronous subprocesses
3517    (as used in M-x compile and M-x shell).
3518    Only MSDOS does not support this (it overrides
3519    this in its config_opsysfile below).  */
3520
3521 #define subprocesses
3522
3523 /* Include the os and machine dependent files.  */
3524 #include config_opsysfile
3525 #ifdef config_machfile
3526 # include config_machfile
3527 #endif
3528
3529 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3530    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3531   (There is probably a better place to do this, but right now the
3532    Cocoa side does this in s/darwin.h and we cannot parallel this
3533    exactly since GNUstep is multi-OS.  */
3534 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3535 #  define SYSTEM_PURESIZE_EXTRA 30000
3536 #endif
3537
3538 #ifdef emacs /* Don't do this for lib-src.  */
3539 /* Tell regex.c to use a type compatible with Emacs.  */
3540 #define RE_TRANSLATE_TYPE Lisp_Object
3541 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3542 #ifdef make_number
3543 /* If make_number is a macro, use it.  */
3544 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3545 #else
3546 /* If make_number is a function, avoid it.  */
3547 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3548 #endif
3549 #endif
3550
3551 /* These default definitions are good for almost all machines.
3552    Any exceptions should override them in m/MACHINE.h.
3553    They must be usable in preprocessor conditionals.  */
3554
3555 #ifndef BITS_PER_CHAR
3556 #define BITS_PER_CHAR 8
3557 #endif
3558
3559 #ifndef BITS_PER_SHORT
3560 #define BITS_PER_SHORT 16
3561 #endif
3562
3563 #ifndef BITS_PER_INT
3564 #define BITS_PER_INT 32
3565 #endif
3566
3567 #ifndef BITS_PER_LONG
3568 #ifdef _LP64
3569 #define BITS_PER_LONG 64
3570 #else
3571 #define BITS_PER_LONG 32
3572 #endif
3573 #endif
3574
3575 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3576 #define BITS_PER_LONG_LONG 64
3577 #endif
3578
3579 /* Define if the compiler supports function prototypes.  It may do so but
3580    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3581 #undef PROTOTYPES
3582
3583 #include <string.h>
3584 #include <stdlib.h>
3585
3586 #if defined __GNUC__ && (__GNUC__ > 2 \
3587                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3588 #define NO_RETURN       __attribute__ ((__noreturn__))
3589 #else
3590 #define NO_RETURN       /* nothing */
3591 #endif
3592
3593 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3594 #define NO_INLINE __attribute__((noinline))
3595 #else
3596 #define NO_INLINE
3597 #endif
3598
3599 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3600 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3601 #else
3602 #define EXTERNALLY_VISIBLE
3603 #endif
3604
3605 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3606 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3607 #else
3608 # define ATTRIBUTE_FORMAT(spec) /* empty */
3609 #endif
3610
3611 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3612 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3613    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3614 #else
3615 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3616    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3617 #endif
3618
3619 /* Some versions of GNU/Linux define noinline in their headers.  */
3620 #ifdef noinline
3621 #undef noinline
3622 #endif
3623
3624 /* These won't be used automatically yet.  We also need to know, at least,
3625    that the stack is continuous.  */
3626 #ifdef __GNUC__
3627 #  ifndef GC_SETJMP_WORKS
3628   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3629 #    define GC_SETJMP_WORKS 1
3630 #  endif
3631 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3632 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3633 #  endif
3634 #endif
3635
3636 #endif /* EMACS_CONFIG_H */
3637
3638 /*
3639 Local Variables:
3640 mode: c
3641 End:
3642 */
3643 ])dnl
3644
3645 #### Report on what we decided to do.
3646 #### Report GTK as a toolkit, even if it doesn't use Xt.
3647 #### It makes printing result more understandable as using GTK sets
3648 #### toolkit_scroll_bars to yes by default.
3649 if test "${HAVE_GTK}" = "yes"; then
3650   USE_X_TOOLKIT=GTK
3651 fi
3652
3653 and_machfile=
3654 if test -n "$machfile"; then
3655   and_machfile=" and \`${machfile}'"
3656 fi
3657
3658 echo "
3659 Configured for \`${canonical}'.
3660
3661   Where should the build process find the source code?    ${srcdir}
3662   What operating system and machine description files should Emacs use?
3663         \`${opsysfile}'${and_machfile}
3664   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3665   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3666   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3667   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3668   What window system should Emacs use?                    ${window_system}
3669   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3670
3671 if test -n "${x_includes}"; then
3672 echo "  Where do we find X Windows header files?                ${x_includes}"
3673 else
3674 echo "  Where do we find X Windows header files?                Standard dirs"
3675 fi
3676 if test -n "${x_libraries}"; then
3677 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3678 else
3679 echo "  Where do we find X Windows libraries?                   Standard dirs"
3680 fi
3681
3682 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3683 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3684 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3685 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3686 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3687 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3688 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3689 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3690
3691 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3692 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3693 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3694 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3695 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3696 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3697 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3698
3699 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3700 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3701 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3702 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3703
3704 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3705 echo
3706
3707 if test $USE_XASSERTS = yes; then
3708    echo "  Compiling with asserts turned on."
3709    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3710 fi
3711
3712 echo
3713
3714 if test "$HAVE_NS" = "yes"; then
3715    echo
3716    echo "You must run \"make install\" in order to test the built application.
3717 The installed application will go to nextstep/Emacs.app and can be
3718 run or moved from there."
3719    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3720       echo "The application will be fully self-contained."
3721     else
3722       echo "The lisp resources for the application will be installed under ${prefix}.
3723 You may need to run \"make install\" with sudo.  The application will fail
3724 to run if these resources are not installed."
3725    fi
3726    echo
3727 fi
3728
3729
3730 # Remove any trailing slashes in these variables.
3731 [test "${prefix}" != NONE &&
3732   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3733 test "${exec_prefix}" != NONE &&
3734   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3735
3736 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3737 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3738 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3739 dnl (else you get "no `Makefile.am' found for any configure output").
3740 dnl This will work, but you get a config.status that is not quite right
3741 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3742 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3743 dnl it seems better to just live with the duplication.
3744 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3745
3746 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3747        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3748        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3749        leim/Makefile])
3750
3751 dnl test/ is not present in release tarfiles.
3752 opt_makefile=test/automated/Makefile
3753
3754 if test -f $srcdir/${opt_makefile}.in; then
3755   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3756   dnl Again, it's best not to use a variable.  Though you can add
3757   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3758   AC_CONFIG_FILES([test/automated/Makefile])
3759 fi
3760
3761 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3762
3763 AC_SUBST(SUBDIR_MAKEFILES_IN)
3764
3765 dnl Make the necessary directories, if they don't exist.
3766 AC_CONFIG_COMMANDS([mkdirs], [
3767 for dir in etc lisp ; do
3768   test -d ${dir} || mkdir ${dir}
3769 done
3770 ])
3771
3772 dnl You might wonder (I did) why epaths.h is generated by running make,
3773 dnl rather than just letting configure generate it from epaths.in.
3774 dnl One reason is that the various paths are not fully expanded (see above);
3775 dnl eg gamedir=${prefix}/var/games/emacs.
3776 dnl Secondly, the GNU Coding standards require that one should be able
3777 dnl to run `make prefix=/some/where/else' and override the values set
3778 dnl by configure.  This also explains the `move-if-change' test and
3779 dnl the use of force in the `epaths-force' rule in Makefile.in.
3780 AC_CONFIG_COMMANDS([epaths], [
3781 echo creating src/epaths.h
3782 ${MAKE-make} epaths-force
3783 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3784
3785 AC_CONFIG_COMMANDS([gdbinit], [
3786 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3787   echo creating src/.gdbinit
3788   echo source $srcdir/src/.gdbinit > src/.gdbinit
3789 fi
3790 ])
3791
3792 AC_OUTPUT
3793
3794 dnl configure.in ends here