lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>, Riccardo Murri <riccardo.murri@gmail.com>
   6 ;; Keywords: tools
   7 ;; Created: Sept 2006
   8 ;; Version: 2007-09-05
   9 ;; URL: http://launchpad.net/vc-bzr
  10
  11 ;; This file is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; This file is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.
  30
  31 ;; Load this library to register bzr support in VC.  It covers basic VC
  32 ;; functionality, but was only lightly exercised with a few Emacs/bzr
  33 ;; version combinations, namely those current on the authors' PCs.
  34 ;; See various Fixmes below.
  35
  36
  37 ;; Known bugs
  38 ;; ==========
  39
  40 ;; When edititing a symlink and *both* the symlink and its target
  41 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  42 ;; symlink, thereby not detecting whether the actual contents
  43 ;; (that is, the target contents) are changed.
  44 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  45
  46 ;; For an up-to-date list of bugs, please see:
  47 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  48
  49
  50 ;;; Code:
  51
  52 (eval-when-compile
  53   (require 'cl)
  54   (require 'vc))                        ; for vc-exec-after
  55
  56 ;; Clear up the cache to force vc-call to check again and discover
  57 ;; new functions when we reload this file.
  58 (put 'Bzr 'vc-functions nil)
  59
  60 (defgroup vc-bzr nil
  61   "VC bzr backend."
  62   :version "22.2"
  63   :group 'vc)
  64
  65 (defcustom vc-bzr-program "bzr"
  66   "Name of the bzr command (excluding any arguments)."
  67   :group 'vc-bzr
  68   :type 'string)
  69
  70 ;; Fixme: there's probably no call for this.
  71 (defcustom vc-bzr-program-args nil
  72   "List of global arguments to pass to `vc-bzr-program'."
  73   :group 'vc-bzr
  74   :type '(repeat string))
  75
  76 (defcustom vc-bzr-diff-switches nil
  77   "String/list of strings specifying extra switches for bzr diff under VC."
  78   :type '(choice (const :tag "None" nil)
  79                  (string :tag "Argument String")
  80                  (repeat :tag "Argument List" :value ("") string))
  81   :group 'vc-bzr)
  82
  83 ;; since v0.9, bzr supports removing the progress indicators
  84 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  85 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  86   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  87 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' to the environment."
  88   (let ((process-environment
  89          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  90                 "LC_ALL=C"              ; Force English output
  91                 process-environment)))
  92     (apply 'vc-do-command buffer okstatus vc-bzr-program
  93            file-or-list bzr-command (append vc-bzr-program-args args))))
  94
  95
  96 ;;;###autoload
  97 (defconst vc-bzr-admin-dirname ".bzr"    ; FIXME: "_bzr" on w32?
  98   "Name of the directory containing Bzr repository status files.")
  99 ;;;###autoload
 100 (defconst vc-bzr-admin-checkout-format-file
 101   (concat vc-bzr-admin-dirname "/checkout/format"))
 102 (defconst vc-bzr-admin-dirstate
 103   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 104 (defconst vc-bzr-admin-branch-format-file
 105   (concat vc-bzr-admin-dirname "/branch/format"))
 106 (defconst vc-bzr-admin-revhistory
 107   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 108 (defconst vc-bzr-admin-lastrev
 109   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 110
 111 ;;;###autoload (defun vc-bzr-registered (file)
 112 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 113 ;;;###autoload       (progn
 114 ;;;###autoload         (load "vc-bzr")
 115 ;;;###autoload         (vc-bzr-registered file))))
 116
 117 (defun vc-bzr-root (file)
 118   "Return the root directory of the bzr repository containing FILE."
 119   ;; Cache technique copied from vc-arch.el.
 120   (or (vc-file-getprop file 'bzr-root)
 121       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 122         (when root (vc-file-setprop file 'bzr-root root)))))
 123
 124 (defun vc-bzr-registered (file)
 125   "Return non-nil if FILE is registered with bzr.
 126
 127 For speed, this function tries first to parse Bzr internal file
 128 `checkout/dirstate', but it may fail if Bzr internal file format
 129 has changed.  As a safeguard, the `checkout/dirstate' file is
 130 only parsed if it contains the string `#bazaar dirstate flat
 131 format 3' in the first line.
 132
 133 If the `checkout/dirstate' file cannot be parsed, fall back to
 134 running `vc-bzr-state'."
 135   (lexical-let ((root (vc-bzr-root file)))
 136     (when root    ; Short cut.
 137       ;; This looks at internal files.  May break if they change
 138       ;; their format.
 139       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 140         (if (not (file-readable-p dirstate))
 141             (vc-bzr-state file)         ; Expensive.
 142           (with-temp-buffer
 143             (insert-file-contents dirstate)
 144             (goto-char (point-min))
 145             (if (not (looking-at "#bazaar dirstate flat format 3"))
 146                 (vc-bzr-state file)     ; Some other unknown format?
 147               (let* ((relfile (file-relative-name file root))
 148                      (reldir (file-name-directory relfile)))
 149                 (re-search-forward
 150                  (concat "^\0"
 151                          (if reldir (regexp-quote (directory-file-name reldir)))
 152                          "\0"
 153                          (regexp-quote (file-name-nondirectory relfile))
 154                          "\0")
 155                  nil t)))))))))
 156
 157 (defconst vc-bzr-state-words
 158   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 159   "Regexp matching file status words as reported in `bzr' output.")
 160
 161 (defun vc-bzr-file-name-relative (filename)
 162   "Return file name FILENAME stripped of the initial Bzr repository path."
 163   (lexical-let*
 164       ((filename* (expand-file-name filename))
 165        (rootdir (vc-bzr-root (file-name-directory filename*))))
 166     (when rootdir
 167          (file-relative-name filename* rootdir))))
 168
 169 ;; FIXME:  Also get this in a non-registered sub-directory.
 170 ;; It already works for me. -- Riccardo
 171 (defun vc-bzr-status (file)
 172   "Return FILE status according to Bzr.
 173 Return value is a cons (STATUS . WARNING), where WARNING is a
 174 string or nil, and STATUS is one of the symbols: `added',
 175 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 176 which directly correspond to `bzr status' output, or 'unchanged
 177 for files whose copy in the working tree is identical to the one
 178 in the branch repository, or nil for files that are not
 179 registered with Bzr.
 180
 181 If any error occurred in running `bzr status', then return nil."
 182   (with-temp-buffer
 183     (let ((ret (condition-case nil
 184                    (vc-bzr-command "status" t 0 file)
 185                  (file-error nil)))     ; vc-bzr-program not found.
 186           (status 'unchanged))
 187           ;; the only secure status indication in `bzr status' output
 188           ;; is a couple of lines following the pattern::
 189           ;;   | <status>:
 190           ;;   |   <file name>
 191           ;; if the file is up-to-date, we get no status report from `bzr',
 192           ;; so if the regexp search for the above pattern fails, we consider
 193           ;; the file to be up-to-date.
 194           (goto-char (point-min))
 195           (when (re-search-forward
 196                  ;; bzr prints paths relative to the repository root.
 197                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 198                          (regexp-quote (vc-bzr-file-name-relative file))
 199                          (if (file-directory-p file) "/?" "")
 200                          "[ \t\n]*$")
 201                  nil t)
 202             (lexical-let ((statusword (match-string 1)))
 203               ;; Erase the status text that matched.
 204               (delete-region (match-beginning 0) (match-end 0))
 205               (setq status
 206                     (and (equal ret 0) ; Seems redundant.  --Stef
 207                          (intern (replace-regexp-in-string " " ""
 208                                                          statusword))))))
 209           (when status
 210             (goto-char (point-min))
 211             (skip-chars-forward " \n\t") ;Throw away spaces.
 212             (cons status
 213                   ;; "bzr" will output warnings and informational messages to
 214                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 215                   ;; `start-process' itself) limitations, we cannot catch stderr
 216                   ;; and stdout into different buffers.  So, if there's anything
 217                   ;; left in the buffer after removing the above status
 218                   ;; keywords, let us just presume that any other message from
 219                   ;; "bzr" is a user warning, and display it.
 220                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 221
 222 (defun vc-bzr-state (file)
 223   (lexical-let ((result (vc-bzr-status file)))
 224     (when (consp result)
 225       (if (cdr result)
 226           (message "Warnings in `bzr' output: %s" (cdr result)))
 227       (cdr (assq (car result)
 228                  '((added . edited)
 229                    (kindchanged . edited)
 230                    (renamed . edited)
 231                    (modified . edited)
 232                    (removed . edited)
 233                    (ignored . nil)
 234                    (unknown . nil)
 235                    (unchanged . up-to-date)))))))
 236
 237 (defun vc-bzr-workfile-unchanged-p (file)
 238   (eq 'unchanged (car (vc-bzr-status file))))
 239
 240 (defun vc-bzr-working-revision (file)
 241   (lexical-let*
 242       ((rootdir (vc-bzr-root file))
 243        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 244                                              rootdir))
 245        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 246        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 247     ;; This looks at internal files to avoid forking a bzr process.
 248     ;; May break if they change their format.
 249     (if (file-exists-p branch-format-file)
 250         (with-temp-buffer
 251           (insert-file-contents branch-format-file)
 252           (goto-char (point-min))
 253           (cond
 254            ((or
 255              (looking-at "Bazaar-NG branch, format 0.0.4")
 256              (looking-at "Bazaar-NG branch format 5"))
 257             ;; count lines in .bzr/branch/revision-history
 258             (insert-file-contents revhistory-file)
 259             (number-to-string (count-lines (line-end-position) (point-max))))
 260            ((looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 261             ;; revno is the first number in .bzr/branch/last-revision
 262             (insert-file-contents lastrev-file)
 263             (if (re-search-forward "[0-9]+" nil t)
 264                 (buffer-substring (match-beginning 0) (match-end 0))))))
 265       ;; fallback to calling "bzr revno"
 266       (lexical-let*
 267           ((result (vc-bzr-command-discarding-stderr
 268                     vc-bzr-program "revno" file))
 269            (exitcode (car result))
 270            (output (cdr result)))
 271         (cond
 272          ((eq exitcode 0) (substring output 0 -1))
 273          (t nil))))))
 274
 275 (defun vc-bzr-checkout-model (file)
 276   'implicit)
 277
 278 (defun vc-bzr-create-repo ()
 279   "Create a new Bzr repository."
 280   (vc-bzr-command "init" nil 0 nil))
 281
 282 (defun vc-bzr-register (files &optional rev comment)
 283   "Register FILE under bzr.
 284 Signal an error unless REV is nil.
 285 COMMENT is ignored."
 286   (if rev (error "Can't register explicit revision with bzr"))
 287   (vc-bzr-command "add" nil 0 files))
 288
 289 ;; Could run `bzr status' in the directory and see if it succeeds, but
 290 ;; that's relatively expensive.
 291 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 292   "Return non-nil if FILE is (potentially) controlled by bzr.
 293 The criterion is that there is a `.bzr' directory in the same
 294 or a superior directory.")
 295
 296 (defun vc-bzr-could-register (file)
 297   "Return non-nil if FILE could be registered under bzr."
 298   (and (vc-bzr-responsible-p file)      ; shortcut
 299        (condition-case ()
 300            (with-temp-buffer
 301              (vc-bzr-command "add" t 0 file "--dry-run")
 302              ;; The command succeeds with no output if file is
 303              ;; registered (in bzr 0.8).
 304              (goto-char (point-min))
 305              (looking-at "added "))
 306          (error))))
 307
 308 (defun vc-bzr-unregister (file)
 309   "Unregister FILE from bzr."
 310   (vc-bzr-command "remove" nil 0 file))
 311
 312 (defun vc-bzr-checkin (files rev comment)
 313   "Check FILE in to bzr with log message COMMENT.
 314 REV non-nil gets an error."
 315   (if rev (error "Can't check in a specific revision with bzr"))
 316   (vc-bzr-command "commit" nil 0 files "-m" comment))
 317
 318 (defun vc-bzr-checkout (file &optional editable rev destfile)
 319   "Checkout revision REV of FILE from bzr to DESTFILE.
 320 EDITABLE is ignored."
 321   (unless destfile
 322     (setq destfile (vc-version-backup-file-name file rev)))
 323   (let ((coding-system-for-read 'binary)
 324         (coding-system-for-write 'binary))
 325     (with-temp-file destfile
 326       (if rev
 327           (vc-bzr-command "cat" t 0 file "-r" rev)
 328         (vc-bzr-command "cat" t 0 file)))))
 329
 330 (defun vc-bzr-revert (file &optional contents-done)
 331   (unless contents-done
 332     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 333
 334 (defvar log-view-message-re)
 335 (defvar log-view-file-re)
 336 (defvar log-view-font-lock-keywords)
 337 (defvar log-view-current-tag-function)
 338
 339 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 340   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 341   (require 'add-log)
 342   ;; Don't have file markers, so use impossible regexp.
 343   (set (make-local-variable 'log-view-file-re) "\\'\\`")
 344   (set (make-local-variable 'log-view-message-re)
 345        "^ *-+\n *\\(?:revno: \\([0-9]+\\)\\|merged: .+\\)")
 346   (set (make-local-variable 'log-view-font-lock-keywords)
 347        ;; log-view-font-lock-keywords is careful to use the buffer-local
 348        ;; value of log-view-message-re only since Emacs-23.
 349        (append `((,log-view-message-re . 'log-view-message-face))
 350                ;; log-view-font-lock-keywords
 351                '(("^ *committer: \
 352 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 353                   (1 'change-log-name)
 354                   (2 'change-log-email))
 355                  ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face))))))
 356
 357 (defun vc-bzr-print-log (files &optional buffer) ; get buffer arg in Emacs 22
 358   "Get bzr change log for FILES into specified BUFFER."
 359   ;; Fixme: This might need the locale fixing up if things like `revno'
 360   ;; got localized, but certainly it shouldn't use LC_ALL=C.
 361   (vc-bzr-command "log" buffer 0 files)
 362   ;; FIXME: Until Emacs-23, VC was missing a hook to sort out the mode for
 363   ;; the buffer, or at least set the regexps right.
 364   (unless (fboundp 'vc-default-log-view-mode)
 365     (add-hook 'log-view-mode-hook 'vc-bzr-log-view-mode)))
 366
 367 (defun vc-bzr-show-log-entry (revision)
 368   "Find entry for patch name REVISION in bzr change log buffer."
 369   (goto-char (point-min))
 370   (let (case-fold-search)
 371     (if (re-search-forward (concat "^-+\nrevno: " revision "$") nil t)
 372         (beginning-of-line 0)
 373       (goto-char (point-min)))))
 374
 375 (autoload 'vc-diff-switches-list "vc" nil nil t)
 376
 377 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 378   "VC bzr backend for diff."
 379   (let ((working (vc-working-revision (if (consp files) (car files) files))))
 380     (if (and (equal rev1 working) (not rev2))
 381         (setq rev1 nil))
 382     (if (and (not rev1) rev2)
 383         (setq rev1 working))
 384     ;; bzr diff produces condition code 1 for some reason.
 385     (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*") 1 files
 386            "--diff-options" (mapconcat 'identity (vc-diff-switches-list bzr)
 387                                        " ")
 388            (when rev1
 389              (if rev2
 390                  (list "-r" (format "%s..%s" rev1 rev2))
 391                (list "-r" rev1))))))
 392
 393
 394
 395 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 396 ;; straight integer revisions.
 397
 398 (defun vc-bzr-delete-file (file)
 399   "Delete FILE and delete it in the bzr repository."
 400   (condition-case ()
 401       (delete-file file)
 402     (file-error nil))
 403   (vc-bzr-command "remove" nil 0 file))
 404
 405 (defun vc-bzr-rename-file (old new)
 406   "Rename file from OLD to NEW using `bzr mv'."
 407   (vc-bzr-command "mv" nil 0 new old))
 408
 409 (defvar vc-bzr-annotation-table nil
 410   "Internal use.")
 411 (make-variable-buffer-local 'vc-bzr-annotation-table)
 412
 413 (defun vc-bzr-annotate-command (file buffer &optional revision)
 414   "Prepare BUFFER for `vc-annotate' on FILE.
 415 Each line is tagged with the revision number, which has a `help-echo'
 416 property containing author and date information."
 417   (apply #'vc-bzr-command "annotate" buffer 0 file "--long" "--all"
 418          (if revision (list "-r" revision)))
 419   (with-current-buffer buffer
 420     ;; Store the tags for the annotated source lines in a hash table
 421     ;; to allow saving space by sharing the text properties.
 422     (setq vc-bzr-annotation-table (make-hash-table :test 'equal))
 423     (goto-char (point-min))
 424     (while (re-search-forward "^\\( *[0-9]+\\) +\\(.+\\) +\\([0-9]\\{8\\}\\) |"
 425                               nil t)
 426       (let* ((rev (match-string 1))
 427              (author (match-string 2))
 428              (date (match-string 3))
 429              (key (match-string 0))
 430              (tag (gethash key vc-bzr-annotation-table)))
 431         (unless tag
 432           (setq tag (propertize rev 'help-echo (concat "Author: " author
 433                                                        ", date: " date)
 434                                 'mouse-face 'highlight))
 435           (puthash key tag vc-bzr-annotation-table))
 436         (replace-match "")
 437         (insert tag " |")))))
 438
 439 ;; Definition from Emacs 22
 440 (unless (fboundp 'vc-annotate-convert-time)
 441   (defun vc-annotate-convert-time (time)
 442     "Convert a time value to a floating-point number of days.
 443 The argument TIME is a list as returned by `current-time' or
 444 `encode-time', only the first two elements of that list are considered."
 445     (/ (+ (* (float (car time)) (lsh 1 16)) (cadr time)) 24 3600)))
 446
 447 (defun vc-bzr-annotate-time ()
 448   (when (re-search-forward "^ *[0-9]+ |" nil t)
 449     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 450       (string-match "[0-9]+\\'" prop)
 451       (vc-annotate-convert-time
 452        (encode-time 0 0 0
 453                     (string-to-number (substring (match-string 0 prop) 6 8))
 454                     (string-to-number (substring (match-string 0 prop) 4 6))
 455                     (string-to-number (substring (match-string 0 prop) 0 4))
 456                     )))))
 457
 458 (defun vc-bzr-annotate-extract-revision-at-line ()
 459   "Return revision for current line of annoation buffer, or nil.
 460 Return nil if current line isn't annotated."
 461   (save-excursion
 462     (beginning-of-line)
 463     (if (looking-at " *\\([0-9]+\\) | ")
 464         (match-string-no-properties 1))))
 465
 466 ;; Not needed for Emacs 22
 467 (defun vc-bzr-annotate-difference (point)
 468   (let ((next-time (vc-bzr-annotate-time)))
 469     (if next-time
 470         (- (vc-annotate-convert-time (current-time)) next-time))))
 471
 472 (defun vc-bzr-command-discarding-stderr (command &rest args)
 473   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 474 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 475 the (numerical) exit code of the process, and OUTPUT is a string
 476 containing whatever the process sent to its standard output
 477 stream.  Standard error output is discarded."
 478   (with-temp-buffer
 479     (cons
 480      (apply #'call-process command nil (list (current-buffer) nil) nil args)
 481      (buffer-substring (point-min) (point-max)))))
 482
 483 ;; TODO: it would be nice to mark the conflicted files in  VC Dired,
 484 ;; and implement a command to run ediff and `bzr resolve' once the
 485 ;; changes have been merged.
 486 (defun vc-bzr-dir-state (dir &optional localp)
 487   "Find the VC state of all files in DIR and its subdirectories.
 488 Optional argument LOCALP is always ignored."
 489   (let ((bzr-root-directory (vc-bzr-root dir))
 490         (at-start t)
 491         current-bzr-state current-vc-state)
 492     ;; Check that DIR is a bzr repository.
 493     (unless (file-name-absolute-p bzr-root-directory)
 494       (error "Cannot find bzr repository for directory `%s'" dir))
 495     ;; `bzr ls --versioned' lists all versioned files;
 496     ;; assume they are up-to-date, unless we are given
 497     ;; evidence of the contrary.
 498     (setq at-start t)
 499     (with-temp-buffer
 500       (buffer-disable-undo)             ;; Because these buffers can get huge
 501       (vc-bzr-command "ls" t 0 nil "--versioned")
 502       (goto-char (point-min))
 503       (while (or at-start
 504                  (eq 0 (forward-line)))
 505         (setq at-start nil)
 506         (let ((file (expand-file-name
 507                      (buffer-substring-no-properties
 508                       (line-beginning-position) (line-end-position))
 509                      bzr-root-directory)))
 510           (vc-file-setprop file 'vc-state 'up-to-date)
 511           ;; XXX: is this correct? what happens if one
 512           ;; mixes different SCMs in the same dir?
 513           (vc-file-setprop file 'vc-backend 'Bzr))))
 514     ;; `bzr status' reports on added/modified/renamed and unknown/ignored files
 515     (setq at-start t)
 516     (with-temp-buffer
 517       (vc-bzr-command "status" t 0 nil)
 518       (goto-char (point-min))
 519       (while (or at-start
 520                  (eq 0 (forward-line)))
 521         (setq at-start nil)
 522         (cond
 523          ((looking-at "^added")
 524           (setq current-vc-state 'added)
 525           (setq current-bzr-state 'added))
 526          ((looking-at "^kind changed")
 527           (setq current-vc-state 'edited)
 528           (setq current-bzr-state 'kindchanged))
 529          ((looking-at "^modified")
 530           (setq current-vc-state 'edited)
 531           (setq current-bzr-state 'modified))
 532          ((looking-at "^renamed")
 533           (setq current-vc-state 'edited)
 534           (setq current-bzr-state 'renamed))
 535          ((looking-at "^ignored")
 536           (setq current-vc-state 'ignored)
 537           (setq current-bzr-state 'not-versioned))
 538          ((looking-at "^unknown")
 539           (setq current-vc-state 'unregistered)
 540           (setq current-bzr-state 'not-versioned))
 541          ((looking-at "  ")
 542           ;; file names are indented by two spaces
 543           (when current-vc-state
 544             (let ((file (expand-file-name
 545                          (buffer-substring-no-properties
 546                           (match-end 0) (line-end-position))
 547                          bzr-root-directory)))
 548               (vc-file-setprop file 'vc-state current-vc-state)
 549               (vc-file-setprop file 'vc-bzr-state current-bzr-state)
 550               (when (eq 'added current-bzr-state)
 551                 (vc-file-setprop file 'vc-working-revision "0"))))
 552           (when (eq 'not-versioned current-bzr-state)
 553             (let ((file (expand-file-name
 554                          (buffer-substring-no-properties
 555                           (match-end 0) (line-end-position))
 556                          bzr-root-directory)))
 557               (vc-file-setprop file 'vc-backend 'none)
 558               (vc-file-setprop file 'vc-state nil))))
 559          (t
 560           ;; skip this part of `bzr status' output
 561           (setq current-vc-state nil)
 562           (setq current-bzr-state nil)))))))
 563
 564 (defun vc-bzr-dired-state-info (file)
 565   "Bzr-specific version of `vc-dired-state-info'."
 566   (if (eq 'edited (vc-state file))
 567       (let ((bzr-state (vc-file-getprop file 'vc-bzr-state)))
 568         (if bzr-state
 569             (concat "(" (symbol-name bzr-state) ")")
 570           ;; else fall back to default vc representation
 571           (vc-default-dired-state-info 'Bzr file)))))
 572
 573 (eval-after-load "vc"
 574   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
 575
 576 (provide 'vc-bzr)
 577 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
 578 ;;; vc-bzr.el ends here