lisp/term/w32-win.el

   1 ;;; w32-win.el --- parse switches controlling interface with W32 window system
   2
   3 ;; Copyright (C) 1993-1994, 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Kevin Gallo
   6 ;; Keywords: terminals
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; w32-win.el:  this file is loaded from ../lisp/startup.el when it recognizes
  26 ;; that W32 windows are to be used.  Command line switches are parsed and those
  27 ;; pertaining to W32 are processed and removed from the command line.  The
  28 ;; W32 display is opened and hooks are set for popping up the initial window.
  29
  30 ;; startup.el will then examine startup files, and eventually call the hooks
  31 ;; which create the first window (s).
  32
  33 ;;; Code:
  34 \f
  35
  36 ;; These are the standard X switches from the Xt Initialize.c file of
  37 ;; Release 4.
  38
  39 ;; Command line         Resource Manager string
  40
  41 ;; +rv                  *reverseVideo
  42 ;; +synchronous         *synchronous
  43 ;; -background          *background
  44 ;; -bd                  *borderColor
  45 ;; -bg                  *background
  46 ;; -bordercolor         *borderColor
  47 ;; -borderwidth         .borderWidth
  48 ;; -bw                  .borderWidth
  49 ;; -display             .display
  50 ;; -fg                  *foreground
  51 ;; -fn                  *font
  52 ;; -font                *font
  53 ;; -foreground          *foreground
  54 ;; -geometry            .geometry
  55 ;; -i                   .iconType
  56 ;; -itype               .iconType
  57 ;; -iconic              .iconic
  58 ;; -name                .name
  59 ;; -reverse             *reverseVideo
  60 ;; -rv                  *reverseVideo
  61 ;; -selectionTimeout    .selectionTimeout
  62 ;; -synchronous         *synchronous
  63 ;; -xrm
  64
  65 ;; An alist of X options and the function which handles them.  See
  66 ;; ../startup.el.
  67
  68 ;; (if (not (eq window-system 'w32))
  69 ;;     (error "%s: Loading w32-win.el but not compiled for w32" (invocation-name)))
  70
  71 (require 'frame)
  72 (require 'mouse)
  73 (require 'scroll-bar)
  74 (require 'faces)
  75 (require 'select)
  76 (require 'menu-bar)
  77 (require 'dnd)
  78 (require 'w32-vars)
  79
  80 ;; Keep an obsolete alias for w32-focus-frame and w32-select-font in case
  81 ;; they are used by code outside Emacs.
  82 (define-obsolete-function-alias 'w32-focus-frame 'x-focus-frame "23.1")
  83 (declare-function x-select-font "w32font.c"
  84                   (&optional frame exclude-proportional))
  85 (define-obsolete-function-alias 'w32-select-font 'x-select-font "23.1")
  86
  87 (defvar w32-color-map) ;; defined in w32fns.c
  88
  89 (declare-function w32-send-sys-command "w32fns.c")
  90 (declare-function set-message-beep "w32console.c")
  91
  92 ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
  93 (if (fboundp 'new-fontset)
  94     (require 'fontset))
  95
  96 ;; The following definition is used for debugging scroll bar events.
  97 ;(defun w32-handle-scroll-bar-event (event) (interactive "e") (princ event))
  98
  99 ;; (defun w32-drag-n-drop-debug (event)
 100 ;;   "Print the drag-n-drop EVENT in a readable form."
 101 ;;   (interactive "e")
 102 ;;   (princ event))
 103
 104 (defun w32-drag-n-drop (event)
 105   "Edit the files listed in the drag-n-drop EVENT.
 106 Switch to a buffer editing the last file dropped."
 107   (interactive "e")
 108   (save-excursion
 109     ;; Make sure the drop target has positive co-ords
 110     ;; before setting the selected frame - otherwise it
 111     ;; won't work.  <skx@tardis.ed.ac.uk>
 112     (let* ((window (posn-window (event-start event)))
 113            (coords (posn-x-y (event-start event)))
 114            (x (car coords))
 115            (y (cdr coords)))
 116       (if (and (> x 0) (> y 0))
 117           (set-frame-selected-window nil window))
 118       (mapc (lambda (file-name)
 119                 (let ((f (subst-char-in-string ?\\ ?/ file-name))
 120                       (coding (or file-name-coding-system
 121                                   default-file-name-coding-system)))
 122                   (setq file-name
 123                         (mapconcat 'url-hexify-string
 124                                    (split-string (encode-coding-string f coding)
 125                                                  "/")
 126                                    "/")))
 127                 (dnd-handle-one-url window 'private
 128                                     (concat "file:" file-name)))
 129                 (car (cdr (cdr event)))))
 130   (raise-frame)))
 131
 132 (defun w32-drag-n-drop-other-frame (event)
 133   "Edit the files listed in the drag-n-drop EVENT, in other frames.
 134 May create new frames, or reuse existing ones.  The frame editing
 135 the last file dropped is selected."
 136   (interactive "e")
 137   (mapcar 'find-file-other-frame (car (cdr (cdr event)))))
 138
 139 ;; Bind the drag-n-drop event.
 140 (global-set-key [drag-n-drop] 'w32-drag-n-drop)
 141 (global-set-key [C-drag-n-drop] 'w32-drag-n-drop-other-frame)
 142
 143 ;; Keyboard layout/language change events
 144 ;; For now ignore language-change events; in the future
 145 ;; we should switch the Emacs Input Method to match the
 146 ;; new layout/language selected by the user.
 147 (global-set-key [language-change] 'ignore)
 148
 149 (defvar x-resource-name)
 150
 151 \f
 152 ;;;; Function keys
 153
 154  ;;; make f10 activate the real menubar rather than the mini-buffer menu
 155  ;;; navigation feature.
 156  (defun w32-menu-bar-open (&optional frame)
 157    "Start key navigation of the menu bar in FRAME.
 158
 159 This initially activates the first menu-bar item, and you can then navigate
 160 with the arrow keys, select a menu entry with the Return key or cancel with
 161 the Escape key.  If FRAME has no menu bar, this function does nothing.
 162
 163 If FRAME is nil or not given, use the selected frame.
 164 If FRAME does not have the menu bar enabled, display a text menu using
 165 `tmm-menubar'."
 166    (interactive "i")
 167    (if menu-bar-mode
 168        (w32-send-sys-command ?\xf100 frame)
 169      (with-selected-frame (or frame (selected-frame))
 170        (tmm-menubar))))
 171 \f
 172
 173 ;; W32 systems have different fonts than commonly found on X, so
 174 ;; we define our own standard fontset here.
 175 (defvar w32-standard-fontset-spec
 176  "-*-Courier New-normal-r-*-*-13-*-*-*-c-*-fontset-standard"
 177  "String of fontset spec of the standard fontset.
 178 This defines a fontset consisting of the Courier New variations for
 179 European languages which are distributed with Windows as
 180 \"Multilanguage Support\".
 181
 182 See the documentation of `create-fontset-from-fontset-spec' for the format.")
 183
 184 (defun x-win-suspend-error ()
 185   "Report an error when a suspend is attempted."
 186   (error "Suspending an Emacs running under W32 makes no sense"))
 187
 188 (defvar dynamic-library-alist)
 189 (defvar libpng-version)                 ; image.c #ifdef HAVE_NTGUI
 190
 191 ;;; Set default known names for external libraries
 192 (setq dynamic-library-alist
 193       (list
 194        '(xpm "libxpm.dll" "xpm4.dll" "libXpm-nox4.dll")
 195        ;; Versions of libpng 1.4.x and later are incompatible with
 196        ;; earlier versions.  Set up the list of libraries according to
 197        ;; the version we were compiled against.  (If we were compiled
 198        ;; without PNG support, libpng-version's value is -1.)
 199        (if (>= libpng-version 10400)
 200            ;; libpng14-14.dll is libpng 1.4.3 from GTK+
 201            '(png "libpng14-14.dll" "libpng14.dll")
 202          '(png "libpng12d.dll" "libpng12.dll" "libpng3.dll" "libpng.dll"
 203                ;; these are libpng 1.2.8 from GTK+
 204                "libpng13d.dll" "libpng13.dll"))
 205         '(jpeg "jpeg62.dll" "libjpeg.dll" "jpeg-62.dll" "jpeg.dll")
 206         '(tiff "libtiff3.dll" "libtiff.dll")
 207         '(gif "giflib4.dll" "libungif4.dll" "libungif.dll")
 208         '(svg "librsvg-2-2.dll")
 209         '(gdk-pixbuf "libgdk_pixbuf-2.0-0.dll")
 210         '(glib "libglib-2.0-0.dll")
 211         '(gobject "libgobject-2.0-0.dll")))
 212
 213 ;;; multi-tty support
 214 (defvar w32-initialized nil
 215   "Non-nil if the w32 window system has been initialized.")
 216
 217 (declare-function x-open-connection "w32fns.c"
 218                   (display &optional xrm-string must-succeed))
 219 (declare-function create-fontset-from-fontset-spec "fontset"
 220                   (fontset-spec &optional style-variant noerror))
 221 (declare-function create-fontset-from-x-resource "fontset" ())
 222 (declare-function x-get-resource "frame.c"
 223                   (attribute class &optional component subclass))
 224 (declare-function x-handle-args "common-win" (args))
 225 (declare-function x-parse-geometry "frame.c" (string))
 226 (defvar x-command-line-resources)
 227
 228 (defun w32-initialize-window-system ()
 229   "Initialize Emacs for W32 GUI frames."
 230
 231   ;; Do the actual Windows setup here; the above code just defines
 232   ;; functions and variables that we use now.
 233
 234   (setq command-line-args (x-handle-args command-line-args))
 235
 236   ;; Make sure we have a valid resource name.
 237   (or (stringp x-resource-name)
 238       (setq x-resource-name
 239             ;; Change any . or * characters in x-resource-name to hyphens,
 240             ;; so as not to choke when we use it in X resource queries.
 241             (replace-regexp-in-string "[.*]" "-" (invocation-name))))
 242
 243   (x-open-connection "" x-command-line-resources
 244                      ;; Exit with a fatal error if this fails and we
 245                      ;; are the initial display
 246                      (eq initial-window-system 'w32))
 247
 248   ;; Create the default fontset.
 249   (create-default-fontset)
 250   ;; Create the standard fontset.
 251   (condition-case err
 252       (create-fontset-from-fontset-spec w32-standard-fontset-spec t)
 253     (error (display-warning
 254             'initialization
 255             (format "Creation of the standard fontset failed: %s" err)
 256             :error)))
 257   ;; Create fontset specified in X resources "Fontset-N" (N is 0, 1,...).
 258   (create-fontset-from-x-resource)
 259
 260   ;; Apply a geometry resource to the initial frame.  Put it at the end
 261   ;; of the alist, so that anything specified on the command line takes
 262   ;; precedence.
 263   (let* ((res-geometry (x-get-resource "geometry" "Geometry"))
 264          parsed)
 265     (if res-geometry
 266         (progn
 267           (setq parsed (x-parse-geometry res-geometry))
 268           ;; If the resource specifies a position,
 269           ;; call the position and size "user-specified".
 270           (if (or (assq 'top parsed) (assq 'left parsed))
 271               (setq parsed (cons '(user-position . t)
 272                                  (cons '(user-size . t) parsed))))
 273           ;; All geometry parms apply to the initial frame.
 274           (setq initial-frame-alist (append initial-frame-alist parsed))
 275           ;; The size parms apply to all frames.
 276           (if (and (assq 'height parsed)
 277                    (not (assq 'height default-frame-alist)))
 278               (setq default-frame-alist
 279                     (cons (cons 'height (cdr (assq 'height parsed)))
 280                           default-frame-alist))
 281           (if (and (assq 'width parsed)
 282                    (not (assq 'width default-frame-alist)))
 283               (setq default-frame-alist
 284                     (cons (cons 'width (cdr (assq 'width parsed)))
 285                           default-frame-alist)))))))
 286
 287   ;; Check the reverseVideo resource.
 288   (let ((case-fold-search t))
 289     (let ((rv (x-get-resource "reverseVideo" "ReverseVideo")))
 290       (if (and rv (string-match "^\\(true\\|yes\\|on\\)$" rv))
 291           (setq default-frame-alist
 292                 (cons '(reverse . t) default-frame-alist)))))
 293
 294   ;; Don't let Emacs suspend under w32 gui
 295   (add-hook 'suspend-hook 'x-win-suspend-error)
 296
 297   ;; Turn off window-splitting optimization; w32 is usually fast enough
 298   ;; that this is only annoying.
 299   (setq split-window-keep-point t)
 300
 301   ;; W32 expects the menu bar cut and paste commands to use the clipboard.
 302   (menu-bar-enable-clipboard)
 303
 304   ;; Don't show the frame name; that's redundant.
 305   (setq-default mode-line-frame-identification "  ")
 306
 307   ;; Set to a system sound if you want a fancy bell.
 308   (set-message-beep 'ok)
 309   (setq w32-initialized t))
 310
 311 (add-to-list 'handle-args-function-alist '(w32 . x-handle-args))
 312 (add-to-list 'frame-creation-function-alist '(w32 . x-create-frame-with-faces))
 313 (add-to-list 'window-system-initialization-alist '(w32 . w32-initialize-window-system))
 314
 315 (provide 'w32-win)
 316
 317 ;;; w32-win.el ends here