lisp/gnus/gnus-delay.el

   1 ;;; gnus-delay.el --- Delayed posting of articles
   2
   3 ;; Copyright (C) 2001-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Kai Großjohann <Kai.Grossjohann@CS.Uni-Dortmund.DE>
   6 ;; Keywords: mail, news, extensions
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Provide delayed posting of articles.
  26
  27 ;;; Todo:
  28
  29 ;; * `gnus-delay-send-queue' barfs when group does not exist.
  30 ;; * Integrate gnus-delay.el into the rest of Gnus automatically.  How
  31 ;;   should this be done?  Basically, we need to do what
  32 ;;   `gnus-delay-initialize' does.  But in which files?
  33
  34 ;;; Code:
  35
  36 (require 'nndraft)
  37 (require 'gnus-draft)
  38 (autoload 'parse-time-string "parse-time" nil nil)
  39
  40 (defgroup gnus-delay nil
  41   "Arrange for sending postings later."
  42   :version "22.1"
  43   :group 'gnus)
  44
  45 (defcustom gnus-delay-group "delayed"
  46   "Group name for storing delayed articles."
  47   :type 'string
  48   :group 'gnus-delay)
  49
  50 (defcustom gnus-delay-header "X-Gnus-Delayed"
  51   "Header name for storing info about delayed articles."
  52   :type 'string
  53   :group 'gnus-delay)
  54
  55 (defcustom gnus-delay-default-delay "3d"
  56   "*Default length of delay."
  57   :type 'string
  58   :group 'gnus-delay)
  59
  60 (defcustom gnus-delay-default-hour 8
  61   "*If deadline is given as date, then assume this time of day."
  62   :version "22.1"
  63   :type 'integer
  64   :group 'gnus-delay)
  65
  66 ;;;###autoload
  67 (defun gnus-delay-article (delay)
  68   "Delay this article by some time.
  69 DELAY is a string, giving the length of the time.  Possible values are:
  70
  71 * <digits><units> for <units> in minutes (`m'), hours (`h'), days (`d'),
  72   weeks (`w'), months (`M'), or years (`Y');
  73
  74 * YYYY-MM-DD for a specific date.  The time of day is given by the
  75   variable `gnus-delay-default-hour', minute and second are zero.
  76
  77 * hh:mm for a specific time.  Use 24h format.  If it is later than this
  78   time, then the deadline is tomorrow, else today."
  79   (interactive
  80    (list (read-string
  81           "Target date (YYYY-MM-DD), time (hh:mm), or length of delay (units in [mhdwMY]): "
  82           gnus-delay-default-delay)))
  83   (let (num unit days year month day hour minute deadline)
  84     (cond ((string-match
  85             "\\([0-9][0-9][0-9]?[0-9]?\\)-\\([0-9]+\\)-\\([0-9]+\\)"
  86             delay)
  87            (setq year  (string-to-number (match-string 1 delay))
  88                  month (string-to-number (match-string 2 delay))
  89                  day   (string-to-number (match-string 3 delay)))
  90            (setq deadline
  91                  (message-make-date
  92                   (encode-time 0 0      ; second and minute
  93                                gnus-delay-default-hour
  94                                day month year))))
  95           ((string-match "\\([0-9]+\\):\\([0-9]+\\)" delay)
  96            (setq hour   (string-to-number (match-string 1 delay))
  97                  minute (string-to-number (match-string 2 delay)))
  98            ;; Use current time, except...
  99            (setq deadline (apply 'vector (decode-time (current-time))))
 100            ;; ... for minute and hour.
 101            (aset deadline 1 minute)
 102            (aset deadline 2 hour)
 103            ;; Convert to seconds.
 104            (setq deadline (gnus-float-time (apply 'encode-time
 105                                                   (append deadline nil))))
 106            ;; If this time has passed already, add a day.
 107            (when (< deadline (gnus-float-time))
 108              (setq deadline (+ 86400 deadline))) ; 86400 secs/day
 109            ;; Convert seconds to date header.
 110            (setq deadline (message-make-date
 111                            (seconds-to-time deadline))))
 112           ((string-match "\\([0-9]+\\)\\s-*\\([mhdwMY]\\)" delay)
 113            (setq num (match-string 1 delay))
 114            (setq unit (match-string 2 delay))
 115            ;; Start from seconds, then multiply into needed units.
 116            (setq num (string-to-number num))
 117            (cond ((string= unit "Y")
 118                   (setq delay (* num 60 60 24 365)))
 119                  ((string= unit "M")
 120                   (setq delay (* num 60 60 24 30)))
 121                  ((string= unit "w")
 122                   (setq delay (* num 60 60 24 7)))
 123                  ((string= unit "d")
 124                   (setq delay (* num 60 60 24)))
 125                  ((string= unit "h")
 126                   (setq delay (* num 60 60)))
 127                  (t
 128                   (setq delay (* num 60))))
 129            (setq deadline (message-make-date
 130                            (seconds-to-time (+ (gnus-float-time) delay)))))
 131           (t (error "Malformed delay `%s'" delay)))
 132     (message-add-header (format "%s: %s" gnus-delay-header deadline)))
 133   (set-buffer-modified-p t)
 134   ;; If group does not exist, create it.
 135   (gnus-agent-queue-setup gnus-delay-group)
 136   (message-disassociate-draft)
 137   (nndraft-request-associate-buffer gnus-delay-group)
 138   (save-buffer 0)
 139   (kill-buffer (current-buffer))
 140   (message-do-actions message-postpone-actions))
 141
 142 ;;;###autoload
 143 (defun gnus-delay-send-queue ()
 144   "Send all the delayed messages that are due now."
 145   (interactive)
 146   (save-excursion
 147     (let* ((group (format "nndraft:%s" gnus-delay-group))
 148            (message-send-hook (copy-sequence message-send-hook))
 149            articles
 150            article deadline)
 151       (when (gnus-group-entry group)
 152         (gnus-activate-group group)
 153         (add-hook 'message-send-hook
 154                   (lambda () (message-remove-header gnus-delay-header)))
 155         (setq articles (nndraft-articles))
 156         (while (setq article (pop articles))
 157           (gnus-request-head article group)
 158           (set-buffer nntp-server-buffer)
 159           (goto-char (point-min))
 160           (if (re-search-forward
 161                (concat "^" (regexp-quote gnus-delay-header) ":\\s-+")
 162                nil t)
 163               (progn
 164                 (setq deadline (nnheader-header-value))
 165                 (setq deadline (apply 'encode-time
 166                                       (parse-time-string deadline)))
 167                 (setq deadline (time-since deadline))
 168                 (when (and (>= (nth 0 deadline) 0)
 169                            (>= (nth 1 deadline) 0))
 170                   (message "Sending delayed article %d" article)
 171                   (gnus-draft-send article group)
 172                   (message "Sending delayed article %d...done" article)))
 173             (message "Delay header missing for article %d" article)))))))
 174
 175 ;;;###autoload
 176 (defun gnus-delay-initialize (&optional no-keymap no-check)
 177   "Initialize the gnus-delay package.
 178 This sets up a key binding in `message-mode' to delay a message.
 179 This tells Gnus to look for delayed messages after getting new news.
 180
 181 The optional arg NO-KEYMAP is ignored.
 182 Checking delayed messages is skipped if optional arg NO-CHECK is non-nil."
 183   (unless no-check
 184     (add-hook 'gnus-get-new-news-hook 'gnus-delay-send-queue)))
 185
 186 (provide 'gnus-delay)
 187
 188 ;; Local Variables:
 189 ;; coding: iso-8859-1
 190 ;; End:
 191
 192 ;;; gnus-delay.el ends here