configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 148 if test "$with_wide_int" = yes; then
 149   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 150 fi
 151
 152 dnl _ON results in a '--without' option in the --help output, so
 153 dnl the help text should refer to "don't compile", etc.
 154 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 155 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 156 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 157 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 158 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 159 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 160 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 161 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 162
 163 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 164 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 165 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 166
 167 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 168 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 169 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 170 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 171
 172 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 173 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 174 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 175 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 176 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 177
 178 ## For the times when you want to build Emacs but don't have
 179 ## a suitable makeinfo, and can live without the manuals.
 180 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 181 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 182
 183 ## This is an option because I do not know if all info/man support
 184 ## compressed files, nor how to test if they do so.
 185 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 186 if test $with_compress_info = yes; then
 187    GZIP_INFO=yes
 188 else
 189    GZIP_INFO=
 190 fi
 191 AC_SUBST(GZIP_INFO)
 192
 193 AC_ARG_WITH([pkg-config-prog],dnl
 194 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 195                   [path to pkg-config for finding GTK and librsvg])])
 196 if test "X${with_pkg_config_prog}" != X; then
 197    if test "${with_pkg_config_prog}" != yes; then
 198       PKG_CONFIG="${with_pkg_config_prog}"
 199    fi
 200 fi
 201
 202 CRT_DIR=
 203 AC_ARG_WITH([crt-dir],dnl
 204 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 205 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 206 CRT_DIR="${with_crt_dir}"
 207
 208 AC_ARG_WITH(gameuser,dnl
 209 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 210 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 211   && gameuser="${with_gameuser}"
 212 test "X$gameuser" = X && gameuser=games
 213
 214 AC_ARG_WITH([gnustep-conf],dnl
 215 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 216 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 217   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 218 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 219      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 220
 221 AC_ARG_ENABLE(ns-self-contained,
 222 [AS_HELP_STRING([--disable-ns-self-contained],
 223                 [disable self contained build under NeXTstep])],
 224    EN_NS_SELF_CONTAINED=$enableval,
 225    EN_NS_SELF_CONTAINED=yes)
 226
 227 AC_ARG_ENABLE(asserts,
 228 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 229       USE_XASSERTS=$enableval,
 230       USE_XASSERTS=no)
 231
 232 AC_ARG_ENABLE(maintainer-mode,
 233 [AS_HELP_STRING([--enable-maintainer-mode],
 234                 [enable make rules and dependencies not useful (and sometimes
 235                  confusing) to the casual installer])],
 236       USE_MAINTAINER_MODE=$enableval,
 237       USE_MAINTAINER_MODE=yes)
 238 if test $USE_MAINTAINER_MODE = yes; then
 239   MAINT=
 240 else
 241   MAINT=#
 242 fi
 243 AC_SUBST(MAINT)
 244
 245 AC_ARG_ENABLE(locallisppath,
 246 [AS_HELP_STRING([--enable-locallisppath=PATH],
 247                 [directories Emacs should search for lisp files specific
 248                  to this site])],
 249 if test "${enableval}" = "no"; then
 250   locallisppath=
 251 elif test "${enableval}" != "yes"; then
 252   locallisppath=${enableval}
 253 fi)
 254
 255 AC_ARG_ENABLE(checking,
 256 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 257                 [enable expensive run-time checks.  With LIST,
 258                  enable only specific categories of checks.
 259                  Categories are: all,yes,no.
 260                  Flags are: stringbytes, stringoverrun, stringfreelist,
 261                  xmallocoverrun, conslist])],
 262 [ac_checking_flags="${enableval}"],[])
 263 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 264 for check in $ac_checking_flags
 265 do
 266         case $check in
 267         # these set all the flags to specific states
 268         yes)            ac_enable_checking=1 ;;
 269         no)             ac_enable_checking= ;
 270                         ac_gc_check_stringbytes= ;
 271                         ac_gc_check_string_overrun= ;
 272                         ac_gc_check_string_free_list= ;
 273                         ac_xmalloc_overrun= ;
 274                         ac_gc_check_cons_list= ;;
 275         all)            ac_enable_checking=1 ;
 276                         ac_gc_check_stringbytes=1 ;
 277                         ac_gc_check_string_overrun=1 ;
 278                         ac_gc_check_string_free_list=1 ;
 279                         ac_xmalloc_overrun=1 ;
 280                         ac_gc_check_cons_list=1 ;;
 281         # these enable particular checks
 282         stringbytes)    ac_gc_check_stringbytes=1 ;;
 283         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 284         stringfreelist) ac_gc_check_string_free_list=1 ;;
 285         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 286         conslist)       ac_gc_check_cons_list=1 ;;
 287         *)      AC_MSG_ERROR(unknown check category $check) ;;
 288         esac
 289 done
 290 IFS="$ac_save_IFS"
 291
 292 if test x$ac_enable_checking != x ; then
 293   AC_DEFINE(ENABLE_CHECKING, 1,
 294 [Enable expensive run-time checking of data types?])
 295 fi
 296 if test x$ac_gc_check_stringbytes != x ; then
 297   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 298 [Define this temporarily to hunt a bug.  If defined, the size of
 299    strings is redundantly recorded in sdata structures so that it can
 300    be compared to the sizes recorded in Lisp strings.])
 301 fi
 302 if test x$ac_gc_check_string_overrun != x ; then
 303   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 304 [Define this to check for short string overrun.])
 305 fi
 306 if test x$ac_gc_check_string_free_list != x ; then
 307   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 308 [Define this to check the string free list.])
 309 fi
 310 if test x$ac_xmalloc_overrun != x ; then
 311   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 312 [Define this to check for malloc buffer overrun.])
 313 fi
 314 if test x$ac_gc_check_cons_list != x ; then
 315   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 316 [Define this to check for errors in cons list.])
 317 fi
 318
 319 AC_ARG_ENABLE(use-lisp-union-type,
 320 [AS_HELP_STRING([--enable-use-lisp-union-type],
 321                 [use a union for the Lisp_Object data type.
 322                 This is only useful for development for catching certain types of bugs.])],
 323 if test "${enableval}" != "no"; then
 324    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 325    [Define this to use a lisp union for the Lisp_Object data type.])
 326 fi)
 327
 328
 329 AC_ARG_ENABLE(profiling,
 330 [AS_HELP_STRING([--enable-profiling],
 331                 [build emacs with profiling support.
 332                  This might not work on all platforms])],
 333 [ac_enable_profiling="${enableval}"],[])
 334 if test x$ac_enable_profiling != x ; then
 335    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 336 else
 337    PROFILING_CFLAGS=
 338 fi
 339 AC_SUBST(PROFILING_CFLAGS)
 340
 341 AC_ARG_ENABLE(autodepend,
 342 [AS_HELP_STRING([--enable-autodepend],
 343                 [automatically generate dependencies to .h-files.
 344                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 345                  found])],
 346 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 347
 348 #### Make srcdir absolute, if it isn't already.  It's important to
 349 #### avoid running the path through pwd unnecessarily, since pwd can
 350 #### give you automounter prefixes, which can go away.  We do all this
 351 #### so Emacs can find its files when run uninstalled.
 352 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 353 unset CDPATH
 354 case "${srcdir}" in
 355   /* ) ;;
 356   . )
 357     ## We may be able to use the $PWD environment variable to make this
 358     ## absolute.  But sometimes PWD is inaccurate.
 359     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 360     ## but that tested only for a well-formed and valid PWD,
 361     ## it did not object when PWD was well-formed and valid but just wrong.
 362     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 363     then
 364       srcdir="$PWD"
 365     else
 366       srcdir="`(cd ${srcdir}; pwd)`"
 367     fi
 368   ;;
 369   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 370 esac
 371
 372 #### Given the configuration name, set machfile and opsysfile to the
 373 #### names of the m/*.h and s/*.h files we should use.
 374
 375 ### Canonicalize the configuration name.
 376
 377 AC_CANONICAL_HOST
 378 canonical=$host
 379 configuration=${host_alias-${build_alias-$host}}
 380
 381 dnl This used to use changequote, but, apart from `changequote is evil'
 382 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 383 dnl the great gob of text.  Thus it's not processed for possible expansion.
 384 dnl Just make sure the brackets remain balanced.
 385 dnl
 386 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 387 dnl indicated by comments.
 388 dnl quotation begins
 389 [
 390
 391 ### If you add support for a new configuration, add code to this
 392 ### switch statement to recognize your configuration name and select
 393 ### the appropriate operating system and machine description files.
 394
 395 ### You would hope that you could choose an m/*.h file pretty much
 396 ### based on the machine portion of the configuration name, and an s/*.h
 397 ### file based on the operating system portion.  However, it turns out
 398 ### that each m/*.h file is pretty manufacturer-specific - for
 399 ### example mips.h is MIPS
 400 ### So we basically have to have a special case for each
 401 ### configuration name.
 402 ###
 403 ### As far as handling version numbers on operating systems is
 404 ### concerned, make sure things will fail in a fixable way.  If
 405 ### /etc/MACHINES doesn't say anything about version numbers, be
 406 ### prepared to handle anything reasonably.  If version numbers
 407 ### matter, be sure /etc/MACHINES says something about it.
 408
 409 machine='' opsys='' unported=no
 410 case "${canonical}" in
 411
 412   ## GNU/Linux ports
 413   *-*-linux-gnu*)
 414     opsys=gnu-linux
 415     case ${canonical} in
 416       alpha*)   machine=alpha ;;
 417       s390-*)   machine=ibms390 ;;
 418       s390x-*)  machine=ibms390x ;;
 419       powerpc*) machine=macppc ;;
 420       sparc*)   machine=sparc ;;
 421       ia64*)    machine=ia64 ;;
 422       m68k*)    machine=m68k ;;
 423       x86_64*)  machine=amdx86-64 ;;
 424     esac
 425   ;;
 426
 427   ## FreeBSD ports
 428   *-*-freebsd* )
 429     opsys=freebsd
 430     case "${canonical}" in
 431       alpha*)           machine=alpha ;;
 432       amd64-*|x86_64-*) machine=amdx86-64 ;;
 433       ia64-*)           machine=ia64 ;;
 434       i[3456]86-*)      machine=intel386 ;;
 435       powerpc-*)        machine=macppc ;;
 436       sparc-*)          machine=sparc ;;
 437       sparc64-*)        machine=sparc ;;
 438     esac
 439   ;;
 440
 441   ## FreeBSD kernel + glibc based userland
 442   *-*-kfreebsd*gnu* )
 443     opsys=gnu-kfreebsd
 444     case "${canonical}" in
 445       alpha*)           machine=alpha ;;
 446       amd64-*|x86_64-*) machine=amdx86-64 ;;
 447       ia64-*)           machine=ia64 ;;
 448       i[3456]86-*)      machine=intel386 ;;
 449       powerpc-*)        machine=macppc ;;
 450       sparc-*)          machine=sparc ;;
 451       sparc64-*)        machine=sparc ;;
 452     esac
 453   ;;
 454
 455   ## NetBSD ports
 456   *-*-netbsd* )
 457     opsys=netbsd
 458     case "${canonical}" in
 459       alpha*)      machine=alpha ;;
 460       x86_64-*)    machine=amdx86-64 ;;
 461       i[3456]86-*) machine=intel386 ;;
 462       m68k-*)      machine=m68k ;;
 463       powerpc-*)   machine=macppc ;;
 464       sparc*-)     machine=sparc ;;
 465       vax-*)       machine=vax ;;
 466     esac
 467   ;;
 468
 469   ## OpenBSD ports
 470   *-*-openbsd* )
 471     opsys=openbsd
 472     case "${canonical}" in
 473       alpha*)    machine=alpha ;;
 474       x86_64-*)  machine=amdx86-64 ;;
 475       i386-*)    machine=intel386 ;;
 476       powerpc-*) machine=macppc ;;
 477       sparc*)    machine=sparc ;;
 478       vax-*)     machine=vax ;;
 479     esac
 480   ;;
 481
 482   ## Apple Darwin / Mac OS X
 483   *-apple-darwin* )
 484     case "${canonical}" in
 485       i[3456]86-* )  machine=intel386 ;;
 486       powerpc-* )    machine=macppc ;;
 487       x86_64-* )     machine=amdx86-64 ;;
 488       * )            unported=yes ;;
 489     esac
 490     opsys=darwin
 491     # Define CPP as follows to make autoconf work correctly.
 492     CPP="${CC-cc} -E -no-cpp-precomp"
 493     # Use fink packages if available.
 494     if test -d /sw/include && test -d /sw/lib; then
 495       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 496       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 497       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 498     fi
 499   ;;
 500
 501   ## HP 9000 series 700 and 800, running HP/UX
 502   hppa*-hp-hpux10.2* )
 503     opsys=hpux10-20
 504   ;;
 505   hppa*-hp-hpux1[1-9]* )
 506     opsys=hpux11
 507     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 508   ;;
 509
 510   ia64*-hp-hpux1[1-9]* )
 511     machine=hp800 opsys=hpux11
 512     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 513     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 514     CANNOT_DUMP=yes
 515   ;;
 516
 517   hppa*-*-linux-gnu* )
 518     machine=hp800 opsys=gnu-linux
 519   ;;
 520
 521   ## IBM machines
 522   rs6000-ibm-aix4.[23]* )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525   powerpc-ibm-aix4.[23]*  )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   rs6000-ibm-aix[56]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix[56]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534
 535   ## Silicon Graphics machines
 536   ## Iris 4D
 537   mips-sgi-irix6.5 )
 538     machine=iris4d opsys=irix6-5
 539     # Without defining _LANGUAGE_C, things get masked out in the headers
 540     # so that, for instance, grepping for `free' in stdlib.h fails and
 541     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 542     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 543     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 544   ;;
 545
 546   ## Suns
 547   *-sun-solaris* \
 548     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 549     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 550     case "${canonical}" in
 551       i[3456]86-*-* )     machine=intel386 ;;
 552       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 553       sparc* )          machine=sparc ;;
 554       * )               unported=yes ;;
 555     esac
 556     case "${canonical}" in
 557       *-sunos5.6* | *-solaris2.6* )
 558                 opsys=sol2-6
 559                 NON_GNU_CPP=/usr/ccs/lib/cpp
 560                 RANLIB="ar -ts"
 561                 ;;
 562       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 563                 opsys=sol2-6
 564                 emacs_check_sunpro_c=yes
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 ;;
 567       *-sunos5* | *-solaris* )
 568                 opsys=sol2-10
 569                 emacs_check_sunpro_c=yes
 570                 NON_GNU_CPP=/usr/ccs/lib/cpp
 571                 ;;
 572     esac
 573     ## Watch out for a compiler that we know will not work.
 574     case "${canonical}" in
 575      *-solaris* | *-sunos5* )
 576                 if [ "x$CC" = x/usr/ucb/cc ]; then
 577                   ## /usr/ucb/cc doesn't work;
 578                   ## we should find some other compiler that does work.
 579                   unset CC
 580                 fi
 581                 ;;
 582       *) ;;
 583     esac
 584   ;;
 585
 586   ## Intel 386 machines where we don't care about the manufacturer.
 587   i[3456]86-*-* )
 588     machine=intel386
 589     case "${canonical}" in
 590       *-cygwin )                opsys=cygwin ;;
 591       *-darwin* )               opsys=darwin
 592                                 CPP="${CC-cc} -E -no-cpp-precomp"
 593                                 ;;
 594       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 595       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 596       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 598     esac
 599   ;;
 600
 601   * )
 602     unported=yes
 603   ;;
 604 esac
 605
 606 ### If the code above didn't choose an operating system, just choose
 607 ### an operating system based on the configuration name.  You really
 608 ### only want to use this when you have no idea what the right
 609 ### operating system is; if you know what operating systems a machine
 610 ### runs, it's cleaner to make it explicit in the case statement
 611 ### above.
 612 if test x"${opsys}" = x; then
 613   case "${canonical}" in
 614     *-gnu* )                            opsys=gnu ;;
 615     * )
 616       unported=yes
 617     ;;
 618   esac
 619 fi
 620
 621 ]
 622 dnl quotation ends
 623
 624 if test $unported = yes; then
 625   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 626 Check `etc/MACHINES' for recognized configuration names.])
 627 fi
 628
 629 if test -n "$machine"; then
 630   machfile="m/${machine}.h"
 631 else
 632   machfile=
 633 fi
 634 opsysfile="s/${opsys}.h"
 635
 636
 637 #### Choose a compiler.
 638 test -n "$CC" && cc_specified=yes
 639
 640 # Save the value of CFLAGS that the user specified.
 641 SPECIFIED_CFLAGS="$CFLAGS"
 642
 643 dnl Sets GCC=yes if using gcc.
 644 AC_PROG_CC
 645 AM_PROG_CC_C_O
 646
 647 # Initialize gnulib right after verifying that the C compiler works.
 648 gl_EARLY
 649
 650 # On Suns, sometimes $CPP names a directory.
 651 if test -n "$CPP" && test -d "$CPP"; then
 652   CPP=
 653 fi
 654
 655 ## If not using gcc, and on Solaris, and no CPP specified, see if
 656 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 657 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 658  test x"$CPP" = x; then
 659   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 660   AC_CACHE_VAL(emacs_cv_sunpro_c,
 661   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 662 [[#ifndef __SUNPRO_C
 663 fail;
 664 #endif
 665 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 666   AC_MSG_RESULT($emacs_cv_sunpro_c)
 667
 668   if test x"$emacs_cv_sunpro_c" = xyes; then
 669     NON_GNU_CPP="$CC -E -Xs"
 670   fi
 671 fi
 672
 673 #### Some systems specify a CPP to use unless we are using GCC.
 674 #### Now that we know whether we are using GCC, we can decide whether
 675 #### to use that one.
 676 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 677 then
 678   CPP="$NON_GNU_CPP"
 679 fi
 680
 681 #### Some systems specify a CC to use unless we are using GCC.
 682 #### Now that we know whether we are using GCC, we can decide whether
 683 #### to use that one.
 684 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 685   test x$cc_specified != xyes
 686 then
 687   CC="$NON_GNU_CC"
 688 fi
 689
 690 if test x$GCC = xyes; then
 691   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 692 else
 693   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 694 fi
 695
 696 ### Use -Wdeclaration-after-statement if the compiler supports it
 697 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 698 SAVE_CFLAGS="$CFLAGS"
 699 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 700 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 701 if test $has_option = yes; then
 702    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 703 fi
 704 AC_MSG_RESULT($has_option)
 705 CFLAGS="$SAVE_CFLAGS"
 706 unset has_option
 707 unset SAVE_CFLAGS
 708
 709 ### Use -Wold-style-definition if the compiler supports it
 710 # This can be removed when conversion to standard C is finished.
 711 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 712 SAVE_CFLAGS="$CFLAGS"
 713 CFLAGS="$CFLAGS -Wold-style-definition"
 714 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 715 if test $has_option = yes; then
 716    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 717 fi
 718 AC_MSG_RESULT($has_option)
 719 CFLAGS="$SAVE_CFLAGS"
 720 unset has_option
 721 unset SAVE_CFLAGS
 722
 723 ### Use -Wimplicit-function-declaration if the compiler supports it
 724 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 725 SAVE_CFLAGS="$CFLAGS"
 726 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 727 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 728 if test $has_option = yes; then
 729    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 730 fi
 731 AC_MSG_RESULT($has_option)
 732 CFLAGS="$SAVE_CFLAGS"
 733 unset has_option
 734 unset SAVE_CFLAGS
 735
 736 AC_SUBST(C_WARNINGS_SWITCH)
 737
 738
 739 #### Some other nice autoconf tests.
 740
 741 dnl checks for programs
 742 AC_PROG_CPP
 743 AC_PROG_INSTALL
 744 if test "x$RANLIB" = x; then
 745   AC_PROG_RANLIB
 746 fi
 747
 748 ## Although we're running on an amd64 kernel, we're actually compiling for
 749 ## the x86 architecture.  The user should probably have provided an
 750 ## explicit --build to `configure', but if everything else than the kernel
 751 ## is running in i386 mode, we can help them out.
 752 if test "$machine" = "amdx86-64"; then
 753   AC_CHECK_DECL([i386])
 754   if test "$ac_cv_have_decl_i386" = "yes"; then
 755     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 756     machine=intel386
 757     machfile="m/${machine}.h"
 758   fi
 759 fi
 760
 761 AC_PATH_PROG(INSTALL_INFO, install-info)
 762 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 763 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 764 dnl Don't use GZIP, which is used by gzip for additional parameters.
 765 AC_PATH_PROG(GZIP_PROG, gzip)
 766
 767
 768 ## Need makeinfo >= 4.6 (?) to build the manuals.
 769 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 770 dnl By this stage, configure has already checked for egrep and set EGREP,
 771 dnl or exited with an error if no egrep was found.
 772 if test "$MAKEINFO" != "no" && \
 773   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 774    MAKEINFO=no
 775 fi
 776
 777 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 778 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 779 ## therefore in the category of "special tools" not normally required, which
 780 ## configure does not have to check for (eg autoconf itself).
 781 ## In a Bazaar checkout on the other hand, the manuals are not included.
 782 ## So makeinfo is a requirement to build from Bazaar, and configure
 783 ## should test for it as it does for any other build requirement.
 784 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 785 ## with pre-built manuals, from a Bazaar checkout.
 786 HAVE_MAKEINFO=yes
 787
 788 if test "$MAKEINFO" = "no"; then
 789   MAKEINFO=makeinfo
 790   if test "x${with_makeinfo}" = "xno"; then
 791     HAVE_MAKEINFO=no
 792   elif test ! -e $srcdir/info/emacs; then
 793     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 794 source tree does not seem to have pre-built manuals in the `info' directory.
 795 Either install a suitable version of makeinfo, or re-run configure
 796 with the `--without-makeinfo' option to build without the manuals.] )
 797   fi
 798 fi
 799 AC_SUBST(HAVE_MAKEINFO)
 800
 801 dnl Add our options to ac_link now, after it is set up.
 802
 803 if test x$GCC = xyes; then
 804   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 805     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 806 else
 807   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 808     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 809 fi
 810
 811 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 812 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 813 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 814 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 815 dnl if not built to support GNU ld.
 816
 817 late_LDFLAGS=$LDFLAGS
 818 if test x$GCC = xyes; then
 819   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 820 else
 821   LDFLAGS="$LDFLAGS -znocombreloc"
 822 fi
 823
 824 AC_MSG_CHECKING([for -znocombreloc])
 825 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 826   [AC_MSG_RESULT(yes)],
 827   LDFLAGS=$late_LDFLAGS
 828   [AC_MSG_RESULT(no)])
 829
 830
 831 # The value of CPP is a quoted variable reference, so we need to do this
 832 # to get its actual value...
 833 CPP=`eval "echo $CPP"`
 834
 835
 836 dnl The function dump-emacs will not be defined and temacs will do
 837 dnl (load "loadup") automatically unless told otherwise.
 838 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 839 case "$opsys" in
 840   your-opsys-here) CANNOT_DUMP=yes ;;
 841 esac
 842
 843 test "$CANNOT_DUMP" = "yes" && \
 844   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 845
 846 AC_SUBST(CANNOT_DUMP)
 847
 848
 849 UNEXEC_OBJ=unexelf.o
 850 case "$opsys" in
 851   # MSDOS uses unexcoff.o
 852   # MSWindows uses unexw32.o
 853   aix4-2)
 854    UNEXEC_OBJ=unexaix.o
 855    ;;
 856   cygwin)
 857    UNEXEC_OBJ=unexcw.o
 858    ;;
 859   darwin)
 860    UNEXEC_OBJ=unexmacosx.o
 861    ;;
 862   hpux10-20 | hpux11)
 863    UNEXEC_OBJ=unexhp9k800.o
 864    ;;
 865   sol2-10)
 866    # Use the Solaris dldump() function, called from unexsol.c, to dump
 867    # emacs, instead of the generic ELF dump code found in unexelf.c.
 868    # The resulting binary has a complete symbol table, and is better
 869    # for debugging and other observability tools (debuggers, pstack, etc).
 870    #
 871    # If you encounter a problem using dldump(), please consider sending
 872    # a message to the OpenSolaris tools-linking mailing list:
 873    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 874    #
 875    # It is likely that dldump() works with older Solaris too, but this has
 876    # not been tested, so for now this change is for Solaris 10 or newer.
 877    UNEXEC_OBJ=unexsol.o
 878    ;;
 879 esac
 880
 881 LD_SWITCH_SYSTEM=
 882 case "$opsys" in
 883   freebsd)
 884    ## Let `ld' find image libs and similar things in /usr/local/lib.
 885    ## The system compiler, GCC, has apparently been modified to not
 886    ## look there, contrary to what a stock GCC would do.
 887    LD_SWITCH_SYSTEM=-L/usr/local/lib
 888    ;;
 889
 890   gnu-linux)
 891    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 892    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 893    ;;
 894
 895   netbsd)
 896    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 897    ;;
 898
 899   openbsd)
 900    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 901    ## otherwise Emacs dumps core on elf systems.
 902    LD_SWITCH_SYSTEM="-Z"
 903    ;;
 904 esac
 905 AC_SUBST(LD_SWITCH_SYSTEM)
 906
 907 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 908
 909 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 910 ## which has not been defined yet.  When this was handled with cpp,
 911 ## it was expanded to null when configure sourced the s/*.h file.
 912 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 913 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 914 ## (or somesuch), but because it is supposed to go at the _front_
 915 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 916 ## Compare with the gnu-linux case below, which added to the end
 917 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 918 ## LD_SWITCH_SYSTEM_TEMACS.
 919 case "$opsys" in
 920   netbsd|openbsd)
 921    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 922    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 923 esac
 924
 925
 926 C_SWITCH_MACHINE=
 927 if test "$machine" = "alpha"; then
 928   AC_CHECK_DECL([__ELF__])
 929   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 930     ## With ELF, make sure that all common symbols get allocated to in the
 931     ## data section.  Otherwise, the dump of temacs may miss variables in
 932     ## the shared library that have been initialized.  For example, with
 933     ## GNU libc, __malloc_initialized would normally be resolved to the
 934     ## shared library's .bss section, which is fatal.
 935     if test "x$GCC" = "xyes"; then
 936       C_SWITCH_MACHINE="-fno-common"
 937     else
 938       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 939     fi
 940   else
 941     UNEXEC_OBJ=unexalpha.o
 942   fi
 943 fi
 944 AC_SUBST(C_SWITCH_MACHINE)
 945
 946 AC_SUBST(UNEXEC_OBJ)
 947
 948 C_SWITCH_SYSTEM=
 949 ## Some programs in src produce warnings saying certain subprograms
 950 ## are too complex and need a MAXMEM value greater than 2000 for
 951 ## additional optimization.  --nils@exp-math.uni-essen.de
 952 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 953   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 954 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 955 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 956 AC_SUBST(C_SWITCH_SYSTEM)
 957
 958
 959 LIBS_SYSTEM=
 960 case "$opsys" in
 961   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 962   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 963
 964   freebsd) LIBS_SYSTEM="-lutil" ;;
 965
 966   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 967
 968   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 969
 970   ## Motif needs -lgen.
 971   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 972 esac
 973 AC_SUBST(LIBS_SYSTEM)
 974
 975
 976 ### Make sure subsequent tests use flags consistent with the build flags.
 977
 978 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 979   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 980 else
 981   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 982 fi
 983
 984 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 985 AC_DEFUN([AC_TYPE_SIZE_T])
 986
 987 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 988 AC_SYS_LARGEFILE
 989
 990
 991 LIB_MATH=-lm
 992 LIB_STANDARD=
 993 START_FILES=
 994
 995 case $opsys in
 996   cygwin )
 997     LIB_MATH=
 998     START_FILES='pre-crt0.o'
 999     ;;
1000   darwin )
1001     ## Adding -lm confuses the dynamic linker, so omit it.
1002     LIB_MATH=
1003     START_FILES='pre-crt0.o'
1004     ;;
1005   freebsd )
1006     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1007     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1008     ;;
1009   gnu-linux | gnu-kfreebsd )
1010     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1011     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1012     ;;
1013   hpux10-20 | hpux11 )
1014     LIB_STANDARD=-lc
1015     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1016     ;;
1017   netbsd | openbsd )
1018     if test -f $CRT_DIR/crti.o; then
1019         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1020         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1021     else
1022         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1023         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1024     fi
1025     ;;
1026 esac
1027
1028 AC_SUBST(LIB_MATH)
1029 AC_SUBST(START_FILES)
1030
1031 dnl Not all platforms use crtn.o files.  Check if the current one does.
1032 crt_files=
1033
1034 for file in x $LIB_STANDARD $START_FILES; do
1035   case "$file" in
1036     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1037   esac
1038 done
1039
1040 if test "x$crt_files" != x; then
1041
1042   ## If user specified a crt-dir, use that unconditionally.
1043   if test "X$CRT_DIR" = "X"; then
1044
1045     CRT_DIR=/usr/lib            # default
1046
1047     case "$canonical" in
1048       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1049       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1050       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1051       ## For anything else (eg /usr/lib32), it is up the user to specify
1052       ## the location (bug#5655).
1053       ## Test for crtn.o, not just the directory, because sometimes the
1054       ## directory exists but does not have the relevant files (bug#1287).
1055       ## FIXME better to test for binary compatibility somehow.
1056       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1057       ;;
1058
1059       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1060     esac
1061
1062     case "$opsys" in
1063       hpux10-20) CRT_DIR=/lib ;;
1064     esac
1065
1066   fi                            # CRT_DIR = ""
1067
1068   crt_missing=
1069   crt_gcc=no
1070   test "x${GCC}" = xyes && crt_gcc=yes
1071
1072   for file in $crt_files; do
1073
1074     ## If we're using gcc, try to determine it automatically by asking
1075     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1076     ## system-dependent default from above.]
1077     ## Note that this overrides a faulty with-crt-dir.
1078     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1079        crt_gcc=no                dnl only try once
1080
1081        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1082        case "$crt_file" in
1083          */*)
1084            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1085            ;;
1086        esac
1087     fi
1088
1089     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1090   done                          # $crt_files
1091
1092   test "x$crt_missing" = x || \
1093     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1094 Try using the --with-crt-dir option.])
1095
1096 fi                              # crt_files != ""
1097
1098 AC_SUBST(CRT_DIR)
1099
1100
1101 dnl This function definition taken from Gnome 2.0
1102 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1103 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1104 dnl also defines GSTUFF_PKG_ERRORS on error
1105 AC_DEFUN([PKG_CHECK_MODULES], [
1106   succeeded=no
1107
1108   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1109
1110   if test "$PKG_CONFIG" = "no" ; then
1111      ifelse([$4], , [AC_MSG_ERROR([
1112       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1113   else
1114      PKG_CONFIG_MIN_VERSION=0.9.0
1115      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1116         AC_MSG_CHECKING(for $2)
1117
1118         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1119             AC_MSG_RESULT(yes)
1120             succeeded=yes
1121
1122             AC_MSG_CHECKING($1_CFLAGS)
1123             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1124             AC_MSG_RESULT($$1_CFLAGS)
1125
1126             AC_MSG_CHECKING($1_LIBS)
1127             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1128             AC_MSG_RESULT($$1_LIBS)
1129         else
1130             AC_MSG_RESULT(no)
1131             $1_CFLAGS=""
1132             $1_LIBS=""
1133             ## If we have a custom action on failure, don't print errors, but
1134             ## do set a variable so people can do so.
1135             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1136             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1137         fi
1138
1139         AC_SUBST($1_CFLAGS)
1140         AC_SUBST($1_LIBS)
1141      else
1142         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1143         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1144      fi
1145   fi
1146
1147   if test $succeeded = yes; then
1148      ifelse([$3], , :, [$3])
1149   else
1150      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1151   fi
1152 ])
1153
1154
1155 if test "${with_sound}" != "no"; then
1156   # Sound support for GNU/Linux and the free BSDs.
1157   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1158     have_sound_header=yes)
1159   # Emulation library used on NetBSD.
1160   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1161   AC_SUBST(LIBSOUND)
1162
1163   ALSA_REQUIRED=1.0.0
1164   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1165   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1166   if test $HAVE_ALSA = yes; then
1167     SAVE_CFLAGS="$CFLAGS"
1168     SAVE_LDFLAGS="$LDFLAGS"
1169     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1170     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1171     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1172                     emacs_alsa_normal=yes,
1173                     emacs_alsa_normal=no)
1174     if test "$emacs_alsa_normal" != yes; then
1175       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1176                      [[snd_lib_error_set_handler (0);]])],
1177                      emacs_alsa_subdir=yes,
1178                      emacs_alsa_subdir=no)
1179       if test "$emacs_alsa_subdir" != yes; then
1180         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1181       fi
1182       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1183     fi
1184
1185     CFLAGS="$SAVE_CFLAGS"
1186     LDFLAGS="$SAVE_LDFLAGS"
1187     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1188     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1189     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1190   fi
1191
1192   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1193   dnl compiles only on the specified platforms.  For others, it
1194   dnl probably doesn't make sense to try.
1195   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1196      case "$opsys" in
1197        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1198        gnu-linux|freebsd|netbsd)
1199          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1200          ;;
1201      esac
1202   fi
1203
1204   AC_SUBST(CFLAGS_SOUND)
1205 fi
1206
1207 dnl checks for header files
1208 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1209   linux/version.h sys/systeminfo.h limits.h \
1210   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1211   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1212   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1213
1214 AC_MSG_CHECKING(if personality LINUX32 can be set)
1215 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1216                emacs_cv_personality_linux32=yes,
1217                emacs_cv_personality_linux32=no)
1218 AC_MSG_RESULT($emacs_cv_personality_linux32)
1219
1220 if test $emacs_cv_personality_linux32 = yes; then
1221   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1222             [Define to 1 if personality LINUX32 can be set.])
1223 fi
1224
1225 dnl On Solaris 8 there's a compilation warning for term.h because
1226 dnl it doesn't define `bool'.
1227 AC_CHECK_HEADERS(term.h, , , -)
1228 AC_HEADER_STDC
1229 AC_HEADER_TIME
1230 AC_CHECK_DECLS([sys_siglist])
1231 if test $ac_cv_have_decl_sys_siglist != yes; then
1232   # For Tru64, at least:
1233   AC_CHECK_DECLS([__sys_siglist])
1234   if test $ac_cv_have_decl___sys_siglist = yes; then
1235     AC_DEFINE(sys_siglist, __sys_siglist,
1236               [Define to any substitute for sys_siglist.])
1237   fi
1238 fi
1239 AC_HEADER_SYS_WAIT
1240
1241 dnl Some systems have utime.h but don't declare the struct anyplace.
1242 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1243 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1244 #include <sys/time.h>
1245 #include <time.h>
1246 #else
1247 #ifdef HAVE_SYS_TIME_H
1248 #include <sys/time.h>
1249 #else
1250 #include <time.h>
1251 #endif
1252 #endif
1253 #ifdef HAVE_UTIME_H
1254 #include <utime.h>
1255 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1256   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1257 if test $emacs_cv_struct_utimbuf = yes; then
1258   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1259 fi
1260
1261 dnl Check for speed_t typedef.
1262 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1263   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1264     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1265 if test $emacs_cv_speed_t = yes; then
1266   AC_DEFINE(HAVE_SPEED_T, 1,
1267            [Define to 1 if `speed_t' is declared by <termios.h>.])
1268 fi
1269
1270 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1271 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1272 #include <sys/time.h>
1273 #include <time.h>
1274 #else
1275 #ifdef HAVE_SYS_TIME_H
1276 #include <sys/time.h>
1277 #else
1278 #include <time.h>
1279 #endif
1280 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1281   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1282 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1283 if test $emacs_cv_struct_timeval = yes; then
1284   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1285 fi
1286
1287 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1288 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1289 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1290   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1291 HAVE_EXCEPTION=$emacs_cv_struct_exception
1292 if test $emacs_cv_struct_exception != yes; then
1293   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1294 fi
1295
1296 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1297 #if HAVE_SYS_SOCKET_H
1298 #include <sys/socket.h>
1299 #endif])
1300
1301 dnl checks for structure members
1302 AC_STRUCT_TM
1303 AC_STRUCT_TIMEZONE
1304 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1305                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1306                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1307                 [#include <time.h>])
1308 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1309                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1310                   struct ifreq.ifr_addr], , ,
1311                  [AC_INCLUDES_DEFAULT
1312 #if HAVE_SYS_SOCKET_H
1313 #include <sys/socket.h>
1314 #endif
1315 #if HAVE_NET_IF_H
1316 #include <net/if.h>
1317 #endif])
1318
1319 dnl checks for compiler characteristics
1320
1321 dnl Testing __STDC__ to determine prototype support isn't good enough.
1322 dnl DEC C, for instance, doesn't define it with default options, and
1323 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1324 dnl and void *.
1325 AC_C_PROTOTYPES
1326 AC_C_VOLATILE
1327 AC_C_CONST
1328 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1329   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1330                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1331 if test $emacs_cv_void_star = yes; then
1332   AC_DEFINE(POINTER_TYPE, void)
1333 else
1334   AC_DEFINE(POINTER_TYPE, char)
1335 fi
1336 AH_TEMPLATE(POINTER_TYPE,
1337             [Define as `void' if your compiler accepts `void *'; otherwise
1338              define as `char'.])dnl
1339
1340 dnl Check for endianess
1341 AC_C_BIGENDIAN
1342
1343 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1344   [emacs_cv_attribute_aligned],
1345   [AC_COMPILE_IFELSE(
1346      [AC_LANG_PROGRAM(
1347         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1348         [[]])],
1349      [emacs_cv_attribute_aligned=yes],
1350      [emacs_cv_attribute_aligned=no])])
1351 if test $emacs_cv_attribute_aligned = yes; then
1352   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1353     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1354 fi
1355
1356 dnl check for Make feature
1357 AC_PROG_MAKE_SET
1358
1359 DEPFLAGS=
1360 MKDEPDIR=":"
1361 deps_frag=deps.mk
1362 dnl check for GNU Make if we have GCC and autodepend is on.
1363 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1364    AC_MSG_CHECKING([whether we are using GNU Make])
1365    HAVE_GNU_MAKE=no
1366    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1367    if test "x$testval" != x; then
1368       HAVE_GNU_MAKE=yes
1369    else
1370       ac_enable_autodepend=no
1371    fi
1372    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1373    if test $HAVE_GNU_MAKE = yes; then
1374       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1375       SAVE_CFLAGS="$CFLAGS"
1376       CFLAGS="$CFLAGS -MMD -MF deps.d"
1377       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1378       CFLAGS="$SAVE_CFLAGS"
1379       test -f deps.d || ac_enable_autodepend=no
1380       rm -rf deps.d
1381       AC_MSG_RESULT([$ac_enable_autodepend])
1382    fi
1383    if test $ac_enable_autodepend = yes; then
1384       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1385       ## In parallel builds, another make might create depdir between
1386       ## the first test and mkdir, so stick another test on the end.
1387       ## Or use install-sh -d?  mkdir -p is not portable.
1388       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1389       deps_frag=autodeps.mk
1390    fi
1391 fi
1392 deps_frag=$srcdir/src/$deps_frag
1393 AC_SUBST(MKDEPDIR)
1394 AC_SUBST(DEPFLAGS)
1395 AC_SUBST_FILE(deps_frag)
1396
1397
1398 lisp_frag=$srcdir/src/lisp.mk
1399 AC_SUBST_FILE(lisp_frag)
1400
1401
1402 dnl checks for operating system services
1403 AC_SYS_LONG_FILE_NAMES
1404
1405 #### Choose a window system.
1406
1407 AC_PATH_X
1408 if test "$no_x" = yes; then
1409   window_system=none
1410 else
1411   window_system=x11
1412 fi
1413
1414 ## Workaround for bug in autoconf <= 2.62.
1415 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1416 ## No need to do anything special for these standard directories.
1417 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1418
1419    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1420
1421 fi
1422
1423 LD_SWITCH_X_SITE_AUX=
1424 LD_SWITCH_X_SITE_AUX_RPATH=
1425 if test "${x_libraries}" != NONE; then
1426   if test -n "${x_libraries}"; then
1427     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1428     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1429     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1430   fi
1431   x_default_search_path=""
1432   x_search_path=${x_libraries}
1433   if test -z "${x_search_path}"; then
1434     x_search_path=/usr/lib
1435   fi
1436   for x_library in `echo ${x_search_path}: | \
1437                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1438     x_search_path="\
1439 ${x_library}/X11/%L/%T/%N%C%S:\
1440 ${x_library}/X11/%l/%T/%N%C%S:\
1441 ${x_library}/X11/%T/%N%C%S:\
1442 ${x_library}/X11/%L/%T/%N%S:\
1443 ${x_library}/X11/%l/%T/%N%S:\
1444 ${x_library}/X11/%T/%N%S"
1445     if test x"${x_default_search_path}" = x; then
1446       x_default_search_path=${x_search_path}
1447     else
1448       x_default_search_path="${x_search_path}:${x_default_search_path}"
1449     fi
1450   done
1451 fi
1452 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1453 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1454
1455 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1456   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1457 fi
1458
1459 if test x"${x_includes}" = x; then
1460   bitmapdir=/usr/include/X11/bitmaps
1461 else
1462   # accumulate include directories that have X11 bitmap subdirectories
1463   bmd_acc="dummyval"
1464   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1465     if test -d "${bmd}/X11/bitmaps"; then
1466       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1467     fi
1468     if test -d "${bmd}/bitmaps"; then
1469       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1470     fi
1471   done
1472   if test ${bmd_acc} != "dummyval"; then
1473     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1474   fi
1475 fi
1476
1477 HAVE_NS=no
1478 NS_IMPL_COCOA=no
1479 NS_IMPL_GNUSTEP=no
1480 tmp_CPPFLAGS="$CPPFLAGS"
1481 tmp_CFLAGS="$CFLAGS"
1482 CPPFLAGS="$CPPFLAGS -x objective-c"
1483 CFLAGS="$CFLAGS -x objective-c"
1484 TEMACS_LDFLAGS2="\${LDFLAGS}"
1485 dnl I don't think it's especially important, but src/Makefile.in
1486 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1487 dnl trailing "/" to it, so now we do it here.
1488 if test "${with_ns}" != no; then
1489   if test "${opsys}" = darwin; then
1490      NS_IMPL_COCOA=yes
1491      ns_appdir=`pwd`/nextstep/Emacs.app
1492      ns_appbindir=${ns_appdir}/Contents/MacOS/
1493      ns_appresdir=${ns_appdir}/Contents/Resources
1494      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1495   elif test -f $GNUSTEP_CONFIG_FILE; then
1496      NS_IMPL_GNUSTEP=yes
1497      ns_appdir=`pwd`/nextstep/Emacs.app
1498      ns_appbindir=${ns_appdir}/
1499      ns_appresdir=${ns_appdir}/Resources
1500      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1501      dnl FIXME sourcing this several times in subshells seems inefficient.
1502      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1503      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1504      dnl I seemed to need these as well with GNUstep-startup 0.25.
1505      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1506      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1507      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1508        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1509      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1510        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1511      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1512      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1513      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1514      LIB_STANDARD=
1515      START_FILES=
1516      TEMACS_LDFLAGS2=
1517   fi
1518   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1519                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1520   files are missing or cannot be compiled.])])
1521   NS_HAVE_NSINTEGER=yes
1522   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1523                                      [NSInteger i;])],
1524                     ns_have_nsinteger=yes,
1525                     ns_have_nsinteger=no)
1526   if test $ns_have_nsinteger = no; then
1527     NS_HAVE_NSINTEGER=no
1528   fi
1529 fi
1530 AC_SUBST(TEMACS_LDFLAGS2)
1531
1532 ns_frag=/dev/null
1533 NS_OBJ=
1534 NS_OBJC_OBJ=
1535 if test "${HAVE_NS}" = yes; then
1536   window_system=nextstep
1537   with_xft=no
1538   # set up packaging dirs
1539   exec_prefix=${ns_appbindir}
1540   libexecdir=${ns_appbindir}/libexec
1541   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1542      prefix=${ns_appresdir}
1543   fi
1544   ns_frag=$srcdir/src/ns.mk
1545   NS_OBJ="fontset.o fringe.o image.o"
1546   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1547 fi
1548 CFLAGS="$tmp_CFLAGS"
1549 CPPFLAGS="$tmp_CPPFLAGS"
1550 AC_SUBST(NS_OBJ)
1551 AC_SUBST(NS_OBJC_OBJ)
1552 AC_SUBST(LIB_STANDARD)
1553 AC_SUBST_FILE(ns_frag)
1554
1555 case "${window_system}" in
1556   x11 )
1557     HAVE_X_WINDOWS=yes
1558     HAVE_X11=yes
1559     case "${with_x_toolkit}" in
1560       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1561       motif ) USE_X_TOOLKIT=MOTIF ;;
1562       gtk ) with_gtk=yes
1563 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1564 dnl USE_X_TOOLKIT is set.
1565             USE_X_TOOLKIT=none ;;
1566       gtk3 ) with_gtk3=yes
1567              USE_X_TOOLKIT=none ;;
1568       no ) USE_X_TOOLKIT=none ;;
1569 dnl If user did not say whether to use a toolkit, make this decision later:
1570 dnl use the toolkit if we have gtk, or X11R5 or newer.
1571       * ) USE_X_TOOLKIT=maybe ;;
1572     esac
1573   ;;
1574   nextstep | none )
1575     HAVE_X_WINDOWS=no
1576     HAVE_X11=no
1577     USE_X_TOOLKIT=none
1578   ;;
1579 esac
1580
1581 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1582    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1583    if test "$HAVE_XSERVER" = true ||
1584       test -n "$DISPLAY" ||
1585       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1586         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1587 were found.  You should install the relevant development files for X
1588 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1589 sure you have development files for image handling, i.e.
1590 tiff, gif, jpeg, png and xpm.
1591 If you are sure you want Emacs compiled without X window support, pass
1592   --without-x
1593 to configure.])
1594    fi
1595 fi
1596
1597 ### If we're using X11, we should use the X menu package.
1598 HAVE_MENUS=no
1599 case ${HAVE_X11} in
1600   yes ) HAVE_MENUS=yes ;;
1601 esac
1602
1603 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1604 # Assume not, until told otherwise.
1605 GNU_MALLOC=yes
1606 doug_lea_malloc=yes
1607 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1608 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1609 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1610                emacs_cv_var___after_morecore_hook,
1611 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1612   emacs_cv_var___after_morecore_hook=yes,
1613   emacs_cv_var___after_morecore_hook=no)])
1614 if test $emacs_cv_var___after_morecore_hook = no; then
1615   doug_lea_malloc=no
1616 fi
1617
1618
1619 dnl See comments in aix4-2.h about maybe using system malloc there.
1620 system_malloc=no
1621 case "$opsys" in
1622   ## darwin ld insists on the use of malloc routines in the System framework.
1623   darwin|sol2-10) system_malloc=yes ;;
1624 esac
1625
1626 if test "${system_malloc}" = "yes"; then
1627   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1628   GNU_MALLOC=no
1629   GNU_MALLOC_reason="
1630     (The GNU allocators don't work with this system configuration.)"
1631   GMALLOC_OBJ=
1632   VMLIMIT_OBJ=
1633 else
1634   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1635   VMLIMIT_OBJ=vm-limit.o
1636 fi
1637 AC_SUBST(GMALLOC_OBJ)
1638 AC_SUBST(VMLIMIT_OBJ)
1639
1640 if test "$doug_lea_malloc" = "yes" ; then
1641   if test "$GNU_MALLOC" = yes ; then
1642     GNU_MALLOC_reason="
1643       (Using Doug Lea's new malloc from the GNU C Library.)"
1644   fi
1645   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1646             [Define to 1 if you are using the GNU C Library.])
1647
1648   ## Use mmap directly for allocating larger buffers.
1649   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1650   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1651   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1652   case "$opsys" in
1653     gnu*) REL_ALLOC=no ;;
1654   esac
1655 fi
1656
1657 if test x"${REL_ALLOC}" = x; then
1658   REL_ALLOC=${GNU_MALLOC}
1659 fi
1660
1661 use_mmap_for_buffers=no
1662 case "$opsys" in
1663   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1664 esac
1665
1666 AC_FUNC_MMAP
1667 if test $use_mmap_for_buffers = yes; then
1668   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1669   REL_ALLOC=no
1670 fi
1671
1672 LIBS="$LIBS_SYSTEM $LIBS"
1673
1674 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1675 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1676 AC_CHECK_LIB(dnet, dnet_ntoa)
1677 dnl This causes -lresolv to get used in subsequent tests,
1678 dnl which causes failures on some systems such as HPUX 9.
1679 dnl AC_CHECK_LIB(resolv, gethostbyname)
1680
1681 dnl FIXME replace main with a function we actually want from this library.
1682 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1683
1684 AC_CHECK_LIB(pthreads, cma_open)
1685
1686 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1687 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1688 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1689 ## added to LIBS in configure would never contain the pthreads part,
1690 ## but the value used in Makefiles might.  FIXME?
1691 ##
1692 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1693 ## be harmless on older versions of X where it happens to exist.
1694 test "$opsys" = "aix4-2" && \
1695   test $ac_cv_lib_pthreads_cma_open = yes && \
1696   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1697
1698 dnl Check for need for bigtoc support on IBM AIX
1699
1700 case ${host_os} in
1701 aix*)
1702   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1703     case $GCC in
1704     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1705     *) gdb_cv_bigtoc=-bbigtoc ;;
1706     esac
1707
1708     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1709     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1710   ])
1711   ;;
1712 esac
1713
1714 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1715 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1716 # REAL_CPPFLAGS later on.
1717
1718 REAL_CFLAGS="$CFLAGS"
1719 REAL_CPPFLAGS="$CPPFLAGS"
1720
1721 if test "${HAVE_X11}" = "yes"; then
1722   DEFS="$C_SWITCH_X_SITE $DEFS"
1723   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1724   LIBS="-lX11 $LIBS"
1725   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1726   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1727
1728   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1729   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1730   # but it's more convenient here to set LD_RUN_PATH
1731   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1732   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1733     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1734     export LD_RUN_PATH
1735   fi
1736
1737   if test "${opsys}" = "gnu-linux"; then
1738     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1739     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1740      [[XOpenDisplay ("foo");]])],
1741      [xlinux_first_failure=no],
1742      [xlinux_first_failure=yes])
1743     if test "${xlinux_first_failure}" = "yes"; then
1744       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1745       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1746       OLD_CPPFLAGS="$CPPFLAGS"
1747       OLD_LIBS="$LIBS"
1748       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1749       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1750       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1751       LIBS="$LIBS -b i486-linuxaout"
1752       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1753        [[XOpenDisplay ("foo");]])],
1754        [xlinux_second_failure=no],
1755        [xlinux_second_failure=yes])
1756       if test "${xlinux_second_failure}" = "yes"; then
1757         # If we get the same failure with -b, there is no use adding -b.
1758         # So take it out.  This plays safe.
1759         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1760         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1761         CPPFLAGS="$OLD_CPPFLAGS"
1762         LIBS="$OLD_LIBS"
1763         AC_MSG_RESULT(no)
1764       else
1765         AC_MSG_RESULT(yes)
1766       fi
1767     else
1768       AC_MSG_RESULT(no)
1769     fi
1770   fi
1771
1772   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1773   # header files included from there.
1774   AC_MSG_CHECKING(for Xkb)
1775   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1776 #include <X11/XKBlib.h>]],
1777         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1778         emacs_xkb=yes, emacs_xkb=no)
1779   AC_MSG_RESULT($emacs_xkb)
1780   if test $emacs_xkb = yes; then
1781     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1782   fi
1783
1784   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1785 XScreenNumberOfScreen XSetWMProtocols)
1786 fi
1787
1788 if test "${window_system}" = "x11"; then
1789   AC_MSG_CHECKING(X11 version 6)
1790   AC_CACHE_VAL(emacs_cv_x11_version_6,
1791   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1792 [[#if XlibSpecificationRelease < 6
1793 fail;
1794 #endif
1795 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1796   if test $emacs_cv_x11_version_6 = yes; then
1797     AC_MSG_RESULT(6 or newer)
1798     AC_DEFINE(HAVE_X11R6, 1,
1799               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1800     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1801     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1802     ## XIM support.
1803     case "$opsys" in
1804       sol2-*) : ;;
1805       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1806            [Define if you have usable X11R6-style XIM support.])
1807          ;;
1808     esac
1809   else
1810     AC_MSG_RESULT(before 6)
1811   fi
1812 fi
1813
1814
1815 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1816 HAVE_RSVG=no
1817 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1818   if test "${with_rsvg}" != "no"; then
1819     RSVG_REQUIRED=2.11.0
1820     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1821
1822     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1823     AC_SUBST(RSVG_CFLAGS)
1824     AC_SUBST(RSVG_LIBS)
1825
1826     if test $HAVE_RSVG = yes; then
1827       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1828       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1829       LIBS="$RSVG_LIBS $LIBS"
1830     fi
1831   fi
1832 fi
1833
1834 HAVE_IMAGEMAGICK=no
1835 if test "${HAVE_X11}" = "yes"; then
1836   if test "${with_imagemagick}" != "no"; then
1837     ## 6.2.8 is the earliest version known to work, but earlier versions
1838     ## might work - let us know if you find one.
1839     ## 6.0.7 does not work.  See bug#7955.
1840     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1841     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1842     AC_SUBST(IMAGEMAGICK_CFLAGS)
1843     AC_SUBST(IMAGEMAGICK_LIBS)
1844
1845     if test $HAVE_IMAGEMAGICK = yes; then
1846       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1847       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1848       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1849       AC_CHECK_FUNCS(MagickExportImagePixels)
1850     fi
1851   fi
1852 fi
1853
1854
1855 HAVE_GTK=no
1856 GTK_OBJ=
1857 if test "${with_gtk3}" = "yes"; then
1858   GLIB_REQUIRED=2.28
1859   GTK_REQUIRED=3.0
1860   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1861
1862   dnl Checks for libraries.
1863   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1864   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1865      AC_MSG_ERROR($GTK_PKG_ERRORS)
1866   fi
1867   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1868   GTK_OBJ=emacsgtkfixed.o
1869 fi
1870
1871 if test "$pkg_check_gtk" != "yes"; then
1872   HAVE_GTK=no
1873 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1874   GLIB_REQUIRED=2.6
1875   GTK_REQUIRED=2.6
1876   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1877
1878   dnl Checks for libraries.
1879   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1880   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1881      AC_MSG_ERROR($GTK_PKG_ERRORS)
1882   fi
1883 fi
1884 fi
1885
1886 if test x"$pkg_check_gtk" = xyes; then
1887
1888   AC_SUBST(GTK_CFLAGS)
1889   AC_SUBST(GTK_LIBS)
1890   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1891   CFLAGS="$CFLAGS $GTK_CFLAGS"
1892   LIBS="$GTK_LIBS $LIBS"
1893   dnl Try to compile a simple GTK program.
1894   GTK_COMPILES=no
1895   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1896   if test "${GTK_COMPILES}" != "yes"; then
1897     if test "$USE_X_TOOLKIT" != "maybe"; then
1898       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1899     fi
1900   else
1901     HAVE_GTK=yes
1902     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1903     GTK_OBJ="gtkutil.o $GTK_OBJ"
1904     USE_X_TOOLKIT=none
1905     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1906       :
1907     else
1908       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1909        closing open displays.  This is no problem if you just use
1910        one display, but if you use more than one and close one of them
1911        Emacs may crash.]])
1912       sleep 3
1913     fi
1914   fi
1915
1916 fi
1917 AC_SUBST(GTK_OBJ)
1918
1919
1920 if test "${HAVE_GTK}" = "yes"; then
1921
1922   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1923   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1924   if test "$with_toolkit_scroll_bars" != no; then
1925     with_toolkit_scroll_bars=yes
1926   fi
1927
1928   dnl  Check if we have the old file selection dialog declared and
1929   dnl  in the link library.  In 2.x it may be in the library,
1930   dnl  but not declared if deprecated featured has been selected out.
1931   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1932   HAVE_GTK_FILE_SELECTION=no
1933   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1934                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1935 #include <gtk/gtk.h>])
1936   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1937     AC_CHECK_FUNCS(gtk_file_selection_new)
1938   fi
1939
1940   dnl Check if pthreads are available.  Emacs only needs this when using
1941   dnl gtk_file_chooser under Gnome.
1942     HAVE_GTK_AND_PTHREAD=no
1943     AC_CHECK_HEADERS(pthread.h)
1944     if test "$ac_cv_header_pthread_h"; then
1945       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1946     fi
1947     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1948       case "${canonical}" in
1949         *-hpux*) ;;
1950         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1951       esac
1952       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1953                [Define to 1 if you have GTK and pthread (-lpthread).])
1954     fi
1955
1956   dnl Check for functions introduced in 2.14 and later.
1957   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1958                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1959                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1960                  gtk_orientable_set_orientation)
1961
1962 fi
1963
1964 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1965 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1966 dnl also not configured.
1967 HAVE_DBUS=no
1968 DBUS_OBJ=
1969 if test "${with_dbus}" = "yes"; then
1970    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1971    if test "$HAVE_DBUS" = yes; then
1972      LIBS="$LIBS $DBUS_LIBS"
1973      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1974      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1975      DBUS_OBJ=dbusbind.o
1976    fi
1977 fi
1978 AC_SUBST(DBUS_OBJ)
1979
1980 dnl GConf has been tested under GNU/Linux only.
1981 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1982 HAVE_GCONF=no
1983 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1984    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1985    if test "$HAVE_GCONF" = yes; then
1986       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1987       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1988       AC_CHECK_FUNCS([g_type_init])
1989    fi
1990 fi
1991
1992 dnl SELinux is available for GNU/Linux only.
1993 HAVE_LIBSELINUX=no
1994 LIBSELINUX_LIBS=
1995 if test "${with_selinux}" = "yes"; then
1996    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1997    if test "$HAVE_LIBSELINUX" = yes; then
1998       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1999       LIBSELINUX_LIBS=-lselinux
2000    fi
2001 fi
2002 AC_SUBST(LIBSELINUX_LIBS)
2003
2004 HAVE_GNUTLS=no
2005 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2006 if test "${with_gnutls}" = "yes" ; then
2007   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2008   if test "${HAVE_GNUTLS}" = "yes"; then
2009     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2010   fi
2011
2012   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2013   LIBS="$LIBGNUTLS_LIBS $LIBS"
2014   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2015
2016   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2017     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2018   fi
2019 fi
2020
2021 AC_SUBST(LIBGNUTLS_LIBS)
2022 AC_SUBST(LIBGNUTLS_CFLAGS)
2023
2024 dnl Do not put whitespace before the #include statements below.
2025 dnl Older compilers (eg sunos4 cc) choke on it.
2026 HAVE_XAW3D=no
2027 LUCID_LIBW=
2028 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2029   if test "$with_xaw3d" != no; then
2030     AC_MSG_CHECKING(for xaw3d)
2031     AC_CACHE_VAL(emacs_cv_xaw3d,
2032     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2033 #include <X11/Intrinsic.h>
2034 #include <X11/Xaw3d/Simple.h>]],
2035       [[]])],
2036       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2037                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2038       emacs_cv_xaw3d=no)])
2039   else
2040     emacs_cv_xaw3d=no
2041   fi
2042   if test $emacs_cv_xaw3d = yes; then
2043     AC_MSG_RESULT([yes; using Lucid toolkit])
2044     USE_X_TOOLKIT=LUCID
2045     HAVE_XAW3D=yes
2046     LUCID_LIBW=-lXaw3d
2047     AC_DEFINE(HAVE_XAW3D, 1,
2048               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2049   else
2050     AC_MSG_RESULT(no)
2051     AC_MSG_CHECKING(for libXaw)
2052     AC_CACHE_VAL(emacs_cv_xaw,
2053     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2054 #include <X11/Intrinsic.h>
2055 #include <X11/Xaw/Simple.h>]],
2056       [[]])],
2057       emacs_cv_xaw=yes,
2058       emacs_cv_xaw=no)])
2059     if test $emacs_cv_xaw = yes; then
2060       AC_MSG_RESULT([yes; using Lucid toolkit])
2061       USE_X_TOOLKIT=LUCID
2062       LUCID_LIBW=-lXaw
2063     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2064       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2065     else
2066       AC_MSG_ERROR([No X toolkit could be found.
2067 If you are sure you want Emacs compiled without an X toolkit, pass
2068   --with-x-toolkit=no
2069 to configure.  Otherwise, install the development libraries for the toolkit
2070 that you want to use (e.g. Gtk+) and re-run configure.])
2071     fi
2072   fi
2073 fi
2074
2075 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2076
2077 LIBXTR6=
2078 if test "${USE_X_TOOLKIT}" != "none"; then
2079   AC_MSG_CHECKING(X11 toolkit version)
2080   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2081   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2082 [[#if XtSpecificationRelease < 6
2083 fail;
2084 #endif
2085 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2086   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2087   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2088     AC_MSG_RESULT(6 or newer)
2089     AC_DEFINE(HAVE_X11XTR6, 1,
2090               [Define to 1 if you have the X11R6 or newer version of Xt.])
2091     LIBXTR6="-lSM -lICE"
2092     case "$opsys" in
2093       ## Use libw.a along with X11R6 Xt.
2094       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2095     esac
2096   else
2097     AC_MSG_RESULT(before 6)
2098   fi
2099
2100 dnl If using toolkit, check whether libXmu.a exists.
2101 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2102   OLDLIBS="$LIBS"
2103   if test x$HAVE_X11XTR6 = xyes; then
2104     LIBS="-lXt -lSM -lICE $LIBS"
2105   else
2106     LIBS="-lXt $LIBS"
2107   fi
2108   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2109   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2110 fi
2111 AC_SUBST(LIBXTR6)
2112
2113 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2114 dnl Why not just test for libxmu in the normal way?
2115 LIBXMU=-lXmu
2116 case $opsys in
2117   ## These systems don't supply Xmu.
2118   hpux* | aix4-2 )
2119     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2120     ;;
2121 esac
2122 AC_SUBST(LIBXMU)
2123
2124 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2125 if test "${HAVE_X11}" = "yes"; then
2126   if test "${USE_X_TOOLKIT}" != "none"; then
2127     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2128   fi
2129 fi
2130
2131 LIBXP=
2132 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2133   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2134   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2135     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2136 int x = 5;
2137 #else
2138 Motif version prior to 2.1.
2139 #endif]])],
2140     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2141   if test $emacs_cv_motif_version_2_1 = yes; then
2142     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2143   else
2144     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2145     # We put this in CFLAGS temporarily to precede other -I options
2146     # that might be in CFLAGS temporarily.
2147     # We put this in CPPFLAGS where it precedes the other -I options.
2148     OLD_CPPFLAGS=$CPPFLAGS
2149     OLD_CFLAGS=$CFLAGS
2150     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2151     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2152     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2153       [[int x = 5;]])],
2154       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2155     if test $emacs_cv_lesstif = yes; then
2156       # Make sure this -I option remains in CPPFLAGS after it is set
2157       # back to REAL_CPPFLAGS.
2158       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2159       # have those other -I options anyway.  Ultimately, having this
2160       # directory ultimately in CPPFLAGS will be enough.
2161       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2162       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2163     else
2164       CFLAGS=$OLD_CFLAGS
2165       CPPFLAGS=$OLD_CPPFLAGS
2166     fi
2167   fi
2168 fi
2169
2170 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2171 dnl using Motif or Xaw3d is available, and unless
2172 dnl --with-toolkit-scroll-bars=no was specified.
2173
2174 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2175             [Define to 1 if we should use toolkit scroll bars.])dnl
2176 USE_TOOLKIT_SCROLL_BARS=no
2177 if test "${with_toolkit_scroll_bars}" != "no"; then
2178   if test "${USE_X_TOOLKIT}" != "none"; then
2179     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2180       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2181       HAVE_XAW3D=no
2182       USE_TOOLKIT_SCROLL_BARS=yes
2183     elif test "${HAVE_XAW3D}" = "yes"; then
2184       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2185       USE_TOOLKIT_SCROLL_BARS=yes
2186     fi
2187   elif test "${HAVE_GTK}" = "yes"; then
2188     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2189     USE_TOOLKIT_SCROLL_BARS=yes
2190   elif test "${HAVE_NS}" = "yes"; then
2191     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2192     USE_TOOLKIT_SCROLL_BARS=yes
2193   fi
2194 fi
2195
2196 dnl See if XIM is available.
2197 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2198           #include <X11/Xlib.h>
2199           #include <X11/Xresource.h>]],
2200          [[XIMProc  callback;]])],
2201          [HAVE_XIM=yes
2202          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2203          HAVE_XIM=no)
2204
2205 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2206
2207 if test "${with_xim}" != "no"; then
2208   AC_DEFINE(USE_XIM, 1,
2209             [Define to 1 if we should use XIM, if it is available.])
2210 fi
2211
2212
2213 if test "${HAVE_XIM}" != "no"; then
2214   late_CFLAGS=$CFLAGS
2215   if test "$GCC" = yes; then
2216     CFLAGS="$CFLAGS --pedantic-errors"
2217   fi
2218   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2219 #include <X11/Xlib.h>
2220 #include <X11/Xresource.h>]],
2221 [[Display *display;
2222 XrmDatabase db;
2223 char *res_name;
2224 char *res_class;
2225 XIMProc  callback;
2226 XPointer *client_data;
2227 #ifndef __GNUC__
2228 /* If we're not using GCC, it's probably not XFree86, and this is
2229    probably right, but we can't use something like --pedantic-errors.  */
2230 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2231                                            char*, XIMProc, XPointer*);
2232 #endif
2233 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2234    client_data);]])],
2235     [emacs_cv_arg6_star=yes])
2236   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2237          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2238 either XPointer or XPointer*.])dnl
2239   if test "$emacs_cv_arg6_star" = yes; then
2240     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2241   else
2242     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2243   fi
2244   CFLAGS=$late_CFLAGS
2245 fi
2246
2247 ### Start of font-backend (under any platform) section.
2248 # (nothing here yet -- this is a placeholder)
2249 ### End of font-backend (under any platform) section.
2250
2251 ### Start of font-backend (under X11) section.
2252 if test "${HAVE_X11}" = "yes"; then
2253    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2254
2255    ## Use -lXft if available, unless `--with-xft=no'.
2256    HAVE_XFT=maybe
2257     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2258       with_xft="no";
2259     fi
2260     if test "x${with_xft}" != "xno"; then
2261
2262       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2263       ## Because xftfont.c uses XRenderQueryExtension, we also
2264       ## need to link to -lXrender.
2265       HAVE_XRENDER=no
2266       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2267       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2268         OLD_CPPFLAGS="$CPPFLAGS"
2269         OLD_CFLAGS="$CFLAGS"
2270         OLD_LIBS="$LIBS"
2271         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2272         CFLAGS="$CFLAGS $XFT_CFLAGS"
2273         XFT_LIBS="-lXrender $XFT_LIBS"
2274         LIBS="$XFT_LIBS $LIBS"
2275         AC_CHECK_HEADER(X11/Xft/Xft.h,
2276           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2277
2278         if test "${HAVE_XFT}" = "yes"; then
2279           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2280             AC_SUBST(XFT_LIBS)
2281           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2282         else
2283           CPPFLAGS="$OLD_CPPFLAGS"
2284           CFLAGS="$OLD_CFLAGS"
2285           LIBS="$OLD_LIBS"
2286         fi                        # "${HAVE_XFT}" = "yes"
2287       fi                          # "$HAVE_XFT" != no
2288     fi                            # "x${with_xft}" != "xno"
2289
2290     ## We used to allow building with FreeType and without Xft.
2291     ## However, the ftx font backend driver is not in good shape.
2292     if test "$HAVE_XFT" != "yes"; then
2293        dnl For the "Does Emacs use" message at the end.
2294        HAVE_XFT=no
2295        HAVE_FREETYPE=no
2296     else
2297        dnl Strict linkers fail with
2298        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2299        dnl if -lfreetype is not specified.
2300        dnl The following is needed to set FREETYPE_LIBS.
2301        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2302                          HAVE_FREETYPE=no)
2303
2304        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2305     fi
2306
2307     HAVE_LIBOTF=no
2308     if test "${HAVE_FREETYPE}" = "yes"; then
2309       AC_DEFINE(HAVE_FREETYPE, 1,
2310                 [Define to 1 if using the freetype and fontconfig libraries.])
2311       if test "${with_libotf}" != "no"; then
2312         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2313                           HAVE_LIBOTF=no)
2314         if test "$HAVE_LIBOTF" = "yes"; then
2315           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2316           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2317                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2318                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2319           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2320             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2321                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2322           fi
2323         fi
2324       fi
2325     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2326     dnl Does the new font backend require it, or can it work without it?
2327     fi
2328
2329     HAVE_M17N_FLT=no
2330     if test "${HAVE_LIBOTF}" = yes; then
2331       if test "${with_m17n_flt}" != "no"; then
2332         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2333         if test "$HAVE_M17N_FLT" = "yes"; then
2334           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2335         fi
2336       fi
2337     fi
2338 else
2339     HAVE_XFT=no
2340     HAVE_FREETYPE=no
2341     HAVE_LIBOTF=no
2342     HAVE_M17N_FLT=no
2343 fi
2344
2345 ### End of font-backend (under X11) section.
2346
2347 AC_SUBST(FREETYPE_CFLAGS)
2348 AC_SUBST(FREETYPE_LIBS)
2349 AC_SUBST(FONTCONFIG_CFLAGS)
2350 AC_SUBST(FONTCONFIG_LIBS)
2351 AC_SUBST(LIBOTF_CFLAGS)
2352 AC_SUBST(LIBOTF_LIBS)
2353 AC_SUBST(M17N_FLT_CFLAGS)
2354 AC_SUBST(M17N_FLT_LIBS)
2355
2356 ### Use -lXpm if available, unless `--with-xpm=no'.
2357 HAVE_XPM=no
2358 LIBXPM=
2359 if test "${HAVE_X11}" = "yes"; then
2360   if test "${with_xpm}" != "no"; then
2361     AC_CHECK_HEADER(X11/xpm.h,
2362       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2363     if test "${HAVE_XPM}" = "yes"; then
2364       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2365       AC_EGREP_CPP(no_return_alloc_pixels,
2366       [#include "X11/xpm.h"
2367 #ifndef XpmReturnAllocPixels
2368 no_return_alloc_pixels
2369 #endif
2370       ], HAVE_XPM=no, HAVE_XPM=yes)
2371
2372       if test "${HAVE_XPM}" = "yes"; then
2373         AC_MSG_RESULT(yes)
2374       else
2375         AC_MSG_RESULT(no)
2376       fi
2377     fi
2378   fi
2379
2380   if test "${HAVE_XPM}" = "yes"; then
2381     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2382     LIBXPM=-lXpm
2383   fi
2384 fi
2385 AC_SUBST(LIBXPM)
2386
2387 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2388 HAVE_JPEG=no
2389 LIBJPEG=
2390 if test "${HAVE_X11}" = "yes"; then
2391   if test "${with_jpeg}" != "no"; then
2392     dnl Checking for jpeglib.h can lose because of a redefinition of
2393     dnl  HAVE_STDLIB_H.
2394     AC_CHECK_HEADER(jerror.h,
2395       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2396   fi
2397
2398   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2399   if test "${HAVE_JPEG}" = "yes"; then
2400     AC_DEFINE(HAVE_JPEG)
2401     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2402         [#include <jpeglib.h>
2403          version=JPEG_LIB_VERSION
2404 ],
2405         [AC_DEFINE(HAVE_JPEG)],
2406         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2407         HAVE_JPEG=no])
2408   fi
2409   if test "${HAVE_JPEG}" = "yes"; then
2410     LIBJPEG=-ljpeg
2411   fi
2412 fi
2413 AC_SUBST(LIBJPEG)
2414
2415 ### Use -lpng if available, unless `--with-png=no'.
2416 HAVE_PNG=no
2417 LIBPNG=
2418 if test "${HAVE_X11}" = "yes"; then
2419   if test "${with_png}" != "no"; then
2420     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2421     # in /usr/include/libpng.
2422     AC_CHECK_HEADERS(png.h libpng/png.h)
2423     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2424       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2425     fi
2426   fi
2427
2428   if test "${HAVE_PNG}" = "yes"; then
2429     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2430     LIBPNG="-lpng -lz -lm"
2431   fi
2432 fi
2433 AC_SUBST(LIBPNG)
2434
2435 ### Use -ltiff if available, unless `--with-tiff=no'.
2436 HAVE_TIFF=no
2437 LIBTIFF=
2438 if test "${HAVE_X11}" = "yes"; then
2439   if test "${with_tiff}" != "no"; then
2440     AC_CHECK_HEADER(tiffio.h,
2441       [tifflibs="-lz -lm"
2442       # At least one tiff package requires the jpeg library.
2443       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2444       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2445   fi
2446
2447   if test "${HAVE_TIFF}" = "yes"; then
2448     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2449     dnl FIXME -lz -lm, as per libpng?
2450     LIBTIFF=-ltiff
2451   fi
2452 fi
2453 AC_SUBST(LIBTIFF)
2454
2455 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2456 HAVE_GIF=no
2457 LIBGIF=
2458 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2459   AC_CHECK_HEADER(gif_lib.h,
2460 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2461 # Earlier versions can crash Emacs.
2462     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2463
2464   if test "$HAVE_GIF" = yes; then
2465     LIBGIF=-lgif
2466   elif test "$HAVE_GIF" = maybe; then
2467 # If gif_lib.h but no libgif, try libungif.
2468     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2469     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2470   fi
2471
2472   if test "${HAVE_GIF}" = "yes"; then
2473     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2474   fi
2475 fi
2476 AC_SUBST(LIBGIF)
2477
2478 dnl Check for required libraries.
2479 if test "${HAVE_X11}" = "yes"; then
2480   MISSING=""
2481   WITH_NO=""
2482   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2483     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2484   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2485     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2486   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2487     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2488   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2489     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2490   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2491     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2492
2493   if test "X${MISSING}" != X; then
2494     AC_MSG_ERROR([The following required libraries were not found:
2495     $MISSING
2496 Maybe some development libraries/packages are missing?
2497 If you don't want to link with them give
2498     $WITH_NO
2499 as options to configure])
2500   fi
2501 fi
2502
2503 ### Use -lgpm if available, unless `--with-gpm=no'.
2504 HAVE_GPM=no
2505 LIBGPM=
2506 if test "${with_gpm}" != "no"; then
2507   AC_CHECK_HEADER(gpm.h,
2508     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2509
2510   if test "${HAVE_GPM}" = "yes"; then
2511     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2512     LIBGPM=-lgpm
2513   fi
2514 fi
2515 AC_SUBST(LIBGPM)
2516
2517 dnl Check for malloc/malloc.h on darwin
2518 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2519
2520 C_SWITCH_X_SYSTEM=
2521 ### Use NeXTstep API to implement GUI.
2522 if test "${HAVE_NS}" = "yes"; then
2523   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2524   if test "${NS_IMPL_COCOA}" = "yes"; then
2525     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2526     GNU_OBJC_CFLAGS=
2527   fi
2528   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2529     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2530     # See also .m.o rule in Makefile.in */
2531     # FIXME: are all these flags really needed?  Document here why.  */
2532     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2533     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2534   fi
2535   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2536     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2537   fi
2538   # We also have mouse menus.
2539   HAVE_MENUS=yes
2540   OTHER_FILES=ns-app
2541 fi
2542
2543
2544 ### Use session management (-lSM -lICE) if available
2545 HAVE_X_SM=no
2546 LIBXSM=
2547 if test "${HAVE_X11}" = "yes"; then
2548   AC_CHECK_HEADER(X11/SM/SMlib.h,
2549     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2550
2551   if test "${HAVE_X_SM}" = "yes"; then
2552     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2553     LIBXSM="-lSM -lICE"
2554     case "$LIBS" in
2555       *-lSM*) ;;
2556       *)      LIBS="$LIBXSM $LIBS" ;;
2557     esac
2558   fi
2559 fi
2560 AC_SUBST(LIBXSM)
2561
2562 ### Use libxml (-lxml2) if available
2563 if test "${with_xml2}" != "no"; then
2564   ### I'm not sure what the version number should be, so I just guessed.
2565   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2566   if test "${HAVE_LIBXML2}" = "yes"; then
2567     LIBS="$LIBXML2_LIBS $LIBS"
2568     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2569     if test "${HAVE_LIBXML2}" = "yes"; then
2570       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2571     else
2572       LIBXML2_LIBS=""
2573       LIBXML2_CFLAGS=""
2574     fi
2575   fi
2576 fi
2577 AC_SUBST(LIBXML2_LIBS)
2578 AC_SUBST(LIBXML2_CFLAGS)
2579
2580 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2581 AC_CACHE_CHECK(whether netdb declares h_errno,
2582                emacs_cv_netdb_declares_h_errno,
2583 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2584   [[return h_errno;]])],
2585   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2586 if test $emacs_cv_netdb_declares_h_errno = yes; then
2587   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2588 fi
2589
2590 # fmod, logb, and frexp are found in -lm on most systems.
2591 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2592 AC_CHECK_LIB(m, sqrt)
2593
2594 # Check for mail-locking functions in a "mail" library.  Probably this should
2595 # have the same check as for liblockfile below.
2596 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2597 if test $have_mail = yes; then
2598   LIBS_MAIL=-lmail
2599   LIBS="$LIBS_MAIL $LIBS"
2600   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2601 else
2602   LIBS_MAIL=
2603 fi
2604 dnl Debian, at least:
2605 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2606 if test $have_lockfile = yes; then
2607    LIBS_MAIL=-llockfile
2608    LIBS="$LIBS_MAIL $LIBS"
2609    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2610 else
2611 # If we have the shared liblockfile, assume we must use it for mail
2612 # locking (e.g. Debian).  If we couldn't link against liblockfile
2613 # (no liblockfile.a installed), ensure that we don't need to.
2614   dnl This works for files generally, not just executables.
2615   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2616   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2617                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2618   if test $ac_cv_prog_liblockfile = yes; then
2619     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2620 This probably means that movemail could lose mail.
2621 There may be a `development' package to install containing liblockfile.])
2622   fi
2623 fi
2624 AC_CHECK_FUNCS(touchlock)
2625 AC_CHECK_HEADERS(maillock.h)
2626 AC_SUBST(LIBS_MAIL)
2627
2628 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2629 ## interlock access to the mail spool.  The alternative is a lock file named
2630 ## /usr/spool/mail/$USER.lock.
2631 mail_lock=no
2632 case "$opsys" in
2633   aix4-2) mail_lock="lockf" ;;
2634
2635   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2636
2637   ## On GNU/Linux systems, both methods are used by various mail programs.
2638   ## I assume most people are using newer mailers that have heard of flock.
2639   ## Change this if you need to.
2640   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2641   ## configure gets the right answers, and that means *NOT* using flock.
2642   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2643   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2644   ## Debian maintainer hasn't provided a clean fix for Emacs.
2645   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2646   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2647   ## correct logic.  -- fx
2648   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2649   ## liblockfile is a Free Software replacement for libmail, used on
2650   ## Debian systems and elsewhere. -rfr.
2651   gnu-*)
2652     mail_lock="flock"
2653     if test $have_mail = yes || test $have_lockfile = yes; then
2654       test $ac_cv_header_maillock_h = yes && mail_lock=no
2655     fi
2656     ;;
2657 esac
2658
2659 BLESSMAIL_TARGET=
2660 case "$mail_lock" in
2661   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2662
2663   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2664
2665   *) BLESSMAIL_TARGET="need-blessmail" ;;
2666 esac
2667 AC_SUBST(BLESSMAIL_TARGET)
2668
2669
2670 AC_CHECK_FUNCS(gethostname getdomainname \
2671 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2672 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2673 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2674 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2675 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2676 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2677 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2678 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2679 cfmakeraw cfsetspeed isnan copysign __executable_start)
2680
2681 dnl Cannot use AC_CHECK_FUNCS
2682 AC_CACHE_CHECK([for __builtin_unwind_init],
2683                emacs_cv_func___builtin_unwind_init,
2684 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2685                 emacs_cv_func___builtin_unwind_init=yes,
2686                 emacs_cv_func___builtin_unwind_init=no)])
2687 if test $emacs_cv_func___builtin_unwind_init = yes; then
2688   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2689             [Define to 1 if you have the `__builtin_unwind_init' function.])
2690 fi
2691
2692 AC_CHECK_HEADERS(sys/un.h)
2693
2694 AC_FUNC_FSEEKO
2695
2696 AC_FUNC_GETPGRP
2697
2698 # Configure gnulib.
2699 gl_ASSERT_NO_GNULIB_POSIXCHECK
2700 gl_ASSERT_NO_GNULIB_TESTS
2701 gl_INIT
2702
2703 # UNIX98 PTYs.
2704 AC_CHECK_FUNCS(grantpt)
2705
2706 # PTY-related GNU extensions.
2707 AC_CHECK_FUNCS(getpt)
2708
2709 # Check this now, so that we will NOT find the above functions in ncurses.
2710 # That is because we have not set up to link ncurses in lib-src.
2711 # It's better to believe a function is not available
2712 # than to expect to find it in ncurses.
2713 # Also we need tputs and friends to be able to build at all.
2714 have_tputs_et_al=true
2715 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2716 if test "$have_tputs_et_al" != true; then
2717   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2718 Maybe some development libraries/packages are missing?  Try installing
2719 libncurses-dev(el), libterminfo-dev(el) or similar.])
2720 fi
2721 # Must define this when any termcap library is found.
2722 AC_DEFINE(HAVE_LIBNCURSES, 1,
2723           [Define to 1 if you have the `ncurses' library (-lncurses).])
2724 ## FIXME This was the cpp logic, but I am not sure it is right.
2725 ## The above test has not necessarily found libncurses.
2726 HAVE_LIBNCURSES=yes
2727
2728 ## Use terminfo instead of termcap?
2729 ## Note only system files NOT using terminfo are:
2730 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2731 ## darwin|gnu without ncurses.
2732 TERMINFO=no
2733 LIBS_TERMCAP=
2734 case "$opsys" in
2735   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2736   ## hpux10-20: Use the system provided termcap(3) library.
2737   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2738   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2739   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2740
2741   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2742   ##  The ncurses library has been moved out of the System framework in
2743   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2744   ##  option to use it.
2745   darwin|gnu*)
2746     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2747     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2748       TERMINFO=yes
2749       LIBS_TERMCAP="-lncurses"
2750     fi
2751     ;;
2752
2753   freebsd)
2754     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2755     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2756     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2757 [[#if __FreeBSD_version < 400000
2758 fail;
2759 #endif
2760 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2761
2762     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2763
2764     if test $emacs_cv_freebsd_terminfo = yes; then
2765       TERMINFO=yes
2766       LIBS_TERMCAP="-lncurses"
2767     else
2768       LIBS_TERMCAP="-ltermcap"
2769     fi
2770     ;;
2771
2772   netbsd)
2773     if test $ac_cv_search_tputs = -lterminfo; then
2774       TERMINFO=yes
2775       LIBS_TERMCAP="-lterminfo"
2776     else
2777       LIBS_TERMCAP="-ltermcap"
2778     fi
2779     ;;
2780
2781 esac
2782
2783 case "$opsys" in
2784   ## hpux: Make sure we get select from libc rather than from libcurses
2785   ##  because libcurses on HPUX 10.10 has a broken version of select.
2786   ##  We used to use -lc -lcurses, but this may be cleaner.
2787   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2788
2789   openbsd) LIBS_TERMCAP="-lncurses" ;;
2790
2791   ## Must use system termcap, if we use any termcap.  It does special things.
2792   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2793 esac
2794
2795 TERMCAP_OBJ=tparam.o
2796 if test $TERMINFO = yes; then
2797   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2798
2799   ## Default used to be -ltermcap.  Add a case above if need something else.
2800   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2801
2802   TERMCAP_OBJ=terminfo.o
2803 fi
2804 AC_SUBST(LIBS_TERMCAP)
2805 AC_SUBST(TERMCAP_OBJ)
2806
2807
2808 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2809 resolv=no
2810 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2811 #include <arpa/nameser.h>
2812 #include <resolv.h>]],
2813     [[return res_init();]])],
2814     have_res_init=yes, have_res_init=no)
2815 if test "$have_res_init" = no; then
2816   OLIBS="$LIBS"
2817   LIBS="$LIBS -lresolv"
2818   AC_MSG_CHECKING(for res_init with -lresolv)
2819   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2820 #include <arpa/nameser.h>
2821 #include <resolv.h>]],
2822     [[return res_init();]])],
2823     have_res_init=yes, have_res_init=no)
2824   AC_MSG_RESULT($have_res_init)
2825   if test "$have_res_init" = yes ; then
2826     resolv=yes
2827   fi
2828   LIBS="$OLIBS"
2829 fi
2830
2831 if test "$have_res_init" = yes; then
2832   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2833 fi
2834
2835 # Do we need the Hesiod library to provide the support routines?
2836 LIBHESIOD=
2837 if test "$with_hesiod" != no ; then
2838   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2839   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2840      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2841                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2842   if test "$resolv" = yes ; then
2843     RESOLVLIB=-lresolv
2844   else
2845     RESOLVLIB=
2846   fi
2847   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2848         hesiod=yes, :, $RESOLVLIB)])
2849
2850   if test x"$hesiod" = xyes; then
2851     AC_DEFINE(HAVE_LIBHESIOD, 1,
2852               [Define to 1 if you have the hesiod library (-lhesiod).])
2853     LIBHESIOD=-lhesiod
2854   fi
2855 fi
2856 AC_SUBST(LIBHESIOD)
2857
2858 # Do we need libresolv (due to res_init or Hesiod)?
2859 if test "$resolv" = yes ; then
2860   AC_DEFINE(HAVE_LIBRESOLV, 1,
2861             [Define to 1 if you have the resolv library (-lresolv).])
2862   LIBRESOLV=-lresolv
2863 else
2864   LIBRESOLV=
2865 fi
2866 AC_SUBST(LIBRESOLV)
2867
2868 # These tell us which Kerberos-related libraries to use.
2869 COM_ERRLIB=
2870 CRYPTOLIB=
2871 KRB5LIB=
2872 DESLIB=
2873 KRB4LIB=
2874
2875 if test "${with_kerberos}" != no; then
2876   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2877   if test $have_com_err = yes; then
2878     COM_ERRLIB=-lcom_err
2879     LIBS="$COM_ERRLIB $LIBS"
2880     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2881   fi
2882   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2883   if test $have_crypto = yes; then
2884     CRYPTOLIB=-lcrypto
2885     LIBS="$CRYPTOLIB $LIBS"
2886     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2887   fi
2888   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2889   if test $have_k5crypto = yes; then
2890     CRYPTOLIB=-lk5crypto
2891     LIBS="$CRYPTOLIB $LIBS"
2892     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2893   fi
2894   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2895   if test $have_krb5=yes; then
2896     KRB5LIB=-lkrb5
2897     LIBS="$KRB5LIB $LIBS"
2898     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2899   fi
2900   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2901   if test "${with_kerberos5}" = no; then
2902     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2903     if test $have_des425 = yes; then
2904       DESLIB=-ldes425
2905       LIBS="$DESLIB $LIBS"
2906       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2907     else
2908       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2909       if test $have_des = yes; then
2910         DESLIB=-ldes
2911         LIBS="$DESLIB $LIBS"
2912         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2913       fi
2914     fi
2915     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2916     if test $have_krb4 = yes; then
2917       KRB4LIB=-lkrb4
2918       LIBS="$KRB4LIB $LIBS"
2919       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2920     else
2921       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2922       if test $have_krb = yes; then
2923         KRB4LIB=-lkrb
2924         LIBS="$KRB4LIB $LIBS"
2925         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2926       fi
2927     fi
2928   fi
2929
2930   if test "${with_kerberos5}" != no; then
2931     AC_CHECK_HEADERS(krb5.h,
2932       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2933                         [#include <krb5.h>])])
2934   else
2935     AC_CHECK_HEADERS(des.h,,
2936                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2937                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2938     AC_CHECK_HEADERS(krb.h,,
2939                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2940                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2941   fi
2942   AC_CHECK_HEADERS(com_err.h)
2943 fi
2944
2945 AC_SUBST(COM_ERRLIB)
2946 AC_SUBST(CRYPTOLIB)
2947 AC_SUBST(KRB5LIB)
2948 AC_SUBST(DESLIB)
2949 AC_SUBST(KRB4LIB)
2950
2951 # Solaris requires -lintl if you want strerror (which calls dgettext)
2952 # to return localized messages.
2953 AC_CHECK_LIB(intl, dgettext)
2954
2955 AC_MSG_CHECKING(whether localtime caches TZ)
2956 AC_CACHE_VAL(emacs_cv_localtime_cache,
2957 [if test x$ac_cv_func_tzset = xyes; then
2958 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2959 char TZ_GMT0[] = "TZ=GMT0";
2960 char TZ_PST8[] = "TZ=PST8";
2961 main()
2962 {
2963   time_t now = time ((time_t *) 0);
2964   int hour_GMT0, hour_unset;
2965   if (putenv (TZ_GMT0) != 0)
2966     exit (1);
2967   hour_GMT0 = localtime (&now)->tm_hour;
2968   unsetenv("TZ");
2969   hour_unset = localtime (&now)->tm_hour;
2970   if (putenv (TZ_PST8) != 0)
2971     exit (1);
2972   if (localtime (&now)->tm_hour == hour_GMT0)
2973     exit (1);
2974   unsetenv("TZ");
2975   if (localtime (&now)->tm_hour != hour_unset)
2976     exit (1);
2977   exit (0);
2978 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2979 [# If we have tzset, assume the worst when cross-compiling.
2980 emacs_cv_localtime_cache=yes])
2981 else
2982         # If we lack tzset, report that localtime does not cache TZ,
2983         # since we can't invalidate the cache if we don't have tzset.
2984         emacs_cv_localtime_cache=no
2985 fi])dnl
2986 AC_MSG_RESULT($emacs_cv_localtime_cache)
2987 if test $emacs_cv_localtime_cache = yes; then
2988   AC_DEFINE(LOCALTIME_CACHE, 1,
2989             [Define to 1 if localtime caches TZ.])
2990 fi
2991
2992 if test "x$HAVE_TIMEVAL" = xyes; then
2993   AC_CHECK_FUNCS(gettimeofday)
2994   if test $ac_cv_func_gettimeofday = yes; then
2995     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2996                    emacs_cv_gettimeofday_two_arguments,
2997     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2998 #ifdef TIME_WITH_SYS_TIME
2999 #include <sys/time.h>
3000 #include <time.h>
3001 #else
3002 #ifdef HAVE_SYS_TIME_H
3003 #include <sys/time.h>
3004 #else
3005 #include <time.h>
3006 #endif
3007 #endif]],
3008       [[struct timeval time;
3009        gettimeofday (&time, 0);]])],
3010       emacs_cv_gettimeofday_two_arguments=yes,
3011       emacs_cv_gettimeofday_two_arguments=no)])
3012     if test $emacs_cv_gettimeofday_two_arguments = no; then
3013       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3014                 [Define to 1 if gettimeofday accepts only one argument.])
3015     fi
3016   fi
3017 fi
3018
3019 ok_so_far=yes
3020 AC_CHECK_FUNC(socket, , ok_so_far=no)
3021 if test $ok_so_far = yes; then
3022   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3023 fi
3024 if test $ok_so_far = yes; then
3025   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3026 fi
3027 if test $ok_so_far = yes; then
3028 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3029   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3030             [Define to 1 if you have inet sockets.])
3031 fi
3032
3033 if test -f /usr/lpp/X11/bin/smt.exp; then
3034   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3035             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3036 fi
3037
3038 AC_MSG_CHECKING(whether system supports dynamic ptys)
3039 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3040   AC_MSG_RESULT(yes)
3041   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3042 else
3043   AC_MSG_RESULT(no)
3044 fi
3045
3046 AC_FUNC_FORK
3047
3048 dnl Adapted from Haible's version.
3049 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3050   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3051     [[char* cs = nl_langinfo(CODESET);]])],
3052     emacs_cv_langinfo_codeset=yes,
3053     emacs_cv_langinfo_codeset=no)
3054   ])
3055 if test $emacs_cv_langinfo_codeset = yes; then
3056   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3057     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3058 fi
3059
3060 AC_TYPE_MBSTATE_T
3061
3062 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3063   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3064                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3065 if test "$emacs_cv_c_restrict_arr" = yes; then
3066   AC_DEFINE(__restrict_arr, __restrict,
3067     [Define to compiler's equivalent of C99 restrict keyword in array
3068      declarations.  Define as empty for no equivalent.])
3069 fi
3070
3071 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3072 dnl how the tty code is related to POSIX and/or other versions of termios.
3073 dnl The following looks like a useful start.
3074 dnl
3075 dnl AC_SYS_POSIX_TERMIOS
3076 dnl if test $ac_cv_sys_posix_termios = yes; then
3077 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3078 dnl                                and macros for terminal control.])
3079 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3080 dnl fi
3081
3082 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3083
3084 # Set up the CFLAGS for real compilation, so we can substitute it.
3085 CFLAGS="$REAL_CFLAGS"
3086 CPPFLAGS="$REAL_CPPFLAGS"
3087
3088 ## Hack to detect a buggy GCC version.
3089 if test "x$GCC" = xyes \
3090    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3091    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3092    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3093    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3094 fi
3095
3096 version=$PACKAGE_VERSION
3097
3098 ### Specify what sort of things we'll be editing into Makefile and config.h.
3099 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3100 AC_SUBST(version)
3101 AC_SUBST(configuration)
3102 ## Unused?
3103 AC_SUBST(canonical)
3104 AC_SUBST(srcdir)
3105 AC_SUBST(prefix)
3106 AC_SUBST(exec_prefix)
3107 AC_SUBST(bindir)
3108 AC_SUBST(datadir)
3109 AC_SUBST(sharedstatedir)
3110 AC_SUBST(libexecdir)
3111 AC_SUBST(mandir)
3112 AC_SUBST(infodir)
3113 AC_SUBST(lispdir)
3114 AC_SUBST(locallisppath)
3115 AC_SUBST(lisppath)
3116 AC_SUBST(x_default_search_path)
3117 AC_SUBST(etcdir)
3118 AC_SUBST(archlibdir)
3119 AC_SUBST(docdir)
3120 AC_SUBST(bitmapdir)
3121 AC_SUBST(gamedir)
3122 AC_SUBST(gameuser)
3123 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3124 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3125 ## end of LIBX_BASE, but nothing ever set it.
3126 AC_SUBST(LD_SWITCH_X_SITE)
3127 AC_SUBST(C_SWITCH_X_SITE)
3128 AC_SUBST(C_SWITCH_X_SYSTEM)
3129 AC_SUBST(CFLAGS)
3130 ## Used in lwlib/Makefile.in.
3131 AC_SUBST(X_TOOLKIT_TYPE)
3132 if test -n "${machfile}"; then
3133   M_FILE="\$(srcdir)/${machfile}"
3134 else
3135   M_FILE=
3136 fi
3137 S_FILE="\$(srcdir)/${opsysfile}"
3138 AC_SUBST(M_FILE)
3139 AC_SUBST(S_FILE)
3140 AC_SUBST(ns_appdir)
3141 AC_SUBST(ns_appbindir)
3142 AC_SUBST(ns_appresdir)
3143 AC_SUBST(ns_appsrc)
3144 AC_SUBST(GNU_OBJC_CFLAGS)
3145 AC_SUBST(OTHER_FILES)
3146
3147 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3148                    [Define to the canonical Emacs configuration name.])
3149 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3150                    [Define to the options passed to configure.])
3151 if test -n "$machfile"; then
3152   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3153                      [Define to the used machine dependent file.])
3154 fi
3155 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3156                    [Define to the used os dependent file.])
3157
3158 XMENU_OBJ=
3159 XOBJ=
3160 FONT_OBJ=
3161 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3162   AC_DEFINE(HAVE_X_WINDOWS, 1,
3163             [Define to 1 if you want to use the X window system.])
3164   XMENU_OBJ=xmenu.o
3165   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3166   FONT_OBJ=xfont.o
3167   if test "$HAVE_XFT" = "yes"; then
3168     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3169   elif test "$HAVE_FREETYPE" = "yes"; then
3170     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3171   fi
3172   AC_SUBST(FONT_OBJ)
3173 fi
3174 AC_SUBST(XMENU_OBJ)
3175 AC_SUBST(XOBJ)
3176 AC_SUBST(FONT_OBJ)
3177
3178 WIDGET_OBJ=
3179 MOTIF_LIBW=
3180 if test "${USE_X_TOOLKIT}" != "none" ; then
3181   WIDGET_OBJ=widget.o
3182   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3183   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3184     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3185   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3186     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3187     MOTIF_LIBW=-lXm
3188     case "$opsys" in
3189       gnu-linux)
3190         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3191         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3192         ;;
3193
3194       unixware)
3195         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3196         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3197         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3198         ;;
3199
3200       aix4-2)
3201         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3202         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3203         ;;
3204     esac
3205     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3206   fi
3207 fi
3208 AC_SUBST(WIDGET_OBJ)
3209
3210 TOOLKIT_LIBW=
3211 case "$USE_X_TOOLKIT" in
3212   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3213   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3214   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3215 esac
3216 AC_SUBST(TOOLKIT_LIBW)
3217
3218 if test "$USE_X_TOOLKIT" = "none"; then
3219   LIBXT_OTHER="\$(LIBXSM)"
3220   OLDXMENU_TARGET="really-oldXMenu"
3221 else
3222   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3223   OLDXMENU_TARGET="really-lwlib"
3224 fi
3225 AC_SUBST(LIBXT_OTHER)
3226
3227 ## The X Menu stuff is present in the X10 distribution, but missing
3228 ## from X11.  If we have X10, just use the installed library;
3229 ## otherwise, use our own copy.
3230 if test "${HAVE_X11}" = "yes" ; then
3231   AC_DEFINE(HAVE_X11, 1,
3232             [Define to 1 if you want to use version 11 of X windows.
3233              Otherwise, Emacs expects to use version 10.])
3234
3235   if test "$USE_X_TOOLKIT" = "none"; then
3236     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3237   else
3238     OLDXMENU="\${lwlibdir}/liblw.a"
3239   fi
3240   LIBXMENU="\$(OLDXMENU)"
3241   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3242   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3243 else
3244   ## For a syntactically valid Makefile; not actually used for anything.
3245   ## See comments in src/Makefile.in.
3246   OLDXMENU=nothing
3247   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3248   if test "${HAVE_X_WINDOWS}" = "yes"; then
3249     LIBXMENU="-lXMenu"
3250   else
3251     LIBXMENU=
3252   fi
3253   LIBX_OTHER=
3254   OLDXMENU_DEPS=
3255 fi
3256
3257 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3258   OLDXMENU_TARGET=
3259   OLDXMENU=nothing
3260   LIBXMENU=
3261   OLDXMENU_DEPS=
3262 fi
3263
3264 AC_SUBST(OLDXMENU_TARGET)
3265 AC_SUBST(OLDXMENU)
3266 AC_SUBST(LIBXMENU)
3267 AC_SUBST(LIBX_OTHER)
3268 AC_SUBST(OLDXMENU_DEPS)
3269
3270 if test "${HAVE_MENUS}" = "yes" ; then
3271   AC_DEFINE(HAVE_MENUS, 1,
3272             [Define to 1 if you have mouse menus.
3273              (This is automatic if you use X, but the option to specify it remains.)
3274              It is also defined with other window systems that support xmenu.c.])
3275 fi
3276
3277 if test "${GNU_MALLOC}" = "yes" ; then
3278   AC_DEFINE(GNU_MALLOC, 1,
3279             [Define to 1 if you want to use the GNU memory allocator.])
3280 fi
3281
3282 RALLOC_OBJ=
3283 if test "${REL_ALLOC}" = "yes" ; then
3284   AC_DEFINE(REL_ALLOC, 1,
3285             [Define REL_ALLOC if you want to use the relocating allocator for
3286              buffer space.])
3287
3288   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3289 fi
3290 AC_SUBST(RALLOC_OBJ)
3291
3292 if test "$opsys" = "cygwin"; then
3293   CYGWIN_OBJ="sheap.o"
3294   ## Cygwin differs because of its unexec().
3295   PRE_ALLOC_OBJ=
3296   POST_ALLOC_OBJ=lastfile.o
3297 else
3298   CYGWIN_OBJ=
3299   PRE_ALLOC_OBJ=lastfile.o
3300   POST_ALLOC_OBJ=
3301 fi
3302 AC_SUBST(CYGWIN_OBJ)
3303 AC_SUBST(PRE_ALLOC_OBJ)
3304 AC_SUBST(POST_ALLOC_OBJ)
3305
3306
3307 case "$opsys" in
3308   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3309
3310   darwin)
3311    ## The -headerpad option tells ld (see man page) to leave room at the
3312    ## end of the header for adding load commands.  Needed for dumping.
3313    ## 0x690 is the total size of 30 segment load commands (at 56
3314    ## each); under Cocoa 31 commands are required.
3315    if test "$HAVE_NS" = "yes"; then
3316      libs_nsgui="-framework AppKit"
3317      headerpad_extra=6C8
3318    else
3319      libs_nsgui=
3320      headerpad_extra=690
3321    fi
3322    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3323
3324    ## This is here because src/Makefile.in did some extra fiddling around
3325    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3326    ##   #ifndef LD_SWITCH_SYSTEM
3327    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3328    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3329    ## not using gcc, darwin system not on an alpha (ie darwin, since
3330    ## darwin + alpha does not occur).
3331    ## Because this was done in src/Makefile.in, the resulting part of
3332    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3333    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3334    ## rather than LD_SWITCH_SYSTEM.
3335    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3336      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3337    ;;
3338
3339   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3340   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3341   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3342   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3343   ## had different values in configure (in ac_link) and src/Makefile.in.
3344   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3345   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3346
3347   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3348 esac
3349
3350 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3351   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3352 fi
3353
3354 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3355
3356
3357 LD_FIRSTFLAG=
3358 ORDINARY_LINK=
3359 case "$opsys" in
3360   ## gnu: GNU needs its own crt0.
3361   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3362
3363   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3364   ## library search parth, i.e. it won't search /usr/lib for libc and
3365   ## friends.  Using -nostartfiles instead avoids this problem, and
3366   ## will also work on earlier NetBSD releases.
3367   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3368
3369   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3370   ##   MkLinux/LinuxPPC needs this.
3371   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3372   gnu-*)
3373     case "$machine" in
3374       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3375     esac
3376     ;;
3377 esac
3378
3379
3380 if test "x$ORDINARY_LINK" = "xyes"; then
3381
3382   LD_FIRSTFLAG=""
3383   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3384
3385 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3386 ## freebsd, gnu-* not on macppc|ibms390x.
3387 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3388
3389   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3390   ## places that are difficult to figure out at make time.  Fortunately,
3391   ## these same versions allow you to pass arbitrary flags on to the
3392   ## linker, so there is no reason not to use it as a linker.
3393   ##
3394   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3395   ## searching for libraries in its internal directories, so we have to
3396   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3397   LD_FIRSTFLAG="-nostdlib"
3398 fi
3399
3400 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3401 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3402
3403 AC_SUBST(LD_FIRSTFLAG)
3404
3405
3406 ## FIXME? The logic here is not precisely the same as that above.
3407 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3408 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3409 LIB_GCC=
3410 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3411
3412   case "$opsys" in
3413     freebsd|netbsd|openbsd) LIB_GCC= ;;
3414
3415     gnu-*)
3416       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3417       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3418       case $host_cpu in
3419       arm*)
3420         LIB_GCC="-lgcc_s"
3421         ;;
3422       *)
3423         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3424         ## immediately undefine it again and redefine it to empty.
3425         ## Was the C_SWITCH_X_SITE part really necessary?
3426 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3427         LIB_GCC=
3428         ;;
3429       esac
3430       ;;
3431
3432     ## Ask GCC where to find libgcc.a.
3433     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3434   esac
3435 fi                              dnl if $GCC
3436 AC_SUBST(LIB_GCC)
3437
3438
3439 ## If we're using X11/GNUstep, define some consequences.
3440 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3441   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3442   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3443 fi
3444
3445
3446 AH_TOP([/* GNU Emacs site configuration template file.
3447
3448 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3449   Free Software Foundation, Inc.
3450
3451 This file is part of GNU Emacs.
3452
3453 GNU Emacs is free software: you can redistribute it and/or modify
3454 it under the terms of the GNU General Public License as published by
3455 the Free Software Foundation, either version 3 of the License, or
3456 (at your option) any later version.
3457
3458 GNU Emacs is distributed in the hope that it will be useful,
3459 but WITHOUT ANY WARRANTY; without even the implied warranty of
3460 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3461 GNU General Public License for more details.
3462
3463 You should have received a copy of the GNU General Public License
3464 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3465
3466
3467 /* No code in Emacs #includes config.h twice, but some bits of code
3468    intended to work with other packages as well (like gmalloc.c)
3469    think they can include it as many times as they like.  */
3470 #ifndef EMACS_CONFIG_H
3471 #define EMACS_CONFIG_H
3472 ])dnl
3473
3474 AH_BOTTOM([
3475 /* On AIX 3 this must be included before any other include file.  */
3476 #include <alloca.h>
3477 #if ! HAVE_ALLOCA
3478 # error "alloca not available on this machine"
3479 #endif
3480
3481 /* Define AMPERSAND_FULL_NAME if you use the convention
3482    that & in the full name stands for the login id.  */
3483 /* Turned on June 1996 supposing nobody will mind it.  */
3484 #define AMPERSAND_FULL_NAME
3485
3486 /* `subprocesses' should be defined if you want to
3487    have code for asynchronous subprocesses
3488    (as used in M-x compile and M-x shell).
3489    Only MSDOS does not support this (it overrides
3490    this in its config_opsysfile below).  */
3491
3492 #define subprocesses
3493
3494 /* Include the os and machine dependent files.  */
3495 #include config_opsysfile
3496 #ifdef config_machfile
3497 # include config_machfile
3498 #endif
3499
3500 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3501    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3502   (There is probably a better place to do this, but right now the
3503    Cocoa side does this in s/darwin.h and we cannot parallel this
3504    exactly since GNUstep is multi-OS.  */
3505 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3506 #  define SYSTEM_PURESIZE_EXTRA 30000
3507 #endif
3508
3509 #ifdef emacs /* Don't do this for lib-src.  */
3510 /* Tell regex.c to use a type compatible with Emacs.  */
3511 #define RE_TRANSLATE_TYPE Lisp_Object
3512 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3513 #ifdef make_number
3514 /* If make_number is a macro, use it.  */
3515 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3516 #else
3517 /* If make_number is a function, avoid it.  */
3518 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3519 #endif
3520 #endif
3521
3522 /* These default definitions are good for almost all machines.
3523    Any exceptions should override them in m/MACHINE.h.
3524    They must be usable in preprocessor conditionals.  */
3525
3526 #ifndef BITS_PER_CHAR
3527 #define BITS_PER_CHAR 8
3528 #endif
3529
3530 #ifndef BITS_PER_SHORT
3531 #define BITS_PER_SHORT 16
3532 #endif
3533
3534 #ifndef BITS_PER_INT
3535 #define BITS_PER_INT 32
3536 #endif
3537
3538 #ifndef BITS_PER_LONG
3539 #ifdef _LP64
3540 #define BITS_PER_LONG 64
3541 #else
3542 #define BITS_PER_LONG 32
3543 #endif
3544 #endif
3545
3546 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3547 #define BITS_PER_LONG_LONG 64
3548 #endif
3549
3550 /* Define if the compiler supports function prototypes.  It may do so but
3551    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3552 #undef PROTOTYPES
3553
3554 #include <string.h>
3555 #include <stdlib.h>
3556
3557 #ifndef HAVE_STRCHR
3558 #define strchr(a, b) index (a, b)
3559 #endif
3560
3561 #ifndef HAVE_STRRCHR
3562 #define strrchr(a, b) rindex (a, b)
3563 #endif
3564
3565 #if defined __GNUC__ && (__GNUC__ > 2 \
3566                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3567 #define NO_RETURN       __attribute__ ((__noreturn__))
3568 #else
3569 #define NO_RETURN       /* nothing */
3570 #endif
3571
3572 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3573 #define NO_INLINE __attribute__((noinline))
3574 #else
3575 #define NO_INLINE
3576 #endif
3577
3578 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3579 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3580 #else
3581 #define EXTERNALLY_VISIBLE
3582 #endif
3583
3584 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3585 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3586 #else
3587 # define ATTRIBUTE_FORMAT(spec) /* empty */
3588 #endif
3589
3590 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3591 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3592    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3593 #else
3594 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3595    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3596 #endif
3597
3598 /* Some versions of GNU/Linux define noinline in their headers.  */
3599 #ifdef noinline
3600 #undef noinline
3601 #endif
3602
3603 /* These won't be used automatically yet.  We also need to know, at least,
3604    that the stack is continuous.  */
3605 #ifdef __GNUC__
3606 #  ifndef GC_SETJMP_WORKS
3607   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3608 #    define GC_SETJMP_WORKS 1
3609 #  endif
3610 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3611 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3612 #  endif
3613 #endif
3614
3615 #endif /* EMACS_CONFIG_H */
3616
3617 /*
3618 Local Variables:
3619 mode: c
3620 End:
3621 */
3622 ])dnl
3623
3624 #### Report on what we decided to do.
3625 #### Report GTK as a toolkit, even if it doesn't use Xt.
3626 #### It makes printing result more understandable as using GTK sets
3627 #### toolkit_scroll_bars to yes by default.
3628 if test "${HAVE_GTK}" = "yes"; then
3629   USE_X_TOOLKIT=GTK
3630 fi
3631
3632 and_machfile=
3633 if test -n "$machfile"; then
3634   and_machfile=" and \`${machfile}'"
3635 fi
3636
3637 echo "
3638 Configured for \`${canonical}'.
3639
3640   Where should the build process find the source code?    ${srcdir}
3641   What operating system and machine description files should Emacs use?
3642         \`${opsysfile}'${and_machfile}
3643   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3644   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3645   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3646   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3647   What window system should Emacs use?                    ${window_system}
3648   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3649
3650 if test -n "${x_includes}"; then
3651 echo "  Where do we find X Windows header files?                ${x_includes}"
3652 else
3653 echo "  Where do we find X Windows header files?                Standard dirs"
3654 fi
3655 if test -n "${x_libraries}"; then
3656 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3657 else
3658 echo "  Where do we find X Windows libraries?                   Standard dirs"
3659 fi
3660
3661 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3662 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3663 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3664 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3665 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3666 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3667 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3668 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3669
3670 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3671 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3672 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3673 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3674 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3675 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3676
3677 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3678 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3679 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3680 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3681
3682 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3683 echo
3684
3685 if test $USE_XASSERTS = yes; then
3686    echo "  Compiling with asserts turned on."
3687    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3688 fi
3689
3690 echo
3691
3692 if test "$HAVE_NS" = "yes"; then
3693    echo
3694    echo "You must run \"make install\" in order to test the built application.
3695 The installed application will go to nextstep/Emacs.app and can be
3696 run or moved from there."
3697    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3698       echo "The application will be fully self-contained."
3699     else
3700       echo "The lisp resources for the application will be installed under ${prefix}.
3701 You may need to run \"make install\" with sudo.  The application will fail
3702 to run if these resources are not installed."
3703    fi
3704    echo
3705 fi
3706
3707
3708 # Remove any trailing slashes in these variables.
3709 [test "${prefix}" != NONE &&
3710   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3711 test "${exec_prefix}" != NONE &&
3712   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3713
3714 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3715 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3716 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3717 dnl (else you get "no `Makefile.am' found for any configure output").
3718 dnl This will work, but you get a config.status that is not quite right
3719 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3720 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3721 dnl it seems better to just live with the duplication.
3722 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3723
3724 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3725        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3726        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3727        leim/Makefile])
3728
3729 dnl test/ is not present in release tarfiles.
3730 opt_makefile=test/automated/Makefile
3731
3732 if test -f $srcdir/${opt_makefile}.in; then
3733   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3734   dnl Again, it's best not to use a variable.  Though you can add
3735   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3736   AC_CONFIG_FILES([test/automated/Makefile])
3737 fi
3738
3739 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3740
3741 AC_SUBST(SUBDIR_MAKEFILES_IN)
3742
3743 dnl Make the necessary directories, if they don't exist.
3744 AC_CONFIG_COMMANDS([mkdirs], [
3745 for dir in etc lisp ; do
3746   test -d ${dir} || mkdir ${dir}
3747 done
3748 ])
3749
3750 dnl You might wonder (I did) why epaths.h is generated by running make,
3751 dnl rather than just letting configure generate it from epaths.in.
3752 dnl One reason is that the various paths are not fully expanded (see above);
3753 dnl eg gamedir=${prefix}/var/games/emacs.
3754 dnl Secondly, the GNU Coding standards require that one should be able
3755 dnl to run `make prefix=/some/where/else' and override the values set
3756 dnl by configure.  This also explains the `move-if-change' test and
3757 dnl the use of force in the `epaths-force' rule in Makefile.in.
3758 AC_CONFIG_COMMANDS([epaths], [
3759 echo creating src/epaths.h
3760 ${MAKE-make} epaths-force
3761 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3762
3763 AC_CONFIG_COMMANDS([gdbinit], [
3764 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3765   echo creating src/.gdbinit
3766   echo source $srcdir/src/.gdbinit > src/.gdbinit
3767 fi
3768 ])
3769
3770 AC_OUTPUT
3771
3772 dnl configure.in ends here