configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.4.1)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h:src/config.in)
   8
   9 lispdir='${datadir}/emacs/${version}/lisp'
  10 locallisppath='${datadir}/emacs/site-lisp'
  11 lisppath='${locallisppath}:${lispdir}'
  12 etcdir='${datadir}/emacs/${version}/etc'
  13 lockdir='${sharedstatedir}/emacs/lock'
  14 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  15 docdir='${datadir}/emacs/${version}/etc'
  16
  17 AC_ARG_WITH(gcc,
  18 [  --with-gcc              use GCC to compile Emacs])
  19 AC_ARG_WITH(pop,
  20 [  --with-pop              support POP for mail retrieval],
  21 [AC_DEFINE(MAIL_USE_POP)])
  22 AC_ARG_WITH(kerberos,
  23 [  --with-kerberos         support Kerberos-authenticated POP],
  24 [AC_DEFINE(KERBEROS)])
  25 AC_ARG_WITH(hesiod,
  26 [  --with-hesiod           support Hesiod to get the POP server host],
  27 [AC_DEFINE(HESIOD)])
  28 dnl This should be the last --with option, because --with-x is
  29 dnl added later on when we find the path of X, and it's best to
  30 dnl keep them together visually.
  31 AC_ARG_WITH(x-toolkit,
  32 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif)],
  33 [         case "${withval}" in
  34             y | ye | yes )      val=athena ;;
  35             n | no )            val=no  ;;
  36             l | lu | luc | luci | lucid )       val=lucid ;;
  37             a | at | ath | athe | athen | athena )      val=athena ;;
  38             m | mo | mot | moti | motif )       val=motif ;;
  39 dnl These don't currently work.
  40 dnl         o | op | ope | open | open- | open-l | open-lo \
  41 dnl             | open-loo | open-look )        val=open-look ;;
  42             * )
  43 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  44 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  45 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
  46 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
  47 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  48             ;;
  49           esac
  50           with_x_toolkit=$val
  51 ])
  52
  53 #### Make srcdir absolute, if it isn't already.  It's important to
  54 #### avoid running the path through pwd unnecessary, since pwd can
  55 #### give you automounter prefixes, which can go away.  We do all this
  56 #### so Emacs can find its files when run uninstalled.
  57 case "${srcdir}" in
  58   /* ) ;;
  59   . )
  60     ## We may be able to use the $PWD environment variable to make this
  61     ## absolute.  But sometimes PWD is inaccurate.
  62     ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
  63     CDPATH=
  64     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  65     then
  66       srcdir="$PWD"
  67     else
  68       srcdir="`(cd ${srcdir}; pwd)`"
  69     fi
  70   ;;
  71   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  72 esac
  73
  74 #### Check if the source directory already has a configured system in it.
  75 if test `pwd` != `(cd ${srcdir} && pwd)` \
  76    && test -f "${srcdir}/src/config.h" ; then
  77   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  78    as a build directory right now; it has been configured in its own
  79    right.  To configure in another directory as well, you MUST
  80    use GNU make.  If you do not have GNU make, then you must
  81    now do \`make distclean' in ${srcdir},
  82    and then run $0 again.])
  83
  84 changequote(, )dnl
  85   extrasub='/^VPATH[     ]*=/c\
  86 changequote([, ])dnl
  87 vpath %.c $(srcdir)\
  88 vpath %.h $(srcdir)\
  89 vpath %.y $(srcdir)\
  90 vpath %.l $(srcdir)\
  91 vpath %.s $(srcdir)\
  92 vpath %.in $(srcdir)'
  93 fi
  94
  95 #### Given the configuration name, set machfile and opsysfile to the
  96 #### names of the m/*.h and s/*.h files we should use.
  97
  98 ### Canonicalize the configuration name.
  99
 100 AC_CANONICAL_HOST
 101 canonical=$host
 102 configuration=$host_alias
 103
 104 changequote(, )dnl
 105
 106 ### If you add support for a new configuration, add code to this
 107 ### switch statement to recognize your configuration name and select
 108 ### the appropriate operating system and machine description files.
 109
 110 ### You would hope that you could choose an m/*.h file pretty much
 111 ### based on the machine portion of the configuration name, and an s-
 112 ### file based on the operating system portion.  However, it turns out
 113 ### that each m/*.h file is pretty manufacturer-specific - for
 114 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 115 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 116 ### machines.  So we basically have to have a special case for each
 117 ### configuration name.
 118 ###
 119 ### As far as handling version numbers on operating systems is
 120 ### concerned, make sure things will fail in a fixable way.  If
 121 ### /etc/MACHINES doesn't say anything about version numbers, be
 122 ### prepared to handle anything reasonably.  If version numbers
 123 ### matter, be sure /etc/MACHINES says something about it.
 124 ###
 125 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 126 ### "System V Release 4"; he writes, "The old convention encouraged
 127 ### confusion between `system' and `release' levels'."
 128
 129 machine='' opsys='' unported=no
 130 case "${canonical}" in
 131
 132   ## NetBSD ports
 133   *-*-netbsd* )
 134     opsys=netbsd
 135     case "${canonical}" in
 136       i[345]86-*-netbsd*) machine=intel386 ;;
 137       m68k-*-netbsd*)
 138                         # This is somewhat bogus.
 139                         machine=hp9000s300 ;;
 140       mips-*-netbsd*)   machine=pmax ;;
 141       ns32k-*-netbsd*)  machine=ns32000 ;;
 142       sparc-*-netbsd*)  machine=sparc ;;
 143     esac
 144   ;;
 145
 146   ## Acorn RISCiX:
 147   arm-acorn-riscix1.1* )
 148     machine=acorn opsys=riscix1-1
 149   ;;
 150   arm-acorn-riscix1.2* | arm-acorn-riscix )
 151     machine=acorn opsys=riscix1-2
 152   ;;
 153
 154   ## Alliant machines
 155   ## Strictly speaking, we need the version of the alliant operating
 156   ## system to choose the right machine file, but currently the
 157   ## configuration name doesn't tell us enough to choose the right
 158   ## one; we need to give alliants their own operating system name to
 159   ## do this right.  When someone cares, they can help us.
 160   fx80-alliant-* )
 161     machine=alliant4 opsys=bsd4-2
 162   ;;
 163   i860-alliant-* )
 164     machine=alliant-2800 opsys=bsd4-3
 165   ;;
 166
 167   ## Alpha (DEC) machines.
 168   alpha-dec-osf* )
 169     machine=alpha opsys=osf1
 170   ;;
 171
 172   alpha-*-linux* )
 173     machine=alpha opsys=linux
 174   ;;
 175
 176   ## Altos 3068
 177   m68*-altos-sysv* )
 178     machine=altos opsys=usg5-2
 179   ;;
 180
 181   ## Amdahl UTS
 182   580-amdahl-sysv* )
 183     machine=amdahl opsys=usg5-2-2
 184   ;;
 185
 186   ## Apollo, Domain/OS
 187   m68*-apollo-* )
 188     machine=apollo opsys=bsd4-3
 189   ;;
 190
 191   ## AT&T 3b2, 3b5, 3b15, 3b20
 192   we32k-att-sysv* )
 193     machine=att3b opsys=usg5-2-2
 194   ;;
 195
 196   ## AT&T 3b1 - The Mighty Unix PC!
 197   m68*-att-sysv* )
 198     machine=7300 opsys=usg5-2-2
 199   ;;
 200
 201   ## Bull dpx20
 202   rs6000-bull-bosx* )
 203     machine=ibmrs6000 opsys=aix3-2
 204   ;;
 205
 206   ## Bull dpx2
 207   m68*-bull-sysv3* )
 208     machine=dpx2 opsys=usg5-3
 209   ;;
 210
 211   ## Bull sps7
 212   m68*-bull-sysv2* )
 213     machine=sps7 opsys=usg5-2
 214   ;;
 215
 216   ## CCI 5/32, 6/32 -- see "Tahoe".
 217
 218   ## Celerity
 219   ## I don't know what configuration name to use for this; config.sub
 220   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 221   ## in touch with us!
 222   celerity-celerity-bsd* )
 223     machine=celerity opsys=bsd4-2
 224   ;;
 225
 226   ## Clipper
 227   ## What operating systems does this chip run that Emacs has been
 228   ## tested on?
 229   clipper-* )
 230     machine=clipper
 231     ## We'll use the catch-all code at the bottom to guess the
 232     ## operating system.
 233   ;;
 234
 235   ## Convex
 236   *-convex-bsd* | *-convex-convexos* )
 237     machine=convex opsys=bsd4-3
 238     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 239     NON_GNU_CPP="cc -E -P"
 240   ;;
 241
 242   ## Cubix QBx/386
 243   i[345]86-cubix-sysv* )
 244     machine=intel386 opsys=usg5-3
 245   ;;
 246
 247   ## Cydra 5
 248   cydra*-cydrome-sysv* )
 249     machine=cydra5 opsys=usg5-3
 250   ;;
 251
 252   ## Data General AViiON Machines
 253   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 254     machine=aviion opsys=dgux5-4r3
 255   ;;
 256   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 257     machine=aviion opsys=dgux5-4r2
 258   ;;
 259   m88k-dg-dgux* )
 260     machine=aviion opsys=dgux
 261   ;;
 262
 263   ## DECstations
 264   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 265     machine=pmax opsys=bsd4-2
 266   ;;
 267   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 268     machine=pmax opsys=bsd4-3
 269   ;;
 270   mips-dec-ultrix* )
 271     machine=pmax opsys=ultrix4-3
 272   ;;
 273   mips-dec-osf* )
 274     machine=pmax opsys=osf1
 275   ;;
 276   mips-dec-mach_bsd4.3* )
 277     machine=pmax opsys=mach-bsd4-3
 278   ;;
 279
 280   ## Motorola Delta machines
 281   m68k-motorola-sysv* | m68000-motorola-sysv* )
 282     machine=delta opsys=usg5-3
 283     if test -z "`type gnucc | grep 'not found'`"
 284     then
 285       if test -s /etc/167config
 286       then CC="gnucc -m68040"
 287       else CC="gnucc -m68881"
 288       fi
 289     else
 290       if test -z "`type gcc | grep 'not found'`"
 291       then CC=gcc
 292       else CC=cc
 293       fi
 294     fi
 295   ;;
 296   m88k-motorola-sysv4* )
 297     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 298     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 299     # I hope there are not other 4.0 versions for this machine
 300     # which really need usg5-4 instead.
 301     machine=delta88k opsys=usg5-4-2
 302   ;;
 303   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 304     machine=delta88k opsys=usg5-3
 305   ;;
 306
 307   ## Dual machines
 308   m68*-dual-sysv* )
 309     machine=dual opsys=usg5-2
 310   ;;
 311   m68*-dual-uniplus* )
 312     machine=dual opsys=unipl5-2
 313   ;;
 314
 315   ## Elxsi 6400
 316   elxsi-elxsi-sysv* )
 317     machine=elxsi opsys=usg5-2
 318   ;;
 319
 320   ## Encore machines
 321   ns16k-encore-bsd* )
 322     machine=ns16000 opsys=umax
 323   ;;
 324
 325   ## The GEC 93 - apparently, this port isn't really finished yet.
 326
 327   ## Gould Power Node and NP1
 328   pn-gould-bsd4.2* )
 329     machine=gould opsys=bsd4-2
 330   ;;
 331   pn-gould-bsd4.3* )
 332     machine=gould opsys=bsd4-3
 333   ;;
 334   np1-gould-bsd* )
 335     machine=gould-np1 opsys=bsd4-3
 336   ;;
 337
 338   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 339   ## as far as Emacs is concerned).
 340   m88k-harris-cxux* )
 341     # Build needs to be different on 7.0 and later releases
 342     case "`uname -r`" in
 343        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 344        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 345     esac
 346     NON_GNU_CPP="/lib/cpp"
 347   ;;
 348   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 349   m68k-harris-cxux* )
 350     machine=nh3000 opsys=cxux
 351   ;;
 352   ## Harris power pc NightHawk running Power UNIX (Series 6000)
 353   powerpc-harris-powerunix )
 354     machine=nh6000 opsys=powerunix
 355     NON_GNU_CPP="cc -Xo -E -P"
 356   ;;
 357
 358   ## Honeywell XPS100
 359   xps*-honeywell-sysv* )
 360     machine=xps100 opsys=usg5-2
 361   ;;
 362
 363   ## HP 9000 series 200 or 300
 364   m68*-hp-bsd* )
 365     machine=hp9000s300 opsys=bsd4-3
 366   ;;
 367   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 368   m68*-hp-hpux* )
 369     case "`uname -r`" in
 370       ## Someone's system reports A.B8.05 for this.
 371       ## I wonder what other possibilities there are.
 372       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 373       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 374       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 375       *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
 376       *) machine=hp9000s300 opsys=hpux ;;
 377     esac
 378   ;;
 379
 380   ## HP 9000 series 700 and 800, running HP/UX
 381   hppa*-hp-hpux7* )
 382     machine=hp800 opsys=hpux
 383   ;;
 384   hppa*-hp-hpux8* )
 385     machine=hp800 opsys=hpux8
 386   ;;
 387   hppa*-hp-hpux9shr* )
 388     machine=hp800 opsys=hpux9shr
 389   ;;
 390   hppa*-hp-hpux9* )
 391     machine=hp800 opsys=hpux9
 392   ;;
 393   hppa*-hp-hpux10* )
 394     machine=hp800 opsys=hpux10
 395   ;;
 396
 397   ## HP 9000 series 700 and 800, running HP/UX
 398   hppa*-hp-hpux* )
 399     ## Cross-compilation?  Nah!
 400     case "`uname -r`" in
 401       ## Someone's system reports A.B8.05 for this.
 402       ## I wonder what other possibilities there are.
 403       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 404       *.08.* ) machine=hp800 opsys=hpux8 ;;
 405       *.09.* ) machine=hp800 opsys=hpux9 ;;
 406       *) machine=hp800 opsys=hpux ;;
 407     esac
 408   ;;
 409
 410   ## Orion machines
 411   orion-orion-bsd* )
 412     machine=orion opsys=bsd4-2
 413   ;;
 414   clipper-orion-bsd* )
 415     machine=orion105 opsys=bsd4-2
 416   ;;
 417
 418   ## IBM machines
 419   i[345]86-ibm-aix1.1* )
 420     machine=ibmps2-aix opsys=usg5-2-2
 421   ;;
 422   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 423     machine=ibmps2-aix opsys=usg5-3
 424   ;;
 425   i370-ibm-aix*)
 426     machine=ibm370aix opsys=usg5-3
 427   ;;
 428   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 429     machine=ibmrs6000 opsys=aix3-1
 430   ;;
 431   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 432     machine=ibmrs6000 opsys=aix3-2-5
 433   ;;
 434   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 435     machine=ibmrs6000 opsys=aix4-1
 436   ;;
 437   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 438     machine=ibmrs6000 opsys=aix4
 439   ;;
 440   rs6000-ibm-aix* | powerpc-ibm-aix* )
 441     machine=ibmrs6000 opsys=aix3-2
 442   ;;
 443   romp-ibm-bsd4.3* )
 444     machine=ibmrt opsys=bsd4-3
 445   ;;
 446   romp-ibm-bsd4.2* )
 447     machine=ibmrt opsys=bsd4-2
 448   ;;
 449   romp-ibm-aos4.3* )
 450     machine=ibmrt opsys=bsd4-3
 451   ;;
 452   romp-ibm-aos4.2* )
 453     machine=ibmrt opsys=bsd4-2
 454   ;;
 455   romp-ibm-aos* )
 456     machine=ibmrt opsys=bsd4-3
 457   ;;
 458   romp-ibm-bsd* )
 459     machine=ibmrt opsys=bsd4-3
 460   ;;
 461   romp-ibm-aix* )
 462     machine=ibmrt-aix opsys=usg5-2-2
 463   ;;
 464
 465   ## Integrated Solutions `Optimum V'
 466   m68*-isi-bsd4.2* )
 467     machine=isi-ov opsys=bsd4-2
 468   ;;
 469   m68*-isi-bsd4.3* )
 470     machine=isi-ov opsys=bsd4-3
 471   ;;
 472
 473   ## Intel 386 machines where we do care about the manufacturer
 474   i[345]86-intsys-sysv* )
 475     machine=is386 opsys=usg5-2-2
 476   ;;
 477
 478   ## Prime EXL
 479   i[345]86-prime-sysv* )
 480     machine=i386 opsys=usg5-3
 481   ;;
 482
 483   ## Sequent Symmetry running Dynix
 484   i[345]86-sequent-bsd* )
 485     machine=symmetry opsys=bsd4-3
 486   ;;
 487
 488   ## Sequent Symmetry running DYNIX/ptx
 489   ## Use the old cpp rather than the newer ANSI one.
 490   i[345]86-sequent-ptx* )
 491     machine=sequent-ptx opsys=ptx
 492     NON_GNU_CPP="/lib/cpp"
 493   ;;
 494
 495   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 496   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 497   i[345]86-ncr-sysv* )
 498     machine=ncr386 opsys=usg5-4-2
 499   ;;
 500
 501   ## Intel Paragon OSF/1
 502   i860-intel-osf1* )
 503     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 504   ;;
 505
 506   ## Intel 860
 507   i860-*-sysv4* )
 508     machine=i860 opsys=usg5-4
 509     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 510     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 511   ;;
 512
 513   ## Masscomp machines
 514   m68*-masscomp-rtu* )
 515     machine=masscomp opsys=rtu
 516   ;;
 517
 518   ## Megatest machines
 519   m68*-megatest-bsd* )
 520     machine=mega68 opsys=bsd4-2
 521   ;;
 522
 523   ## Workstations sold by MIPS
 524   ## This is not necessarily all workstations using the MIPS processor -
 525   ## Irises are produced by SGI, and DECstations by DEC.
 526
 527   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 528   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 529   ## it gives for choosing between the alternatives seems to be "Use
 530   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 531   ## the BSD world."  I'll assume that these are instructions for
 532   ## handling two odd situations, and that every other situation
 533   ## should use mips.h and usg5-2-2, they being listed first.
 534   mips-mips-usg* )
 535     machine=mips4
 536     ## Fall through to the general code at the bottom to decide on the OS.
 537   ;;
 538   mips-mips-riscos4* )
 539     machine=mips4 opsys=bsd4-3
 540     NON_GNU_CC="cc -systype bsd43"
 541     NON_GNU_CPP="cc -systype bsd43 -E"
 542   ;;
 543   mips-mips-riscos5* )
 544     machine=mips4 opsys=riscos5
 545     NON_GNU_CC="cc -systype bsd43"
 546     NON_GNU_CPP="cc -systype bsd43 -E"
 547   ;;
 548   mips-mips-bsd* )
 549     machine=mips opsys=bsd4-3
 550   ;;
 551   mips-mips-* )
 552     machine=mips opsys=usg5-2-2
 553   ;;
 554
 555   ## NeXT
 556   m68*-next-* | m68k-*-nextstep* )
 557     machine=m68k opsys=nextstep
 558   ;;
 559
 560   ## The complete machine from National Semiconductor
 561   ns32k-ns-genix* )
 562     machine=ns32000 opsys=usg5-2
 563   ;;
 564
 565   ## NCR machines
 566   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 567     machine=tower32 opsys=usg5-2-2
 568   ;;
 569   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 570     machine=tower32v3 opsys=usg5-3
 571   ;;
 572
 573   ## Nixdorf Targon 31
 574   m68*-nixdorf-sysv* )
 575     machine=targon31 opsys=usg5-2-2
 576   ;;
 577
 578   ## Nu (TI or LMI)
 579   m68*-nu-sysv* )
 580     machine=nu opsys=usg5-2
 581   ;;
 582
 583   ## Plexus
 584   m68*-plexus-sysv* )
 585     machine=plexus opsys=usg5-2
 586   ;;
 587
 588   ## Pyramid machines
 589   ## I don't really have any idea what sort of processor the Pyramid has,
 590   ## so I'm assuming it is its own architecture.
 591   pyramid-pyramid-bsd* )
 592     machine=pyramid opsys=bsd4-2
 593   ;;
 594
 595   ## Sequent Balance
 596   ns32k-sequent-bsd4.2* )
 597     machine=sequent opsys=bsd4-2
 598   ;;
 599   ns32k-sequent-bsd4.3* )
 600     machine=sequent opsys=bsd4-3
 601   ;;
 602
 603   ## Siemens Nixdorf
 604   mips-siemens-sysv* | mips-sni-sysv*)
 605     machine=mips-siemens opsys=usg5-4
 606     NON_GNU_CC=/usr/ccs/bin/cc
 607     NON_GNU_CPP=/usr/ccs/lib/cpp
 608   ;;
 609
 610   ## Silicon Graphics machines
 611   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 612   m68*-sgi-iris3.5* )
 613     machine=irist opsys=iris3-5
 614   ;;
 615   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 616     machine=irist opsys=iris3-6
 617   ;;
 618   ## Iris 4D
 619   mips-sgi-irix3* )
 620     machine=iris4d opsys=irix3-3
 621   ;;
 622   mips-sgi-irix4* )
 623     machine=iris4d opsys=irix4-0
 624   ;;
 625   mips-sgi-irix6* )
 626     machine=iris4d opsys=irix6-0  NON_GNU_CPP=/lib/cpp
 627   ;;
 628   mips-sgi-irix5.[01]* )
 629     machine=iris4d opsys=irix5-0
 630   ;;
 631   mips-sgi-irix5* | mips-sgi-irix* )
 632     machine=iris4d opsys=irix5-2
 633   ;;
 634
 635   ## SONY machines
 636   m68*-sony-bsd4.2* )
 637     machine=news opsys=bsd4-2
 638   ;;
 639   m68*-sony-bsd4.3* )
 640     machine=news opsys=bsd4-3
 641   ;;
 642   m68*-sony-newsos3* | m68*-sony-news3*)
 643     machine=news opsys=bsd4-3
 644   ;;
 645   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 646     machine=news-risc opsys=bsd4-3
 647   ;;
 648   mips-sony-news* )
 649     machine=news-risc opsys=newsos5
 650   ;;
 651
 652   ## Stride
 653   m68*-stride-sysv* )
 654     machine=stride opsys=usg5-2
 655   ;;
 656
 657   ## Suns
 658   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 659     | i[345]86-*-solaris2* | i[345]86-*-sunos5* | powerpc*-*-solaris2* \
 660     | rs6000-*-solaris2*)
 661     case "${canonical}" in
 662       m68*-sunos1* )    machine=sun1 ;;
 663       m68*-sunos2* )    machine=sun2 ;;
 664       m68* )            machine=sun3 ;;
 665       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 666       i[345]86-*-* )     machine=intel386 ;;
 667       powerpc* | rs6000* )  machine=rs6000 ;;
 668       sparc* )          machine=sparc ;;
 669       * )               unported=yes ;;
 670     esac
 671     case "${canonical}" in
 672       ## The Sun386 didn't get past 4.0.
 673       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 674       *-sunos4.0*         ) opsys=sunos4-0 ;;
 675       *-sunos4.1.[3-9]* | *-sunos4shr*)
 676                 opsys=sunos4shr
 677                 NON_GNU_CPP=/usr/lib/cpp
 678                 ;;
 679       *-sunos4.1.[3-9]*-noshare )
 680                 opsys=sunos4-1-3
 681                 NON_GNU_CPP=/usr/lib/cpp
 682                 NON_GCC_TEST_OPTIONS=-Bstatic
 683                 GCC_TEST_OPTIONS=-static
 684                 ;;
 685       *-sunos4* | *-sunos )
 686                 opsys=sunos4-1
 687                 NON_GCC_TEST_OPTIONS=-Bstatic
 688                 GCC_TEST_OPTIONS=-static
 689                 ;;
 690       *-sunos5.3* | *-solaris2.3* )
 691                 opsys=sol2-3
 692                 NON_GNU_CPP=/usr/ccs/lib/cpp
 693                 ;;
 694       *-sunos5.4* | *-solaris2.4* )
 695                 opsys=sol2-4
 696                 NON_GNU_CPP=/usr/ccs/lib/cpp
 697                 RANLIB="ar -ts"
 698                 ;;
 699       *-sunos5.5* | *-solaris2.5* )
 700                 opsys=sol2-5
 701                 NON_GNU_CPP=/usr/ccs/lib/cpp
 702                 RANLIB="ar -ts"
 703                 ;;
 704       *-sunos5* | *-solaris* )
 705                 opsys=sol2-4
 706                 NON_GNU_CPP=/usr/ccs/lib/cpp
 707                 ;;
 708       *                   ) opsys=bsd4-2   ;;
 709     esac
 710   ;;
 711   sparc-*-nextstep* )
 712     machine=sparc opsys=nextstep
 713   ;;
 714
 715   ## Tadpole 68k
 716   m68*-tadpole-sysv* )
 717     machine=tad68k opsys=usg5-3
 718   ;;
 719
 720   ## Tahoe machines
 721   tahoe-tahoe-bsd4.2* )
 722     machine=tahoe opsys=bsd4-2
 723   ;;
 724   tahoe-tahoe-bsd4.3* )
 725     machine=tahoe opsys=bsd4-3
 726   ;;
 727
 728   ## Tandem Integrity S2
 729   mips-tandem-sysv* )
 730     machine=tandem-s2 opsys=usg5-3
 731   ;;
 732
 733   ## Tektronix XD88
 734   m88k-tektronix-sysv3* )
 735   machine=tekxd88 opsys=usg5-3
 736   ;;
 737
 738   ## Tektronix 16000 box (6130?)
 739   ns16k-tektronix-bsd* )
 740     machine=ns16000 opsys=bsd4-2
 741   ;;
 742   ## Tektronix 4300
 743   ## src/m/tek4300.h hints that this is a m68k machine.
 744   m68*-tektronix-bsd* )
 745     machine=tek4300 opsys=bsd4-3
 746   ;;
 747
 748   ## Titan P2 or P3
 749   ## We seem to have lost the machine-description file titan.h!
 750   titan-titan-sysv* )
 751     machine=titan opsys=usg5-3
 752   ;;
 753
 754   ## Ustation E30 (SS5E)
 755   m68*-unisys-uniplus* )
 756     machine=ustation opsystem=unipl5-2
 757   ;;
 758
 759   ## Vaxen.
 760   vax-dec-* )
 761     machine=vax
 762     case "${canonical}" in
 763       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 764       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 765       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 766       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 767       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 768       *-vms* )                                          opsys=vms ;;
 769       * )                                               unported=yes
 770     esac
 771   ;;
 772
 773   ## Whitechapel MG1
 774   ns16k-whitechapel-* )
 775     machine=mg1
 776     ## We don't know what sort of OS runs on these; we'll let the
 777     ## operating system guessing code below try.
 778   ;;
 779
 780   ## Wicat
 781   m68*-wicat-sysv* )
 782     machine=wicat opsys=usg5-2
 783   ;;
 784
 785   ## Intel 386 machines where we don't care about the manufacturer
 786   i[345]86-*-* )
 787     machine=intel386
 788     case "${canonical}" in
 789       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 790       *-isc2.2* )               opsys=isc2-2 ;;
 791       *-isc4.0* )               opsys=isc4-0 ;;
 792       *-isc4.* )                opsys=isc4-1
 793                                 GCC_TEST_OPTIONS=-posix
 794                                 NON_GCC_TEST_OPTIONS=-Xp
 795                                 ;;
 796       *-isc* )                  opsys=isc3-0 ;;
 797       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 798       *-esix* )                 opsys=esix ;;
 799       *-xenix* )                opsys=xenix ;;
 800       *-linux* )                opsys=linux ;;
 801       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 802       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
 803       *-bsdi2* )                opsys=bsdos2 ;;
 804       *-386bsd* )               opsys=386bsd ;;
 805       *-freebsd* )              opsys=freebsd ;;
 806       *-nextstep* )             opsys=nextstep ;;
 807       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 808     esac
 809   ;;
 810
 811   ## Linux/68k
 812   m68k-*-linux* )
 813     machine=m68k opsys=linux
 814   ;;
 815
 816   * )
 817     unported=yes
 818   ;;
 819 esac
 820
 821 ### If the code above didn't choose an operating system, just choose
 822 ### an operating system based on the configuration name.  You really
 823 ### only want to use this when you have no idea what the right
 824 ### operating system is; if you know what operating systems a machine
 825 ### runs, it's cleaner to make it explicit in the case statement
 826 ### above.
 827 if test x"${opsys}" = x; then
 828   case "${canonical}" in
 829     *-gnu* )                            opsys=gnu ;;
 830     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 831     *-bsd4.2 )                          opsys=bsd4-2 ;;
 832     *-bsd4.3 )                          opsys=bsd4-3 ;;
 833     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 834     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 835     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 836     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 837     *-sysv4.1* | *-sysvr4.1* )
 838         NON_GNU_CPP=/usr/lib/cpp
 839         opsys=usg5-4 ;;
 840     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 841         if [ x$NON_GNU_CPP = x ]; then
 842           NON_GNU_CPP=/usr/ccs/lib/cpp
 843         fi
 844         opsys=usg5-4-2 ;;
 845     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 846     * )
 847       unported=yes
 848     ;;
 849   esac
 850 fi
 851
 852 if test "x$RANLIB" = x; then
 853   RANLIB=ranlib
 854 fi
 855
 856 changequote([, ])dnl
 857
 858 if test $unported = yes; then
 859   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 860 Check \`etc/MACHINES' for recognized configuration names.])
 861 fi
 862
 863 machfile="m/${machine}.h"
 864 opsysfile="s/${opsys}.h"
 865
 866
 867 #### Choose a compiler.
 868 test -n "$CC" && cc_specified=yes
 869
 870 # Save the value of CFLAGS that the user specified.
 871 SPECIFIED_CFLAGS="$CFLAGS"
 872
 873 case ${with_gcc} in
 874   "yes" ) CC="gcc" GCC=yes ;;
 875   "no"  ) : ${CC=cc} ;;
 876   * ) AC_PROG_CC
 877 esac
 878
 879 # On Suns, sometimes $CPP names a directory.
 880 if test -n "$CPP" && test -d "$CPP"; then
 881   CPP=
 882 fi
 883
 884 #### Some systems specify a CPP to use unless we are using GCC.
 885 #### Now that we know whether we are using GCC, we can decide whether
 886 #### to use that one.
 887 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 888 then
 889   CPP="$NON_GNU_CPP"
 890 fi
 891
 892 #### Some systems specify a CC to use unless we are using GCC.
 893 #### Now that we know whether we are using GCC, we can decide whether
 894 #### to use that one.
 895 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 896   test x$cc_specified != xyes
 897 then
 898   CC="$NON_GNU_CC"
 899 fi
 900
 901 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 902 then
 903   CC="$CC $GCC_TEST_OPTIONS"
 904 fi
 905
 906 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 907 then
 908   CC="$CC $NON_GCC_TEST_OPTIONS"
 909 fi
 910
 911 #### Some other nice autoconf tests.  If you add a test here which
 912 #### should make an entry in src/config.h, don't forget to add an
 913 #### #undef clause to src/config.h.in for autoconf to modify.
 914
 915 dnl checks for programs
 916 AC_PROG_LN_S
 917 AC_PROG_CPP
 918 AC_PROG_INSTALL
 919 AC_PROG_YACC
 920
 921 dnl checks for Unix variants
 922 AC_AIX
 923
 924 dnl checks for header files
 925 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
 926 AC_HEADER_STDC
 927 AC_HEADER_TIME
 928 AC_DECL_SYS_SIGLIST
 929
 930 dnl Some systems have utime.h but don't declare the struct anyplace.
 931 AC_MSG_CHECKING(for struct utimbuf)
 932 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 933 #include <sys/time.h>
 934 #include <time.h>
 935 #else
 936 #ifdef HAVE_SYS_TIME_H
 937 #include <sys/time.h>
 938 #else
 939 #include <time.h>
 940 #endif
 941 #endif
 942 #ifdef HAVE_UTIME_H
 943 #include <utime.h>
 944 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 945   [AC_MSG_RESULT(yes)
 946    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 947   AC_MSG_RESULT(no))
 948
 949 dnl checks for typedefs
 950 AC_TYPE_SIGNAL
 951
 952 AC_MSG_CHECKING(for struct timeval)
 953 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 954 #include <sys/time.h>
 955 #include <time.h>
 956 #else
 957 #ifdef HAVE_SYS_TIME_H
 958 #include <sys/time.h>
 959 #else
 960 #include <time.h>
 961 #endif
 962 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 963   [AC_MSG_RESULT(yes)
 964    HAVE_TIMEVAL=yes
 965    AC_DEFINE(HAVE_TIMEVAL)],
 966   AC_MSG_RESULT(no))
 967
 968 dnl checks for structure members
 969 AC_STRUCT_TM
 970 AC_STRUCT_TIMEZONE
 971
 972 dnl checks for compiler characteristics
 973 AC_C_CONST
 974
 975 dnl check for Make feature
 976 AC_PROG_MAKE_SET
 977
 978 dnl checks for operating system services
 979 AC_SYS_LONG_FILE_NAMES
 980
 981 #### Choose a window system.
 982
 983 AC_PATH_X
 984 if test "$no_x" = yes; then
 985   window_system=none
 986 else
 987   window_system=x11
 988 fi
 989
 990 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
 991   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
 992   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
 993 fi
 994 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
 995   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
 996 fi
 997
 998 if test x"${x_includes}" = x; then
 999   bitmapdir=/usr/include/X11/bitmaps
1000 else
1001   # accumulate include directories that have X11 bitmap sudirectories
1002   bmd_acc="dummyval"
1003   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1004     if test -d "${bmd}/X11/bitmaps"; then
1005       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1006     elif test -d "${bmd}/bitmaps"; then
1007       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1008     fi
1009   done
1010   if test ${bmd_acc} != "dummyval"; then
1011     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1012   fi
1013 fi
1014
1015 case "${window_system}" in
1016   x11 )
1017     HAVE_X_WINDOWS=yes
1018     HAVE_X11=yes
1019     case "${with_x_toolkit}" in
1020       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1021       motif ) USE_X_TOOLKIT=MOTIF ;;
1022 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1023       * ) USE_X_TOOLKIT=none ;;
1024     esac
1025   ;;
1026   none )
1027     HAVE_X_WINDOWS=no
1028     HAVE_X11=no
1029     USE_X_TOOLKIT=none
1030   ;;
1031 esac
1032 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1033
1034 ### If we're using X11, we should use the X menu package.
1035 HAVE_MENUS=no
1036 case ${HAVE_X11} in
1037   yes ) HAVE_MENUS=yes ;;
1038 esac
1039
1040 if test "${opsys}" = "hpux9"; then
1041   case "${x_libraries}" in
1042     *X11R4* )
1043       opsysfile="s/hpux9-x11r4.h"
1044       ;;
1045   esac
1046 fi
1047
1048 if test "${opsys}" = "hpux9shr"; then
1049   case "${x_libraries}" in
1050     *X11R4* )
1051       opsysfile="s/hpux9shxr4.h"
1052       ;;
1053   esac
1054 fi
1055
1056 #### Extract some information from the operating system and machine files.
1057
1058 AC_CHECKING([the machine- and system-dependent files to find out
1059  - which libraries the lib-src programs will want, and
1060  - whether the GNU malloc routines are usable])
1061
1062 ### First figure out CFLAGS (which we use for running the compiler here)
1063 ### and REAL_CFLAGS (which we use for real compilation).
1064 ### The two are the same except on a few systems, where they are made
1065 ### different to work around various lossages.  For example,
1066 ### GCC 2.5 on Linux needs them to be different because it treats -g
1067 ### as implying static linking.
1068
1069 ### If the CFLAGS env var is specified, we use that value
1070 ### instead of the default.
1071
1072 ### It's not important that this name contain the PID; you can't run
1073 ### two configures in the same directory and have anything work
1074 ### anyway.
1075 tempcname="conftest.c"
1076
1077 echo '
1078 #include "'${srcdir}'/src/'${opsysfile}'"
1079 #include "'${srcdir}'/src/'${machfile}'"
1080 #ifndef LIBS_MACHINE
1081 #define LIBS_MACHINE
1082 #endif
1083 #ifndef LIBS_SYSTEM
1084 #define LIBS_SYSTEM
1085 #endif
1086 #ifndef C_SWITCH_SYSTEM
1087 #define C_SWITCH_SYSTEM
1088 #endif
1089 #ifndef C_SWITCH_MACHINE
1090 #define C_SWITCH_MACHINE
1091 #endif
1092 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1093 configure___ c_switch_system=C_SWITCH_SYSTEM
1094 configure___ c_switch_machine=C_SWITCH_MACHINE
1095
1096 #ifndef LIB_X11_LIB
1097 #define LIB_X11_LIB -lX11
1098 #endif
1099
1100 #ifndef LIBX11_MACHINE
1101 #define LIBX11_MACHINE
1102 #endif
1103
1104 #ifndef LIBX11_SYSTEM
1105 #define LIBX11_SYSTEM
1106 #endif
1107 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1108
1109 #ifdef UNEXEC
1110 configure___ unexec=UNEXEC
1111 #else
1112 configure___ unexec=unexec.o
1113 #endif
1114
1115 #ifdef SYSTEM_MALLOC
1116 configure___ system_malloc=yes
1117 #else
1118 configure___ system_malloc=no
1119 #endif
1120
1121 #ifndef C_DEBUG_SWITCH
1122 #define C_DEBUG_SWITCH -g
1123 #endif
1124
1125 #ifndef C_OPTIMIZE_SWITCH
1126 #define C_OPTIMIZE_SWITCH -O
1127 #endif
1128
1129 #ifdef THIS_IS_CONFIGURE
1130
1131 /* Get the CFLAGS for tests in configure.  */
1132 #ifdef __GNUC__
1133 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1134 #else
1135 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1136 #endif
1137
1138 #else /* not THIS_IS_CONFIGURE */
1139
1140 /* Get the CFLAGS for real compilation.  */
1141 #ifdef __GNUC__
1142 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1143 #else
1144 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1145 #endif
1146
1147 #endif /* not THIS_IS_CONFIGURE */
1148 ' > ${tempcname}
1149
1150 # The value of CPP is a quoted variable reference, so we need to do this
1151 # to get its actual value...
1152 CPP=`eval "echo $CPP"`
1153 changequote(, )dnl
1154 eval `${CPP} -Isrc ${tempcname} \
1155        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1156 if test "x$SPECIFIED_CFLAGS" = x; then
1157   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1158          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1159 else
1160   REAL_CFLAGS="$CFLAGS"
1161 fi
1162 changequote([, ])dnl
1163 rm ${tempcname}
1164
1165 ### Compute the unexec source name from the object name.
1166 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1167
1168 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1169 # Assume not, until told otherwise.
1170 GNU_MALLOC=yes
1171 if test "${system_malloc}" = "yes"; then
1172   GNU_MALLOC=no
1173   GNU_MALLOC_reason="
1174   (The GNU allocators don't work with this system configuration.)"
1175 fi
1176
1177 if test x"${REL_ALLOC}" = x; then
1178   REL_ALLOC=${GNU_MALLOC}
1179 fi
1180
1181 LISP_FLOAT_TYPE=yes
1182
1183
1184 #### Add the libraries to LIBS and check for some functions.
1185
1186 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1187 LIBS="$libsrc_libs $LIBS"
1188
1189 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1190 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1191 AC_CHECK_LIB(dnet, dnet_ntoa)
1192 dnl This causes -lresolv to get used in subsequent tests,
1193 dnl which causes failures on some systems such as HPUX 9.
1194 dnl AC_CHECK_LIB(resolv, gethostbyname)
1195
1196 dnl FIXME replace main with a function we actually want from this library.
1197 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1198
1199 AC_CHECK_LIB(pthreads, cma_open)
1200
1201 AC_MSG_CHECKING(for XFree86)
1202 if test -d /usr/X386/include; then
1203   HAVE_XFREE386=yes
1204   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1205 else
1206   HAVE_XFREE386=no
1207 fi
1208 AC_MSG_RESULT($HAVE_XFREE386)
1209
1210 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1211 # for the tests that follow.  We set it back to REAL_CFLAGS later on.
1212
1213 if test "${HAVE_X11}" = "yes"; then
1214   DEFS="$C_SWITCH_X_SITE $DEFS"
1215   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1216   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1217
1218   if test "${opsys}" = "linux"; then
1219     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1220     AC_TRY_LINK([],
1221      [XOpenDisplay ("foo");],
1222      [xlinux_first_failure=no],
1223      [xlinux_first_failure=yes])
1224     if test "${xlinux_first_failure}" = "yes"; then
1225       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1226       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1227       OLD_CPPFLAGS="$CPPFLAGS"
1228       OLD_LIBS="$LIBS"
1229       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1230       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1231       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1232       LIBS="$LIBS -b i486-linuxaout"
1233       AC_TRY_LINK([],
1234        [XOpenDisplay ("foo");],
1235        [xlinux_second_failure=no],
1236        [xlinux_second_failure=yes])
1237       if test "${xlinux_second_failure}" = "yes"; then
1238         # If we get the same failure with -b, there is no use adding -b.
1239         # So take it out.  This plays safe.
1240         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1241         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1242         CPPFLAGS="$OLD_CPPFLAGS"
1243         LIBS="$OLD_LIBS"
1244         AC_MSG_RESULT(no)
1245       else
1246         AC_MSG_RESULT(yes)
1247       fi
1248     else
1249       AC_MSG_RESULT(no)
1250     fi
1251   fi
1252
1253   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1254 XScreenNumberOfScreen XSetWMProtocols)
1255   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1256 fi
1257
1258 if test "${window_system}" = "x11"; then
1259   AC_MSG_CHECKING(X11 version)
1260   AC_TRY_LINK([#include <X11/Xlib.h>],
1261 [#if XlibSpecificationRelease < 6
1262 fail;
1263 #endif
1264 ], [AC_MSG_RESULT(6)
1265     AC_DEFINE(HAVE_X11R6)],
1266    [AC_MSG_RESULT(not 6)])
1267 fi
1268
1269 if test "${USE_X_TOOLKIT}" != "none"; then
1270   AC_MSG_CHECKING(X11 toolkit version)
1271   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1272 [#if XtSpecificationRelease < 6
1273 fail;
1274 #endif
1275 ], [AC_MSG_RESULT(6)
1276     AC_DEFINE(HAVE_X11XTR6)],
1277    [AC_MSG_RESULT(not 6)])
1278 fi
1279
1280 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1281 AC_MSG_CHECKING(whether netdb declares h_errno)
1282 AC_TRY_LINK([#include <netdb.h>],
1283   [return h_errno;],
1284   [AC_MSG_RESULT(yes)
1285    AC_DEFINE(HAVE_H_ERRNO)],
1286   [AC_MSG_RESULT(no)])
1287
1288 AC_FUNC_ALLOCA
1289
1290 # fmod, logb, and frexp are found in -lm on most systems.
1291 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1292 AC_CHECK_LIB(m, sqrt(0.0) + t)
1293 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1294 random lrand48 bcopy bcmp logb frexp fmod ftime res_init setsid \
1295 strerror fpathconf select mktime eaccess getpagesize tzset)
1296
1297 AC_MSG_CHECKING(whether localtime caches TZ)
1298 AC_CACHE_VAL(emacs_cv_localtime_cache,
1299 [if test $ac_cv_func_tzset = yes; then
1300 AC_TRY_RUN([#include <time.h>
1301 #if STDC_HEADERS
1302 # include <stdlib.h>
1303 #endif
1304 main()
1305 {
1306   time_t now = time ((time_t *) 0);
1307   int hour;
1308   if (putenv ("TZ=GMT0") != 0)
1309     exit (1);
1310   hour = localtime (&now)->tm_hour;
1311   if (putenv ("TZ=PST8") != 0)
1312     exit (1);
1313   exit (localtime (&now)->tm_hour == hour);
1314 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1315 [# If we have tzset, assume the worst when cross-compiling.
1316 emacs_cv_localtime_cache=yes])
1317 else
1318         # If we lack tzset, report that localtime does not cache TZ,
1319         # since we can't invalidate the cache if we don't have tzset.
1320         emacs_cv_localtime_cache=no
1321 fi])dnl
1322 AC_MSG_RESULT($emacs_cv_localtime_cache)
1323 if test $emacs_cv_localtime_cache = yes; then
1324   AC_DEFINE(LOCALTIME_CACHE)
1325 fi
1326
1327 if test "x$HAVE_TIMEVAL" = xyes; then
1328 AC_MSG_CHECKING(whether gettimeofday can't accept two arguments)
1329 AC_TRY_LINK([
1330 #ifdef TIME_WITH_SYS_TIME
1331 #include <sys/time.h>
1332 #include <time.h>
1333 #else
1334 #ifdef HAVE_SYS_TIME_H
1335 #include <sys/time.h>
1336 #else
1337 #include <time.h>
1338 #endif
1339 #endif
1340   ],
1341   [
1342   struct timeval time;
1343   struct timezone dummy;
1344   gettimeofday (&time, &dummy);
1345 ],
1346   [AC_MSG_RESULT(no)],
1347   [AC_MSG_RESULT(yes)
1348    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
1349 fi
1350
1351 ok_so_far=yes
1352 AC_CHECK_FUNC(socket, , ok_so_far=no)
1353 if test $ok_so_far = yes; then
1354   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1355 fi
1356 if test $ok_so_far = yes; then
1357   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1358 fi
1359 if test $ok_so_far = yes; then
1360   AC_DEFINE(HAVE_INET_SOCKETS)
1361 fi
1362
1363 if test -f /usr/lpp/X11/bin/smt.exp; then
1364   AC_DEFINE(HAVE_AIX_SMT_EXP)
1365 fi
1366
1367 # Set up the CFLAGS for real compilation, so we can substitute it.
1368 CFLAGS="$REAL_CFLAGS"
1369
1370 changequote(, )dnl
1371 #### Find out which version of Emacs this is.
1372 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1373          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1374 changequote([, ])dnl
1375 if test x"${version}" = x; then
1376   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1377 fi
1378
1379 ### Specify what sort of things we'll be editing into Makefile and config.h.
1380 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1381 AC_SUBST(version)
1382 AC_SUBST(configuration)
1383 AC_SUBST(canonical)
1384 AC_SUBST(srcdir)
1385 AC_SUBST(prefix)
1386 AC_SUBST(exec_prefix)
1387 AC_SUBST(bindir)
1388 AC_SUBST(datadir)
1389 AC_SUBST(sharedstatedir)
1390 AC_SUBST(libexecdir)
1391 AC_SUBST(mandir)
1392 AC_SUBST(infodir)
1393 AC_SUBST(lispdir)
1394 AC_SUBST(locallisppath)
1395 AC_SUBST(lisppath)
1396 AC_SUBST(etcdir)
1397 AC_SUBST(lockdir)
1398 AC_SUBST(archlibdir)
1399 AC_SUBST(docdir)
1400 AC_SUBST(bitmapdir)
1401 AC_SUBST(c_switch_system)
1402 AC_SUBST(c_switch_machine)
1403 AC_SUBST(LD_SWITCH_X_SITE)
1404 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1405 AC_SUBST(C_SWITCH_X_SITE)
1406 AC_SUBST(CFLAGS)
1407 AC_SUBST(X_TOOLKIT_TYPE)
1408 AC_SUBST(machfile)
1409 AC_SUBST(opsysfile)
1410 AC_SUBST(RANLIB)
1411
1412 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1413 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1414 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1415 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1416 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1417 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1418 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1419 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1420
1421 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1422   AC_DEFINE(HAVE_X_WINDOWS)
1423 fi
1424 if test "${USE_X_TOOLKIT}" != "none" ; then
1425   AC_DEFINE(USE_X_TOOLKIT)
1426 fi
1427 if test "${HAVE_X11}" = "yes" ; then
1428   AC_DEFINE(HAVE_X11)
1429 fi
1430 if test "${HAVE_XFREE386}" = "yes" ; then
1431   AC_DEFINE(HAVE_XFREE386)
1432 fi
1433 if test "${HAVE_MENUS}" = "yes" ; then
1434   AC_DEFINE(HAVE_MENUS)
1435 fi
1436 if test "${GNU_MALLOC}" = "yes" ; then
1437   AC_DEFINE(GNU_MALLOC)
1438 fi
1439 if test "${REL_ALLOC}" = "yes" ; then
1440   AC_DEFINE(REL_ALLOC)
1441 fi
1442 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1443   AC_DEFINE(LISP_FLOAT_TYPE)
1444 fi
1445
1446 #### Report on what we decided to do.
1447 echo "
1448 Configured for \`${canonical}'.
1449
1450   Where should the build process find the source code?    ${srcdir}
1451   What operating system and machine description files should Emacs use?
1452         \`${opsysfile}' and \`${machfile}'
1453   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1454   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1455   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1456   What window system should Emacs use?                    ${window_system}
1457   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
1458
1459 if test -n "${x_includes}"; then
1460 echo "  Where do we find X Windows header files?                ${x_includes}"
1461 else
1462 echo "  Where do we find X Windows header files?                Standard dirs"
1463 fi
1464 if test -n "${x_libraries}"; then
1465 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
1466 else
1467 echo "  Where do we find X Windows libraries?                   Standard dirs"
1468 fi
1469
1470 echo
1471
1472 # Remove any trailing slashes in these variables.
1473 changequote(, )dnl
1474 test "${prefix}" != NONE &&
1475   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1476 test "${exec_prefix}" != NONE &&
1477   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1478 changequote([, ])dnl
1479
1480 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1481         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in, [
1482
1483 ### Make the necessary directories, if they don't exist.
1484 for dir in cpp etc ; do
1485   test -d ${dir} || mkdir ${dir}
1486 done
1487
1488 # Build src/Makefile from ${srcdir}/src/Makefile.c
1489 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1490 # This must be done after src/config.h is built, since we rely on that file.
1491
1492 changequote(, )dnl The horror, the horror.
1493 # Now get this: Some word that is part of the ${srcdir} directory name
1494 # or the ${configuration} value might, just might, happen to be an
1495 # identifier like `sun4' or `i386' or something, and be predefined by
1496 # the C preprocessor to some helpful value like 1, or maybe the empty
1497 # string.  Needless to say consequent macro substitutions are less
1498 # than conducive to the makefile finding the correct directory.
1499 undefs="`echo $top_srcdir $configuration $canonical |
1500 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1501     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1502 `"
1503 changequote([, ])dnl
1504
1505 echo creating lib-src/Makefile
1506 ( cd lib-src
1507   rm -f junk.c junk1.c junk2.c
1508   sed -e '/start of cpp stuff/q' \
1509       < Makefile.c > junk1.c
1510   sed -e '1,/start of cpp stuff/d'\
1511       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1512       < Makefile.c > junk.c
1513   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1514       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1515   cat junk1.c junk2.c > Makefile.new
1516   rm -f junk.c junk1.c junk2.c
1517   chmod 444 Makefile.new
1518   mv -f Makefile.new Makefile
1519 )
1520
1521 echo creating src/Makefile
1522 ( cd src
1523   rm -f junk.c junk1.c junk2.c
1524   sed -e '/start of cpp stuff/q' \
1525       < Makefile.c > junk1.c
1526   sed -e '1,/start of cpp stuff/d'\
1527       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1528       < Makefile.c > junk.c
1529   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1530       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1531   cat junk1.c junk2.c > Makefile.new
1532   rm -f junk.c junk1.c junk2.c
1533   chmod 444 Makefile.new
1534   mv -f Makefile.new Makefile
1535 )
1536
1537 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1538   echo creating src/.gdbinit
1539   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1540 fi
1541
1542 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])