configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2013 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26
  27 dnl This is the documented way to record the args passed to configure,
  28 dnl rather than $ac_configure_args.
  29 emacs_config_options="$@"
  30 ## Add some environment variables, if they were passed via the environment
  31 ## rather than on the command-line.
  32 for var in CFLAGS CPPFLAGS LDFLAGS; do
  33     case "$emacs_config_options" in
  34       *$var=*) continue ;;
  35     esac
  36     eval val="\$${var}"
  37     test x"$val" = x && continue
  38     emacs_config_options="${emacs_config_options}${emacs_config_options:+ }$var=\"$val\""
  39 done
  40
  41 AC_CONFIG_HEADER(src/config.h:src/config.in)
  42 AC_CONFIG_SRCDIR(src/lisp.h)
  43 AC_CONFIG_AUX_DIR(build-aux)
  44 dnl Fairly arbitrary, older versions might work too.
  45 AM_INIT_AUTOMAKE(1.11)
  46
  47 dnl Support for --program-prefix, --program-suffix and
  48 dnl --program-transform-name options
  49 AC_ARG_PROGRAM
  50
  51 dnl It is important that variables on the RHS not be expanded here,
  52 dnl hence the single quotes.  This is per the GNU coding standards, see
  53 dnl (autoconf) Installation Directory Variables
  54 dnl See also epaths.h below.
  55 lispdir='${datadir}/emacs/${version}/lisp'
  56 leimdir='${datadir}/emacs/${version}/leim'
  57 standardlisppath='${lispdir}:${leimdir}'
  58 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  59 '${datadir}/emacs/site-lisp'
  60 lisppath='${locallisppath}:${standardlisppath}'
  61 etcdir='${datadir}/emacs/${version}/etc'
  62 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  63 docdir='${datadir}/emacs/${version}/etc'
  64 gamedir='${localstatedir}/games/emacs'
  65
  66 dnl Special option to disable the most of other options.
  67 AC_ARG_WITH(all,
  68 [AS_HELP_STRING([--without-all],
  69                 [omit almost all features and build
  70                 small executable with minimal dependencies])],
  71   with_features=$withval,
  72   with_features=yes)
  73
  74 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  75 dnl Create a new --with option that defaults to being disabled.
  76 dnl NAME is the base name of the option.  The shell variable with_NAME
  77 dnl   will be set to either the user's value (if the option is
  78 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  79 dnl   option is not specified).  Note that the shell variable name is
  80 dnl   constructed as autoconf does, by replacing non-alphanumeric
  81 dnl   characters with "_".
  82 dnl HELP-STRING is the help text for the option.
  83 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  84   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  85     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  86 ])dnl
  87
  88 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  89 dnl Create a new --with option that defaults to $with_features.
  90 dnl NAME is the base name of the option.  The shell variable with_NAME
  91 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  92 dnl   'yes' (if the option is not specified).  Note that the shell
  93 dnl   variable name is constructed as autoconf does, by replacing
  94 dnl   non-alphanumeric characters with "_".
  95 dnl HELP-STRING is the help text for the option.
  96 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  97   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  98    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  99 ])dnl
 100
 101 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 102 if test "$with_pop" = yes; then
 103    AC_DEFINE(MAIL_USE_POP)
 104 fi
 105 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 106
 107 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 108 if test "$with_kerberos" != no; then
 109    AC_DEFINE(KERBEROS)
 110 fi
 111 AH_TEMPLATE(KERBEROS,
 112             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 113
 114 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 115 if test "${with_kerberos5}" != no; then
 116   if test "${with_kerberos}" = no; then
 117     with_kerberos=yes
 118     AC_DEFINE(KERBEROS)
 119   fi
 120   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 121 fi
 122
 123 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 124 dnl FIXME hesiod support may not be present, so it seems like an error
 125 dnl to define, or at least use, this unconditionally.
 126 if test "$with_hesiod" != no; then
 127   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 128 fi
 129
 130 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 131 if test "$with_mmdf" != no; then
 132    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 133 fi
 134
 135 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 136 if test "$with_mail_unlink" != no; then
 137    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 138 fi
 139
 140 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 141     [string giving default POP mail host])],
 142     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 143
 144 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 145
 146 dnl FIXME currently it is not the last.
 147 dnl This should be the last --with option, because --with-x is
 148 dnl added later on when we find the file name of X, and it's best to
 149 dnl keep them together visually.
 150 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 151  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 152 [         case "${withval}" in
 153             y | ye | yes )      val=gtk ;;
 154             n | no )            val=no  ;;
 155             l | lu | luc | luci | lucid )       val=lucid ;;
 156             a | at | ath | athe | athen | athena )      val=athena ;;
 157             m | mo | mot | moti | motif )       val=motif ;;
 158             g | gt | gtk  )     val=gtk ;;
 159             gtk2  )     val=gtk2 ;;
 160             gtk3  )     val=gtk3 ;;
 161             * )
 162 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 163 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 164 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 165 `athena' and `lucid' are synonyms.])
 166             ;;
 167           esac
 168           with_x_toolkit=$val
 169 ])
 170
 171 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 172 if test "$with_wide_int" = yes; then
 173   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 174 fi
 175
 176 dnl _ON results in a '--without' option in the --help output, so
 177 dnl the help text should refer to "don't compile", etc.
 178 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 179 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 180 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 181 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 182 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 183 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 184 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 185 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 186
 187 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 188 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 189 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 190
 191 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 192 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 193 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 194 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 195 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 196
 197 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 198 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 199 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 200 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 201 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 202 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 203
 204 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 205  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 206  [ case "${withval}" in
 207     y | ye | yes )      val=yes ;;
 208     n | no )            val=no  ;;
 209     g | gf | gfi | gfil | gfile )       val=gfile ;;
 210     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 211     w | w3 | w32 )      val=w32 ;;
 212     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 213 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 214 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 215 otherwise for the first of `gfile' or `inotify' that is usable.])
 216     ;;
 217    esac
 218    with_file_notification=$val
 219  ],
 220  [with_file_notification=$with_features])
 221
 222 ## For the times when you want to build Emacs but don't have
 223 ## a suitable makeinfo, and can live without the manuals.
 224 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 225 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 226
 227 ## Makefile.in needs the cache file name.
 228 AC_SUBST(cache_file)
 229
 230 ## This is an option because I do not know if all info/man support
 231 ## compressed files, nor how to test if they do so.
 232 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 233 if test $with_compress_info = yes; then
 234    GZIP_INFO=yes
 235 else
 236    GZIP_INFO=
 237 fi
 238 AC_SUBST(GZIP_INFO)
 239
 240 AC_ARG_WITH([pkg-config-prog],dnl
 241 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 242                   [file name of pkg-config for finding GTK and librsvg])])
 243 if test "X${with_pkg_config_prog}" != X; then
 244    if test "${with_pkg_config_prog}" != yes; then
 245       PKG_CONFIG="${with_pkg_config_prog}"
 246    fi
 247 fi
 248
 249 AC_ARG_WITH(gameuser,dnl
 250 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 251 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 252   && gameuser="${with_gameuser}"
 253 test "X$gameuser" = X && gameuser=games
 254
 255 AC_ARG_WITH([gnustep-conf],dnl
 256 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 257    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 258 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 259   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 260 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 261      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 262
 263 AC_ARG_ENABLE(ns-self-contained,
 264 [AS_HELP_STRING([--disable-ns-self-contained],
 265                 [disable self contained build under NeXTstep])],
 266    EN_NS_SELF_CONTAINED=$enableval,
 267    EN_NS_SELF_CONTAINED=yes)
 268
 269 AC_ARG_ENABLE(locallisppath,
 270 [AS_HELP_STRING([--enable-locallisppath=PATH],
 271                 [directories Emacs should search for lisp files specific
 272                  to this site])],
 273 if test "${enableval}" = "no"; then
 274   locallisppath=
 275 elif test "${enableval}" != "yes"; then
 276   locallisppath=${enableval}
 277 fi)
 278
 279 AC_ARG_ENABLE(checking,
 280 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 281                 [enable expensive run-time checks.  With LIST,
 282                  enable only specific categories of checks.
 283                  Categories are: all,yes,no.
 284                  Flags are: stringbytes, stringoverrun, stringfreelist,
 285                  xmallocoverrun, conslist, glyphs])],
 286 [ac_checking_flags="${enableval}"],[])
 287 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 288 for check in $ac_checking_flags
 289 do
 290         case $check in
 291         # these set all the flags to specific states
 292         yes)            ac_enable_checking=1 ;;
 293         no)             ac_enable_checking= ;
 294                         ac_gc_check_stringbytes= ;
 295                         ac_gc_check_string_overrun= ;
 296                         ac_gc_check_string_free_list= ;
 297                         ac_xmalloc_overrun= ;
 298                         ac_gc_check_cons_list= ;
 299                         ac_glyphs_debug= ;;
 300         all)            ac_enable_checking=1 ;
 301                         ac_gc_check_stringbytes=1 ;
 302                         ac_gc_check_string_overrun=1 ;
 303                         ac_gc_check_string_free_list=1 ;
 304                         ac_xmalloc_overrun=1 ;
 305                         ac_gc_check_cons_list=1 ;
 306                         ac_glyphs_debug=1 ;;
 307         # these enable particular checks
 308         stringbytes)    ac_gc_check_stringbytes=1 ;;
 309         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 310         stringfreelist) ac_gc_check_string_free_list=1 ;;
 311         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 312         conslist)       ac_gc_check_cons_list=1 ;;
 313         glyphs)         ac_glyphs_debug=1 ;;
 314         *)      AC_MSG_ERROR(unknown check category $check) ;;
 315         esac
 316 done
 317 IFS="$ac_save_IFS"
 318
 319 if test x$ac_enable_checking != x ; then
 320   AC_DEFINE(ENABLE_CHECKING, 1,
 321 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 322 fi
 323 if test x$ac_gc_check_stringbytes != x ; then
 324   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 325 [Define this temporarily to hunt a bug.  If defined, the size of
 326    strings is redundantly recorded in sdata structures so that it can
 327    be compared to the sizes recorded in Lisp strings.])
 328 fi
 329 if test x$ac_gc_check_string_overrun != x ; then
 330   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 331 [Define this to check for short string overrun.])
 332 fi
 333 if test x$ac_gc_check_string_free_list != x ; then
 334   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 335 [Define this to check the string free list.])
 336 fi
 337 if test x$ac_xmalloc_overrun != x ; then
 338   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 339 [Define this to check for malloc buffer overrun.])
 340 fi
 341 if test x$ac_gc_check_cons_list != x ; then
 342   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 343 [Define this to check for errors in cons list.])
 344 fi
 345 if test x$ac_glyphs_debug != x ; then
 346   AC_DEFINE(GLYPH_DEBUG, 1,
 347 [Define this to enable glyphs debugging code.])
 348 fi
 349
 350 AC_ARG_ENABLE(check-lisp-object-type,
 351 [AS_HELP_STRING([--enable-check-lisp-object-type],
 352                 [enable compile time checks for the Lisp_Object data type.
 353                 This is useful for development for catching certain types of bugs.])],
 354 if test "${enableval}" != "no"; then
 355    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 356    [Define this to enable compile time checks for the Lisp_Object data type.])
 357 fi)
 358
 359
 360 dnl The name of this option is unfortunate.  It predates, and has no
 361 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 362 dnl Actually, it stops it working.
 363 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 364 AC_ARG_ENABLE(profiling,
 365 [AS_HELP_STRING([--enable-profiling],
 366                 [build emacs with low-level, gprof profiling support.
 367                 Mainly useful for debugging Emacs itself.  May not work on
 368                 all platforms.  Stops profiler.el working.])],
 369 [ac_enable_profiling="${enableval}"],[])
 370 if test x$ac_enable_profiling != x ; then
 371    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 372 else
 373    PROFILING_CFLAGS=
 374 fi
 375 AC_SUBST(PROFILING_CFLAGS)
 376
 377 AC_ARG_ENABLE(autodepend,
 378 [AS_HELP_STRING([--enable-autodepend],
 379                 [automatically generate dependencies to .h-files.
 380                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 381                  found])],
 382 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 383
 384 AC_ARG_ENABLE(gtk-deprecation-warnings,
 385 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 386                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 387 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 388
 389 #### Make srcdir absolute, if it isn't already.  It's important to
 390 #### avoid running the file name through pwd unnecessarily, since pwd can
 391 #### give you automounter prefixes, which can go away.  We do all this
 392 #### so Emacs can find its files when run uninstalled.
 393 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 394 unset CDPATH
 395 case "${srcdir}" in
 396   [[\\/]]* | ?:[[\\/]]*) ;;
 397   . )
 398     ## We may be able to use the $PWD environment variable to make this
 399     ## absolute.  But sometimes PWD is inaccurate.
 400     ## Note: we used to use $PWD at the end instead of `pwd`,
 401     ## but that tested only for a well-formed and valid PWD,
 402     ## it did not object when PWD was well-formed and valid but just wrong.
 403     if test ".$PWD" != "." && test ".`(cd "$PWD" ; sh -c pwd)`" = ".`pwd`"  ;
 404     then
 405       srcdir="$PWD"
 406     else
 407       srcdir=`(cd "$srcdir"; pwd)`
 408     fi
 409   ;;
 410   *  ) srcdir=`(cd "$srcdir"; pwd)` ;;
 411 esac
 412
 413 ### Canonicalize the configuration name.
 414
 415 AC_CANONICAL_HOST
 416 canonical=$host
 417 configuration=${host_alias-${build_alias-$host}}
 418
 419 dnl This used to use changequote, but, apart from `changequote is evil'
 420 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 421 dnl the great gob of text.  Thus it's not processed for possible expansion.
 422 dnl Just make sure the brackets remain balanced.
 423 dnl
 424 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 425 dnl indicated by comments.
 426 dnl quotation begins
 427 [
 428
 429 ### If you add support for a new configuration, add code to this
 430 ### switch statement to recognize your configuration name and select
 431 ### the appropriate operating system file.
 432
 433 ### You would hope that you could choose an s/*.h
 434 ### file based on the operating system portion.  However, it turns out
 435 ### that each s/*.h file is pretty manufacturer-specific.
 436 ### So we basically have to have a special case for each
 437 ### configuration name.
 438 ###
 439 ### As far as handling version numbers on operating systems is
 440 ### concerned, make sure things will fail in a fixable way.  If
 441 ### /etc/MACHINES doesn't say anything about version numbers, be
 442 ### prepared to handle anything reasonably.  If version numbers
 443 ### matter, be sure /etc/MACHINES says something about it.
 444
 445 opsys='' unported=no
 446 case "${canonical}" in
 447
 448   ## GNU/Linux and similar ports
 449   *-*-linux* )
 450     opsys=gnu-linux
 451   ;;
 452
 453   ## FreeBSD ports
 454   *-*-freebsd* )
 455     opsys=freebsd
 456   ;;
 457
 458   ## DragonFly ports
 459   *-*-dragonfly* )
 460     opsys=dragonfly
 461   ;;
 462
 463   ## FreeBSD kernel + glibc based userland
 464   *-*-kfreebsd*gnu* )
 465     opsys=gnu-kfreebsd
 466   ;;
 467
 468   ## NetBSD ports
 469   *-*-netbsd* )
 470     opsys=netbsd
 471   ;;
 472
 473   ## OpenBSD ports
 474   *-*-openbsd* )
 475     opsys=openbsd
 476   ;;
 477
 478   ## Apple Darwin / Mac OS X
 479   *-apple-darwin* )
 480     case "${canonical}" in
 481       i[3456]86-* )  ;;
 482       powerpc-* )    ;;
 483       x86_64-* )     ;;
 484       * )            unported=yes ;;
 485     esac
 486     opsys=darwin
 487     ## Use fink packages if available.
 488     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 489 ##    if test -d /sw/include && test -d /sw/lib; then
 490 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 491 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 492 ##    fi
 493   ;;
 494
 495   ## Cygwin ports
 496   *-*-cygwin )
 497     opsys=cygwin
 498   ;;
 499
 500   ## HP 9000 series 700 and 800, running HP/UX
 501   hppa*-hp-hpux10.2* )
 502     opsys=hpux10-20
 503   ;;
 504   hppa*-hp-hpux1[1-9]* )
 505     opsys=hpux11
 506     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 507   ;;
 508
 509   ## IBM machines
 510   rs6000-ibm-aix4.[23]* )
 511     opsys=aix4-2
 512   ;;
 513   powerpc-ibm-aix4.[23]*  )
 514     opsys=aix4-2
 515   ;;
 516   rs6000-ibm-aix[56]* )
 517     opsys=aix4-2
 518   ;;
 519   powerpc-ibm-aix[56]*  )
 520     opsys=aix4-2
 521   ;;
 522
 523   ## Silicon Graphics machines
 524   ## Iris 4D
 525   mips-sgi-irix6.5 )
 526     opsys=irix6-5
 527     # Without defining _LANGUAGE_C, things get masked out in the headers
 528     # so that, for instance, grepping for `free' in stdlib.h fails and
 529     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 530     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 531   ;;
 532
 533   ## Suns
 534   *-sun-solaris* \
 535     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 536     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 537     case "${canonical}" in
 538       i[3456]86-*-* )   ;;
 539       amd64-*-*|x86_64-*-*) ;;
 540       sparc* )          ;;
 541       * )               unported=yes ;;
 542     esac
 543     case "${canonical}" in
 544       *-sunos5.6* | *-solaris2.6* )
 545                 opsys=sol2-6
 546                 RANLIB="ar -ts"
 547                 ;;
 548       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 549                 opsys=sol2-6
 550                 emacs_check_sunpro_c=yes
 551                 ;;
 552       *-sunos5* | *-solaris* )
 553                 opsys=sol2-10
 554                 emacs_check_sunpro_c=yes
 555                 ;;
 556     esac
 557     ## Watch out for a compiler that we know will not work.
 558     case "${canonical}" in
 559      *-solaris* | *-sunos5* )
 560                 if [ "x$CC" = x/usr/ucb/cc ]; then
 561                   ## /usr/ucb/cc doesn't work;
 562                   ## we should find some other compiler that does work.
 563                   unset CC
 564                 fi
 565                 ;;
 566       *) ;;
 567     esac
 568   ;;
 569
 570   ## Intel 386 machines where we don't care about the manufacturer.
 571   i[3456]86-*-* )
 572     case "${canonical}" in
 573       *-darwin* )               opsys=darwin ;;
 574       *-mingw32 )
 575                 opsys=mingw32
 576                 # MinGW overrides and adds some system headers in nt/inc.
 577                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 578                 ;;
 579       *-sysv4.2uw* )            opsys=unixware ;;
 580       *-sysv5uw* )              opsys=unixware ;;
 581       *-sysv5OpenUNIX* )        opsys=unixware ;;
 582       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 583     esac
 584   ;;
 585
 586   * )
 587     unported=yes
 588   ;;
 589 esac
 590
 591 ### If the code above didn't choose an operating system, just choose
 592 ### an operating system based on the configuration name.  You really
 593 ### only want to use this when you have no idea what the right
 594 ### operating system is; if you know what operating systems a machine
 595 ### runs, it's cleaner to make it explicit in the case statement
 596 ### above.
 597 if test x"${opsys}" = x; then
 598   case "${canonical}" in
 599     *-gnu* )                            opsys=gnu ;;
 600     * )
 601       unported=yes
 602     ;;
 603   esac
 604 fi
 605
 606 ]
 607 dnl quotation ends
 608
 609 if test $unported = yes; then
 610   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 611 Check `etc/MACHINES' for recognized configuration names.])
 612 fi
 613
 614
 615 #### Choose a compiler.
 616
 617 dnl Sets GCC=yes if using gcc.
 618 AC_PROG_CC
 619 AM_PROG_CC_C_O
 620
 621 if test x$GCC = xyes; then
 622   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 623 else
 624   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 625 fi
 626
 627 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 628 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 629 dnl that clash with MinGW.
 630 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 631
 632 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 633 # as we don't use them.
 634 AC_DEFUN([gl_FCNTL_O_FLAGS])
 635 # Avoid gnulib's threadlib module, as we do threads our own way.
 636 AC_DEFUN([gl_THREADLIB])
 637
 638 # Initialize gnulib right after choosing the compiler.
 639 dnl Amongst other things, this sets AR and ARFLAGS.
 640 gl_EARLY
 641
 642 if test "$ac_test_CFLAGS" != set; then
 643   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 644   # if -g3 works and the user does not specify CFLAGS.
 645   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 646   case $CFLAGS in
 647     '-g')
 648       emacs_g3_CFLAGS='-g3';;
 649     '-g -O2')
 650       emacs_g3_CFLAGS='-g3 -O2';;
 651     *)
 652       emacs_g3_CFLAGS='';;
 653   esac
 654   if test -n "$emacs_g3_CFLAGS"; then
 655     emacs_save_CFLAGS=$CFLAGS
 656     CFLAGS=$emacs_g3_CFLAGS
 657     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 658       [emacs_cv_prog_cc_g3],
 659       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 660          [emacs_cv_prog_cc_g3=yes],
 661          [emacs_cv_prog_cc_g3=no])])
 662     if test $emacs_cv_prog_cc_g3 != yes; then
 663       CFLAGS=$emacs_save_CFLAGS
 664     fi
 665     if test $opsys = mingw32; then
 666       CFLAGS="$CFLAGS -gdwarf-2"
 667     fi
 668   fi
 669
 670   case $CFLAGS in
 671     *-O*) ;;
 672     *)
 673       # No optimization flag was inferred for this non-GCC compiler.
 674       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 675       emacs_save_CFLAGS=$CFLAGS
 676       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 677       CFLAGS=${CFLAGS}-O
 678       AC_CACHE_CHECK([whether $CC accepts -O],
 679         [emacs_cv_prog_cc_o],
 680         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 681            [emacs_cv_prog_cc_o=yes],
 682            [emacs_cv_prog_cc_o=no])])
 683       if test $emacs_cv_prog_cc_o != yes; then
 684         CFLAGS=$emacs_save_CFLAGS
 685       fi ;;
 686   esac
 687 fi
 688
 689 AC_ARG_ENABLE([gcc-warnings],
 690   [AS_HELP_STRING([--enable-gcc-warnings],
 691                   [turn on lots of GCC warnings/errors. This is intended for
 692                    developers, and may generate false alarms when used
 693                    with older or non-GNU development tools.])],
 694   [case $enableval in
 695      yes|no) ;;
 696      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 697    esac
 698    gl_gcc_warnings=$enableval],
 699   [gl_gcc_warnings=no]
 700 )
 701
 702 AC_ARG_ENABLE(link-time-optimization,
 703 [AS_HELP_STRING([--enable-link-time-optimization],
 704                 [build emacs with link-time optimization.
 705                  This is supported only for GCC since 4.5.0.])],
 706 if test "${enableval}" != "no"; then
 707    AC_MSG_CHECKING([whether link-time optimization is supported])
 708    ac_lto_supported=no
 709    if test x$GCC = xyes; then
 710       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 711       if test x$CPUS != x; then
 712          LTO="-flto=$CPUS"
 713       else
 714          LTO="-flto"
 715       fi
 716       old_CFLAGS=$CFLAGS
 717       CFLAGS="$CFLAGS $LTO"
 718       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 719         [ac_lto_supported=yes], [ac_lto_supported=no])
 720       CFLAGS="$old_CFLAGS"
 721    fi
 722    AC_MSG_RESULT([$ac_lto_supported])
 723    if test "$ac_lto_supported" = "yes"; then
 724       CFLAGS="$CFLAGS $LTO"
 725    fi
 726 fi)
 727
 728 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 729 # ------------------------------------------------
 730 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 731 # Otherwise, run RUN-IF-NOT-FOUND.
 732 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 733   [AC_PREPROC_IFELSE(
 734     [AC_LANG_PROGRAM(
 735       [[
 736 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 737 /* ok */
 738 #else
 739 # error "your version of gcc is older than $1.$2"
 740 #endif
 741       ]]),
 742     ], [$3], [$4])
 743   ]
 744 )
 745
 746 # When compiling with GCC, prefer -isystem to -I when including system
 747 # include files, to avoid generating useless diagnostics for the files.
 748 if test "$gl_gcc_warnings" != yes; then
 749   isystem='-I'
 750 else
 751   isystem='-isystem '
 752
 753   # This, $nw, is the list of warnings we disable.
 754   nw=
 755
 756   case $with_x_toolkit in
 757     lucid | athena | motif)
 758        # Old toolkits mishandle 'const'.
 759        nw="$nw -Wwrite-strings"
 760        ;;
 761     *)
 762        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 763        ;;
 764   esac
 765   AC_SUBST([WERROR_CFLAGS])
 766
 767   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 768   nw="$nw -Woverlength-strings"     # Not a problem these days
 769   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 770   nw="$nw -Wformat-nonliteral"      # we do this a lot
 771   nw="$nw -Wvla"                    # warnings in gettext.h
 772   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 773   nw="$nw -Wswitch-default"         # Too many warnings for now
 774   nw="$nw -Winline"                 # OK to ignore 'inline'
 775   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 776   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 777                                     # signed overflow has undefined behavior
 778   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 779   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 780   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 781
 782   # Emacs doesn't care about shadowing; see
 783   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 784   nw="$nw -Wshadow"
 785
 786   # Emacs's use of alloca inhibits protecting the stack.
 787   nw="$nw -Wstack-protector"
 788
 789   # The following line should be removable at some point.
 790   nw="$nw -Wsuggest-attribute=pure"
 791
 792   # clang is unduly picky about some things.
 793   AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 794     [AC_COMPILE_IFELSE(
 795        [AC_LANG_PROGRAM([[
 796             #ifndef __clang__
 797               #error "not clang"
 798             #endif
 799           ]])],
 800        [emacs_cv_clang=yes],
 801        [emacs_cv_clang=no])])
 802   if test $emacs_cv_clang = yes; then
 803     nw="$nw -Wcast-align"
 804   fi
 805
 806   gl_MANYWARN_ALL_GCC([ws])
 807   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 808   for w in $ws; do
 809     gl_WARN_ADD([$w])
 810   done
 811   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 812   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 813   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 814   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 815   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 816   gl_WARN_ADD([-Wno-format-nonliteral])
 817
 818   # In spite of excluding -Wlogical-op above, it is enabled, as of
 819   # gcc 4.5.0 20090517.
 820   gl_WARN_ADD([-Wno-logical-op])
 821
 822   # More things that clang is unduly picky about.
 823   if test $emacs_cv_clang = yes; then
 824     gl_WARN_ADD([-Wno-format-extra-args])
 825     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 826     gl_WARN_ADD([-Wno-unused-command-line-argument])
 827     gl_WARN_ADD([-Wno-unused-value])
 828   fi
 829
 830   gl_WARN_ADD([-fdiagnostics-show-option])
 831   gl_WARN_ADD([-funit-at-a-time])
 832
 833   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 834   AH_VERBATIM([FORTIFY_SOURCE],
 835   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 836       without upsetting glibc 2.15+. */
 837    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 838    # define _FORTIFY_SOURCE 2
 839    #endif
 840   ])
 841   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 842
 843   # We use a slightly smaller set of warning options for lib/.
 844   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 845   nw=
 846   nw="$nw -Wunused-macros"
 847
 848   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 849   AC_SUBST([GNULIB_WARN_CFLAGS])
 850 fi
 851
 852
 853
 854 dnl Some other nice autoconf tests.
 855 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 856 dnl AC_PROG_INSTALL
 857 dnl AC_PROG_MKDIR_P
 858 dnl if test "x$RANLIB" = x; then
 859 dnl   AC_PROG_RANLIB
 860 dnl fi
 861
 862
 863 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 864 dnl can be made to directories.  This is not relevant for our usage, and
 865 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 866 dnl hosted on AFS, both examples where simple links work, but links to
 867 dnl directories fail.  We use a cut-down version instead.
 868 dnl AC_PROG_LN_S
 869
 870 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 871 rm -f conf$$ conf$$.file
 872
 873 LN_S_FILEONLY='cp -p'
 874
 875 if (echo >conf$$.file) 2>/dev/null; then
 876   if ln -s conf$$.file conf$$ 2>/dev/null; then
 877     LN_S_FILEONLY='ln -s'
 878   elif ln conf$$.file conf$$ 2>/dev/null; then
 879     LN_S_FILEONLY=ln
 880   fi
 881 fi
 882
 883 rm -f conf$$ conf$$.file
 884
 885 if test "$LN_S_FILEONLY" = "ln -s"; then
 886    AC_MSG_RESULT([yes])
 887 else
 888    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 889 fi
 890
 891 AC_SUBST(LN_S_FILEONLY)
 892
 893
 894 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 895 dnl doesn't support links to directories, as in "ln file dir".  But that
 896 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 897 dnl executables at "make install" time.
 898 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 899 dnl for more details.
 900 if test "$opsys" = "mingw32"; then
 901   LN_S="ln"
 902 fi
 903
 904 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 905   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 906 dnl Don't use GZIP, which is used by gzip for additional parameters.
 907 AC_PATH_PROG(GZIP_PROG, gzip)
 908
 909 if test $opsys = gnu-linux; then
 910   AC_PATH_PROG(PAXCTL, paxctl,,
 911     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 912   if test "X$PAXCTL" != X; then
 913     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 914     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 915       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 916       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 917   fi
 918 fi
 919
 920 ## Need makeinfo >= 4.7 (?) to build the manuals.
 921 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 922 dnl By this stage, configure has already checked for egrep and set EGREP,
 923 dnl or exited with an error if no egrep was found.
 924 if test "$MAKEINFO" != "no"; then
 925   case `
 926     $MAKEINFO --version 2> /dev/null |
 927     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
 928   ` in
 929     '') MAKEINFO=no;;
 930   esac
 931 fi
 932
 933 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 934 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 935 ## therefore in the category of "special tools" not normally required, which
 936 ## configure does not have to check for (eg autoconf itself).
 937 ## In a Bazaar checkout on the other hand, the manuals are not included.
 938 ## So makeinfo is a requirement to build from Bazaar, and configure
 939 ## should test for it as it does for any other build requirement.
 940 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 941 ## with pre-built manuals, from a Bazaar checkout.
 942 HAVE_MAKEINFO=yes
 943
 944 if test "$MAKEINFO" = "no"; then
 945   MAKEINFO=makeinfo
 946   if test "x${with_makeinfo}" = "xno"; then
 947     HAVE_MAKEINFO=no
 948   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
 949     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 950 source tree does not seem to have pre-built manuals in the `info' directory.
 951 Either install a suitable version of makeinfo, or re-run configure
 952 with the `--without-makeinfo' option to build without the manuals.] )
 953   fi
 954 fi
 955 AC_SUBST(HAVE_MAKEINFO)
 956
 957 dnl Just so that there is only a single place we need to edit.
 958 INFO_EXT=.info
 959 INFO_OPTS=--no-split
 960 AC_SUBST(INFO_EXT)
 961 AC_SUBST(INFO_OPTS)
 962
 963 dnl Add our options to ac_link now, after it is set up.
 964
 965 if test x$GCC = xyes; then
 966   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 967     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 968 else
 969   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 970     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 971 fi
 972
 973 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 974 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 975 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 976 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 977 dnl if not built to support GNU ld.
 978
 979 late_LDFLAGS=$LDFLAGS
 980 if test x$GCC = xyes; then
 981   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 982 else
 983   LDFLAGS="$LDFLAGS -znocombreloc"
 984 fi
 985
 986 AC_MSG_CHECKING([for -znocombreloc])
 987 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 988   [AC_MSG_RESULT(yes)],
 989   LDFLAGS=$late_LDFLAGS
 990   [AC_MSG_RESULT(no)])
 991
 992
 993 dnl The function dump-emacs will not be defined and temacs will do
 994 dnl (load "loadup") automatically unless told otherwise.
 995 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 996 case "$opsys" in
 997   your-opsys-here) CANNOT_DUMP=yes ;;
 998 esac
 999
1000 test "$CANNOT_DUMP" = "yes" && \
1001   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1002
1003 AC_SUBST(CANNOT_DUMP)
1004
1005
1006 UNEXEC_OBJ=unexelf.o
1007 case "$opsys" in
1008   # MSDOS uses unexcoff.o
1009   aix4-2)
1010    UNEXEC_OBJ=unexaix.o
1011    ;;
1012   cygwin)
1013    UNEXEC_OBJ=unexcw.o
1014    ;;
1015   darwin)
1016    UNEXEC_OBJ=unexmacosx.o
1017    ;;
1018   hpux10-20 | hpux11)
1019    UNEXEC_OBJ=unexhp9k800.o
1020    ;;
1021   mingw32)
1022    UNEXEC_OBJ=unexw32.o
1023    ;;
1024   sol2-10)
1025    # Use the Solaris dldump() function, called from unexsol.c, to dump
1026    # emacs, instead of the generic ELF dump code found in unexelf.c.
1027    # The resulting binary has a complete symbol table, and is better
1028    # for debugging and other observability tools (debuggers, pstack, etc).
1029    #
1030    # If you encounter a problem using dldump(), please consider sending
1031    # a message to the OpenSolaris tools-linking mailing list:
1032    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1033    #
1034    # It is likely that dldump() works with older Solaris too, but this has
1035    # not been tested, so for now this change is for Solaris 10 or newer.
1036    UNEXEC_OBJ=unexsol.o
1037    ;;
1038 esac
1039
1040 LD_SWITCH_SYSTEM=
1041 case "$opsys" in
1042   freebsd|dragonfly)
1043    ## Let `ld' find image libs and similar things in /usr/local/lib.
1044    ## The system compiler, GCC, has apparently been modified to not
1045    ## look there, contrary to what a stock GCC would do.
1046 ### It's not our place to do this.  See bug#10313#17.
1047 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1048       :
1049    ;;
1050
1051   gnu-linux)
1052    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1053    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1054    ;;
1055
1056   netbsd)
1057 ### It's not our place to do this.  See bug#10313#17.
1058 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1059       :
1060    ;;
1061
1062   openbsd)
1063    ## Han Boetes <han@boetes.org> says this is necessary,
1064    ## otherwise Emacs dumps core on elf systems.
1065    LD_SWITCH_SYSTEM="-Z"
1066    ;;
1067 esac
1068 AC_SUBST(LD_SWITCH_SYSTEM)
1069
1070 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1071
1072 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1073 ## which has not been defined yet.  When this was handled with cpp,
1074 ## it was expanded to null when configure sourced the s/*.h file.
1075 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1076 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1077 ## (or somesuch), but because it is supposed to go at the _front_
1078 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1079 ## Compare with the gnu-linux case below, which added to the end
1080 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1081 ## LD_SWITCH_SYSTEM_TEMACS.
1082 case "$opsys" in
1083   netbsd|openbsd)
1084    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1085 esac
1086
1087
1088 C_SWITCH_MACHINE=
1089 case $canonical in
1090  alpha*)
1091   AC_CHECK_DECL([__ELF__])
1092   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1093     ## With ELF, make sure that all common symbols get allocated to in the
1094     ## data section.  Otherwise, the dump of temacs may miss variables in
1095     ## the shared library that have been initialized.  For example, with
1096     ## GNU libc, __malloc_initialized would normally be resolved to the
1097     ## shared library's .bss section, which is fatal.
1098     if test "x$GCC" = "xyes"; then
1099       C_SWITCH_MACHINE="-fno-common"
1100     else
1101       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1102     fi
1103   else
1104     UNEXEC_OBJ=unexalpha.o
1105   fi
1106   ;;
1107 esac
1108 AC_SUBST(C_SWITCH_MACHINE)
1109
1110 AC_SUBST(UNEXEC_OBJ)
1111
1112 C_SWITCH_SYSTEM=
1113 ## Some programs in src produce warnings saying certain subprograms
1114 ## are too complex and need a MAXMEM value greater than 2000 for
1115 ## additional optimization.  --nils@exp-math.uni-essen.de
1116 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1117   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1118 test "$opsys" = "mingw32" && C_SWITCH_SYSTEM="-mtune=pentium4"
1119 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1120 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1121 AC_SUBST(C_SWITCH_SYSTEM)
1122
1123
1124 LIBS_SYSTEM=
1125 case "$opsys" in
1126   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1127   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1128
1129   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1130
1131   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1132
1133   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1134
1135   ## Motif needs -lgen.
1136   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1137 esac
1138
1139 AC_SUBST(LIBS_SYSTEM)
1140
1141 ### Make sure subsequent tests use flags consistent with the build flags.
1142
1143 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1144   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1145 else
1146   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1147 fi
1148
1149 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1150 AC_DEFUN([AC_TYPE_SIZE_T])
1151 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1152 AC_DEFUN([AC_TYPE_UID_T])
1153
1154
1155 LIB_MATH=-lm
1156 dnl Current possibilities handled by sed (aix4-2 -> aix,
1157 dnl gnu-linux -> gnu/linux, etc.):
1158 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1159 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1160 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1161
1162 case $opsys in
1163   cygwin )
1164     LIB_MATH=
1165     ;;
1166   darwin )
1167     ## Adding -lm confuses the dynamic linker, so omit it.
1168     LIB_MATH=
1169     ;;
1170   freebsd | dragonfly )
1171     SYSTEM_TYPE=berkeley-unix
1172     ;;
1173   gnu-linux | gnu-kfreebsd )
1174     ;;
1175   hpux10-20 | hpux11 )
1176     ;;
1177   mingw32 )
1178     LIB_MATH=
1179     SYSTEM_TYPE=windows-nt
1180     ;;
1181   dnl NB this may be adjusted below.
1182   netbsd | openbsd )
1183     SYSTEM_TYPE=berkeley-unix
1184     ;;
1185
1186   sol2* | unixware )
1187     SYSTEM_TYPE=usg-unix-v
1188     ;;
1189
1190 esac
1191
1192 AC_SUBST(LIB_MATH)
1193 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1194   [The type of system you are compiling for; sets `system-type'.])
1195
1196
1197 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1198 pre_PKG_CONFIG_LIBS=$LIBS
1199
1200 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1201
1202 dnl This function definition taken from Gnome 2.0
1203 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1204 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1205 dnl also defines GSTUFF_PKG_ERRORS on error
1206 AC_DEFUN([PKG_CHECK_MODULES], [
1207   succeeded=no
1208
1209   if test "$PKG_CONFIG" = "no" ; then
1210      ifelse([$4], , [AC_MSG_ERROR([
1211       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1212   else
1213      PKG_CONFIG_MIN_VERSION=0.9.0
1214      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1215         AC_MSG_CHECKING(for $2)
1216
1217         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1218            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1219            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1220             edit_cflags="
1221               s,///*,/,g
1222               s/^/ /
1223               s/ -I/ $isystem/g
1224               s/^ //
1225             "
1226             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1227             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1228             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1229             succeeded=yes
1230         else
1231             AC_MSG_RESULT(no)
1232             $1_CFLAGS=""
1233             $1_LIBS=""
1234             ## If we have a custom action on failure, don't print errors, but
1235             ## do set a variable so people can do so.  Do it in a subshell
1236             ## to capture any diagnostics in invoking pkg-config.
1237             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1238             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1239         fi
1240
1241         AC_SUBST($1_CFLAGS)
1242         AC_SUBST($1_LIBS)
1243      else
1244         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1245         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1246      fi
1247   fi
1248
1249   if test $succeeded = yes; then
1250      ifelse([$3], , :, [$3])
1251   else
1252      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1253   fi
1254 ])
1255
1256 if test "${with_sound}" != "no"; then
1257   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1258   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1259     have_sound_header=yes, [], [
1260     #ifdef __MINGW32__
1261     #define WIN32_LEAN_AND_MEAN
1262     #include <windows.h>
1263     #endif
1264     ])
1265   # Emulation library used on NetBSD.
1266   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1267   AC_SUBST(LIBSOUND)
1268
1269   ALSA_REQUIRED=1.0.0
1270   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1271   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1272   if test $HAVE_ALSA = yes; then
1273     SAVE_CFLAGS="$CFLAGS"
1274     SAVE_LIBS="$LIBS"
1275     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1276     LIBS="$ALSA_LIBS $LIBS"
1277     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1278                     emacs_alsa_normal=yes,
1279                     emacs_alsa_normal=no)
1280     if test "$emacs_alsa_normal" != yes; then
1281       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1282                      [[snd_lib_error_set_handler (0);]])],
1283                      emacs_alsa_subdir=yes,
1284                      emacs_alsa_subdir=no)
1285       if test "$emacs_alsa_subdir" != yes; then
1286         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1287       fi
1288       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1289     fi
1290
1291     CFLAGS="$SAVE_CFLAGS"
1292     LIBS="$SAVE_LIBS"
1293     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1294     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1295     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1296   fi
1297
1298   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1299   dnl compiles only on the specified platforms.  For others, it
1300   dnl probably doesn't make sense to try.
1301   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1302      case "$opsys" in
1303        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1304        gnu-linux|freebsd|netbsd|mingw32)
1305          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1306          ;;
1307      esac
1308   fi
1309
1310   AC_SUBST(CFLAGS_SOUND)
1311 fi
1312
1313 dnl checks for header files
1314 AC_CHECK_HEADERS_ONCE(
1315   sys/systeminfo.h
1316   coff.h pty.h
1317   sys/resource.h
1318   sys/utsname.h pwd.h utmp.h util.h)
1319
1320 AC_MSG_CHECKING(if personality LINUX32 can be set)
1321 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1322                emacs_cv_personality_linux32=yes,
1323                emacs_cv_personality_linux32=no)
1324 AC_MSG_RESULT($emacs_cv_personality_linux32)
1325
1326 if test $emacs_cv_personality_linux32 = yes; then
1327   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1328             [Define to 1 if personality LINUX32 can be set.])
1329 fi
1330
1331 dnl On Solaris 8 there's a compilation warning for term.h because
1332 dnl it doesn't define `bool'.
1333 AC_CHECK_HEADERS(term.h, , , -)
1334 AC_HEADER_TIME
1335 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1336                                       ]])
1337 if test $ac_cv_have_decl_sys_siglist != yes; then
1338   # For Tru64, at least:
1339   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1340                                           ]])
1341 fi
1342 AC_HEADER_SYS_WAIT
1343
1344 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1345 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1346 #if HAVE_SYS_SOCKET_H
1347 #include <sys/socket.h>
1348 #endif])
1349 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1350 #if HAVE_SYS_SOCKET_H
1351 #include <sys/socket.h>
1352 #endif])
1353 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1354 #if HAVE_SYS_SOCKET_H
1355 #include <sys/socket.h>
1356 #endif])
1357
1358 dnl checks for structure members
1359 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1360                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1361                   struct ifreq.ifr_addr,
1362                   struct ifreq.ifr_addr.sa_len], , ,
1363                  [AC_INCLUDES_DEFAULT
1364 #if HAVE_SYS_SOCKET_H
1365 #include <sys/socket.h>
1366 #endif
1367 #if HAVE_NET_IF_H
1368 #include <net/if.h>
1369 #endif])
1370
1371 dnl Check for endianness.
1372 dnl AC_C_BIGENDIAN is done by gnulib.
1373
1374 dnl check for Make feature
1375 dnl AC_PROG_MAKE_SET is done by Automake.
1376
1377 DEPFLAGS=
1378 MKDEPDIR=":"
1379 deps_frag=deps.mk
1380 dnl check for GNU Make if we have GCC and autodepend is on.
1381 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1382    AC_MSG_CHECKING([whether we are using GNU Make])
1383    HAVE_GNU_MAKE=no
1384    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1385    if test "x$testval" != x; then
1386       HAVE_GNU_MAKE=yes
1387    else
1388       ac_enable_autodepend=no
1389    fi
1390    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1391    if test $HAVE_GNU_MAKE = yes; then
1392       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1393       SAVE_CFLAGS="$CFLAGS"
1394       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1395       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1396       CFLAGS="$SAVE_CFLAGS"
1397       test -f deps.d || ac_enable_autodepend=no
1398       rm -rf deps.d
1399       AC_MSG_RESULT([$ac_enable_autodepend])
1400    fi
1401    if test $ac_enable_autodepend = yes; then
1402       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1403       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1404       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1405       deps_frag=autodeps.mk
1406    fi
1407 fi
1408 deps_frag=$srcdir/src/$deps_frag
1409 AC_SUBST(MKDEPDIR)
1410 AC_SUBST(DEPFLAGS)
1411 AC_SUBST_FILE(deps_frag)
1412
1413
1414 lisp_frag=$srcdir/src/lisp.mk
1415 AC_SUBST_FILE(lisp_frag)
1416
1417
1418 dnl checks for operating system services
1419 AC_SYS_LONG_FILE_NAMES
1420
1421 #### Choose a window system.
1422
1423 ## We leave window_system equal to none if
1424 ## we end up building without one.  Any new window system should
1425 ## set window_system to an appropriate value and add objects to
1426 ## window-system-specific substs.
1427
1428 window_system=none
1429 AC_PATH_X
1430 if test "$no_x" != yes; then
1431   window_system=x11
1432 fi
1433
1434 LD_SWITCH_X_SITE_RPATH=
1435 if test "${x_libraries}" != NONE; then
1436   if test -n "${x_libraries}"; then
1437     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1438     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1439   fi
1440   x_default_search_path=""
1441   x_search_path=${x_libraries}
1442   if test -z "${x_search_path}"; then
1443     x_search_path=/usr/lib
1444   fi
1445   for x_library in `echo ${x_search_path}: | \
1446                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1447     x_search_path="\
1448 ${x_library}/X11/%L/%T/%N%C%S:\
1449 ${x_library}/X11/%l/%T/%N%C%S:\
1450 ${x_library}/X11/%T/%N%C%S:\
1451 ${x_library}/X11/%L/%T/%N%S:\
1452 ${x_library}/X11/%l/%T/%N%S:\
1453 ${x_library}/X11/%T/%N%S"
1454     if test x"${x_default_search_path}" = x; then
1455       x_default_search_path=${x_search_path}
1456     else
1457       x_default_search_path="${x_search_path}:${x_default_search_path}"
1458     fi
1459   done
1460 fi
1461 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1462
1463 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1464   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1465 fi
1466
1467 if test x"${x_includes}" = x; then
1468   bitmapdir=/usr/include/X11/bitmaps
1469 else
1470   # accumulate include directories that have X11 bitmap subdirectories
1471   bmd_acc="dummyval"
1472   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1473     if test -d "${bmd}/X11/bitmaps"; then
1474       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1475     fi
1476     if test -d "${bmd}/bitmaps"; then
1477       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1478     fi
1479   done
1480   if test ${bmd_acc} != "dummyval"; then
1481     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1482   fi
1483 fi
1484
1485 HAVE_NS=no
1486 NS_IMPL_COCOA=no
1487 NS_IMPL_GNUSTEP=no
1488 tmp_CPPFLAGS="$CPPFLAGS"
1489 tmp_CFLAGS="$CFLAGS"
1490 CPPFLAGS="$CPPFLAGS -x objective-c"
1491 CFLAGS="$CFLAGS -x objective-c"
1492 GNU_OBJC_CFLAGS=
1493 LIBS_GNUSTEP=
1494 if test "${with_ns}" != no; then
1495   if test "${opsys}" = darwin; then
1496      NS_IMPL_COCOA=yes
1497      ns_appdir=`pwd`/nextstep/Emacs.app
1498      ns_appbindir=${ns_appdir}/Contents/MacOS
1499      ns_appresdir=${ns_appdir}/Contents/Resources
1500      ns_appsrc=Cocoa/Emacs.base
1501   elif test -f $GNUSTEP_CONFIG_FILE; then
1502      NS_IMPL_GNUSTEP=yes
1503      ns_appdir=`pwd`/nextstep/Emacs.app
1504      ns_appbindir=${ns_appdir}
1505      ns_appresdir=${ns_appdir}/Resources
1506      ns_appsrc=GNUstep/Emacs.base
1507      dnl FIXME sourcing this several times in subshells seems inefficient.
1508      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1509      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1510      dnl I seemed to need these as well with GNUstep-startup 0.25.
1511      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1512      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1513      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1514        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1515      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1516        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1517      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1518      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1519      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1520      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1521      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1522      dnl If they had chosen to either define it or not, we could have
1523      dnl just used AC_CHECK_DECL here.
1524      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1525        emacs_cv_objc_exceptions,
1526 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1527 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1528 1;
1529 #else
1530 fail;
1531 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1532      if test $emacs_cv_objc_exceptions = yes; then
1533        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1534        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1535          [Define if GNUstep uses ObjC exceptions.])
1536        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1537      fi
1538   fi
1539
1540   dnl This is only used while we test the NS headers, it gets reset below.
1541   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1542
1543   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1544                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1545   files are missing or cannot be compiled.])])
1546
1547   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1548                                      [
1549 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1550 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1551  ; /* OK */
1552 #else
1553 #error "OSX 10.4 or newer required"
1554 #endif
1555 #endif
1556                     ])],
1557                     ns_osx_have_104=yes,
1558                     ns_osx_have_104=no)
1559   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1560                                      [NSInteger i;])],
1561                     ns_have_nsinteger=yes,
1562                     ns_have_nsinteger=no)
1563   if test $ns_osx_have_104 = no; then
1564      AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1565   fi
1566   if test $ns_have_nsinteger = yes; then
1567     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1568   fi
1569 fi
1570
1571 AC_SUBST(LIBS_GNUSTEP)
1572
1573 INSTALL_ARCH_INDEP_EXTRA=install-etc
1574 ns_self_contained=no
1575 NS_OBJ=
1576 NS_OBJC_OBJ=
1577 if test "${HAVE_NS}" = yes; then
1578   if test "$with_toolkit_scroll_bars" = "no"; then
1579     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1580   fi
1581
1582   window_system=nextstep
1583   # set up packaging dirs
1584   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1585      ns_self_contained=yes
1586      prefix=${ns_appresdir}
1587      exec_prefix=${ns_appbindir}
1588      dnl This one isn't really used, only archlibdir is.
1589      libexecdir="\${ns_appbindir}/libexec"
1590      archlibdir="\${ns_appbindir}/libexec"
1591      docdir="\${ns_appresdir}/etc"
1592      etcdir="\${ns_appresdir}/etc"
1593      dnl FIXME maybe set datarootdir instead.
1594      dnl That would also get applications, icons, man.
1595      infodir="\${ns_appresdir}/info"
1596      mandir="\${ns_appresdir}/man"
1597      lispdir="\${ns_appresdir}/lisp"
1598      leimdir="\${ns_appresdir}/leim"
1599      INSTALL_ARCH_INDEP_EXTRA=
1600   fi
1601   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1602 fi
1603 CFLAGS="$tmp_CFLAGS"
1604 CPPFLAGS="$tmp_CPPFLAGS"
1605 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1606 AC_SUBST(ns_self_contained)
1607 AC_SUBST(NS_OBJ)
1608 AC_SUBST(NS_OBJC_OBJ)
1609
1610 HAVE_W32=no
1611 W32_OBJ=
1612 W32_LIBS=
1613 EMACSRES=
1614 CLIENTRES=
1615 CLIENTW=
1616 W32_RES_LINK=
1617 EMACS_MANIFEST=
1618 if test "${with_w32}" != no; then
1619   case "${opsys}" in
1620     cygwin)
1621       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1622              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1623                    cannot be found.])])
1624     ;;
1625     mingw32)
1626     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1627     ;;
1628     *)
1629       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1630     ;;
1631   esac
1632 fi
1633
1634 if test "${opsys}" = "mingw32"; then
1635   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1636   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1637      #include <windows.h>
1638      #include <usp10.h>]],
1639    [[PIMAGE_NT_HEADERS pHeader;
1640      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1641    [emacs_cv_w32api=yes
1642     HAVE_W32=yes],
1643    emacs_cv_w32api=no)
1644   AC_MSG_RESULT($emacs_cv_w32api)
1645   if test "${emacs_cv_w32api}" = "no"; then
1646     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1647   fi
1648 fi
1649
1650 FIRSTFILE_OBJ=
1651 NTDIR=
1652 LIBS_ECLIENT=
1653 LIB_WSOCK32=
1654 NTLIB=
1655 CM_OBJ="cm.o"
1656 XARGS_LIMIT=
1657 if test "${HAVE_W32}" = "yes"; then
1658   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1659   AC_CHECK_TOOL(WINDRES, [windres],
1660                 [AC_MSG_ERROR([No resource compiler found.])])
1661   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1662   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1663   EMACSRES="emacs.res"
1664   case "$canonical" in
1665     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1666     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1667   esac
1668   if test "${opsys}" = "cygwin"; then
1669     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1670     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1671     # Tell the linker that emacs.res is an object (which we compile from
1672     # the rc file), not a linker script.
1673     W32_RES_LINK="-Wl,emacs.res"
1674   else
1675     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1676     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1677     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1678     W32_RES_LINK="\$(EMACSRES)"
1679     CLIENTRES="emacsclient.res"
1680     CLIENTW="emacsclientw\$(EXEEXT)"
1681     FIRSTFILE_OBJ=firstfile.o
1682     NTDIR=nt
1683     CM_OBJ=
1684     LIBS_ECLIENT="-lcomctl32"
1685     LIB_WSOCK32="-lwsock32"
1686     NTLIB="ntlib.$ac_objext"
1687     XARGS_LIMIT="-s 10000"
1688   fi
1689 fi
1690 AC_SUBST(W32_OBJ)
1691 AC_SUBST(W32_LIBS)
1692 AC_SUBST(EMACSRES)
1693 AC_SUBST(EMACS_MANIFEST)
1694 AC_SUBST(CLIENTRES)
1695 AC_SUBST(CLIENTW)
1696 AC_SUBST(W32_RES_LINK)
1697 AC_SUBST(FIRSTFILE_OBJ)
1698 AC_SUBST(NTDIR)
1699 AC_SUBST(CM_OBJ)
1700 AC_SUBST(LIBS_ECLIENT)
1701 AC_SUBST(LIB_WSOCK32)
1702 AC_SUBST(NTLIB)
1703 AC_SUBST(XARGS_LIMIT)
1704
1705 if test "${HAVE_W32}" = "yes"; then
1706   window_system=w32
1707   with_xft=no
1708 fi
1709
1710 ## $window_system is now set to the window system we will
1711 ## ultimately use.
1712
1713 term_header=
1714 HAVE_X_WINDOWS=no
1715 HAVE_X11=no
1716 USE_X_TOOLKIT=none
1717
1718 case "${window_system}" in
1719   x11 )
1720     HAVE_X_WINDOWS=yes
1721     HAVE_X11=yes
1722     term_header=xterm.h
1723     case "${with_x_toolkit}" in
1724       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1725       motif ) USE_X_TOOLKIT=MOTIF ;;
1726       gtk ) with_gtk=yes
1727             term_header=gtkutil.h
1728 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1729 dnl USE_X_TOOLKIT is set.
1730             USE_X_TOOLKIT=none ;;
1731       gtk2 ) with_gtk2=yes
1732              term_header=gtkutil.h
1733              USE_X_TOOLKIT=none ;;
1734       gtk3 ) with_gtk3=yes
1735              term_header=gtkutil.h
1736              USE_X_TOOLKIT=none ;;
1737       no ) USE_X_TOOLKIT=none ;;
1738 dnl If user did not say whether to use a toolkit, make this decision later:
1739 dnl use the toolkit if we have gtk, or X11R5 or newer.
1740       * ) USE_X_TOOLKIT=maybe ;;
1741     esac
1742   ;;
1743   nextstep )
1744     term_header=nsterm.h
1745   ;;
1746   w32 )
1747     term_header=w32term.h
1748   ;;
1749 esac
1750
1751 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1752    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1753    if test "$HAVE_XSERVER" = true ||
1754       test -n "$DISPLAY" ||
1755       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1756         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1757 were found.  You should install the relevant development files for X
1758 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1759 sure you have development files for image handling, i.e.
1760 tiff, gif, jpeg, png and xpm.
1761 If you are sure you want Emacs compiled without X window support, pass
1762   --without-x
1763 to configure.])
1764    fi
1765 fi
1766
1767 ### If we're using X11, we should use the X menu package.
1768 HAVE_MENUS=no
1769 case ${HAVE_X11} in
1770   yes ) HAVE_MENUS=yes ;;
1771 esac
1772
1773 # Does the opsystem file prohibit the use of the GNU malloc?
1774 # Assume not, until told otherwise.
1775 GNU_MALLOC=yes
1776
1777 AC_CACHE_CHECK(
1778   [whether malloc is Doug Lea style],
1779   [emacs_cv_var_doug_lea_malloc],
1780   [AC_LINK_IFELSE(
1781      [AC_LANG_PROGRAM(
1782         [[#include <malloc.h>
1783           static void hook (void) {}]],
1784         [[malloc_set_state (malloc_get_state ());
1785           __after_morecore_hook = hook;
1786           __malloc_initialize_hook = hook;]])],
1787      [emacs_cv_var_doug_lea_malloc=yes],
1788      [emacs_cv_var_doug_lea_malloc=no])])
1789 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1790
1791
1792 dnl See comments in aix4-2.h about maybe using system malloc there.
1793 system_malloc=no
1794 case "$opsys" in
1795   ## darwin ld insists on the use of malloc routines in the System framework.
1796   darwin|sol2-10) system_malloc=yes ;;
1797 esac
1798
1799 if test "${system_malloc}" = "yes"; then
1800   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1801   GNU_MALLOC=no
1802   GNU_MALLOC_reason="
1803     (The GNU allocators don't work with this system configuration.)"
1804   GMALLOC_OBJ=
1805   VMLIMIT_OBJ=
1806 else
1807   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1808   VMLIMIT_OBJ=vm-limit.o
1809
1810   AC_CHECK_HEADERS([sys/vlimit.h])
1811   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1812     [AC_LINK_IFELSE(
1813        [AC_LANG_PROGRAM(
1814          [[extern char data_start[]; char ch;]],
1815          [[return data_start < &ch;]])],
1816        [emacs_cv_data_start=yes],
1817        [emacs_cv_data_start=no])])
1818   if test $emacs_cv_data_start = yes; then
1819     AC_DEFINE([HAVE_DATA_START], 1,
1820       [Define to 1 if data_start is the address of the start
1821        of the main data segment.])
1822   fi
1823 fi
1824 AC_SUBST(GMALLOC_OBJ)
1825 AC_SUBST(VMLIMIT_OBJ)
1826
1827 if test "$doug_lea_malloc" = "yes" ; then
1828   if test "$GNU_MALLOC" = yes ; then
1829     GNU_MALLOC_reason="
1830       (Using Doug Lea's new malloc from the GNU C Library.)"
1831   fi
1832   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1833             [Define to 1 if you are using the GNU C Library.])
1834
1835   ## Use mmap directly for allocating larger buffers.
1836   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1837   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1838   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1839   case "$opsys" in
1840     gnu*) REL_ALLOC=no ;;
1841   esac
1842 fi
1843
1844 if test x"${REL_ALLOC}" = x; then
1845   REL_ALLOC=${GNU_MALLOC}
1846 fi
1847
1848 use_mmap_for_buffers=no
1849 case "$opsys" in
1850   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1851 esac
1852
1853 AC_FUNC_MMAP
1854 if test $use_mmap_for_buffers = yes; then
1855   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1856   REL_ALLOC=no
1857 fi
1858
1859 LIBS="$LIBS_SYSTEM $LIBS"
1860
1861 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
1862 AC_CHECK_LIB(dnet, dnet_ntoa)
1863 dnl This causes -lresolv to get used in subsequent tests,
1864 dnl which causes failures on some systems such as HPUX 9.
1865 dnl AC_CHECK_LIB(resolv, gethostbyname)
1866
1867 dnl FIXME replace main with a function we actually want from this library.
1868 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1869
1870 dnl Check if pthreads is available.
1871 LIB_PTHREAD=
1872 AC_CHECK_HEADERS_ONCE(pthread.h)
1873 if test "$ac_cv_header_pthread_h"; then
1874   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1875   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1876   dnl testing for pthread_self if Emacs uses gmalloc.c.
1877   if test "$GMALLOC_OBJ" = gmalloc.o; then
1878     emacs_pthread_function=pthread_atfork
1879   else
1880     emacs_pthread_function=pthread_self
1881   fi
1882   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1883 fi
1884 if test "$HAVE_PTHREAD" = yes; then
1885   case "${canonical}" in
1886     *-hpux*) ;;
1887     *) LIB_PTHREAD="-lpthread"
1888        LIBS="$LIB_PTHREAD $LIBS" ;;
1889   esac
1890   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1891 fi
1892 AC_SUBST([LIB_PTHREAD])
1893
1894 AC_CHECK_LIB(pthreads, cma_open)
1895
1896 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1897 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1898 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1899 ## added to LIBS in configure would never contain the pthreads part,
1900 ## but the value used in Makefiles might.  FIXME?
1901 ##
1902 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1903 ## be harmless on older versions of X where it happens to exist.
1904 test "$opsys" = "aix4-2" && \
1905   test $ac_cv_lib_pthreads_cma_open = yes && \
1906   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1907
1908 dnl Check for need for bigtoc support on IBM AIX
1909
1910 case ${host_os} in
1911 aix*)
1912   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1913     case $GCC in
1914     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1915     *) gdb_cv_bigtoc=-bbigtoc ;;
1916     esac
1917
1918     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1919     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1920   ])
1921   ;;
1922 esac
1923
1924 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1925 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1926 # REAL_CPPFLAGS later on.
1927
1928 REAL_CFLAGS="$CFLAGS"
1929 REAL_CPPFLAGS="$CPPFLAGS"
1930
1931 if test "${HAVE_X11}" = "yes"; then
1932   DEFS="$C_SWITCH_X_SITE $DEFS"
1933   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1934   LIBS="-lX11 $LIBS"
1935   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1936   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1937
1938   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1939   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1940   # but it's more convenient here to set LD_RUN_PATH since this
1941   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1942   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1943     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1944     export LD_RUN_PATH
1945   fi
1946
1947   if test "${opsys}" = "gnu-linux"; then
1948     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1949     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1950      [[XOpenDisplay ("foo");]])],
1951      [xgnu_linux_first_failure=no],
1952      [xgnu_linux_first_failure=yes])
1953     if test "${xgnu_linux_first_failure}" = "yes"; then
1954       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1955       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1956       OLD_CPPFLAGS="$CPPFLAGS"
1957       OLD_LIBS="$LIBS"
1958       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1959       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1960       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1961       LIBS="$LIBS -b i486-linuxaout"
1962       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1963        [[XOpenDisplay ("foo");]])],
1964        [xgnu_linux_second_failure=no],
1965        [xgnu_linux_second_failure=yes])
1966       if test "${xgnu_linux_second_failure}" = "yes"; then
1967         # If we get the same failure with -b, there is no use adding -b.
1968         # So take it out.  This plays safe.
1969         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1970         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1971         CPPFLAGS="$OLD_CPPFLAGS"
1972         LIBS="$OLD_LIBS"
1973         AC_MSG_RESULT(no)
1974       else
1975         AC_MSG_RESULT(yes)
1976       fi
1977     else
1978       AC_MSG_RESULT(no)
1979     fi
1980   fi
1981
1982   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1983   # header files included from there.
1984   AC_MSG_CHECKING(for Xkb)
1985   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1986 #include <X11/XKBlib.h>]],
1987         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1988         emacs_xkb=yes, emacs_xkb=no)
1989   AC_MSG_RESULT($emacs_xkb)
1990   if test $emacs_xkb = yes; then
1991     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
1992   fi
1993
1994   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1995 XScreenNumberOfScreen)
1996 fi
1997
1998 if test "${window_system}" = "x11"; then
1999   AC_MSG_CHECKING(X11 version 6)
2000   AC_CACHE_VAL(emacs_cv_x11_version_6,
2001   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2002 [[#if XlibSpecificationRelease < 6
2003 fail;
2004 #endif
2005 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2006   if test $emacs_cv_x11_version_6 = yes; then
2007     AC_MSG_RESULT(6 or newer)
2008     AC_DEFINE(HAVE_X11R6, 1,
2009               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2010     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2011     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2012     ## XIM support.
2013     case "$opsys" in
2014       sol2-*) : ;;
2015       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2016            [Define if you have usable X11R6-style XIM support.])
2017          ;;
2018     esac
2019   else
2020     AC_MSG_RESULT(before 6)
2021   fi
2022 fi
2023
2024
2025 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2026 HAVE_RSVG=no
2027 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2028   if test "${with_rsvg}" != "no"; then
2029     RSVG_REQUIRED=2.11.0
2030     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2031
2032     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2033     AC_SUBST(RSVG_CFLAGS)
2034     AC_SUBST(RSVG_LIBS)
2035
2036     if test $HAVE_RSVG = yes; then
2037       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2038       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2039       LIBS="$RSVG_LIBS $LIBS"
2040     fi
2041   fi
2042 fi
2043
2044 HAVE_IMAGEMAGICK=no
2045 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
2046   if test "${with_imagemagick}" != "no"; then
2047     ## 6.2.8 is the earliest version known to work, but earlier versions
2048     ## might work - let us know if you find one.
2049     ## 6.0.7 does not work.  See bug#7955.
2050     ## 6.8.2 makes Emacs crash; see Bug#13867.
2051     IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2052     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2053     AC_SUBST(IMAGEMAGICK_CFLAGS)
2054     AC_SUBST(IMAGEMAGICK_LIBS)
2055
2056     if test $HAVE_IMAGEMAGICK = yes; then
2057       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2058       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2059       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2060       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2061     fi
2062   fi
2063 fi
2064
2065
2066 HAVE_GTK=no
2067 GTK_OBJ=
2068 gtk_term_header=$term_header
2069 check_gtk2=no
2070 gtk3_pkg_errors=
2071 if test "${opsys}" != "mingw32"; then
2072   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2073     GLIB_REQUIRED=2.28
2074     GTK_REQUIRED=3.0
2075     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2076
2077     dnl Checks for libraries.
2078     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2079     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2080        AC_MSG_ERROR($GTK_PKG_ERRORS)
2081     fi
2082     if test "$pkg_check_gtk" = "yes"; then
2083        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2084        GTK_OBJ=emacsgtkfixed.o
2085        gtk_term_header=gtkutil.h
2086        USE_GTK_TOOLKIT="GTK3"
2087        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2088           GTK_CFLAGS="$GTK_CFLAGS -DGDK_DISABLE_DEPRECATION_WARNINGS"
2089           GTK_CFLAGS="$GTK_CFLAGS -DGLIB_DISABLE_DEPRECATION_WARNINGS"
2090        fi
2091     else
2092        check_gtk2=yes
2093        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2094     fi
2095   fi
2096
2097   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2098     GLIB_REQUIRED=2.10
2099     GTK_REQUIRED=2.10
2100     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2101
2102     dnl Checks for libraries.
2103     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2104     if test "$pkg_check_gtk" = "no" &&
2105        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2106     then
2107       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2108     fi
2109     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2110   fi
2111 fi
2112
2113 if test x"$pkg_check_gtk" = xyes; then
2114
2115   AC_SUBST(GTK_CFLAGS)
2116   AC_SUBST(GTK_LIBS)
2117   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2118   CFLAGS="$CFLAGS $GTK_CFLAGS"
2119   LIBS="$GTK_LIBS $LIBS"
2120   dnl Try to compile a simple GTK program.
2121   AC_MSG_CHECKING([whether GTK compiles])
2122   GTK_COMPILES=no
2123   AC_LINK_IFELSE(
2124     [AC_LANG_PROGRAM(
2125        [[/* Check the Gtk and Glib APIs.  */
2126          #include <gtk/gtk.h>
2127          #include <glib-object.h>
2128          static void
2129          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2130          {}
2131        ]],
2132        [[
2133          GtkSettings *gs = 0;
2134          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2135             strict C prohibits this.  Use gtk_main_iteration to test that the
2136             libraries are there.  */
2137          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2138                                     0, 0, 0, G_CALLBACK (callback), 0))
2139            gtk_main_iteration ();
2140        ]])],
2141     [GTK_COMPILES=yes])
2142   AC_MSG_RESULT([$GTK_COMPILES])
2143   if test "${GTK_COMPILES}" != "yes"; then
2144     GTK_OBJ=
2145     if test "$USE_X_TOOLKIT" != "maybe"; then
2146       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2147     fi
2148   else
2149     HAVE_GTK=yes
2150     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2151     GTK_OBJ="gtkutil.o $GTK_OBJ"
2152     term_header=$gtk_term_header
2153     USE_X_TOOLKIT=none
2154     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2155       :
2156     else
2157       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2158        closing open displays.  This is no problem if you just use
2159        one display, but if you use more than one and close one of them
2160        Emacs may crash.]])
2161       sleep 3
2162     fi
2163   fi
2164
2165 fi
2166 AC_SUBST(GTK_OBJ)
2167
2168
2169 if test "${HAVE_GTK}" = "yes"; then
2170
2171   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2172   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2173   if test "$with_toolkit_scroll_bars" != no; then
2174     with_toolkit_scroll_bars=yes
2175   fi
2176
2177   dnl  Check if we have the old file selection dialog declared and
2178   dnl  in the link library.  In 2.x it may be in the library,
2179   dnl  but not declared if deprecated featured has been selected out.
2180   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2181   HAVE_GTK_FILE_SELECTION=no
2182   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2183                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2184 #include <gtk/gtk.h>])
2185   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2186     AC_CHECK_FUNCS(gtk_file_selection_new)
2187   fi
2188
2189   dnl Same as above for gtk_handle_box.
2190   HAVE_GTK_HANDLE_BOX=no
2191   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2192                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2193 #include <gtk/gtk.h>])
2194   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2195     AC_CHECK_FUNCS(gtk_handle_box_new)
2196   fi
2197
2198   dnl Same as above for gtk_tearoff_menu_item.
2199   HAVE_GTK_TEAROFF_MENU_ITEM=no
2200   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2201                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2202 #include <gtk/gtk.h>])
2203   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2204     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2205   fi
2206
2207   dnl Check for functions introduced in 2.14 and later.
2208   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2209                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2210                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2211                  gtk_orientable_set_orientation \
2212                  gtk_window_set_has_resize_grip)
2213
2214  term_header=gtkutil.h
2215 fi
2216
2217 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2218 dnl other platforms.
2219 HAVE_DBUS=no
2220 DBUS_OBJ=
2221 if test "${with_dbus}" = "yes"; then
2222    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2223    if test "$HAVE_DBUS" = yes; then
2224      LIBS="$LIBS $DBUS_LIBS"
2225      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2226      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2227      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2228      dnl D-Bus 1.5.12.
2229      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2230                     dbus_type_is_valid \
2231                     dbus_validate_bus_name \
2232                     dbus_validate_path \
2233                     dbus_validate_interface \
2234                     dbus_validate_member)
2235      DBUS_OBJ=dbusbind.o
2236    fi
2237 fi
2238 AC_SUBST(DBUS_OBJ)
2239
2240 dnl GSettings has been tested under GNU/Linux only.
2241 HAVE_GSETTINGS=no
2242 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2243    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2244    if test "$HAVE_GSETTINGS" = "yes"; then
2245       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2246       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2247       SETTINGS_LIBS="$GSETTINGS_LIBS"
2248    fi
2249 fi
2250
2251 dnl GConf has been tested under GNU/Linux only.
2252 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2253 HAVE_GCONF=no
2254 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2255    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2256    if test "$HAVE_GCONF" = yes; then
2257       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2258       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2259       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2260       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2261    fi
2262 fi
2263
2264 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2265     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2266     if test "$HAVE_GOBJECT" = "yes"; then
2267        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2268        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2269     fi
2270     SAVE_CFLAGS="$CFLAGS"
2271     SAVE_LIBS="$LIBS"
2272     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2273     LIBS="$SETTINGS_LIBS $LIBS"
2274     AC_CHECK_FUNCS([g_type_init])
2275     CFLAGS="$SAVE_CFLAGS"
2276     LIBS="$SAVE_LIBS"
2277 fi
2278 AC_SUBST(SETTINGS_CFLAGS)
2279 AC_SUBST(SETTINGS_LIBS)
2280
2281
2282 dnl SELinux is available for GNU/Linux only.
2283 HAVE_LIBSELINUX=no
2284 LIBSELINUX_LIBS=
2285 if test "${with_selinux}" = "yes"; then
2286    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2287    if test "$HAVE_LIBSELINUX" = yes; then
2288       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2289       LIBSELINUX_LIBS=-lselinux
2290    fi
2291 fi
2292 AC_SUBST(LIBSELINUX_LIBS)
2293
2294 HAVE_GNUTLS=no
2295 if test "${with_gnutls}" = "yes" ; then
2296   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2297   if test "${HAVE_GNUTLS}" = "yes"; then
2298     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2299   fi
2300
2301   # Windows loads GnuTLS dynamically
2302   if test "${opsys}" = "mingw32"; then
2303     LIBGNUTLS_LIBS=
2304   else
2305     CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2306     LIBS="$LIBGNUTLS_LIBS $LIBS"
2307   fi
2308 fi
2309
2310 AC_SUBST(LIBGNUTLS_LIBS)
2311 AC_SUBST(LIBGNUTLS_CFLAGS)
2312
2313 NOTIFY_OBJ=
2314 NOTIFY_SUMMARY=no
2315
2316 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2317 dnl a particular library.  This doesn't make much sense?
2318 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2319   with_file_notification=no
2320 fi
2321
2322 if test "${with_file_notification}" != "no"; then
2323
2324   dnl MS Windows native file monitor is available for mingw32 only.
2325   if test "${with_file_notification}" = "w32" || \
2326      ( test "${opsys}" = "mingw32" && \
2327        test "${with_file_notification}" = "yes" ); then
2328      AC_CHECK_HEADER(windows.h)
2329      if test "$ac_cv_header_windows_h" = yes ; then
2330         AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2331         NOTIFY_OBJ=w32notify.o
2332         NOTIFY_SUMMARY="yes (w32)"
2333         with_file_notification=w32
2334      elif test "${with_file_notification}" = "w32"; then
2335        AC_MSG_ERROR([File notification `w32' requested but requirements not found.])
2336      elif test "${opsys}" = "mingw32"; then
2337        dnl Do not try any further.
2338        with_file_notification=no
2339      fi
2340   fi
2341
2342   dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2343   dnl has been added in glib 2.24.  It has been tested under
2344   dnl GNU/Linux only.  We take precedence over inotify, but this makes
2345   dnl only sense when glib has been compiled with inotify support.  How
2346   dnl to check?
2347   if test "${with_file_notification}" = "gfile" || \
2348     test "${with_file_notification}" = "yes"; then
2349      PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2350      if test "$HAVE_GFILENOTIFY" = "yes"; then
2351         AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2352         NOTIFY_OBJ=gfilenotify.o
2353         NOTIFY_SUMMARY="yes -lgio (gfile)"
2354         with_file_notification=gfile
2355      elif test "${with_file_notification}" = "gfile"; then
2356         AC_MSG_ERROR([File notification `gfile' requested but requirements not found.])
2357      fi
2358   fi
2359
2360   dnl inotify is only available on GNU/Linux.
2361   if test "${with_file_notification}" = "inotify" || \
2362     test "${with_file_notification}" = "yes"; then
2363      AC_CHECK_HEADER(sys/inotify.h)
2364      if test "$ac_cv_header_sys_inotify_h" = yes ; then
2365          AC_CHECK_FUNC(inotify_init1)
2366          if test "$ac_cv_func_inotify_init1" = yes; then
2367              AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2368            NOTIFY_OBJ=inotify.o
2369            NOTIFY_SUMMARY="yes -lglibc (inotify)"
2370            with_file_notification=inotify
2371          fi
2372      fi
2373      if test "${with_file_notification}" = "inotify" && \
2374        test -z "${NOTIFY_OBJ}"; then
2375         AC_MSG_ERROR([File notification `inotify' requested but requirements not found.])
2376      fi
2377   fi
2378 fi                              dnl ${with_file_notification} != no
2379
2380 if test -n "$NOTIFY_OBJ"; then
2381    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2382 fi
2383 AC_SUBST(NOTIFY_OBJ)
2384 AC_SUBST(GFILENOTIFY_CFLAGS)
2385 AC_SUBST(GFILENOTIFY_LIBS)
2386
2387 dnl Do not put whitespace before the #include statements below.
2388 dnl Older compilers (eg sunos4 cc) choke on it.
2389 HAVE_XAW3D=no
2390 LUCID_LIBW=
2391 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2392   if test "$with_xaw3d" != no; then
2393     AC_CACHE_VAL(emacs_cv_xaw3d,
2394     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2395 #include <X11/Intrinsic.h>
2396 #include <X11/Xaw3d/Simple.h>]],
2397       [[]])],
2398       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2399                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2400       emacs_cv_xaw3d=no)])
2401   else
2402     emacs_cv_xaw3d=no
2403   fi
2404   if test $emacs_cv_xaw3d = yes; then
2405     AC_MSG_CHECKING(for xaw3d)
2406     AC_MSG_RESULT([yes; using Lucid toolkit])
2407     USE_X_TOOLKIT=LUCID
2408     HAVE_XAW3D=yes
2409     LUCID_LIBW=-lXaw3d
2410     AC_DEFINE(HAVE_XAW3D, 1,
2411               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2412   else
2413     AC_MSG_CHECKING(for xaw3d)
2414     AC_MSG_RESULT(no)
2415     AC_MSG_CHECKING(for libXaw)
2416     AC_CACHE_VAL(emacs_cv_xaw,
2417     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2418 #include <X11/Intrinsic.h>
2419 #include <X11/Xaw/Simple.h>]],
2420       [[]])],
2421       emacs_cv_xaw=yes,
2422       emacs_cv_xaw=no)])
2423     if test $emacs_cv_xaw = yes; then
2424       AC_MSG_RESULT([yes; using Lucid toolkit])
2425       USE_X_TOOLKIT=LUCID
2426       LUCID_LIBW=-lXaw
2427     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2428       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2429     else
2430       AC_MSG_ERROR([No X toolkit could be found.
2431 If you are sure you want Emacs compiled without an X toolkit, pass
2432   --with-x-toolkit=no
2433 to configure.  Otherwise, install the development libraries for the toolkit
2434 that you want to use (e.g. Gtk+) and re-run configure.])
2435     fi
2436   fi
2437 fi
2438
2439 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2440
2441 LIBXTR6=
2442 if test "${USE_X_TOOLKIT}" != "none"; then
2443   AC_MSG_CHECKING(X11 toolkit version)
2444   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2445   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2446 [[#if XtSpecificationRelease < 6
2447 fail;
2448 #endif
2449 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2450   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2451   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2452     AC_MSG_RESULT(6 or newer)
2453     AC_DEFINE(HAVE_X11XTR6, 1,
2454               [Define to 1 if you have the X11R6 or newer version of Xt.])
2455     LIBXTR6="-lSM -lICE"
2456     case "$opsys" in
2457       ## Use libw.a along with X11R6 Xt.
2458       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2459     esac
2460   else
2461     AC_MSG_RESULT(before 6)
2462   fi
2463
2464 dnl If using toolkit, check whether libXmu.a exists.
2465 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2466   OLDLIBS="$LIBS"
2467   if test x$HAVE_X11XTR6 = xyes; then
2468     LIBS="-lXt -lSM -lICE $LIBS"
2469   else
2470     LIBS="-lXt $LIBS"
2471   fi
2472   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2473   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2474   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2475 fi
2476 AC_SUBST(LIBXTR6)
2477
2478 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2479 dnl Why not just test for libxmu in the normal way?
2480 LIBXMU=-lXmu
2481 case $opsys in
2482   ## These systems don't supply Xmu.
2483   hpux* | aix4-2 )
2484     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2485     ;;
2486   mingw32 )
2487     LIBXMU=
2488     ;;
2489 esac
2490 AC_SUBST(LIBXMU)
2491
2492 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2493 if test "${HAVE_X11}" = "yes"; then
2494   if test "${USE_X_TOOLKIT}" != "none"; then
2495     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2496   fi
2497 fi
2498
2499 LIBXP=
2500 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2501   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2502   if test -d /usr/include/openmotif; then
2503     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2504     emacs_cv_openmotif=yes
2505     case "$canonical" in
2506       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2507       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2508       ;;
2509       *)
2510       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2511     esac
2512   else
2513     emacs_cv_openmotif=no
2514   fi
2515   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2516   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2517     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2518 int x = 5;
2519 #else
2520 Motif version prior to 2.1.
2521 #endif]])],
2522     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2523   if test $emacs_cv_motif_version_2_1 = yes; then
2524     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2525     if test x$emacs_cv_openmotif = xyes; then
2526       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2527     fi
2528   else
2529     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2530     # We put this in CFLAGS temporarily to precede other -I options
2531     # that might be in CFLAGS temporarily.
2532     # We put this in CPPFLAGS where it precedes the other -I options.
2533     OLD_CPPFLAGS=$CPPFLAGS
2534     OLD_CFLAGS=$CFLAGS
2535     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2536     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2537     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2538       [[int x = 5;]])],
2539       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2540     if test $emacs_cv_lesstif = yes; then
2541       # Make sure this -I option remains in CPPFLAGS after it is set
2542       # back to REAL_CPPFLAGS.
2543       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2544       # have those other -I options anyway.  Ultimately, having this
2545       # directory ultimately in CPPFLAGS will be enough.
2546       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2547       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2548     else
2549       CFLAGS=$OLD_CFLAGS
2550       CPPFLAGS=$OLD_CPPFLAGS
2551     fi
2552   fi
2553   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2554     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2555 fi
2556
2557 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2558 dnl using Motif or Xaw3d is available, and unless
2559 dnl --with-toolkit-scroll-bars=no was specified.
2560
2561 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2562             [Define to 1 if we should use toolkit scroll bars.])dnl
2563 USE_TOOLKIT_SCROLL_BARS=no
2564 if test "${with_toolkit_scroll_bars}" != "no"; then
2565   if test "${USE_X_TOOLKIT}" != "none"; then
2566     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2567       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2568       HAVE_XAW3D=no
2569       USE_TOOLKIT_SCROLL_BARS=yes
2570     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2571       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2572       USE_TOOLKIT_SCROLL_BARS=yes
2573     fi
2574   elif test "${HAVE_GTK}" = "yes"; then
2575     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2576     USE_TOOLKIT_SCROLL_BARS=yes
2577   elif test "${HAVE_NS}" = "yes"; then
2578     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2579     USE_TOOLKIT_SCROLL_BARS=yes
2580   elif test "${HAVE_W32}" = "yes"; then
2581     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2582     USE_TOOLKIT_SCROLL_BARS=yes
2583   fi
2584 fi
2585
2586 dnl See if XIM is available.
2587 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2588           #include <X11/Xlib.h>
2589           #include <X11/Xresource.h>]],
2590          [[XIMProc  callback;]])],
2591          [HAVE_XIM=yes
2592          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2593          HAVE_XIM=no)
2594
2595 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2596
2597 if test "${with_xim}" != "no"; then
2598   AC_DEFINE(USE_XIM, 1,
2599             [Define to 1 if we should use XIM, if it is available.])
2600 fi
2601
2602
2603 if test "${HAVE_XIM}" != "no"; then
2604   late_CFLAGS=$CFLAGS
2605   if test "$GCC" = yes; then
2606     CFLAGS="$CFLAGS --pedantic-errors"
2607   fi
2608   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2609 #include <X11/Xlib.h>
2610 #include <X11/Xresource.h>]],
2611 [[Display *display;
2612 XrmDatabase db;
2613 char *res_name;
2614 char *res_class;
2615 XIMProc  callback;
2616 XPointer *client_data;
2617 #ifndef __GNUC__
2618 /* If we're not using GCC, it's probably not XFree86, and this is
2619    probably right, but we can't use something like --pedantic-errors.  */
2620 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2621                                            char*, XIMProc, XPointer*);
2622 #endif
2623 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2624    client_data);]])],
2625     [emacs_cv_arg6_star=yes])
2626   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2627          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2628 either XPointer or XPointer*.])dnl
2629   if test "$emacs_cv_arg6_star" = yes; then
2630     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2631   else
2632     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2633   fi
2634   CFLAGS=$late_CFLAGS
2635 fi
2636
2637 ### Start of font-backend (under any platform) section.
2638 # (nothing here yet -- this is a placeholder)
2639 ### End of font-backend (under any platform) section.
2640
2641 ### Start of font-backend (under X11) section.
2642 if test "${HAVE_X11}" = "yes"; then
2643    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2644
2645    ## Use -lXft if available, unless `--with-xft=no'.
2646    HAVE_XFT=maybe
2647     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2648       with_xft="no";
2649     fi
2650     if test "x${with_xft}" != "xno"; then
2651
2652       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2653       ## Because xftfont.c uses XRenderQueryExtension, we also
2654       ## need to link to -lXrender.
2655       HAVE_XRENDER=no
2656       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2657       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2658         OLD_CPPFLAGS="$CPPFLAGS"
2659         OLD_CFLAGS="$CFLAGS"
2660         OLD_LIBS="$LIBS"
2661         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2662         CFLAGS="$CFLAGS $XFT_CFLAGS"
2663         XFT_LIBS="-lXrender $XFT_LIBS"
2664         LIBS="$XFT_LIBS $LIBS"
2665         AC_CHECK_HEADER(X11/Xft/Xft.h,
2666           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2667           [[#include <X11/X.h>]])
2668
2669         if test "${HAVE_XFT}" = "yes"; then
2670           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2671             AC_SUBST(XFT_LIBS)
2672           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2673         else
2674           CPPFLAGS="$OLD_CPPFLAGS"
2675           CFLAGS="$OLD_CFLAGS"
2676           LIBS="$OLD_LIBS"
2677         fi                        # "${HAVE_XFT}" = "yes"
2678       fi                          # "$HAVE_XFT" != no
2679     fi                            # "x${with_xft}" != "xno"
2680
2681     ## We used to allow building with FreeType and without Xft.
2682     ## However, the ftx font backend driver is not in good shape.
2683     if test "$HAVE_XFT" != "yes"; then
2684        dnl For the "Does Emacs use" message at the end.
2685        HAVE_XFT=no
2686        HAVE_FREETYPE=no
2687     else
2688        dnl Strict linkers fail with
2689        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2690        dnl if -lfreetype is not specified.
2691        dnl The following is needed to set FREETYPE_LIBS.
2692        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2693                          HAVE_FREETYPE=no)
2694
2695        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2696     fi
2697
2698     HAVE_LIBOTF=no
2699     if test "${HAVE_FREETYPE}" = "yes"; then
2700       AC_DEFINE(HAVE_FREETYPE, 1,
2701                 [Define to 1 if using the freetype and fontconfig libraries.])
2702       if test "${with_libotf}" != "no"; then
2703         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2704                           HAVE_LIBOTF=no)
2705         if test "$HAVE_LIBOTF" = "yes"; then
2706           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2707           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2708                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2709                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2710           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2711             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2712                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2713           fi
2714         fi
2715       fi
2716     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2717     dnl Does the new font backend require it, or can it work without it?
2718     fi
2719
2720     HAVE_M17N_FLT=no
2721     if test "${HAVE_LIBOTF}" = yes; then
2722       if test "${with_m17n_flt}" != "no"; then
2723         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2724         if test "$HAVE_M17N_FLT" = "yes"; then
2725           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2726         fi
2727       fi
2728     fi
2729 else
2730     HAVE_XFT=no
2731     HAVE_FREETYPE=no
2732     HAVE_LIBOTF=no
2733     HAVE_M17N_FLT=no
2734 fi
2735
2736 ### End of font-backend (under X11) section.
2737
2738 AC_SUBST(FREETYPE_CFLAGS)
2739 AC_SUBST(FREETYPE_LIBS)
2740 AC_SUBST(FONTCONFIG_CFLAGS)
2741 AC_SUBST(FONTCONFIG_LIBS)
2742 AC_SUBST(LIBOTF_CFLAGS)
2743 AC_SUBST(LIBOTF_LIBS)
2744 AC_SUBST(M17N_FLT_CFLAGS)
2745 AC_SUBST(M17N_FLT_LIBS)
2746
2747 ### Use -lXpm if available, unless `--with-xpm=no'.
2748 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2749 HAVE_XPM=no
2750 LIBXPM=
2751 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2752   if test "${with_xpm}" != "no"; then
2753     SAVE_CPPFLAGS="$CPPFLAGS"
2754     SAVE_LDFLAGS="$LDFLAGS"
2755     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2756     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2757     AC_CHECK_HEADER(X11/xpm.h,
2758       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2759     if test "${HAVE_XPM}" = "yes"; then
2760       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2761       AC_EGREP_CPP(no_return_alloc_pixels,
2762       [#include "X11/xpm.h"
2763 #ifndef XpmReturnAllocPixels
2764 no_return_alloc_pixels
2765 #endif
2766       ], HAVE_XPM=no, HAVE_XPM=yes)
2767
2768       if test "${HAVE_XPM}" = "yes"; then
2769         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2770         AC_MSG_RESULT(yes)
2771       else
2772         AC_MSG_RESULT(no)
2773         CPPFLAGS="$SAVE_CPPFLAGS"
2774         LDFLAGS="$SAVE_LDFLAGS"
2775       fi
2776     fi
2777   fi
2778
2779   if test "${HAVE_XPM}" = "yes"; then
2780     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2781     LIBXPM=-lXpm
2782   fi
2783 fi
2784
2785 if test "${HAVE_X11}" = "yes"; then
2786   if test "${with_xpm}" != "no"; then
2787     AC_CHECK_HEADER(X11/xpm.h,
2788       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2789     if test "${HAVE_XPM}" = "yes"; then
2790       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2791       AC_EGREP_CPP(no_return_alloc_pixels,
2792       [#include "X11/xpm.h"
2793 #ifndef XpmReturnAllocPixels
2794 no_return_alloc_pixels
2795 #endif
2796       ], HAVE_XPM=no, HAVE_XPM=yes)
2797
2798       if test "${HAVE_XPM}" = "yes"; then
2799         AC_MSG_RESULT(yes)
2800       else
2801         AC_MSG_RESULT(no)
2802       fi
2803     fi
2804   fi
2805
2806   if test "${HAVE_XPM}" = "yes"; then
2807     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2808     LIBXPM=-lXpm
2809   fi
2810 fi
2811
2812 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
2813 ### slightly different requirements wrt image libraries (it doesn't
2814 ### use -lXpm because it loads the xpm shared library dynamically at
2815 ### run time).
2816 if test "${opsys}" = "mingw32"; then
2817   if test "${with_xpm}" != "no"; then
2818     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
2819 #define FOR_MSW 1])
2820   fi
2821
2822   if test "${HAVE_XPM}" = "yes"; then
2823     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2824   fi
2825 fi
2826
2827 AC_SUBST(LIBXPM)
2828
2829 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2830 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
2831 HAVE_JPEG=no
2832 LIBJPEG=
2833 if test "${opsys}" = "mingw32"; then
2834   if test "${with_jpeg}" != "no"; then
2835     dnl Checking for jpeglib.h can lose because of a redefinition of
2836     dnl HAVE_STDLIB_H.
2837     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
2838   fi
2839   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2840   if test "${HAVE_JPEG}" = "yes"; then
2841     AC_DEFINE(HAVE_JPEG)
2842     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2843         [#include <jpeglib.h>
2844          version=JPEG_LIB_VERSION
2845 ],
2846         [AC_DEFINE(HAVE_JPEG)],
2847         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2848         HAVE_JPEG=no])
2849   fi
2850 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2851   if test "${with_jpeg}" != "no"; then
2852     dnl Checking for jpeglib.h can lose because of a redefinition of
2853     dnl  HAVE_STDLIB_H.
2854     AC_CHECK_HEADER(jerror.h,
2855       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2856   fi
2857
2858   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2859   if test "${HAVE_JPEG}" = "yes"; then
2860     AC_DEFINE(HAVE_JPEG)
2861     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2862         [#include <jpeglib.h>
2863          version=JPEG_LIB_VERSION
2864 ],
2865         [AC_DEFINE(HAVE_JPEG)],
2866         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2867         HAVE_JPEG=no])
2868   fi
2869   if test "${HAVE_JPEG}" = "yes"; then
2870     LIBJPEG=-ljpeg
2871   fi
2872 fi
2873 AC_SUBST(LIBJPEG)
2874
2875 ### Use -lpng if available, unless `--with-png=no'.
2876 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
2877 HAVE_PNG=no
2878 LIBPNG=
2879 if test "${opsys}" = "mingw32"; then
2880   if test "${with_png}" != "no"; then
2881     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
2882   fi
2883   if test "${HAVE_PNG}" = "yes"; then
2884     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2885
2886     AC_CHECK_DECL(png_longjmp,
2887       [],
2888       [AC_DEFINE(PNG_DEPSTRUCT, [],
2889          [Define to empty to suppress deprecation warnings when building
2890           with --enable-gcc-warnings and with libpng versions before 1.5,
2891           which lack png_longjmp.])],
2892       [[#ifdef HAVE_LIBPNG_PNG_H
2893         # include <libpng/png.h>
2894         #else
2895         # include <png.h>
2896         #endif
2897       ]])
2898   fi
2899 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2900   if test "${with_png}" != "no"; then
2901     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2902     # in /usr/include/libpng.
2903     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2904     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2905       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2906     fi
2907   fi
2908
2909   if test "${HAVE_PNG}" = "yes"; then
2910     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2911     LIBPNG="-lpng -lz -lm"
2912
2913     AC_CHECK_DECL(png_longjmp,
2914       [],
2915       [AC_DEFINE(PNG_DEPSTRUCT, [],
2916          [Define to empty to suppress deprecation warnings when building
2917           with --enable-gcc-warnings and with libpng versions before 1.5,
2918           which lack png_longjmp.])],
2919       [[#ifdef HAVE_LIBPNG_PNG_H
2920         # include <libpng/png.h>
2921         #else
2922         # include <png.h>
2923         #endif
2924       ]])
2925   fi
2926 fi
2927 AC_SUBST(LIBPNG)
2928
2929 ### Use -ltiff if available, unless `--with-tiff=no'.
2930 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
2931 HAVE_TIFF=no
2932 LIBTIFF=
2933 if test "${opsys}" = "mingw32"; then
2934   if test "${with_tiff}" != "no"; then
2935     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
2936   fi
2937   if test "${HAVE_TIFF}" = "yes"; then
2938     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2939   fi
2940 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2941   if test "${with_tiff}" != "no"; then
2942     AC_CHECK_HEADER(tiffio.h,
2943       [tifflibs="-lz -lm"
2944       # At least one tiff package requires the jpeg library.
2945       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2946       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2947   fi
2948
2949   if test "${HAVE_TIFF}" = "yes"; then
2950     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2951     dnl FIXME -lz -lm, as per libpng?
2952     LIBTIFF=-ltiff
2953   fi
2954 fi
2955 AC_SUBST(LIBTIFF)
2956
2957 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2958 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
2959 HAVE_GIF=no
2960 LIBGIF=
2961 if test "${opsys}" = "mingw32"; then
2962   if test "${with_gif}" != "no"; then
2963     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
2964   fi
2965   if test "${HAVE_GIF}" = "yes"; then
2966     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2967   fi
2968 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
2969         || test "${HAVE_W32}" = "yes"; then
2970   AC_CHECK_HEADER(gif_lib.h,
2971 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2972 # Earlier versions can crash Emacs.
2973     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2974
2975   if test "$HAVE_GIF" = yes; then
2976     LIBGIF=-lgif
2977   elif test "$HAVE_GIF" = maybe; then
2978 # If gif_lib.h but no libgif, try libungif.
2979     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2980     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2981   fi
2982
2983   if test "${HAVE_GIF}" = "yes"; then
2984     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2985   fi
2986 fi
2987 AC_SUBST(LIBGIF)
2988
2989 dnl Check for required libraries.
2990 if test "${HAVE_X11}" = "yes"; then
2991   MISSING=""
2992   WITH_NO=""
2993   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2994     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2995   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2996     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2997   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2998     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2999   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3000     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3001   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3002     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3003
3004   if test "X${MISSING}" != X; then
3005     AC_MSG_ERROR([The following required libraries were not found:
3006     $MISSING
3007 Maybe some development libraries/packages are missing?
3008 If you don't want to link with them give
3009     $WITH_NO
3010 as options to configure])
3011   fi
3012 fi
3013
3014 ### Use -lgpm if available, unless `--with-gpm=no'.
3015 HAVE_GPM=no
3016 LIBGPM=
3017 if test "${with_gpm}" != "no"; then
3018   AC_CHECK_HEADER(gpm.h,
3019     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3020
3021   if test "${HAVE_GPM}" = "yes"; then
3022     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3023     LIBGPM=-lgpm
3024   fi
3025 fi
3026 AC_SUBST(LIBGPM)
3027
3028 dnl Check for malloc/malloc.h on darwin
3029 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3030
3031 GNUSTEP_CFLAGS=
3032 ### Use NeXTstep API to implement GUI.
3033 if test "${HAVE_NS}" = "yes"; then
3034   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3035   if test "${NS_IMPL_COCOA}" = "yes"; then
3036     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3037   fi
3038   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3039     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3040     # See also .m.o rule in Makefile.in */
3041     # FIXME: are all these flags really needed?  Document here why.  */
3042     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3043     ## Extra CFLAGS applied to src/*.m files.
3044     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3045   fi
3046   # We also have mouse menus.
3047   HAVE_MENUS=yes
3048   OTHER_FILES=ns-app
3049 fi
3050
3051 if test "${HAVE_W32}" = "yes"; then
3052   HAVE_MENUS=yes
3053 fi
3054
3055 ### Use session management (-lSM -lICE) if available
3056 HAVE_X_SM=no
3057 LIBXSM=
3058 if test "${HAVE_X11}" = "yes"; then
3059   AC_CHECK_HEADER(X11/SM/SMlib.h,
3060     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3061
3062   if test "${HAVE_X_SM}" = "yes"; then
3063     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3064     LIBXSM="-lSM -lICE"
3065     case "$LIBS" in
3066       *-lSM*) ;;
3067       *)      LIBS="$LIBXSM $LIBS" ;;
3068     esac
3069   fi
3070 fi
3071 AC_SUBST(LIBXSM)
3072
3073 ### Use XRandr (-lXrandr) if available
3074 HAVE_XRANDR=no
3075 if test "${HAVE_X11}" = "yes"; then
3076   XRANDR_REQUIRED=1.2.2
3077   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3078   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3079   if test $HAVE_XRANDR = no; then
3080     # Test old way in case pkg-config doesn't have it (older machines).
3081     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3082       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3083     if test $HAVE_XRANDR = yes; then
3084       XRANDR_LIBS=-lXrandr
3085       AC_SUBST(XRANDR_LIBS)
3086     fi
3087   fi
3088   if test $HAVE_XRANDR = yes; then
3089     SAVE_CFLAGS="$CFLAGS"
3090     SAVE_LIBS="$LIBS"
3091     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3092     LIBS="$XRANDR_LIBS $LIBS"
3093     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3094     CFLAGS="$SAVE_CFLAGS"
3095     LIBS="$SAVE_LIBS"
3096
3097     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3098   fi
3099 fi
3100
3101 ### Use Xinerama (-lXinerama) if available
3102 HAVE_XINERAMA=no
3103 if test "${HAVE_X11}" = "yes"; then
3104   XINERAMA_REQUIRED=1.0.2
3105   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3106   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3107                     HAVE_XINERAMA=no)
3108   if test $HAVE_XINERAMA = no; then
3109     # Test old way in case pkg-config doesn't have it (older machines).
3110     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3111       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3112     if test $HAVE_XINERAMA = yes; then
3113       XINERAMA_LIBS=-lXinerama
3114       AC_SUBST(XINERAMA_LIBS)
3115     fi
3116   fi
3117   if test $HAVE_XINERAMA = yes; then
3118     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3119   fi
3120 fi
3121
3122
3123 ### Use libxml (-lxml2) if available
3124 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3125 HAVE_LIBXML2=no
3126 if test "${with_xml2}" != "no"; then
3127   ### I'm not sure what the version number should be, so I just guessed.
3128   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3129   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3130   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3131     SAVE_CPPFLAGS="$CPPFLAGS"
3132     CPPFLAGS="$CPPFLAGS -I/usr/include/libxml2"
3133     AC_CHECK_HEADER(libxml/HTMLparser.h,
3134       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3135                      [#include <libxml/HTMLparser.h>])])
3136     CPPFLAGS="$SAVE_CPPFLAGS"
3137     if test "${HAVE_LIBXML2}" = "yes"; then
3138       LIBXML2_LIBS="-lxml2"
3139       LIBXML2_CFLAGS="-I/usr/include/libxml2"
3140     fi
3141   fi
3142   if test "${HAVE_LIBXML2}" = "yes"; then
3143     if test "${opsys}" != "mingw32"; then
3144       LIBS="$LIBXML2_LIBS $LIBS"
3145       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3146     else
3147       LIBXML2_LIBS=""
3148     fi
3149     if test "${HAVE_LIBXML2}" = "yes"; then
3150       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3151     else
3152       LIBXML2_LIBS=""
3153       LIBXML2_CFLAGS=""
3154     fi
3155   fi
3156 fi
3157 AC_SUBST(LIBXML2_LIBS)
3158 AC_SUBST(LIBXML2_CFLAGS)
3159
3160 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3161 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3162 if test "${opsys}" = "mingw32"; then
3163   emacs_cv_netdb_declares_h_errno=yes
3164 fi
3165 AC_CACHE_CHECK(whether netdb declares h_errno,
3166                emacs_cv_netdb_declares_h_errno,
3167 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3168   [[return h_errno;]])],
3169   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3170 if test $emacs_cv_netdb_declares_h_errno = yes; then
3171   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3172 fi
3173
3174 # sqrt and other floating-point functions such as fmod and frexp
3175 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3176 if test "${opsys}" != "mingw32"; then
3177   AC_CHECK_LIB(m, sqrt)
3178 fi
3179
3180 # Check for mail-locking functions in a "mail" library.  Probably this should
3181 # have the same check as for liblockfile below.
3182 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3183 if test $have_mail = yes; then
3184   LIBS_MAIL=-lmail
3185   LIBS="$LIBS_MAIL $LIBS"
3186   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3187 else
3188   LIBS_MAIL=
3189 fi
3190 dnl Debian, at least:
3191 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3192 if test $have_lockfile = yes; then
3193    LIBS_MAIL=-llockfile
3194    LIBS="$LIBS_MAIL $LIBS"
3195    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3196 else
3197 # If we have the shared liblockfile, assume we must use it for mail
3198 # locking (e.g. Debian).  If we couldn't link against liblockfile
3199 # (no liblockfile.a installed), ensure that we don't need to.
3200   dnl This works for files generally, not just executables.
3201   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3202   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3203                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3204   if test $ac_cv_prog_liblockfile = yes; then
3205     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3206 This probably means that movemail could lose mail.
3207 There may be a `development' package to install containing liblockfile.])
3208   fi
3209 fi
3210 AC_CHECK_HEADERS_ONCE(maillock.h)
3211 AC_SUBST(LIBS_MAIL)
3212
3213 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3214 ## interlock access to the mail spool.  The alternative is a lock file named
3215 ## /usr/spool/mail/$USER.lock.
3216 mail_lock=no
3217 case "$opsys" in
3218   aix4-2) mail_lock="lockf" ;;
3219
3220   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3221
3222   ## On GNU/Linux systems, both methods are used by various mail programs.
3223   ## I assume most people are using newer mailers that have heard of flock.
3224   ## Change this if you need to.
3225   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3226   ## configure gets the right answers, and that means *NOT* using flock.
3227   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3228   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3229   ## Debian maintainer hasn't provided a clean fix for Emacs.
3230   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3231   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3232   ## correct logic.  -- fx
3233   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3234   ## liblockfile is a Free Software replacement for libmail, used on
3235   ## Debian systems and elsewhere. -rfr.
3236   gnu-*)
3237     mail_lock="flock"
3238     if test $have_mail = yes || test $have_lockfile = yes; then
3239       test $ac_cv_header_maillock_h = yes && mail_lock=no
3240     fi
3241     ;;
3242
3243   mingw32)
3244     mail_lock="none-needed" ;;
3245 esac
3246
3247 BLESSMAIL_TARGET=
3248 case "$mail_lock" in
3249   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3250
3251   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3252
3253   none-needed) ;;
3254
3255   *) BLESSMAIL_TARGET="need-blessmail" ;;
3256 esac
3257 AC_SUBST(BLESSMAIL_TARGET)
3258
3259
3260 AC_CHECK_FUNCS(accept4 gethostname \
3261 getrusage get_current_dir_name \
3262 lrand48 \
3263 select getpagesize setlocale \
3264 getrlimit setrlimit shutdown getaddrinfo \
3265 strsignal setitimer \
3266 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3267 gai_strerror mkostemp mkstemp getline getdelim sync \
3268 difftime posix_memalign \
3269 getpwent endpwent getgrent endgrent \
3270 touchlock \
3271 cfmakeraw cfsetspeed copysign __executable_start log2)
3272
3273 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3274 ## has a broken `rint' in some library versions including math library
3275 ## version number A.09.05.
3276 ## You can fix the math library by installing patch number PHSS_4630.
3277 ## But we can fix it more reliably for Emacs by just not using rint.
3278 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3279 case $opsys in
3280    hpux*) : ;;
3281    *) AC_CHECK_FUNCS(random rint) ;;
3282 esac
3283
3284 dnl Cannot use AC_CHECK_FUNCS
3285 AC_CACHE_CHECK([for __builtin_unwind_init],
3286                emacs_cv_func___builtin_unwind_init,
3287 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3288                 emacs_cv_func___builtin_unwind_init=yes,
3289                 emacs_cv_func___builtin_unwind_init=no)])
3290 if test $emacs_cv_func___builtin_unwind_init = yes; then
3291   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3292             [Define to 1 if you have the `__builtin_unwind_init' function.])
3293 fi
3294
3295 AC_CHECK_HEADERS_ONCE(sys/un.h)
3296
3297 AC_FUNC_FSEEKO
3298
3299 # UNIX98 PTYs.
3300 AC_CHECK_FUNCS(grantpt)
3301
3302 # PTY-related GNU extensions.
3303 AC_CHECK_FUNCS(getpt posix_openpt)
3304
3305 # Check this now, so that we will NOT find the above functions in ncurses.
3306 # That is because we have not set up to link ncurses in lib-src.
3307 # It's better to believe a function is not available
3308 # than to expect to find it in ncurses.
3309 # Also we need tputs and friends to be able to build at all.
3310 AC_MSG_CHECKING([for library containing tputs])
3311 # Run a test program that contains a call to tputs, a call that is
3312 # never executed.  This tests whether a pre-'main' dynamic linker
3313 # works with the library.  It's too much trouble to actually call
3314 # tputs in the test program, due to portability hassles.  When
3315 # cross-compiling, assume the test program will run if it links.
3316 AC_DEFUN([tputs_link_source], [
3317   AC_LANG_SOURCE(
3318      [[extern void tputs (const char *, int, int (*)(int));
3319        int main (int argc, char **argv)
3320        {
3321           if (argc == 10000)
3322             tputs (argv[0], 0, 0);
3323           return 0;
3324        }]])
3325 ])
3326 if test "${opsys}" = "mingw32"; then
3327   msg='none required'
3328 else
3329   # Maybe curses should be tried earlier?
3330   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3331   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3332     OLIBS=$LIBS
3333     if test -z "$tputs_library"; then
3334       LIBS_TERMCAP=
3335       msg='none required'
3336     else
3337       LIBS_TERMCAP=-l$tputs_library
3338       msg=$LIBS_TERMCAP
3339       LIBS="$LIBS_TERMCAP $LIBS"
3340     fi
3341     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3342       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3343     LIBS=$OLIBS
3344     if test "X$msg" != Xno; then
3345       break
3346     fi
3347   done
3348 fi
3349 AC_MSG_RESULT([$msg])
3350 if test "X$msg" = Xno; then
3351   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3352 The following libraries were tried (in order):
3353   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3354 Please try installing whichever of these libraries is most appropriate
3355 for your system, together with its header files.
3356 For example, a libncurses-dev(el) or similar package.])
3357 fi
3358
3359 ## Use termcap instead of terminfo?
3360 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3361 TERMINFO=yes
3362 ## FIXME?  In the cases below where we unconditionally set
3363 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3364 ## if that was found above to have tputs.
3365 ## Should we use the gnu* logic everywhere?
3366 case "$opsys" in
3367   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3368   ##  The ncurses library has been moved out of the System framework in
3369   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3370   ##  option to use it.
3371   darwin) LIBS_TERMCAP="-lncurses" ;;
3372
3373   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3374
3375   freebsd)
3376     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3377     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3378     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3379 [[#if __FreeBSD_version < 400000
3380 fail;
3381 #endif
3382 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3383
3384     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3385
3386     if test $emacs_cv_freebsd_terminfo = yes; then
3387       LIBS_TERMCAP="-lncurses"
3388     else
3389       TERMINFO=no
3390       LIBS_TERMCAP="-ltermcap"
3391     fi
3392     ;;
3393
3394   mingw32)
3395     TERMINFO=no
3396     LIBS_TERMCAP=
3397     ;;
3398
3399   netbsd)
3400     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3401       TERMINFO=no
3402       LIBS_TERMCAP="-ltermcap"
3403     fi
3404     ;;
3405
3406   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3407
3408   ## hpux: Make sure we get select from libc rather than from libcurses
3409   ##  because libcurses on HPUX 10.10 has a broken version of select.
3410   ##  We used to use -lc -lcurses, but this may be cleaner.
3411   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3412   # set that way, now it uses the default).  Isn't this a contradiction?
3413   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3414
3415 esac
3416
3417 TERMCAP_OBJ=tparam.o
3418 if test $TERMINFO = yes; then
3419   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3420   TERMCAP_OBJ=terminfo.o
3421 fi
3422 AC_SUBST(LIBS_TERMCAP)
3423 AC_SUBST(TERMCAP_OBJ)
3424
3425
3426 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3427 # On Darwin, res_init appears not to be useful: see bug#562 and
3428 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3429 resolv=no
3430
3431 if test $opsys != darwin; then
3432
3433   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3434 #include <arpa/nameser.h>
3435 #include <resolv.h>]],
3436     [[return res_init();]])],
3437     have_res_init=yes, have_res_init=no)
3438   if test "$have_res_init" = no; then
3439     OLIBS="$LIBS"
3440     LIBS="$LIBS -lresolv"
3441     AC_MSG_CHECKING(for res_init with -lresolv)
3442     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3443 #include <arpa/nameser.h>
3444 #include <resolv.h>]],
3445       [[return res_init();]])],
3446       have_res_init=yes, have_res_init=no)
3447     AC_MSG_RESULT($have_res_init)
3448     if test "$have_res_init" = yes ; then
3449       resolv=yes
3450     fi
3451     LIBS="$OLIBS"
3452   fi
3453
3454   if test "$have_res_init" = yes; then
3455     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3456   fi
3457 fi                              dnl !darwin
3458
3459 # Do we need the Hesiod library to provide the support routines?
3460 dnl FIXME?  Should we be skipping this on Darwin too?
3461 LIBHESIOD=
3462 if test "$with_hesiod" != no ; then
3463   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3464   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3465      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3466                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3467   if test "$resolv" = yes ; then
3468     RESOLVLIB=-lresolv
3469   else
3470     RESOLVLIB=
3471   fi
3472   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3473         hesiod=yes, :, $RESOLVLIB)])
3474
3475   if test x"$hesiod" = xyes; then
3476     LIBHESIOD=-lhesiod
3477   fi
3478 fi
3479 AC_SUBST(LIBHESIOD)
3480
3481 # Do we need libresolv (due to res_init or Hesiod)?
3482 if test "$resolv" = yes && test $opsys != darwin; then
3483   LIBRESOLV=-lresolv
3484 else
3485   LIBRESOLV=
3486 fi
3487 AC_SUBST(LIBRESOLV)
3488
3489 # These tell us which Kerberos-related libraries to use.
3490 COM_ERRLIB=
3491 CRYPTOLIB=
3492 KRB5LIB=
3493 DESLIB=
3494 KRB4LIB=
3495
3496 if test "${with_kerberos}" != no; then
3497   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3498   if test $have_com_err = yes; then
3499     COM_ERRLIB=-lcom_err
3500     LIBS="$COM_ERRLIB $LIBS"
3501   fi
3502   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3503   if test $have_crypto = yes; then
3504     CRYPTOLIB=-lcrypto
3505     LIBS="$CRYPTOLIB $LIBS"
3506   fi
3507   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3508   if test $have_k5crypto = yes; then
3509     CRYPTOLIB=-lk5crypto
3510     LIBS="$CRYPTOLIB $LIBS"
3511   fi
3512   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3513   if test $have_krb5=yes; then
3514     KRB5LIB=-lkrb5
3515     LIBS="$KRB5LIB $LIBS"
3516   fi
3517   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3518   if test "${with_kerberos5}" = no; then
3519     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3520     if test $have_des425 = yes; then
3521       DESLIB=-ldes425
3522       LIBS="$DESLIB $LIBS"
3523     else
3524       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3525       if test $have_des = yes; then
3526         DESLIB=-ldes
3527         LIBS="$DESLIB $LIBS"
3528       fi
3529     fi
3530     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3531     if test $have_krb4 = yes; then
3532       KRB4LIB=-lkrb4
3533       LIBS="$KRB4LIB $LIBS"
3534     else
3535       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3536       if test $have_krb = yes; then
3537         KRB4LIB=-lkrb
3538         LIBS="$KRB4LIB $LIBS"
3539       fi
3540     fi
3541   fi
3542
3543   if test "${with_kerberos5}" != no; then
3544     AC_CHECK_HEADERS(krb5.h,
3545       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3546                         [#include <krb5.h>])])
3547   else
3548     AC_CHECK_HEADERS(krb.h,,
3549                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3550                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3551   fi
3552   AC_CHECK_HEADERS(com_err.h)
3553 fi
3554
3555 AC_SUBST(COM_ERRLIB)
3556 AC_SUBST(CRYPTOLIB)
3557 AC_SUBST(KRB5LIB)
3558 AC_SUBST(DESLIB)
3559 AC_SUBST(KRB4LIB)
3560
3561 AC_CHECK_FUNCS_ONCE(tzset)
3562 AC_MSG_CHECKING(whether localtime caches TZ)
3563 AC_CACHE_VAL(emacs_cv_localtime_cache,
3564 [if test x$ac_cv_func_tzset = xyes; then
3565 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3566 char TZ_GMT0[] = "TZ=GMT0";
3567 char TZ_PST8[] = "TZ=PST8";
3568 main()
3569 {
3570   time_t now = time ((time_t *) 0);
3571   int hour_GMT0, hour_unset;
3572   if (putenv (TZ_GMT0) != 0)
3573     exit (1);
3574   hour_GMT0 = localtime (&now)->tm_hour;
3575   unsetenv("TZ");
3576   hour_unset = localtime (&now)->tm_hour;
3577   if (putenv (TZ_PST8) != 0)
3578     exit (1);
3579   if (localtime (&now)->tm_hour == hour_GMT0)
3580     exit (1);
3581   unsetenv("TZ");
3582   if (localtime (&now)->tm_hour != hour_unset)
3583     exit (1);
3584   exit (0);
3585 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3586 [# If we have tzset, assume the worst when cross-compiling.
3587 emacs_cv_localtime_cache=yes])
3588 else
3589         # If we lack tzset, report that localtime does not cache TZ,
3590         # since we can't invalidate the cache if we don't have tzset.
3591         emacs_cv_localtime_cache=no
3592 fi])dnl
3593 AC_MSG_RESULT($emacs_cv_localtime_cache)
3594 if test $emacs_cv_localtime_cache = yes; then
3595   AC_DEFINE(LOCALTIME_CACHE, 1,
3596             [Define to 1 if localtime caches TZ.])
3597 fi
3598
3599 ok_so_far=yes
3600 AC_CHECK_FUNC(socket, , ok_so_far=no)
3601 if test $ok_so_far = yes; then
3602   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3603 fi
3604 if test $ok_so_far = yes; then
3605   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3606 fi
3607 if test $ok_so_far = yes; then
3608 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3609   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3610             [Define to 1 if you have inet sockets.])
3611 fi
3612
3613 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3614 dnl This can be removed once we assume Autoconf 2.70.
3615 case $canonical in
3616   *-solaris2.4 | *-solaris2.4.*)
3617     dnl Disable the Autoconf-generated vfork test.
3618     : ${ac_cv_func_vfork_works=no};;
3619 esac
3620
3621 AC_FUNC_FORK
3622
3623 AC_CHECK_FUNCS(snprintf)
3624
3625 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3626 dnl Emacs uses.
3627 XGSELOBJ=
3628 AC_MSG_CHECKING([whether GLib is linked in])
3629 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3630         [[#include <glib.h>
3631         ]],
3632         [[g_print ("Hello world");]])],
3633      [links_glib=yes],
3634      [links_glib=no])
3635 AC_MSG_RESULT([$links_glib])
3636 if test "${links_glib}" = "yes"; then
3637   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3638   if test "$HAVE_NS" = no;then
3639     XGSELOBJ=xgselect.o
3640   fi
3641 fi
3642 AC_SUBST(XGSELOBJ)
3643
3644 dnl Adapted from Haible's version.
3645 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3646   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3647     [[char* cs = nl_langinfo(CODESET);]])],
3648     emacs_cv_langinfo_codeset=yes,
3649     emacs_cv_langinfo_codeset=no)
3650   ])
3651 if test $emacs_cv_langinfo_codeset = yes; then
3652   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3653     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3654 fi
3655
3656 AC_TYPE_MBSTATE_T
3657
3658 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3659   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3660                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3661 if test "$emacs_cv_c_restrict_arr" = yes; then
3662   AC_DEFINE(__restrict_arr, __restrict,
3663     [Define to compiler's equivalent of C99 restrict keyword in array
3664      declarations.  Define as empty for no equivalent.])
3665 fi
3666
3667 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3668 dnl how the tty code is related to POSIX and/or other versions of termios.
3669 dnl The following looks like a useful start.
3670 dnl
3671 dnl AC_SYS_POSIX_TERMIOS
3672 dnl if test $ac_cv_sys_posix_termios = yes; then
3673 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3674 dnl                                and macros for terminal control.])
3675 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3676 dnl fi
3677
3678 dnl Turned on June 1996 supposing nobody will mind it.
3679 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3680 if test "${opsys}" != "mingw32"; then
3681    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3682      in the full name stands for the login id.])
3683 fi
3684
3685 dnl Every platform that uses configure supports this.
3686 dnl There is a create-lockfiles option you can
3687 dnl customize if you do not want the lock files to be written.
3688 dnl So it is not clear that this #define still needs to exist.
3689 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3690   so that Emacs can tell instantly when you try to modify a file that
3691   someone else has modified in his/her Emacs.])
3692
3693 dnl Everybody supports this, except MS.
3694 dnl Seems like the kind of thing we should be testing for, though.
3695 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3696 if test "${opsys}" != "mingw32"; then
3697   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3698 fi
3699
3700 dnl Everybody supports this, except MS-DOS.
3701 dnl Seems like the kind of thing we should be testing for, though.
3702 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3703 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3704   4.2-compatible sockets.])
3705
3706 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3707
3708 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3709   a null file, or a data sink.])
3710 if test "${opsys}" = "mingw32"; then
3711   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3712 else
3713   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3714 fi
3715
3716 AH_TEMPLATE(SEPCHAR, [Character that separates PATH elements.])
3717 if test "${opsys}" = "mingw32"; then
3718   AC_DEFINE(SEPCHAR, [';'])
3719 else
3720   AC_DEFINE(SEPCHAR, [':'])
3721 fi
3722
3723 dnl Everybody supports this, except MS-DOS.
3724 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3725
3726 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3727
3728
3729 AC_DEFINE(DIRECTORY_SEP, ['/'],
3730   [Character that separates directories in a file name.])
3731
3732 if test "${opsys}" = "mingw32"; then
3733   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3734     [Returns true if character is a device separator.])
3735
3736   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3737     [Returns true if character is a directory separator.])
3738
3739   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3740     [Returns true if character is any form of separator.])
3741 else
3742   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3743     [Returns true if character is a device separator.])
3744
3745   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3746     [Returns true if character is a directory separator.])
3747
3748   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3749     [Returns true if character is any form of separator.])
3750 fi
3751
3752 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3753
3754 case $opsys in
3755   aix4-2)
3756     dnl Unfortunately without libXmu we cannot support EditRes.
3757     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3758       AC_DEFINE(NO_EDITRES, 1)
3759     fi
3760     ;;
3761
3762   hpux*)
3763     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3764     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3765     AC_DEFINE(NO_EDITRES, 1)
3766     ;;
3767 esac
3768
3769
3770 case $opsys in
3771   irix6-5 | sol2* | unixware )
3772     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3773     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3774     dnl need the constant to dimension an array.  So wire in the appropriate
3775     dnl value here.
3776     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3777     ;;
3778 esac
3779
3780 emacs_broken_SIGIO=no
3781
3782 case $opsys in
3783   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3784   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3785   hpux* | irix6-5 | openbsd | sol2* | unixware | gnu-kfreebsd )
3786     emacs_broken_SIGIO=yes
3787     ;;
3788
3789   aix4-2)
3790     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3791     dnl the way this system works, libc functions that return malloced
3792     dnl memory use the libc malloc implementation. Calling xfree or
3793     dnl xrealloc on the results of such functions results in a crash.
3794     dnl
3795     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3796     dnl but that does not currently work on this system.
3797     dnl
3798     dnl It is possible to completely override the malloc implementation on
3799     dnl AIX, but that involves putting the malloc functions in a shared
3800     dnl library and setting the MALLOCTYPE environment variable to point to
3801     dnl that shared library.
3802     dnl
3803     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3804     dnl to avoid a crash just use the Emacs implementation for that function.
3805     dnl
3806     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3807     dnl of this file, so that we do not check for get_current_dir_name
3808     dnl on AIX.  But that might be fragile if something else ends
3809     dnl up testing for get_current_dir_name as a dependency.
3810     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3811       get_current_dir_name should not be used.])
3812     ;;
3813
3814   freebsd)
3815     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3816     dnl writes/reads on a PTY, read(2) returns bogus data:
3817     dnl
3818     dnl write(2)  1022 bytes
3819     dnl write(2)   954 bytes, get EAGAIN
3820     dnl read(2)   1024 bytes in process_read_output
3821     dnl read(2)     11 bytes in process_read_output
3822     dnl
3823     dnl That is, read(2) returns more bytes than have ever been written
3824     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3825     dnl successfully after processing (for example with CRs added if the
3826     dnl terminal is set up that way which it is here).  The same bytes will
3827     dnl be seen again in a later read(2), without the CRs.
3828     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3829       work around an issue when reading from a PTY.])
3830     ;;
3831 esac
3832
3833 case $opsys in
3834   gnu-* | sol2-10 )
3835     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3836     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3837   ;;
3838 esac
3839
3840 case $opsys in
3841   darwin | dragonfly | freebsd | netbsd | openbsd )
3842     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3843       close a pty to make it a controlling terminal (it is already a
3844       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3845   ;;
3846 esac
3847
3848 dnl FIXME Surely we can test for this rather than hard-code it.
3849 case $opsys in
3850   netbsd | openbsd) sound_device="/dev/audio" ;;
3851   *) sound_device="/dev/dsp" ;;
3852 esac
3853
3854 dnl Used in sound.c
3855 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3856   [Name of the default sound device.])
3857
3858
3859 dnl Emacs can read input using SIGIO and buffering characters itself,
3860 dnl or using CBREAK mode and making C-g cause SIGINT.
3861 dnl The choice is controlled by the variable interrupt_input.
3862 dnl
3863 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3864 dnl
3865 dnl Emacs uses the presence of the USABLE_SIGIO macro
3866 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3867 dnl INTERRUPT_INPUT to decide whether to use it by default.
3868 dnl
3869 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3870 dnl CBREAK mode has two disadvantages
3871 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3872 dnl I hear that in system V this problem does not exist.
3873 dnl 2) Control-G causes output to be discarded.
3874 dnl I do not know whether this can be fixed in system V.
3875 dnl
3876 dnl Another method of doing input is planned but not implemented.
3877 dnl It would have Emacs fork off a separate process
3878 dnl to read the input and send it to the true Emacs process
3879 dnl through a pipe.
3880 case $opsys in
3881   darwin | gnu-linux | gnu-kfreebsd )
3882     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3883   ;;
3884 esac
3885
3886
3887 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3888 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3889 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3890 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3891 dnl taking float or double parameters.
3892 case $opsys in
3893   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3894     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3895       file defines `NeedWidePrototypes' as `NO'.])
3896   ;;
3897 esac
3898
3899
3900 dnl Used in process.c, this must be a loop, even if it only runs once.
3901 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3902 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3903 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3904 dnl trying suffixes 0-16.
3905 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3906   first PTY, if PTYs are supported.])
3907 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3908 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3909   end of a PTY, if non-standard.])
3910 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3911   end of a PTY, if non-standard.])
3912
3913 case $opsys in
3914   aix4-2 )
3915     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3916     dnl You allocate a pty by opening /dev/ptc to get the master side.
3917     dnl To get the name of the slave side, you just ttyname() the master side.
3918     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3919     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3920     ;;
3921
3922   cygwin )
3923     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3924     dnl multi-line AC_DEFINEs are hard. :(
3925     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3926     AC_DEFINE(PTY_NAME_SPRINTF, [])
3927     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3928     ;;
3929
3930   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3931   darwin )
3932     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3933     dnl Not used, because PTY_ITERATION is defined.
3934     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3935     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3936     dnl But we don't have to block SIGCHLD because it is blocked in the
3937     dnl implementation of grantpt.
3938     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3939     AC_DEFINE(PTY_NAME_SPRINTF, [])
3940     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3941     ;;
3942
3943   gnu | openbsd )
3944     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3945     ;;
3946
3947   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
3948     dnl if HAVE_GRANTPT
3949     if test "x$ac_cv_func_grantpt" = xyes; then
3950       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3951       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3952       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3953       dnl to prevent sigchld_handler from intercepting the child's death.
3954       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3955       dnl if HAVE_POSIX_OPENPT
3956       if test "x$ac_cv_func_posix_openpt" = xyes; then
3957         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY)])
3958         AC_DEFINE(PTY_NAME_SPRINTF, [])
3959       dnl if HAVE_GETPT
3960       elif test "x$ac_cv_func_getpt" = xyes; then
3961         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3962         AC_DEFINE(PTY_NAME_SPRINTF, [])
3963       else
3964         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3965       fi
3966     else
3967       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3968     fi
3969     ;;
3970
3971   hpux*)
3972     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3973     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3974     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3975     ;;
3976
3977   irix6-5 )
3978     dnl It looks like this cannot be right, because it is not a loop.
3979     dnl However, process.c actually does this:
3980     dnl # ifndef __sgi
3981     dnl   continue;
3982     dnl # else
3983     dnl   return -1;
3984     dnl # endif
3985     dnl which presumably makes it OK, since irix == sgi (?).
3986     dnl FIXME it seems like this special treatment is unnecessary?
3987     dnl Why can't irix use a single-trip loop like eg cygwin?
3988     AC_DEFINE(PTY_ITERATION, [])
3989     dnl Not used, because PTY_ITERATION is defined.
3990     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3991     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3992     dnl No need to get the pty name at all.
3993     AC_DEFINE(PTY_NAME_SPRINTF, [])
3994     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3995     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3996     ;;
3997
3998   sol2* )
3999     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4000     dnl from intercepting that death.  If any child but grantpt's should die
4001     dnl within, it should be caught after sigrelse(2).
4002     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
4003     ;;
4004
4005   unixware )
4006     dnl Comments are as per sol2*.
4007     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
4008     ;;
4009 esac
4010
4011
4012 case $opsys in
4013   sol2* | unixware )
4014     dnl This change means that we don't loop through allocate_pty too
4015     dnl many times in the (rare) event of a failure.
4016     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4017     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4018     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4019     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4020     ;;
4021 esac
4022
4023
4024 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4025 "typing" a signal character on the pty.])
4026
4027 case $opsys in
4028   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4029   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4030   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4031     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4032     ;;
4033
4034   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4035   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4036   gnu-linux | gnu-kfreebsd )
4037
4038     AC_MSG_CHECKING([for signals via characters])
4039     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4040 #include <linux/version.h>
4041 #if LINUX_VERSION_CODE < 0x20400
4042 # error "Linux version too old"
4043 #endif
4044       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4045
4046     AC_MSG_RESULT([$emacs_signals_via_chars])
4047     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4048     ;;
4049 esac
4050
4051
4052 dnl Used in lisp.h, emacs.c, vm-limit.c
4053 dnl NEWS.18 describes this as "a number which contains
4054 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4055 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4056 stored in a Lisp_Object.])
4057 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4058
4059 case $opsys in
4060   aix*)
4061     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4062     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4063     ;;
4064   hpux*)
4065     dnl The data segment on this machine always starts at address 0x40000000.
4066     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4067     ;;
4068   irix6-5)
4069     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4070     ;;
4071 esac
4072
4073
4074 AH_TEMPLATE(TAB3, [Undocumented.])
4075
4076 case $opsys in
4077   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4078
4079   gnu | dragonfly | freebsd | netbsd | openbsd )
4080     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4081     AC_DEFINE(TAB3, OXTABS)
4082     ;;
4083
4084   gnu-linux | gnu-kfreebsd )
4085     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4086 #ifndef __ia64__
4087 # error "not ia64"
4088 #endif
4089       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4090         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
4091         [Mark a secondary stack, like the register stack on the ia64.]), [])
4092     ;;
4093
4094   hpux*)
4095     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4096       run_time_remap; for HPUX.])
4097     ;;
4098 esac
4099
4100
4101 dnl This won't be used automatically yet.  We also need to know, at least,
4102 dnl that the stack is continuous.
4103 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4104   registers relevant for conservative garbage collection in the jmp_buf.])
4105
4106
4107 case $opsys in
4108   dnl Not all the architectures are tested, but there are Debian packages
4109   dnl for SCM and/or Guile on them, so the technique must work.  See also
4110   dnl comments in alloc.c concerning setjmp and gcc.
4111   dnl Fixme: it's probably safe to just use the GCC conditional below.
4112   gnu-linux | gnu-kfreebsd )
4113     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4114 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4115   || defined __alpha__ || defined __mips__ || defined __s390__ \
4116   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4117   || defined __ia64__ || defined __sh__
4118 /* ok */
4119 #else
4120 # error "setjmp not known to work on this arch"
4121 #endif
4122     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4123     ;;
4124 esac
4125
4126
4127 if test x$GCC = xyes; then
4128    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4129    AC_DEFINE(GC_SETJMP_WORKS, 1)
4130 else
4131   case $opsys in
4132     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4133     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4134       AC_DEFINE(GC_SETJMP_WORKS, 1)
4135       ;;
4136   esac
4137 fi                              dnl GCC?
4138
4139 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4140 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4141   [AC_LINK_IFELSE(
4142      [AC_LANG_PROGRAM(
4143        [[#include <setjmp.h>
4144          #ifdef __MINGW32__
4145          # define _longjmp longjmp
4146          #endif
4147        ]],
4148        [[jmp_buf j;
4149          if (! _setjmp (j))
4150            _longjmp (j, 1);]])],
4151      [emacs_cv_func__setjmp=yes],
4152      [emacs_cv_func__setjmp=no])])
4153 if test $emacs_cv_func__setjmp = yes; then
4154   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4155 else
4156   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4157     [AC_LINK_IFELSE(
4158        [AC_LANG_PROGRAM(
4159          [[#include <setjmp.h>
4160          ]],
4161          [[sigjmp_buf j;
4162            if (! sigsetjmp (j, 1))
4163              siglongjmp (j, 1);]])],
4164        [emacs_cv_func_sigsetjmp=yes],
4165        [emacs_cv_func_sigsetjmp=no])])
4166   if test $emacs_cv_func_sigsetjmp = yes; then
4167     AC_DEFINE([HAVE_SIGSETJMP], 1,
4168       [Define to 1 if sigsetjmp and siglongjmp work.
4169        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4170   fi
4171 fi
4172
4173 case $opsys in
4174   sol2* | unixware )
4175     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4176     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4177     dnl and this is all we need.
4178     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4179     ;;
4180 esac
4181
4182
4183 case $opsys in
4184   hpux* | sol2* )
4185     dnl Used in xfaces.c.
4186     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4187       some systems, where it requires time.h.])
4188     ;;
4189 esac
4190
4191
4192 dnl Define symbols to identify the version of Unix this is.
4193 dnl Define all the symbols that apply correctly.
4194 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4195 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4196 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4197 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4198
4199 case $opsys in
4200   aix4-2)
4201     AC_DEFINE(USG, [])
4202     dnl This symbol should be defined on AIX Version 3  ???????
4203     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4204 #ifndef _AIX
4205 # error "_AIX not defined"
4206 #endif
4207     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4208     ;;
4209
4210   cygwin)
4211     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4212     ;;
4213
4214   darwin)
4215     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4216     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4217     dnl distinguish OS X from pure Darwin.
4218     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4219     ;;
4220
4221   gnu-linux | gnu-kfreebsd )
4222     AC_DEFINE(USG, [])
4223     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4224     ;;
4225
4226   hpux*)
4227     AC_DEFINE(USG, [])
4228     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4229     ;;
4230
4231   irix6-5)
4232     AC_DEFINE(USG, [])
4233     AC_DEFINE(USG5_4, [])
4234     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4235     ;;
4236
4237   mingw32)
4238     AC_DEFINE(DOS_NT, [])
4239     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4240     if test "x$ac_enable_checking" != "x" ; then
4241       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4242     fi
4243     ;;
4244
4245   sol2*)
4246     AC_DEFINE(USG, [])
4247     AC_DEFINE(USG5_4, [])
4248     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4249     ;;
4250
4251   unixware)
4252     AC_DEFINE(USG, [])
4253     AC_DEFINE(USG5_4, [])
4254     ;;
4255 esac
4256
4257 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4258   [case $opsys in
4259      aix4-2)
4260        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4261        emacs_cv_usable_FIONREAD=no
4262        ;;
4263
4264      mingw32)
4265        emacs_cv_usable_FIONREAD=yes
4266        ;;
4267
4268      *)
4269        AC_COMPILE_IFELSE(
4270          [AC_LANG_PROGRAM([[#include <sys/types.h>
4271                             #include <sys/ioctl.h>
4272                             #ifdef USG5_4
4273                             # include <sys/filio.h>
4274                             #endif
4275                           ]],
4276                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4277          [emacs_cv_usable_FIONREAD=yes],
4278          [emacs_cv_usable_FIONREAD=no])
4279        ;;
4280    esac])
4281 if test $emacs_cv_usable_FIONREAD = yes; then
4282   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4283
4284   if test $emacs_broken_SIGIO = no; then
4285     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4286       [AC_COMPILE_IFELSE(
4287          [AC_LANG_PROGRAM([[#include <fcntl.h>
4288                             #include <signal.h>
4289                           ]],
4290                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4291          [emacs_cv_usable_SIGIO=yes],
4292          [emacs_cv_usable_SIGIO=no])],
4293       [emacs_cv_usable_SIGIO=yes],
4294       [emacs_cv_usable_SIGIO=no])
4295     if test $emacs_cv_usable_SIGIO = yes; then
4296       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4297     fi
4298   fi
4299 fi
4300
4301
4302 case $opsys in
4303   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
4304   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
4305   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
4306   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
4307   cygwin)
4308     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4309       G_SLICE environment variable to "always-malloc" at startup, if
4310       using GTK.])
4311     ;;
4312
4313   hpux11)
4314     dnl It works to open the pty's tty in the parent (Emacs), then
4315     dnl close and reopen it in the child.
4316     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4317       works to open a pty's tty in the parent process, then close and
4318       reopen it in the child.])
4319     ;;
4320
4321   irix6-5)
4322     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4323       use VSUSP instead of VSWTCH.])
4324     ;;
4325
4326   sol2-10)
4327     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4328       on Solaris.])
4329     ;;
4330 esac
4331
4332 # Set up the CFLAGS for real compilation, so we can substitute it.
4333 CFLAGS="$REAL_CFLAGS"
4334 CPPFLAGS="$REAL_CPPFLAGS"
4335
4336 ## Hack to detect a buggy GCC version.
4337 if test "x$GCC" = xyes \
4338    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4339    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4340    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4341    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4342 fi
4343
4344 version=$PACKAGE_VERSION
4345
4346 copyright="Copyright (C) 2013 Free Software Foundation, Inc."
4347 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4348   [Short copyright string for this version of Emacs.])
4349 AC_SUBST(copyright)
4350
4351 ### Specify what sort of things we'll be editing into Makefile and config.h.
4352 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4353 AC_SUBST(version)
4354 AC_SUBST(configuration)
4355 ## Unused?
4356 AC_SUBST(canonical)
4357 AC_SUBST(srcdir)
4358 AC_SUBST(prefix)
4359 AC_SUBST(exec_prefix)
4360 AC_SUBST(bindir)
4361 AC_SUBST(datadir)
4362 AC_SUBST(sharedstatedir)
4363 AC_SUBST(libexecdir)
4364 AC_SUBST(mandir)
4365 AC_SUBST(infodir)
4366 AC_SUBST(lispdir)
4367 AC_SUBST(leimdir)
4368 AC_SUBST(standardlisppath)
4369 AC_SUBST(locallisppath)
4370 AC_SUBST(lisppath)
4371 AC_SUBST(x_default_search_path)
4372 AC_SUBST(etcdir)
4373 AC_SUBST(archlibdir)
4374 AC_SUBST(docdir)
4375 AC_SUBST(bitmapdir)
4376 AC_SUBST(gamedir)
4377 AC_SUBST(gameuser)
4378 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4379 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4380 ## end of LIBX_BASE, but nothing ever set it.
4381 AC_SUBST(LD_SWITCH_X_SITE)
4382 AC_SUBST(C_SWITCH_X_SITE)
4383 AC_SUBST(GNUSTEP_CFLAGS)
4384 AC_SUBST(CFLAGS)
4385 ## Used in lwlib/Makefile.in.
4386 AC_SUBST(X_TOOLKIT_TYPE)
4387 AC_SUBST(ns_appdir)
4388 AC_SUBST(ns_appbindir)
4389 AC_SUBST(ns_appresdir)
4390 AC_SUBST(ns_appsrc)
4391 AC_SUBST(GNU_OBJC_CFLAGS)
4392 AC_SUBST(OTHER_FILES)
4393
4394 if test -n "${term_header}"; then
4395     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4396         [Define to the header for the built-in window system.])
4397 fi
4398
4399 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4400                    [Define to the canonical Emacs configuration name.])
4401 dnl Replace any embedded " characters (bug#13274).
4402 emacs_config_options=`echo "$emacs_config_options " | sed -e 's/--no-create //' -e 's/--no-recursion //' -e 's/ *$//' -e "s/\"/'/g"`
4403 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4404                    [Define to the options passed to configure.])
4405 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4406   define this to include extra configuration information.])
4407
4408 case $opsys in
4409   mingw32)
4410     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4411     ;;
4412 esac
4413
4414 XMENU_OBJ=
4415 XOBJ=
4416 FONT_OBJ=
4417 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4418   AC_DEFINE(HAVE_X_WINDOWS, 1,
4419             [Define to 1 if you want to use the X window system.])
4420   XMENU_OBJ=xmenu.o
4421   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4422   FONT_OBJ=xfont.o
4423   if test "$HAVE_XFT" = "yes"; then
4424     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4425   elif test "$HAVE_FREETYPE" = "yes"; then
4426     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4427   fi
4428   AC_SUBST(FONT_OBJ)
4429 fi
4430 AC_SUBST(XMENU_OBJ)
4431 AC_SUBST(XOBJ)
4432 AC_SUBST(FONT_OBJ)
4433
4434 WIDGET_OBJ=
4435 MOTIF_LIBW=
4436 if test "${USE_X_TOOLKIT}" != "none" ; then
4437   WIDGET_OBJ=widget.o
4438   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4439   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4440     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4441   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4442     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4443     MOTIF_LIBW=-lXm
4444     case "$opsys" in
4445       gnu-linux)
4446         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4447         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4448         ;;
4449
4450       unixware)
4451         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4452         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4453         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4454         ;;
4455
4456       aix4-2)
4457         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4458         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4459         ;;
4460     esac
4461     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4462   fi
4463 fi
4464 AC_SUBST(WIDGET_OBJ)
4465
4466 TOOLKIT_LIBW=
4467 case "$USE_X_TOOLKIT" in
4468   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4469   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4470   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4471 esac
4472 AC_SUBST(TOOLKIT_LIBW)
4473
4474 if test "${opsys}" != "mingw32"; then
4475   if test "$USE_X_TOOLKIT" = "none"; then
4476     LIBXT_OTHER="\$(LIBXSM)"
4477     OLDXMENU_TARGET="really-oldXMenu"
4478   else
4479     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4480     OLDXMENU_TARGET="really-lwlib"
4481   fi
4482 fi
4483 AC_SUBST(LIBXT_OTHER)
4484
4485 ## The X Menu stuff is present in the X10 distribution, but missing
4486 ## from X11.  If we have X10, just use the installed library;
4487 ## otherwise, use our own copy.
4488 if test "${HAVE_X11}" = "yes" ; then
4489   AC_DEFINE(HAVE_X11, 1,
4490             [Define to 1 if you want to use version 11 of X windows.
4491              Otherwise, Emacs expects to use version 10.])
4492
4493   if test "$USE_X_TOOLKIT" = "none"; then
4494     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4495   else
4496     OLDXMENU="\${lwlibdir}/liblw.a"
4497   fi
4498   LIBXMENU="\$(OLDXMENU)"
4499   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4500   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4501 else
4502   ## For a syntactically valid Makefile; not actually used for anything.
4503   ## See comments in src/Makefile.in.
4504   OLDXMENU=nothing
4505   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4506   if test "${HAVE_X_WINDOWS}" = "yes"; then
4507     LIBXMENU="-lXMenu"
4508   else
4509     LIBXMENU=
4510   fi
4511   LIBX_OTHER=
4512   OLDXMENU_DEPS=
4513 fi
4514
4515 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4516   OLDXMENU_TARGET=
4517   OLDXMENU=nothing
4518   LIBXMENU=
4519   OLDXMENU_DEPS=
4520 fi
4521
4522 AC_SUBST(OLDXMENU_TARGET)
4523 AC_SUBST(OLDXMENU)
4524 AC_SUBST(LIBXMENU)
4525 AC_SUBST(LIBX_OTHER)
4526 AC_SUBST(OLDXMENU_DEPS)
4527
4528 if test "${HAVE_MENUS}" = "yes" ; then
4529   AC_DEFINE(HAVE_MENUS, 1,
4530             [Define to 1 if you have mouse menus.
4531              (This is automatic if you use X, but the option to specify it remains.)
4532              It is also defined with other window systems that support xmenu.c.])
4533 fi
4534
4535 if test "${GNU_MALLOC}" = "yes" ; then
4536   AC_DEFINE(GNU_MALLOC, 1,
4537             [Define to 1 if you want to use the GNU memory allocator.])
4538 fi
4539
4540 RALLOC_OBJ=
4541 if test "${REL_ALLOC}" = "yes" ; then
4542   AC_DEFINE(REL_ALLOC, 1,
4543             [Define REL_ALLOC if you want to use the relocating allocator for
4544              buffer space.])
4545
4546   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4547 fi
4548 AC_SUBST(RALLOC_OBJ)
4549
4550 if test "$opsys" = "cygwin"; then
4551   CYGWIN_OBJ="sheap.o cygw32.o"
4552   ## Cygwin differs because of its unexec().
4553   PRE_ALLOC_OBJ=
4554   POST_ALLOC_OBJ=lastfile.o
4555 elif test "$opsys" = "mingw32"; then
4556   CYGWIN_OBJ=
4557   PRE_ALLOC_OBJ=
4558   POST_ALLOC_OBJ=lastfile.o
4559 else
4560   CYGWIN_OBJ=
4561   PRE_ALLOC_OBJ=lastfile.o
4562   POST_ALLOC_OBJ=
4563 fi
4564 AC_SUBST(CYGWIN_OBJ)
4565 AC_SUBST(PRE_ALLOC_OBJ)
4566 AC_SUBST(POST_ALLOC_OBJ)
4567
4568 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4569 # it temporarily reverts them to their pre-pkg-config values,
4570 # because gnulib needs to work with both src (which uses the
4571 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4572 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4573 # and it therefore needs to run in an environment where LIBS does not
4574 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4575 # for some package unrelated to lib-src.
4576 SAVE_CFLAGS=$CFLAGS
4577 SAVE_LIBS=$LIBS
4578 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4579 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4580 gl_ASSERT_NO_GNULIB_POSIXCHECK
4581 gl_ASSERT_NO_GNULIB_TESTS
4582 gl_INIT
4583 CFLAGS=$SAVE_CFLAGS
4584 LIBS=$SAVE_LIBS
4585
4586 if test "${opsys}" = "mingw32"; then
4587   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I $srcdir/nt/inc"
4588   # Remove unneeded switches from the value of CC that goes to Makefiles
4589   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4590 fi
4591
4592 case "$opsys" in
4593   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4594
4595   darwin)
4596    ## The -headerpad option tells ld (see man page) to leave room at the
4597    ## end of the header for adding load commands.  Needed for dumping.
4598    ## 0x690 is the total size of 30 segment load commands (at 56
4599    ## each); under Cocoa 31 commands are required.
4600    if test "$HAVE_NS" = "yes"; then
4601      libs_nsgui="-framework AppKit"
4602      if test "$NS_IMPL_COCOA" = "yes"; then
4603         libs_nsgui="$libs_nsgui -framework IOKit"
4604      fi
4605      headerpad_extra=6C8
4606    else
4607      libs_nsgui=
4608      headerpad_extra=690
4609    fi
4610    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4611
4612    ## This is here because src/Makefile.in did some extra fiddling around
4613    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4614    ## LD_SWITCH_SYSTEM_TEMACS instead,
4615    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4616      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4617    ;;
4618
4619   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4620   ## find X at run-time.
4621   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4622   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4623   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4624   ## had different values in configure (in ac_link) and src/Makefile.in.
4625   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4626   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4627
4628   mingw32)
4629    ## MinGW64 does not prepend an underscore to symbols, so we must
4630    ## pass a different -entry switch to linker.  FIXME: It is better
4631    ## to make the entry points the same by changing unexw32.c.
4632    case "$canonical" in
4633      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,_start -Wl,-Map,./temacs.map" ;;
4634      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4635    esac
4636    ;;
4637
4638   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4639
4640   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4641 esac
4642
4643 if test x$ac_enable_profiling != x ; then
4644   case $opsys in
4645     *freebsd | gnu-linux) ;;
4646     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4647   esac
4648 fi
4649
4650 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4651
4652 ## MinGW-specific post-link processing of temacs.
4653 TEMACS_POST_LINK=":"
4654 ADDSECTION=
4655 EMACS_HEAPSIZE=
4656 if test "${opsys}" = "mingw32"; then
4657   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4658   ADDSECTION="../nt/addsection\$(EXEEXT)"
4659   ## Preload heap size of temacs.exe in MB.
4660   case "$canonical" in
4661     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4662     *) EMACS_HEAPSIZE=27 ;;
4663   esac
4664 fi
4665
4666 AC_SUBST(ADDSECTION)
4667 AC_SUBST(TEMACS_POST_LINK)
4668 AC_SUBST(EMACS_HEAPSIZE)
4669
4670 ## Common for all window systems
4671 if test "$window_system" != "none"; then
4672   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4673   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4674 fi
4675
4676 AC_SUBST(WINDOW_SYSTEM_OBJ)
4677
4678 AH_TOP([/* GNU Emacs site configuration template file.
4679
4680 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2013
4681   Free Software Foundation, Inc.
4682
4683 This file is part of GNU Emacs.
4684
4685 GNU Emacs is free software: you can redistribute it and/or modify
4686 it under the terms of the GNU General Public License as published by
4687 the Free Software Foundation, either version 3 of the License, or
4688 (at your option) any later version.
4689
4690 GNU Emacs is distributed in the hope that it will be useful,
4691 but WITHOUT ANY WARRANTY; without even the implied warranty of
4692 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4693 GNU General Public License for more details.
4694
4695 You should have received a copy of the GNU General Public License
4696 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4697
4698
4699 /* No code in Emacs #includes config.h twice, but some bits of code
4700    intended to work with other packages as well (like gmalloc.c)
4701    think they can include it as many times as they like.  */
4702 #ifndef EMACS_CONFIG_H
4703 #define EMACS_CONFIG_H
4704 ])dnl
4705
4706 AH_BOTTOM([#include <conf_post.h>
4707
4708 #endif /* EMACS_CONFIG_H */
4709
4710 /*
4711 Local Variables:
4712 mode: c
4713 End:
4714 */
4715 ])dnl
4716
4717 #### Report on what we decided to do.
4718 #### Report GTK as a toolkit, even if it doesn't use Xt.
4719 #### It makes printing result more understandable as using GTK sets
4720 #### toolkit_scroll_bars to yes by default.
4721 if test "${HAVE_GTK}" = "yes"; then
4722   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4723 fi
4724
4725 if test $USE_ACL -ne 0; then
4726   acl_summary="yes $LIB_ACL"
4727 else
4728   acl_summary=no
4729 fi
4730
4731 echo "
4732 Configured for \`${canonical}'.
4733
4734   Where should the build process find the source code?    ${srcdir}
4735   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4736   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4737   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4738   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4739   What window system should Emacs use?                    ${window_system}
4740   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4741
4742 if test -n "${x_includes}"; then
4743 echo "  Where do we find X Windows header files?                ${x_includes}"
4744 else
4745 echo "  Where do we find X Windows header files?                Standard dirs"
4746 fi
4747 if test -n "${x_libraries}"; then
4748 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4749 else
4750 echo "  Where do we find X Windows libraries?                   Standard dirs"
4751 fi
4752
4753 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4754 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4755 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4756 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4757 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4758 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4759 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4760 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4761
4762 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4763 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4764 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4765 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4766 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
4767 echo "  Does Emacs use access control lists?                    ${acl_summary}"
4768 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4769 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4770 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4771
4772 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4773 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4774 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4775 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4776
4777 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4778 echo
4779
4780 if test -n "${EMACSDATA}"; then
4781    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4782 fi
4783 if test -n "${EMACSDOC}"; then
4784    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4785 fi
4786
4787 echo
4788
4789 if test "$HAVE_NS" = "yes"; then
4790    echo
4791    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4792 The installed application will go to nextstep/Emacs.app and can be
4793 run or moved from there."
4794    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4795       echo "The application will be fully self-contained."
4796     else
4797       echo "The lisp resources for the application will be installed under ${prefix}.
4798 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4799 to run if these resources are not installed."
4800    fi
4801    echo
4802 fi
4803
4804 if test "${opsys}" = "cygwin"; then
4805   case `uname -r` in
4806     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4807            echo
4808            ;;
4809   esac
4810 fi
4811
4812 # Remove any trailing slashes in these variables.
4813 [test "${prefix}" != NONE &&
4814   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4815 test "${exec_prefix}" != NONE &&
4816   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4817
4818 if test "$HAVE_NS" = "yes"; then
4819   if test "$NS_IMPL_GNUSTEP" = yes; then
4820     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4821       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4822   else
4823     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4824       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4825   fi
4826 fi
4827
4828 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4829 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4830 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4831 dnl (else you get "no `Makefile.am' found for any configure output").
4832 dnl This will work, but you get a config.status that is not quite right
4833 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4834 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4835 dnl it seems better to just live with the duplication.
4836 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
4837
4838 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4839        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4840        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4841        leim/Makefile nextstep/Makefile nt/Makefile])
4842
4843 dnl test/ is not present in release tarfiles.
4844 opt_makefile=test/automated/Makefile
4845
4846 if test -f "$srcdir/$opt_makefile.in"; then
4847   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4848   dnl Again, it's best not to use a variable.  Though you can add
4849   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4850   AC_CONFIG_FILES([test/automated/Makefile])
4851 fi
4852
4853
4854 dnl admin/ may or may not be present.
4855 opt_makefile=admin/unidata/Makefile
4856
4857 if test -f "$srcdir/$opt_makefile.in"; then
4858   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4859   AC_CONFIG_FILES([admin/unidata/Makefile])
4860 fi
4861
4862
4863 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4864
4865 AC_SUBST(SUBDIR_MAKEFILES_IN)
4866
4867 dnl Make the necessary directories, if they don't exist.
4868 AC_CONFIG_COMMANDS([mkdirs], [
4869 for dir in etc lisp ; do
4870   test -d ${dir} || mkdir ${dir}
4871 done
4872 ])
4873
4874 dnl You might wonder (I did) why epaths.h is generated by running make,
4875 dnl rather than just letting configure generate it from epaths.in.
4876 dnl One reason is that the various paths are not fully expanded (see above);
4877 dnl eg gamedir=${prefix}/var/games/emacs.
4878 dnl Secondly, the GNU Coding standards require that one should be able
4879 dnl to run `make prefix=/some/where/else' and override the values set
4880 dnl by configure.  This also explains the `move-if-change' test and
4881 dnl the use of force in the `epaths-force' rule in Makefile.in.
4882 AC_CONFIG_COMMANDS([epaths], [
4883 echo creating src/epaths.h
4884 if test "${opsys}" = "mingw32"; then
4885   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
4886 else
4887   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4888 fi
4889 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
4890
4891 AC_CONFIG_COMMANDS([gdbinit], [
4892 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
4893   echo creating src/.gdbinit
4894   echo "source $srcdir/src/.gdbinit" > src/.gdbinit
4895 fi
4896 ])
4897
4898 AC_OUTPUT