lisp/calendar/cal-china.el

   1 ;;; cal-china.el --- calendar functions for the Chinese calendar
   2
   3 ;; Copyright (C) 1995, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: calendar
   7 ;; Human-Keywords: Chinese calendar, calendar, holidays, diary
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This collection of functions implements the features of calendar.el,
  29 ;; diary.el, and holidays.el that deal with the Chinese calendar.  The rules
  30 ;; used for the Chinese calendar are those of Baolin Liu (see L. E. Doggett's
  31 ;; article "Calendars" in the Explanatory Supplement to the Astronomical
  32 ;; Almanac, second edition, 1992) for the calendar as revised at the beginning
  33 ;; of the Qing dynasty in 1644.  The nature of the astronomical calculations
  34 ;; is such that precise calculations cannot be made without great expense in
  35 ;; time, so that the calendars produced may not agree perfectly with published
  36 ;; tables--but no two pairs of published tables agree perfectly either!  Liu's
  37 ;; rules produce a calendar for 2033 which is not accepted by all authorities.
  38 ;; The date of Chinese New Year is correct from 1644-2051.
  39
  40 ;; Technical details of all the calendrical calculations can be found in
  41 ;; ``Calendrical Calculations'' by Nachum Dershowitz and Edward M. Reingold,
  42 ;; Cambridge University Press (1997).
  43
  44 ;; Comments, corrections, and improvements should be sent to
  45 ;;  Edward M. Reingold               Department of Computer Science
  46 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  47 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  48 ;;                                   Urbana, Illinois 61801
  49
  50 ;;; Code:
  51
  52 (defvar displayed-month)
  53 (defvar displayed-year)
  54
  55 (require 'lunar)
  56
  57 (defvar chinese-calendar-celestial-stem
  58   ["Jia" "Yi" "Bing" "Ding" "Wu" "Ji" "Geng" "Xin" "Ren" "Gui"])
  59
  60 (defvar chinese-calendar-terrestrial-branch
  61   ["Zi" "Chou" "Yin" "Mao" "Chen" "Si" "Wu" "Wei" "Shen" "You" "Xu" "Hai"])
  62
  63 (defcustom chinese-calendar-time-zone
  64   '(if (< year 1928)
  65        (+ 465 (/ 40.0 60.0))
  66      480)
  67   "*Number of minutes difference between local standard time for Chinese
  68 calendar and Coordinated Universal (Greenwich) Time.  Default is for Beijing.
  69 This is an expression in `year' since it changed at 1928-01-01 00:00:00 from
  70 UT+7:45:40 to UT+8."
  71   :type 'sexp
  72   :group 'chinese-calendar)
  73
  74 (defcustom chinese-calendar-location-name "Beijing"
  75   "*Name of location used for calculation of Chinese calendar."
  76   :type 'string
  77   :group 'chinese-calendar)
  78
  79 (defcustom chinese-calendar-daylight-time-offset 0
  80 ; The correct value is as follows, but the Chinese calendrical
  81 ; authorities do NOT use DST in determining astronomical events:
  82 ;  60
  83   "*Number of minutes difference between daylight savings and standard time
  84 for Chinese calendar.  Default is for no daylight savings time."
  85   :type 'integer
  86   :group 'chinese-calendar)
  87
  88 (defcustom chinese-calendar-standard-time-zone-name
  89   '(if (< year 1928)
  90        "PMT"
  91      "CST")
  92   "*Abbreviated name of standard time zone used for Chinese calendar.
  93 This is an expression depending on `year' because it changed
  94 at 1928-01-01 00:00:00 from `PMT' to `CST'."
  95   :type 'sexp
  96   :group 'chinese-calendar)
  97
  98 (defcustom chinese-calendar-daylight-time-zone-name "CDT"
  99   "*Abbreviated name of daylight-savings time zone used for Chinese calendar."
 100   :type 'string
 101   :group 'chinese-calendar)
 102
 103 (defcustom chinese-calendar-daylight-savings-starts nil
 104 ; The correct value is as follows, but the Chinese calendrical
 105 ; authorities do NOT use DST in determining astronomical events:
 106 ;  '(cond ((< 1986 year) (calendar-nth-named-day 1 0 4 year 10))
 107 ;         ((= 1986 year) '(5 4 1986))
 108 ;         (t nil))
 109   "*Sexp giving the date on which daylight savings time starts for Chinese
 110 calendar.  Default is for no daylight savings time.  See documentation of
 111 `calendar-daylight-savings-starts'."
 112   :type 'sexp
 113   :group 'chinese-calendar)
 114
 115 (defcustom chinese-calendar-daylight-savings-ends nil
 116 ; The correct value is as follows, but the Chinese calendrical
 117 ; authorities do NOT use DST in determining astronomical events:
 118 ;  '(if (<= 1986 year) (calendar-nth-named-day 1 0 9 year 11))
 119   "*Sexp giving the date on which daylight savings time ends for Chinese
 120 calendar.  Default is for no daylight savings time.  See documentation of
 121 `calendar-daylight-savings-ends'."
 122   :type 'sexp
 123   :group 'chinese-calendar)
 124
 125 (defcustom chinese-calendar-daylight-savings-starts-time 0
 126   "*Number of minutes after midnight that daylight savings time starts for
 127 Chinese calendar.  Default is for no daylight savings time."
 128   :type 'integer
 129   :group 'chinese-calendar)
 130
 131 (defcustom chinese-calendar-daylight-savings-ends-time 0
 132   "*Number of minutes after midnight that daylight savings time ends for
 133 Chinese calendar.  Default is for no daylight savings time."
 134   :type 'integer
 135   :group 'chinese-calendar)
 136
 137 (defun chinese-zodiac-sign-on-or-after (d)
 138   "Absolute date of first new Zodiac sign on or after absolute date d.
 139 The Zodiac signs begin when the sun's longitude is a multiple of 30 degrees."
 140  (let* ((year (extract-calendar-year
 141                 (calendar-gregorian-from-absolute d)))
 142          (calendar-time-zone (eval chinese-calendar-time-zone))
 143          (calendar-daylight-time-offset
 144           chinese-calendar-daylight-time-offset)
 145          (calendar-standard-time-zone-name
 146           chinese-calendar-standard-time-zone-name)
 147          (calendar-daylight-time-zone-name
 148           chinese-calendar-daylight-time-zone-name)
 149          (calendar-calendar-daylight-savings-starts
 150           chinese-calendar-daylight-savings-starts)
 151          (calendar-daylight-savings-ends
 152           chinese-calendar-daylight-savings-ends)
 153          (calendar-daylight-savings-starts-time
 154           chinese-calendar-daylight-savings-starts-time)
 155          (calendar-daylight-savings-ends-time
 156           chinese-calendar-daylight-savings-ends-time))
 157    (floor
 158     (calendar-absolute-from-astro
 159      (solar-date-next-longitude
 160       (calendar-astro-from-absolute d)
 161       30)))))
 162
 163 (defun chinese-new-moon-on-or-after (d)
 164   "Absolute date of first new moon on or after absolute date d."
 165   (let* ((year (extract-calendar-year
 166                 (calendar-gregorian-from-absolute d)))
 167          (calendar-time-zone (eval chinese-calendar-time-zone))
 168          (calendar-daylight-time-offset
 169           chinese-calendar-daylight-time-offset)
 170          (calendar-standard-time-zone-name
 171           chinese-calendar-standard-time-zone-name)
 172          (calendar-daylight-time-zone-name
 173           chinese-calendar-daylight-time-zone-name)
 174          (calendar-calendar-daylight-savings-starts
 175           chinese-calendar-daylight-savings-starts)
 176          (calendar-daylight-savings-ends
 177           chinese-calendar-daylight-savings-ends)
 178          (calendar-daylight-savings-starts-time
 179           chinese-calendar-daylight-savings-starts-time)
 180          (calendar-daylight-savings-ends-time
 181           chinese-calendar-daylight-savings-ends-time))
 182     (floor
 183      (calendar-absolute-from-astro
 184       (lunar-new-moon-on-or-after
 185        (calendar-astro-from-absolute d))))))
 186
 187 (defvar chinese-year-cache
 188   '((1990 (12 726464) (1 726494) (2 726523) (3 726553) (4 726582) (5 726611)
 189           (5.5 726641) (6 726670) (7 726699) (8 726729) (9 726758) (10 726788)
 190           (11 726818))
 191     (1991 (12 726848) (1 726878) (2 726907) (3 726937) (4 726966) (5 726995)
 192           (6 727025) (7 727054) (8 727083) (9 727113) (10 727142) (11 727172))
 193     (1992 (12 727202) (1 727232) (2 727261) (3 727291) (4 727321) (5 727350)
 194           (6 727379) (7 727409) (8 727438) (9 727467) (10 727497) (11 727526))
 195     (1993 (12 727556) (1 727586) (2 727615) (3 727645) (3.5 727675) (4 727704)
 196           (5 727734) (6 727763) (7 727793) (8 727822) (9 727851) (10 727881)
 197           (11 727910))
 198     (1994 (12 727940) (1 727969) (2 727999) (3 728029) (4 728059) (5 728088)
 199           (6 728118) (7 728147) (8 728177) (9 728206) (10 728235) (11 728265))
 200     (1995 (12 728294) (1 728324) (2 728353) (3 728383) (4 728413) (5 728442)
 201           (6 728472) (7 728501) (8 728531) (8.5 728561) (9 728590) (10 728619)
 202           (11 728649))
 203     (1996 (12 728678) (1 728708) (2 728737) (3 728767) (4 728796) (5 728826)
 204           (6 728856) (7 728885) (8 728915) (9 728944) (10 728974) (11 729004))
 205     (1997 (12 729033) (1 729062) (2 729092) (3 729121) (4 729151) (5 729180)
 206           (6 729210) (7 729239) (8 729269) (9 729299) (10 729328) (11 729358))
 207     (1998 (12 729388) (1 729417) (2 729447) (3 729476) (4 729505) (5 729535)
 208           (5.5 729564) (6 729593) (7 729623) (8 729653) (9 729682) (10 729712)
 209           (11 729742))
 210     (1999 (12 729771) (1 729801) (2 729831) (3 729860) (4 729889) (5 729919)
 211           (6 729948) (7 729977) (8 730007) (9 730036) (10 730066) (11 730096))
 212     (2000 (12 730126) (1 730155) (2 730185) (3 730215) (4 730244) (5 730273)
 213           (6 730303) (7 730332) (8 730361) (9 730391) (10 730420) (11 730450))
 214     (2001 (12 730480) (1 730509) (2 730539) (3 730569) (4 730598) (4.5 730628)
 215           (5 730657) (6 730687) (7 730716) (8 730745) (9 730775) (10 730804)
 216           (11 730834))
 217     (2002 (12 730863) (1 730893) (2 730923) (3 730953) (4 730982) (5 731012)
 218           (6 731041) (7 731071) (8 731100) (9 731129) (10 731159) (11 731188))
 219     (2003 (12 731218) (1 731247) (2 731277) (3 731307) (4 731336) (5 731366)
 220           (6 731396) (7 731425) (8 731455) (9 731484) (10 731513) (11 731543))
 221     (2004 (12 731572) (1 731602) (2 731631) (2.5 731661) (3 731690) (4 731720)
 222           (5 731750) (6 731779) (7 731809) (8 731838) (9 731868) (10 731897)
 223           (11 731927))
 224     (2005 (12 731956) (1 731986) (2 732015) (3 732045) (4 732074) (5 732104)
 225           (6 732133) (7 732163) (8 732193) (9 732222) (10 732252) (11 732281))
 226     (2006 (12 732311) (1 732340) (2 732370) (3 732399) (4 732429) (5 732458)
 227           (6 732488) (7 732517) (7.5 732547) (8 732576) (9 732606) (10 732636)
 228           (11 732665))
 229     (2007 (12 732695) (1 732725) (2 732754) (3 732783) (4 732813) (5 732842)
 230           (6 732871) (7 732901) (8 732930) (9 732960) (10 732990) (11 733020))
 231     (2008 (12 733049) (1 733079) (2 733109) (3 733138) (4 733167) (5 733197)
 232           (6 733226) (7 733255) (8 733285) (9 733314) (10 733344) (11 733374))
 233     (2009 (12 733403) (1 733433) (2 733463) (3 733493) (4 733522) (5 733551)
 234           (5.5 733581) (6 733610) (7 733639) (8 733669) (9 733698) (10 733728)
 235           (11 733757))
 236     (2010 (12 733787) (1 733817) (2 733847) (3 733876) (4 733906) (5 733935)
 237           (6 733965) (7 733994) (8 734023) (9 734053) (10 734082) (11 734112)))
 238   "An assoc list of Chinese year structures as determined by `chinese-year'.
 239
 240 Values are computed as needed, but to save time, the initial value consists
 241 of the precomputed years 1990-2010.  The code works just as well with this
 242 set to nil initially (which is how the value for 1990-2010 was computed).")
 243
 244 (defun chinese-year (y)
 245   "The structure of the Chinese year for Gregorian year Y.
 246 The result is a list of pairs (i d), where month i begins on absolute date d,
 247 of the Chinese months from the Chinese month following the solstice in
 248 Gregorian year Y-1 to the Chinese month of the solstice of Gregorian year Y.
 249
 250 The list is cached for further use."
 251   (let ((list (cdr (assoc y chinese-year-cache))))
 252     (if (not list)
 253         (progn
 254           (setq list (compute-chinese-year y))
 255           (setq chinese-year-cache
 256                 (append chinese-year-cache (list (cons y list))))))
 257     list))
 258
 259 (defun number-chinese-months (list start)
 260   "Assign month numbers to the lunar months in LIST, starting with START.
 261 Numbers are assigned sequentially, START, START+1, ..., 11, with half
 262 numbers used for leap months.
 263
 264 First month of list will never be a leap month, nor will the last."
 265   (if list
 266       (if (zerop (- 12 start (length list)))
 267           ;; List is too short for a leap month
 268           (cons (list start (car list))
 269                 (number-chinese-months (cdr list) (1+ start)))
 270         (cons
 271          ;; First month
 272          (list start (car list))
 273          ;; Remaining months
 274          (if (and (cdr (cdr list));; at least two more months...
 275                   (<= (car (cdr (cdr list)))
 276                       (chinese-zodiac-sign-on-or-after (car (cdr list)))))
 277              ;; Next month is a leap month
 278              (cons (list (+ start 0.5) (car (cdr list)))
 279                    (number-chinese-months (cdr (cdr list)) (1+ start)))
 280            ;; Next month is not a leap month
 281            (number-chinese-months (cdr list) (1+ start)))))))
 282
 283 (defun chinese-month-list (start end)
 284   "List of starting dates of Chinese months from START to END."
 285   (if (<= start end)
 286       (let ((new-moon (chinese-new-moon-on-or-after start)))
 287         (if (<= new-moon end)
 288             (cons new-moon
 289                   (chinese-month-list (1+ new-moon) end))))))
 290
 291 (defun compute-chinese-year (y)
 292   "Compute the structure of the Chinese year for Gregorian year Y.
 293 The result is a list of pairs (i d), where month i begins on absolute date d,
 294 of the Chinese months from the Chinese month following the solstice in
 295 Gregorian year Y-1 to the Chinese month of the solstice of Gregorian year Y."
 296   (let* ((next-solstice (chinese-zodiac-sign-on-or-after
 297                          (calendar-absolute-from-gregorian
 298                           (list 12 15 y))))
 299          (list (chinese-month-list (1+ (chinese-zodiac-sign-on-or-after
 300                                         (calendar-absolute-from-gregorian
 301                                          (list 12 15 (1- y)))))
 302                                    next-solstice))
 303          (next-sign (chinese-zodiac-sign-on-or-after (car list))))
 304     (if (= (length list) 12)
 305         ;; No room for a leap month, just number them 12, 1, 2, ..., 11
 306         (cons (list 12 (car list))
 307               (number-chinese-months (cdr list) 1))
 308       ;; Now we can assign numbers to the list for y
 309       ;; The first month or two are special
 310       (if (or (> (car list) next-sign) (>= next-sign (car (cdr list))))
 311           ;; First month on list is a leap month, second is not
 312           (append (list (list 11.5 (car list))
 313                         (list 12 (car (cdr list))))
 314                   (number-chinese-months (cdr (cdr list)) 1))
 315         ;; First month on list is not a leap month
 316         (append (list (list 12 (car list)))
 317                 (if (>= (chinese-zodiac-sign-on-or-after (car (cdr list)))
 318                         (car (cdr (cdr list))))
 319                     ;; Second month on list is a leap month
 320                     (cons (list 12.5 (car (cdr list)))
 321                           (number-chinese-months (cdr (cdr list)) 1))
 322                   ;; Second month on list is not a leap month
 323                   (number-chinese-months (cdr list) 1)))))))
 324
 325 (defun calendar-absolute-from-chinese (date)
 326   "The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
 327 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 328   (let* ((cycle (car date))
 329          (year (car (cdr date)))
 330          (month (car (cdr (cdr date))))
 331          (day (car (cdr (cdr (cdr date)))))
 332          (g-year (+ (* (1- cycle) 60);; years in prior cycles
 333                     (1- year)        ;; prior years this cycle
 334                     -2636)))         ;; years before absolute date 0
 335     (+ (1- day);; prior days this month
 336        (car
 337         (cdr    ;; absolute date of start of this month
 338          (assoc month (append (memq (assoc 1 (chinese-year g-year))
 339                                     (chinese-year g-year))
 340                               (chinese-year (1+ g-year)))))))))
 341
 342 (defun calendar-chinese-from-absolute (date)
 343   "Compute Chinese date (cycle year month day) corresponding to absolute DATE.
 344 The absolute date is the number of days elapsed since the (imaginary)
 345 Gregorian date Sunday, December 31, 1 BC."
 346   (let* ((g-year (extract-calendar-year
 347                   (calendar-gregorian-from-absolute date)))
 348          (c-year (+ g-year 2695))
 349          (list (append (chinese-year (1- g-year))
 350                        (chinese-year g-year)
 351                        (chinese-year (1+ g-year)))))
 352     (while (<= (car (cdr (car (cdr list)))) date)
 353       ;; the first month on the list is in Chinese year c-year
 354       ;; date is on or after start of second month on list...
 355       (if (= 1 (car (car (cdr list))))
 356           ;; second month on list is a new Chinese year
 357           (setq c-year (1+ c-year)))
 358       ;; ...so first month on list is of no interest
 359       (setq list (cdr list)))
 360     (list (/ (1- c-year) 60)
 361           (calendar-mod c-year 60)
 362           (car (car list))
 363           (1+ (- date (car (cdr (car list))))))))
 364
 365 (defun holiday-chinese-new-year ()
 366   "Date of Chinese New Year."
 367   (let ((m displayed-month)
 368         (y displayed-year))
 369     (increment-calendar-month m y 1)
 370     (if (< m 5)
 371         (let ((chinese-new-year
 372                (calendar-gregorian-from-absolute
 373                 (car (cdr (assoc 1 (chinese-year y)))))))
 374           (if (calendar-date-is-visible-p chinese-new-year)
 375           (list
 376            (list chinese-new-year
 377                  (format "Chinese New Year (%s)"
 378                          (calendar-chinese-sexagesimal-name (+ y 57))))))))))
 379
 380 (defun calendar-chinese-date-string (&optional date)
 381   "String of Chinese date of Gregorian DATE.
 382 Defaults to today's date if DATE is not given."
 383   (let* ((a-date (calendar-absolute-from-gregorian
 384                   (or date (calendar-current-date))))
 385          (c-date (calendar-chinese-from-absolute a-date))
 386          (cycle (car c-date))
 387          (year (car (cdr c-date)))
 388          (month (car (cdr (cdr c-date))))
 389          (day (car (cdr (cdr (cdr c-date)))))
 390          (this-month (calendar-absolute-from-chinese
 391                       (list cycle year month 1)))
 392          (next-month (calendar-absolute-from-chinese
 393                       (list (if (= year 60) (1+ cycle) cycle)
 394                             (if (= (floor month) 12) (1+ year) year)
 395                             (calendar-mod (1+ (floor month)) 12)
 396                             1)))
 397          (m-cycle (% (+ (* year 5) (floor month)) 60)))
 398     (format "Cycle %s, year %s (%s), %smonth %s%s, day %s (%s)"
 399             cycle
 400             year (calendar-chinese-sexagesimal-name year)
 401             (if (not (integerp month))
 402                 "second "
 403               (if (< 30 (- next-month this-month))
 404                   "first "
 405                 ""))
 406             (floor month)
 407             (if (integerp month)
 408                 (format " (%s)" (calendar-chinese-sexagesimal-name
 409                                  (+ (* 12 year) month 50)))
 410               "")
 411             day (calendar-chinese-sexagesimal-name (+ a-date 15)))))
 412
 413 (defun calendar-chinese-sexagesimal-name (n)
 414   "The N-th name of the Chinese sexagesimal cycle.
 415 N congruent to 1 gives the first name, N congruent to 2 gives the second name,
 416 ..., N congruent to 60 gives the sixtieth name."
 417   (format "%s-%s"
 418           (aref chinese-calendar-celestial-stem (% (1- n) 10))
 419           (aref chinese-calendar-terrestrial-branch (% (1- n) 12))))
 420
 421 (defun calendar-print-chinese-date ()
 422   "Show the Chinese date equivalents of date."
 423   (interactive)
 424   (message "Computing Chinese date...")
 425   (message "Chinese date: %s"
 426            (calendar-chinese-date-string (calendar-cursor-to-date t))))
 427
 428 (defun calendar-goto-chinese-date (date &optional noecho)
 429   "Move cursor to Chinese date DATE.
 430 Echo Chinese date unless NOECHO is t."
 431   (interactive
 432    (let* ((c (calendar-chinese-from-absolute
 433               (calendar-absolute-from-gregorian
 434                (calendar-current-date))))
 435           (cycle (calendar-read
 436                   "Chinese calendar cycle number (>44): "
 437                   '(lambda (x) (> x 44))
 438                   (int-to-string (car c))))
 439           (year (calendar-read
 440                  "Year in Chinese cycle (1..60): "
 441                  '(lambda (x) (and (<= 1 x) (<= x 60)))
 442                  (int-to-string (car (cdr c)))))
 443           (month-list (make-chinese-month-assoc-list
 444                        (chinese-months cycle year)))
 445           (month (cdr (assoc
 446                        (completing-read "Chinese calendar month: "
 447                                         month-list nil t)
 448                        month-list)))
 449           (last (if (= month
 450                        (car (cdr (cdr
 451                                   (calendar-chinese-from-absolute
 452                                    (+ 29
 453                                       (calendar-absolute-from-chinese
 454                                        (list cycle year month 1))))))))
 455                     30
 456                   29))
 457           (day (calendar-read
 458                 (format "Chinese calendar day (1-%d): " last)
 459                 '(lambda (x) (and (<= 1 x) (<= x last))))))
 460      (list (list cycle year month day))))
 461   (calendar-goto-date (calendar-gregorian-from-absolute
 462                        (calendar-absolute-from-chinese date)))
 463   (or noecho (calendar-print-chinese-date)))
 464
 465 (defun chinese-months (c y)
 466   "A list of the months in cycle C, year Y of the Chinese calendar."
 467   (let* ((l (memq 1 (append
 468                      (mapcar '(lambda (x)
 469                                 (car x))
 470                              (chinese-year (extract-calendar-year
 471                                             (calendar-gregorian-from-absolute
 472                                              (calendar-absolute-from-chinese
 473                                               (list c y 1 1))))))
 474                      (mapcar '(lambda (x)
 475                                 (if (> (car x) 11) (car x)))
 476                              (chinese-year (extract-calendar-year
 477                                             (calendar-gregorian-from-absolute
 478                                              (calendar-absolute-from-chinese
 479                                               (list (if (= y 60) (1+ c) c)
 480                                                     (if (= y 60) 1 y)
 481                                                     1 1))))))))))
 482     l))
 483
 484 (defun make-chinese-month-assoc-list (l)
 485   "Make list of months L into an assoc list."
 486   (if (and l (car l))
 487       (if (and (cdr l) (car (cdr l)))
 488           (if (= (car l) (floor (car (cdr l))))
 489               (append
 490                (list (cons (format "%s (first)" (car l)) (car l))
 491                      (cons (format "%s (second)" (car l)) (car (cdr l))))
 492                (make-chinese-month-assoc-list (cdr (cdr l))))
 493             (append
 494              (list (cons (int-to-string (car l)) (car l)))
 495              (make-chinese-month-assoc-list (cdr l))))
 496         (list (cons (int-to-string (car l)) (car l))))))
 497
 498 (defun diary-chinese-date ()
 499   "Chinese calendar equivalent of date diary entry."
 500   (format "Chinese date: %s" (calendar-chinese-date-string date)))
 501
 502 (provide 'cal-china)
 503
 504 ;;; arch-tag: 7e5b7e0d-676c-47e3-8696-93e7ea0ab644
 505 ;;; cal-china.el ends here