lisp/buff-menu.el

   1 ;;; buff-menu.el --- Interface for viewing and manipulating buffers
   2
   3 ;; Copyright (C) 1985-1987, 1993-1995, 2000-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The Buffer Menu is used to view, edit, delete, or change attributes
  28 ;; of buffers.  The entry points are C-x C-b (`list-buffers') and
  29 ;; M-x buffer-menu.
  30
  31 ;;; Code:
  32
  33 (require 'tabulated-list)
  34
  35 (defgroup Buffer-menu nil
  36   "Show a menu of all buffers in a buffer."
  37   :group 'tools
  38   :group 'convenience)
  39
  40 (defcustom Buffer-menu-use-header-line t
  41   "If non-nil, use the header line to display Buffer Menu column titles."
  42   :type 'boolean
  43   :group 'Buffer-menu)
  44
  45 (defface buffer-menu-buffer
  46   '((t (:weight bold)))
  47   "Face for buffer names in the Buffer Menu."
  48   :group 'Buffer-menu)
  49 (put 'Buffer-menu-buffer 'face-alias 'buffer-menu-buffer)
  50
  51 (defcustom Buffer-menu-buffer+size-width nil
  52   "Combined width of buffer name and size columns in Buffer Menu.
  53 If nil, use `Buffer-menu-name-width' and `Buffer-menu-size-width'.
  54
  55 If non-nil, the value of `Buffer-menu-name-width' is overridden;
  56 the name column is assigned width `Buffer-menu-buffer+size-width'
  57 minus `Buffer-menu-size-width'.  This use is deprecated."
  58   :type 'number
  59   :group 'Buffer-menu
  60   :version "24.2")
  61
  62 (make-obsolete-variable 'Buffer-menu-buffer+size-width
  63                         "`Buffer-menu-name-width' and `Buffer-menu-size-width'"
  64                         "24.2")
  65
  66 (defcustom Buffer-menu-name-width 19
  67   "Width of buffer size column in the Buffer Menu."
  68   :type 'number
  69   :group 'Buffer-menu
  70   :version "24.2")
  71
  72 (defcustom Buffer-menu-size-width 7
  73   "Width of buffer name column in the Buffer Menu."
  74   :type 'number
  75   :group 'Buffer-menu
  76   :version "24.2")
  77
  78 (defcustom Buffer-menu-mode-width 16
  79   "Width of mode name column in the Buffer Menu."
  80   :type 'number
  81   :group 'Buffer-menu)
  82
  83 (defcustom Buffer-menu-use-frame-buffer-list t
  84   "If non-nil, the Buffer Menu uses the selected frame's buffer list.
  85 Buffers that were never selected in that frame are listed at the end.
  86 If the value is nil, the Buffer Menu uses the global buffer list.
  87 This variable matters if the Buffer Menu is sorted by visited order,
  88 as it is by default."
  89   :type 'boolean
  90   :group 'Buffer-menu
  91   :version "22.1")
  92
  93 (defvar Buffer-menu-files-only nil
  94   "Non-nil if the current Buffer Menu lists only file buffers.
  95 This is set by the prefix argument to `buffer-menu' and related
  96 commands.")
  97 (make-variable-buffer-local 'Buffer-menu-files-only)
  98
  99 (defvar Info-current-file) ; from info.el
 100 (defvar Info-current-node) ; from info.el
 101
 102 (defvar Buffer-menu-mode-map
 103   (let ((map (make-sparse-keymap))
 104         (menu-map (make-sparse-keymap)))
 105     (set-keymap-parent map tabulated-list-mode-map)
 106     (define-key map "v" 'Buffer-menu-select)
 107     (define-key map "2" 'Buffer-menu-2-window)
 108     (define-key map "1" 'Buffer-menu-1-window)
 109     (define-key map "f" 'Buffer-menu-this-window)
 110     (define-key map "e" 'Buffer-menu-this-window)
 111     (define-key map "\C-m" 'Buffer-menu-this-window)
 112     (define-key map "o" 'Buffer-menu-other-window)
 113     (define-key map "\C-o" 'Buffer-menu-switch-other-window)
 114     (define-key map "s" 'Buffer-menu-save)
 115     (define-key map "d" 'Buffer-menu-delete)
 116     (define-key map "k" 'Buffer-menu-delete)
 117     (define-key map "\C-k" 'Buffer-menu-delete)
 118     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
 119     (define-key map "x" 'Buffer-menu-execute)
 120     (define-key map " " 'next-line)
 121     (define-key map "\177" 'Buffer-menu-backup-unmark)
 122     (define-key map "~" 'Buffer-menu-not-modified)
 123     (define-key map "u" 'Buffer-menu-unmark)
 124     (define-key map "m" 'Buffer-menu-mark)
 125     (define-key map "t" 'Buffer-menu-visit-tags-table)
 126     (define-key map "%" 'Buffer-menu-toggle-read-only)
 127     (define-key map "b" 'Buffer-menu-bury)
 128     (define-key map "V" 'Buffer-menu-view)
 129     (define-key map "T" 'Buffer-menu-toggle-files-only)
 130     (define-key map (kbd "M-s a C-s")   'Buffer-menu-isearch-buffers)
 131     (define-key map (kbd "M-s a M-C-s") 'Buffer-menu-isearch-buffers-regexp)
 132
 133     (define-key map [menu-bar Buffer-menu-mode] (cons (purecopy "Buffer-Menu") menu-map))
 134     (define-key menu-map [quit]
 135       `(menu-item ,(purecopy "Quit") quit-window
 136                  :help ,(purecopy "Remove the buffer menu from the display")))
 137     (define-key menu-map [rev]
 138       `(menu-item ,(purecopy "Refresh") revert-buffer
 139                  :help ,(purecopy "Refresh the *Buffer List* buffer contents")))
 140     (define-key menu-map [s0] menu-bar-separator)
 141     (define-key menu-map [tf]
 142       `(menu-item ,(purecopy "Show Only File Buffers") Buffer-menu-toggle-files-only
 143                   :button (:toggle . Buffer-menu-files-only)
 144                   :help ,(purecopy "Toggle whether the current buffer-menu displays only file buffers")))
 145     (define-key menu-map [s1] menu-bar-separator)
 146     ;; FIXME: The "Select" entries could use better names...
 147     (define-key menu-map [sel]
 148       `(menu-item ,(purecopy "Select Marked") Buffer-menu-select
 149                  :help ,(purecopy "Select this line's buffer; also display buffers marked with `>'")))
 150     (define-key menu-map [bm2]
 151       `(menu-item ,(purecopy "Select Two") Buffer-menu-2-window
 152                  :help ,(purecopy "Select this line's buffer, with previous buffer in second window")))
 153     (define-key menu-map [bm1]
 154       `(menu-item ,(purecopy "Select Current") Buffer-menu-1-window
 155                  :help ,(purecopy "Select this line's buffer, alone, in full frame")))
 156     (define-key menu-map [ow]
 157       `(menu-item ,(purecopy "Select in Other Window") Buffer-menu-other-window
 158                  :help ,(purecopy "Select this line's buffer in other window, leaving buffer menu visible")))
 159     (define-key menu-map [tw]
 160       `(menu-item ,(purecopy "Select in Current Window") Buffer-menu-this-window
 161                  :help ,(purecopy "Select this line's buffer in this window")))
 162     (define-key menu-map [s2] menu-bar-separator)
 163     (define-key menu-map [is]
 164       `(menu-item ,(purecopy "Regexp Isearch Marked Buffers...") Buffer-menu-isearch-buffers-regexp
 165                  :help ,(purecopy "Search for a regexp through all marked buffers using Isearch")))
 166     (define-key menu-map [ir]
 167       `(menu-item ,(purecopy "Isearch Marked Buffers...") Buffer-menu-isearch-buffers
 168                  :help ,(purecopy "Search for a string through all marked buffers using Isearch")))
 169     (define-key menu-map [s3] menu-bar-separator)
 170     (define-key menu-map [by]
 171       `(menu-item ,(purecopy "Bury") Buffer-menu-bury
 172                  :help ,(purecopy "Bury the buffer listed on this line")))
 173     (define-key menu-map [vt]
 174       `(menu-item ,(purecopy "Set Unmodified") Buffer-menu-not-modified
 175                  :help ,(purecopy "Mark buffer on this line as unmodified (no changes to save)")))
 176     (define-key menu-map [ex]
 177       `(menu-item ,(purecopy "Execute") Buffer-menu-execute
 178                  :help ,(purecopy "Save and/or delete buffers marked with s or k commands")))
 179     (define-key menu-map [s4] menu-bar-separator)
 180     (define-key menu-map [delb]
 181       `(menu-item ,(purecopy "Mark for Delete and Move Backwards") Buffer-menu-delete-backwards
 182                  :help ,(purecopy "Mark buffer on this line to be deleted by x command and move up one line")))
 183     (define-key menu-map [del]
 184       `(menu-item ,(purecopy "Mark for Delete") Buffer-menu-delete
 185                  :help ,(purecopy "Mark buffer on this line to be deleted by x command")))
 186
 187     (define-key menu-map [sv]
 188       `(menu-item ,(purecopy "Mark for Save") Buffer-menu-save
 189                  :help ,(purecopy "Mark buffer on this line to be saved by x command")))
 190     (define-key menu-map [umk]
 191       `(menu-item ,(purecopy "Unmark") Buffer-menu-unmark
 192                  :help ,(purecopy "Cancel all requested operations on buffer on this line and move down")))
 193     (define-key menu-map [mk]
 194       `(menu-item ,(purecopy "Mark") Buffer-menu-mark
 195                  :help ,(purecopy "Mark buffer on this line for being displayed by v command")))
 196     map)
 197   "Local keymap for `Buffer-menu-mode' buffers.")
 198
 199 (define-derived-mode Buffer-menu-mode tabulated-list-mode "Buffer Menu"
 200   "Major mode for Buffer Menu buffers.
 201 The Buffer Menu is invoked by the commands \\[list-buffers], \\[buffer-menu], and
 202 \\[buffer-menu-other-window].  See `buffer-menu' for details."
 203   (set (make-local-variable 'buffer-stale-function)
 204        (lambda (&optional _noconfirm) 'fast))
 205   (add-hook 'tabulated-list-revert-hook 'list-buffers--refresh nil t))
 206
 207 (define-obsolete-variable-alias 'buffer-menu-mode-hook
 208   'Buffer-menu-mode-hook "23.1")
 209
 210 (defun buffer-menu (&optional arg)
 211   "Switch to the Buffer Menu.
 212 By default, all buffers are listed except those whose names start
 213 with a space (which are for internal use).  With prefix argument
 214 ARG, show only buffers that are visiting files.
 215
 216 The first column (denoted \"C\") shows \".\" for the buffer from
 217 which you came.  It shows \">\" for buffers you mark to be
 218 displayed, and \"D\" for those you mark for deletion.
 219
 220 The \"R\" column has a \"%\" if the buffer is read-only.
 221 The \"M\" column has a \"*\" if it is modified, or \"S\" if you
 222 have marked it for saving.
 223
 224 After this come the buffer name, its size in characters, its
 225 major mode, and the visited file name (if any).
 226
 227
 228 In the Buffer Menu, the following commands are defined:
 229 \\<Buffer-menu-mode-map>
 230 \\[quit-window]    Remove the Buffer Menu from the display.
 231 \\[Buffer-menu-this-window]  Select current line's buffer in place of the buffer menu.
 232 \\[Buffer-menu-other-window]    Select that buffer in another window,
 233      so the Buffer Menu remains visible in its window.
 234 \\[Buffer-menu-view]    Select current line's buffer, in View mode.
 235 \\[Buffer-menu-view-other-window]  Select that buffer in
 236      another window, in view-mode.
 237 \\[Buffer-menu-switch-other-window]  Make another window display that buffer.
 238 \\[Buffer-menu-mark]    Mark current line's buffer to be displayed.
 239 \\[Buffer-menu-select]    Select current line's buffer.
 240      Also show buffers marked with m, in other windows.
 241 \\[Buffer-menu-1-window]    Select that buffer in full-frame window.
 242 \\[Buffer-menu-2-window]    Select that buffer in one window, together with the
 243      buffer selected before this one in another window.
 244 \\[Buffer-menu-isearch-buffers]  Incremental search in the marked buffers.
 245 \\[Buffer-menu-isearch-buffers-regexp]  Isearch for regexp in the marked buffers.
 246 \\[Buffer-menu-visit-tags-table]    visit-tags-table this buffer.
 247 \\[Buffer-menu-not-modified]    Clear modified-flag on that buffer.
 248 \\[Buffer-menu-save]    Mark that buffer to be saved, and move down.
 249 \\[Buffer-menu-delete]  Mark that buffer to be deleted, and move down.
 250 \\[Buffer-menu-delete-backwards]  Mark that buffer to be deleted, and move up.
 251 \\[Buffer-menu-execute]    Delete or save marked buffers.
 252 \\[Buffer-menu-unmark]    Remove all marks from current line.
 253      With prefix argument, also move up one line.
 254 \\[Buffer-menu-backup-unmark]  Back up a line and remove marks.
 255 \\[Buffer-menu-toggle-read-only]    Toggle read-only status of buffer on this line.
 256 \\[revert-buffer]    Update the list of buffers.
 257 \\[Buffer-menu-toggle-files-only]    Toggle whether the menu displays only file buffers.
 258 \\[Buffer-menu-bury]    Bury the buffer listed on this line."
 259   (interactive "P")
 260   (switch-to-buffer (list-buffers-noselect arg))
 261   (message
 262    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 263
 264 (defun buffer-menu-other-window (&optional arg)
 265   "Display the Buffer Menu in another window.
 266 See `buffer-menu' for a description of the Buffer Menu.
 267
 268 By default, all buffers are listed except those whose names start
 269 with a space (which are for internal use).  With prefix argument
 270 ARG, show only buffers that are visiting files."
 271   (interactive "P")
 272   (switch-to-buffer-other-window (list-buffers-noselect arg))
 273   (message
 274    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 275
 276 ;;;###autoload
 277 (defun list-buffers (&optional arg)
 278   "Display a list of existing buffers.
 279 The list is displayed in a buffer named \"*Buffer List*\".
 280 See `buffer-menu' for details about the Buffer Menu buffer.
 281
 282 By default, all buffers are listed except those whose names start
 283 with a space (which are for internal use).  With prefix argument
 284 ARG, show only buffers that are visiting files."
 285   (interactive "P")
 286   (display-buffer (list-buffers-noselect arg)))
 287
 288 (defun Buffer-menu-toggle-files-only (arg)
 289   "Toggle whether the current buffer-menu displays only file buffers.
 290 With a positive ARG, display only file buffers.  With zero or
 291 negative ARG, display other buffers as well."
 292   (interactive "P")
 293   (setq Buffer-menu-files-only
 294         (cond ((not arg) (not Buffer-menu-files-only))
 295               ((> (prefix-numeric-value arg) 0) t)))
 296   (message (if Buffer-menu-files-only
 297                "Showing only file-visiting buffers."
 298              "Showing all non-internal buffers."))
 299   (revert-buffer))
 300
 301 (defalias 'Buffer-menu-sort 'tabulated-list-sort)
 302 \f
 303
 304 (defun Buffer-menu-buffer (&optional error-if-non-existent-p)
 305   "Return the buffer described by the current Buffer Menu line.
 306 If there is no buffer here, return nil if ERROR-IF-NON-EXISTENT-P
 307 is nil or omitted, and signal an error otherwise."
 308   (let ((buffer (tabulated-list-get-id)))
 309     (cond ((null buffer)
 310            (if error-if-non-existent-p
 311                (error "No buffer on this line")))
 312           ((not (buffer-live-p buffer))
 313            (if error-if-non-existent-p
 314                (error "This buffer has been killed")))
 315           (t buffer))))
 316
 317 (defun Buffer-menu-no-header ()
 318   (beginning-of-line)
 319   (if (or Buffer-menu-use-header-line
 320           (not (eq (char-after) ?C)))
 321       t
 322     (ding)
 323     (forward-line 1)
 324     nil))
 325
 326 (defun Buffer-menu-beginning ()
 327   (goto-char (point-min))
 328   (unless Buffer-menu-use-header-line
 329     (forward-line)))
 330
 331 \f
 332 ;;; Commands for modifying Buffer Menu entries.
 333
 334 (defun Buffer-menu-mark ()
 335   "Mark the Buffer menu entry at point for later display.
 336 It will be displayed by the \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 337   (interactive)
 338   (tabulated-list-set-col 0 ">" t)
 339   (forward-line))
 340
 341 (defun Buffer-menu-unmark (&optional backup)
 342   "Cancel all requested operations on buffer on this line and move down.
 343 Optional prefix arg means move up."
 344   (interactive "P")
 345   (tabulated-list-set-col 0 " " t)
 346   (forward-line (if backup -1 1)))
 347
 348 (defun Buffer-menu-backup-unmark ()
 349   "Move up and cancel all requested operations on buffer on line above."
 350   (interactive)
 351   (forward-line -1)
 352   (tabulated-list-set-col 0 " " t))
 353
 354 (defun Buffer-menu-delete (&optional arg)
 355   "Mark the buffer on this Buffer Menu buffer line for deletion.
 356 A subsequent \\<Buffer-menu-mode-map>`\\[Buffer-menu-execute]' command
 357 will delete it.
 358
 359 If prefix argument ARG is non-nil, it specifies the number of
 360 buffers to delete; a negative ARG means to delete backwards."
 361   (interactive "p")
 362   (if (or (null arg) (= arg 0))
 363       (setq arg 1))
 364   (while (> arg 0)
 365     (when (Buffer-menu-buffer)
 366       (tabulated-list-set-col 0 "D" t))
 367     (forward-line 1)
 368     (setq arg (1- arg)))
 369   (while (< arg 0)
 370     (when (Buffer-menu-buffer)
 371       (tabulated-list-set-col 0 "D" t))
 372     (forward-line -1)
 373     (setq arg (1+ arg))))
 374
 375 (defun Buffer-menu-delete-backwards (&optional arg)
 376   "Mark the buffer on this Buffer Menu line for deletion, and move up.
 377 Prefix ARG means move that many lines."
 378   (interactive "p")
 379   (Buffer-menu-delete (- (or arg 1))))
 380
 381 (defun Buffer-menu-save ()
 382   "Mark the buffer on this Buffer Menu line for saving.
 383 A subsequent \\<Buffer-menu-mode-map>`\\[Buffer-menu-execute]' command
 384 will save it."
 385   (interactive)
 386   (when (Buffer-menu-buffer)
 387     (tabulated-list-set-col 2 "S" t)
 388     (forward-line 1)))
 389
 390 (defun Buffer-menu-not-modified (&optional arg)
 391   "Mark the buffer on this line as unmodified (no changes to save).
 392 If ARG is non-nil (interactively, with a prefix argument), mark
 393 it as modified."
 394   (interactive "P")
 395   (with-current-buffer (Buffer-menu-buffer t)
 396     (set-buffer-modified-p arg))
 397   (tabulated-list-set-col 2 (if arg "*" " ") t))
 398
 399 (defun Buffer-menu-execute ()
 400   "Save and/or delete marked buffers in the Buffer Menu.
 401 Buffers marked with \\<Buffer-menu-mode-map>`\\[Buffer-menu-save]' are saved.
 402 Buffers marked with \\<Buffer-menu-mode-map>`\\[Buffer-menu-delete]' are deleted."
 403   (interactive)
 404   (save-excursion
 405     (Buffer-menu-beginning)
 406     (while (not (eobp))
 407       (let ((buffer (tabulated-list-get-id))
 408             (entry  (tabulated-list-get-entry)))
 409         (cond ((null entry)
 410                (forward-line 1))
 411               ((not (buffer-live-p buffer))
 412                (tabulated-list-delete-entry))
 413               (t
 414                (let ((delete (eq (char-after) ?D)))
 415                  (when (equal (aref entry 2) "S")
 416                    (condition-case nil
 417                        (progn
 418                          (with-current-buffer buffer
 419                            (save-buffer))
 420                          (tabulated-list-set-col 2 " " t))
 421                      (error (warn "Error saving %s" buffer))))
 422                  (if delete
 423                      (unless (eq buffer (current-buffer))
 424                        (kill-buffer buffer)
 425                        (tabulated-list-delete-entry))
 426                    (forward-line 1)))))))))
 427
 428 (defun Buffer-menu-select ()
 429   "Select this line's buffer; also, display buffers marked with `>'.
 430 You can mark buffers with the \\<Buffer-menu-mode-map>`\\[Buffer-menu-mark]' command.
 431 This command deletes and replaces all the previously existing windows
 432 in the selected frame."
 433   (interactive)
 434   (let* ((this-buffer (Buffer-menu-buffer t))
 435          (menu-buffer (current-buffer))
 436          (others (delq this-buffer (Buffer-menu-marked-buffers t)))
 437          (height (/ (1- (frame-height)) (1+ (length others)))))
 438     (delete-other-windows)
 439     (switch-to-buffer this-buffer)
 440     (unless (eq menu-buffer this-buffer)
 441       (bury-buffer menu-buffer))
 442     (dolist (buffer others)
 443       (split-window nil height)
 444       (other-window 1)
 445       (switch-to-buffer buffer))
 446     ;; Back to the beginning!
 447     (other-window 1)))
 448
 449 (defun Buffer-menu-marked-buffers (&optional unmark)
 450   "Return the list of buffers marked with `Buffer-menu-mark'.
 451 If UNMARK is non-nil, unmark them."
 452   (let (buffers)
 453     (Buffer-menu-beginning)
 454     (while (re-search-forward "^>" nil t)
 455       (let ((buffer (Buffer-menu-buffer)))
 456         (if (and buffer unmark)
 457             (tabulated-list-set-col 0 " " t))
 458         (if (buffer-live-p buffer)
 459             (push buffer buffers))))
 460     (nreverse buffers)))
 461
 462 (defun Buffer-menu-isearch-buffers ()
 463   "Search for a string through all marked buffers using Isearch."
 464   (interactive)
 465   (multi-isearch-buffers (Buffer-menu-marked-buffers)))
 466
 467 (defun Buffer-menu-isearch-buffers-regexp ()
 468   "Search for a regexp through all marked buffers using Isearch."
 469   (interactive)
 470   (multi-isearch-buffers-regexp (Buffer-menu-marked-buffers)))
 471
 472 \f
 473 (defun Buffer-menu-visit-tags-table ()
 474   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 475   (interactive)
 476   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 477     (if file
 478         (visit-tags-table file)
 479       (error "Specified buffer has no file"))))
 480
 481 (defun Buffer-menu-1-window ()
 482   "Select this line's buffer, alone, in full frame."
 483   (interactive)
 484   (switch-to-buffer (Buffer-menu-buffer t))
 485   (bury-buffer (other-buffer))
 486   (delete-other-windows))
 487
 488 (defun Buffer-menu-this-window ()
 489   "Select this line's buffer in this window."
 490   (interactive)
 491   (switch-to-buffer (Buffer-menu-buffer t)))
 492
 493 (defun Buffer-menu-other-window ()
 494   "Select this line's buffer in other window, leaving buffer menu visible."
 495   (interactive)
 496   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 497
 498 (defun Buffer-menu-switch-other-window ()
 499   "Make the other window select this line's buffer.
 500 The current window remains selected."
 501   (interactive)
 502   (display-buffer (Buffer-menu-buffer t) t))
 503
 504 (defun Buffer-menu-2-window ()
 505   "Select this line's buffer, with previous buffer in second window."
 506   (interactive)
 507   (let ((buff (Buffer-menu-buffer t))
 508         (menu (current-buffer)))
 509     (delete-other-windows)
 510     (switch-to-buffer (other-buffer))
 511     (switch-to-buffer-other-window buff)
 512     (bury-buffer menu)))
 513
 514 (defun Buffer-menu-toggle-read-only ()
 515   "Toggle read-only status of buffer on this line."
 516   (interactive)
 517   (let (read-only)
 518     (with-current-buffer (Buffer-menu-buffer t)
 519       (with-no-warnings (toggle-read-only))
 520       (setq read-only buffer-read-only))
 521     (tabulated-list-set-col 1 (if read-only "%" " ") t)))
 522
 523 (defun Buffer-menu-bury ()
 524   "Bury the buffer listed on this line."
 525   (interactive)
 526   (let ((buffer (tabulated-list-get-id)))
 527     (cond ((null buffer))
 528           ((buffer-live-p buffer)
 529            (bury-buffer buffer)
 530            (save-excursion
 531              (let ((elt (tabulated-list-delete-entry)))
 532                (goto-char (point-max))
 533                (apply 'tabulated-list-print-entry elt)))
 534            (message "Buffer buried."))
 535           (t
 536            (tabulated-list-delete-entry)
 537            (message "Buffer is dead; removing from list.")))))
 538
 539 (defun Buffer-menu-view ()
 540   "View this line's buffer in View mode."
 541   (interactive)
 542   (view-buffer (Buffer-menu-buffer t)))
 543
 544 (defun Buffer-menu-view-other-window ()
 545   "View this line's buffer in View mode in another window."
 546   (interactive)
 547   (view-buffer-other-window (Buffer-menu-buffer t)))
 548 \f
 549 ;;; Functions for populating the Buffer Menu.
 550
 551 ;;;###autoload
 552 (defun list-buffers-noselect (&optional files-only buffer-list)
 553   "Create and return a Buffer Menu buffer.
 554 This is called by `buffer-menu' and others as a subroutine.
 555
 556 If FILES-ONLY is non-nil, show only file-visiting buffers.
 557 If BUFFER-LIST is non-nil, it should be a list of buffers; it
 558 means list those buffers and no others."
 559   (let ((old-buffer (current-buffer))
 560         (buffer (get-buffer-create "*Buffer List*")))
 561     (with-current-buffer buffer
 562       (Buffer-menu-mode)
 563       (setq Buffer-menu-files-only (and files-only (>= files-only 0)))
 564       (list-buffers--refresh buffer-list old-buffer)
 565       (tabulated-list-print))
 566     buffer))
 567
 568 (defun list-buffers--refresh (&optional buffer-list old-buffer)
 569   ;; Set up `tabulated-list-format'.
 570   (let ((name-width Buffer-menu-name-width)
 571         (size-width Buffer-menu-size-width))
 572     ;; Handle obsolete variable:
 573     (if Buffer-menu-buffer+size-width
 574         (setq name-width (- Buffer-menu-buffer+size-width size-width)))
 575     (setq tabulated-list-format
 576           (vector '("C" 1 t :pad-right 0)
 577                   '("R" 1 t :pad-right 0)
 578                   '("M" 1 t)
 579                   `("Buffer" ,name-width t)
 580                   `("Size" ,size-width tabulated-list-entry-size->
 581                            :right-align t)
 582                   `("Mode" ,Buffer-menu-mode-width t)
 583                   '("File" 1 t))))
 584   (setq tabulated-list-use-header-line Buffer-menu-use-header-line)
 585   ;; Collect info for each buffer we're interested in.
 586   (let ((buffer-menu-buffer (current-buffer))
 587         (show-non-file (not Buffer-menu-files-only))
 588         entries)
 589     (dolist (buffer (or buffer-list
 590                         (buffer-list (if Buffer-menu-use-frame-buffer-list
 591                                          (selected-frame)))))
 592       (with-current-buffer buffer
 593         (let* ((name (buffer-name))
 594                (file buffer-file-name))
 595           (when (and (buffer-live-p buffer)
 596                      (or buffer-list
 597                          (and (not (string= (substring name 0 1) " "))
 598                               (not (eq buffer buffer-menu-buffer))
 599                               (or file show-non-file))))
 600             (push (list buffer
 601                         (vector (if (eq buffer old-buffer) "." " ")
 602                                 (if buffer-read-only "%" " ")
 603                                 (if (buffer-modified-p) "*" " ")
 604                                 (Buffer-menu--pretty-name name)
 605                                 (number-to-string (buffer-size))
 606                                 (concat (format-mode-line mode-name nil nil buffer)
 607                                         (if mode-line-process
 608                                             (format-mode-line mode-line-process
 609                                                               nil nil buffer)))
 610                                 (Buffer-menu--pretty-file-name file)))
 611                   entries)))))
 612     (setq tabulated-list-entries (nreverse entries)))
 613   (tabulated-list-init-header))
 614
 615 (defun tabulated-list-entry-size-> (entry1 entry2)
 616   (> (string-to-number (aref (cadr entry1) 4))
 617      (string-to-number (aref (cadr entry2) 4))))
 618
 619 (defun Buffer-menu--pretty-name (name)
 620   (propertize name 'font-lock-face 'buffer-menu-buffer))
 621
 622 (defun Buffer-menu--pretty-file-name (file)
 623   (cond (file
 624          (abbreviate-file-name file))
 625         ((and (boundp 'list-buffers-directory)
 626               list-buffers-directory)
 627          list-buffers-directory)
 628         ((eq major-mode 'Info-mode)
 629          (Buffer-menu-info-node-description Info-current-file))
 630         (t "")))
 631
 632 (defun Buffer-menu-info-node-description (file)
 633   (cond
 634    ((equal file "dir") "*Info Directory*")
 635    ((eq file 'apropos) "*Info Apropos*")
 636    ((eq file 'history) "*Info History*")
 637    ((eq file 'toc)     "*Info TOC*")
 638    ((not (stringp file)) "") ; Avoid errors
 639    (t
 640     (concat "(" (file-name-nondirectory file) ") " Info-current-node))))
 641
 642 ;;; buff-menu.el ends here