lisp/nxml/rng-valid.el

   1 ;;; rng-valid.el --- real-time validation of XML using RELAX NG
   2
   3 ;; Copyright (C) 2003, 2007-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: James Clark
   6 ;; Keywords: XML, RelaxNG
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; For usage information, see the documentation for rng-validate-mode.
  26 ;;
  27 ;; This file provides a minor mode that continually validates a buffer
  28 ;; against a RELAX NG schema. The validation state is used to support
  29 ;; schema-sensitive editing as well as validation. Validation is
  30 ;; performed while Emacs is idle.  XML parsing is done using
  31 ;; xmltok.el. This file is responsible for checking that end-tags
  32 ;; match their start-tags.  Namespace processing is handled by
  33 ;; nxml-ns.el. The RELAX NG Compact Syntax schema is parsed into
  34 ;; internal form by rng-cmpct.el.  This internal form is described by
  35 ;; rng-pttrn.el.  Validation of the document by matching against this
  36 ;; internal form is done by rng-match.el. Handling of W3C XML Schema
  37 ;; datatypes is delegated by rng-match.el to rng-xsd.el.  The minor
  38 ;; mode is intended to be used in conjunction with the nxml major
  39 ;; mode, but does not have to be.
  40 ;;
  41 ;; The major responsibility of this file is to allow validation to
  42 ;; happen incrementally.  If a buffer has been validated and is then
  43 ;; changed, we can often revalidate it without having to completely
  44 ;; parse and validate it from start to end.  As we parse and validate
  45 ;; the buffer, we periodically cache the state.  The state has three
  46 ;; components: the stack of open elements, the namespace processing
  47 ;; state and the RELAX NG validation state. The state is cached as the
  48 ;; value of the rng-state text property on the closing greater-than of
  49 ;; tags (but at intervals, not on every tag).  We keep track of the
  50 ;; position up to which cached state is known to be correct by adding
  51 ;; a function to the buffer's after-change-functions. This is stored
  52 ;; in the rng-validate-up-to-date-end variable.  The first way in
  53 ;; which we make validation incremental is obvious: we start
  54 ;; validation from the first cached state before
  55 ;; rng-validate-up-to-date-end.
  56 ;;
  57 ;; To make this work efficiently, we have to be able to copy the
  58 ;; current parsing and validation state efficiently.  We do this by
  59 ;; minimizing destructive changes to the objects storing the state.
  60 ;; When state is changed, we use the old state to create new objects
  61 ;; representing the new state rather than destructively modifying the
  62 ;; objects representing the old state. Copying the state is just a
  63 ;; matter of making a list of three objects, one for each component of
  64 ;; the state; the three objects themselves can be shared and do not
  65 ;; need to be copied.
  66 ;;
  67 ;; There's one other idea that is used to make validation incremental.
  68 ;; Suppose we have a buffer that's 4000 bytes long and suppose we
  69 ;; validated it, caching state at positions 1000, 2000 and 3000.  Now
  70 ;; suppose we make a change at position 1500 inserting 100 characters.
  71 ;; rng-validate-up-to-date-end will be changed to 1500.  When Emacs
  72 ;; becomes idle and we revalidate, validation will restart using the
  73 ;; cached state at position 1000.  However, we take advantage of the
  74 ;; cached state beyond rng-validate-up-to-date-end as follows.  When
  75 ;; our validation reaches position 2100 (the current position of the
  76 ;; character that was at 2000), we compare our current state with the
  77 ;; cached state.  If they are the same, then we can stop parsing
  78 ;; immediately and set rng-validate-up-to-date-end to the end of the
  79 ;; buffer: we already know that the state cached at position 3100 is
  80 ;; correct.  If they are not the same, then we have to continue
  81 ;; parsing.  After the change, but before revalidation, we call the
  82 ;; region from 1600 to the end of the buffer "conditionally
  83 ;; up-to-date".
  84 ;;
  85 ;; As well as the cached parsing and validation state, we also keep
  86 ;; track of the errors in the file.  Errors are stored as overlays
  87 ;; with a category of rng-error.  The number of such overlays in the
  88 ;; buffer must always be equal to rng-error-count.
  89
  90 ;;; Code:
  91
  92 (require 'xmltok)
  93 (require 'nxml-enc)
  94 (require 'nxml-util)
  95 (require 'nxml-ns)
  96 (require 'rng-match)
  97 (require 'rng-util)
  98 (require 'rng-loc)
  99
 100 ;;; Customizable variables
 101
 102 (defgroup relax-ng nil
 103   "Validation of XML using RELAX NG."
 104   :group 'wp
 105   :group 'nxml
 106   :group 'languages)
 107
 108 (defface rng-error '((t (:inherit font-lock-warning-face)))
 109   "Face for highlighting XML errors."
 110   :group 'relax-ng)
 111
 112 (defcustom rng-state-cache-distance 2000
 113   "Distance in characters between each parsing and validation state cache."
 114   :type 'integer
 115   :group 'relax-ng)
 116
 117 (defcustom rng-validate-chunk-size 8000
 118   "Number of characters in a RELAX NG validation chunk.
 119 A validation chunk will be the smallest chunk that is at least this
 120 size and ends with a tag.  After validating a chunk, validation will
 121 continue only if Emacs is still idle."
 122   :type 'integer
 123   :group 'relax-ng)
 124
 125 (defcustom rng-validate-delay 1.5
 126   "Time in seconds that Emacs must be idle before starting a full validation.
 127 A full validation continues until either validation is up to date
 128 or Emacs is no longer idle."
 129   :type 'number
 130   :group 'relax-ng)
 131
 132 (defcustom rng-validate-quick-delay 0.3
 133   "Time in seconds that Emacs must be idle before starting a quick validation.
 134 A quick validation validates at most one chunk."
 135   :type 'number
 136   :group 'relax-ng)
 137
 138 ;; Global variables
 139
 140 (defvar rng-validate-timer nil)
 141 (make-variable-buffer-local 'rng-validate-timer)
 142 ;; ensure that we can cancel the timer even after a kill-all-local-variables
 143 (put 'rng-validate-timer 'permanent-local t)
 144
 145 (defvar rng-validate-quick-timer nil)
 146 (make-variable-buffer-local 'rng-validate-quick-timer)
 147 ;; ensure that we can cancel the timer even after a kill-all-local-variables
 148 (put 'rng-validate-quick-timer 'permanent-local t)
 149
 150 (defvar rng-error-count nil
 151   "Number of errors in the current buffer.
 152 Always equal to number of overlays with category `rng-error'.")
 153 (make-variable-buffer-local 'rng-error-count)
 154
 155 (defvar rng-message-overlay nil
 156   "Overlay in this buffer whose `help-echo' property was last printed.
 157 It is nil if none.")
 158 (make-variable-buffer-local 'rng-message-overlay)
 159
 160 (defvar rng-message-overlay-inhibit-point nil
 161   "Position at which message from overlay should be inhibited.
 162 If point is equal to this and the error overlay around
 163 point is `rng-message-overlay', then the `help-echo' property
 164 of the error overlay should not be printed with `message'.")
 165 (make-variable-buffer-local 'rng-message-overlay-inhibit-point)
 166
 167 (defvar rng-message-overlay-current nil
 168   "Non-nil if `rng-message-overlay' is still the current message.")
 169 (make-variable-buffer-local 'rng-message-overlay-current)
 170
 171 (defvar rng-open-elements nil
 172   "Stack of names of open elements represented as a list.
 173 Each member of the list is either t or a (PREFIX . LOCAL-NAME) pair.
 174 \(PREFIX . LOCAL-NAME) is pushed for a start-tag; t is pushed
 175 for a mismatched end-tag.")
 176
 177 (defvar rng-pending-contents nil
 178   "Text content of current element that has yet to be processed.
 179 Value is a list of segments (VALUE START END) positions in reverse
 180 order.  VALUE is a string or nil.  If VALUE is nil, then the value is
 181 the string between START and END.  A segment can also be nil
 182 indicating an unresolvable entity or character reference.")
 183
 184 (defvar rng-collecting-text nil)
 185
 186 (defvar rng-validate-up-to-date-end nil
 187   "Last position where validation is known to be up to date.")
 188 (make-variable-buffer-local 'rng-validate-up-to-date-end)
 189
 190 (defvar rng-conditional-up-to-date-start nil
 191   "Marker for the start of the conditionally up-to-date region.
 192 It is nil if there is no conditionally up-to-date region.  The
 193 conditionally up-to-date region must be such that for any cached
 194 state S with position P in the conditionally up-to-date region,
 195 if at some point it is determined that S becomes correct for P,
 196 then all states with position >= P in the conditionally up to
 197 date region must also then be correct and all errors between P
 198 and the end of the region must then be correctly marked.")
 199 (make-variable-buffer-local 'rng-conditional-up-to-date-start)
 200
 201 (defvar rng-conditional-up-to-date-end nil
 202   "Marker for the end of the conditionally up-to-date region.
 203 It is nil if there is no conditionally up-to-date region.
 204 See the variable `rng-conditional-up-to-date-start'.")
 205 (make-variable-buffer-local 'rng-conditional-up-to-date-end)
 206
 207 (defvar rng-parsing-for-state nil
 208   "Non-nil means we are currently parsing just to compute the state.
 209 Should be dynamically bound.")
 210
 211 (defvar rng-validate-mode nil)
 212 (make-variable-buffer-local 'rng-validate-mode)
 213
 214 (defvar rng-dtd nil)
 215 (make-variable-buffer-local 'rng-dtd)
 216
 217 ;;;###autoload
 218 (defun rng-validate-mode (&optional arg no-change-schema)
 219   "Minor mode performing continual validation against a RELAX NG schema.
 220
 221 Checks whether the buffer is a well-formed XML 1.0 document,
 222 conforming to the XML Namespaces Recommendation and valid against a
 223 RELAX NG schema.  The mode-line indicates whether it is or not.  Any
 224 parts of the buffer that cause it not to be are considered errors and
 225 are highlighted with face `rng-error'.  A description of each error is
 226 available as a tooltip.  \\[rng-next-error] goes to the next error
 227 after point.  Clicking mouse-1 on the word `Invalid' in the mode-line
 228 goes to the first error in the buffer.  If the buffer changes, then it
 229 will be automatically rechecked when Emacs becomes idle; the
 230 rechecking will be paused whenever there is input pending.
 231
 232 By default, uses a vacuous schema that allows any well-formed XML
 233 document.  A schema can be specified explicitly using
 234 \\[rng-set-schema-file-and-validate], or implicitly based on the buffer's
 235 file name or on the root element name.  In each case the schema must
 236 be a RELAX NG schema using the compact schema \(such schemas
 237 conventionally have a suffix of `.rnc').  The variable
 238 `rng-schema-locating-files' specifies files containing rules
 239 to use for finding the schema."
 240   (interactive "P")
 241   (setq rng-validate-mode
 242         (if (null arg)
 243             (not rng-validate-mode)
 244           (> (prefix-numeric-value arg) 0)))
 245   (save-restriction
 246     (widen)
 247     (nxml-with-unmodifying-text-property-changes
 248       (rng-clear-cached-state (point-min) (point-max)))
 249     ;; 1+ to clear empty overlays at (point-max)
 250     (rng-clear-overlays (point-min) (1+ (point-max)))
 251     (setq rng-validate-up-to-date-end (point-min)))
 252   (rng-clear-conditional-region)
 253   (setq rng-error-count 0)
 254   ;; do this here to avoid infinite loop if we set the schema
 255   (remove-hook 'rng-schema-change-hook 'rng-validate-clear t)
 256   (cond (rng-validate-mode
 257          (unwind-protect
 258              (save-excursion
 259                ;; An error can change the current buffer
 260                (when (or (not rng-current-schema)
 261                          (and (eq rng-current-schema rng-any-element)
 262                               (not no-change-schema)))
 263                  (rng-auto-set-schema t)))
 264            (unless rng-current-schema (rng-set-schema-file-1 nil))
 265            (add-hook 'rng-schema-change-hook 'rng-validate-clear nil t)
 266            (add-hook 'after-change-functions 'rng-after-change-function nil t)
 267            (add-hook 'kill-buffer-hook 'rng-kill-timers nil t)
 268            (add-hook 'echo-area-clear-hook 'rng-echo-area-clear-function nil t)
 269            (add-hook 'post-command-hook 'rng-maybe-echo-error-at-point nil t)
 270            (rng-match-init-buffer)
 271            (rng-activate-timers)
 272            ;; Start validating right away if the buffer is visible.
 273            ;; If it's not visible, don't do this, because the user
 274            ;; won't get any progress indication. When the user finds
 275            ;; a new file, then the buffer won't be visible
 276            ;; when this is invoked.
 277            (when (get-buffer-window (current-buffer) 'visible)
 278              (rng-validate-while-idle (current-buffer)))))
 279         (t
 280          (rng-cancel-timers)
 281          (force-mode-line-update)
 282          (remove-hook 'kill-buffer-hook 'rng-cancel-timers t)
 283          (remove-hook 'post-command-hook 'rng-maybe-echo-error-at-point t)
 284          (remove-hook 'echo-area-clear-hook 'rng-echo-area-clear-function t)
 285          (remove-hook 'after-change-functions 'rng-after-change-function t))))
 286
 287 (defun rng-set-schema-file-and-validate (filename)
 288   "Sets the schema and turns on `rng-validate-mode' if not already on.
 289 The schema is set like `rng-set-schema'."
 290   (interactive "fSchema file: ")
 291   (rng-set-schema-file filename)
 292   (or rng-validate-mode (rng-validate-mode)))
 293
 294 (defun rng-set-document-type-and-validate (type-id)
 295   (interactive (list (rng-read-type-id)))
 296   (and (rng-set-document-type type-id)
 297        (or rng-validate-mode (rng-validate-mode))))
 298
 299 (defun rng-auto-set-schema-and-validate ()
 300   "Set the schema for this buffer automatically and turn on `rng-validate-mode'.
 301 The schema is set like `rng-auto-set-schema'."
 302   (interactive)
 303   (rng-auto-set-schema)
 304   (or rng-validate-mode (rng-validate-mode)))
 305
 306 (defun rng-after-change-function (start end pre-change-len)
 307   (setq rng-message-overlay-inhibit-point nil)
 308   (nxml-with-unmodifying-text-property-changes
 309     (rng-clear-cached-state start end))
 310   ;; rng-validate-up-to-date-end holds the position before the change
 311   ;; Adjust it to reflect the change.
 312   (if (< start rng-validate-up-to-date-end)
 313       (setq rng-validate-up-to-date-end
 314             (if (<= (+ start pre-change-len) rng-validate-up-to-date-end)
 315                 (+ rng-validate-up-to-date-end
 316                    (- end start pre-change-len))
 317               start)))
 318   ;; Adjust the conditional zone
 319   (cond (rng-conditional-up-to-date-start
 320          (when (< rng-conditional-up-to-date-start end)
 321            (if (< end rng-conditional-up-to-date-end)
 322                (set-marker rng-conditional-up-to-date-start end)
 323              (rng-clear-conditional-region))))
 324         ((< end rng-validate-up-to-date-end)
 325          (setq rng-conditional-up-to-date-end
 326                (copy-marker rng-validate-up-to-date-end nil))
 327          (setq rng-conditional-up-to-date-start
 328                (copy-marker end t))))
 329   ;; Adjust rng-validate-up-to-date-end
 330   (if (< start rng-validate-up-to-date-end)
 331       (setq rng-validate-up-to-date-end start))
 332   ;; Must make rng-validate-up-to-date-end < point-max
 333   ;; (unless the buffer is empty).
 334   ;; otherwise rng-validate-prepare will say there's nothing to do.
 335   (when (>= rng-validate-up-to-date-end (point-max))
 336     (setq rng-validate-up-to-date-end
 337           (if (< (point-min) (point-max))
 338               (1- (point-max))
 339             ;; Only widen if really necessary.
 340             (save-restriction (widen) (max (point-min) (1- (point-max)))))))
 341   ;; Arrange to revalidate
 342   (rng-activate-timers)
 343   ;; Need to do this after activating the timer
 344   (force-mode-line-update))
 345
 346 (defun rng-compute-mode-line-string ()
 347   (cond (rng-validate-timer
 348          (concat " Validated:"
 349                  (number-to-string
 350                   ;; Use floor rather than round because we want
 351                   ;; to show 99% rather than 100% for changes near
 352                   ;; the end.
 353                   (floor (if (eq (buffer-size) 0)
 354                              0.0
 355                            (/ (* (- rng-validate-up-to-date-end (point-min))
 356                                  100.0)
 357                               (- (point-max) (point-min))))))
 358                  "%%"))
 359         ((> rng-error-count 0)
 360          (concat " "
 361                  (propertize "Invalid"
 362                              'help-echo "mouse-1: go to first error"
 363                              'local-map (make-mode-line-mouse-map
 364                                          'mouse-1
 365                                          'rng-mouse-first-error))))
 366         (t " Valid")))
 367
 368 (defun rng-cancel-timers ()
 369   (let ((inhibit-quit t))
 370     (when rng-validate-timer
 371       (cancel-timer rng-validate-timer)
 372       (setq rng-validate-timer nil))
 373     (when rng-validate-quick-timer
 374       (cancel-timer rng-validate-quick-timer)
 375       (setq rng-validate-quick-timer nil))))
 376
 377 (defun rng-kill-timers ()
 378   ;; rng-validate-timer and rng-validate-quick-timer have the
 379   ;; permanent-local property, so that the timers can be
 380   ;; canceled even after changing mode.
 381   ;; This function takes care of canceling the timers and
 382   ;; then killing the local variables.
 383   (when (local-variable-p 'rng-validate-timer)
 384     (when rng-validate-timer
 385       (cancel-timer rng-validate-timer))
 386     (kill-local-variable 'rng-validate-timer))
 387   (when (local-variable-p 'rng-validate-quick-timer)
 388     (when rng-validate-quick-timer
 389       (cancel-timer rng-validate-quick-timer))
 390     (kill-local-variable 'rng-validate-quick-timer)))
 391
 392 (defun rng-activate-timers ()
 393   (unless rng-validate-timer
 394     (let ((inhibit-quit t))
 395       (setq rng-validate-timer
 396             (run-with-idle-timer rng-validate-delay
 397                                  t
 398                                  'rng-validate-while-idle
 399                                  (current-buffer)))
 400       (setq rng-validate-quick-timer
 401             (run-with-idle-timer rng-validate-quick-delay
 402                                  t
 403                                  'rng-validate-quick-while-idle
 404                                  (current-buffer))))))
 405
 406 (defun rng-validate-clear ()
 407   (rng-validate-mode 1 t))
 408
 409 ;; These two variables are dynamically bound and used
 410 ;; to pass information between rng-validate-while-idle
 411 ;; and rng-validate-while-idle-continue-p.
 412
 413 (defvar rng-validate-display-point nil)
 414 (defvar rng-validate-display-modified-p nil)
 415
 416 (defun rng-validate-while-idle-continue-p ()
 417   (and (not (input-pending-p))
 418        ;; Fake rng-validate-up-to-date-end so that the mode line
 419        ;; shows progress.  Also use this to save point.
 420        (let ((rng-validate-up-to-date-end (point)))
 421          (goto-char rng-validate-display-point)
 422          (when (not rng-validate-display-modified-p)
 423            (restore-buffer-modified-p nil))
 424          (force-mode-line-update)
 425          (let ((continue (sit-for 0)))
 426            (goto-char rng-validate-up-to-date-end)
 427            continue))))
 428
 429 ;; Calling rng-do-some-validation once with a continue-p function, as
 430 ;; opposed to calling it repeatedly, helps on initial validation of a
 431 ;; large buffer with lots of errors.  The overlays for errors will all
 432 ;; get added when rng-do-some-validation returns and won't slow the
 433 ;; validation process down.
 434
 435 (defun rng-validate-while-idle (buffer)
 436   (with-current-buffer buffer
 437     (if rng-validate-mode
 438         (if (let ((rng-validate-display-point (point))
 439                   (rng-validate-display-modified-p (buffer-modified-p)))
 440               (rng-do-some-validation 'rng-validate-while-idle-continue-p))
 441             (force-mode-line-update)
 442           (rng-validate-done))
 443       ;; must have done kill-all-local-variables
 444       (rng-kill-timers))))
 445
 446 (defun rng-validate-quick-while-idle (buffer)
 447   (with-current-buffer buffer
 448     (if rng-validate-mode
 449         (if (rng-do-some-validation)
 450             (force-mode-line-update)
 451           (rng-validate-done))
 452       ;; must have done kill-all-local-variables
 453       (rng-kill-timers))))
 454
 455 (defun rng-validate-done ()
 456   (when (or (not (current-message))
 457             (rng-current-message-from-error-overlay-p))
 458     (rng-error-overlay-message (or (rng-error-overlay-after (point))
 459                                    (rng-error-overlay-after (1- (point))))))
 460   (rng-cancel-timers)
 461   (force-mode-line-update))
 462
 463 (defun rng-do-some-validation (&optional continue-p-function)
 464   "Do some validation work.  Return t if more to do, nil otherwise."
 465   (save-excursion
 466     (save-restriction
 467       (widen)
 468       (nxml-with-invisible-motion
 469         (condition-case-unless-debug err
 470             (and (rng-validate-prepare)
 471                  (let ((rng-dt-namespace-context-getter '(nxml-ns-get-context)))
 472                    (nxml-with-unmodifying-text-property-changes
 473                      (rng-do-some-validation-1 continue-p-function))))
 474           ;; errors signaled from a function run by an idle timer
 475           ;; are ignored; if we don't catch them, validation
 476           ;; will get mysteriously stuck at a single place
 477           (rng-compile-error
 478            (message "Incorrect schema. %s" (nth 1 err))
 479            (rng-validate-mode 0)
 480            nil)
 481           (error
 482            (message "Internal error in rng-validate-mode triggered at buffer position %d. %s"
 483                     (point)
 484                     (error-message-string err))
 485            (rng-validate-mode 0)
 486            nil))))))
 487
 488 (defun rng-validate-prepare ()
 489   "Prepare to do some validation, initializing point and the state.
 490 Return t if there is work to do, nil otherwise."
 491   (cond ((= rng-validate-up-to-date-end (point-min))
 492          (rng-set-initial-state)
 493          t)
 494         ((= rng-validate-up-to-date-end (point-max))
 495          nil)
 496         (t (let ((state (get-text-property (1- rng-validate-up-to-date-end)
 497                                            'rng-state)))
 498              (cond (state
 499                     (rng-restore-state state)
 500                     (goto-char rng-validate-up-to-date-end))
 501                    (t
 502                     (let ((pos (previous-single-property-change
 503                                 rng-validate-up-to-date-end
 504                                 'rng-state)))
 505                       (cond (pos
 506                              (rng-restore-state
 507                               (or (get-text-property (1- pos) 'rng-state)
 508                                   (error "Internal error: state null")))
 509                              (goto-char pos))
 510                             (t (rng-set-initial-state))))))))))
 511
 512 (defun rng-dtd-trivial-p (dtd)
 513   "Check whether the current dtd is different from the trivial default."
 514   (or (null dtd) (eq dtd xmltok-predefined-entity-alist)))
 515
 516 (defun rng-do-some-validation-1 (&optional continue-p-function)
 517   (let ((limit (+ rng-validate-up-to-date-end
 518                   rng-validate-chunk-size))
 519         (remove-start rng-validate-up-to-date-end)
 520         (next-cache-point (+ (point) rng-state-cache-distance))
 521         (continue t)
 522         (xmltok-dtd rng-dtd)
 523         have-remaining-chars
 524         xmltok-type
 525         xmltok-start
 526         xmltok-name-colon
 527         xmltok-name-end
 528         xmltok-replacement
 529         xmltok-attributes
 530         xmltok-namespace-attributes
 531         xmltok-dependent-regions
 532         xmltok-errors)
 533     (when (= (point) 1)
 534       (let ((regions (xmltok-forward-prolog)))
 535         (rng-clear-overlays 1 (point))
 536         (while regions
 537           (when (eq (aref (car regions) 0) 'encoding-name)
 538             (rng-process-encoding-name (aref (car regions) 1)
 539                                        (aref (car regions) 2)))
 540           (setq regions (cdr regions))))
 541       (unless (equal rng-dtd xmltok-dtd)
 542         (rng-clear-conditional-region))
 543       (setq rng-dtd xmltok-dtd))
 544     (while continue
 545       (setq have-remaining-chars (rng-forward))
 546       (let ((pos (point)))
 547         (setq continue
 548               (and have-remaining-chars
 549                    (or (< pos limit)
 550                        (and continue-p-function
 551                             (funcall continue-p-function)
 552                             (setq limit (+ limit rng-validate-chunk-size))
 553                             t))))
 554         (cond ((and rng-conditional-up-to-date-start
 555                     ;; > because we are getting the state from (1- pos)
 556                     (> pos rng-conditional-up-to-date-start)
 557                     (< pos rng-conditional-up-to-date-end)
 558                     (rng-state-matches-current (get-text-property (1- pos)
 559                                                                   'rng-state)))
 560                (when (< remove-start (1- pos))
 561                  (rng-clear-cached-state remove-start (1- pos)))
 562                ;; sync up with cached validation state
 563                (setq continue nil)
 564                ;; do this before setting rng-validate-up-to-date-end
 565                ;; in case we get a quit
 566                (rng-mark-xmltok-errors)
 567                (rng-mark-xmltok-dependent-regions)
 568                (setq rng-validate-up-to-date-end
 569                      (marker-position rng-conditional-up-to-date-end))
 570                (rng-clear-conditional-region)
 571                (setq have-remaining-chars
 572                      (< rng-validate-up-to-date-end (point-max))))
 573               ((or (>= pos next-cache-point)
 574                    (not continue))
 575                (setq next-cache-point (+ pos rng-state-cache-distance))
 576                (rng-clear-cached-state remove-start pos)
 577                (when have-remaining-chars
 578                  (rng-cache-state (1- pos)))
 579                (setq remove-start pos)
 580                (unless continue
 581                  ;; if we have just blank chars skip to the end
 582                  (when have-remaining-chars
 583                    (skip-chars-forward " \t\r\n")
 584                    (when (= (point) (point-max))
 585                      (rng-clear-overlays pos (point))
 586                      (rng-clear-cached-state pos (point))
 587                      (setq have-remaining-chars nil)
 588                      (setq pos (point))))
 589                  (when (not have-remaining-chars)
 590                    (rng-process-end-document))
 591                  (rng-mark-xmltok-errors)
 592                  (rng-mark-xmltok-dependent-regions)
 593                  (setq rng-validate-up-to-date-end pos)
 594                  (when rng-conditional-up-to-date-end
 595                    (cond ((<= rng-conditional-up-to-date-end pos)
 596                           (rng-clear-conditional-region))
 597                          ((< rng-conditional-up-to-date-start pos)
 598                           (set-marker rng-conditional-up-to-date-start
 599                                       pos)))))))))
 600     have-remaining-chars))
 601
 602 (defun rng-clear-conditional-region ()
 603   (when rng-conditional-up-to-date-start
 604     (set-marker rng-conditional-up-to-date-start nil)
 605     (setq rng-conditional-up-to-date-start nil))
 606   (when rng-conditional-up-to-date-end
 607     (set-marker rng-conditional-up-to-date-end nil)
 608     (setq rng-conditional-up-to-date-end nil)))
 609
 610 (defun rng-clear-cached-state (start end)
 611   "Clear cached state between START and END."
 612   (remove-text-properties start end '(rng-state nil)))
 613
 614 (defun rng-cache-state (pos)
 615   "Save the current state in a text property on the character at pos."
 616   (put-text-property pos
 617                      (1+ pos)
 618                      'rng-state
 619                      (rng-get-state)))
 620
 621 (defun rng-state-matches-current (state)
 622   (and state
 623        (rng-match-state-equal (car state))
 624        (nxml-ns-state-equal (nth 1 state))
 625        (equal (nth 2 state) rng-open-elements)))
 626
 627 (defun rng-get-state ()
 628   (list (rng-match-state)
 629         (nxml-ns-state)
 630         rng-open-elements))
 631
 632 (defun rng-restore-state (state)
 633   (rng-set-match-state (car state))
 634   (setq state (cdr state))
 635   (nxml-ns-set-state (car state))
 636   (setq rng-open-elements (cadr state))
 637   (setq rng-pending-contents nil)
 638   (setq rng-collecting-text (rng-match-text-typed-p)))
 639
 640 (defun rng-set-initial-state ()
 641   (nxml-ns-init)
 642   (rng-match-start-document)
 643   (setq rng-open-elements nil)
 644   (setq rng-pending-contents nil)
 645   (goto-char (point-min)))
 646
 647 (defun rng-clear-overlays (beg end)
 648   (unless rng-parsing-for-state
 649     (let ((overlays (overlays-in beg end)))
 650       (while overlays
 651         (let* ((overlay (car overlays))
 652                (category (overlay-get overlay 'category)))
 653           (cond ((eq category 'rng-error)
 654                  (let ((inhibit-quit t))
 655                    (when (eq overlay rng-message-overlay)
 656                      (rng-error-overlay-message nil))
 657                    (delete-overlay overlay)
 658                    ;; rng-error-count could be nil
 659                    ;; if overlays left over from a previous use
 660                    ;; of rng-validate-mode that ended with a change of mode
 661                    (when rng-error-count
 662                      (setq rng-error-count (1- rng-error-count)))))
 663                 ((and (eq category 'rng-dependent)
 664                       (<= beg (overlay-start overlay)))
 665                  (delete-overlay overlay))))
 666         (setq overlays (cdr overlays))))))
 667
 668 ;;; Dependent regions
 669
 670 (defun rng-mark-xmltok-dependent-regions ()
 671   (while xmltok-dependent-regions
 672     (apply 'rng-mark-xmltok-dependent-region
 673            (car xmltok-dependent-regions))
 674     (setq xmltok-dependent-regions
 675           (cdr xmltok-dependent-regions))))
 676
 677 (defun rng-mark-xmltok-dependent-region (fun start end &rest args)
 678   (let ((overlay (make-overlay start end nil t t)))
 679     (overlay-put overlay 'category 'rng-dependent)
 680     (overlay-put overlay 'rng-funargs (cons fun args))))
 681
 682 (put 'rng-dependent 'evaporate t)
 683 (put 'rng-dependent 'modification-hooks '(rng-dependent-region-changed))
 684 (put 'rng-dependent 'insert-behind-hooks '(rng-dependent-region-changed))
 685
 686 (defun rng-dependent-region-changed (overlay
 687                                      after-p
 688                                      change-start
 689                                      change-end
 690                                      &optional pre-change-length)
 691   (when (and after-p
 692              ;; Emacs sometimes appears to call deleted overlays
 693              (overlay-start overlay)
 694              (let ((funargs (overlay-get overlay 'rng-funargs)))
 695                (save-match-data
 696                  (save-excursion
 697                    (save-restriction
 698                      (widen)
 699                      (apply (car funargs)
 700                             (append (list change-start
 701                                           change-end
 702                                           pre-change-length
 703                                           (overlay-start overlay)
 704                                           (overlay-end overlay))
 705                                     (cdr funargs))))))))
 706     (rng-after-change-function (overlay-start overlay)
 707                                change-end
 708                                (+ pre-change-length
 709                                   (- (overlay-start overlay)
 710                                      change-start)))
 711     (delete-overlay overlay)))
 712
 713 ;;; Error state
 714
 715 (defun rng-mark-xmltok-errors ()
 716   (while xmltok-errors
 717     (let ((err (car xmltok-errors)))
 718       (rng-mark-not-well-formed (xmltok-error-message err)
 719                                 (xmltok-error-start err)
 720                                 (xmltok-error-end err)))
 721     (setq xmltok-errors (cdr xmltok-errors))))
 722
 723 (defun rng-mark-invalid (message beg end)
 724   (rng-mark-error message beg end))
 725
 726 (defun rng-mark-not-well-formed (message beg end)
 727   ;; Don't try to validate further
 728   ;;(rng-set-match-state rng-not-allowed-ipattern)
 729   (rng-mark-error message beg end))
 730
 731 (defun rng-mark-error (message beg end)
 732   (unless rng-parsing-for-state
 733     (let ((overlays (overlays-in beg end)))
 734       (while (and overlays message)
 735         (let ((o (car overlays)))
 736           (when (and (eq (overlay-get o 'category) 'rng-error)
 737                      (= (overlay-start o) beg)
 738                      (= (overlay-end o) end))
 739             (overlay-put o
 740                          'help-echo
 741                          (concat (overlay-get o 'help-echo)
 742                                  "\n"
 743                                  message))
 744             (setq message nil)))
 745         (setq overlays (cdr overlays))))
 746     (when message
 747       (let ((inhibit-quit t))
 748         (setq rng-error-count (1+ rng-error-count))
 749         (let ((overlay
 750                (make-overlay beg end nil t
 751                              ;; Need to make the rear delimiter advance
 752                              ;; with the front delimiter when the overlay
 753                              ;; is empty, otherwise the front delimiter
 754                              ;; will move past the rear delimiter.
 755                              (= beg end))))
 756           ;; Ensure when we have two overlapping messages, the help-echo
 757           ;; of the one that starts first is shown
 758           (overlay-put overlay 'priority beg)
 759           (overlay-put overlay 'category 'rng-error)
 760           (overlay-put overlay 'help-echo message))))))
 761
 762 (put 'rng-error 'face 'rng-error)
 763 (put 'rng-error 'modification-hooks '(rng-error-modified))
 764
 765 ;; If we don't do this, then the front delimiter can move
 766 ;; past the end delimiter.
 767 (defun rng-error-modified (overlay after-p beg end &optional pre-change-len)
 768   (when (and after-p
 769              (overlay-start overlay)    ; check not deleted
 770              (>= (overlay-start overlay)
 771                  (overlay-end overlay)))
 772     (let ((inhibit-quit t))
 773       (delete-overlay overlay)
 774       (setq rng-error-count (1- rng-error-count)))))
 775
 776 (defun rng-echo-area-clear-function ()
 777   (setq rng-message-overlay-current nil))
 778
 779 ;;; Error navigation
 780
 781 (defun rng-maybe-echo-error-at-point ()
 782   (when (or (not (current-message))
 783             (rng-current-message-from-error-overlay-p))
 784     (rng-error-overlay-message (rng-error-overlay-after (point)))))
 785
 786 (defun rng-error-overlay-after (pos)
 787   (let ((overlays (overlays-in pos (1+ pos)))
 788         (best nil))
 789     (while overlays
 790       (let ((overlay (car overlays)))
 791         (when (and (eq (overlay-get overlay 'category)
 792                        'rng-error)
 793                    (or (not best)
 794                        (< (overlay-start best)
 795                           (overlay-start overlay))))
 796           (setq best overlay)))
 797       (setq overlays (cdr overlays)))
 798     best))
 799
 800 (defun rng-first-error ()
 801   "Go to the first validation error.
 802 Turn on `rng-validate-mode' if it is not already on."
 803   (interactive)
 804   (or rng-validate-mode (rng-validate-mode))
 805   (rng-do-some-validation)
 806   (let ((err (rng-find-next-error-overlay (1- (point-min)))))
 807     (if err
 808         (rng-goto-error-overlay err)
 809       (let ((pos (save-excursion
 810                    (goto-char (point-min))
 811                    (rng-next-error 1))))
 812         (when pos
 813           (goto-char pos))))))
 814
 815 (defun rng-mouse-first-error (event)
 816   "Go to the first validation error from a mouse click."
 817   (interactive "e")
 818   (select-window (posn-window (event-start event)))
 819   (rng-first-error))
 820
 821 (defun rng-next-error (arg)
 822   "Go to the next validation error after point.
 823 Turn on `rng-validate-mode' if it is not already on.
 824 A prefix ARG specifies how many errors to move.
 825 A negative ARG moves backwards.  Just \\[universal-argument] as a prefix
 826 means goto the first error."
 827   (interactive "P")
 828   (if (consp arg)
 829       (rng-first-error)
 830     (or rng-validate-mode (rng-validate-mode))
 831     (setq arg (prefix-numeric-value arg))
 832     (if (< arg 0)
 833         (rng-previous-error-1 (- arg))
 834       (rng-next-error-1 arg))))
 835
 836 (defun rng-previous-error (arg)
 837   "Go to the previous validation error before point.
 838 Turn on `rng-validate-mode' if it is not already on.
 839 A prefix ARG specifies how many errors to move.
 840 A negative ARG moves forwards.  Just \\[universal-argument] as a prefix
 841 means goto the first error."
 842   (interactive "P")
 843   (if (consp arg)
 844       (rng-first-error)
 845     (or rng-validate-mode (rng-validate-mode))
 846     (setq arg (prefix-numeric-value arg))
 847     (if (< arg 0)
 848         (rng-next-error-1 (- arg))
 849       (rng-previous-error-1 arg))))
 850
 851 (defun rng-next-error-1 (arg)
 852   (let* ((pos (point))
 853          err last-err)
 854     (while (and (> arg 0)
 855                 (setq err (rng-find-next-error-overlay pos)))
 856       (setq arg (1- arg))
 857       (setq last-err err)
 858       (setq pos (overlay-start err)))
 859     (when (> arg 0)
 860       (setq pos (max pos (1- rng-validate-up-to-date-end)))
 861       (when (< rng-validate-up-to-date-end (point-max))
 862         (message "Parsing...")
 863         (while (let ((more-to-do (rng-do-some-validation)))
 864                  (while (and (> arg 0)
 865                              (setq err (rng-find-next-error-overlay pos)))
 866                    (setq arg (1- arg))
 867                    (setq last-err err)
 868                    (setq pos (overlay-start err)))
 869                  (when (and (> arg 0)
 870                             more-to-do
 871                             (< rng-validate-up-to-date-end (point-max)))
 872                    ;; Display percentage validated.
 873                    (force-mode-line-update)
 874                    (sit-for 0)
 875                    (setq pos
 876                          (max pos (1- rng-validate-up-to-date-end)))
 877                    t)))))
 878     (if last-err
 879         (rng-goto-error-overlay last-err)
 880       (message "No more errors")
 881       nil)))
 882
 883 (defun rng-previous-error-1 (arg)
 884   (let* ((pos (point))
 885          err last-err)
 886     (while (and (> arg 0)
 887                 (setq err (rng-find-previous-error-overlay pos)))
 888       (setq pos (overlay-start err))
 889       (setq last-err err)
 890       (setq arg (1- arg)))
 891     (when (and (> arg 0)
 892                (< rng-validate-up-to-date-end (min pos (point-max))))
 893       (message "Parsing...")
 894       (while (and (rng-do-some-validation)
 895                   (< rng-validate-up-to-date-end (min pos (point-max))))
 896         (force-mode-line-update)
 897         (sit-for 0))
 898       (while (and (> arg 0)
 899                   (setq err (rng-find-previous-error-overlay pos)))
 900         (setq pos (overlay-start err))
 901         (setq last-err err)
 902         (setq arg (1- arg))))
 903     (if last-err
 904         (rng-goto-error-overlay last-err)
 905       (message "No previous errors")
 906       nil)))
 907
 908 (defun rng-goto-error-overlay (err)
 909   "Goto the start of error overlay ERR and print its message."
 910   (goto-char (overlay-start err))
 911   (setq rng-message-overlay-inhibit-point nil)
 912   (rng-error-overlay-message err))
 913
 914 (defun rng-error-overlay-message (err)
 915   (if err
 916       (unless (or (and (eq rng-message-overlay-inhibit-point (point))
 917                        (eq rng-message-overlay err))
 918                   (= (point-max) 1))
 919         (message "%s" (overlay-get err 'help-echo))
 920         (setq rng-message-overlay-current t)
 921         (setq rng-message-overlay-inhibit-point (point)))
 922     (when (rng-current-message-from-error-overlay-p)
 923       (message nil))
 924     (setq rng-message-overlay-inhibit-point nil))
 925   (setq rng-message-overlay err))
 926
 927 (defun rng-current-message-from-error-overlay-p ()
 928   (and rng-message-overlay-current
 929        rng-message-overlay
 930        (equal (overlay-get rng-message-overlay 'help-echo)
 931               (current-message))))
 932
 933 (defun rng-find-next-error-overlay (pos)
 934   "Return the overlay for the next error starting after POS.
 935 Return nil if there is no such overlay or it is out of date.
 936 Do not do any additional validation."
 937   (when rng-error-count
 938     (let (done found overlays)
 939       (while (not done)
 940         (cond (overlays
 941                (let ((overlay (car overlays)))
 942                  (setq overlays (cdr overlays))
 943                  (when (and (eq (overlay-get overlay 'category) 'rng-error)
 944                             ;; Is it the first?
 945                             (= (overlay-start overlay) pos)
 946                             ;; Is it up to date?
 947                             (<= (overlay-end overlay)
 948                                 rng-validate-up-to-date-end))
 949                    (setq done t)
 950                    (setq found overlay))))
 951               ((or (= pos (point-max))
 952                    (> (setq pos (next-overlay-change pos))
 953                       rng-validate-up-to-date-end))
 954                (setq done t))
 955               (t (setq overlays (overlays-in pos (1+ pos))))))
 956       found)))
 957
 958 (defun rng-find-previous-error-overlay (pos)
 959   "Return the overlay for the last error starting before POS.
 960 Return nil if there is no such overlay or it is out of date.
 961 Do not do any additional validation."
 962   (when (and rng-error-count
 963              (<= pos rng-validate-up-to-date-end))
 964     (let (done found overlays)
 965       (while (not done)
 966         (cond (overlays
 967                (let ((overlay (car overlays)))
 968                  (setq overlays (cdr overlays))
 969                  (when (and (eq (overlay-get overlay 'category) 'rng-error)
 970                             ;; Is it the first?
 971                             (= (overlay-start overlay) pos))
 972                    (setq done t)
 973                    (setq found overlay))))
 974               ((= pos (point-min))
 975                (setq done t))
 976               (t
 977                (setq pos (previous-overlay-change pos))
 978                (setq overlays (overlays-in pos (1+ pos))))))
 979       found)))
 980
 981 ;;; Parsing
 982
 983 (defun rng-forward (&optional limit)
 984   "Move forward over one or more tokens updating the state.
 985 If LIMIT is nil, stop after tags.
 986 If LIMIT is non-nil, stop when end of last token parsed is >= LIMIT.
 987 Return nil at end of buffer, t otherwise."
 988   (let (type)
 989     (while (progn
 990              (setq type (xmltok-forward))
 991              (rng-clear-overlays xmltok-start (point))
 992              (let ((continue
 993                     (cond ((eq type 'start-tag)
 994                            (rng-process-start-tag 'start-tag)
 995                            nil)
 996                           ((eq type 'end-tag)
 997                            (rng-process-end-tag)
 998                            nil)
 999                           ((eq type 'empty-element)
1000                            (rng-process-start-tag 'empty-element)
1001                            nil)
1002                           ((eq type 'space)
1003                            (rng-process-text xmltok-start nil t)
1004                            t)
1005                           ((eq type 'data)
1006                            (rng-process-text xmltok-start nil nil)
1007                            t)
1008                           ((memq type '(entity-ref char-ref))
1009                            (cond (xmltok-replacement
1010                                   (rng-process-text xmltok-start
1011                                                     nil
1012                                                     'maybe
1013                                                     xmltok-replacement))
1014                                  ((eq type 'char-ref)
1015                                   (rng-process-unknown-char))
1016                                  (t
1017                                   (rng-process-unknown-entity)))
1018                            t)
1019                           ((eq type 'cdata-section)
1020                            (rng-process-text (+ xmltok-start 9) ; "<![CDATA["
1021                                              (- (point) 3) ; "]]>"
1022                                              'maybe)
1023                            t)
1024                           ((eq type 'partial-start-tag)
1025                            (rng-process-start-tag 'partial-start-tag)
1026                            t)
1027                           ((eq type 'partial-empty-element)
1028                            (rng-process-start-tag 'empty-element)
1029                            t)
1030                           ((eq type 'partial-end-tag)
1031                            (rng-process-end-tag 'partial)
1032                            t)
1033                           (t type))))
1034                (if limit
1035                    (< (point) limit)
1036                  continue))))
1037     (and type t)))
1038
1039 (defun rng-process-start-tag (tag-type)
1040   "TAG-TYPE is `start-tag' for a start-tag, `empty-element' for
1041 an empty element.  `partial-empty-element' should be passed
1042 as empty-element."
1043   (and rng-collecting-text (rng-flush-text))
1044   (setq rng-collecting-text nil)
1045   (setq rng-pending-contents nil)
1046   (rng-process-namespaces)
1047   (let ((tag (rng-process-tag-name)))
1048     (rng-process-attributes)
1049     ;; set the state appropriately
1050     (cond ((eq tag-type 'empty-element)
1051            (rng-process-start-tag-close)
1052            ;; deal with missing content with empty element
1053            (when (not (rng-match-empty-content))
1054              (rng-match-after)
1055              (rng-mark-start-tag-close "Empty content not allowed"))
1056            (nxml-ns-pop-state))
1057           ((eq tag-type 'start-tag)
1058            (rng-process-start-tag-close)
1059            (setq rng-collecting-text (rng-match-text-typed-p))
1060            (rng-push-tag tag))
1061           ((eq tag-type 'partial-start-tag)
1062            (rng-process-start-tag-close)
1063            (rng-match-after)
1064            (nxml-ns-pop-state)))))
1065
1066 (defun rng-process-namespaces ()
1067   (let ((nsatts xmltok-namespace-attributes)
1068         prefixes)
1069     (nxml-ns-push-state)
1070     (while nsatts
1071       (let* ((att (car nsatts))
1072              (value (xmltok-attribute-value att)))
1073         (when value
1074           (let ((ns (nxml-make-namespace value))
1075                 (prefix (and (xmltok-attribute-prefix att)
1076                              (xmltok-attribute-local-name att))))
1077             (cond ((member prefix prefixes)
1078                    (rng-mark-invalid "Duplicate namespace declaration"
1079                                      (xmltok-attribute-name-start att)
1080                                      (xmltok-attribute-name-end att)))
1081                   ((not prefix)
1082                    (nxml-ns-set-default ns))
1083                   (ns
1084                    (nxml-ns-set-prefix prefix ns))
1085                   (t
1086                    ;; cannot have xmlns:foo=""
1087                    (rng-mark-invalid "Namespace prefix cannot be undeclared"
1088                                      (1- (xmltok-attribute-value-start att))
1089                                      (1+ (xmltok-attribute-value-end att)))))
1090             (setq prefixes (cons prefix prefixes)))))
1091       (setq nsatts (cdr nsatts)))))
1092
1093 (defun rng-process-tag-name ()
1094   (let* ((prefix (xmltok-start-tag-prefix))
1095          (local-name (xmltok-start-tag-local-name))
1096          (name
1097           (if prefix
1098               (let ((ns (nxml-ns-get-prefix prefix)))
1099                 (cond (ns (cons ns local-name))
1100                       ((and (setq ns
1101                                   (rng-match-infer-start-tag-namespace
1102                                    local-name))
1103                             (rng-match-start-tag-open (cons ns local-name)))
1104                        (nxml-ns-set-prefix prefix ns)
1105                        (rng-mark-start-tag-close "Missing xmlns:%s=\"%s\""
1106                                                  prefix
1107                                                  (nxml-namespace-name ns))
1108                        nil)
1109                       (t
1110                        (rng-recover-bad-element-prefix)
1111                        nil)))
1112             (cons (nxml-ns-get-default) local-name))))
1113     (when (and name
1114                (not (rng-match-start-tag-open name)))
1115       (unless (and (not (car name))
1116                    (let ((ns (rng-match-infer-start-tag-namespace (cdr name))))
1117                      (and ns
1118                           (rng-match-start-tag-open (cons ns local-name))
1119                           (progn
1120                             (nxml-ns-set-default ns)
1121                             ;; XXX need to check we don't have xmlns=""
1122                             (rng-mark-start-tag-close "Missing xmlns=\"%s\""
1123                                                       (nxml-namespace-name ns))
1124                             t))))
1125         (rng-recover-start-tag-open name)))
1126     (cons prefix local-name)))
1127
1128 (defun rng-process-attributes ()
1129   (let ((atts xmltok-attributes)
1130         names)
1131     (while atts
1132       (let* ((att (car atts))
1133              (prefix (xmltok-attribute-prefix att))
1134              (local-name (xmltok-attribute-local-name att))
1135              (name
1136               (if prefix
1137                   (let ((ns (nxml-ns-get-prefix prefix)))
1138                     (and ns
1139                          (cons ns local-name)))
1140                 (cons nil local-name))))
1141         (cond ((not name)
1142                (rng-recover-bad-attribute-prefix att))
1143               ((member name names)
1144                (rng-recover-duplicate-attribute-name att))
1145               ((not (rng-match-attribute-name name))
1146                (rng-recover-attribute-name att))
1147               ((rng-match-text-typed-p)
1148                (let ((value (xmltok-attribute-value att)))
1149                  (if value
1150                      (or (rng-match-attribute-value value)
1151                          (rng-recover-attribute-value att))
1152                    (rng-match-after))))
1153               (t (or (rng-match-end-tag)
1154                      (error "Internal error:\
1155  invalid on untyped attribute value"))))
1156         (setq names (cons name names)))
1157       (setq atts (cdr atts)))))
1158
1159 (defun rng-process-start-tag-close ()
1160   ;; deal with missing attributes
1161   (unless (rng-match-start-tag-close)
1162     (rng-mark-start-tag-close (rng-missing-attributes-message))
1163     (rng-match-ignore-attributes)))
1164
1165 (defun rng-mark-start-tag-close (&rest args)
1166   (when (not (eq xmltok-type 'partial-start-tag))
1167     (rng-mark-invalid (apply 'format args)
1168                       (- (point)
1169                          (if (eq xmltok-type 'empty-element)
1170                              2
1171                            1))
1172                       (point))))
1173
1174 (defun rng-recover-bad-element-prefix ()
1175   (rng-mark-invalid "Prefix not declared"
1176                     (1+ xmltok-start)
1177                     xmltok-name-colon)
1178   (rng-match-unknown-start-tag-open))
1179
1180 (defun rng-recover-bad-attribute-prefix (att)
1181   (rng-mark-invalid "Prefix not declared"
1182                     (xmltok-attribute-name-start att)
1183                     (xmltok-attribute-name-colon att)))
1184
1185 (defun rng-recover-duplicate-attribute-name (att)
1186   (rng-mark-invalid "Duplicate attribute"
1187                     (xmltok-attribute-name-start att)
1188                     (xmltok-attribute-name-end att)))
1189
1190 (defun rng-recover-start-tag-open (name)
1191   (let ((required (rng-match-required-element-name)))
1192     (cond ((and required
1193                 (rng-match-start-tag-open required)
1194                 (rng-match-after)
1195                 (rng-match-start-tag-open name))
1196            (rng-mark-invalid (concat "Missing element "
1197                                      (rng-quote-string
1198                                       (rng-name-to-string required)))
1199                              xmltok-start
1200                              (1+ xmltok-start)))
1201           ((and (rng-match-optionalize-elements)
1202                 (rng-match-start-tag-open name))
1203            (rng-mark-invalid "Required elements missing"
1204                              xmltok-start
1205                              (1+ xmltok-start)))
1206           ((rng-match-out-of-context-start-tag-open name)
1207            (rng-mark-invalid "Element not allowed in this context"
1208                              (1+ xmltok-start)
1209                              xmltok-name-end))
1210           (t
1211            (rng-match-unknown-start-tag-open)
1212            (rng-mark-invalid "Unknown element"
1213                              (1+ xmltok-start)
1214                              xmltok-name-end)))))
1215
1216 (defun rng-recover-attribute-value (att)
1217   (let ((start (xmltok-attribute-value-start att))
1218         (end (xmltok-attribute-value-end att)))
1219     (if (= start end)
1220         (rng-mark-invalid "Empty attribute value invalid" start (1+ end))
1221       (rng-mark-invalid "Attribute value invalid" start end)))
1222   (rng-match-after))
1223
1224 (defun rng-recover-attribute-name (att)
1225   (rng-mark-invalid "Attribute not allowed"
1226                     (xmltok-attribute-name-start att)
1227                     (xmltok-attribute-name-end att)))
1228
1229 (defun rng-missing-attributes-message ()
1230   (let ((required-attributes
1231          (rng-match-required-attribute-names)))
1232     (cond ((not required-attributes)
1233            "Required attributes missing")
1234           ((not (cdr required-attributes))
1235            (concat "Missing attribute "
1236                    (rng-quote-string
1237                     (rng-name-to-string (car required-attributes) t))))
1238           (t
1239            (concat "Missing attributes "
1240                    (mapconcat (lambda (nm)
1241                                 (rng-quote-string
1242                                  (rng-name-to-string nm t)))
1243                               required-attributes
1244                               ", "))))))
1245
1246 (defun rng-process-end-tag (&optional partial)
1247   (cond ((not rng-open-elements)
1248          (rng-mark-not-well-formed "Extra end-tag"
1249                                    xmltok-start
1250                                    (point)))
1251         ((or partial
1252              (equal (cons (xmltok-end-tag-prefix)
1253                           (xmltok-end-tag-local-name))
1254                     (car rng-open-elements)))
1255          (rng-end-element))
1256         (t (rng-recover-mismatched-end-tag))))
1257
1258 (defun rng-end-element ()
1259   (if rng-collecting-text
1260       (let ((contents (rng-contents-string)))
1261         (cond ((not contents) (rng-match-after))
1262               ((not (rng-match-element-value contents))
1263                (let* ((region (rng-contents-region)))
1264                  (if (not region)
1265                      (rng-mark-invalid "Empty content not allowed"
1266                                        xmltok-start
1267                                        (+ xmltok-start 2))
1268                    (rng-mark-invalid "Invalid data"
1269                                      (car region)
1270                                      (cdr region))))
1271                (rng-match-after)))
1272         (setq rng-collecting-text nil)
1273         (setq rng-pending-contents nil))
1274     (unless (rng-match-end-tag)
1275        (rng-mark-invalid (rng-missing-element-message)
1276                          xmltok-start
1277                          (+ xmltok-start 2))
1278        (rng-match-after)))
1279   (nxml-ns-pop-state)
1280   (when (eq (car rng-open-elements) t)
1281     (rng-pop-tag))
1282   (rng-pop-tag))
1283
1284 (defun rng-missing-element-message ()
1285   (let ((element (rng-match-required-element-name)))
1286     (if element
1287         (concat "Missing element "
1288                 (rng-quote-string (rng-name-to-string element)))
1289       "Required child elements missing")))
1290
1291 (defun rng-recover-mismatched-end-tag ()
1292   (let* ((name (cons (xmltok-end-tag-prefix)
1293                      (xmltok-end-tag-local-name))))
1294     (cond ((member name (cdr rng-open-elements))
1295            (let* ((suppress-error (eq (car rng-open-elements) t))
1296                   missing top)
1297              (while (progn
1298                       (setq top (car rng-open-elements))
1299                       (rng-pop-tag)
1300                       (unless (eq top t)
1301                         (setq missing (cons top missing))
1302                         (nxml-ns-pop-state)
1303                         (rng-match-after))
1304                       (not (equal top name))))
1305              (unless suppress-error
1306                (rng-mark-missing-end-tags (cdr missing)))))
1307           ((rng-match-empty-before-p)
1308            (rng-mark-mismatched-end-tag)
1309            (rng-end-element))
1310           (t (rng-mark-mismatched-end-tag)
1311              (setq rng-open-elements
1312                    (cons t rng-open-elements))))))
1313
1314 (defun rng-mark-missing-end-tags (missing)
1315   (rng-mark-not-well-formed
1316    (format "Missing end-tag%s %s"
1317            (if (null (cdr missing)) "" "s")
1318            (mapconcat (lambda (name)
1319                         (rng-quote-string
1320                          (if (car name)
1321                              (concat (car name)
1322                                      ":"
1323                                      (cdr name))
1324                            (cdr name))))
1325                       missing
1326                       ", "))
1327    xmltok-start
1328    (+ xmltok-start 2)))
1329
1330 (defun rng-mark-mismatched-end-tag ()
1331   (rng-mark-not-well-formed "Mismatched end-tag"
1332                             (+ xmltok-start 2)
1333                             xmltok-name-end))
1334
1335 (defun rng-push-tag (prefix-local-name)
1336   (setq rng-open-elements
1337         (cons prefix-local-name rng-open-elements)))
1338
1339 (defun rng-pop-tag ()
1340   (setq rng-open-elements (cdr rng-open-elements)))
1341
1342 (defun rng-contents-string ()
1343   (let ((contents rng-pending-contents))
1344     (cond ((not contents) "")
1345           ((memq nil contents) nil)
1346           ((not (cdr contents))
1347            (rng-segment-string (car contents)))
1348           (t (apply 'concat
1349                     (nreverse (mapcar 'rng-segment-string
1350                                       contents)))))))
1351
1352 (defun rng-segment-string (segment)
1353   (or (car segment)
1354       (apply 'buffer-substring-no-properties
1355              (cdr segment))))
1356
1357 (defun rng-segment-blank-p (segment)
1358   (if (car segment)
1359       (rng-blank-p (car segment))
1360     (apply 'rng-region-blank-p
1361            (cdr segment))))
1362
1363 (defun rng-contents-region ()
1364   (if (null rng-pending-contents)
1365       nil
1366     (let* ((contents rng-pending-contents)
1367            (head (cdar contents))
1368            (start (car head))
1369            (end (cadr head)))
1370       (while (setq contents (cdr contents))
1371         (setq start (car (cdar contents))))
1372       (cons start end))))
1373
1374 (defun rng-process-text (start end whitespace &optional value)
1375   "Process characters between position START and END as text.
1376 END nil means point.  WHITESPACE t means known to be whitespace, nil
1377 means known not to be, anything else means unknown whether whitespace
1378 or not.  END must not be nil if WHITESPACE is neither t nor nil.
1379 VALUE is a string or nil; nil means the value is equal to the
1380 string between START and END."
1381   (cond (rng-collecting-text
1382          (setq rng-pending-contents (cons (list value start (or end (point)))
1383                                           rng-pending-contents)))
1384         ((not (or (and whitespace
1385                        (or (eq whitespace t)
1386                            (if value
1387                                (rng-blank-p value)
1388                              (rng-region-blank-p start end))))
1389                   (rng-match-mixed-text)))
1390          (rng-mark-invalid "Text not allowed" start (or end (point))))))
1391
1392 (defun rng-process-unknown-char ()
1393   (when rng-collecting-text
1394     (setq rng-pending-contents
1395           (cons nil rng-pending-contents))))
1396
1397 (defun rng-process-unknown-entity ()
1398   (rng-process-unknown-char)
1399   (rng-match-optionalize-elements))
1400
1401 (defun rng-region-blank-p (beg end)
1402   (save-excursion
1403     (goto-char beg)
1404     (= (skip-chars-forward " \n\r\t" end)
1405        (- end beg))))
1406
1407 (defun rng-flush-text ()
1408   (while rng-pending-contents
1409     (let ((segment (car rng-pending-contents)))
1410       (unless (or (rng-segment-blank-p segment)
1411                   (rng-match-mixed-text))
1412         (let ((region (cdr segment)))
1413           (rng-mark-invalid "In this context text cannot be mixed with elements"
1414                             (car region)
1415                             (cadr region)))))
1416     (setq rng-pending-contents (cdr rng-pending-contents))))
1417
1418 (defun rng-process-end-document ()
1419   ;; this is necessary to clear empty overlays at (point-max)
1420   (rng-clear-overlays (point) (point))
1421   (let ((start (save-excursion
1422                  (skip-chars-backward " \t\r\n")
1423                  (point))))
1424     (cond (rng-open-elements
1425            (unless (eq (car rng-open-elements) t)
1426              (rng-mark-not-well-formed "Missing end-tag"
1427                                        start
1428                                        (point))))
1429           ((not (rng-match-nullable-p))
1430            (rng-mark-not-well-formed "No document element"
1431                                      start
1432                                      (point))))))
1433
1434 (defun rng-process-encoding-name (beg end)
1435   (unless (let ((charset (buffer-substring-no-properties beg end)))
1436             (or (nxml-mime-charset-coding-system charset)
1437                 (string= (downcase charset) "utf-16")))
1438     (rng-mark-not-well-formed "Unsupported encoding" beg end)))
1439
1440 (defun rng-name-to-string (name &optional attributep)
1441   (let ((ns (car name))
1442         (local-name (cdr name)))
1443     (if (or (not ns)
1444             (and (not attributep)
1445                  (eq (nxml-ns-get-default) ns)))
1446         local-name
1447       (let ((prefix (nxml-ns-prefix-for ns)))
1448         (if prefix
1449             (concat prefix ":" local-name)
1450           (concat "{" (symbol-name ns) "}" local-name))))))
1451
1452 (provide 'rng-valid)
1453
1454 ;;; rng-valid.el ends here