lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "*Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "*A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a legal Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "*A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "*If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defvar PC-old-read-file-name-internal nil)
 145
 146 (defun PC-bindings (bind)
 147   (let ((completion-map minibuffer-local-completion-map)
 148         (must-match-map minibuffer-local-must-match-map))
 149     (cond ((not bind)
 150            ;; These bindings are the default bindings.  It would be better to
 151            ;; restore the previous bindings.
 152            (define-key completion-map "\t"      'minibuffer-complete)
 153            (define-key completion-map " "       'minibuffer-complete-word)
 154            (define-key completion-map "?"       'minibuffer-completion-help)
 155
 156            (define-key must-match-map "\t"      'minibuffer-complete)
 157            (define-key must-match-map " "       'minibuffer-complete-word)
 158            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 159            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 160            (define-key must-match-map "?"       'minibuffer-completion-help)
 161
 162            (define-key global-map "\e\t"        'complete-symbol))
 163           (PC-default-bindings
 164            (define-key completion-map "\t"      'PC-complete)
 165            (define-key completion-map " "       'PC-complete-word)
 166            (define-key completion-map "?"       'PC-completion-help)
 167
 168            (define-key completion-map "\e\t"    'PC-complete)
 169            (define-key completion-map "\e "     'PC-complete-word)
 170            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 171            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 172            (define-key completion-map "\e?"     'PC-completion-help)
 173
 174            (define-key must-match-map "\t"      'PC-complete)
 175            (define-key must-match-map " "       'PC-complete-word)
 176            (define-key must-match-map "\r"      'PC-complete-and-exit)
 177            (define-key must-match-map "\n"      'PC-complete-and-exit)
 178            (define-key must-match-map "?"       'PC-completion-help)
 179
 180            (define-key must-match-map "\e\t"    'PC-complete)
 181            (define-key must-match-map "\e "     'PC-complete-word)
 182            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 183            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 184            (define-key must-match-map "\e?"     'PC-completion-help)
 185
 186            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 187
 188 ;;;###autoload
 189 (define-minor-mode partial-completion-mode
 190   "Toggle Partial Completion mode.
 191 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 192
 193 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 194 nil) is enhanced so that if some string is divided into words and each word is
 195 delimited by a character in `PC-word-delimiters', partial words are completed
 196 as much as possible and `*' characters are treated likewise in file names.
 197
 198 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 199 command begins with that sequence of characters, and
 200 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 201 other file in that directory begin with that sequence of characters.
 202
 203 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 204 specially in \\[find-file].  For example,
 205 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 206 See also the variable `PC-include-file-path'."
 207   :global t :group 'partial-completion
 208   ;; Deal with key bindings...
 209   (PC-bindings partial-completion-mode)
 210   ;; Deal with include file feature...
 211   (cond ((not partial-completion-mode)
 212          (remove-hook 'find-file-not-found-hooks 'PC-look-for-include-file))
 213         ((not PC-disable-includes)
 214          (add-hook 'find-file-not-found-hooks 'PC-look-for-include-file)))
 215   ;; ... with some underhand redefining.
 216   (cond ((and (not partial-completion-mode)
 217               (functionp PC-old-read-file-name-internal))
 218          (fset 'read-file-name-internal PC-old-read-file-name-internal))
 219         ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 220          (setq PC-old-read-file-name-internal
 221                (symbol-function 'read-file-name-internal))
 222          (fset 'read-file-name-internal
 223                'PC-read-include-file-name-internal)))
 224     (when (and partial-completion-mode (null PC-env-vars-alist))
 225       (setq PC-env-vars-alist
 226             (mapcar (lambda (string)
 227                       (let ((d (string-match "=" string)))
 228                         (cons (concat "$" (substring string 0 d))
 229                               (and d (substring string (1+ d))))))
 230                     process-environment))))
 231
 232 \f
 233 (defun PC-complete ()
 234   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 235 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 236 name which consists of three or more words, the first beginning with \"b\"
 237 and the third beginning with \"di\".
 238
 239 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 240 `beginning-of-defun', so this would produce a list of completions
 241 just like when normal Emacs completions are ambiguous.
 242
 243 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 244 \".\", and SPC."
 245   (interactive)
 246   (if (PC-was-meta-key)
 247       (minibuffer-complete)
 248     ;; If the previous command was not this one,
 249     ;; never scroll, always retry completion.
 250     (or (eq last-command this-command)
 251         (setq minibuffer-scroll-window nil))
 252     (let ((window minibuffer-scroll-window))
 253       ;; If there's a fresh completion window with a live buffer,
 254       ;; and this command is repeated, scroll that window.
 255       (if (and window (window-buffer window)
 256                (buffer-name (window-buffer window)))
 257           (save-excursion
 258             (set-buffer (window-buffer window))
 259             (if (pos-visible-in-window-p (point-max) window)
 260                 (set-window-start window (point-min) nil)
 261               (scroll-other-window)))
 262         (PC-do-completion nil)))))
 263
 264
 265 (defun PC-complete-word ()
 266   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 267 See `PC-complete' for details.
 268 This can be bound to other keys, like `-' and `.', if you wish."
 269   (interactive)
 270   (if (eq (PC-was-meta-key) PC-meta-flag)
 271       (if (eq last-command-char ? )
 272           (minibuffer-complete-word)
 273         (self-insert-command 1))
 274     (self-insert-command 1)
 275     (if (eobp)
 276         (PC-do-completion 'word))))
 277
 278
 279 (defun PC-complete-space ()
 280   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 281 See `PC-complete' for details.
 282 This is suitable for binding to other keys which should act just like SPC."
 283   (interactive)
 284   (if (eq (PC-was-meta-key) PC-meta-flag)
 285       (minibuffer-complete-word)
 286     (insert " ")
 287     (if (eobp)
 288         (PC-do-completion 'word))))
 289
 290
 291 (defun PC-complete-and-exit ()
 292   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 293 See `PC-complete' for details."
 294   (interactive)
 295   (if (eq (PC-was-meta-key) PC-meta-flag)
 296       (minibuffer-complete-and-exit)
 297     (PC-do-complete-and-exit)))
 298
 299 (defun PC-force-complete-and-exit ()
 300   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 301 See `PC-complete' for details."
 302   (interactive)
 303   (let ((minibuffer-completion-confirm nil))
 304     (PC-do-complete-and-exit)))
 305
 306 (defun PC-do-complete-and-exit ()
 307   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 308       (exit-minibuffer)
 309     (let ((flag (PC-do-completion 'exit)))
 310       (and flag
 311            (if (or (eq flag 'complete)
 312                    (not minibuffer-completion-confirm))
 313                (exit-minibuffer)
 314              (PC-temp-minibuffer-message " [Confirm]"))))))
 315
 316
 317 (defun PC-completion-help ()
 318   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 319 See `PC-complete' for details."
 320   (interactive)
 321   (if (eq (PC-was-meta-key) PC-meta-flag)
 322       (minibuffer-completion-help)
 323     (PC-do-completion 'help)))
 324
 325 (defun PC-was-meta-key ()
 326   (or (/= (length (this-command-keys)) 1)
 327       (let ((key (aref (this-command-keys) 0)))
 328         (if (integerp key)
 329             (>= key 128)
 330           (not (null (memq 'meta (event-modifiers key))))))))
 331
 332
 333 (defvar PC-ignored-extensions 'empty-cache)
 334 (defvar PC-delims 'empty-cache)
 335 (defvar PC-ignored-regexp nil)
 336 (defvar PC-word-failed-flag nil)
 337 (defvar PC-delim-regex nil)
 338 (defvar PC-ndelims-regex nil)
 339 (defvar PC-delims-list nil)
 340
 341 (defvar PC-completion-as-file-name-predicate
 342   (function
 343    (lambda ()
 344      (memq minibuffer-completion-table
 345            '(read-file-name-internal read-directory-name-internal))))
 346    "A function testing whether a minibuffer completion now will work filename-style.
 347 The function takes no arguments, and typically looks at the value
 348 of `minibuffer-completion-table' and the minibuffer contents.")
 349
 350 (defun PC-do-completion (&optional mode beg end)
 351   (or beg (setq beg (minibuffer-prompt-end)))
 352   (or end (setq end (point-max)))
 353   (let* ((table minibuffer-completion-table)
 354          (pred minibuffer-completion-predicate)
 355          (filename (funcall PC-completion-as-file-name-predicate))
 356          (dirname nil)
 357          (dirlength 0)
 358          (str (buffer-substring beg end))
 359          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 360          (ambig nil)
 361          basestr
 362          env-on
 363          regex
 364          p offset
 365          (poss nil)
 366          helpposs
 367          (case-fold-search completion-ignore-case))
 368
 369     ;; Check if buffer contents can already be considered complete
 370     (if (and (eq mode 'exit)
 371              (PC-is-complete-p str table pred))
 372         'complete
 373
 374       ;; Do substitutions in directory names
 375       (and filename
 376            (setq basestr (or (file-name-directory str) ""))
 377            (setq dirlength (length basestr))
 378            ;; Do substitutions in directory names
 379            (setq p (substitute-in-file-name basestr))
 380            (not (string-equal basestr p))
 381            (setq str (concat p (file-name-nondirectory str)))
 382            (progn
 383              (delete-region beg end)
 384              (insert str)
 385              (setq end (+ beg (length str)))))
 386
 387       ;; Prepare various delimiter strings
 388       (or (equal PC-word-delimiters PC-delims)
 389           (setq PC-delims PC-word-delimiters
 390                 PC-delim-regex (concat "[" PC-delims "]")
 391                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 392                 PC-delims-list (append PC-delims nil)))
 393
 394       ;; Add wildcards if necessary
 395       (and filename
 396            (let ((dir (file-name-directory str))
 397                  (file (file-name-nondirectory str)))
 398              (while (and (stringp dir) (not (file-directory-p dir)))
 399                (setq dir (directory-file-name dir))
 400                (setq file (concat (replace-regexp-in-string
 401                                    PC-delim-regex "*\\&"
 402                                    (file-name-nondirectory dir))
 403                                   "*/" file))
 404                (setq dir (file-name-directory dir)))
 405              (setq str (concat dir file))))
 406
 407       ;; Look for wildcard expansions in directory name
 408       (and filename
 409            (string-match "\\*.*/" str)
 410            (let ((pat str)
 411                  files)
 412              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 413              (while (setq p (string-match PC-delim-regex pat p))
 414                (setq pat (concat (substring pat 0 p)
 415                                  "*"
 416                                  (substring pat p))
 417                      p (+ p 2)))
 418              (setq files (PC-expand-many-files (concat pat "*")))
 419              (if files
 420                  (let ((dir (file-name-directory (car files)))
 421                        (p files))
 422                    (while (and (setq p (cdr p))
 423                                (equal dir (file-name-directory (car p)))))
 424                    (if p
 425                        (setq filename nil table nil pred nil
 426                              ambig t)
 427                      (delete-region beg end)
 428                      (setq str (concat dir (file-name-nondirectory str)))
 429                      (insert str)
 430                      (setq end (+ beg (length str)))))
 431                (setq filename nil table nil pred nil))))
 432
 433       ;; Strip directory name if appropriate
 434       (if filename
 435           (if incname
 436               (setq basestr (substring str incname)
 437                     dirname (substring str 0 incname))
 438             (setq basestr (file-name-nondirectory str)
 439                   dirname (file-name-directory str))
 440             ;; Make sure str is consistent with its directory and basename
 441             ;; parts.  This is important on DOZe'NT systems when str only
 442             ;; includes a drive letter, like in "d:".
 443             (setq str (concat dirname basestr)))
 444         (setq basestr str))
 445
 446       ;; Convert search pattern to a standard regular expression
 447       (setq regex (regexp-quote basestr)
 448             offset (if (and (> (length regex) 0)
 449                             (not (eq (aref basestr 0) ?\*))
 450                             (or (eq PC-first-char t)
 451                                 (and PC-first-char filename))) 1 0)
 452             p offset)
 453       (while (setq p (string-match PC-delim-regex regex p))
 454         (if (eq (aref regex p) ? )
 455             (setq regex (concat (substring regex 0 p)
 456                                 PC-ndelims-regex
 457                                 PC-delim-regex
 458                                 (substring regex (1+ p)))
 459                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 460           (let ((bump (if (memq (aref regex p)
 461                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 462                           -1 0)))
 463             (setq regex (concat (substring regex 0 (+ p bump))
 464                                 PC-ndelims-regex
 465                                 (substring regex (+ p bump)))
 466                   p (+ p (length PC-ndelims-regex) 1)))))
 467       (setq p 0)
 468       (if filename
 469           (while (setq p (string-match "\\\\\\*" regex p))
 470             (setq regex (concat (substring regex 0 p)
 471                                 "[^/]*"
 472                                 (substring regex (+ p 2))))))
 473       ;;(setq the-regex regex)
 474       (setq regex (concat "\\`" regex))
 475
 476       (and (> (length basestr) 0)
 477            (= (aref basestr 0) ?$)
 478            (setq env-on t
 479                  table PC-env-vars-alist
 480                  pred nil))
 481
 482       ;; Find an initial list of possible completions
 483       (if (not (setq p (string-match (concat PC-delim-regex
 484                                              (if filename "\\|\\*" ""))
 485                                      str
 486                                      (+ (length dirname) offset))))
 487
 488           ;; Minibuffer contains no hyphens -- simple case!
 489           (setq poss (all-completions (if env-on
 490                                           basestr str)
 491                                       table
 492                                       pred))
 493
 494         ;; Use all-completions to do an initial cull.  This is a big win,
 495         ;; since all-completions is written in C!
 496         (let ((compl (all-completions (if env-on
 497                                           (file-name-nondirectory (substring str 0 p))
 498                                         (substring str 0 p))
 499                                         table
 500                                         pred)))
 501           (setq p compl)
 502           (while p
 503             (and (string-match regex (car p))
 504                  (progn
 505                    (set-text-properties 0 (length (car p)) '() (car p))
 506                    (setq poss (cons (car p) poss))))
 507             (setq p (cdr p)))))
 508
 509       ;; Now we have a list of possible completions
 510       (cond
 511
 512        ;; No valid completions found
 513        ((null poss)
 514         (if (and (eq mode 'word)
 515                  (not PC-word-failed-flag))
 516             (let ((PC-word-failed-flag t))
 517               (delete-backward-char 1)
 518               (PC-do-completion 'word))
 519           (beep)
 520           (PC-temp-minibuffer-message (if ambig
 521                                           " [Ambiguous dir name]"
 522                                         (if (eq mode 'help)
 523                                             " [No completions]"
 524                                           " [No match]")))
 525           nil))
 526
 527        ;; More than one valid completion found
 528        ((or (cdr (setq helpposs poss))
 529             (memq mode '(help word)))
 530
 531         ;; Handle completion-ignored-extensions
 532         (and filename
 533              (not (eq mode 'help))
 534              (let ((p2 poss))
 535
 536                ;; Build a regular expression representing the extensions list
 537                (or (equal completion-ignored-extensions PC-ignored-extensions)
 538                    (setq PC-ignored-regexp
 539                          (concat "\\("
 540                                  (mapconcat
 541                                   'regexp-quote
 542                                   (setq PC-ignored-extensions
 543                                         completion-ignored-extensions)
 544                                   "\\|")
 545                                  "\\)\\'")))
 546
 547                ;; Check if there are any without an ignored extension.
 548                ;; Also ignore `.' and `..'.
 549                (setq p nil)
 550                (while p2
 551                  (or (string-match PC-ignored-regexp (car p2))
 552                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 553                      (setq p (cons (car p2) p)))
 554                  (setq p2 (cdr p2)))
 555
 556                ;; If there are "good" names, use them
 557                (and p (setq poss p))))
 558
 559         ;; Is the actual string one of the possible completions?
 560         (setq p (and (not (eq mode 'help)) poss))
 561         (while (and p
 562                     (not (string-equal (car p) basestr)))
 563           (setq p (cdr p)))
 564         (and p (null mode)
 565              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 566         (if (and p
 567                  (not (and (null mode)
 568                            (eq this-command last-command))))
 569             t
 570
 571           ;; If ambiguous, try for a partial completion
 572           (let ((improved nil)
 573                 prefix
 574                 (pt nil)
 575                 (skip "\\`"))
 576
 577             ;; Check if next few letters are the same in all cases
 578             (if (and (not (eq mode 'help))
 579                      (setq prefix (try-completion "" (mapcar 'list poss))))
 580                 (let ((first t) i)
 581                   (if (eq mode 'word)
 582                       (setq prefix (PC-chop-word prefix basestr)))
 583                   (goto-char (+ beg (length dirname)))
 584                   (while (and (progn
 585                                 (setq i 0)
 586                                 (while (< i (length prefix))
 587                                   (if (and (< (point) end)
 588                                            (eq (aref prefix i)
 589                                                (following-char)))
 590                                       (forward-char 1)
 591                                     (if (and (< (point) end)
 592                                              (or (and (looking-at " ")
 593                                                       (memq (aref prefix i)
 594                                                             PC-delims-list))
 595                                                  (eq (downcase (aref prefix i))
 596                                                      (downcase
 597                                                       (following-char)))))
 598                                         (progn
 599                                           (delete-char 1)
 600                                           (setq end (1- end)))
 601                                       (and filename (looking-at "\\*")
 602                                            (progn
 603                                              (delete-char 1)
 604                                              (setq end (1- end))))
 605                                       (setq improved t))
 606                                     (insert (substring prefix i (1+ i)))
 607                                     (setq end (1+ end)))
 608                                   (setq i (1+ i)))
 609                                 (or pt (equal (point) beg)
 610                                     (setq pt (point)))
 611                                 (looking-at PC-delim-regex))
 612                               (setq skip (concat skip
 613                                                  (regexp-quote prefix)
 614                                                  PC-ndelims-regex)
 615                                     prefix (try-completion
 616                                             ""
 617                                             (mapcar
 618                                              (function
 619                                               (lambda (x)
 620                                                 (list
 621                                                  (and (string-match skip x)
 622                                                       (substring
 623                                                        x
 624                                                        (match-end 0))))))
 625                                              poss)))
 626                               (or (> i 0) (> (length prefix) 0))
 627                               (or (not (eq mode 'word))
 628                                   (and first (> (length prefix) 0)
 629                                        (setq first nil
 630                                              prefix (substring prefix 0 1))))))
 631                   (goto-char (if (eq mode 'word) end
 632                                (or pt beg)))))
 633
 634             (if (and (eq mode 'word)
 635                      (not PC-word-failed-flag))
 636
 637                 (if improved
 638
 639                     ;; We changed it... would it be complete without the space?
 640                     (if (PC-is-complete-p (buffer-substring 1 (1- end))
 641                                           table pred)
 642                         (delete-region (1- end) end)))
 643
 644               (if improved
 645
 646                   ;; We changed it... enough to be complete?
 647                   (and (eq mode 'exit)
 648                        (PC-is-complete-p (field-string) table pred))
 649
 650                 ;; If totally ambiguous, display a list of completions
 651                 (if (or (eq completion-auto-help t)
 652                         (and completion-auto-help
 653                              (eq last-command this-command))
 654                         (eq mode 'help))
 655                     (with-output-to-temp-buffer "*Completions*"
 656                       (display-completion-list (sort helpposs 'string-lessp))
 657                       (save-excursion
 658                         (set-buffer standard-output)
 659                         ;; Record which part of the buffer we are completing
 660                         ;; so that choosing a completion from the list
 661                         ;; knows how much old text to replace.
 662                         (setq completion-base-size dirlength)))
 663                   (PC-temp-minibuffer-message " [Next char not unique]"))
 664                 nil)))))
 665
 666        ;; Only one possible completion
 667        (t
 668         (if (and (equal basestr (car poss))
 669                  (not (and env-on filename)))
 670             (if (null mode)
 671                 (PC-temp-minibuffer-message " [Sole completion]"))
 672           (delete-region beg end)
 673           (insert (format "%s"
 674                           (if filename
 675                               (substitute-in-file-name (concat dirname (car poss)))
 676                             (car poss)))))
 677         t)))))
 678
 679
 680 (defun PC-is-complete-p (str table pred)
 681   (let ((res (if (listp table)
 682                  (assoc str table)
 683                (if (vectorp table)
 684                    (or (equal str "nil")   ; heh, heh, heh
 685                        (intern-soft str table))
 686                  (funcall table str pred 'lambda)))))
 687     (and res
 688          (or (not pred)
 689              (and (not (listp table)) (not (vectorp table)))
 690              (funcall pred res))
 691          res)))
 692
 693 (defun PC-chop-word (new old)
 694   (let ((i -1)
 695         (j -1))
 696     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 697                 (setq j (string-match PC-delim-regex new (1+ j)))))
 698     (if (and j
 699              (or (not PC-word-failed-flag)
 700                  (setq j (string-match PC-delim-regex new (1+ j)))))
 701         (substring new 0 (1+ j))
 702       new)))
 703
 704 (defvar PC-not-minibuffer nil)
 705
 706 (defun PC-temp-minibuffer-message (message)
 707   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 708   (cond (PC-not-minibuffer
 709          (message message)
 710          (sit-for 2)
 711          (message ""))
 712         ((fboundp 'temp-minibuffer-message)
 713          (temp-minibuffer-message message))
 714         (t
 715          (let ((point-max (point-max)))
 716            (save-excursion
 717              (goto-char point-max)
 718              (insert message))
 719            (let ((inhibit-quit t))
 720              (sit-for 2)
 721              (delete-region point-max (point-max))
 722              (when quit-flag
 723                (setq quit-flag nil
 724                      unread-command-events '(7))))))))
 725
 726
 727 (defun PC-lisp-complete-symbol ()
 728   "Perform completion on Lisp symbol preceding point.
 729 That symbol is compared against the symbols that exist
 730 and any additional characters determined by what is there
 731 are inserted.
 732 If the symbol starts just after an open-parenthesis,
 733 only symbols with function definitions are considered.
 734 Otherwise, all symbols with function definitions, values
 735 or properties are considered."
 736   (interactive)
 737   (let* ((end (point))
 738          (buffer-syntax (syntax-table))
 739          (beg (unwind-protect
 740                   (save-excursion
 741                     (if lisp-mode-syntax-table
 742                         (set-syntax-table lisp-mode-syntax-table))
 743                     (backward-sexp 1)
 744                     (while (= (char-syntax (following-char)) ?\')
 745                       (forward-char 1))
 746                     (point))
 747                 (set-syntax-table buffer-syntax)))
 748          (minibuffer-completion-table obarray)
 749          (minibuffer-completion-predicate
 750           (if (eq (char-after (1- beg)) ?\()
 751               'fboundp
 752             (function (lambda (sym)
 753                         (or (boundp sym) (fboundp sym)
 754                             (symbol-plist sym))))))
 755          (PC-not-minibuffer t))
 756     (PC-do-completion nil beg end)))
 757
 758 (defun PC-complete-as-file-name ()
 759    "Perform completion on file names preceding point.
 760  Environment vars are converted to their values."
 761    (interactive)
 762    (let* ((end (point))
 763           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 764                                        (point-min) t)
 765                    (+ (point) 2)
 766                    (point-min)))
 767           (minibuffer-completion-table 'read-file-name-internal)
 768           (minibuffer-completion-predicate "")
 769           (PC-not-minibuffer t))
 770      (goto-char end)
 771      (PC-do-completion nil beg end)))
 772
 773 ;;; Use the shell to do globbing.
 774 ;;; This could now use file-expand-wildcards instead.
 775
 776 (defun PC-expand-many-files (name)
 777   (save-excursion
 778     (set-buffer (generate-new-buffer " *Glob Output*"))
 779     (erase-buffer)
 780     (shell-command (concat "echo " name) t)
 781     (goto-char (point-min))
 782     (if (looking-at ".*No match")
 783         nil
 784       (insert "(\"")
 785       (while (search-forward " " nil t)
 786         (delete-backward-char 1)
 787         (insert "\" \""))
 788       (goto-char (point-max))
 789       (delete-backward-char 1)
 790       (insert "\")")
 791       (goto-char (point-min))
 792       (let ((files (read (current-buffer))) (p nil))
 793         (kill-buffer (current-buffer))
 794         (or (equal completion-ignored-extensions PC-ignored-extensions)
 795             (setq PC-ignored-regexp
 796                   (concat "\\("
 797                           (mapconcat
 798                            'regexp-quote
 799                            (setq PC-ignored-extensions
 800                                  completion-ignored-extensions)
 801                            "\\|")
 802                           "\\)\\'")))
 803         (setq p nil)
 804         (while files
 805           (or (string-match PC-ignored-regexp (car files))
 806               (setq p (cons (car files) p)))
 807           (setq files (cdr files)))
 808         p))))
 809
 810 ;;; Facilities for loading C header files.  This is independent from the
 811 ;;; main completion code.  See also the variable `PC-include-file-path'
 812 ;;; at top of this file.
 813
 814 (defun PC-look-for-include-file ()
 815   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 816       (let ((name (substring (buffer-file-name)
 817                              (match-beginning 1) (match-end 1)))
 818             (punc (aref (buffer-file-name) (match-beginning 0)))
 819             (path nil)
 820             new-buf)
 821         (kill-buffer (current-buffer))
 822         (if (equal name "")
 823             (save-excursion
 824               (set-buffer (car (buffer-list)))
 825               (save-excursion
 826                 (beginning-of-line)
 827                 (if (looking-at
 828                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 829                     (setq name (buffer-substring (match-beginning 1)
 830                                                  (match-end 1))
 831                           punc (char-after (1- (match-beginning 1))))
 832                   ;; Suggested by Frank Siebenlist:
 833                   (if (or (looking-at
 834                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 835                           (looking-at
 836                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 837                           (looking-at
 838                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 839                       (progn
 840                         (setq name (buffer-substring (match-beginning 1)
 841                                                      (match-end 1))
 842                               punc ?\<
 843                               path load-path)
 844                         (if (string-match "\\.elc$" name)
 845                             (setq name (substring name 0 -1))
 846                           (or (string-match "\\.el$" name)
 847                               (setq name (concat name ".el")))))
 848                     (error "Not on an #include line"))))))
 849         (or (string-match "\\.[[:alnum:]]+$" name)
 850             (setq name (concat name ".h")))
 851         (if (eq punc ?\<)
 852             (let ((path (or path (PC-include-file-path))))
 853               (while (and path
 854                           (not (file-exists-p
 855                                 (concat (file-name-as-directory (car path))
 856                                         name))))
 857                 (setq path (cdr path)))
 858               (if path
 859                   (setq name (concat (file-name-as-directory (car path)) name))
 860                 (error "No such include file: <%s>" name)))
 861           (let ((dir (save-excursion
 862                        (set-buffer (car (buffer-list)))
 863                        default-directory)))
 864             (if (file-exists-p (concat dir name))
 865                 (setq name (concat dir name))
 866               (error "No such include file: `%s'" name))))
 867         (setq new-buf (get-file-buffer name))
 868         (if new-buf
 869             ;; no need to verify last-modified time for this!
 870             (set-buffer new-buf)
 871           (setq new-buf (create-file-buffer name))
 872           (set-buffer new-buf)
 873           (erase-buffer)
 874           (insert-file-contents name t))
 875         ;; Returning non-nil with the new buffer current
 876         ;; is sufficient to tell find-file to use it.
 877         t)
 878     nil))
 879
 880 (defun PC-include-file-path ()
 881   (or PC-include-file-path
 882       (let ((env (getenv "INCPATH"))
 883             (path nil)
 884             pos)
 885         (or env (error "No include file path specified"))
 886         (while (setq pos (string-match ":[^:]+$" env))
 887           (setq path (cons (substring env (1+ pos)) path)
 888                 env (substring env 0 pos)))
 889         path)))
 890
 891 ;;; This is adapted from lib-complete.el, by Mike Williams.
 892 (defun PC-include-file-all-completions (file search-path &optional full)
 893   "Return all completions for FILE in any directory on SEARCH-PATH.
 894 If optional third argument FULL is non-nil, returned pathnames should be
 895 absolute rather than relative to some directory on the SEARCH-PATH."
 896   (setq search-path
 897         (mapcar (lambda (dir)
 898                   (if dir (file-name-as-directory dir) default-directory))
 899                 search-path))
 900   (if (file-name-absolute-p file)
 901       ;; It's an absolute file name, so don't need search-path
 902       (progn
 903         (setq file (expand-file-name file))
 904         (file-name-all-completions
 905          (file-name-nondirectory file) (file-name-directory file)))
 906     (let ((subdir (file-name-directory file))
 907           (ndfile (file-name-nondirectory file))
 908           file-lists)
 909       ;; Append subdirectory part to each element of search-path
 910       (if subdir
 911           (setq search-path
 912                 (mapcar (lambda (dir) (concat dir subdir))
 913                         search-path)
 914                 file ))
 915       ;; Make list of completions in each directory on search-path
 916       (while search-path
 917         (let* ((dir (car search-path))
 918                (subdir (if full dir subdir)))
 919           (if (file-directory-p dir)
 920               (progn
 921                 (setq file-lists
 922                       (cons
 923                        (mapcar (lambda (file) (concat subdir file))
 924                                (file-name-all-completions ndfile
 925                                                           (car search-path)))
 926                        file-lists))))
 927           (setq search-path (cdr search-path))))
 928       ;; Compress out duplicates while building complete list (slloooow!)
 929       (let ((sorted (sort (apply 'nconc file-lists)
 930                           (lambda (x y) (not (string-lessp x y)))))
 931             compressed)
 932         (while sorted
 933           (if (equal (car sorted) (car compressed)) nil
 934             (setq compressed (cons (car sorted) compressed)))
 935           (setq sorted (cdr sorted)))
 936         compressed))))
 937
 938 (defun PC-read-include-file-name-internal (string dir action)
 939   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 940       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 941              (str2 (substring string (match-beginning 0)))
 942              (completion-table
 943               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 944                       (PC-include-file-all-completions
 945                        name (PC-include-file-path)))))
 946         (cond
 947          ((not completion-table) nil)
 948          ((eq action nil) (try-completion str2 completion-table nil))
 949          ((eq action t) (all-completions str2 completion-table nil))
 950          ((eq action 'lambda)
 951           (eq (try-completion str2 completion-table nil) t))))
 952     (funcall PC-old-read-file-name-internal string dir action)))
 953 \f
 954
 955 (provide 'complete)
 956
 957 ;;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
 958 ;;; complete.el ends here