lisp/gnus/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988, 1989, 1990, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;               2000, 2002
   5 ;;               Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'nntp)
  34 (require 'nnoo)
  35 (eval-when-compile (require 'cl))
  36
  37 (nnoo-declare nnspool)
  38
  39 (defvoo nnspool-inews-program news-inews-program
  40   "Program to post news.
  41 This is most commonly `inews' or `injnews'.")
  42
  43 (defvoo nnspool-inews-switches '("-h" "-S")
  44   "Switches for nnspool-request-post to pass to `inews' for posting news.
  45 If you are using Cnews, you probably should set this variable to nil.")
  46
  47 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  48   "Local news spool directory.")
  49
  50 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  51   "Local news nov directory.")
  52
  53 (defvoo nnspool-lib-dir "/usr/lib/news/"
  54   "Where the local news library files are stored.")
  55
  56 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  57   "Local news active file.")
  58
  59 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  60   "Local news newsgroups file.")
  61
  62 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  63   "Local news distributions file.")
  64
  65 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  66   "Local news history file.")
  67
  68 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  69   "Local news active date file.")
  70
  71 (defvoo nnspool-large-newsgroup 50
  72   "The number of the articles which indicates a large newsgroup.
  73 If the number of the articles is greater than the value, verbose
  74 messages will be shown to indicate the current status.")
  75
  76 (defvoo nnspool-nov-is-evil nil
  77   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  78
  79 (defconst nnspool-sift-nov-with-sed nil
  80   "If non-nil, use sed to get the relevant portion from the overview file.
  81 If nil, nnspool will load the entire file into a buffer and process it
  82 there.")
  83
  84 (defvoo nnspool-rejected-article-hook nil
  85   "*A hook that will be run when an article has been rejected by the server.")
  86
  87 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  88   "Coding system for nnspool.")
  89
  90 \f
  91
  92 (defconst nnspool-version "nnspool 2.0"
  93   "Version numbers of this version of NNSPOOL.")
  94
  95 (defvoo nnspool-current-directory nil
  96   "Current news group directory.")
  97
  98 (defvoo nnspool-current-group nil)
  99 (defvoo nnspool-status-string "")
 100
 101 \f
 102 ;;; Interface functions.
 103
 104 (nnoo-define-basics nnspool)
 105
 106 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 107   "Retrieve the headers of ARTICLES."
 108   (save-excursion
 109     (set-buffer nntp-server-buffer)
 110     (erase-buffer)
 111     (when (nnspool-possibly-change-directory group)
 112       (let* ((number (length articles))
 113              (count 0)
 114              (default-directory nnspool-current-directory)
 115              (do-message (and (numberp nnspool-large-newsgroup)
 116                               (> number nnspool-large-newsgroup)))
 117              (nnheader-file-coding-system nnspool-file-coding-system)
 118              file beg article ag)
 119         (if (and (numberp (car articles))
 120                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 121             ;; We successfully retrieved the NOV headers.
 122             'nov
 123           ;; No NOV headers here, so we do it the hard way.
 124           (while (setq article (pop articles))
 125             (if (stringp article)
 126                 ;; This is a Message-ID.
 127                 (setq ag (nnspool-find-id article)
 128                       file (and ag (nnspool-article-pathname
 129                                     (car ag) (cdr ag)))
 130                       article (cdr ag))
 131               ;; This is an article in the current group.
 132               (setq file (int-to-string article)))
 133             ;; Insert the head of the article.
 134             (when (and file
 135                        (file-exists-p file))
 136               (insert "221 ")
 137               (princ article (current-buffer))
 138               (insert " Article retrieved.\n")
 139               (setq beg (point))
 140               (inline (nnheader-insert-head file))
 141               (goto-char beg)
 142               (if (search-forward "\n\n" nil t)
 143                   (progn
 144                     (forward-char -1)
 145                     (insert ".\n"))
 146                 (goto-char (point-max))
 147                 (if (bolp)
 148                     (insert ".\n")
 149                   (insert "\n.\n")))
 150               (delete-region (point) (point-max)))
 151
 152             (and do-message
 153                  (zerop (% (incf count) 20))
 154                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 155                                    (/ (* count 100) number))))
 156
 157           (when do-message
 158             (nnheader-message 5 "nnspool: Receiving headers...done"))
 159
 160           ;; Fold continuation lines.
 161           (nnheader-fold-continuation-lines)
 162           'headers)))))
 163
 164 (deffoo nnspool-open-server (server &optional defs)
 165   (nnoo-change-server 'nnspool server defs)
 166   (cond
 167    ((not (file-exists-p nnspool-spool-directory))
 168     (nnspool-close-server)
 169     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 170                      nnspool-spool-directory))
 171    ((not (file-directory-p
 172           (directory-file-name
 173            (file-truename nnspool-spool-directory))))
 174     (nnspool-close-server)
 175     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 176    ((not (file-exists-p nnspool-active-file))
 177     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 178                      nnspool-active-file))
 179    (t
 180     (nnheader-report 'nnspool "Opened server %s using directory %s"
 181                      server nnspool-spool-directory)
 182     t)))
 183
 184 (deffoo nnspool-request-article (id &optional group server buffer)
 185   "Select article by message ID (or number)."
 186   (nnspool-possibly-change-directory group)
 187   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 188         file ag)
 189     (if (stringp id)
 190         ;; This is a Message-ID.
 191         (when (setq ag (nnspool-find-id id))
 192           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 193       (setq file (nnspool-article-pathname nnspool-current-group id)))
 194     (and file
 195          (file-exists-p file)
 196          (not (file-directory-p file))
 197          (save-excursion (nnspool-find-file file))
 198          ;; We return the article number and group name.
 199          (if (numberp id)
 200              (cons nnspool-current-group id)
 201            ag))))
 202
 203 (deffoo nnspool-request-body (id &optional group server)
 204   "Select article body by message ID (or number)."
 205   (nnspool-possibly-change-directory group)
 206   (let ((res (nnspool-request-article id)))
 207     (when res
 208       (save-excursion
 209         (set-buffer nntp-server-buffer)
 210         (goto-char (point-min))
 211         (when (search-forward "\n\n" nil t)
 212           (delete-region (point-min) (point)))
 213         res))))
 214
 215 (deffoo nnspool-request-head (id &optional group server)
 216   "Select article head by message ID (or number)."
 217   (nnspool-possibly-change-directory group)
 218   (let ((res (nnspool-request-article id)))
 219     (when res
 220       (save-excursion
 221         (set-buffer nntp-server-buffer)
 222         (goto-char (point-min))
 223         (when (search-forward "\n\n" nil t)
 224           (delete-region (1- (point)) (point-max)))
 225         (nnheader-fold-continuation-lines)))
 226     res))
 227
 228 (deffoo nnspool-request-group (group &optional server dont-check)
 229   "Select news GROUP."
 230   (let ((pathname (nnspool-article-pathname group))
 231         dir)
 232     (if (not (file-directory-p pathname))
 233         (nnheader-report
 234          'nnspool "Invalid group name (no such directory): %s" group)
 235       (setq nnspool-current-directory pathname)
 236       (nnheader-report 'nnspool "Selected group %s" group)
 237       (if dont-check
 238           (progn
 239             (nnheader-report 'nnspool "Selected group %s" group)
 240             t)
 241         ;; Yes, completely empty spool directories *are* possible.
 242         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 243         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 244           (setq dir
 245                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 246         (if dir
 247             (nnheader-insert
 248              "211 %d %d %d %s\n" (length dir) (car dir)
 249              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 250              group)
 251           (nnheader-report 'nnspool "Empty group %s" group)
 252           (nnheader-insert "211 0 0 0 %s\n" group))))))
 253
 254 (deffoo nnspool-request-type (group &optional article)
 255   'news)
 256
 257 (deffoo nnspool-close-group (group &optional server)
 258   t)
 259
 260 (deffoo nnspool-request-list (&optional server)
 261   "List active newsgroups."
 262   (save-excursion
 263     (or (nnspool-find-file nnspool-active-file)
 264         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 265
 266 (deffoo nnspool-request-list-newsgroups (&optional server)
 267   "List newsgroups (defined in NNTP2)."
 268   (save-excursion
 269     (or (nnspool-find-file nnspool-newsgroups-file)
 270         (nnheader-report 'nnspool (nnheader-file-error
 271                                    nnspool-newsgroups-file)))))
 272
 273 (deffoo nnspool-request-list-distributions (&optional server)
 274   "List distributions (defined in NNTP2)."
 275   (save-excursion
 276     (or (nnspool-find-file nnspool-distributions-file)
 277         (nnheader-report 'nnspool (nnheader-file-error
 278                                    nnspool-distributions-file)))))
 279
 280 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 281 (deffoo nnspool-request-newgroups (date &optional server)
 282   "List groups created after DATE."
 283   (if (nnspool-find-file nnspool-active-times-file)
 284       (save-excursion
 285         ;; Find the last valid line.
 286         (goto-char (point-max))
 287         (while (and (not (looking-at
 288                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 289                     (zerop (forward-line -1))))
 290         (let ((seconds (time-to-seconds (date-to-time date)))
 291               groups)
 292           ;; Go through lines and add the latest groups to a list.
 293           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 294                       (progn
 295                         ;; We insert a .0 to make the list reader
 296                         ;; interpret the number as a float.  It is far
 297                         ;; too big to be stored in a lisp integer.
 298                         (goto-char (1- (match-end 0)))
 299                         (insert ".0")
 300                         (> (progn
 301                              (goto-char (match-end 1))
 302                              (read (current-buffer)))
 303                            seconds))
 304                       (push (buffer-substring
 305                              (match-beginning 1) (match-end 1))
 306                             groups)
 307                       (zerop (forward-line -1))))
 308           (erase-buffer)
 309           (while groups
 310             (insert (car groups) " 0 0 y\n")
 311             (setq groups (cdr groups))))
 312         t)
 313     nil))
 314
 315 (deffoo nnspool-request-post (&optional server)
 316   "Post a new news in current buffer."
 317   (save-excursion
 318     (let* ((process-connection-type nil) ; t bugs out on Solaris
 319            (inews-buffer (generate-new-buffer " *nnspool post*"))
 320            (proc
 321             (condition-case err
 322                 (apply 'start-process "*nnspool inews*" inews-buffer
 323                        nnspool-inews-program nnspool-inews-switches)
 324               (error
 325                (nnheader-report 'nnspool "inews error: %S" err)))))
 326       (if (not proc)
 327           ;; The inews program failed.
 328           ()
 329         (nnheader-report 'nnspool "")
 330         (set-process-sentinel proc 'nnspool-inews-sentinel)
 331         (mm-with-unibyte-current-buffer
 332           (process-send-region proc (point-min) (point-max)))
 333         ;; We slap a condition-case around this, because the process may
 334         ;; have exited already...
 335         (ignore-errors
 336           (process-send-eof proc))
 337         t))))
 338
 339
 340 \f
 341 ;;; Internal functions.
 342
 343 (defun nnspool-inews-sentinel (proc status)
 344   (save-excursion
 345     (set-buffer (process-buffer proc))
 346     (goto-char (point-min))
 347     (if (or (zerop (buffer-size))
 348             (search-forward "spooled" nil t))
 349         (kill-buffer (current-buffer))
 350       ;; Make status message by folding lines.
 351       (while (re-search-forward "[ \t\n]+" nil t)
 352         (replace-match " " t t))
 353       (nnheader-report 'nnspool "%s" (buffer-string))
 354       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 355       (ding)
 356       (run-hooks 'nnspool-rejected-article-hook))))
 357
 358 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 359   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 360       nil
 361     (let ((nov (nnheader-group-pathname
 362                 nnspool-current-group nnspool-nov-directory ".overview"))
 363           (arts articles)
 364           (nnheader-file-coding-system nnspool-file-coding-system)
 365           last)
 366       (if (not (file-exists-p nov))
 367           ()
 368         (save-excursion
 369           (set-buffer nntp-server-buffer)
 370           (erase-buffer)
 371           (if nnspool-sift-nov-with-sed
 372               (nnspool-sift-nov-with-sed articles nov)
 373             (nnheader-insert-file-contents nov)
 374             (if (and fetch-old
 375                      (not (numberp fetch-old)))
 376                 t                       ; We want all the headers.
 377               (ignore-errors
 378                 ;; Delete unwanted NOV lines.
 379                 (nnheader-nov-delete-outside-range
 380                  (if fetch-old (max 1 (- (car articles) fetch-old))
 381                    (car articles))
 382                  (car (last articles)))
 383                 ;; If the buffer is empty, this wasn't very successful.
 384                 (unless (zerop (buffer-size))
 385                   ;; We check what the last article number was.
 386                   ;; The NOV file may be out of sync with the articles
 387                   ;; in the group.
 388                   (forward-line -1)
 389                   (setq last (read (current-buffer)))
 390                   (if (= last (car articles))
 391                       ;; Yup, it's all there.
 392                       t
 393                     ;; Perhaps not.  We try to find the missing articles.
 394                     (while (and arts
 395                                 (<= last (car arts)))
 396                       (pop arts))
 397                     ;; The articles in `arts' are missing from the buffer.
 398                     (while arts
 399                       (nnspool-insert-nov-head (pop arts)))
 400                     t))))))))))
 401
 402 (defun nnspool-insert-nov-head (article)
 403   "Read the head of ARTICLE, convert to NOV headers, and insert."
 404   (save-excursion
 405     (let ((cur (current-buffer))
 406           buf)
 407       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 408       (when (nnheader-insert-head
 409              (nnspool-article-pathname nnspool-current-group article))
 410         (nnheader-insert-article-line article)
 411         (let ((headers (nnheader-parse-head)))
 412           (set-buffer cur)
 413           (goto-char (point-max))
 414           (nnheader-insert-nov headers)))
 415       (kill-buffer buf))))
 416
 417 (defun nnspool-sift-nov-with-sed (articles file)
 418   (let ((first (car articles))
 419         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 420                      (car articles))))
 421     (call-process "awk" nil t nil
 422                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 423                           (1- first) (1+ last))
 424                   file)))
 425
 426 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 427 ;; Find out what group an article identified by a Message-ID is in.
 428 (defun nnspool-find-id (id)
 429   (save-excursion
 430     (set-buffer (get-buffer-create " *nnspool work*"))
 431     (erase-buffer)
 432     (ignore-errors
 433       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 434     (goto-char (point-min))
 435     (prog1
 436         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 437           (cons (match-string 1) (string-to-int (match-string 2))))
 438       (kill-buffer (current-buffer)))))
 439
 440 (defun nnspool-find-file (file)
 441   "Insert FILE in server buffer safely."
 442   (set-buffer nntp-server-buffer)
 443   (erase-buffer)
 444   (condition-case ()
 445       (let ((coding-system-for-read nnspool-file-coding-system))
 446         (mm-insert-file-contents file)
 447         t)
 448     (file-error nil)))
 449
 450 (defun nnspool-possibly-change-directory (group)
 451   (if (not group)
 452       t
 453     (let ((pathname (nnspool-article-pathname group)))
 454       (if (file-directory-p pathname)
 455           (setq nnspool-current-directory pathname
 456                 nnspool-current-group group)
 457         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 458
 459 (defun nnspool-article-pathname (group &optional article)
 460   "Find the file name for GROUP."
 461   (nnheader-group-pathname group nnspool-spool-directory article))
 462
 463 (provide 'nnspool)
 464
 465 ;;; arch-tag: bdac8d27-2934-4eee-bad0-49e6b90c0d05
 466 ;;; nnspool.el ends here