lisp/iswitchb.el

   1 ;;; iswitchb.el --- switch between buffers using substrings
   2
   3 ;; Copyright (C) 1996, 1997, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Stephen Eglen <stephen@gnu.org>
   7 ;; Maintainer: Stephen Eglen <stephen@gnu.org>
   8 ;; Keywords: completion convenience
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Installation:
  30 ;; To get the functions in this package bound to keys, use
  31 ;; M-x iswitchb-mode or customize the option `iswitchb-mode'.
  32 ;; Alternatively, add the following line to your .emacs:
  33 ;; (iswitchb-mode 1)
  34
  35 ;; As you type in a substring, the list of buffers currently matching
  36 ;; the substring is displayed as you type.  The list is ordered so
  37 ;; that the most recent buffers visited come at the start of the list.
  38 ;; The buffer at the start of the list will be the one visited when
  39 ;; you press return.  By typing more of the substring, the list is
  40 ;; narrowed down so that gradually the buffer you want will be at the
  41 ;; top of the list.  Alternatively, you can use C-s and C-r to rotate
  42 ;; buffer names in the list until the one you want is at the top of
  43 ;; the list.  Completion is also available so that you can see what is
  44 ;; common to all of the matching buffers as you type.
  45
  46 ;; This code is similar to a couple of other packages.  Michael R Cook
  47 ;; <cook@sightpath.com> wrote a similar buffer switching package, but
  48 ;; does exact matching rather than substring matching on buffer names.
  49 ;; I also modified a couple of functions from icomplete.el to provide
  50 ;; the completion feedback in the minibuffer.
  51
  52 ;;; Example
  53
  54 ;; If I have two buffers called "123456" and "123", with "123456" the
  55 ;; most recent, when I use iswitchb, I first of all get presented with
  56 ;; the list of all the buffers
  57 ;;
  58 ;;       iswitch  {123456,123}
  59 ;;
  60 ;; If I then press 2:
  61 ;;       iswitch 2[3]{123456,123}
  62 ;;
  63 ;; The list in {} are the matching buffers, most recent first (buffers
  64 ;; visible in the current frame are put at the end of the list by
  65 ;; default).  At any time I can select the item at the head of the
  66 ;; list by pressing RET.  I can also put the first element at the end
  67 ;; of the list by pressing C-s, or put the last element at the head of
  68 ;; the list by pressing C-r.  The item in [] indicates what can be
  69 ;; added to my input by pressing TAB.  In this case, I will get "3"
  70 ;; added to my input.  So, press TAB:
  71 ;;       iswitch 23{123456,123}
  72 ;;
  73 ;; At this point, I still have two matching buffers.
  74 ;; If I want the first buffer in the list, I simply press RET.  If I
  75 ;; wanted the second in the list, I could press C-s to move it to the
  76 ;; top of the list and then RET to select it.
  77 ;;
  78 ;; However, if I type 4, I only have one match left:
  79 ;;       iswitch 234[123456] [Matched]
  80 ;;
  81 ;; Since there is only one matching buffer left, it is given in [] and we
  82 ;; see the text [Matched] afterwards.  I can now press TAB or RET to go
  83 ;; to that buffer.
  84 ;;
  85 ;; If however, I now type "a":
  86 ;;       iswitch 234a [No match]
  87 ;; There are no matching buffers.  If I press RET or TAB, I can be
  88 ;; prompted to create a new buffer called "234a".
  89 ;;
  90 ;; Of course, where this function comes in really useful is when you
  91 ;; can specify the buffer using only a few keystrokes.  In the above
  92 ;; example, the quickest way to get to the "123456" buffer would be
  93 ;; just to type 4 and then RET (assuming there isn't any newer buffer
  94 ;; with 4 in its name).
  95
  96 ;; To see a full list of all matching buffers in a separate buffer,
  97 ;; hit ? or press TAB when there are no further completions to the
  98 ;; substring.  Repeated TAB presses will scroll you through this
  99 ;; separate buffer.
 100
 101 ;; The buffer at the head of the list can be killed by pressing C-k.
 102 ;; If the buffer needs saving, you will be queried before the buffer
 103 ;; is killed.
 104
 105 ;; If you find that the file you are after is not in a buffer, you can
 106 ;; press C-x C-f to immediately drop into find-file.
 107
 108 ;; See the doc string of iswitchb for full keybindings and features.
 109 ;; (describe-function 'iswitchb)
 110
 111 ;; Case matching: The case of strings when matching can be ignored or
 112 ;; used depending on the value of iswitchb-case (default is the same
 113 ;; as case-fold-search, normally t).  Imagine you have the following
 114 ;; buffers:
 115 ;;
 116 ;; INBOX *info* *scratch*
 117 ;;
 118 ;; Then these will be the matching buffers, depending on how you type
 119 ;; the two letters `in' and the value of iswitchb-case:
 120 ;;
 121 ;; iswitchb-case   user input  | matching buffers
 122 ;; ----------------------------------------------
 123 ;; nil             in          | *info*
 124 ;; t               in          | INBOX, *info*
 125 ;; t               IN          | INBOX
 126 ;; t               In          | [No match]
 127
 128 ;;; Customisation
 129
 130 ;; See the User Variables section below for easy ways to change the
 131 ;; functionality of the program.  These are accessible using the
 132 ;; custom package.
 133 ;; To modify the keybindings, use something like:
 134 ;;
 135 ;;(add-hook 'iswitchb-mode-hook 'iswitchb-my-keys)
 136 ;;(defun iswitchb-my-keys ()
 137 ;;  "Add my keybindings for iswitchb."
 138 ;;  (define-key iswitchb-mode-map " " 'iswitchb-next-match))
 139 ;;
 140 ;; Seeing all the matching buffers
 141 ;;
 142 ;; If you have many matching buffers, they may not all fit onto one
 143 ;; line of the minibuffer.  In Emacs 21, the variable
 144 ;; `resize-mini-windows' controls how many lines of the minibuffer can
 145 ;; be seen.  For older versions of emacs, you can use
 146 ;; `resize-minibuffer-mode'.  You can also limit iswitchb so that it
 147 ;; only shows a certain number of lines -- see the documentation for
 148 ;; `iswitchb-minibuffer-setup-hook'.
 149
 150 ;; Changing the list of buffers
 151
 152 ;; By default, the list of current buffers is most recent first,
 153 ;; oldest last, with the exception that the buffers visible in the
 154 ;; current frame are put at the end of the list.  A hook exists to
 155 ;; allow other functions to order the list.  For example, if you add:
 156 ;;
 157 ;; (add-hook 'iswitchb-make-buflist-hook 'iswitchb-summaries-to-end)
 158 ;;
 159 ;; then all buffers matching "Summary" are moved to the end of the
 160 ;; list.  (I find this handy for keeping the INBOX Summary and so on
 161 ;; out of the way.)  It also moves buffers matching "output\*$" to the
 162 ;; end of the list (these are created by AUCTeX when compiling.)
 163 ;; Other functions could be made available which alter the list of
 164 ;; matching buffers (either deleting or rearranging elements.)
 165
 166 ;; Font-Lock
 167
 168 ;; font-lock is used to highlight the first matching buffer.  To
 169 ;; switch this off, set (setq iswitchb-use-faces nil).  Colouring of
 170 ;; the matching buffer name was suggested by Carsten Dominik
 171 ;; (dominik@strw.leidenuniv.nl)
 172
 173 ;; Replacement for read-buffer
 174
 175 ;; iswitchb-read-buffer has been written to be a drop in replacement
 176 ;; for the normal buffer selection routine `read-buffer'.  To use
 177 ;; iswitch for all buffer selections in Emacs, add:
 178 ;; (setq read-buffer-function 'iswitchb-read-buffer)
 179 ;; (This variable was introduced in Emacs 20.3.)
 180 ;; XEmacs users can get the same behaviour by doing:
 181 ;; (defalias 'read-buffer 'iswitchb-read-buffer)
 182 ;; since `read-buffer' is defined in lisp.
 183
 184 ;; Using iswitchb for other completion tasks.
 185
 186 ;; Kin Cho (kin@neoscale.com) sent the following suggestion to use
 187 ;; iswitchb for other completion tasks.
 188 ;;
 189 ;; (defun my-icompleting-read (prompt choices)
 190 ;;   "Use iswitch as a completing-read replacement to choose from
 191 ;; choices.  PROMPT is a string to prompt with.  CHOICES is a list of
 192 ;; strings to choose from."
 193 ;;   (let ((iswitchb-make-buflist-hook
 194 ;;          (lambda ()
 195 ;;            (setq iswitchb-temp-buflist choices))))
 196 ;;     (iswitchb-read-buffer prompt)))
 197 ;;
 198 ;; example:
 199 ;; (my-icompleting-read "Which fruit? " '
 200 ;;                   ("apple" "pineapple" "pear" "bananas" "oranges") )
 201
 202 ;; Kin Cho also suggested the following defun.  Once you have a subset of
 203 ;; matching buffers matching your current prompt, you can then press
 204 ;; e.g. C-o to restrict matching to those buffers and clearing the prompt:
 205 ;; (defun iswitchb-exclude-nonmatching()
 206 ;;    "Make iswitchb work on only the currently matching names."
 207 ;;    (interactive)
 208 ;;    (setq iswitchb-buflist iswitchb-matches)
 209 ;;    (setq iswitchb-rescan t)
 210 ;;    (delete-minibuffer-contents))
 211 ;;
 212 ;; (add-hook 'iswitchb-define-mode-map-hook
 213 ;;        '(lambda () (define-key
 214 ;;                      iswitchb-mode-map "\C-o"
 215 ;;                      'iswitchb-exclude-nonmatching)))
 216
 217 ;; Other lisp packages extend iswitchb behaviour to other tasks.  See
 218 ;; ido.el (by Kim Storm) and mcomplete.el (Yuji Minejima).
 219
 220 ;; Window managers: Switching frames/focus follows mouse; Sawfish.
 221
 222 ;; If you switch to a buffer that is visible in another frame,
 223 ;; iswitchb can switch focus to that frame.  If your window manager
 224 ;; uses "click to focus" policy for window selection, you should also
 225 ;; set focus-follows-mouse to nil.
 226
 227 ;; iswitch functionality has also been implemented for switching
 228 ;; between windows in the Sawfish window manager.
 229
 230 ;; Regexp matching
 231
 232 ;; There is provision for regexp matching within iswitchb, enabled
 233 ;; through `iswitchb-regexp'.  This allows you to type `c$' for
 234 ;; example and see all buffer names ending in `c'.  No completion
 235 ;; mechanism is currently offered when regexp searching.
 236
 237 ;;; TODO
 238
 239 ;;; Acknowledgements
 240
 241 ;; Thanks to Jari Aalto <jari.aalto@poboxes.com> for help with the
 242 ;; first version of this package, iswitch-buffer.  Thanks also to many
 243 ;; others for testing earlier versions.
 244
 245 ;;; Code:
 246
 247 ;; CL needed for cadr and last
 248 (if (not (and (fboundp 'cadr)
 249               (fboundp 'last)))
 250     (require 'cl))
 251
 252 (require 'font-lock)
 253
 254 ;;; User Variables
 255 ;;
 256 ;; These are some things you might want to change.
 257
 258 (defgroup iswitchb nil
 259   "Switch between buffers using substrings."
 260   :group 'convenience
 261   :group 'completion
 262   :link '(emacs-commentary-link :tag "Commentary" "iswitchb.el")
 263   :link '(url-link "http://www.anc.ed.ac.uk/~stephen/emacs/")
 264   :link '(emacs-library-link :tag "Lisp File" "iswitchb.el"))
 265
 266 (defcustom iswitchb-case case-fold-search
 267   "*Non-nil if searching of buffer names should ignore case.
 268 If this is non-nil but the user input has any upper case letters, matching
 269 is temporarily case sensitive."
 270   :type 'boolean
 271   :group 'iswitchb)
 272
 273 (defcustom iswitchb-buffer-ignore
 274   '("^ ")
 275   "*List of regexps or functions matching buffer names to ignore.
 276 For example, traditional behavior is not to list buffers whose names begin
 277 with a space, for which the regexp is `^ '.  See the source file for
 278 example functions that filter buffernames."
 279   :type '(repeat (choice regexp function))
 280   :group 'iswitchb)
 281 (put 'iswitchb-buffer-ignore 'risky-local-variable t)
 282
 283 (defcustom iswitchb-max-to-show nil
 284   "*If non-nil, limit the number of names shown in the minibuffer.
 285 If this value is N, and N is greater than the number of matching
 286 buffers, the first N/2 and the last N/2 matching buffers are
 287 shown.  This can greatly speed up iswitchb if you have a
 288 multitude of buffers open."
 289   :type '(choice (const :tag "Show all" nil) integer)
 290   :group 'iswitchb)
 291
 292 (defcustom iswitchb-use-virtual-buffers nil
 293   "*If non-nil, refer to past buffers when none match.
 294 This feature relies upon the `recentf' package, which will be
 295 enabled if this variable is configured to a non-nil value."
 296   :type 'boolean
 297   :require 'recentf
 298   :set (function
 299         (lambda (sym value)
 300           (if value (recentf-mode 1))
 301           (set sym value)))
 302   :group 'iswitchb)
 303
 304 (defvar iswitchb-virtual-buffers nil)
 305
 306 (defcustom iswitchb-cannot-complete-hook 'iswitchb-completion-help
 307   "*Hook run when `iswitchb-complete' can't complete any more.
 308 The most useful values are `iswitchb-completion-help', which pops up a
 309 window with completion alternatives, or `iswitchb-next-match' or
 310 `iswitchb-prev-match', which cycle the buffer list."
 311   :type 'hook
 312   :group 'iswitchb)
 313
 314 ;; Examples for setting the value of iswitchb-buffer-ignore
 315 ;;(defun iswitchb-ignore-c-mode (name)
 316 ;;  "Ignore all c mode buffers -- example function for iswitchb."
 317 ;;  (with-current-buffer name
 318 ;;    (derived-mode-p 'c-mode)))
 319
 320 ;;(setq iswitchb-buffer-ignore '("^ " iswitchb-ignore-c-mode))
 321 ;;(setq iswitchb-buffer-ignore '("^ " "\\.c\\'" "\\.h\\'"))
 322
 323 (defcustom iswitchb-default-method  'always-frame
 324     "*How to switch to new buffer when using `iswitchb-buffer'.
 325 Possible values:
 326 `samewindow'    Show new buffer in same window
 327 `otherwindow'   Show new buffer in another window (same frame)
 328 `display'       Display buffer in another window without switching to it
 329 `otherframe'    Show new buffer in another frame
 330 `maybe-frame'   If a buffer is visible in another frame, prompt to ask if you
 331                 you want to see the buffer in the same window of the current
 332                 frame or in the other frame.
 333 `always-frame'  If a buffer is visible in another frame, raise that
 334                 frame.  Otherwise, visit the buffer in the same window."
 335     :type '(choice (const samewindow)
 336                    (const otherwindow)
 337                    (const display)
 338                    (const otherframe)
 339                    (const maybe-frame)
 340                    (const always-frame))
 341     :group 'iswitchb)
 342
 343 (defcustom iswitchb-regexp nil
 344   "*Non-nil means that `iswitchb' will do regexp matching.
 345 Value can be toggled within `iswitchb' using `iswitchb-toggle-regexp'."
 346   :type 'boolean
 347   :group 'iswitchb)
 348
 349 (defcustom iswitchb-newbuffer t
 350   "*Non-nil means create new buffer if no buffer matches substring.
 351 See also `iswitchb-prompt-newbuffer'."
 352   :type 'boolean
 353   :group 'iswitchb)
 354
 355 (defcustom iswitchb-prompt-newbuffer t
 356   "*Non-nil means prompt user to confirm before creating new buffer.
 357 See also `iswitchb-newbuffer'."
 358   :type 'boolean
 359   :group 'iswitchb)
 360
 361 (defcustom iswitchb-use-faces t
 362   "*Non-nil means use font-lock fonts for showing first match."
 363   :type 'boolean
 364   :group 'iswitchb)
 365 (define-obsolete-variable-alias 'iswitchb-use-fonts 'iswitchb-use-faces "22.1")
 366
 367 (defcustom iswitchb-use-frame-buffer-list nil
 368   "*Non-nil means use the currently selected frame's buffer list."
 369   :type 'boolean
 370   :group 'iswitchb)
 371
 372 (defcustom iswitchb-make-buflist-hook  nil
 373   "Hook to run when list of matching buffers is created."
 374   :type 'hook
 375   :group 'iswitchb)
 376
 377 (defvar iswitchb-all-frames 'visible
 378   "*Argument to pass to `walk-windows' when finding visible buffers.
 379 See documentation of `walk-windows' for useful values.")
 380
 381 (defcustom iswitchb-minibuffer-setup-hook nil
 382   "Iswitchb-specific customization of minibuffer setup.
 383
 384 This hook is run during minibuffer setup if `iswitchb' is active.
 385 For instance:
 386 \(add-hook 'iswitchb-minibuffer-setup-hook
 387           '\(lambda () (set (make-local-variable 'max-mini-window-height) 3)))
 388 will constrain the minibuffer to a maximum height of 3 lines when
 389 iswitchb is running."
 390   :type 'hook
 391   :group 'iswitchb)
 392
 393 (defface iswitchb-single-match
 394   '((t
 395      (:inherit font-lock-comment-face)))
 396   "Iswitchb face for single matching buffer name."
 397   :version "22.1"
 398   :group 'iswitchb)
 399
 400 (defface iswitchb-current-match
 401   '((t
 402      (:inherit font-lock-function-name-face)))
 403   "Iswitchb face for current matching buffer name."
 404   :version "22.1"
 405   :group 'iswitchb)
 406
 407 (defface iswitchb-virtual-matches
 408   '((t
 409      (:inherit font-lock-builtin-face)))
 410   "Iswitchb face for matching virtual buffer names.
 411 See also `iswitchb-use-virtual-buffers'."
 412   :version "22.1"
 413   :group 'iswitchb)
 414
 415 (defface iswitchb-invalid-regexp
 416   '((t
 417      (:inherit font-lock-warning-face)))
 418   "Iswitchb face for indicating invalid regexp. "
 419   :version "22.1"
 420   :group 'iswitchb)
 421
 422 ;; Do we need the variable iswitchb-use-mycompletion?
 423
 424 ;;; Internal Variables
 425
 426 (defvar iswitchb-method nil
 427   "Stores the method for viewing the selected buffer.
 428 Its value is one of `samewindow', `otherwindow', `display', `otherframe',
 429 `maybe-frame' or `always-frame'.  See `iswitchb-default-method' for
 430 details of values.")
 431
 432 (defvar iswitchb-eoinput 1
 433   "Point where minibuffer input ends and completion info begins.
 434 Copied from `icomplete-eoinput'.")
 435 (make-variable-buffer-local 'iswitchb-eoinput)
 436
 437 (defvar iswitchb-buflist nil
 438   "Stores the current list of buffers that will be searched through.
 439 The list is ordered, so that the most recent buffers come first,
 440 although by default, the buffers visible in the current frame are put
 441 at the end of the list.  Created by `iswitchb-make-buflist'.")
 442
 443 ;; todo -- is this necessary?
 444
 445 (defvar iswitchb-use-mycompletion nil
 446   "Non-nil means use `iswitchb-buffer' completion feedback.
 447 Should only be set to t by iswitchb functions, so that it doesn't
 448 interfere with other minibuffer usage.")
 449
 450 (defvar iswitchb-change-word-sub nil
 451   "Private variable used by `iswitchb-word-matching-substring'.")
 452
 453 (defvar iswitchb-common-match-string  nil
 454   "Stores the string that is common to all matching buffers.")
 455
 456 (defvar iswitchb-rescan nil
 457   "Non-nil means we need to regenerate the list of matching buffers.")
 458
 459 (defvar iswitchb-text nil
 460   "Stores the users string as it is typed in.")
 461
 462 (defvar iswitchb-matches nil
 463   "List of buffers currently matching `iswitchb-text'.")
 464
 465 (defvar iswitchb-mode-map
 466   (let ((map (make-sparse-keymap)))
 467     (set-keymap-parent map minibuffer-local-map)
 468     (define-key map "?" 'iswitchb-completion-help)
 469     (define-key map "\C-s" 'iswitchb-next-match)
 470     (define-key map "\C-r" 'iswitchb-prev-match)
 471     (define-key map "\t" 'iswitchb-complete)
 472     (define-key map "\C-j" 'iswitchb-select-buffer-text)
 473     (define-key map "\C-t" 'iswitchb-toggle-regexp)
 474     (define-key map "\C-x\C-f" 'iswitchb-find-file)
 475     (define-key map "\C-c" 'iswitchb-toggle-case)
 476     (define-key map "\C-k" 'iswitchb-kill-buffer)
 477     (define-key map "\C-m" 'iswitchb-exit-minibuffer)
 478     map)
 479   "Minibuffer keymap for `iswitchb-buffer'.")
 480
 481 (defvar iswitchb-global-map
 482   (let ((map (make-sparse-keymap)))
 483     (dolist (b '((switch-to-buffer . iswitchb-buffer)
 484                  (switch-to-buffer-other-window . iswitchb-buffer-other-window)
 485                  (switch-to-buffer-other-frame . iswitchb-buffer-other-frame)
 486                  (display-buffer . iswitchb-display-buffer)))
 487       (if (fboundp 'command-remapping)
 488           (define-key map (vector 'remap (car b)) (cdr b))
 489         (substitute-key-definition (car b) (cdr b) map global-map)))
 490     map)
 491   "Global keymap for `iswitchb-mode'.")
 492
 493 (defvar iswitchb-history nil
 494   "History of buffers selected using `iswitchb-buffer'.")
 495
 496 (defvar iswitchb-exit nil
 497   "Flag to monitor how `iswitchb-buffer' exits.
 498 If equal to `takeprompt', we use the prompt as the buffer name to be
 499 selected.")
 500
 501 (defvar iswitchb-buffer-ignore-orig nil
 502   "Stores original value of `iswitchb-buffer-ignore'.")
 503
 504 (defvar iswitchb-default nil
 505   "Default buffer for iswitchb.")
 506
 507 ;; The following variables are needed to keep the byte compiler quiet.
 508 (defvar iswitchb-require-match nil
 509   "Non-nil if matching buffer must be selected.")
 510
 511 (defvar iswitchb-temp-buflist nil
 512   "Stores a temporary version of the buffer list being created.")
 513
 514 (defvar iswitchb-bufs-in-frame nil
 515   "List of the buffers visible in the current frame.")
 516
 517 (defvar iswitchb-minibuf-depth nil
 518   "Value we expect to be returned by `minibuffer-depth' in the minibuffer.")
 519
 520 (defvar iswitchb-common-match-inserted nil
 521   "Non-nil if we have just inserted a common match in the minibuffer.")
 522
 523 (defvar iswitchb-invalid-regexp)
 524
 525 ;;; FUNCTIONS
 526
 527 ;;; ISWITCHB KEYMAP
 528 (defun iswitchb-define-mode-map ()
 529   "Set up the keymap for `iswitchb-buffer'.
 530 This is obsolete.  Use \\[iswitchb-mode] or customize the
 531 variable `iswitchb-mode'."
 532   (interactive)
 533   (let (map)
 534     ;; generated every time so that it can inherit new functions.
 535     ;;(or iswitchb-mode-map
 536
 537     (setq map (copy-keymap minibuffer-local-map))
 538     (define-key map "?" 'iswitchb-completion-help)
 539     (define-key map "\C-s" 'iswitchb-next-match)
 540     (define-key map "\C-r" 'iswitchb-prev-match)
 541     (define-key map "\t" 'iswitchb-complete)
 542     (define-key map "\C-j" 'iswitchb-select-buffer-text)
 543     (define-key map "\C-t" 'iswitchb-toggle-regexp)
 544     (define-key map "\C-x\C-f" 'iswitchb-find-file)
 545     (define-key map "\C-n" 'iswitchb-toggle-ignore)
 546     (define-key map "\C-c" 'iswitchb-toggle-case)
 547     (define-key map "\C-k" 'iswitchb-kill-buffer)
 548     (define-key map "\C-m" 'iswitchb-exit-minibuffer)
 549     (setq iswitchb-mode-map map)
 550     (run-hooks 'iswitchb-define-mode-map-hook)))
 551
 552 ;;; MAIN FUNCTION
 553 (defun iswitchb ()
 554   "Switch to buffer matching a substring.
 555 As you type in a string, all of the buffers matching the string are
 556 displayed.  When you have found the buffer you want, it can then be
 557 selected.  As you type, most keys have their normal keybindings,
 558 except for the following:
 559 \\<iswitchb-mode-map>
 560
 561 RET Select the buffer at the front of the list of matches.  If the
 562 list is empty, possibly prompt to create new buffer.
 563
 564 \\[iswitchb-select-buffer-text] Select the current prompt as the buffer.
 565 If no buffer is found, prompt for a new one.
 566
 567 \\[iswitchb-next-match] Put the first element at the end of the list.
 568 \\[iswitchb-prev-match] Put the last element at the start of the list.
 569 \\[iswitchb-complete] Complete a common suffix to the current string that
 570 matches all buffers.  If there is only one match, select that buffer.
 571 If there is no common suffix, show a list of all matching buffers
 572 in a separate window.
 573 \\[iswitchb-toggle-regexp] Toggle regexp searching.
 574 \\[iswitchb-toggle-case] Toggle case-sensitive searching of buffer names.
 575 \\[iswitchb-completion-help] Show list of matching buffers in separate window.
 576 \\[iswitchb-find-file] Exit iswitchb and drop into `find-file'.
 577 \\[iswitchb-kill-buffer] Kill buffer at head of buffer list."
 578   ;;\\[iswitchb-toggle-ignore] Toggle ignoring certain buffers (see \
 579   ;;`iswitchb-buffer-ignore')
 580
 581   (let* ((prompt "iswitch ")
 582          iswitchb-invalid-regexp
 583          (buf (iswitchb-read-buffer prompt)))
 584
 585     ;;(message "chosen text %s" iswitchb-final-text)
 586     ;; Choose the buffer name: either the text typed in, or the head
 587     ;; of the list of matches
 588
 589     (cond ( (eq iswitchb-exit 'findfile)
 590             (call-interactively 'find-file))
 591           (iswitchb-invalid-regexp
 592            (message "Won't make invalid regexp named buffer"))
 593           (t
 594            ;; View the buffer
 595            ;;(message "go to buf %s" buf)
 596            ;; Check buf is non-nil.
 597            (if buf
 598                (if (get-buffer buf)
 599                    ;; buffer exists, so view it and then exit
 600                    (iswitchb-visit-buffer buf)
 601                  ;; else buffer doesn't exist
 602                  (iswitchb-possible-new-buffer buf)))
 603            ))))
 604
 605 (defun iswitchb-read-buffer (prompt &optional default require-match
 606                                     start matches-set)
 607   "Replacement for the built-in `read-buffer'.
 608 Return the name of a buffer selected.
 609 PROMPT is the prompt to give to the user.
 610 DEFAULT if given is the default buffer to be selected, which will
 611 go to the front of the list.
 612 If REQUIRE-MATCH is non-nil, an existing-buffer must be selected.
 613 If START is a string, the selection process is started with that
 614 string.
 615 If MATCHES-SET is non-nil, the buflist is not updated before
 616 the selection process begins.  Used by isearchb.el."
 617   (let
 618       (
 619        buf-sel
 620        iswitchb-final-text
 621        (icomplete-mode nil) ;; prevent icomplete starting up
 622        )
 623
 624     (iswitchb-define-mode-map)
 625     (setq iswitchb-exit nil)
 626     (setq iswitchb-default
 627           (if (bufferp default)
 628               (buffer-name default)
 629             default))
 630     (setq iswitchb-text (or start ""))
 631     (unless matches-set
 632       (setq iswitchb-rescan t)
 633       (iswitchb-make-buflist iswitchb-default)
 634       (iswitchb-set-matches))
 635     (let
 636         ((minibuffer-local-completion-map iswitchb-mode-map)
 637          ;; Record the minibuffer depth that we expect to find once
 638          ;; the minibuffer is set up and iswitchb-entryfn-p is called.
 639          (iswitchb-minibuf-depth (1+ (minibuffer-depth)))
 640          (iswitchb-require-match require-match))
 641       ;; prompt the user for the buffer name
 642       (setq iswitchb-final-text (completing-read
 643                                  prompt           ;the prompt
 644                                  '(("dummy" . 1)) ;table
 645                                  nil              ;predicate
 646                                  nil ;require-match [handled elsewhere]
 647                                  start  ;initial-contents
 648                                  'iswitchb-history)))
 649     (if (and (not (eq iswitchb-exit 'usefirst))
 650              (get-buffer iswitchb-final-text))
 651         ;; This happens for example if the buffer was chosen with the mouse.
 652         (setq iswitchb-matches (list iswitchb-final-text)
 653               iswitchb-virtual-buffers nil))
 654
 655     ;; If no buffer matched, but a virtual buffer was selected, visit
 656     ;; that file now and act as though that buffer had been selected.
 657     (if (and iswitchb-virtual-buffers
 658              (not (iswitchb-existing-buffer-p)))
 659         (let ((virt (car iswitchb-virtual-buffers)))
 660           (find-file-noselect (cdr virt))
 661           (setq iswitchb-matches (list (car virt))
 662                 iswitchb-virtual-buffers nil)))
 663
 664     ;; Handling the require-match must be done in a better way.
 665     (if (and require-match
 666              (not (iswitchb-existing-buffer-p)))
 667         (error "Must specify valid buffer"))
 668
 669     (if (or (eq iswitchb-exit 'takeprompt)
 670             (null iswitchb-matches))
 671         (setq buf-sel iswitchb-final-text)
 672       ;; else take head of list
 673       (setq buf-sel (car iswitchb-matches)))
 674
 675     ;; Or possibly choose the default buffer
 676     (if  (equal iswitchb-final-text "")
 677         (setq buf-sel (car iswitchb-matches)))
 678
 679     buf-sel))
 680
 681 (defun iswitchb-existing-buffer-p ()
 682   "Return non-nil if there is a matching buffer."
 683   (not (null iswitchb-matches)))
 684
 685 ;;; COMPLETION CODE
 686
 687 (defun iswitchb-set-common-completion  ()
 688   "Find common completion of `iswitchb-text' in `iswitchb-matches'.
 689 The result is stored in `iswitchb-common-match-string'."
 690
 691   (let* (val)
 692     (setq  iswitchb-common-match-string nil)
 693     (if (and iswitchb-matches
 694              (not iswitchb-regexp) ;; testing
 695              (stringp iswitchb-text)
 696              (> (length iswitchb-text) 0))
 697         (if (setq val (iswitchb-find-common-substring
 698                        iswitchb-matches iswitchb-text))
 699             (setq iswitchb-common-match-string val)))
 700     val))
 701
 702 (defun iswitchb-complete ()
 703   "Try and complete the current pattern amongst the buffer names."
 704   (interactive)
 705   (let (res)
 706     (cond ((not  iswitchb-matches)
 707            (run-hooks 'iswitchb-cannot-complete-hook))
 708           (iswitchb-invalid-regexp
 709            ;; Do nothing
 710            )
 711           ((= 1 (length iswitchb-matches))
 712            ;; only one choice, so select it.
 713            (exit-minibuffer))
 714
 715           (t
 716            ;; else there could be some completions
 717            (setq res iswitchb-common-match-string)
 718            (if (and (not (memq res '(t nil)))
 719                     (not (equal res iswitchb-text)))
 720                ;; found something to complete, so put it in the minibuffer.
 721                (progn
 722                  (setq iswitchb-rescan nil
 723                        iswitchb-common-match-inserted t)
 724                  (delete-region (minibuffer-prompt-end) (point))
 725                  (insert  res))
 726              ;; else nothing to complete
 727              (run-hooks 'iswitchb-cannot-complete-hook)
 728              )))))
 729
 730 ;;; TOGGLE FUNCTIONS
 731
 732 (defun iswitchb-toggle-case ()
 733   "Toggle the value of variable `iswitchb-case'."
 734   (interactive)
 735   (setq iswitchb-case (not iswitchb-case))
 736   ;; ask for list to be regenerated.
 737   (setq iswitchb-rescan t))
 738
 739 (defun iswitchb-toggle-regexp ()
 740   "Toggle the value of `iswitchb-regexp'."
 741   (interactive)
 742   (setq iswitchb-regexp (not iswitchb-regexp))
 743   ;; ask for list to be regenerated.
 744   (setq iswitchb-rescan t))
 745
 746 (defun iswitchb-toggle-ignore ()
 747   "Toggle ignoring buffers specified with `iswitchb-buffer-ignore'."
 748   (interactive)
 749   (if iswitchb-buffer-ignore
 750       (progn
 751         (setq iswitchb-buffer-ignore-orig iswitchb-buffer-ignore)
 752         (setq iswitchb-buffer-ignore nil))
 753     ;; else
 754     (setq iswitchb-buffer-ignore iswitchb-buffer-ignore-orig))
 755   (iswitchb-make-buflist iswitchb-default)
 756   ;; ask for list to be regenerated.
 757   (setq iswitchb-rescan t))
 758
 759 (defun iswitchb-exit-minibuffer ()
 760   "Exit minibuffer, but make sure we have a match if one is needed."
 761   (interactive)
 762   (if (or (not iswitchb-require-match)
 763            (iswitchb-existing-buffer-p))
 764       (progn
 765         (setq iswitchb-exit 'usefirst)
 766         (throw 'exit nil))))
 767
 768 (defun iswitchb-select-buffer-text ()
 769   "Select the buffer named by the prompt.
 770 If no buffer exactly matching the prompt exists, maybe create a new one."
 771   (interactive)
 772   (setq iswitchb-exit 'takeprompt)
 773   (exit-minibuffer))
 774
 775 (defun iswitchb-find-file ()
 776   "Drop into `find-file' from buffer switching."
 777   (interactive)
 778   (setq iswitchb-exit 'findfile)
 779   (exit-minibuffer))
 780
 781 (eval-when-compile
 782   (defvar recentf-list))
 783
 784 (defun iswitchb-next-match ()
 785   "Put first element of `iswitchb-matches' at the end of the list."
 786   (interactive)
 787   (let ((next  (cadr iswitchb-matches)))
 788     (if (and (null next) iswitchb-virtual-buffers)
 789         (setq recentf-list
 790               (iswitchb-chop recentf-list
 791                              (cdr (cadr iswitchb-virtual-buffers))))
 792       (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist next)))
 793     (setq iswitchb-rescan t)))
 794
 795 (defun iswitchb-prev-match ()
 796   "Put last element of `iswitchb-matches' at the front of the list."
 797   (interactive)
 798   (let ((prev  (car (last iswitchb-matches))))
 799     (if (and (null prev) iswitchb-virtual-buffers)
 800         (setq recentf-list
 801               (iswitchb-chop recentf-list
 802                              (cdr (car (last iswitchb-virtual-buffers)))))
 803       (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist prev)))
 804     (setq iswitchb-rescan t)))
 805
 806 (defun iswitchb-chop (list elem)
 807   "Remove all elements before ELEM and put them at the end of LIST."
 808   (let ((ret nil)
 809         (next nil)
 810         (sofar nil))
 811     (while (not ret)
 812       (setq next (car list))
 813       (if (equal next elem)
 814           (setq ret (append list (nreverse sofar)))
 815         ;; else
 816         (progn
 817           (setq list (cdr list))
 818           (setq sofar (cons next sofar)))))
 819     ret))
 820
 821 ;;; CREATE LIST OF ALL CURRENT BUFFERS
 822
 823 (defun iswitchb-make-buflist (default)
 824   "Set `iswitchb-buflist' to the current list of buffers.
 825 Currently visible buffers are put at the end of the list.
 826 The hook `iswitchb-make-buflist-hook' is run after the list has been
 827 created to allow the user to further modify the order of the buffer names
 828 in this list.  If DEFAULT is non-nil, and corresponds to an existing buffer,
 829 it is put to the start of the list."
 830   (setq iswitchb-buflist
 831         (let* ((iswitchb-current-buffers (iswitchb-get-buffers-in-frames))
 832                (iswitchb-temp-buflist
 833                 (delq nil
 834                       (mapcar
 835                        (lambda (x)
 836                          (let ((b-name (buffer-name x)))
 837                            (if (not
 838                                 (or
 839                                  (iswitchb-ignore-buffername-p b-name)
 840                                  (memq b-name iswitchb-current-buffers)))
 841                                b-name)))
 842                        (buffer-list (and iswitchb-use-frame-buffer-list
 843                                          (selected-frame)))))))
 844           (setq iswitchb-temp-buflist
 845                 (nconc iswitchb-temp-buflist iswitchb-current-buffers))
 846           (run-hooks 'iswitchb-make-buflist-hook)
 847          ;; Should this be after the hooks, or should the hooks be the
 848           ;; final thing to be run?
 849           (if default
 850               (progn
 851                 (setq iswitchb-temp-buflist
 852                       (delete default iswitchb-temp-buflist))
 853                 (setq iswitchb-temp-buflist
 854                       (cons default iswitchb-temp-buflist))))
 855           iswitchb-temp-buflist)))
 856
 857 (defun iswitchb-to-end (lst)
 858   "Move the elements from LST to the end of `iswitchb-temp-buflist'."
 859   (dolist (elem lst)
 860     (setq iswitchb-temp-buflist (delq elem iswitchb-temp-buflist)))
 861   (setq iswitchb-temp-buflist (nconc iswitchb-temp-buflist lst)))
 862
 863 (defun iswitchb-get-buffers-in-frames (&optional current)
 864   "Return the list of buffers that are visible in the current frame.
 865 If optional argument CURRENT is given, restrict searching to the
 866 current frame, rather than all frames, regardless of value of
 867 `iswitchb-all-frames'."
 868   (let ((iswitchb-bufs-in-frame nil))
 869     (walk-windows 'iswitchb-get-bufname nil
 870                   (if current
 871                       nil
 872                     iswitchb-all-frames))
 873     iswitchb-bufs-in-frame))
 874
 875 (defun iswitchb-get-bufname (win)
 876   "Used by `iswitchb-get-buffers-in-frames' to walk through all windows."
 877   (let ((buf (buffer-name (window-buffer win))))
 878         (if (not (member buf iswitchb-bufs-in-frame))
 879             ;; Only add buf if it is not already in list.
 880             ;; This prevents same buf in two different windows being
 881             ;; put into the list twice.
 882             (setq iswitchb-bufs-in-frame
 883                   (cons buf iswitchb-bufs-in-frame)))))
 884
 885 ;;; FIND MATCHING BUFFERS
 886
 887 (defun iswitchb-set-matches ()
 888   "Set `iswitchb-matches' to the list of buffers matching prompt."
 889   (if iswitchb-rescan
 890       (setq iswitchb-matches
 891             (let* ((buflist iswitchb-buflist))
 892               (iswitchb-get-matched-buffers iswitchb-text iswitchb-regexp
 893                                             buflist))
 894             iswitchb-virtual-buffers nil)))
 895
 896 (defun iswitchb-get-matched-buffers (regexp
 897                                      &optional string-format buffer-list)
 898   "Return buffers matching REGEXP.
 899 If STRING-FORMAT is nil, consider REGEXP as just a string.
 900 BUFFER-LIST can be list of buffers or list of strings."
 901   (let* ((case-fold-search (iswitchb-case))
 902          name ret)
 903     (if (null string-format) (setq regexp (regexp-quote regexp)))
 904     (setq iswitchb-invalid-regexp nil)
 905     (condition-case error
 906         (dolist (x buffer-list (nreverse ret))
 907           (setq name (if (stringp x) x (buffer-name x)))
 908           (when (and (string-match regexp name)
 909                      (not (iswitchb-ignore-buffername-p name)))
 910             (push name ret)))
 911       (invalid-regexp
 912        (setq iswitchb-invalid-regexp t)
 913        (cdr error)))))
 914
 915 (defun iswitchb-ignore-buffername-p (bufname)
 916   "Return t if the buffer BUFNAME should be ignored."
 917   (let ((data       (match-data))
 918         (re-list    iswitchb-buffer-ignore)
 919         ignorep
 920         nextstr)
 921     (while re-list
 922       (setq nextstr (car re-list))
 923       (cond
 924        ((stringp nextstr)
 925         (if (string-match nextstr bufname)
 926             (progn
 927               (setq ignorep t)
 928               (setq re-list nil))))
 929        ((functionp nextstr)
 930         (if (funcall nextstr bufname)
 931             (progn
 932               (setq ignorep t)
 933               (setq re-list nil)))))
 934       (setq re-list (cdr re-list)))
 935     (set-match-data data)
 936
 937     ;; return the result
 938     ignorep))
 939
 940 (defun iswitchb-word-matching-substring (word)
 941   "Return part of WORD before 1st match to `iswitchb-change-word-sub'.
 942 If `iswitchb-change-word-sub' cannot be found in WORD, return nil."
 943   (let ((case-fold-search (iswitchb-case)))
 944     (let ((m (string-match iswitchb-change-word-sub word)))
 945       (if m
 946           (substring word m)
 947         ;; else no match
 948         nil))))
 949
 950 (defun iswitchb-find-common-substring (lis subs)
 951   "Return common string following SUBS in each element of LIS."
 952   (let (res
 953         alist
 954         iswitchb-change-word-sub)
 955     (setq iswitchb-change-word-sub
 956           (if iswitchb-regexp
 957               subs
 958             (regexp-quote subs)))
 959     (setq res (mapcar 'iswitchb-word-matching-substring lis))
 960     (setq res (delq nil res)) ;; remove any nil elements (shouldn't happen)
 961     (setq alist (mapcar 'iswitchb-makealist res)) ;; could use an  OBARRAY
 962
 963     ;; try-completion returns t if there is an exact match.
 964     (let ((completion-ignore-case (iswitchb-case)))
 965
 966     (try-completion subs alist))))
 967
 968 (defun iswitchb-makealist (res)
 969   "Return dotted pair (RES . 1)."
 970   (cons res 1))
 971
 972 ;; from Wayne Mesard <wmesard@esd.sgi.com>
 973 (defun iswitchb-rotate-list (lis)
 974   "Destructively remove the last element from LIS.
 975 Return the modified list with the last element prepended to it."
 976   (if (<= (length lis) 1)
 977       lis
 978     (let ((las lis)
 979           (prev lis))
 980       (while (consp (cdr las))
 981         (setq prev las
 982               las (cdr las)))
 983       (setcdr prev nil)
 984       (cons (car las) lis))))
 985
 986 (defun iswitchb-completion-help ()
 987   "Show possible completions in a *Completions* buffer."
 988   ;; we could allow this buffer to be used to select match, but I think
 989   ;; choose-completion-string will need redefining, so it just inserts
 990   ;; choice with out any previous input.
 991   (interactive)
 992   (setq iswitchb-rescan nil)
 993   (let ((buf (current-buffer))
 994         (temp-buf "*Completions*")
 995         (win))
 996
 997     (if (and (eq last-command this-command)
 998              (not iswitchb-common-match-inserted))
 999         ;; scroll buffer
1000         (progn
1001           (set-buffer temp-buf)
1002           (setq win (get-buffer-window temp-buf))
1003           (if (pos-visible-in-window-p (point-max) win)
1004               (set-window-start win (point-min))
1005             (scroll-other-window))
1006           (set-buffer buf))
1007
1008       (with-output-to-temp-buffer temp-buf
1009         (if (featurep 'xemacs)
1010
1011             ;; XEmacs extents are put on by default, doesn't seem to be
1012             ;; any way of switching them off.
1013             (display-completion-list (if iswitchb-matches
1014                                          iswitchb-matches
1015                                        iswitchb-buflist)
1016                                      :help-string "iswitchb "
1017                                      :activate-callback
1018                                      (lambda (x y z)
1019                                        (message "doesn't work yet, sorry!")))
1020           ;; else running Emacs
1021           (with-current-buffer standard-output
1022             (fundamental-mode))
1023           (display-completion-list (if iswitchb-matches
1024                                        iswitchb-matches
1025                                      iswitchb-buflist))))
1026       (setq iswitchb-common-match-inserted nil))))
1027
1028 ;;; KILL CURRENT BUFFER
1029
1030 (defun iswitchb-kill-buffer ()
1031   "Kill the buffer at the head of `iswitchb-matches'."
1032   (interactive)
1033   (let ( (enable-recursive-minibuffers t)
1034          buf)
1035
1036     (setq buf (car iswitchb-matches))
1037     ;; check to see if buf is non-nil.
1038     (if buf
1039         (progn
1040           (kill-buffer buf)
1041
1042           ;; Check if buffer exists.  XEmacs gnuserv.el makes alias
1043           ;; for kill-buffer which does not return t if buffer is
1044           ;; killed, so we can't rely on kill-buffer return value.
1045           (if (get-buffer buf)
1046               ;; buffer couldn't be killed.
1047               (setq iswitchb-rescan t)
1048             ;; else buffer was killed so remove name from list.
1049             (setq iswitchb-buflist  (delq buf iswitchb-buflist)))))))
1050
1051 ;;; VISIT CHOSEN BUFFER
1052 (defun iswitchb-visit-buffer (buffer)
1053   "Visit buffer named BUFFER according to `iswitchb-method'."
1054   (let* (win  newframe)
1055     (cond
1056      ((eq iswitchb-method 'samewindow)
1057       (switch-to-buffer buffer))
1058
1059      ((memq iswitchb-method '(always-frame maybe-frame))
1060       (cond
1061        ((and (setq win (iswitchb-window-buffer-p buffer))
1062              (or (eq iswitchb-method 'always-frame)
1063                  (y-or-n-p "Jump to frame? ")))
1064         (setq newframe (window-frame win))
1065         (if (fboundp 'select-frame-set-input-focus)
1066             (select-frame-set-input-focus newframe)
1067           (raise-frame newframe)
1068           (select-frame newframe)
1069           )
1070         (select-window win))
1071        (t
1072         ;;  No buffer in other frames...
1073         (switch-to-buffer buffer)
1074         )))
1075
1076      ((eq iswitchb-method 'otherwindow)
1077       (switch-to-buffer-other-window buffer))
1078
1079      ((eq iswitchb-method 'display)
1080       (display-buffer buffer))
1081
1082      ((eq iswitchb-method 'otherframe)
1083       (progn
1084         (switch-to-buffer-other-frame buffer)
1085         (if (fboundp 'select-frame-set-input-focus)
1086             (select-frame-set-input-focus (selected-frame)))
1087         )))))
1088
1089 (defun iswitchb-possible-new-buffer (buf)
1090   "Possibly create and visit a new buffer called BUF."
1091
1092   (let ((newbufcreated))
1093     (if (and iswitchb-newbuffer
1094              (or
1095               (not iswitchb-prompt-newbuffer)
1096
1097               (and iswitchb-prompt-newbuffer
1098                    (y-or-n-p
1099                     (format
1100                      "No buffer matching `%s', create one? "
1101                      buf)))))
1102         ;; then create a new buffer
1103         (progn
1104           (setq newbufcreated (get-buffer-create buf))
1105           (if (fboundp 'set-buffer-major-mode)
1106               (set-buffer-major-mode newbufcreated))
1107           (iswitchb-visit-buffer newbufcreated))
1108       ;; else wont create new buffer
1109       (message "no buffer matching `%s'" buf))))
1110
1111 (defun iswitchb-window-buffer-p  (buffer)
1112   "Return window pointer if BUFFER is visible in another frame.
1113 If BUFFER is visible in the current frame, return nil."
1114   (interactive)
1115   (let ((blist (iswitchb-get-buffers-in-frames 'current)))
1116     ;;If the buffer is visible in current frame, return nil
1117     (if (memq buffer blist)
1118         nil
1119       ;;  maybe in other frame or icon
1120       (get-buffer-window buffer 0) ; better than 'visible
1121       )))
1122
1123 (defun iswitchb-default-keybindings ()
1124   "Set up default keybindings for `iswitchb-buffer'.
1125 Call this function to override the normal bindings.  This function also
1126 adds a hook to the minibuffer.
1127
1128 Obsolescent.  Use `iswitchb-mode'."
1129   (interactive)
1130   (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)
1131   (global-set-key "\C-xb" 'iswitchb-buffer)
1132   (global-set-key "\C-x4b" 'iswitchb-buffer-other-window)
1133   (global-set-key "\C-x4\C-o" 'iswitchb-display-buffer)
1134   (global-set-key "\C-x5b" 'iswitchb-buffer-other-frame))
1135
1136 (defun iswitchb-buffer ()
1137   "Switch to another buffer.
1138
1139 The buffer name is selected interactively by typing a substring.  The
1140 buffer is displayed according to `iswitchb-default-method' -- the
1141 default is to show it in the same window, unless it is already visible
1142 in another frame.
1143 For details of keybindings, do `\\[describe-function] iswitchb'."
1144   (interactive)
1145   (setq iswitchb-method iswitchb-default-method)
1146   (iswitchb))
1147
1148 (defun iswitchb-buffer-other-window ()
1149   "Switch to another buffer and show it in another window.
1150 The buffer name is selected interactively by typing a substring.
1151 For details of keybindings, do `\\[describe-function] iswitchb'."
1152   (interactive)
1153   (setq iswitchb-method 'otherwindow)
1154   (iswitchb))
1155
1156 (defun iswitchb-display-buffer ()
1157   "Display a buffer in another window but don't select it.
1158 The buffer name is selected interactively by typing a substring.
1159 For details of keybindings, do `\\[describe-function] iswitchb'."
1160   (interactive)
1161   (setq iswitchb-method 'display)
1162   (iswitchb))
1163
1164 (defun iswitchb-buffer-other-frame ()
1165   "Switch to another buffer and show it in another frame.
1166 The buffer name is selected interactively by typing a substring.
1167 For details of keybindings, do `\\[describe-function] iswitchb'."
1168   (interactive)
1169   (setq iswitchb-method 'otherframe)
1170   (iswitchb))
1171
1172 ;;; XEmacs hack for showing default buffer
1173
1174 ;; The first time we enter the minibuffer, Emacs puts up the default
1175 ;; buffer to switch to, but XEmacs doesn't -- presumably there is a
1176 ;; subtle difference in the two versions of post-command-hook.  The
1177 ;; default is shown for both whenever we delete all of our text
1178 ;; though, indicating its just a problem the first time we enter the
1179 ;; function.  To solve this, we use another entry hook for emacs to
1180 ;; show the default the first time we enter the minibuffer.
1181
1182 (defun iswitchb-init-XEmacs-trick ()
1183   "Display default buffer when first entering minibuffer.
1184 This is a hack for XEmacs, and should really be handled by `iswitchb-exhibit'."
1185   (if (iswitchb-entryfn-p)
1186       (progn
1187         (iswitchb-exhibit)
1188         (goto-char (point-min)))))
1189
1190 ;; add this hook for XEmacs only.
1191 (if (featurep 'xemacs)
1192     (add-hook 'iswitchb-minibuffer-setup-hook
1193               'iswitchb-init-XEmacs-trick))
1194
1195 ;;; XEmacs / backspace key
1196 ;; For some reason, if the backspace key is pressed in XEmacs, the
1197 ;; line gets confused, so I've added a simple key definition to make
1198 ;; backspace act like the normal delete key.
1199
1200 (defun iswitchb-xemacs-backspacekey ()
1201   "Bind backspace to `backward-delete-char'."
1202   (define-key iswitchb-mode-map '[backspace] 'backward-delete-char)
1203   (define-key iswitchb-mode-map '[(meta backspace)] 'backward-kill-word))
1204
1205 (if (featurep 'xemacs)
1206     (add-hook 'iswitchb-define-mode-map-hook
1207               'iswitchb-xemacs-backspacekey))
1208
1209 ;;; ICOMPLETE TYPE CODE
1210
1211 (defun iswitchb-exhibit ()
1212   "Find matching buffers and display a list in the minibuffer.
1213 Copied from `icomplete-exhibit' with two changes:
1214 1. It prints a default buffer name when there is no text yet entered.
1215 2. It calls my completion routine rather than the standard completion."
1216   (if iswitchb-use-mycompletion
1217       (let ((contents (buffer-substring (minibuffer-prompt-end) (point-max)))
1218             (buffer-undo-list t))
1219         (save-excursion
1220           (goto-char (point-max))
1221                                         ; Register the end of input, so we
1222                                         ; know where the extra stuff
1223                                         ; (match-status info) begins:
1224           (if (not (boundp 'iswitchb-eoinput))
1225               ;; In case it got wiped out by major mode business:
1226               (make-local-variable 'iswitchb-eoinput))
1227           (setq iswitchb-eoinput (point))
1228           ;; Update the list of matches
1229           (setq iswitchb-text contents)
1230           (iswitchb-set-matches)
1231           (setq iswitchb-rescan t)
1232           (iswitchb-set-common-completion)
1233
1234           ;; Insert the match-status information:
1235           (insert (iswitchb-completions
1236                    contents))))))
1237
1238 (eval-when-compile
1239   (defvar most-len)
1240   (defvar most-is-exact))
1241
1242 (defun iswitchb-output-completion (com)
1243   (if (= (length com) most-len)
1244       ;; Most is one exact match,
1245       ;; note that and leave out
1246       ;; for later indication:
1247       (ignore
1248        (setq most-is-exact t))
1249     (substring com most-len)))
1250
1251 (defun iswitchb-completions (name)
1252   "Return the string that is displayed after the user's text.
1253 Modified from `icomplete-completions'."
1254
1255   (let ((comps iswitchb-matches)
1256                                         ; "-determined" - only one candidate
1257         (open-bracket-determined "[")
1258         (close-bracket-determined "]")
1259                                         ;"-prospects" - more than one candidate
1260         (open-bracket-prospects "{")
1261         (close-bracket-prospects "}")
1262         first)
1263
1264     (if (and iswitchb-use-faces comps)
1265         (progn
1266           (setq first (car comps))
1267           (setq first (format "%s" first))
1268           (put-text-property 0 (length first) 'face
1269                              (if (= (length comps) 1)
1270                                  (if iswitchb-invalid-regexp
1271                                      'iswitchb-invalid-regexp
1272                                    'iswitchb-single-match)
1273                                'iswitchb-current-match)
1274                              first)
1275           (setq comps  (cons first (cdr comps)))))
1276
1277     ;; If no buffers matched, and virtual buffers are being used, then
1278     ;; consult the list of past visited files, to see if we can find
1279     ;; the file which the user might thought was still open.
1280     (when (and iswitchb-use-virtual-buffers (null comps)
1281                recentf-list)
1282       (setq iswitchb-virtual-buffers nil)
1283       (let ((head recentf-list) name)
1284         (while head
1285           (if (and (setq name (file-name-nondirectory (car head)))
1286                    (string-match (if iswitchb-regexp
1287                                      iswitchb-text
1288                                    (regexp-quote iswitchb-text)) name)
1289                    (null (get-file-buffer (car head)))
1290                    (not (assoc name iswitchb-virtual-buffers))
1291                    (not (iswitchb-ignore-buffername-p name))
1292                    (file-exists-p (car head)))
1293               (setq iswitchb-virtual-buffers
1294                     (cons (cons name (car head))
1295                           iswitchb-virtual-buffers)))
1296           (setq head (cdr head)))
1297         (setq iswitchb-virtual-buffers (nreverse iswitchb-virtual-buffers)
1298               comps (mapcar 'car iswitchb-virtual-buffers))
1299         (let ((comp comps))
1300           (while comp
1301             (put-text-property 0 (length (car comp))
1302                                'face 'iswitchb-virtual-matches
1303                                (car comp))
1304             (setq comp (cdr comp))))))
1305
1306     (cond ((null comps) (format " %sNo match%s"
1307                                 open-bracket-determined
1308                                 close-bracket-determined))
1309
1310           (iswitchb-invalid-regexp
1311            (concat " " (car comps)))
1312           ((null (cdr comps))           ;one match
1313            (concat
1314             (if (if (not iswitchb-regexp)
1315                     (= (length name)
1316                        (length (car comps)))
1317                   (string-match name (car comps))
1318                   (string-equal (match-string 0 (car comps))
1319                                 (car comps)))
1320                 ""
1321               (concat open-bracket-determined
1322                                ;; when there is one match, show the
1323                                ;; matching buffer name in full
1324                                (car comps)
1325                                close-bracket-determined))
1326                    (if (not iswitchb-use-faces) " [Matched]")))
1327           (t                            ;multiple matches
1328            (if (and iswitchb-max-to-show
1329                     (> (length comps) iswitchb-max-to-show))
1330                (setq comps
1331                      (append
1332                       (let ((res nil)
1333                             (comp comps)
1334                             (end (/ iswitchb-max-to-show 2)))
1335                         (while (>= (setq end (1- end)) 0)
1336                           (setq res (cons (car comp) res)
1337                                 comp (cdr comp)))
1338                         (nreverse res))
1339                       (list "...")
1340                       (nthcdr (- (length comps)
1341                                  (/ iswitchb-max-to-show 2)) comps))))
1342            (let* (
1343                   ;;(most (try-completion name candidates predicate))
1344                   (most nil)
1345                   (most-len (length most))
1346                   most-is-exact
1347                   (alternatives
1348                    (mapconcat (if most 'iswitchb-output-completion
1349                                 'identity) comps ",")))
1350
1351              (concat
1352
1353               ;; put in common completion item -- what you get by
1354               ;; pressing tab
1355               (if (and (stringp iswitchb-common-match-string)
1356                        (> (length iswitchb-common-match-string) (length name)))
1357                   (concat open-bracket-determined
1358                           (substring iswitchb-common-match-string
1359                                      (length name))
1360                           close-bracket-determined))
1361               ;; end of partial matches...
1362
1363               ;; think this bit can be ignored.
1364               (and (> most-len (length name))
1365                    (concat open-bracket-determined
1366                            (substring most (length name))
1367                            close-bracket-determined))
1368
1369               ;; list all alternatives
1370               open-bracket-prospects
1371               (if most-is-exact
1372                   (concat "," alternatives)
1373                 alternatives)
1374               close-bracket-prospects))))))
1375
1376 (defun iswitchb-minibuffer-setup ()
1377   "Set up minibuffer for `iswitchb-buffer'.
1378 Copied from `icomplete-minibuffer-setup-hook'."
1379   (when (iswitchb-entryfn-p)
1380     (set (make-local-variable 'iswitchb-use-mycompletion) t)
1381     (add-hook 'pre-command-hook 'iswitchb-pre-command nil t)
1382     (add-hook 'post-command-hook 'iswitchb-post-command nil t)
1383     (run-hooks 'iswitchb-minibuffer-setup-hook)))
1384
1385 (defun iswitchb-pre-command ()
1386   "Run before command in `iswitchb-buffer'."
1387   (iswitchb-tidy))
1388
1389 (defun iswitchb-post-command ()
1390   "Run after command in `iswitchb-buffer'."
1391   (iswitchb-exhibit))
1392
1393 (defun iswitchb-tidy ()
1394   "Remove completions display, if any, prior to new user input.
1395 Copied from `icomplete-tidy'."
1396
1397   (if (and (boundp 'iswitchb-eoinput)
1398            iswitchb-eoinput)
1399
1400       (if (> iswitchb-eoinput (point-max))
1401           ;; Oops, got rug pulled out from under us - reinit:
1402           (setq iswitchb-eoinput (point-max))
1403         (let ((buffer-undo-list buffer-undo-list )) ; prevent entry
1404           (delete-region iswitchb-eoinput (point-max))))
1405
1406     ;; Reestablish the local variable 'cause minibuffer-setup is weird:
1407     (make-local-variable 'iswitchb-eoinput)
1408     (setq iswitchb-eoinput 1)))
1409
1410 (defun iswitchb-entryfn-p ()
1411   "Return non-nil if we are using `iswitchb-buffer'."
1412   (eq iswitchb-minibuf-depth (minibuffer-depth)))
1413
1414 (defun iswitchb-summaries-to-end ()
1415   "Move the summaries to the end of the list.
1416 This is an example function which can be hooked on to
1417 `iswitchb-make-buflist-hook'.  Any buffer matching the regexps
1418 `Summary' or `output\*$'are put to the end of the list."
1419   (let ((summaries (delq nil
1420                          (mapcar
1421                           (lambda (x)
1422                             (if (string-match "Summary\\|output\\*$" x)
1423                                 x))
1424                           iswitchb-temp-buflist))))
1425     (iswitchb-to-end summaries)))
1426
1427 (defun iswitchb-case ()
1428   "Return non-nil if we should ignore case when matching.
1429 See the variable `iswitchb-case' for details."
1430   (if iswitchb-case
1431       (if (featurep 'xemacs)
1432           (isearch-no-upper-case-p iswitchb-text)
1433         (isearch-no-upper-case-p iswitchb-text t))))
1434
1435 ;;;###autoload
1436 (define-minor-mode iswitchb-mode
1437   "Toggle Iswitchb global minor mode.
1438 With arg, turn Iswitchb mode on if ARG is positive, otherwise turn it off.
1439 This mode enables switching between buffers using substrings.  See
1440 `iswitchb' for details."
1441   nil nil iswitchb-global-map :global t :group 'iswitchb
1442   (if iswitchb-mode
1443       (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)
1444     (remove-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)))
1445
1446 (provide 'iswitchb)
1447
1448 ;; arch-tag: d74198ae-753f-44f2-b34f-0c515398d90a
1449 ;;; iswitchb.el ends here