lisp/calendar/time-date.el

   1 ;;; time-date.el --- Date and time handling functions
   2
   3 ;; Copyright (C) 1998-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu Umeda <umerin@mse.kyutech.ac.jp>
   7 ;; Keywords: mail news util
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Time values come in several formats.  The oldest format is a cons
  27 ;; cell of the form (HIGH . LOW).  This format is obsolete, but still
  28 ;; supported.  The other formats are the lists (HIGH LOW), (HIGH LOW
  29 ;; USEC), and (HIGH LOW USEC PSEC).  These formats specify the time
  30 ;; value equal to HIGH * 2^16 + LOW + USEC * 10^-6 + PSEC * 10^-12
  31 ;; seconds, where missing components are treated as zero.  HIGH can be
  32 ;; negative, either because the value is a time difference, or because
  33 ;; the machine supports negative time stamps that fall before the epoch.
  34 ;; The macro `with-decoded-time-value' and the function
  35 ;; `encode-time-value' make it easier to deal with these formats.
  36 ;; See `time-subtract' for an example of how to use them.
  37
  38 ;;; Code:
  39
  40 (defmacro with-decoded-time-value (varlist &rest body)
  41   "Decode a time value and bind it according to VARLIST, then eval BODY.
  42
  43 The value of the last form in BODY is returned.
  44
  45 Each element of the list VARLIST is a list of the form
  46 \(HIGH-SYMBOL LOW-SYMBOL MICRO-SYMBOL [PICO-SYMBOL [TYPE-SYMBOL]] TIME-VALUE).
  47 The time value TIME-VALUE is decoded and the result it bound to
  48 the symbols HIGH-SYMBOL, LOW-SYMBOL and MICRO-SYMBOL.
  49 The optional PICO-SYMBOL is bound to the picoseconds part.
  50
  51 The optional TYPE-SYMBOL is bound to the type of the time value.
  52 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH
  53 LOW), type 2 is the list (HIGH LOW MICRO), and type 3 is the
  54 list (HIGH LOW MICRO PICO)."
  55   (declare (indent 1)
  56            (debug ((&rest (symbolp symbolp symbolp &or [symbolp form] form))
  57                    body)))
  58   (if varlist
  59       (let* ((elt (pop varlist))
  60              (high (pop elt))
  61              (low (pop elt))
  62              (micro (pop elt))
  63              (pico (unless (<= (length elt) 2)
  64                      (pop elt)))
  65              (type (unless (eq (length elt) 1)
  66                      (pop elt)))
  67              (time-value (car elt))
  68              (gensym (make-symbol "time")))
  69         `(let* ,(append `((,gensym ,time-value)
  70                           (,high (pop ,gensym))
  71                           ,low ,micro)
  72                         (when pico `(,pico))
  73                         (when type `(,type)))
  74            (if (consp ,gensym)
  75                (progn
  76                  (setq ,low (pop ,gensym))
  77                  (if ,gensym
  78                      (progn
  79                        (setq ,micro (car ,gensym))
  80                        ,(cond (pico
  81                                `(if (cdr ,gensym)
  82                                     ,(append `(setq ,pico (cadr ,gensym))
  83                                              (when type `(,type 3)))
  84                                   ,(append `(setq ,pico 0)
  85                                            (when type `(,type 2)))))
  86                               (type
  87                                `(setq type 2))))
  88                    ,(append `(setq ,micro 0)
  89                             (when pico `(,pico 0))
  90                             (when type `(,type 1)))))
  91              ,(append `(setq ,low ,gensym ,micro 0)
  92                       (when pico `(,pico 0))
  93                       (when type `(,type 0))))
  94            (with-decoded-time-value ,varlist ,@body)))
  95     `(progn ,@body)))
  96
  97 (defun encode-time-value (high low micro pico &optional type)
  98   "Encode HIGH, LOW, MICRO, and PICO into a time value of type TYPE.
  99 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH LOW),
 100 type 2 is (HIGH LOW MICRO), and type 3 is (HIGH LOW MICRO PICO).
 101
 102 For backward compatibility, if only four arguments are given,
 103 it is assumed that PICO was omitted and should be treated as zero."
 104   (cond
 105    ((eq type 0) (cons high low))
 106    ((eq type 1) (list high low))
 107    ((eq type 2) (list high low micro))
 108    ((eq type 3) (list high low micro pico))
 109    ((null type) (encode-time-value high low micro 0 pico))))
 110
 111 (autoload 'parse-time-string "parse-time")
 112 (autoload 'timezone-make-date-arpa-standard "timezone")
 113
 114 ;;;###autoload
 115 ;; `parse-time-string' isn't sufficiently general or robust.  It fails
 116 ;; to grok some of the formats that timezone does (e.g. dodgy
 117 ;; post-2000 stuff from some Elms) and either fails or returns bogus
 118 ;; values.  timezone-make-date-arpa-standard should help.
 119 (defun date-to-time (date)
 120   "Parse a string DATE that represents a date-time and return a time value.
 121 If DATE lacks timezone information, GMT is assumed."
 122   (condition-case ()
 123       (apply 'encode-time (parse-time-string date))
 124     (error (condition-case ()
 125                (apply 'encode-time
 126                       (parse-time-string
 127                        (timezone-make-date-arpa-standard date)))
 128              (error (error "Invalid date: %s" date))))))
 129
 130 ;; Bit of a mess.  Emacs has float-time since at least 21.1.
 131 ;; This file is synced to Gnus, and XEmacs packages may have been written
 132 ;; using time-to-seconds from the Gnus library.
 133 ;;;###autoload(if (or (featurep 'emacs)
 134 ;;;###autoload        (and (fboundp 'float-time)
 135 ;;;###autoload             (subrp (symbol-function 'float-time))))
 136 ;;;###autoload    (progn
 137 ;;;###autoload      (defalias 'time-to-seconds 'float-time)
 138 ;;;###autoload      (make-obsolete 'time-to-seconds 'float-time "21.1"))
 139 ;;;###autoload  (autoload 'time-to-seconds "time-date"))
 140
 141 (eval-when-compile
 142   (or (featurep 'emacs)
 143       (and (fboundp 'float-time)
 144            (subrp (symbol-function 'float-time)))
 145       (defun time-to-seconds (time)
 146         "Convert time value TIME to a floating point number."
 147         (with-decoded-time-value ((high low micro pico type time))
 148           (+ (* 1.0 high 65536)
 149              low
 150              (/ (+ (* micro 1e6) pico) 1e12))))))
 151
 152 ;;;###autoload
 153 (defun seconds-to-time (seconds)
 154   "Convert SECONDS (a floating point number) to a time value."
 155   (let* ((usec (* 1000000 (mod seconds 1)))
 156          (ps (round (* 1000000 (mod usec 1))))
 157          (us (floor usec))
 158          (lo (floor (mod seconds 65536)))
 159          (hi (floor seconds 65536)))
 160     (if (eq ps 1000000)
 161         (progn
 162           (setq ps 0)
 163           (setq us (1+ us))
 164           (if (eq us 1000000)
 165               (progn
 166                 (setq us 0)
 167                 (setq lo (1+ lo))
 168                 (if (eq lo 65536)
 169                     (progn
 170                       (setq lo 0)
 171                       (setq hi (1+ hi))))))))
 172     (list hi lo us ps)))
 173
 174 ;;;###autoload
 175 (defun time-less-p (t1 t2)
 176   "Return non-nil if time value T1 is earlier than time value T2."
 177   (with-decoded-time-value ((high1 low1 micro1 pico1 type1 t1)
 178                             (high2 low2 micro2 pico2 type2 t2))
 179     (or (< high1 high2)
 180         (and (= high1 high2)
 181              (or (< low1 low2)
 182                  (and (= low1 low2)
 183                       (or (< micro1 micro2)
 184                           (and (= micro1 micro2)
 185                                (< pico1 pico2)))))))))
 186
 187 ;;;###autoload
 188 (defun days-to-time (days)
 189   "Convert DAYS into a time value."
 190   (let* ((seconds (* 1.0 days 60 60 24))
 191          (high (condition-case nil (floor (/ seconds 65536))
 192                  (range-error most-positive-fixnum))))
 193     (list high (condition-case nil (floor (- seconds (* 1.0 high 65536)))
 194                  (range-error 65535)))))
 195
 196 ;;;###autoload
 197 (defun time-since (time)
 198   "Return the time elapsed since TIME.
 199 TIME should be either a time value or a date-time string."
 200   (when (stringp time)
 201     ;; Convert date strings to internal time.
 202     (setq time (date-to-time time)))
 203   (time-subtract (current-time) time))
 204
 205 ;;;###autoload
 206 (defalias 'subtract-time 'time-subtract)
 207
 208 ;;;###autoload
 209 (defun time-subtract (t1 t2)
 210   "Subtract two time values, T1 minus T2.
 211 Return the difference in the format of a time value."
 212   (with-decoded-time-value ((high low micro pico type t1)
 213                             (high2 low2 micro2 pico2 type2 t2))
 214     (setq high (- high high2)
 215           low (- low low2)
 216           micro (- micro micro2)
 217           pico (- pico pico2)
 218           type (max type type2))
 219     (when (< pico 0)
 220       (setq micro (1- micro)
 221             pico (+ pico 1000000)))
 222     (when (< micro 0)
 223       (setq low (1- low)
 224             micro (+ micro 1000000)))
 225     (when (< low 0)
 226       (setq high (1- high)
 227             low (+ low 65536)))
 228     (encode-time-value high low micro pico type)))
 229
 230 ;;;###autoload
 231 (defun time-add (t1 t2)
 232   "Add two time values T1 and T2.  One should represent a time difference."
 233   (with-decoded-time-value ((high low micro pico type t1)
 234                             (high2 low2 micro2 pico2 type2 t2))
 235     (setq high (+ high high2)
 236           low (+ low low2)
 237           micro (+ micro micro2)
 238           pico (+ pico pico2)
 239           type (max type type2))
 240     (when (>= pico 1000000)
 241       (setq micro (1+ micro)
 242             pico (- pico 1000000)))
 243     (when (>= micro 1000000)
 244       (setq low (1+ low)
 245             micro (- micro 1000000)))
 246     (when (>= low 65536)
 247       (setq high (1+ high)
 248             low (- low 65536)))
 249     (encode-time-value high low micro pico type)))
 250
 251 ;;;###autoload
 252 (defun date-to-day (date)
 253   "Return the number of days between year 1 and DATE.
 254 DATE should be a date-time string."
 255   (time-to-days (date-to-time date)))
 256
 257 ;;;###autoload
 258 (defun days-between (date1 date2)
 259   "Return the number of days between DATE1 and DATE2.
 260 DATE1 and DATE2 should be date-time strings."
 261   (- (date-to-day date1) (date-to-day date2)))
 262
 263 ;;;###autoload
 264 (defun date-leap-year-p (year)
 265   "Return t if YEAR is a leap year."
 266   (or (and (zerop (% year 4))
 267            (not (zerop (% year 100))))
 268       (zerop (% year 400))))
 269
 270 ;;;###autoload
 271 (defun time-to-day-in-year (time)
 272   "Return the day number within the year corresponding to TIME."
 273   (let* ((tim (decode-time time))
 274          (month (nth 4 tim))
 275          (day (nth 3 tim))
 276          (year (nth 5 tim))
 277          (day-of-year (+ day (* 31 (1- month)))))
 278     (when (> month 2)
 279       (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 280       (when (date-leap-year-p year)
 281         (setq day-of-year (1+ day-of-year))))
 282     day-of-year))
 283
 284 ;;;###autoload
 285 (defun time-to-days (time)
 286   "The number of days between the Gregorian date 0001-12-31bce and TIME.
 287 TIME should be a time value.
 288 The Gregorian date Sunday, December 31, 1bce is imaginary."
 289   (let* ((tim (decode-time time))
 290          (year (nth 5 tim)))
 291     (+ (time-to-day-in-year time)       ;       Days this year
 292        (* 365 (1- year))                ;       + Days in prior years
 293        (/ (1- year) 4)                  ;       + Julian leap years
 294        (- (/ (1- year) 100))            ;       - century years
 295        (/ (1- year) 400))))             ;       + Gregorian leap years
 296
 297 (defun time-to-number-of-days (time)
 298   "Return the number of days represented by TIME.
 299 Returns a floating point number."
 300   (/ (funcall (eval-when-compile
 301                 (if (or (featurep 'emacs)
 302                         (and (fboundp 'float-time)
 303                              (subrp (symbol-function 'float-time))))
 304                     'float-time
 305                   'time-to-seconds)) time) (* 60 60 24)))
 306
 307 ;;;###autoload
 308 (defun safe-date-to-time (date)
 309   "Parse a string DATE that represents a date-time and return a time value.
 310 If DATE is malformed, return a time value of zeros."
 311   (condition-case ()
 312       (date-to-time date)
 313     (error '(0 0))))
 314
 315 \f
 316 ;;;###autoload
 317 (defun format-seconds (string seconds)
 318   "Use format control STRING to format the number SECONDS.
 319 The valid format specifiers are:
 320 %y is the number of (365-day) years.
 321 %d is the number of days.
 322 %h is the number of hours.
 323 %m is the number of minutes.
 324 %s is the number of seconds.
 325 %z is a non-printing control flag (see below).
 326 %% is a literal \"%\".
 327
 328 Upper-case specifiers are followed by the unit-name (e.g. \"years\").
 329 Lower-case specifiers return only the unit.
 330
 331 \"%\" may be followed by a number specifying a width, with an
 332 optional leading \".\" for zero-padding.  For example, \"%.3Y\" will
 333 return something of the form \"001 year\".
 334
 335 The \"%z\" specifier does not print anything.  When it is used, specifiers
 336 must be given in order of decreasing size.  To the left of \"%z\", nothing
 337 is output until the first non-zero unit is encountered.
 338
 339 This function does not work for SECONDS greater than `most-positive-fixnum'."
 340   (let ((start 0)
 341         (units '(("y" "year"   31536000)
 342                  ("d" "day"       86400)
 343                  ("h" "hour"       3600)
 344                  ("m" "minute"       60)
 345                  ("s" "second"        1)
 346                  ("z")))
 347         (case-fold-search t)
 348         spec match usedunits zeroflag larger prev name unit num zeropos)
 349     (while (string-match "%\\.?[0-9]*\\(.\\)" string start)
 350       (setq start (match-end 0)
 351             spec (match-string 1 string))
 352       (unless (string-equal spec "%")
 353         (or (setq match (assoc (downcase spec) units))
 354             (error "Bad format specifier: `%s'" spec))
 355         (if (assoc (downcase spec) usedunits)
 356             (error "Multiple instances of specifier: `%s'" spec))
 357         (if (string-equal (car match) "z")
 358             (setq zeroflag t)
 359           (unless larger
 360             (setq unit (nth 2 match)
 361                   larger (and prev (> unit prev))
 362                   prev unit)))
 363         (push match usedunits)))
 364     (and zeroflag larger
 365          (error "Units are not in decreasing order of size"))
 366     (dolist (u units)
 367       (setq spec (car u)
 368             name (cadr u)
 369             unit (nth 2 u))
 370       (when (string-match (format "%%\\(\\.?[0-9]+\\)?\\(%s\\)" spec) string)
 371         (if (string-equal spec "z")     ; must be last in units
 372             (setq string
 373                   (replace-regexp-in-string
 374                    "%z" ""
 375                    (substring string (min (or zeropos (match-end 0))
 376                                           (match-beginning 0)))))
 377           ;; Cf article-make-date-line in gnus-art.
 378           (setq num (floor seconds unit)
 379                 seconds (- seconds (* num unit)))
 380           ;; Start position of the first non-zero unit.
 381           (or zeropos
 382               (setq zeropos (unless (zerop num) (match-beginning 0))))
 383           (setq string
 384                 (replace-match
 385                  (format (concat "%" (match-string 1 string) "d%s") num
 386                          (if (string-equal (match-string 2 string) spec)
 387                              ""       ; lower-case, no unit-name
 388                            (format " %s%s" name
 389                                    (if (= num 1) "" "s"))))
 390                  t t string))))))
 391   (replace-regexp-in-string "%%" "%" string))
 392
 393
 394 (provide 'time-date)
 395
 396 ;;; time-date.el ends here