lisp/image-mode.el

   1 ;;; image-mode.el --- support for visiting image files
   2 ;;
   3 ;; Copyright (C) 2005-2012 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Richard Stallman <rms@gnu.org>
   6 ;; Keywords: multimedia
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Defines a major mode for visiting image files
  27 ;; that allows conversion between viewing the text of the file
  28 ;; and viewing the file as an image.  Viewing the image
  29 ;; works by putting a `display' text-property on the
  30 ;; image data, with the image-data still present underneath; if the
  31 ;; resulting buffer file is saved to another name it will correctly save
  32 ;; the image data to the new file.
  33
  34 ;;; Code:
  35
  36 (require 'image)
  37 (eval-when-compile (require 'cl))
  38
  39 ;;; Image mode window-info management.
  40
  41 (defvar image-mode-winprops-alist t)
  42 (make-variable-buffer-local 'image-mode-winprops-alist)
  43
  44 (defvar image-mode-new-window-functions nil
  45   "Special hook run when image data is requested in a new window.
  46 It is called with one argument, the initial WINPROPS.")
  47
  48 (defun image-mode-winprops (&optional window cleanup)
  49   "Return winprops of WINDOW.
  50 A winprops object has the shape (WINDOW . ALIST)."
  51   (cond ((null window)
  52          (setq window (selected-window)))
  53         ((not (windowp window))
  54          (error "Not a window: %s" window)))
  55   (when cleanup
  56     (setq image-mode-winprops-alist
  57           (delq nil (mapcar (lambda (winprop)
  58                               (if (window-live-p (car-safe winprop))
  59                                   winprop))
  60                             image-mode-winprops-alist))))
  61   (let ((winprops (assq window image-mode-winprops-alist)))
  62     ;; For new windows, set defaults from the latest.
  63     (unless winprops
  64       (setq winprops (cons window
  65                            (copy-alist (cdar image-mode-winprops-alist))))
  66       (run-hook-with-args 'image-mode-new-window-functions winprops))
  67     ;; Move window to front.
  68     (setq image-mode-winprops-alist
  69           (cons winprops (delq winprops image-mode-winprops-alist)))
  70     winprops))
  71
  72 (defun image-mode-window-get (prop &optional winprops)
  73   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  74   (cdr (assq prop (cdr winprops))))
  75
  76 (defsetf image-mode-window-get (prop &optional winprops) (val)
  77   `(image-mode-window-put ,prop ,val ,winprops))
  78
  79 (defun image-mode-window-put (prop val &optional winprops)
  80   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  81   (setcdr winprops (cons (cons prop val)
  82                          (delq (assq prop (cdr winprops)) (cdr winprops)))))
  83
  84 (defun image-set-window-vscroll (vscroll)
  85   (setf (image-mode-window-get 'vscroll) vscroll)
  86   (set-window-vscroll (selected-window) vscroll))
  87
  88 (defun image-set-window-hscroll (ncol)
  89   (setf (image-mode-window-get 'hscroll) ncol)
  90   (set-window-hscroll (selected-window) ncol))
  91
  92 (defun image-mode-reapply-winprops ()
  93   ;; When set-window-buffer, set hscroll and vscroll to what they were
  94   ;; last time the image was displayed in this window.
  95   (when (and (image-get-display-property)
  96              (listp image-mode-winprops-alist))
  97     (let* ((winprops (image-mode-winprops nil t))
  98            (hscroll (image-mode-window-get 'hscroll winprops))
  99            (vscroll (image-mode-window-get 'vscroll winprops)))
 100       (if hscroll (set-window-hscroll (selected-window) hscroll))
 101       (if vscroll (set-window-vscroll (selected-window) vscroll)))))
 102
 103 (defun image-mode-setup-winprops ()
 104   ;; Record current scroll settings.
 105   (unless (listp image-mode-winprops-alist)
 106     (setq image-mode-winprops-alist nil))
 107   (add-hook 'window-configuration-change-hook
 108             'image-mode-reapply-winprops nil t))
 109
 110 ;;; Image scrolling functions
 111
 112 (defun image-get-display-property ()
 113   (get-char-property (point-min) 'display
 114                      ;; There might be different images for different displays.
 115                      (if (eq (window-buffer) (current-buffer))
 116                          (selected-window))))
 117
 118 (declare-function image-size "image.c" (spec &optional pixels frame))
 119
 120 (defun image-display-size (spec &optional pixels frame)
 121   "Wrapper around `image-size', handling slice display properties.
 122 Like `image-size', the return value is (WIDTH . HEIGHT).
 123 WIDTH and HEIGHT are in canonical character units if PIXELS is
 124 nil, and in pixel units if PIXELS is non-nil.
 125
 126 If SPEC is an image display property, this function is equivalent
 127 to `image-size'.  If SPEC is a list of properties containing
 128 `image' and `slice' properties, return the display size taking
 129 the slice property into account.  If the list contains `image'
 130 but not `slice', return the `image-size' of the specified image."
 131   (if (eq (car spec) 'image)
 132       (image-size spec pixels frame)
 133     (let ((image (assoc 'image spec))
 134           (slice (assoc 'slice spec)))
 135       (cond ((and image slice)
 136              (if pixels
 137                  (cons (nth 3 slice) (nth 4 slice))
 138                (cons (/ (float (nth 3 slice)) (frame-char-width frame))
 139                      (/ (float (nth 4 slice)) (frame-char-height frame)))))
 140             (image
 141              (image-size image pixels frame))
 142             (t
 143              (error "Invalid image specification: %s" spec))))))
 144
 145 (defun image-forward-hscroll (&optional n)
 146   "Scroll image in current window to the left by N character widths.
 147 Stop if the right edge of the image is reached."
 148   (interactive "p")
 149   (cond ((= n 0) nil)
 150         ((< n 0)
 151          (image-set-window-hscroll (max 0 (+ (window-hscroll) n))))
 152         (t
 153          (let* ((image (image-get-display-property))
 154                 (edges (window-inside-edges))
 155                 (win-width (- (nth 2 edges) (nth 0 edges)))
 156                 (img-width (ceiling (car (image-display-size image)))))
 157            (image-set-window-hscroll (min (max 0 (- img-width win-width))
 158                                           (+ n (window-hscroll))))))))
 159
 160 (defun image-backward-hscroll (&optional n)
 161   "Scroll image in current window to the right by N character widths.
 162 Stop if the left edge of the image is reached."
 163   (interactive "p")
 164   (image-forward-hscroll (- n)))
 165
 166 (defun image-next-line (n)
 167   "Scroll image in current window upward by N lines.
 168 Stop if the bottom edge of the image is reached."
 169   (interactive "p")
 170   (cond ((= n 0) nil)
 171         ((< n 0)
 172          (image-set-window-vscroll (max 0 (+ (window-vscroll) n))))
 173         (t
 174          (let* ((image (image-get-display-property))
 175                 (edges (window-inside-edges))
 176                 (win-height (- (nth 3 edges) (nth 1 edges)))
 177                 (img-height (ceiling (cdr (image-display-size image)))))
 178            (image-set-window-vscroll (min (max 0 (- img-height win-height))
 179                                           (+ n (window-vscroll))))))))
 180
 181 (defun image-previous-line (&optional n)
 182   "Scroll image in current window downward by N lines.
 183 Stop if the top edge of the image is reached."
 184   (interactive "p")
 185   (image-next-line (- n)))
 186
 187 (defun image-scroll-up (&optional n)
 188   "Scroll image in current window upward by N lines.
 189 Stop if the bottom edge of the image is reached.
 190 If ARG is omitted or nil, scroll upward by a near full screen.
 191 A near full screen is `next-screen-context-lines' less than a full screen.
 192 Negative ARG means scroll downward.
 193 If ARG is the atom `-', scroll downward by nearly full screen.
 194 When calling from a program, supply as argument a number, nil, or `-'."
 195   (interactive "P")
 196   (cond ((null n)
 197          (let* ((edges (window-inside-edges))
 198                 (win-height (- (nth 3 edges) (nth 1 edges))))
 199            (image-next-line
 200             (max 0 (- win-height next-screen-context-lines)))))
 201         ((eq n '-)
 202          (let* ((edges (window-inside-edges))
 203                 (win-height (- (nth 3 edges) (nth 1 edges))))
 204            (image-next-line
 205             (min 0 (- next-screen-context-lines win-height)))))
 206         (t (image-next-line (prefix-numeric-value n)))))
 207
 208 (defun image-scroll-down (&optional n)
 209   "Scroll image in current window downward by N lines.
 210 Stop if the top edge of the image is reached.
 211 If ARG is omitted or nil, scroll downward by a near full screen.
 212 A near full screen is `next-screen-context-lines' less than a full screen.
 213 Negative ARG means scroll upward.
 214 If ARG is the atom `-', scroll upward by nearly full screen.
 215 When calling from a program, supply as argument a number, nil, or `-'."
 216   (interactive "P")
 217   (cond ((null n)
 218          (let* ((edges (window-inside-edges))
 219                 (win-height (- (nth 3 edges) (nth 1 edges))))
 220            (image-next-line
 221             (min 0 (- next-screen-context-lines win-height)))))
 222         ((eq n '-)
 223          (let* ((edges (window-inside-edges))
 224                 (win-height (- (nth 3 edges) (nth 1 edges))))
 225            (image-next-line
 226             (max 0 (- win-height next-screen-context-lines)))))
 227         (t (image-next-line (- (prefix-numeric-value n))))))
 228
 229 (defun image-bol (arg)
 230   "Scroll horizontally to the left edge of the image in the current window.
 231 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 232 stopping if the top or bottom edge of the image is reached."
 233   (interactive "p")
 234   (and arg
 235        (/= (setq arg (prefix-numeric-value arg)) 1)
 236        (image-next-line (- arg 1)))
 237   (image-set-window-hscroll 0))
 238
 239 (defun image-eol (arg)
 240   "Scroll horizontally to the right edge of the image in the current window.
 241 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 242 stopping if the top or bottom edge of the image is reached."
 243   (interactive "p")
 244   (and arg
 245        (/= (setq arg (prefix-numeric-value arg)) 1)
 246        (image-next-line (- arg 1)))
 247   (let* ((image (image-get-display-property))
 248          (edges (window-inside-edges))
 249          (win-width (- (nth 2 edges) (nth 0 edges)))
 250          (img-width (ceiling (car (image-display-size image)))))
 251     (image-set-window-hscroll (max 0 (- img-width win-width)))))
 252
 253 (defun image-bob ()
 254   "Scroll to the top-left corner of the image in the current window."
 255   (interactive)
 256   (image-set-window-hscroll 0)
 257   (image-set-window-vscroll 0))
 258
 259 (defun image-eob ()
 260   "Scroll to the bottom-right corner of the image in the current window."
 261   (interactive)
 262   (let* ((image (image-get-display-property))
 263          (edges (window-inside-edges))
 264          (win-width (- (nth 2 edges) (nth 0 edges)))
 265          (img-width (ceiling (car (image-display-size image))))
 266          (win-height (- (nth 3 edges) (nth 1 edges)))
 267          (img-height (ceiling (cdr (image-display-size image)))))
 268     (image-set-window-hscroll (max 0 (- img-width win-width)))
 269     (image-set-window-vscroll (max 0 (- img-height win-height)))))
 270
 271 ;; Adjust frame and image size.
 272
 273 (defun image-mode-fit-frame ()
 274   "Toggle whether to fit the frame to the current image.
 275 This function assumes the current frame has only one window."
 276   ;; FIXME: This does not take into account decorations like mode-line,
 277   ;; minibuffer, header-line, ...
 278   (interactive)
 279   (let* ((saved (frame-parameter nil 'image-mode-saved-size))
 280          (display (image-get-display-property))
 281          (size (image-display-size display)))
 282     (if (and saved
 283              (eq (caar saved) (frame-width))
 284              (eq (cdar saved) (frame-height)))
 285         (progn ;; Toggle back to previous non-fitted size.
 286           (set-frame-parameter nil 'image-mode-saved-size nil)
 287           (setq size (cdr saved)))
 288       ;; Round up size, and save current size so we can toggle back to it.
 289       (setcar size (ceiling (car size)))
 290       (setcdr size (ceiling (cdr size)))
 291       (set-frame-parameter nil 'image-mode-saved-size
 292                            (cons size (cons (frame-width) (frame-height)))))
 293     (set-frame-width  (selected-frame) (car size))
 294     (set-frame-height (selected-frame) (cdr size))))
 295
 296 ;;; Image Mode setup
 297
 298 (defvar image-type nil
 299   "The image type for the current Image mode buffer.")
 300 (make-variable-buffer-local 'image-type)
 301
 302 (defvar image-mode-previous-major-mode nil
 303   "Internal variable to keep the previous non-image major mode.")
 304
 305 (defvar image-mode-map
 306   (let ((map (make-sparse-keymap)))
 307     (set-keymap-parent map special-mode-map)
 308     (define-key map "\C-c\C-c" 'image-toggle-display)
 309     (define-key map (kbd "SPC")       'image-scroll-up)
 310     (define-key map (kbd "DEL")       'image-scroll-down)
 311     (define-key map (kbd "RET")       'image-toggle-animation)
 312     (define-key map [remap forward-char] 'image-forward-hscroll)
 313     (define-key map [remap backward-char] 'image-backward-hscroll)
 314     (define-key map [remap right-char] 'image-forward-hscroll)
 315     (define-key map [remap left-char] 'image-backward-hscroll)
 316     (define-key map [remap previous-line] 'image-previous-line)
 317     (define-key map [remap next-line] 'image-next-line)
 318     (define-key map [remap scroll-up] 'image-scroll-up)
 319     (define-key map [remap scroll-down] 'image-scroll-down)
 320     (define-key map [remap scroll-up-command] 'image-scroll-up)
 321     (define-key map [remap scroll-down-command] 'image-scroll-down)
 322     (define-key map [remap move-beginning-of-line] 'image-bol)
 323     (define-key map [remap move-end-of-line] 'image-eol)
 324     (define-key map [remap beginning-of-buffer] 'image-bob)
 325     (define-key map [remap end-of-buffer] 'image-eob)
 326     map)
 327   "Mode keymap for `image-mode'.")
 328
 329 (defvar image-minor-mode-map
 330   (let ((map (make-sparse-keymap)))
 331     (define-key map "\C-c\C-c" 'image-toggle-display)
 332     map)
 333   "Mode keymap for `image-minor-mode'.")
 334
 335 (defvar bookmark-make-record-function)
 336
 337 (put 'image-mode 'mode-class 'special)
 338
 339 ;;;###autoload
 340 (defun image-mode ()
 341   "Major mode for image files.
 342 You can use \\<image-mode-map>\\[image-toggle-display]
 343 to toggle between display as an image and display as text."
 344   (interactive)
 345   (condition-case err
 346       (progn
 347         (unless (display-images-p)
 348           (error "Display does not support images"))
 349
 350         (kill-all-local-variables)
 351         (setq major-mode 'image-mode)
 352
 353         (if (not (image-get-display-property))
 354             (progn
 355               (image-toggle-display-image)
 356               ;; If attempt to display the image fails.
 357               (if (not (image-get-display-property))
 358                   (error "Invalid image")))
 359           ;; Set next vars when image is already displayed but local
 360           ;; variables were cleared by kill-all-local-variables
 361           (setq cursor-type nil truncate-lines t
 362                 image-type (plist-get (cdr (image-get-display-property)) :type)))
 363
 364         (setq mode-name (if image-type (format "Image[%s]" image-type) "Image"))
 365         (use-local-map image-mode-map)
 366
 367         ;; Use our own bookmarking function for images.
 368         (set (make-local-variable 'bookmark-make-record-function)
 369              'image-bookmark-make-record)
 370
 371         ;; Keep track of [vh]scroll when switching buffers
 372         (image-mode-setup-winprops)
 373
 374         (add-hook 'change-major-mode-hook 'image-toggle-display-text nil t)
 375         (add-hook 'after-revert-hook 'image-after-revert-hook nil t)
 376         (run-mode-hooks 'image-mode-hook)
 377         (let ((image (image-get-display-property))
 378               (msg1 (substitute-command-keys
 379                      "Type \\[image-toggle-display] to view the image as ")))
 380           (cond
 381            ((null image)
 382             (message "%s" (concat msg1 "an image.")))
 383            ((image-animated-p image)
 384             (message "%s"
 385                      (concat msg1 "text, or "
 386                              (substitute-command-keys
 387                               "\\[image-toggle-animation] to animate."))))
 388            (t
 389             (message "%s" (concat msg1 "text."))))))
 390
 391     (error
 392      (image-mode-as-text)
 393      (funcall
 394       (if (called-interactively-p 'any) 'error 'message)
 395       "Cannot display image: %s" (cdr err)))))
 396
 397 ;;;###autoload
 398 (define-minor-mode image-minor-mode
 399   "Toggle Image minor mode in this buffer.
 400 With a prefix argument ARG, enable Image minor mode if ARG is
 401 positive, and disable it otherwise.  If called from Lisp, enable
 402 the mode if ARG is omitted or nil.
 403
 404 Image minor mode provides the key \\<image-mode-map>\\[image-toggle-display],
 405 to switch back to `image-mode' and display an image file as the
 406 actual image."
 407   nil (:eval (if image-type (format " Image[%s]" image-type) " Image"))
 408   image-minor-mode-map
 409   :group 'image
 410   :version "22.1"
 411   (if image-minor-mode
 412       (add-hook 'change-major-mode-hook (lambda () (image-minor-mode -1)) nil t)))
 413
 414 ;;;###autoload
 415 (defun image-mode-as-text ()
 416   "Set a non-image mode as major mode in combination with image minor mode.
 417 A non-image major mode found from `auto-mode-alist' or Fundamental mode
 418 displays an image file as text.  `image-minor-mode' provides the key
 419 \\<image-mode-map>\\[image-toggle-display] to switch back to `image-mode'
 420 to display an image file as the actual image.
 421
 422 You can use `image-mode-as-text' in `auto-mode-alist' when you want
 423 to display an image file as text initially.
 424
 425 See commands `image-mode' and `image-minor-mode' for more information
 426 on these modes."
 427   (interactive)
 428   ;; image-mode-as-text = normal-mode + image-minor-mode
 429   (let ((previous-image-type image-type)) ; preserve `image-type'
 430     (if image-mode-previous-major-mode
 431         ;; Restore previous major mode that was already found by this
 432         ;; function and cached in `image-mode-previous-major-mode'
 433         (funcall image-mode-previous-major-mode)
 434       (let ((auto-mode-alist
 435              (delq nil (mapcar
 436                         (lambda (elt)
 437                           (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 438                                         '(image-mode image-mode-maybe image-mode-as-text))
 439                             elt))
 440                         auto-mode-alist)))
 441             (magic-fallback-mode-alist
 442              (delq nil (mapcar
 443                         (lambda (elt)
 444                           (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 445                                         '(image-mode image-mode-maybe image-mode-as-text))
 446                             elt))
 447                         magic-fallback-mode-alist))))
 448         (normal-mode)
 449         (set (make-local-variable 'image-mode-previous-major-mode) major-mode)))
 450     ;; Restore `image-type' after `kill-all-local-variables' in `normal-mode'.
 451     (setq image-type previous-image-type)
 452     ;; Enable image minor mode with `C-c C-c'.
 453     (image-minor-mode 1)
 454     ;; Show the image file as text.
 455     (image-toggle-display-text)
 456     (message "%s" (concat
 457                    (substitute-command-keys
 458                     "Type \\[image-toggle-display] to view the image as ")
 459                    (if (image-get-display-property)
 460                        "text" "an image") "."))))
 461
 462 (define-obsolete-function-alias 'image-mode-maybe 'image-mode "23.2")
 463
 464 (defun image-toggle-display-text ()
 465   "Show the image file as text.
 466 Remove text properties that display the image."
 467   (let ((inhibit-read-only t)
 468         (buffer-undo-list t)
 469         (modified (buffer-modified-p)))
 470     (remove-list-of-text-properties (point-min) (point-max)
 471                                     '(display read-nonsticky ;; intangible
 472                                               read-only front-sticky))
 473     (set-buffer-modified-p modified)
 474     (if (called-interactively-p 'any)
 475         (message "Repeat this command to go back to displaying the image"))))
 476
 477 (defvar archive-superior-buffer)
 478 (defvar tar-superior-buffer)
 479 (declare-function image-flush "image.c" (spec &optional frame))
 480
 481 (defun image-toggle-display-image ()
 482   "Show the image of the image file.
 483 Turn the image data into a real image, but only if the whole file
 484 was inserted."
 485   (unless (derived-mode-p 'image-mode major-mode)
 486     (error "The buffer is not in Image mode"))
 487   (let* ((filename (buffer-file-name))
 488          (data-p (not (and filename
 489                            (file-readable-p filename)
 490                            (not (file-remote-p filename))
 491                            (not (buffer-modified-p))
 492                            (not (and (boundp 'archive-superior-buffer)
 493                                      archive-superior-buffer))
 494                            (not (and (boundp 'tar-superior-buffer)
 495                                      tar-superior-buffer)))))
 496          (file-or-data (if data-p
 497                            (string-make-unibyte
 498                             (buffer-substring-no-properties (point-min) (point-max)))
 499                          filename))
 500          (type (image-type file-or-data nil data-p))
 501          (image (create-image file-or-data type data-p))
 502          (inhibit-read-only t)
 503          (buffer-undo-list t)
 504          (modified (buffer-modified-p))
 505          props)
 506
 507     ;; Discard any stale image data before looking it up again.
 508     (image-flush image)
 509     (setq image (append image (image-transform-properties image)))
 510     (setq props
 511           `(display ,image
 512                     ;; intangible ,image
 513                     rear-nonsticky (display) ;; intangible
 514                     read-only t front-sticky (read-only)))
 515
 516     (let ((buffer-file-truename nil)) ; avoid changing dir mtime by lock_file
 517       (add-text-properties (point-min) (point-max) props)
 518       (restore-buffer-modified-p modified))
 519     ;; Inhibit the cursor when the buffer contains only an image,
 520     ;; because cursors look very strange on top of images.
 521     (setq cursor-type nil)
 522     ;; This just makes the arrow displayed in the right fringe
 523     ;; area look correct when the image is wider than the window.
 524     (setq truncate-lines t)
 525     ;; Disable adding a newline at the end of the image file when it
 526     ;; is written with, e.g., C-x C-w.
 527     (if (coding-system-equal (coding-system-base buffer-file-coding-system)
 528                              'no-conversion)
 529         (set (make-local-variable 'find-file-literally) t))
 530     ;; Allow navigation of large images
 531     (set (make-local-variable 'auto-hscroll-mode) nil)
 532     (setq image-type type)
 533     (if (eq major-mode 'image-mode)
 534         (setq mode-name (format "Image[%s]" type)))
 535     (if (called-interactively-p 'any)
 536         (message "Repeat this command to go back to displaying the file as text"))))
 537
 538 (defun image-toggle-display ()
 539   "Toggle between image and text display.
 540 If the current buffer is displaying an image file as an image,
 541 call `image-mode-as-text' to switch to text.  Otherwise, display
 542 the image by calling `image-mode'."
 543   (interactive)
 544   (if (image-get-display-property)
 545       (image-mode-as-text)
 546     (image-mode)))
 547
 548 (defun image-after-revert-hook ()
 549   (when (image-get-display-property)
 550     (image-toggle-display-text)
 551     ;; Update image display.
 552     (mapc (lambda (window) (redraw-frame (window-frame window)))
 553           (get-buffer-window-list (current-buffer) 'nomini 'visible))
 554     (image-toggle-display-image)))
 555
 556 \f
 557 ;;; Animated images
 558
 559 (defcustom image-animate-loop nil
 560   "Whether to play animated images on a loop in Image mode."
 561   :type 'boolean
 562   :version "24.1"
 563   :group 'image)
 564
 565 (defun image-toggle-animation ()
 566   "Start or stop animating the current image."
 567   (interactive)
 568   (let ((image (image-get-display-property))
 569         animation)
 570     (cond
 571      ((null image)
 572       (error "No image is present"))
 573      ((null (setq animation (image-animated-p image)))
 574       (message "No image animation."))
 575      (t
 576       (let ((timer (image-animate-timer image)))
 577         (if timer
 578             (cancel-timer timer)
 579           (let ((index (plist-get (cdr image) :index)))
 580             ;; If we're at the end, restart.
 581             (and index
 582                  (>= index (1- (car animation)))
 583                  (setq index nil))
 584             (image-animate image index
 585                            (if image-animate-loop t)))))))))
 586
 587 \f
 588 ;;; Support for bookmark.el
 589 (declare-function bookmark-make-record-default
 590                   "bookmark" (&optional no-file no-context posn))
 591 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
 592 (declare-function bookmark-default-handler "bookmark" (bmk))
 593
 594 (defun image-bookmark-make-record ()
 595   `(,@(bookmark-make-record-default nil 'no-context 0)
 596       (image-type . ,image-type)
 597       (handler    . image-bookmark-jump)))
 598
 599 ;;;###autoload
 600 (defun image-bookmark-jump (bmk)
 601   ;; This implements the `handler' function interface for record type
 602   ;; returned by `bookmark-make-record-function', which see.
 603   (prog1 (bookmark-default-handler bmk)
 604     (when (not (string= image-type (bookmark-prop-get bmk 'image-type)))
 605       (image-toggle-display))))
 606 \f
 607
 608 (defvar image-transform-minor-mode-map
 609   (let ((map (make-sparse-keymap)))
 610     ;; (define-key map  [(control ?+)] 'image-scale-in)
 611     ;; (define-key map  [(control ?-)] 'image-scale-out)
 612     ;; (define-key map  [(control ?=)] 'image-scale-none)
 613     ;; (define-key map "c f h" 'image-scale-fit-height)
 614     ;; (define-key map "c ]" 'image-rotate-right)
 615     map)
 616   "Minor mode keymap `image-transform-mode'.")
 617
 618 (define-minor-mode image-transform-mode
 619   "Minor mode for scaling and rotating images.
 620 This minor mode has no effect unless Emacs is compiled with
 621 ImageMagick support."
 622   nil "image-transform" image-transform-minor-mode-map)
 623
 624 (defvar image-transform-resize nil
 625   "The image resize operation.
 626 Its value should be one of the following:
 627  - nil, meaning no resizing.
 628  - `fit-height', meaning to fit the image to the window height.
 629  - `fit-width', meaning to fit the image to the window width.
 630  - A number, which is a scale factor (the default size is 100).")
 631
 632 (defvar image-transform-rotation 0.0
 633   "Rotation angle for the image in the current Image mode buffer.")
 634
 635 (defun image-transform-properties (spec)
 636   "Return rescaling/rotation properties for image SPEC.
 637 These properties are determined by the Image mode variables
 638 `image-transform-resize' and `image-transform-rotation'.  The
 639 return value is suitable for appending to an image spec.
 640
 641 Rescaling and rotation properties only take effect if Emacs is
 642 compiled with ImageMagick support."
 643   (when (or image-transform-resize
 644             (not (equal image-transform-rotation 0.0)))
 645     ;; Note: `image-size' looks up and thus caches the untransformed
 646     ;; image.  There's no easy way to prevent that.
 647     (let* ((size (image-size spec t))
 648            (height
 649             (cond
 650              ((numberp image-transform-resize)
 651               (unless (= image-transform-resize 100)
 652                 (* image-transform-resize (cdr size))))
 653              ((eq image-transform-resize 'fit-height)
 654               (- (nth 3 (window-inside-pixel-edges))
 655                  (nth 1 (window-inside-pixel-edges))))))
 656            (width (if (eq image-transform-resize 'fit-width)
 657                       (- (nth 2 (window-inside-pixel-edges))
 658                          (nth 0 (window-inside-pixel-edges))))))
 659       ;;TODO fit-to-* should consider the rotation angle
 660       `(,@(if height (list :height height))
 661         ,@(if width (list :width width))
 662         ,@(if (not (equal 0.0 image-transform-rotation))
 663               (list :rotation image-transform-rotation))))))
 664
 665 (defun image-transform-set-scale (scale)
 666   "Prompt for a number, and resize the current image by that amount.
 667 This command has no effect unless Emacs is compiled with
 668 ImageMagick support."
 669   (interactive "nScale: ")
 670   (setq image-transform-resize scale)
 671   (image-toggle-display-image))
 672
 673 (defun image-transform-fit-to-height ()
 674   "Fit the current image to the height of the current window.
 675 This command has no effect unless Emacs is compiled with
 676 ImageMagick support."
 677   (interactive)
 678   (setq image-transform-resize 'fit-height)
 679   (image-toggle-display-image))
 680
 681 (defun image-transform-fit-to-width ()
 682   "Fit the current image to the width of the current window.
 683 This command has no effect unless Emacs is compiled with
 684 ImageMagick support."
 685   (interactive)
 686   (setq image-transform-resize 'fit-width)
 687   (image-toggle-display-image))
 688
 689 (defun image-transform-set-rotation (rotation)
 690   "Prompt for an angle ROTATION, and rotate the image by that amount.
 691 ROTATION should be in degrees.  This command has no effect unless
 692 Emacs is compiled with ImageMagick support."
 693   (interactive "nRotation angle (in degrees): ")
 694   ;;TODO 0 90 180 270 degrees are the only reasonable angles here
 695   ;;otherwise combining with rescaling will get very awkward
 696   (setq image-transform-rotation (float rotation))
 697   (image-toggle-display-image))
 698
 699 (provide 'image-mode)
 700
 701 ;;; image-mode.el ends here