lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * working-revision (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       OK
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-revision (file)                          NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-revision (file rev buffer)               OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional revision)          NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (revision)                     OK
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (files)             NEEDED?
  91 ;; - annotate-command (file buf &optional rev)     OK
  92 ;; - annotate-time ()                              OK
  93 ;; - annotate-current-time ()                      NOT NEEDED
  94 ;; - annotate-extract-revision-at-line ()          OK
  95 ;; SNAPSHOT SYSTEM
  96 ;; - create-snapshot (dir name branchp)            OK
  97 ;; - assign-name (file name)                       NOT NEEDED
  98 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
  99 ;; MISCELLANEOUS
 100 ;; - make-version-backups-p (file)                 NOT NEEDED
 101 ;; - repository-hostname (dirname)                 NOT NEEDED
 102 ;; - previous-revision (file rev)                  OK
 103 ;; - next-revision (file rev)                      OK
 104 ;; - check-headers ()                              COULD BE SUPPORTED
 105 ;; - clear-headers ()                              NOT NEEDED
 106 ;; - delete-file (file)                            OK
 107 ;; - rename-file (old new)                         OK
 108 ;; - find-file-hook ()                             NOT NEEDED
 109 ;; - find-file-not-found-hook ()                   NOT NEEDED
 110
 111 (eval-when-compile (require 'cl) (require 'vc))
 112
 113 (defvar git-commits-coding-system 'utf-8
 114   "Default coding system for git commits.")
 115
 116 ;;; BACKEND PROPERTIES
 117
 118 (defun vc-git-revision-granularity ()
 119   'repository)
 120
 121 ;;; STATE-QUERYING FUNCTIONS
 122
 123 ;;;###autoload (defun vc-git-registered (file)
 124 ;;;###autoload   "Return non-nil if FILE is registered with git."
 125 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 126 ;;;###autoload       (progn
 127 ;;;###autoload         (load "vc-git")
 128 ;;;###autoload         (vc-git-registered file))))
 129
 130 (defun vc-git-registered (file)
 131   "Check whether FILE is registered with git."
 132   (when (vc-git-root file)
 133     (with-temp-buffer
 134       (let* ((dir (file-name-directory file))
 135              (name (file-relative-name file dir)))
 136         (and (ignore-errors
 137                (when dir (cd dir))
 138                (vc-git--out-ok "ls-files" "-c" "-z" "--" name))
 139              (let ((str (buffer-string)))
 140                (and (> (length str) (length name))
 141                     (string= (substring str 0 (1+ (length name)))
 142                              (concat name "\0")))))))))
 143
 144 (defun vc-git-state (file)
 145   "Git-specific version of `vc-state'."
 146   ;; FIXME: This can't set 'ignored yet
 147   (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 148   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 149     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0"
 150                                 diff))
 151         'edited
 152       'up-to-date)))
 153
 154 (defun vc-git-dir-state (dir)
 155   "Git-specific version of `dir-state'."
 156   ;; FIXME: This can't set 'ignored yet
 157   (with-temp-buffer
 158     (buffer-disable-undo)               ;; Because these buffers can get huge
 159     (vc-git-command (current-buffer) nil nil "ls-files" "-t" "-c" "-m" "-o")
 160     (goto-char (point-min))
 161     (let ((status-char nil)
 162           (file nil))
 163       (while (not (eobp))
 164         (setq status-char (char-after))
 165         (setq file
 166               (expand-file-name
 167                (buffer-substring-no-properties (+ (point) 2)
 168                                                (line-end-position))))
 169         (cond
 170          ;; The rest of the possible states in "git ls-files -t" output:
 171          ;;      R              removed/deleted
 172          ;;      K              to be killed
 173          ;; should not show up in vc-dired, so don't deal with them
 174          ;; here.
 175          ((eq status-char ?H)
 176           (vc-file-setprop file 'vc-state 'up-to-date))
 177          ((eq status-char ?M)
 178           (vc-file-setprop file 'vc-state 'edited))
 179          ((eq status-char ?C)
 180           (vc-file-setprop file 'vc-state 'edited))
 181          ((eq status-char ??)
 182           (vc-file-setprop file 'vc-backend 'none)
 183           (vc-file-setprop file 'vc-state 'nil)))
 184         (forward-line)))))
 185
 186 (defun vc-git-working-revision (file)
 187   "Git-specific version of `vc-working-revision'."
 188   (let ((str (with-output-to-string
 189                (with-current-buffer standard-output
 190                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 191     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 192         (match-string 2 str)
 193       str)))
 194
 195 (defun vc-git-checkout-model (file)
 196   'implicit)
 197
 198 (defun vc-git-workfile-unchanged-p (file)
 199   (eq 'up-to-date (vc-git-state file)))
 200
 201 (defun vc-git-mode-line-string (file)
 202   "Return string for placement into the modeline for FILE."
 203   (let* ((branch (vc-git-working-revision file))
 204          (def-ml (vc-default-mode-line-string 'Git file))
 205          (help-echo (get-text-property 0 'help-echo def-ml)))
 206     (if (zerop (length branch))
 207         (propertize
 208          (concat def-ml "!")
 209          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 210       (propertize def-ml
 211                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 212
 213 (defun vc-git-dired-state-info (file)
 214   "Git-specific version of `vc-dired-state-info'."
 215   (let ((git-state (vc-state file)))
 216     (if (eq git-state 'edited)
 217         "(modified)"
 218       ;; fall back to the default VC representation
 219       (vc-default-dired-state-info 'Git file))))
 220
 221 ;;; STATE-CHANGING FUNCTIONS
 222
 223 (defun vc-git-create-repo ()
 224   "Create a new Git repository."
 225   (vc-git-command nil 0 nil "init"))
 226
 227 (defun vc-git-register (files &optional rev comment)
 228   "Register FILE into the git version-control system."
 229   (vc-git-command nil 0 files "update-index" "--add" "--"))
 230
 231 (defalias 'vc-git-responsible-p 'vc-git-root)
 232
 233 (defun vc-git-unregister (file)
 234   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 235
 236
 237 (defun vc-git-checkin (files rev comment)
 238   (let ((coding-system-for-write git-commits-coding-system))
 239     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 240
 241 (defun vc-git-find-revision (file rev buffer)
 242   (let ((coding-system-for-read 'binary)
 243         (coding-system-for-write 'binary)
 244         (fullname (substring
 245                    (vc-git--run-command-string
 246                     file "ls-files" "-z" "--full-name" "--")
 247                    0 -1)))
 248     (vc-git-command
 249      buffer 0
 250      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 251
 252 (defun vc-git-checkout (file &optional editable rev)
 253   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 254
 255 (defun vc-git-revert (file &optional contents-done)
 256   "Revert FILE to the version stored in the git repository."
 257   (if contents-done
 258       (vc-git-command nil 0 file "update-index" "--")
 259     (vc-git-command nil 0 file "checkout" "HEAD")))
 260
 261 ;;; HISTORY FUNCTIONS
 262
 263 (defun vc-git-print-log (files &optional buffer)
 264   "Get change log associated with FILES."
 265   (let ((coding-system-for-read git-commits-coding-system)
 266         ;; Support both the old print-log interface that passes a
 267         ;; single file, and the new one that passes a file list.
 268         (flist (if (listp files) files (list files))))
 269     ;; `vc-do-command' creates the buffer, but we need it before running
 270     ;; the command.
 271     (vc-setup-buffer buffer)
 272     ;; If the buffer exists from a previous invocation it might be
 273     ;; read-only.
 274     (let ((inhibit-read-only t))
 275       ;; XXX `log-view-mode' needs to have something to identify where
 276       ;; the log for each individual file starts. It seems that by
 277       ;; default git does not output this info. So loop here and call
 278       ;; "git rev-list" on each file separately to make sure that each
 279       ;; file gets a "File:" header before the corresponding
 280       ;; log. Maybe there is a way to do this with one command...
 281       (dolist (file flist)
 282         (with-current-buffer
 283             buffer
 284           (insert "File: " (file-name-nondirectory file) "\n"))
 285         (vc-git-command buffer 'async (file-relative-name file)
 286                         "rev-list" "--pretty" "HEAD" "--")))))
 287
 288 (defvar log-view-message-re)
 289 (defvar log-view-file-re)
 290 (defvar log-view-font-lock-keywords)
 291
 292 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 293   (require 'add-log) ;; we need the faces add-log
 294   ;; Don't have file markers, so use impossible regexp.
 295   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 296   (set (make-local-variable 'log-view-message-re)
 297        "^commit *\\([0-9a-z]+\\)")
 298   (set (make-local-variable 'log-view-font-lock-keywords)
 299        (append
 300         `((,log-view-message-re  (1 'change-log-acknowledgement))
 301           (,log-view-file-re (1 'change-log-file-face)))
 302         ;; Handle the case:
 303         ;; user: foo@bar
 304         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 305            (1 'change-log-email))
 306           ;; Handle the case:
 307           ;; user: FirstName LastName <foo@bar>
 308           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 309            (1 'change-log-name)
 310            (2 'change-log-email))
 311           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 312            (1 'change-log-name))
 313           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 314            (1 'change-log-name)
 315            (2 'change-log-email))
 316           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 317            (1 'change-log-acknowledgement)
 318            (2 'change-log-acknowledgement))
 319           ("^Date:   \\(.+\\)" (1 'change-log-date))
 320           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 321
 322 (defun vc-git-show-log-entry (revision)
 323   "Move to the log entry for REVISION.
 324 REVISION may have the form BRANCH, BRANCH~N,
 325 or BRANCH^ (where \"^\" can be repeated)."
 326   (goto-char (point-min))
 327   (search-forward "\ncommit" nil t
 328                   (cond ((string-match "~\\([0-9]\\)$" revision)
 329                          (1+ (string-to-number (match-string 1 revision))))
 330                         ((string-match "\\^+$" revision)
 331                          (1+ (length (match-string 0 revision))))
 332                         (t nil)))
 333   (beginning-of-line))
 334
 335 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 336   (let ((buf (or buffer "*vc-diff*")))
 337     (if (and rev1 rev2)
 338         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 339                         rev1 rev2 "--")
 340       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 341                       (or rev1 "HEAD") "--"))))
 342
 343 (defun vc-git-revision-table (files)
 344   ;; What about `files'?!?  --Stef
 345   (let ((table (list "HEAD")))
 346     (with-temp-buffer
 347       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 348       (goto-char (point-min))
 349       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 350         (push (match-string 2) table)))
 351     table))
 352
 353 (defun vc-git-revision-completion-table (files)
 354   (lexical-let ((files files)
 355                 table)
 356     (setq table (lazy-completion-table
 357                  table (lambda () (vc-git-revision-table files))))
 358     table))
 359
 360 (defun vc-git-annotate-command (file buf &optional rev)
 361   ;; FIXME: rev is ignored
 362   (let ((name (file-relative-name file)))
 363     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 364
 365 (defun vc-git-annotate-time ()
 366   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 367        (vc-annotate-convert-time
 368         (apply #'encode-time (mapcar (lambda (match)
 369                                        (string-to-number (match-string match)))
 370                                      '(6 5 4 3 2 1 7))))))
 371
 372 (defun vc-git-annotate-extract-revision-at-line ()
 373   (save-excursion
 374     (move-beginning-of-line 1)
 375     (and (looking-at "[0-9a-f]+")
 376          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 377
 378 ;;; SNAPSHOT SYSTEM
 379
 380 (defun vc-git-create-snapshot (dir name branchp)
 381   (let ((default-directory dir))
 382     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 383          (if branchp
 384              (vc-git-command nil 0 nil "checkout" "-b" name)
 385            (vc-git-command nil 0 nil "tag" name)))))
 386
 387 (defun vc-git-retrieve-snapshot (dir name update)
 388   (let ((default-directory dir))
 389     (vc-git-command nil 0 nil "checkout" name)
 390     ;; FIXME: update buffers if `update' is true
 391     ))
 392
 393
 394 ;;; MISCELLANEOUS
 395
 396 (defun vc-git-previous-revision (file rev)
 397   "Git-specific version of `vc-previous-revision'."
 398   (let ((default-directory (file-name-directory (expand-file-name file)))
 399         (file (file-name-nondirectory file)))
 400     (vc-git-symbolic-commit
 401      (with-temp-buffer
 402        (and
 403         (vc-git--out-ok "rev-list" "-2" rev "--" file)
 404         (goto-char (point-max))
 405         (bolp)
 406         (zerop (forward-line -1))
 407         (not (bobp))
 408         (buffer-substring-no-properties
 409          (point)
 410          (1- (point-max))))))))
 411
 412 (defun vc-git-next-revision (file rev)
 413   "Git-specific version of `vc-next-revision'."
 414   (let* ((default-directory (file-name-directory
 415                              (expand-file-name file)))
 416          (file (file-name-nondirectory file))
 417          (current-rev
 418           (with-temp-buffer
 419             (and
 420              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 421              (goto-char (point-max))
 422              (bolp)
 423              (zerop (forward-line -1))
 424              (bobp)
 425              (buffer-substring-no-properties
 426               (point)
 427               (1- (point-max)))))))
 428     (and current-rev
 429          (vc-git-symbolic-commit
 430           (with-temp-buffer
 431             (and
 432              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 433              (goto-char (point-min))
 434              (search-forward current-rev nil t)
 435              (zerop (forward-line -1))
 436              (buffer-substring-no-properties
 437               (point)
 438               (progn (forward-line 1) (1- (point))))))))))
 439
 440 (defun vc-git-delete-file (file)
 441   (vc-git-command nil 0 file "rm" "-f" "--"))
 442
 443 (defun vc-git-rename-file (old new)
 444   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 445
 446 \f
 447 ;;; Internal commands
 448
 449 (defun vc-git-root (file)
 450   (vc-find-root file ".git"))
 451
 452 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 453   "A wrapper around `vc-do-command' for use in vc-git.el.
 454 The difference to vc-do-command is that this function always invokes `git'."
 455   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 456
 457 (defun vc-git--call (buffer command &rest args)
 458   (apply 'call-process "git" nil buffer nil command args))
 459
 460 (defun vc-git--out-ok (command &rest args)
 461   (zerop (apply 'vc-git--call '(t nil) command args)))
 462
 463 (defun vc-git--run-command-string (file &rest args)
 464   "Run a git command on FILE and return its output as string."
 465   (let* ((ok t)
 466          (str (with-output-to-string
 467                 (with-current-buffer standard-output
 468                   (unless (apply 'vc-git--out-ok
 469                                  (append args (list (file-relative-name
 470                                                      file))))
 471                     (setq ok nil))))))
 472     (and ok str)))
 473
 474 (defun vc-git-symbolic-commit (commit)
 475   "Translate COMMIT string into symbolic form.
 476 Returns nil if not possible."
 477   (and commit
 478        (with-temp-buffer
 479          (and
 480           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 481           (goto-char (point-min))
 482           (= (forward-line 2) 1)
 483           (bolp)
 484           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 485
 486 (provide 'vc-git)
 487
 488 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 489 ;;; vc-git.el ends here