configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010, 2011
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30 AM_INIT_AUTOMAKE
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 dnl _ON results in a '--without' option in the --help output, so
 150 dnl the help text should refer to "don't compile", etc.
 151 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 152 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 153 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 154 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 155 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 156 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 157 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 158 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 159
 160 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 161 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 162 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 163
 164 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 165 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 166 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 167 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 168
 169 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 170 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 171 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 172 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 173 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 174
 175 ## For the times when you want to build Emacs but don't have
 176 ## a suitable makeinfo, and can live without the manuals.
 177 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 178 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 179
 180 ## This is an option because I do not know if all info/man support
 181 ## compressed files, nor how to test if they do so.
 182 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 183 if test $with_compress_info = yes; then
 184    GZIP_INFO=yes
 185 else
 186    GZIP_INFO=
 187 fi
 188 AC_SUBST(GZIP_INFO)
 189
 190 AC_ARG_WITH([pkg-config-prog],dnl
 191 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 192                   [path to pkg-config for finding GTK and librsvg])])
 193 if test "X${with_pkg_config_prog}" != X; then
 194    if test "${with_pkg_config_prog}" != yes; then
 195       PKG_CONFIG="${with_pkg_config_prog}"
 196    fi
 197 fi
 198
 199 CRT_DIR=
 200 AC_ARG_WITH([crt-dir],dnl
 201 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 202 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 203 CRT_DIR="${with_crt_dir}"
 204
 205 AC_ARG_WITH(gameuser,dnl
 206 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 207 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 208   && gameuser="${with_gameuser}"
 209 test "X$gameuser" = X && gameuser=games
 210
 211 AC_ARG_WITH([gnustep-conf],dnl
 212 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 213 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 214   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 215 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 216      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 217
 218 AC_ARG_ENABLE(ns-self-contained,
 219 [AS_HELP_STRING([--disable-ns-self-contained],
 220                 [disable self contained build under NeXTstep])],
 221    EN_NS_SELF_CONTAINED=$enableval,
 222    EN_NS_SELF_CONTAINED=yes)
 223
 224 AC_ARG_ENABLE(asserts,
 225 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 226       USE_XASSERTS=$enableval,
 227       USE_XASSERTS=no)
 228
 229 AC_ARG_ENABLE(maintainer-mode,
 230 [AS_HELP_STRING([--enable-maintainer-mode],
 231                 [enable make rules and dependencies not useful (and sometimes
 232                  confusing) to the casual installer])],
 233       USE_MAINTAINER_MODE=$enableval,
 234       USE_MAINTAINER_MODE=no)
 235 if test $USE_MAINTAINER_MODE = yes; then
 236   MAINT=
 237 else
 238   MAINT=#
 239 fi
 240 AC_SUBST(MAINT)
 241
 242 AC_ARG_ENABLE(locallisppath,
 243 [AS_HELP_STRING([--enable-locallisppath=PATH],
 244                 [directories Emacs should search for lisp files specific
 245                  to this site])],
 246 if test "${enableval}" = "no"; then
 247   locallisppath=
 248 elif test "${enableval}" != "yes"; then
 249   locallisppath=${enableval}
 250 fi)
 251
 252 AC_ARG_ENABLE(checking,
 253 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 254                 [enable expensive run-time checks.  With LIST,
 255                  enable only specific categories of checks.
 256                  Categories are: all,yes,no.
 257                  Flags are: stringbytes, stringoverrun, stringfreelist,
 258                  xmallocoverrun, conslist])],
 259 [ac_checking_flags="${enableval}"],[])
 260 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 261 for check in $ac_checking_flags
 262 do
 263         case $check in
 264         # these set all the flags to specific states
 265         yes)            ac_enable_checking=1 ;;
 266         no)             ac_enable_checking= ;
 267                         ac_gc_check_stringbytes= ;
 268                         ac_gc_check_string_overrun= ;
 269                         ac_gc_check_string_free_list= ;
 270                         ac_xmalloc_overrun= ;
 271                         ac_gc_check_cons_list= ;;
 272         all)            ac_enable_checking=1 ;
 273                         ac_gc_check_stringbytes=1 ;
 274                         ac_gc_check_string_overrun=1 ;
 275                         ac_gc_check_string_free_list=1 ;
 276                         ac_xmalloc_overrun=1 ;
 277                         ac_gc_check_cons_list=1 ;;
 278         # these enable particular checks
 279         stringbytes)    ac_gc_check_stringbytes=1 ;;
 280         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 281         stringfreelist) ac_gc_check_string_free_list=1 ;;
 282         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 283         conslist)       ac_gc_check_cons_list=1 ;;
 284         *)      AC_MSG_ERROR(unknown check category $check) ;;
 285         esac
 286 done
 287 IFS="$ac_save_IFS"
 288
 289 if test x$ac_enable_checking != x ; then
 290   AC_DEFINE(ENABLE_CHECKING, 1,
 291 [Enable expensive run-time checking of data types?])
 292 fi
 293 if test x$ac_gc_check_stringbytes != x ; then
 294   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 295 [Define this temporarily to hunt a bug.  If defined, the size of
 296    strings is redundantly recorded in sdata structures so that it can
 297    be compared to the sizes recorded in Lisp strings.])
 298 fi
 299 if test x$ac_gc_check_stringoverrun != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 301 [Define this to check for short string overrun.])
 302 fi
 303 if test x$ac_gc_check_string_free_list != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 305 [Define this to check the string free list.])
 306 fi
 307 if test x$ac_xmalloc_overrun != x ; then
 308   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 309 [Define this to check for malloc buffer overrun.])
 310 fi
 311 if test x$ac_gc_check_cons_list != x ; then
 312   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 313 [Define this to check for errors in cons list.])
 314 fi
 315
 316 AC_ARG_ENABLE(use-lisp-union-type,
 317 [AS_HELP_STRING([--enable-use-lisp-union-type],
 318                 [use a union for the Lisp_Object data type.
 319                 This is only useful for development for catching certain types of bugs.])],
 320 if test "${enableval}" != "no"; then
 321    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 322    [Define this to use a lisp union for the Lisp_Object data type.])
 323 fi)
 324
 325
 326 AC_ARG_ENABLE(profiling,
 327 [AS_HELP_STRING([--enable-profiling],
 328                 [build emacs with profiling support.
 329                  This might not work on all platforms])],
 330 [ac_enable_profiling="${enableval}"],[])
 331 if test x$ac_enable_profiling != x ; then
 332    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 333 else
 334    PROFILING_CFLAGS=
 335 fi
 336 AC_SUBST(PROFILING_CFLAGS)
 337
 338 AC_ARG_ENABLE(autodepend,
 339 [AS_HELP_STRING([--enable-autodepend],
 340                 [automatically generate dependencies to .h-files.
 341                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 342                  found])],
 343 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 344
 345 #### Make srcdir absolute, if it isn't already.  It's important to
 346 #### avoid running the path through pwd unnecessarily, since pwd can
 347 #### give you automounter prefixes, which can go away.  We do all this
 348 #### so Emacs can find its files when run uninstalled.
 349 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 350 unset CDPATH
 351 case "${srcdir}" in
 352   /* ) ;;
 353   . )
 354     ## We may be able to use the $PWD environment variable to make this
 355     ## absolute.  But sometimes PWD is inaccurate.
 356     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 357     ## but that tested only for a well-formed and valid PWD,
 358     ## it did not object when PWD was well-formed and valid but just wrong.
 359     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 360     then
 361       srcdir="$PWD"
 362     else
 363       srcdir="`(cd ${srcdir}; pwd)`"
 364     fi
 365   ;;
 366   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 367 esac
 368
 369 #### Check if the source directory already has a configured system in it.
 370 if test `pwd` != `(cd ${srcdir} && pwd)` \
 371    && test -f "${srcdir}/src/config.h" ; then
 372   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 373    as a build directory right now; it has been configured in its own
 374    right.  To configure in another directory as well, you MUST
 375    use GNU make.  If you do not have GNU make, then you must
 376    now do `make distclean' in ${srcdir},
 377    and then run $0 again.]])
 378 fi
 379
 380 #### Given the configuration name, set machfile and opsysfile to the
 381 #### names of the m/*.h and s/*.h files we should use.
 382
 383 ### Canonicalize the configuration name.
 384
 385 AC_CANONICAL_HOST
 386 canonical=$host
 387 configuration=${host_alias-${build_alias-$host}}
 388
 389 dnl This used to use changequote, but, apart from `changequote is evil'
 390 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 391 dnl the great gob of text.  Thus it's not processed for possible expansion.
 392 dnl Just make sure the brackets remain balanced.
 393 dnl
 394 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 395 dnl indicated by comments.
 396 dnl quotation begins
 397 [
 398
 399 ### If you add support for a new configuration, add code to this
 400 ### switch statement to recognize your configuration name and select
 401 ### the appropriate operating system and machine description files.
 402
 403 ### You would hope that you could choose an m/*.h file pretty much
 404 ### based on the machine portion of the configuration name, and an s/*.h
 405 ### file based on the operating system portion.  However, it turns out
 406 ### that each m/*.h file is pretty manufacturer-specific - for
 407 ### example mips.h is MIPS
 408 ### So we basically have to have a special case for each
 409 ### configuration name.
 410 ###
 411 ### As far as handling version numbers on operating systems is
 412 ### concerned, make sure things will fail in a fixable way.  If
 413 ### /etc/MACHINES doesn't say anything about version numbers, be
 414 ### prepared to handle anything reasonably.  If version numbers
 415 ### matter, be sure /etc/MACHINES says something about it.
 416
 417 machine='' opsys='' unported=no
 418 case "${canonical}" in
 419
 420   ## GNU/Linux ports
 421   *-*-linux-gnu*)
 422     opsys=gnu-linux
 423     case ${canonical} in
 424       alpha*)   machine=alpha ;;
 425       s390-*)   machine=ibms390 ;;
 426       s390x-*)  machine=ibms390x ;;
 427       powerpc*) machine=macppc ;;
 428       sparc*)   machine=sparc ;;
 429       ia64*)    machine=ia64 ;;
 430       m68k*)    machine=m68k ;;
 431       x86_64*)  machine=amdx86-64 ;;
 432     esac
 433   ;;
 434
 435   ## FreeBSD ports
 436   *-*-freebsd* )
 437     opsys=freebsd
 438     case "${canonical}" in
 439       alpha*)           machine=alpha ;;
 440       amd64-*|x86_64-*) machine=amdx86-64 ;;
 441       ia64-*)           machine=ia64 ;;
 442       i[3456]86-*)      machine=intel386 ;;
 443       powerpc-*)        machine=macppc ;;
 444       sparc-*)          machine=sparc ;;
 445       sparc64-*)        machine=sparc ;;
 446     esac
 447   ;;
 448
 449   ## FreeBSD kernel + glibc based userland
 450   *-*-kfreebsd*gnu* )
 451     opsys=gnu-kfreebsd
 452     case "${canonical}" in
 453       alpha*)           machine=alpha ;;
 454       amd64-*|x86_64-*) machine=amdx86-64 ;;
 455       ia64-*)           machine=ia64 ;;
 456       i[3456]86-*)      machine=intel386 ;;
 457       powerpc-*)        machine=macppc ;;
 458       sparc-*)          machine=sparc ;;
 459       sparc64-*)        machine=sparc ;;
 460     esac
 461   ;;
 462
 463   ## NetBSD ports
 464   *-*-netbsd* )
 465     opsys=netbsd
 466     case "${canonical}" in
 467       alpha*)      machine=alpha ;;
 468       x86_64-*)    machine=amdx86-64 ;;
 469       i[3456]86-*) machine=intel386 ;;
 470       m68k-*)      machine=m68k ;;
 471       powerpc-*)   machine=macppc ;;
 472       sparc*-)     machine=sparc ;;
 473       vax-*)       machine=vax ;;
 474     esac
 475   ;;
 476
 477   ## OpenBSD ports
 478   *-*-openbsd* )
 479     opsys=openbsd
 480     case "${canonical}" in
 481       alpha*)    machine=alpha ;;
 482       x86_64-*)  machine=amdx86-64 ;;
 483       i386-*)    machine=intel386 ;;
 484       powerpc-*) machine=macppc ;;
 485       sparc*)    machine=sparc ;;
 486       vax-*)     machine=vax ;;
 487     esac
 488   ;;
 489
 490   ## Apple Darwin / Mac OS X
 491   *-apple-darwin* )
 492     case "${canonical}" in
 493       i[3456]86-* )  machine=intel386 ;;
 494       powerpc-* )    machine=macppc ;;
 495       x86_64-* )     machine=amdx86-64 ;;
 496       * )            unported=yes ;;
 497     esac
 498     opsys=darwin
 499     # Define CPP as follows to make autoconf work correctly.
 500     CPP="${CC-cc} -E -no-cpp-precomp"
 501     # Use fink packages if available.
 502     if test -d /sw/include && test -d /sw/lib; then
 503       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 504       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 505       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 506     fi
 507   ;;
 508
 509   ## HP 9000 series 700 and 800, running HP/UX
 510   hppa*-hp-hpux10.2* )
 511     opsys=hpux10-20
 512   ;;
 513   hppa*-hp-hpux1[1-9]* )
 514     opsys=hpux11
 515     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 516   ;;
 517
 518   ## IBM machines
 519   rs6000-ibm-aix4.[23]* )
 520     machine=ibmrs6000 opsys=aix4-2
 521   ;;
 522   powerpc-ibm-aix4.[23]*  )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525   rs6000-ibm-aix[56]* )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   powerpc-ibm-aix[56]*  )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531
 532   ## Silicon Graphics machines
 533   ## Iris 4D
 534   mips-sgi-irix6.5 )
 535     machine=iris4d opsys=irix6-5
 536     # Without defining _LANGUAGE_C, things get masked out in the headers
 537     # so that, for instance, grepping for `free' in stdlib.h fails and
 538     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 539     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 540     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 541   ;;
 542
 543   ## Suns
 544   *-sun-solaris* \
 545     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 546     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 547     case "${canonical}" in
 548       i[3456]86-*-* )     machine=intel386 ;;
 549       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 550       sparc* )          machine=sparc ;;
 551       * )               unported=yes ;;
 552     esac
 553     case "${canonical}" in
 554       *-sunos5.6* | *-solaris2.6* )
 555                 opsys=sol2-6
 556                 NON_GNU_CPP=/usr/ccs/lib/cpp
 557                 RANLIB="ar -ts"
 558                 ;;
 559       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 560                 opsys=sol2-6
 561                 emacs_check_sunpro_c=yes
 562                 NON_GNU_CPP=/usr/ccs/lib/cpp
 563                 ;;
 564       *-sunos5* | *-solaris* )
 565                 opsys=sol2-10
 566                 emacs_check_sunpro_c=yes
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 ;;
 569     esac
 570     ## Watch out for a compiler that we know will not work.
 571     case "${canonical}" in
 572      *-solaris* | *-sunos5* )
 573                 if [ "x$CC" = x/usr/ucb/cc ]; then
 574                   ## /usr/ucb/cc doesn't work;
 575                   ## we should find some other compiler that does work.
 576                   unset CC
 577                 fi
 578                 ;;
 579       *) ;;
 580     esac
 581   ;;
 582
 583   ## Intel 386 machines where we don't care about the manufacturer.
 584   i[3456]86-*-* )
 585     machine=intel386
 586     case "${canonical}" in
 587       *-cygwin )                opsys=cygwin ;;
 588       *-darwin* )               opsys=darwin
 589                                 CPP="${CC-cc} -E -no-cpp-precomp"
 590                                 ;;
 591       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 593       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 594       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 595     esac
 596   ;;
 597
 598   * )
 599     unported=yes
 600   ;;
 601 esac
 602
 603 ### If the code above didn't choose an operating system, just choose
 604 ### an operating system based on the configuration name.  You really
 605 ### only want to use this when you have no idea what the right
 606 ### operating system is; if you know what operating systems a machine
 607 ### runs, it's cleaner to make it explicit in the case statement
 608 ### above.
 609 if test x"${opsys}" = x; then
 610   case "${canonical}" in
 611     *-gnu* )                            opsys=gnu ;;
 612     * )
 613       unported=yes
 614     ;;
 615   esac
 616 fi
 617
 618 ]
 619 dnl quotation ends
 620
 621 if test $unported = yes; then
 622   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 623 Check `etc/MACHINES' for recognized configuration names.])
 624 fi
 625
 626 if test -n "$machine"; then
 627   machfile="m/${machine}.h"
 628 else
 629   machfile=
 630 fi
 631 opsysfile="s/${opsys}.h"
 632
 633
 634 #### Choose a compiler.
 635 test -n "$CC" && cc_specified=yes
 636
 637 # Save the value of CFLAGS that the user specified.
 638 SPECIFIED_CFLAGS="$CFLAGS"
 639
 640 dnl Sets GCC=yes if using gcc.
 641 AC_PROG_CC
 642 AM_PROG_CC_C_O
 643
 644 # Initialize gnulib right after verifying that the C compiler works.
 645 gl_EARLY
 646
 647 # On Suns, sometimes $CPP names a directory.
 648 if test -n "$CPP" && test -d "$CPP"; then
 649   CPP=
 650 fi
 651
 652 ## If not using gcc, and on Solaris, and no CPP specified, see if
 653 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 654 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 655  test x"$CPP" = x; then
 656   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 657   AC_CACHE_VAL(emacs_cv_sunpro_c,
 658   [AC_TRY_LINK([],
 659 [#ifndef __SUNPRO_C
 660 fail;
 661 #endif
 662 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 663   AC_MSG_RESULT($emacs_cv_sunpro_c)
 664
 665   if test x"$emacs_cv_sunpro_c" = xyes; then
 666     NON_GNU_CPP="$CC -E -Xs"
 667   fi
 668 fi
 669
 670 #### Some systems specify a CPP to use unless we are using GCC.
 671 #### Now that we know whether we are using GCC, we can decide whether
 672 #### to use that one.
 673 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 674 then
 675   CPP="$NON_GNU_CPP"
 676 fi
 677
 678 #### Some systems specify a CC to use unless we are using GCC.
 679 #### Now that we know whether we are using GCC, we can decide whether
 680 #### to use that one.
 681 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 682   test x$cc_specified != xyes
 683 then
 684   CC="$NON_GNU_CC"
 685 fi
 686
 687 if test x$GCC = xyes; then
 688   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 689 else
 690   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 691 fi
 692
 693 ### Use -Wno-pointer-sign if the compiler supports it
 694 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 695 SAVE_CFLAGS="$CFLAGS"
 696 CFLAGS="$CFLAGS -Wno-pointer-sign"
 697 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 698 if test $has_option = yes; then
 699    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 700 fi
 701 AC_MSG_RESULT($has_option)
 702 CFLAGS="$SAVE_CFLAGS"
 703 unset has_option
 704 unset SAVE_CFLAGS
 705
 706 ### Use -Wdeclaration-after-statement if the compiler supports it
 707 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 708 SAVE_CFLAGS="$CFLAGS"
 709 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 710 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 711 if test $has_option = yes; then
 712    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 713 fi
 714 AC_MSG_RESULT($has_option)
 715 CFLAGS="$SAVE_CFLAGS"
 716 unset has_option
 717 unset SAVE_CFLAGS
 718
 719 ### Use -Wold-style-definition if the compiler supports it
 720 # This can be removed when conversion to standard C is finished.
 721 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 722 SAVE_CFLAGS="$CFLAGS"
 723 CFLAGS="$CFLAGS -Wold-style-definition"
 724 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 725 if test $has_option = yes; then
 726    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 727 fi
 728 AC_MSG_RESULT($has_option)
 729 CFLAGS="$SAVE_CFLAGS"
 730 unset has_option
 731 unset SAVE_CFLAGS
 732
 733 ### Use -Wimplicit-function-declaration if the compiler supports it
 734 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 735 SAVE_CFLAGS="$CFLAGS"
 736 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 737 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 738 if test $has_option = yes; then
 739    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 740 fi
 741 AC_MSG_RESULT($has_option)
 742 CFLAGS="$SAVE_CFLAGS"
 743 unset has_option
 744 unset SAVE_CFLAGS
 745
 746 AC_SUBST(C_WARNINGS_SWITCH)
 747
 748
 749 #### Some other nice autoconf tests.
 750
 751 dnl checks for programs
 752 AC_PROG_CPP
 753 AC_PROG_INSTALL
 754 if test "x$RANLIB" = x; then
 755   AC_PROG_RANLIB
 756 fi
 757
 758 ## Although we're running on an amd64 kernel, we're actually compiling for
 759 ## the x86 architecture.  The user should probably have provided an
 760 ## explicit --build to `configure', but if everything else than the kernel
 761 ## is running in i386 mode, we can help them out.
 762 if test "$machine" = "amdx86-64"; then
 763   AC_CHECK_DECL([i386])
 764   if test "$ac_cv_have_decl_i386" = "yes"; then
 765     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 766     machine=intel386
 767     machfile="m/${machine}.h"
 768   fi
 769 fi
 770
 771 AC_PATH_PROG(INSTALL_INFO, install-info)
 772 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 773 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 774 dnl Don't use GZIP, which is used by gzip for additional parameters.
 775 AC_PATH_PROG(GZIP_PROG, gzip)
 776
 777
 778 ## Need makeinfo >= 4.6 (?) to build the manuals.
 779 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 780 dnl By this stage, configure has already checked for egrep and set EGREP,
 781 dnl or exited with an error if no egrep was found.
 782 if test "$MAKEINFO" != "no" && \
 783   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 784    MAKEINFO=no
 785 fi
 786
 787 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 788 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 789 ## therefore in the category of "special tools" not normally required, which
 790 ## configure does not have to check for (eg autoconf itself).
 791 ## In a Bazaar checkout on the other hand, the manuals are not included.
 792 ## So makeinfo is a requirement to build from Bazaar, and configure
 793 ## should test for it as it does for any other build requirement.
 794 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 795 ## with pre-built manuals, from a Bazaar checkout.
 796 HAVE_MAKEINFO=yes
 797
 798 if test "$MAKEINFO" = "no"; then
 799   MAKEINFO=makeinfo
 800   if test "x${with_makeinfo}" = "xno"; then
 801     HAVE_MAKEINFO=no
 802   elif test ! -e $srcdir/info/emacs; then
 803     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 804 source tree does not seem to have pre-built manuals in the `info' directory.
 805 Either install a suitable version of makeinfo, or re-run configure
 806 with the `--without-makeinfo' option to build without the manuals.] )
 807   fi
 808 fi
 809 AC_SUBST(HAVE_MAKEINFO)
 810
 811 dnl Add our options to ac_link now, after it is set up.
 812
 813 if test x$GCC = xyes; then
 814   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 815     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 816 else
 817   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 818     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 819 fi
 820
 821 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 822 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 823 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 824 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 825 dnl if not built to support GNU ld.
 826
 827 late_LDFLAGS=$LDFLAGS
 828 if test x$GCC = xyes; then
 829   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 830 else
 831   LDFLAGS="$LDFLAGS -znocombreloc"
 832 fi
 833
 834 AC_MSG_CHECKING([for -znocombreloc])
 835 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 836   [AC_MSG_RESULT(yes)],
 837   LDFLAGS=$late_LDFLAGS
 838   [AC_MSG_RESULT(no)])
 839
 840
 841 # The value of CPP is a quoted variable reference, so we need to do this
 842 # to get its actual value...
 843 CPP=`eval "echo $CPP"`
 844
 845
 846 dnl Not used by any currently supported platform.
 847 dnl The function dump-emacs will not be defined and temacs will do
 848 dnl (load "loadup") automatically unless told otherwise.
 849 CANNOT_DUMP=no
 850 case "$opsys" in
 851   your-opsys-here)
 852    CANNOT_DUMP=yes
 853    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 854   ;;
 855 esac
 856 AC_SUBST(CANNOT_DUMP)
 857
 858
 859 UNEXEC_OBJ=unexelf.o
 860 case "$opsys" in
 861   # MSDOS uses unexcoff.o
 862   # MSWindows uses unexw32.o
 863   aix4-2)
 864    UNEXEC_OBJ=unexaix.o
 865    ;;
 866   cygwin)
 867    UNEXEC_OBJ=unexcw.o
 868    ;;
 869   darwin)
 870    UNEXEC_OBJ=unexmacosx.o
 871    ;;
 872   hpux10-20 | hpux11)
 873    UNEXEC_OBJ=unexhp9k800.o
 874    ;;
 875   sol2-10)
 876    # Use the Solaris dldump() function, called from unexsol.c, to dump
 877    # emacs, instead of the generic ELF dump code found in unexelf.c.
 878    # The resulting binary has a complete symbol table, and is better
 879    # for debugging and other observability tools (debuggers, pstack, etc).
 880    #
 881    # If you encounter a problem using dldump(), please consider sending
 882    # a message to the OpenSolaris tools-linking mailing list:
 883    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 884    #
 885    # It is likely that dldump() works with older Solaris too, but this has
 886    # not been tested, so for now this change is for Solaris 10 or newer.
 887    UNEXEC_OBJ=unexsol.o
 888    ;;
 889 esac
 890
 891 LD_SWITCH_SYSTEM=
 892 case "$opsys" in
 893   freebsd)
 894    ## Let `ld' find image libs and similar things in /usr/local/lib.
 895    ## The system compiler, GCC, has apparently been modified to not
 896    ## look there, contrary to what a stock GCC would do.
 897    LD_SWITCH_SYSTEM=-L/usr/local/lib
 898    ;;
 899
 900   gnu-linux)
 901    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 902    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 903    ;;
 904
 905   netbsd)
 906    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 907    ;;
 908
 909   openbsd)
 910    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 911    ## otherwise Emacs dumps core on elf systems.
 912    LD_SWITCH_SYSTEM="-Z"
 913    ;;
 914 esac
 915 AC_SUBST(LD_SWITCH_SYSTEM)
 916
 917 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 918
 919 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 920 ## which has not been defined yet.  When this was handled with cpp,
 921 ## it was expanded to null when configure sourced the s/*.h file.
 922 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 923 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 924 ## (or somesuch), but because it is supposed to go at the _front_
 925 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 926 ## Compare with the gnu-linux case below, which added to the end
 927 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 928 ## LD_SWITCH_SYSTEM_TEMACS.
 929 case "$opsys" in
 930   netbsd|openbsd)
 931    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 932    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 933 esac
 934
 935
 936 C_SWITCH_MACHINE=
 937 if test "$machine" = "alpha"; then
 938   AC_CHECK_DECL([__ELF__])
 939   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 940     ## With ELF, make sure that all common symbols get allocated to in the
 941     ## data section.  Otherwise, the dump of temacs may miss variables in
 942     ## the shared library that have been initialized.  For example, with
 943     ## GNU libc, __malloc_initialized would normally be resolved to the
 944     ## shared library's .bss section, which is fatal.
 945     if test "x$GCC" = "xyes"; then
 946       C_SWITCH_MACHINE="-fno-common"
 947     else
 948       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 949     fi
 950   else
 951     UNEXEC_OBJ=unexalpha.o
 952   fi
 953 fi
 954 AC_SUBST(C_SWITCH_MACHINE)
 955
 956 AC_SUBST(UNEXEC_OBJ)
 957
 958 C_SWITCH_SYSTEM=
 959 ## Some programs in src produce warnings saying certain subprograms
 960 ## are too complex and need a MAXMEM value greater than 2000 for
 961 ## additional optimization.  --nils@exp-math.uni-essen.de
 962 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 963   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 964 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 965 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 966 AC_SUBST(C_SWITCH_SYSTEM)
 967
 968
 969 LIBS_SYSTEM=
 970 case "$opsys" in
 971   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 972   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 973
 974   freebsd) LIBS_SYSTEM="-lutil" ;;
 975
 976   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 977
 978   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 979
 980   ## Motif needs -lgen.
 981   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 982 esac
 983 AC_SUBST(LIBS_SYSTEM)
 984
 985
 986 ### Make sure subsequent tests use flags consistent with the build flags.
 987
 988 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 989   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 990 else
 991   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 992 fi
 993
 994 dnl For AC_FUNC_GETLOADAVG, at least:
 995 AC_CONFIG_LIBOBJ_DIR(src)
 996
 997 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 998 AC_SYS_LARGEFILE
 999
1000
1001 ## If user specified a crt-dir, use that unconditionally.
1002 if test "X$CRT_DIR" = "X"; then
1003
1004   case "$canonical" in
1005     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1006     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1007     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1008     ## For anything else (eg /usr/lib32), it is up the user to specify
1009     ## the location (bug#5655).
1010     ## Test for crtn.o, not just the directory, because sometimes the
1011     ## directory exists but does not have the relevant files (bug#1287).
1012     ## FIXME better to test for binary compatibility somehow.
1013     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1014     ;;
1015
1016     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1017   esac
1018
1019   case "$opsys" in
1020     hpux10-20) CRT_DIR=/lib ;;
1021   esac
1022
1023   ## Default is /usr/lib.
1024   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1025
1026 else
1027
1028   ## Some platforms don't use any of these files, so it is not
1029   ## appropriate to put this test outside the if block.
1030   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1031     AC_MSG_ERROR([crt*.o not found in specified location.])
1032
1033 fi
1034
1035 AC_SUBST(CRT_DIR)
1036
1037 LIB_MATH=-lm
1038 LIB_STANDARD=
1039 START_FILES=
1040
1041 case $opsys in
1042   cygwin )
1043     LIB_MATH=
1044     START_FILES='pre-crt0.o'
1045     ;;
1046   darwin )
1047     ## Adding -lm confuses the dynamic linker, so omit it.
1048     LIB_MATH=
1049     START_FILES='pre-crt0.o'
1050     ;;
1051   freebsd )
1052     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1053     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1054     ;;
1055   gnu-linux | gnu-kfreebsd )
1056     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1057     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1058     ;;
1059   hpux10-20 | hpux11 )
1060     LIB_STANDARD=-lc
1061     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1062     ;;
1063   netbsd | openbsd )
1064     if test -f $CRT_DIR/crti.o; then
1065         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1066         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1067     else
1068         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1069         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1070     fi
1071     ;;
1072 esac
1073
1074 AC_SUBST(LIB_MATH)
1075 AC_SUBST(START_FILES)
1076
1077 dnl This function definition taken from Gnome 2.0
1078 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1079 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1080 dnl also defines GSTUFF_PKG_ERRORS on error
1081 AC_DEFUN([PKG_CHECK_MODULES], [
1082   succeeded=no
1083
1084   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1085
1086   if test "$PKG_CONFIG" = "no" ; then
1087      ifelse([$4], , [AC_MSG_ERROR([
1088       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1089   else
1090      PKG_CONFIG_MIN_VERSION=0.9.0
1091      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1092         AC_MSG_CHECKING(for $2)
1093
1094         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1095             AC_MSG_RESULT(yes)
1096             succeeded=yes
1097
1098             AC_MSG_CHECKING($1_CFLAGS)
1099             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1100             AC_MSG_RESULT($$1_CFLAGS)
1101
1102             AC_MSG_CHECKING($1_LIBS)
1103             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1104             AC_MSG_RESULT($$1_LIBS)
1105         else
1106             AC_MSG_RESULT(no)
1107             $1_CFLAGS=""
1108             $1_LIBS=""
1109             ## If we have a custom action on failure, don't print errors, but
1110             ## do set a variable so people can do so.
1111             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1112             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1113         fi
1114
1115         AC_SUBST($1_CFLAGS)
1116         AC_SUBST($1_LIBS)
1117      else
1118         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1119         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1120      fi
1121   fi
1122
1123   if test $succeeded = yes; then
1124      ifelse([$3], , :, [$3])
1125   else
1126      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1127   fi
1128 ])
1129
1130
1131 if test "${with_sound}" != "no"; then
1132   # Sound support for GNU/Linux and the free BSDs.
1133   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1134     have_sound_header=yes)
1135   # Emulation library used on NetBSD.
1136   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1137   AC_SUBST(LIBSOUND)
1138
1139   ALSA_REQUIRED=1.0.0
1140   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1141   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1142   if test $HAVE_ALSA = yes; then
1143     SAVE_CFLAGS="$CFLAGS"
1144     SAVE_LDFLAGS="$LDFLAGS"
1145     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1146     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1147     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1148                     emacs_alsa_normal=yes,
1149                     emacs_alsa_normal=no)
1150     if test "$emacs_alsa_normal" != yes; then
1151       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1152                      [snd_lib_error_set_handler (0);],
1153                      emacs_alsa_subdir=yes,
1154                      emacs_alsa_subdir=no)
1155       if test "$emacs_alsa_subdir" != yes; then
1156         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1157       fi
1158       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1159     fi
1160
1161     CFLAGS="$SAVE_CFLAGS"
1162     LDFLAGS="$SAVE_LDFLAGS"
1163     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1164     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1165     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1166   fi
1167
1168   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1169   dnl compiles only on the specified platforms.  For others, it
1170   dnl probably doesn't make sense to try.
1171   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1172      case "$opsys" in
1173        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1174        gnu-linux|freebsd|netbsd)
1175          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1176          ;;
1177      esac
1178   fi
1179
1180   AC_SUBST(CFLAGS_SOUND)
1181 fi
1182
1183 dnl checks for header files
1184 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1185   linux/version.h sys/systeminfo.h limits.h \
1186   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1187   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1188   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1189
1190 AC_MSG_CHECKING(if personality LINUX32 can be set)
1191 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1192                emacs_cv_personality_linux32=yes,
1193                emacs_cv_personality_linux32=no)
1194 AC_MSG_RESULT($emacs_cv_personality_linux32)
1195
1196 if test $emacs_cv_personality_linux32 = yes; then
1197   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1198             [Define to 1 if personality LINUX32 can be set.])
1199 fi
1200
1201 dnl On Solaris 8 there's a compilation warning for term.h because
1202 dnl it doesn't define `bool'.
1203 AC_CHECK_HEADERS(term.h, , , -)
1204 AC_HEADER_STDC
1205 AC_HEADER_TIME
1206 AC_CHECK_DECLS([sys_siglist])
1207 if test $ac_cv_have_decl_sys_siglist != yes; then
1208   # For Tru64, at least:
1209   AC_CHECK_DECLS([__sys_siglist])
1210   if test $ac_cv_have_decl___sys_siglist = yes; then
1211     AC_DEFINE(sys_siglist, __sys_siglist,
1212               [Define to any substitute for sys_siglist.])
1213   fi
1214 fi
1215 AC_HEADER_SYS_WAIT
1216
1217 dnl Some systems have utime.h but don't declare the struct anyplace.
1218 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1219 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1220 #include <sys/time.h>
1221 #include <time.h>
1222 #else
1223 #ifdef HAVE_SYS_TIME_H
1224 #include <sys/time.h>
1225 #else
1226 #include <time.h>
1227 #endif
1228 #endif
1229 #ifdef HAVE_UTIME_H
1230 #include <utime.h>
1231 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1232   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1233 if test $emacs_cv_struct_utimbuf = yes; then
1234   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1235 fi
1236
1237 dnl checks for typedefs
1238 AC_TYPE_SIGNAL
1239
1240 dnl Check for speed_t typedef.
1241 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1242   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1243     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1244 if test $emacs_cv_speed_t = yes; then
1245   AC_DEFINE(HAVE_SPEED_T, 1,
1246            [Define to 1 if `speed_t' is declared by <termios.h>.])
1247 fi
1248
1249 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1250 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1251 #include <sys/time.h>
1252 #include <time.h>
1253 #else
1254 #ifdef HAVE_SYS_TIME_H
1255 #include <sys/time.h>
1256 #else
1257 #include <time.h>
1258 #endif
1259 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1260   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1261 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1262 if test $emacs_cv_struct_timeval = yes; then
1263   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1264 fi
1265
1266 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1267 AC_TRY_COMPILE([#include <math.h>],
1268 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1269   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1270 HAVE_EXCEPTION=$emacs_cv_struct_exception
1271 if test $emacs_cv_struct_exception != yes; then
1272   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1273 fi
1274
1275 AC_CHECK_HEADERS(sys/socket.h)
1276 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1277 #if HAVE_SYS_SOCKET_H
1278 #include <sys/socket.h>
1279 #endif])
1280
1281 dnl checks for structure members
1282 AC_STRUCT_TM
1283 AC_STRUCT_TIMEZONE
1284 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1285                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1286                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1287                 [#include <time.h>])
1288 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1289                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1290                   struct ifreq.ifr_addr], , ,
1291                  [AC_INCLUDES_DEFAULT
1292 #if HAVE_SYS_SOCKET_H
1293 #include <sys/socket.h>
1294 #endif
1295 #if HAVE_NET_IF_H
1296 #include <net/if.h>
1297 #endif])
1298
1299 dnl checks for compiler characteristics
1300
1301 dnl Testing __STDC__ to determine prototype support isn't good enough.
1302 dnl DEC C, for instance, doesn't define it with default options, and
1303 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1304 dnl and void *.
1305 AC_C_PROTOTYPES
1306 AC_C_VOLATILE
1307 AC_C_CONST
1308 dnl This isn't useful because we can't turn on use of `inline' unless
1309 dnl the compiler groks `extern inline'.
1310 dnl AC_C_INLINE
1311 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1312   [AC_TRY_COMPILE(, [void * foo;],
1313                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1314 if test $emacs_cv_void_star = yes; then
1315   AC_DEFINE(POINTER_TYPE, void)
1316 else
1317   AC_DEFINE(POINTER_TYPE, char)
1318 fi
1319 AH_TEMPLATE(POINTER_TYPE,
1320             [Define as `void' if your compiler accepts `void *'; otherwise
1321              define as `char'.])dnl
1322
1323 dnl Check for endianess
1324 AC_C_BIGENDIAN
1325
1326 dnl check for Make feature
1327 AC_PROG_MAKE_SET
1328
1329 DEPFLAGS=
1330 MKDEPDIR=":"
1331 deps_frag=deps.mk
1332 dnl check for GNU Make if we have GCC and autodepend is on.
1333 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1334    AC_MSG_CHECKING([whether we are using GNU Make])
1335    HAVE_GNU_MAKE=no
1336    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1337    if test "x$testval" != x; then
1338       HAVE_GNU_MAKE=yes
1339    else
1340       ac_enable_autodepend=no
1341    fi
1342    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1343    if test $HAVE_GNU_MAKE = yes; then
1344       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1345       SAVE_CFLAGS="$CFLAGS"
1346       CFLAGS="$CFLAGS -MMD -MF deps.d"
1347       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1348       CFLAGS="$SAVE_CFLAGS"
1349       test -f deps.d || ac_enable_autodepend=no
1350       rm -rf deps.d
1351       AC_MSG_RESULT([$ac_enable_autodepend])
1352    fi
1353    if test $ac_enable_autodepend = yes; then
1354       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1355       ## In parallel builds, another make might create depdir between
1356       ## the first test and mkdir, so stick another test on the end.
1357       ## Or use mkinstalldirs?  mkdir -p is not portable.
1358       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1359       deps_frag=autodeps.mk
1360    fi
1361 fi
1362 deps_frag=$srcdir/src/$deps_frag
1363 AC_SUBST(MKDEPDIR)
1364 AC_SUBST(DEPFLAGS)
1365 AC_SUBST_FILE(deps_frag)
1366
1367
1368 dnl checks for operating system services
1369 AC_SYS_LONG_FILE_NAMES
1370
1371 #### Choose a window system.
1372
1373 AC_PATH_X
1374 if test "$no_x" = yes; then
1375   window_system=none
1376 else
1377   window_system=x11
1378 fi
1379
1380 ## Workaround for bug in autoconf <= 2.62.
1381 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1382 ## No need to do anything special for these standard directories.
1383 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1384
1385    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1386
1387 fi
1388
1389 LD_SWITCH_X_SITE_AUX=
1390 LD_SWITCH_X_SITE_AUX_RPATH=
1391 if test "${x_libraries}" != NONE; then
1392   if test -n "${x_libraries}"; then
1393     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1394     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1395     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1396   fi
1397   x_default_search_path=""
1398   x_search_path=${x_libraries}
1399   if test -z "${x_search_path}"; then
1400     x_search_path=/usr/lib
1401   fi
1402   for x_library in `echo ${x_search_path}: | \
1403                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1404     x_search_path="\
1405 ${x_library}/X11/%L/%T/%N%C%S:\
1406 ${x_library}/X11/%l/%T/%N%C%S:\
1407 ${x_library}/X11/%T/%N%C%S:\
1408 ${x_library}/X11/%L/%T/%N%S:\
1409 ${x_library}/X11/%l/%T/%N%S:\
1410 ${x_library}/X11/%T/%N%S"
1411     if test x"${x_default_search_path}" = x; then
1412       x_default_search_path=${x_search_path}
1413     else
1414       x_default_search_path="${x_search_path}:${x_default_search_path}"
1415     fi
1416   done
1417 fi
1418 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1419 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1420
1421 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1422   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1423 fi
1424
1425 if test x"${x_includes}" = x; then
1426   bitmapdir=/usr/include/X11/bitmaps
1427 else
1428   # accumulate include directories that have X11 bitmap subdirectories
1429   bmd_acc="dummyval"
1430   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1431     if test -d "${bmd}/X11/bitmaps"; then
1432       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1433     fi
1434     if test -d "${bmd}/bitmaps"; then
1435       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1436     fi
1437   done
1438   if test ${bmd_acc} != "dummyval"; then
1439     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1440   fi
1441 fi
1442
1443 HAVE_NS=no
1444 NS_IMPL_COCOA=no
1445 NS_IMPL_GNUSTEP=no
1446 tmp_CPPFLAGS="$CPPFLAGS"
1447 tmp_CFLAGS="$CFLAGS"
1448 CPPFLAGS="$CPPFLAGS -x objective-c"
1449 CFLAGS="$CFLAGS -x objective-c"
1450 TEMACS_LDFLAGS2="\${LDFLAGS}"
1451 dnl I don't think it's especially important, but src/Makefile.in
1452 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1453 dnl trailing "/" to it, so now we do it here.
1454 if test "${with_ns}" != no; then
1455   if test "${opsys}" = darwin; then
1456      NS_IMPL_COCOA=yes
1457      ns_appdir=`pwd`/nextstep/Emacs.app
1458      ns_appbindir=${ns_appdir}/Contents/MacOS/
1459      ns_appresdir=${ns_appdir}/Contents/Resources
1460      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1461   elif test -f $GNUSTEP_CONFIG_FILE; then
1462      NS_IMPL_GNUSTEP=yes
1463      ns_appdir=`pwd`/nextstep/Emacs.app
1464      ns_appbindir=${ns_appdir}/
1465      ns_appresdir=${ns_appdir}/Resources
1466      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1467      dnl FIXME sourcing this several times in subshells seems inefficient.
1468      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1469      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1470      dnl I seemed to need these as well with GNUstep-startup 0.25.
1471      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1472      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1473      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1474        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1475      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1476        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1477      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1478      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1479      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1480      LIB_STANDARD=
1481      START_FILES=
1482      TEMACS_LDFLAGS2=
1483   fi
1484   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1485                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1486   files are missing or cannot be compiled.])])
1487   NS_HAVE_NSINTEGER=yes
1488   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1489                                      [NSInteger i;])],
1490                     ns_have_nsinteger=yes,
1491                     ns_have_nsinteger=no)
1492   if test $ns_have_nsinteger = no; then
1493     NS_HAVE_NSINTEGER=no
1494   fi
1495 fi
1496 AC_SUBST(TEMACS_LDFLAGS2)
1497
1498 ns_frag=/dev/null
1499 NS_OBJ=
1500 NS_SUPPORT=
1501 if test "${HAVE_NS}" = yes; then
1502   window_system=nextstep
1503   with_xft=no
1504   # set up packaging dirs
1505   exec_prefix=${ns_appbindir}
1506   libexecdir=${ns_appbindir}/libexec
1507   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1508      prefix=${ns_appresdir}
1509   fi
1510   ns_frag=$srcdir/src/ns.mk
1511   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1512   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1513 fi
1514 CFLAGS="$tmp_CFLAGS"
1515 CPPFLAGS="$tmp_CPPFLAGS"
1516 AC_SUBST(NS_OBJ)
1517 AC_SUBST(NS_SUPPORT)
1518 AC_SUBST(LIB_STANDARD)
1519 AC_SUBST_FILE(ns_frag)
1520
1521 case "${window_system}" in
1522   x11 )
1523     HAVE_X_WINDOWS=yes
1524     HAVE_X11=yes
1525     case "${with_x_toolkit}" in
1526       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1527       motif ) USE_X_TOOLKIT=MOTIF ;;
1528       gtk ) with_gtk=yes
1529 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1530 dnl USE_X_TOOLKIT is set.
1531             USE_X_TOOLKIT=none ;;
1532       gtk3 ) with_gtk3=yes
1533              USE_X_TOOLKIT=none ;;
1534       no ) USE_X_TOOLKIT=none ;;
1535 dnl If user did not say whether to use a toolkit, make this decision later:
1536 dnl use the toolkit if we have gtk, or X11R5 or newer.
1537       * ) USE_X_TOOLKIT=maybe ;;
1538     esac
1539   ;;
1540   nextstep | none )
1541     HAVE_X_WINDOWS=no
1542     HAVE_X11=no
1543     USE_X_TOOLKIT=none
1544   ;;
1545 esac
1546
1547 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1548    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1549    if test "$HAVE_XSERVER" = true ||
1550       test -n "$DISPLAY" ||
1551       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1552         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1553 were found.  You should install the relevant development files for X
1554 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1555 sure you have development files for image handling, i.e.
1556 tiff, gif, jpeg, png and xpm.
1557 If you are sure you want Emacs compiled without X window support, pass
1558   --without-x
1559 to configure.])
1560    fi
1561 fi
1562
1563 ### If we're using X11, we should use the X menu package.
1564 HAVE_MENUS=no
1565 case ${HAVE_X11} in
1566   yes ) HAVE_MENUS=yes ;;
1567 esac
1568
1569 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1570 # Assume not, until told otherwise.
1571 GNU_MALLOC=yes
1572 doug_lea_malloc=yes
1573 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1574 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1575 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1576                emacs_cv_var___after_morecore_hook,
1577 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1578   emacs_cv_var___after_morecore_hook=yes,
1579   emacs_cv_var___after_morecore_hook=no)])
1580 if test $emacs_cv_var___after_morecore_hook = no; then
1581   doug_lea_malloc=no
1582 fi
1583
1584
1585 dnl See comments in aix4-2.h about maybe using system malloc there.
1586 system_malloc=no
1587 case "$opsys" in
1588   ## darwin ld insists on the use of malloc routines in the System framework.
1589   darwin|sol2-10) system_malloc=yes ;;
1590 esac
1591
1592 if test "${system_malloc}" = "yes"; then
1593   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1594   GNU_MALLOC=no
1595   GNU_MALLOC_reason="
1596     (The GNU allocators don't work with this system configuration.)"
1597   GMALLOC_OBJ=
1598   VMLIMIT_OBJ=
1599 else
1600   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1601   VMLIMIT_OBJ=vm-limit.o
1602 fi
1603 AC_SUBST(GMALLOC_OBJ)
1604 AC_SUBST(VMLIMIT_OBJ)
1605
1606 if test "$doug_lea_malloc" = "yes" ; then
1607   if test "$GNU_MALLOC" = yes ; then
1608     GNU_MALLOC_reason="
1609       (Using Doug Lea's new malloc from the GNU C Library.)"
1610   fi
1611   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1612             [Define to 1 if you are using the GNU C Library.])
1613
1614   ## Use mmap directly for allocating larger buffers.
1615   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1616   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1617   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1618   case "$opsys" in
1619     gnu*) REL_ALLOC=no ;;
1620   esac
1621 fi
1622
1623 if test x"${REL_ALLOC}" = x; then
1624   REL_ALLOC=${GNU_MALLOC}
1625 fi
1626
1627 use_mmap_for_buffers=no
1628 case "$opsys" in
1629   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1630 esac
1631
1632 AC_FUNC_MMAP
1633 if test $use_mmap_for_buffers = yes; then
1634   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1635   REL_ALLOC=no
1636 fi
1637
1638 LIBS="$LIBS_SYSTEM $LIBS"
1639
1640 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1641 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1642 AC_CHECK_LIB(dnet, dnet_ntoa)
1643 dnl This causes -lresolv to get used in subsequent tests,
1644 dnl which causes failures on some systems such as HPUX 9.
1645 dnl AC_CHECK_LIB(resolv, gethostbyname)
1646
1647 dnl FIXME replace main with a function we actually want from this library.
1648 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1649
1650 AC_CHECK_LIB(pthreads, cma_open)
1651
1652 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1653 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1654 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1655 ## added to LIBS in configure would never contain the pthreads part,
1656 ## but the value used in Makefiles might.  FIXME?
1657 ##
1658 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1659 ## be harmless on older versions of X where it happens to exist.
1660 test "$opsys" = "aix4-2" && \
1661   test $ac_cv_lib_pthreads_cma_open = yes && \
1662   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1663
1664 dnl Check for need for bigtoc support on IBM AIX
1665
1666 case ${host_os} in
1667 aix*)
1668   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1669     case $GCC in
1670     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1671     *) gdb_cv_bigtoc=-bbigtoc ;;
1672     esac
1673
1674     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1675     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1676   ])
1677   ;;
1678 esac
1679
1680 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1681 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1682 # REAL_CPPFLAGS later on.
1683
1684 REAL_CFLAGS="$CFLAGS"
1685 REAL_CPPFLAGS="$CPPFLAGS"
1686
1687 if test "${HAVE_X11}" = "yes"; then
1688   DEFS="$C_SWITCH_X_SITE $DEFS"
1689   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1690   LIBS="-lX11 $LIBS"
1691   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1692   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1693
1694   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1695   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1696   # but it's more convenient here to set LD_RUN_PATH
1697   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1698   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1699     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1700     export LD_RUN_PATH
1701   fi
1702
1703   if test "${opsys}" = "gnu-linux"; then
1704     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1705     AC_TRY_LINK([],
1706      [XOpenDisplay ("foo");],
1707      [xlinux_first_failure=no],
1708      [xlinux_first_failure=yes])
1709     if test "${xlinux_first_failure}" = "yes"; then
1710       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1711       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1712       OLD_CPPFLAGS="$CPPFLAGS"
1713       OLD_LIBS="$LIBS"
1714       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1715       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1716       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1717       LIBS="$LIBS -b i486-linuxaout"
1718       AC_TRY_LINK([],
1719        [XOpenDisplay ("foo");],
1720        [xlinux_second_failure=no],
1721        [xlinux_second_failure=yes])
1722       if test "${xlinux_second_failure}" = "yes"; then
1723         # If we get the same failure with -b, there is no use adding -b.
1724         # So take it out.  This plays safe.
1725         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1726         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1727         CPPFLAGS="$OLD_CPPFLAGS"
1728         LIBS="$OLD_LIBS"
1729         AC_MSG_RESULT(no)
1730       else
1731         AC_MSG_RESULT(yes)
1732       fi
1733     else
1734       AC_MSG_RESULT(no)
1735     fi
1736   fi
1737
1738   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1739   # header files included from there.
1740   AC_MSG_CHECKING(for Xkb)
1741   AC_TRY_LINK([#include <X11/Xlib.h>
1742 #include <X11/XKBlib.h>],
1743         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1744         emacs_xkb=yes, emacs_xkb=no)
1745   AC_MSG_RESULT($emacs_xkb)
1746   if test $emacs_xkb = yes; then
1747     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1748   fi
1749
1750   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1751 XScreenNumberOfScreen XSetWMProtocols)
1752 fi
1753
1754 if test "${window_system}" = "x11"; then
1755   AC_MSG_CHECKING(X11 version 6)
1756   AC_CACHE_VAL(emacs_cv_x11_version_6,
1757   [AC_TRY_LINK([#include <X11/Xlib.h>],
1758 [#if XlibSpecificationRelease < 6
1759 fail;
1760 #endif
1761 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1762   if test $emacs_cv_x11_version_6 = yes; then
1763     AC_MSG_RESULT(6 or newer)
1764     AC_DEFINE(HAVE_X11R6, 1,
1765               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1766     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1767     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1768     ## XIM support.
1769     case "$opsys" in
1770       sol2-*) : ;;
1771       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1772            [Define if you have usable X11R6-style XIM support.])
1773          ;;
1774     esac
1775   else
1776     AC_MSG_RESULT(before 6)
1777   fi
1778 fi
1779
1780
1781 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1782 HAVE_RSVG=no
1783 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1784   if test "${with_rsvg}" != "no"; then
1785     RSVG_REQUIRED=2.11.0
1786     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1787
1788     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1789     AC_SUBST(RSVG_CFLAGS)
1790     AC_SUBST(RSVG_LIBS)
1791
1792     if test $HAVE_RSVG = yes; then
1793       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1794       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1795       LIBS="$RSVG_LIBS $LIBS"
1796     fi
1797   fi
1798 fi
1799
1800 HAVE_IMAGEMAGICK=no
1801 if test "${HAVE_X11}" = "yes"; then
1802   if test "${with_imagemagick}" != "no"; then
1803     IMAGEMAGICK_MODULE="Wand"
1804     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1805     AC_SUBST(IMAGEMAGICK_CFLAGS)
1806     AC_SUBST(IMAGEMAGICK_LIBS)
1807
1808     if test $HAVE_IMAGEMAGICK = yes; then
1809       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1810       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1811       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1812       AC_CHECK_FUNCS(MagickExportImagePixels)
1813     fi
1814   fi
1815 fi
1816
1817
1818 HAVE_GTK=no
1819 if test "${with_gtk3}" = "yes"; then
1820   GLIB_REQUIRED=2.6
1821   GTK_REQUIRED=2.90
1822   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1823
1824   dnl Checks for libraries.
1825   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1826   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1827      AC_MSG_ERROR($GTK_PKG_ERRORS)
1828   fi
1829 fi
1830
1831 if test "$pkg_check_gtk" != "yes"; then
1832   HAVE_GTK=no
1833 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1834   GLIB_REQUIRED=2.6
1835   GTK_REQUIRED=2.6
1836   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1837
1838   dnl Checks for libraries.
1839   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1840   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1841      AC_MSG_ERROR($GTK_PKG_ERRORS)
1842   fi
1843 fi
1844 fi
1845
1846 GTK_OBJ=
1847 if test x"$pkg_check_gtk" = xyes; then
1848
1849   AC_SUBST(GTK_CFLAGS)
1850   AC_SUBST(GTK_LIBS)
1851   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1852   CFLAGS="$CFLAGS $GTK_CFLAGS"
1853   LIBS="$GTK_LIBS $LIBS"
1854   dnl Try to compile a simple GTK program.
1855   GTK_COMPILES=no
1856   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1857   if test "${GTK_COMPILES}" != "yes"; then
1858     if test "$USE_X_TOOLKIT" != "maybe"; then
1859       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1860     fi
1861   else
1862     HAVE_GTK=yes
1863     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1864     GTK_OBJ=gtkutil.o
1865     USE_X_TOOLKIT=none
1866     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1867       :
1868     else
1869       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1870        closing open displays.  This is no problem if you just use
1871        one display, but if you use more than one and close one of them
1872        Emacs may crash.]])
1873       sleep 3
1874     fi
1875   fi
1876
1877 fi
1878 AC_SUBST(GTK_OBJ)
1879
1880
1881 if test "${HAVE_GTK}" = "yes"; then
1882
1883   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1884   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1885   if test "$with_toolkit_scroll_bars" != no; then
1886     with_toolkit_scroll_bars=yes
1887   fi
1888
1889   dnl  Check if we have the old file selection dialog declared and
1890   dnl  in the link library.  In 2.x it may be in the library,
1891   dnl  but not declared if deprecated featured has been selected out.
1892   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1893   HAVE_GTK_FILE_SELECTION=no
1894   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1895                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1896 #include <gtk/gtk.h>])
1897   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1898     AC_CHECK_FUNCS(gtk_file_selection_new)
1899   fi
1900
1901   dnl Check if pthreads are available.  Emacs only needs this when using
1902   dnl gtk_file_chooser under Gnome.
1903     HAVE_GTK_AND_PTHREAD=no
1904     AC_CHECK_HEADERS(pthread.h)
1905     if test "$ac_cv_header_pthread_h"; then
1906       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1907     fi
1908     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1909       case "${canonical}" in
1910         *-hpux*) ;;
1911         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1912       esac
1913       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1914                [Define to 1 if you have GTK and pthread (-lpthread).])
1915     fi
1916
1917   dnl Check for functions introduced in 2.14 and later.
1918   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1919                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1920                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1921                  gtk_orientable_set_orientation)
1922
1923 fi
1924
1925 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1926 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1927 dnl also not configured.
1928 HAVE_DBUS=no
1929 DBUS_OBJ=
1930 if test "${with_dbus}" = "yes"; then
1931    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1932    if test "$HAVE_DBUS" = yes; then
1933      LIBS="$LIBS $DBUS_LIBS"
1934      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1935      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1936      DBUS_OBJ=dbusbind.o
1937    fi
1938 fi
1939 AC_SUBST(DBUS_OBJ)
1940
1941 dnl GConf has been tested under GNU/Linux only.
1942 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1943 HAVE_GCONF=no
1944 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1945    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1946    if test "$HAVE_GCONF" = yes; then
1947       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1948       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1949       AC_CHECK_FUNCS([g_type_init])
1950    fi
1951 fi
1952
1953 dnl SELinux is available for GNU/Linux only.
1954 HAVE_LIBSELINUX=no
1955 LIBSELINUX_LIBS=
1956 if test "${with_selinux}" = "yes"; then
1957    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1958    if test "$HAVE_LIBSELINUX" = yes; then
1959       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1960       LIBSELINUX_LIBS=-lselinux
1961    fi
1962 fi
1963 AC_SUBST(LIBSELINUX_LIBS)
1964
1965 HAVE_GNUTLS=no
1966 if test "${with_gnutls}" = "yes" ; then
1967   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1968   if test "${HAVE_GNUTLS}" = "yes"; then
1969     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1970   fi
1971 fi
1972 AC_SUBST(LIBGNUTLS_LIBS)
1973 AC_SUBST(LIBGNUTLS_CFLAGS)
1974
1975 dnl Do not put whitespace before the #include statements below.
1976 dnl Older compilers (eg sunos4 cc) choke on it.
1977 HAVE_XAW3D=no
1978 LUCID_LIBW=
1979 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1980   if test "$with_xaw3d" != no; then
1981     AC_MSG_CHECKING(for xaw3d)
1982     AC_CACHE_VAL(emacs_cv_xaw3d,
1983     [AC_TRY_LINK([
1984 #include <X11/Intrinsic.h>
1985 #include <X11/Xaw3d/Simple.h>],
1986       [],
1987       emacs_cv_xaw3d=yes,
1988       emacs_cv_xaw3d=no)])
1989   else
1990     emacs_cv_xaw3d=no
1991   fi
1992   if test $emacs_cv_xaw3d = yes; then
1993     AC_MSG_RESULT([yes; using Lucid toolkit])
1994     USE_X_TOOLKIT=LUCID
1995     HAVE_XAW3D=yes
1996     LUCID_LIBW=-lXaw3d
1997     AC_DEFINE(HAVE_XAW3D, 1,
1998               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1999   else
2000     AC_MSG_RESULT(no)
2001     AC_MSG_CHECKING(for libXaw)
2002     AC_CACHE_VAL(emacs_cv_xaw,
2003     [AC_TRY_LINK([
2004 #include <X11/Intrinsic.h>
2005 #include <X11/Xaw/Simple.h>],
2006       [],
2007       emacs_cv_xaw=yes,
2008       emacs_cv_xaw=no)])
2009     if test $emacs_cv_xaw = yes; then
2010       AC_MSG_RESULT([yes; using Lucid toolkit])
2011       USE_X_TOOLKIT=LUCID
2012       LUCID_LIBW=-lXaw
2013     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2014       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2015     else
2016       AC_MSG_RESULT([no; do not use toolkit by default])
2017       USE_X_TOOLKIT=none
2018     fi
2019   fi
2020 fi
2021
2022 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2023
2024 LIBXTR6=
2025 if test "${USE_X_TOOLKIT}" != "none"; then
2026   AC_MSG_CHECKING(X11 toolkit version)
2027   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2028   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2029 [#if XtSpecificationRelease < 6
2030 fail;
2031 #endif
2032 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2033   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2034   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2035     AC_MSG_RESULT(6 or newer)
2036     AC_DEFINE(HAVE_X11XTR6, 1,
2037               [Define to 1 if you have the X11R6 or newer version of Xt.])
2038     LIBXTR6="-lSM -lICE"
2039     case "$opsys" in
2040       ## Use libw.a along with X11R6 Xt.
2041       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2042     esac
2043   else
2044     AC_MSG_RESULT(before 6)
2045   fi
2046
2047 dnl If using toolkit, check whether libXmu.a exists.
2048 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2049   OLDLIBS="$LIBS"
2050   if test x$HAVE_X11XTR6 = xyes; then
2051     LIBS="-lXt -lSM -lICE $LIBS"
2052   else
2053     LIBS="-lXt $LIBS"
2054   fi
2055   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2056   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2057 fi
2058 AC_SUBST(LIBXTR6)
2059
2060 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2061 dnl Why not just test for libxmu in the normal way?
2062 LIBXMU=-lXmu
2063 case $opsys in
2064   ## These systems don't supply Xmu.
2065   hpux* | aix4-2 )
2066     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2067     ;;
2068 esac
2069 AC_SUBST(LIBXMU)
2070
2071 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2072 if test "${HAVE_X11}" = "yes"; then
2073   if test "${USE_X_TOOLKIT}" != "none"; then
2074     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2075   fi
2076 fi
2077
2078 LIBXP=
2079 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2080   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2081   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2082     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2083 int x = 5;
2084 #else
2085 Motif version prior to 2.1.
2086 #endif],
2087     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2088   if test $emacs_cv_motif_version_2_1 = yes; then
2089     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2090   else
2091     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2092     # We put this in CFLAGS temporarily to precede other -I options
2093     # that might be in CFLAGS temporarily.
2094     # We put this in CPPFLAGS where it precedes the other -I options.
2095     OLD_CPPFLAGS=$CPPFLAGS
2096     OLD_CFLAGS=$CFLAGS
2097     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2098     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2099     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2100       [int x = 5;],
2101       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2102     if test $emacs_cv_lesstif = yes; then
2103       # Make sure this -I option remains in CPPFLAGS after it is set
2104       # back to REAL_CPPFLAGS.
2105       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2106       # have those other -I options anyway.  Ultimately, having this
2107       # directory ultimately in CPPFLAGS will be enough.
2108       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2109       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2110     else
2111       CFLAGS=$OLD_CFLAGS
2112       CPPFLAGS=$OLD_CPPFLAGS
2113     fi
2114   fi
2115 fi
2116
2117 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2118 dnl using Motif or Xaw3d is available, and unless
2119 dnl --with-toolkit-scroll-bars=no was specified.
2120
2121 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2122             [Define to 1 if we should use toolkit scroll bars.])dnl
2123 USE_TOOLKIT_SCROLL_BARS=no
2124 if test "${with_toolkit_scroll_bars}" != "no"; then
2125   if test "${USE_X_TOOLKIT}" != "none"; then
2126     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2127       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2128       HAVE_XAW3D=no
2129       USE_TOOLKIT_SCROLL_BARS=yes
2130     elif test "${HAVE_XAW3D}" = "yes"; then
2131       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2132       USE_TOOLKIT_SCROLL_BARS=yes
2133     fi
2134   elif test "${HAVE_GTK}" = "yes"; then
2135     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2136     USE_TOOLKIT_SCROLL_BARS=yes
2137   elif test "${HAVE_NS}" = "yes"; then
2138     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2139     USE_TOOLKIT_SCROLL_BARS=yes
2140   fi
2141 fi
2142
2143 dnl See if XIM is available.
2144 AC_TRY_COMPILE([
2145           #include <X11/Xlib.h>
2146           #include <X11/Xresource.h>],
2147          [XIMProc  callback;],
2148          [HAVE_XIM=yes
2149          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2150          HAVE_XIM=no)
2151
2152 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2153
2154 if test "${with_xim}" != "no"; then
2155   AC_DEFINE(USE_XIM, 1,
2156             [Define to 1 if we should use XIM, if it is available.])
2157 fi
2158
2159
2160 if test "${HAVE_XIM}" != "no"; then
2161   late_CFLAGS=$CFLAGS
2162   if test "$GCC" = yes; then
2163     CFLAGS="$CFLAGS --pedantic-errors"
2164   fi
2165   AC_TRY_COMPILE([
2166 #include <X11/Xlib.h>
2167 #include <X11/Xresource.h>],
2168 [Display *display;
2169 XrmDatabase db;
2170 char *res_name;
2171 char *res_class;
2172 XIMProc  callback;
2173 XPointer *client_data;
2174 #ifndef __GNUC__
2175 /* If we're not using GCC, it's probably not XFree86, and this is
2176    probably right, but we can't use something like --pedantic-errors.  */
2177 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2178                                            char*, XIMProc, XPointer*);
2179 #endif
2180 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2181    client_data);],
2182     [emacs_cv_arg6_star=yes])
2183   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2184          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2185 either XPointer or XPointer*.])dnl
2186   if test "$emacs_cv_arg6_star" = yes; then
2187     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2188   else
2189     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2190   fi
2191   CFLAGS=$late_CFLAGS
2192 fi
2193
2194 ### Start of font-backend (under any platform) section.
2195 # (nothing here yet -- this is a placeholder)
2196 ### End of font-backend (under any platform) section.
2197
2198 ### Start of font-backend (under X11) section.
2199 if test "${HAVE_X11}" = "yes"; then
2200    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2201
2202    ## Use -lXft if available, unless `--with-xft=no'.
2203    HAVE_XFT=maybe
2204     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2205       with_xft="no";
2206     fi
2207     if test "x${with_xft}" != "xno"; then
2208
2209       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2210       ## Because xftfont.c uses XRenderQueryExtension, we also
2211       ## need to link to -lXrender.
2212       HAVE_XRENDER=no
2213       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2214       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2215         OLD_CPPFLAGS="$CPPFLAGS"
2216         OLD_CFLAGS="$CFLAGS"
2217         OLD_LIBS="$LIBS"
2218         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2219         CFLAGS="$CFLAGS $XFT_CFLAGS"
2220         XFT_LIBS="-lXrender $XFT_LIBS"
2221         LIBS="$XFT_LIBS $LIBS"
2222         AC_CHECK_HEADER(X11/Xft/Xft.h,
2223           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2224
2225         if test "${HAVE_XFT}" = "yes"; then
2226           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2227             AC_SUBST(XFT_LIBS)
2228           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2229         else
2230           CPPFLAGS="$OLD_CPPFLAGS"
2231           CFLAGS="$OLD_CFLAGS"
2232           LIBS="$OLD_LIBS"
2233         fi                        # "${HAVE_XFT}" = "yes"
2234       fi                          # "$HAVE_XFT" != no
2235     fi                            # "x${with_xft}" != "xno"
2236
2237     dnl For the "Does Emacs use" message at the end.
2238     if test "$HAVE_XFT" != "yes"; then
2239        HAVE_XFT=no
2240     fi
2241
2242
2243     HAVE_FREETYPE=no
2244     ## We used to allow building with FreeType and without Xft.
2245     ## However, the ftx font backend driver is not in good shape.
2246     if test "${HAVE_XFT}" = "yes"; then
2247       dnl As we use Xft, we anyway use freetype.
2248       dnl There's no need for additional CFLAGS and LIBS.
2249       HAVE_FREETYPE=yes
2250       FONTCONFIG_CFLAGS=
2251       FONTCONFIG_LIBS=
2252     fi
2253
2254     HAVE_LIBOTF=no
2255     if test "${HAVE_FREETYPE}" = "yes"; then
2256       AC_DEFINE(HAVE_FREETYPE, 1,
2257                 [Define to 1 if using the freetype and fontconfig libraries.])
2258       if test "${with_libotf}" != "no"; then
2259         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2260                           HAVE_LIBOTF=no)
2261         if test "$HAVE_LIBOTF" = "yes"; then
2262           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2263           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2264                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2265                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2266           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2267             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2268                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2269           fi
2270         fi
2271       fi
2272     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2273     dnl Does the new font backend require it, or can it work without it?
2274     fi
2275
2276     HAVE_M17N_FLT=no
2277     if test "${HAVE_LIBOTF}" = yes; then
2278       if test "${with_m17n_flt}" != "no"; then
2279         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2280         if test "$HAVE_M17N_FLT" = "yes"; then
2281           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2282         fi
2283       fi
2284     fi
2285 else
2286     HAVE_XFT=no
2287     HAVE_FREETYPE=no
2288     HAVE_LIBOTF=no
2289     HAVE_M17N_FLT=no
2290 fi
2291
2292 ### End of font-backend (under X11) section.
2293
2294 AC_SUBST(FREETYPE_CFLAGS)
2295 AC_SUBST(FREETYPE_LIBS)
2296 AC_SUBST(FONTCONFIG_CFLAGS)
2297 AC_SUBST(FONTCONFIG_LIBS)
2298 AC_SUBST(LIBOTF_CFLAGS)
2299 AC_SUBST(LIBOTF_LIBS)
2300 AC_SUBST(M17N_FLT_CFLAGS)
2301 AC_SUBST(M17N_FLT_LIBS)
2302
2303 ### Use -lXpm if available, unless `--with-xpm=no'.
2304 HAVE_XPM=no
2305 LIBXPM=
2306 if test "${HAVE_X11}" = "yes"; then
2307   if test "${with_xpm}" != "no"; then
2308     AC_CHECK_HEADER(X11/xpm.h,
2309       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2310     if test "${HAVE_XPM}" = "yes"; then
2311       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2312       AC_EGREP_CPP(no_return_alloc_pixels,
2313       [#include "X11/xpm.h"
2314 #ifndef XpmReturnAllocPixels
2315 no_return_alloc_pixels
2316 #endif
2317       ], HAVE_XPM=no, HAVE_XPM=yes)
2318
2319       if test "${HAVE_XPM}" = "yes"; then
2320         AC_MSG_RESULT(yes)
2321       else
2322         AC_MSG_RESULT(no)
2323       fi
2324     fi
2325   fi
2326
2327   if test "${HAVE_XPM}" = "yes"; then
2328     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2329     LIBXPM=-lXpm
2330   fi
2331 fi
2332 AC_SUBST(LIBXPM)
2333
2334 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2335 HAVE_JPEG=no
2336 LIBJPEG=
2337 if test "${HAVE_X11}" = "yes"; then
2338   if test "${with_jpeg}" != "no"; then
2339     dnl Checking for jpeglib.h can lose because of a redefinition of
2340     dnl  HAVE_STDLIB_H.
2341     AC_CHECK_HEADER(jerror.h,
2342       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2343   fi
2344
2345   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2346   if test "${HAVE_JPEG}" = "yes"; then
2347     AC_DEFINE(HAVE_JPEG)
2348     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2349         [#include <jpeglib.h>
2350          version=JPEG_LIB_VERSION
2351 ],
2352         [AC_DEFINE(HAVE_JPEG)],
2353         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2354         HAVE_JPEG=no])
2355   fi
2356   if test "${HAVE_JPEG}" = "yes"; then
2357     LIBJPEG=-ljpeg
2358   fi
2359 fi
2360 AC_SUBST(LIBJPEG)
2361
2362 ### Use -lpng if available, unless `--with-png=no'.
2363 HAVE_PNG=no
2364 LIBPNG=
2365 if test "${HAVE_X11}" = "yes"; then
2366   if test "${with_png}" != "no"; then
2367     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2368     # in /usr/include/libpng.
2369     AC_CHECK_HEADERS(png.h libpng/png.h)
2370     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2371       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2372     fi
2373   fi
2374
2375   if test "${HAVE_PNG}" = "yes"; then
2376     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2377     LIBPNG="-lpng -lz -lm"
2378   fi
2379 fi
2380 AC_SUBST(LIBPNG)
2381
2382 ### Use -ltiff if available, unless `--with-tiff=no'.
2383 HAVE_TIFF=no
2384 LIBTIFF=
2385 if test "${HAVE_X11}" = "yes"; then
2386   if test "${with_tiff}" != "no"; then
2387     AC_CHECK_HEADER(tiffio.h,
2388       [tifflibs="-lz -lm"
2389       # At least one tiff package requires the jpeg library.
2390       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2391       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2392   fi
2393
2394   if test "${HAVE_TIFF}" = "yes"; then
2395     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2396     dnl FIXME -lz -lm, as per libpng?
2397     LIBTIFF=-ltiff
2398   fi
2399 fi
2400 AC_SUBST(LIBTIFF)
2401
2402 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2403 HAVE_GIF=no
2404 LIBGIF=
2405 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2406   AC_CHECK_HEADER(gif_lib.h,
2407 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2408 # Earlier versions can crash Emacs.
2409     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2410
2411   if test "$HAVE_GIF" = yes; then
2412     LIBGIF=-lgif
2413   elif test "$HAVE_GIF" = maybe; then
2414 # If gif_lib.h but no libgif, try libungif.
2415     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2416     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2417   fi
2418
2419   if test "${HAVE_GIF}" = "yes"; then
2420     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2421   fi
2422 fi
2423 AC_SUBST(LIBGIF)
2424
2425 dnl Check for required libraries.
2426 if test "${HAVE_X11}" = "yes"; then
2427   MISSING=""
2428   WITH_NO=""
2429   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2430     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2431   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2432     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2433   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2434     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2435   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2436     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2437   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2438     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2439
2440   if test "X${MISSING}" != X; then
2441     AC_MSG_ERROR([The following required libraries were not found:
2442     $MISSING
2443 Maybe some development libraries/packages are missing?
2444 If you don't want to link with them give
2445     $WITH_NO
2446 as options to configure])
2447   fi
2448 fi
2449
2450 ### Use -lgpm if available, unless `--with-gpm=no'.
2451 HAVE_GPM=no
2452 LIBGPM=
2453 MOUSE_SUPPORT=
2454 if test "${with_gpm}" != "no"; then
2455   AC_CHECK_HEADER(gpm.h,
2456     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2457
2458   if test "${HAVE_GPM}" = "yes"; then
2459     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2460     LIBGPM=-lgpm
2461     ## May be reset below.
2462     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2463   fi
2464 fi
2465 AC_SUBST(LIBGPM)
2466
2467 dnl Check for malloc/malloc.h on darwin
2468 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2469
2470 C_SWITCH_X_SYSTEM=
2471 ### Use NeXTstep API to implement GUI.
2472 if test "${HAVE_NS}" = "yes"; then
2473   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2474   if test "${NS_IMPL_COCOA}" = "yes"; then
2475     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2476     GNU_OBJC_CFLAGS=
2477   fi
2478   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2479     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2480     # See also .m.o rule in Makefile.in */
2481     # FIXME: are all these flags really needed?  Document here why.  */
2482     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2483     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2484   fi
2485   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2486     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2487   fi
2488   # We also have mouse menus.
2489   HAVE_MENUS=yes
2490   OTHER_FILES=ns-app
2491 fi
2492
2493
2494 ### Use session management (-lSM -lICE) if available
2495 HAVE_X_SM=no
2496 LIBXSM=
2497 if test "${HAVE_X11}" = "yes"; then
2498   AC_CHECK_HEADER(X11/SM/SMlib.h,
2499     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2500
2501   if test "${HAVE_X_SM}" = "yes"; then
2502     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2503     LIBXSM="-lSM -lICE"
2504     case "$LIBS" in
2505       *-lSM*) ;;
2506       *)      LIBS="$LIBXSM $LIBS" ;;
2507     esac
2508   fi
2509 fi
2510 AC_SUBST(LIBXSM)
2511
2512 ### Use libxml (-lxml2) if available
2513 if test "${with_xml2}" != "no"; then
2514   ### I'm not sure what the version number should be, so I just guessed.
2515   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2516   if test "${HAVE_LIBXML2}" = "yes"; then
2517     LIBS="$LIBXML2_LIBS $LIBS"
2518     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2519     if test "${HAVE_LIBXML2}" = "yes"; then
2520       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2521     else
2522       LIBXML2_LIBS=""
2523       LIBXML2_CFLAGS=""
2524     fi
2525   fi
2526 fi
2527 AC_SUBST(LIBXML2_LIBS)
2528 AC_SUBST(LIBXML2_CFLAGS)
2529
2530 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2531 AC_CACHE_CHECK(whether netdb declares h_errno,
2532                emacs_cv_netdb_declares_h_errno,
2533 [AC_TRY_LINK([#include <netdb.h>],
2534   [return h_errno;],
2535   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2536 if test $emacs_cv_netdb_declares_h_errno = yes; then
2537   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2538 fi
2539
2540 AC_FUNC_ALLOCA
2541
2542 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2543 dnl FIXME is there an autoconf test that does the right thing, without
2544 dnl needing to call A_M_E afterwards?
2545 if test x"$ac_cv_func_alloca_works" != xyes; then
2546    AC_MSG_ERROR( [a system implementation of alloca is required] )
2547 fi
2548
2549 # fmod, logb, and frexp are found in -lm on most systems.
2550 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2551 AC_CHECK_LIB(m, sqrt)
2552
2553 # Check for mail-locking functions in a "mail" library.  Probably this should
2554 # have the same check as for liblockfile below.
2555 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2556 if test $have_mail = yes; then
2557   LIBS_MAIL=-lmail
2558   LIBS="$LIBS_MAIL $LIBS"
2559   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2560 else
2561   LIBS_MAIL=
2562 fi
2563 dnl Debian, at least:
2564 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2565 if test $have_lockfile = yes; then
2566    LIBS_MAIL=-llockfile
2567    LIBS="$LIBS_MAIL $LIBS"
2568    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2569 else
2570 # If we have the shared liblockfile, assume we must use it for mail
2571 # locking (e.g. Debian).  If we couldn't link against liblockfile
2572 # (no liblockfile.a installed), ensure that we don't need to.
2573   dnl This works for files generally, not just executables.
2574   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2575   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2576                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2577   if test $ac_cv_prog_liblockfile = yes; then
2578     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2579 This probably means that movemail could lose mail.
2580 There may be a `development' package to install containing liblockfile.])
2581   fi
2582 fi
2583 AC_CHECK_FUNCS(touchlock)
2584 AC_CHECK_HEADERS(maillock.h)
2585 AC_SUBST(LIBS_MAIL)
2586
2587 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2588 ## interlock access to the mail spool.  The alternative is a lock file named
2589 ## /usr/spool/mail/$USER.lock.
2590 mail_lock=no
2591 case "$opsys" in
2592   aix4-2) mail_lock="lockf" ;;
2593
2594   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2595
2596   ## On GNU/Linux systems, both methods are used by various mail programs.
2597   ## I assume most people are using newer mailers that have heard of flock.
2598   ## Change this if you need to.
2599   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2600   ## configure gets the right answers, and that means *NOT* using flock.
2601   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2602   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2603   ## Debian maintainer hasn't provided a clean fix for Emacs.
2604   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2605   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2606   ## correct logic.  -- fx
2607   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2608   ## liblockfile is a Free Software replacement for libmail, used on
2609   ## Debian systems and elsewhere. -rfr.
2610   gnu-*)
2611     mail_lock="flock"
2612     if test $have_mail = yes || test $have_lockfile = yes; then
2613       test $ac_cv_header_maillock_h = yes && mail_lock=no
2614     fi
2615     ;;
2616 esac
2617
2618 BLESSMAIL_TARGET=
2619 case "$mail_lock" in
2620   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2621
2622   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2623
2624   *) BLESSMAIL_TARGET="need-blessmail" ;;
2625 esac
2626 AC_SUBST(BLESSMAIL_TARGET)
2627
2628
2629 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2630 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2631 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2632 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2633 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2634 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2635 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2636 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2637 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2638 cfmakeraw cfsetspeed isnan copysign __executable_start)
2639
2640 dnl Cannot use AC_CHECK_FUNCS
2641 AC_CACHE_CHECK([for __builtin_unwind_init],
2642                emacs_cv_func___builtin_unwind_init,
2643 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2644                 emacs_cv_func___builtin_unwind_init=yes,
2645                 emacs_cv_func___builtin_unwind_init=no)])
2646 if test $emacs_cv_func___builtin_unwind_init = yes; then
2647   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2648             [Define to 1 if you have the `__builtin_unwind_init' function.])
2649 fi
2650
2651 AC_CHECK_HEADERS(sys/un.h)
2652
2653 AC_FUNC_GETLOADAVG
2654
2655 AC_FUNC_FSEEKO
2656
2657 AC_FUNC_GETPGRP
2658
2659 # Configure gnulib.
2660 gl_INIT
2661
2662 AC_FUNC_STRFTIME
2663
2664 # UNIX98 PTYs.
2665 AC_CHECK_FUNCS(grantpt)
2666
2667 # PTY-related GNU extensions.
2668 AC_CHECK_FUNCS(getpt)
2669
2670 # Check this now, so that we will NOT find the above functions in ncurses.
2671 # That is because we have not set up to link ncurses in lib-src.
2672 # It's better to believe a function is not available
2673 # than to expect to find it in ncurses.
2674 # Also we need tputs and friends to be able to build at all.
2675 have_tputs_et_al=true
2676 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2677 if test "$have_tputs_et_al" != true; then
2678   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2679 Maybe some development libraries/packages are missing?  Try installing
2680 libncurses-dev(el), libterminfo-dev(el) or similar.])
2681 fi
2682 # Must define this when any termcap library is found.
2683 AC_DEFINE(HAVE_LIBNCURSES, 1,
2684           [Define to 1 if you have the `ncurses' library (-lncurses).])
2685 ## FIXME This was the cpp logic, but I am not sure it is right.
2686 ## The above test has not necessarily found libncurses.
2687 HAVE_LIBNCURSES=yes
2688
2689 ## Use terminfo instead of termcap?
2690 ## Note only system files NOT using terminfo are:
2691 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2692 ## darwin|gnu without ncurses.
2693 TERMINFO=no
2694 LIBS_TERMCAP=
2695 case "$opsys" in
2696   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2697   ## hpux10-20: Use the system provided termcap(3) library.
2698   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2699   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2700   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2701
2702   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2703   ##  The ncurses library has been moved out of the System framework in
2704   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2705   ##  option to use it.
2706   darwin|gnu*)
2707     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2708     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2709       TERMINFO=yes
2710       LIBS_TERMCAP="-lncurses"
2711     fi
2712     ;;
2713
2714   freebsd)
2715     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2716     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2717     [AC_TRY_LINK([#include <osreldate.h>],
2718 [#if __FreeBSD_version < 400000
2719 fail;
2720 #endif
2721 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2722
2723     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2724
2725     if test $emacs_cv_freebsd_terminfo = yes; then
2726       TERMINFO=yes
2727       LIBS_TERMCAP="-lncurses"
2728     else
2729       LIBS_TERMCAP="-ltermcap"
2730     fi
2731     ;;
2732
2733   netbsd)
2734     if test $ac_cv_search_tputs = -lterminfo; then
2735       TERMINFO=yes
2736       LIBS_TERMCAP="-lterminfo"
2737     else
2738       LIBS_TERMCAP="-ltermcap"
2739     fi
2740     ;;
2741
2742 esac
2743
2744 case "$opsys" in
2745   ## hpux: Make sure we get select from libc rather than from libcurses
2746   ##  because libcurses on HPUX 10.10 has a broken version of select.
2747   ##  We used to use -lc -lcurses, but this may be cleaner.
2748   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2749
2750   openbsd) LIBS_TERMCAP="-lncurses" ;;
2751
2752   ## Must use system termcap, if we use any termcap.  It does special things.
2753   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2754 esac
2755
2756 TERMCAP_OBJ=tparam.o
2757 if test $TERMINFO = yes; then
2758   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2759
2760   ## Default used to be -ltermcap.  Add a case above if need something else.
2761   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2762
2763   TERMCAP_OBJ=terminfo.o
2764 fi
2765 AC_SUBST(LIBS_TERMCAP)
2766 AC_SUBST(TERMCAP_OBJ)
2767
2768
2769 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2770 resolv=no
2771 AC_TRY_LINK([#include <netinet/in.h>
2772 #include <arpa/nameser.h>
2773 #include <resolv.h>],
2774     [return res_init();],
2775     have_res_init=yes, have_res_init=no)
2776 if test "$have_res_init" = no; then
2777   OLIBS="$LIBS"
2778   LIBS="$LIBS -lresolv"
2779   AC_MSG_CHECKING(for res_init with -lresolv)
2780   AC_TRY_LINK([#include <netinet/in.h>
2781 #include <arpa/nameser.h>
2782 #include <resolv.h>],
2783     [return res_init();],
2784     have_res_init=yes, have_res_init=no)
2785   AC_MSG_RESULT($have_res_init)
2786   if test "$have_res_init" = yes ; then
2787     resolv=yes
2788   fi
2789   LIBS="$OLIBS"
2790 fi
2791
2792 if test "$have_res_init" = yes; then
2793   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2794 fi
2795
2796 # Do we need the Hesiod library to provide the support routines?
2797 LIBHESIOD=
2798 if test "$with_hesiod" != no ; then
2799   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2800   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2801      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2802                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2803   if test "$resolv" = yes ; then
2804     RESOLVLIB=-lresolv
2805   else
2806     RESOLVLIB=
2807   fi
2808   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2809         hesiod=yes, :, $RESOLVLIB)])
2810
2811   if test x"$hesiod" = xyes; then
2812     AC_DEFINE(HAVE_LIBHESIOD, 1,
2813               [Define to 1 if you have the hesiod library (-lhesiod).])
2814     LIBHESIOD=-lhesiod
2815   fi
2816 fi
2817 AC_SUBST(LIBHESIOD)
2818
2819 # Do we need libresolv (due to res_init or Hesiod)?
2820 if test "$resolv" = yes ; then
2821   AC_DEFINE(HAVE_LIBRESOLV, 1,
2822             [Define to 1 if you have the resolv library (-lresolv).])
2823   LIBRESOLV=-lresolv
2824 else
2825   LIBRESOLV=
2826 fi
2827 AC_SUBST(LIBRESOLV)
2828
2829 # These tell us which Kerberos-related libraries to use.
2830 COM_ERRLIB=
2831 CRYPTOLIB=
2832 KRB5LIB=
2833 DESLIB=
2834 KRB4LIB=
2835
2836 if test "${with_kerberos}" != no; then
2837   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2838   if test $have_com_err = yes; then
2839     COM_ERRLIB=-lcom_err
2840     LIBS="$COM_ERRLIB $LIBS"
2841     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2842   fi
2843   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2844   if test $have_crypto = yes; then
2845     CRYPTOLIB=-lcrypto
2846     LIBS="$CRYPTOLIB $LIBS"
2847     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2848   fi
2849   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2850   if test $have_k5crypto = yes; then
2851     CRYPTOLIB=-lk5crypto
2852     LIBS="$CRYPTOLIB $LIBS"
2853     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2854   fi
2855   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2856   if test $have_krb5=yes; then
2857     KRB5LIB=-lkrb5
2858     LIBS="$KRB5LIB $LIBS"
2859     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2860   fi
2861   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2862   if test "${with_kerberos5}" = no; then
2863     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2864     if test $have_des425 = yes; then
2865       DESLIB=-ldes425
2866       LIBS="$DESLIB $LIBS"
2867       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2868     else
2869       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2870       if test $have_des = yes; then
2871         DESLIB=-ldes
2872         LIBS="$DESLIB $LIBS"
2873         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2874       fi
2875     fi
2876     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2877     if test $have_krb4 = yes; then
2878       KRB4LIB=-lkrb4
2879       LIBS="$KRB4LIB $LIBS"
2880       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2881     else
2882       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2883       if test $have_krb = yes; then
2884         KRB4LIB=-lkrb
2885         LIBS="$KRB4LIB $LIBS"
2886         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2887       fi
2888     fi
2889   fi
2890
2891   if test "${with_kerberos5}" != no; then
2892     AC_CHECK_HEADERS(krb5.h,
2893       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2894                         [#include <krb5.h>])])
2895   else
2896     AC_CHECK_HEADERS(des.h,,
2897                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2898                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2899     AC_CHECK_HEADERS(krb.h,,
2900                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2901                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2902   fi
2903   AC_CHECK_HEADERS(com_err.h)
2904 fi
2905
2906 AC_SUBST(COM_ERRLIB)
2907 AC_SUBST(CRYPTOLIB)
2908 AC_SUBST(KRB5LIB)
2909 AC_SUBST(DESLIB)
2910 AC_SUBST(KRB4LIB)
2911
2912 # Solaris requires -lintl if you want strerror (which calls dgettext)
2913 # to return localized messages.
2914 AC_CHECK_LIB(intl, dgettext)
2915
2916 AC_MSG_CHECKING(whether localtime caches TZ)
2917 AC_CACHE_VAL(emacs_cv_localtime_cache,
2918 [if test x$ac_cv_func_tzset = xyes; then
2919 AC_TRY_RUN([#include <time.h>
2920 char TZ_GMT0[] = "TZ=GMT0";
2921 char TZ_PST8[] = "TZ=PST8";
2922 main()
2923 {
2924   time_t now = time ((time_t *) 0);
2925   int hour_GMT0, hour_unset;
2926   if (putenv (TZ_GMT0) != 0)
2927     exit (1);
2928   hour_GMT0 = localtime (&now)->tm_hour;
2929   unsetenv("TZ");
2930   hour_unset = localtime (&now)->tm_hour;
2931   if (putenv (TZ_PST8) != 0)
2932     exit (1);
2933   if (localtime (&now)->tm_hour == hour_GMT0)
2934     exit (1);
2935   unsetenv("TZ");
2936   if (localtime (&now)->tm_hour != hour_unset)
2937     exit (1);
2938   exit (0);
2939 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2940 [# If we have tzset, assume the worst when cross-compiling.
2941 emacs_cv_localtime_cache=yes])
2942 else
2943         # If we lack tzset, report that localtime does not cache TZ,
2944         # since we can't invalidate the cache if we don't have tzset.
2945         emacs_cv_localtime_cache=no
2946 fi])dnl
2947 AC_MSG_RESULT($emacs_cv_localtime_cache)
2948 if test $emacs_cv_localtime_cache = yes; then
2949   AC_DEFINE(LOCALTIME_CACHE, 1,
2950             [Define to 1 if localtime caches TZ.])
2951 fi
2952
2953 if test "x$HAVE_TIMEVAL" = xyes; then
2954   AC_CHECK_FUNCS(gettimeofday)
2955   if test $ac_cv_func_gettimeofday = yes; then
2956     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2957                    emacs_cv_gettimeofday_two_arguments,
2958     [AC_TRY_COMPILE([
2959 #ifdef TIME_WITH_SYS_TIME
2960 #include <sys/time.h>
2961 #include <time.h>
2962 #else
2963 #ifdef HAVE_SYS_TIME_H
2964 #include <sys/time.h>
2965 #else
2966 #include <time.h>
2967 #endif
2968 #endif],
2969       [struct timeval time;
2970        gettimeofday (&time, 0);],
2971       emacs_cv_gettimeofday_two_arguments=yes,
2972       emacs_cv_gettimeofday_two_arguments=no)])
2973     if test $emacs_cv_gettimeofday_two_arguments = no; then
2974       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2975                 [Define to 1 if gettimeofday accepts only one argument.])
2976     fi
2977   fi
2978 fi
2979
2980 ok_so_far=yes
2981 AC_CHECK_FUNC(socket, , ok_so_far=no)
2982 if test $ok_so_far = yes; then
2983   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2984 fi
2985 if test $ok_so_far = yes; then
2986   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2987 fi
2988 if test $ok_so_far = yes; then
2989 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2990   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2991             [Define to 1 if you have inet sockets.])
2992 fi
2993
2994 if test -f /usr/lpp/X11/bin/smt.exp; then
2995   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2996             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2997 fi
2998
2999 AC_MSG_CHECKING(whether system supports dynamic ptys)
3000 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3001   AC_MSG_RESULT(yes)
3002   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3003 else
3004   AC_MSG_RESULT(no)
3005 fi
3006
3007 AC_FUNC_FORK
3008
3009 dnl Adapted from Haible's version.
3010 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3011   [AC_TRY_LINK([#include <langinfo.h>],
3012     [char* cs = nl_langinfo(CODESET);],
3013     emacs_cv_langinfo_codeset=yes,
3014     emacs_cv_langinfo_codeset=no)
3015   ])
3016 if test $emacs_cv_langinfo_codeset = yes; then
3017   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3018     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3019 fi
3020
3021 AC_CHECK_TYPES(size_t)
3022
3023 AC_TYPE_MBSTATE_T
3024
3025 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3026   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3027                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3028 if test "$emacs_cv_c_restrict_arr" = yes; then
3029   AC_DEFINE(__restrict_arr, __restrict,
3030     [Define to compiler's equivalent of C99 restrict keyword in array
3031      declarations.  Define as empty for no equivalent.])
3032 fi
3033
3034 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3035 dnl how the tty code is related to POSIX and/or other versions of termios.
3036 dnl The following looks like a useful start.
3037 dnl
3038 dnl AC_SYS_POSIX_TERMIOS
3039 dnl if test $ac_cv_sys_posix_termios = yes; then
3040 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3041 dnl                                and macros for terminal control.])
3042 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3043 dnl fi
3044
3045 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3046
3047 # Set up the CFLAGS for real compilation, so we can substitute it.
3048 CFLAGS="$REAL_CFLAGS"
3049 CPPFLAGS="$REAL_CPPFLAGS"
3050
3051 ## Hack to detect a buggy GCC version.
3052 if test "x$GCC" = xyes \
3053    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3054    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3055    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3056    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3057 fi
3058
3059 #### Find out which version of Emacs this is.
3060 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3061          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3062 if test x"${version}" = x; then
3063   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3064 fi
3065 if test x"${version}" != x"$PACKAGE_VERSION"; then
3066   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3067 fi
3068
3069 ### Specify what sort of things we'll be editing into Makefile and config.h.
3070 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3071 AC_SUBST(version)
3072 AC_SUBST(configuration)
3073 ## Unused?
3074 AC_SUBST(canonical)
3075 AC_SUBST(srcdir)
3076 AC_SUBST(prefix)
3077 AC_SUBST(exec_prefix)
3078 AC_SUBST(bindir)
3079 AC_SUBST(datadir)
3080 AC_SUBST(sharedstatedir)
3081 AC_SUBST(libexecdir)
3082 AC_SUBST(mandir)
3083 AC_SUBST(infodir)
3084 AC_SUBST(lispdir)
3085 AC_SUBST(locallisppath)
3086 AC_SUBST(lisppath)
3087 AC_SUBST(x_default_search_path)
3088 AC_SUBST(etcdir)
3089 AC_SUBST(archlibdir)
3090 AC_SUBST(docdir)
3091 AC_SUBST(bitmapdir)
3092 AC_SUBST(gamedir)
3093 AC_SUBST(gameuser)
3094 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3095 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3096 ## end of LIBX_BASE, but nothing ever set it.
3097 AC_SUBST(LD_SWITCH_X_SITE)
3098 AC_SUBST(C_SWITCH_X_SITE)
3099 AC_SUBST(C_SWITCH_X_SYSTEM)
3100 AC_SUBST(CFLAGS)
3101 ## Used in lwlib/Makefile.in.
3102 AC_SUBST(X_TOOLKIT_TYPE)
3103 if test -n "${machfile}"; then
3104   M_FILE="\$(srcdir)/${machfile}"
3105 else
3106   M_FILE=
3107 fi
3108 S_FILE="\$(srcdir)/${opsysfile}"
3109 AC_SUBST(M_FILE)
3110 AC_SUBST(S_FILE)
3111 AC_SUBST(GETLOADAVG_LIBS)
3112 AC_SUBST(ns_appdir)
3113 AC_SUBST(ns_appbindir)
3114 AC_SUBST(ns_appresdir)
3115 AC_SUBST(ns_appsrc)
3116 AC_SUBST(GNU_OBJC_CFLAGS)
3117 AC_SUBST(OTHER_FILES)
3118
3119 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3120                    [Define to the canonical Emacs configuration name.])
3121 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3122                    [Define to the options passed to configure.])
3123 if test -n "$machfile"; then
3124   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3125                      [Define to the used machine dependent file.])
3126 fi
3127 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3128                    [Define to the used os dependent file.])
3129
3130 XMENU_OBJ=
3131 XOBJ=
3132 FONT_OBJ=
3133 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3134   AC_DEFINE(HAVE_X_WINDOWS, 1,
3135             [Define to 1 if you want to use the X window system.])
3136   XMENU_OBJ=xmenu.o
3137   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3138   FONT_OBJ=xfont.o
3139   if test "$HAVE_XFT" = "yes"; then
3140     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3141   elif test "$HAVE_FREETYPE" = "yes"; then
3142     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3143   fi
3144   AC_SUBST(FONT_OBJ)
3145 fi
3146 AC_SUBST(XMENU_OBJ)
3147 AC_SUBST(XOBJ)
3148 AC_SUBST(FONT_OBJ)
3149
3150 WIDGET_OBJ=
3151 MOTIF_LIBW=
3152 if test "${USE_X_TOOLKIT}" != "none" ; then
3153   WIDGET_OBJ=widget.o
3154   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3155   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3156     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3157   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3158     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3159     MOTIF_LIBW=-lXm
3160     case "$opsys" in
3161       gnu-linux)
3162         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3163         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3164         ;;
3165
3166       unixware)
3167         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3168         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3169         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3170         ;;
3171
3172       aix4-2)
3173         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3174         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3175         ;;
3176     esac
3177     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3178   fi
3179 fi
3180 AC_SUBST(WIDGET_OBJ)
3181
3182 TOOLKIT_LIBW=
3183 case "$USE_X_TOOLKIT" in
3184   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3185   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3186   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3187 esac
3188 AC_SUBST(TOOLKIT_LIBW)
3189
3190 if test "$USE_X_TOOLKIT" = "none"; then
3191   LIBXT_OTHER="\$(LIBXSM)"
3192   OLDXMENU_TARGET="really-oldXMenu"
3193 else
3194   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3195   OLDXMENU_TARGET="really-lwlib"
3196 fi
3197 AC_SUBST(LIBXT_OTHER)
3198
3199 ## The X Menu stuff is present in the X10 distribution, but missing
3200 ## from X11.  If we have X10, just use the installed library;
3201 ## otherwise, use our own copy.
3202 if test "${HAVE_X11}" = "yes" ; then
3203   AC_DEFINE(HAVE_X11, 1,
3204             [Define to 1 if you want to use version 11 of X windows.
3205              Otherwise, Emacs expects to use version 10.])
3206
3207   if test "$USE_X_TOOLKIT" = "none"; then
3208     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3209   else
3210     OLDXMENU="\${lwlibdir}/liblw.a"
3211   fi
3212   LIBXMENU="\$(OLDXMENU)"
3213   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3214   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3215 else
3216   ## For a syntactically valid Makefile; not actually used for anything.
3217   ## See comments in src/Makefile.in.
3218   OLDXMENU=nothing
3219   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3220   if test "${HAVE_X_WINDOWS}" = "yes"; then
3221     LIBXMENU="-lXMenu"
3222   else
3223     LIBXMENU=
3224   fi
3225   LIBX_OTHER=
3226   OLDXMENU_DEPS=
3227 fi
3228
3229 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3230   OLDXMENU_TARGET=
3231   OLDXMENU=nothing
3232   LIBXMENU=
3233   OLDXMENU_DEPS=
3234 fi
3235
3236 AC_SUBST(OLDXMENU_TARGET)
3237 AC_SUBST(OLDXMENU)
3238 AC_SUBST(LIBXMENU)
3239 AC_SUBST(LIBX_OTHER)
3240 AC_SUBST(OLDXMENU_DEPS)
3241
3242 if test "${HAVE_MENUS}" = "yes" ; then
3243   AC_DEFINE(HAVE_MENUS, 1,
3244             [Define to 1 if you have mouse menus.
3245              (This is automatic if you use X, but the option to specify it remains.)
3246              It is also defined with other window systems that support xmenu.c.])
3247 fi
3248
3249 if test "${GNU_MALLOC}" = "yes" ; then
3250   AC_DEFINE(GNU_MALLOC, 1,
3251             [Define to 1 if you want to use the GNU memory allocator.])
3252 fi
3253
3254 RALLOC_OBJ=
3255 if test "${REL_ALLOC}" = "yes" ; then
3256   AC_DEFINE(REL_ALLOC, 1,
3257             [Define REL_ALLOC if you want to use the relocating allocator for
3258              buffer space.])
3259
3260   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3261 fi
3262 AC_SUBST(RALLOC_OBJ)
3263
3264 if test "$opsys" = "cygwin"; then
3265   CYGWIN_OBJ="sheap.o"
3266   ## Cygwin differs because of its unexec().
3267   PRE_ALLOC_OBJ=
3268   POST_ALLOC_OBJ=lastfile.o
3269 else
3270   CYGWIN_OBJ=
3271   PRE_ALLOC_OBJ=lastfile.o
3272   POST_ALLOC_OBJ=
3273 fi
3274 AC_SUBST(CYGWIN_OBJ)
3275 AC_SUBST(PRE_ALLOC_OBJ)
3276 AC_SUBST(POST_ALLOC_OBJ)
3277
3278
3279 case "$opsys" in
3280   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3281
3282   darwin)
3283    ## The -headerpad option tells ld (see man page) to leave room at the
3284    ## end of the header for adding load commands.  Needed for dumping.
3285    ## 0x690 is the total size of 30 segment load commands (at 56
3286    ## each); under Cocoa 31 commands are required.
3287    if test "$HAVE_NS" = "yes"; then
3288      libs_nsgui="-framework AppKit"
3289      headerpad_extra=6C8
3290    else
3291      libs_nsgui=
3292      headerpad_extra=690
3293    fi
3294    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3295
3296    ## This is here because src/Makefile.in did some extra fiddling around
3297    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3298    ##   #ifndef LD_SWITCH_SYSTEM
3299    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3300    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3301    ## not using gcc, darwin system not on an alpha (ie darwin, since
3302    ## darwin + alpha does not occur).
3303    ## Because this was done in src/Makefile.in, the resulting part of
3304    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3305    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3306    ## rather than LD_SWITCH_SYSTEM.
3307    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3308      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3309    ;;
3310
3311   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3312   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3313   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3314   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3315   ## had different values in configure (in ac_link) and src/Makefile.in.
3316   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3317   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3318
3319   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3320 esac
3321
3322 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3323   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3324 fi
3325
3326 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3327
3328
3329 LD_FIRSTFLAG=
3330 ORDINARY_LINK=
3331 case "$opsys" in
3332   ## gnu: GNU needs its own crt0.
3333   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3334
3335   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3336   ## library search parth, i.e. it won't search /usr/lib for libc and
3337   ## friends.  Using -nostartfiles instead avoids this problem, and
3338   ## will also work on earlier NetBSD releases.
3339   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3340
3341   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3342   ##   MkLinux/LinuxPPC needs this.
3343   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3344   gnu-*)
3345     case "$machine" in
3346       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3347     esac
3348     ;;
3349 esac
3350
3351
3352 if test "x$ORDINARY_LINK" = "xyes"; then
3353
3354   LD_FIRSTFLAG=""
3355   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3356
3357 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3358 ## freebsd, gnu-* not on macppc|ibms390x.
3359 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3360
3361   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3362   ## places that are difficult to figure out at make time.  Fortunately,
3363   ## these same versions allow you to pass arbitrary flags on to the
3364   ## linker, so there is no reason not to use it as a linker.
3365   ##
3366   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3367   ## searching for libraries in its internal directories, so we have to
3368   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3369   LD_FIRSTFLAG="-nostdlib"
3370 fi
3371
3372 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3373 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3374
3375 AC_SUBST(LD_FIRSTFLAG)
3376
3377
3378 ## FIXME? The logic here is not precisely the same as that above.
3379 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3380 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3381 LIB_GCC=
3382 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3383
3384   case "$opsys" in
3385     freebsd|netbsd|openbsd) LIB_GCC= ;;
3386
3387     gnu-*)
3388       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3389       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3390       case $host_cpu in
3391       arm*)
3392         LIB_GCC="-lgcc_s"
3393         ;;
3394       *)
3395         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3396         ## immediately undefine it again and redefine it to empty.
3397         ## Was the C_SWITCH_X_SITE part really necessary?
3398 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3399         LIB_GCC=
3400         ;;
3401       esac
3402       ;;
3403
3404     ## Ask GCC where to find libgcc.a.
3405     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3406   esac
3407 fi                              dnl if $GCC
3408 AC_SUBST(LIB_GCC)
3409
3410
3411 TOOLTIP_SUPPORT=
3412 WINDOW_SUPPORT=
3413 ## If we're using X11/GNUstep, define some consequences.
3414 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3415   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3416   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3417   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3418   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3419
3420   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3421   test "$HAVE_X_WINDOWS" = "yes" && \
3422     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3423
3424 fi
3425 AC_SUBST(MOUSE_SUPPORT)
3426 AC_SUBST(TOOLTIP_SUPPORT)
3427 AC_SUBST(WINDOW_SUPPORT)
3428
3429
3430 AH_TOP([/* GNU Emacs site configuration template file.
3431    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3432      2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
3433
3434 This file is part of GNU Emacs.
3435
3436 GNU Emacs is free software: you can redistribute it and/or modify
3437 it under the terms of the GNU General Public License as published by
3438 the Free Software Foundation, either version 3 of the License, or
3439 (at your option) any later version.
3440
3441 GNU Emacs is distributed in the hope that it will be useful,
3442 but WITHOUT ANY WARRANTY; without even the implied warranty of
3443 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3444 GNU General Public License for more details.
3445
3446 You should have received a copy of the GNU General Public License
3447 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3448
3449
3450 /* No code in Emacs #includes config.h twice, but some bits of code
3451    intended to work with other packages as well (like gmalloc.c)
3452    think they can include it as many times as they like.  */
3453 #ifndef EMACS_CONFIG_H
3454 #define EMACS_CONFIG_H
3455 ])dnl
3456
3457 AH_BOTTOM([
3458 /* Define AMPERSAND_FULL_NAME if you use the convention
3459    that & in the full name stands for the login id.  */
3460 /* Turned on June 1996 supposing nobody will mind it.  */
3461 #define AMPERSAND_FULL_NAME
3462
3463 /* If using GNU, then support inline function declarations.  */
3464 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3465    generally, because even if non-gcc compilers accept `inline', they
3466    may reject `extern inline'.  */
3467 #if defined (__GNUC__)
3468 #define INLINE __inline__
3469 #else
3470 #define INLINE
3471 #endif
3472
3473 /* `subprocesses' should be defined if you want to
3474    have code for asynchronous subprocesses
3475    (as used in M-x compile and M-x shell).
3476    Only MSDOS does not support this (it overrides
3477    this in its config_opsysfile below).  */
3478
3479 #define subprocesses
3480
3481 /* Include the os and machine dependent files.  */
3482 #include config_opsysfile
3483 #ifdef config_machfile
3484 # include config_machfile
3485 #endif
3486
3487 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3488    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3489   (There is probably a better place to do this, but right now the
3490    Cocoa side does this in s/darwin.h and we cannot parallel this
3491    exactly since GNUstep is multi-OS.  */
3492 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3493 #  define SYSTEM_PURESIZE_EXTRA 30000
3494 #endif
3495
3496 /* SIGTYPE is the macro we actually use.  */
3497 #ifndef SIGTYPE
3498 #define SIGTYPE RETSIGTYPE
3499 #endif
3500
3501 #ifdef emacs /* Don't do this for lib-src.  */
3502 /* Tell regex.c to use a type compatible with Emacs.  */
3503 #define RE_TRANSLATE_TYPE Lisp_Object
3504 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3505 #ifdef make_number
3506 /* If make_number is a macro, use it.  */
3507 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3508 #else
3509 /* If make_number is a function, avoid it.  */
3510 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3511 #endif
3512 #endif
3513
3514 #define my_strftime nstrftime   /* for strftime.c */
3515
3516 /* These default definitions are good for almost all machines.
3517    The exceptions override them in m/MACHINE.h.  */
3518
3519 #ifndef BITS_PER_CHAR
3520 #define BITS_PER_CHAR 8
3521 #endif
3522
3523 #ifndef BITS_PER_SHORT
3524 #define BITS_PER_SHORT 16
3525 #endif
3526
3527 /* Note that lisp.h uses this in a preprocessor conditional, so it
3528    would not work to use sizeof.  That being so, we do all of them
3529    without sizeof, for uniformity's sake.  */
3530 #ifndef BITS_PER_INT
3531 #define BITS_PER_INT 32
3532 #endif
3533
3534 #ifndef BITS_PER_LONG
3535 #ifdef _LP64
3536 #define BITS_PER_LONG 64
3537 #else
3538 #define BITS_PER_LONG 32
3539 #endif
3540 #endif
3541
3542 /* Define if the compiler supports function prototypes.  It may do so but
3543    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3544 #undef PROTOTYPES
3545
3546 #include <string.h>
3547 #include <stdlib.h>
3548
3549 #ifdef HAVE_ALLOCA_H
3550 # include <alloca.h>
3551 #elif defined __GNUC__
3552 # define alloca __builtin_alloca
3553 #elif defined _AIX
3554 # define alloca __alloca
3555 #else
3556 # include <stddef.h>
3557 # ifdef  __cplusplus
3558 extern "C"
3559 # endif
3560 void *alloca (size_t);
3561 #endif
3562
3563 #ifndef HAVE_SIZE_T
3564 typedef unsigned size_t;
3565 #endif
3566
3567 #ifndef HAVE_STRCHR
3568 #define strchr(a, b) index (a, b)
3569 #endif
3570
3571 #ifndef HAVE_STRRCHR
3572 #define strrchr(a, b) rindex (a, b)
3573 #endif
3574
3575 #if defined __GNUC__ && (__GNUC__ > 2 \
3576                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3577 #define NO_RETURN       __attribute__ ((__noreturn__))
3578 #else
3579 #define NO_RETURN       /* nothing */
3580 #endif
3581
3582 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3583 #define NO_INLINE __attribute__((noinline))
3584 #else
3585 #define NO_INLINE
3586 #endif
3587
3588 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3589 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3590 #else
3591 #define EXTERNALLY_VISIBLE
3592 #endif
3593
3594 /* Some versions of GNU/Linux define noinline in their headers.  */
3595 #ifdef noinline
3596 #undef noinline
3597 #endif
3598
3599 /* These won't be used automatically yet.  We also need to know, at least,
3600    that the stack is continuous.  */
3601 #ifdef __GNUC__
3602 #  ifndef GC_SETJMP_WORKS
3603   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3604 #    define GC_SETJMP_WORKS 1
3605 #  endif
3606 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3607 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3608 #  endif
3609 #endif
3610
3611 #endif /* EMACS_CONFIG_H */
3612
3613 /*
3614 Local Variables:
3615 mode: c
3616 End:
3617 */
3618 ])dnl
3619
3620 #### Report on what we decided to do.
3621 #### Report GTK as a toolkit, even if it doesn't use Xt.
3622 #### It makes printing result more understandable as using GTK sets
3623 #### toolkit_scroll_bars to yes by default.
3624 if test "${HAVE_GTK}" = "yes"; then
3625   USE_X_TOOLKIT=GTK
3626 fi
3627
3628 and_machfile=
3629 if test -n "$machfile"; then
3630   and_machfile=" and \`${machfile}'"
3631 fi
3632
3633 echo "
3634 Configured for \`${canonical}'.
3635
3636   Where should the build process find the source code?    ${srcdir}
3637   What operating system and machine description files should Emacs use?
3638         \`${opsysfile}'${and_machfile}
3639   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3640   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3641   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3642   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3643   What window system should Emacs use?                    ${window_system}
3644   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3645
3646 if test -n "${x_includes}"; then
3647 echo "  Where do we find X Windows header files?                ${x_includes}"
3648 else
3649 echo "  Where do we find X Windows header files?                Standard dirs"
3650 fi
3651 if test -n "${x_libraries}"; then
3652 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3653 else
3654 echo "  Where do we find X Windows libraries?                   Standard dirs"
3655 fi
3656
3657 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3658 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3659 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3660 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3661 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3662 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3663 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3664 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3665
3666 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3667 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3668 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3669 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3670 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3671 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3672
3673 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3674 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3675 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3676 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3677
3678 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3679 echo
3680
3681 if test $USE_XASSERTS = yes; then
3682    echo "  Compiling with asserts turned on."
3683    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3684 fi
3685
3686 echo
3687
3688 if test "$HAVE_NS" = "yes"; then
3689    echo
3690    echo "You must run \"make install\" in order to test the built application.
3691 The installed application will go to nextstep/Emacs.app and can be
3692 run or moved from there."
3693    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3694       echo "The application will be fully self-contained."
3695     else
3696       echo "The lisp resources for the application will be installed under ${prefix}.
3697 You may need to run \"make install\" with sudo.  The application will fail
3698 to run if these resources are not installed."
3699    fi
3700    echo
3701 fi
3702
3703
3704 # Remove any trailing slashes in these variables.
3705 [test "${prefix}" != NONE &&
3706   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3707 test "${exec_prefix}" != NONE &&
3708   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3709
3710 dnl You might wonder (I did) why epaths.h is generated by running make,
3711 dnl rather than just letting configure generate it from epaths.in.
3712 dnl One reason is that the various paths are not fully expanded (see above);
3713 dnl eg gamedir=${prefix}/var/games/emacs.
3714 dnl Secondly, the GNU Coding standards require that one should be able
3715 dnl to run `make prefix=/some/where/else' and override the values set
3716 dnl by configure.  This also explains the `move-if-change' test and
3717 dnl the use of force in the `epaths-force' rule in Makefile.in.
3718 AC_OUTPUT(Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3719         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3720         doc/lispref/Makefile src/Makefile \
3721         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile, [
3722
3723 ### Make the necessary directories, if they don't exist.
3724 for dir in etc lisp ; do
3725   test -d ${dir} || mkdir ${dir}
3726 done
3727
3728 echo creating src/epaths.h
3729 ${MAKE-make} epaths-force
3730
3731 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3732   echo creating src/.gdbinit
3733   echo source $srcdir/src/.gdbinit > src/.gdbinit
3734 fi
3735
3736 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3737