lisp/term/w32-win.el

   1 ;;; w32-win.el --- parse switches controlling interface with W32 window system
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Kevin Gallo
   7 ;; Keywords: terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; w32-win.el:  this file is loaded from ../lisp/startup.el when it recognizes
  27 ;; that W32 windows are to be used.  Command line switches are parsed and those
  28 ;; pertaining to W32 are processed and removed from the command line.  The
  29 ;; W32 display is opened and hooks are set for popping up the initial window.
  30
  31 ;; startup.el will then examine startup files, and eventually call the hooks
  32 ;; which create the first window (s).
  33
  34 ;;; Code:
  35 \f
  36
  37 ;; These are the standard X switches from the Xt Initialize.c file of
  38 ;; Release 4.
  39
  40 ;; Command line         Resource Manager string
  41
  42 ;; +rv                  *reverseVideo
  43 ;; +synchronous         *synchronous
  44 ;; -background          *background
  45 ;; -bd                  *borderColor
  46 ;; -bg                  *background
  47 ;; -bordercolor         *borderColor
  48 ;; -borderwidth         .borderWidth
  49 ;; -bw                  .borderWidth
  50 ;; -display             .display
  51 ;; -fg                  *foreground
  52 ;; -fn                  *font
  53 ;; -font                *font
  54 ;; -foreground          *foreground
  55 ;; -geometry            .geometry
  56 ;; -i                   .iconType
  57 ;; -itype               .iconType
  58 ;; -iconic              .iconic
  59 ;; -name                .name
  60 ;; -reverse             *reverseVideo
  61 ;; -rv                  *reverseVideo
  62 ;; -selectionTimeout    .selectionTimeout
  63 ;; -synchronous         *synchronous
  64 ;; -xrm
  65
  66 ;; An alist of X options and the function which handles them.  See
  67 ;; ../startup.el.
  68
  69 ;; (if (not (eq window-system 'w32))
  70 ;;     (error "%s: Loading w32-win.el but not compiled for w32" (invocation-name)))
  71
  72 (require 'frame)
  73 (require 'mouse)
  74 (require 'scroll-bar)
  75 (require 'faces)
  76 (require 'select)
  77 (require 'menu-bar)
  78 (require 'dnd)
  79 (require 'w32-vars)
  80
  81 ;; Keep an obsolete alias for w32-focus-frame in case it is used by code
  82 ;; outside Emacs.
  83 (define-obsolete-function-alias 'w32-focus-frame 'x-focus-frame "23.1")
  84
  85 (defvar xlfd-regexp-registry-subnum)
  86 (defvar w32-color-map) ;; defined in w32fns.c
  87
  88 (declare-function w32-send-sys-command "w32fns.c")
  89 (declare-function w32-select-font "w32fns.c")
  90 (declare-function set-message-beep "w32console.c")
  91
  92 ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
  93 (if (fboundp 'new-fontset)
  94     (require 'fontset))
  95
  96 ;; The following definition is used for debugging scroll bar events.
  97 ;(defun w32-handle-scroll-bar-event (event) (interactive "e") (princ event))
  98
  99 (defun w32-drag-n-drop-debug (event)
 100   "Print the drag-n-drop EVENT in a readable form."
 101   (interactive "e")
 102   (princ event))
 103
 104 (defun w32-drag-n-drop (event)
 105   "Edit the files listed in the drag-n-drop EVENT.
 106 Switch to a buffer editing the last file dropped."
 107   (interactive "e")
 108   (save-excursion
 109     ;; Make sure the drop target has positive co-ords
 110     ;; before setting the selected frame - otherwise it
 111     ;; won't work.  <skx@tardis.ed.ac.uk>
 112     (let* ((window (posn-window (event-start event)))
 113            (coords (posn-x-y (event-start event)))
 114            (x (car coords))
 115            (y (cdr coords)))
 116       (if (and (> x 0) (> y 0))
 117           (set-frame-selected-window nil window))
 118       (mapc (lambda (file-name)
 119                 (let ((f (subst-char-in-string ?\\ ?/ file-name))
 120                       (coding (or file-name-coding-system
 121                                   default-file-name-coding-system)))
 122                   (setq file-name
 123                         (mapconcat 'url-hexify-string
 124                                    (split-string (encode-coding-string f coding)
 125                                                  "/")
 126                                    "/")))
 127                 (dnd-handle-one-url window 'private
 128                                     (concat "file:" file-name)))
 129                 (car (cdr (cdr event)))))
 130   (raise-frame)))
 131
 132 (defun w32-drag-n-drop-other-frame (event)
 133   "Edit the files listed in the drag-n-drop EVENT, in other frames.
 134 May create new frames, or reuse existing ones.  The frame editing
 135 the last file dropped is selected."
 136   (interactive "e")
 137   (mapcar 'find-file-other-frame (car (cdr (cdr event)))))
 138
 139 ;; Bind the drag-n-drop event.
 140 (global-set-key [drag-n-drop] 'w32-drag-n-drop)
 141 (global-set-key [C-drag-n-drop] 'w32-drag-n-drop-other-frame)
 142
 143 ;; Keyboard layout/language change events
 144 ;; For now ignore language-change events; in the future
 145 ;; we should switch the Emacs Input Method to match the
 146 ;; new layout/language selected by the user.
 147 (global-set-key [language-change] 'ignore)
 148
 149 (defvar x-invocation-args)
 150
 151 (defvar x-command-line-resources nil)
 152
 153 (defun x-handle-switch (switch)
 154   "Handle SWITCH of the form \"-switch value\" or \"-switch\"."
 155   (let ((aelt (assoc switch command-line-x-option-alist)))
 156     (if aelt
 157         (push (cons (nth 3 aelt) (or (nth 4 aelt) (pop x-invocation-args)))
 158               default-frame-alist))))
 159
 160 (defun x-handle-numeric-switch (switch)
 161   "Handle SWITCH of the form \"-switch n\"."
 162   (let ((aelt (assoc switch command-line-x-option-alist)))
 163     (if aelt
 164         (push (cons (nth 3 aelt) (string-to-number (pop x-invocation-args)))
 165               default-frame-alist))))
 166
 167 ;; Handle options that apply to initial frame only
 168 (defun x-handle-initial-switch (switch)
 169   (let ((aelt (assoc switch command-line-x-option-alist)))
 170     (if aelt
 171         (push (cons (nth 3 aelt) (or (nth 4 aelt) (pop x-invocation-args)))
 172               initial-frame-alist))))
 173
 174 (defun x-handle-iconic (switch)
 175   "Make \"-iconic\" SWITCH apply only to the initial frame."
 176   (push '(visibility . icon) initial-frame-alist))
 177
 178 (defun x-handle-xrm-switch (switch)
 179   "Handle the \"-xrm\" SWITCH."
 180   (or (consp x-invocation-args)
 181       (error "%s: missing argument to `%s' option" (invocation-name) switch))
 182   (setq x-command-line-resources
 183         (if (null x-command-line-resources)
 184             (car x-invocation-args)
 185           (concat x-command-line-resources "\n" (car x-invocation-args))))
 186   (setq x-invocation-args (cdr x-invocation-args)))
 187
 188 (declare-function x-parse-geometry "frame.c" (string))
 189
 190 (defun x-handle-geometry (switch)
 191   "Handle the \"-geometry\" SWITCH."
 192   (let* ((geo (x-parse-geometry (car x-invocation-args)))
 193          (left (assq 'left geo))
 194          (top (assq 'top geo))
 195          (height (assq 'height geo))
 196          (width (assq 'width geo)))
 197     (if (or height width)
 198         (setq default-frame-alist
 199               (append default-frame-alist
 200                       '((user-size . t))
 201                       (if height (list height))
 202                       (if width (list width)))
 203               initial-frame-alist
 204               (append initial-frame-alist
 205                       '((user-size . t))
 206                       (if height (list height))
 207                       (if width (list width)))))
 208     (if (or left top)
 209         (setq initial-frame-alist
 210               (append initial-frame-alist
 211                       '((user-position . t))
 212                       (if left (list left))
 213                       (if top (list top)))))
 214     (setq x-invocation-args (cdr x-invocation-args))))
 215
 216 (defvar x-resource-name)
 217
 218 (defun x-handle-name-switch (switch)
 219   "Handle the \"-name\" SWITCH."
 220 ;; Handle the -name option.  Set the variable x-resource-name
 221 ;; to the option's operand; set the name of the initial frame, too.
 222   (or (consp x-invocation-args)
 223       (error "%s: missing argument to `%s' option" (invocation-name) switch))
 224   (setq x-resource-name (pop x-invocation-args))
 225   (push (cons 'name x-resource-name) initial-frame-alist))
 226
 227 (defvar x-display-name nil
 228   "The display name specifying server and frame.")
 229
 230 (defun x-handle-display (switch)
 231   "Handle the \"-display\" SWITCH."
 232   (setq x-display-name (pop x-invocation-args)))
 233
 234 (defun x-handle-args (args)
 235   "Process the X-related command line options in ARGS.
 236 This is done before the user's startup file is loaded.  They are copied to
 237 `x-invocation args' from which the X-related things are extracted, first
 238 the switch (e.g., \"-fg\") in the following code, and possible values
 239 \(e.g., \"black\") in the option handler code (e.g., x-handle-switch).
 240 This returns ARGS with the arguments that have been processed removed."
 241   ;; We use ARGS to accumulate the args that we don't handle here, to return.
 242   (setq x-invocation-args args
 243         args nil)
 244   (while (and x-invocation-args
 245               (not (equal (car x-invocation-args) "--")))
 246     (let* ((this-switch (car x-invocation-args))
 247            (orig-this-switch this-switch)
 248            completion argval aelt handler)
 249       (setq x-invocation-args (cdr x-invocation-args))
 250       ;; Check for long options with attached arguments
 251       ;; and separate out the attached option argument into argval.
 252       (if (string-match "^--[^=]*=" this-switch)
 253           (setq argval (substring this-switch (match-end 0))
 254                 this-switch (substring this-switch 0 (1- (match-end 0)))))
 255       ;; Complete names of long options.
 256       (if (string-match "^--" this-switch)
 257           (progn
 258             (setq completion (try-completion this-switch command-line-x-option-alist))
 259             (if (eq completion t)
 260                 ;; Exact match for long option.
 261                 nil
 262               (if (stringp completion)
 263                   (let ((elt (assoc completion command-line-x-option-alist)))
 264                     ;; Check for abbreviated long option.
 265                     (or elt
 266                         (error "Option `%s' is ambiguous" this-switch))
 267                     (setq this-switch completion))))))
 268       (setq aelt (assoc this-switch command-line-x-option-alist))
 269       (if aelt (setq handler (nth 2 aelt)))
 270       (if handler
 271           (if argval
 272               (let ((x-invocation-args
 273                      (cons argval x-invocation-args)))
 274                 (funcall handler this-switch))
 275             (funcall handler this-switch))
 276         (push orig-this-switch args))))
 277   (nconc (nreverse args) x-invocation-args))
 278 \f
 279 ;;
 280 ;; Available colors
 281 ;;
 282 ;; The ordering of the colors is chosen for the user's convenience in
 283 ;; `list-colors-display', which displays the reverse of this list.
 284 ;; Roughly speaking, `list-colors-display' orders by (i) named shades
 285 ;; of grey with hue 0.0, sorted by value (ii) named colors with
 286 ;; saturation 1.0, sorted by hue, (iii) named non-white colors with
 287 ;; saturation less than 1.0, sorted by hue, (iv) other named shades of
 288 ;; white, (v) numbered colors sorted by hue, and (vi) numbered shades
 289 ;; of grey.
 290
 291 (defvar x-colors
 292   '("gray100" "gray99" "gray98" "gray97" "gray96" "gray95" "gray94" "gray93" "gray92"
 293     "gray91" "gray90" "gray89" "gray88" "gray87" "gray86" "gray85" "gray84" "gray83"
 294     "gray82" "gray81" "gray80" "gray79" "gray78" "gray77" "gray76" "gray75" "gray74"
 295     "gray73" "gray72" "gray71" "gray70" "gray69" "gray68" "gray67" "gray66" "gray65"
 296     "gray64" "gray63" "gray62" "gray61" "gray60" "gray59" "gray58" "gray57" "gray56"
 297     "gray55" "gray54" "gray53" "gray52" "gray51" "gray50" "gray49" "gray48" "gray47"
 298     "gray46" "gray45" "gray44" "gray43" "gray42" "gray41" "gray40" "gray39" "gray38"
 299     "gray37" "gray36" "gray35" "gray34" "gray33" "gray32" "gray31" "gray30" "gray29"
 300     "gray28" "gray27" "gray26" "gray25" "gray24" "gray23" "gray22" "gray21" "gray20"
 301     "gray19" "gray18" "gray17" "gray16" "gray15" "gray14" "gray13" "gray12" "gray11"
 302     "gray10" "gray9" "gray8" "gray7" "gray6" "gray5" "gray4" "gray3" "gray2" "gray1"
 303     "gray0" "LightPink1" "LightPink2" "LightPink3" "LightPink4" "pink1" "pink2" "pink3"
 304     "pink4" "PaleVioletRed1" "PaleVioletRed2" "PaleVioletRed3" "PaleVioletRed4"
 305     "LavenderBlush1" "LavenderBlush2" "LavenderBlush3" "LavenderBlush4" "VioletRed1"
 306     "VioletRed2" "VioletRed3" "VioletRed4" "HotPink1" "HotPink2" "HotPink3" "HotPink4"
 307     "DeepPink1" "DeepPink2" "DeepPink3" "DeepPink4" "maroon1" "maroon2" "maroon3"
 308     "maroon4" "orchid1" "orchid2" "orchid3" "orchid4" "plum1" "plum2" "plum3" "plum4"
 309     "thistle1" "thistle2" "thistle3" "thistle4" "MediumOrchid1" "MediumOrchid2"
 310     "MediumOrchid3" "MediumOrchid4" "DarkOrchid1" "DarkOrchid2" "DarkOrchid3"
 311     "DarkOrchid4" "purple1" "purple2" "purple3" "purple4" "MediumPurple1"
 312     "MediumPurple2" "MediumPurple3" "MediumPurple4" "SlateBlue1" "SlateBlue2"
 313     "SlateBlue3" "SlateBlue4" "RoyalBlue1" "RoyalBlue2" "RoyalBlue3" "RoyalBlue4"
 314     "LightSteelBlue1" "LightSteelBlue2" "LightSteelBlue3" "LightSteelBlue4" "SlateGray1"
 315     "SlateGray2" "SlateGray3" "SlateGray4" "DodgerBlue1" "DodgerBlue2" "DodgerBlue3"
 316     "DodgerBlue4" "SteelBlue1" "SteelBlue2" "SteelBlue3" "SteelBlue4" "SkyBlue1"
 317     "SkyBlue2" "SkyBlue3" "SkyBlue4" "LightSkyBlue1" "LightSkyBlue2" "LightSkyBlue3"
 318     "LightSkyBlue4" "LightBlue1" "LightBlue2" "LightBlue3" "LightBlue4" "CadetBlue1"
 319     "CadetBlue2" "CadetBlue3" "CadetBlue4" "azure1" "azure2" "azure3" "azure4"
 320     "LightCyan1" "LightCyan2" "LightCyan3" "LightCyan4" "PaleTurquoise1"
 321     "PaleTurquoise2" "PaleTurquoise3" "PaleTurquoise4" "DarkSlateGray1" "DarkSlateGray2"
 322     "DarkSlateGray3" "DarkSlateGray4" "aquamarine1" "aquamarine2" "aquamarine3"
 323     "aquamarine4" "SeaGreen1" "SeaGreen2" "SeaGreen3" "SeaGreen4" "honeydew1"
 324     "honeydew2" "honeydew3" "honeydew4" "DarkSeaGreen1" "DarkSeaGreen2" "DarkSeaGreen3"
 325     "DarkSeaGreen4" "PaleGreen1" "PaleGreen2" "PaleGreen3" "PaleGreen4"
 326     "DarkOliveGreen1" "DarkOliveGreen2" "DarkOliveGreen3" "DarkOliveGreen4" "OliveDrab1"
 327     "OliveDrab2" "OliveDrab3" "OliveDrab4" "ivory1" "ivory2" "ivory3" "ivory4"
 328     "LightYellow1" "LightYellow2" "LightYellow3" "LightYellow4" "khaki1" "khaki2"
 329     "khaki3" "khaki4" "LemonChiffon1" "LemonChiffon2" "LemonChiffon3" "LemonChiffon4"
 330     "LightGoldenrod1" "LightGoldenrod2" "LightGoldenrod3" "LightGoldenrod4" "cornsilk1"
 331     "cornsilk2" "cornsilk3" "cornsilk4" "goldenrod1" "goldenrod2" "goldenrod3"
 332     "goldenrod4" "DarkGoldenrod1" "DarkGoldenrod2" "DarkGoldenrod3" "DarkGoldenrod4"
 333     "wheat1" "wheat2" "wheat3" "wheat4" "NavajoWhite1" "NavajoWhite2" "NavajoWhite3"
 334     "NavajoWhite4" "burlywood1" "burlywood2" "burlywood3" "burlywood4" "AntiqueWhite1"
 335     "AntiqueWhite2" "AntiqueWhite3" "AntiqueWhite4" "bisque1" "bisque2" "bisque3"
 336     "bisque4" "tan1" "tan2" "tan3" "tan4" "PeachPuff1" "PeachPuff2" "PeachPuff3"
 337     "PeachPuff4" "seashell1" "seashell2" "seashell3" "seashell4" "chocolate1"
 338     "chocolate2" "chocolate3" "chocolate4" "sienna1" "sienna2" "sienna3" "sienna4"
 339     "LightSalmon1" "LightSalmon2" "LightSalmon3" "LightSalmon4" "salmon1" "salmon2"
 340     "salmon3" "salmon4" "coral1" "coral2" "coral3" "coral4" "tomato1" "tomato2"
 341     "tomato3" "tomato4" "MistyRose1" "MistyRose2" "MistyRose3" "MistyRose4" "snow1"
 342     "snow2" "snow3" "snow4" "RosyBrown1" "RosyBrown2" "RosyBrown3" "RosyBrown4"
 343     "IndianRed1" "IndianRed2" "IndianRed3" "IndianRed4" "firebrick1" "firebrick2"
 344     "firebrick3" "firebrick4" "brown1" "brown2" "brown3" "brown4" "magenta1" "magenta2"
 345     "magenta3" "magenta4" "blue1" "blue2" "blue3" "blue4" "DeepSkyBlue1" "DeepSkyBlue2"
 346     "DeepSkyBlue3" "DeepSkyBlue4" "turquoise1" "turquoise2" "turquoise3" "turquoise4"
 347     "cyan1" "cyan2" "cyan3" "cyan4" "SpringGreen1" "SpringGreen2" "SpringGreen3"
 348     "SpringGreen4" "green1" "green2" "green3" "green4" "chartreuse1" "chartreuse2"
 349     "chartreuse3" "chartreuse4" "yellow1" "yellow2" "yellow3" "yellow4" "gold1" "gold2"
 350     "gold3" "gold4" "orange1" "orange2" "orange3" "orange4" "DarkOrange1" "DarkOrange2"
 351     "DarkOrange3" "DarkOrange4" "OrangeRed1" "OrangeRed2" "OrangeRed3" "OrangeRed4"
 352     "red1" "red2" "red3" "red4" "lavender blush" "ghost white" "lavender" "alice blue"
 353     "azure" "light cyan" "mint cream" "honeydew" "ivory" "light goldenrod yellow"
 354     "light yellow" "beige" "floral white" "old lace" "blanched almond" "moccasin"
 355     "papaya whip" "bisque" "antique white" "linen" "peach puff" "seashell" "misty rose"
 356     "snow" "light pink" "pink" "hot pink" "deep pink" "maroon" "pale violet red"
 357     "violet red" "medium violet red" "violet" "plum" "thistle" "orchid" "medium orchid"
 358     "dark orchid" "purple" "blue violet" "medium purple" "light slate blue"
 359     "medium slate blue" "slate blue" "dark slate blue" "midnight blue" "navy"
 360     "dark blue" "light steel blue" "cornflower blue" "dodger blue" "royal blue"
 361     "light slate gray" "slate gray" "dark slate gray" "steel blue" "cadet blue"
 362     "light sky blue" "sky blue" "light blue" "powder blue" "pale turquoise" "turquoise"
 363     "medium turquoise" "dark cyan" "aquamarine" "medium aquamarine" "light sea green"
 364     "medium sea green" "sea green" "dark sea green" "pale green" "lime green"
 365     "forest green" "light green" "green yellow" "yellow green" "olive drab"
 366     "dark olive green" "lemon chiffon" "khaki" "dark khaki" "cornsilk"
 367     "pale goldenrod" "light goldenrod" "goldenrod" "dark goldenrod" "wheat"
 368     "navajo white" "tan" "burlywood" "sandy brown" "peru" "chocolate" "saddle brown"
 369     "sienna" "rosy brown" "dark salmon" "coral" "tomato" "light salmon" "salmon"
 370     "light coral" "indian red" "firebrick" "brown" "dark red" "magenta"
 371     "dark magenta" "dark violet" "medium blue" "blue" "deep sky blue"
 372     "cyan" "medium spring green" "spring green" "green" "lawn green" "chartreuse"
 373     "yellow" "gold" "orange" "dark orange" "orange red" "red" "white" "white smoke"
 374     "gainsboro" "light grey" "gray" "dark grey" "dim gray" "black" )
 375   "The list of X colors from the `rgb.txt' file.
 376 XConsortium: rgb.txt,v 10.41 94/02/20 18:39:36 rws Exp")
 377
 378 (defun xw-defined-colors (&optional frame)
 379   "Internal function called by `defined-colors', which see."
 380   (or frame (setq frame (selected-frame)))
 381   (let ((defined-colors nil))
 382     (dolist (this-color (or (mapcar 'car w32-color-map) x-colors))
 383       (and (color-supported-p this-color frame t)
 384            (push this-color defined-colors)))
 385     defined-colors))
 386 \f
 387 \f
 388 ;;;; Function keys
 389
 390  ;;; make f10 activate the real menubar rather than the mini-buffer menu
 391  ;;; navigation feature.
 392  (defun w32-menu-bar-open (&optional frame)
 393    "Start key navigation of the menu bar in FRAME.
 394
 395 This initially activates the first menu-bar item, and you can then navigate
 396 with the arrow keys, select a menu entry with the Return key or cancel with
 397 the Escape key.  If FRAME has no menu bar, this function does nothing.
 398
 399 If FRAME is nil or not given, use the selected frame.
 400 If FRAME does not have the menu bar enabled, display a text menu using
 401 `tmm-menubar'."
 402    (interactive "i")
 403    (if menu-bar-mode
 404        (w32-send-sys-command ?\xf100 frame)
 405      (with-selected-frame (or frame (selected-frame))
 406        (tmm-menubar))))
 407 \f
 408
 409 ;; W32 systems have different fonts than commonly found on X, so
 410 ;; we define our own standard fontset here.
 411 (defvar w32-standard-fontset-spec
 412  "-*-Courier New-normal-r-*-*-13-*-*-*-c-*-fontset-standard"
 413  "String of fontset spec of the standard fontset.
 414 This defines a fontset consisting of the Courier New variations for
 415 European languages which are distributed with Windows as
 416 \"Multilanguage Support\".
 417
 418 See the documentation of `create-fontset-from-fontset-spec' for the format.")
 419
 420 (defun x-win-suspend-error ()
 421   "Report an error when a suspend is attempted."
 422   (error "Suspending an Emacs running under W32 makes no sense"))
 423
 424 (declare-function generate-fontset-menu "fontset" ())
 425
 426 (defun mouse-set-font (&rest fonts)
 427   "Select an Emacs font from a list of known good fonts and fontsets.
 428
 429 If `w32-use-w32-font-dialog' is non-nil (the default), use the Windows
 430 font dialog to display the list of possible fonts.  Otherwise use a
 431 pop-up menu (like Emacs does on other platforms) initialized with
 432 the fonts in `w32-fixed-font-alist'.
 433 If `w32-list-proportional-fonts' is non-nil, add proportional fonts
 434 to the list in the font selection dialog (the fonts listed by the
 435 pop-up menu are unaffected by `w32-list-proportional-fonts')."
 436   (interactive
 437    (if w32-use-w32-font-dialog
 438        (let ((chosen-font (w32-select-font (selected-frame)
 439                                            w32-list-proportional-fonts)))
 440          (and chosen-font (list chosen-font)))
 441      (x-popup-menu
 442       last-nonmenu-event
 443       ;; Append list of fontsets currently defined.
 444       ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
 445       (if (fboundp 'new-fontset)
 446           (append w32-fixed-font-alist (list (generate-fontset-menu)))))))
 447   (if fonts
 448       (let (font)
 449         (while fonts
 450           (condition-case nil
 451               (progn
 452                 (setq font (car fonts))
 453                 (set-default-font font)
 454                 (setq fonts nil))
 455             (error (setq fonts (cdr fonts)))))
 456         (if (null font)
 457             (error "Font not found")))))
 458
 459 (defvar image-library-alist)
 460
 461 ;;; Set default known names for image libraries
 462 (setq image-library-alist
 463       '((xpm "libxpm.dll" "xpm4.dll" "libXpm-nox4.dll")
 464         (png "libpng12d.dll" "libpng12.dll" "libpng.dll"
 465          ;; these are libpng 1.2.8 from GTK+
 466          "libpng13d.dll" "libpng13.dll")
 467         (jpeg "jpeg62.dll" "libjpeg.dll" "jpeg-62.dll" "jpeg.dll")
 468         (tiff "libtiff3.dll" "libtiff.dll")
 469         (gif "giflib4.dll" "libungif4.dll" "libungif.dll")
 470         (svg "librsvg-2-2.dll")
 471         (gdk-pixbuf "libgdk_pixbuf-2.0-0.dll")
 472         (glib "libglib-2.0-0.dll")))
 473
 474 ;;; multi-tty support
 475 (defvar w32-initialized nil
 476   "Non-nil if the w32 window system has been initialized.")
 477
 478 (declare-function x-open-connection "w32fns.c"
 479                   (display &optional xrm-string must-succeed))
 480
 481 (declare-function setup-default-fontset "fontset" ())
 482 (declare-function set-fontset-font "fontset.c"
 483                   (name target font-spec &optional frame add))
 484 (declare-function setup-default-fontset "fontset" ())
 485 (declare-function create-fontset-from-fontset-spec "fontset"
 486                   (fontset-spec &optional style-variant noerror))
 487 (declare-function create-fontset-from-x-resource "fontset" ())
 488 (declare-function x-get-resource "frame.c"
 489                   (attribute class &optional component subclass))
 490
 491 (defun w32-initialize-window-system ()
 492   "Initialize Emacs for W32 GUI frames."
 493
 494   ;; Do the actual Windows setup here; the above code just defines
 495   ;; functions and variables that we use now.
 496
 497   (setq command-line-args (x-handle-args command-line-args))
 498
 499   ;; Make sure we have a valid resource name.
 500   (or (stringp x-resource-name)
 501       (setq x-resource-name
 502             ;; Change any . or * characters in x-resource-name to hyphens,
 503             ;; so as not to choke when we use it in X resource queries.
 504             (replace-regexp-in-string "[.*]" "-" (invocation-name))))
 505
 506   (x-open-connection "" x-command-line-resources
 507                      ;; Exit with a fatal error if this fails and we
 508                      ;; are the initial display
 509                      (eq initial-window-system 'w32))
 510
 511   ;; Setup the default fontset.
 512   (setup-default-fontset)
 513
 514   ;; Enable Japanese fonts on Windows to be used by default.
 515   (set-fontset-font t (make-char 'katakana-jisx0201)
 516                     '("*" . "JISX0208-SJIS"))
 517   (set-fontset-font t (make-char 'latin-jisx0201)
 518                     '("*" . "JISX0208-SJIS"))
 519   (set-fontset-font t (make-char 'japanese-jisx0208)
 520                     '("*" . "JISX0208-SJIS"))
 521   (set-fontset-font t (make-char 'japanese-jisx0208-1978)
 522                     '("*" . "JISX0208-SJIS"))
 523
 524   ;; Create the standard fontset.
 525   (create-fontset-from-fontset-spec w32-standard-fontset-spec t)
 526   ;; Create fontset specified in X resources "Fontset-N" (N is 0, 1,...).
 527   (create-fontset-from-x-resource)
 528
 529   ;; Apply a geometry resource to the initial frame.  Put it at the end
 530   ;; of the alist, so that anything specified on the command line takes
 531   ;; precedence.
 532   (let* ((res-geometry (x-get-resource "geometry" "Geometry"))
 533          parsed)
 534     (if res-geometry
 535         (progn
 536           (setq parsed (x-parse-geometry res-geometry))
 537           ;; If the resource specifies a position,
 538           ;; call the position and size "user-specified".
 539           (if (or (assq 'top parsed) (assq 'left parsed))
 540               (setq parsed (cons '(user-position . t)
 541                                  (cons '(user-size . t) parsed))))
 542           ;; All geometry parms apply to the initial frame.
 543           (setq initial-frame-alist (append initial-frame-alist parsed))
 544           ;; The size parms apply to all frames.
 545           (if (assq 'height parsed)
 546               (push (cons 'height (cdr (assq 'height parsed)))
 547                     default-frame-alist))
 548           (if (assq 'width parsed)
 549               (push (cons 'width (cdr (assq 'width parsed)))
 550                     default-frame-alist)))))
 551
 552   ;; Check the reverseVideo resource.
 553   (let ((case-fold-search t))
 554     (let ((rv (x-get-resource "reverseVideo" "ReverseVideo")))
 555       (if (and rv (string-match "^\\(true\\|yes\\|on\\)$" rv))
 556           (push '(reverse . t) default-frame-alist))))
 557
 558   ;; Don't let Emacs suspend under w32 gui
 559   (add-hook 'suspend-hook 'x-win-suspend-error)
 560
 561   ;; Turn off window-splitting optimization; w32 is usually fast enough
 562   ;; that this is only annoying.
 563   (setq split-window-keep-point t)
 564
 565   ;; Turn on support for mouse wheels
 566   (mouse-wheel-mode 1)
 567
 568   ;; W32 expects the menu bar cut and paste commands to use the clipboard.
 569   (menu-bar-enable-clipboard)
 570
 571   ;; Don't show the frame name; that's redundant.
 572   (setq-default mode-line-frame-identification "  ")
 573
 574   ;; Set to a system sound if you want a fancy bell.
 575   (set-message-beep 'ok)
 576   (setq w32-initialized t))
 577
 578 (add-to-list 'handle-args-function-alist '(w32 . x-handle-args))
 579 (add-to-list 'frame-creation-function-alist '(w32 . x-create-frame-with-faces))
 580 (add-to-list 'window-system-initialization-alist '(w32 . w32-initialize-window-system))
 581
 582 (provide 'w32-win)
 583
 584 ;; arch-tag: 69fb1701-28c2-4890-b351-3d1fe4b4f166
 585 ;;; w32-win.el ends here