lisp/obsolete/fast-lock.el

   1 ;;; fast-lock.el --- automagic text properties caching for fast Font Lock mode
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Marshall <simon@gnu.org>
   7 ;; Maintainer: FSF
   8 ;; Keywords: faces files
   9 ;; Version: 3.14
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Fast Lock mode is a Font Lock support mode.
  31 ;; It makes visiting a file in Font Lock mode faster by restoring its face text
  32 ;; properties from automatically saved associated Font Lock cache files.
  33 ;;
  34 ;; See caveats and feedback below.
  35 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  36
  37 ;; Installation:
  38 ;;
  39 ;; Put in your ~/.emacs:
  40 ;;
  41 ;; (setq font-lock-support-mode 'fast-lock-mode)
  42 ;;
  43 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  44 ;; so-called "gaudier" fontification regexps on big files without frustration).
  45 ;;
  46 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  47 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  48 ;; will be loaded from that file instead of being generated by Font Lock code.
  49
  50 ;; Caveats:
  51 ;;
  52 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  53 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  54 ;;
  55 ;; Version control packages are likely to stamp all over file modification
  56 ;; times.  Therefore the act of checking out may invalidate a cache.
  57 \f
  58 ;; History:
  59 ;;
  60 ;; 0.02--1.00:
  61 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  62 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  63 ;; 1.00--1.01:
  64 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  65 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  66 ;; - Moved save-all conditions to `fast-lock-save-cache'
  67 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  68 ;; 1.01--2.00: complete rewrite---not worth the space to document
  69 ;; - Changed structure of text properties cache and threw out file mod checks
  70 ;; 2.00--2.01:
  71 ;; - Made `condition-case' forms understand `quit'.
  72 ;; - Made `fast-lock' require `font-lock'
  73 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  74 ;; 2.01--3.00:
  75 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  76 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  77 ;; - Removed `fast-lock-read-others'
  78 ;; - Made `fast-lock-read-cache' ignore cache owner
  79 ;; - Made `fast-lock-save-cache-external' create cache directory
  80 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  81 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  82 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  83 ;; - Package now provides itself
  84 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  85 ;; - Lucid: Use `list-faces' for `face-list'
  86 ;; - Lucid: Added `set-text-properties'
  87 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  88 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  89 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  90 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  91 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  92 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  93 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
  94 ;; 3.02--3.03:
  95 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
  96 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
  97 ;; 3.03--3.04:
  98 ;; - Corrected `subrp' test of Lucid code
  99 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
 100 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
 101 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 102 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 103 ;; 3.04--3.05:
 104 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 105 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 106 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 107 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 108 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 109 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 110 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 111 ;; - XEmacs: Removed `list-faces' `defalias'
 112 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 113 ;; - Added `fast-lock-submit-bug-report'
 114 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 115 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 116 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 117 ;; - Made `fast-lock-cache-data' output a message if load attempted
 118 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 119 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 120 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 121 ;; - Added `fast-lock-save-events'
 122 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 123 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 124 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 125 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 126 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 127 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 128 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 129 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 130 ;; - Added `fast-lock-after-fontify-buffer'
 131 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 132 ;; - Made `fast-lock-get-face-properties' functions use it
 133 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 134 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 135 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 136 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 137 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 138 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 139 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 140 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 141 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 142 ;; 3.06--3.07:
 143 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 144 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 145 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 146 ;; 3.07--3.08:
 147 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 148 ;; 3.08--3.09:
 149 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
 150 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 151 ;; - Added `fast-lock-after-unfontify-buffer'
 152 ;; 3.09--3.10:
 153 ;; - Rewrite for Common Lisp macros
 154 ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
 155 ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
 156 ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
 157 ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
 158 ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
 159 ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
 160 ;; 3.10--3.11:
 161 ;; - Made `fast-lock-get-face-properties' cope with face lists
 162 ;; - Added `fast-lock-verbose'
 163 ;; - XEmacs: Add `font-lock-value-in-major-mode' if necessary
 164 ;; - Removed `fast-lock-submit-bug-report' and bade farewell
 165 ;; 3.11--3.12:
 166 ;; - Added Custom support (Hrvoje Niksic help)
 167 ;; - Made `save-buffer-state' wrap `inhibit-point-motion-hooks'
 168 ;; - Made `fast-lock-cache-data' simplify calls of `font-lock-compile-keywords'
 169 ;; 3.12--3.13:
 170 ;; - Removed `byte-*' variables from `eval-when-compile' (Erik Naggum hint)
 171 ;; - Changed structure of cache to include `font-lock-syntactic-keywords'
 172 ;; - Made `fast-lock-save-cache-1' save syntactic fontification data
 173 ;; - Made `fast-lock-cache-data' take syntactic fontification data
 174 ;; - Added `fast-lock-get-syntactic-properties'
 175 ;; - Renamed `fast-lock-set-face-properties' to `fast-lock-add-properties'
 176 ;; - Made `fast-lock-add-properties' add syntactic and face fontification data
 177 ;; 3.13--3.14:
 178 ;; - Made `fast-lock-cache-name' cope with `windowsnt' (Geoff Voelker fix)
 179 ;; - Made `fast-lock-verbose' use `other' widget (Andreas Schwab fix)
 180 ;; - Used `with-temp-message' where possible to make messages temporary.
 181 \f
 182 ;;; Code:
 183
 184 (require 'font-lock)
 185
 186 (declare-function msdos-long-file-names "msdos.c")
 187
 188 ;; Make sure fast-lock.el is supported.
 189 (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 190     (error "`fast-lock' was written for long file name systems"))
 191
 192 (defvar font-lock-face-list)
 193
 194 (eval-when-compile
 195  ;;
 196  ;; We don't do this at the top-level as we only use non-autoloaded macros.
 197  (require 'cl)
 198  ;;
 199  ;; We use this to preserve or protect things when modifying text properties.
 200  (defmacro save-buffer-state (varlist &rest body)
 201    "Bind variables according to VARLIST and eval BODY restoring buffer state."
 202    `(let* (,@(append varlist
 203                      '((modified (buffer-modified-p)) (buffer-undo-list t)
 204                        (inhibit-read-only t) (inhibit-point-motion-hooks t)
 205                        before-change-functions after-change-functions
 206                        deactivate-mark buffer-file-name buffer-file-truename)))
 207      ,@body
 208      (when (and (not modified) (buffer-modified-p))
 209        (set-buffer-modified-p nil))))
 210  (put 'save-buffer-state 'lisp-indent-function 1)
 211  ;;
 212  ;; We use this to verify that a face should be saved.
 213  (defmacro fast-lock-save-facep (face)
 214    "Return non-nil if FACE is one of `fast-lock-save-faces'."
 215    `(or (null fast-lock-save-faces)
 216      (if (symbolp ,face)
 217          (memq ,face fast-lock-save-faces)
 218          (let ((faces ,face))
 219            (while (unless (memq (car faces) fast-lock-save-faces)
 220                     (setq faces (cdr faces))))
 221            faces)))))
 222
 223 ;;(defun fast-lock-submit-bug-report ()
 224 ;;  "Submit via mail a bug report on fast-lock.el."
 225 ;;  (interactive)
 226 ;;  (let ((reporter-prompt-for-summary-p t))
 227 ;;    (reporter-submit-bug-report "simon@gnu.org" "fast-lock 3.14"
 228 ;;     '(fast-lock-cache-directories fast-lock-minimum-size
 229 ;;       fast-lock-save-others fast-lock-save-events fast-lock-save-faces
 230 ;;       fast-lock-verbose)
 231 ;;     nil nil
 232 ;;     (concat "Hi Si.,
 233 ;;
 234 ;;I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 235 ;;know how to make a clear and unambiguous report.  To reproduce the bug:
 236 ;;
 237 ;;Start a fresh editor via `" invocation-name " -no-init-file -no-site-file'.
 238 ;;In the `*scratch*' buffer, evaluate:"))))
 239
 240 (defgroup fast-lock nil
 241   "Font Lock support mode to cache fontification."
 242   :load 'fast-lock
 243   :group 'font-lock)
 244
 245 (defvar fast-lock-mode nil)             ; Whether we are turned on.
 246 (defvar fast-lock-cache-timestamp nil)  ; For saving/reading.
 247 (defvar fast-lock-cache-filename nil)   ; For deleting.
 248 \f
 249 ;; User Variables:
 250
 251 (defcustom fast-lock-minimum-size 25600
 252   "*Minimum size of a buffer for cached fontification.
 253 Only buffers more than this can have associated Font Lock cache files saved.
 254 If nil, means cache files are never created.
 255 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 256 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 257  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
 258 means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
 259 for buffers in Rmail mode, and size is irrelevant otherwise."
 260   :type '(choice (const :tag "none" nil)
 261                  (integer :tag "size")
 262                  (repeat :menu-tag "mode specific" :tag "mode specific"
 263                          :value ((t . nil))
 264                          (cons :tag "Instance"
 265                                (radio :tag "Mode"
 266                                       (const :tag "all" t)
 267                                       (symbol :tag "name"))
 268                                (radio :tag "Size"
 269                                       (const :tag "none" nil)
 270                                       (integer :tag "size")))))
 271   :group 'fast-lock)
 272
 273 (defcustom fast-lock-cache-directories '("." "~/.emacs-flc")
 274 ; - `internal', keep each file's Font Lock cache file in the same file.
 275 ; - `external', keep each file's Font Lock cache file in the same directory.
 276   "*Directories in which Font Lock cache files are saved and read.
 277 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 278 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 279
 280 An attempt will be made to save or read Font Lock cache files using these items
 281 until one succeeds (i.e., until a readable or writable one is found).  If an
 282 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 283 For example:
 284
 285  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 286    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 287     =>
 288  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 289
 290 would cause a file's current directory to be used if the file is under your
 291 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'."
 292   :type '(repeat (radio (directory :tag "directory")
 293                         (cons :tag "Matching"
 294                               (regexp :tag "regexp")
 295                               (directory :tag "directory"))))
 296   :group 'fast-lock)
 297
 298 (defcustom fast-lock-save-events '(kill-buffer kill-emacs)
 299   "*Events under which caches will be saved.
 300 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 301 If concurrent editing sessions use the same associated cache file for a file's
 302 buffer, then you should add `save-buffer' to this list."
 303   :type '(set (const :tag "buffer saving" save-buffer)
 304               (const :tag "buffer killing" kill-buffer)
 305               (const :tag "emacs killing" kill-emacs))
 306   :group 'fast-lock)
 307
 308 (defcustom fast-lock-save-others t
 309   "*If non-nil, save Font Lock cache files irrespective of file owner.
 310 If nil, means only buffer files known to be owned by you can have associated
 311 Font Lock cache files saved.  Ownership may be unknown for networked files."
 312   :type 'boolean
 313   :group 'fast-lock)
 314
 315 (defcustom fast-lock-verbose font-lock-verbose
 316   "*If non-nil, means show status messages for cache processing.
 317 If a number, only buffers greater than this size have processing messages."
 318   :type '(choice (const :tag "never" nil)
 319                  (other :tag "always" t)
 320                  (integer :tag "size"))
 321   :group 'fast-lock)
 322
 323 (defvar fast-lock-save-faces
 324   (when (featurep 'xemacs)
 325     ;; XEmacs uses extents for everything, so we have to pick the right ones.
 326     font-lock-face-list)
 327   "Faces that will be saved in a Font Lock cache file.
 328 If nil, means information for all faces will be saved.")
 329 \f
 330 ;; User Functions:
 331
 332 ;;;###autoload
 333 (defun fast-lock-mode (&optional arg)
 334   "Toggle Fast Lock mode.
 335 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 336 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 337
 338  (setq font-lock-support-mode 'fast-lock-mode)
 339
 340 If Fast Lock mode is enabled, and the current buffer does not contain any text
 341 properties, any associated Font Lock cache is used if its timestamp matches the
 342 buffer's file, and its `font-lock-keywords' match those that you are using.
 343
 344 Font Lock caches may be saved:
 345 - When you save the file's buffer.
 346 - When you kill an unmodified file's buffer.
 347 - When you exit Emacs, for all unmodified or saved buffers.
 348 Depending on the value of `fast-lock-save-events'.
 349 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 350
 351 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 352
 353 Various methods of control are provided for the Font Lock cache.  In general,
 354 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 355 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 356 `fast-lock-save-others' and `fast-lock-save-faces'."
 357   (interactive "P")
 358   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 359   ;; but many packages temporarily wrap that to nil when doing their own thing.
 360   (set (make-local-variable 'fast-lock-mode)
 361        (and buffer-file-truename
 362             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 363             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 364   (if (and fast-lock-mode (not font-lock-mode))
 365       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
 366       (progn
 367         (message "Use font-lock-support-mode rather than calling fast-lock-mode")
 368         (sit-for 2))
 369     ;; Let's get down to business.
 370     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 371     (set (make-local-variable 'fast-lock-cache-filename) nil)
 372     (when (and fast-lock-mode (not font-lock-fontified))
 373       (fast-lock-read-cache))))
 374
 375 (defun fast-lock-read-cache ()
 376   "Read the Font Lock cache for the current buffer.
 377
 378 The following criteria must be met for a Font Lock cache file to be read:
 379 - Fast Lock mode must be turned on in the buffer.
 380 - The buffer must not be modified.
 381 - The buffer's `font-lock-keywords' must match the cache's.
 382 - The buffer file's timestamp must match the cache's.
 383 - Criteria imposed by `fast-lock-cache-directories'.
 384
 385 See `fast-lock-mode'."
 386   (interactive)
 387   (let ((directories fast-lock-cache-directories)
 388         (modified (buffer-modified-p)) (inhibit-read-only t)
 389         (fontified font-lock-fontified))
 390     (set (make-local-variable 'font-lock-fontified) nil)
 391     ;; Keep trying directories until fontification is turned off.
 392     (while (and directories (not font-lock-fontified))
 393       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 394         (condition-case nil
 395             (when directory
 396               (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 397               (when (file-readable-p fast-lock-cache-filename)
 398                 (load fast-lock-cache-filename t t t)))
 399           (error nil) (quit nil))
 400         (setq directories (cdr directories))))
 401     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 402     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 403     ;; of `fast-lock-cache-timestamp'.)
 404     (set-buffer-modified-p modified)
 405     (unless font-lock-fontified
 406       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 407
 408 (defun fast-lock-save-cache (&optional buffer)
 409   "Save the Font Lock cache of BUFFER or the current buffer.
 410
 411 The following criteria must be met for a Font Lock cache file to be saved:
 412 - Fast Lock mode must be turned on in the buffer.
 413 - The event must be one of `fast-lock-save-events'.
 414 - The buffer must be at least `fast-lock-minimum-size' bytes long.
 415 - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 416 - The buffer must contain at least one `face' text property.
 417 - The buffer must not be modified.
 418 - The buffer file's timestamp must be the same as the file's on disk.
 419 - The on disk file's timestamp must be different than the buffer's cache.
 420 - Criteria imposed by `fast-lock-cache-directories'.
 421
 422 See `fast-lock-mode'."
 423   (interactive)
 424   (save-excursion
 425     (when buffer
 426       (set-buffer buffer))
 427     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
 428           (file-timestamp (visited-file-modtime)) (saved nil))
 429       (when (and fast-lock-mode
 430              ;;
 431              ;; "Only save if the buffer matches the file, the file has
 432              ;; changed, and it was changed by the current emacs session."
 433              ;;
 434              ;; Only save if the buffer is not modified,
 435              ;; (i.e., so we don't save for something not on disk)
 436              (not (buffer-modified-p))
 437              ;; and the file's timestamp is the same as the buffer's,
 438              ;; (i.e., someone else hasn't written the file in the meantime)
 439              (verify-visited-file-modtime (current-buffer))
 440              ;; and the file's timestamp is different from the cache's.
 441              ;; (i.e., a save has occurred since the cache was read)
 442              (not (equal fast-lock-cache-timestamp file-timestamp))
 443              ;;
 444              ;; Only save if user's restrictions are satisfied.
 445              (and min-size (>= (buffer-size) min-size))
 446              (or fast-lock-save-others
 447                  (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 448              ;;
 449              ;; Only save if there are `face' properties to save.
 450              (text-property-not-all (point-min) (point-max) 'face nil))
 451         ;;
 452         ;; Try each directory until we manage to save or the user quits.
 453         (let ((directories fast-lock-cache-directories))
 454           (while (and directories (memq saved '(nil error)))
 455             (let* ((dir (fast-lock-cache-directory (car directories) t))
 456                    (file (and dir (fast-lock-cache-name dir))))
 457               (when (and file (file-writable-p file))
 458                 (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 459               (setq directories (cdr directories)))))))))
 460
 461 ;;;###autoload
 462 (defun turn-on-fast-lock ()
 463   "Unconditionally turn on Fast Lock mode."
 464   (fast-lock-mode t))
 465 \f
 466 ;;; API Functions:
 467
 468 (defun fast-lock-after-fontify-buffer ()
 469   ;; Delete the Font Lock cache file used to restore fontification, if any.
 470   (when fast-lock-cache-filename
 471     (if (file-writable-p fast-lock-cache-filename)
 472         (delete-file fast-lock-cache-filename)
 473       (message "File %s font lock cache cannot be deleted" (buffer-name))))
 474   ;; Flag so that a cache will be saved later even if the file is never saved.
 475   (setq fast-lock-cache-timestamp nil))
 476
 477 (defalias 'fast-lock-after-unfontify-buffer
 478   'ignore)
 479 \f
 480 ;; Miscellaneous Functions:
 481
 482 (defun fast-lock-save-cache-after-save-file ()
 483   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 484   (when (memq 'save-buffer fast-lock-save-events)
 485     (fast-lock-save-cache)))
 486
 487 (defun fast-lock-save-cache-before-kill-buffer ()
 488   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 489   (when (memq 'kill-buffer fast-lock-save-events)
 490     (fast-lock-save-cache)))
 491
 492 (defun fast-lock-save-caches-before-kill-emacs ()
 493   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 494   (when (memq 'kill-emacs fast-lock-save-events)
 495     (mapcar 'fast-lock-save-cache (buffer-list))))
 496
 497 (defun fast-lock-cache-directory (directory create)
 498   "Return usable directory based on DIRECTORY.
 499 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 500 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 501 See `fast-lock-cache-directories'."
 502   (let ((dir
 503          (cond ((not buffer-file-name)
 504                 ;; Should never be nil, but `crypt++' screws it up.
 505                 nil)
 506                ((stringp directory)
 507                 ;; Just a directory.
 508                 directory)
 509                (t
 510                 ;; A directory if the file name matches the regexp.
 511                 (let ((bufile (expand-file-name buffer-file-truename))
 512                       (case-fold-search nil))
 513                   (when (save-match-data (string-match (car directory) bufile))
 514                     (cdr directory)))))))
 515     (cond ((not dir)
 516            nil)
 517           ((file-accessible-directory-p dir)
 518            dir)
 519           (create
 520            (condition-case nil
 521                (progn (make-directory dir t) dir)
 522              (error nil))))))
 523
 524 ;; If you are wondering why we only hash if the directory is not ".", rather
 525 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 526 ;; relative cache directories (that are not ".") then it is possible that more
 527 ;; than one file would have the same cache name in that directory, if the luser
 528 ;; made a link from one relative cache directory to another.  (Phew!)
 529 (defun fast-lock-cache-name (directory)
 530   "Return full cache file name using caching DIRECTORY.
 531 If DIRECTORY is `.', the file name is the buffer file name appended with `.flc'.
 532 Otherwise, the file name is constructed from DIRECTORY and the buffer's true
 533 abbreviated file name, with all `/' characters in the name replaced with `#'
 534 characters, and appended with `.flc'.
 535
 536 If the same file has different cache file names when edited on different
 537 machines, e.g., on one machine the cache file name has the prefix `#home',
 538 perhaps due to automount, try putting in your `~/.emacs' something like:
 539
 540  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 541
 542 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 543
 544 See `fast-lock-cache-directory'."
 545   (if (string-equal directory ".")
 546       (concat buffer-file-name ".flc")
 547     (let* ((bufile (expand-file-name buffer-file-truename))
 548            (chars-alist
 549             (if (memq system-type '(emx windows-nt cygwin))
 550                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 551               '((?/ . (?#)) (?# . (?# ?#)))))
 552            (mapchars
 553             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 554       (concat
 555        (file-name-as-directory (expand-file-name directory))
 556        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 557        ".flc"))))
 558 \f
 559 ;; Font Lock Cache Processing Functions:
 560
 561 ;; The version 3 format of the cache is:
 562 ;;
 563 ;; (fast-lock-cache-data VERSION TIMESTAMP
 564 ;;  font-lock-syntactic-keywords SYNTACTIC-PROPERTIES
 565 ;;  font-lock-keywords FACE-PROPERTIES)
 566
 567 (defun fast-lock-save-cache-1 (file timestamp)
 568   ;; Save the FILE with the TIMESTAMP plus fontification data.
 569   ;; Returns non-nil if a save was attempted to a writable cache file.
 570   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 571         (verbose (if (numberp fast-lock-verbose)
 572                      (> (buffer-size) fast-lock-verbose)
 573                    fast-lock-verbose))
 574         (saved t))
 575     (with-temp-message
 576         (when verbose
 577           (format "Saving %s font lock cache..." (buffer-name)))
 578       (condition-case nil
 579           (save-excursion
 580             (print (list 'fast-lock-cache-data 3
 581                          (list 'quote timestamp)
 582                          (list 'quote font-lock-syntactic-keywords)
 583                          (list 'quote (fast-lock-get-syntactic-properties))
 584                          (list 'quote font-lock-keywords)
 585                          (list 'quote (fast-lock-get-face-properties)))
 586                    tpbuf)
 587             (set-buffer tpbuf)
 588             (write-region (point-min) (point-max) file nil 'quietly)
 589             (setq fast-lock-cache-timestamp timestamp
 590                   fast-lock-cache-filename file))
 591         (error (setq saved 'error)) (quit (setq saved 'quit)))
 592       (kill-buffer tpbuf))
 593     (cond ((eq saved 'quit)
 594            (message "Saving %s font lock cache...quit" (buffer-name)))
 595           ((eq saved 'error)
 596            (message "Saving %s font lock cache...failed" (buffer-name))))
 597     ;; We return non-nil regardless of whether a failure occurred.
 598     saved))
 599
 600 (defun fast-lock-cache-data (version timestamp
 601                              syntactic-keywords syntactic-properties
 602                              keywords face-properties
 603                              &rest ignored)
 604   ;; Find value of syntactic keywords in case it is a symbol.
 605   (setq font-lock-syntactic-keywords (font-lock-eval-keywords
 606                                       font-lock-syntactic-keywords))
 607   ;; Compile all keywords in case some are and some aren't.
 608   (when font-lock-syntactic-keywords
 609     (setq font-lock-syntactic-keywords (font-lock-compile-keywords
 610                                         font-lock-syntactic-keywords t)))
 611   (when syntactic-keywords
 612     (setq syntactic-keywords (font-lock-compile-keywords syntactic-keywords t)))
 613   (setq font-lock-keywords (font-lock-compile-keywords font-lock-keywords)
 614         keywords (font-lock-compile-keywords keywords))
 615   ;; Use the Font Lock cache SYNTACTIC-PROPERTIES and FACE-PROPERTIES if we're
 616   ;; using cache VERSION format 3, the current buffer's file timestamp matches
 617   ;; the TIMESTAMP, the current buffer's `font-lock-syntactic-keywords' are the
 618   ;; same as SYNTACTIC-KEYWORDS, and the current buffer's `font-lock-keywords'
 619   ;; are the same as KEYWORDS.
 620   (let ((buf-timestamp (visited-file-modtime))
 621         (verbose (if (numberp fast-lock-verbose)
 622                      (> (buffer-size) fast-lock-verbose)
 623                    fast-lock-verbose))
 624         (loaded t))
 625     (if (or (/= version 3)
 626             (buffer-modified-p)
 627             (not (equal timestamp buf-timestamp))
 628             (not (equal syntactic-keywords font-lock-syntactic-keywords))
 629             (not (equal keywords font-lock-keywords)))
 630         (setq loaded nil)
 631       (with-temp-message
 632           (when verbose
 633             (format "Loading %s font lock cache..." (buffer-name)))
 634         (condition-case nil
 635             (fast-lock-add-properties syntactic-properties face-properties)
 636           (error (setq loaded 'error)) (quit (setq loaded 'quit))))
 637       (cond ((eq loaded 'quit)
 638              (message "Loading %s font lock cache...quit" (buffer-name)))
 639             ((eq loaded 'error)
 640              (message "Loading %s font lock cache...failed" (buffer-name)))))
 641     (setq font-lock-fontified (eq loaded t)
 642           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 643 \f
 644 ;; Text Properties Processing Functions:
 645
 646 ;; This is fast, but fails if adjacent characters have different `face' text
 647 ;; properties.  Maybe that's why I dropped it in the first place?
 648 ;(defun fast-lock-get-face-properties ()
 649 ;  "Return a list of `face' text properties in the current buffer.
 650 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 651 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 652 ;  (save-restriction
 653 ;    (widen)
 654 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 655 ;         (limit (point-max)) end properties value cell)
 656 ;      (while start
 657 ;       (setq end (next-single-property-change start 'face nil limit)
 658 ;             value (get-text-property start 'face))
 659 ;       ;; Make, or add to existing, list of regions with same `face'.
 660 ;       (if (setq cell (assq value properties))
 661 ;           (setcdr cell (cons start (cons end (cdr cell))))
 662 ;         (setq properties (cons (list value start end) properties)))
 663 ;       (setq start (next-single-property-change end 'face)))
 664 ;      properties)))
 665
 666 ;; This is slow, but copes if adjacent characters have different `face' text
 667 ;; properties, but fails if they are lists.
 668 ;(defun fast-lock-get-face-properties ()
 669 ;  "Return a list of `face' text properties in the current buffer.
 670 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 671 ;where VALUE is a `face' property value and STARTx and ENDx are positions.
 672 ;Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 673 ;  (save-restriction
 674 ;    (widen)
 675 ;    (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 676 ;         properties regions face start end)
 677 ;      (while faces
 678 ;       (setq face (car faces) faces (cdr faces) regions () end (point-min))
 679 ;       ;; Make a list of start/end regions with `face' property face.
 680 ;       (while (setq start (text-property-any end limit 'face face))
 681 ;         (setq end (or (text-property-not-all start limit 'face face) limit)
 682 ;               regions (cons start (cons end regions))))
 683 ;       ;; Add `face' face's regions, if any, to properties.
 684 ;       (when regions
 685 ;         (push (cons face regions) properties)))
 686 ;      properties)))
 687
 688 (defun fast-lock-get-face-properties ()
 689   "Return a list of `face' text properties in the current buffer.
 690 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 691 where VALUE is a `face' property value and STARTx and ENDx are positions."
 692   (save-restriction
 693     (widen)
 694     (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 695           end properties value cell)
 696       (while start
 697         (setq end (next-single-property-change start 'face nil (point-max))
 698               value (get-text-property start 'face))
 699         ;; Make, or add to existing, list of regions with same `face'.
 700         (cond ((setq cell (assoc value properties))
 701                (setcdr cell (cons start (cons end (cdr cell)))))
 702               ((fast-lock-save-facep value)
 703                (push (list value start end) properties)))
 704         (setq start (text-property-not-all end (point-max) 'face nil)))
 705       properties)))
 706
 707 (defun fast-lock-get-syntactic-properties ()
 708   "Return a list of `syntax-table' text properties in the current buffer.
 709 See `fast-lock-get-face-properties'."
 710   (save-restriction
 711     (widen)
 712     (let ((start (text-property-not-all (point-min) (point-max) 'syntax-table
 713                                         nil))
 714           end properties value cell)
 715       (while start
 716         (setq end (next-single-property-change start 'syntax-table nil
 717                                                (point-max))
 718               value (get-text-property start 'syntax-table))
 719         ;; Make, or add to existing, list of regions with same `syntax-table'.
 720         (if (setq cell (assoc value properties))
 721             (setcdr cell (cons start (cons end (cdr cell))))
 722           (push (list value start end) properties))
 723         (setq start (text-property-not-all end (point-max) 'syntax-table nil)))
 724       properties)))
 725
 726 (defun fast-lock-add-properties (syntactic-properties face-properties)
 727   "Add `syntax-table' and `face' text properties to the current buffer.
 728 Any existing `syntax-table' and `face' text properties are removed first.
 729 See `fast-lock-get-face-properties'."
 730   (save-buffer-state (plist regions)
 731     (save-restriction
 732       (widen)
 733       (font-lock-unfontify-region (point-min) (point-max))
 734       ;;
 735       ;; Set the `syntax-table' property for each start/end region.
 736       (while syntactic-properties
 737         (setq plist (list 'syntax-table (car (car syntactic-properties)))
 738               regions (cdr (car syntactic-properties))
 739               syntactic-properties (cdr syntactic-properties))
 740         (while regions
 741           (add-text-properties (nth 0 regions) (nth 1 regions) plist)
 742           (setq regions (nthcdr 2 regions))))
 743       ;;
 744       ;; Set the `face' property for each start/end region.
 745       (while face-properties
 746         (setq plist (list 'face (car (car face-properties)))
 747               regions (cdr (car face-properties))
 748               face-properties (cdr face-properties))
 749         (while regions
 750           (add-text-properties (nth 0 regions) (nth 1 regions) plist)
 751           (setq regions (nthcdr 2 regions)))))))
 752 \f
 753 ;; Functions for XEmacs:
 754
 755 (when (featurep 'xemacs)
 756   ;;
 757   ;; It would be better to use XEmacs' `map-extents' over extents with a
 758   ;; `font-lock' property, but `face' properties are on different extents.
 759   (defun fast-lock-get-face-properties ()
 760     "Return a list of `face' text properties in the current buffer.
 761 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 762 where VALUE is a `face' property value and STARTx and ENDx are positions.
 763 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 764     (save-restriction
 765       (widen)
 766       (let ((properties ()) cell)
 767         (map-extents
 768          (function (lambda (extent ignore)
 769             (let ((value (extent-face extent)))
 770               ;; We're only interested if it's one of `fast-lock-save-faces'.
 771               (when (and value (fast-lock-save-facep value))
 772                 (let ((start (extent-start-position extent))
 773                       (end (extent-end-position extent)))
 774                   ;; Make or add to existing list of regions with the same
 775                   ;; `face' property value.
 776                   (if (setq cell (assoc value properties))
 777                       (setcdr cell (cons start (cons end (cdr cell))))
 778                     (push (list value start end) properties))))
 779               ;; Return nil to keep `map-extents' going.
 780               nil))))
 781         properties)))
 782   ;;
 783   ;; XEmacs does not support the `syntax-table' text property.
 784   (defalias 'fast-lock-get-syntactic-properties
 785     'ignore)
 786   ;;
 787   ;; Make extents just like XEmacs' font-lock.el does.
 788   (defun fast-lock-add-properties (syntactic-properties face-properties)
 789     "Set `face' text properties in the current buffer.
 790 Any existing `face' text properties are removed first.
 791 See `fast-lock-get-face-properties'."
 792     (save-restriction
 793       (widen)
 794       (font-lock-unfontify-region (point-min) (point-max))
 795       ;; Set the `face' property, etc., for each start/end region.
 796       (while face-properties
 797         (let ((face (car (car face-properties)))
 798               (regions (cdr (car face-properties))))
 799           (while regions
 800             (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 801             (setq regions (nthcdr 2 regions)))
 802           (setq face-properties (cdr face-properties))))
 803       ;; XEmacs does not support the `syntax-table' text property.
 804       ))
 805   ;;
 806   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 807   (add-hook 'font-lock-after-fontify-buffer-hook
 808             'fast-lock-after-fontify-buffer))
 809
 810 (unless (boundp 'font-lock-syntactic-keywords)
 811   (defvar font-lock-syntactic-keywords nil))
 812
 813 (unless (boundp 'font-lock-inhibit-thing-lock)
 814   (defvar font-lock-inhibit-thing-lock nil))
 815
 816 (unless (fboundp 'font-lock-compile-keywords)
 817   (defalias 'font-lock-compile-keywords 'identity))
 818
 819 (unless (fboundp 'font-lock-eval-keywords)
 820   (defun font-lock-eval-keywords (keywords)
 821     (if (symbolp keywords)
 822         (font-lock-eval-keywords (if (fboundp keywords)
 823                                      (funcall keywords)
 824                                    (eval keywords)))
 825       keywords)))
 826
 827 (unless (fboundp 'font-lock-value-in-major-mode)
 828   (defun font-lock-value-in-major-mode (alist)
 829     (if (consp alist)
 830         (cdr (or (assq major-mode alist) (assq t alist)))
 831       alist)))
 832
 833 (unless (fboundp 'current-message)
 834   (defun current-message ()
 835     ""))
 836 \f
 837 ;; Install ourselves:
 838
 839 (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
 840 (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
 841 (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
 842
 843 ;;;###autoload
 844 (when (fboundp 'add-minor-mode)
 845   (defvar fast-lock-mode nil)
 846   (add-minor-mode 'fast-lock-mode nil))
 847 ;;;###dont-autoload
 848 (unless (assq 'fast-lock-mode minor-mode-alist)
 849   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 850
 851 ;; Provide ourselves:
 852
 853 (provide 'fast-lock)
 854
 855 ;; arch-tag: 638c431e-8cae-4538-80a1-963ff97d233e
 856 ;;; fast-lock.el ends here