lisp/url/url-util.el

   1 ;;; url-util.el --- Miscellaneous helper routines for URL library
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009  Free Software Foundation, Inc.
   5
   6 ;; Author: Bill Perry <wmperry@gnu.org>
   7 ;; Keywords: comm, data, processes
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'url-parse)
  29 (eval-when-compile (require 'cl))
  30 (autoload 'timezone-parse-date "timezone")
  31 (autoload 'timezone-make-date-arpa-standard "timezone")
  32 (autoload 'mail-header-extract "mailheader")
  33
  34 (defvar url-parse-args-syntax-table
  35   (copy-syntax-table emacs-lisp-mode-syntax-table)
  36   "A syntax table for parsing sgml attributes.")
  37
  38 (modify-syntax-entry ?' "\"" url-parse-args-syntax-table)
  39 (modify-syntax-entry ?` "\"" url-parse-args-syntax-table)
  40 (modify-syntax-entry ?{ "(" url-parse-args-syntax-table)
  41 (modify-syntax-entry ?} ")" url-parse-args-syntax-table)
  42
  43 ;;;###autoload
  44 (defcustom url-debug nil
  45   "*What types of debug messages from the URL library to show.
  46 Debug messages are logged to the *URL-DEBUG* buffer.
  47
  48 If t, all messages will be logged.
  49 If a number, all messages will be logged, as well shown via `message'.
  50 If a list, it is a list of the types of messages to be logged."
  51   :type '(choice (const :tag "none" nil)
  52                  (const :tag "all" t)
  53                  (checklist :tag "custom"
  54                             (const :tag "HTTP" :value http)
  55                             (const :tag "DAV" :value dav)
  56                             (const :tag "General" :value retrieval)
  57                             (const :tag "Filename handlers" :value handlers)
  58                             (symbol :tag "Other")))
  59   :group 'url-hairy)
  60
  61 ;;;###autoload
  62 (defun url-debug (tag &rest args)
  63   (if quit-flag
  64       (error "Interrupted!"))
  65   (if (or (eq url-debug t)
  66           (numberp url-debug)
  67           (and (listp url-debug) (memq tag url-debug)))
  68       (with-current-buffer (get-buffer-create "*URL-DEBUG*")
  69         (goto-char (point-max))
  70         (insert (symbol-name tag) " -> " (apply 'format args) "\n")
  71         (if (numberp url-debug)
  72             (apply 'message args)))))
  73
  74 ;;;###autoload
  75 (defun url-parse-args (str &optional nodowncase)
  76   ;; Return an assoc list of attribute/value pairs from an RFC822-type string
  77   (let (
  78         name                            ; From name=
  79         value                           ; its value
  80         results                         ; Assoc list of results
  81         name-pos                        ; Start of XXXX= position
  82         val-pos                         ; Start of value position
  83         st
  84         nd
  85         )
  86     (save-excursion
  87       (save-restriction
  88         (set-buffer (get-buffer-create " *urlparse-temp*"))
  89         (set-syntax-table url-parse-args-syntax-table)
  90         (erase-buffer)
  91         (insert str)
  92         (setq st (point-min)
  93               nd (point-max))
  94         (set-syntax-table url-parse-args-syntax-table)
  95         (narrow-to-region st nd)
  96         (goto-char (point-min))
  97         (while (not (eobp))
  98           (skip-chars-forward "; \n\t")
  99           (setq name-pos (point))
 100           (skip-chars-forward "^ \n\t=;")
 101           (if (not nodowncase)
 102               (downcase-region name-pos (point)))
 103           (setq name (buffer-substring name-pos (point)))
 104           (skip-chars-forward " \t\n")
 105           (if (/= (or (char-after (point)) 0)  ?=) ; There is no value
 106               (setq value nil)
 107             (skip-chars-forward " \t\n=")
 108             (setq val-pos (point)
 109                   value
 110                   (cond
 111                    ((or (= (or (char-after val-pos) 0) ?\")
 112                         (= (or (char-after val-pos) 0) ?'))
 113                     (buffer-substring (1+ val-pos)
 114                                       (condition-case ()
 115                                           (prog2
 116                                               (forward-sexp 1)
 117                                               (1- (point))
 118                                             (skip-chars-forward "\""))
 119                                         (error
 120                                          (skip-chars-forward "^ \t\n")
 121                                          (point)))))
 122                    (t
 123                     (buffer-substring val-pos
 124                                       (progn
 125                                         (skip-chars-forward "^;")
 126                                         (skip-chars-backward " \t")
 127                                         (point)))))))
 128           (setq results (cons (cons name value) results))
 129           (skip-chars-forward "; \n\t"))
 130         results))))
 131
 132 ;;;###autoload
 133 (defun url-insert-entities-in-string (string)
 134   "Convert HTML markup-start characters to entity references in STRING.
 135 Also replaces the \" character, so that the result may be safely used as
 136   an attribute value in a tag.  Returns a new string with the result of the
 137   conversion.  Replaces these characters as follows:
 138     &  ==>  &amp;
 139     <  ==>  &lt;
 140     >  ==>  &gt;
 141     \"  ==>  &quot;"
 142   (if (string-match "[&<>\"]" string)
 143       (with-current-buffer (get-buffer-create " *entity*")
 144         (erase-buffer)
 145         (buffer-disable-undo (current-buffer))
 146         (insert string)
 147         (goto-char (point-min))
 148         (while (progn
 149                  (skip-chars-forward "^&<>\"")
 150                  (not (eobp)))
 151           (insert (cdr (assq (char-after (point))
 152                              '((?\" . "&quot;")
 153                                (?& . "&amp;")
 154                                (?< . "&lt;")
 155                                (?> . "&gt;")))))
 156           (delete-char 1))
 157         (buffer-string))
 158     string))
 159
 160 ;;;###autoload
 161 (defun url-normalize-url (url)
 162   "Return a 'normalized' version of URL.
 163 Strips out default port numbers, etc."
 164   (let (type data retval)
 165     (setq data (url-generic-parse-url url)
 166           type (url-type data))
 167     (if (member type '("www" "about" "mailto" "info"))
 168         (setq retval url)
 169       ;; FIXME all this does, and all this function seems to do in
 170       ;; most cases, is remove any trailing "#anchor" part of a url.
 171       (setf (url-target data) nil)
 172       (setq retval (url-recreate-url data)))
 173     retval))
 174
 175 ;;;###autoload
 176 (defun url-lazy-message (&rest args)
 177   "Just like `message', but is a no-op if called more than once a second.
 178 Will not do anything if `url-show-status' is nil."
 179   (if (or (null url-show-status)
 180           (active-minibuffer-window)
 181           (= url-lazy-message-time
 182              (setq url-lazy-message-time (nth 1 (current-time)))))
 183       nil
 184     (apply 'message args)))
 185
 186 ;;;###autoload
 187 (defun url-get-normalized-date (&optional specified-time)
 188  "Return a 'real' date string that most HTTP servers can understand."
 189  (let ((system-time-locale "C"))
 190   (format-time-string "%a, %d %b %Y %T GMT"
 191    (or specified-time (current-time)) t)))
 192
 193 ;;;###autoload
 194 (defun url-eat-trailing-space (x)
 195   "Remove spaces/tabs at the end of a string."
 196   (let ((y (1- (length x)))
 197         (skip-chars (list ?  ?\t ?\n)))
 198     (while (and (>= y 0) (memq (aref x y) skip-chars))
 199       (setq y (1- y)))
 200     (substring x 0 (1+ y))))
 201
 202 ;;;###autoload
 203 (defun url-strip-leading-spaces (x)
 204   "Remove spaces at the front of a string."
 205   (let ((y (1- (length x)))
 206         (z 0)
 207         (skip-chars (list ?  ?\t ?\n)))
 208     (while (and (<= z y) (memq (aref x z) skip-chars))
 209       (setq z (1+ z)))
 210     (substring x z nil)))
 211
 212 ;;;###autoload
 213 (defun url-pretty-length (n)
 214   (cond
 215    ((< n 1024)
 216     (format "%d bytes" n))
 217    ((< n (* 1024 1024))
 218     (format "%dk" (/ n 1024.0)))
 219    (t
 220     (format "%2.2fM" (/ n (* 1024 1024.0))))))
 221
 222 ;;;###autoload
 223 (defun url-display-percentage (fmt perc &rest args)
 224   (when url-show-status
 225     (if (null fmt)
 226         (if (fboundp 'clear-progress-display)
 227             (clear-progress-display))
 228       (if (and (fboundp 'progress-display) perc)
 229           (apply 'progress-display fmt perc args)
 230         (apply 'message fmt args)))))
 231
 232 ;;;###autoload
 233 (defun url-percentage (x y)
 234   (if (fboundp 'float)
 235       (round (* 100 (/ x (float y))))
 236     (/ (* x 100) y)))
 237
 238 ;;;###autoload
 239 (defalias 'url-basepath 'url-file-directory)
 240
 241 ;;;###autoload
 242 (defun url-file-directory (file)
 243   "Return the directory part of FILE, for a URL."
 244   (cond
 245    ((null file) "")
 246    ((string-match (eval-when-compile (regexp-quote "?")) file)
 247     (file-name-directory (substring file 0 (match-beginning 0))))
 248    (t (file-name-directory file))))
 249
 250 ;;;###autoload
 251 (defun url-file-nondirectory (file)
 252   "Return the nondirectory part of FILE, for a URL."
 253   (cond
 254    ((null file) "")
 255    ((string-match (eval-when-compile (regexp-quote "?")) file)
 256     (file-name-nondirectory (substring file 0 (match-beginning 0))))
 257    (t (file-name-nondirectory file))))
 258
 259 ;;;###autoload
 260 (defun url-parse-query-string (query &optional downcase allow-newlines)
 261   (let (retval pairs cur key val)
 262     (setq pairs (split-string query "&"))
 263     (while pairs
 264       (setq cur (car pairs)
 265             pairs (cdr pairs))
 266       (if (not (string-match "=" cur))
 267           nil                           ; Grace
 268         (setq key (url-unhex-string (substring cur 0 (match-beginning 0))
 269                                     allow-newlines))
 270         (setq val (url-unhex-string (substring cur (match-end 0) nil)
 271                                     allow-newlines))
 272         (if downcase
 273             (setq key (downcase key)))
 274         (setq cur (assoc key retval))
 275         (if cur
 276             (setcdr cur (cons val (cdr cur)))
 277           (setq retval (cons (list key val) retval)))))
 278     retval))
 279
 280 (defun url-unhex (x)
 281   (if (> x ?9)
 282       (if (>= x ?a)
 283           (+ 10 (- x ?a))
 284         (+ 10 (- x ?A)))
 285     (- x ?0)))
 286
 287 ;; Fixme: Is this definition better, and does it ever matter?
 288
 289 ;; (defun url-unhex-string (str &optional allow-newlines)
 290 ;;   "Remove %XX, embedded spaces, etc in a url.
 291 ;; If optional second argument ALLOW-NEWLINES is non-nil, then allow the
 292 ;; decoding of carriage returns and line feeds in the string, which is normally
 293 ;; forbidden in URL encoding."
 294 ;;   (setq str (or str ""))
 295 ;;   (setq str (replace-regexp-in-string "%[[:xdigit:]]\\{2\\}"
 296 ;;                                    (lambda (match)
 297 ;;                                      (string (string-to-number
 298 ;;                                               (substring match 1) 16)))
 299 ;;                                    str t t))
 300 ;;   (if allow-newlines
 301 ;;       (replace-regexp-in-string "[\n\r]" (lambda (match)
 302 ;;                                         (format "%%%.2X" (aref match 0)))
 303 ;;                              str t t)
 304 ;;     str))
 305
 306 ;;;###autoload
 307 (defun url-unhex-string (str &optional allow-newlines)
 308   "Remove %XX embedded spaces, etc in a URL.
 309 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
 310 decoding of carriage returns and line feeds in the string, which is normally
 311 forbidden in URL encoding."
 312   (setq str (or str ""))
 313   (let ((tmp "")
 314         (case-fold-search t))
 315     (while (string-match "%[0-9a-f][0-9a-f]" str)
 316       (let* ((start (match-beginning 0))
 317              (ch1 (url-unhex (elt str (+ start 1))))
 318              (code (+ (* 16 ch1)
 319                       (url-unhex (elt str (+ start 2))))))
 320         (setq tmp (concat
 321                    tmp (substring str 0 start)
 322                    (cond
 323                     (allow-newlines
 324                      (char-to-string code))
 325                     ((or (= code ?\n) (= code ?\r))
 326                      " ")
 327                     (t (char-to-string code))))
 328               str (substring str (match-end 0)))))
 329     (setq tmp (concat tmp str))
 330     tmp))
 331
 332 (defconst url-unreserved-chars
 333   '(
 334     ?a ?b ?c ?d ?e ?f ?g ?h ?i ?j ?k ?l ?m ?n ?o ?p ?q ?r ?s ?t ?u ?v ?w ?x ?y ?z
 335     ?A ?B ?C ?D ?E ?F ?G ?H ?I ?J ?K ?L ?M ?N ?O ?P ?Q ?R ?S ?T ?U ?V ?W ?X ?Y ?Z
 336     ?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9
 337     ?- ?_ ?. ?! ?~ ?* ?' ?\( ?\))
 338   "A list of characters that are _NOT_ reserved in the URL spec.
 339 This is taken from RFC 2396.")
 340
 341 ;;;###autoload
 342 (defun url-hexify-string (string)
 343   "Return a new string that is STRING URI-encoded.
 344 First, STRING is converted to utf-8, if necessary.  Then, for each
 345 character in the utf-8 string, those found in `url-unreserved-chars'
 346 are left as-is, all others are represented as a three-character
 347 string: \"%\" followed by two lowercase hex digits."
 348   ;; To go faster and avoid a lot of consing, we could do:
 349   ;;
 350   ;; (defconst url-hexify-table
 351   ;;   (let ((map (make-vector 256 nil)))
 352   ;;     (dotimes (byte 256) (aset map byte
 353   ;;                               (if (memq byte url-unreserved-chars)
 354   ;;                                   (char-to-string byte)
 355   ;;                                 (format "%%%02x" byte))))
 356   ;;     map))
 357   ;;
 358   ;; (mapconcat (curry 'aref url-hexify-table) ...)
 359   (mapconcat (lambda (byte)
 360                (if (memq byte url-unreserved-chars)
 361                    (char-to-string byte)
 362                  (format "%%%02x" byte)))
 363              (if (multibyte-string-p string)
 364                  (encode-coding-string string 'utf-8)
 365                string)
 366              ""))
 367
 368 ;;;###autoload
 369 (defun url-file-extension (fname &optional x)
 370   "Return the filename extension of FNAME.
 371 If optional argument X is t, then return the basename
 372 of the file with the extension stripped off."
 373   (if (and fname
 374            (setq fname (url-file-nondirectory fname))
 375            (string-match "\\.[^./]+$" fname))
 376       (if x (substring fname 0 (match-beginning 0))
 377         (substring fname (match-beginning 0) nil))
 378     ;;
 379     ;; If fname has no extension, and x then return fname itself instead of
 380     ;; nothing. When caching it allows the correct .hdr file to be produced
 381     ;; for filenames without extension.
 382     ;;
 383     (if x
 384         fname
 385       "")))
 386
 387 ;;;###autoload
 388 (defun url-truncate-url-for-viewing (url &optional width)
 389   "Return a shortened version of URL that is WIDTH characters wide or less.
 390 WIDTH defaults to the current frame width."
 391   (let* ((fr-width (or width (frame-width)))
 392          (str-width (length url))
 393          (fname nil)
 394          (modified 0)
 395          (urlobj nil))
 396     ;; The first thing that can go are the search strings
 397     (if (and (>= str-width fr-width)
 398              (string-match "?" url))
 399         (setq url (concat (substring url 0 (match-beginning 0)) "?...")
 400               str-width (length url)))
 401     (if (< str-width fr-width)
 402         nil                             ; Hey, we are done!
 403       (setq urlobj (url-generic-parse-url url)
 404             fname (url-filename urlobj)
 405             fr-width (- fr-width 4))
 406       (while (and (>= str-width fr-width)
 407                   (string-match "/" fname))
 408         (setq fname (substring fname (match-end 0) nil)
 409               modified (1+ modified))
 410         (setf (url-filename urlobj) fname)
 411         (setq url (url-recreate-url urlobj)
 412               str-width (length url)))
 413       (if (> modified 1)
 414           (setq fname (concat "/.../" fname))
 415         (setq fname (concat "/" fname)))
 416       (setf (url-filename urlobj) fname)
 417       (setq url (url-recreate-url urlobj)))
 418     url))
 419
 420 ;;;###autoload
 421 (defun url-view-url (&optional no-show)
 422   "View the current document's URL.
 423 Optional argument NO-SHOW means just return the URL, don't show it in
 424 the minibuffer.
 425
 426 This uses `url-current-object', set locally to the buffer."
 427   (interactive)
 428   (if (not url-current-object)
 429       nil
 430     (if no-show
 431         (url-recreate-url url-current-object)
 432       (message "%s" (url-recreate-url url-current-object)))))
 433
 434 (eval-and-compile
 435   (defvar url-get-url-filename-chars "-%.?@a-zA-Z0-9()_/:~=&"
 436     "Valid characters in a URL.")
 437   )
 438
 439 (defun url-get-url-at-point (&optional pt)
 440   "Get the URL closest to point, but don't change position.
 441 Has a preference for looking backward when not directly on a symbol."
 442   ;; Not at all perfect - point must be right in the name.
 443   (save-excursion
 444     (if pt (goto-char pt))
 445     (let (start url)
 446       (save-excursion
 447         ;; first see if you're just past a filename
 448         (if (not (eobp))
 449             (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
 450                 (progn
 451                   (skip-chars-backward " \n\t\r({[]})")
 452                   (if (not (bobp))
 453                       (backward-char 1)))))
 454         (if (and (char-after (point))
 455                  (string-match (eval-when-compile
 456                                  (concat "[" url-get-url-filename-chars "]"))
 457                                (char-to-string (char-after (point)))))
 458             (progn
 459               (skip-chars-backward url-get-url-filename-chars)
 460               (setq start (point))
 461               (skip-chars-forward url-get-url-filename-chars))
 462           (setq start (point)))
 463         (setq url (buffer-substring-no-properties start (point))))
 464       (if (and url (string-match "^(.*)\\.?$" url))
 465           (setq url (match-string 1 url)))
 466       (if (and url (string-match "^URL:" url))
 467           (setq url (substring url 4 nil)))
 468       (if (and url (string-match "\\.$" url))
 469           (setq url (substring url 0 -1)))
 470       (if (and url (string-match "^www\\." url))
 471           (setq url (concat "http://" url)))
 472       (if (and url (not (string-match url-nonrelative-link url)))
 473           (setq url nil))
 474       url)))
 475
 476 (defun url-generate-unique-filename (&optional fmt)
 477   "Generate a unique filename in `url-temporary-directory'."
 478   ;; This variable is obsolete, but so is this function.
 479   (let ((tempdir (with-no-warnings url-temporary-directory)))
 480     (if (not fmt)
 481         (let ((base (format "url-tmp.%d" (user-real-uid)))
 482               (fname "")
 483               (x 0))
 484           (setq fname (format "%s%d" base x))
 485           (while (file-exists-p
 486                   (expand-file-name fname tempdir))
 487             (setq x (1+ x)
 488                   fname (concat base (int-to-string x))))
 489           (expand-file-name fname tempdir))
 490       (let ((base (concat "url" (int-to-string (user-real-uid))))
 491             (fname "")
 492             (x 0))
 493         (setq fname (format fmt (concat base (int-to-string x))))
 494         (while (file-exists-p
 495                 (expand-file-name fname tempdir))
 496           (setq x (1+ x)
 497                 fname (format fmt (concat base (int-to-string x)))))
 498         (expand-file-name fname tempdir)))))
 499 (make-obsolete 'url-generate-unique-filename 'make-temp-file "23.1")
 500
 501 (defun url-extract-mime-headers ()
 502   "Set `url-current-mime-headers' in current buffer."
 503   (save-excursion
 504     (goto-char (point-min))
 505     (unless url-current-mime-headers
 506       (set (make-local-variable 'url-current-mime-headers)
 507            (mail-header-extract)))))
 508
 509 (defun url-make-private-file (file)
 510   "Make FILE only readable and writable by the current user.
 511 Creates FILE and its parent directories if they do not exist."
 512   (let ((dir (file-name-directory file)))
 513     (when dir
 514       ;; For historical reasons.
 515       (make-directory dir t)))
 516   ;; Based on doc-view-make-safe-dir.
 517   (condition-case nil
 518       (let ((umask (default-file-modes)))
 519         (unwind-protect
 520             (progn
 521               (set-default-file-modes #o0600)
 522               (with-temp-buffer
 523                 (write-region (point-min) (point-max)
 524                               file nil 'silent nil 'excl)))
 525           (set-default-file-modes umask)))
 526     (file-already-exists
 527      (if (file-symlink-p file)
 528          (error "Danger: `%s' is a symbolic link" file))
 529      (set-file-modes file #o0600))))
 530
 531 (provide 'url-util)
 532
 533 ;; arch-tag: 24352abc-5a5a-412e-90cd-313b26bed5c9
 534 ;;; url-util.el ends here