lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.ai.mit.edu>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For those who are annoyed by the mouse pointer obscuring text,
  28 ;; this mode moves the mouse pointer - either just a little out of
  29 ;; the way, or all the way to the corner of the frame.
  30 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31 ;; To set up permanently, put the following in your .emacs:
  32 ;;
  33 ;; (if window-system (mouse-avoidance-mode 'animate))
  34 ;;
  35 ;; The 'animate can be 'jump or 'banish or 'exile or 'protean if you prefer.
  36 ;; See the documentation for function `mouse-avoidance-mode' for
  37 ;; details of the different modes.
  38 ;;
  39 ;; For added silliness, make the animatee animate...
  40 ;; put something similar to the following into your .emacs:
  41 ;;
  42 ;; (if window-system
  43 ;;     (mouse-avoidance-set-pointer-shape
  44 ;;           (eval (nth (random 4)
  45 ;;                      '(x-pointer-man x-pointer-spider
  46 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  47 ;;
  48 ;; For completely random pointer shape, replace the setq above with:
  49 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  50 ;;
  51 ;; Bugs / Warnings / To-Do:
  52 ;;
  53 ;; - Using this code does slow emacs down.  "banish" mode shouldn't
  54 ;;   be too bad, and on my workstation even "animate" is reasonable.
  55 ;;
  56 ;; - It ought to find out where any overlapping frames are and avoid them,
  57 ;;   rather than always raising the frame.
  58
  59 ;; Credits:
  60 ;; This code was helped by all those who contributed suggestions,
  61 ;;   fixes, and additions
  62 ;; Joe Harrington (and his advisor), for the original inspiration.
  63 ;; Ken Manheimer, for dreaming up the Protean mode.
  64 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  65 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  66 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  67
  68 ;;; Code:
  69
  70 (provide 'avoid)
  71
  72 (defvar mouse-avoidance-mode nil
  73   "Value is t or a symbol if the mouse pointer should avoid the cursor.
  74 See function `mouse-avoidance-mode' for possible values.  Changing this
  75 variable is NOT the recommended way to change modes; use that function
  76 instead.")
  77
  78 (defvar mouse-avoidance-nudge-dist 15
  79   "*Average distance that mouse will be moved when approached by cursor.
  80 Only applies in mouse-avoidance-mode `jump' and its derivatives.
  81 For best results make this larger than `mouse-avoidance-threshold'.")
  82
  83 (defvar mouse-avoidance-nudge-var 10
  84   "*Variability of `mouse-avoidance-nudge-dist' (which see).")
  85
  86 (defvar mouse-avoidance-animation-delay .01
  87   "Delay between animation steps, in seconds.")
  88
  89 (defvar mouse-avoidance-threshold 5
  90   "*Mouse-pointer's flight distance.
  91 If the cursor gets closer than this, the mouse pointer will move away.
  92 Only applies in mouse-avoidance-modes `animate' and `jump'.")
  93
  94 ;; Internal variables
  95 (defvar mouse-avoidance-state nil)
  96 (defvar mouse-avoidance-pointer-shapes nil)
  97 (defvar mouse-avoidance-n-pointer-shapes 0)
  98 (defvar mouse-avoidance-old-pointer-shape nil)
  99
 100 ;;; Functions:
 101
 102 (defsubst mouse-avoidance-set-pointer-shape (shape)
 103   "Set the shape of the mouse pointer to SHAPE."
 104   (setq x-pointer-shape shape)
 105   (set-mouse-color nil))
 106
 107 (defun mouse-avoidance-point-position ()
 108   "Return the position of point as (FRAME X . Y).
 109 Analogous to mouse-position."
 110   (let* ((w (selected-window))
 111          (edges (window-edges w))
 112          (list
 113           (compute-motion (max (window-start w) (point-min))   ; start pos
 114                           ;; window-start can be < point-min if the
 115                           ;; latter has changed since the last redisplay
 116                           '(0 . 0)                             ; start XY
 117                           (point)                              ; stop pos
 118                           (cons (window-width) (window-height)); stop XY: none
 119                           (1- (window-width))                  ; width
 120                           (cons (window-hscroll w) 0)          ; 0 may not be right?
 121                           (selected-window))))
 122     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
 123     ;; we want:               (frame hpos . vpos)
 124     (cons (selected-frame)
 125           (cons (+ (car edges)       (car (cdr list)))
 126                 (+ (car (cdr edges)) (car (cdr (cdr list))))))))
 127
 128 ;(defun mouse-avoidance-point-position-test ()
 129 ;  (interactive)
 130 ;  (message (format "point=%s mouse=%s"
 131 ;                  (cdr (mouse-avoidance-point-position))
 132 ;                  (cdr (mouse-position)))))
 133
 134 (defun mouse-avoidance-set-mouse-position (pos)
 135   ;; Carefully set mouse position to given position (X . Y)
 136   ;; Ideally, should check if X,Y is in the current frame, and if not,
 137   ;; leave the mouse where it was.  However, this is currently
 138   ;; difficult to do, so we just raise the frame to avoid frame switches.
 139   ;; Returns t if it moved the mouse.
 140   (let ((f (selected-frame)))
 141     (raise-frame f)
 142     (set-mouse-position f (car pos) (cdr pos))
 143     t))
 144
 145 (defun mouse-avoidance-too-close-p (mouse)
 146   ;;  Return t if mouse pointer and point cursor are too close.
 147   ;; Acceptable distance is defined by mouse-avoidance-threshold.
 148   (let ((point (mouse-avoidance-point-position)))
 149     (and (eq (car mouse) (car point))
 150          (car (cdr mouse))
 151          (< (abs (- (car (cdr mouse)) (car (cdr point))))
 152             mouse-avoidance-threshold)
 153          (< (abs (- (cdr (cdr mouse)) (cdr (cdr point))))
 154             mouse-avoidance-threshold))))
 155
 156 (defun mouse-avoidance-banish-destination ()
 157   "The position to which mouse-avoidance-mode `banish' moves the mouse.
 158 You can redefine this if you want the mouse banished to a different corner."
 159  (cons (1- (frame-width))
 160        0))
 161
 162 (defun mouse-avoidance-banish-mouse ()
 163   ;; Put the mouse pointer in the upper-right corner of the current frame.
 164   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 165
 166 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 167   ;; Decide how far to move in either dimension.
 168   ;; Args are the CURRENT location, the desired DELTA for
 169   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 170   ;; in distance allowed, and the MIN and MAX possible window positions.
 171   ;; Returns something as close to DELTA as possible within the constraints.
 172   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 173         (R1                  (+ (- dist)    var ))
 174         (L2                  (+    dist  (- var)))
 175         (R2 (min (- max cur) (+    dist     var))))
 176     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 177     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 178     (cond ((and L1 (< delta L1)) L1)
 179           ((and R1 (< delta R1)) delta)
 180           ((and R1 (< delta 0)) R1)
 181           ((and L2 (< delta L2)) L2)
 182           ((and R2 (< delta R2)) delta)
 183           (R2)
 184           ((or R1 L2))
 185           (t 0))))
 186
 187 (defun mouse-avoidance-nudge-mouse ()
 188   ;; Push the mouse a little way away, possibly animating the move
 189   ;; For these modes, state keeps track of the total offset that we've
 190   ;; accumulated, and tries to keep it close to zero.
 191   (let* ((cur (mouse-position))
 192          (cur-frame (car cur))
 193          (cur-pos (cdr cur))
 194          (deltax (mouse-avoidance-delta
 195                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 196                                    (car mouse-avoidance-state))
 197                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 198                   0 (frame-width)))
 199          (deltay (mouse-avoidance-delta
 200                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 201                                    (cdr mouse-avoidance-state))
 202                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 203                   0 (frame-height))))
 204     (setq mouse-avoidance-state
 205           (cons (+ (car mouse-avoidance-state) deltax)
 206                 (+ (cdr mouse-avoidance-state) deltay)))
 207     (if (or (eq mouse-avoidance-mode 'animate)
 208             (eq mouse-avoidance-mode 'proteus))
 209         (let ((i 0.0))
 210           (while (<= i 1)
 211             (mouse-avoidance-set-mouse-position
 212              (cons (+ (car cur-pos) (round (* i deltax)))
 213                    (+ (cdr cur-pos) (round (* i deltay)))))
 214             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 215             (if (eq mouse-avoidance-mode 'proteus)
 216                 (mouse-avoidance-set-pointer-shape
 217                  (mouse-avoidance-random-shape)))
 218             (sit-for mouse-avoidance-animation-delay)))
 219       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 220                                                 (+ (cdr (cdr cur)) deltay))))))
 221
 222 (defun mouse-avoidance-random-shape ()
 223   "Return a random cursor shape.
 224 This assumes that any variable whose name begins with x-pointer- and
 225 has an integer value is a valid cursor shape.  You might want to
 226 redefine this function to suit your own tastes."
 227   (if (null mouse-avoidance-pointer-shapes)
 228       (progn
 229         (setq mouse-avoidance-pointer-shapes
 230               (mapcar '(lambda (x) (symbol-value (intern x)))
 231                       (all-completions "x-pointer-" obarray
 232                                        '(lambda (x)
 233                                           (and (boundp x)
 234                                                (integerp (symbol-value x)))))))
 235         (setq mouse-avoidance-n-pointer-shapes
 236               (length mouse-avoidance-pointer-shapes))))
 237   (nth (random mouse-avoidance-n-pointer-shapes)
 238        mouse-avoidance-pointer-shapes))
 239
 240 (defun mouse-avoidance-banish-hook ()
 241   (if (and (not executing-kbd-macro)    ; don't check inside macro
 242            (mouse-avoidance-kbd-command (this-command-keys)))
 243       (mouse-avoidance-banish-mouse)))
 244
 245 (defun mouse-avoidance-exile-hook ()
 246   ;; For exile mode, the state is nil when the mouse is in its normal
 247   ;; position, and set to the old mouse-position when the mouse is in exile.
 248   (if (and (not executing-kbd-macro)
 249            (mouse-avoidance-kbd-command (this-command-keys)))
 250       (let ((mp (mouse-position)))
 251         (cond ((and (not mouse-avoidance-state)
 252                     (mouse-avoidance-too-close-p mp))
 253                (setq mouse-avoidance-state mp)
 254                (mouse-avoidance-banish-mouse))
 255               ((and mouse-avoidance-state
 256                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 257                (if (and (eq (car mp) (selected-frame))
 258                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 259                    (mouse-avoidance-set-mouse-position
 260                     ;; move back only if user has not moved mouse
 261                     (cdr mouse-avoidance-state)))
 262                ;; but clear state anyway, to be ready for another move
 263                (setq mouse-avoidance-state nil))))))
 264
 265 (defun mouse-avoidance-fancy-hook ()
 266   ;; Used for the "fancy" modes, ie jump et al.
 267   (if (and (not executing-kbd-macro)    ; don't check inside macro
 268            (mouse-avoidance-kbd-command (this-command-keys))
 269            (mouse-avoidance-too-close-p (mouse-position)))
 270       (let ((old-pos (mouse-position)))
 271         (mouse-avoidance-nudge-mouse)
 272         (if (not (eq (selected-frame) (car old-pos)))
 273             ;; This should never happen.
 274             (apply 'set-mouse-position old-pos)))))
 275
 276 (defun mouse-avoidance-kbd-command (key)
 277   "Return t if the KEYSEQENCE is composed of keyboard events only.
 278 Return nil if there are any lists in the key sequence."
 279   (cond ((null key) nil)                ; Null event seems to be
 280                                         ; returned occasionally.
 281         ((not (vectorp key)) t)         ; Strings are keyboard events.
 282         ((catch 'done
 283            (let ((i 0)
 284                  (l (length key)))
 285              (while (< i l)
 286                (if (listp (aref key i))
 287                    (throw 'done nil))
 288                (setq i (1+ i))))
 289            t))))
 290
 291 ;;;###autoload
 292 (defun mouse-avoidance-mode (&optional mode)
 293   "Set cursor avoidance mode to MODE.
 294 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 295 `cat-and-mouse', `proteus', or `none'.
 296
 297 If MODE is nil, toggle mouse avoidance between `none` and `banish'
 298 modes.  Positive numbers and symbols other than the above are treated
 299 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 300
 301 Effects of the different modes:
 302  * banish: Move the mouse to the upper-right corner on any keypress.
 303  * exile: Move the mouse to the corner only if the cursor gets too close,
 304      and allow it to return once the cursor is out of the way.
 305  * jump: If the cursor gets too close to the mouse, displace the mouse
 306      a random distance & direction.
 307  * animate: As `jump', but shows steps along the way for illusion of motion.
 308  * cat-and-mouse: Same as `animate'.
 309  * proteus: As `animate', but changes the shape of the mouse pointer too.
 310
 311 Whenever the mouse is moved, the frame is also raised.
 312
 313 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 314 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 315 definition of \"random distance\".)"
 316   (interactive
 317    (list (intern (completing-read
 318                   "Select cursor avoidance technique (SPACE for list): "
 319                   '(("banish") ("exile") ("jump") ("animate")
 320                     ("cat-and-mouse") ("proteus") ("none"))
 321                   nil t))))
 322   (if (eq mode 'cat-and-mouse)
 323       (setq mode 'animate))
 324   (remove-hook 'post-command-idle-hook 'mouse-avoidance-banish-hook)
 325   (remove-hook 'post-command-idle-hook 'mouse-avoidance-exile-hook)
 326   (remove-hook 'post-command-idle-hook 'mouse-avoidance-fancy-hook)
 327
 328   ;; Restore pointer shape if necessary
 329   (if (eq mouse-avoidance-mode 'proteus)
 330       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 331
 332   ;; Do additional setup depending on version of mode requested
 333   (cond ((eq mode 'none)
 334          (setq mouse-avoidance-mode nil))
 335         ((or (eq mode 'jump)
 336              (eq mode 'animate)
 337              (eq mode 'proteus))
 338          (add-hook 'post-command-idle-hook 'mouse-avoidance-fancy-hook)
 339          (setq mouse-avoidance-mode mode
 340                mouse-avoidance-state (cons 0 0)
 341                mouse-avoidance-old-pointer-shape x-pointer-shape))
 342         ((eq mode 'exile)
 343          (add-hook 'post-command-idle-hook 'mouse-avoidance-exile-hook)
 344          (setq mouse-avoidance-mode mode
 345                mouse-avoidance-state nil))
 346         ((or (eq mode 'banish)
 347              (eq mode t)
 348              (and (null mode) (null mouse-avoidance-mode))
 349              (and mode (> (prefix-numeric-value mode) 0)))
 350          (add-hook 'post-command-idle-hook 'mouse-avoidance-banish-hook)
 351          (setq mouse-avoidance-mode 'banish))
 352         (t (setq mouse-avoidance-mode nil)))
 353   (force-mode-line-update))
 354
 355 (or (assq 'mouse-avoidance-mode minor-mode-alist)
 356     (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 357                                  minor-mode-alist)))
 358
 359 ;;; End of avoid.el