lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: mouse, terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Enable mouse support when running inside an xterm.
  29
  30 ;; This is actually useful when you are running X11 locally, but is
  31 ;; working on remote machine over a modem line or through a gateway.
  32
  33 ;; It works by translating xterm escape codes into generic emacs mouse
  34 ;; events so it should work with any package that uses the mouse.
  35
  36 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  37 ;; functionality, it is still available by holding down the SHIFT key
  38 ;; when you press the mouse button.
  39
  40 ;;; Todo:
  41
  42 ;; The xterm mouse escape codes are supposedly also supported by the
  43 ;; Linux console, but I have not been able to verify this.
  44
  45 ;; Support multi-click -- somehow.
  46
  47 ;;; Code:
  48
  49 (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  50
  51 (defvar xterm-mouse-last)
  52
  53 ;; Mouse events symbols must have an 'event-kind property with
  54 ;; the value 'mouse-click.
  55 (dolist (event-type '(mouse-1 mouse-2 mouse-3))
  56   (put event-type 'event-kind 'mouse-click))
  57
  58 (defun xterm-mouse-translate (event)
  59   "Read a click and release event from XTerm."
  60   (save-excursion
  61     (save-window-excursion
  62       (deactivate-mark)
  63       (let* ((xterm-mouse-last)
  64              (down (xterm-mouse-event))
  65              (down-command (nth 0 down))
  66              (down-data (nth 1 down))
  67              (down-where (nth 1 down-data))
  68              (down-binding (key-binding (if (symbolp down-where)
  69                                             (vector down-where down-command)
  70                                           (vector down-command))))
  71              (is-click (string-match "^mouse" (symbol-name (car down)))))
  72
  73         (unless is-click
  74           (unless (and (eq (read-char) ?\e)
  75                        (eq (read-char) ?\[)
  76                        (eq (read-char) ?M))
  77             (error "Unexpected escape sequence from XTerm")))
  78
  79         (let* ((click (if is-click down (xterm-mouse-event)))
  80                (click-command (nth 0 click))
  81                (click-data (nth 1 click))
  82                (click-where (nth 1 click-data)))
  83           (if (memq down-binding '(nil ignore))
  84               (if (and (symbolp click-where)
  85                        (consp click-where))
  86                   (vector (list click-where click-data) click)
  87                 (vector click))
  88             (setq unread-command-events
  89                   (if (eq down-where click-where)
  90                       (list click)
  91                     (list
  92                      ;; Cheat `mouse-drag-region' with move event.
  93                      (list 'mouse-movement click-data)
  94                      ;; Generate a drag event.
  95                      (if (symbolp down-where)
  96                          0
  97                        (list (intern (format "drag-mouse-%d"
  98                                              (+ 1 xterm-mouse-last)))
  99                              down-data click-data)))))
 100             (if (and (symbolp down-where)
 101                      (consp down-where))
 102                 (vector (list down-where down-data) down)
 103               (vector down))))))))
 104
 105 (defvar xterm-mouse-x 0
 106   "Position of last xterm mouse event relative to the frame.")
 107
 108 (defvar xterm-mouse-y 0
 109   "Position of last xterm mouse event relative to the frame.")
 110
 111 ;; Indicator for the xterm-mouse mode.
 112
 113 (defun xterm-mouse-position-function (pos)
 114   "Bound to `mouse-position-function' in XTerm mouse mode."
 115   (setcdr pos (cons xterm-mouse-x xterm-mouse-y))
 116   pos)
 117
 118 ;; read xterm sequences above ascii 127 (#x7f)
 119 (defun xterm-mouse-event-read ()
 120   (let ((c (read-char)))
 121     (if (< c 0)
 122         (+ c #x8000000 128)
 123       c)))
 124
 125 (defun xterm-mouse-event ()
 126   "Convert XTerm mouse event to Emacs mouse event."
 127   (let* ((type (- (xterm-mouse-event-read) #o40))
 128          (x (- (xterm-mouse-event-read) #o40 1))
 129          (y (- (xterm-mouse-event-read) #o40 1))
 130          (mouse (intern
 131                  ;; For buttons > 3, the release-event looks
 132                  ;; differently (see xc/programs/xterm/button.c,
 133                  ;; function EditorButton), and there seems to come in
 134                  ;; a release-event only, no down-event.
 135                  (cond ((>= type 64)
 136                         (format "mouse-%d" (- type 60)))
 137                        ((= type 3)
 138                         (format "mouse-%d" (+ 1 xterm-mouse-last)))
 139                        (t
 140                         (setq xterm-mouse-last type)
 141                         (format "down-mouse-%d" (+ 1 type))))))
 142          (w (window-at x y))
 143          (ltrb (window-edges w))
 144          (left (nth 0 ltrb))
 145          (top (nth 1 ltrb)))
 146
 147     (setq xterm-mouse-x x
 148           xterm-mouse-y y)
 149     (if w
 150         (list mouse (posn-at-x-y (- x left) (- y top) w t))
 151       (list mouse
 152             (append (list nil 'menu-bar) (nthcdr 2 (posn-at-x-y x y w t)))))))
 153
 154 ;;;###autoload
 155 (define-minor-mode xterm-mouse-mode
 156   "Toggle XTerm mouse mode.
 157 With prefix arg, turn XTerm mouse mode on iff arg is positive.
 158
 159 Turn it on to use Emacs mouse commands, and off to use xterm mouse commands.
 160 This works in terminal emulators compatible with xterm.  It only
 161 works for simple uses of the mouse.  Basically, only non-modified
 162 single clicks are supported.  When turned on, the normal xterm
 163 mouse functionality for such clicks is still available by holding
 164 down the SHIFT key while pressing the mouse button."
 165   :global t :group 'mouse
 166   (if xterm-mouse-mode
 167       ;; Turn it on
 168       (unless window-system
 169         (setq mouse-position-function #'xterm-mouse-position-function)
 170         (turn-on-xterm-mouse-tracking))
 171     ;; Turn it off
 172     (turn-off-xterm-mouse-tracking 'force)
 173     (setq mouse-position-function nil)))
 174
 175 (defun turn-on-xterm-mouse-tracking ()
 176   "Enable Emacs mouse tracking in xterm."
 177   (if xterm-mouse-mode
 178       (send-string-to-terminal "\e[?1000h")))
 179
 180 (defun turn-off-xterm-mouse-tracking (&optional force)
 181   "Disable Emacs mouse tracking in xterm."
 182   (if (or force xterm-mouse-mode)
 183       (send-string-to-terminal "\e[?1000l")))
 184
 185 ;; Restore normal mouse behaviour outside Emacs.
 186 (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 187 (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 188 (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 189
 190 (provide 'xt-mouse)
 191
 192 ;;; arch-tag: 84962d4e-fae9-4c13-a9d7-ef4925a4ac03
 193 ;;; xt-mouse.el ends here