lisp/calendar/appt.el

   1 ;;; appt.el --- appointment notification functions
   2
   3 ;; Copyright (C) 1989-1990, 1994, 1998, 2001-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Neil Mager <neilm@juliet.ll.mit.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Package: calendar
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;
  29 ;; appt.el - visible and/or audible notification of
  30 ;;           appointments from diary file.
  31 ;;
  32 ;;
  33 ;; Thanks to  Edward M. Reingold for much help and many suggestions,
  34 ;; And to many others for bug fixes and suggestions.
  35 ;;
  36 ;;
  37 ;; This functions in this file will alert the user of a
  38 ;; pending appointment based on his/her diary file.  This package
  39 ;; is documented in the Emacs manual.
  40 ;;
  41 ;; To activate this package, simply use (appt-activate 1).
  42 ;; A `diary-file' with appointments of the format described in the
  43 ;; documentation of the function `appt-check' is required.
  44 ;; Relevant customizable variables are also listed in the
  45 ;; documentation of that function.
  46 ;;
  47 ;; Today's appointment list is initialized from the diary when this
  48 ;; package is activated.  Additionally, the appointments list is
  49 ;; recreated automatically at 12:01am for those who do not logout
  50 ;; every day or are programming late.  It is also updated when the
  51 ;; `diary-file' (or a file it includes) is saved.  Calling
  52 ;; `appt-check' with an argument (or re-enabling the package) forces a
  53 ;; re-initialization at any time.
  54 ;;
  55 ;; In order to add or delete items from today's list, without
  56 ;; changing the diary file, use `appt-add' and `appt-delete'.
  57 ;;
  58
  59 ;; Brief internal description - Skip this if you are not interested!
  60 ;;
  61 ;; The function `appt-make-list' creates the appointments list which
  62 ;; `appt-check' reads.
  63 ;;
  64 ;; You can change the way the appointment window is created/deleted by
  65 ;; setting the variables `appt-disp-window-function' and
  66 ;; `appt-delete-window-function'.  For instance, you could be set them
  67 ;; to functions that display appointments in pop-up frames, which are
  68 ;; lowered or iconified after `appt-display-interval' minutes.
  69 ;;
  70
  71 ;;; Code:
  72
  73 (require 'diary-lib)
  74
  75
  76 (defgroup appt nil
  77   "Appointment notification."
  78   :prefix "appt-"
  79   :group 'calendar)
  80
  81 (defcustom appt-message-warning-time 12
  82   "Default time in minutes before an appointment that the warning begins.
  83 You probably want to make `appt-display-interval' a factor of this."
  84   :type 'integer
  85   :group 'appt)
  86
  87 (defcustom appt-warning-time-regexp "warntime \\([0-9]+\\)"
  88   "Regexp matching a string giving the warning time for an appointment.
  89 The first subexpression matches the time in minutes (an integer).
  90 This overrides the default `appt-message-warning-time'.
  91 You may want to put this inside a diary comment (see `diary-comment-start').
  92 For example, to be warned 30 minutes in advance of an appointment:
  93    2011/06/01 12:00 Do something ## warntime 30
  94 "
  95   :version "24.1"
  96   :type 'regexp
  97   :group 'appt)
  98
  99 (defcustom appt-audible t
 100   "Non-nil means beep to indicate appointment."
 101   :type 'boolean
 102   :group 'appt)
 103
 104 ;; TODO - add popup.
 105 (defcustom appt-display-format 'window
 106   "How appointment reminders should be displayed.
 107 The options are:
 108    window - use a separate window
 109    echo   - use the echo area
 110    nil    - no visible reminder.
 111 See also `appt-audible' and `appt-display-mode-line'."
 112   :type '(choice
 113           (const :tag "Separate window" window)
 114           (const :tag "Echo-area" echo)
 115           (const :tag "No visible display" nil))
 116   :group 'appt
 117   :version "24.1") ; no longer inherit from deleted obsolete variables
 118
 119 (defcustom appt-display-mode-line t
 120   "Non-nil means display minutes to appointment and time on the mode line.
 121 This is in addition to any other display of appointment messages.
 122 The mode line updates every minute, independent of the value of
 123 `appt-display-interval'."
 124   :type 'boolean
 125   :group 'appt)
 126
 127 (defcustom appt-display-duration 10
 128   "The number of seconds an appointment message is displayed.
 129 Only relevant if reminders are to be displayed in their own window."
 130   :type 'integer
 131   :group 'appt)
 132
 133 (defcustom appt-display-diary t
 134   "Non-nil displays the diary when the appointment list is first initialized.
 135 This occurs when this package is first activated, and then at
 136 midnight when the appointment list updates."
 137   :type 'boolean
 138   :group 'appt)
 139
 140 (defcustom appt-display-interval 3
 141   "Interval in minutes at which to display appointment reminders.
 142 Once an appointment becomes due, Emacs displays reminders every
 143 `appt-display-interval' minutes.  You probably want to make
 144 `appt-message-warning-time' be a multiple of this, so that you get
 145 a final message displayed precisely when the appointment is due.
 146
 147 Note that this variable controls the interval at which
 148 `appt-display-message' is called.  The mode line display (if active)
 149 always updates every minute."
 150   :type 'integer
 151   :group 'appt)
 152
 153 (defcustom appt-disp-window-function 'appt-disp-window
 154   "Function called to display appointment window.
 155 Only relevant if reminders are being displayed in a window.
 156 It should take three string arguments: the number of minutes till
 157 the appointment, the current time, and the text of the appointment."
 158   :type 'function
 159   :group 'appt)
 160
 161 (defcustom appt-delete-window-function 'appt-delete-window
 162   "Function called to remove appointment window and buffer.
 163 Only relevant if reminders are being displayed in a window."
 164   :type 'function
 165   :group 'appt)
 166
 167
 168 ;;; Internal variables below this point.
 169
 170 (defconst appt-buffer-name "*appt-buf*"
 171   "Name of the appointments buffer.")
 172
 173 ;; TODO Turn this into an alist?  It would be easier to add more
 174 ;; optional elements.
 175 ;; Why is the first element (MINUTES) rather than just MINUTES?
 176 ;; It may just inherit from diary-entries-list, where we have
 177 ;; ((MONTH DAY YEAR) ENTRY)
 178 (defvar appt-time-msg-list nil
 179   "The list of appointments for today.
 180 Use `appt-add' and `appt-delete' to add and delete appointments.
 181 The original list is generated from today's `diary-entries-list', and
 182 can be regenerated using the function `appt-check'.
 183 Each element of the generated list has the form
 184 \((MINUTES) STRING [FLAG] [WARNTIME])
 185 where MINUTES is the time in minutes of the appointment after midnight,
 186 and STRING is the description of the appointment.
 187 FLAG and WARNTIME are not always present.  A non-nil FLAG
 188 indicates that the element was made with `appt-add', so calling
 189 `appt-make-list' again should preserve it.  If WARNTIME is non-nil,
 190 it is an integer to use in place of `appt-message-warning-time'.")
 191
 192 (defconst appt-max-time (1- (* 24 60))
 193   "11:59pm in minutes - number of minutes in a day minus 1.")
 194
 195 (defvar appt-mode-string nil
 196   "String being displayed in the mode line saying you have an appointment.
 197 The actual string includes the amount of time till the appointment.
 198 Only used if `appt-display-mode-line' is non-nil.")
 199 (put 'appt-mode-string 'risky-local-variable t) ; for 'face property
 200
 201 (defvar appt-prev-comp-time nil
 202   "Time of day (mins since midnight) at which we last checked appointments.")
 203
 204 (defvar appt-display-count 0
 205   "Internal variable used to count number of consecutive reminders.")
 206
 207 (defvar appt-timer nil
 208   "Timer used for diary appointment notifications (`appt-check').
 209 If this is non-nil, appointment checking is active.")
 210
 211
 212 ;;; Functions.
 213
 214 (defun appt-display-message (string mins)
 215   "Display a reminder about an appointment.
 216 The string STRING describes the appointment, due in integer MINS minutes.
 217 The format of the visible reminder is controlled by `appt-display-format'.
 218 The variable `appt-audible' controls the audible reminder."
 219   (if appt-audible (beep 1))
 220   (cond ((eq appt-display-format 'window)
 221          (funcall appt-disp-window-function
 222                   (number-to-string mins)
 223                   ;; TODO - use calendar-month-abbrev-array rather than %b?
 224                   (format-time-string "%a %b %e " (current-time))
 225                   string)
 226          (run-at-time (format "%d sec" appt-display-duration)
 227                       nil
 228                       appt-delete-window-function))
 229         ((eq appt-display-format 'echo)
 230          (message "%s" string))))
 231
 232
 233 (defun appt-check (&optional force)
 234   "Check for an appointment and update any reminder display.
 235 If optional argument FORCE is non-nil, reparse the diary file for
 236 appointments.  Otherwise the diary file is only parsed once per day,
 237 or when it (or a file it includes) is saved.
 238
 239 Note: the time must be the first thing in the line in the diary
 240 for a warning to be issued.  The format of the time can be either
 241 24 hour or am/pm.  For example:
 242
 243               02/23/89
 244                 18:00 Dinner
 245
 246               Thursday
 247                 11:45am Lunch meeting.
 248
 249 Appointments are checked every `appt-display-interval' minutes.
 250 The following variables control appointment notification:
 251
 252 `appt-display-format'
 253         Controls the format in which reminders are displayed.
 254
 255 `appt-audible'
 256         Non-nil means there is an audible component to reminders.
 257
 258 `appt-message-warning-time'
 259         The default number of minutes in advance at which reminders
 260         should start.
 261
 262 `appt-display-mode-line'
 263         Non-nil means show in the mode line a countdown to the
 264         time of each appointment, once reminders start.
 265
 266 `appt-display-interval'
 267         Interval in minutes at which to display appointment messages.
 268
 269 `appt-display-diary'
 270         Non-nil means display the diary whenever the appointment list is
 271         initialized (e.g. the first time we check for appointments each day).
 272
 273 The following variables are only relevant if reminders are being
 274 displayed in a window:
 275
 276 `appt-display-duration'
 277         Number of seconds for which an appointment message is displayed.
 278
 279 `appt-disp-window-function'
 280         Function called to display appointment window.
 281
 282 `appt-delete-window-function'
 283         Function called to remove appointment window and buffer."
 284   (interactive "P")                     ; so people can force updates
 285   (let* ((min-to-app -1)
 286          (prev-appt-mode-string appt-mode-string)
 287          (prev-appt-display-count appt-display-count)
 288          now now-mins appt-mins appt-warn-time)
 289     (save-excursion                   ; FIXME ?
 290       ;; Convert current time to minutes after midnight (12.01am = 1).
 291       (setq now (decode-time)
 292             now-mins (+ (* 60 (nth 2 now)) (nth 1 now)))
 293       ;; At first check in any day, update appointments to today's list.
 294       (if (or force                      ; eg initialize, diary save
 295               (null appt-prev-comp-time) ; first check
 296               (< now-mins appt-prev-comp-time)) ; new day
 297           (ignore-errors
 298             (let ((diary-hook (if (assoc 'appt-make-list diary-hook)
 299                                   diary-hook
 300                                 (cons 'appt-make-list diary-hook))))
 301               (if appt-display-diary
 302                   (diary)
 303                 ;; Not displaying the diary, so we can ignore
 304                 ;; diary-number-of-entries.  Since appt.el only
 305                 ;; works on a daily basis, no need for more entries.
 306                 (diary-list-entries (calendar-current-date) 1 t)))))
 307       ;; Reset everything now in case we somehow missed a minute,
 308       ;; or (more likely) an appt was deleted.  (This is the only
 309       ;; reason we need prev-appt-display-count.)
 310       (setq appt-prev-comp-time now-mins
 311             appt-mode-string nil
 312             appt-display-count 0)
 313       ;; Remove any entries that are in the past.
 314       ;; FIXME how can there be any such entries, given that this
 315       ;; function removes entries when they hit zero minutes,
 316       ;; and appt-make-list doesn't add any in the past in the first place?
 317       (while (and appt-time-msg-list
 318                   (< (setq appt-mins (caar (car appt-time-msg-list)))
 319                      now-mins))
 320         (setq appt-time-msg-list (cdr appt-time-msg-list)))
 321       ;; If there are entries in the list, and the user wants a
 322       ;; message issued, get the first time off of the list and
 323       ;; calculate the number of minutes until the appointment.
 324       (when appt-time-msg-list
 325         (setq appt-warn-time (or (nth 3 (car appt-time-msg-list))
 326                                  appt-message-warning-time)
 327               min-to-app (- appt-mins now-mins))
 328         ;; If we have an appointment between midnight and
 329         ;; `appt-warn-time' minutes after midnight, we
 330         ;; must begin to issue a message before midnight.  Midnight
 331         ;; is considered 0 minutes and 11:59pm is 1439
 332         ;; minutes.  Therefore we must recalculate the minutes to
 333         ;; appointment variable.  It is equal to the number of
 334         ;; minutes before midnight plus the number of minutes after
 335         ;; midnight our appointment is.
 336         ;; FIXME but appt-make-list constructs appt-time-msg-list to only
 337         ;; contain entries with today's date, so this cannot work?
 338         ;; Also above we just removed anything with appt-mins < now-mins.
 339         (if (and (< appt-mins appt-warn-time)
 340                  (> (+ now-mins appt-warn-time) appt-max-time))
 341             (setq min-to-app (+ (- (1+ appt-max-time) now-mins)
 342                                 appt-mins)))
 343         ;; Issue warning if the appointment time is within
 344         ;; appt-message-warning time.
 345         (when (and (<= min-to-app appt-warn-time)
 346                    (>= min-to-app 0))
 347           ;; This is true every appt-display-interval minutes.
 348           (and (zerop (mod prev-appt-display-count appt-display-interval))
 349                (appt-display-message (cadr (car appt-time-msg-list))
 350                                      min-to-app))
 351           (when appt-display-mode-line
 352             (setq appt-mode-string
 353                   (concat " " (propertize
 354                                (format "App't %s"
 355                                        (if (zerop min-to-app) "NOW"
 356                                          (format "in %s min." min-to-app)))
 357                                'face 'mode-line-emphasis))))
 358           ;; When an appointment is reached, delete it from the
 359           ;; list.  Reset the count to 0 in case we display another
 360           ;; appointment on the next cycle.
 361           (if (zerop min-to-app)
 362               (setq appt-time-msg-list (cdr appt-time-msg-list)
 363                     appt-display-count 0)
 364             (setq appt-display-count (1+ prev-appt-display-count)))))
 365       ;; If we have changed the mode line string, redisplay all mode lines.
 366       (and appt-display-mode-line
 367            (not (string-equal appt-mode-string prev-appt-mode-string))
 368            (progn
 369              (force-mode-line-update t)
 370              ;; If the string now has a notification, redisplay right now.
 371              (if appt-mode-string
 372                  (sit-for 0)))))))
 373
 374 (defun appt-disp-window (min-to-app new-time appt-msg)
 375   "Display appointment due in MIN-TO-APP (a string) minutes.
 376 NEW-TIME is a string giving the date.  Displays the appointment
 377 message APPT-MSG in a separate buffer."
 378   (let ((this-window (selected-window))
 379         (appt-disp-buf (get-buffer-create appt-buffer-name)))
 380     ;; Make sure we're not in the minibuffer before splitting the window.
 381     ;; FIXME this seems needlessly complicated?
 382     (when (minibufferp)
 383       (other-window 1)
 384       (and (minibufferp) (display-multi-frame-p) (other-frame 1)))
 385     (if (cdr (assq 'unsplittable (frame-parameters)))
 386         ;; In an unsplittable frame, use something somewhere else.
 387         (progn
 388           (set-buffer appt-disp-buf)
 389           (display-buffer appt-disp-buf))
 390       (unless (or (special-display-p (buffer-name appt-disp-buf))
 391                   (same-window-p (buffer-name appt-disp-buf)))
 392         ;; By default, split the bottom window and use the lower part.
 393         (appt-select-lowest-window)
 394         ;; Split the window, unless it's too small to do so.
 395         (when (>= (window-height) (* 2 window-min-height))
 396           (select-window (split-window))))
 397       (switch-to-buffer appt-disp-buf))
 398     ;; FIXME Link to diary entry?
 399     (calendar-set-mode-line
 400      (format " Appointment %s. %s "
 401              (if (string-equal "0" min-to-app) "now"
 402                (format "in %s minute%s" min-to-app
 403                        (if (string-equal "1" min-to-app) "" "s")))
 404              new-time))
 405     (setq buffer-read-only nil
 406           buffer-undo-list t)
 407     (erase-buffer)
 408     (insert appt-msg)
 409     (shrink-window-if-larger-than-buffer (get-buffer-window appt-disp-buf t))
 410     (set-buffer-modified-p nil)
 411     (setq buffer-read-only t)
 412     (raise-frame (selected-frame))
 413     (select-window this-window)))
 414
 415 (defun appt-delete-window ()
 416   "Function called to undisplay appointment messages.
 417 Usually just deletes the appointment buffer."
 418   (let ((window (get-buffer-window appt-buffer-name t)))
 419     (and window
 420          (or (eq window (frame-root-window (window-frame window)))
 421              (delete-window window))))
 422   (kill-buffer appt-buffer-name)
 423   (if appt-audible
 424       (beep 1)))
 425
 426 (defun appt-select-lowest-window ()
 427   "Select the lowest window on the frame."
 428   (let ((lowest-window (selected-window))
 429         (bottom-edge (nth 3 (window-edges)))
 430         next-bottom-edge)
 431     (walk-windows (lambda (w)
 432                     (when (< bottom-edge (setq next-bottom-edge
 433                                                (nth 3 (window-edges w))))
 434                       (setq bottom-edge next-bottom-edge
 435                             lowest-window w))) 'nomini)
 436     (select-window lowest-window)))
 437
 438 (defconst appt-time-regexp
 439   "[0-9]?[0-9]\\(h\\([0-9][0-9]\\)?\\|[:.][0-9][0-9]\\)\\(am\\|pm\\)?")
 440
 441 ;;;###autoload
 442 (defun appt-add (time msg &optional warntime)
 443   "Add an appointment for today at TIME with message MSG.
 444 The time should be in either 24 hour format or am/pm format.
 445 Optional argument WARNTIME is an integer (or string) giving the number
 446 of minutes before the appointment at which to start warning.
 447 The default is `appt-message-warning-time'."
 448   (interactive "sTime (hh:mm[am/pm]): \nsMessage:
 449 sMinutes before the appointment to start warning: ")
 450   (unless (string-match appt-time-regexp time)
 451     (error "Unacceptable time-string"))
 452   (and (stringp warntime)
 453        (setq warntime (unless (string-equal warntime "")
 454                         (string-to-number warntime))))
 455   (and warntime
 456        (not (integerp warntime))
 457        (error "Argument WARNTIME must be an integer, or nil"))
 458   (or appt-timer (appt-activate))
 459   (let ((time-msg (list (list (appt-convert-time time))
 460                         (concat time " " msg) t)))
 461     ;; It is presently non-sensical to have multiple warnings about
 462     ;; the same appointment with just different delays, but it might
 463     ;; not always be so.  TODO
 464     (if warntime (setq time-msg (append time-msg (list warntime))))
 465     (unless (member time-msg appt-time-msg-list)
 466       (setq appt-time-msg-list
 467             (appt-sort-list (nconc appt-time-msg-list (list time-msg)))))))
 468
 469 (defun appt-delete ()
 470   "Delete an appointment from the list of appointments."
 471   (interactive)
 472   (let ((tmp-msg-list appt-time-msg-list))
 473     (dolist (element tmp-msg-list)
 474       (if (y-or-n-p (concat "Delete "
 475                             ;; We want to quote any doublequotes in the
 476                             ;; string, as well as put doublequotes around it.
 477                             (prin1-to-string
 478                              (substring-no-properties (cadr element) 0))
 479                             " from list? "))
 480           (setq appt-time-msg-list (delq element appt-time-msg-list)))))
 481   (appt-check)
 482   (message ""))
 483
 484
 485 (defvar number)
 486 (defvar original-date)
 487 (defvar diary-entries-list)
 488
 489 (defun appt-make-list ()
 490   "Update the appointments list from today's diary buffer.
 491 The time must be at the beginning of a line for it to be
 492 put in the appointments list (see examples in documentation of
 493 the function `appt-check').  We assume that the variables DATE and
 494 NUMBER hold the arguments that `diary-list-entries' received.
 495 They specify the range of dates that the diary is being processed for.
 496
 497 Any appointments made with `appt-add' are not affected by this function."
 498   ;; We have something to do if the range of dates that the diary is
 499   ;; considering includes the current date.
 500   (if (and (not (calendar-date-compare
 501                  (list (calendar-current-date))
 502                  (list original-date)))
 503            (calendar-date-compare
 504             (list (calendar-current-date))
 505             (list (calendar-gregorian-from-absolute
 506                    (+ (calendar-absolute-from-gregorian original-date)
 507                       number)))))
 508       (save-excursion
 509         ;; Clear the appointments list, then fill it in from the diary.
 510         (dolist (elt appt-time-msg-list)
 511           ;; Delete any entries that were not made with appt-add.
 512           (unless (nth 2 elt)
 513             (setq appt-time-msg-list
 514                   (delq elt appt-time-msg-list))))
 515         (if diary-entries-list
 516             ;; Cycle through the entry-list (diary-entries-list)
 517             ;; looking for entries beginning with a time.  If the
 518             ;; entry begins with a time, add it to the
 519             ;; appt-time-msg-list.  Then sort the list.
 520             (let ((entry-list diary-entries-list)
 521                   time-string literal)
 522               ;; Below, we assume diary-entries-list was in date
 523               ;; order.  It is, unless something on
 524               ;; diary-list-entries-hook has changed it, eg
 525               ;; diary-include-other-files (bug#7019).  It must be
 526               ;; in date order if number = 1.
 527               (and diary-list-entries-hook
 528                    appt-display-diary
 529                    (not (eq diary-number-of-entries 1))
 530                    (not (memq (car (last diary-list-entries-hook))
 531                               '(diary-sort-entries sort-diary-entries)))
 532                    (setq entry-list (sort entry-list 'diary-entry-compare)))
 533               ;; Skip diary entries for dates before today.
 534               (while (and entry-list
 535                           (calendar-date-compare
 536                            (car entry-list) (list (calendar-current-date))))
 537                 (setq entry-list (cdr entry-list)))
 538               ;; Parse the entries for today.
 539               (while (and entry-list
 540                           (calendar-date-equal
 541                            (calendar-current-date) (caar entry-list)))
 542                 (setq time-string (cadr (car entry-list))
 543                       ;; Including any comments.
 544                       literal (or (nth 2 (nth 3 (car entry-list)))
 545                                   time-string))
 546                 (while (string-match appt-time-regexp time-string)
 547                   (let* ((beg (match-beginning 0))
 548                          ;; Get just the time for this appointment.
 549                          (only-time (match-string 0 time-string))
 550                          ;; Find the end of this appointment
 551                          ;; (the start of the next).
 552                          (end (string-match
 553                                (concat "\n[ \t]*" appt-time-regexp)
 554                                time-string
 555                                (match-end 0)))
 556                          (warntime
 557                           (if (string-match appt-warning-time-regexp literal)
 558                               (string-to-number (match-string 1 literal))))
 559                          ;; Get the whole string for this appointment.
 560                          (appt-time-string
 561                           (substring time-string beg end))
 562                          ;; FIXME why the list?  It makes the first
 563                          ;; element (MINUTES) rather than MINUTES.
 564                          (appt-time (list (appt-convert-time only-time)))
 565                          (time-msg (append
 566                                     (list appt-time appt-time-string)
 567                                     (if warntime (list nil warntime)))))
 568                     ;; Add this appointment to appt-time-msg-list.
 569                     (setq appt-time-msg-list
 570                           (nconc appt-time-msg-list (list time-msg))
 571                           ;; Discard this appointment from the string.
 572                           ;; (This allows for multiple appts per entry.)
 573                           time-string
 574                           (if end (substring time-string end) ""))
 575                     ;; Similarly, discard the start of literal.
 576                     (and (> (length time-string) 0)
 577                          (string-match appt-time-regexp literal)
 578                          (setq end (string-match
 579                                     (concat "\n[ \t]*" appt-time-regexp)
 580                                     literal (match-end 0)))
 581                          (setq literal (substring literal end)))))
 582                 (setq entry-list (cdr entry-list)))))
 583         (setq appt-time-msg-list (appt-sort-list appt-time-msg-list))
 584         ;; Convert current time to minutes after midnight (12:01am = 1),
 585         ;; and remove elements in the list that are in the past.
 586         (let* ((now (decode-time))
 587                (now-mins (+ (* 60 (nth 2 now)) (nth 1 now))))
 588           (while (and appt-time-msg-list
 589                       (< (caar (car appt-time-msg-list)) now-mins))
 590             (setq appt-time-msg-list (cdr appt-time-msg-list)))))))
 591
 592
 593 (defun appt-sort-list (appt-list)
 594   "Sort an appointment list, putting earlier items at the front.
 595 APPT-LIST is a list of the same format as `appt-time-msg-list'."
 596   (sort appt-list (lambda (e1 e2) (< (caar e1) (caar e2)))))
 597
 598
 599 (defun appt-convert-time (time2conv)
 600   "Convert hour:min[am/pm] format TIME2CONV to minutes from midnight.
 601 A period (.) can be used instead of a colon (:) to separate the
 602 hour and minute parts."
 603   ;; Formats that should be accepted:
 604   ;;   10:00 10.00 10h00 10h 10am 10:00am 10.00am
 605   (let ((min (if (string-match "[h:.]\\([0-9][0-9]\\)" time2conv)
 606                  (string-to-number (match-string 1 time2conv))
 607                0))
 608         (hr (if (string-match "[0-9]*[0-9]" time2conv)
 609                 (string-to-number (match-string 0 time2conv))
 610               0)))
 611     ;; Convert the time appointment time into 24 hour time.
 612     (cond ((and (string-match "pm" time2conv) (< hr 12))
 613            (setq hr (+ 12 hr)))
 614           ((and (string-match "am" time2conv) (= hr 12))
 615            (setq hr 0)))
 616     ;; Convert the actual time into minutes.
 617     (+ (* hr 60) min)))
 618
 619 (defun appt-update-list ()
 620   "If the current buffer is visiting the diary, update appointments.
 621 This function also acts on any file listed in `diary-included-files'.
 622 It is intended for use with `write-file-functions'."
 623   (and (member buffer-file-name (append diary-included-files
 624                                         (list (expand-file-name diary-file))))
 625        appt-timer
 626        (let ((appt-display-diary nil))
 627          (appt-check t)))
 628   nil)
 629
 630 ;;;###autoload
 631 (defun appt-activate (&optional arg)
 632   "Toggle checking of appointments.
 633 With optional numeric argument ARG, turn appointment checking on if
 634 ARG is positive, otherwise off."
 635   (interactive "P")
 636   (let ((appt-active appt-timer))
 637     (setq appt-active (if arg (> (prefix-numeric-value arg) 0)
 638                         (not appt-active)))
 639     (remove-hook 'write-file-functions 'appt-update-list)
 640     (or global-mode-string (setq global-mode-string '("")))
 641     (delq 'appt-mode-string global-mode-string)
 642     (when appt-timer
 643       (cancel-timer appt-timer)
 644       (setq appt-timer nil))
 645     (if appt-active
 646         (progn
 647           (add-hook 'write-file-functions 'appt-update-list)
 648           (setq appt-timer (run-at-time t 60 'appt-check)
 649                 global-mode-string
 650                 (append global-mode-string '(appt-mode-string)))
 651           (appt-check t)
 652           (message "Appointment reminders enabled%s"
 653                    ;; Someone might want to use appt-add without a diary.
 654                    (if (ignore-errors (diary-check-diary-file))
 655                        ""
 656                      " (no diary file found)")))
 657       (message "Appointment reminders disabled"))))
 658
 659
 660 (provide 'appt)
 661
 662 ;;; appt.el ends here