lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996-1999, 2004-2014 Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 ;; (require 'url)
  27 (require 'url-parse)
  28 ;; (require 'url-util)
  29 (eval-when-compile (require 'mm-decode))
  30 ;; (require 'mailcap)
  31 ;; The following are autoloaded instead of `require'd to avoid eagerly
  32 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  33 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  34 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  35 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  36 (autoload 'url-http-parse-response "url-http" "Parse just the response code.")
  37
  38 ;; Always used after mm-dissect-buffer and defined in the same file.
  39 (declare-function mm-save-part-to-file "mm-decode" (handle file))
  40 (declare-function mm-destroy-parts "mm-decode" (handles))
  41 ;; mm-decode loads mm-bodies.
  42 (declare-function mm-decode-string "mm-bodies" (string charset))
  43 ;; mm-decode loads mail-parse.
  44 (declare-function mail-content-type-get "mail-parse" (ct attribute))
  45
  46 ;; Implementation status
  47 ;; ---------------------
  48 ;; Function                             Status
  49 ;; ------------------------------------------------------------
  50 ;; add-name-to-file                     Needs DAV Bindings
  51 ;; copy-file                            Broken (assumes 1st item is URL)
  52 ;; delete-directory                     Finished (DAV)
  53 ;; delete-file                          Finished (DAV)
  54 ;; diff-latest-backup-file
  55 ;; directory-file-name                  unnecessary (what about VMS)?
  56 ;; directory-files                      Finished (DAV)
  57 ;; dired-call-process
  58 ;; dired-compress-file
  59 ;; dired-uncache
  60 ;; expand-file-name                     Finished
  61 ;; file-accessible-directory-p
  62 ;; file-attributes                      Finished, better with DAV
  63 ;; file-directory-p                     Needs DAV, finished
  64 ;; file-executable-p                    Finished
  65 ;; file-exists-p                        Finished
  66 ;; file-local-copy
  67 ;; file-modes
  68 ;; file-name-all-completions            Finished (DAV)
  69 ;; file-name-as-directory
  70 ;; file-name-completion                 Finished (DAV)
  71 ;; file-name-directory
  72 ;; file-name-nondirectory
  73 ;; file-name-sans-versions              why?
  74 ;; file-newer-than-file-p
  75 ;; file-ownership-preserved-p           No way to know
  76 ;; file-readable-p                      Finished
  77 ;; file-regular-p                       !directory_p
  78 ;; file-remote-p                        Finished
  79 ;; file-symlink-p                       Needs DAV bindings
  80 ;; file-truename                        Needs DAV bindings
  81 ;; file-writable-p                      Check for LOCK?
  82 ;; find-backup-file-name                why?
  83 ;; get-file-buffer                      why?
  84 ;; insert-directory                     Use DAV
  85 ;; insert-file-contents                 Finished
  86 ;; load
  87 ;; make-directory                       Finished (DAV)
  88 ;; make-symbolic-link                   Needs DAV bindings
  89 ;; rename-file                          Finished (DAV)
  90 ;; set-file-modes                       Use mod_dav specific executable flag?
  91 ;; set-visited-file-modtime             Impossible?
  92 ;; shell-command                        Impossible?
  93 ;; unhandled-file-name-directory
  94 ;; vc-registered                        Finished (DAV)
  95 ;; verify-visited-file-modtime
  96 ;; write-region
  97
  98 (defvar url-handler-regexp) ; defined below to avoid recursive load (revno:108572)
  99
 100 ;;;###autoload
 101 (define-minor-mode url-handler-mode
 102   "Toggle using `url' library for URL filenames (URL Handler mode).
 103 With a prefix argument ARG, enable URL Handler mode if ARG is
 104 positive, and disable it otherwise.  If called from Lisp, enable
 105 the mode if ARG is omitted or nil."
 106   :global t :group 'url
 107   ;; Remove old entry, if any.
 108   (setq file-name-handler-alist
 109         (delq (rassq 'url-file-handler file-name-handler-alist)
 110               file-name-handler-alist))
 111   (if url-handler-mode
 112       (push (cons url-handler-regexp 'url-file-handler)
 113             file-name-handler-alist)))
 114
 115 (defcustom url-handler-regexp "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
 116   "Regular expression for URLs handled by `url-handler-mode'.
 117 When URL Handler mode is enabled, this regular expression is
 118 added to `file-name-handler-alist'.
 119
 120 Some valid URL protocols just do not make sense to visit
 121 interactively \(about, data, info, irc, mailto, etc\).  This
 122 regular expression avoids conflicts with local files that look
 123 like URLs \(Gnus is particularly bad at this\)."
 124   :group 'url
 125   :type 'regexp
 126   :set (lambda (symbol value)
 127          (let ((enable url-handler-mode))
 128            (url-handler-mode 0)
 129            (set-default symbol value)
 130            (if enable
 131                (url-handler-mode)))))
 132
 133 (defun url-run-real-handler (operation args)
 134   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 135                                           (if (eq operation inhibit-file-name-operation)
 136                                               inhibit-file-name-handlers)))
 137         (inhibit-file-name-operation operation))
 138     (apply operation args)))
 139
 140 (defvar url-file-handler-load-in-progress nil
 141   "Check for recursive load.")
 142
 143 ;;;###autoload
 144 (defun url-file-handler (operation &rest args)
 145   "Function called from the `file-name-handler-alist' routines.
 146 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 147 the arguments that would have been passed to OPERATION."
 148   ;; Avoid recursive load.
 149   (if (and load-in-progress url-file-handler-load-in-progress)
 150       (url-run-real-handler operation args)
 151     (let ((url-file-handler-load-in-progress load-in-progress)
 152           (fn (get operation 'url-file-handlers))
 153           (val nil)
 154           (hooked nil))
 155       (if (and (not fn) (intern-soft (format "url-%s" operation))
 156                (fboundp (intern-soft (format "url-%s" operation))))
 157           (error "Missing URL handler mapping for %s" operation))
 158       (if fn
 159           (setq hooked t
 160                 val (save-match-data (apply fn args)))
 161         (setq hooked nil
 162               val (url-run-real-handler operation args)))
 163       (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 164                  operation args val)
 165       val)))
 166
 167 (defun url-file-handler-identity (&rest args)
 168   ;; Identity function
 169   (car args))
 170
 171 ;; These are operations that we can fully support
 172 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 173 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 174 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 175 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 176 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 177 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 178 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 179 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 180
 181 ;; These are operations that we do not support yet (DAV!!!)
 182 (put 'file-writable-p 'url-file-handlers 'ignore)
 183 (put 'file-symlink-p 'url-file-handlers 'ignore)
 184 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 185 ;; files and such since we can't do anything clever with them anyway.
 186 (put 'vc-registered 'url-file-handlers 'ignore)
 187
 188 (defun url-handler-expand-file-name (file &optional base)
 189   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 190   ;; there are two interpretations possible: either it's a local "/foo/bar"
 191   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 192   ;; interpretation is the right one, but when working with Emacs file
 193   ;; names, the first is preferred.
 194   (if (file-name-absolute-p file)
 195       (expand-file-name file "/")
 196     (url-expand-file-name file base)))
 197
 198 ;; directory-file-name and file-name-as-directory are kind of hard to
 199 ;; implement really right for URLs since URLs can have repeated / chars.
 200 ;; We'd want the following behavior:
 201 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 202 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 203 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 204 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 205 (defun url-handler-directory-file-name (dir)
 206   ;; When there's more than a single /, just don't touch the slashes at all.
 207   (if (string-match "//\\'" dir) dir
 208     (url-run-real-handler 'directory-file-name (list dir))))
 209
 210 (defun url-handler-unhandled-file-name-directory (filename)
 211   (let ((url (url-generic-parse-url filename)))
 212     (if (equal (url-type url) "file")
 213         ;; `file' URLs are actually local.  The filename part may be ""
 214         ;; which really stands for "/".
 215         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 216         ;; or some name that represents the local host?
 217         (or (file-name-directory (url-filename url)) "/")
 218       ;; All other URLs are not expected to be directly accessible from
 219       ;; a local process.
 220       nil)))
 221
 222 (defun url-handler-file-remote-p (filename &optional identification connected)
 223   (let ((url (url-generic-parse-url filename)))
 224     (if (and (url-type url) (not (equal (url-type url) "file")))
 225         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 226         ;; we ignore it.
 227         (cond
 228          ((eq identification 'method) (url-type url))
 229          ((eq identification 'user) (url-user url))
 230          ((eq identification 'host) (url-host url))
 231          ((eq identification 'localname) (url-filename url))
 232          (t (url-recreate-url
 233              (url-parse-make-urlobj (url-type url) (url-user url) nil
 234                                     (url-host url) (url-port url)))))
 235       ;; If there is no URL type, or it is a "file://" URL, the
 236       ;; filename is expected to be non remote.  A more subtle check
 237       ;; for "file://" URLs could be applied, as said in
 238       ;; `url-handler-unhandled-file-name-directory'.
 239       nil)))
 240
 241 ;; The actual implementation
 242 ;;;###autoload
 243 (defun url-copy-file (url newname &optional ok-if-already-exists
 244                           keep-time preserve-uid-gid)
 245   "Copy URL to NEWNAME.  Both args must be strings.
 246 Signals a `file-already-exists' error if file NEWNAME already exists,
 247 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 248 A number as third arg means request confirmation if NEWNAME already exists.
 249 This is what happens in interactive use with M-x.
 250 Fourth arg KEEP-TIME non-nil means give the new file the same
 251 last-modified time as the old one.  (This works on only some systems.)
 252 Fifth arg PRESERVE-UID-GID is ignored.
 253 A prefix arg makes KEEP-TIME non-nil."
 254   (if (and (file-exists-p newname)
 255            (not ok-if-already-exists))
 256       (error "Opening output file: File already exists, %s" newname))
 257   (let ((buffer (url-retrieve-synchronously url))
 258         (handle nil))
 259     (if (not buffer)
 260         (error "Opening input file: No such file or directory, %s" url))
 261     (with-current-buffer buffer
 262       (setq handle (mm-dissect-buffer t)))
 263     (mm-save-part-to-file handle newname)
 264     (kill-buffer buffer)
 265     (mm-destroy-parts handle)))
 266 (put 'copy-file 'url-file-handlers 'url-copy-file)
 267
 268 ;;;###autoload
 269 (defun url-file-local-copy (url &rest ignored)
 270   "Copy URL into a temporary file on this machine.
 271 Returns the name of the local copy, or nil, if FILE is directly
 272 accessible."
 273   (let ((filename (make-temp-file "url")))
 274     (url-copy-file url filename 'ok-if-already-exists)
 275     filename))
 276 (put 'file-local-copy 'url-file-handlers 'url-file-local-copy)
 277
 278 (defun url-insert (buffer &optional beg end)
 279   "Insert the body of a URL object.
 280 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 281 If the headers specify a coding-system, it is applied to the body before it is inserted.
 282 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 283 of the inserted text and CHARSET is the charset that was specified in the header,
 284 or nil if none was found.
 285 BEG and END can be used to only insert a subpart of the body.
 286 They count bytes from the beginning of the body."
 287   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 288          (data (with-current-buffer (mm-handle-buffer handle)
 289                  (if beg
 290                      (buffer-substring (+ (point-min) beg)
 291                                        (if end (+ (point-min) end) (point-max)))
 292                    (buffer-string))))
 293          (charset (mail-content-type-get (mm-handle-type handle)
 294                                           'charset)))
 295     (mm-destroy-parts handle)
 296     (if charset
 297         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 298       (insert data))
 299     (list (length data) charset)))
 300
 301 ;;;###autoload
 302 (defun url-insert-file-contents (url &optional visit beg end replace)
 303   (let ((buffer (url-retrieve-synchronously url)))
 304     (unless buffer (signal 'file-error (list url "No Data")))
 305     (with-current-buffer buffer
 306       (let ((response (url-http-parse-response)))
 307         (if (and (>= response 200) (< response 300))
 308             (goto-char (point-min))
 309           (let ((desc (buffer-substring-no-properties (1+ (point))
 310                                                       (line-end-position))))
 311             (kill-buffer buffer)
 312             (signal 'file-error (list url desc))))))
 313     (if visit (setq buffer-file-name url))
 314     (save-excursion
 315       (let* ((start (point))
 316              (size-and-charset (url-insert buffer beg end)))
 317         (kill-buffer buffer)
 318         (when replace
 319           (delete-region (point-min) start)
 320           (delete-region (point) (point-max)))
 321         (unless (cadr size-and-charset)
 322           ;; If the headers don't specify any particular charset, use the
 323           ;; usual heuristic/rules that we apply to files.
 324           (decode-coding-inserted-region start (point) url visit beg end replace))
 325         (list url (car size-and-charset))))))
 326 (put 'insert-file-contents 'url-file-handlers 'url-insert-file-contents)
 327
 328 (defun url-file-name-completion (url directory &optional predicate)
 329   ;; Even if it's not implemented, it's not an error to ask for completion,
 330   ;; in case it's available (bug#14806).
 331   ;; (error "Unimplemented")
 332   url)
 333 (put 'file-name-completion 'url-file-handlers 'url-file-name-completion)
 334
 335 (defun url-file-name-all-completions (file directory)
 336   ;; Even if it's not implemented, it's not an error to ask for completion,
 337   ;; in case it's available (bug#14806).
 338   ;; (error "Unimplemented")
 339   nil)
 340 (put 'file-name-all-completions
 341      'url-file-handlers 'url-file-name-all-completions)
 342
 343 ;; All other handlers map onto their respective backends.
 344 (defmacro url-handlers-create-wrapper (method args)
 345   `(progn
 346      (defun ,(intern (format "url-%s" method)) ,args
 347        ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 348                 (or (documentation method t) "No original documentation."))
 349        (setq url (url-generic-parse-url url))
 350        (when (url-type url)
 351          (funcall (url-scheme-get-property (url-type url) (quote ,method))
 352                   ,@(remove '&rest (remove '&optional args)))))
 353      (unless (get ',method 'url-file-handlers)
 354        (put ',method 'url-file-handlers ',(intern (format "url-%s" method))))))
 355
 356 (url-handlers-create-wrapper file-exists-p (url))
 357 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 358 (url-handlers-create-wrapper file-symlink-p (url))
 359 (url-handlers-create-wrapper file-writable-p (url))
 360 (url-handlers-create-wrapper file-directory-p (url))
 361 (url-handlers-create-wrapper file-executable-p (url))
 362 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 363 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 364
 365 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 366
 367 (defun url-handlers-set-buffer-mode ()
 368   "Set correct modes for the current buffer if visiting a remote file."
 369   (and (stringp buffer-file-name)
 370        (string-match url-handler-regexp buffer-file-name)
 371        (auto-save-mode 0)))
 372
 373 (provide 'url-handlers)
 374
 375 ;;; url-handlers.el ends here