configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 165
 166 ## For the times when you want to build Emacs but don't have
 167 ## a suitable makeinfo, and can live without the manuals.
 168 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 169 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 170
 171 dnl Can remove these in Emacs 24.
 172 AC_ARG_WITH([gtk],,
 173   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 174 specify a toolkit.])],,)
 175
 176 AC_ARG_WITH([gcc],,
 177   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 178 variable to specify a compiler.])],,)
 179
 180 AC_ARG_WITH([pkg-config-prog],dnl
 181 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 182                   [path to pkg-config for finding GTK and librsvg])])
 183 if test "X${with_pkg_config_prog}" != X; then
 184    if test "${with_pkg_config_prog}" != yes; then
 185       PKG_CONFIG="${with_pkg_config_prog}"
 186    fi
 187 fi
 188
 189 CRT_DIR=
 190 AC_ARG_WITH([crt-dir],dnl
 191 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 192 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 193 CRT_DIR="${with_crt_dir}"
 194
 195 AC_ARG_WITH([gnustep-conf],dnl
 196 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 197 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 198   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 199 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 200      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 201
 202 AC_ARG_ENABLE(ns-self-contained,
 203 [AS_HELP_STRING([--disable-ns-self-contained],
 204                 [disable self contained build under NeXTstep])],
 205    EN_NS_SELF_CONTAINED=$enableval,
 206    EN_NS_SELF_CONTAINED=yes)
 207
 208 AC_ARG_ENABLE(asserts,
 209 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 210       USE_XASSERTS=$enableval,
 211       USE_XASSERTS=no)
 212
 213 AC_ARG_ENABLE(maintainer-mode,
 214 [AS_HELP_STRING([--enable-maintainer-mode],
 215                 [enable make rules and dependencies not useful (and sometimes
 216                  confusing) to the casual installer])],
 217       USE_MAINTAINER_MODE=$enableval,
 218       USE_MAINTAINER_MODE=no)
 219 if test $USE_MAINTAINER_MODE = yes; then
 220   MAINT=
 221 else
 222   MAINT=#
 223 fi
 224 AC_SUBST(MAINT)
 225
 226 AC_ARG_ENABLE(locallisppath,
 227 [AS_HELP_STRING([--enable-locallisppath=PATH],
 228                 [directories Emacs should search for lisp files specific
 229                  to this site])],
 230 if test "${enableval}" = "no"; then
 231   locallisppath=
 232 elif test "${enableval}" != "yes"; then
 233   locallisppath=${enableval}
 234 fi)
 235
 236 AC_ARG_ENABLE(checking,
 237 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 238                 [enable expensive run-time checks.  With LIST,
 239                  enable only specific categories of checks.
 240                  Categories are: all,yes,no.
 241                  Flags are: stringbytes, stringoverrun, stringfreelist,
 242                  xmallocoverrun, conslist])],
 243 [ac_checking_flags="${enableval}"],[])
 244 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 245 for check in $ac_checking_flags
 246 do
 247         case $check in
 248         # these set all the flags to specific states
 249         yes)            ac_enable_checking=1 ;;
 250         no)             ac_enable_checking= ;
 251                         ac_gc_check_stringbytes= ;
 252                         ac_gc_check_string_overrun= ;
 253                         ac_gc_check_string_free_list= ;
 254                         ac_xmalloc_overrun= ;
 255                         ac_gc_check_cons_list= ;;
 256         all)            ac_enable_checking=1 ;
 257                         ac_gc_check_stringbytes=1 ;
 258                         ac_gc_check_string_overrun=1 ;
 259                         ac_gc_check_string_free_list=1 ;
 260                         ac_xmalloc_overrun=1 ;
 261                         ac_gc_check_cons_list=1 ;;
 262         # these enable particular checks
 263         stringbytes)    ac_gc_check_stringbytes=1 ;;
 264         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 265         stringfreelist) ac_gc_check_string_free_list=1 ;;
 266         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 267         conslist)       ac_gc_check_cons_list=1 ;;
 268         *)      AC_MSG_ERROR(unknown check category $check) ;;
 269         esac
 270 done
 271 IFS="$ac_save_IFS"
 272
 273 if test x$ac_enable_checking != x ; then
 274   AC_DEFINE(ENABLE_CHECKING, 1,
 275 [Enable expensive run-time checking of data types?])
 276 fi
 277 if test x$ac_gc_check_stringbytes != x ; then
 278   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 279 [Define this temporarily to hunt a bug.  If defined, the size of
 280    strings is redundantly recorded in sdata structures so that it can
 281    be compared to the sizes recorded in Lisp strings.])
 282 fi
 283 if test x$ac_gc_check_stringoverrun != x ; then
 284   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 285 [Define this to check for short string overrun.])
 286 fi
 287 if test x$ac_gc_check_string_free_list != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 289 [Define this to check the string free list.])
 290 fi
 291 if test x$ac_xmalloc_overrun != x ; then
 292   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 293 [Define this to check for malloc buffer overrun.])
 294 fi
 295 if test x$ac_gc_check_cons_list != x ; then
 296   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 297 [Define this to check for errors in cons list.])
 298 fi
 299
 300 AC_ARG_ENABLE(profiling,
 301 [AS_HELP_STRING([--enable-profiling],
 302                 [build emacs with profiling support.
 303                  This might not work on all platforms])],
 304 [ac_enable_profiling="${enableval}"],[])
 305 if test x$ac_enable_profiling != x ; then
 306    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 307    PROFILING_LDFLAGS="-pg"
 308 else
 309    PROFILING_CFLAGS=
 310    PROFILING_LDFLAGS=
 311 fi
 312
 313 AC_ARG_ENABLE(autodepend,
 314 [AS_HELP_STRING([--enable-autodepend],
 315                 [automatically generate dependencies to .h-files.
 316                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 317                  found])],
 318 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 319
 320 #### Make srcdir absolute, if it isn't already.  It's important to
 321 #### avoid running the path through pwd unnecessarily, since pwd can
 322 #### give you automounter prefixes, which can go away.  We do all this
 323 #### so Emacs can find its files when run uninstalled.
 324 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 325 unset CDPATH
 326 case "${srcdir}" in
 327   /* ) ;;
 328   . )
 329     ## We may be able to use the $PWD environment variable to make this
 330     ## absolute.  But sometimes PWD is inaccurate.
 331     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 332     ## but that tested only for a well-formed and valid PWD,
 333     ## it did not object when PWD was well-formed and valid but just wrong.
 334     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 335     then
 336       srcdir="$PWD"
 337     else
 338       srcdir="`(cd ${srcdir}; pwd)`"
 339     fi
 340   ;;
 341   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 342 esac
 343
 344 #### Check if the source directory already has a configured system in it.
 345 if test `pwd` != `(cd ${srcdir} && pwd)` \
 346    && test -f "${srcdir}/src/config.h" ; then
 347   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 348    as a build directory right now; it has been configured in its own
 349    right.  To configure in another directory as well, you MUST
 350    use GNU make.  If you do not have GNU make, then you must
 351    now do `make distclean' in ${srcdir},
 352    and then run $0 again.]])
 353 fi
 354
 355 #### Given the configuration name, set machfile and opsysfile to the
 356 #### names of the m/*.h and s/*.h files we should use.
 357
 358 ### Canonicalize the configuration name.
 359
 360 AC_CANONICAL_HOST
 361 canonical=$host
 362 configuration=${host_alias-${build_alias-$host}}
 363
 364 dnl This used to use changequote, but, apart from `changequote is evil'
 365 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 366 dnl the great gob of text.  Thus it's not processed for possible expansion.
 367 dnl Just make sure the brackets remain balanced.
 368 dnl
 369 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 370 dnl indicated by comments.
 371 dnl quotation begins
 372 [
 373
 374 ### If you add support for a new configuration, add code to this
 375 ### switch statement to recognize your configuration name and select
 376 ### the appropriate operating system and machine description files.
 377
 378 ### You would hope that you could choose an m/*.h file pretty much
 379 ### based on the machine portion of the configuration name, and an s-
 380 ### file based on the operating system portion.  However, it turns out
 381 ### that each m/*.h file is pretty manufacturer-specific - for
 382 ### example mips.h is MIPS
 383 ### So we basically have to have a special case for each
 384 ### configuration name.
 385 ###
 386 ### As far as handling version numbers on operating systems is
 387 ### concerned, make sure things will fail in a fixable way.  If
 388 ### /etc/MACHINES doesn't say anything about version numbers, be
 389 ### prepared to handle anything reasonably.  If version numbers
 390 ### matter, be sure /etc/MACHINES says something about it.
 391 ###
 392 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 393 ### "System V Release 4"; he writes, "The old convention encouraged
 394 ### confusion between `system' and `release' levels'."
 395
 396 machine='' opsys='' unported=no
 397 case "${canonical}" in
 398
 399   ## FreeBSD ports
 400   *-*-freebsd* )
 401     opsys=freebsd
 402     case "${canonical}" in
 403       alpha*-*-freebsd*)        machine=alpha ;;
 404       arm*-*-freebsd*)          machine=arm ;;
 405       ia64-*-freebsd*)          machine=ia64 ;;
 406       sparc-*-freebsd*)         machine=sparc ;;
 407       sparc64-*-freebsd*)       machine=sparc ;;
 408       powerpc-*-freebsd*)       machine=macppc ;;
 409       i[3456]86-*-freebsd*)     machine=intel386 ;;
 410       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 411     esac
 412   ;;
 413
 414   ## FreeBSD kernel + glibc based userland
 415   *-*-kfreebsd*gnu* )
 416     opsys=gnu-kfreebsd
 417     case "${canonical}" in
 418       alpha*-*-kfreebsd*)       machine=alpha ;;
 419       ia64-*-kfreebsd*)         machine=ia64 ;;
 420       sparc-*-kfreebsd*)        machine=sparc ;;
 421       sparc64-*-kfreebsd*)      machine=sparc ;;
 422       powerpc-*-kfreebsd*)      machine=macppc ;;
 423       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 424       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## NetBSD ports
 429   *-*-netbsd* )
 430     opsys=netbsd
 431     if test -f /usr/lib/crti.o; then]
 432 dnl The close and open brackets here are because this section is quoted --
 433 dnl see the `changequote' comment above.
 434       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 435 [   fi
 436
 437     case "${canonical}" in
 438       alpha*-*-netbsd*) machine=alpha ;;
 439       i[3456]86-*-netbsd*) machine=intel386 ;;
 440       mips-*-netbsd*)   machine=mips ;;
 441       mipsel-*-netbsd*) machine=mips ;;
 442       mipseb-*-netbsd*) machine=mips ;;
 443       powerpc-*-netbsd*) machine=macppc ;;
 444       sparc*-*-netbsd*) machine=sparc ;;
 445       vax-*-netbsd*)    machine=vax ;;
 446       arm-*-netbsd*)    machine=arm ;;
 447       x86_64-*-netbsd*) machine=amdx86-64 ;;
 448       hppa-*-netbsd*)   machine=hp800 ;;
 449       m68k-*-netbsd*)   machine=m68k ;;
 450     esac
 451   ;;
 452
 453   ## OpenBSD ports
 454   *-*-openbsd* )
 455     opsys=openbsd
 456     case "${canonical}" in
 457       alpha*-*-openbsd*)        machine=alpha ;;
 458       arm-*-openbsd*)          machine=arm ;;
 459       i386-*-openbsd*)         machine=intel386 ;;
 460       powerpc-*-openbsd*)      machine=macppc ;;
 461       sparc*-*-openbsd*)       machine=sparc ;;
 462       vax-*-openbsd*)          machine=vax ;;
 463       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 464       hppa-*-openbsd*)         machine=hp800 ;;
 465     esac
 466   ;;
 467
 468   alpha*-*-linux-gnu* )
 469     machine=alpha opsys=gnu-linux
 470   ;;
 471
 472   arm*-*-linux-gnu* )
 473     machine=arm opsys=gnu-linux
 474   ;;
 475
 476   ## Apple Darwin / Mac OS X
 477   *-apple-darwin* )
 478     case "${canonical}" in
 479       i[3456]86-* )  machine=intel386 ;;
 480       powerpc-* )    machine=macppc ;;
 481       x86_64-* )     machine=amdx86-64 ;;
 482       * )            unported=yes ;;
 483     esac
 484     opsys=darwin
 485     # Define CPP as follows to make autoconf work correctly.
 486     CPP="${CC-cc} -E -no-cpp-precomp"
 487     # Use fink packages if available.
 488     if test -d /sw/include && test -d /sw/lib; then
 489       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 490       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 491       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 492     fi
 493   ;;
 494
 495   ## HP 9000 series 700 and 800, running HP/UX
 496   hppa*-hp-hpux10.2* )
 497     machine=hp800 opsys=hpux10-20
 498   ;;
 499   hppa*-hp-hpux1[1-9]* )
 500     machine=hp800 opsys=hpux11
 501     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 502   ;;
 503
 504   hppa*-*-linux-gnu* )
 505     machine=hp800 opsys=gnu-linux
 506   ;;
 507
 508   ## IBM machines
 509   s390-*-linux-gnu* )
 510     machine=ibms390 opsys=gnu-linux
 511   ;;
 512   s390x-*-linux-gnu* )
 513     machine=ibms390x opsys=gnu-linux
 514   ;;
 515   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527
 528   ## Macintosh PowerPC
 529   powerpc*-*-linux-gnu* )
 530     machine=macppc opsys=gnu-linux
 531   ;;
 532
 533   ## Silicon Graphics machines
 534   ## Iris 4D
 535   mips-sgi-irix6.5 )
 536     machine=iris4d opsys=irix6-5
 537     # Without defining _LANGUAGE_C, things get masked out in the headers
 538     # so that, for instance, grepping for `free' in stdlib.h fails and
 539     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 540     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 541     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 542   ;;
 543
 544   ## Suns
 545   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 546     machine=sparc opsys=gnu-linux
 547   ;;
 548
 549   *-sun-solaris* \
 550     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 551     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 552     case "${canonical}" in
 553       i[3456]86-*-* )     machine=intel386 ;;
 554       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 555       sparc* )          machine=sparc ;;
 556       * )               unported=yes ;;
 557     esac
 558     case "${canonical}" in
 559       *-sunos5.6* | *-solaris2.6* )
 560                 opsys=sol2-6
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 RANLIB="ar -ts"
 563                 ;;
 564       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 565                 opsys=sol2-6
 566                 emacs_check_sunpro_c=yes
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 ;;
 569       *-sunos5* | *-solaris* )
 570                 opsys=sol2-10
 571                 emacs_check_sunpro_c=yes
 572                 NON_GNU_CPP=/usr/ccs/lib/cpp
 573                 ;;
 574     esac
 575     ## Watch out for a compiler that we know will not work.
 576     case "${canonical}" in
 577      *-solaris* | *-sunos5* )
 578                 if [ "x$CC" = x/usr/ucb/cc ]; then
 579                   ## /usr/ucb/cc doesn't work;
 580                   ## we should find some other compiler that does work.
 581                   unset CC
 582                 fi
 583                 ;;
 584       *) ;;
 585     esac
 586   ;;
 587
 588   ## IA-64
 589   ia64*-*-linux* )
 590     machine=ia64 opsys=gnu-linux
 591   ;;
 592
 593   ## Intel 386 machines where we don't care about the manufacturer
 594   i[3456]86-*-* )
 595     machine=intel386
 596     case "${canonical}" in
 597       *-cygwin )                opsys=cygwin ;;
 598       *-darwin* )               opsys=darwin
 599                                 CPP="${CC-cc} -E -no-cpp-precomp"
 600                                 ;;
 601       *-linux-gnu* )            opsys=gnu-linux ;;
 602       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 604       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 606     esac
 607   ;;
 608
 609   ## m68k Linux-based GNU system
 610   m68k-*-linux-gnu* )
 611     machine=m68k opsys=gnu-linux
 612   ;;
 613
 614   ## Mips Linux-based GNU system
 615   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 616     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 617     machine=mips opsys=gnu-linux
 618   ;;
 619
 620   ## AMD x86-64 Linux-based GNU system
 621   x86_64-*-linux-gnu* )
 622     machine=amdx86-64 opsys=gnu-linux
 623   ;;
 624
 625   ## Tensilica Xtensa Linux-based GNU system
 626   xtensa*-*-linux-gnu* )
 627     machine=xtensa opsys=gnu-linux
 628     ;;
 629
 630   ## SuperH Linux-based GNU system
 631   sh[34]*-*-linux-gnu* )
 632     machine=sh3 opsys=gnu-linux
 633   ;;
 634
 635   * )
 636     unported=yes
 637   ;;
 638 esac
 639
 640 ### If the code above didn't choose an operating system, just choose
 641 ### an operating system based on the configuration name.  You really
 642 ### only want to use this when you have no idea what the right
 643 ### operating system is; if you know what operating systems a machine
 644 ### runs, it's cleaner to make it explicit in the case statement
 645 ### above.
 646 if test x"${opsys}" = x; then
 647   case "${canonical}" in
 648     *-gnu* )                            opsys=gnu ;;
 649     * )
 650       unported=yes
 651     ;;
 652   esac
 653 fi
 654
 655 ]
 656 dnl quotation ends
 657
 658 if test $unported = yes; then
 659   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 660 Check `etc/MACHINES' for recognized configuration names.])
 661 fi
 662
 663 machfile="m/${machine}.h"
 664 opsysfile="s/${opsys}.h"
 665
 666
 667 #### Choose a compiler.
 668 test -n "$CC" && cc_specified=yes
 669
 670 # Save the value of CFLAGS that the user specified.
 671 SPECIFIED_CFLAGS="$CFLAGS"
 672
 673 dnl Sets GCC=yes if using gcc.
 674 AC_PROG_CC
 675
 676 # On Suns, sometimes $CPP names a directory.
 677 if test -n "$CPP" && test -d "$CPP"; then
 678   CPP=
 679 fi
 680
 681 ## If not using gcc, and on Solaris, and no CPP specified, see if
 682 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 683 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 684  test x"$CPP" = x; then
 685   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 686   AC_CACHE_VAL(emacs_cv_sunpro_c,
 687   [AC_TRY_LINK([],
 688 [#ifndef __SUNPRO_C
 689 fail;
 690 #endif
 691 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 692   AC_MSG_RESULT($emacs_cv_sunpro_c)
 693
 694   if test x"$emacs_cv_sunpro_c" = xyes; then
 695     NON_GNU_CPP="$CC -E -Xs"
 696   fi
 697 fi
 698
 699 #### Some systems specify a CPP to use unless we are using GCC.
 700 #### Now that we know whether we are using GCC, we can decide whether
 701 #### to use that one.
 702 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 703 then
 704   CPP="$NON_GNU_CPP"
 705 fi
 706
 707 #### Some systems specify a CC to use unless we are using GCC.
 708 #### Now that we know whether we are using GCC, we can decide whether
 709 #### to use that one.
 710 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 711   test x$cc_specified != xyes
 712 then
 713   CC="$NON_GNU_CC"
 714 fi
 715
 716 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 717 then
 718   CC="$CC $GCC_TEST_OPTIONS"
 719 fi
 720
 721 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 722 then
 723   CC="$CC $NON_GCC_TEST_OPTIONS"
 724 fi
 725
 726 dnl checks for Unix variants
 727 AC_USE_SYSTEM_EXTENSIONS
 728
 729 ### Use -Wno-pointer-sign if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wno-pointer-sign"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 ### Use -Wdeclaration-after-statement if the compiler supports it
 743 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 744 SAVE_CFLAGS="$CFLAGS"
 745 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 746 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 747 if test $has_option = yes; then
 748    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 749 fi
 750 AC_MSG_RESULT($has_option)
 751 CFLAGS="$SAVE_CFLAGS"
 752 unset has_option
 753 unset SAVE_CFLAGS
 754
 755 #### Some other nice autoconf tests.
 756
 757 dnl checks for programs
 758 AC_PROG_LN_S
 759 AC_PROG_CPP
 760 AC_PROG_INSTALL
 761 if test "x$RANLIB" = x; then
 762   AC_PROG_RANLIB
 763 fi
 764 AC_PATH_PROG(INSTALL_INFO, install-info)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 766 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 767 dnl Don't use GZIP, which is used by gzip for additional parameters.
 768 AC_PATH_PROG(GZIP_PROG, gzip)
 769
 770
 771 ## Need makeinfo >= 4.6 (?) to build the manuals.
 772 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 773 dnl By this stage, configure has already checked for egrep and set EGREP,
 774 dnl or exited with an error if no egrep was found.
 775 if test "$MAKEINFO" != "no" && \
 776   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 777    MAKEINFO=no
 778 fi
 779
 780 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 781 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 782 ## therefore in the category of "special tools" not normally required, which
 783 ## configure does not have to check for (eg autoconf itself).
 784 ## In a Bazaar checkout on the other hand, the manuals are not included.
 785 ## So makeinfo is a requirement to build from Bazaar, and configure
 786 ## should test for it as it does for any other build requirement.
 787 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 788 ## with pre-built manuals, from a Bazaar checkout.
 789 if test "$MAKEINFO" = "no"; then
 790   if test "x${with_makeinfo}" = "xno"; then
 791     MAKEINFO=off
 792   elif test ! -e $srcdir/info/emacs; then
 793     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 794 source tree does not seem to have pre-built manuals in the `info' directory.
 795 Either install a suitable version of makeinfo, or re-run configure
 796 with the `--without-makeinfo' option to build without the manuals.] )
 797   fi
 798 fi
 799
 800 dnl Add our options to ac_link now, after it is set up.
 801
 802 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 803 then
 804   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 805 fi
 806
 807 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 808 then
 809   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 813 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 814 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 815 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 816 dnl if not built to support GNU ld.
 817
 818 late_LDFLAGS=$LDFLAGS
 819 if test "$GCC" = yes; then
 820   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 821 else
 822   LDFLAGS="$LDFLAGS -znocombreloc"
 823 fi
 824
 825 AC_MSG_CHECKING([for -znocombreloc])
 826 AC_LINK_IFELSE([main(){return 0;}],
 827   [AC_MSG_RESULT(yes)],
 828   LDFLAGS=$late_LDFLAGS
 829   [AC_MSG_RESULT(no)])
 830
 831 LIB_MATH=-lm
 832
 833 case $opsys in
 834   cygwin )
 835     LIB_MATH=
 836     ;;
 837   darwin )
 838     ## Adding -lm confuses the dynamic linker, so omit it.
 839     LIB_MATH=
 840     ;;
 841 esac
 842
 843 AC_SUBST(LIB_MATH)
 844
 845 #### Extract some information from the operating system and machine files.
 846
 847 AC_CHECKING([the machine- and system-dependent files to find out
 848  - which libraries the lib-src programs will want, and
 849  - whether the GNU malloc routines are usable])
 850
 851 ### First figure out CFLAGS (which we use for running the compiler here)
 852 ### and REAL_CFLAGS (which we use for real compilation).
 853 ### The two are the same except on a few systems, where they are made
 854 ### different to work around various lossages.  For example,
 855 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 856 ### as implying static linking.
 857
 858 ### If the CFLAGS env var is specified, we use that value
 859 ### instead of the default.
 860
 861 ### It's not important that this name contain the PID; you can't run
 862 ### two configures in the same directory and have anything work
 863 ### anyway.
 864 tempcname="conftest.c"
 865
 866 echo '
 867 #include "'${srcdir}'/src/'${opsysfile}'"
 868 #include "'${srcdir}'/src/'${machfile}'"
 869 #ifndef LIBS_SYSTEM
 870 #define LIBS_SYSTEM
 871 #endif
 872 #ifndef C_SWITCH_SYSTEM
 873 #define C_SWITCH_SYSTEM
 874 #endif
 875 #ifndef C_SWITCH_MACHINE
 876 #define C_SWITCH_MACHINE
 877 #endif
 878 configure___ libsrc_libs=LIBS_SYSTEM
 879 configure___ c_switch_system=C_SWITCH_SYSTEM
 880 configure___ c_switch_machine=C_SWITCH_MACHINE
 881
 882 configure___ LIBX=-lX11
 883
 884 configure___ unexec=UNEXEC
 885
 886 #ifdef SYSTEM_MALLOC
 887 configure___ system_malloc=yes
 888 #else
 889 configure___ system_malloc=no
 890 #endif
 891
 892 #ifdef USE_MMAP_FOR_BUFFERS
 893 configure___ use_mmap_for_buffers=yes
 894 #else
 895 configure___ use_mmap_for_buffers=no
 896 #endif
 897
 898 #ifndef C_OPTIMIZE_SWITCH
 899 #ifdef __GNUC__
 900 #define C_OPTIMIZE_SWITCH -O2
 901 #else
 902 #define C_OPTIMIZE_SWITCH -O
 903 #endif
 904 #endif
 905
 906 #ifndef C_WARNINGS_SWITCH
 907 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 908 #endif
 909
 910 #ifndef LD_SWITCH_MACHINE
 911 #define LD_SWITCH_MACHINE
 912 #endif
 913
 914 #ifndef LD_SWITCH_SYSTEM
 915 #define LD_SWITCH_SYSTEM
 916 #endif
 917
 918 #ifndef LD_SWITCH_X_SITE_AUX
 919 #define LD_SWITCH_X_SITE_AUX
 920 #endif
 921
 922 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 923 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 924
 925 #ifdef THIS_IS_CONFIGURE
 926
 927 /* Get the CFLAGS for tests in configure.  */
 928 #ifdef __GNUC__
 929 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 930 #else
 931 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 932 #endif
 933
 934 #else /* not THIS_IS_CONFIGURE */
 935
 936 /* Get the CFLAGS for real compilation.  */
 937 #ifdef __GNUC__
 938 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 939 #else
 940 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 941 #endif
 942
 943 #endif /* not THIS_IS_CONFIGURE */
 944 ' > ${tempcname}
 945
 946 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 947
 948 # The value of CPP is a quoted variable reference, so we need to do this
 949 # to get its actual value...
 950 CPP=`eval "echo $CPP"`
 951 [eval `${CPP} -Isrc ${tempcname} \
 952        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 953 if test "x$SPECIFIED_CFLAGS" = x; then
 954   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 955          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 956 else
 957   REAL_CFLAGS="$CFLAGS"
 958 fi]
 959 rm ${tempcname}
 960
 961 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 962
 963 ### Make sure subsequent tests use flags consistent with the build flags.
 964
 965 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 966   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 967 else
 968   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 969 fi
 970
 971 dnl For AC_FUNC_GETLOADAVG, at least:
 972 AC_CONFIG_LIBOBJ_DIR(src)
 973
 974 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 975 AC_SYS_LARGEFILE
 976
 977
 978 ## If user specified a crt-dir, use that unconditionally.
 979 if test "X$CRT_DIR" = "X"; then
 980
 981   case "$canonical" in
 982     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
 983     ## On x86-64 and s390x GNU/Linux distributions, the standard library
 984     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
 985     ## For anything else (eg /usr/lib32), it is up the user to specify
 986     ## the location (bug#5655).
 987     ## Test for crtn.o, not just the directory, because sometimes the
 988     ## directory exists but does not have the relevant files (bug#1287).
 989     ## FIXME better to test for binary compatibility somehow.
 990     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
 991     ;;
 992
 993     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
 994   esac
 995
 996   case "$opsys" in
 997     hpux10-20) CRT_DIR=/lib ;;
 998   esac
 999
1000   ## Default is /usr/lib.
1001   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1002
1003 else
1004
1005   ## Some platforms don't use any of these files, so it is not
1006   ## appropriate to put this test outside the if block.
1007   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1008     AC_MSG_ERROR([crt*.o not found in specified location.])
1009
1010 fi
1011
1012 AC_SUBST(CRT_DIR)
1013
1014
1015 dnl This function defintion taken from Gnome 2.0
1016 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1017 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1018 dnl also defines GSTUFF_PKG_ERRORS on error
1019 AC_DEFUN([PKG_CHECK_MODULES], [
1020   succeeded=no
1021
1022   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1023
1024   if test "$PKG_CONFIG" = "no" ; then
1025      ifelse([$4], , [AC_MSG_ERROR([
1026       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1027   else
1028      PKG_CONFIG_MIN_VERSION=0.9.0
1029      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1030         AC_MSG_CHECKING(for $2)
1031
1032         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1033             AC_MSG_RESULT(yes)
1034             succeeded=yes
1035
1036             AC_MSG_CHECKING($1_CFLAGS)
1037             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1038             AC_MSG_RESULT($$1_CFLAGS)
1039
1040             AC_MSG_CHECKING($1_LIBS)
1041             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1042             AC_MSG_RESULT($$1_LIBS)
1043         else
1044             AC_MSG_RESULT(no)
1045             $1_CFLAGS=""
1046             $1_LIBS=""
1047             ## If we have a custom action on failure, don't print errors, but
1048             ## do set a variable so people can do so.
1049             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1050             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1051         fi
1052
1053         AC_SUBST($1_CFLAGS)
1054         AC_SUBST($1_LIBS)
1055      else
1056         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1057         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1058      fi
1059   fi
1060
1061   if test $succeeded = yes; then
1062      ifelse([$3], , :, [$3])
1063   else
1064      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1065   fi
1066 ])
1067
1068
1069 if test "${with_sound}" != "no"; then
1070   # Sound support for GNU/Linux and the free BSDs.
1071   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1072   # Emulation library used on NetBSD.
1073   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1074   AC_SUBST(LIBSOUND)
1075
1076   ALSA_REQUIRED=1.0.0
1077   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1078   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1079   if test $HAVE_ALSA = yes; then
1080     SAVE_CFLAGS="$CFLAGS"
1081     SAVE_LDFLAGS="$LDFLAGS"
1082     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1083     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1084     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1085                     emacs_alsa_normal=yes,
1086                     emacs_alsa_normal=no)
1087     if test "$emacs_alsa_normal" != yes; then
1088       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1089                      [snd_lib_error_set_handler (0);],
1090                      emacs_alsa_subdir=yes,
1091                      emacs_alsa_subdir=no)
1092       if test "$emacs_alsa_subdir" != yes; then
1093         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1094       fi
1095       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1096     fi
1097
1098     CFLAGS="$SAVE_CFLAGS"
1099     LDFLAGS="$SAVE_LDFLAGS"
1100     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1101     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1102     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1103   fi
1104   AC_SUBST(CFLAGS_SOUND)
1105 fi
1106
1107 dnl checks for header files
1108 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1109   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1110   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1111   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1112   sys/utsname.h pwd.h utmp.h)
1113
1114 AC_MSG_CHECKING(if personality LINUX32 can be set)
1115 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1116                emacs_cv_personality_linux32=yes,
1117                emacs_cv_personality_linux32=no)
1118 AC_MSG_RESULT($emacs_cv_personality_linux32)
1119
1120 if test $emacs_cv_personality_linux32 = yes; then
1121   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1122             [Define to 1 if personality LINUX32 can be set.])
1123 fi
1124
1125 dnl On Solaris 8 there's a compilation warning for term.h because
1126 dnl it doesn't define `bool'.
1127 AC_CHECK_HEADERS(term.h, , , -)
1128 AC_HEADER_STDC
1129 AC_HEADER_TIME
1130 AC_CHECK_DECLS([sys_siglist])
1131 if test $ac_cv_have_decl_sys_siglist != yes; then
1132   # For Tru64, at least:
1133   AC_CHECK_DECLS([__sys_siglist])
1134   if test $ac_cv_have_decl___sys_siglist = yes; then
1135     AC_DEFINE(sys_siglist, __sys_siglist,
1136               [Define to any substitute for sys_siglist.])
1137   fi
1138 fi
1139 AC_HEADER_SYS_WAIT
1140
1141 dnl Some systems have utime.h but don't declare the struct anyplace.
1142 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1143 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1144 #include <sys/time.h>
1145 #include <time.h>
1146 #else
1147 #ifdef HAVE_SYS_TIME_H
1148 #include <sys/time.h>
1149 #else
1150 #include <time.h>
1151 #endif
1152 #endif
1153 #ifdef HAVE_UTIME_H
1154 #include <utime.h>
1155 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1156   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1157 if test $emacs_cv_struct_utimbuf = yes; then
1158   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1159 fi
1160
1161 dnl checks for typedefs
1162 AC_TYPE_SIGNAL
1163
1164 dnl Check for speed_t typedef.
1165 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1166   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1167     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1168 if test $emacs_cv_speed_t = yes; then
1169   AC_DEFINE(HAVE_SPEED_T, 1,
1170            [Define to 1 if `speed_t' is declared by <termios.h>.])
1171 fi
1172
1173 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1174 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1175 #include <sys/time.h>
1176 #include <time.h>
1177 #else
1178 #ifdef HAVE_SYS_TIME_H
1179 #include <sys/time.h>
1180 #else
1181 #include <time.h>
1182 #endif
1183 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1184   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1185 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1186 if test $emacs_cv_struct_timeval = yes; then
1187   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1188 fi
1189
1190 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1191 AC_TRY_COMPILE([#include <math.h>],
1192 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1193   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1194 HAVE_EXCEPTION=$emacs_cv_struct_exception
1195 if test $emacs_cv_struct_exception != yes; then
1196   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1197 fi
1198
1199 AC_CHECK_HEADERS(sys/socket.h)
1200 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1201 #if HAVE_SYS_SOCKET_H
1202 #include <sys/socket.h>
1203 #endif])
1204
1205 dnl checks for structure members
1206 AC_STRUCT_TM
1207 AC_STRUCT_TIMEZONE
1208 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1209                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1210                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1211                 [#include <time.h>])
1212 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1213                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1214                   struct ifreq.ifr_addr], , ,
1215                  [AC_INCLUDES_DEFAULT
1216 #if HAVE_SYS_SOCKET_H
1217 #include <sys/socket.h>
1218 #endif
1219 #if HAVE_NET_IF_H
1220 #include <net/if.h>
1221 #endif])
1222
1223 dnl checks for compiler characteristics
1224
1225 dnl Testing __STDC__ to determine prototype support isn't good enough.
1226 dnl DEC C, for instance, doesn't define it with default options, and
1227 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1228 dnl and void *.
1229 AC_C_PROTOTYPES
1230 AC_C_VOLATILE
1231 AC_C_CONST
1232 dnl This isn't useful because we can't turn on use of `inline' unless
1233 dnl the compiler groks `extern inline'.
1234 dnl AC_C_INLINE
1235 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1236   [AC_TRY_COMPILE(, [void * foo;],
1237                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1238 if test $emacs_cv_void_star = yes; then
1239   AC_DEFINE(POINTER_TYPE, void)
1240 else
1241   AC_DEFINE(POINTER_TYPE, char)
1242 fi
1243 AH_TEMPLATE(POINTER_TYPE,
1244             [Define as `void' if your compiler accepts `void *'; otherwise
1245              define as `char'.])dnl
1246
1247
1248
1249 dnl This could be used for targets which can have both byte sexes.
1250 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1251 dnl AC_C_BIGENDIAN
1252
1253 dnl check for Make feature
1254 AC_PROG_MAKE_SET
1255
1256 dnl check for GNU Make if we have GCC and autodepend is on.
1257 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1258    AC_MSG_CHECKING([whether we are using GNU Make])
1259    HAVE_GNU_MAKE=no
1260    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1261    if test "x$testval" != x; then
1262       HAVE_GNU_MAKE=yes
1263    else
1264       ac_enable_autodepend=no
1265    fi
1266    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1267    if test $HAVE_GNU_MAKE = yes; then
1268       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1269       SAVE_CFLAGS="$CFLAGS"
1270       CFLAGS="$CFLAGS -MMD -MF deps.d"
1271       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1272       CFLAGS="$SAVE_CFLAGS"
1273       test -f deps.d || ac_enable_autodepend=no
1274       rm -rf deps.d
1275       AC_MSG_RESULT([$ac_enable_autodepend])
1276    fi
1277    if test $ac_enable_autodepend = yes; then
1278       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1279    fi
1280 fi
1281
1282 dnl checks for operating system services
1283 AC_SYS_LONG_FILE_NAMES
1284
1285 #### Choose a window system.
1286
1287 AC_PATH_X
1288 if test "$no_x" = yes; then
1289   window_system=none
1290 else
1291   window_system=x11
1292 fi
1293
1294 ## Workaround for bug in autoconf <= 2.62.
1295 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1296 ## No need to do anything special for these standard directories.
1297 ## This is an experiment, take it out if it causes problems.
1298 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1299
1300    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1301
1302 fi
1303
1304 if test "${x_libraries}" != NONE; then
1305   if test -n "${x_libraries}"; then
1306     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1307     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1308   fi
1309   x_default_search_path=""
1310   x_search_path=${x_libraries}
1311   if test -z "${x_search_path}"; then
1312     x_search_path=/usr/lib
1313   fi
1314   for x_library in `echo ${x_search_path}: | \
1315                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1316     x_search_path="\
1317 ${x_library}/X11/%L/%T/%N%C%S:\
1318 ${x_library}/X11/%l/%T/%N%C%S:\
1319 ${x_library}/X11/%T/%N%C%S:\
1320 ${x_library}/X11/%L/%T/%N%S:\
1321 ${x_library}/X11/%l/%T/%N%S:\
1322 ${x_library}/X11/%T/%N%S"
1323     if test x"${x_default_search_path}" = x; then
1324       x_default_search_path=${x_search_path}
1325     else
1326       x_default_search_path="${x_search_path}:${x_default_search_path}"
1327     fi
1328   done
1329 fi
1330 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1331   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1332 fi
1333
1334 if test x"${x_includes}" = x; then
1335   bitmapdir=/usr/include/X11/bitmaps
1336 else
1337   # accumulate include directories that have X11 bitmap subdirectories
1338   bmd_acc="dummyval"
1339   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1340     if test -d "${bmd}/X11/bitmaps"; then
1341       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1342     fi
1343     if test -d "${bmd}/bitmaps"; then
1344       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1345     fi
1346   done
1347   if test ${bmd_acc} != "dummyval"; then
1348     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1349   fi
1350 fi
1351
1352 HAVE_NS=no
1353 NS_IMPL_COCOA=no
1354 NS_IMPL_GNUSTEP=no
1355 tmp_CPPFLAGS="$CPPFLAGS"
1356 tmp_CFLAGS="$CFLAGS"
1357 CPPFLAGS="$CPPFLAGS -x objective-c"
1358 CFLAGS="$CFLAGS -x objective-c"
1359 if test "${with_ns}" != no; then
1360   if test "${opsys}" = darwin; then
1361      NS_IMPL_COCOA=yes
1362      ns_appdir=`pwd`/nextstep/Emacs.app
1363      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1364      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1365      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1366   elif test -f $GNUSTEP_CONFIG_FILE; then
1367      NS_IMPL_GNUSTEP=yes
1368      ns_appdir=`pwd`/nextstep/Emacs.app
1369      ns_appbindir=`pwd`/nextstep/Emacs.app
1370      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1371      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1372      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1373      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1374      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1375      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1376      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1377      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1378      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1379      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1380   fi
1381   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1382                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1383   files are missing or cannot be compiled.])])
1384   NS_HAVE_NSINTEGER=yes
1385   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1386                                      [NSInteger i;])],
1387                     ns_have_nsinteger=yes,
1388                     ns_have_nsinteger=no)
1389   if test $ns_have_nsinteger = no; then
1390     NS_HAVE_NSINTEGER=no
1391   fi
1392 fi
1393 if test "${HAVE_NS}" = yes; then
1394   window_system=nextstep
1395   with_xft=no
1396   # set up packaging dirs
1397   exec_prefix=${ns_appbindir}
1398   libexecdir=${ns_appbindir}/libexec
1399   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1400      prefix=${ns_appresdir}
1401   fi
1402 fi
1403 CFLAGS="$tmp_CFLAGS"
1404 CPPFLAGS="$tmp_CPPFLAGS"
1405
1406 case "${window_system}" in
1407   x11 )
1408     HAVE_X_WINDOWS=yes
1409     HAVE_X11=yes
1410     case "${with_x_toolkit}" in
1411       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1412       motif ) USE_X_TOOLKIT=MOTIF ;;
1413       gtk ) with_gtk=yes
1414 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1415 dnl USE_X_TOOLKIT is set.
1416             USE_X_TOOLKIT=none ;;
1417       no ) USE_X_TOOLKIT=none ;;
1418 dnl If user did not say whether to use a toolkit, make this decision later:
1419 dnl use the toolkit if we have gtk, or X11R5 or newer.
1420       * ) USE_X_TOOLKIT=maybe ;;
1421     esac
1422   ;;
1423   nextstep | none )
1424     HAVE_X_WINDOWS=no
1425     HAVE_X11=no
1426     USE_X_TOOLKIT=none
1427   ;;
1428 esac
1429
1430 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1431    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1432    if test "$HAVE_XSERVER" = true ||
1433       test -n "$DISPLAY" ||
1434       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1435         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1436 were found.  You should install the relevant development files for X
1437 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1438 sure you have development files for image handling, i.e.
1439 tiff, gif, jpeg, png and xpm.
1440 If you are sure you want Emacs compiled without X window support, pass
1441   --without-x
1442 to configure.])
1443    fi
1444 fi
1445
1446 ### If we're using X11, we should use the X menu package.
1447 HAVE_MENUS=no
1448 case ${HAVE_X11} in
1449   yes ) HAVE_MENUS=yes ;;
1450 esac
1451
1452 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1453 # Assume not, until told otherwise.
1454 GNU_MALLOC=yes
1455 doug_lea_malloc=yes
1456 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1457 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1458 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1459                emacs_cv_var___after_morecore_hook,
1460 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1461   emacs_cv_var___after_morecore_hook=yes,
1462   emacs_cv_var___after_morecore_hook=no)])
1463 if test $emacs_cv_var___after_morecore_hook = no; then
1464   doug_lea_malloc=no
1465 fi
1466 if test "${system_malloc}" = "yes"; then
1467   GNU_MALLOC=no
1468   GNU_MALLOC_reason="
1469     (The GNU allocators don't work with this system configuration.)"
1470 fi
1471 if test "$doug_lea_malloc" = "yes" ; then
1472   if test "$GNU_MALLOC" = yes ; then
1473     GNU_MALLOC_reason="
1474       (Using Doug Lea's new malloc from the GNU C Library.)"
1475   fi
1476   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1477             [Define to 1 if you are using the GNU C Library.])
1478 fi
1479
1480 if test x"${REL_ALLOC}" = x; then
1481   REL_ALLOC=${GNU_MALLOC}
1482 fi
1483
1484 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1485 dnl the system configuration file (s/*.h) to turn the use of mmap
1486 dnl in the relocating allocator on.
1487
1488 AC_FUNC_MMAP
1489 if test $use_mmap_for_buffers = yes; then
1490   REL_ALLOC=no
1491 fi
1492
1493 LIBS="$libsrc_libs $LIBS"
1494
1495 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1496 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1497 AC_CHECK_LIB(dnet, dnet_ntoa)
1498 dnl This causes -lresolv to get used in subsequent tests,
1499 dnl which causes failures on some systems such as HPUX 9.
1500 dnl AC_CHECK_LIB(resolv, gethostbyname)
1501
1502 dnl FIXME replace main with a function we actually want from this library.
1503 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1504
1505 AC_CHECK_LIB(pthreads, cma_open)
1506
1507 dnl Check for need for bigtoc support on IBM AIX
1508
1509 case ${host_os} in
1510 aix*)
1511   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1512     case $GCC in
1513     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1514     *) gdb_cv_bigtoc=-bbigtoc ;;
1515     esac
1516
1517     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1518     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1519   ])
1520   ;;
1521 esac
1522
1523 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1524 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1525 # REAL_CPPFLAGS later on.
1526
1527 REAL_CPPFLAGS="$CPPFLAGS"
1528
1529 if test "${HAVE_X11}" = "yes"; then
1530   DEFS="$C_SWITCH_X_SITE $DEFS"
1531   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1532   LIBS="$LIBX $LIBS"
1533   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1534   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1535
1536   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1537   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1538   # but it's more convenient here to set LD_RUN_PATH
1539   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1540   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1541     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1542     export LD_RUN_PATH
1543   fi
1544
1545   if test "${opsys}" = "gnu-linux"; then
1546     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1547     AC_TRY_LINK([],
1548      [XOpenDisplay ("foo");],
1549      [xlinux_first_failure=no],
1550      [xlinux_first_failure=yes])
1551     if test "${xlinux_first_failure}" = "yes"; then
1552       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1553       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1554       OLD_CPPFLAGS="$CPPFLAGS"
1555       OLD_LIBS="$LIBS"
1556       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1557       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1558       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1559       LIBS="$LIBS -b i486-linuxaout"
1560       AC_TRY_LINK([],
1561        [XOpenDisplay ("foo");],
1562        [xlinux_second_failure=no],
1563        [xlinux_second_failure=yes])
1564       if test "${xlinux_second_failure}" = "yes"; then
1565         # If we get the same failure with -b, there is no use adding -b.
1566         # So take it out.  This plays safe.
1567         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1568         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1569         CPPFLAGS="$OLD_CPPFLAGS"
1570         LIBS="$OLD_LIBS"
1571         AC_MSG_RESULT(no)
1572       else
1573         AC_MSG_RESULT(yes)
1574       fi
1575     else
1576       AC_MSG_RESULT(no)
1577     fi
1578   fi
1579
1580   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1581   # header files included from there.
1582   AC_MSG_CHECKING(for Xkb)
1583   AC_TRY_LINK([#include <X11/Xlib.h>
1584 #include <X11/XKBlib.h>],
1585         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1586         emacs_xkb=yes, emacs_xkb=no)
1587   AC_MSG_RESULT($emacs_xkb)
1588   if test $emacs_xkb = yes; then
1589     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1590   fi
1591
1592   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1593 XScreenNumberOfScreen XSetWMProtocols)
1594 fi
1595
1596 if test "${window_system}" = "x11"; then
1597   AC_MSG_CHECKING(X11 version 6)
1598   AC_CACHE_VAL(emacs_cv_x11_version_6,
1599   [AC_TRY_LINK([#include <X11/Xlib.h>],
1600 [#if XlibSpecificationRelease < 6
1601 fail;
1602 #endif
1603 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1604   if test $emacs_cv_x11_version_6 = yes; then
1605     AC_MSG_RESULT(6 or newer)
1606     AC_DEFINE(HAVE_X11R6, 1,
1607               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1608   else
1609     AC_MSG_RESULT(before 6)
1610   fi
1611 fi
1612
1613
1614 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1615 HAVE_RSVG=no
1616 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1617   if test "${with_rsvg}" != "no"; then
1618     RSVG_REQUIRED=2.11.0
1619     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1620
1621     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1622     AC_SUBST(RSVG_CFLAGS)
1623     AC_SUBST(RSVG_LIBS)
1624
1625     if test ".${RSVG_CFLAGS}" != "."; then
1626       HAVE_RSVG=yes
1627       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1628       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1629       LIBS="$RSVG_LIBS $LIBS"
1630     fi
1631   fi
1632 fi
1633
1634
1635 HAVE_GTK=no
1636 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1637   GLIB_REQUIRED=2.6
1638   GTK_REQUIRED=2.6
1639   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1640
1641   dnl Checks for libraries.
1642   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1643   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1644      AC_MSG_ERROR($GTK_PKG_ERRORS)
1645   fi
1646 fi
1647
1648
1649 GTK_OBJ=
1650 if test x"$pkg_check_gtk" = xyes; then
1651
1652   AC_SUBST(GTK_CFLAGS)
1653   AC_SUBST(GTK_LIBS)
1654   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1655   CFLAGS="$CFLAGS $GTK_CFLAGS"
1656   LIBS="$GTK_LIBS $LIBS"
1657   dnl Try to compile a simple GTK program.
1658   GTK_COMPILES=no
1659   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1660   if test "${GTK_COMPILES}" != "yes"; then
1661     if test "$USE_X_TOOLKIT" != "maybe"; then
1662       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1663     fi
1664   else
1665     HAVE_GTK=yes
1666     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1667     GTK_OBJ=gtkutil.o
1668     USE_X_TOOLKIT=none
1669     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1670       :
1671     else
1672       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1673        closing open displays.  This is no problem if you just use
1674        one display, but if you use more than one and close one of them
1675        Emacs may crash.]])
1676       sleep 3
1677     fi
1678   fi
1679
1680 fi
1681 AC_SUBST(GTK_OBJ)
1682
1683
1684 if test "${HAVE_GTK}" = "yes"; then
1685
1686   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1687   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1688   if test "$with_toolkit_scroll_bars" != no; then
1689     with_toolkit_scroll_bars=yes
1690   fi
1691
1692   dnl  Check if we can use multiple displays with this GTK version.
1693   dnl  If gdk_display_open exists, assume all others are there also.
1694   HAVE_GTK_MULTIDISPLAY=no
1695   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1696   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1697     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1698               [Define to 1 if GTK can handle more than one display.])
1699   fi
1700
1701   dnl  Check if we have the old file selection dialog declared and
1702   dnl  in the link library.  In 2.x it may be in the library,
1703   dnl  but not declared if deprecated featured has been selected out.
1704   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1705   HAVE_GTK_FILE_SELECTION=no
1706   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1707                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1708 #include <gtk/gtk.h>])
1709   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1710     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1711                    HAVE_GTK_FILE_SELECTION=no)
1712   fi
1713
1714   dnl  Check if we have the new file chooser dialog
1715   HAVE_GTK_FILE_CHOOSER=no
1716   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1717                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1718 #include <gtk/gtk.h>])
1719   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1720     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1721                    HAVE_GTK_FILE_CHOOSER=no)
1722   fi
1723
1724   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1725      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1726     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1727               [Define to 1 if GTK has both file selection and chooser dialog.])
1728   fi
1729
1730   dnl Check if pthreads are available.  Emacs only needs this when using
1731   dnl gtk_file_chooser under Gnome.
1732   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1733     HAVE_GTK_AND_PTHREAD=no
1734     AC_CHECK_HEADERS(pthread.h)
1735     if test "$ac_cv_header_pthread_h"; then
1736       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1737     fi
1738     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1739       case "${canonical}" in
1740         *-hpux*) ;;
1741         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1742       esac
1743       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1744                [Define to 1 if you have GTK and pthread (-lpthread).])
1745     fi
1746   fi
1747 fi
1748
1749 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1750 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1751 dnl also not configured.
1752 HAVE_DBUS=no
1753 DBUS_OBJ=
1754 if test "${with_dbus}" = "yes"; then
1755    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1756    if test "$HAVE_DBUS" = yes; then
1757      LIBS="$LIBS $DBUS_LIBS"
1758      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1759      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1760      DBUS_OBJ=dbusbind.o
1761    fi
1762 fi
1763 AC_SUBST(DBUS_OBJ)
1764
1765 dnl GConf has been tested under GNU/Linux only.
1766 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1767 HAVE_GCONF=no
1768 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1769    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1770    if test "$HAVE_GCONF" = yes; then
1771       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1772    fi
1773 fi
1774
1775 dnl SELinux is available for GNU/Linux only.
1776 HAVE_LIBSELINUX=no
1777 LIBSELINUX_LIBS=
1778 if test "${with_selinux}" = "yes"; then
1779    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1780    if test "$HAVE_LIBSELINUX" = yes; then
1781       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1782       LIBSELINUX_LIBS=-lselinux
1783    fi
1784 fi
1785 AC_SUBST(LIBSELINUX_LIBS)
1786
1787 dnl Do not put whitespace before the #include statements below.
1788 dnl Older compilers (eg sunos4 cc) choke on it.
1789 HAVE_XAW3D=no
1790 LUCID_LIBW=
1791 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1792   if test "$with_xaw3d" != no; then
1793     AC_MSG_CHECKING(for xaw3d)
1794     AC_CACHE_VAL(emacs_cv_xaw3d,
1795     [AC_TRY_LINK([
1796 #include <X11/Intrinsic.h>
1797 #include <X11/Xaw3d/Simple.h>],
1798       [],
1799       emacs_cv_xaw3d=yes,
1800       emacs_cv_xaw3d=no)])
1801   else
1802     emacs_cv_xaw3d=no
1803   fi
1804   if test $emacs_cv_xaw3d = yes; then
1805     AC_MSG_RESULT([yes; using Lucid toolkit])
1806     USE_X_TOOLKIT=LUCID
1807     HAVE_XAW3D=yes
1808     LUCID_LIBW=-lXaw3d
1809     AC_DEFINE(HAVE_XAW3D, 1,
1810               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1811   else
1812     AC_MSG_RESULT(no)
1813     AC_MSG_CHECKING(for libXaw)
1814     AC_CACHE_VAL(emacs_cv_xaw,
1815     [AC_TRY_LINK([
1816 #include <X11/Intrinsic.h>
1817 #include <X11/Xaw/Simple.h>],
1818       [],
1819       emacs_cv_xaw=yes,
1820       emacs_cv_xaw=no)])
1821     if test $emacs_cv_xaw = yes; then
1822       AC_MSG_RESULT([yes; using Lucid toolkit])
1823       USE_X_TOOLKIT=LUCID
1824       LUCID_LIBW=-lXaw
1825     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1826       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1827     else
1828       AC_MSG_RESULT([no; do not use toolkit by default])
1829       USE_X_TOOLKIT=none
1830     fi
1831   fi
1832 fi
1833 AC_SUBST(LUCID_LIBW)
1834
1835 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1836
1837 if test "${USE_X_TOOLKIT}" != "none"; then
1838   AC_MSG_CHECKING(X11 toolkit version)
1839   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1840   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1841 [#if XtSpecificationRelease < 6
1842 fail;
1843 #endif
1844 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1845   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1846   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1847     AC_MSG_RESULT(6 or newer)
1848     AC_DEFINE(HAVE_X11XTR6, 1,
1849               [Define to 1 if you have the X11R6 or newer version of Xt.])
1850   else
1851     AC_MSG_RESULT(before 6)
1852   fi
1853
1854 dnl If using toolkit, check whether libXmu.a exists.
1855 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1856   OLDLIBS="$LIBS"
1857   if test x$HAVE_X11XTR6 = xyes; then
1858     LIBS="-lXt -lSM -lICE $LIBS"
1859   else
1860     LIBS="-lXt $LIBS"
1861   fi
1862   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1863   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1864 fi
1865
1866 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1867 if test "${HAVE_X11}" = "yes"; then
1868   if test "${USE_X_TOOLKIT}" != "none"; then
1869     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1870   fi
1871 fi
1872
1873 LIBXP=
1874 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1875   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1876   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1877     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1878 int x = 5;
1879 #else
1880 Motif version prior to 2.1.
1881 #endif],
1882     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1883   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1884   if test $emacs_cv_motif_version_2_1 = yes; then
1885     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
1886   else
1887     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1888     # We put this in CFLAGS temporarily to precede other -I options
1889     # that might be in CFLAGS temporarily.
1890     # We put this in CPPFLAGS where it precedes the other -I options.
1891     OLD_CPPFLAGS=$CPPFLAGS
1892     OLD_CFLAGS=$CFLAGS
1893     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1894     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1895     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1896       [int x = 5;],
1897       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1898     if test $emacs_cv_lesstif = yes; then
1899       # Make sure this -I option remains in CPPFLAGS after it is set
1900       # back to REAL_CPPFLAGS.
1901       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1902       # have those other -I options anyway.  Ultimately, having this
1903       # directory ultimately in CPPFLAGS will be enough.
1904       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1905       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1906     else
1907       CFLAGS=$OLD_CFLAGS
1908       CPPFLAGS=$OLD_CPPFLAGS
1909     fi
1910   fi
1911 fi
1912 AC_SUBST(LIBXP)
1913
1914 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1915 dnl using Motif or Xaw3d is available, and unless
1916 dnl --with-toolkit-scroll-bars=no was specified.
1917
1918 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1919             [Define to 1 if we should use toolkit scroll bars.])dnl
1920 USE_TOOLKIT_SCROLL_BARS=no
1921 if test "${with_toolkit_scroll_bars}" != "no"; then
1922   if test "${USE_X_TOOLKIT}" != "none"; then
1923     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1924       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1925       HAVE_XAW3D=no
1926       USE_TOOLKIT_SCROLL_BARS=yes
1927     elif test "${HAVE_XAW3D}" = "yes"; then
1928       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1929       USE_TOOLKIT_SCROLL_BARS=yes
1930     fi
1931   elif test "${HAVE_GTK}" = "yes"; then
1932     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1933     USE_TOOLKIT_SCROLL_BARS=yes
1934   elif test "${HAVE_NS}" = "yes"; then
1935     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1936     USE_TOOLKIT_SCROLL_BARS=yes
1937   fi
1938 fi
1939
1940 dnl See if XIM is available.
1941 AC_TRY_COMPILE([
1942           #include <X11/Xlib.h>
1943           #include <X11/Xresource.h>],
1944          [XIMProc  callback;],
1945          [HAVE_XIM=yes
1946          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1947          HAVE_XIM=no)
1948
1949 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1950
1951 if test "${with_xim}" != "no"; then
1952   AC_DEFINE(USE_XIM, 1,
1953             [Define to 1 if we should use XIM, if it is available.])
1954 fi
1955
1956
1957 if test "${HAVE_XIM}" != "no"; then
1958   late_CFLAGS=$CFLAGS
1959   if test "$GCC" = yes; then
1960     CFLAGS="$CFLAGS --pedantic-errors"
1961   fi
1962   AC_TRY_COMPILE([
1963 #include <X11/Xlib.h>
1964 #include <X11/Xresource.h>],
1965 [Display *display;
1966 XrmDatabase db;
1967 char *res_name;
1968 char *res_class;
1969 XIMProc  callback;
1970 XPointer *client_data;
1971 #ifndef __GNUC__
1972 /* If we're not using GCC, it's probably not XFree86, and this is
1973    probably right, but we can't use something like --pedantic-errors.  */
1974 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1975                                            char*, XIMProc, XPointer*);
1976 #endif
1977 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1978    client_data);],
1979     [emacs_cv_arg6_star=yes])
1980   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1981          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1982 either XPointer or XPointer*.])dnl
1983   if test "$emacs_cv_arg6_star" = yes; then
1984     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1985   else
1986     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1987   fi
1988   CFLAGS=$late_CFLAGS
1989 fi
1990
1991 ### Start of font-backend (under any platform) section.
1992 # (nothing here yet -- this is a placeholder)
1993 ### End of font-backend (under any platform) section.
1994
1995 ### Start of font-backend (under X11) section.
1996 if test "${HAVE_X11}" = "yes"; then
1997    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1998
1999    ## Use -lXft if available, unless `--with-xft=no'.
2000    HAVE_XFT=maybe
2001     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2002       with_xft="no";
2003     fi
2004     if test "x${with_xft}" != "xno"; then
2005
2006       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2007       ## Because xftfont.c uses XRenderQueryExtension, we also
2008       ## need to link to -lXrender.
2009       HAVE_XRENDER=no
2010       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2011       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2012         OLD_CPPFLAGS="$CPPFLAGS"
2013         OLD_CFLAGS="$CFLAGS"
2014         OLD_LIBS="$LIBS"
2015         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2016         CFLAGS="$CFLAGS $XFT_CFLAGS"
2017         XFT_LIBS="-lXrender $XFT_LIBS"
2018         LIBS="$XFT_LIBS $LIBS"
2019         AC_CHECK_HEADER(X11/Xft/Xft.h,
2020           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2021
2022         if test "${HAVE_XFT}" = "yes"; then
2023           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2024             AC_SUBST(XFT_LIBS)
2025           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2026         else
2027           CPPFLAGS="$OLD_CPPFLAGS"
2028           CFLAGS="$OLD_CFLAGS"
2029           LIBS="$OLD_LIBS"
2030         fi                        # "${HAVE_XFT}" = "yes"
2031       fi                          # "$HAVE_XFT" != no
2032     fi                            # "x${with_xft}" != "xno"
2033
2034     dnl For the "Does Emacs use" message at the end.
2035     if test "$HAVE_XFT" != "yes"; then
2036        HAVE_XFT=no
2037     fi
2038
2039
2040     HAVE_FREETYPE=no
2041     ## We used to allow building with FreeType and without Xft.
2042     ## However, the ftx font backend driver is not in good shape.
2043     if test "${HAVE_XFT}" = "yes"; then
2044       dnl As we use Xft, we anyway use freetype.
2045       dnl There's no need for additional CFLAGS and LIBS.
2046       HAVE_FREETYPE=yes
2047       FONTCONFIG_CFLAGS=
2048       FONTCONFIG_LIBS=
2049     fi
2050
2051     HAVE_LIBOTF=no
2052     if test "${HAVE_FREETYPE}" = "yes"; then
2053       AC_DEFINE(HAVE_FREETYPE, 1,
2054                 [Define to 1 if using the freetype and fontconfig libraries.])
2055       if test "${with_libotf}" != "no"; then
2056         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2057                           HAVE_LIBOTF=no)
2058         if test "$HAVE_LIBOTF" = "yes"; then
2059           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2060           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2061                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2062                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2063           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2064             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2065                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2066           fi
2067         fi
2068       fi
2069     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2070     dnl Does the new font backend require it, or can it work without it?
2071     fi
2072
2073     HAVE_M17N_FLT=no
2074     if test "${HAVE_LIBOTF}" = yes; then
2075       if test "${with_m17n_flt}" != "no"; then
2076         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2077         if test "$HAVE_M17N_FLT" = "yes"; then
2078           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2079         fi
2080       fi
2081     fi
2082 else
2083     HAVE_XFT=no
2084     HAVE_FREETYPE=no
2085     HAVE_LIBOTF=no
2086     HAVE_M17N_FLT=no
2087 fi
2088 ### End of font-backend (under X11) section.
2089
2090 AC_SUBST(FREETYPE_CFLAGS)
2091 AC_SUBST(FREETYPE_LIBS)
2092 AC_SUBST(FONTCONFIG_CFLAGS)
2093 AC_SUBST(FONTCONFIG_LIBS)
2094 AC_SUBST(LIBOTF_CFLAGS)
2095 AC_SUBST(LIBOTF_LIBS)
2096 AC_SUBST(M17N_FLT_CFLAGS)
2097 AC_SUBST(M17N_FLT_LIBS)
2098
2099 ### Use -lXpm if available, unless `--with-xpm=no'.
2100 HAVE_XPM=no
2101 LIBXPM=
2102 if test "${HAVE_X11}" = "yes"; then
2103   if test "${with_xpm}" != "no"; then
2104     AC_CHECK_HEADER(X11/xpm.h,
2105       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2106     if test "${HAVE_XPM}" = "yes"; then
2107       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2108       AC_EGREP_CPP(no_return_alloc_pixels,
2109       [#include "X11/xpm.h"
2110 #ifndef XpmReturnAllocPixels
2111 no_return_alloc_pixels
2112 #endif
2113       ], HAVE_XPM=no, HAVE_XPM=yes)
2114
2115       if test "${HAVE_XPM}" = "yes"; then
2116         AC_MSG_RESULT(yes)
2117       else
2118         AC_MSG_RESULT(no)
2119       fi
2120     fi
2121   fi
2122
2123   if test "${HAVE_XPM}" = "yes"; then
2124     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2125     LIBXPM=-lXpm
2126   fi
2127 fi
2128 AC_SUBST(LIBXPM)
2129
2130 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2131 HAVE_JPEG=no
2132 LIBJPEG=
2133 if test "${HAVE_X11}" = "yes"; then
2134   if test "${with_jpeg}" != "no"; then
2135     dnl Checking for jpeglib.h can lose because of a redefinition of
2136     dnl  HAVE_STDLIB_H.
2137     AC_CHECK_HEADER(jerror.h,
2138       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2139   fi
2140
2141   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2142   if test "${HAVE_JPEG}" = "yes"; then
2143     AC_DEFINE(HAVE_JPEG)
2144     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2145         [#include <jpeglib.h>
2146          version=JPEG_LIB_VERSION
2147 ],
2148         [AC_DEFINE(HAVE_JPEG)],
2149         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2150         HAVE_JPEG=no])
2151   fi
2152   if test "${HAVE_JPEG}" = "yes"; then
2153     LIBJPEG=-ljpeg
2154   fi
2155 fi
2156 AC_SUBST(LIBJPEG)
2157
2158 ### Use -lpng if available, unless `--with-png=no'.
2159 HAVE_PNG=no
2160 LIBPNG=
2161 if test "${HAVE_X11}" = "yes"; then
2162   if test "${with_png}" != "no"; then
2163     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2164     # in /usr/include/libpng.
2165     AC_CHECK_HEADERS(png.h libpng/png.h)
2166     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2167       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2168     fi
2169   fi
2170
2171   if test "${HAVE_PNG}" = "yes"; then
2172     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2173     LIBPNG="-lpng -lz -lm"
2174   fi
2175 fi
2176 AC_SUBST(LIBPNG)
2177
2178 ### Use -ltiff if available, unless `--with-tiff=no'.
2179 HAVE_TIFF=no
2180 LIBTIFF=
2181 if test "${HAVE_X11}" = "yes"; then
2182   if test "${with_tiff}" != "no"; then
2183     AC_CHECK_HEADER(tiffio.h,
2184       [tifflibs="-lz -lm"
2185       # At least one tiff package requires the jpeg library.
2186       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2187       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2188   fi
2189
2190   if test "${HAVE_TIFF}" = "yes"; then
2191     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2192     dnl FIXME -lz -lm, as per libpng?
2193     LIBTIFF=-ltiff
2194   fi
2195 fi
2196 AC_SUBST(LIBTIFF)
2197
2198 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2199 HAVE_GIF=no
2200 LIBGIF=
2201 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2202   AC_CHECK_HEADER(gif_lib.h,
2203 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2204 # Earlier versions can crash Emacs.
2205     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2206
2207   if test "$HAVE_GIF" = yes; then
2208     LIBGIF=-lgif
2209   elif test "$HAVE_GIF" = maybe; then
2210 # If gif_lib.h but no libgif, try libungif.
2211     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2212     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2213   fi
2214
2215   if test "${HAVE_GIF}" = "yes"; then
2216     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2217   fi
2218 fi
2219 AC_SUBST(LIBGIF)
2220
2221 dnl Check for required libraries.
2222 if test "${HAVE_X11}" = "yes"; then
2223   MISSING=""
2224   WITH_NO=""
2225   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2226     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2227   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2228     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2229   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2230     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2231   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2232     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2233   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2234     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2235
2236   if test "X${MISSING}" != X; then
2237     AC_MSG_ERROR([The following required libraries were not found:
2238     $MISSING
2239 Maybe some development libraries/packages are missing?
2240 If you don't want to link with them give
2241     $WITH_NO
2242 as options to configure])
2243   fi
2244 fi
2245
2246 ### Use -lgpm if available, unless `--with-gpm=no'.
2247 HAVE_GPM=no
2248 LIBGPM=
2249 if test "${with_gpm}" != "no"; then
2250   AC_CHECK_HEADER(gpm.h,
2251     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2252
2253   if test "${HAVE_GPM}" = "yes"; then
2254     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2255     LIBGPM=-lgpm
2256   fi
2257 fi
2258 AC_SUBST(LIBGPM)
2259
2260 dnl Check for malloc/malloc.h on darwin
2261 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2262
2263 ### Use NeXTstep API to implement GUI.
2264 if test "${HAVE_NS}" = "yes"; then
2265   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2266   if test "${NS_IMPL_COCOA}" = "yes"; then
2267     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2268     GNU_OBJC_CFLAGS=
2269   fi
2270   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2271     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2272     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2273   fi
2274   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2275     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2276   fi
2277   # We also have mouse menus.
2278   HAVE_MENUS=yes
2279   OTHER_FILES=ns-app
2280 fi
2281
2282
2283 ### Use session management (-lSM -lICE) if available
2284 HAVE_X_SM=no
2285 LIBXSM=
2286 if test "${HAVE_X11}" = "yes"; then
2287   AC_CHECK_HEADER(X11/SM/SMlib.h,
2288     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2289
2290   if test "${HAVE_X_SM}" = "yes"; then
2291     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2292     LIBXSM="-lSM -lICE"
2293     case "$LIBS" in
2294       *-lSM*) ;;
2295       *)      LIBS="$LIBXSM $LIBS" ;;
2296     esac
2297   fi
2298 fi
2299 AC_SUBST(LIBXSM)
2300
2301 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2302 AC_CACHE_CHECK(whether netdb declares h_errno,
2303                emacs_cv_netdb_declares_h_errno,
2304 [AC_TRY_LINK([#include <netdb.h>],
2305   [return h_errno;],
2306   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2307 if test $emacs_cv_netdb_declares_h_errno = yes; then
2308   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2309 fi
2310
2311 AC_FUNC_ALLOCA
2312
2313 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2314 dnl FIXME is there an autoconf test that does the right thing, without
2315 dnl needing to call A_M_E afterwards?
2316 if test x"$ac_cv_func_alloca_works" != xyes; then
2317    AC_MSG_ERROR( [a system implementation of alloca is required] )
2318 fi
2319
2320 # fmod, logb, and frexp are found in -lm on most systems.
2321 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2322 AC_CHECK_LIB(m, sqrt)
2323
2324 # Check for mail-locking functions in a "mail" library.  Probably this should
2325 # have the same check as for liblockfile below.
2326 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2327 if test $have_mail = yes; then
2328   LIBS_MAIL=-lmail
2329   LIBS="$LIBS_MAIL $LIBS"
2330   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2331 else
2332   LIBS_MAIL=
2333 fi
2334 dnl Debian, at least:
2335 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2336 if test $have_lockfile = yes; then
2337    LIBS_MAIL=-llockfile
2338    LIBS="$LIBS_MAIL $LIBS"
2339    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2340 else
2341 # If we have the shared liblockfile, assume we must use it for mail
2342 # locking (e.g. Debian).  If we couldn't link against liblockfile
2343 # (no liblockfile.a installed), ensure that we don't need to.
2344   dnl This works for files generally, not just executables.
2345   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2346   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2347                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2348   if test $ac_cv_prog_liblockfile = yes; then
2349     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2350 This probably means that movemail could lose mail.
2351 There may be a `development' package to install containing liblockfile.])
2352   fi
2353 fi
2354 AC_CHECK_FUNCS(touchlock)
2355 AC_CHECK_HEADERS(maillock.h)
2356 AC_SUBST(LIBS_MAIL)
2357
2358 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2359 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2360 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2361 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2362 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2363 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2364 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2365 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2366 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2367 cfmakeraw cfsetspeed)
2368
2369 AC_CHECK_HEADERS(sys/un.h)
2370
2371 AC_FUNC_MKTIME
2372 if test "$ac_cv_func_working_mktime" = no; then
2373   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2374 fi
2375
2376 AC_FUNC_GETLOADAVG
2377
2378 AC_FUNC_FSEEKO
2379
2380 # Configure getopt.
2381 m4_include([m4/getopt.m4])
2382 gl_GETOPT_IFELSE([
2383   gl_GETOPT_SUBSTITUTE_HEADER
2384   gl_PREREQ_GETOPT
2385   GETOPTOBJS='getopt.o getopt1.o'
2386 ])
2387 AC_SUBST(GETOPTOBJS)
2388
2389 AC_FUNC_GETPGRP
2390
2391 AC_FUNC_STRFTIME
2392
2393 # UNIX98 PTYs.
2394 AC_CHECK_FUNCS(grantpt)
2395
2396 # PTY-related GNU extensions.
2397 AC_CHECK_FUNCS(getpt)
2398
2399 # Check this now, so that we will NOT find the above functions in ncurses.
2400 # That is because we have not set up to link ncurses in lib-src.
2401 # It's better to believe a function is not available
2402 # than to expect to find it in ncurses.
2403 # Also we need tputs and frieds to be able to build at all.
2404 have_tputs_et_al=true
2405 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2406 if test "$have_tputs_et_al" != true; then
2407   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2408 Maybe some development libraries/packages are missing?  Try installing
2409 libncurses-dev(el), libterminfo-dev(el) or similar.])
2410 fi
2411 # Must define this when any termcap library is found.
2412 AC_DEFINE(HAVE_LIBNCURSES, 1,
2413           [Define to 1 if you have the `ncurses' library (-lncurses).])
2414
2415 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2416
2417 resolv=no
2418 AC_TRY_LINK([#include <netinet/in.h>
2419 #include <arpa/nameser.h>
2420 #include <resolv.h>],
2421     [return res_init();],
2422     have_res_init=yes, have_res_init=no)
2423 if test "$have_res_init" = no; then
2424   OLIBS="$LIBS"
2425   LIBS="$LIBS -lresolv"
2426   AC_MSG_CHECKING(for res_init with -lresolv)
2427   AC_TRY_LINK([#include <netinet/in.h>
2428 #include <arpa/nameser.h>
2429 #include <resolv.h>],
2430     [return res_init();],
2431     have_res_init=yes, have_res_init=no)
2432   AC_MSG_RESULT($have_res_init)
2433   if test "$have_res_init" = yes ; then
2434     resolv=yes
2435   fi
2436   LIBS="$OLIBS"
2437 fi
2438
2439 if test "$have_res_init" = yes; then
2440   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2441 fi
2442
2443 # Do we need the Hesiod library to provide the support routines?
2444 LIBHESIOD=
2445 if test "$with_hesiod" != no ; then
2446   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2447   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2448      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2449                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2450   if test "$resolv" = yes ; then
2451     RESOLVLIB=-lresolv
2452   else
2453     RESOLVLIB=
2454   fi
2455   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2456         hesiod=yes, :, $RESOLVLIB)])
2457
2458   if test x"$hesiod" = xyes; then
2459     AC_DEFINE(HAVE_LIBHESIOD, 1,
2460               [Define to 1 if you have the hesiod library (-lhesiod).])
2461     LIBHESIOD=-lhesiod
2462   fi
2463 fi
2464 AC_SUBST(LIBHESIOD)
2465
2466 # Do we need libresolv (due to res_init or Hesiod)?
2467 if test "$resolv" = yes ; then
2468   AC_DEFINE(HAVE_LIBRESOLV, 1,
2469             [Define to 1 if you have the resolv library (-lresolv).])
2470   LIBRESOLV=-lresolv
2471 else
2472   LIBRESOLV=
2473 fi
2474 AC_SUBST(LIBRESOLV)
2475
2476 # These tell us which Kerberos-related libraries to use.
2477 COM_ERRLIB=
2478 CRYPTOLIB=
2479 KRB5LIB=
2480 DESLIB=
2481 KRB4LIB=
2482
2483 if test "${with_kerberos}" != no; then
2484   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2485   if test $have_com_err = yes; then
2486     COM_ERRLIB=-lcom_err
2487     LIBS="$COM_ERRLIB $LIBS"
2488     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2489   fi
2490   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2491   if test $have_crypto = yes; then
2492     CRYPTOLIB=-lcrypto
2493     LIBS="$CRYPTOLIB $LIBS"
2494     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2495   fi
2496   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2497   if test $have_k5crypto = yes; then
2498     CRYPTOLIB=-lk5crypto
2499     LIBS="$CRYPTOLIB $LIBS"
2500     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2501   fi
2502   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2503   if test $have_krb5=yes; then
2504     KRB5LIB=-lkrb5
2505     LIBS="$KRB5LIB $LIBS"
2506     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2507   fi
2508   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2509   if test "${with_kerberos5}" = no; then
2510     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2511     if test $have_des425 = yes; then
2512       DESLIB=-ldes425
2513       LIBS="$DESLIB $LIBS"
2514       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2515     else
2516       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2517       if test $have_des = yes; then
2518         DESLIB=-ldes
2519         LIBS="$DESLIB $LIBS"
2520         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2521       fi
2522     fi
2523     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2524     if test $have_krb4 = yes; then
2525       KRB4LIB=-lkrb4
2526       LIBS="$KRB4LIB $LIBS"
2527       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2528     else
2529       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2530       if test $have_krb = yes; then
2531         KRB4LIB=-lkrb
2532         LIBS="$KRB4LIB $LIBS"
2533         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2534       fi
2535     fi
2536   fi
2537
2538   if test "${with_kerberos5}" != no; then
2539     AC_CHECK_HEADERS(krb5.h,
2540       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2541                         [#include <krb5.h>])])
2542   else
2543     AC_CHECK_HEADERS(des.h,,
2544                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2545                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2546     AC_CHECK_HEADERS(krb.h,,
2547                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2548                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2549   fi
2550   AC_CHECK_HEADERS(com_err.h)
2551 fi
2552
2553 AC_SUBST(COM_ERRLIB)
2554 AC_SUBST(CRYPTOLIB)
2555 AC_SUBST(KRB5LIB)
2556 AC_SUBST(DESLIB)
2557 AC_SUBST(KRB4LIB)
2558
2559 # Solaris requires -lintl if you want strerror (which calls dgettext)
2560 # to return localized messages.
2561 AC_CHECK_LIB(intl, dgettext)
2562
2563 AC_MSG_CHECKING(whether localtime caches TZ)
2564 AC_CACHE_VAL(emacs_cv_localtime_cache,
2565 [if test x$ac_cv_func_tzset = xyes; then
2566 AC_TRY_RUN([#include <time.h>
2567 extern char **environ;
2568 unset_TZ ()
2569 {
2570   char **from, **to;
2571   for (to = from = environ; (*to = *from); from++)
2572     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2573       to++;
2574 }
2575 char TZ_GMT0[] = "TZ=GMT0";
2576 char TZ_PST8[] = "TZ=PST8";
2577 main()
2578 {
2579   time_t now = time ((time_t *) 0);
2580   int hour_GMT0, hour_unset;
2581   if (putenv (TZ_GMT0) != 0)
2582     exit (1);
2583   hour_GMT0 = localtime (&now)->tm_hour;
2584   unset_TZ ();
2585   hour_unset = localtime (&now)->tm_hour;
2586   if (putenv (TZ_PST8) != 0)
2587     exit (1);
2588   if (localtime (&now)->tm_hour == hour_GMT0)
2589     exit (1);
2590   unset_TZ ();
2591   if (localtime (&now)->tm_hour != hour_unset)
2592     exit (1);
2593   exit (0);
2594 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2595 [# If we have tzset, assume the worst when cross-compiling.
2596 emacs_cv_localtime_cache=yes])
2597 else
2598         # If we lack tzset, report that localtime does not cache TZ,
2599         # since we can't invalidate the cache if we don't have tzset.
2600         emacs_cv_localtime_cache=no
2601 fi])dnl
2602 AC_MSG_RESULT($emacs_cv_localtime_cache)
2603 if test $emacs_cv_localtime_cache = yes; then
2604   AC_DEFINE(LOCALTIME_CACHE, 1,
2605             [Define to 1 if localtime caches TZ.])
2606 fi
2607
2608 if test "x$HAVE_TIMEVAL" = xyes; then
2609   AC_CHECK_FUNCS(gettimeofday)
2610   if test $ac_cv_func_gettimeofday = yes; then
2611     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2612                    emacs_cv_gettimeofday_two_arguments,
2613     [AC_TRY_COMPILE([
2614 #ifdef TIME_WITH_SYS_TIME
2615 #include <sys/time.h>
2616 #include <time.h>
2617 #else
2618 #ifdef HAVE_SYS_TIME_H
2619 #include <sys/time.h>
2620 #else
2621 #include <time.h>
2622 #endif
2623 #endif],
2624       [struct timeval time;
2625        gettimeofday (&time, 0);],
2626       emacs_cv_gettimeofday_two_arguments=yes,
2627       emacs_cv_gettimeofday_two_arguments=no)])
2628     if test $emacs_cv_gettimeofday_two_arguments = no; then
2629       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2630                 [Define to 1 if gettimeofday accepts only one argument.])
2631     fi
2632   fi
2633 fi
2634
2635 ok_so_far=yes
2636 AC_CHECK_FUNC(socket, , ok_so_far=no)
2637 if test $ok_so_far = yes; then
2638   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2639 fi
2640 if test $ok_so_far = yes; then
2641   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2642 fi
2643 if test $ok_so_far = yes; then
2644 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2645   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2646             [Define to 1 if you have inet sockets.])
2647 fi
2648
2649 AC_CHECK_HEADERS(sys/ioctl.h)
2650
2651 if test -f /usr/lpp/X11/bin/smt.exp; then
2652   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2653             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2654 fi
2655
2656 AC_MSG_CHECKING(whether system supports dynamic ptys)
2657 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2658   AC_MSG_RESULT(yes)
2659   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2660 else
2661   AC_MSG_RESULT(no)
2662 fi
2663
2664 AC_FUNC_FORK
2665
2666 dnl Adapted from Haible's version.
2667 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2668   [AC_TRY_LINK([#include <langinfo.h>],
2669     [char* cs = nl_langinfo(CODESET);],
2670     emacs_cv_langinfo_codeset=yes,
2671     emacs_cv_langinfo_codeset=no)
2672   ])
2673 if test $emacs_cv_langinfo_codeset = yes; then
2674   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2675     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2676 fi
2677
2678 AC_CHECK_TYPES(size_t)
2679
2680 AC_TYPE_MBSTATE_T
2681
2682 dnl Restrict could probably be used effectively other than in regex.c.
2683 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2684   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2685                   emacs_cv_c_restrict=yes,
2686                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2687                                   emacs_cv_c_restrict=__restrict,
2688                                   emacs_cv_c_restrict=no)])])
2689 case "$emacs_cv_c_restrict" in
2690   yes) emacs_restrict=restrict;;
2691   no) emacs_restrict="";;
2692   *) emacs_restrict="$emacs_cv_c_restrict";;
2693 esac
2694 if test "$emacs_restrict" != __restrict; then
2695   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2696     [Define to compiler's equivalent of C99 restrict keyword.
2697      Don't define if equivalent is `__restrict'.])
2698 fi
2699
2700 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2701   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2702                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2703 if test "$emacs_cv_c_restrict_arr" = yes; then
2704   AC_DEFINE(__restrict_arr, __restrict,
2705     [Define to compiler's equivalent of C99 restrict keyword in array
2706      declarations.  Define as empty for no equivalent.])
2707 fi
2708
2709 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2710 dnl how the tty code is related to POSIX and/or other versions of termios.
2711 dnl The following looks like a useful start.
2712 dnl
2713 dnl AC_SYS_POSIX_TERMIOS
2714 dnl if test $ac_cv_sys_posix_termios = yes; then
2715 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2716 dnl                                and macros for terminal control.])
2717 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2718 dnl fi
2719
2720 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2721
2722 # Set up the CFLAGS for real compilation, so we can substitute it.
2723 CFLAGS="$REAL_CFLAGS"
2724 CPPFLAGS="$REAL_CPPFLAGS"
2725
2726 #### Find out which version of Emacs this is.
2727 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2728          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2729 if test x"${version}" = x; then
2730   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2731 fi
2732 if test x"${version}" != x"$PACKAGE_VERSION"; then
2733   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2734 fi
2735
2736 ### Specify what sort of things we'll be editing into Makefile and config.h.
2737 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2738 AC_SUBST(version)
2739 AC_SUBST(configuration)
2740 AC_SUBST(canonical)
2741 AC_SUBST(srcdir)
2742 AC_SUBST(prefix)
2743 AC_SUBST(exec_prefix)
2744 AC_SUBST(bindir)
2745 AC_SUBST(datadir)
2746 AC_SUBST(sharedstatedir)
2747 AC_SUBST(libexecdir)
2748 AC_SUBST(mandir)
2749 AC_SUBST(infodir)
2750 AC_SUBST(lispdir)
2751 AC_SUBST(locallisppath)
2752 AC_SUBST(lisppath)
2753 AC_SUBST(x_default_search_path)
2754 AC_SUBST(etcdir)
2755 AC_SUBST(archlibdir)
2756 AC_SUBST(docdir)
2757 AC_SUBST(bitmapdir)
2758 AC_SUBST(gamedir)
2759 AC_SUBST(gameuser)
2760 AC_SUBST(c_switch_system)
2761 AC_SUBST(c_switch_machine)
2762 AC_SUBST(unexec)
2763 AC_SUBST(LD_SWITCH_X_SITE)
2764 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2765 AC_SUBST(C_SWITCH_X_SITE)
2766 AC_SUBST(CFLAGS)
2767 AC_SUBST(X_TOOLKIT_TYPE)
2768 AC_SUBST(machfile)
2769 AC_SUBST(opsysfile)
2770 AC_SUBST(GETLOADAVG_LIBS)
2771 AC_SUBST(ns_appdir)
2772 AC_SUBST(ns_appbindir)
2773 AC_SUBST(ns_appresdir)
2774 AC_SUBST(ns_appsrc)
2775 AC_SUBST(GNUSTEP_MAKEFILES)
2776 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2777 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2778 AC_SUBST(GNU_OBJC_CFLAGS)
2779 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2780 AC_SUBST(OTHER_FILES)
2781
2782 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2783                    [Define to the canonical Emacs configuration name.])
2784 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2785                    [Define to the options passed to configure.])
2786 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2787                    [Define to the used machine dependent file.])
2788 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2789                    [Define to the used os dependent file.])
2790 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2791 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2792  may need to deal with X Windows.  For instance, if you've defined
2793  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2794  your loader can find on its own, you might want to add "-L/..." or
2795  something similar.])
2796 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2797                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2798                     in case it's needed (for Solaris, for example).])
2799 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2800 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2801  may need to deal with X Windows.  For instance, if you've defined
2802  HAVE_X_WINDOWS above and your X include files aren't in a place
2803  that your compiler can find on its own, you might want to add
2804  "-I/..." or something similar.])
2805
2806 XMENU_OBJ=
2807 XOBJ=
2808 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2809   AC_DEFINE(HAVE_X_WINDOWS, 1,
2810             [Define to 1 if you want to use the X window system.])
2811   XMENU_OBJ=xmenu.o
2812   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
2813 fi
2814 AC_SUBST(XMENU_OBJ)
2815 AC_SUBST(XOBJ)
2816
2817 WIDGET_OBJ=
2818 if test "${USE_X_TOOLKIT}" != "none" ; then
2819   WIDGET_OBJ=widget.o
2820   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2821   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2822     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2823   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2824     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2825   fi
2826 fi
2827 AC_SUBST(WIDGET_OBJ)
2828 if test "${HAVE_X11}" = "yes" ; then
2829   AC_DEFINE(HAVE_X11, 1,
2830             [Define to 1 if you want to use version 11 of X windows.
2831              Otherwise, Emacs expects to use version 10.])
2832 fi
2833 if test "${HAVE_MENUS}" = "yes" ; then
2834   AC_DEFINE(HAVE_MENUS, 1,
2835             [Define to 1 if you have mouse menus.
2836              (This is automatic if you use X, but the option to specify it remains.)
2837              It is also defined with other window systems that support xmenu.c.])
2838 fi
2839 if test "${GNU_MALLOC}" = "yes" ; then
2840   AC_DEFINE(GNU_MALLOC, 1,
2841             [Define to 1 if you want to use the GNU memory allocator.])
2842 fi
2843 if test "${REL_ALLOC}" = "yes" ; then
2844   AC_DEFINE(REL_ALLOC, 1,
2845             [Define REL_ALLOC if you want to use the relocating allocator for
2846              buffer space.])
2847 fi
2848
2849
2850 AH_TOP([/* GNU Emacs site configuration template file.
2851    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2852      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2853
2854 This file is part of GNU Emacs.
2855
2856 GNU Emacs is free software: you can redistribute it and/or modify
2857 it under the terms of the GNU General Public License as published by
2858 the Free Software Foundation, either version 3 of the License, or
2859 (at your option) any later version.
2860
2861 GNU Emacs is distributed in the hope that it will be useful,
2862 but WITHOUT ANY WARRANTY; without even the implied warranty of
2863 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2864 GNU General Public License for more details.
2865
2866 You should have received a copy of the GNU General Public License
2867 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2868
2869
2870 /* No code in Emacs #includes config.h twice, but some bits of code
2871    intended to work with other packages as well (like gmalloc.c)
2872    think they can include it as many times as they like.  */
2873 #ifndef EMACS_CONFIG_H
2874 #define EMACS_CONFIG_H
2875 ])dnl
2876
2877 AH_BOTTOM([
2878 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2879 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2880 #define HAVE_WINDOW_SYSTEM
2881 #define HAVE_MOUSE
2882 #endif
2883
2884 /* Define AMPERSAND_FULL_NAME if you use the convention
2885    that & in the full name stands for the login id.  */
2886 /* Turned on June 1996 supposing nobody will mind it.  */
2887 #define AMPERSAND_FULL_NAME
2888
2889 /* Define HAVE_SOUND if we have sound support.  We know it works
2890    and compiles only on the specified platforms.   For others,
2891    it probably doesn't make sense to try.  */
2892
2893 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2894 #ifdef HAVE_MACHINE_SOUNDCARD_H
2895 #define HAVE_SOUND 1
2896 #endif
2897 #ifdef HAVE_SYS_SOUNDCARD_H
2898 #define HAVE_SOUND 1
2899 #endif
2900 #ifdef HAVE_SOUNDCARD_H
2901 #define HAVE_SOUND 1
2902 #endif
2903 #ifdef HAVE_ALSA
2904 #define HAVE_SOUND 1
2905 #endif
2906 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2907
2908 /* If using GNU, then support inline function declarations. */
2909 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2910    generally, because even if non-gcc compilers accept `inline', they
2911    may reject `extern inline'.  */
2912 #if defined (__GNUC__) && defined (OPTIMIZE)
2913 #define INLINE __inline__
2914 #else
2915 #define INLINE
2916 #endif
2917
2918 /* `subprocesses' should be defined if you want to
2919    have code for asynchronous subprocesses
2920    (as used in M-x compile and M-x shell).
2921    Only MSDOS does not support this (it overrides
2922    this in its config_opsysfile below).  */
2923
2924 #define subprocesses
2925
2926 /* Include the os and machine dependent files.  */
2927 #include config_opsysfile
2928 #include config_machfile
2929
2930 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2931   (There is probably a better place to do this, but right now the Cocoa
2932    side does this in s/darwin.h and we cannot
2933    parallel this exactly since GNUstep is multi-OS. */
2934 #ifdef HAVE_NS
2935 # ifdef NS_IMPL_GNUSTEP
2936 /* See also .m.o rule in Makefile.in */
2937 /* FIXME: are all these flags really needed?  Document here why.  */
2938 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2939 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2940 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2941 #  define SYSTEM_PURESIZE_EXTRA 30000
2942 # endif /* NS_IMPL_GNUSTEP */
2943 #endif /* HAVE_NS */
2944
2945 /* SIGTYPE is the macro we actually use.  */
2946 #ifndef SIGTYPE
2947 #define SIGTYPE RETSIGTYPE
2948 #endif
2949
2950 #ifdef emacs /* Don't do this for lib-src.  */
2951 /* Tell regex.c to use a type compatible with Emacs.  */
2952 #define RE_TRANSLATE_TYPE Lisp_Object
2953 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2954 #ifdef make_number
2955 /* If make_number is a macro, use it.  */
2956 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2957 #else
2958 /* If make_number is a function, avoid it.  */
2959 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2960 #endif
2961 #endif
2962
2963 /* Avoid link-time collision with system mktime if we will use our own.  */
2964 #if ! HAVE_MKTIME || BROKEN_MKTIME
2965 #define mktime emacs_mktime
2966 #endif
2967
2968 #define my_strftime nstrftime   /* for strftime.c */
2969
2970 /* The rest of the code currently tests the CPP symbol BSTRING.
2971    Override any claims made by the system-description files.
2972    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2973 #undef BSTRING
2974 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2975 #define BSTRING
2976 #endif
2977
2978 /* Some of the files of Emacs which are intended for use with other
2979    programs assume that if you have a config.h file, you must declare
2980    the type of getenv.
2981
2982    This declaration shouldn't appear when alloca.s or Makefile.in
2983    includes config.h.  */
2984 #ifndef NOT_C_CODE
2985 extern char *getenv ();
2986 #endif
2987
2988 /* These default definitions are good for almost all machines.
2989    The exceptions override them in m/MACHINE.h.  */
2990
2991 #ifndef BITS_PER_CHAR
2992 #define BITS_PER_CHAR 8
2993 #endif
2994
2995 #ifndef BITS_PER_SHORT
2996 #define BITS_PER_SHORT 16
2997 #endif
2998
2999 /* Note that lisp.h uses this in a preprocessor conditional, so it
3000    would not work to use sizeof.  That being so, we do all of them
3001    without sizeof, for uniformity's sake.  */
3002 #ifndef BITS_PER_INT
3003 #define BITS_PER_INT 32
3004 #endif
3005
3006 #ifndef BITS_PER_LONG
3007 #ifdef _LP64
3008 #define BITS_PER_LONG 64
3009 #else
3010 #define BITS_PER_LONG 32
3011 #endif
3012 #endif
3013
3014 /* Define if the compiler supports function prototypes.  It may do so
3015    but not define __STDC__ (e.g. DEC C by default) or may define it as
3016    zero.  */
3017 #undef PROTOTYPES
3018 /* For mktime.c:  */
3019 #ifndef __P
3020 # if defined PROTOTYPES
3021 #  define __P(args) args
3022 # else
3023 #  define __P(args) ()
3024 # endif  /* GCC.  */
3025 #endif /* __P */
3026
3027 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3028 #ifndef NOT_C_CODE
3029 #ifdef HAVE_STRING_H
3030 #include "string.h"
3031 #endif
3032 #ifdef HAVE_STRINGS_H
3033 #include "strings.h"  /* May be needed for bcopy & al. */
3034 #endif
3035 #ifdef HAVE_STDLIB_H
3036 #include <stdlib.h>
3037 #endif
3038 #ifndef __GNUC__
3039 # ifdef HAVE_ALLOCA_H
3040 #  include <alloca.h>
3041 # else /* AIX files deal with #pragma.  */
3042 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3043 char *alloca ();
3044 #  endif
3045 # endif /* HAVE_ALLOCA_H */
3046 #endif /* __GNUC__ */
3047 #ifndef HAVE_SIZE_T
3048 typedef unsigned size_t;
3049 #endif
3050 #endif /* NOT_C_CODE */
3051
3052 /* Define HAVE_X_I18N if we have usable i18n support.  */
3053
3054 #ifdef HAVE_X11R6
3055 #define HAVE_X_I18N
3056 #elif !defined X11R5_INHIBIT_I18N
3057 #define HAVE_X_I18N
3058 #endif
3059
3060 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3061
3062 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3063 #define HAVE_X11R6_XIM
3064 #endif
3065
3066 #if defined __GNUC__ && (__GNUC__ > 2 \
3067                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3068 #define NO_RETURN       __attribute__ ((__noreturn__))
3069 #else
3070 #define NO_RETURN       /* nothing */
3071 #endif
3072
3073 /* These won't be used automatically yet.  We also need to know, at least,
3074    that the stack is continuous.  */
3075 #ifdef __GNUC__
3076 #  ifndef GC_SETJMP_WORKS
3077   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3078      see NON_SAVING_SETJMP in the target descriptions.  */
3079   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3080      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3081      Fixme: Deal with SVR3.  */
3082 #    define GC_SETJMP_WORKS 1
3083 #  endif
3084 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3085 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3086 #  endif
3087 #endif
3088
3089 #ifndef HAVE_BCOPY
3090 #define bcopy(a,b,s) memcpy (b,a,s)
3091 #endif
3092 #ifndef HAVE_BZERO
3093 #define bzero(a,s) memset (a,0,s)
3094 #endif
3095 #ifndef HAVE_BCMP
3096 #define BCMP memcmp
3097 #endif
3098
3099 #endif /* EMACS_CONFIG_H */
3100
3101 /*
3102 Local Variables:
3103 mode: c
3104 End:
3105 */
3106 ])dnl
3107
3108 #### Report on what we decided to do.
3109 #### Report GTK as a toolkit, even if it doesn't use Xt.
3110 #### It makes printing result more understandable as using GTK sets
3111 #### toolkit_scroll_bars to yes by default.
3112 if test "${HAVE_GTK}" = "yes"; then
3113   USE_X_TOOLKIT=GTK
3114 fi
3115
3116 echo "
3117 Configured for \`${canonical}'.
3118
3119   Where should the build process find the source code?    ${srcdir}
3120   What operating system and machine description files should Emacs use?
3121         \`${opsysfile}' and \`${machfile}'
3122   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3123   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3124   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3125   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3126   What window system should Emacs use?                    ${window_system}
3127   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3128
3129 if test -n "${x_includes}"; then
3130 echo "  Where do we find X Windows header files?                ${x_includes}"
3131 else
3132 echo "  Where do we find X Windows header files?                Standard dirs"
3133 fi
3134 if test -n "${x_libraries}"; then
3135 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3136 else
3137 echo "  Where do we find X Windows libraries?                   Standard dirs"
3138 fi
3139
3140 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3141 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3142 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3143 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3144 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3145 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3146 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3147 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3148 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3149 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3150 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3151
3152 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3153 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3154 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3155 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3156
3157 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3158 echo
3159
3160 if test $USE_XASSERTS = yes; then
3161    echo "  Compiling with asserts turned on."
3162    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3163 fi
3164
3165 echo
3166
3167 if test "$HAVE_NS" = "yes"; then
3168    echo
3169    echo "You must run \"make install\" in order to test the built application.
3170 The installed application will go to nextstep/Emacs.app and can be
3171 run or moved from there."
3172    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3173       echo "The application will be fully self-contained."
3174     else
3175       echo "The lisp resources for the application will be installed under ${prefix}.
3176 You may need to run \"make install\" with sudo.  The application will fail
3177 to run if these resources are not installed."
3178    fi
3179    echo
3180 fi
3181
3182 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3183   echo "D-Bus integration has been tested for GNU/Linux only."
3184   echo
3185 fi
3186
3187
3188 # Remove any trailing slashes in these variables.
3189 [test "${prefix}" != NONE &&
3190   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3191 test "${exec_prefix}" != NONE &&
3192   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3193
3194 # Now get this: Some word that is part of the ${srcdir} directory name
3195 # or the ${configuration} value might, just might, happen to be an
3196 # identifier like `sun4' or `i386' or something, and be predefined by
3197 # the C preprocessor to some helpful value like 1, or maybe the empty
3198 # string.  Needless to say consequent macro substitutions are less
3199 # than conducive to the makefile finding the correct directory.
3200 [cpp_undefs="`echo $srcdir $configuration $canonical unix |
3201   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3202   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3203
3204 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3205 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3206 ## from Makefile.c can correctly provide the arg `-traditional' to the
3207 ## C preprocessor.
3208
3209 AC_EGREP_CPP(yes..yes,
3210         [yes..yes],
3211         CPP_NEED_TRADITIONAL=no,
3212         CPP_NEED_TRADITIONAL=yes)
3213
3214 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3215         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3216         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3217         lwlib/Makefile lisp/Makefile leim/Makefile, [
3218
3219 ### Make the necessary directories, if they don't exist.
3220 for dir in etc lisp ; do
3221   test -d ${dir} || mkdir ${dir}
3222 done
3223
3224 # Build src/Makefile from ${srcdir}/src/Makefile.c
3225 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3226 # This must be done after src/config.h is built, since we rely on that file.
3227
3228 echo creating src/epaths.h
3229 ${MAKE-make} epaths-force
3230
3231 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3232 # `..' to `. .'  unless invoked with -traditional
3233
3234 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3235   CPPFLAGS="$CPPFLAGS -traditional"
3236 fi
3237
3238 echo creating lib-src/Makefile
3239 ( cd lib-src
3240   rm -f junk.c junk1.c junk2.c
3241   sed -e '/start of cpp stuff/q' \
3242       < Makefile.c > junk1.c
3243   sed -e '1,/start of cpp stuff/d'\
3244       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3245       < Makefile.c > junk.c
3246   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3247       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3248   cat junk1.c junk2.c > Makefile.new
3249   rm -f junk.c junk1.c junk2.c
3250   chmod 444 Makefile.new
3251   mv -f Makefile.new Makefile
3252 )
3253
3254 echo creating src/Makefile
3255 ( cd src
3256   rm -f junk.c junk1.c junk2.c
3257   sed -e '/start of cpp stuff/q' \
3258       < Makefile.c > junk1.c
3259   sed -e '1,/start of cpp stuff/d'\
3260       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3261       < Makefile.c > junk.c
3262   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3263       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3264   cat junk1.c junk2.c > Makefile.new
3265   rm -f junk.c junk1.c junk2.c
3266   chmod 444 Makefile.new
3267   mv -f Makefile.new Makefile
3268 )
3269
3270 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3271   echo creating src/.gdbinit
3272   echo source $srcdir/src/.gdbinit > src/.gdbinit
3273 fi
3274
3275 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3276
3277 m4_if(dnl       Do not change this comment
3278    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3279 )dnl