lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 96, 97, 1998 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file parses the command line and gets Emacs running.  Options on
  28 ;; the command line are handled in precedence order.  The order is the
  29 ;; one in the list below; first described means first handled.  Options
  30 ;; within each category (delimited by a bar) are handled in the order
  31 ;; encountered on the command line.
  32
  33 ;; -------------------------
  34 ;; -version                  Print Emacs version to stderr, then exit
  35 ;; --version                 successfully right away.
  36 ;;                           This option is handled by emacs.c
  37 ;; -------------------------
  38 ;; -help                     Print a short usage description and exit
  39 ;; --help                    successfully right away.
  40 ;;                           This option is handled by emacs.c
  41 ;; -------------------------
  42 ;; -nl                       Do not use shared memory (for systems that
  43 ;; -no-shared-memory         support this) for the dumped Emacs data.
  44 ;;                           This option is handled by emacs.c
  45 ;;
  46 ;; -map                      For VMS.
  47 ;; --map-data                This option is handled by emacs.c
  48 ;; -------------------------
  49 ;; -t FILE                   Use FILE as the name of the terminal.
  50 ;; --terminal FILE           Using this implies "-nw" also.
  51 ;;                           This option is handled by emacs.c
  52 ;; -------------------------
  53 ;; -d DISPNAME               Use DISPNAME as the name of the X-windows
  54 ;; -display DISPNAME         display for the initial frame.
  55 ;; --display DISPNAME        This option is handled by emacs.c
  56 ;; -------------------------
  57 ;; -nw                       Do not use a windows system (but use the
  58 ;; --no-windows              terminal instead.)
  59 ;;                           This option is handled by emacs.c
  60 ;; -------------------------
  61 ;; -batch                    Execute noninteractively (messages go to stdout,
  62 ;; --batch                   variable noninteractive set to t)
  63 ;;                           This option is handled by emacs.c
  64 ;; -------------------------
  65 ;; -q                        Do not load user's init file and do not load
  66 ;; -no-init-file             "default.el".  Regardless of this switch,
  67 ;; --no-init-file            "site-start" is still loaded.
  68 ;; -------------------------
  69 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  70 ;; --no-site-file            way to prevent loading that file.)
  71 ;; -------------------------
  72 ;; -u USER                   Load USER's init file instead of the init
  73 ;; -user USER                file belonging to the user starting Emacs.
  74 ;; --user USER
  75 ;; -------------------------
  76 ;; -debug-init               Don't catch errors in init files; let the
  77 ;; --debug-init              debugger run.
  78 ;; -------------------------
  79 ;; -i ICONTYPE               Set type of icon using when Emacs is
  80 ;; -itype ICONTYPE           iconified under X-windows.
  81 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  82 ;;
  83 ;; -iconic                   Start Emacs iconified under X-windows.
  84 ;; --iconic                  This option is passed on to term/x-win.el
  85 ;; -------------------------
  86 ;; Various X-windows options for colors/fonts/geometry/title etc.
  87 ;; These options are passed on to term/x-win.el which see.  Certain
  88 ;; of these are also found in term/pc-win.el
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;;
  92 ;; -L DIRNAME                Add DIRNAME to load-path
  93 ;; -directory DIRNAME
  94 ;; --directory DIRNAME
  95 ;;
  96 ;; -l FILE                   Load and execute the Emacs lisp code
  97 ;; -load FILE                in FILE.
  98 ;; --load FILE
  99 ;;
 100 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 101 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 102 ;; --funcall FUNC            and should not be used.  (It's a typo
 103 ;; -e FUNC                   promoted to a feature.)
 104 ;;
 105 ;; -eval FORM                Execute Emacs lisp form FORM.
 106 ;; --eval FORM
 107 ;;
 108 ;; -insert FILE              Insert the contents of FILE into buffer.
 109 ;; --insert FILE
 110 ;; -------------------------
 111 ;; -kill                     Kill (exit) Emacs right away.
 112 ;; --kill
 113 ;; -------------------------
 114
 115 ;;; Code:
 116
 117 (setq top-level '(normal-top-level))
 118
 119 (defvar command-line-processed nil
 120   "Non-nil once command line has been processed")
 121
 122 (defgroup initialization nil
 123   "Emacs start-up procedure"
 124   :group 'internal)
 125
 126 (defcustom inhibit-startup-message nil
 127   "*Non-nil inhibits the initial startup message.
 128 This is for use in your personal init file, once you are familiar
 129 with the contents of the startup message."
 130   :type 'boolean
 131   :group 'initialization)
 132
 133 (defcustom inhibit-startup-echo-area-message nil
 134   "*Non-nil inhibits the initial startup echo area message.
 135 Setting this variable takes effect
 136 only if you do it with the customization buffer
 137 or if your `.emacs' file contains a line of this form:
 138  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 139 If your `.emacs' file is byte-compiled, use the following form instead:
 140  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 141 Thus, someone else using a copy of your `.emacs' file will see
 142 the startup message unless he personally acts to inhibit it."
 143   :type '(choice (const :tag "Don't inhibit")
 144                  (string :tag "Enter your user name, to inhibit"))
 145   :group 'initialization)
 146
 147 (defcustom inhibit-default-init nil
 148   "*Non-nil inhibits loading the `default' library."
 149   :type 'boolean
 150   :group 'initialization)
 151
 152 (defvar command-switch-alist nil
 153   "Alist of command-line switches.
 154 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 155 HANDLER-FUNCTION receives switch name as sole arg;
 156 remaining command-line args are in the variable `command-line-args-left'.")
 157
 158 (defvar command-line-args-left nil
 159   "List of command-line args not yet processed.")
 160
 161 (defvar command-line-functions nil    ;; lrs 7/31/89
 162   "List of functions to process unrecognized command-line arguments.
 163 Each function should access the dynamically bound variables
 164 `argi' (the current argument) and `command-line-args-left' (the remaining
 165 arguments).  The function should return non-nil only if it recognizes and
 166 processes `argi'.  If it does so, it may consume successive arguments by
 167 altering `command-line-args-left' to remove them.")
 168
 169 (defvar command-line-default-directory nil
 170   "Default directory to use for command line arguments.
 171 This is normally copied from `default-directory' when Emacs starts.")
 172
 173 ;;; This is here, rather than in x-win.el, so that we can ignore these
 174 ;;; options when we are not using X.
 175 (defvar command-line-x-option-alist
 176   '(("-bw" 1 x-handle-numeric-switch border-width)
 177     ("-d" 1 x-handle-display)
 178     ("-display" 1 x-handle-display)
 179     ("-name" 1 x-handle-name-switch)
 180     ("-title" 1 x-handle-switch title)
 181     ("-T" 1 x-handle-switch title)
 182     ("-r" 0 x-handle-switch reverse t)
 183     ("-rv" 0 x-handle-switch reverse t)
 184     ("-reverse" 0 x-handle-switch reverse t)
 185     ("-reverse-video" 0 x-handle-switch reverse t)
 186     ("-fn" 1 x-handle-switch font)
 187     ("-font" 1 x-handle-switch font)
 188     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 189     ("-g" 1 x-handle-geometry)
 190     ("-geometry" 1 x-handle-geometry)
 191     ("-fg" 1 x-handle-switch foreground-color)
 192     ("-foreground" 1 x-handle-switch foreground-color)
 193     ("-bg" 1 x-handle-switch background-color)
 194     ("-background" 1 x-handle-switch background-color)
 195     ("-ms" 1 x-handle-switch mouse-color)
 196     ("-itype" 0 x-handle-switch icon-type t)
 197     ("-i" 0 x-handle-switch icon-type t)
 198     ("-iconic" 0 x-handle-iconic)
 199     ("-xrm" 1 x-handle-xrm-switch)
 200     ("-cr" 1 x-handle-switch cursor-color)
 201     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 202     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 203     ("-bd" 1 x-handle-switch)
 204     ("--border-width" 1 x-handle-numeric-switch border-width)
 205     ("--display" 1 x-handle-display)
 206     ("--name" 1 x-handle-name-switch)
 207     ("--title" 1 x-handle-switch title)
 208     ("--reverse-video" 0 x-handle-switch reverse t)
 209     ("--font" 1 x-handle-switch font)
 210     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 211     ("--geometry" 1 x-handle-geometry)
 212     ("--foreground-color" 1 x-handle-switch foreground-color)
 213     ("--background-color" 1 x-handle-switch background-color)
 214     ("--mouse-color" 1 x-handle-switch mouse-color)
 215     ("--icon-type" 0 x-handle-switch icon-type t)
 216     ("--iconic" 0 x-handle-iconic)
 217     ("--xrm" 1 x-handle-xrm-switch)
 218     ("--cursor-color" 1 x-handle-switch cursor-color)
 219     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 220     ("--border-color" 1 x-handle-switch border-width))
 221   "Alist of X Windows options.
 222 Each element has the form
 223   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 224 where NAME is the option name string, NUMARGS is the number of arguments
 225 that the option accepts, HANDLER is a function to call to handle the option.
 226 FRAME-PARAM (optional) is the frame parameter this option specifies,
 227 and VALUE is the value which is given to that frame parameter
 228 \(most options use the argument for this, so VALUE is not present).")
 229
 230 (defvar before-init-hook nil
 231   "Normal hook run after handling urgent options but before loading init files.")
 232
 233 (defvar after-init-hook nil
 234   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 235 There is no `condition-case' around the running of these functions;
 236 therefore, if you set `debug-on-error' non-nil in `.emacs',
 237 an error in one of these functions will invoke the debugger.")
 238
 239 (defvar emacs-startup-hook nil
 240   "Normal hook run after loading init files and handling the command line.")
 241
 242 (defvar term-setup-hook nil
 243   "Normal hook run after loading terminal-specific Lisp code.
 244 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 245 so as to override the definitions made by the terminal-specific file.
 246 Emacs never sets this variable itself.")
 247
 248 (defvar keyboard-type nil
 249   "The brand of keyboard you are using.
 250 This variable is used to define
 251 the proper function and keypad keys for use under X.  It is used in a
 252 fashion analogous to the environment variable TERM.")
 253
 254 (defvar window-setup-hook nil
 255   "Normal hook run to initialize window system display.
 256 Emacs runs this hook after processing the command line arguments and loading
 257 the user's init file.")
 258
 259 (defcustom initial-major-mode 'lisp-interaction-mode
 260   "Major mode command symbol to use for the initial *scratch* buffer."
 261   :type 'function
 262   :group 'initialization)
 263
 264 (defcustom init-file-user nil
 265   "Identity of user whose `.emacs' file is or was read.
 266 The value is nil if `-q' or `--no-init-file' was specified,
 267 meaning do not load any init file.
 268
 269 Otherwise, the value may be the null string, meaning use the init file
 270 for the user that originally logged in, or it may be a
 271 string containing a user's name meaning use that person's init file.
 272
 273 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 274 evaluates to the name of the directory where the `.emacs' file was
 275 looked for.
 276
 277 Setting `init-file-user' does not prevent Emacs from loading
 278 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 279   :type '(choice (const :tag "none" nil) string)
 280   :group 'initialization)
 281
 282 (defcustom site-run-file "site-start"
 283   "File containing site-wide run-time initializations.
 284 This file is loaded at run-time before `~/.emacs'.  It contains inits
 285 that need to be in place for the entire site, but which, due to their
 286 higher incidence of change, don't make sense to load into emacs'
 287 dumped image.  Thus, the run-time load order is: 1. file described in
 288 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 289
 290 Don't use the `site-start.el' file for things some users may not like.
 291 Put them in `default.el' instead, so that users can more easily
 292 override them.  Users can prevent loading `default.el' with the `-q'
 293 option or by setting `inhibit-default-init' in their own init files,
 294 but inhibiting `site-start.el' requires `--no-site-file', which
 295 is less convenient."
 296   :type 'string
 297   :group 'initialization)
 298
 299 (defconst iso-8859-n-locale-regexp "8859[-_]?\\([1-49]\\)"
 300   "Regexp that specifies when to enable an ISO 8859-N character set.
 301 We do that if this regexp matches the locale name
 302 specified by the LC_ALL, LC_CTYPE and LANG environment variables.
 303 The paren group in the regexp should match the specific character
 304 set number, N.")
 305
 306 (defcustom mail-host-address nil
 307   "*Name of this machine, for purposes of naming users."
 308   :type '(choice (const nil) string)
 309   :group 'mail)
 310
 311 (defcustom user-mail-address nil
 312   "*Full mailing address of this user.
 313 This is initialized based on `mail-host-address',
 314 after your init file is read, in case it sets `mail-host-address'."
 315   :type 'string
 316   :group 'mail)
 317
 318 (defcustom auto-save-list-file-prefix
 319   (if (eq system-type 'ms-dos)
 320       "~/_s"  ; MS-DOS cannot have initial dot, and allows only 8.3 names
 321     "~/.saves-")
 322   "Prefix for generating `auto-save-list-file-name'.
 323 This is used after reading your `.emacs' file to initialize
 324 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 325 if you have not already set `auto-save-list-file-name' yourself.
 326 Set this to nil if you want to prevent `auto-save-list-file-name'
 327 from being initialized."
 328   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 329                  string)
 330   :group 'auto-save)
 331
 332 (defvar locale-translation-file-name "/usr/share/locale/locale.alias"
 333   "*File name for the system's file of locale-name aliases.")
 334
 335 (defvar init-file-debug nil)
 336
 337 (defvar init-file-had-error nil)
 338
 339 (defun normal-top-level-add-subdirs-to-load-path ()
 340   "Add all subdirectories of current directory to `load-path'.
 341 More precisely, this uses only the subdirectories whose names
 342 start with letters or digits; it excludes any subdirectory named `RCS'
 343 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 344   (let (dirs
 345         (pending (list default-directory)))
 346     ;; This loop does a breadth-first tree walk on DIR's subtree,
 347     ;; putting each subdir into DIRS as its contents are examined.
 348     (while pending
 349       (setq dirs (cons (car pending) dirs))
 350       (setq pending (cdr pending))
 351       (let ((contents (directory-files (car dirs)))
 352             (default-directory (car dirs)))
 353         (while contents
 354           (unless (member (car contents) '("." ".." "RCS" "CVS"))
 355             (when (and (string-match "\\`[a-zA-Z0-9]" (car contents))
 356                        (file-directory-p (car contents)))
 357               (let ((expanded (expand-file-name (car contents))))
 358                 (unless (file-exists-p (expand-file-name ".nosearch"
 359                                                          expanded))
 360                   (setq pending (nconc pending (list expanded)))))))
 361           (setq contents (cdr contents)))))
 362     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 363
 364 ;; This function is called from a subdirs.el file.
 365 ;; It assumes that default-directory is the directory
 366 ;; in which the subdirs.el file exists,
 367 ;; and it adds to load-path the subdirs of that directory
 368 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 369 (defun normal-top-level-add-to-load-path (dirs)
 370   (let ((tail load-path)
 371         (thisdir (directory-file-name default-directory)))
 372     (while (and tail
 373                 (not (equal thisdir (car tail)))
 374                 (not (and (memq system-type '(ms-dos windows-nt))
 375                           (equal (downcase thisdir) (downcase (car tail))))))
 376       (setq tail (cdr tail)))
 377     (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail)))))
 378
 379 (defun normal-top-level ()
 380   (if command-line-processed
 381       (message "Back to top level.")
 382     (setq command-line-processed t)
 383     ;; Give *Messages* the same default-directory as *scratch*,
 384     ;; just to keep things predictable.
 385     (let ((dir default-directory))
 386       (save-excursion
 387         (set-buffer (get-buffer "*Messages*"))
 388         (setq default-directory dir)))
 389     ;; For root, preserve owner and group when editing files.
 390     (if (equal (user-uid) 0)
 391         (setq backup-by-copying-when-mismatch t))
 392     ;; Look in each dir in load-path for a subdirs.el file.
 393     ;; If we find one, load it, which will add the appropriate subdirs
 394     ;; of that dir into load-path,
 395     (let ((tail load-path)
 396           new)
 397       (while tail
 398         (setq new (cons (car tail) new))
 399         (let ((default-directory (car tail)))
 400           (load (expand-file-name "subdirs.el" (car tail)) t t t))
 401         (setq tail (cdr tail))))
 402     (if (not (eq system-type 'vax-vms))
 403         (progn
 404           ;; If the PWD environment variable isn't accurate, delete it.
 405           (let ((pwd (getenv "PWD")))
 406             (and (stringp pwd)
 407                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 408                  ;; describes the directory linked to, not FOO itself.
 409                  (or (equal (file-attributes
 410                              (concat (file-name-as-directory pwd) "."))
 411                             (file-attributes
 412                              (concat (file-name-as-directory default-directory)
 413                                      ".")))
 414                      (setq process-environment
 415                            (delete (concat "PWD=" pwd)
 416                                    process-environment)))))))
 417     (setq default-directory (abbreviate-file-name default-directory))
 418     (let ((menubar-bindings-done nil))
 419       (unwind-protect
 420           (command-line)
 421         ;; Do this again, in case .emacs defined more abbreviations.
 422         (setq default-directory (abbreviate-file-name default-directory))
 423         ;; Specify the file for recording all the auto save files of this session.
 424         ;; This is used by recover-session.
 425         (or auto-save-list-file-name
 426             (and auto-save-list-file-prefix
 427                  (setq auto-save-list-file-name
 428                        ;; Under MS-DOS our PID is almost always reused between
 429                        ;; Emacs invocations.  We need something more unique.
 430                        (if (eq system-type 'ms-dos)
 431                            (concat
 432                             (make-temp-name
 433                              (expand-file-name auto-save-list-file-prefix))
 434                             "~")
 435
 436                          (expand-file-name (format "%s%d-%s~"
 437                                                    auto-save-list-file-prefix
 438                                                    (emacs-pid)
 439                                                    (system-name)))))))
 440         (run-hooks 'emacs-startup-hook)
 441         (and term-setup-hook
 442              (run-hooks 'term-setup-hook))
 443         ;; Modify the initial frame based on what .emacs puts into
 444         ;; ...-frame-alist.
 445         (if (fboundp 'frame-notice-user-settings)
 446             (frame-notice-user-settings))
 447         ;; Now we know the user's default font, so add it to the menu.
 448         (if (fboundp 'font-menu-add-default)
 449             (font-menu-add-default))
 450         (and window-setup-hook
 451              (run-hooks 'window-setup-hook))
 452         (or menubar-bindings-done
 453             (if (memq window-system '(x w32))
 454                 (precompute-menubar-bindings)))))))
 455
 456 ;; Precompute the keyboard equivalents in the menu bar items.
 457 (defun precompute-menubar-bindings ()
 458   (let ((submap (lookup-key global-map [menu-bar])))
 459     (while submap
 460       (and (consp (car submap))
 461            (symbolp (car (car submap)))
 462            (stringp (car-safe (cdr (car submap))))
 463            (keymapp (cdr (cdr (car submap))))
 464            (progn
 465              (x-popup-menu nil (cdr (cdr (car submap))))
 466              (if purify-flag
 467                  (garbage-collect))))
 468       (setq submap (cdr submap))))
 469   (setq define-key-rebound-commands t))
 470
 471 (defun command-line ()
 472   (setq command-line-default-directory default-directory)
 473
 474   ;; Choose a reasonable location for temporary files.
 475   (setq temporary-file-directory
 476         (file-name-as-directory
 477          (cond ((memq system-type '(ms-dos windows-nt))
 478                 (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 479                ((memq system-type '(vax-vms axp-vms))
 480                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 481                (t
 482                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp")))))
 483
 484   ;; See if we should import version-control from the environment variable.
 485   (let ((vc (getenv "VERSION_CONTROL")))
 486     (cond ((eq vc nil))                 ;don't do anything if not set
 487           ((or (string= vc "t")
 488                (string= vc "numbered"))
 489            (setq version-control t))
 490           ((or (string= vc "nil")
 491                (string= vc "existing"))
 492            (setq version-control nil))
 493           ((or (string= vc "never")
 494                (string= vc "simple"))
 495            (setq version-control 'never))))
 496
 497   (let ((ctype
 498          ;; Use the first of these three envvars that has a nonempty value.
 499          (or (let ((string (getenv "LC_ALL")))
 500                (and (not (equal string "")) string))
 501              (let ((string (getenv "LC_CTYPE")))
 502                (and (not (equal string "")) string))
 503              (let ((string (getenv "LANG")))
 504                (and (not (equal string "")) string)))))
 505     ;; Translate "swedish" into "sv_SE.ISO-8859-1", and so on,
 506     ;; using the translation file that GNU/Linux systems have.
 507     (and ctype
 508          (not (string-match iso-8859-n-locale-regexp ctype))
 509          (file-exists-p locale-translation-file-name)
 510          (with-temp-buffer
 511            (insert-file-contents locale-translation-file-name)
 512            (if (re-search-forward (concat "^" ctype "[ \t]*") nil t)
 513                (setq ctype (buffer-substring (point)
 514                                              (progn (end-of-line) (point)))))))
 515     ;; Now see if the locale specifies an ISO 8859 character set.
 516     (when (and ctype
 517                (string-match iso-8859-n-locale-regexp ctype))
 518       (let (charset (which (match-string 1 ctype)))
 519         (if (equal "5" which)
 520             (setq which "9"))
 521         (setq charset (concat "latin-" which))
 522         (when (string-match "latin-[12345]" charset)
 523           ;; Set up for this character set.
 524           ;; This is now the right way to do it
 525           ;; for both unibyte and multibyte modes.
 526           (set-language-environment charset)
 527           (unless (or noninteractive (eq window-system 'x))
 528             ;; Send those codes literally to a non-X terminal.
 529             (when default-enable-multibyte-characters
 530               ;; If this is nil, we are using single-byte characters,
 531               ;; so the terminal coding system is irrelevant.
 532               (set-terminal-coding-system
 533                (intern (downcase charset)))))
 534           (standard-display-european-internal)))))
 535
 536   ;;! This has been commented out; I currently find the behavior when
 537   ;;! split-window-keep-point is nil disturbing, but if I can get used
 538   ;;! to it, then it would be better to eliminate the option.
 539   ;;! ;; Choose a good default value for split-window-keep-point.
 540   ;;! (setq split-window-keep-point (> baud-rate 2400))
 541
 542   ;; Read window system's init file if using a window system.
 543   (condition-case error
 544       (if (and window-system (not noninteractive))
 545           (load (concat term-file-prefix
 546                         (symbol-name window-system)
 547                         "-win")
 548                 ;; Every window system should have a startup file;
 549                 ;; barf if we can't find it.
 550                 nil t))
 551     ;; If we can't read it, print the error message and exit.
 552     (error
 553      (princ
 554       (if (eq (car error) 'error)
 555           (apply 'concat (cdr error))
 556         (if (memq 'file-error (get (car error) 'error-conditions))
 557             (format "%s: %s"
 558                      (nth 1 error)
 559                      (mapconcat '(lambda (obj) (prin1-to-string obj t))
 560                                 (cdr (cdr error)) ", "))
 561           (format "%s: %s"
 562                    (get (car error) 'error-message)
 563                    (mapconcat '(lambda (obj) (prin1-to-string obj t))
 564                               (cdr error) ", "))))
 565       'external-debugging-output)
 566      (setq window-system nil)
 567      (kill-emacs)))
 568
 569   (let ((done nil)
 570         (args (cdr command-line-args)))
 571
 572     ;; Figure out which user's init file to load,
 573     ;; either from the environment or from the options.
 574     (setq init-file-user (if noninteractive nil (user-login-name)))
 575     ;; If user has not done su, use current $HOME to find .emacs.
 576     (and init-file-user (string= init-file-user (user-real-login-name))
 577          (setq init-file-user ""))
 578
 579     ;; Process the command-line args, and delete the arguments
 580     ;; processed.  This is consistent with the way main in emacs.c
 581     ;; does things.
 582     (while (and (not done) args)
 583       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 584                         ("--debug-init") ("--iconic") ("--icon-type")))
 585             (argi (car args))
 586             (argval nil))
 587         ;; Handle --OPTION=VALUE format.
 588         (if (and (string-match "\\`--" argi)
 589                  (string-match "=" argi))
 590             (setq argval (substring argi (match-end 0))
 591                   argi (substring argi 0 (match-beginning 0))))
 592         (or (equal argi "--")
 593             (let ((completion (try-completion argi longopts)))
 594               (if (eq completion t)
 595                   (setq argi (substring argi 1))
 596                 (if (stringp completion)
 597                     (let ((elt (assoc completion longopts)))
 598                       (or elt
 599                           (error "Option `%s' is ambiguous" argi))
 600                       (setq argi (substring (car elt) 1)))
 601                   (setq argval nil)))))
 602         (cond
 603          ((or (string-equal argi "-q")
 604               (string-equal argi "-no-init-file"))
 605           (setq init-file-user nil
 606                 args (cdr args)))
 607          ((or (string-equal argi "-u")
 608               (string-equal argi "-user"))
 609           (or argval
 610               (setq args (cdr args)
 611                     argval (car args)))
 612           (setq init-file-user argval
 613                 argval nil
 614                 args (cdr args)))
 615          ((string-equal argi "-no-site-file")
 616           (setq site-run-file nil
 617                 args (cdr args)))
 618          ((string-equal argi "-debug-init")
 619           (setq init-file-debug t
 620                 args (cdr args)))
 621          ((string-equal argi "-iconic")
 622           (setq initial-frame-alist
 623                 (cons '(visibility . icon) initial-frame-alist))
 624           (setq args (cdr args)))
 625          ((or (string-equal argi "-icon-type")
 626               (string-equal argi "-i")
 627               (string-equal argi "-itype"))
 628           (setq default-frame-alist
 629                 (cons '(icon-type . t) default-frame-alist))
 630           (setq args (cdr args)))
 631          (t (setq done t)))
 632         ;; Was argval set but not used?
 633         (and argval
 634              (error "Option `%s' doesn't allow an argument" argi))))
 635
 636     ;; Re-attach the program name to the front of the arg list.
 637     (and command-line-args (setcdr command-line-args args)))
 638
 639   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 640   (if (fboundp 'frame-initialize)
 641       (frame-initialize))
 642   ;; If frame was created with a menu bar, set menu-bar-mode on.
 643   (if (or (not (memq window-system '(x w32)))
 644           (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0))
 645       (menu-bar-mode t))
 646
 647   (run-hooks 'before-init-hook)
 648
 649   ;; Run the site-start library if it exists.  The point of this file is
 650   ;; that it is run before .emacs.  There is no point in doing this after
 651   ;; .emacs; that is useless.
 652   (if site-run-file
 653       (load site-run-file t t))
 654
 655   ;; Register available input methods by loading LEIM list file.
 656   (load "leim-list.el" 'noerror 'nomessage 'nosuffix)
 657
 658   ;; Sites should not disable this.  Only individuals should disable
 659   ;; the startup message.
 660   (setq inhibit-startup-message nil)
 661
 662   ;; Load that user's init file, or the default one, or none.
 663   (let (debug-on-error-from-init-file
 664         debug-on-error-should-be-set
 665         (debug-on-error-initial
 666          (if (eq init-file-debug t) 'startup init-file-debug)))
 667     (let ((debug-on-error debug-on-error-initial)
 668           ;; This function actually reads the init files.
 669           (inner
 670            (function
 671             (lambda ()
 672               (if init-file-user
 673                   (progn
 674                     (setq user-init-file
 675                           (cond
 676                            ((eq system-type 'ms-dos)
 677                             (concat "~" init-file-user "/_emacs"))
 678                            ((eq system-type 'windows-nt)
 679                             (if (file-exists-p "~/.emacs")
 680                                 "~/.emacs"
 681                               "~/_emacs"))
 682                            ((eq system-type 'vax-vms)
 683                             "sys$login:.emacs")
 684                            (t
 685                             (concat "~" init-file-user "/.emacs"))))
 686                     (load user-init-file t t)
 687                     (or inhibit-default-init
 688                         (let ((inhibit-startup-message nil))
 689                           ;; Users are supposed to be told their rights.
 690                           ;; (Plus how to get help and how to undo.)
 691                           ;; Don't you dare turn this off for anyone
 692                           ;; except yourself.
 693                           (load "default" t t)))))))))
 694       (if init-file-debug
 695           ;; Do this without a condition-case if the user wants to debug.
 696           (funcall inner)
 697         (condition-case error
 698             (progn
 699               (funcall inner)
 700               (setq init-file-had-error nil))
 701           (error (message "Error in init file: %s%s%s"
 702                           (get (car error) 'error-message)
 703                           (if (cdr error) ": " "")
 704                           (mapconcat 'prin1-to-string (cdr error) ", "))
 705                  (setq init-file-had-error t))))
 706       ;; If we can tell that the init file altered debug-on-error,
 707       ;; arrange to preserve the value that it set up.
 708       (or (eq debug-on-error debug-on-error-initial)
 709           (setq debug-on-error-should-be-set t
 710                 debug-on-error-from-init-file debug-on-error)))
 711     (if debug-on-error-should-be-set
 712         (setq debug-on-error debug-on-error-from-init-file)))
 713
 714   ;; Do this here in case the init file sets mail-host-address.
 715   (or user-mail-address
 716       (setq user-mail-address (concat (user-login-name) "@"
 717                                       (or mail-host-address
 718                                           (system-name)))))
 719
 720   (run-hooks 'after-init-hook)
 721
 722   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 723   (if (get-buffer "*scratch*")
 724       (save-excursion
 725         (set-buffer "*scratch*")
 726         (if (eq major-mode 'fundamental-mode)
 727             (funcall initial-major-mode))))
 728   ;; Load library for our terminal type.
 729   ;; User init file can set term-file-prefix to nil to prevent this.
 730   (and term-file-prefix (not noninteractive) (not window-system)
 731        (let ((term (getenv "TERM"))
 732              hyphend)
 733          (while (and term
 734                      (not (load (concat term-file-prefix term) t t)))
 735            ;; Strip off last hyphen and what follows, then try again
 736            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 737                (setq term (substring term 0 hyphend))
 738              (setq term nil)))))
 739
 740   ;; Process the remaining args.
 741   (command-line-1 (cdr command-line-args))
 742
 743   ;; If -batch, terminate after processing the command options.
 744   (if noninteractive (kill-emacs t)))
 745
 746 (defcustom initial-scratch-message "\
 747 This buffer is for notes you don't want to save, and for Lisp evaluation.
 748 If you want to create a file, visit that file with C-x C-f,
 749 then enter the text in that file's own buffer.
 750
 751 "
 752   "Initial message displayed in *scratch* buffer at startup.
 753 If this is nil, no message will be displayed."
 754   :type 'string)
 755
 756 (defun command-line-1 (command-line-args-left)
 757   (or noninteractive (input-pending-p) init-file-had-error
 758       (and inhibit-startup-echo-area-message
 759            user-init-file
 760            (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
 761                     (equal inhibit-startup-echo-area-message
 762                            (if (string= init-file-user "")
 763                                (user-login-name)
 764                              init-file-user)))
 765                ;; Wasn't set with custom; see if .emacs has a setq.
 766                (let ((buffer (get-buffer-create " *temp*")))
 767                  (prog1
 768                      (condition-case nil
 769                          (save-excursion
 770                            (set-buffer buffer)
 771                            (insert-file-contents user-init-file)
 772                            (re-search-forward
 773                             (concat
 774                              "([ \t\n]*setq[ \t\n]+"
 775                              "inhibit-startup-echo-area-message[ \t\n]+"
 776                              (regexp-quote
 777                               (prin1-to-string
 778                                (if (string= init-file-user "")
 779                                    (user-login-name)
 780                                  init-file-user)))
 781                              "[ \t\n]*)")
 782                             nil t))
 783                        (error nil))
 784                    (kill-buffer buffer)))))
 785       (message (if (eq (key-binding "\C-h\C-p") 'describe-project)
 786                    "For information about the GNU Project and its goals, type C-h C-p."
 787                  (substitute-command-keys
 788                   "For information about the GNU Project and its goals, type \\[describe-project]."))))
 789   (if (null command-line-args-left)
 790       (cond ((and (not inhibit-startup-message) (not noninteractive)
 791                   ;; Don't clobber a non-scratch buffer if init file
 792                   ;; has selected it.
 793                   (string= (buffer-name) "*scratch*"))
 794              ;; If there are no switches to process, we might as well
 795              ;; run this hook now, and there may be some need to do it
 796              ;; before doing any output.
 797              (and term-setup-hook
 798                   (run-hooks 'term-setup-hook))
 799              ;; Don't let the hook be run twice.
 800              (setq term-setup-hook nil)
 801
 802              ;; It's important to notice the user settings before we
 803              ;; display the startup message; otherwise, the settings
 804              ;; won't take effect until the user gives the first
 805              ;; keystroke, and that's distracting.
 806              (if (fboundp 'frame-notice-user-settings)
 807                  (frame-notice-user-settings))
 808
 809              (and window-setup-hook
 810                   (run-hooks 'window-setup-hook))
 811              (setq window-setup-hook nil)
 812              ;; Do this now to avoid an annoying delay if the user
 813              ;; clicks the menu bar during the sit-for.
 814              (if (memq window-system '(x w32))
 815                  (precompute-menubar-bindings))
 816              (setq menubar-bindings-done t)
 817              (when (= (buffer-size) 0)
 818                (let ((buffer-undo-list t))
 819                  (unwind-protect
 820                      (when (not (input-pending-p))
 821                        (goto-char (point-max))
 822                        ;; The convention for this piece of code is that
 823                        ;; each piece of output starts with one or two newlines
 824                        ;; and does not end with any newlines.
 825                        (insert "Welcome to GNU Emacs")
 826                        (if (eq system-type 'gnu/linux)
 827                            (insert ", one component of a Linux-based GNU system."))
 828                        (insert "\n")
 829                        (if (assq 'display (frame-parameters))
 830                            (progn
 831                              (insert "\
 832 The menu bar above is sufficient for basic editing with the mouse.
 833
 834 Useful Files menu items:
 835 Exit Emacs              (or type Control-x followed by Control-c)
 836 Recover Session         recover files you were editing before a crash
 837
 838 Important Help menu items:
 839 Emacs Tutorial          Learn-by-doing tutorial for using Emacs efficiently.
 840 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
 841 Copying Conditions      Conditions for redistributing and changing Emacs.
 842 Getting New Versions    How to obtain the latest version of Emacs.
 843 ")
 844                              (insert "\n\n" (emacs-version)
 845                                      "
 846 Copyright (C) 1998 Free Software Foundation, Inc."))
 847                          ;; If keys have their default meanings,
 848                          ;; use precomputed string to save lots of time.
 849                          (if (and (eq (key-binding "\C-h") 'help-command)
 850                                   (eq (key-binding "\C-xu") 'advertised-undo)
 851                                   (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 852                                   (eq (key-binding "\C-ht") 'help-with-tutorial)
 853                                   (eq (key-binding "\C-hi") 'info)
 854                                   (eq (key-binding "\C-h\C-n") 'view-emacs-news))
 855                              (insert "
 856 Get help           C-h  (Hold down CTRL and press h)
 857 Undo changes       C-x u       Exit Emacs               C-x C-c
 858 Get a tutorial     C-h t       Use Info to read docs    C-h i")
 859                            (insert (substitute-command-keys
 860                                     (format "\n
 861 Get help           %s
 862 Undo changes       \\[advertised-undo]
 863 Exit Emacs         \\[save-buffers-kill-emacs]
 864 Get a tutorial     \\[help-with-tutorial]
 865 Use Info to read docs   \\[info]"
 866                                             (let ((where (where-is-internal
 867                                                           'help-command nil t)))
 868                                               (if where
 869                                                   (key-description where)
 870                                                 "M-x help"))))))
 871                          ;; Say how to use the menu bar
 872                          ;; if that is not with the mouse.
 873                          (if (and (eq (key-binding "\M-`") 'tmm-menubar)
 874                                   (eq (key-binding [f10]) 'tmm-menubar))
 875                              (insert "
 876 Activate menubar   F10  or  ESC `  or   M-`")
 877                            (insert (substitute-command-keys "
 878 Activate menubar     \\[tmm-menubar]")))
 879
 880                        ;; Windows and MSDOS (currently) do not count as
 881                        ;; window systems, but do have mouse support.
 882                          (if window-system
 883                              (insert "
 884 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
 885                          ;; Many users seem to have problems with these.
 886                          (insert "
 887 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
 888 If you have no Meta key, you may instead type ESC followed by the character.)")
 889                          (and auto-save-list-file-prefix
 890                               (directory-files
 891                                (file-name-directory auto-save-list-file-prefix)
 892                                nil
 893                                (concat "\\`"
 894                                        (regexp-quote (file-name-nondirectory
 895                                                       auto-save-list-file-prefix)))
 896                                t)
 897                               (insert "\n\nIf an Emacs session crashed recently, "
 898                                       "type M-x recover-session RET\nto recover"
 899                                       " the files you were editing."))
 900
 901                          (insert "\n\n" (emacs-version)
 902                                  "
 903 Copyright (C) 1998 Free Software Foundation, Inc.")
 904                          (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
 905                                   (eq (key-binding "\C-h\C-d") 'describe-distribution)
 906                                   (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
 907                              (insert
 908                               "\n
 909 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 910 You may give out copies of Emacs; type C-h C-c to see the conditions.
 911 Type C-h C-d for information on getting the latest version.")
 912                            (insert (substitute-command-keys
 913                                     "\n
 914 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 915 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 916 Type \\[describe-distribution] for information on getting the latest version."))))
 917                        (goto-char (point-min))
 918
 919                        (set-buffer-modified-p nil)
 920                        (sit-for 120))
 921                    (with-current-buffer (get-buffer "*scratch*")
 922                      (erase-buffer)
 923                      (and initial-scratch-message
 924                           (insert initial-scratch-message))
 925                      (set-buffer-modified-p nil)))))))
 926     ;; Delay 2 seconds after the init file error message
 927     ;; was displayed, so user can read it.
 928     (if init-file-had-error
 929         (sit-for 2))
 930     (let ((dir command-line-default-directory)
 931           (file-count 0)
 932           first-file-buffer
 933           tem
 934           just-files  ;; t if this follows the magic -- option.
 935           ;; This includes our standard options' long versions
 936           ;; and long versions of what's on command-switch-alist.
 937           (longopts
 938            (append '(("--funcall") ("--load") ("--insert") ("--kill")
 939                      ("--directory") ("--eval") ("--find-file") ("--visit"))
 940                    (mapcar '(lambda (elt)
 941                               (list (concat "-" (car elt))))
 942                            command-switch-alist)))
 943           (line 0))
 944
 945       ;; Add the long X options to longopts.
 946       (setq tem command-line-x-option-alist)
 947       (while tem
 948         (if (string-match "^--" (car (car tem)))
 949             (setq longopts (cons (list (car (car tem))) longopts)))
 950         (setq tem (cdr tem)))
 951
 952       ;; Loop, processing options.
 953       (while (and command-line-args-left)
 954         (let* ((argi (car command-line-args-left))
 955                (orig-argi argi)
 956                argval completion
 957                ;; List of directories specified in -L/--directory,
 958                ;; in reverse of the order specified.
 959                extra-load-path
 960                (initial-load-path load-path))
 961           (setq command-line-args-left (cdr command-line-args-left))
 962
 963           ;; Do preliminary decoding of the option.
 964           (if just-files
 965               ;; After --, don't look for options; treat all args as files.
 966               (setq argi "")
 967             ;; Convert long options to ordinary options
 968             ;; and separate out an attached option argument into argval.
 969             (if (string-match "^--[^=]*=" argi)
 970                 (setq argval (substring argi (match-end 0))
 971                       argi (substring argi 0 (1- (match-end 0)))))
 972             (if (equal argi "--")
 973                 (setq completion nil)
 974               (setq completion (try-completion argi longopts)))
 975             (if (eq completion t)
 976                 (setq argi (substring argi 1))
 977               (if (stringp completion)
 978                   (let ((elt (assoc completion longopts)))
 979                     (or elt
 980                         (error "Option `%s' is ambiguous" argi))
 981                     (setq argi (substring (car elt) 1)))
 982                 (setq argval nil argi orig-argi))))
 983
 984           ;; Execute the option.
 985           (cond ((setq tem (assoc argi command-switch-alist))
 986                  (if argval
 987                      (let ((command-line-args-left
 988                             (cons argval command-line-args-left)))
 989                        (funcall (cdr tem) argi))
 990                    (funcall (cdr tem) argi)))
 991                 ((or (string-equal argi "-f")  ;what the manual claims
 992                      (string-equal argi "-funcall")
 993                      (string-equal argi "-e")) ; what the source used to say
 994                  (if argval
 995                      (setq tem (intern argval))
 996                    (setq tem (intern (car command-line-args-left)))
 997                    (setq command-line-args-left (cdr command-line-args-left)))
 998                  (if (arrayp (symbol-function tem))
 999                      (command-execute tem)
1000                    (funcall tem)))
1001                 ((string-equal argi "-eval")
1002                  (if argval
1003                      (setq tem argval)
1004                    (setq tem (car command-line-args-left))
1005                    (setq command-line-args-left (cdr command-line-args-left)))
1006                  (eval (read tem)))
1007                 ;; Set the default directory as specified in -L.
1008                 ((or (string-equal argi "-L")
1009                      (string-equal argi "-directory"))
1010                  (if argval
1011                      (setq tem argval)
1012                    (setq tem (car command-line-args-left)
1013                          command-line-args-left (cdr command-line-args-left)))
1014                  (setq tem (command-line-normalize-file-name tem))
1015                  (setq extra-load-path
1016                        (cons (expand-file-name tem) extra-load-path))
1017                  (setq load-path (append (nreverse extra-load-path)
1018                                          initial-load-path)))
1019                 ((or (string-equal argi "-l")
1020                      (string-equal argi "-load"))
1021                  (if argval
1022                      (setq tem argval)
1023                    (setq tem (car command-line-args-left)
1024                          command-line-args-left (cdr command-line-args-left)))
1025                  (let ((file (command-line-normalize-file-name tem)))
1026                    ;; Take file from default dir if it exists there;
1027                    ;; otherwise let `load' search for it.
1028                    (if (file-exists-p (expand-file-name file))
1029                        (setq file (expand-file-name file)))
1030                    (load file nil t)))
1031                 ((string-equal argi "-insert")
1032                  (if argval
1033                      (setq tem argval)
1034                    (setq tem (car command-line-args-left)
1035                          command-line-args-left (cdr command-line-args-left)))
1036                  (or (stringp tem)
1037                      (error "File name omitted from `-insert' option"))
1038                  (insert-file-contents (command-line-normalize-file-name tem)))
1039                 ((string-equal argi "-kill")
1040                  (kill-emacs t))
1041                 ((string-match "^\\+[0-9]+\\'" argi)
1042                  (setq line (string-to-int argi)))
1043                 ((setq tem (assoc argi command-line-x-option-alist))
1044                  ;; Ignore X-windows options and their args if not using X.
1045                  (setq command-line-args-left
1046                        (nthcdr (nth 1 tem) command-line-args-left)))
1047                 ((or (string-equal argi "-find-file")
1048                      (string-equal argi "-visit"))
1049                  ;; An explicit option to specify visiting a file.
1050                  (setq file-count (1+ file-count))
1051                  (let ((file
1052                         (expand-file-name
1053                          (command-line-normalize-file-name orig-argi)
1054                          dir)))
1055                    (if (= file-count 1)
1056                        (setq first-file-buffer (find-file file))
1057                      (find-file-other-window file)))
1058                  (or (zerop line)
1059                      (goto-line line))
1060                  (setq line 0))
1061                 ((equal argi "--")
1062                  (setq just-files t))
1063                 (t
1064                  ;; We have almost exhausted our options. See if the
1065                  ;; user has made any other command-line options available
1066                  (let ((hooks command-line-functions);; lrs 7/31/89
1067                        (did-hook nil))
1068                    (while (and hooks
1069                                (not (setq did-hook (funcall (car hooks)))))
1070                      (setq hooks (cdr hooks)))
1071                    (if (not did-hook)
1072                        ;; Ok, presume that the argument is a file name
1073                        (progn
1074                          (if (string-match "\\`-" argi)
1075                              (error "Unknown option `%s'" argi))
1076                          (setq file-count (1+ file-count))
1077                          (let ((file
1078                                 (expand-file-name
1079                                  (command-line-normalize-file-name orig-argi)
1080                                  dir)))
1081                            (if (= file-count 1)
1082                                (setq first-file-buffer (find-file file))
1083                              (find-file-other-window file)))
1084                          (or (zerop line)
1085                              (goto-line line))
1086                          (setq line 0))))))))
1087       ;; If 3 or more files visited, and not all visible,
1088       ;; show user what they all are.
1089       (and (> file-count 2)
1090            (not noninteractive)
1091            (or (get-buffer-window first-file-buffer)
1092                (progn (other-window 1)
1093                       (buffer-menu)))))))
1094
1095 (defun command-line-normalize-file-name (file)
1096   "Collapse multiple slashes to one, to handle non-Emacs file names."
1097   (save-match-data
1098     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1099     ;; That is significant on some systems.
1100     ;; However, /// at the beginning is supposed to mean just /, not //.
1101     (if (string-match "^///+" file)
1102         (setq file (replace-match "/" t t file)))
1103     (while (string-match "//+" file 1)
1104       (setq file (replace-match "/" t t file)))
1105     file))
1106
1107 ;;; startup.el ends here