lisp/net/rlogin.el

   1 ;;; rlogin.el --- remote login interface
   2
   3 ;; Copyright (C) 1992, 93, 94, 95, 97, 1998, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Noah Friedman
   6 ;; Maintainer: Noah Friedman <friedman@splode.com>
   7 ;; Keywords: unix, comm
   8
   9 ;; $Id: rlogin.el,v 1.4 2003/05/06 17:46:28 lektu Exp $
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Support for remote logins using `rlogin'.
  31 ;; This program is layered on top of shell.el; the code here only accounts
  32 ;; for the variations needed to handle a remote process, e.g. directory
  33 ;; tracking and the sending of some special characters.
  34
  35 ;; If you wish for rlogin mode to prompt you in the minibuffer for
  36 ;; passwords when a password prompt appears, just enter m-x send-invisible
  37 ;; and type in your line, or add `comint-watch-for-password-prompt' to
  38 ;; `comint-output-filter-functions'.
  39
  40 ;;; Code:
  41
  42 (require 'comint)
  43 (require 'shell)
  44
  45 (defgroup rlogin nil
  46   "Remote login interface"
  47   :group 'processes
  48   :group 'unix)
  49
  50 (defcustom rlogin-program "rlogin"
  51   "*Name of program to invoke rlogin"
  52   :type 'string
  53   :group 'rlogin)
  54
  55 (defcustom rlogin-explicit-args nil
  56   "*List of arguments to pass to rlogin on the command line."
  57   :type '(repeat (string :tag "Argument"))
  58   :group 'rlogin)
  59
  60 (defcustom rlogin-mode-hook nil
  61   "*Hooks to run after setting current buffer to rlogin-mode."
  62   :type 'hook
  63   :group 'rlogin)
  64
  65 (defcustom rlogin-process-connection-type
  66   (save-match-data
  67     ;; Solaris 2.x `rlogin' will spew a bunch of ioctl error messages if
  68     ;; stdin isn't a tty.
  69     (cond ((and (boundp 'system-configuration)
  70                 (stringp system-configuration)
  71                 (string-match "-solaris2" system-configuration))
  72            t)
  73           (t nil)))
  74   "*If non-nil, use a pty for the local rlogin process.
  75 If nil, use a pipe (if pipes are supported on the local system).
  76
  77 Generally it is better not to waste ptys on systems which have a static
  78 number of them.  On the other hand, some implementations of `rlogin' assume
  79 a pty is being used, and errors will result from using a pipe instead."
  80   :type '(choice (const :tag "pipes" nil)
  81                  (other :tag "ptys" t))
  82   :group 'rlogin)
  83
  84 (defcustom rlogin-directory-tracking-mode 'local
  85   "*Control whether and how to do directory tracking in an rlogin buffer.
  86
  87 nil means don't do directory tracking.
  88
  89 t means do so using an ftp remote file name.
  90
  91 Any other value means do directory tracking using local file names.
  92 This works only if the remote machine and the local one
  93 share the same directories (through NFS).  This is the default.
  94
  95 This variable becomes local to a buffer when set in any fashion for it.
  96
  97 It is better to use the function of the same name to change the behavior of
  98 directory tracking in an rlogin session once it has begun, rather than
  99 simply setting this variable, since the function does the necessary
 100 re-synching of directories."
 101   :type '(choice (const :tag "off" nil)
 102                  (const :tag "ftp" t)
 103                  (other :tag "local" local))
 104   :group 'rlogin)
 105
 106 (make-variable-buffer-local 'rlogin-directory-tracking-mode)
 107
 108 (defcustom rlogin-host nil
 109   "*The name of the remote host.  This variable is buffer-local."
 110   :type '(choice (const nil) string)
 111   :group 'rlogin)
 112
 113 (defcustom rlogin-remote-user nil
 114   "*The username used on the remote host.
 115 This variable is buffer-local and defaults to your local user name.
 116 If rlogin is invoked with the `-l' option to specify the remote username,
 117 this variable is set from that."
 118   :type '(choice (const nil) string)
 119   :group 'rlogin)
 120
 121 ;; Initialize rlogin mode map.
 122 (defvar rlogin-mode-map '())
 123 (cond
 124  ((null rlogin-mode-map)
 125   (setq rlogin-mode-map (if (consp shell-mode-map)
 126                             (cons 'keymap shell-mode-map)
 127                           (copy-keymap shell-mode-map)))
 128   (define-key rlogin-mode-map "\C-c\C-c" 'rlogin-send-Ctrl-C)
 129   (define-key rlogin-mode-map "\C-c\C-d" 'rlogin-send-Ctrl-D)
 130   (define-key rlogin-mode-map "\C-c\C-z" 'rlogin-send-Ctrl-Z)
 131   (define-key rlogin-mode-map "\C-c\C-\\" 'rlogin-send-Ctrl-backslash)
 132   (define-key rlogin-mode-map "\C-d" 'rlogin-delchar-or-send-Ctrl-D)
 133   (define-key rlogin-mode-map "\C-i" 'rlogin-tab-or-complete)))
 134
 135 \f
 136 ;;;###autoload (add-hook 'same-window-regexps "^\\*rlogin-.*\\*\\(\\|<[0-9]+>\\)")
 137
 138 (defvar rlogin-history nil)
 139
 140 ;;;###autoload
 141 (defun rlogin (input-args &optional buffer)
 142   "Open a network login connection via `rlogin' with args INPUT-ARGS.
 143 INPUT-ARGS should start with a host name; it may also contain
 144 other arguments for `rlogin'.
 145
 146 Input is sent line-at-a-time to the remote connection.
 147
 148 Communication with the remote host is recorded in a buffer `*rlogin-HOST*'
 149 \(or `*rlogin-USER@HOST*' if the remote username differs\).
 150 If a prefix argument is given and the buffer `*rlogin-HOST*' already exists,
 151 a new buffer with a different connection will be made.
 152
 153 When called from a program, if the optional second argument BUFFER is
 154 a string or buffer, it specifies the buffer to use.
 155
 156 The variable `rlogin-program' contains the name of the actual program to
 157 run.  It can be a relative or absolute path.
 158
 159 The variable `rlogin-explicit-args' is a list of arguments to give to
 160 the rlogin when starting.  They are added after any arguments given in
 161 INPUT-ARGS.
 162
 163 If the default value of `rlogin-directory-tracking-mode' is t, then the
 164 default directory in that buffer is set to a remote (FTP) file name to
 165 access your home directory on the remote machine.  Occasionally this causes
 166 an error, if you cannot access the home directory on that machine.  This
 167 error is harmless as long as you don't try to use that default directory.
 168
 169 If `rlogin-directory-tracking-mode' is neither t nor nil, then the default
 170 directory is initially set up to your (local) home directory.
 171 This is useful if the remote machine and your local machine
 172 share the same files via NFS.  This is the default.
 173
 174 If you wish to change directory tracking styles during a session, use the
 175 function `rlogin-directory-tracking-mode' rather than simply setting the
 176 variable."
 177   (interactive (list
 178                 (read-from-minibuffer "rlogin arguments (hostname first): "
 179                                       nil nil nil 'rlogin-history)
 180                 current-prefix-arg))
 181
 182   (let* ((process-connection-type rlogin-process-connection-type)
 183          (args (if rlogin-explicit-args
 184                    (append (rlogin-parse-words input-args)
 185                            rlogin-explicit-args)
 186                  (rlogin-parse-words input-args)))
 187          (host (car args))
 188          (user (or (car (cdr (member "-l" args)))
 189                    (user-login-name)))
 190          (buffer-name (if (string= user (user-login-name))
 191                           (format "*rlogin-%s*" host)
 192                         (format "*rlogin-%s@%s*" user host))))
 193
 194     (cond ((null buffer))
 195           ((stringp buffer)
 196            (setq buffer-name buffer))
 197           ((bufferp buffer)
 198            (setq buffer-name (buffer-name buffer)))
 199           ((numberp buffer)
 200            (setq buffer-name (format "%s<%d>" buffer-name buffer)))
 201           (t
 202            (setq buffer-name (generate-new-buffer-name buffer-name))))
 203
 204     (setq buffer (get-buffer-create buffer-name))
 205     (pop-to-buffer buffer-name)
 206
 207     (unless (comint-check-proc buffer-name)
 208       (comint-exec buffer buffer-name rlogin-program nil args)
 209
 210       (rlogin-mode)
 211
 212       (make-local-variable 'rlogin-host)
 213       (setq rlogin-host host)
 214       (make-local-variable 'rlogin-remote-user)
 215       (setq rlogin-remote-user user)
 216
 217       (condition-case ()
 218           (cond ((eq rlogin-directory-tracking-mode t)
 219                  ;; Do this here, rather than calling the tracking mode
 220                  ;; function, to avoid a gratuitous resync check; the default
 221                  ;; should be the user's home directory, be it local or remote.
 222                  (setq comint-file-name-prefix
 223                        (concat "/" rlogin-remote-user "@" rlogin-host ":"))
 224                  (cd-absolute comint-file-name-prefix))
 225                 ((null rlogin-directory-tracking-mode))
 226                 (t
 227                  (cd-absolute (concat comint-file-name-prefix "~/"))))
 228         (error nil)))))
 229
 230 (put 'rlogin-mode 'mode-class 'special)
 231
 232 (define-derived-mode rlogin-mode shell-mode "Rlogin"
 233   (setq shell-dirtrackp rlogin-directory-tracking-mode)
 234   (make-local-variable 'comint-file-name-prefix))
 235
 236 (defun rlogin-directory-tracking-mode (&optional prefix)
 237   "Do remote or local directory tracking, or disable entirely.
 238
 239 If called with no prefix argument or a unspecified prefix argument (just
 240 ``\\[universal-argument]'' with no number) do remote directory tracking via
 241 ange-ftp.  If called as a function, give it no argument.
 242
 243 If called with a negative prefix argument, disable directory tracking
 244 entirely.
 245
 246 If called with a positive, numeric prefix argument, e.g.
 247 ``\\[universal-argument] 1 M-x rlogin-directory-tracking-mode\'',
 248 then do directory tracking but assume the remote filesystem is the same as
 249 the local system.  This only works in general if the remote machine and the
 250 local one share the same directories (through NFS)."
 251   (interactive "P")
 252   (cond
 253    ((or (null prefix)
 254         (consp prefix))
 255     (setq rlogin-directory-tracking-mode t)
 256     (setq shell-dirtrackp t)
 257     (setq comint-file-name-prefix
 258           (concat "/" rlogin-remote-user "@" rlogin-host ":")))
 259    ((< prefix 0)
 260     (setq rlogin-directory-tracking-mode nil)
 261     (setq shell-dirtrackp nil))
 262    (t
 263     (setq rlogin-directory-tracking-mode 'local)
 264     (setq comint-file-name-prefix "")
 265     (setq shell-dirtrackp t)))
 266   (cond
 267    (shell-dirtrackp
 268     (let* ((proc (get-buffer-process (current-buffer)))
 269            (proc-mark (process-mark proc))
 270            (current-input (buffer-substring proc-mark (point-max)))
 271            (orig-point (point))
 272            (offset (and (>= orig-point proc-mark)
 273                         (- (point-max) orig-point))))
 274       (unwind-protect
 275           (progn
 276             (delete-region proc-mark (point-max))
 277             (goto-char (point-max))
 278             (shell-resync-dirs))
 279         (goto-char proc-mark)
 280         (insert current-input)
 281         (if offset
 282             (goto-char (- (point-max) offset))
 283           (goto-char orig-point)))))))
 284
 285 \f
 286 ;; Parse a line into its constituent parts (words separated by
 287 ;; whitespace).  Return a list of the words.
 288 (defun rlogin-parse-words (line)
 289   (let ((list nil)
 290         (posn 0)
 291         (match-data (match-data)))
 292     (while (string-match "[^ \t\n]+" line posn)
 293       (setq list (cons (substring line (match-beginning 0) (match-end 0))
 294                        list))
 295       (setq posn (match-end 0)))
 296     (set-match-data (match-data))
 297     (nreverse list)))
 298
 299 (defun rlogin-send-Ctrl-C ()
 300   (interactive)
 301   (process-send-string nil "\C-c"))
 302
 303 (defun rlogin-send-Ctrl-D ()
 304   (interactive)
 305   (process-send-string nil "\C-d"))
 306
 307 (defun rlogin-send-Ctrl-Z ()
 308   (interactive)
 309   (process-send-string nil "\C-z"))
 310
 311 (defun rlogin-send-Ctrl-backslash ()
 312   (interactive)
 313   (process-send-string nil "\C-\\"))
 314
 315 (defun rlogin-delchar-or-send-Ctrl-D (arg)
 316   "\
 317 Delete ARG characters forward, or send a C-d to process if at end of buffer."
 318   (interactive "p")
 319   (if (eobp)
 320       (rlogin-send-Ctrl-D)
 321     (delete-char arg)))
 322
 323 (defun rlogin-tab-or-complete ()
 324   "Complete file name if doing directory tracking, or just insert TAB."
 325   (interactive)
 326   (if rlogin-directory-tracking-mode
 327       (comint-dynamic-complete)
 328     (insert "\C-i")))
 329
 330 (provide 'rlogin)
 331
 332 ;;; arch-tag: 6e20eabf-feda-40fa-ab40-0d156db447e4
 333 ;;; rlogin.el ends here