lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Authors: Roland McGrath <roland@gnu.org>,
   8 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   9 ;; Maintainer: FSF
  10 ;; Keywords: tools, processes
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This package provides the compile facilities documented in the Emacs user's
  30 ;; manual.
  31
  32 ;; This mode uses some complex data-structures:
  33
  34 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  35
  36 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  37 ;; LINE will be nil for a message that doesn't contain them.  Then the
  38 ;; location refers to a indented beginning of line or beginning of file.
  39 ;; Once any location in some file has been jumped to, the list is extended to
  40 ;; (COLUMN LINE FILE-STRUCTURE MARKER TIMESTAMP . VISITED)
  41 ;; for all LOCs pertaining to that file.
  42 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  43 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  44 ;; before that point.  VISITED is t if we have jumped there, else nil.
  45 ;; TIMESTAMP is necessary because of "incremental compilation": `omake -P'
  46 ;; polls filesystem for changes and recompiles when a file is modified
  47 ;; using the same *compilation* buffer. this necessitates re-parsing markers.
  48
  49 ;;   FILE-STRUCTURE is a list of
  50 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  51
  52 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  53 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  54 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  55 ;; a file of that name can't be found.
  56 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  57 ;; are either nil or line numbers.  If present, nil comes first, followed by
  58 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  59 ;; ordered the same way.  Note that the whole file structure is referenced in
  60 ;; every LOC.
  61
  62 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  63
  64 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  65 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  66 ;; other end, if the parsed message contained a range.  If the end of the
  67 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  68 ;; These are the value of the `message' text-properties in the compilation
  69 ;; buffer.
  70
  71 ;;; Code:
  72
  73 (eval-when-compile (require 'cl))
  74 (require 'tool-bar)
  75
  76 (defvar font-lock-extra-managed-props)
  77 (defvar font-lock-keywords)
  78 (defvar font-lock-maximum-size)
  79 (defvar font-lock-support-mode)
  80
  81
  82 (defgroup compilation nil
  83   "Run compiler as inferior of Emacs, parse error messages."
  84   :group 'tools
  85   :group 'processes)
  86
  87
  88 ;;;###autoload
  89 (defcustom compilation-mode-hook nil
  90   "List of hook functions run by `compilation-mode' (see `run-mode-hooks')."
  91   :type 'hook
  92   :group 'compilation)
  93
  94 ;;;###autoload
  95 (defcustom compilation-window-height nil
  96   "Number of lines in a compilation window.  If nil, use Emacs default."
  97   :type '(choice (const :tag "Default" nil)
  98                  integer)
  99   :group 'compilation)
 100
 101 (defvar compilation-first-column 1
 102   "*This is how compilers number the first column, usually 1 or 0.")
 103
 104 (defvar compilation-parse-errors-filename-function nil
 105   "Function to call to post-process filenames while parsing error messages.
 106 It takes one arg FILENAME which is the name of a file as found
 107 in the compilation output, and should return a transformed file name.")
 108
 109 ;;;###autoload
 110 (defvar compilation-process-setup-function nil
 111   "*Function to call to customize the compilation process.
 112 This function is called immediately before the compilation process is
 113 started.  It can be used to set any variables or functions that are used
 114 while processing the output of the compilation process.  The function
 115 is called with variables `compilation-buffer' and `compilation-window'
 116 bound to the compilation buffer and window, respectively.")
 117
 118 ;;;###autoload
 119 (defvar compilation-buffer-name-function nil
 120   "Function to compute the name of a compilation buffer.
 121 The function receives one argument, the name of the major mode of the
 122 compilation buffer.  It should return a string.
 123 If nil, compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 124
 125 ;;;###autoload
 126 (defvar compilation-finish-function nil
 127   "Function to call when a compilation process finishes.
 128 It is called with two arguments: the compilation buffer, and a string
 129 describing how the process finished.")
 130
 131 (make-obsolete-variable 'compilation-finish-function
 132   "use `compilation-finish-functions', but it works a little differently."
 133   "22.1")
 134
 135 ;;;###autoload
 136 (defvar compilation-finish-functions nil
 137   "Functions to call when a compilation process finishes.
 138 Each function is called with two arguments: the compilation buffer,
 139 and a string describing how the process finished.")
 140
 141 (defvar compilation-in-progress nil
 142   "List of compilation processes now running.")
 143 (or (assq 'compilation-in-progress minor-mode-alist)
 144     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 145                                  minor-mode-alist)))
 146
 147 (defvar compilation-error "error"
 148   "Stem of message to print when no matches are found.")
 149
 150 (defvar compilation-arguments nil
 151   "Arguments that were given to `compilation-start'.")
 152
 153 (defvar compilation-num-errors-found)
 154
 155 (defconst compilation-error-regexp-alist-alist
 156   '((absoft
 157      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 158 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 159
 160     (ada
 161      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 162
 163     (aix
 164      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 165
 166     (ant
 167      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 168 \\( warning\\)?" 1 2 3 (4))
 169
 170     (maven
 171      ;; Maven is a popular build tool for Java.  Maven is Free Software.
 172      "\\(.*?\\):\\[\\([0-9]+\\),\\([0-9]+\\)\\]" 1 2 3)
 173
 174     (bash
 175      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 176
 177     (borland
 178      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 179 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 180  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 181
 182     (caml
 183      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 184 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 185      2 (3 . 4) (5 . 6) (7))
 186
 187     (comma
 188      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 189 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 190
 191     (edg-1
 192      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 193      1 2 nil (3 . 4))
 194     (edg-2
 195      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 196      2 1 nil 0)
 197
 198     (epc
 199      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 200
 201     (ftnchek
 202      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 203      4 2 3 (1))
 204
 205     (iar
 206      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 207      1 2 nil (3))
 208
 209     (ibm
 210      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 211  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 212
 213     ;; fixme: should be `mips'
 214     (irix
 215      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 216 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 217
 218     (java
 219      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 220
 221     (jikes-file
 222      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 223     (jikes-line
 224      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 225      nil 1 nil 2 0
 226      (2 (compilation-face '(3))))
 227
 228     (gnu
 229      ;; I have no idea what this first line is supposed to match, but it
 230      ;; makes things ambiguous with output such as "foo:344:50:blabla" since
 231      ;; the "foo" part can match this first line (in which case the file
 232      ;; name as "344").  To avoid this, the second line disallows filenames
 233      ;; exclusively composed of digits.  --Stef
 234      ;; Similarly, we get lots of false positives with messages including
 235      ;; times of the form "HH:MM:SS" where MM is taken as a line number, so
 236      ;; the last line tries to rule out message where the info after the
 237      ;; line number starts with "SS".  --Stef
 238
 239      ;; The core of the regexp is the one with *?.  It says that a file name
 240      ;; can be composed of any non-newline char, but it also rules out some
 241      ;; valid but unlikely cases, such as a trailing space or a space
 242      ;; followed by a -.
 243      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 244 \\([0-9]*[^0-9\n]\\(?:[^\n ]\\| [^-/\n]\\)*?\\): ?\
 245 \\([0-9]+\\)\\(?:\\([.:]\\)\\([0-9]+\\)\\)?\
 246 \\(?:-\\([0-9]+\\)?\\(?:\\3\\([0-9]+\\)\\)?\\)?:\
 247 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 248  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\|instantiated from\\|[Nn]ote\\)\\|\
 249 \[0-9]?\\(?:[^0-9\n]\\|$\\)\\|[0-9][0-9][0-9]\\)"
 250      1 (2 . 5) (4 . 6) (7 . 8))
 251
 252     ;; The `gnu' style above can incorrectly match gcc's "In file
 253     ;; included from" message, so we process that first. -- cyd
 254     (gcc-include
 255      "^\\(?:In file included\\|                \\) from \
 256 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 257
 258     (lcc
 259      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 260      2 3 4 (1))
 261
 262     (makepp
 263      "^makepp\\(?:\\(?:: warning\\(:\\).*?\\|\\(: Scanning\\|: [LR]e?l?oading makefile\\|: Imported\\|log:.*?\\) \\|: .*?\\)\
 264 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]\\)"
 265      4 5 nil (1 . 2) 3
 266      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]" nil nil
 267       (2 compilation-info-face)
 268       (3 compilation-line-face nil t)
 269       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 270          append)))
 271
 272     ;; Should be lint-1, lint-2 (SysV lint)
 273     (mips-1
 274      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 275     (mips-2
 276      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 277
 278     (msft
 279      ;; AFAWK, The message may be a "warning", "error", or "fatal error".
 280      "^\\([0-9]+>\\)?\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 281 : \\(?:warnin\\(g\\)\\|[a-z ]+\\) C[0-9]+:" 2 3 nil (4))
 282
 283     (oracle
 284      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 285 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 286 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 287      3 1 2)
 288
 289     ;; "during global destruction": This comes out under "use
 290     ;; warnings" in recent perl when breaking circular references
 291     ;; during program or thread exit.
 292     (perl
 293      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\| \
 294 during global destruction\\.$\\)" 1 2)
 295
 296     (php
 297      "\\(?:Parse\\|Fatal\\) error: \\(.*\\) in \\(.*\\) on line \\([0-9]+\\)"
 298      2 3 nil nil)
 299
 300     (rxp
 301      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 302  \\([0-9]+\\) of file://\\(.+\\)"
 303      4 2 3 (1))
 304
 305     (sparc-pascal-file
 306      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 307  [12][09][0-9][0-9] +\\(.*\\):$"
 308      1 nil nil 0)
 309     (sparc-pascal-line
 310      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 311      nil 3 nil (2) nil (1 (compilation-face '(2))))
 312     (sparc-pascal-example
 313      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 314      nil 1 nil (3) nil (2 (compilation-face '(3))))
 315
 316     (sun
 317      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 318 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 319      3 4 5 (1 . 2))
 320
 321     (sun-ada
 322      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 323
 324     (watcom
 325      "\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)): ?\
 326 \\(?:\\(Error! E[0-9]+\\)\\|\\(Warning! W[0-9]+\\)\\):"
 327      1 2 nil (4))
 328
 329     (4bsd
 330      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 331 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 332
 333     (gcov-file
 334      "^ *-: *\\(0\\):Source:\\(.+\\)$"
 335      2 1 nil 0 nil
 336      (1 compilation-line-face prepend) (2 compilation-info-face prepend))
 337     (gcov-header
 338      "^ *-: *\\(0\\):\\(?:Object\\|Graph\\|Data\\|Runs\\|Programs\\):.+$"
 339      nil 1 nil 0 nil
 340      (1 compilation-line-face prepend))
 341     ;; Underlines over all lines of gcov output are too uncomfortable to read.
 342     ;; However, hyperlinks embedded in the lines are useful.
 343     ;; So I put default face on the lines; and then put
 344     ;; compilation-*-face by manually to eliminate the underlines.
 345     ;; The hyperlinks are still effective.
 346     (gcov-nomark
 347      "^ *-: *\\([1-9]\\|[0-9]\\{2,\\}\\):.*$"
 348      nil 1 nil 0 nil
 349      (0 'default t)
 350      (1 compilation-line-face prepend))
 351     (gcov-called-line
 352      "^ *\\([0-9]+\\): *\\([0-9]+\\):.*$"
 353      nil 2 nil 0 nil
 354      (0 'default t)
 355      (1 compilation-info-face prepend) (2 compilation-line-face prepend))
 356     (gcov-never-called
 357      "^ *\\(#####\\): *\\([0-9]+\\):.*$"
 358      nil 2 nil 2 nil
 359      (0 'default t)
 360      (1 compilation-error-face prepend) (2 compilation-line-face prepend))
 361
 362     (perl--Pod::Checker
 363      ;; podchecker error messages, per Pod::Checker.
 364      ;; The style is from the Pod::Checker::poderror() function, eg.
 365      ;; *** ERROR: Spurious text after =cut at line 193 in file foo.pm
 366      ;;
 367      ;; Plus end_pod() can give "at line EOF" instead of a
 368      ;; number, so for that match "on line N" which is the
 369      ;; originating spot, eg.
 370      ;; *** ERROR: =over on line 37 without closing =back at line EOF in file bar.pm
 371      ;;
 372      ;; Plus command() can give both "on line N" and "at line N";
 373      ;; the latter is desired and is matched because the .* is
 374      ;; greedy.
 375      ;; *** ERROR: =over on line 1 without closing =back (at head1) at line 3 in file x.pod
 376      ;;
 377      "^\\*\\*\\* \\(?:ERROR\\|\\(WARNING\\)\\).* \\(?:at\\|on\\) line \
 378 \\([0-9]+\\) \\(?:.* \\)?in file \\([^ \t\n]+\\)"
 379      3 2 nil (1))
 380     (perl--Test
 381      ;; perl Test module error messages.
 382      ;; Style per the ok() function "$context", eg.
 383      ;; # Failed test 1 in foo.t at line 6
 384      ;;
 385      "^# Failed test [0-9]+ in \\([^ \t\r\n]+\\) at line \\([0-9]+\\)"
 386      1 2)
 387     (perl--Test2
 388      ;; Or when comparing got/want values,
 389      ;; # Test 2 got: "xx" (t-compilation-perl-2.t at line 10)
 390      ;;
 391      ;; And under Test::Harness they're preceded by progress stuff with
 392      ;; \r and "NOK",
 393      ;; ... NOK 1# Test 1 got: "1234" (t/foo.t at line 46)
 394      ;;
 395      "^\\(.*NOK.*\\)?# Test [0-9]+ got:.* (\\([^ \t\r\n]+\\) at line \
 396 \\([0-9]+\\))"
 397      2 3)
 398     (perl--Test::Harness
 399      ;; perl Test::Harness output, eg.
 400      ;; NOK 1# Test 1 got: "1234" (t/foo.t at line 46)
 401      ;;
 402      ;; Test::Harness is slightly designed for tty output, since
 403      ;; it prints CRs to overwrite progress messages, but if you
 404      ;; run it in with M-x compile this pattern can at least step
 405      ;; through the failures.
 406      ;;
 407      "^.*NOK.* \\([^ \t\r\n]+\\) at line \\([0-9]+\\)"
 408      1 2)
 409     (weblint
 410      ;; The style comes from HTML::Lint::Error::as_string(), eg.
 411      ;; index.html (13:1) Unknown element <fdjsk>
 412      ;;
 413      ;; The pattern only matches filenames without spaces, since that
 414      ;; should be usual and should help reduce the chance of a false
 415      ;; match of a message from some unrelated program.
 416      ;;
 417      ;; This message style is quite close to the "ibm" entry which is
 418      ;; for IBM C, though that ibm bit doesn't put a space after the
 419      ;; filename.
 420      ;;
 421      "^\\([^ \t\r\n(]+\\) (\\([0-9]+\\):\\([0-9]+\\)) "
 422      1 2 3)
 423     )
 424   "Alist of values for `compilation-error-regexp-alist'.")
 425
 426 (defcustom compilation-error-regexp-alist
 427   (mapcar 'car compilation-error-regexp-alist-alist)
 428   "Alist that specifies how to match errors in compiler output.
 429 On GNU and Unix, any string is a valid filename, so these
 430 matchers must make some common sense assumptions, which catch
 431 normal cases.  A shorter list will be lighter on resource usage.
 432
 433 Instead of an alist element, you can use a symbol, which is
 434 looked up in `compilation-error-regexp-alist-alist'.  You can see
 435 the predefined symbols and their effects in the file
 436 `etc/compilation.txt' (linked below if you are customizing this).
 437
 438 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 439 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 440 gives the file name, and the LINE'th subexpression gives the line
 441 number.  The COLUMN'th subexpression gives the column number on
 442 that line.
 443
 444 If FILE, LINE or COLUMN are nil or that index didn't match, that
 445 information is not present on the matched line.  In that case the
 446 file name is assumed to be the same as the previous one in the
 447 buffer, line number defaults to 1 and column defaults to
 448 beginning of line's indentation.
 449
 450 FILE can also have the form (FILE FORMAT...), where the FORMATs
 451 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 452 name, until a file of that name is found.  Or FILE can also be a
 453 function that returns (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
 454 In the former case, FILENAME may be relative or absolute.
 455
 456 LINE can also be of the form (LINE . END-LINE) meaning a range
 457 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 458 meaning a range of columns starting on LINE and ending on
 459 END-LINE, if that matched.
 460
 461 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 462 TYPE can also be of the form (WARNING . INFO).  In that case this
 463 will be equivalent to 1 if the WARNING'th subexpression matched
 464 or else equivalent to 0 if the INFO'th subexpression matched.
 465 See `compilation-error-face', `compilation-warning-face',
 466 `compilation-info-face' and `compilation-skip-threshold'.
 467
 468 What matched the HYPERLINK'th subexpression has `mouse-face' and
 469 `compilation-message-face' applied.  If this is nil, the text
 470 matched by the whole REGEXP becomes the hyperlink.
 471
 472 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 473 be added."
 474   :type `(set :menu-tag "Pick"
 475               ,@(mapcar (lambda (elt)
 476                           (list 'const (car elt)))
 477                         compilation-error-regexp-alist-alist))
 478   :link `(file-link :tag "example file"
 479                     ,(expand-file-name "compilation.txt" data-directory))
 480   :group 'compilation)
 481
 482 ;;;###autoload(put 'compilation-directory 'safe-local-variable 'stringp)
 483 (defvar compilation-directory nil
 484   "Directory to restore to when doing `recompile'.")
 485
 486 (defvar compilation-directory-matcher
 487   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 488   "A list for tracking when directories are entered or left.
 489 If nil, do not track directories, e.g. if all file names are absolute.  The
 490 first element is the REGEXP matching these messages.  It can match any number
 491 of variants, e.g. different languages.  The remaining elements are all of the
 492 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 493 matches, that is a directory name.  If LEAVE is nil or the corresponding
 494 LEAVE'th subexpression doesn't match, this message is about going into another
 495 directory.  If it does match anything, this message is about going back to the
 496 directory we were in before the last entering message.  If you change this,
 497 you may also want to change `compilation-page-delimiter'.")
 498
 499 (defvar compilation-page-delimiter
 500   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 501   "Value of `page-delimiter' in Compilation mode.")
 502
 503 (defvar compilation-mode-font-lock-keywords
 504    '(;; configure output lines.
 505      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 506       (1 font-lock-variable-name-face)
 507       (2 (compilation-face '(4 . 3))))
 508      ;; Command output lines.  Recognize `make[n]:' lines too.
 509      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 510       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 511      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 512      ("^Compilation \\(finished\\).*"
 513       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 514       (1 compilation-info-face))
 515      ("^Compilation \\(exited abnormally\\|interrupt\\|killed\\|terminated\\|segmentation fault\\)\\(?:.*with code \\([0-9]+\\)\\)?.*"
 516       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 517       (1 compilation-error-face)
 518       (2 compilation-error-face nil t)))
 519    "Additional things to highlight in Compilation mode.
 520 This gets tacked on the end of the generated expressions.")
 521
 522 (defvar compilation-highlight-regexp t
 523   "Regexp matching part of visited source lines to highlight temporarily.
 524 Highlight entire line if t; don't highlight source lines if nil.")
 525
 526 (defvar compilation-highlight-overlay nil
 527   "Overlay used to temporarily highlight compilation matches.")
 528
 529 (defcustom compilation-error-screen-columns t
 530   "If non-nil, column numbers in error messages are screen columns.
 531 Otherwise they are interpreted as character positions, with
 532 each character occupying one column.
 533 The default is to use screen columns, which requires that the compilation
 534 program and Emacs agree about the display width of the characters,
 535 especially the TAB character."
 536   :type 'boolean
 537   :group 'compilation
 538   :version "20.4")
 539
 540 (defcustom compilation-read-command t
 541   "Non-nil means \\[compile] reads the compilation command to use.
 542 Otherwise, \\[compile] just uses the value of `compile-command'."
 543   :type 'boolean
 544   :group 'compilation)
 545
 546 ;;;###autoload
 547 (defcustom compilation-ask-about-save t
 548   "Non-nil means \\[compile] asks which buffers to save before compiling.
 549 Otherwise, it saves all modified buffers without asking."
 550   :type 'boolean
 551   :group 'compilation)
 552
 553 ;;;###autoload
 554 (defcustom compilation-search-path '(nil)
 555   "List of directories to search for source files named in error messages.
 556 Elements should be directory names, not file names of directories.
 557 The value nil as an element means to try the default directory."
 558   :type '(repeat (choice (const :tag "Default" nil)
 559                          (string :tag "Directory")))
 560   :group 'compilation)
 561
 562 ;;;###autoload
 563 (defcustom compile-command "make -k "
 564   "Last shell command used to do a compilation; default for next compilation.
 565
 566 Sometimes it is useful for files to supply local values for this variable.
 567 You might also use mode hooks to specify it in certain modes, like this:
 568
 569     (add-hook 'c-mode-hook
 570        (lambda ()
 571          (unless (or (file-exists-p \"makefile\")
 572                      (file-exists-p \"Makefile\"))
 573            (set (make-local-variable 'compile-command)
 574                 (concat \"make -k \"
 575                         (file-name-sans-extension buffer-file-name))))))"
 576   :type 'string
 577   :group 'compilation)
 578 ;;;###autoload(put 'compile-command 'safe-local-variable 'stringp)
 579
 580 ;;;###autoload
 581 (defcustom compilation-disable-input nil
 582   "If non-nil, send end-of-file as compilation process input.
 583 This only affects platforms that support asynchronous processes (see
 584 `start-process'); synchronous compilation processes never accept input."
 585   :type 'boolean
 586   :group 'compilation
 587   :version "22.1")
 588
 589 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 590 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 591 ;; key.  This holds the tree seen from root, for storing new nodes.
 592 (defvar compilation-locs ())
 593
 594 (defvar compilation-debug nil
 595   "*Set this to t before creating a *compilation* buffer.
 596 Then every error line will have a debug text property with the matcher that
 597 fit this line and the match data.  Use `describe-text-properties'.")
 598
 599 (defvar compilation-exit-message-function nil "\
 600 If non-nil, called when a compilation process dies to return a status message.
 601 This should be a function of three arguments: process status, exit status,
 602 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 603 write into the compilation buffer, and to put in its mode line.")
 604
 605 (defvar compilation-environment nil
 606   "*List of environment variables for compilation to inherit.
 607 Each element should be a string of the form ENVVARNAME=VALUE.
 608 This list is temporarily prepended to `process-environment' prior to
 609 starting the compilation process.")
 610
 611 ;; History of compile commands.
 612 (defvar compile-history nil)
 613
 614 (defface compilation-error
 615   '((t :inherit font-lock-warning-face))
 616   "Face used to highlight compiler errors."
 617   :group 'compilation
 618   :version "22.1")
 619
 620 (defface compilation-warning
 621   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 622     (((class color)) (:foreground "cyan" :weight bold))
 623     (t (:weight bold)))
 624   "Face used to highlight compiler warnings."
 625   :group 'compilation
 626   :version "22.1")
 627
 628 (defface compilation-info
 629   '((((class color) (min-colors 16) (background light))
 630      (:foreground "Green3" :weight bold))
 631     (((class color) (min-colors 88) (background dark))
 632      (:foreground "Green1" :weight bold))
 633     (((class color) (min-colors 16) (background dark))
 634      (:foreground "Green" :weight bold))
 635     (((class color)) (:foreground "green" :weight bold))
 636     (t (:weight bold)))
 637   "Face used to highlight compiler information."
 638   :group 'compilation
 639   :version "22.1")
 640
 641 (defface compilation-line-number
 642   '((t :inherit font-lock-variable-name-face))
 643   "Face for displaying line numbers in compiler messages."
 644   :group 'compilation
 645   :version "22.1")
 646
 647 (defface compilation-column-number
 648   '((t :inherit font-lock-type-face))
 649   "Face for displaying column numbers in compiler messages."
 650   :group 'compilation
 651   :version "22.1")
 652
 653 (defcustom compilation-message-face 'underline
 654   "Face name to use for whole messages.
 655 Faces `compilation-error-face', `compilation-warning-face',
 656 `compilation-info-face', `compilation-line-face' and
 657 `compilation-column-face' get prepended to this, when applicable."
 658   :type 'face
 659   :group 'compilation
 660   :version "22.1")
 661
 662 (defvar compilation-error-face 'compilation-error
 663   "Face name to use for file name in error messages.")
 664
 665 (defvar compilation-warning-face 'compilation-warning
 666   "Face name to use for file name in warning messages.")
 667
 668 (defvar compilation-info-face 'compilation-info
 669   "Face name to use for file name in informational messages.")
 670
 671 (defvar compilation-line-face 'compilation-line-number
 672   "Face name to use for line numbers in compiler messages.")
 673
 674 (defvar compilation-column-face 'compilation-column-number
 675   "Face name to use for column numbers in compiler messages.")
 676
 677 ;; same faces as dired uses
 678 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 679   "Face name to use for entering directory messages.")
 680
 681 (defvar compilation-leave-directory-face 'font-lock-type-face
 682   "Face name to use for leaving directory messages.")
 683
 684
 685
 686 ;; Used for compatibility with the old compile.el.
 687 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 688 (defvar compilation-parsing-end (make-marker))
 689 (defvar compilation-parse-errors-function nil)
 690 (defvar compilation-error-list nil)
 691 (defvar compilation-old-error-list nil)
 692
 693 (defcustom compilation-auto-jump-to-first-error nil
 694   "If non-nil, automatically jump to the first error after `compile'."
 695   :type 'boolean
 696   :group 'compilation
 697   :version "23.1")
 698
 699 (defvar compilation-auto-jump-to-next nil
 700   "If non-nil, automatically jump to the next error encountered.")
 701 (make-variable-buffer-local 'compilation-auto-jump-to-next)
 702
 703
 704 (defvar compilation-skip-to-next-location t
 705   "*If non-nil, skip multiple error messages for the same source location.")
 706
 707 (defcustom compilation-skip-threshold 1
 708   "Compilation motion commands skip less important messages.
 709 The value can be either 2 -- skip anything less than error, 1 --
 710 skip anything less than warning or 0 -- don't skip any messages.
 711 Note that all messages not positively identified as warning or
 712 info, are considered errors."
 713   :type '(choice (const :tag "Warnings and info" 2)
 714                  (const :tag "Info" 1)
 715                  (const :tag "None" 0))
 716   :group 'compilation
 717   :version "22.1")
 718
 719 (defcustom compilation-skip-visited nil
 720   "Compilation motion commands skip visited messages if this is t.
 721 Visited messages are ones for which the file, line and column have been jumped
 722 to from the current content in the current compilation buffer, even if it was
 723 from a different message."
 724   :type 'boolean
 725   :group 'compilation
 726   :version "22.1")
 727
 728 (defun compilation-face (type)
 729   (or (and (car type) (match-end (car type)) compilation-warning-face)
 730       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 731       compilation-error-face))
 732
 733 ;; Internal function for calculating the text properties of a directory
 734 ;; change message.  The directory property is important, because it is
 735 ;; the stack of nested enter-messages.  Relative filenames on the following
 736 ;; lines are relative to the top of the stack.
 737 (defun compilation-directory-properties (idx leave)
 738   (if leave (setq leave (match-end leave)))
 739   ;; find previous stack, and push onto it, or if `leave' pop it
 740   (let ((dir (previous-single-property-change (point) 'directory)))
 741     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 742                           (get-text-property dir 'directory))))
 743     `(face ,(if leave
 744                 compilation-leave-directory-face
 745               compilation-enter-directory-face)
 746       directory ,(if leave
 747                      (or (cdr dir)
 748                          '(nil))        ; nil only isn't a property-change
 749                    (cons (match-string-no-properties idx) dir))
 750       mouse-face highlight
 751       keymap compilation-button-map
 752       help-echo "mouse-2: visit destination directory")))
 753
 754 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 755 ;; KEY element from the ALIST, creating it in the right position if not already
 756 ;; present. ALIST structure is
 757 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 758 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 759 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 760 ;; numbers can be inserted in front and searching can abort after half the
 761 ;; list on average.
 762 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 763 (defmacro compilation-assq (key alist)
 764   `(let* ((l1 ,alist)
 765           (l2 (cdr l1)))
 766      (car (if (if (null ,key)
 767                   (if l2 (null (caar l2)))
 768                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 769                   (setq l1 l2
 770                         l2 (cdr l1)))
 771                 (if l2 (eq ,key (caar l2))))
 772               l2
 773             (setcdr l1 (cons (list ,key) l2)))))))
 774
 775 (defun compilation-auto-jump (buffer pos)
 776   (with-current-buffer buffer
 777     (goto-char pos)
 778     (let ((win (get-buffer-window buffer 0)))
 779       (if win (set-window-point win pos)))
 780     (if compilation-auto-jump-to-first-error
 781         (compile-goto-error))))
 782
 783 ;; This function is the central driver, called when font-locking to gather
 784 ;; all information needed to later jump to corresponding source code.
 785 ;; Return a property list with all meta information on this error location.
 786
 787 (defun compilation-error-properties (file line end-line col end-col type fmt)
 788   (unless (< (next-single-property-change (match-beginning 0)
 789                                           'directory nil (point))
 790              (point))
 791     (if file
 792         (if (functionp file)
 793             (setq file (funcall file))
 794           (let (dir)
 795             (setq file (match-string-no-properties file))
 796             (unless (file-name-absolute-p file)
 797               (setq dir (previous-single-property-change (point) 'directory)
 798                     dir (if dir (or (get-text-property (1- dir) 'directory)
 799                                     (get-text-property dir 'directory)))))
 800             (setq file (cons file (car dir)))))
 801       ;; This message didn't mention one, get it from previous
 802       (let ((prev-pos
 803              ;; Find the previous message.
 804              (previous-single-property-change (point) 'message)))
 805         (if prev-pos
 806             ;; Get the file structure that belongs to it.
 807             (let* ((prev
 808                     (or (get-text-property (1- prev-pos) 'message)
 809                         (get-text-property prev-pos 'message)))
 810                    (prev-struct
 811                     (car (nth 2 (car prev)))))
 812               ;; Construct FILE . DIR from that.
 813               (if prev-struct
 814                   (setq file (cons (car prev-struct)
 815                                    (cadr prev-struct))))))
 816         (unless file
 817           (setq file '("*unknown*")))))
 818     ;; All of these fields are optional, get them only if we have an index, and
 819     ;; it matched some part of the message.
 820     (and line
 821          (setq line (match-string-no-properties line))
 822          (setq line (string-to-number line)))
 823     (and end-line
 824          (setq end-line (match-string-no-properties end-line))
 825          (setq end-line (string-to-number end-line)))
 826     (if col
 827         (if (functionp col)
 828             (setq col (funcall col))
 829           (and
 830            (setq col (match-string-no-properties col))
 831            (setq col (- (string-to-number col) compilation-first-column)))))
 832     (if (and end-col (functionp end-col))
 833         (setq end-col (funcall end-col))
 834       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 835           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 836         (if end-line (setq end-col -1))))
 837     (if (consp type)                    ; not a static type, check what it is.
 838         (setq type (or (and (car type) (match-end (car type)) 1)
 839                        (and (cdr type) (match-end (cdr type)) 0)
 840                        2)))
 841
 842     (when (and compilation-auto-jump-to-next
 843                (>= type compilation-skip-threshold))
 844       (kill-local-variable 'compilation-auto-jump-to-next)
 845       (run-with-timer 0 nil 'compilation-auto-jump
 846                       (current-buffer) (match-beginning 0)))
 847
 848     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 849
 850 (defun compilation-move-to-column (col screen)
 851   "Go to column COL on the current line.
 852 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 853 just char-counts."
 854   (if screen
 855       (move-to-column col)
 856     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 857
 858 (defun compilation-internal-error-properties (file line end-line col end-col type fmts)
 859   "Get the meta-info that will be added as text-properties.
 860 LINE, END-LINE, COL, END-COL are integers or nil.
 861 TYPE can be 0, 1, or 2, meaning error, warning, or just info.
 862 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil.
 863 FMTS is a list of format specs for transforming the file name.
 864  (See `compilation-error-regexp-alist'.)"
 865   (unless file (setq file '("*unknown*")))
 866   (let* ((file-struct (compilation-get-file-structure file fmts))
 867          ;; Get first already existing marker (if any has one, all have one).
 868          ;; Do this first, as the compilation-assq`s may create new nodes.
 869          (marker-line (car (cddr file-struct))) ; a line structure
 870          (marker (nth 3 (cadr marker-line)))    ; its marker
 871          (compilation-error-screen-columns compilation-error-screen-columns)
 872          end-marker loc end-loc)
 873     (if (not (and marker (marker-buffer marker)))
 874         (setq marker nil)               ; no valid marker for this file
 875       (setq loc (or line 1))            ; normalize no linenumber to line 1
 876       (catch 'marker                    ; find nearest loc, at least one exists
 877         (dolist (x (nthcdr 3 file-struct))      ; loop over remaining lines
 878           (if (> (car x) loc)           ; still bigger
 879               (setq marker-line x)
 880             (if (> (- (or (car marker-line) 1) loc)
 881                    (- loc (car x)))     ; current line is nearer
 882                 (setq marker-line x))
 883             (throw 'marker t))))
 884       (setq marker (nth 3 (cadr marker-line))
 885             marker-line (or (car marker-line) 1))
 886       (with-current-buffer (marker-buffer marker)
 887         (save-excursion
 888           (save-restriction
 889             (widen)
 890             (goto-char (marker-position marker))
 891             (when (or end-col end-line)
 892               (beginning-of-line (- (or end-line line) marker-line -1))
 893               (if (or (null end-col) (< end-col 0))
 894                   (end-of-line)
 895                 (compilation-move-to-column
 896                  end-col compilation-error-screen-columns))
 897               (setq end-marker (list (point-marker))))
 898             (beginning-of-line (if end-line
 899                                    (- line end-line -1)
 900                                  (- loc marker-line -1)))
 901             (if col
 902                 (compilation-move-to-column
 903                  col compilation-error-screen-columns)
 904               (forward-to-indentation 0))
 905             (setq marker (list (point-marker)))))))
 906
 907     (setq loc (compilation-assq line (cdr file-struct)))
 908     (if end-line
 909         (setq end-loc (compilation-assq end-line (cdr file-struct))
 910               end-loc (compilation-assq end-col end-loc))
 911       (if end-col                       ; use same line element
 912           (setq end-loc (compilation-assq end-col loc))))
 913     (setq loc (compilation-assq col loc))
 914     ;; If they are new, make the loc(s) reference the file they point to.
 915     (or (cdr loc) (setcdr loc `(,line ,file-struct ,@marker)))
 916     (if end-loc
 917         (or (cdr end-loc)
 918             (setcdr end-loc `(,(or end-line line) ,file-struct ,@end-marker))))
 919
 920     ;; Must start with face
 921     `(face ,compilation-message-face
 922            message (,loc ,type ,end-loc)
 923            ,@(if compilation-debug
 924                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 925                           ,@(match-data))))
 926            help-echo ,(if col
 927                           "mouse-2: visit this file, line and column"
 928                         (if line
 929                             "mouse-2: visit this file and line"
 930                           "mouse-2: visit this file"))
 931            keymap compilation-button-map
 932            mouse-face highlight)))
 933
 934 (defun compilation-mode-font-lock-keywords ()
 935   "Return expressions to highlight in Compilation mode."
 936   (if compilation-parse-errors-function
 937       ;; An old package!  Try the compatibility code.
 938       '((compilation-compat-parse-errors))
 939     (append
 940      ;; make directory tracking
 941      (if compilation-directory-matcher
 942          `((,(car compilation-directory-matcher)
 943             ,@(mapcar (lambda (elt)
 944                         `(,(car elt)
 945                           (compilation-directory-properties
 946                            ,(car elt) ,(cdr elt))
 947                           t t))
 948                       (cdr compilation-directory-matcher)))))
 949
 950      ;; Compiler warning/error lines.
 951      (mapcar
 952       (lambda (item)
 953         (if (symbolp item)
 954             (setq item (cdr (assq item
 955                                   compilation-error-regexp-alist-alist))))
 956         (let ((file (nth 1 item))
 957               (line (nth 2 item))
 958               (col (nth 3 item))
 959               (type (nth 4 item))
 960               end-line end-col fmt)
 961           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 962           (if (consp line)      (setq end-line (cdr line) line (car line)))
 963           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 964
 965           (if (functionp line)
 966               ;; The old compile.el had here an undocumented hook that
 967               ;; allowed `line' to be a function that computed the actual
 968               ;; error location.  Let's do our best.
 969               `(,(car item)
 970                 (0 (save-match-data
 971                      (compilation-compat-error-properties
 972                       (funcall ',line (cons (match-string ,file)
 973                                             (cons default-directory
 974                                                   ',(nthcdr 4 item)))
 975                                ,(if col `(match-string ,col))))))
 976                 (,file compilation-error-face t))
 977
 978             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 979               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 980
 981             `(,(nth 0 item)
 982
 983               ,@(when (integerp file)
 984                   `((,file ,(if (consp type)
 985                                 `(compilation-face ',type)
 986                               (aref [compilation-info-face
 987                                      compilation-warning-face
 988                                      compilation-error-face]
 989                                     (or type 2))))))
 990
 991               ,@(when line
 992                   `((,line compilation-line-face nil t)))
 993               ,@(when end-line
 994                   `((,end-line compilation-line-face nil t)))
 995
 996               ,@(when (integerp col)
 997                   `((,col compilation-column-face nil t)))
 998               ,@(when (integerp end-col)
 999                   `((,end-col compilation-column-face nil t)))
1000
1001               ,@(nthcdr 6 item)
1002               (,(or (nth 5 item) 0)
1003                (compilation-error-properties ',file ,line ,end-line
1004                                              ,col ,end-col ',(or type 2)
1005                                              ',fmt)
1006                append)))))              ; for compilation-message-face
1007       compilation-error-regexp-alist)
1008
1009      compilation-mode-font-lock-keywords)))
1010
1011 \f
1012 ;;;###autoload
1013 (defun compile (command &optional comint)
1014   "Compile the program including the current buffer.  Default: run `make'.
1015 Runs COMMAND, a shell command, in a separate process asynchronously
1016 with output going to the buffer `*compilation*'.
1017
1018 You can then use the command \\[next-error] to find the next error message
1019 and move to the source code that caused it.
1020
1021 If optional second arg COMINT is t the buffer will be in Comint mode with
1022 `compilation-shell-minor-mode'.
1023
1024 Interactively, prompts for the command if `compilation-read-command' is
1025 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
1026 Additionally, with universal prefix arg, compilation buffer will be in
1027 comint mode, i.e. interactive.
1028
1029 To run more than one compilation at once, start one then rename
1030 the \`*compilation*' buffer to some other name with
1031 \\[rename-buffer].  Then _switch buffers_ and start the new compilation.
1032 It will create a new \`*compilation*' buffer.
1033
1034 On most systems, termination of the main compilation process
1035 kills its subprocesses.
1036
1037 The name used for the buffer is actually whatever is returned by
1038 the function in `compilation-buffer-name-function', so you can set that
1039 to a function that generates a unique name."
1040   (interactive
1041    (list
1042     (let ((command (eval compile-command)))
1043       (if (or compilation-read-command current-prefix-arg)
1044           (read-shell-command "Compile command: " command
1045                               (if (equal (car compile-history) command)
1046                                   '(compile-history . 1)
1047                                 'compile-history))
1048         command))
1049     (consp current-prefix-arg)))
1050   (unless (equal command (eval compile-command))
1051     (setq compile-command command))
1052   (save-some-buffers (not compilation-ask-about-save) nil)
1053   (setq-default compilation-directory default-directory)
1054   (compilation-start command comint))
1055
1056 ;; run compile with the default command line
1057 (defun recompile ()
1058   "Re-compile the program including the current buffer.
1059 If this is run in a Compilation mode buffer, re-use the arguments from the
1060 original use.  Otherwise, recompile using `compile-command'."
1061   (interactive)
1062   (save-some-buffers (not compilation-ask-about-save) nil)
1063   (let ((default-directory (or compilation-directory default-directory)))
1064     (apply 'compilation-start (or compilation-arguments
1065                                   `(,(eval compile-command))))))
1066
1067 (defcustom compilation-scroll-output nil
1068   "Non-nil to scroll the *compilation* buffer window as output appears.
1069
1070 Setting it causes the Compilation mode commands to put point at the
1071 end of their output window so that the end of the output is always
1072 visible rather than the beginning.
1073
1074 The value `first-error' stops scrolling at the first error, and leaves
1075 point on its location in the *compilation* buffer."
1076   :type '(choice (const :tag "No scrolling" nil)
1077                  (const :tag "Scroll compilation output" t)
1078                  (const :tag "Stop scrolling at the first error" first-error))
1079   :version "20.3"
1080   :group 'compilation)
1081
1082
1083 (defun compilation-buffer-name (mode-name mode-command name-function)
1084   "Return the name of a compilation buffer to use.
1085 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
1086 to determine the buffer name.
1087 Likewise if `compilation-buffer-name-function' is non-nil.
1088 If current buffer has the major mode MODE-COMMAND,
1089 return the name of the current buffer, so that it gets reused.
1090 Otherwise, construct a buffer name from MODE-NAME."
1091   (cond (name-function
1092          (funcall name-function mode-name))
1093         (compilation-buffer-name-function
1094          (funcall compilation-buffer-name-function mode-name))
1095         ((eq mode-command major-mode)
1096          (buffer-name))
1097         (t
1098          (concat "*" (downcase mode-name) "*"))))
1099
1100 ;; This is a rough emulation of the old hack, until the transition to new
1101 ;; compile is complete.
1102 (defun compile-internal (command error-message
1103                                  &optional name-of-mode parser
1104                                  error-regexp-alist name-function
1105                                  enter-regexp-alist leave-regexp-alist
1106                                  file-regexp-alist nomessage-regexp-alist
1107                                  no-async highlight-regexp local-map)
1108   (if parser
1109       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
1110   (let ((compilation-error-regexp-alist
1111          (append file-regexp-alist (or error-regexp-alist
1112                                        compilation-error-regexp-alist)))
1113         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
1114                                                      "\\1" error-message)))
1115     (compilation-start command nil name-function highlight-regexp)))
1116 (make-obsolete 'compile-internal 'compilation-start "22.1")
1117
1118 ;;;###autoload
1119 (defun compilation-start (command &optional mode name-function highlight-regexp)
1120   "Run compilation command COMMAND (low level interface).
1121 If COMMAND starts with a cd command, that becomes the `default-directory'.
1122 The rest of the arguments are optional; for them, nil means use the default.
1123
1124 MODE is the major mode to set in the compilation buffer.  Mode
1125 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
1126
1127 If NAME-FUNCTION is non-nil, call it with one argument (the mode name)
1128 to determine the buffer name.  Otherwise, the default is to
1129 reuses the current buffer if it has the proper major mode,
1130 else use or create a buffer with name based on the major mode.
1131
1132 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
1133 the matching section of the visited source line; the default is to use the
1134 global value of `compilation-highlight-regexp'.
1135
1136 Returns the compilation buffer created."
1137   (or mode (setq mode 'compilation-mode))
1138   (let* ((name-of-mode
1139           (if (eq mode t)
1140               (prog1 "compilation" (require 'comint))
1141             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
1142          (thisdir default-directory)
1143          outwin outbuf)
1144     (with-current-buffer
1145         (setq outbuf
1146               (get-buffer-create
1147                (compilation-buffer-name name-of-mode mode name-function)))
1148       (let ((comp-proc (get-buffer-process (current-buffer))))
1149         (if comp-proc
1150             (if (or (not (eq (process-status comp-proc) 'run))
1151                     (yes-or-no-p
1152                      (format "A %s process is running; kill it? "
1153                              name-of-mode)))
1154                 (condition-case ()
1155                     (progn
1156                       (interrupt-process comp-proc)
1157                       (sit-for 1)
1158                       (delete-process comp-proc))
1159                   (error nil))
1160               (error "Cannot have two processes in `%s' at once"
1161                      (buffer-name)))))
1162       (buffer-disable-undo (current-buffer))
1163       ;; first transfer directory from where M-x compile was called
1164       (setq default-directory thisdir)
1165       ;; Make compilation buffer read-only.  The filter can still write it.
1166       ;; Clear out the compilation buffer.
1167       (let ((inhibit-read-only t)
1168             (default-directory thisdir))
1169         ;; Then evaluate a cd command if any, but don't perform it yet, else
1170         ;; start-command would do it again through the shell: (cd "..") AND
1171         ;; sh -c "cd ..; make"
1172         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
1173                 (if (match-end 1)
1174                     (substitute-env-vars (match-string 1 command))
1175                   "~")
1176               default-directory))
1177         (erase-buffer)
1178         ;; Select the desired mode.
1179         (if (not (eq mode t))
1180             (funcall mode)
1181           (setq buffer-read-only nil)
1182           (with-no-warnings (comint-mode))
1183           (compilation-shell-minor-mode))
1184         ;; Remember the original dir, so we can use it when we recompile.
1185         ;; default-directory' can't be used reliably for that because it may be
1186         ;; affected by the special handling of "cd ...;".
1187         ;; NB: must be fone after (funcall mode) as that resets local variables
1188         (set (make-local-variable 'compilation-directory) thisdir)
1189         (if highlight-regexp
1190             (set (make-local-variable 'compilation-highlight-regexp)
1191                  highlight-regexp))
1192         (if (or compilation-auto-jump-to-first-error
1193                 (eq compilation-scroll-output 'first-error))
1194             (set (make-local-variable 'compilation-auto-jump-to-next) t))
1195         ;; Output a mode setter, for saving and later reloading this buffer.
1196         (insert "-*- mode: " name-of-mode
1197                 "; default-directory: " (prin1-to-string default-directory)
1198                 " -*-\n"
1199                 (format "%s started at %s\n\n"
1200                         mode-name
1201                         (substring (current-time-string) 0 19))
1202                 command "\n")
1203         (setq thisdir default-directory))
1204       (set-buffer-modified-p nil))
1205     ;; Pop up the compilation buffer.
1206     ;; http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01638.html
1207     (setq outwin (display-buffer outbuf))
1208     (with-current-buffer outbuf
1209       (let ((process-environment
1210              (append
1211               compilation-environment
1212               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
1213                       system-uses-terminfo)
1214                   (list "TERM=dumb" "TERMCAP="
1215                         (format "COLUMNS=%d" (window-width)))
1216                 (list "TERM=emacs"
1217                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
1218                               (window-width))))
1219               ;; Set the EMACS variable, but
1220               ;; don't override users' setting of $EMACS.
1221               (unless (getenv "EMACS")
1222                 (list "EMACS=t"))
1223               (list "INSIDE_EMACS=t")
1224               (copy-sequence process-environment))))
1225         (set (make-local-variable 'compilation-arguments)
1226              (list command mode name-function highlight-regexp))
1227         (set (make-local-variable 'revert-buffer-function)
1228              'compilation-revert-buffer)
1229         (set-window-start outwin (point-min))
1230
1231         ;; Position point as the user will see it.
1232         (let ((desired-visible-point
1233                ;; Put it at the end if `compilation-scroll-output' is set.
1234                (if compilation-scroll-output
1235                    (point-max)
1236                  ;; Normally put it at the top.
1237                  (point-min))))
1238           (if (eq outwin (selected-window))
1239               (goto-char desired-visible-point)
1240             (set-window-point outwin desired-visible-point)))
1241
1242         ;; The setup function is called before compilation-set-window-height
1243         ;; so it can set the compilation-window-height buffer locally.
1244         (if compilation-process-setup-function
1245             (funcall compilation-process-setup-function))
1246         (compilation-set-window-height outwin)
1247         ;; Start the compilation.
1248         (let ((proc
1249                (if (eq mode t)
1250                    ;; comint uses `start-file-process'.
1251                    (get-buffer-process
1252                     (with-no-warnings
1253                       (comint-exec
1254                        outbuf (downcase mode-name)
1255                        (if (file-remote-p default-directory)
1256                            "/bin/sh"
1257                          shell-file-name)
1258                        nil `("-c" ,command))))
1259                  (start-file-process-shell-command (downcase mode-name)
1260                                                    outbuf command))))
1261           ;; Make the buffer's mode line show process state.
1262           (setq mode-line-process
1263                 (list (propertize ":%s" 'face 'compilation-warning)))
1264           (set-process-sentinel proc 'compilation-sentinel)
1265           (set-process-filter proc 'compilation-filter)
1266           ;; Use (point-max) here so that output comes in
1267           ;; after the initial text,
1268           ;; regardless of where the user sees point.
1269           (set-marker (process-mark proc) (point-max) outbuf)
1270           (when compilation-disable-input
1271             (condition-case nil
1272                 (process-send-eof proc)
1273               ;; The process may have exited already.
1274               (error nil)))
1275           (setq compilation-in-progress
1276                 (cons proc compilation-in-progress))))
1277       ;; Now finally cd to where the shell started make/grep/...
1278       (setq default-directory thisdir))
1279     (if (buffer-local-value 'compilation-scroll-output outbuf)
1280         (save-selected-window
1281           (select-window outwin)
1282           (goto-char (point-max))))
1283     ;; Make it so the next C-x ` will use this buffer.
1284     (setq next-error-last-buffer outbuf)))
1285
1286 (defun compilation-set-window-height (window)
1287   "Set the height of WINDOW according to `compilation-window-height'."
1288   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1289     (and height
1290          (window-full-width-p window)
1291          ;; If window is alone in its frame, aside from a minibuffer,
1292          ;; don't change its height.
1293          (not (eq window (frame-root-window (window-frame window))))
1294          ;; Stef said that doing the saves in this order is safer:
1295          (save-excursion
1296            (save-selected-window
1297              (select-window window)
1298              (enlarge-window (- height (window-height))))))))
1299
1300 (defvar compilation-menu-map
1301   (let ((map (make-sparse-keymap "Errors"))
1302         (opt-map (make-sparse-keymap "Skip")))
1303     (define-key map [stop-subjob]
1304       '(menu-item "Stop Compilation" kill-compilation
1305                   :help "Kill the process made by the M-x compile or M-x grep commands"))
1306     (define-key map [compilation-mode-separator3]
1307       '("----" . nil))
1308     (define-key map [compilation-next-error-follow-minor-mode]
1309       '(menu-item
1310         "Auto Error Display" next-error-follow-minor-mode
1311         :help "Display the error under cursor when moving the cursor"
1312         :button (:toggle . next-error-follow-minor-mode)))
1313     (define-key map [compilation-skip]
1314       (cons "Skip Less Important Messages" opt-map))
1315     (define-key opt-map [compilation-skip-none]
1316       '(menu-item "Don't Skip Any Messages"
1317                   (lambda ()
1318                     (interactive)
1319                     (customize-set-variable 'compilation-skip-threshold 0))
1320                   :help "Do not skip any type of messages"
1321                   :button (:radio . (eq compilation-skip-threshold 0))))
1322     (define-key opt-map [compilation-skip-info]
1323       '(menu-item "Skip Info"
1324                   (lambda ()
1325                     (interactive)
1326                     (customize-set-variable 'compilation-skip-threshold 1))
1327                   :help "Skip anything less than warning"
1328                   :button (:radio . (eq compilation-skip-threshold 1))))
1329     (define-key opt-map [compilation-skip-warning-and-info]
1330       '(menu-item "Skip Warnings and Info"
1331                   (lambda ()
1332                     (interactive)
1333                     (customize-set-variable 'compilation-skip-threshold 2))
1334                   :help "Skip over Warnings and Info, stop for errors"
1335                   :button (:radio . (eq compilation-skip-threshold 2))))
1336     (define-key map [compilation-mode-separator2]
1337       '("----" . nil))
1338     (define-key map [compilation-first-error]
1339       '(menu-item "First Error" first-error
1340                   :help "Restart at the first error, visit corresponding source code"))
1341     (define-key map [compilation-previous-error]
1342       '(menu-item "Previous Error" previous-error
1343                   :help "Visit previous `next-error' message and corresponding source code"))
1344     (define-key map [compilation-next-error]
1345       '(menu-item "Next Error" next-error
1346                   :help "Visit next `next-error' message and corresponding source code"))
1347     map))
1348
1349 (defvar compilation-minor-mode-map
1350   (let ((map (make-sparse-keymap)))
1351     (define-key map [mouse-2] 'compile-goto-error)
1352     (define-key map [follow-link] 'mouse-face)
1353     (define-key map "\C-c\C-c" 'compile-goto-error)
1354     (define-key map "\C-m" 'compile-goto-error)
1355     (define-key map "\C-c\C-k" 'kill-compilation)
1356     (define-key map "\M-n" 'compilation-next-error)
1357     (define-key map "\M-p" 'compilation-previous-error)
1358     (define-key map "\M-{" 'compilation-previous-file)
1359     (define-key map "\M-}" 'compilation-next-file)
1360     ;; Set up the menu-bar
1361     (define-key map [menu-bar compilation]
1362       (cons "Errors" compilation-menu-map))
1363     map)
1364   "Keymap for `compilation-minor-mode'.")
1365
1366 (defvar compilation-shell-minor-mode-map
1367   (let ((map (make-sparse-keymap)))
1368     (define-key map "\M-\C-m" 'compile-goto-error)
1369     (define-key map "\M-\C-n" 'compilation-next-error)
1370     (define-key map "\M-\C-p" 'compilation-previous-error)
1371     (define-key map "\M-{" 'compilation-previous-file)
1372     (define-key map "\M-}" 'compilation-next-file)
1373     ;; Set up the menu-bar
1374     (define-key map [menu-bar compilation]
1375       (cons "Errors" compilation-menu-map))
1376     map)
1377   "Keymap for `compilation-shell-minor-mode'.")
1378
1379 (defvar compilation-button-map
1380   (let ((map (make-sparse-keymap)))
1381     (define-key map [mouse-2] 'compile-goto-error)
1382     (define-key map [follow-link] 'mouse-face)
1383     (define-key map "\C-m" 'compile-goto-error)
1384     map)
1385   "Keymap for compilation-message buttons.")
1386 (fset 'compilation-button-map compilation-button-map)
1387
1388 (defvar compilation-mode-map
1389   (let ((map (make-sparse-keymap)))
1390     ;; Don't inherit from compilation-minor-mode-map,
1391     ;; because that introduces a menu bar item we don't want.
1392     ;; That confuses C-down-mouse-3.
1393     (define-key map [mouse-2] 'compile-goto-error)
1394     (define-key map [follow-link] 'mouse-face)
1395     (define-key map "\C-c\C-c" 'compile-goto-error)
1396     (define-key map "\C-m" 'compile-goto-error)
1397     (define-key map "\C-c\C-k" 'kill-compilation)
1398     (define-key map "\M-n" 'compilation-next-error)
1399     (define-key map "\M-p" 'compilation-previous-error)
1400     (define-key map "\M-{" 'compilation-previous-file)
1401     (define-key map "\M-}" 'compilation-next-file)
1402     (define-key map "\t" 'compilation-next-error)
1403     (define-key map [backtab] 'compilation-previous-error)
1404
1405     (define-key map " " 'scroll-up)
1406     (define-key map "\^?" 'scroll-down)
1407     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1408
1409     ;; Set up the menu-bar
1410     (let ((submap (make-sparse-keymap "Compile")))
1411       (define-key map [menu-bar compilation]
1412         (cons "Compile" submap))
1413       (set-keymap-parent submap compilation-menu-map))
1414     (define-key map [menu-bar compilation compilation-separator2]
1415       '("----" . nil))
1416     (define-key map [menu-bar compilation compilation-grep]
1417       '(menu-item "Search Files (grep)..." grep
1418                   :help "Run grep, with user-specified args, and collect output in a buffer"))
1419     (define-key map [menu-bar compilation compilation-recompile]
1420       '(menu-item "Recompile" recompile
1421         :help "Re-compile the program including the current buffer"))
1422     (define-key map [menu-bar compilation compilation-compile]
1423       '(menu-item "Compile..." compile
1424                   :help "Compile the program including the current buffer.  Default: run `make'"))
1425     map)
1426   "Keymap for compilation log buffers.
1427 `compilation-minor-mode-map' is a parent of this.")
1428
1429 (defvar compilation-mode-tool-bar-map
1430   (if (display-graphic-p)
1431       (let ((map (butlast (copy-keymap tool-bar-map)))
1432             (help (last tool-bar-map))) ;; Keep Help last in tool bar
1433         (tool-bar-local-item
1434          "left-arrow" 'previous-error-no-select 'previous-error-no-select map
1435          :rtl "right-arrow"
1436          :help "Goto previous error")
1437         (tool-bar-local-item
1438          "right-arrow" 'next-error-no-select 'next-error-no-select map
1439          :rtl "left-arrow"
1440          :help "Goto next error")
1441         (tool-bar-local-item
1442          "cancel" 'kill-compilation 'kill-compilation map
1443          :enable '(let ((buffer (compilation-find-buffer)))
1444                     (get-buffer-process buffer))
1445          :help "Stop compilation")
1446         (tool-bar-local-item
1447          "refresh" 'recompile 'recompile map
1448          :help "Restart compilation")
1449         (append map help))))
1450
1451 (put 'compilation-mode 'mode-class 'special)
1452
1453 ;;;###autoload
1454 (defun compilation-mode (&optional name-of-mode)
1455   "Major mode for compilation log buffers.
1456 \\<compilation-mode-map>To visit the source for a line-numbered error,
1457 move point to the error message line and type \\[compile-goto-error].
1458 To kill the compilation, type \\[kill-compilation].
1459
1460 Runs `compilation-mode-hook' with `run-mode-hooks' (which see).
1461
1462 \\{compilation-mode-map}"
1463   (interactive)
1464   (kill-all-local-variables)
1465   (use-local-map compilation-mode-map)
1466   (set (make-local-variable 'tool-bar-map) compilation-mode-tool-bar-map)
1467   (setq major-mode 'compilation-mode
1468         mode-name (or name-of-mode "Compilation"))
1469   (set (make-local-variable 'page-delimiter)
1470        compilation-page-delimiter)
1471   (compilation-setup)
1472   (setq buffer-read-only t)
1473   (run-mode-hooks 'compilation-mode-hook))
1474
1475 (defmacro define-compilation-mode (mode name doc &rest body)
1476   "This is like `define-derived-mode' without the PARENT argument.
1477 The parent is always `compilation-mode' and the customizable `compilation-...'
1478 variables are also set from the name of the mode you have chosen,
1479 by replacing the first word, e.g `compilation-scroll-output' from
1480 `grep-scroll-output' if that variable exists."
1481   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1482     `(define-derived-mode ,mode compilation-mode ,name
1483        ,doc
1484        ,@(mapcar (lambda (v)
1485                    (setq v (cons v
1486                                  (intern-soft (replace-regexp-in-string
1487                                                "^compilation" mode-name
1488                                                (symbol-name v)))))
1489                    (and (cdr v)
1490                         (or (boundp (cdr v))
1491                             (if (boundp 'byte-compile-bound-variables)
1492                                 (memq (cdr v) byte-compile-bound-variables)))
1493                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1494                  '(compilation-buffer-name-function
1495                    compilation-directory-matcher
1496                    compilation-error
1497                    compilation-error-regexp-alist
1498                    compilation-error-regexp-alist-alist
1499                    compilation-error-screen-columns
1500                    compilation-finish-function
1501                    compilation-finish-functions
1502                    compilation-first-column
1503                    compilation-mode-font-lock-keywords
1504                    compilation-page-delimiter
1505                    compilation-parse-errors-filename-function
1506                    compilation-process-setup-function
1507                    compilation-scroll-output
1508                    compilation-search-path
1509                    compilation-skip-threshold
1510                    compilation-window-height))
1511        ,@body)))
1512
1513 (defun compilation-revert-buffer (ignore-auto noconfirm)
1514   (if buffer-file-name
1515       (let (revert-buffer-function)
1516         (revert-buffer ignore-auto noconfirm))
1517     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1518         (apply 'compilation-start compilation-arguments))))
1519
1520 (defvar compilation-current-error nil
1521   "Marker to the location from where the next error will be found.
1522 The global commands next/previous/first-error/goto-error use this.")
1523
1524 (defvar compilation-messages-start nil
1525   "Buffer position of the beginning of the compilation messages.
1526 If nil, use the beginning of buffer.")
1527
1528 ;; A function name can't be a hook, must be something with a value.
1529 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1530
1531 (defun compilation-setup (&optional minor)
1532   "Prepare the buffer for the compilation parsing commands to work.
1533 Optional argument MINOR indicates this is called from
1534 `compilation-minor-mode'."
1535   (make-local-variable 'compilation-current-error)
1536   (make-local-variable 'compilation-messages-start)
1537   (make-local-variable 'compilation-error-screen-columns)
1538   (make-local-variable 'overlay-arrow-position)
1539   (set (make-local-variable 'overlay-arrow-string) "")
1540   (setq next-error-overlay-arrow-position nil)
1541   (add-hook 'kill-buffer-hook
1542             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1543   ;; Note that compilation-next-error-function is for interfacing
1544   ;; with the next-error function in simple.el, and it's only
1545   ;; coincidentally named similarly to compilation-next-error.
1546   (setq next-error-function 'compilation-next-error-function)
1547   (set (make-local-variable 'comint-file-name-prefix)
1548        (or (file-remote-p default-directory) ""))
1549   (set (make-local-variable 'font-lock-extra-managed-props)
1550        '(directory message help-echo mouse-face debug))
1551   (set (make-local-variable 'compilation-locs)
1552        (make-hash-table :test 'equal :weakness 'value))
1553   ;; lazy-lock would never find the message unless it's scrolled to.
1554   ;; jit-lock might fontify some things too late.
1555   (set (make-local-variable 'font-lock-support-mode) nil)
1556   (set (make-local-variable 'font-lock-maximum-size) nil)
1557   (if minor
1558       (let ((fld font-lock-defaults))
1559         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1560         (if font-lock-mode
1561             (if fld
1562                 (font-lock-fontify-buffer)
1563               (font-lock-change-mode)
1564               (turn-on-font-lock))
1565           (turn-on-font-lock)))
1566     (setq font-lock-defaults '(compilation-mode-font-lock-keywords t))
1567     ;; maybe defer font-lock till after derived mode is set up
1568     (run-mode-hooks 'compilation-turn-on-font-lock)))
1569
1570 ;;;###autoload
1571 (define-minor-mode compilation-shell-minor-mode
1572   "Toggle compilation shell minor mode.
1573 With arg, turn compilation mode on if and only if arg is positive.
1574 In this minor mode, all the error-parsing commands of the
1575 Compilation major mode are available but bound to keys that don't
1576 collide with Shell mode.  See `compilation-mode'.
1577 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1578   nil " Shell-Compile"
1579   :group 'compilation
1580   (if compilation-shell-minor-mode
1581       (compilation-setup t)
1582     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1583     (font-lock-fontify-buffer)))
1584
1585 ;;;###autoload
1586 (define-minor-mode compilation-minor-mode
1587   "Toggle compilation minor mode.
1588 With arg, turn compilation mode on if and only if arg is positive.
1589 In this minor mode, all the error-parsing commands of the
1590 Compilation major mode are available.  See `compilation-mode'.
1591 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1592   nil " Compilation"
1593   :group 'compilation
1594   (if compilation-minor-mode
1595       (compilation-setup t)
1596     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1597     (font-lock-fontify-buffer)))
1598
1599 (defun compilation-handle-exit (process-status exit-status msg)
1600   "Write MSG in the current buffer and hack its `mode-line-process'."
1601   (let ((inhibit-read-only t)
1602         (status (if compilation-exit-message-function
1603                     (funcall compilation-exit-message-function
1604                              process-status exit-status msg)
1605                   (cons msg exit-status)))
1606         (omax (point-max))
1607         (opoint (point))
1608         (cur-buffer (current-buffer)))
1609     ;; Record where we put the message, so we can ignore it later on.
1610     (goto-char omax)
1611     (insert ?\n mode-name " " (car status))
1612     (if (and (numberp compilation-window-height)
1613              (zerop compilation-window-height))
1614         (message "%s" (cdr status)))
1615     (if (bolp)
1616         (forward-char -1))
1617     (insert " at " (substring (current-time-string) 0 19))
1618     (goto-char (point-max))
1619     ;; Prevent that message from being recognized as a compilation error.
1620     (add-text-properties omax (point)
1621                          (append '(compilation-handle-exit t) nil))
1622     (setq mode-line-process
1623           (let ((out-string (format ":%s [%s]" process-status (cdr status)))
1624                 (msg (format "%s %s" mode-name
1625                              (replace-regexp-in-string "\n?$" "" (car status)))))
1626             (message "%s" msg)
1627             (propertize out-string
1628                         'help-echo msg 'face (if (> exit-status 0)
1629                                                  'compilation-error
1630                                                'compilation-info))))
1631     ;; Force mode line redisplay soon.
1632     (force-mode-line-update)
1633     (if (and opoint (< opoint omax))
1634         (goto-char opoint))
1635     (with-no-warnings
1636       (if compilation-finish-function
1637           (funcall compilation-finish-function cur-buffer msg)))
1638     (run-hook-with-args 'compilation-finish-functions cur-buffer msg)))
1639
1640 ;; Called when compilation process changes state.
1641 (defun compilation-sentinel (proc msg)
1642   "Sentinel for compilation buffers."
1643   (if (memq (process-status proc) '(exit signal))
1644       (let ((buffer (process-buffer proc)))
1645         (if (null (buffer-name buffer))
1646             ;; buffer killed
1647             (set-process-buffer proc nil)
1648           (with-current-buffer buffer
1649             ;; Write something in the compilation buffer
1650             ;; and hack its mode line.
1651             (compilation-handle-exit (process-status proc)
1652                                      (process-exit-status proc)
1653                                      msg)
1654             ;; Since the buffer and mode line will show that the
1655             ;; process is dead, we can delete it now.  Otherwise it
1656             ;; will stay around until M-x list-processes.
1657             (delete-process proc)))
1658         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1659
1660 (defun compilation-filter (proc string)
1661   "Process filter for compilation buffers.
1662 Just inserts the text, but uses `insert-before-markers'."
1663   (if (buffer-name (process-buffer proc))
1664       (with-current-buffer (process-buffer proc)
1665         (let ((inhibit-read-only t))
1666           (save-excursion
1667             (goto-char (process-mark proc))
1668             (insert-before-markers string)
1669             (run-hooks 'compilation-filter-hook))))))
1670
1671 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1672 (defsubst compilation-buffer-internal-p ()
1673   "Test if inside a compilation buffer."
1674   (local-variable-p 'compilation-locs))
1675
1676 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1677 (defsubst compilation-buffer-p (buffer)
1678   "Test if BUFFER is a compilation buffer."
1679   (with-current-buffer buffer
1680     (compilation-buffer-internal-p)))
1681
1682 (defmacro compilation-loop (< property-change 1+ error limit)
1683   `(let (opt)
1684      (while (,< n 0)
1685        (setq opt pt)
1686        (or (setq pt (,property-change pt 'message))
1687            ;; Handle the case where where the first error message is
1688            ;; at the start of the buffer, and n < 0.
1689            (if (or (eq (get-text-property ,limit 'message)
1690                        (get-text-property opt 'message))
1691                    (eq pt opt))
1692                (error ,error compilation-error)
1693              (setq pt ,limit)))
1694        ;; prop 'message usually has 2 changes, on and off, so
1695        ;; re-search if off
1696        (or (setq msg (get-text-property pt 'message))
1697            (if (setq pt (,property-change pt 'message nil ,limit))
1698                (setq msg (get-text-property pt 'message)))
1699            (error ,error compilation-error))
1700        (or (< (cadr msg) compilation-skip-threshold)
1701            (if different-file
1702                (eq (prog1 last (setq last (nth 2 (car msg))))
1703                    last))
1704            (if compilation-skip-visited
1705                (nthcdr 5 (car msg)))
1706            (if compilation-skip-to-next-location
1707                (eq (car msg) loc))
1708            ;; count this message only if none of the above are true
1709            (setq n (,1+ n))))))
1710
1711 (defun compilation-next-error (n &optional different-file pt)
1712   "Move point to the next error in the compilation buffer.
1713 This function does NOT find the source line like \\[next-error].
1714 Prefix arg N says how many error messages to move forwards (or
1715 backwards, if negative).
1716 Optional arg DIFFERENT-FILE, if non-nil, means find next error for a
1717 file that is different from the current one.
1718 Optional arg PT, if non-nil, specifies the value of point to start
1719 looking for the next message."
1720   (interactive "p")
1721   (or (compilation-buffer-p (current-buffer))
1722       (error "Not in a compilation buffer"))
1723   (or pt (setq pt (point)))
1724   (let* ((msg (get-text-property pt 'message))
1725          ;; `loc' is used by the compilation-loop macro.
1726          (loc (car msg))
1727          last)
1728     (if (zerop n)
1729         (unless (or msg                 ; find message near here
1730                     (setq msg (get-text-property (max (1- pt) (point-min))
1731                                                  'message)))
1732           (setq pt (previous-single-property-change pt 'message nil
1733                                                     (line-beginning-position)))
1734           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1735             (setq pt (next-single-property-change pt 'message nil
1736                                                   (line-end-position)))
1737             (or (setq msg (get-text-property pt 'message))
1738                 (setq pt (point)))))
1739       (setq last (nth 2 (car msg)))
1740       (if (>= n 0)
1741           (compilation-loop > next-single-property-change 1-
1742                             (if (get-buffer-process (current-buffer))
1743                                 "No more %ss yet"
1744                               "Moved past last %s")
1745                             (point-max))
1746         ;; Don't move "back" to message at or before point.
1747         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1748         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1749         (compilation-loop < previous-single-property-change 1+
1750                           "Moved back before first %s" (point-min))))
1751     (goto-char pt)
1752     (or msg
1753         (error "No %s here" compilation-error))))
1754
1755 (defun compilation-previous-error (n)
1756   "Move point to the previous error in the compilation buffer.
1757 Prefix arg N says how many error messages to move backwards (or
1758 forwards, if negative).
1759 Does NOT find the source line like \\[previous-error]."
1760   (interactive "p")
1761   (compilation-next-error (- n)))
1762
1763 (defun compilation-next-file (n)
1764   "Move point to the next error for a different file than the current one.
1765 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1766   (interactive "p")
1767   (compilation-next-error n t))
1768
1769 (defun compilation-previous-file (n)
1770   "Move point to the previous error for a different file than the current one.
1771 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1772   (interactive "p")
1773   (compilation-next-file (- n)))
1774
1775 (defun kill-compilation ()
1776   "Kill the process made by the \\[compile] or \\[grep] commands."
1777   (interactive)
1778   (let ((buffer (compilation-find-buffer)))
1779     (if (get-buffer-process buffer)
1780         (interrupt-process (get-buffer-process buffer))
1781       (error "The %s process is not running" (downcase mode-name)))))
1782
1783 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1784
1785 (defun compile-goto-error (&optional event)
1786   "Visit the source for the error message at point.
1787 Use this command in a compilation log buffer.  Sets the mark at point there."
1788   (interactive (list last-input-event))
1789   (if event (posn-set-point (event-end event)))
1790   (or (compilation-buffer-p (current-buffer))
1791       (error "Not in a compilation buffer"))
1792   (if (get-text-property (point) 'directory)
1793       (dired-other-window (car (get-text-property (point) 'directory)))
1794     (push-mark)
1795     (setq compilation-current-error (point))
1796     (next-error-internal)))
1797
1798 (defun compilation-find-buffer (&optional avoid-current)
1799   "Return a compilation buffer.
1800 If AVOID-CURRENT is nil, and the current buffer is a compilation buffer,
1801 return it.  If AVOID-CURRENT is non-nil, return the current buffer only
1802 as a last resort."
1803   (if (and (compilation-buffer-internal-p) (not avoid-current))
1804       (current-buffer)
1805     (next-error-find-buffer avoid-current 'compilation-buffer-internal-p)))
1806
1807 ;;;###autoload
1808 (defun compilation-next-error-function (n &optional reset)
1809   "Advance to the next error message and visit the file where the error was.
1810 This is the value of `next-error-function' in Compilation buffers."
1811   (interactive "p")
1812   (when reset
1813     (setq compilation-current-error nil))
1814   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1815          (last 1) timestamp
1816          (loc (compilation-next-error (or n 1) nil
1817                                       (or compilation-current-error
1818                                           compilation-messages-start
1819                                           (point-min))))
1820          (end-loc (nth 2 loc))
1821          (marker (point-marker)))
1822     (setq compilation-current-error (point-marker)
1823           overlay-arrow-position
1824             (if (bolp)
1825                 compilation-current-error
1826               (copy-marker (line-beginning-position)))
1827           loc (car loc))
1828     ;; If loc contains no marker, no error in that file has been visited.
1829     ;; If the marker is invalid the buffer has been killed.
1830     ;; If the file is newer than the timestamp, it has been modified
1831     ;; (`omake -P' polls filesystem for changes and recompiles when needed
1832     ;;  in the same process and buffer).
1833     ;; So, recalculate all markers for that file.
1834     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc))
1835                  ;; There may be no timestamp info if the loc is a `fake-loc'.
1836                  ;; So we skip the time-check here, although we should maybe
1837                  ;; change `compilation-fake-loc' to add timestamp info.
1838                  (or (null (nth 4 loc))
1839                      (equal (nth 4 loc)
1840                             (setq timestamp
1841                                   (with-current-buffer
1842                                       (marker-buffer (nth 3 loc))
1843                                     (visited-file-modtime))))))
1844       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1845                                                   (cadr (car (nth 2 loc))))
1846         (save-restriction
1847           (widen)
1848           (goto-char (point-min))
1849           ;; Treat file's found lines in forward order, 1 by 1.
1850           (dolist (line (reverse (cddr (nth 2 loc))))
1851             (when (car line)            ; else this is a filename w/o a line#
1852               (beginning-of-line (- (car line) last -1))
1853               (setq last (car line)))
1854             ;; Treat line's found columns and store/update a marker for each.
1855             (dolist (col (cdr line))
1856               (if (car col)
1857                   (if (eq (car col) -1) ; special case for range end
1858                       (end-of-line)
1859                     (compilation-move-to-column (car col) columns))
1860                 (beginning-of-line)
1861                 (skip-chars-forward " \t"))
1862               (if (nth 3 col)
1863                   (set-marker (nth 3 col) (point))
1864                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1865     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1866     (setcdr (nthcdr 3 loc) (list timestamp))
1867     (setcdr (nthcdr 4 loc) t)))         ; Set this one as visited.
1868
1869 (defvar compilation-gcpro nil
1870   "Internal variable used to keep some values from being GC'd.")
1871 (make-variable-buffer-local 'compilation-gcpro)
1872
1873 (defun compilation-fake-loc (marker file &optional line col)
1874   "Preassociate MARKER with FILE.
1875 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1876 This is useful when you compile temporary files, but want
1877 automatic translation of the messages to the real buffer from
1878 which the temporary file came.  This only works if done before a
1879 message about FILE appears!
1880
1881 Optional args LINE and COL default to 1 and beginning of
1882 indentation respectively.  The marker is expected to reflect
1883 this.  In the simplest case the marker points to the first line
1884 of the region that was saved to the temp file.
1885
1886 If you concatenate several regions into the temp file (e.g. a
1887 header with variable assignments and a code region), you must
1888 call this several times, once each for the last line of one
1889 region and the first line of the next region."
1890   (or (consp file) (setq file (list file)))
1891   (setq file (compilation-get-file-structure file))
1892   ;; Between the current call to compilation-fake-loc and the first occurrence
1893   ;; of an error message referring to `file', the data is only kept in the
1894   ;; weak hash-table compilation-locs, so we need to prevent this entry
1895   ;; in compilation-locs from being GC'd away.  --Stef
1896   (push file compilation-gcpro)
1897   (let ((loc (compilation-assq (or line 1) (cdr file))))
1898     (setq loc (compilation-assq col loc))
1899     (if (cdr loc)
1900         (setcdr (cddr loc) (list marker))
1901       (setcdr loc (list line file marker)))
1902     loc))
1903
1904 (defcustom compilation-context-lines nil
1905   "Display this many lines of leading context before the current message.
1906 If nil and the left fringe is displayed, don't scroll the
1907 compilation output window; an arrow in the left fringe points to
1908 the current message.  If nil and there is no left fringe, the message
1909 displays at the top of the window; there is no arrow."
1910   :type '(choice integer (const :tag "No window scrolling" nil))
1911   :group 'compilation
1912   :version "22.1")
1913
1914 (defsubst compilation-set-window (w mk)
1915   "Align the compilation output window W with marker MK near top."
1916   (if (integerp compilation-context-lines)
1917       (set-window-start w (save-excursion
1918                             (goto-char mk)
1919                             (beginning-of-line
1920                              (- 1 compilation-context-lines))
1921                             (point)))
1922     ;; If there is no left fringe.
1923     (if (equal (car (window-fringes)) 0)
1924         (set-window-start w (save-excursion
1925                               (goto-char mk)
1926                             (beginning-of-line 1)
1927                             (point)))))
1928     (set-window-point w mk))
1929
1930 (defvar next-error-highlight-timer)
1931
1932 (defun compilation-goto-locus (msg mk end-mk)
1933   "Jump to an error corresponding to MSG at MK.
1934 All arguments are markers.  If END-MK is non-nil, mark is set there
1935 and overlay is highlighted between MK and END-MK."
1936   ;; Show compilation buffer in other window, scrolled to this error.
1937   (let* ((from-compilation-buffer (eq (window-buffer (selected-window))
1938                                       (marker-buffer msg)))
1939          ;; Use an existing window if it is in a visible frame.
1940          (pre-existing (get-buffer-window (marker-buffer msg) 0))
1941          (w (if (and from-compilation-buffer pre-existing)
1942                 ;; Calling display-buffer here may end up (partly) hiding
1943                 ;; the error location if the two buffers are in two
1944                 ;; different frames.  So don't do it if it's not necessary.
1945                 pre-existing
1946               (let ((display-buffer-reuse-frames t)
1947                     (pop-up-windows t))
1948                 ;; Pop up a window.
1949                 (display-buffer (marker-buffer msg)))))
1950          (highlight-regexp (with-current-buffer (marker-buffer msg)
1951                              ;; also do this while we change buffer
1952                              (compilation-set-window w msg)
1953                              compilation-highlight-regexp)))
1954     ;; Ideally, the window-size should be passed to `display-buffer' (via
1955     ;; something like special-display-buffer) so it's only used when
1956     ;; creating a new window.
1957     (unless pre-existing (compilation-set-window-height w))
1958
1959     (if from-compilation-buffer
1960         ;; If the compilation buffer window was selected,
1961         ;; keep the compilation buffer in this window;
1962         ;; display the source in another window.
1963         (let ((pop-up-windows t))
1964           (pop-to-buffer (marker-buffer mk) 'other-window))
1965       (if (window-dedicated-p (selected-window))
1966           (pop-to-buffer (marker-buffer mk))
1967         (switch-to-buffer (marker-buffer mk))))
1968     ;; If narrowing gets in the way of going to the right place, widen.
1969     (unless (eq (goto-char mk) (point))
1970       (widen)
1971       (goto-char mk))
1972     (if end-mk
1973         (push-mark end-mk t)
1974       (if mark-active (setq mark-active)))
1975     ;; If hideshow got in the way of
1976     ;; seeing the right place, open permanently.
1977     (dolist (ov (overlays-at (point)))
1978       (when (eq 'hs (overlay-get ov 'invisible))
1979         (delete-overlay ov)
1980         (goto-char mk)))
1981
1982     (when highlight-regexp
1983       (if (timerp next-error-highlight-timer)
1984           (cancel-timer next-error-highlight-timer))
1985       (unless compilation-highlight-overlay
1986         (setq compilation-highlight-overlay
1987               (make-overlay (point-min) (point-min)))
1988         (overlay-put compilation-highlight-overlay 'face 'next-error))
1989       (with-current-buffer (marker-buffer mk)
1990         (save-excursion
1991           (if end-mk (goto-char end-mk) (end-of-line))
1992           (let ((end (point)))
1993             (if mk (goto-char mk) (beginning-of-line))
1994             (if (and (stringp highlight-regexp)
1995                      (re-search-forward highlight-regexp end t))
1996                 (progn
1997                   (goto-char (match-beginning 0))
1998                   (move-overlay compilation-highlight-overlay
1999                                 (match-beginning 0) (match-end 0)
2000                                 (current-buffer)))
2001               (move-overlay compilation-highlight-overlay
2002                             (point) end (current-buffer)))
2003             (if (or (eq next-error-highlight t)
2004                     (numberp next-error-highlight))
2005                 ;; We want highlighting: delete overlay on next input.
2006                 (add-hook 'pre-command-hook
2007                           'compilation-goto-locus-delete-o)
2008               ;; We don't want highlighting: delete overlay now.
2009               (delete-overlay compilation-highlight-overlay))
2010             ;; We want highlighting for a limited time:
2011             ;; set up a timer to delete it.
2012             (when (numberp next-error-highlight)
2013               (setq next-error-highlight-timer
2014                     (run-at-time next-error-highlight nil
2015                                  'compilation-goto-locus-delete-o)))))))
2016     (when (and (eq next-error-highlight 'fringe-arrow))
2017       ;; We want a fringe arrow (instead of highlighting).
2018       (setq next-error-overlay-arrow-position
2019             (copy-marker (line-beginning-position))))))
2020
2021 (defun compilation-goto-locus-delete-o ()
2022   (delete-overlay compilation-highlight-overlay)
2023   ;; Get rid of timer and hook that would try to do this again.
2024   (if (timerp next-error-highlight-timer)
2025       (cancel-timer next-error-highlight-timer))
2026   (remove-hook 'pre-command-hook
2027                'compilation-goto-locus-delete-o))
2028 \f
2029 (defun compilation-find-file (marker filename directory &rest formats)
2030   "Find a buffer for file FILENAME.
2031 If FILENAME is not found at all, ask the user where to find it.
2032 Pop up the buffer containing MARKER and scroll to MARKER if we ask
2033 the user where to find the file.
2034 Search the directories in `compilation-search-path'.
2035 A nil in `compilation-search-path' means to try the
2036 \"current\" directory, which is passed in DIRECTORY.
2037 If DIRECTORY is relative, it is combined with `default-directory'.
2038 If DIRECTORY is nil, that means use `default-directory'.
2039 FORMATS, if given, is a list of formats to reformat FILENAME when
2040 looking for it: for each element FMT in FORMATS, this function
2041 attempts to find a file whose name is produced by (format FMT FILENAME)."
2042   (or formats (setq formats '("%s")))
2043   (let ((dirs compilation-search-path)
2044         (spec-dir (if directory
2045                       (expand-file-name directory)
2046                     default-directory))
2047         buffer thisdir fmts name)
2048     (if (file-name-absolute-p filename)
2049         ;; The file name is absolute.  Use its explicit directory as
2050         ;; the first in the search path, and strip it from FILENAME.
2051         (setq filename (abbreviate-file-name (expand-file-name filename))
2052               dirs (cons (file-name-directory filename) dirs)
2053               filename (file-name-nondirectory filename)))
2054     ;; Now search the path.
2055     (while (and dirs (null buffer))
2056       (setq thisdir (or (car dirs) spec-dir)
2057             fmts formats)
2058       ;; For each directory, try each format string.
2059       (while (and fmts (null buffer))
2060         (setq name (expand-file-name (format (car fmts) filename) thisdir)
2061               buffer (and (file-exists-p name)
2062                           (find-file-noselect name))
2063               fmts (cdr fmts)))
2064       (setq dirs (cdr dirs)))
2065     (while (null buffer)    ;Repeat until the user selects an existing file.
2066       ;; The file doesn't exist.  Ask the user where to find it.
2067       (save-excursion            ;This save-excursion is probably not right.
2068         (let ((pop-up-windows t))
2069           (compilation-set-window (display-buffer (marker-buffer marker))
2070                                   marker)
2071           (let* ((name (read-file-name
2072                         (format "Find this %s in (default %s): "
2073                                 compilation-error filename)
2074                         spec-dir filename t nil
2075                         ;; The predicate below is fine when called from
2076                         ;; minibuffer-complete-and-exit, but it's too
2077                         ;; restrictive otherwise, since it also prevents the
2078                         ;; user from completing "fo" to "foo/" when she
2079                         ;; wants to enter "foo/bar".
2080                         ;;
2081                         ;; Try to make sure the user can only select
2082                         ;; a valid answer.  This predicate may be ignored,
2083                         ;; tho, so we still have to double-check afterwards.
2084                         ;; TODO: We should probably fix read-file-name so
2085                         ;; that it never ignores this predicate, even when
2086                         ;; using popup dialog boxes.
2087                         ;; (lambda (name)
2088                         ;;   (if (file-directory-p name)
2089                         ;;       (setq name (expand-file-name filename name)))
2090                         ;;   (file-exists-p name))
2091                         ))
2092                  (origname name))
2093             (cond
2094              ((not (file-exists-p name))
2095               (message "Cannot find file `%s'" name)
2096               (ding) (sit-for 2))
2097              ((and (file-directory-p name)
2098                    (not (file-exists-p
2099                          (setq name (expand-file-name filename name)))))
2100               (message "No `%s' in directory %s" filename origname)
2101               (ding) (sit-for 2))
2102              (t
2103               (setq buffer (find-file-noselect name))))))))
2104     ;; Make intangible overlays tangible.
2105     ;; This is weird: it's not even clear which is the current buffer,
2106     ;; so the code below can't be expected to DTRT here.  -- Stef
2107     (dolist (ov (overlays-in (point-min) (point-max)))
2108       (when (overlay-get ov 'intangible)
2109         (overlay-put ov 'intangible nil)))
2110     buffer))
2111
2112 (defun compilation-get-file-structure (file &optional fmt)
2113   "Retrieve FILE's file-structure or create a new one.
2114 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
2115 In the former case, FILENAME may be relative or absolute.
2116
2117 The file-structure looks like this:
2118   (list (list FILENAME [DIR-FROM-PREV-MSG]) FMT LINE-STRUCT...)"
2119   (or (gethash file compilation-locs)
2120       ;; File was not previously encountered, at least not in the form passed.
2121       ;; Let's normalize it and look again.
2122       (let ((filename (car file))
2123             ;; Get the specified directory from FILE.
2124             (spec-directory (if (cdr file)
2125                                 (file-truename (cdr file)))))
2126
2127         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
2128         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
2129         ;; buffer.)
2130         (when (and (boundp 'comint-file-name-prefix)
2131                    (not (equal comint-file-name-prefix "")))
2132           (if (file-name-absolute-p filename)
2133               (setq filename
2134                     (concat comint-file-name-prefix filename))
2135             (if spec-directory
2136                 (setq spec-directory
2137                       (file-truename
2138                        (concat comint-file-name-prefix spec-directory))))))
2139
2140         ;; If compilation-parse-errors-filename-function is
2141         ;; defined, use it to process the filename.
2142         (when compilation-parse-errors-filename-function
2143           (setq filename
2144                 (funcall compilation-parse-errors-filename-function
2145                          filename)))
2146
2147         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
2148         ;; file names like "./bar//foo.c" for file "bar/foo.c";
2149         ;; expand-file-name will collapse these into "/foo.c" and fail to find
2150         ;; the appropriate file.  So we look for doubled slashes in the file
2151         ;; name and fix them.
2152         (setq filename (command-line-normalize-file-name filename))
2153
2154         ;; Store it for the possibly unnormalized name
2155         (puthash file
2156                  ;; Retrieve or create file-structure for normalized name
2157                  ;; The gethash used to not use spec-directory, but
2158                  ;; this leads to errors when files in different
2159                  ;; directories have the same name:
2160                  ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg00463.html
2161                  (or (gethash (cons filename spec-directory) compilation-locs)
2162                      (puthash (cons filename spec-directory)
2163                               (list (list filename spec-directory) fmt)
2164                               compilation-locs))
2165                  compilation-locs))))
2166
2167 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
2168
2169 ;;; Compatibility with the old compile.el.
2170
2171 (defun compile-buffer-substring (n) (if n (match-string n)))
2172
2173 (defun compilation-compat-error-properties (err)
2174   "Map old-style error ERR to new-style message."
2175   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
2176   ;; (MARKER . MARKER).
2177   (let ((dst (cdr err)))
2178     (if (markerp dst)
2179         ;; Must start with a face, for font-lock.
2180         `(face nil
2181           message ,(list (list nil nil nil dst) 2)
2182           help-echo "mouse-2: visit the source location"
2183           keymap compilation-button-map
2184           mouse-face highlight)
2185       ;; Too difficult to do it by hand: dispatch to the normal code.
2186       (let* ((file (pop dst))
2187              (line (pop dst))
2188              (col (pop dst))
2189              (filename (pop file))
2190              (dirname (pop file))
2191              (fmt (pop file)))
2192         (compilation-internal-error-properties
2193          (cons filename dirname) line nil col nil 2 fmt)))))
2194
2195 (defun compilation-compat-parse-errors (limit)
2196   (when compilation-parse-errors-function
2197     ;; FIXME: We should remove the rest of the compilation keywords
2198     ;; but we can't do that from here because font-lock is using
2199     ;; the value right now.  --stef
2200     (save-excursion
2201       (setq compilation-error-list nil)
2202       ;; Reset compilation-parsing-end each time because font-lock
2203       ;; might force us the re-parse many times (typically because
2204       ;; some code adds some text-property to the output that we
2205       ;; already parsed).  You might say "why reparse", well:
2206       ;; because font-lock has just removed the `message' property so
2207       ;; have to do it all over again.
2208       (if compilation-parsing-end
2209           (set-marker compilation-parsing-end (point))
2210         (setq compilation-parsing-end (point-marker)))
2211       (condition-case nil
2212           ;; Ignore any error: we're calling this function earlier than
2213           ;; in the old compile.el so things might not all be setup yet.
2214           (funcall compilation-parse-errors-function limit nil)
2215         (error nil))
2216       (dolist (err (if (listp compilation-error-list) compilation-error-list))
2217         (let* ((src (car err))
2218                (dst (cdr err))
2219                (loc (cond ((markerp dst) (list nil nil nil dst))
2220                           ((consp dst)
2221                            (list (nth 2 dst) (nth 1 dst)
2222                                  (cons (cdar dst) (caar dst)))))))
2223           (when loc
2224             (goto-char src)
2225             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
2226             (put-text-property src (line-end-position)
2227                                'message (list loc 2)))))))
2228   (goto-char limit)
2229   nil)
2230
2231 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
2232 (defun compilation-forget-errors ()
2233   ;; In case we hit the same file/line specs, we want to recompute a new
2234   ;; marker for them, so flush our cache.
2235   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
2236   (setq compilation-gcpro nil)
2237   ;; FIXME: the old code reset the directory-stack, so maybe we should
2238   ;; put a `directory change' marker of some sort, but where?  -stef
2239   ;;
2240   ;; FIXME: The old code moved compilation-current-error (which was
2241   ;; virtually represented by a mix of compilation-parsing-end and
2242   ;; compilation-error-list) to point-min, but that was only meaningful for
2243   ;; the internal uses of compilation-forget-errors: all calls from external
2244   ;; packages seem to be followed by a move of compilation-parsing-end to
2245   ;; something equivalent to point-max.  So we heuristically move
2246   ;; compilation-current-error to point-max (since the external package
2247   ;; won't know that it should do it).  --Stef
2248   (setq compilation-current-error nil)
2249   (let* ((proc (get-buffer-process (current-buffer)))
2250          (mark (if proc (process-mark proc)))
2251          (pos (or mark (point-max))))
2252     (setq compilation-messages-start
2253           ;; In the future, ignore the text already present in the buffer.
2254           ;; Since many process filter functions insert before markers,
2255           ;; we need to put ours just before the insertion point rather
2256           ;; than at the insertion point.  If that's not possible, then
2257           ;; don't use a marker.  --Stef
2258           (if (> pos (point-min)) (copy-marker (1- pos)) pos)))
2259   ;; Again, since this command is used in buffers that contain several
2260   ;; compilations, to set the beginning of "this compilation", it's a good
2261   ;; place to reset compilation-auto-jump-to-next.
2262   (set (make-local-variable 'compilation-auto-jump-to-next)
2263        (or compilation-auto-jump-to-first-error
2264            (eq compilation-scroll-output 'first-error))))
2265
2266 ;;;###autoload
2267 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
2268
2269 (provide 'compile)
2270
2271 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
2272 ;;; compile.el ends here